X-Git-Url: https://thelambdalab.xyz/gitweb/index.cgi?a=blobdiff_plain;f=src%2Fscheme.4th;h=a32ee45a8d10b5c315fc3f8aceab42bafe3ecd8d;hb=6cb6a8d3e4449a1cf70ac4cbb0b88cf2c38d6434;hp=1a90ae3f6e7a5c528a4a784e7a3264d7a17bdfc0;hpb=ed191ba289bdcd6c0aa2e1079e63e8069ca6965c;p=scheme.forth.jl.git

diff --git a/src/scheme.4th b/src/scheme.4th
index 1a90ae3..a32ee45 100644
--- a/src/scheme.4th
+++ b/src/scheme.4th
@@ -3,6 +3,7 @@ scheme definitions
 
 include term-colours.4th
 include defer-is.4th
+include goto.4th
 include catch-throw.4th
 include integer.4th
 include float.4th
@@ -163,6 +164,10 @@ variable nextfree
     R> R>
 ;
 
+: 2pick ( an bn an-1 bn-1 ... a0 b0 n -- an bn an-1 bn-1 ... a0 b0 an bn )
+    2* 1+ dup
+    >R pick R> pick ;
+
 \ }}}
 
 \ ---- Pre-defined symbols ---- {{{
@@ -1310,95 +1315,6 @@ parse-idx-stack parse-idx-sp !
 : quote-body ( quote-obj -- quote-body-obj )
     cdr car ;
 
-: quasiquote? ( obj -- obj bool )
-    quasiquote-symbol tagged-list? ;
-
-: unquote? ( obj -- obj bool )
-    unquote-symbol tagged-list? ;
-
-: unquote-splicing? ( obj -- obj bool )
-    unquote-splicing-symbol tagged-list? ;
-
-: eval-unquote ( env obj -- res )
-    cdr ( env args )
-
-    nil? if
-        except-message: ." no arguments to unquote." recoverable-exception throw
-    then
-
-    2dup cdr
-    nil? false = if
-        except-message: ." too many arguments to unquote." recoverable-exception throw
-    then
-
-    2drop car 2swap eval
-;
-
-( Create a new list from elements of l1 consed on to l2 )
-: join-lists ( l2 l1 -- l3 )
-    nil? if 2drop exit then
-
-    2dup car
-    -2rot cdr
-    recurse cons
-;
-
-defer eval-quasiquote-item
-: eval-quasiquote-pair ( env obj -- res )
-    2over 2over ( env obj env obj )
-
-    cdr eval-quasiquote-item
-
-    -2rot car ( cdritem env objcar )
-
-    unquote-splicing? if
-        eval-unquote ( cdritems caritem )
-
-        2swap nil? if
-            2drop
-        else
-            2swap join-lists
-        then
-    else
-        eval-quasiquote-item ( cdritems caritem )
-        2swap cons
-    then
-
-;
-
-:noname ( env obj )
-    nil? if
-        2swap 2drop exit
-    then
-
-    unquote? if
-        eval-unquote exit
-    then
-
-    pair-type istype? if
-        eval-quasiquote-pair exit
-    then
-
-    2swap 2drop
-; is eval-quasiquote-item
-
-: eval-quasiquote ( obj env -- res )
-    2swap cdr ( env args )
-
-    nil? if
-        except-message: ." no arguments to quasiquote." recoverable-exception throw
-    then
-
-    2dup cdr ( env args args-cdr )
-    nil? false = if
-        except-message: ." too many arguments to quasiquote." recoverable-exception throw
-    then
-
-    2drop car ( env arg )
-
-    eval-quasiquote-item
-;
-
 : variable? ( obj -- obj bool )
     symbol-type istype? ;
 
@@ -1613,174 +1529,219 @@ hide env
     2swap
 ;
 
-: apply ( proc argvals -- result )
-        2swap dup case
-            primitive-proc-type of
-                drop execute     
-            endof
-
-            compound-proc-type of
-                2dup procedure-body ( argvals proc body )
-                -2rot 2dup procedure-params ( body argvals proc argnames )
-                -2rot procedure-env ( body argnames argvals procenv )
-
-                -2rot 2swap
-                flatten-proc-args
-                2swap 2rot
+\ }}}
 
-                extend-env ( body env )
+\ ---- Analyze ----
 
-                eval-sequence
+: evaluate-eproc ( eproc env --- res )
 
-                R> drop ['] eval goto-deferred  \ Tail call optimization
-            endof
+    >R >R
 
-            except-message: ." object '" drop print ." ' not applicable." recoverable-exception throw
-        endcase
-;
+    begin
+        nil? invert
+    while
+        2dup car
+        2swap cdr
+    repeat
+    
+    2drop \ get rid of null
 
-:noname ( obj env -- result )
-    2swap
+    R> R> 2swap
 
-    \ --- DEBUG ---
-    ( 
-      fg yellow ." Evaluating: " bold 2dup print reset-term
-      space fg green ." PS: " bold depth . reset-term
-      space fg blue  ." RS: " bold RSP@ RSP0 - . reset-term cr
-    )
+    \ Final element of eproc list is primitive procedure
+    drop \ dump type signifier
 
-    self-evaluating? if
-        2swap 2drop
-        exit
-    then
+    goto \ jump straight to primitive procedure (executor)
+;
 
-    quote? if
-        quote-body
-        2swap 2drop
-        exit
-    then
+: self-evaluating-executor ( exp env -- exp )
+    2drop ;
 
-    quasiquote? if
-        2swap eval-quasiquote
-        exit
-    then
+: analyze-self-evaluating ( exp --- eproc )
+    ['] self-evaluating-executor primitive-proc-type
+    nil cons cons
+;
 
-    variable? if
-        2swap lookup-var
-        exit
-    then
+: quote-executor ( exp env -- exp )
+    2drop ;
 
-    definition? if
-        2swap eval-definition
-        exit
-    then
+: analyze-quoted ( exp -- eproc )
+    quote-body
 
-    assignment? if
-        2swap eval-assignment
-        exit
-    then
+    ['] quote-executor primitive-proc-type
+    nil cons cons
+;
 
-    macro-definition? if
-        2swap eval-define-macro
-        exit
-    then
+: variable-executor ( var env -- val )
+    lookup-var ;
 
-    if? if
-        2over 2over
-        if-predicate
-        2swap eval 
+: analyze-variable ( exp -- eproc )
+    ['] variable-executor primitive-proc-type
+    nil cons cons
+;
 
-        true? if
-            if-consequent
-        else
-            if-alternative
-        then
+: definition-executor ( var val-eproc env -- ok )
+    2swap 2over ( var env val-eproc env )
+    evaluate-eproc 2swap ( var val env )
+    define-var
+    ok-symbol
+;
 
-        2swap
-        ['] eval goto-deferred
-    then
+: analyze-definition ( exp -- eproc )
+    2dup definition-var
+    2swap definition-val analyze
 
-    lambda? if
-        2dup lambda-parameters
-        2swap lambda-body
-        2rot make-procedure
-        exit
-    then
+    ['] definition-executor primitive-proc-type
+    nil cons cons cons
+;
 
-    application? if
+: assignment-executor ( var val-eproc env -- ok )
+    2swap 2over ( var env val-eproc env )
+    evaluate-eproc 2swap ( var val env )
+    set-var
+    ok-symbol
+;
 
-        2over 2over ( env exp env exp )
-        operator ( env exp env opname )
+: analyze-assignment ( exp -- eproc )
+    2dup assignment-var
+    2swap assignment-val analyze ( var val-eproc )
 
-        2swap eval ( env exp proc )
+    ['] assignment-executor primitive-proc-type
+    nil cons cons cons
+;
 
-        -2rot ( proc env exp )
-        operands 2swap ( proc operands env )
-        list-of-vals ( proc argvals )
+: if-executor ( cproc aproc pproc env -- res )
+    2swap 2over ( cproc aproc env pproc env -- res )
+    evaluate-eproc
 
-        apply
-        exit
+    true? if
+        2swap 2drop
+    else
+        2rot 2drop
     then
 
-    except-message: ." tried to evaluate object with unknown type." recoverable-exception throw
-; is eval
+    evaluate-eproc
+;
 
-\ }}}
+: analyze-if ( exp -- eproc )
+    2dup if-predicate analyze
+    2swap 2dup if-consequent analyze
+    2swap if-alternative analyze
 
-\ ---- Analyze ----
+    ['] if-executor primitive-proc-type
+    nil cons cons cons cons
+;
+
+: sequence-executor ( eproc-list env -- res )
+    2swap
 
-: evaluate-eproc ( env eproc --- res )
     begin
+        2dup cdr ( env elist elist-rest)
         nil? invert
     while
-        2dup car
-        2swap cdr
+
+        -2rot car 2over ( elist-rest env elist-head env )
+        evaluate-eproc  ( elist-rest env head-res )
+        2drop 2swap     ( env elist-rest )
     repeat
-    
-    2drop \ get rid of null
 
-    \ Final element of eproc list is primitive procedure
-    drop        \ dump type signifier
-    R> drop >body >R  \ GOTO primitive procedure (executor)
+    2drop car 2swap
+    ['] evaluate-eproc goto
 ;
 
-: self-evaluating-executor ( env exp -- exp )
-    2swap 2drop ;
 
-: analyze-self-evaluating ( exp --- eproc )
-    ['] self-evaluating-executor primitive-proc-type
+: (analyze-sequence) ( explist -- eproc-list )
+    nil? if exit then
+
+    2dup car analyze
+    2swap cdr recurse
+
+    cons
+;
+
+: analyze-sequence ( explist -- eproc )
+    (analyze-sequence)
+    ['] sequence-executor primitive-proc-type
     nil cons cons
 ;
 
-: quote-executor ( env exp -- exp )
-    2swap 2drop ;
+: lambda-executor ( params bproc env -- res )
+    make-procedure
+    ( Although this is packaged up as a regular compound procedure,
+      the "body" element contains an _eproc_ to be evaluated in an
+      environment resulting from extending env with the parameter
+      bindings. )
+;
 
-: analyze-quoted ( exp -- eproc )
-    quote-body
+: analyze-lambda ( exp -- eproc )
+    2dup lambda-parameters
+    2swap lambda-body
 
-    ['] quote-executor primitive-proc-type
-    nil cons cons
+    nil? if
+        except-message: ." encountered lambda with an empty body." recoverable-exception throw
+    then
+
+    analyze-sequence
+
+    ['] lambda-executor primitive-proc-type
+    nil cons cons cons
 ;
 
-: variable-executor ( env var -- val )
-    2swap lookup-var ;
+: operand-eproc-list ( operands -- eprocs )
+    nil? invert if
+        2dup car analyze
+        2swap cdr recurse
+        cons
+    then
+;
 
-: analyze-variable ( exp -- eproc )
-    ['] variable-executor primitive-proc-type
-    nil cons cons
+: evaluate-operand-eprocs ( env aprocs -- vals )
+    nil? if
+        2swap 2drop
+    else
+        2over 2over car 2swap evaluate-eproc ( env aprocs thisval )
+        -2rot cdr recurse ( thisval restvals )
+        cons
+    then
 ;
 
-: assignment-executor ( env var val-eproc -- ok )
-    2rot 2dup 2rot ( var env env val-eproc )
-    evaluate-eproc 2swap ( var val env )
-    set-var
-    ok-symbol ;
+: application-executor ( operator-proc arg-procs env -- res )
+    2rot 2over ( aprocs env fproc env )
+    evaluate-eproc ( aprocs env proc )
 
-: analyze-assignment ( exp -- eproc )
-    2dup assignment-var
-    2swap assignment-val analyze ( var val-eproc )
+    -2rot 2swap ( proc env aprocs )
+    evaluate-operand-eprocs ( proc vals )
 
-    ['] assignment-executor primitive-proc-type
+    2swap ( vals proc )
+    
+    dup case
+        primitive-proc-type of
+            drop execute
+        endof
+
+        compound-proc-type of
+                2dup procedure-body ( argvals proc body )
+                -2rot 2dup procedure-params ( bproc argvals proc argnames )
+                -2rot procedure-env ( bproc argnames argvals procenv )
+
+                -2rot 2swap
+                flatten-proc-args
+                2swap 2rot
+
+                extend-env ( bproc env )
+
+               ['] evaluate-eproc goto
+        endof
+
+        except-message: ." object '" drop print ." ' not applicable." recoverable-exception throw
+    endcase
+;
+
+: analyze-application ( exp -- eproc )
+    2dup operator analyze
+    2swap operands operand-eproc-list
+
+    ['] application-executor primitive-proc-type
     nil cons cons cons
 ;
 
@@ -1801,11 +1762,39 @@ hide env
         exit
     then
 
+    definition? if
+        analyze-definition
+        exit
+    then
+
+\    macro-definition? if
+\        analyze-macro-definition
+\        exit
+\    then
+
     assignment? if
         analyze-assignment
         exit
     then
 
+    if? if
+        analyze-if
+        exit
+    then
+
+    lambda? if
+        analyze-lambda
+        exit
+    then
+
+    application? if
+        analyze-application
+        exit
+    then
+
+    
+    except-message: ." tried to analyze unknown expression type." recoverable-exception throw
+
 ; is analyze
 
 
@@ -1843,33 +1832,6 @@ hide env
     R> drop ['] expand goto-deferred
 ;
 
-: expand-quasiquote-item ( exp -- result )
-    nil? if exit then
-
-    unquote? if
-        unquote-symbol 2swap cdr car expand nil cons cons
-        exit
-    then
-
-    unquote-splicing? if
-        unquote-splicing-symbol 2swap cdr car expand nil cons cons
-        exit
-    then
-    
-    pair-type istype? if
-        2dup car recurse
-        2swap cdr recurse
-        cons
-    then
-;
-
-: expand-quasiquote ( exp -- result )
-    quasiquote-symbol 2swap cdr
-
-    expand-quasiquote-item
-
-    cons ;
-
 : expand-definition ( exp -- result )
     define-symbol 2swap
 
@@ -1939,8 +1901,6 @@ hide env
 
     quote? if exit then
 
-    quasiquote? if expand-quasiquote exit then
-
     definition? if expand-definition exit then
 
     assignment? if expand-assignment exit then
@@ -1957,6 +1917,10 @@ hide env
 
 \ }}}
 
+:noname ( exp env -- res )
+    2swap expand analyze 2swap evaluate-eproc
+; is eval
+
 \ ---- Print ---- {{{
 
 : printfixnum ( fixnum -- ) drop 0 .R ;
@@ -2181,8 +2145,6 @@ variable gc-stack-depth
 
         2swap 2drop ( port obj )
 
-        expand
-
         global-env obj@ eval ( port res )
     again
 ;
@@ -2211,8 +2173,6 @@ variable gc-stack-depth
         true exit
     then
 
-    expand
-
     global-env obj@ eval
 
     fg cyan ." ; " print reset-term