X-Git-Url: https://thelambdalab.xyz/gitweb/index.cgi?a=blobdiff_plain;f=scheme.4th;h=a05b898f42660dfb9863508e218f1ff8db4a7390;hb=9e0ea182c4546eeefad63a27d63f057df3fb42c5;hp=bf57ac782080ff75c486bbe3fb23ccc80fb0f251;hpb=c86116e9a58b939ec2e9a9a9528dda8836479cae;p=scheme.forth.jl.git

diff --git a/scheme.4th b/scheme.4th
index bf57ac7..a05b898 100644
--- a/scheme.4th
+++ b/scheme.4th
@@ -1,16 +1,198 @@
-\ Scheme interpreter
-
 vocabulary scheme
 scheme definitions
 
 include term-colours.4th
+include defer-is.4th
+
+\ ------ Types ------
 
 0 constant number-type
 1 constant boolean-type
 2 constant character-type
-: istype? ( obj -- obj b )
+3 constant string-type
+4 constant nil-type
+5 constant pair-type
+6 constant symbol-type
+: istype? ( obj type -- obj bool )
     over = ;
 
+\ ------ Cons cell memory ------
+
+1000 constant N
+create car-cells N allot
+create car-type-cells N allot
+create cdr-cells N allot
+create cdr-type-cells N allot
+
+variable nextfree
+0 nextfree !
+
+: cons ( car-obj cdr-obj -- pair-obj )
+    cdr-type-cells nextfree @ + !
+    cdr-cells nextfree @ + !
+    car-type-cells nextfree @ + !
+    car-cells nextfree @ + !
+
+    nextfree @ pair-type
+
+    1 nextfree +!
+;
+
+: car ( pair-obj -- car-obj )
+    drop
+    dup car-cells + @ swap
+    car-type-cells + @
+;
+
+: cdr ( pair-obj -- car-obj )
+    drop
+    dup cdr-cells + @ swap
+    cdr-type-cells + @
+;
+
+: set-car! ( obj pair-obj -- )
+    drop dup
+    rot swap  car-type-cells + !
+    car-cells + !
+;
+
+: set-cdr! ( obj pair-obj -- )
+    drop dup
+    rot swap  cdr-type-cells + !
+    cdr-cells + !
+;
+
+: caar car car ;
+: cadr cdr car ;
+: cdar car cdr ;
+: cddr cdr cdr ;
+
+: nil 0 nil-type ;
+: nil? nil-type istype? ;
+
+: objvar create nil swap , , ;
+
+: value@ ( objvar -- val ) @ ;
+: type@ ( objvar -- type ) 1+ @ ;
+: value! ( newval objvar -- ) ! ;
+: type! ( newtype objvar -- ) 1+ ! ;
+: setobj ( newobj objvar -- ) dup rot swap 1+ ! ! ; 
+: fetchobj ( objvar -- obj ) dup @ swap 1+ @ ; 
+
+: objeq? ( obj obj -- bool )
+    rot = -rot = and ;
+
+\ ---- Pre-defined symbols ----
+
+objvar symbol-table
+
+: (create-symbol) ( addr n -- symbol-obj )
+    dup 0= if
+        2drop nil
+    else
+        2dup drop @ character-type 2swap
+        swap 1+ swap 1-
+        recurse
+
+        cons
+    then
+;
+
+: create-symbol ( -- )
+    bl word
+    count
+
+    (create-symbol)
+    drop symbol-type
+
+    2dup
+
+    symbol-table fetchobj
+    cons
+    symbol-table setobj
+
+    create swap , ,
+    does> dup @ swap 1+ @
+;
+
+create-symbol quote quote-symbol
+create-symbol define define-symbol
+create-symbol set! set!-symbol
+
+\ ---- Environments ----
+
+objvar global-env
+
+: enclosing-env ( env -- env )
+    cdr ;
+
+: first-frame ( env -- frame )
+    car ;
+
+: make-frame ( vars vals -- frame )
+    cons ;
+
+: frame-vars ( frame -- vars )
+    car ;
+
+: frame-vals ( frame -- vals )
+    cdr ;
+
+: add-binding ( var val frame -- )
+    2swap 2over frame-vals cons
+    2over set-car!
+    2swap 2over frame-vars cons
+    swap set-cdr!
+;
+
+: extend-env ( vars vals env -- env )
+    >R >R
+    make-frame
+    R> R>
+    cons
+;
+
+objvar vars
+objvar vals
+
+: lookup-var-frame ( var frame -- val? bool )
+    2dup frame-vars vars setobj
+    frame-vals vals setobj
+
+    begin
+        vars fetchobj nil objeq? false =
+    while
+        2dup vars fetchobj car objeq? if
+            2drop
+            vals fetchobj car true
+            exit
+        then
+
+        vars fetchobj cdr vars setobj
+        vals fetchobj cdr vals setobj
+    repeat
+
+    2drop false
+;
+
+: lookup-var ( var env -- val )
+    begin
+        2dup nil objeq? false =
+    while
+        2over 2over first-frame
+        lookup-var-frame if
+            -rot 2drop -rot 2drop
+            exit
+        then
+
+        enclosing-env
+    repeat
+
+    2drop 
+    bold fg red ." Unbound variable " print ." . Aborting." reset-term cr
+    abort
+;
+
 \ ---- Read ----
 
 variable parse-idx
@@ -18,7 +200,6 @@ variable stored-parse-idx
 create parse-str 161 allot
 variable parse-str-span
 
-
 create parse-idx-stack 10 allot 
 variable parse-idx-sp
 parse-idx-stack parse-idx-sp !
@@ -105,7 +286,7 @@ parse-idx-stack parse-idx-sp !
         inc-parse-idx
     repeat
 
-    delim? charavailable? false = or if
+    delim? if
         pop-parse-idx
         true
     else
@@ -124,16 +305,24 @@ parse-idx-stack parse-idx-sp !
     nextchar [char] f <>
     and if pop-parse-idx false exit then
 
-    pop-parse-idx
-    true
+    inc-parse-idx
+    delim? if
+        pop-parse-idx
+        true
+    else
+        pop-parse-idx
+        false
+    then
 ;
 
 : str-equiv? ( str -- bool )
+
     push-parse-idx
 
-    true
+    true -rot
 
     swap dup rot + swap
+
     do
         i @ nextchar <> if
             drop false
@@ -143,7 +332,7 @@ parse-idx-stack parse-idx-sp !
         inc-parse-idx
     loop
 
-    delim? <> if drop false then
+    delim? false = if drop false then
 
     pop-parse-idx
 ;
@@ -158,15 +347,21 @@ parse-idx-stack parse-idx-sp !
 
     inc-parse-idx
 
-    S" newline" str-equiv? if true exit then
-    S" space" str-equiv? if true exit then
-    S" tab" str-equiv? if true exit then
+    S" newline" str-equiv? if pop-parse-idx true exit then
+    S" space" str-equiv? if pop-parse-idx true exit then
+    S" tab" str-equiv? if pop-parse-idx true exit then
 
     charavailable? false = if pop-parse-idx false exit then
 
     pop-parse-idx true
 ;
 
+: pair? ( -- bool )
+    nextchar [char] ( = ;
+
+: string? ( -- bool )
+    nextchar [char] " = ;
+
 : readnum ( -- num-atom )
     minus? dup if
         inc-parse-idx
@@ -198,8 +393,161 @@ parse-idx-stack parse-idx-sp !
     boolean-type
 ;
 
+: readchar ( -- char-atom )
+    inc-parse-idx
+    inc-parse-idx
+
+    S" newline" str-equiv? if 7 parse-idx +! '\n' character-type exit then
+    S" space" str-equiv? if 5 parse-idx +! bl character-type exit then
+    S" tab" str-equiv? if 3 parse-idx +! 9 character-type exit then
+
+    nextchar character-type
+
+    inc-parse-idx
+;
+
+: readstring ( -- charlist )
+    nextchar [char] " = if
+        inc-parse-idx
+
+        delim? false = if
+            bold fg red
+            ." No delimiter following right double quote. Aborting." cr
+            reset-term abort
+        then
+
+        dec-parse-idx
+
+        0 nil-type exit
+    then
+
+    nextchar [char] \ = if
+        inc-parse-idx
+        nextchar case
+            [char] n of '\n' endof
+            [char] " of [char] " endof
+            [char] \
+        endcase
+    else
+        nextchar
+    then
+    inc-parse-idx character-type
+
+    recurse
+
+    cons
+;
+
+: readsymbol ( -- charlist )
+    delim? if nil exit then
+
+    nextchar inc-parse-idx character-type
+
+    recurse
+
+    cons
+;
+
+: charlist-equiv ( charlist charlist -- bool )
+
+    2over 2over
+
+    \ One or both nil
+    nil? -rot 2drop
+    if
+        nil? -rot 2drop
+        if
+            2drop 2drop true exit
+        else
+            2drop 2drop false exit
+        then
+    else
+        nil? -rot 2drop
+        if
+            2drop 2drop false exit
+        then
+    then
+
+    2over 2over
+
+    \ Neither nil
+    car drop -rot car drop = if
+            cdr 2swap cdr recurse
+        else
+            2drop 2drop false
+    then
+;
+
+: charlist>symbol ( charlist -- symbol-obj )
+
+    symbol-table fetchobj
+
+    begin
+        nil? false =
+    while
+        2over 2over
+        car drop pair-type
+        charlist-equiv if
+            2swap 2drop
+            car
+            exit
+        else
+            cdr
+        then
+    repeat
+
+    2drop
+    drop symbol-type 2dup
+    symbol-table fetchobj cons
+    symbol-table setobj
+;
+
+defer read
+
+: readpair ( -- pairobj )
+    eatspaces
+
+    \ Empty lists
+    nextchar [char] ) = if
+        inc-parse-idx
+
+        delim? false = if
+            bold fg red
+            ." No delimiter following right paren. Aborting." cr
+            reset-term abort
+        then
+
+        dec-parse-idx
+
+        0 nil-type exit
+    then
+
+    \ Read first pair element
+    read
+
+    \ Pairs
+    eatspaces
+    nextchar [char] . = if
+        inc-parse-idx
+
+        delim? false = if
+            bold fg red
+            ." No delimiter following '.'. Aborting." cr
+            reset-term abort
+        then
+
+        eatspaces read
+    else
+        recurse
+    then
+
+    eatspaces
+
+    cons
+;
+
 \ Parse a scheme expression
-: read ( -- obj )
+:noname ( -- obj )
 
     eatspaces
 
@@ -213,26 +561,96 @@ parse-idx-stack parse-idx-sp !
         exit
     then
 
+    character? if
+        readchar
+        exit
+    then
+
+    string? if
+        inc-parse-idx
+        readstring
+        drop string-type
+
+        nextchar [char] " <> if
+            bold red ." Missing closing double-quote." reset-term cr
+            abort
+        then
+
+        inc-parse-idx
+        exit
+    then
+
+    pair? if
+        inc-parse-idx
+
+        eatspaces
+
+        readpair
+
+        eatspaces
+
+        nextchar [char] ) <> if
+            bold red ." Missing closing paren." reset-term cr
+            abort
+        then
+
+        inc-parse-idx
+
+        exit
+    then
+
+    nextchar [char] ' = if
+        inc-parse-idx
+        quote-symbol recurse nil cons cons exit
+    then
+
     eof? if
         bold fg blue ." Moriturus te saluto." reset-term ."  ok" cr
         quit
     then
 
-    bold fg red ." Error parsing string starting at character '"
-    nextchar emit
-    ." '. Aborting." reset-term cr
-    abort
-;
+    \ Anything else is assumed to be a symbol
+    readsymbol charlist>symbol
+
+; is read
 
 \ ---- Eval ----
 
 : self-evaluating? ( obj -- obj bool )
-    number-type istype? if true exit then
     boolean-type istype? if true exit then
-    false ;
+    number-type istype? if true exit then
+    character-type istype? if true exit then
+    string-type istype? if true exit then
+    nil-type istype? if true exit then
+
+    false
+;
+
+: tagged-list? ( obj tag-obj -- obj bool )
+    2over 
+    pair-type istype? false = if
+        2drop 2drop false
+    else
+        car objeq?
+    then ;
+
+: quote? ( obj -- obj bool )
+    quote-symbol tagged-list?  ;
+
+: quote-body ( quote-obj -- quote-body-obj )
+    cadr ;
+    
+: eval ( obj env -- result )
+    2swap
 
-: eval
     self-evaluating? if
+        2swap 2drop
+        exit
+    then
+
+    quote? if
+        quote-body
+        2swap 2drop
         exit
     then
 
@@ -242,7 +660,7 @@ parse-idx-stack parse-idx-sp !
 
 \ ---- Print ----
 
-: printnum ( numobj -- ) drop . ;
+: printnum ( numobj -- ) drop 0 .R ;
 
 : printbool ( numobj -- )
     drop if
@@ -252,11 +670,67 @@ parse-idx-stack parse-idx-sp !
     then
 ;
 
-: print ( obj -- )
-    ." ; "
+: printchar ( charobj -- )
+    drop
+    case
+        9 of ." #\tab" endof
+        bl of ." #\space" endof
+        '\n' of ." #\newline" endof
+        
+        dup ." #\" emit
+    endcase
+;
+
+: (printstring) ( stringobj -- )
+    nil-type istype? if 2drop exit then
+
+    2dup car drop dup
+    case
+        '\n' of ." \n" drop endof
+        [char] \ of ." \\" drop endof
+        [char] " of [char] \ emit [char] " emit drop endof
+        emit
+    endcase
+
+    cdr recurse
+;
+: printstring ( stringobj -- )
+    [char] " emit
+    (printstring)
+    [char] " emit ;
+
+: printsymbol ( symbolobj -- )
+    nil-type istype? if 2drop exit then
+
+    2dup car drop emit
+    cdr recurse
+;
+
+: printnil ( nilobj -- )
+    2drop ." ()" ;
+
+defer print
+: printpair ( pairobj -- )
+    2dup
+    car print
+    cdr
+    nil-type istype? if 2drop exit then
+    pair-type istype? if space recurse exit then
+    ."  . " print
+;
+
+:noname ( obj -- )
     number-type istype? if printnum exit then
     boolean-type istype? if printbool exit then
-;
+    character-type istype? if printchar exit then
+    string-type istype? if printstring exit then
+    symbol-type istype? if printsymbol exit then
+    nil-type istype? if printnil exit then
+    pair-type istype? if ." (" printpair ." )" exit then
+
+    bold fg red ." Error printing expression - unrecognized type. Aborting" reset-term cr
+    abort
+; is print
 
 \ ---- REPL ----
 
@@ -269,8 +743,8 @@ parse-idx-stack parse-idx-sp !
     begin
         cr bold fg green ." > " reset-term
         read
-        eval
-        fg cyan print reset-term
+        global-env fetchobj eval
+        fg cyan ." ; " print reset-term
     again
 ;