;;; murk.el --- Multiserver Unibuffer iRc Klient -*- lexical-binding:t -*-

;; Copyright (C) 2024 plugd

;; Author: plugd <plugd@thelambdalab.xyz>
;; Created: 11 May 2024
;; Version: 0.0
;; Homepage: http://thelambdalab.xyz/murk
;; Keywords: comm
;; Package-Requires: ((emacs "26.1"))

;; This file is not part of GNU Emacs.

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this file.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; A very simple IRC server which uses only a single buffer.

;;; Code:

(provide 'murk)

(require 'cl-lib)


;;; Customizations

(defgroup murk nil
  "Multiserver Unibuffer iRc Klient"
  :group 'network)

(defcustom murk-default-nick "plugd"
  "Default nick."
  :type '(string))

(defcustom murk-default-quit-msg "Bye"
  "Default quit message when none supplied."
  :type '(string))

(defcustom murk-networks
  '(("debug" "localhost" 6697)
    ("libera" "irc.libera.chat" 6697)
    ("tilde" "tilde.chat" 6697)
    ("sdf" "irc.sdf.org" 6697)
    ("freenode" "chat.freenode.net" 6697)
    ("mbr" "mbrserver.com" 6667 :notls))
  "IRC networks."
  :type '(alist :key-type string))

(defcustom murk-show-joins nil
  "Set to non-nil to be notified of joins, parts and quits.")

(defcustom murk-display-header t
  "If non-nil, use buffer header to display current host and channel."
  :type '(boolean))

(defcustom murk-autoreply-table nil
  "Table of autoreply messages.

Each autoreply is a list of two elements: (matcher reply)

Here matcher is a list:

(network src cmd params ...)

and reply is another list:

 (cmd params ...)

Each entry in the matcher list is a regular expression tested against the
corresponding values in the incomming message.  Entries can be nil,
in which case they match anything."
  :type '(list (list) (list)))


;;; Faces
;;

(defface murk-text
  '((t :inherit default))
  "Face used for murk text.")

(defface murk-prompt
  '((t :inherit font-lock-keyword-face))
  "Face used for the prompt.")

(defface murk-context
  '((t :inherit murk-context))
  "Face used for the context name in the prompt.")

(defface murk-faded
  '((t :inherit shadow))
  "Face used for faded murk text.")

(defface murk-timestamp
  '((t :inherit shadow))
  "Face used for timestamps.")

(defface murk-error
  '((t :inherit error))
  "Face used for murk error text.")

(defface murk-notice
  '((t :inherit warning))
  "Face used for murk notice text.")


;;; Global variables
;;

(defvar murk-version "Murk v0.0"
  "Value of this string is used in response to CTCP version queries.")

(defvar murk-notice-prefix "-!-")
(defvar murk-error-prefix "!!!")
(defvar murk-prompt-string ">")

(defvar murk-debug nil
  "If non-nil, enable debug mode.")


;;; Utility procedures
;;

(defun murk--filtered-join (&rest args)
  (string-join (seq-filter (lambda (el) el) args) " "))

(defun murk--as-string (obj)
  (if obj
      (with-output-to-string (princ obj))
    nil))


;;; Network processes
;;

(defvar murk-connection-table nil
  "An alist associating servers to connection information.
This includes the process and the response string.")

(defun murk-connection-process (server)
  (elt (assoc server murk-connection-table) 1))

(defun murk-connection-nick (server)
  (elt (assoc server murk-connection-table) 2))

(defun murk-set-connection-nick (server nick)
  (setf (elt (assoc server murk-connection-table) 2) nick))

(defun murk-connection-response (server)
  (elt (assoc server murk-connection-table) 3))

(defun murk-set-connection-response (server string)
  (setf (elt (assoc server murk-connection-table) 3) string))

(defun murk-connection-new (server process nick)
  (add-to-list 'murk-connection-table
               (list server process nick "")))

(defun murk-connection-remove (server)
  (setq murk-connection-table
        (seq-remove (lambda (row) (equal (car row) server))
                    murk-connection-table)))

(defun murk-make-server-filter (server)
  (lambda (_proc string)
    (dolist (line (split-string (concat (murk-connection-response server) string)
                                "\n"))
      (if (string-suffix-p "\r" line)
          (murk-eval-msg-string server (string-trim line))
        (murk-set-connection-response server line)))))

(defun murk-make-server-sentinel (server)
  (lambda (_proc string)
    (unless (equal "open" (string-trim string))
      (murk-display-error "Disconnected from server.")
      (murk-connection-remove server)
      (murk-remove-server-contexts server)
      (murk-highlight-current-context)
      (murk-render-prompt))))

(defun murk-start-process (server)
  (let* ((row (assoc server murk-networks))
         (host (elt row 1))
         (port (elt row 2))
         (flags (seq-drop row 3)))
    (make-network-process :name (concat "murk-" server)
                          :host host
                          :service port
                          :family nil
                          :filter (murk-make-server-filter server)
                          :sentinel (murk-make-server-sentinel server)
                          :nowait nil
                          :tls-parameters (if (memq :notls flags)
                                              nil
                                            (cons 'gnutls-x509pki
                                                  (gnutls-boot-parameters
                                                   :type 'gnutls-x509pki
                                                   :hostname host)))
                          :buffer "*murk*")))

(defvar murk-ping-period 60)

;; IDEA: Have a single ping timer which pings all connected hosts

(defun murk-connect (server)
  (if (assoc server murk-connection-table)
      (murk-display-error "Already connected to this network")
    (if (not (assoc server murk-networks))
        (murk-display-error "Network '" server "' is unknown.")
      (let ((proc (murk-start-process server)))
        (murk-connection-new server proc murk-default-nick))
      (murk-send-msg server (murk-msg nil nil "USER" murk-default-nick 0 "*" murk-default-nick))
      (murk-send-msg server (murk-msg nil nil "NICK" murk-default-nick))
      (murk-add-context (list server))
      (murk-highlight-current-context)
      (murk-render-prompt))))

(defun murk-send-msg (server msg)
  (if murk-debug
      (murk-display-string nil nil (murk-msg->string msg)))
  (let ((proc (murk-connection-process server)))
    (if (and proc (eq (process-status proc) 'open))
        (process-send-string proc (concat (murk-msg->string msg) "\r\n"))
      (murk-display-error "No server connection established"))))


;;; Server messages
;;

(defun murk-msg (tags src cmd &rest params)
  (list (murk--as-string tags)
        (murk--as-string src)
        (upcase (murk--as-string cmd))
        (mapcar #'murk--as-string
                (if (and params (listp (elt params 0)))
                    (elt params 0)
                  params))))

(defun murk-msg-tags (msg) (elt msg 0))
(defun murk-msg-src (msg) (elt msg 1))
(defun murk-msg-cmd (msg) (elt msg 2))
(defun murk-msg-params (msg) (elt msg 3))
(defun murk-msg-trail (msg)
  (let ((params (murk-msg-params msg)))
    (if params
        (elt params (- (length params) 1)))))

(defvar murk-msg-regex
  (rx
   (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
        (* whitespace))
   (opt (: ":" (: (group (* (not (any space "!" "@"))))
                  (* (not (any space)))))
        (* whitespace))
   (group (: (* (not whitespace))))
   (* whitespace)
   (opt (group (+ not-newline))))
  "Regex used to parse IRC messages.
Note that this regex is incomplete.  Noteably, we discard the non-nick
portion of the source component of the message, as mURK doesn't use this.")

(defun murk-string->msg (string)
  (if (string-match murk-msg-regex string)
      (let* ((tags (match-string 1 string))
             (src (match-string 2 string))
             (cmd (upcase (match-string 3 string)))
             (params-str (match-string 4 string))
             (params
              (if params-str
                  (let* ((idx (seq-position params-str ?:))
                         (l (split-string (string-trim (substring params-str 0 idx))))
                         (r (if idx (list (substring params-str (+ 1 idx))) nil)))
                    (append l r))
                nil)))
        (apply #'murk-msg (append (list tags src cmd) params)))
    (error "Failed to parse string %s" string)))

(defun murk-msg->string (msg)
  (let ((tags (murk-msg-tags msg))
        (src (murk-msg-src msg))
        (cmd (murk-msg-cmd msg))
        (params (murk-msg-params msg)))
    (murk--filtered-join
     (if tags (concat "@" tags) nil)
     (if src (concat ":" src) nil)
     cmd
     (if (> (length params) 1)
         (string-join (seq-take params (- (length params) 1)) " ")
       nil)
     (if (> (length params) 0)
         (concat ":" (elt params (- (length params) 1)))
       nil))))


;;; Contexts
;;

;; A context is a list (server channel users) identifying the server
;; and channel.  The tail of the list contains the nicks of users
;; present in the channel.
;;
;; Each server has a special context (server) used for messages
;; to/from the server itself.

(defvar murk-contexts nil
  "List of currently-available contexts.
The head of this list is always the current context.")

(defun murk-current-context ()
  "Return the current context."
  (if murk-contexts
      (car murk-contexts)
    nil))

(defun murk-contexts-equal (c1 c2)
  (if (murk-server-context-p c1)
      (and (murk-server-context-p c2)
           (equal (murk-context-server c1)
                  (murk-context-server c2)))
    (and (not (murk-server-context-p c2))
         (equal (seq-take c1 2)
                (seq-take c2 2)))))

(defun murk-context-server (ctx)
  (elt ctx 0))

(defun murk-context-channel (ctx)
  (elt ctx 1))

(defun murk-context-users (ctx)
  (elt ctx 2))

(defun murk-set-context-users (ctx users)
  (setcar (cddr ctx) users))

(defun murk-server-context-p (ctx)
  (not (cdr ctx)))

(defun murk-add-context (ctx)
  (add-to-list 'murk-contexts ctx))

(defun murk-remove-context (ctx)
  (setq murk-contexts
        (seq-remove
         (lambda (this-ctx)
           (murk-contexts-equal this-ctx ctx))
         murk-contexts)))

(defun murk-remove-server-contexts (server)
  (setq murk-contexts
        (seq-remove (lambda (row) (equal (car row) server))
                    murk-contexts)))

(defun murk-context->string (ctx)
   (if (murk-server-context-p ctx)
       (concat "[" (murk-context-server ctx) "]")
     (concat (murk-context-channel ctx) "@"
             (murk-context-server ctx))))

(defun murk-string->context (string)
  (if (not (string-prefix-p "#" string))
      (murk-get-context string)
    (let* ((parts (string-split string "@"))
           (channel (elt parts 0))
           (server (elt parts 1)))
      (murk-get-context server channel))))

(defun murk-get-context (server &optional channel)
  (if (and channel (string-prefix-p "#" channel))
      (let ((test-ctx (list server channel)))
        (seq-find (lambda (ctx)
                    (equal (seq-take ctx 2) test-ctx))
                  murk-contexts))
    (car (member (list server) murk-contexts))))

(defun murk-cycle-contexts (&optional reverse)
  (setq murk-contexts
        (if reverse
            (let ((nminus1 (- (length murk-contexts) 1)))
              (cons
               (elt murk-contexts nminus1)
               (seq-take murk-contexts nminus1)))
          (append (cdr murk-contexts) (list (car murk-contexts))))))

(defun murk-switch-to-context (ctx)
  (setq murk-contexts
        (let* ((new-head (memq ctx murk-contexts))
               (new-tail (take (- (length murk-contexts)
                                  (length new-head)))))
          (append new-head new-tail))))

(defun murk-add-context-users (ctx users)
  (murk-set-context-users
   ctx
   (cl-union users (murk-context-users ctx))))

(defun murk-del-context-user (ctx user)
  (murk-set-context-users
   ctx
   (delete user (murk-context-users ctx))))

(defun murk-del-server-user (server user)
  (dolist (ctx murk-contexts)
    (if (and (equal (murk-context-server ctx) server)
             (not (murk-server-context-p ctx)))
        (murk-del-context-user ctx user))))

(defun murk-rename-server-user (server old-nick new-nick)
  (dolist (ctx murk-contexts)
    (when (and (equal (murk-context-server ctx) server)
               (member old-nick (murk-context-users ctx)))
      (murk-del-context-user ctx old-nick)
      (murk-add-context-users ctx (list new-nick)))))

;;; Buffer
;;

(defvar murk-prompt-marker nil
  "Marker for prompt position in murk buffer.")

(defvar murk-input-marker nil
  "Marker for prompt position in murk buffer.")

(defun murk-render-prompt ()
  (with-current-buffer "*murk*"
    (let ((update-point (= murk-input-marker (point)))
          (update-window-points (mapcar (lambda (w)
                                          (list (= (window-point w) murk-input-marker)
                                                w))
                                        (get-buffer-window-list nil nil t))))
      (save-excursion
        (set-marker-insertion-type murk-prompt-marker nil)
        (set-marker-insertion-type murk-input-marker t)
        (let ((inhibit-read-only t))
          (delete-region murk-prompt-marker murk-input-marker)
          (goto-char murk-prompt-marker)
          (insert
           (propertize (let ((ctx (murk-current-context)))
                         (if ctx
                             (murk-context->string ctx)
                           ""))
                       'face 'murk-context
                       'read-only t)
           (propertize murk-prompt-string
                       'face 'murk-prompt
                       'read-only t)
           (propertize " " ; Need this to be separate to mark it as rear-nonsticky
                       'read-only t
                       'rear-nonsticky t)))
        (set-marker-insertion-type murk-input-marker nil))
      (if update-point
          (goto-char murk-input-marker))
      (dolist (v update-window-points)
        (if (car v)
            (set-window-point (cadr v) murk-input-marker))))))
  
(defun murk-setup-header ()
  (with-current-buffer "*murk*"
    (setq-local header-line-format
                '((:eval
                   (let* ((ctx (murk-current-context)))
                     (if ctx
                         (let ((server (murk-context-server ctx)))
                           (concat
                            "Network: " server ", "
                            (if (murk-server-context-p ctx)
                                "Server"
                              (concat
                               "Channel: "
                               (murk-context-channel ctx)
                               " ("
                               (number-to-string
                                (length (murk-context-users ctx)))
                               ")"))))
                       "No connection")))))))

(defun murk-setup-buffer ()
  (with-current-buffer (get-buffer-create "*murk*")
    (setq-local scroll-conservatively 1)
    (setq-local buffer-invisibility-spec nil)
    (if (markerp murk-prompt-marker)
        (set-marker murk-prompt-marker (point-max))
      (setq murk-prompt-marker (point-max-marker)))
    (if (markerp murk-input-marker)
        (set-marker murk-input-marker (point-max))
      (setq murk-input-marker (point-max-marker)))
    (goto-char (point-max))
    (murk-highlight-current-context)
    (murk-render-prompt)
    (if murk-display-header
        (murk-setup-header))))

(defun murk-clear-buffer ()
  "Completely erase all non-prompt and non-input text from murk buffer."
  (with-current-buffer "*murk*"
    (let ((inhibit-read-only t))
      (delete-region (point-min) murk-prompt-marker))))


;;; Output formatting and highlighting
;;

;; Idea: the face text property can be a list of faces, applied in
;; order.  By assigning each context a unique list and keeping track
;; of these in a hash table, we can easily switch the face
;; corresponding to a particular context by modifying the elements of
;; this list.
;;
;; More subtly, we make only the cdrs of this list shared among
;; all text of a given context, allowing the cars to be different
;; and for different elements of the context-specific text to have
;; different styling.

;; Additionally, we allow selective hiding of contexts via
;; the buffer-invisibility-spec.

(defvar murk-context-facelists (make-hash-table :test 'equal)
  "List of seen contexts and associated face lists.")

(defun murk-get-context-facelist (context)
  (let* ((short-ctx (take 2 context))
         (facelist (gethash short-ctx murk-context-facelists)))
    (unless facelist
      (setq facelist (list 'murk-text))
      (puthash short-ctx facelist murk-context-facelists))
    facelist))

(defun murk--fill-strings (col indent &rest strings)
  (with-temp-buffer
    (setq buffer-invisibility-spec nil)
    (let ((fill-column col)
          (adaptive-fill-regexp (rx-to-string `(= ,indent anychar))))
      (apply #'insert strings)
      (fill-region (point-min) (point-max) nil t)
      (buffer-string))))

(defun murk-display-string (context prefix &rest strings)
  (with-current-buffer "*murk*"
    (save-excursion
      (goto-char murk-prompt-marker)
      (let* ((inhibit-read-only t)
             (old-pos (marker-position murk-prompt-marker))
             (padded-timestamp (concat (format-time-string "%H:%M ")))
             (padded-prefix (if prefix (concat prefix " ") ""))
             (short-ctx (take 2 context))
             (context-atom (if short-ctx
                               (intern (murk-context->string short-ctx))
                             nil))
             (context-face (murk-get-context-facelist short-ctx)))
        (insert-before-markers
         (murk--fill-strings
          80
          (+ (length padded-timestamp)
             (length padded-prefix))
          (propertize padded-timestamp
                      'face 'murk-timestamp
                      'read-only t
                      'context short-ctx
                      'invisible context-atom)
          (propertize padded-prefix
                      'read-only t
                      'context short-ctx
                      'invisible context-atom)
          (murk-add-formatting
           (propertize (concat (apply #'murk-buttonify-urls strings) "\n")
                       'face context-face
                       'read-only t
                       'context short-ctx
                       'invisible context-atom)))))))
  (murk-scroll-windows-to-last-line))

(defun murk-display-message (server from to text)
  (let ((context (if (string-prefix-p "#" to)
                     (murk-get-context server to)
                   (murk-get-context server))))
    (murk-display-string
     context
     (propertize
      (if (murk-server-context-p context)
          (concat "[" from "->" to "]")
        (concat (murk-context->string context) " <" from ">"))
      'face (murk-get-context-facelist context))
     text)))

(defun murk-display-action (server from to action-text)
  (let ((context (if (string-prefix-p "#" to)
                     (murk-get-context server to)
                   (murk-get-context server))))
    (murk-display-string
     context
     (propertize
      (concat (murk-context->string context) " *")
      'face (murk-get-context-facelist context))
     from " " action-text)))

(defun murk-display-notice (context &rest notices)
  (murk-display-string
   context
   (propertize murk-notice-prefix 'face 'murk-notice)
   (apply #'concat notices)))

(defun murk-display-error (&rest messages)
  (murk-display-string
   nil
   (propertize murk-error-prefix 'face 'murk-error)
   (apply #'concat messages)))

(defun murk-highlight-current-context ()
  (maphash
   (lambda (this-context facelist)
     (if (equal (take 2 this-context) (take 2 (murk-current-context)))
         (setcar facelist 'murk-text)
       (setcar facelist 'murk-faded)))
   murk-context-facelists)
  (force-window-update "*murk*"))

(defun murk-zoom-in (context)
  (with-current-buffer "*murk*"
    (maphash
     (lambda (this-context _)
       (when this-context
         (let ((this-context-atom
                (intern (murk-context->string this-context))))
           (if (equal this-context (take 2 context))
               (remove-from-invisibility-spec this-context-atom)
             (add-to-invisibility-spec this-context-atom)))))
     murk-context-facelists)
    (force-window-update "*murk*"))
  (murk-scroll-windows-to-last-line))

(defun murk-zoom-out ()
  (with-current-buffer "*murk*"
    (maphash
     (lambda (this-context _)
       (let ((this-context-atom
              (if this-context
                  (intern (murk-context->string this-context))
                nil)))
         (remove-from-invisibility-spec this-context-atom)))
     murk-context-facelists)
    (force-window-update "*murk*"))
  (murk-scroll-windows-to-last-line))

(defun murk--start-of-final-line ()
  (with-current-buffer "*murk*"
    (save-excursion
      (goto-char (point-max))
      (line-beginning-position))))

(defun murk-scroll-windows-to-last-line ()
  (with-current-buffer "*murk*"
    (dolist (window (get-buffer-window-list))
      (if (>= (window-point window) (murk--start-of-final-line))
          (with-selected-window window
            (recenter -1))))))

(defconst murk-url-regex
  (rx (:
       (group (+ alpha))
       "://"
       (group (or (+ (any alnum "." "-"))
                  (+ (any alnum ":"))))
       (opt (group (: ":" (+ digit))))
       (opt (group (: "/"
                      (opt
                       (* (any alnum "-/.,#:%=&_?~@+"))
                       (any alnum "-/#:%=&_~@+")))))))
  "Imperfect regex used to find URLs in plain text.")

(defun murk-click-url (button)
  (browse-url (button-get button 'url)))

(defun murk-buttonify-urls (&rest strings)
  "Turn substrings which look like urls in STRING into clickable buttons."
  (with-temp-buffer
    (apply #'insert strings)
    (goto-char (point-min))
    (while (re-search-forward murk-url-regex nil t)
      (let ((url (match-string 0)))
        (make-text-button (match-beginning 0)
                          (match-end 0)
                          'action #'murk-click-url
                          'url url
                          'follow-link t
                          'face 'button
                          'help-echo "Open URL in browser.")))
    (buffer-string)))

(defun murk-add-formatting (string)
  (with-temp-buffer
    (insert string)
    (goto-char (point-min))
    (let ((bold nil)
          (italics nil)
          (underline nil)
          (strikethrough nil)
          (prev-point (point)))
      (while (re-search-forward (rx (or (any "\x02\x1D\x1F\x1E\x0F")
                                        (: "\x03" (* digit) (opt "," (* digit)))))
                                nil t)
        (let ((beg (+ (match-beginning 0) 1)))
          (if bold
              (add-face-text-property prev-point beg '(:weight bold)))
          (if italics
              (add-face-text-property prev-point beg '(:slant italic)))
          (if underline
              (add-face-text-property prev-point beg '(:underline t)))
          (if strikethrough
              (add-face-text-property prev-point beg '(:strike-through t)))
          (pcase (match-string 0)
            ("\x02" (setq bold (not bold)))
            ("\x1D" (setq italics (not italics)))
            ("\x1F" (setq underline (not underline)))
            ("\x1E" (setq strikethrough (not strikethrough)))
            ("\x0F" ; Reset
             (setq bold nil)
             (setq italics nil)
             (setq underline nil)
             (setq strikethrough nil))
            (_))
          (delete-region (match-beginning 0) (match-end 0))
          (setq prev-point (point)))))
    (buffer-string)))


;;; Message evaluation
;;

(defun murk-eval-msg-string (server string)
  (if murk-debug
      (murk-display-string nil nil string))
  (let* ((msg (murk-string->msg string)))
    (murk-process-autoreplies server msg)
    (pcase (murk-msg-cmd msg)
      ("PING"
       (murk-send-msg server
        (murk-msg nil nil "PONG" (murk-msg-params msg))))

      ("PONG")

      ("001" ; RPL_WELCOME
       (let* ((params (murk-msg-params msg))
              (nick (elt params 0))
              (text (string-join (seq-drop params 1) " ")))
         (murk-set-connection-nick server nick)
         (murk-display-notice (murk-get-context server) text)))

      ("353" ; NAMEREPLY
       (let* ((params (murk-msg-params msg))
              (channel (elt params 2))
              (names (split-string (elt params 3)))
              (ctx (murk-get-context server channel)))
         (if ctx
             (murk-add-context-users ctx names)
           (murk-display-notice nil "Users in " channel
                                ": " (string-join names " ")))))

      ("366" ; ENDOFNAMES
       (let* ((params (murk-msg-params msg))
              (channel (elt params 1))
              (ctx (murk-get-context server channel)))
         (if ctx
             (murk-display-notice
              ctx
              (murk--as-string (length (murk-context-users ctx)))
              " users in " channel)
           (murk-display-notice nil "End of " channel " names list."))))

      ("331" ; RPL_NOTOPIC
       (let* ((params (murk-msg-params msg))
              (channel (elt params 1))
              (ctx (murk-get-context server channel)))
         (murk-display-notice ctx "No topic set.")))

      ("332" ; RPL_TOPIC
       (let* ((params (murk-msg-params msg))
              (channel (elt params 1))
              (topic (elt params 2))
              (ctx (murk-get-context server channel)))
         (murk-display-notice ctx "Topic: " topic)))

      ((rx (= 3 (any digit)))
       (murk-display-notice (murk-get-context server)
                            (mapconcat 'identity (cdr (murk-msg-params msg)) " ")))

      ((and "JOIN"
            (guard (equal (murk-connection-nick server)
                          (murk-msg-src msg))))
       (let ((channel (car (murk-msg-params msg))))
         (murk-add-context (list server channel nil))
         (murk-display-notice (murk-current-context)
                              "Joining channel " channel " on " server)
         (murk-highlight-current-context)
         (murk-render-prompt)))

      ("JOIN"
       (let* ((channel (car (murk-msg-params msg)))
              (nick (murk-msg-src msg))
              (ctx (murk-get-context server channel)))
         (murk-add-context-users ctx (list nick))
         (if murk-show-joins
             (murk-display-notice ctx nick " joined channel " channel
                                  " on " server))))

      ((and "PART"
            (guard (equal (murk-connection-nick server)
                          (murk-msg-src msg))))
       (let ((channel (car (murk-msg-params msg))))
         (murk-display-notice (murk-current-context) "Left channel " channel)
         (murk-remove-context (list server channel))
         (murk-highlight-current-context)
         (murk-render-prompt)))

      ("PART"
       (let* ((channel (car (murk-msg-params msg)))
              (nick (murk-msg-src msg))
              (ctx (murk-get-context server channel)))
         (murk-del-context-user ctx nick)
         (if murk-show-joins
             (murk-display-notice ctx nick " left channel " channel
                                  " on " server))))

      ((and "NICK"
            (guard (equal (murk-connection-nick server)
                          (murk-msg-src msg))))
       (let ((new-nick (car (murk-msg-params msg)))
             (old-nick (murk-connection-nick server)))
         (murk-set-connection-nick server new-nick)
         (murk-rename-server-user server old-nick new-nick)
         (murk-display-notice (murk-get-context server)
                              "Nick set to " new-nick " on " server)))

      ("NICK"
       (let ((old-nick (murk-msg-src msg))
             (new-nick (car (murk-msg-params msg))))
         (murk-display-notice nil old-nick " is now known as " new-nick
                              " on " server)
         (murk-rename-server-user server old-nick new-nick)))

      ("TOPIC"
       (let ((channel (car (murk-msg-params msg)))
             (nick (murk-msg-src msg))
             (topic (cadr (murk-msg-params msg))))
         (murk-display-notice (murk-get-context server channel)
                              nick " set the topic: " topic)))

      ("QUIT"
       (let ((nick (murk-msg-src msg))
             (reason (mapconcat 'identity (murk-msg-params msg) " ")))
         (murk-del-server-user server nick)
         (if murk-show-joins
             (murk-display-notice (murk-get-context server)
                                  nick " quit: " reason))))

      ("NOTICE"
       (let ((nick (murk-msg-src msg))
             (channel (car (murk-msg-params msg)))
             (text (cadr (murk-msg-params msg))))
         (pcase text
           ((rx (: "\01VERSION "
                   (let version (* (not "\01")))
                   "\01"))
            (murk-display-notice (murk-get-context server)
                                 "CTCP version reply from " nick ": " version))
           (_
            (murk-display-notice (murk-get-context server channel) text)))))

      ("PRIVMSG"
       (let* ((from (murk-msg-src msg))
              (params (murk-msg-params msg))
              (to (car params))
              (text (cadr params)))
         (pcase text
           ("\01VERSION\01"
            (let ((version-string (concat murk-version " - running on GNU Emacs " emacs-version)))
              (murk-send-msg server
                             (murk-msg nil nil "NOTICE"
                                       (list from (concat "\01VERSION "
                                                          version-string
                                                          "\01")))))
            (murk-display-notice (murk-get-context server)
                                 "CTCP version request received from "
                                 from " on " server))

           ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
            (murk-send-msg server (murk-msg nil nil "NOTICE" (list from ping)))
            (murk-display-notice (murk-get-context server)
                                 "CTCP ping received from " from " on " server))

           ("\01USERINFO\01"
            (murk-display-notice (murk-get-context server)
                                 "CTCP userinfo request from " from
                                 " on " server " (no response sent)"))

           ("\01CLIENTINFO\01"
            (murk-display-notice (murk-get-context server)
                                 "CTCP clientinfo request from " from
                                 " on " server " (no response sent)"))

           ((rx (: "\01ACTION " (let action-text (* (not "\01"))) "\01"))
            (murk-display-action server from to action-text))

           (_
            (murk-display-message server from to text)))))

      (_
       (murk-display-notice (murk-get-context server)
                            (murk-msg->string msg))))))


;;; User-defined responses
;;

(defun murk--lists-equal (l1 l2)
    (if (and l1 l2)
        (if (or (not (and (car l1) (car l2)))
                (string-match (car l1) (car l2)))
            (murk--lists-equal (cdr l1) (cdr l2))
          nil)
      t))

(defun murk-process-autoreply (server msg autoreply)
  (let ((matcher (car autoreply))
        (reply (cadr autoreply)))
    (let ((target-server (car matcher)))
      (when (and (or (not target-server)
                     (and (equal server target-server)))
                 (murk--lists-equal (cdr matcher)
                                    (append (list (lurk-msg-src msg)
                                                  (lurk-msg-cmd msg))
                                            (murk-msg-params msg))))
        (murk-send-msg server
         (murk-msg nil nil (car reply) (cdr reply)))))))

(defun murk-process-autoreplies (server msg)
  (mapc
   (lambda (autoreply)
     (murk-process-autoreply server msg autoreply))
   murk-autoreply-table))


;;; Commands
;;

(defvar murk-command-table
  '(("DEBUG" "Toggle debug mode on/off." murk-command-debug murk-boolean-completions)
    ("HEADER" "Toggle display of header." murk-command-header murk-boolean-completions)
    ("SHOWJOINS" "Toggles display of joins/parts." murk-command-showjoins murk-boolean-completions)
    ("NETWORKS" "List known IRC networks." murk-command-networks)
    ("CONNECT" "Connect to an IRC network." murk-command-connect murk-network-completions)
    ("QUIT" "Disconnect from current network." murk-command-quit)
    ("JOIN" "Join one or more channels." murk-command-join)
    ("PART" "Leave channel." murk-command-part murk-context-completions)
    ("NICK" "Change nick." murk-command-nick)
    ("LIST" "Display details of one or more channels." murk-command-list)
    ("TOPIC" "Set/query topic for current channel." murk-command-topic)
    ("USERS" "List nicks of users in current context." murk-command-users)
    ("MSG" "Send private message to user." murk-command-msg murk-nick-completions)
    ("ME" "Display action." murk-command-me)
    ("VERSION" "Request version of another user's client via CTCP." murk-command-version murk-nick-completions)
    ("CLEAR" "Clear buffer text." murk-command-clear murk-context-completions)
    ("HELP" "Display help on client commands." murk-command-help murk-help-completions))
  "Table of commands explicitly supported by murk.")

(defun murk-boolean-completions ()
  '("on" "off"))

(defun murk-network-completions ()
  (mapcar (lambda (row) (car row)) murk-networks))

(defun murk-command-help (params)
  (if params
      (let* ((cmd-str (upcase (car params)))
             (row (assoc cmd-str murk-command-table #'equal)))
        (if row
            (progn
              (murk-display-notice nil "Help for \x02" cmd-str "\x02:")
              (murk-display-notice nil "  " (elt row 1)))
          (murk-display-notice nil "No such (client-interpreted) command.")))
    (murk-display-notice nil "Client-interpreted commands:")
    (dolist (row murk-command-table)
      (murk-display-notice nil "  \x02" (elt row 0) "\x02: " (elt row 1)))
    (murk-display-notice nil "Use /HELP COMMAND to display information about a specific command.")))

(defun murk-command-debug (params)
  (setq murk-debug 
        (if params
            (if (equal (upcase (car params)) "ON")
                t
              nil)
          (not murk-debug)))
  (murk-display-notice nil "Debug mode now " (if murk-debug "on" "off") "."))

(defun murk-command-header (params)
  (if
      (if params
          (equal (upcase (car params)) "ON")
        (not header-line-format))
      (progn
        (murk-setup-header)
        (murk-display-notice nil "Header enabled."))
    (setq-local header-line-format nil)
    (murk-display-notice nil "Header disabled.")))

(defun murk-command-showjoins (params)
  (setq murk-show-joins 
        (if params
            (if (equal (upcase (car params)) "ON")
                t
              nil)
          (not murk-show-joins)))
  (murk-display-notice nil "Joins/parts will now be "
                       (if murk-show-joins "shown" "hidden") "."))

(defun murk-command-connect (params)
  (if params
      (let ((network (car params)))
        (murk-display-notice nil "Attempting to connect to " network "...")
        (murk-connect network))
    (murk-display-notice nil "Usage: /connect <network>")))

(defun murk-command-networks (_params)
  (murk-display-notice nil "Currently-known networks:")
  (dolist (row murk-networks)
    (seq-let (network server port &rest _others) row
      (murk-display-notice nil "\t" network
                           " [" server
                           " " (number-to-string port) "]")))
  (murk-display-notice nil "(Modify the `murk-networks' variable to add more.)"))

(defun murk-command-quit (params)
  (let ((ctx (murk-current-context)))
    (if (not ctx)
        (murk-display-error "No current server")
      (let ((quit-msg (if params (string-join params " ") murk-default-quit-msg)))
        (murk-send-msg
         (murk-context-server ctx)
         (murk-msg nil nil "QUIT" quit-msg))))))

(defun murk-command-join (params)
  (if params
      (let ((server (murk-context-server (murk-current-context))))
        (dolist (channel params)
          (murk-send-msg server (murk-msg nil nil "JOIN" channel))))
    (murk-display-notice nil "Usage: /join channel [channel2 ...]")))

(defun murk-command-part (params)
  (let* ((server (murk-context-server (murk-current-context)))
         (channel (if params
                      (car params)
                    (murk-context-channel (murk-current-context)))))
    (if channel
        (murk-send-msg server (murk-msg nil nil "PART" channel))
      (murk-display-error "No current channel to leave"))))

(defun murk-command-nick (params)
  (if params
      (let ((new-nick (string-join params " "))
            (ctx (murk-current-context)))
        (if ctx
            (murk-send-msg (murk-context-server ctx)
                           (murk-msg nil nil "NICK" new-nick))
          (murk-display-error "No current connection")))
    (murk-display-notice nil "Usage: /nick <new-nick>")))

(defun murk-command-list (params)
  (let ((ctx (murk-current-context)))
    (if ctx
        (if (not params)
            (murk-display-notice nil "This command can generate lots of output. Use `/LIST -yes' if you really want this, or `/LIST <channel_regexp>' to reduce the output.")
          (let ((server (murk-context-server ctx)))
            (if (equal (upcase (car params)) "-YES")
                (murk-send-msg server (murk-msg nil nil "LIST"))
              (murk-send-msg server (murk-msg nil nil "LIST"
                                              (car params))))))
      (murk-display-error "No current connection"))))

(defun murk-command-topic (params)
  (let ((ctx (murk-current-context)))
    (if (and ctx (not (murk-server-context-p ctx)))
        (let ((server (murk-context-server ctx))
              (channel (murk-context-channel ctx)))
          (if params
              (murk-send-msg server
                             (murk-msg nil nil "TOPIC" channel
                                       (string-join params " ")))
            (murk-send-msg server
                           (murk-msg nil nil "TOPIC" channel))))
      (murk-display-notice nil "No current channel."))))

(defun murk-command-msg (params)
  (let ((server (murk-context-server (murk-current-context))))
    (if (and params (>= (length params) 2))
        (let ((to (car params))
              (text (string-join (cdr params) " ")))
          (murk-send-msg server (murk-msg nil nil "PRIVMSG" to text))
          (murk-display-message server
                                (murk-connection-nick server)
                                to text))
      (murk-display-notice nil "Usage: /msg <nick> <message>"))))

(defun murk-command-me (params)
  (let* ((ctx (murk-current-context))
         (server (murk-context-server ctx)))
    (if (and ctx (not (murk-server-context-p ctx)))
        (if params
            (let* ((channel (murk-context-channel ctx))
                   (my-nick (murk-connection-nick server))
                   (action (string-join params " "))
                   (ctcp-text (concat "\01ACTION " action "\01")))
              (murk-send-msg server
                             (murk-msg nil nil "PRIVMSG"
                                       (list channel ctcp-text)))
              (murk-display-action server my-nick channel action))
          (murk-display-notice nil "Usage: /me <action>"))
      (murk-display-notice nil "No current channel."))))

(defun murk-command-version (params)
  (let ((ctx (murk-current-context)))
    (if ctx
        (if params
            (let ((server (murk-context-server ctx))
                  (nick (car params)))
              (murk-send-msg server
                             (lurk-msg nil nil "PRIVMSG"
                                       (list nick "\01VERSION\01")))
              (murk-display-notice ctx "CTCP version request sent to "
                                   nick " on " server))
          (murk-display-notice ctx "Usage: /version <nick>"))
      (murk-display-notice nil "No current channel."))))

(defun murk-command-users (_params)
  (let ((ctx (murk-current-context)))
    (if (and ctx (not (murk-server-context-p ctx)))
        (let ((channel (murk-context-channel ctx))
              (server (murk-context-server ctx))
              (users (murk-context-users ctx)))
          (murk-display-notice ctx "Users in " channel " on " server ":")
          (murk-display-notice ctx (string-join users " ")))
      (murk-display-notice nil "No current channel."))))


;;; Command entering
;;

(defun murk-enter-string (string)
  (if (string-prefix-p "/" string)
      (pcase string
        ((rx (: "/" (let cmd-str (+ (not whitespace)))
                (opt (+ whitespace)
                     (let params-str (+ anychar))
                     string-end)))
         (let ((command-row (assoc (upcase  cmd-str) murk-command-table #'equal))
               (params (if params-str
                           (split-string params-str nil t)
                         nil)))
           (if (and command-row (elt command-row 2))
               (funcall (elt command-row 2) params)
             (murk-send-msg
              (murk-context-server (murk-current-context))
              (murk-msg nil nil (upcase cmd-str) params)))))
        (_
         (murk-display-error "Badly formed command")))
    (unless (string-empty-p string)
      (let ((ctx (murk-current-context)))
        (if ctx
            (if (not (murk-server-context-p ctx))
                (let ((server (murk-context-server ctx))
                      (channel (murk-context-channel ctx)))
                  (murk-send-msg server
                                 (murk-msg nil nil "PRIVMSG" channel string))
                  (murk-display-message server
                                        (murk-connection-nick server)
                                        channel string))
              (murk-display-error "No current channel"))
          (murk-display-error "No current context"))))))


;;; Command history
;;

(defvar murk-history nil
  "Commands and messages sent in current session.")

(defvar murk-history-index nil)

(defun murk-history-cycle (delta)
  (when murk-history
    (with-current-buffer "*murk*"
      (if murk-history-index
          (setq murk-history-index
                (max 0
                     (min (- (length murk-history) 1)
                          (+ delta murk-history-index))))
        (setq murk-history-index 0))
      (delete-region murk-input-marker (point-max))
      (insert (elt murk-history murk-history-index)))))


;;; Interactive commands
;;

(defun murk-enter ()
  "Enter current contents of line after prompt."
  (interactive)
  (with-current-buffer "*murk*"
    (let ((line (buffer-substring murk-input-marker (point-max))))
      (push line murk-history)
      (setq murk-history-index nil)
      (let ((inhibit-read-only t))
        (delete-region murk-input-marker (point-max)))
      (murk-enter-string line))))

(defun murk-history-next ()
  (interactive)
  (murk-history-cycle -1))

(defun murk-history-prev ()
  (interactive)
  (murk-history-cycle +1))

(defun murk-cycle-contexts-forward ()
  (interactive)
  (murk-cycle-contexts)
  (murk-highlight-current-context)
  (murk-render-prompt)
  (if murk-zoomed
      (murk-zoom-in (murk-current-context))))

(defun murk-cycle-contexts-reverse ()
  (interactive)
  (murk-cycle-contexts t)
  (murk-highlight-current-context)
  (murk-render-prompt)
  (if murk-zoomed
      (murk-zoom-in (murk-current-context))))

(defvar murk-zoomed nil
  "Keeps track of zoom status.")

(defun murk-toggle-zoom ()
  (interactive)
  (if murk-zoomed
      (murk-zoom-out)
    (murk-zoom-in (murk-current-context)))
  (setq murk-zoomed (not murk-zoomed)))


(defun murk-complete-input ()
  (interactive)
  (let ((completion-ignore-case t))
    (when (>= (point) murk-input-marker)
      (pcase (buffer-substring murk-input-marker (point))
        ((rx (: "/" (let cmd-str (+ (not whitespace))) (+ " ") (* (not whitespace)) string-end))
         (let ((space-idx (save-excursion
                            (re-search-backward " " murk-input-marker t)))
               (table-row (assoc (upcase cmd-str) murk-command-table #'equal)))
           (if (and table-row (elt table-row 3))
               (let* ((completions-nospace (funcall (elt table-row 3)))
                      (completions (mapcar (lambda (el) (concat el " ")) completions-nospace)))
                 (completion-in-region (+ 1 space-idx) (point) completions)))))
        ((rx (: "/" (* (not whitespace)) string-end))
         (message (buffer-substring murk-input-marker (point)))
         (completion-in-region murk-input-marker (point)
                               (mapcar (lambda (row) (concat "/" (car row) " "))
                                       murk-command-table)))
        (_
         (let* ((end (max murk-input-marker (point)))
                (space-idx (save-excursion
                             (re-search-backward " " murk-input-marker t)))
                (start (if space-idx (+ 1 space-idx) murk-input-marker)))
           (unless (string-prefix-p "/" (buffer-substring start end))
             (let* ((users (murk-context-users (murk-current-context)))
                    (users-no@ (mapcar
                                (lambda (u) (car (split-string u "@" t)))
                                users)))
               (completion-in-region start end users-no@)))))))))

;;; Mode
;;

(defvar murk-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "RET") 'murk-enter)
    (define-key map (kbd "TAB") 'murk-complete-input)
    (define-key map (kbd "C-c C-z") 'murk-toggle-zoom)
    (define-key map (kbd "<C-up>") 'murk-history-prev)
    (define-key map (kbd "<C-down>") 'murk-history-next)
    (define-key map (kbd "<C-tab>") 'murk-cycle-contexts-forward)
    (define-key map (kbd "<C-S-iso-lefttab>") 'murk-cycle-contexts-reverse)
    (define-key map (kbd "<C-S-tab>") 'murk-cycle-contexts-reverse)
    (when (fboundp 'evil-define-key*)
      (evil-define-key* 'motion map
        (kbd "TAB") 'murk-complete-input))
    map))

(define-derived-mode murk-mode text-mode "murk"
  "Major mode for murk.")

(when (fboundp 'evil-set-initial-state)
  (evil-set-initial-state 'murk-mode 'insert))

;;; Main start procedure
;;

(defun murk ()
  "Start murk or just switch to the murk buffer if one already exists."
  (interactive)
  (if (get-buffer "*murk*")
      (switch-to-buffer "*murk*")
    (switch-to-buffer "*murk*")
    (murk-mode)
    (murk-setup-buffer))
  "Started murk.")

;;; murk.el ends here