elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 3.0.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: https://thelambdalab.xyz/elpher
  25 ;; Package-Requires: ((emacs "27.1"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - gopher connections using TLS encryption,
  54 ;; - the fledgling Gemini protocol,
  55 ;; - the greybeard Finger protocol.
  56
  57 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  58 ;; page containing information on key bindings and suggested starting
  59 ;; points for your gopher exploration.
  60
  61 ;; Full instructions can be found in the Elpher info manual.
  62
  63 ;; Elpher is under active development.  Any suggestions for
  64 ;; improvements are welcome, and can be made on the official project
  65 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  66 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  67
  68 ;;; Code:
  69
  70 (provide 'elpher)
  71
  72 ;;; Dependencies
  73 ;;
  74
  75 (require 'seq)
  76 (require 'pp)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'dns)
  81 (require 'nsm)
  82 (require 'gnutls)
  83 (require 'socks)
  84
  85 ;;; ANSI colors or XTerm colors
  86
  87 (or (require 'xterm-color nil t)
  88     (require 'ansi-color))
  89
  90 (defalias 'elpher-color-filter-apply
  91   (if (fboundp 'xterm-color-filter)
  92       (lambda (s)
  93         (let ((_xterm-color-render nil))
  94           (xterm-color-filter s)))
  95     #'ansi-color-filter-apply)
  96   "A function to filter out ANSI escape sequences.")
  97
  98 (defalias 'elpher-color-apply
  99   (if (fboundp 'xterm-color-filter)
 100       #'xterm-color-filter
 101     #'ansi-color-apply)
 102   "A function to apply ANSI escape sequences.")
 103
 104 ;;; Global constants
 105 ;;
 106
 107 (defconst elpher-version "3.0.0"
 108   "Current version of elpher.")
 109
 110 (defconst elpher-margin-width 6
 111   "Width of left-hand margin used when rendering indicies.")
 112
 113 (defconst elpher-type-map
 114   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 115     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 116     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 117     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 118     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 119     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 120     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 122     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 123     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 124     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 125     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 126     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 127     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 128     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 129     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 130     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 131     ((special start) elpher-get-start-page nil "E" elpher-index)
 132     ((special bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 133     ((special history) elpher-get-history-page nil "E" elpher-index)
 134     ((special visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 135   "Association list from types to getters, renderers, margin codes and index faces.")
 136
 137
 138 ;;; Declarations to avoid compiler warnings.
 139 ;;
 140
 141 (eval-when-compile
 142   (declare-function ansi-color-filter-apply "ansi-color")
 143   (declare-function ansi-color-apply "ansi-color")
 144   (declare-function bookmark-store "bookmark")
 145   (declare-function org-link-store-props "ol")
 146   (declare-function org-link-set-parameters "ol")
 147   (defvar ansi-color-context)
 148   (defvar bookmark-make-record-function)
 149   (defvar mu4e~view-beginning-of-url-regexp)
 150   (defvar thing-at-point-uri-schemes))
 151
 152
 153 ;;; Customization group
 154 ;;
 155
 156 (defgroup elpher nil
 157   "A gopher and gemini client."
 158   :group 'applications)
 159
 160 ;; General appearance and customizations
 161
 162 (defcustom elpher-open-urls-with-eww nil
 163   "If non-nil, open URL selectors using eww.
 164 Otherwise, use the system browser via the `browse-url' function."
 165   :type '(boolean))
 166
 167 (defcustom elpher-use-header t
 168   "If non-nil, display current page information in buffer header."
 169   :type '(boolean))
 170
 171 (defcustom elpher-auto-disengage-TLS nil
 172   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 173 While enabling this may seem convenient, it is also potentially
 174 dangerous as it allows switching from an encrypted channel back to
 175 plain text without user input."
 176   :type '(boolean))
 177
 178 (defcustom elpher-connection-timeout 5
 179   "Specifies the number of seconds to wait for a network connection to time out."
 180   :type '(integer))
 181
 182 (defcustom elpher-filter-ansi-from-text nil
 183   "If non-nil, filter ANSI escape sequences from text.
 184 The default behaviour is to use the ansi-color package to interpret these
 185 sequences."
 186   :type '(boolean))
 187
 188 (defcustom elpher-certificate-directory
 189   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 190   "Specify the name of the directory where client certificates will be stored.
 191 These certificates may be used for establishing authenticated TLS connections."
 192   :type '(directory))
 193
 194 (defcustom elpher-openssl-command "openssl"
 195   "The command used to launch openssl when generating TLS client certificates."
 196   :type '(file))
 197
 198 (defcustom elpher-default-url-type "gopher"
 199   "Default URL type (i.e. scheme) to assume if not explicitly given."
 200   :type '(choice (const "gopher")
 201                  (const "gemini")))
 202
 203 (defcustom elpher-gemini-TLS-cert-checks nil
 204   "If non-nil, verify gemini server TLS certs using the default security level.
 205 Otherwise, certificate verification is disabled.
 206
 207 This defaults to off because it is standard practice for Gemini servers
 208 to use self-signed certificates, meaning that most servers provide what
 209 EMACS considers to be an invalid certificate."
 210   :type '(boolean))
 211
 212 (defcustom elpher-gemini-max-fill-width 80
 213   "Specify the maximum default width (in columns) of text/gemini documents.
 214 The actual width used is the minimum of this value and the window width at
 215 the time when the text is rendered."
 216   :type '(integer))
 217
 218 (defcustom elpher-gemini-link-string "→ "
 219   "Specify the string used to indicate links when rendering gemini maps.
 220 May be empty."
 221   :type '(string))
 222
 223 (defcustom elpher-gemini-bullet-string "•"
 224   "Specify the string used for bullets when rendering gemini maps."
 225   :type '(string))
 226
 227 (defcustom elpher-ipv4-always nil
 228   "If non-nil, elpher will always use IPv4 to establish network connections.
 229 This can be useful when browsing from a computer that supports IPv6, because
 230 some servers which do not support IPv6 can take a long time to time-out."
 231   :type '(boolean))
 232
 233 (defcustom elpher-socks-always nil
 234   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 235 Otherwise, the SOCKS proxy is only used for connections to onion services."
 236   :type '(boolean))
 237
 238 ;; Face customizations
 239
 240 (defgroup elpher-faces nil
 241   "Elpher face customizations."
 242   :group 'elpher)
 243
 244 (defface elpher-index
 245   '((t :inherit font-lock-keyword-face))
 246   "Face used for directory type directory records.")
 247
 248 (defface elpher-text
 249   '((t :inherit bold))
 250   "Face used for text type directory records.")
 251
 252 (defface elpher-info
 253   '((t :inherit default))
 254   "Face used for info type directory records.")
 255
 256 (defface elpher-image
 257   '((t :inherit font-lock-string-face))
 258   "Face used for image type directory records.")
 259
 260 (defface elpher-search
 261   '((t :inherit warning))
 262   "Face used for search type directory records.")
 263
 264 (defface elpher-html
 265   '((t :inherit font-lock-comment-face))
 266   "Face used for html type directory records.")
 267
 268 (defface elpher-gemini
 269   '((t :inherit font-lock-constant-face))
 270   "Face used for Gemini type directory records.")
 271
 272 (defface elpher-other-url
 273   '((t :inherit font-lock-comment-face))
 274   "Face used for other URL type links records.")
 275
 276 (defface elpher-telnet
 277   '((t :inherit font-lock-function-name-face))
 278   "Face used for telnet type directory records.")
 279
 280 (defface elpher-binary
 281   '((t :inherit font-lock-doc-face))
 282   "Face used for binary type directory records.")
 283
 284 (defface elpher-unknown
 285   '((t :inherit error))
 286   "Face used for directory records with unknown/unsupported types.")
 287
 288 (defface elpher-margin-key
 289   '((t :inherit bold))
 290   "Face used for directory margin key.")
 291
 292 (defface elpher-margin-brackets
 293   '((t :inherit shadow))
 294   "Face used for brackets around directory margin key.")
 295
 296 (defface elpher-gemini-heading1
 297   '((t :inherit bold :height 1.8))
 298   "Face used for gemini heading level 1.")
 299
 300 (defface elpher-gemini-heading2
 301   '((t :inherit bold :height 1.5))
 302   "Face used for gemini heading level 2.")
 303
 304 (defface elpher-gemini-heading3
 305   '((t :inherit bold :height 1.2))
 306   "Face used for gemini heading level 3.")
 307
 308 (defface elpher-gemini-preformatted
 309   '((t :inherit fixed-pitch))
 310   "Face used for pre-formatted gemini text blocks.")
 311
 312 (defface elpher-gemini-quoted
 313   '((t :inherit font-lock-doc-face))
 314   "Face used for gemini quoted texts.")
 315
 316 ;;; Model
 317 ;;
 318
 319 ;; Address
 320
 321 ;; An elpher "address" object is either a url object or a symbol.
 322 ;; Symbol addresses are "special", corresponding to pages generated
 323 ;; dynamically for and by elpher.  All others represent pages which
 324 ;; rely on content retrieved over the network.
 325
 326 (defun elpher-address-from-url (url-string)
 327   "Create a ADDRESS object corresponding to the given URL-STRING."
 328   (let ((data (match-data))) ; Prevent parsing clobbering match data
 329     (unwind-protect
 330         (let ((url (url-generic-parse-url url-string)))
 331           (unless (and (not (url-fullness url)) (url-type url))
 332             (setf (url-fullness url) t)
 333             (unless (url-type url)
 334               (setf (url-type url) elpher-default-url-type))
 335             (unless (url-host url)
 336               (let ((p (split-string (url-filename url) "/" nil nil)))
 337                 (setf (url-host url) (car p))
 338                 (setf (url-filename url)
 339                       (if (cdr p)
 340                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 341                         ""))))
 342             (when (or (equal "gopher" (url-type url))
 343                       (equal "gophers" (url-type url)))
 344               ;; Gopher defaults
 345               (when (or (equal (url-filename url) "")
 346                         (equal (url-filename url) "/"))
 347                 (setf (url-filename url) "/1")))
 348             (when (equal "gemini" (url-type url))
 349               ;; Gemini defaults
 350               (if (equal (url-filename url) "")
 351                   (setf (url-filename url) "/"))))
 352           (elpher-remove-redundant-ports url))
 353       (set-match-data data))))
 354
 355 (defun elpher-remove-redundant-ports (address)
 356   "Remove redundant port specifiers from ADDRESS.
 357 Here 'redundant' means that the specified port matches the default
 358 for that protocol, eg 70 for gopher."
 359   (if (and (not (elpher-address-special-p address))
 360            (eq (url-portspec address) ; (url-port) is too slow!
 361                (pcase (url-type address)
 362                  ("gemini" 1965)
 363                  ((or "gopher" "gophers") 70)
 364                  ("finger" 79)
 365                  (_ -1))))
 366       (setf (url-portspec address) nil))
 367   address)
 368
 369 (defun elpher-make-gopher-address (type selector host port &optional tls)
 370   "Create an ADDRESS object using gopher directory record attributes.
 371 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 372 If the optional attribute TLS is non-nil, the address will be marked as
 373 requiring gopher-over-TLS."
 374   (cond
 375    ((equal type ?i) nil)
 376    ((and (equal type ?h)
 377          (string-prefix-p "URL:" selector))
 378     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 379    ((equal type ?8)
 380     (elpher-address-from-url
 381      (concat "telnet"
 382              "://" host
 383              ":" (number-to-string port))))
 384    (t
 385     (elpher-address-from-url
 386      (concat "gopher" (if tls "s" "")
 387              "://" host
 388              ":" (number-to-string port)
 389              "/" (string type)
 390              selector)))))
 391
 392 (defun elpher-make-special-address (type)
 393   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 394   type)
 395
 396 (defun elpher-address-to-url (address)
 397   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 398   (if (elpher-address-special-p address)
 399       nil
 400     (url-encode-url (url-recreate-url address))))
 401
 402 (defun elpher-address-type (address)
 403   "Retrieve type of ADDRESS object.
 404 This is used to determine how to retrieve and render the document the
 405 address refers to, via the table `elpher-type-map'."
 406   (if (symbolp address)
 407       (list 'special address)
 408     (let ((protocol (url-type address)))
 409       (cond ((or (equal protocol "gopher")
 410                  (equal protocol "gophers"))
 411              (list 'gopher
 412                    (if (member (url-filename address) '("" "/"))
 413                        ?1
 414                      (string-to-char (substring (url-filename address) 1)))))
 415             ((equal protocol "gemini")
 416              'gemini)
 417             ((equal protocol "telnet")
 418              'telnet)
 419             ((equal protocol "finger")
 420              'finger)
 421             (t 'other-url)))))
 422
 423 (defun elpher-address-protocol (address)
 424   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 425   (if (symbolp address)
 426       nil
 427     (url-type address)))
 428
 429 (defun elpher-address-filename (address)
 430   "Retrieve the filename component of ADDRESS.
 431 For gopher addresses this is a combination of the selector type and selector."
 432   (if (symbolp address)
 433       nil
 434     (url-unhex-string (url-filename address))))
 435
 436 (defun elpher-address-host (address)
 437   "Retrieve host from ADDRESS object."
 438   (url-host address))
 439
 440 (defun elpher-address-user (address)
 441   "Retrieve user from ADDRESS object."
 442   (url-user address))
 443
 444 (defun elpher-address-port (address)
 445   "Retrieve port from ADDRESS object.
 446 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 447   (if (symbolp address)
 448       0
 449     (url-port address)))
 450
 451 (defun elpher-address-special-p (address)
 452   "Return non-nil if ADDRESS object is special (e.g. start page page)."
 453   (symbolp address))
 454
 455 (defun elpher-address-gopher-p (address)
 456   "Return non-nill if ADDRESS object is a gopher address."
 457   (and (not (elpher-address-special-p address))
 458        (member (elpher-address-protocol address) '("gopher" "gophers"))))
 459
 460 (defun elpher-gopher-address-selector (address)
 461   "Retrieve gopher selector from ADDRESS object."
 462   (if (member (url-filename address) '("" "/"))
 463       ""
 464     (url-unhex-string (substring (url-filename address) 2))))
 465
 466
 467 ;; Cache
 468
 469 (defvar elpher-content-cache (make-hash-table :test 'equal))
 470 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 471
 472 (defun elpher-get-cached-content (address)
 473   "Retrieve the cached content for ADDRESS, or nil if none exists."
 474   (gethash address elpher-content-cache))
 475
 476 (defun elpher-cache-content (address content)
 477   "Set the content cache for ADDRESS to CONTENT."
 478   (puthash address content elpher-content-cache))
 479
 480 (defun elpher-get-cached-pos (address)
 481   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 482   (gethash address elpher-pos-cache))
 483
 484 (defun elpher-cache-pos (address pos)
 485   "Set the cursor position cache for ADDRESS to POS."
 486   (puthash address pos elpher-pos-cache))
 487
 488
 489 ;; Page
 490
 491 (defun elpher-make-page (display-string address)
 492   "Create a page with DISPLAY-STRING and ADDRESS."
 493   (list display-string address))
 494
 495 (defun elpher-make-start-page ()
 496   "Create the start page."
 497   (elpher-make-page "Elpher Start Page"
 498                     (elpher-make-special-address 'start)))
 499
 500 (defun elpher-page-display-string (page)
 501   "Retrieve the display string corresponding to PAGE."
 502   (elt page 0))
 503
 504 (defun elpher-page-address (page)
 505   "Retrieve the address corresponding to PAGE."
 506   (elt page 1))
 507
 508 (defun elpher-page-set-address (page new-address)
 509   "Set the address corresponding to PAGE to NEW-ADDRESS."
 510   (setcar (cdr page) new-address))
 511
 512 (defvar elpher-current-page nil
 513   "The current page for this Elpher buffer.")
 514
 515 (defvar elpher-history nil
 516   "The local history stack for this Elpher buffer.
 517 This variable is used by `elpher-back' and
 518 `elpher-show-history'.")
 519
 520 (defvar elpher-visited-pages nil
 521   "The global history for all Elpher buffers.
 522 This variable is used by `elpher-show-visited-pages'.")
 523
 524 (defun elpher-visit-page (page &optional renderer no-history)
 525   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 526 Additionally, push PAGE onto the history stack and the list of
 527 previously-visited pages,unless NO-HISTORY is non-nil."
 528   (elpher-save-pos)
 529   (elpher-process-cleanup)
 530   (unless no-history
 531     (unless (equal (elpher-page-address elpher-current-page)
 532                    (elpher-page-address page))
 533       (push elpher-current-page elpher-history)
 534       (unless (or (elpher-address-special-p (elpher-page-address page))
 535                   (and elpher-visited-pages
 536                        (equal page (car elpher-visited-pages))))
 537         (push page elpher-visited-pages))))
 538   (setq-local elpher-current-page page)
 539   (let* ((address (elpher-page-address page))
 540          (type (elpher-address-type address))
 541          (type-record (cdr (assoc type elpher-type-map))))
 542     (if type-record
 543         (funcall (car type-record)
 544                  (if renderer
 545                      renderer
 546                    (cadr type-record)))
 547       (elpher-visit-previous-page)
 548       (pcase type
 549         (`(gopher ,type-char)
 550          (error "Unsupported gopher selector type '%c' for '%s'"
 551                 type-char (elpher-address-to-url address)))
 552         (other
 553          (error "Unsupported address type '%S' for '%s'"
 554                 other (elpher-address-to-url address)))))))
 555
 556 (defun elpher-visit-previous-page ()
 557   "Visit the previous page in the history."
 558   (let ((previous-page (pop elpher-history)))
 559     (if previous-page
 560         (elpher-visit-page previous-page nil t)
 561       (error "No previous page"))))
 562
 563 (defun elpher-reload-current-page ()
 564   "Reload the current page, discarding any existing cached content."
 565   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 566   (elpher-visit-page elpher-current-page))
 567
 568 (defun elpher-save-pos ()
 569   "Save the current position of point to the current page."
 570   (when elpher-current-page
 571     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 572
 573 (defun elpher-restore-pos ()
 574   "Restore the position of point to that cached in the current page."
 575   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 576     (if pos
 577         (goto-char pos)
 578       (goto-char (point-min)))))
 579
 580
 581 ;;; Buffer preparation
 582 ;;
 583
 584 (defvar elpher-buffer-name "*elpher*"
 585   "The default name of the Elpher buffer.")
 586
 587 (defun elpher-update-header ()
 588   "If `elpher-use-header' is true, display current page info in window header."
 589   (if elpher-use-header
 590       (let* ((display-string (elpher-page-display-string elpher-current-page))
 591              (address (elpher-page-address elpher-current-page))
 592              (tls-string (if (and (not (elpher-address-special-p address))
 593                                   (member (elpher-address-protocol address)
 594                                           '("gophers" "gemini")))
 595                              " [TLS encryption]"
 596                            ""))
 597              (header (concat display-string
 598                              (propertize tls-string 'face 'bold))))
 599         (setq header-line-format header))))
 600
 601 (defmacro elpher-with-clean-buffer (&rest args)
 602   "Evaluate ARGS with a clean *elpher* buffer as current."
 603   `(with-current-buffer elpher-buffer-name
 604      (unless (eq major-mode 'elpher-mode)
 605        ;; avoid resetting buffer-local variables
 606        (elpher-mode))
 607      (let ((inhibit-read-only t)
 608            (ansi-color-context nil)) ;; clean ansi interpreter state
 609        (setq-local network-security-level
 610                    (default-value 'network-security-level))
 611        (erase-buffer)
 612        (elpher-update-header)
 613        ,@args)))
 614
 615 (defun elpher-buffer-message (string &optional line)
 616   "Replace first line in elpher buffer with STRING.
 617 If LINE is non-nil, replace that line instead."
 618   (with-current-buffer elpher-buffer-name
 619     (let ((inhibit-read-only t))
 620       (goto-char (point-min))
 621       (if line
 622           (forward-line line))
 623       (let ((data (match-data)))
 624         (unwind-protect
 625             (progn
 626               (re-search-forward "^.*$")
 627               (replace-match string))
 628           (set-match-data data))))))
 629
 630
 631 ;;; Text Processing
 632 ;;
 633
 634 (defvar elpher-user-coding-system nil
 635   "User-specified coding system to use for decoding text responses.")
 636
 637 (defun elpher-decode (string)
 638   "Decode STRING using autodetected or user-specified coding system."
 639   (decode-coding-string string
 640                         (if elpher-user-coding-system
 641                             elpher-user-coding-system
 642                           (detect-coding-string string t))))
 643
 644 (defun elpher-preprocess-text-response (string)
 645   "Preprocess text selector response contained in STRING.
 646 This involes decoding the character representation, and clearing
 647 away CRs and any terminating period."
 648   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 649                                            (replace-regexp-in-string "\r" "" string))))
 650
 651
 652 ;;; Network error reporting
 653 ;;
 654
 655 (defun elpher-network-error (address error)
 656   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 657 ERROR can be either an error object or a string."
 658   (elpher-with-clean-buffer
 659    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 660            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 661            (if (stringp error) error (error-message-string error)) "\n"
 662            (propertize "\n----------------\n\n" 'face 'error)
 663            "Press 'u' to return to the previous page.")))
 664
 665
 666 ;;; General network communication
 667 ;;
 668
 669 (defvar elpher-network-timer nil
 670   "Timer used for network connections.")
 671
 672 (defvar elpher-use-tls nil
 673   "If non-nil, use TLS to communicate with gopher servers.")
 674
 675 (defvar elpher-client-certificate nil
 676   "If non-nil, contains client certificate details to use for TLS connections.")
 677
 678 (defun elpher-process-cleanup ()
 679   "Immediately shut down any extant elpher process and timers."
 680   (let ((p (get-process "elpher-process")))
 681     (if p (delete-process p)))
 682   (if (timerp elpher-network-timer)
 683       (cancel-timer elpher-network-timer)))
 684
 685 (defun elpher-make-network-timer (thunk)
 686   "Creates a timer to run the THUNK after `elpher-connection-timeout' seconds.
 687 This is just a wraper around `run-at-time' which additionally sets the
 688 buffer-local variable `elpher-network-timer' to allow
 689 `elpher-process-cleanup' to also clear the timer."
 690   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 691     (setq-local elpher-network-timer timer)
 692     timer))
 693
 694 (defun elpher-get-host-response (address default-port query-string response-processor
 695                                          &optional use-tls force-ipv4)
 696   "Generic function for retrieving data from ADDRESS.
 697
 698 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 699 QUERY-STRING is a string sent to the host specified by ADDRESS to
 700 illicet a response.  This response is passed as an argument to the
 701 function RESPONSE-PROCESSOR.
 702
 703 If non-nil, USE-TLS specifies that the connection is to be made over
 704 TLS.  If set to gemini, the certificate verification will be disabled
 705 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 706
 707 If non-nil, FORCE-IPV4 causes the network connection to be made over
 708 ipv4 only.  (The default behaviour when this is not set depends on
 709 the host operating system and the local network capabilities.)"
 710   (if (and use-tls (not (gnutls-available-p)))
 711       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 712     (unless (< (elpher-address-port address) 65536)
 713       (error "Cannot establish network connection: port number > 65536"))
 714     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 715       (setq-local network-security-level 'low)
 716       (setq-local gnutls-verify-error nil))
 717     (condition-case nil
 718         (let* ((kill-buffer-query-functions nil)
 719                (port (elpher-address-port address))
 720                (host (elpher-address-host address))
 721                (service (if (> port 0) port default-port))
 722                (response-string-parts nil)
 723                (bytes-received 0)
 724                (hkbytes-received 0)
 725                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 726                (gnutls-params (list :type 'gnutls-x509pki
 727                                     :hostname host
 728                                     :keylist
 729                                     (elpher-get-current-keylist address)))
 730                (timer (elpher-make-network-timer
 731                                    (lambda ()
 732                                      (elpher-process-cleanup)
 733                                      (cond
 734                                         ; Try again with IPv4
 735                                       ((not (or force-ipv4 socks))
 736                                        (message "Connection timed out.  Retrying with IPv4.")
 737                                        (elpher-get-host-response address default-port
 738                                                                  query-string
 739                                                                  response-processor
 740                                                                  use-tls t))
 741                                       ((and use-tls
 742                                             (not (eq use-tls 'gemini))
 743                                             (or elpher-auto-disengage-TLS
 744                                                 (y-or-n-p
 745                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 746                                        (setq elpher-use-tls nil)
 747                                        (elpher-get-host-response address default-port
 748                                                                  query-string
 749                                                                  response-processor
 750                                                                  nil force-ipv4))
 751                                       (t
 752                                        (elpher-network-error address "Connection time-out."))))))
 753                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 754                        (make-network-process :name "elpher-process"
 755                                              :host host
 756                                              :family (and force-ipv4 'ipv4)
 757                                              :service service
 758                                              :buffer nil
 759                                              :nowait t
 760                                              :tls-parameters
 761                                              (and use-tls
 762                                                   (cons 'gnutls-x509pki
 763                                                         (apply #'gnutls-boot-parameters
 764                                                                gnutls-params)))))))
 765           (setq elpher-network-timer timer)
 766           (set-process-coding-system proc 'binary 'binary)
 767           (set-process-query-on-exit-flag proc nil)
 768           (elpher-buffer-message (concat "Connecting to " host "..."
 769                                          " (press 'u' to abort)"))
 770           (set-process-filter proc
 771                               (lambda (_proc string)
 772                                 (when timer
 773                                   (cancel-timer timer)
 774                                   (setq timer nil))
 775                                 (setq bytes-received (+ bytes-received (length string)))
 776                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 777                                   (when (> new-hkbytes-received hkbytes-received)
 778                                     (setq hkbytes-received new-hkbytes-received)
 779                                     (elpher-buffer-message
 780                                      (concat "("
 781                                              (number-to-string (/ hkbytes-received 10.0))
 782                                              " MB read)")
 783                                      1)))
 784                                 (setq response-string-parts
 785                                       (cons string response-string-parts))))
 786           (set-process-sentinel proc
 787                                 (lambda (proc event)
 788                                   (when timer
 789                                     (cancel-timer timer))
 790                                   (condition-case the-error
 791                                       (cond
 792                                        ((string-prefix-p "open" event)    ; request URL
 793                                         (elpher-buffer-message
 794                                          (concat "Connected to " host ". Receiving data..."
 795                                                  " (press 'u' to abort)"))
 796                                         (let ((inhibit-eol-conversion t))
 797                                           (process-send-string proc query-string)))
 798                                        ((string-prefix-p "deleted" event)) ; do nothing
 799                                        ((and (not response-string-parts)
 800                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 801                                         ; Try again with IPv4
 802                                         (message "Connection failed. Retrying with IPv4.")
 803                                         (elpher-get-host-response address default-port
 804                                                                   query-string
 805                                                                   response-processor
 806                                                                   use-tls t))
 807                                        (response-string-parts
 808                                         (elpher-with-clean-buffer
 809                                          (insert "Data received.  Rendering..."))
 810                                         (funcall response-processor
 811                                                  (apply #'concat (reverse response-string-parts)))
 812                                         (elpher-restore-pos))
 813                                        (t
 814                                         (error "No response from server")))
 815                                     (error
 816                                      (elpher-network-error address the-error)))))
 817           (when socks
 818             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 819             (funcall (process-sentinel proc) proc "open\n")))
 820       (error
 821        (elpher-process-cleanup)
 822        (error "Error initiating connection to server")))))
 823
 824
 825 ;;; Client-side TLS Certificate Management
 826 ;;
 827
 828 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 829   "Generate a key and a self-signed client TLS certificate using openssl.
 830
 831 The Common Name field of the certificate is set to COMMON-NAME.  The
 832 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 833 the key and certificate files to write.
 834
 835 If TEMPORARY is non-nil, the certificate will be given an exporation
 836 period of one day, and the key and certificate files will be deleted
 837 when the certificate is no longer needed for the current session.
 838
 839 Otherwise, the certificate will be given a 100 year expiration period
 840 and the files will not be deleted.
 841
 842 The function returns a list containing the current host name, the
 843 temporary flag, and the key and cert file names in the form required
 844 by `gnutls-boot-parameters`."
 845   (let ((exp-key-file (expand-file-name key-file))
 846         (exp-cert-file (expand-file-name cert-file)))
 847     (condition-case nil
 848         (progn
 849           (call-process elpher-openssl-command nil nil nil
 850                         "req" "-x509" "-newkey" "rsa:2048"
 851                         "-days" (if temporary "1" "36500")
 852                         "-nodes"
 853                         "-subj" (concat "/CN=" common-name)
 854                         "-keyout" exp-key-file
 855                         "-out" exp-cert-file)
 856           (list (elpher-address-host (elpher-page-address elpher-current-page))
 857                 temporary exp-key-file exp-cert-file))
 858       (error
 859        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 860        (error "Program 'openssl', required for certificate generation, not found")))))
 861
 862 (defun elpher-generate-throwaway-certificate ()
 863   "Generate and return details of a throwaway certificate.
 864 The key and certificate files will be deleted when they are no
 865 longer needed for this session."
 866   (let* ((file-base (make-temp-name "elpher"))
 867          (key-file (concat temporary-file-directory file-base ".key"))
 868          (cert-file (concat temporary-file-directory file-base ".crt")))
 869     (elpher-generate-certificate file-base key-file cert-file t)))
 870
 871 (defun elpher-generate-persistent-certificate (file-base common-name)
 872   "Generate and return details of a persistent certificate.
 873 The argument FILE-BASE is used as the base for the key and certificate
 874 files, while COMMON-NAME specifies the common name field of the
 875 certificate.
 876
 877 The key and certificate files are written to in `elpher-certificate-directory'."
 878   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 879          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 880     (elpher-generate-certificate common-name key-file cert-file)))
 881
 882 (defun elpher-get-existing-certificate (file-base)
 883   "Return a certificate object corresponding to an existing certificate.
 884 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 885 the directory `elpher-certificate-directory'."
 886   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 887          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 888     (list (elpher-address-host (elpher-page-address elpher-current-page))
 889           nil
 890           (expand-file-name key-file)
 891           (expand-file-name cert-file))))
 892
 893 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 894   "Install a key+certificate file pair in `elpher-certificate-directory'.
 895 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 896 certificate files to install.  The argument FILE-BASE is used as the
 897 base for the installed key and certificate files."
 898   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 899          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 900     (if (or (file-exists-p key-file)
 901             (file-exists-p cert-file))
 902         (error "A certificate with base name %s is already installed" file-base))
 903     (copy-file key-file-src key-file)
 904     (copy-file cert-file-src cert-file)
 905     (list (elpher-address-host (elpher-page-address elpher-current-page))
 906           nil
 907           (expand-file-name key-file)
 908           (expand-file-name cert-file))))
 909
 910 (defun elpher-list-existing-certificates ()
 911   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 912   (unless (file-directory-p elpher-certificate-directory)
 913     (make-directory elpher-certificate-directory))
 914   (mapcar
 915    (lambda (file)
 916      (file-name-sans-extension file))
 917    (directory-files elpher-certificate-directory nil "\\.key$")))
 918
 919 (defun elpher-forget-current-certificate ()
 920   "Causes any current certificate to be forgotten.)
 921 In the case of throwaway certificates, the key and certificate files
 922 are also deleted."
 923   (interactive)
 924   (when elpher-client-certificate
 925     (unless (and (called-interactively-p 'any)
 926                  (not (y-or-n-p (concat "Really forget client certificate? "
 927                                         "(Throwaway certificates will be deleted.)"))))
 928       (when (cadr elpher-client-certificate)
 929         (delete-file (elt elpher-client-certificate 2))
 930         (delete-file (elt elpher-client-certificate 3)))
 931       (setq elpher-client-certificate nil)
 932       (if (called-interactively-p 'any)
 933           (message "Client certificate forgotten.")))))
 934
 935 (defun elpher-get-current-keylist (address)
 936   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 937
 938 This is obtained from the client certificate described by
 939 `elpher-current-certificate', if one is available and the host for
 940 that certificate matches the host in ADDRESS.
 941
 942 If `elpher-current-certificate' is non-nil, and its host name doesn't
 943 match that of ADDRESS, the certificate is forgotten."
 944   (if elpher-client-certificate
 945       (if (string= (car elpher-client-certificate)
 946                    (elpher-address-host address))
 947           (list (cddr elpher-client-certificate))
 948         (elpher-forget-current-certificate)
 949         (message "Disabling client certificate for new host")
 950         nil)
 951     nil))
 952
 953
 954 ;;; Gopher selector retrieval
 955 ;;
 956
 957 (defun elpher-get-gopher-response (address renderer)
 958   "Get response string from gopher server at ADDRESS and render using RENDERER."
 959   (elpher-get-host-response address 70
 960                             (concat (elpher-gopher-address-selector address) "\r\n")
 961                             renderer
 962                             (or (string= (elpher-address-protocol address) "gophers")
 963                                 elpher-use-tls)))
 964
 965 (defun elpher-get-gopher-page (renderer)
 966   "Getter function for gopher pages.
 967 The RENDERER procedure is used to display the contents of the page
 968 once they are retrieved from the gopher server."
 969   (let* ((address (elpher-page-address elpher-current-page))
 970          (content (elpher-get-cached-content address)))
 971     (if (and content (funcall renderer nil))
 972         (elpher-with-clean-buffer
 973          (insert content)
 974          (elpher-restore-pos))
 975       (elpher-with-clean-buffer
 976        (insert "LOADING... (use 'u' to cancel)\n"))
 977       (condition-case the-error
 978           (elpher-get-gopher-response address renderer)
 979         (error
 980          (elpher-network-error address the-error))))))
 981
 982 ;; Index rendering
 983
 984 (defun elpher-insert-index (string)
 985   "Insert the index corresponding to STRING into the current buffer."
 986   ;; Should be able to split directly on CRLF, but some non-conformant
 987   ;; LF-only servers sadly exist, hence the following.
 988   (let ((str-processed (elpher-preprocess-text-response string)))
 989     (dolist (line (split-string str-processed "\n"))
 990       (ignore-errors
 991         (unless (= (length line) 0)
 992           (let* ((type (elt line 0))
 993                  (fields (split-string (substring line 1) "\t"))
 994                  (display-string (elt fields 0))
 995                  (selector (elt fields 1))
 996                  (host (elt fields 2))
 997                  (port (if (elt fields 3)
 998                            (string-to-number (elt fields 3))
 999                          nil))
1000                  (address (elpher-make-gopher-address type selector host port)))
1001             (elpher-insert-index-record display-string address)))))))
1002
1003 (defun elpher-insert-margin (&optional type-name)
1004   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1005   (if type-name
1006       (progn
1007         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1008                         (concat
1009                          (propertize "[" 'face 'elpher-margin-brackets)
1010                          (propertize type-name 'face 'elpher-margin-key)
1011                          (propertize "]" 'face 'elpher-margin-brackets))))
1012         (insert " "))
1013     (insert (make-string elpher-margin-width ?\s))))
1014
1015 (defun elpher--page-button-help (_window buffer pos)
1016   "Function called by Emacs to generate mouse-over text.
1017 The arguments specify the BUFFER and the POS within the buffer of the item
1018 for which help is required.  The function returns the help to be
1019 displayed.  The _WINDOW argument is currently unused."
1020   (with-current-buffer buffer
1021     (let ((button (button-at pos)))
1022       (when button
1023         (let* ((page (button-get button 'elpher-page))
1024                (address (elpher-page-address page)))
1025           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1026                                                 address
1027                                               (elpher-address-to-url address))))))))
1028
1029 (defun elpher-insert-index-record (display-string &optional address)
1030   "Function to insert an index record into the current buffer.
1031 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1032 If ADDRESS is not supplied or nil the record is rendered as an
1033 'information' line."
1034   (let* ((type (if address (elpher-address-type address) nil))
1035          (type-map-entry (cdr (assoc type elpher-type-map))))
1036     (if type-map-entry
1037         (let* ((margin-code (elt type-map-entry 2))
1038                (face (elt type-map-entry 3))
1039                (filtered-display-string (elpher-color-filter-apply display-string))
1040                (page (elpher-make-page filtered-display-string address)))
1041           (elpher-insert-margin margin-code)
1042           (insert-text-button filtered-display-string
1043                               'face face
1044                               'elpher-page page
1045                               'action #'elpher-click-link
1046                               'follow-link t
1047                               'help-echo #'elpher--page-button-help))
1048       (pcase type
1049         ('nil ;; Information
1050          (elpher-insert-margin)
1051          (let ((propertized-display-string
1052                 (propertize display-string 'face 'elpher-info)))
1053            (insert (elpher-process-text-for-display propertized-display-string))))
1054         (`(gopher ,selector-type) ;; Unknown
1055          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1056          (insert (propertize display-string
1057                              'face 'elpher-unknown)))))
1058     (insert "\n")))
1059
1060 (defun elpher-click-link (button)
1061   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1062   (let ((page (button-get button 'elpher-page)))
1063     (elpher-visit-page page)))
1064
1065 (defun elpher-render-index (data &optional _mime-type-string)
1066   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1067   (elpher-with-clean-buffer
1068    (if (not data)
1069        t
1070      (elpher-insert-index data)
1071      (elpher-cache-content (elpher-page-address elpher-current-page)
1072                            (buffer-string)))))
1073
1074 ;; Text rendering
1075
1076 (defconst elpher-url-regex
1077   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
1078   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
1079
1080 (defun elpher-buttonify-urls (string)
1081   "Turn substrings which look like urls in STRING into clickable buttons."
1082   (with-temp-buffer
1083     (insert string)
1084     (goto-char (point-min))
1085     (while (re-search-forward elpher-url-regex nil t)
1086       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1087                                     (elpher-address-from-url (match-string 0)))))
1088         (make-text-button (match-beginning 0)
1089                           (match-end 0)
1090                           'elpher-page  page
1091                           'action #'elpher-click-link
1092                           'follow-link t
1093                           'help-echo #'elpher--page-button-help
1094                           'face 'button)))
1095     (buffer-string)))
1096
1097 (defun elpher-process-text-for-display (string)
1098   "Perform any desired processing of STRING prior to display as text.
1099 Currently includes buttonifying URLs and processing ANSI escape codes."
1100   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1101                              (elpher-color-filter-apply string)
1102                            (elpher-color-apply string))))
1103
1104 (defun elpher-render-text (data &optional _mime-type-string)
1105   "Render DATA as text.  MIME-TYPE-STRING is unused."
1106   (elpher-with-clean-buffer
1107    (if (not data)
1108        t
1109      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1110      (elpher-cache-content
1111       (elpher-page-address elpher-current-page)
1112       (buffer-string)))))
1113
1114 ;; Image retrieval
1115
1116 (defun elpher-render-image (data &optional _mime-type-string)
1117   "Display DATA as image.  MIME-TYPE-STRING is unused."
1118   (if (not data)
1119       nil
1120     (if (display-images-p)
1121         (progn
1122           (let ((image (create-image
1123                         data
1124                         nil t)))
1125             (elpher-with-clean-buffer
1126              (insert-image image)
1127              (elpher-restore-pos))))
1128       (elpher-render-download data))))
1129
1130 ;; Search retrieval and rendering
1131
1132 (defun elpher-get-gopher-query-page (renderer)
1133   "Getter for gopher addresses requiring input.
1134 The response is rendered using the rendering function RENDERER."
1135   (let* ((address (elpher-page-address elpher-current-page))
1136          (content (elpher-get-cached-content address))
1137          (aborted t))
1138     (if (and content (funcall renderer nil))
1139         (elpher-with-clean-buffer
1140          (insert content)
1141          (elpher-restore-pos)
1142          (message "Displaying cached search results.  Reload to perform a new search."))
1143       (unwind-protect
1144           (let* ((query-string (read-string "Query: "))
1145                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1146                  (search-address (elpher-make-gopher-address ?1
1147                                                              query-selector
1148                                                              (elpher-address-host address)
1149                                                              (elpher-address-port address)
1150                                                              (equal (elpher-address-type address) "gophers"))))
1151             (setq aborted nil)
1152
1153             (elpher-with-clean-buffer
1154              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1155             (elpher-get-gopher-response search-address renderer))
1156         (if aborted
1157             (elpher-visit-previous-page))))))
1158
1159 ;; Raw server response rendering
1160
1161 (defun elpher-render-raw (data &optional mime-type-string)
1162   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1163   (if (not data)
1164       nil
1165     (elpher-with-clean-buffer
1166      (when mime-type-string
1167        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1168      (insert data)
1169      (goto-char (point-min)))
1170     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1171
1172 ;; File save "rendering"
1173
1174 (defun elpher-render-download (data &optional _mime-type-string)
1175   "Save DATA to file.  MIME-TYPE-STRING is unused."
1176   (if (not data)
1177       nil
1178     (let* ((address (elpher-page-address elpher-current-page))
1179            (selector (if (elpher-address-gopher-p address)
1180                          (elpher-gopher-address-selector address)
1181                        (elpher-address-filename address))))
1182       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1183       (let* ((filename-proposal (file-name-nondirectory selector))
1184              (filename (read-file-name "Download complete. Save file as: "
1185                                        nil nil nil
1186                                        (if (> (length filename-proposal) 0)
1187                                            filename-proposal
1188                                          "download.file"))))
1189         (let ((coding-system-for-write 'binary))
1190           (with-temp-file filename
1191             (insert data)))
1192         (message (format "Saved to file %s." filename))))))
1193
1194 ;; HTML rendering
1195
1196 (defun elpher-render-html (data &optional _mime-type-string)
1197   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1198   (elpher-with-clean-buffer
1199    (if (not data)
1200        t
1201      (let ((dom (with-temp-buffer
1202                   (insert data)
1203                   (libxml-parse-html-region (point-min) (point-max)))))
1204        (shr-insert-document dom)))))
1205
1206 ;; Gemini page retrieval
1207
1208 (defvar elpher-gemini-redirect-chain)
1209
1210 (defun elpher-get-gemini-response (address renderer)
1211   "Get response string from gemini server at ADDRESS and render using RENDERER."
1212   (elpher-get-host-response address 1965
1213                             (concat (elpher-address-to-url address) "\r\n")
1214                             (lambda (response-string)
1215                               (elpher-process-gemini-response response-string renderer))
1216                             'gemini))
1217
1218 (defun elpher-parse-gemini-response (response)
1219   "Parse the RESPONSE string and return a list of components.
1220 The list is of the form (code meta body).  A response of nil implies
1221 that the response was malformed."
1222   (let ((header-end-idx (string-match "\r\n" response)))
1223     (if header-end-idx
1224         (let ((header (string-trim (substring response 0 header-end-idx)))
1225               (body (substring response (+ header-end-idx 2))))
1226           (if (>= (length header) 2)
1227               (let ((code (substring header 0 2))
1228                     (meta (string-trim (substring header 2))))
1229                 (list code meta body))
1230             (error "Malformed response: No response status found in header %s" header)))
1231       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1232
1233 (defun elpher-process-gemini-response (response-string renderer)
1234   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1235   (let ((response-components (elpher-parse-gemini-response response-string)))
1236     (let ((response-code (elt response-components 0))
1237           (response-meta (elt response-components 1))
1238           (response-body (elt response-components 2)))
1239       (pcase (elt response-code 0)
1240         (?1 ; Input required
1241          (elpher-with-clean-buffer
1242           (insert "Gemini server is requesting input."))
1243          (let* ((query-string
1244                  (if (eq (elt response-code 1) ?1)
1245                      (read-passwd (concat response-meta ": "))
1246                    (read-string (concat response-meta ": "))))
1247                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1248                 (old-fname (url-filename query-address)))
1249            (setf (url-filename query-address)
1250                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1251            (elpher-get-gemini-response query-address renderer)))
1252         (?2 ; Normal response
1253          (funcall renderer response-body response-meta))
1254         (?3 ; Redirect
1255          (message "Following redirect to %s" response-meta)
1256          (if (>= (length elpher-gemini-redirect-chain) 5)
1257              (error "More than 5 consecutive redirects followed"))
1258          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1259            (if (member redirect-address elpher-gemini-redirect-chain)
1260                (error "Redirect loop detected"))
1261            (if (not (string= (elpher-address-protocol redirect-address)
1262                              "gemini"))
1263                (error "Server tried to automatically redirect to non-gemini URL: %s"
1264                       response-meta))
1265            (elpher-page-set-address elpher-current-page redirect-address)
1266            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1267            (elpher-get-gemini-response redirect-address renderer)))
1268         (?4 ; Temporary failure
1269          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1270                 response-code response-meta))
1271         (?5 ; Permanent failure
1272          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1273                 response-code response-meta))
1274         (?6 ; Client certificate required
1275          (elpher-with-clean-buffer
1276           (if elpher-client-certificate
1277               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1278             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1279           (auto-fill-mode 1)
1280           (elpher-gemini-insert-text response-meta))
1281          (let ((chosen-certificate (elpher-choose-client-certificate)))
1282            (unless chosen-certificate
1283              (error "Gemini server requires a client certificate and none was provided"))
1284            (setq elpher-client-certificate chosen-certificate))
1285          (elpher-with-clean-buffer)
1286          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1287         (_other
1288          (error "Gemini server response unknown: %s %s"
1289                 response-code response-meta))))))
1290
1291 (defun elpher--read-answer-polyfill (question answers)
1292   "Polyfill for `read-answer' in Emacs 26.1.
1293 QUESTION is a string containing a question, and ANSWERS
1294 is a list of possible answers."
1295     (completing-read question (mapcar 'identity answers)))
1296
1297 (if (fboundp 'read-answer)
1298     (defalias 'elpher-read-answer 'read-answer)
1299   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1300
1301 (defun elpher-choose-client-certificate ()
1302   "Prompt for a client certificate to use to establish a TLS connection."
1303   (let* ((read-answer-short t))
1304     (pcase (read-answer "What do you want to do? "
1305                         '(("throwaway" ?t
1306                            "generate and use throw-away certificate")
1307                           ("persistent" ?p
1308                            "generate new or use existing persistent certificate")
1309                           ("abort" ?a
1310                            "stop immediately")))
1311       ("throwaway"
1312        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1313       ("persistent"
1314        (let* ((existing-certificates (elpher-list-existing-certificates))
1315               (file-base (completing-read
1316                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1317                           existing-certificates)))
1318          (if (string-empty-p (string-trim file-base))
1319              nil
1320            (if (member file-base existing-certificates)
1321                (setq elpher-client-certificate
1322                      (elpher-get-existing-certificate file-base))
1323              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1324                                  '(("new" ?n
1325                                     "generate new certificate")
1326                                    ("install" ?i
1327                                     "install existing certificate")
1328                                    ("abort" ?a
1329                                     "stop immediately")))
1330                ("new"
1331                 (let ((common-name (read-string "Common Name field for new certificate: "
1332                                                 file-base)))
1333                   (message "New key and self-signed certificate written to %s"
1334                            elpher-certificate-directory)
1335                   (elpher-generate-persistent-certificate file-base common-name)))
1336                ("install"
1337                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1338                        (key-file (read-file-name "Key file: " nil nil t)))
1339                   (message "Key and certificate installed in %s for future use"
1340                            elpher-certificate-directory)
1341                   (elpher-install-and-use-existing-certificate key-file
1342                                                                cert-file
1343                                                                file-base)))
1344                ("abort" nil))))))
1345       ("abort" nil))))
1346
1347 (defun elpher-get-gemini-page (renderer)
1348   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1349   (let* ((address (elpher-page-address elpher-current-page))
1350          (content (elpher-get-cached-content address)))
1351     (condition-case the-error
1352         (if (and content (funcall renderer nil))
1353             (elpher-with-clean-buffer
1354              (insert content)
1355              (elpher-restore-pos))
1356           (elpher-with-clean-buffer
1357            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1358           (setq elpher-gemini-redirect-chain nil)
1359           (elpher-get-gemini-response address renderer))
1360       (error
1361        (elpher-network-error address the-error)))))
1362
1363 (defun elpher-render-gemini (body &optional mime-type-string)
1364   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1365   (if (not body)
1366       t
1367     (let* ((mime-type-string* (if (or (not mime-type-string)
1368                                       (string-empty-p mime-type-string))
1369                                   "text/gemini; charset=utf-8"
1370                                 mime-type-string))
1371            (mime-type-split (split-string mime-type-string* ";" t))
1372            (mime-type (string-trim (car mime-type-split)))
1373            (parameters (mapcar (lambda (s)
1374                                  (let ((key-val (split-string s "=")))
1375                                    (list (downcase (string-trim (car key-val)))
1376                                          (downcase (string-trim (cadr key-val))))))
1377                                (cdr mime-type-split))))
1378       (when (string-prefix-p "text/" mime-type)
1379         (setq body (decode-coding-string
1380                     body
1381                     (if (assoc "charset" parameters)
1382                         (intern (cadr (assoc "charset" parameters)))
1383                       'utf-8)))
1384         (setq body (replace-regexp-in-string "\r" "" body)))
1385       (pcase mime-type
1386         ((or "text/gemini" "")
1387          (elpher-render-gemini-map body parameters))
1388         ("text/html"
1389          (elpher-render-html body))
1390         ((pred (string-prefix-p "text/"))
1391          (elpher-render-gemini-plain-text body parameters))
1392         ((pred (string-prefix-p "image/"))
1393          (elpher-render-image body))
1394         (_other
1395          (elpher-render-download body))))))
1396
1397 (defun elpher-gemini-get-link-url (link-line)
1398   "Extract the url portion of LINK-LINE, a gemini map file link line.
1399 Returns nil in the event that the contents of the line following the
1400 => prefix are empty."
1401   (let ((l (split-string (substring link-line 2))))
1402     (if l
1403         (string-trim (elt l 0))
1404       nil)))
1405
1406 (defun elpher-gemini-get-link-display-string (link-line)
1407   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1408 Returns the url portion in the event that the display-string portion is empty."
1409   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1410          (idx (string-match "[ \t]" rest)))
1411     (string-trim (if idx
1412                      (substring rest (+ idx 1))
1413                    rest))))
1414
1415 (defun elpher-collapse-dot-sequences (filename)
1416   "Collapse dot sequences in FILENAME.
1417 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1418   (let* ((path (split-string filename "/"))
1419          (path-reversed-normalized
1420           (seq-reduce (lambda (a b)
1421                         (cond ((and a (equal b "..") (cdr a)))
1422                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1423                               ((equal b ".") a)
1424                               (t (cons b a))))
1425                       path nil)))
1426     (string-join (reverse path-reversed-normalized) "/")))
1427
1428 (defun elpher-address-from-gemini-url (url)
1429   "Extract address from URL with defaults as per gemini map files.
1430 While there's obviously some redundancy here between this function and
1431 `elpher-address-from-url', gemini map file URLs require enough special
1432 treatment that a separate function is warranted."
1433   (let ((address (url-generic-parse-url url))
1434         (current-address (elpher-page-address elpher-current-page)))
1435     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1436       (setf (url-fullness address) t)
1437       (if (url-host address) ;if there is an explicit host, filenames are absolute
1438           (if (string-empty-p (url-filename address))
1439               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1440         (setf (url-host address) (url-host current-address))
1441         (setf (url-port address) (url-port current-address))
1442         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1443           (setf (url-filename address)
1444                 (concat (file-name-directory (url-filename current-address))
1445                         (url-filename address)))))
1446       (unless (url-type address)
1447         (setf (url-type address) "gemini"))
1448       (when (equal (url-type address) "gemini")
1449         (setf (url-filename address)
1450               (elpher-collapse-dot-sequences (url-filename address)))))
1451     (elpher-remove-redundant-ports address)))
1452
1453 (defun elpher-gemini-insert-link (link-line)
1454   "Insert link described by LINK-LINE into a text/gemini document."
1455   (let* ((url (elpher-gemini-get-link-url link-line))
1456          (display-string (elpher-gemini-get-link-display-string link-line))
1457          (address (elpher-address-from-gemini-url url))
1458          (type (if address (elpher-address-type address) nil))
1459          (type-map-entry (cdr (assoc type elpher-type-map))))
1460     (when display-string
1461       (insert elpher-gemini-link-string)
1462       (if type-map-entry
1463           (let* ((face (elt type-map-entry 3))
1464                  (filtered-display-string (elpher-color-filter-apply display-string))
1465                  (page (elpher-make-page filtered-display-string address)))
1466             (insert-text-button filtered-display-string
1467                                 'face face
1468                                 'elpher-page page
1469                                 'action #'elpher-click-link
1470                                 'follow-link t
1471                                 'help-echo #'elpher--page-button-help))
1472         (insert (propertize display-string 'face 'elpher-unknown)))
1473       (insert "\n"))))
1474
1475 (defvar elpher--gemini-page-headings nil
1476   "List of headings on the page.")
1477
1478 (defun elpher-gemini-insert-header (header-line)
1479   "Insert header described by HEADER-LINE into a text/gemini document.
1480 The gemini map file line describing the header is given
1481 by HEADER-LINE."
1482   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1483     (let* ((level (length (match-string 1 header-line)))
1484            (header (substring header-line (match-end 0)))
1485            (face (pcase level
1486                    (1 'elpher-gemini-heading1)
1487                    (2 'elpher-gemini-heading2)
1488                    (3 'elpher-gemini-heading3)
1489                    (_ 'default)))
1490            (fill-column (if (display-graphic-p)
1491                             (/ (* fill-column
1492                                   (font-get (font-spec :name (face-font 'default)) :size))
1493                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1494       (setq elpher--gemini-page-headings (cons (cons header (point))
1495                                                elpher--gemini-page-headings))
1496       (unless (display-graphic-p)
1497         (insert (make-string level ?#) " "))
1498       (insert (propertize header 'face face))
1499       (newline))))
1500
1501 (defun elpher-gemini-insert-text (text-line)
1502   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1503 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1504 width defined by `elpher-gemini-max-fill-width'."
1505   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1506   (let* ((line-prefix (match-string 2 text-line))
1507          (processed-text-line
1508           (if line-prefix
1509               (cond ((string-prefix-p "*" line-prefix)
1510                      (concat
1511                       (replace-regexp-in-string "\\*"
1512                                                 elpher-gemini-bullet-string
1513                                                 (match-string 0 text-line))
1514                       (substring text-line (match-end 0))))
1515                     ((string-prefix-p ">" line-prefix)
1516                      (propertize text-line 'face 'elpher-gemini-quoted))
1517                     (t text-line))
1518             text-line))
1519          (adaptive-fill-mode t)
1520          ;; fill-prefix is important for adaptive-fill-mode: without
1521          ;; it, multi-line list items are not indented correct
1522          (fill-prefix (if (match-string 2 text-line)
1523                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1524                         nil)))
1525     (insert (elpher-process-text-for-display processed-text-line))
1526     (newline)))
1527
1528 (defun elpher-render-gemini-map (data _parameters)
1529   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1530   (elpher-with-clean-buffer
1531    (setq elpher--gemini-page-headings nil)
1532    (let ((preformatted nil))
1533      (auto-fill-mode 1)
1534      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1535      (dolist (line (split-string data "\n"))
1536        (cond
1537         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1538         (preformatted (insert (elpher-process-text-for-display
1539                                (propertize line 'face 'elpher-gemini-preformatted))
1540                               "\n"))
1541         ((string-prefix-p "=>" line)
1542          (elpher-gemini-insert-link line))
1543         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1544         (t (elpher-gemini-insert-text line)))))
1545    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1546    (elpher-cache-content
1547     (elpher-page-address elpher-current-page)
1548     (buffer-string))))
1549
1550 (defun elpher-render-gemini-plain-text (data _parameters)
1551   "Render DATA as plain text file.  PARAMETERS is currently unused."
1552   (elpher-with-clean-buffer
1553    (insert (elpher-process-text-for-display data))
1554    (elpher-cache-content
1555     (elpher-page-address elpher-current-page)
1556     (buffer-string))))
1557
1558
1559 ;; Finger page connection
1560
1561 (defun elpher-get-finger-page (renderer)
1562   "Opens a finger connection to the current page address.
1563 The result is rendered using RENDERER."
1564   (let* ((address (elpher-page-address elpher-current-page))
1565          (content (elpher-get-cached-content address)))
1566     (if (and content (funcall renderer nil))
1567         (elpher-with-clean-buffer
1568          (insert content)
1569          (elpher-restore-pos))
1570       (elpher-with-clean-buffer
1571        (insert "LOADING... (use 'u' to cancel)\n"))
1572       (condition-case the-error
1573           (let* ((kill-buffer-query-functions nil)
1574                  (user (let ((filename (elpher-address-filename address)))
1575                          (if (> (length filename) 1)
1576                              (substring filename 1)
1577                            (elpher-address-user address)))))
1578             (elpher-get-host-response address 79
1579                                       (concat user "\r\n")
1580                                       renderer))
1581         (error
1582          (elpher-network-error address the-error))))))
1583
1584
1585 ;; Telnet page connection
1586
1587 (defun elpher-get-telnet-page (renderer)
1588   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1589   (when renderer
1590     (elpher-visit-previous-page)
1591     (error "Command not supported for telnet URLs"))
1592   (let* ((address (elpher-page-address elpher-current-page))
1593          (host (elpher-address-host address))
1594          (port (elpher-address-port address)))
1595     (elpher-visit-previous-page)
1596     (if (> port 0)
1597         (telnet host port)
1598       (telnet host))))
1599
1600
1601 ;; Other URL page opening
1602
1603 (defun elpher-get-other-url-page (renderer)
1604   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1605   (when renderer
1606     (elpher-visit-previous-page)
1607     (error "Command not supported for general URLs"))
1608   (let* ((address (elpher-page-address elpher-current-page))
1609          (url (elpher-address-to-url address)))
1610     (progn
1611       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1612       (message "Opening URL...")
1613       (if elpher-open-urls-with-eww
1614           (browse-web url)
1615         (browse-url url)))))
1616
1617
1618 ;; Start page retrieval
1619
1620 (defun elpher-get-start-page (renderer)
1621   "Getter which displays the start page (RENDERER must be nil)."
1622   (when renderer
1623     (elpher-visit-previous-page)
1624     (error "Command not supported for start page"))
1625   (elpher-with-clean-buffer
1626    (insert "     --------------------------------------------\n"
1627            "           Elpher Gopher and Gemini Client       \n"
1628            "                   version " elpher-version "\n"
1629            "     --------------------------------------------\n"
1630            "\n"
1631            "Default bindings:\n"
1632            "\n"
1633            " - TAB/Shift-TAB: next/prev item on current page\n"
1634            " - RET/mouse-1: open item under cursor\n"
1635            " - m: select an item on current page by name (autocompletes)\n"
1636            " - u/mouse-3/U: return to previous page or to the start page\n"
1637            " - g: go to a particular address (gopher, gemini, finger)\n"
1638            " - o/O: open a different address selector or the root menu of the current server\n"
1639            " - d/D: download item under cursor or current page\n"
1640            " - i/I: info on item under cursor or current page\n"
1641            " - c/C: copy URL representation of item under cursor or current page\n"
1642            " - a/A: bookmark the item under cursor or current page\n"
1643            " - B: list all bookmarks\n"
1644            " - s/S: show current history stack or all previously visted pages\n"
1645            " - r: redraw current page (using cached contents if available)\n"
1646            " - R: reload current page (regenerates cache)\n"
1647            " - !: set character coding system for gopher (default is to autodetect)\n"
1648            " - T: toggle TLS gopher mode\n"
1649            " - F: forget/discard current TLS client certificate\n"
1650            " - .: display the raw server response for the current page\n"
1651            "\n"
1652            "Start your exploration of gopher space and gemini:\n")
1653    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1654                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1655    (elpher-insert-index-record "Project Gemini home page"
1656                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1657    (insert "\n"
1658            "Alternatively, select a search engine and enter some search terms:\n")
1659    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1660                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1661    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1662                                (elpher-address-from-url "gemini://geminispace.info/search"))
1663    (insert "\n"
1664            "Your bookmarks are stored in your ")
1665    (let ((help-string "RET,mouse-1: Open Emacs bookmark list"))
1666      (insert-text-button "Emacs bookmark list"
1667                          'face 'link
1668                          'action (lambda (_)
1669                                    (interactive)
1670                                    (call-interactively #'elpher-open-bookmarks))
1671                          'follow-link t
1672                          'help-echo help-string))
1673    (insert ".\n")
1674    (insert (propertize
1675             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1676             'face 'shadow))
1677    (insert "\n"
1678            "The gopher home of the Elpher project is here:\n")
1679    (elpher-insert-index-record "The Elpher Project Page"
1680                                (elpher-make-gopher-address ?1
1681                                                            "/projects/elpher/"
1682                                                            "thelambdalab.xyz"
1683                                                            70))
1684    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1685      (insert "\n"
1686              "The following info documentation is available:\n"
1687              "   - ")
1688      (insert-text-button "Elpher Manual"
1689                          'face 'link
1690                          'action (lambda (_)
1691                                    (interactive)
1692                                    (info "(elpher)"))
1693                          'follow-link t
1694                          'help-echo help-string)
1695      (insert "\n   - ")
1696      (insert-text-button "Changes introduced by the latest release"
1697                        'face 'link
1698                        'action (lambda (_)
1699                                  (interactive)
1700                                  (info "(elpher)News"))
1701                        'follow-link t
1702                        'help-echo help-string))
1703    (insert "\n")
1704    (insert (propertize
1705             (concat "  (These documents should be available if you have installed Elpher \n"
1706                     "   using MELPA. Otherwise you may have to install the manual yourself.)\n")
1707             'face 'shadow))
1708    (elpher-restore-pos)))
1709
1710 ;; History page retrieval
1711
1712 (defun elpher-show-history ()
1713   "Show the current contents of elpher's history stack.
1714 Use \\[elpher-show-visited-pages] to see the entire history.
1715 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1716   (interactive)
1717   (elpher-visit-page
1718    (elpher-make-page "Current History Stack"
1719                      (elpher-make-special-address 'history))))
1720
1721 (defun elpher-show-visited-pages ()
1722   "Show the all the pages you've visited using Elpher.
1723 Use \\[elpher-show-history] to see just the current history stack.
1724 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1725   (interactive)
1726   (elpher-visit-page
1727    (elpher-make-page "Elpher Visted Pages"
1728                      (elpher-make-special-address 'visited-pages))))
1729
1730 (defun elpher-get-history-page (renderer)
1731   "Getter which displays the history page (RENDERER must be nil)."
1732   (when renderer
1733     (elpher-visit-previous-page)
1734     (error "Command not supported for history page"))
1735   (elpher-display-history-links elpher-history "Current history stack"))
1736
1737 (defun elpher-get-visited-pages-page (renderer)
1738   "Getter which displays the list of visited pages (RENDERER must be nil)."
1739   (when renderer
1740     (elpher-visit-previous-page)
1741     (error "Command not supported for history page"))
1742   (elpher-display-history-links
1743    (seq-filter (lambda (page)
1744                  (not (elpher-address-special-p (elpher-page-address page))))
1745                elpher-visited-pages)
1746    "All visited pages"))
1747
1748 (defun elpher-display-history-links (pages title)
1749   "Show all PAGES in an Elpher buffer with a given TITLE."
1750   (let* ((title-line (concat "---- " title " ----"))
1751          (footer-line (make-string (length title-line) ?-)))
1752     (elpher-with-clean-buffer
1753      (insert title-line "\n\n")
1754      (if pages
1755          (dolist (page pages)
1756            (when page
1757              (let ((display-string (elpher-page-display-string page))
1758                    (address (elpher-page-address page)))
1759                (elpher-insert-index-record display-string address))))
1760        (insert "No history items found.\n"))
1761      (insert "\n" footer-line "\n"
1762              "Select an entry or press 'u' to return to the previous page.")
1763      (elpher-restore-pos))))
1764
1765
1766 ;;; Bookmarks
1767
1768 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1769 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1770 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1771 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1772
1773 (defvar elpher-bookmark-link nil
1774   "Prefer bookmarking a link or the current page.
1775 Bind this variable dynamically, or set it to t.
1776 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1777 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1778
1779 (defun elpher-bookmark-make-record ()
1780   "Return a bookmark record.
1781 If `elpher-bookmark-link' is non-nil and point is on a link button,
1782 return a bookmark record for that link.  Otherwise, return a bookmark
1783 record for the current elpher page."
1784   (let* ((button (and elpher-bookmark-link (button-at (point))))
1785          (page (if button
1786                    (button-get button 'elpher-page)
1787                  elpher-current-page))
1788          (address (elpher-page-address page))
1789          (url (elpher-address-to-url address))
1790          (display-string (elpher-page-display-string page))
1791          (pos (if button nil (point))))
1792     (if (elpher-address-special-p address)
1793         (error "Cannot bookmark %s" display-string)
1794       `(,display-string
1795         (defaults . (,display-string))
1796         (position . ,pos)
1797         (location . ,url)
1798         (handler . elpher-bookmark-jump)))))
1799
1800 ;;;###autoload
1801 (defun elpher-bookmark-jump (bookmark)
1802   "Handler used to open a bookmark using elpher.
1803 The argument BOOKMARK is a bookmark record passed to the function.
1804 This handler is responsible for loading the bookmark in some buffer,
1805 then making that buffer the current buffer.  It should not switch
1806 to the buffer."
1807   (let* ((url (cdr (assq 'location bookmark)))
1808          (cleaned-url (string-trim url))
1809          (address (elpher-address-from-url cleaned-url))
1810          (page (elpher-make-page cleaned-url address)))
1811     (elpher-with-clean-buffer
1812      (elpher-visit-page page))
1813     (set-buffer (get-buffer elpher-buffer-name))
1814     nil))
1815
1816 (defun elpher-bookmark-link ()
1817   "Bookmark the link at point.
1818 To bookmark the current page, use \\[elpher-bookmark-current]."
1819   (interactive)
1820   (let ((elpher-bookmark-link t))
1821     (bookmark-set-no-overwrite)))
1822
1823 (defun elpher-bookmark-current ()
1824   "Bookmark the current page.
1825 To bookmark the link at point use \\[elpher-bookmark-link]."
1826   (interactive)
1827   (call-interactively #'bookmark-set-no-overwrite))
1828
1829 (defun elpher-bookmark-import (file)
1830   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1831   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1832                               (file-readable-p elpher-bookmarks-file))
1833                          elpher-bookmarks-file
1834                        (read-file-name "Old Elpher bookmarks: "
1835                                        user-emacs-directory nil t
1836                                        "elpher-bookmarks"))))
1837   (require 'bookmark)
1838   (dolist (bookmark (with-temp-buffer
1839                       (insert-file-contents file)
1840                       (read (current-buffer))))
1841     (let* ((display-string (car bookmark))
1842            (url (cadr bookmark))
1843            (record `(,display-string
1844                      (location . ,url)
1845                      (handler . elpher-bookmark-jump))))
1846       (bookmark-store display-string (cdr record) t)))
1847   (bookmark-save))
1848
1849 (defun elpher-open-bookmarks ()
1850   "Display the current list of elpher bookmarks.
1851 This is just a call to `bookmark-bmenu-list', but we also check for a legacy
1852 bookmark file and offer to import it."
1853   (interactive)
1854   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1855                                      elpher-bookmarks-file)
1856                                 (locate-user-emacs-file "elpher-bookmarks"))))
1857     (when (and (file-readable-p old-bookmarks-file)
1858                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1859                                  old-bookmarks-file
1860                                  "\" found. Import now?")))
1861       (elpher-bookmark-import old-bookmarks-file)
1862       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1863   (call-interactively #'bookmark-bmenu-list))
1864
1865 (defun elpher-get-bookmarks-page (renderer)
1866   "Getter which displays the history page (RENDERER must be nil)."
1867   (when renderer
1868     (elpher-visit-previous-page)
1869     (error "Command not supported for bookmarks page"))
1870   (let* ((names (seq-filter (lambda (name)
1871                               (let ((record (bookmark-get-bookmark-record name)))
1872                                 ;; record
1873                                 (eq (alist-get 'handler record) 'elpher-bookmark-jump)
1874                                 ))
1875                             (bookmark-all-names))))
1876     (elpher-with-clean-buffer
1877      (insert " ---- Elpher Bookmarks ---- \n\n")
1878      (if names
1879          (dolist (name names)
1880            (when names
1881              (let* ((url (alist-get 'location (bookmark-get-bookmark-record name)))
1882                     (address (elpher-address-from-url url)))
1883                (elpher-insert-index-record name address))))
1884        (insert "No bookmarked pages found.\n"))
1885      (insert "\n --------------------------\n\n"
1886              "Select an entry or press 'u' to return to the previous page.")
1887      (elpher-restore-pos))))
1888
1889 (defun elpher-show-bookmarks ()
1890   "Show elpher bookmarks."
1891   (interactive)
1892   (elpher-visit-page
1893    (elpher-make-page "Elpher Bookmarks"
1894                      (elpher-make-special-address 'bookmarks))))
1895
1896 ;;; Integrations
1897 ;;
1898
1899 ;;; Org
1900
1901 (defun elpher-org-export-link (link description format protocol)
1902   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1903
1904 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1905 of gemini, gopher or finger."
1906   (let* ((url (if (equal protocol "elpher")
1907                   (string-remove-prefix "elpher:" link)
1908                 (format "%s:%s" protocol link)))
1909          (desc (or description url)))
1910     (pcase format
1911       (`gemini (format "=> %s %s" url desc))
1912       (`html (format "<a href=\"%s\">%s</a>" url desc))
1913       (`latex (format "\\href{%s}{%s}" url desc))
1914       (_ (if (not description)
1915              url
1916            (format "%s (%s)" desc url))))))
1917
1918 (defun elpher-org-store-link ()
1919   "Store link to an `elpher' page in Org."
1920   (when (eq major-mode 'elpher-mode)
1921     (let* ((url (elpher-info-current))
1922            (desc (car elpher-current-page))
1923            (protocol (cond
1924                       ((string-prefix-p "gemini:" url) "gemini")
1925                       ((string-prefix-p "gopher:" url) "gopher")
1926                       ((string-prefix-p "finger:" url) "finger")
1927                       (t "elpher"))))
1928       (when (equal "elpher" protocol)
1929         ;; Weird link. Or special inner link?
1930         (setq url (concat "elpher:" url)))
1931       (org-link-store-props :type protocol :link url :description desc)
1932       t)))
1933
1934 (defun elpher-org-follow-link (link protocol)
1935   "Visit a LINK for the given PROTOCOL.
1936
1937 PROTOCOL may be one of gemini, gopher or finger.  This method also
1938 supports the old protocol elpher, where the link is self-contained."
1939   (let ((url (if (equal protocol "elpher")
1940                  (string-remove-prefix "elpher:" link)
1941                (format "%s:%s" protocol link))))
1942     (elpher-go url)))
1943
1944 (defun elpher-org-mode-integration ()
1945   "Set up `elpher' integration for `org-mode'."
1946   (org-link-set-parameters
1947    "elpher"
1948    :store #'elpher-org-store-link
1949    :export (lambda (link description format _plist)
1950              (elpher-org-export-link link description format "elpher"))
1951    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1952   (org-link-set-parameters
1953    "gemini"
1954    :export (lambda (link description format _plist)
1955              (elpher-org-export-link link description format "gemini"))
1956    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
1957   (org-link-set-parameters
1958    "gopher"
1959    :export (lambda (link description format _plist)
1960              (elpher-org-export-link link description format "gopher"))
1961    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
1962   (org-link-set-parameters
1963    "finger"
1964    :export (lambda (link description format _plist)
1965              (elpher-org-export-link link description format "finger"))
1966    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
1967
1968 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
1969
1970 ;;; Browse URL
1971
1972 ;;;###autoload
1973 (defun elpher-browse-url-elpher (url &rest _args)
1974   "Browse URL using Elpher.  This function is used by `browse-url'."
1975   (interactive (browse-url-interactive-arg "Elpher URL: "))
1976   (elpher-go url))
1977
1978 ;; Use elpher to open gopher, finger and gemini links
1979 ;; For recent version of `browse-url' package
1980 (if (boundp 'browse-url-default-handlers)
1981     (add-to-list
1982      'browse-url-default-handlers
1983      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
1984   ;; Patch `browse-url-browser-function' for older ones. The value of
1985   ;; that variable is `browse-url-default-browser' by default, so
1986   ;; that's the function that gets advised.
1987   (advice-add browse-url-browser-function :before-while
1988               (lambda (url &rest _args)
1989                 "Handle gemini, gopher, and finger schemes using Elpher."
1990                 (let ((scheme (downcase (car (split-string url ":" t)))))
1991                   (if (member scheme '("gemini" "gopher" "finger"))
1992                       ;; `elpher-go' always returns nil, which will stop the
1993                       ;; advice chain here in a before-while
1994                       (elpher-go url)
1995                     ;; chain must continue, then return t.
1996                     t)))))
1997
1998 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1999 (with-eval-after-load 'thingatpt
2000   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2001
2002 ;;; Mu4e:
2003
2004 ;; Make mu4e aware of the gemini world
2005 (setq mu4e~view-beginning-of-url-regexp
2006       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2007
2008 ;;; Interactive procedures
2009 ;;
2010
2011 (defun elpher-next-link ()
2012   "Move point to the next link on the current page."
2013   (interactive)
2014   (forward-button 1))
2015
2016 (defun elpher-prev-link ()
2017   "Move point to the previous link on the current page."
2018   (interactive)
2019   (backward-button 1))
2020
2021 (defun elpher-follow-current-link ()
2022   "Open the link or url at point."
2023   (interactive)
2024   (push-button))
2025
2026 ;;;###autoload
2027 (defun elpher-go (host-or-url)
2028   "Go to a particular gopher site HOST-OR-URL.
2029 When run interactively HOST-OR-URL is read from the minibuffer."
2030   (interactive "sGopher or Gemini URL: ")
2031   (let* ((cleaned-host-or-url (string-trim host-or-url))
2032          (address (elpher-address-from-url cleaned-host-or-url))
2033          (page (elpher-make-page cleaned-host-or-url address)))
2034     (switch-to-buffer elpher-buffer-name)
2035     (elpher-with-clean-buffer
2036      (elpher-visit-page page))
2037     nil))
2038
2039 (defun elpher-go-current ()
2040   "Go to a particular site read from the minibuffer, initialized with the current URL."
2041   (interactive)
2042   (let ((address (elpher-page-address elpher-current-page)))
2043     (let ((url (read-string "Gopher or Gemini URL: "
2044                             (unless (elpher-address-special-p address)
2045                               (elpher-address-to-url address)))))
2046       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
2047
2048 (defun elpher-redraw ()
2049   "Redraw current page."
2050   (interactive)
2051   (elpher-visit-page elpher-current-page))
2052
2053 (defun elpher-reload ()
2054   "Reload current page."
2055   (interactive)
2056   (elpher-reload-current-page))
2057
2058 (defun elpher-toggle-tls ()
2059   "Toggle TLS encryption mode for gopher."
2060   (interactive)
2061   (setq elpher-use-tls (not elpher-use-tls))
2062   (if elpher-use-tls
2063       (if (gnutls-available-p)
2064           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2065         (setq elpher-use-tls nil)
2066         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2067     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2068
2069 (defun elpher-view-raw ()
2070   "View raw server response for current page."
2071   (interactive)
2072   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2073       (error "This page was not generated by a server")
2074     (elpher-visit-page elpher-current-page
2075                        #'elpher-render-raw)))
2076
2077 (defun elpher-back ()
2078   "Go to previous site."
2079   (interactive)
2080   (elpher-visit-previous-page))
2081
2082 (defun elpher-back-to-start ()
2083   "Go all the way back to the start page."
2084   (interactive)
2085   (setq-local elpher-current-page nil)
2086   (setq-local elpher-history nil)
2087   (elpher-visit-page (elpher-make-start-page)))
2088
2089 (defun elpher-download ()
2090   "Download the link at point."
2091   (interactive)
2092   (let ((button (button-at (point))))
2093     (if button
2094         (let ((page (button-get button 'elpher-page)))
2095           (if (elpher-address-special-p (elpher-page-address page))
2096               (error "Cannot download %s"
2097                      (elpher-page-display-string page))
2098             (elpher-visit-page (button-get button 'elpher-page)
2099                                #'elpher-render-download)))
2100       (error "No link selected"))))
2101
2102 (defun elpher-download-current ()
2103   "Download the current page."
2104   (interactive)
2105   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2106       (error "Cannot download %s"
2107              (elpher-page-display-string elpher-current-page))
2108     (elpher-visit-page (elpher-make-page
2109                         (elpher-page-display-string elpher-current-page)
2110                         (elpher-page-address elpher-current-page))
2111                        #'elpher-render-download
2112                        t)))
2113
2114 (defun elpher--build-link-map ()
2115   "Build alist mapping link names to destination pages in current buffer."
2116   (let ((link-map nil)
2117         (b (next-button (point-min) t)))
2118     (while b
2119       (push (cons (button-label b) b) link-map)
2120       (setq b (next-button (button-start b))))
2121     link-map))
2122
2123 (defun elpher-jump ()
2124   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2125   (interactive)
2126   (let* ((link-map (elpher--build-link-map)))
2127     (if link-map
2128         (let ((key (let ((completion-ignore-case t))
2129                      (completing-read "Directory item/link: "
2130                                       link-map nil t))))
2131           (if (and key (> (length key) 0))
2132               (let ((b (cdr (assoc key link-map))))
2133                 (goto-char (button-start b))
2134                 (button-activate b)))))))
2135
2136 (defun elpher-root-dir ()
2137   "Visit root of current server."
2138   (interactive)
2139   (let ((address (elpher-page-address elpher-current-page)))
2140     (if (not (elpher-address-special-p address))
2141         (if (or (member (url-filename address) '("/" ""))
2142                 (and (elpher-address-gopher-p address)
2143                      (= (length (elpher-gopher-address-selector address)) 0)))
2144             (error "Already at root directory of current server")
2145           (let ((address-copy (elpher-address-from-url
2146                                (elpher-address-to-url address))))
2147             (setf (url-filename address-copy) "")
2148             (elpher-go (elpher-address-to-url address-copy))))
2149       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2150
2151 (defun elpher-info-page (page)
2152   "Display information on PAGE."
2153   (let ((display-string (elpher-page-display-string page))
2154         (address (elpher-page-address page)))
2155     (if (elpher-address-special-p address)
2156         (message "Special page: %s" display-string)
2157       (message "%s" (elpher-address-to-url address)))))
2158
2159 (defun elpher-info-link ()
2160   "Display information on page corresponding to link at point."
2161   (interactive)
2162   (let ((button (button-at (point))))
2163     (if button
2164         (elpher-info-page (button-get button 'elpher-page))
2165       (error "No item selected"))))
2166
2167 (defun elpher-info-current ()
2168   "Display information on current page."
2169   (interactive)
2170   (elpher-info-page elpher-current-page))
2171
2172 (defun elpher-copy-page-url (page)
2173   "Copy URL representation of address of PAGE to `kill-ring'."
2174   (let ((address (elpher-page-address page)))
2175     (if (elpher-address-special-p address)
2176         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2177       (let ((url (elpher-address-to-url address)))
2178         (message "Copied \"%s\" to kill-ring/clipboard." url)
2179         (kill-new url)))))
2180
2181 (defun elpher-copy-link-url ()
2182   "Copy URL of item at point to `kill-ring'."
2183   (interactive)
2184   (let ((button (button-at (point))))
2185     (if button
2186         (elpher-copy-page-url (button-get button 'elpher-page))
2187       (error "No item selected"))))
2188
2189 (defun elpher-copy-current-url ()
2190   "Copy URL of current page to `kill-ring'."
2191   (interactive)
2192   (elpher-copy-page-url elpher-current-page))
2193
2194 (defun elpher-set-gopher-coding-system ()
2195   "Specify an explicit character coding system for gopher selectors."
2196   (interactive)
2197   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2198     (setq elpher-user-coding-system system)
2199     (if system
2200         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2201       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2202
2203
2204 ;;; Mode and keymap
2205 ;;
2206
2207 (defvar elpher-mode-map
2208   (let ((map (make-sparse-keymap)))
2209     (define-key map (kbd "TAB") 'elpher-next-link)
2210     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2211     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2212     (define-key map (kbd "u") 'elpher-back)
2213     (define-key map (kbd "-") 'elpher-back)
2214     (define-key map (kbd "^") 'elpher-back)
2215     (define-key map [mouse-3] 'elpher-back)
2216     (define-key map (kbd "U") 'elpher-back-to-start)
2217     (define-key map (kbd "g") 'elpher-go)
2218     (define-key map (kbd "o") 'elpher-go-current)
2219     (define-key map (kbd "O") 'elpher-root-dir)
2220     (define-key map (kbd "s") 'elpher-show-history)
2221     (define-key map (kbd "S") 'elpher-show-visited-pages)
2222     (define-key map (kbd "r") 'elpher-redraw)
2223     (define-key map (kbd "R") 'elpher-reload)
2224     (define-key map (kbd "T") 'elpher-toggle-tls)
2225     (define-key map (kbd ".") 'elpher-view-raw)
2226     (define-key map (kbd "d") 'elpher-download)
2227     (define-key map (kbd "D") 'elpher-download-current)
2228     (define-key map (kbd "m") 'elpher-jump)
2229     (define-key map (kbd "i") 'elpher-info-link)
2230     (define-key map (kbd "I") 'elpher-info-current)
2231     (define-key map (kbd "c") 'elpher-copy-link-url)
2232     (define-key map (kbd "C") 'elpher-copy-current-url)
2233     (define-key map (kbd "a") 'elpher-bookmark-link)
2234     (define-key map (kbd "A") 'elpher-bookmark-current)
2235     (define-key map (kbd "B") 'elpher-show-bookmarks)
2236     ;; (define-key map (kbd "B") 'elpher-open-bookmarks)
2237     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2238     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2239     (when (fboundp 'evil-define-key*)
2240       (evil-define-key*
2241        'motion map
2242        (kbd "TAB") 'elpher-next-link
2243        (kbd "C-") 'elpher-follow-current-link
2244        (kbd "C-t") 'elpher-back
2245        (kbd "u") 'elpher-back
2246        (kbd "-") 'elpher-back
2247        (kbd "^") 'elpher-back
2248        [mouse-3] 'elpher-back
2249        (kbd "U") 'elpher-back-to-start
2250        (kbd "g") 'elpher-go
2251        (kbd "o") 'elpher-go-current
2252        (kbd "O") 'elpher-root-dir
2253        (kbd "s") 'elpher-show-history
2254        (kbd "S") 'elpher-show-visited-pages
2255        (kbd "r") 'elpher-redraw
2256        (kbd "R") 'elpher-reload
2257        (kbd "T") 'elpher-toggle-tls
2258        (kbd ".") 'elpher-view-raw
2259        (kbd "d") 'elpher-download
2260        (kbd "D") 'elpher-download-current
2261        (kbd "m") 'elpher-jump
2262        (kbd "i") 'elpher-info-link
2263        (kbd "I") 'elpher-info-current
2264        (kbd "c") 'elpher-copy-link-url
2265        (kbd "C") 'elpher-copy-current-url
2266        (kbd "a") 'elpher-bookmark-link
2267        (kbd "A") 'elpher-bookmark-current
2268        ;; (kbd "B") 'elpher-open-bookmarks
2269        (kbd "B") 'elpher-show-bookmarks
2270        (kbd "!") 'elpher-set-gopher-coding-system
2271        (kbd "F") 'elpher-forget-current-certificate))
2272     map)
2273   "Keymap for gopher client.")
2274
2275 (define-derived-mode elpher-mode special-mode "elpher"
2276   "Major mode for elpher, an elisp gopher client.
2277
2278 This mode is automatically enabled by the interactive
2279 functions which initialize the client, namely
2280 `elpher', and `elpher-go'."
2281   (setq-local elpher--gemini-page-headings nil)
2282   (setq-local elpher-current-page nil)
2283   (setq-local elpher-history nil)
2284   (setq-local elpher-buffer-name (buffer-name))
2285   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2286   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2287   (setq-local xterm-color-preserve-properties t))
2288
2289 (when (fboundp 'evil-set-initial-state)
2290   (evil-set-initial-state 'elpher-mode 'motion))
2291
2292
2293 ;;; Main start procedure
2294 ;;
2295
2296 ;;;###autoload
2297 (defun elpher (&optional arg)
2298   "Start elpher with default landing page.
2299 The buffer used for Elpher sessions is determined by the value of
2300 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2301 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2302 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2303 \\[execute-extended-command] elpher RET’) switches to the session with
2304 that number, creating it if necessary.  A non numeric prefix ARG means
2305 to create a new session.  Returns the buffer selected (or created)."
2306   (interactive "P")
2307   (let* ((name (default-value 'elpher-buffer-name))
2308          (buf (cond ((numberp arg)
2309                      (get-buffer-create (format "%s<%d>" name arg)))
2310                     (arg
2311                      (generate-new-buffer name))
2312                     (t
2313                      (get-buffer-create name)))))
2314     (pop-to-buffer-same-window buf)
2315     (unless (buffer-modified-p)
2316       (elpher-mode)
2317       (elpher-visit-page (elpher-make-start-page))
2318       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2319
2320 ;;; elpher.el ends here