elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.2.0
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.2.0"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((about history) elpher-get-history-page nil "E" elpher-index)
 116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen is \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 232
 233 Beware that using \"about:bookmarks\" as a start page in combination with
 234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 236 the start page."
 237   :type '(string))
 238
 239 ;; Face customizations
 240
 241 (defgroup elpher-faces nil
 242   "Elpher face customizations."
 243   :group 'elpher)
 244
 245 (defface elpher-index
 246   '((t :inherit font-lock-keyword-face))
 247   "Face used for directory type directory records.")
 248
 249 (defface elpher-text
 250   '((t :inherit bold))
 251   "Face used for text type directory records.")
 252
 253 (defface elpher-info
 254   '((t :inherit default))
 255   "Face used for info type directory records.")
 256
 257 (defface elpher-image
 258   '((t :inherit font-lock-string-face))
 259   "Face used for image type directory records.")
 260
 261 (defface elpher-search
 262   '((t :inherit warning))
 263   "Face used for search type directory records.")
 264
 265 (defface elpher-html
 266   '((t :inherit font-lock-comment-face))
 267   "Face used for html type directory records.")
 268
 269 (defface elpher-gemini
 270   '((t :inherit font-lock-constant-face))
 271   "Face used for Gemini type directory records.")
 272
 273 (defface elpher-other-url
 274   '((t :inherit font-lock-comment-face))
 275   "Face used for other URL type links records.")
 276
 277 (defface elpher-telnet
 278   '((t :inherit font-lock-function-name-face))
 279   "Face used for telnet type directory records.")
 280
 281 (defface elpher-binary
 282   '((t :inherit font-lock-doc-face))
 283   "Face used for binary type directory records.")
 284
 285 (defface elpher-unknown
 286   '((t :inherit error))
 287   "Face used for directory records with unknown/unsupported types.")
 288
 289 (defface elpher-margin-key
 290   '((t :inherit bold))
 291   "Face used for directory margin key.")
 292
 293 (defface elpher-margin-brackets
 294   '((t :inherit shadow))
 295   "Face used for brackets around directory margin key.")
 296
 297 (defface elpher-gemini-heading1
 298   '((t :inherit bold :height 1.8))
 299   "Face used for gemini heading level 1.")
 300
 301 (defface elpher-gemini-heading2
 302   '((t :inherit bold :height 1.5))
 303   "Face used for gemini heading level 2.")
 304
 305 (defface elpher-gemini-heading3
 306   '((t :inherit bold :height 1.2))
 307   "Face used for gemini heading level 3.")
 308
 309 (defface elpher-gemini-preformatted
 310   '((t :inherit fixed-pitch))
 311   "Face used for pre-formatted gemini text blocks.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 ;;; Model
 318 ;;
 319
 320 ;; Address
 321
 322 ;; An elpher "address" object is either a url object or a symbol.
 323 ;; Addresses with the "about" type, corresponding to pages generated
 324 ;; dynamically for and by elpher.  All others represent pages which
 325 ;; rely on content retrieved over the network.
 326
 327 (defun elpher-address-from-url (url-string)
 328   "Create a ADDRESS object corresponding to the given URL-STRING."
 329   (let ((data (match-data))) ; Prevent parsing clobbering match data
 330     (unwind-protect
 331         (let ((url (url-generic-parse-url url-string)))
 332           (unless (and (not (url-fullness url)) (url-type url))
 333             (setf (url-fullness url) t)
 334             (unless (url-type url)
 335               (setf (url-type url) elpher-default-url-type))
 336             (unless (url-host url)
 337               (let ((p (split-string (url-filename url) "/" nil nil)))
 338                 (setf (url-host url) (car p))
 339                 (setf (url-filename url)
 340                       (if (cdr p)
 341                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 342                         ""))))
 343             (when (or (equal "gopher" (url-type url))
 344                       (equal "gophers" (url-type url)))
 345               ;; Gopher defaults
 346               (when (or (equal (url-filename url) "")
 347                         (equal (url-filename url) "/"))
 348                 (setf (url-filename url) "/1")))
 349             (when (equal "gemini" (url-type url))
 350               ;; Gemini defaults
 351               (if (equal (url-filename url) "")
 352                   (setf (url-filename url) "/"))))
 353           (elpher-remove-redundant-ports url))
 354       (set-match-data data))))
 355
 356 (defun elpher-remove-redundant-ports (address)
 357   "Remove redundant port specifiers from ADDRESS.
 358 Here 'redundant' means that the specified port matches the default
 359 for that protocol, eg 70 for gopher."
 360   (if (and (not (elpher-address-about-p address))
 361            (eq (url-portspec address) ; (url-port) is too slow!
 362                (pcase (url-type address)
 363                  ("gemini" 1965)
 364                  ((or "gopher" "gophers") 70)
 365                  ("finger" 79)
 366                  (_ -1))))
 367       (setf (url-portspec address) nil))
 368   address)
 369
 370 (defun elpher-make-gopher-address (type selector host port &optional tls)
 371   "Create an ADDRESS object using gopher directory record attributes.
 372 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 373 If the optional attribute TLS is non-nil, the address will be marked as
 374 requiring gopher-over-TLS."
 375   (cond
 376    ((equal type ?i) nil)
 377    ((and (equal type ?h)
 378          (string-prefix-p "URL:" selector))
 379     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 380    ((equal type ?8)
 381     (elpher-address-from-url
 382      (concat "telnet"
 383              "://" host
 384              ":" (number-to-string port))))
 385    (t
 386     (elpher-address-from-url
 387      (concat "gopher" (if tls "s" "")
 388              "://" host
 389              ":" (number-to-string port)
 390              "/" (string type)
 391              selector)))))
 392
 393 (defun elpher-make-about-address (type)
 394   "Create an ADDRESS object corresponding to the given about address TYPE."
 395   (elpher-address-from-url (concat "about:" (symbol-name type))))
 396
 397 (defun elpher-address-to-url (address)
 398   "Get string representation of ADDRESS."
 399   (url-encode-url (url-recreate-url address)))
 400
 401 (defun elpher-address-type (address)
 402   "Retrieve type of ADDRESS object.
 403 This is used to determine how to retrieve and render the document the
 404 address refers to, via the table `elpher-type-map'."
 405   (pcase (url-type address)
 406     ("about"
 407      (list 'about (intern (url-filename address))))
 408     ((or "gopher" "gophers")
 409      (list 'gopher
 410            (if (member (url-filename address) '("" "/"))
 411                ?1
 412              (string-to-char (substring (url-filename address) 1)))))
 413     ("gemini" 'gemini)
 414     ("telnet" 'telnet)
 415     ("finger" 'finger)
 416     ("file" 'file)
 417     (_ 'other-url)))
 418
 419 (defun elpher-address-about-p (address)
 420   "Return non-nil if ADDRESS is an  about address."
 421   (pcase (elpher-address-type address) (`(about ,_) t)))
 422
 423 (defun elpher-address-gopher-p (address)
 424   "Return non-nill if ADDRESS object is a gopher address."
 425   (eq 'gopher (elpher-address-type address)))
 426
 427 (defun elpher-address-protocol (address)
 428   "Retrieve the transport protocol for ADDRESS."
 429   (url-type address))
 430
 431 (defun elpher-address-filename (address)
 432   "Retrieve the filename component of ADDRESS.
 433 For gopher addresses this is a combination of the selector type and selector."
 434   (url-unhex-string (url-filename address)))
 435
 436 (defun elpher-address-host (address)
 437   "Retrieve host from ADDRESS object."
 438   (url-host address))
 439
 440 (defun elpher-address-user (address)
 441   "Retrieve user from ADDRESS object."
 442   (url-user address))
 443
 444 (defun elpher-address-port (address)
 445   "Retrieve port from ADDRESS object.
 446 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 447   (url-port address))
 448
 449 (defun elpher-gopher-address-selector (address)
 450   "Retrieve gopher selector from ADDRESS object."
 451   (if (member (url-filename address) '("" "/"))
 452       ""
 453     (url-unhex-string (substring (url-filename address) 2))))
 454
 455
 456 ;; Cache
 457
 458 (defvar elpher-content-cache (make-hash-table :test 'equal))
 459 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 460
 461 (defun elpher-get-cached-content (address)
 462   "Retrieve the cached content for ADDRESS, or nil if none exists."
 463   (gethash address elpher-content-cache))
 464
 465 (defun elpher-cache-content (address content)
 466   "Set the content cache for ADDRESS to CONTENT."
 467   (puthash address content elpher-content-cache))
 468
 469 (defun elpher-get-cached-pos (address)
 470   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 471   (gethash address elpher-pos-cache))
 472
 473 (defun elpher-cache-pos (address pos)
 474   "Set the cursor position cache for ADDRESS to POS."
 475   (puthash address pos elpher-pos-cache))
 476
 477
 478 ;; Page
 479
 480 (defun elpher-make-page (display-string address)
 481   "Create a page with DISPLAY-STRING and ADDRESS."
 482   (list display-string address))
 483
 484 (defun elpher-make-start-page ()
 485   "Create the welcome page."
 486   (elpher-make-page "Start Page"
 487                     (elpher-address-from-url elpher-start-page)))
 488
 489 (defun elpher-page-display-string (page)
 490   "Retrieve the display string corresponding to PAGE."
 491   (elt page 0))
 492
 493 (defun elpher-page-address (page)
 494   "Retrieve the address corresponding to PAGE."
 495   (elt page 1))
 496
 497 (defun elpher-page-set-address (page new-address)
 498   "Set the address corresponding to PAGE to NEW-ADDRESS."
 499   (setcar (cdr page) new-address))
 500
 501 (defvar elpher-current-page nil
 502   "The current page for this Elpher buffer.")
 503
 504 (defvar elpher-history nil
 505   "The local history stack for this Elpher buffer.
 506 This variable is used by `elpher-back' and
 507 `elpher-show-history'.")
 508
 509 (defvar elpher-visited-pages nil
 510   "The global history for all Elpher buffers.
 511 This variable is used by `elpher-show-visited-pages'.")
 512
 513 (defun elpher-visit-page (page &optional renderer no-history)
 514   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 515 Additionally, push PAGE onto the history stack and the list of
 516 previously-visited pages,unless NO-HISTORY is non-nil."
 517   (elpher-save-pos)
 518   (elpher-process-cleanup)
 519   (unless no-history
 520     (unless (or (not elpher-current-page)
 521                  (equal (elpher-page-address elpher-current-page)
 522                         (elpher-page-address page)))
 523       (push elpher-current-page elpher-history)
 524       (unless (or (elpher-address-about-p (elpher-page-address page))
 525                   (and elpher-visited-pages
 526                        (equal page (car elpher-visited-pages))))
 527         (push page elpher-visited-pages))))
 528   (setq-local elpher-current-page page)
 529   (let* ((address (elpher-page-address page))
 530          (type (elpher-address-type address))
 531          (type-record (cdr (assoc type elpher-type-map))))
 532     (if type-record
 533         (funcall (car type-record)
 534                  (if renderer
 535                      renderer
 536                    (cadr type-record)))
 537       (elpher-visit-previous-page)
 538       (pcase type
 539         (`(gopher ,type-char)
 540          (error "Unsupported gopher selector type '%c' for '%s'"
 541                 type-char (elpher-address-to-url address)))
 542         (other
 543          (error "Unsupported address type '%S' for '%s'"
 544                 other (elpher-address-to-url address)))))))
 545
 546 (defun elpher-visit-previous-page ()
 547   "Visit the previous page in the history."
 548   (if elpher-history
 549       (elpher-visit-page (pop elpher-history) nil t)
 550     (error "No previous page")))
 551
 552 (defun elpher-reload-current-page ()
 553   "Reload the current page, discarding any existing cached content."
 554   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 555   (elpher-visit-page elpher-current-page))
 556
 557 (defun elpher-save-pos ()
 558   "Save the current position of point to the current page."
 559   (when elpher-current-page
 560     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 561
 562 (defun elpher-restore-pos ()
 563   "Restore the position of point to that cached in the current page."
 564   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 565     (if pos
 566         (goto-char pos)
 567       (goto-char (point-min)))))
 568
 569
 570 ;;; Buffer preparation
 571 ;;
 572
 573 (defvar elpher-buffer-name "*elpher*"
 574   "The default name of the Elpher buffer.")
 575
 576 (defun elpher-update-header ()
 577   "If `elpher-use-header' is true, display current page info in window header."
 578   (if elpher-use-header
 579       (let* ((display-string (elpher-page-display-string elpher-current-page))
 580              (address (elpher-page-address elpher-current-page))
 581              (tls-string (if (and (not (elpher-address-about-p address))
 582                                   (member (elpher-address-protocol address)
 583                                           '("gophers" "gemini")))
 584                              " [TLS encryption]"
 585                            ""))
 586              (header (concat display-string
 587                              (propertize tls-string 'face 'bold))))
 588         (setq header-line-format header))))
 589
 590 (defmacro elpher-with-clean-buffer (&rest args)
 591   "Evaluate ARGS with a clean *elpher* buffer as current."
 592   (declare (debug (body))) ;; Allow edebug to step through body
 593   `(with-current-buffer elpher-buffer-name
 594      (unless (eq major-mode 'elpher-mode)
 595        ;; avoid resetting buffer-local variables
 596        (elpher-mode))
 597      (let ((inhibit-read-only t)
 598            (ansi-color-context nil)) ;; clean ansi interpreter state
 599        (setq-local network-security-level
 600                    (default-value 'network-security-level))
 601        (erase-buffer)
 602        (elpher-update-header)
 603        ,@args)))
 604
 605 (defun elpher-buffer-message (string &optional line)
 606   "Replace first line in elpher buffer with STRING.
 607 If LINE is non-nil, replace that line instead."
 608   (with-current-buffer elpher-buffer-name
 609     (let ((inhibit-read-only t))
 610       (goto-char (point-min))
 611       (if line
 612           (forward-line line))
 613       (let ((data (match-data)))
 614         (unwind-protect
 615             (progn
 616               (re-search-forward "^.*$")
 617               (replace-match string))
 618           (set-match-data data))))))
 619
 620
 621 ;;; Text Processing
 622 ;;
 623
 624 (defvar elpher-user-coding-system nil
 625   "User-specified coding system to use for decoding text responses.")
 626
 627 (defun elpher-decode (string)
 628   "Decode STRING using autodetected or user-specified coding system."
 629   (decode-coding-string string
 630                         (if elpher-user-coding-system
 631                             elpher-user-coding-system
 632                           (detect-coding-string string t))))
 633
 634 (defun elpher-preprocess-text-response (string)
 635   "Preprocess text selector response contained in STRING.
 636 This involes decoding the character representation, and clearing
 637 away CRs and any terminating period."
 638   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 639                                            (replace-regexp-in-string "\r" "" string))))
 640
 641 ;;; Buttonify urls
 642
 643 (defconst elpher-url-regex
 644   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 645   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 646
 647 (defun elpher-buttonify-urls (string)
 648   "Turn substrings which look like urls in STRING into clickable buttons."
 649   (with-temp-buffer
 650     (insert string)
 651     (goto-char (point-min))
 652     (while (re-search-forward elpher-url-regex nil t)
 653       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 654                                     (elpher-address-from-url (match-string 0)))))
 655         (make-text-button (match-beginning 0)
 656                           (match-end 0)
 657                           'elpher-page  page
 658                           'action #'elpher-click-link
 659                           'follow-link t
 660                           'help-echo #'elpher--page-button-help
 661                           'face 'button)))
 662     (buffer-string)))
 663
 664 ;;; ANSI colors or XTerm colors (application and filtering)
 665
 666 (or (require 'xterm-color nil t)
 667     (require 'ansi-color))
 668
 669 (defalias 'elpher-color-filter-apply
 670   (if (fboundp 'xterm-color-filter)
 671       (lambda (s)
 672         (let ((_xterm-color-render nil))
 673           (xterm-color-filter s)))
 674     #'ansi-color-filter-apply)
 675   "A function to filter out ANSI escape sequences.")
 676
 677 (defalias 'elpher-color-apply
 678   (if (fboundp 'xterm-color-filter)
 679       #'xterm-color-filter
 680     #'ansi-color-apply)
 681   "A function to apply ANSI escape sequences.")
 682
 683 ;;; Processing text for display
 684
 685 (defun elpher-process-text-for-display (string)
 686   "Perform any desired processing of STRING prior to display as text.
 687 Currently includes buttonifying URLs and processing ANSI escape codes."
 688   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 689                              (elpher-color-filter-apply string)
 690                            (elpher-color-apply string))))
 691
 692
 693 ;;; Network error reporting
 694 ;;
 695
 696 (defun elpher-network-error (address error)
 697   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 698 ERROR can be either an error object or a string."
 699   (elpher-with-clean-buffer
 700    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 701            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 702            (if (stringp error) error (error-message-string error)) "\n"
 703            (propertize "\n----------------\n\n" 'face 'error)
 704            "Press 'u' to return to the previous page.")))
 705
 706
 707 ;;; General network communication
 708 ;;
 709
 710 (defvar elpher-network-timer nil
 711   "Timer used for network connections.")
 712
 713 (defvar elpher-use-tls nil
 714   "If non-nil, use TLS to communicate with gopher servers.")
 715
 716 (defvar elpher-client-certificate nil
 717   "If non-nil, contains client certificate details to use for TLS connections.")
 718
 719 (defun elpher-process-cleanup ()
 720   "Immediately shut down any extant elpher process and timers."
 721   (let ((p (get-process "elpher-process")))
 722     (if p (delete-process p)))
 723   (if (timerp elpher-network-timer)
 724       (cancel-timer elpher-network-timer)))
 725
 726 (defun elpher-make-network-timer (thunk)
 727   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 728 This is just a wraper around `run-at-time' which additionally sets the
 729 buffer-local variable `elpher-network-timer' to allow
 730 `elpher-process-cleanup' to also clear the timer."
 731   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 732     (setq-local elpher-network-timer timer)
 733     timer))
 734
 735 (defun elpher-get-host-response (address default-port query-string response-processor
 736                                          &optional use-tls force-ipv4)
 737   "Generic function for retrieving data from ADDRESS.
 738
 739 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 740 QUERY-STRING is a string sent to the host specified by ADDRESS to
 741 illicet a response.  This response is passed as an argument to the
 742 function RESPONSE-PROCESSOR.
 743
 744 If non-nil, USE-TLS specifies that the connection is to be made over
 745 TLS.  If set to gemini, the certificate verification will be disabled
 746 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 747
 748 If non-nil, FORCE-IPV4 causes the network connection to be made over
 749 ipv4 only.  (The default behaviour when this is not set depends on
 750 the host operating system and the local network capabilities.)"
 751   (if (and use-tls (not (gnutls-available-p)))
 752       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 753     (unless (< (elpher-address-port address) 65536)
 754       (error "Cannot establish network connection: port number > 65536"))
 755     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 756       (setq-local network-security-level 'low)
 757       (setq-local gnutls-verify-error nil))
 758     (condition-case nil
 759         (let* ((kill-buffer-query-functions nil)
 760                (port (elpher-address-port address))
 761                (host (elpher-address-host address))
 762                (service (if (> port 0) port default-port))
 763                (response-string-parts nil)
 764                (bytes-received 0)
 765                (hkbytes-received 0)
 766                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 767                (gnutls-params (list :type 'gnutls-x509pki
 768                                     :hostname host
 769                                     :keylist
 770                                     (elpher-get-current-keylist address)))
 771                (timer (elpher-make-network-timer
 772                                    (lambda ()
 773                                      (elpher-process-cleanup)
 774                                      (cond
 775                                         ; Try again with IPv4
 776                                       ((not (or force-ipv4 socks))
 777                                        (message "Connection timed out.  Retrying with IPv4.")
 778                                        (elpher-get-host-response address default-port
 779                                                                  query-string
 780                                                                  response-processor
 781                                                                  use-tls t))
 782                                       ((and use-tls
 783                                             (not (eq use-tls 'gemini))
 784                                             (or elpher-auto-disengage-TLS
 785                                                 (y-or-n-p
 786                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 787                                        (setq elpher-use-tls nil)
 788                                        (elpher-get-host-response address default-port
 789                                                                  query-string
 790                                                                  response-processor
 791                                                                  nil force-ipv4))
 792                                       (t
 793                                        (elpher-network-error address "Connection time-out."))))))
 794                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 795                        (make-network-process :name "elpher-process"
 796                                              :host host
 797                                              :family (and force-ipv4 'ipv4)
 798                                              :service service
 799                                              :buffer nil
 800                                              :nowait t
 801                                              :tls-parameters
 802                                              (and use-tls
 803                                                   (cons 'gnutls-x509pki
 804                                                         (apply #'gnutls-boot-parameters
 805                                                                gnutls-params)))))))
 806           (setq elpher-network-timer timer)
 807           (set-process-coding-system proc 'binary 'binary)
 808           (set-process-query-on-exit-flag proc nil)
 809           (elpher-buffer-message (concat "Connecting to " host "..."
 810                                          " (press 'u' to abort)"))
 811           (set-process-filter proc
 812                               (lambda (_proc string)
 813                                 (when timer
 814                                   (cancel-timer timer)
 815                                   (setq timer nil))
 816                                 (setq bytes-received (+ bytes-received (length string)))
 817                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 818                                   (when (> new-hkbytes-received hkbytes-received)
 819                                     (setq hkbytes-received new-hkbytes-received)
 820                                     (elpher-buffer-message
 821                                      (concat "("
 822                                              (number-to-string (/ hkbytes-received 10.0))
 823                                              " MB read)")
 824                                      1)))
 825                                 (setq response-string-parts
 826                                       (cons string response-string-parts))))
 827           (set-process-sentinel proc
 828                                 (lambda (proc event)
 829                                   (when timer
 830                                     (cancel-timer timer))
 831                                   (condition-case the-error
 832                                       (cond
 833                                        ((string-prefix-p "open" event)    ; request URL
 834                                         (elpher-buffer-message
 835                                          (concat "Connected to " host ". Receiving data..."
 836                                                  " (press 'u' to abort)"))
 837                                         (let ((inhibit-eol-conversion t))
 838                                           (process-send-string proc query-string)))
 839                                        ((string-prefix-p "deleted" event)) ; do nothing
 840                                        ((and (not response-string-parts)
 841                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 842                                         ; Try again with IPv4
 843                                         (message "Connection failed. Retrying with IPv4.")
 844                                         (elpher-get-host-response address default-port
 845                                                                   query-string
 846                                                                   response-processor
 847                                                                   use-tls t))
 848                                        (response-string-parts
 849                                         (elpher-with-clean-buffer
 850                                          (insert "Data received.  Rendering..."))
 851                                         (funcall response-processor
 852                                                  (apply #'concat (reverse response-string-parts)))
 853                                         (elpher-restore-pos))
 854                                        (t
 855                                         (error "No response from server")))
 856                                     (error
 857                                      (elpher-network-error address the-error)))))
 858           (when socks
 859             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 860             (funcall (process-sentinel proc) proc "open\n")))
 861       (error
 862        (elpher-process-cleanup)
 863        (error "Error initiating connection to server")))))
 864
 865
 866 ;;; Client-side TLS Certificate Management
 867 ;;
 868
 869 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 870   "Generate a key and a self-signed client TLS certificate using openssl.
 871
 872 The Common Name field of the certificate is set to COMMON-NAME.  The
 873 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 874 the key and certificate files to write.
 875
 876 If TEMPORARY is non-nil, the certificate will be given an exporation
 877 period of one day, and the key and certificate files will be deleted
 878 when the certificate is no longer needed for the current session.
 879
 880 Otherwise, the certificate will be given a 100 year expiration period
 881 and the files will not be deleted.
 882
 883 The function returns a list containing the current host name, the
 884 temporary flag, and the key and cert file names in the form required
 885 by `gnutls-boot-parameters`."
 886   (let ((exp-key-file (expand-file-name key-file))
 887         (exp-cert-file (expand-file-name cert-file)))
 888     (condition-case nil
 889         (progn
 890           (call-process elpher-openssl-command nil nil nil
 891                         "req" "-x509" "-newkey" "rsa:2048"
 892                         "-days" (if temporary "1" "36500")
 893                         "-nodes"
 894                         "-subj" (concat "/CN=" common-name)
 895                         "-keyout" exp-key-file
 896                         "-out" exp-cert-file)
 897           (list (elpher-address-host (elpher-page-address elpher-current-page))
 898                 temporary exp-key-file exp-cert-file))
 899       (error
 900        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 901        (error "Program 'openssl', required for certificate generation, not found")))))
 902
 903 (defun elpher-generate-throwaway-certificate ()
 904   "Generate and return details of a throwaway certificate.
 905 The key and certificate files will be deleted when they are no
 906 longer needed for this session."
 907   (let* ((file-base (make-temp-name "elpher"))
 908          (key-file (concat temporary-file-directory file-base ".key"))
 909          (cert-file (concat temporary-file-directory file-base ".crt")))
 910     (elpher-generate-certificate file-base key-file cert-file t)))
 911
 912 (defun elpher-generate-persistent-certificate (file-base common-name)
 913   "Generate and return details of a persistent certificate.
 914 The argument FILE-BASE is used as the base for the key and certificate
 915 files, while COMMON-NAME specifies the common name field of the
 916 certificate.
 917
 918 The key and certificate files are written to in `elpher-certificate-directory'."
 919   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 920          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 921     (elpher-generate-certificate common-name key-file cert-file)))
 922
 923 (defun elpher-get-existing-certificate (file-base)
 924   "Return a certificate object corresponding to an existing certificate.
 925 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 926 the directory `elpher-certificate-directory'."
 927   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 928          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 929     (list (elpher-address-host (elpher-page-address elpher-current-page))
 930           nil
 931           (expand-file-name key-file)
 932           (expand-file-name cert-file))))
 933
 934 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 935   "Install a key+certificate file pair in `elpher-certificate-directory'.
 936 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 937 certificate files to install.  The argument FILE-BASE is used as the
 938 base for the installed key and certificate files."
 939   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 940          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 941     (if (or (file-exists-p key-file)
 942             (file-exists-p cert-file))
 943         (error "A certificate with base name %s is already installed" file-base))
 944     (copy-file key-file-src key-file)
 945     (copy-file cert-file-src cert-file)
 946     (list (elpher-address-host (elpher-page-address elpher-current-page))
 947           nil
 948           (expand-file-name key-file)
 949           (expand-file-name cert-file))))
 950
 951 (defun elpher-list-existing-certificates ()
 952   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 953   (unless (file-directory-p elpher-certificate-directory)
 954     (make-directory elpher-certificate-directory))
 955   (mapcar
 956    (lambda (file)
 957      (file-name-sans-extension file))
 958    (directory-files elpher-certificate-directory nil "\\.key$")))
 959
 960 (defun elpher-forget-current-certificate ()
 961   "Causes any current certificate to be forgotten.)
 962 In the case of throwaway certificates, the key and certificate files
 963 are also deleted."
 964   (interactive)
 965   (when elpher-client-certificate
 966     (unless (and (called-interactively-p 'any)
 967                  (not (y-or-n-p (concat "Really forget client certificate? "
 968                                         "(Throwaway certificates will be deleted.)"))))
 969       (when (cadr elpher-client-certificate)
 970         (delete-file (elt elpher-client-certificate 2))
 971         (delete-file (elt elpher-client-certificate 3)))
 972       (setq elpher-client-certificate nil)
 973       (if (called-interactively-p 'any)
 974           (message "Client certificate forgotten.")))))
 975
 976 (defun elpher-get-current-keylist (address)
 977   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 978
 979 This is obtained from the client certificate described by
 980 `elpher-current-certificate', if one is available and the host for
 981 that certificate matches the host in ADDRESS.
 982
 983 If `elpher-current-certificate' is non-nil, and its host name doesn't
 984 match that of ADDRESS, the certificate is forgotten."
 985   (if elpher-client-certificate
 986       (if (string= (car elpher-client-certificate)
 987                    (elpher-address-host address))
 988           (list (cddr elpher-client-certificate))
 989         (elpher-forget-current-certificate)
 990         (message "Disabling client certificate for new host")
 991         nil)
 992     nil))
 993
 994
 995 ;;; Gopher selector retrieval
 996 ;;
 997
 998 (defun elpher-get-gopher-response (address renderer)
 999   "Get response string from gopher server at ADDRESS and render using RENDERER."
1000   (elpher-get-host-response address 70
1001                             (concat (elpher-gopher-address-selector address) "\r\n")
1002                             renderer
1003                             (or (string= (elpher-address-protocol address) "gophers")
1004                                 elpher-use-tls)))
1005
1006 (defun elpher-get-gopher-page (renderer)
1007   "Getter function for gopher pages.
1008 The RENDERER procedure is used to display the contents of the page
1009 once they are retrieved from the gopher server."
1010   (let* ((address (elpher-page-address elpher-current-page))
1011          (content (elpher-get-cached-content address)))
1012     (if (and content (funcall renderer nil))
1013         (elpher-with-clean-buffer
1014          (insert content)
1015          (elpher-restore-pos))
1016       (elpher-with-clean-buffer
1017        (insert "LOADING... (use 'u' to cancel)\n"))
1018       (condition-case the-error
1019           (elpher-get-gopher-response address renderer)
1020         (error
1021          (elpher-network-error address the-error))))))
1022
1023 ;; Index rendering
1024
1025 (defun elpher-insert-margin (&optional type-name)
1026   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1027   (if type-name
1028       (progn
1029         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1030                         (concat
1031                          (propertize "[" 'face 'elpher-margin-brackets)
1032                          (propertize type-name 'face 'elpher-margin-key)
1033                          (propertize "]" 'face 'elpher-margin-brackets))))
1034         (insert " "))
1035     (insert (make-string elpher-margin-width ?\s))))
1036
1037 (defun elpher--page-button-help (_window buffer pos)
1038   "Function called by Emacs to generate mouse-over text.
1039 The arguments specify the BUFFER and the POS within the buffer of the item
1040 for which help is required.  The function returns the help to be
1041 displayed.  The _WINDOW argument is currently unused."
1042   (with-current-buffer buffer
1043     (let ((button (button-at pos)))
1044       (when button
1045         (let* ((page (button-get button 'elpher-page))
1046                (address (elpher-page-address page)))
1047           (format "mouse-1, RET: open '%s'" (if (elpher-address-about-p address)
1048                                                 address
1049                                               (elpher-address-to-url address))))))))
1050
1051 (defun elpher-insert-index-record (display-string &optional address)
1052   "Function to insert an index record into the current buffer.
1053 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1054 If ADDRESS is not supplied or nil the record is rendered as an
1055 'information' line."
1056   (let* ((type (if address (elpher-address-type address) nil))
1057          (type-map-entry (cdr (assoc type elpher-type-map))))
1058     (if type-map-entry
1059         (let* ((margin-code (elt type-map-entry 2))
1060                (face (elt type-map-entry 3))
1061                (filtered-display-string (elpher-color-filter-apply display-string))
1062                (page (elpher-make-page filtered-display-string address)))
1063           (elpher-insert-margin margin-code)
1064           (insert-text-button filtered-display-string
1065                               'face face
1066                               'elpher-page page
1067                               'action #'elpher-click-link
1068                               'follow-link t
1069                               'help-echo #'elpher--page-button-help))
1070       (pcase type
1071         ('nil ;; Information
1072          (elpher-insert-margin)
1073          (let ((propertized-display-string
1074                 (propertize display-string 'face 'elpher-info)))
1075            (insert (elpher-process-text-for-display propertized-display-string))))
1076         (`(gopher ,selector-type) ;; Unknown
1077          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1078          (insert (propertize display-string
1079                              'face 'elpher-unknown)))))
1080     (insert "\n")))
1081
1082 (defun elpher-click-link (button)
1083   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1084   (let ((page (button-get button 'elpher-page)))
1085     (elpher-visit-page page)))
1086
1087 (defun elpher-render-index (data &optional _mime-type-string)
1088   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1089   (elpher-with-clean-buffer
1090    (if (not data)
1091        t
1092      (let ((data-processed (elpher-preprocess-text-response data)))
1093        (dolist (line (split-string data-processed "\n"))
1094          (ignore-errors
1095            (unless (= (length line) 0)
1096              (let* ((type (elt line 0))
1097                     (fields (split-string (substring line 1) "\t"))
1098                     (display-string (elt fields 0))
1099                     (selector (elt fields 1))
1100                     (host (elt fields 2))
1101                     (port (if (elt fields 3)
1102                               (string-to-number (elt fields 3))
1103                             nil))
1104                     (address (elpher-make-gopher-address type selector host port)))
1105                (elpher-insert-index-record display-string address))))))
1106      (elpher-cache-content (elpher-page-address elpher-current-page)
1107                            (buffer-string)))))
1108
1109 ;; Text rendering
1110
1111 (defun elpher-render-text (data &optional _mime-type-string)
1112   "Render DATA as text.  MIME-TYPE-STRING is unused."
1113   (elpher-with-clean-buffer
1114    (if (not data)
1115        t
1116      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1117      (elpher-cache-content
1118       (elpher-page-address elpher-current-page)
1119       (buffer-string)))))
1120
1121 ;; Image retrieval
1122
1123 (defun elpher-render-image (data &optional _mime-type-string)
1124   "Display DATA as image.  MIME-TYPE-STRING is unused."
1125   (if (not data)
1126       nil
1127     (if (display-images-p)
1128         (let* ((image (create-image
1129                        data
1130                        nil t))
1131                (window (get-buffer-window elpher-buffer-name)))
1132           (when window
1133             (setf (image-property image :max-width) (window-pixel-width window))
1134             (setf (image-property image :max-height) (window-pixel-height window)))
1135           (elpher-with-clean-buffer
1136            (insert-image image)
1137            (elpher-restore-pos)))
1138       (elpher-render-download data))))
1139
1140 ;; Search retrieval and rendering
1141
1142 (defun elpher-get-gopher-query-page (renderer)
1143   "Getter for gopher addresses requiring input.
1144 The response is rendered using the rendering function RENDERER."
1145   (let* ((address (elpher-page-address elpher-current-page))
1146          (content (elpher-get-cached-content address))
1147          (aborted t))
1148     (if (and content (funcall renderer nil))
1149         (elpher-with-clean-buffer
1150          (insert content)
1151          (elpher-restore-pos)
1152          (message "Displaying cached search results.  Reload to perform a new search."))
1153       (unwind-protect
1154           (let* ((query-string (read-string "Query: "))
1155                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1156                  (search-address (elpher-make-gopher-address ?1
1157                                                              query-selector
1158                                                              (elpher-address-host address)
1159                                                              (elpher-address-port address)
1160                                                              (equal (elpher-address-type address) "gophers"))))
1161             (setq aborted nil)
1162
1163             (elpher-with-clean-buffer
1164              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1165             (elpher-get-gopher-response search-address renderer))
1166         (if aborted
1167             (elpher-visit-previous-page))))))
1168
1169 ;; Raw server response rendering
1170
1171 (defun elpher-render-raw (data &optional mime-type-string)
1172   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1173   (if (not data)
1174       nil
1175     (elpher-with-clean-buffer
1176      (when mime-type-string
1177        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1178      (insert data)
1179      (goto-char (point-min)))
1180     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1181
1182 ;; File save "rendering"
1183
1184 (defun elpher-render-download (data &optional _mime-type-string)
1185   "Save DATA to file.  MIME-TYPE-STRING is unused."
1186   (if (not data)
1187       nil
1188     (let* ((address (elpher-page-address elpher-current-page))
1189            (selector (if (elpher-address-gopher-p address)
1190                          (elpher-gopher-address-selector address)
1191                        (elpher-address-filename address))))
1192       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1193       (let* ((filename-proposal (file-name-nondirectory selector))
1194              (filename (read-file-name "Download complete. Save file as: "
1195                                        nil nil nil
1196                                        (if (> (length filename-proposal) 0)
1197                                            filename-proposal
1198                                          "download.file"))))
1199         (let ((coding-system-for-write 'binary))
1200           (with-temp-file filename
1201             (insert data)))
1202         (message (format "Saved to file %s." filename))))))
1203
1204 ;; HTML rendering
1205
1206 (defun elpher-render-html (data &optional _mime-type-string)
1207   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1208   (elpher-with-clean-buffer
1209    (if (not data)
1210        t
1211      (let ((dom (with-temp-buffer
1212                   (insert data)
1213                   (libxml-parse-html-region (point-min) (point-max)))))
1214        (shr-insert-document dom)))))
1215
1216 ;; Gemini page retrieval
1217
1218 (defvar elpher-gemini-redirect-chain)
1219
1220 (defun elpher-get-gemini-response (address renderer)
1221   "Get response string from gemini server at ADDRESS and render using RENDERER."
1222   (elpher-get-host-response address 1965
1223                             (concat (elpher-address-to-url address) "\r\n")
1224                             (lambda (response-string)
1225                               (elpher-process-gemini-response response-string renderer))
1226                             'gemini))
1227
1228 (defun elpher-parse-gemini-response (response)
1229   "Parse the RESPONSE string and return a list of components.
1230 The list is of the form (code meta body).  A response of nil implies
1231 that the response was malformed."
1232   (let ((header-end-idx (string-match "\r\n" response)))
1233     (if header-end-idx
1234         (let ((header (string-trim (substring response 0 header-end-idx)))
1235               (body (substring response (+ header-end-idx 2))))
1236           (if (>= (length header) 2)
1237               (let ((code (substring header 0 2))
1238                     (meta (string-trim (substring header 2))))
1239                 (list code meta body))
1240             (error "Malformed response: No response status found in header %s" header)))
1241       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1242
1243 (defun elpher-process-gemini-response (response-string renderer)
1244   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1245   (let ((response-components (elpher-parse-gemini-response response-string)))
1246     (let ((response-code (elt response-components 0))
1247           (response-meta (elt response-components 1))
1248           (response-body (elt response-components 2)))
1249       (pcase (elt response-code 0)
1250         (?1 ; Input required
1251          (elpher-with-clean-buffer
1252           (insert "Gemini server is requesting input."))
1253          (let* ((query-string
1254                  (if (eq (elt response-code 1) ?1)
1255                      (read-passwd (concat response-meta ": "))
1256                    (read-string (concat response-meta ": "))))
1257                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1258                 (old-fname (url-filename query-address)))
1259            (setf (url-filename query-address)
1260                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1261            (elpher-get-gemini-response query-address renderer)))
1262         (?2 ; Normal response
1263          (funcall renderer response-body response-meta))
1264         (?3 ; Redirect
1265          (message "Following redirect to %s" response-meta)
1266          (if (>= (length elpher-gemini-redirect-chain) 5)
1267              (error "More than 5 consecutive redirects followed"))
1268          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1269            (if (member redirect-address elpher-gemini-redirect-chain)
1270                (error "Redirect loop detected"))
1271            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1272                (error "Server tried to automatically redirect to non-gemini URL: %s"
1273                       response-meta))
1274            (elpher-page-set-address elpher-current-page redirect-address)
1275            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1276            (elpher-get-gemini-response redirect-address renderer)))
1277         (?4 ; Temporary failure
1278          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1279                 response-code response-meta))
1280         (?5 ; Permanent failure
1281          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1282                 response-code response-meta))
1283         (?6 ; Client certificate required
1284          (elpher-with-clean-buffer
1285           (if elpher-client-certificate
1286               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1287             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1288           (auto-fill-mode 1)
1289           (elpher-gemini-insert-text response-meta))
1290          (let ((chosen-certificate (elpher-choose-client-certificate)))
1291            (unless chosen-certificate
1292              (error "Gemini server requires a client certificate and none was provided"))
1293            (setq elpher-client-certificate chosen-certificate))
1294          (elpher-with-clean-buffer)
1295          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1296         (_other
1297          (error "Gemini server response unknown: %s %s"
1298                 response-code response-meta))))))
1299
1300 (defun elpher--read-answer-polyfill (question answers)
1301   "Polyfill for `read-answer' in Emacs 26.1.
1302 QUESTION is a string containing a question, and ANSWERS
1303 is a list of possible answers."
1304     (completing-read question (mapcar 'identity answers)))
1305
1306 (if (fboundp 'read-answer)
1307     (defalias 'elpher-read-answer 'read-answer)
1308   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1309
1310 (defun elpher-choose-client-certificate ()
1311   "Prompt for a client certificate to use to establish a TLS connection."
1312   (let* ((read-answer-short t))
1313     (pcase (read-answer "What do you want to do? "
1314                         '(("throwaway" ?t
1315                            "generate and use throw-away certificate")
1316                           ("persistent" ?p
1317                            "generate new or use existing persistent certificate")
1318                           ("abort" ?a
1319                            "stop immediately")))
1320       ("throwaway"
1321        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1322       ("persistent"
1323        (let* ((existing-certificates (elpher-list-existing-certificates))
1324               (file-base (completing-read
1325                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1326                           existing-certificates)))
1327          (if (string-empty-p (string-trim file-base))
1328              nil
1329            (if (member file-base existing-certificates)
1330                (setq elpher-client-certificate
1331                      (elpher-get-existing-certificate file-base))
1332              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1333                                  '(("new" ?n
1334                                     "generate new certificate")
1335                                    ("install" ?i
1336                                     "install existing certificate")
1337                                    ("abort" ?a
1338                                     "stop immediately")))
1339                ("new"
1340                 (let ((common-name (read-string "Common Name field for new certificate: "
1341                                                 file-base)))
1342                   (message "New key and self-signed certificate written to %s"
1343                            elpher-certificate-directory)
1344                   (elpher-generate-persistent-certificate file-base common-name)))
1345                ("install"
1346                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1347                        (key-file (read-file-name "Key file: " nil nil t)))
1348                   (message "Key and certificate installed in %s for future use"
1349                            elpher-certificate-directory)
1350                   (elpher-install-and-use-existing-certificate key-file
1351                                                                cert-file
1352                                                                file-base)))
1353                ("abort" nil))))))
1354       ("abort" nil))))
1355
1356 (defun elpher-get-gemini-page (renderer)
1357   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1358   (let* ((address (elpher-page-address elpher-current-page))
1359          (content (elpher-get-cached-content address)))
1360     (condition-case the-error
1361         (if (and content (funcall renderer nil))
1362             (elpher-with-clean-buffer
1363              (insert content)
1364              (elpher-restore-pos))
1365           (elpher-with-clean-buffer
1366            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1367           (setq elpher-gemini-redirect-chain nil)
1368           (elpher-get-gemini-response address renderer))
1369       (error
1370        (elpher-network-error address the-error)))))
1371
1372 (defun elpher-render-gemini (body &optional mime-type-string)
1373   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1374   (if (not body)
1375       t
1376     (let* ((mime-type-string* (if (or (not mime-type-string)
1377                                       (string-empty-p mime-type-string))
1378                                   "text/gemini; charset=utf-8"
1379                                 mime-type-string))
1380            (mime-type-split (split-string mime-type-string* ";" t))
1381            (mime-type (string-trim (car mime-type-split)))
1382            (parameters (mapcar (lambda (s)
1383                                  (let ((key-val (split-string s "=")))
1384                                    (list (downcase (string-trim (car key-val)))
1385                                          (downcase (string-trim (cadr key-val))))))
1386                                (cdr mime-type-split))))
1387       (when (string-prefix-p "text/" mime-type)
1388         (setq body (decode-coding-string
1389                     body
1390                     (if (assoc "charset" parameters)
1391                         (intern (cadr (assoc "charset" parameters)))
1392                       'utf-8)))
1393         (setq body (replace-regexp-in-string "\r" "" body)))
1394       (pcase mime-type
1395         ((or "text/gemini" "")
1396          (elpher-render-gemini-map body parameters))
1397         ("text/html"
1398          (elpher-render-html body))
1399         ((pred (string-prefix-p "text/"))
1400          (elpher-render-gemini-plain-text body parameters))
1401         ((pred (string-prefix-p "image/"))
1402          (elpher-render-image body))
1403         (_other
1404          (elpher-render-download body))))))
1405
1406 (defun elpher-gemini-get-link-url (link-line)
1407   "Extract the url portion of LINK-LINE, a gemini map file link line.
1408 Returns nil in the event that the contents of the line following the
1409 => prefix are empty."
1410   (let ((l (split-string (substring link-line 2))))
1411     (if l
1412         (string-trim (elt l 0))
1413       nil)))
1414
1415 (defun elpher-gemini-get-link-display-string (link-line)
1416   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1417 Returns the url portion in the event that the display-string portion is empty."
1418   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1419          (idx (string-match "[ \t]" rest)))
1420     (string-trim (if idx
1421                      (substring rest (+ idx 1))
1422                    rest))))
1423
1424 (defun elpher-collapse-dot-sequences (filename)
1425   "Collapse dot sequences in FILENAME.
1426 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1427   (let* ((path (split-string filename "/"))
1428          (path-reversed-normalized
1429           (seq-reduce (lambda (a b)
1430                         (cond ((and a (equal b "..") (cdr a)))
1431                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1432                               ((equal b ".") a)
1433                               (t (cons b a))))
1434                       path nil)))
1435     (string-join (reverse path-reversed-normalized) "/")))
1436
1437 (defun elpher-address-from-gemini-url (url)
1438   "Extract address from URL with defaults as per gemini map files.
1439 While there's obviously some redundancy here between this function and
1440 `elpher-address-from-url', gemini map file URLs require enough special
1441 treatment that a separate function is warranted."
1442   (let ((address (url-generic-parse-url url))
1443         (current-address (elpher-page-address elpher-current-page)))
1444     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1445       (setf (url-fullness address) t)
1446       (if (url-host address) ;if there is an explicit host, filenames are absolute
1447           (if (string-empty-p (url-filename address))
1448               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1449         (setf (url-host address) (url-host current-address))
1450         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1451         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1452           (setf (url-filename address)
1453                 (concat (file-name-directory (url-filename current-address))
1454                         (url-filename address)))))
1455       (unless (url-type address)
1456         (setf (url-type address) (url-type current-address)))
1457       (when (equal (url-type address) "gemini")
1458         (setf (url-filename address)
1459               (elpher-collapse-dot-sequences (url-filename address)))))
1460     (elpher-remove-redundant-ports address)))
1461
1462 (defun elpher-gemini-insert-link (link-line)
1463   "Insert link described by LINK-LINE into a text/gemini document."
1464   (let* ((url (elpher-gemini-get-link-url link-line))
1465          (display-string (elpher-gemini-get-link-display-string link-line))
1466          (address (elpher-address-from-gemini-url url))
1467          (type (if address (elpher-address-type address) nil))
1468          (type-map-entry (cdr (assoc type elpher-type-map))))
1469     (when display-string
1470       (insert elpher-gemini-link-string)
1471       (if type-map-entry
1472           (let* ((face (elt type-map-entry 3))
1473                  (filtered-display-string (elpher-color-filter-apply display-string))
1474                  (page (elpher-make-page filtered-display-string address)))
1475             (insert-text-button filtered-display-string
1476                                 'face face
1477                                 'elpher-page page
1478                                 'action #'elpher-click-link
1479                                 'follow-link t
1480                                 'help-echo #'elpher--page-button-help))
1481         (insert (propertize display-string 'face 'elpher-unknown)))
1482       (insert "\n"))))
1483
1484 (defvar elpher--gemini-page-headings nil
1485   "List of headings on the page.")
1486
1487 (defun elpher-gemini-insert-header (header-line)
1488   "Insert header described by HEADER-LINE into a text/gemini document.
1489 The gemini map file line describing the header is given
1490 by HEADER-LINE."
1491   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1492     (let* ((level (length (match-string 1 header-line)))
1493            (header (substring header-line (match-end 0)))
1494            (face (pcase level
1495                    (1 'elpher-gemini-heading1)
1496                    (2 'elpher-gemini-heading2)
1497                    (3 'elpher-gemini-heading3)
1498                    (_ 'default)))
1499            (fill-column (if (display-graphic-p)
1500                             (/ (* fill-column
1501                                   (font-get (font-spec :name (face-font 'default)) :size))
1502                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1503       (setq elpher--gemini-page-headings (cons (cons header (point))
1504                                                elpher--gemini-page-headings))
1505       (unless (display-graphic-p)
1506         (insert (make-string level ?#) " "))
1507       (insert (propertize header 'face face))
1508       (newline))))
1509
1510 (defun elpher-gemini-insert-text (text-line)
1511   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1512 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1513 width defined by `elpher-gemini-max-fill-width'."
1514   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1515   (let* ((line-prefix (match-string 2 text-line))
1516          (processed-text-line
1517           (if line-prefix
1518               (cond ((string-prefix-p "*" line-prefix)
1519                      (concat
1520                       (replace-regexp-in-string "\\*"
1521                                                 elpher-gemini-bullet-string
1522                                                 (match-string 0 text-line))
1523                       (substring text-line (match-end 0))))
1524                     ((string-prefix-p ">" line-prefix)
1525                      (propertize text-line 'face 'elpher-gemini-quoted))
1526                     (t text-line))
1527             text-line))
1528          (adaptive-fill-mode t)
1529          ;; fill-prefix is important for adaptive-fill-mode: without
1530          ;; it, multi-line list items are not indented correct
1531          (fill-prefix (if (match-string 2 text-line)
1532                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1533                         nil)))
1534     (insert (elpher-process-text-for-display processed-text-line))
1535     (newline)))
1536
1537 (defun elpher-render-gemini-map (data _parameters)
1538   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1539   (elpher-with-clean-buffer
1540    (setq elpher--gemini-page-headings nil)
1541    (let ((preformatted nil))
1542      (auto-fill-mode 1)
1543      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1544      (dolist (line (split-string data "\n"))
1545        (cond
1546         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1547         (preformatted (insert (elpher-process-text-for-display
1548                                (propertize line 'face 'elpher-gemini-preformatted))
1549                               "\n"))
1550         ((string-prefix-p "=>" line)
1551          (elpher-gemini-insert-link line))
1552         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1553         (t (elpher-gemini-insert-text line)))))
1554    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1555    (elpher-cache-content
1556     (elpher-page-address elpher-current-page)
1557     (buffer-string))))
1558
1559 (defun elpher-render-gemini-plain-text (data _parameters)
1560   "Render DATA as plain text file.  PARAMETERS is currently unused."
1561   (elpher-with-clean-buffer
1562    (insert (elpher-process-text-for-display data))
1563    (elpher-cache-content
1564     (elpher-page-address elpher-current-page)
1565     (buffer-string))))
1566
1567
1568 ;; Finger page connection
1569
1570 (defun elpher-get-finger-page (renderer)
1571   "Opens a finger connection to the current page address.
1572 The result is rendered using RENDERER."
1573   (let* ((address (elpher-page-address elpher-current-page))
1574          (content (elpher-get-cached-content address)))
1575     (if (and content (funcall renderer nil))
1576         (elpher-with-clean-buffer
1577          (insert content)
1578          (elpher-restore-pos))
1579       (elpher-with-clean-buffer
1580        (insert "LOADING... (use 'u' to cancel)\n"))
1581       (condition-case the-error
1582           (let* ((kill-buffer-query-functions nil)
1583                  (user (let ((filename (elpher-address-filename address)))
1584                          (if (> (length filename) 1)
1585                              (substring filename 1)
1586                            (elpher-address-user address)))))
1587             (elpher-get-host-response address 79
1588                                       (concat user "\r\n")
1589                                       renderer))
1590         (error
1591          (elpher-network-error address the-error))))))
1592
1593
1594 ;; Telnet page connection
1595
1596 (defun elpher-get-telnet-page (renderer)
1597   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1598   (when renderer
1599     (elpher-visit-previous-page)
1600     (error "Command not supported for telnet URLs"))
1601   (let* ((address (elpher-page-address elpher-current-page))
1602          (host (elpher-address-host address))
1603          (port (elpher-address-port address)))
1604     (elpher-visit-previous-page)
1605     (if (> port 0)
1606         (telnet host port)
1607       (telnet host))))
1608
1609
1610 ;; Other URL page opening
1611
1612 (defun elpher-get-other-url-page (renderer)
1613   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1614   (when renderer
1615     (elpher-visit-previous-page)
1616     (error "Command not supported for general URLs"))
1617   (let* ((address (elpher-page-address elpher-current-page))
1618          (url (elpher-address-to-url address)))
1619     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1620     (message "Opening URL...")
1621     (if elpher-open-urls-with-eww
1622         (browse-web url)
1623       (browse-url url))))
1624
1625 ;; File page
1626
1627 (defun elpher-get-file-page (renderer)
1628   "Getter which renders a local file using RENDERER.
1629 Assumes UTF-8 encoding for all text files."
1630   (let* ((address (elpher-page-address elpher-current-page))
1631          (filename (elpher-address-filename address)))
1632     (unless (file-exists-p filename)
1633       (elpher-visit-previous-page)
1634         (error "File not found"))
1635     (unless (file-readable-p filename)
1636       (elpher-visit-previous-page)
1637         (error "Could not read from file"))
1638     (let ((body (with-temp-buffer
1639        (let ((coding-system-for-read 'binary)
1640              (coding-system-for-write 'binary))
1641          (insert-file-contents-literally filename)
1642          (encode-coding-string (buffer-string) 'raw-text)))))
1643        (if renderer
1644            (funcall renderer body nil)
1645          (pcase (file-name-extension filename)
1646            ((or  "gmi" "gemini")
1647             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1648            ((or "htm" "html")
1649             (elpher-render-html (decode-coding-string body 'utf-8)))
1650            ((or "txt" "")
1651             (elpher-render-text (decode-coding-string body 'utf-8)))
1652            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1653             (elpher-render-image body))
1654            (_
1655             (elpher-render-download body))))
1656        (elpher-restore-pos))))
1657
1658
1659 ;; Welcome page retrieval
1660
1661 (defun elpher-get-welcome-page (renderer)
1662   "Getter which displays the welcome page (RENDERER must be nil)."
1663   (when renderer
1664     (elpher-visit-previous-page)
1665     (error "Command not supported for welcome page"))
1666   (elpher-with-clean-buffer
1667    (insert "     --------------------------------------------\n"
1668            "           Elpher Gopher and Gemini Client       \n"
1669            "                   version " elpher-version "\n"
1670            "     --------------------------------------------\n"
1671            "\n"
1672            "Default bindings:\n"
1673            "\n"
1674            " - TAB/Shift-TAB: next/prev item on current page\n"
1675            " - RET/mouse-1: open item under cursor\n"
1676            " - m: select an item on current page by name (autocompletes)\n"
1677            " - u/mouse-3/U: return to previous page or to the start page\n"
1678            " - g: go to a particular address (gopher, gemini, finger)\n"
1679            " - o/O: open a different address selector or the root menu of the current server\n"
1680            " - d/D: download item under cursor or current page\n"
1681            " - i/I: info on item under cursor or current page\n"
1682            " - c/C: copy URL representation of item under cursor or current page\n"
1683            " - a/A: bookmark the item under cursor or current page\n"
1684            " - B: list all bookmarks\n"
1685            " - s/S: show current history stack or all previously visted pages\n"
1686            " - r: redraw current page (using cached contents if available)\n"
1687            " - R: reload current page (regenerates cache)\n"
1688            " - !: set character coding system for gopher (default is to autodetect)\n"
1689            " - T: toggle TLS gopher mode\n"
1690            " - F: forget/discard current TLS client certificate\n"
1691            " - .: display the raw server response for the current page\n"
1692            "\n"
1693            "Start your exploration of gopher space and gemini:\n")
1694    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1695                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1696    (elpher-insert-index-record "Project Gemini home page"
1697                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1698    (insert "\n"
1699            "Alternatively, select a search engine and enter some search terms:\n")
1700    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1701                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1702    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1703                                (elpher-address-from-url "gemini://geminispace.info/search"))
1704    (insert "\n"
1705            "Your bookmarks are stored in your ")
1706    (let ((help-string "RET,mouse-1: Open bookmark list"))
1707      (insert-text-button "bookmark list"
1708                          'face 'link
1709                          'action (lambda (_)
1710                                    (interactive)
1711                                    (call-interactively #'elpher-show-bookmarks))
1712                          'follow-link t
1713                          'help-echo help-string))
1714    (insert ".\n")
1715    (insert (propertize
1716             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1717             'face 'shadow))
1718    (insert "\n"
1719            "The gopher home of the Elpher project is here:\n")
1720    (elpher-insert-index-record "The Elpher Project Page"
1721                                (elpher-make-gopher-address ?1
1722                                                            "/projects/elpher/"
1723                                                            "thelambdalab.xyz"
1724                                                            70))
1725    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1726      (insert "\n"
1727              "The following info documentation is available:\n"
1728              "   - ")
1729      (insert-text-button "Elpher Manual"
1730                          'face 'link
1731                          'action (lambda (_)
1732                                    (interactive)
1733                                    (info "(elpher)"))
1734                          'follow-link t
1735                          'help-echo help-string)
1736      (insert "\n   - ")
1737      (insert-text-button "Changes introduced by the latest release"
1738                        'face 'link
1739                        'action (lambda (_)
1740                                  (interactive)
1741                                  (info "(elpher)News"))
1742                        'follow-link t
1743                        'help-echo help-string))
1744    (insert "\n")
1745    (insert (propertize
1746             (concat "(These documents should be available if you have installed Elpher \n"
1747                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1748             'face 'shadow))
1749    (elpher-restore-pos)))
1750
1751 ;; History page retrieval
1752
1753 (defun elpher-show-history ()
1754   "Show the current contents of elpher's history stack.
1755 Use \\[elpher-show-visited-pages] to see the entire history.
1756 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1757   (interactive)
1758   (elpher-visit-page
1759    (elpher-make-page "Current History Stack"
1760                      (elpher-make-about-address 'history))))
1761
1762 (defun elpher-show-visited-pages ()
1763   "Show the all the pages you've visited using Elpher.
1764 Use \\[elpher-show-history] to see just the current history stack.
1765 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1766   (interactive)
1767   (elpher-visit-page
1768    (elpher-make-page "Elpher Visted Pages"
1769                      (elpher-make-about-address 'visited-pages))))
1770
1771 (defun elpher-get-history-page (renderer)
1772   "Getter which displays the history page (RENDERER must be nil)."
1773   (when renderer
1774     (elpher-visit-previous-page)
1775     (error "Command not supported for history page"))
1776   (elpher-display-history-links elpher-history "Current history stack"))
1777
1778 (defun elpher-get-visited-pages-page (renderer)
1779   "Getter which displays the list of visited pages (RENDERER must be nil)."
1780   (when renderer
1781     (elpher-visit-previous-page)
1782     (error "Command not supported for history page"))
1783   (elpher-display-history-links
1784    (seq-filter (lambda (page)
1785                  (not (elpher-address-about-p (elpher-page-address page))))
1786                elpher-visited-pages)
1787    "All visited pages"))
1788
1789 (defun elpher-display-history-links (pages title)
1790   "Show all PAGES in an Elpher buffer with a given TITLE."
1791   (let* ((title-line (concat " ---- " title " ----"))
1792          (footer-line (make-string (length title-line) ?-)))
1793     (elpher-with-clean-buffer
1794      (insert title-line "\n\n")
1795      (if pages
1796          (dolist (page pages)
1797            (when page
1798              (let ((display-string (elpher-page-display-string page))
1799                    (address (elpher-page-address page)))
1800                (elpher-insert-index-record display-string address))))
1801        (insert "No history items found.\n"))
1802      (insert "\n " footer-line "\n"
1803              "Select an entry or press 'u' to return to the previous page.")
1804      (elpher-restore-pos))))
1805
1806
1807 ;;; Bookmarks
1808
1809 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1810 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1811 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1812 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1813
1814 (defvar elpher-bookmark-link nil
1815   "Prefer bookmarking a link or the current page.
1816 Bind this variable dynamically, or set it to t.
1817 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1818 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1819
1820 (defun elpher-bookmark-make-record ()
1821   "Return a bookmark record.
1822 If `elpher-bookmark-link' is non-nil and point is on a link button,
1823 return a bookmark record for that link.  Otherwise, return a bookmark
1824 record for the current elpher page."
1825   (let* ((button (and elpher-bookmark-link (button-at (point))))
1826          (page (if button
1827                    (button-get button 'elpher-page)
1828                  elpher-current-page)))
1829     (unless page
1830       (error "Cannot bookmark this link"))
1831     (let* ((address (elpher-page-address page))
1832            (url (elpher-address-to-url address))
1833            (display-string (elpher-page-display-string page))
1834            (pos (if button nil (point))))
1835       (if (elpher-address-about-p address)
1836           (error "Cannot bookmark %s" display-string)
1837         `(,display-string
1838           (defaults . (,display-string))
1839           (position . ,pos)
1840           (location . ,url)
1841           (handler . elpher-bookmark-jump))))))
1842
1843 ;;;###autoload
1844 (defun elpher-bookmark-jump (bookmark)
1845   "Handler used to open a bookmark using elpher.
1846 The argument BOOKMARK is a bookmark record passed to the function.
1847 This handler is responsible for loading the bookmark in some buffer,
1848 then making that buffer the current buffer.  It should not switch
1849 to the buffer."
1850   (let* ((url (cdr (assq 'location bookmark)))
1851          (cleaned-url (string-trim url))
1852          (address (elpher-address-from-url cleaned-url))
1853          (page (elpher-make-page cleaned-url address)))
1854     (elpher-with-clean-buffer
1855      (elpher-visit-page page))
1856     (set-buffer (get-buffer elpher-buffer-name))
1857     nil))
1858
1859 (defun elpher-bookmark-link ()
1860   "Bookmark the link at point.
1861 To bookmark the current page, use \\[elpher-bookmark-current]."
1862   (interactive)
1863   (let ((elpher-bookmark-link t))
1864     (bookmark-set-no-overwrite)))
1865
1866 (defun elpher-bookmark-current ()
1867   "Bookmark the current page.
1868 To bookmark the link at point use \\[elpher-bookmark-link]."
1869   (interactive)
1870   (call-interactively #'bookmark-set-no-overwrite))
1871
1872 (defun elpher-bookmark-import (file)
1873   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1874   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1875                               (file-readable-p elpher-bookmarks-file))
1876                          elpher-bookmarks-file
1877                        (read-file-name "Old Elpher bookmarks: "
1878                                        user-emacs-directory nil t
1879                                        "elpher-bookmarks"))))
1880   (dolist (bookmark (with-temp-buffer
1881                       (insert-file-contents file)
1882                       (read (current-buffer))))
1883     (let* ((display-string (car bookmark))
1884            (url (cadr bookmark))
1885            (record `(,display-string
1886                      (location . ,url)
1887                      (handler . elpher-bookmark-jump))))
1888       (bookmark-store display-string (cdr record) t)))
1889   (bookmark-save))
1890
1891 (defun elpher-get-bookmarks-page (renderer)
1892   "Getter which displays the bookmarks (RENDERER must be nil)."
1893   (when renderer
1894     (elpher-visit-previous-page)
1895     (error "Command not supported for bookmarks page"))
1896
1897   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1898                                      elpher-bookmarks-file)
1899                                 (locate-user-emacs-file "elpher-bookmarks"))))
1900     (when (and (file-readable-p old-bookmarks-file)
1901                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1902                                  old-bookmarks-file
1903                                  "\" found. Import now?")))
1904       (elpher-bookmark-import old-bookmarks-file)
1905       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1906
1907   (if (and elpher-use-emacs-bookmark-menu
1908            elpher-history)
1909       (progn
1910         (elpher-visit-previous-page)
1911         (call-interactively #'bookmark-bmenu-list))
1912     (elpher-with-clean-buffer
1913      (insert " ---- Elpher Bookmarks ---- \n\n")
1914      (bookmark-maybe-load-default-file)
1915      (dolist (bookmark (bookmark-maybe-sort-alist))
1916        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1917          (let* ((name (car bookmark))
1918                 (url (alist-get 'location (cdr bookmark)))
1919                 (address (elpher-address-from-url url)))
1920            (elpher-insert-index-record name address))))
1921      (when (<= (line-number-at-pos) 3)
1922        (insert "No bookmarked pages found.\n"))
1923      (insert "\n --------------------------\n\n"
1924              "Select an entry or press 'u' to return to the previous page.\n\n"
1925              "Bookmarks can be renamed or deleted via the ")
1926      (insert-text-button "Emacs bookmark menu"
1927                          'action (lambda (_)
1928                                    (interactive)
1929                                    (call-interactively #'bookmark-bmenu-list))
1930                          'follow-link t
1931                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
1932      (insert (substitute-command-keys
1933               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1934      (elpher-restore-pos))))
1935
1936 (defun elpher-show-bookmarks ()
1937   "Interactive function to display the current list of elpher bookmarks."
1938   (interactive)
1939   (elpher-visit-page
1940    (elpher-make-page "Elpher Bookmarks"
1941                      (elpher-make-about-address 'bookmarks))))
1942
1943
1944 ;;; Integrations
1945 ;;
1946
1947 ;;; Org
1948
1949 (defun elpher-org-export-link (link description format protocol)
1950   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1951
1952 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1953 of gemini, gopher or finger."
1954   (let* ((url (if (equal protocol "elpher")
1955                   (string-remove-prefix "elpher:" link)
1956                 (format "%s:%s" protocol link)))
1957          (desc (or description url)))
1958     (pcase format
1959       (`gemini (format "=> %s %s" url desc))
1960       (`html (format "<a href=\"%s\">%s</a>" url desc))
1961       (`latex (format "\\href{%s}{%s}" url desc))
1962       (_ (if (not description)
1963              url
1964            (format "%s (%s)" desc url))))))
1965
1966 (defun elpher-org-store-link ()
1967   "Store link to an `elpher' page in Org."
1968   (when (eq major-mode 'elpher-mode)
1969     (let* ((url (elpher-info-current))
1970            (desc (car elpher-current-page))
1971            (protocol (cond
1972                       ((string-prefix-p "gemini:" url) "gemini")
1973                       ((string-prefix-p "gopher:" url) "gopher")
1974                       ((string-prefix-p "finger:" url) "finger")
1975                       (t "elpher"))))
1976       (when (equal "elpher" protocol)
1977         ;; Weird link. Or special inner link?
1978         (setq url (concat "elpher:" url)))
1979       (org-link-store-props :type protocol :link url :description desc)
1980       t)))
1981
1982 (defun elpher-org-follow-link (link protocol)
1983   "Visit a LINK for the given PROTOCOL.
1984
1985 PROTOCOL may be one of gemini, gopher or finger.  This method also
1986 supports the old protocol elpher, where the link is self-contained."
1987   (let ((url (if (equal protocol "elpher")
1988                  (string-remove-prefix "elpher:" link)
1989                (format "%s:%s" protocol link))))
1990     (elpher-go url)))
1991
1992 (defun elpher-org-mode-integration ()
1993   "Set up `elpher' integration for `org-mode'."
1994   (org-link-set-parameters
1995    "elpher"
1996    :store #'elpher-org-store-link
1997    :export (lambda (link description format _plist)
1998              (elpher-org-export-link link description format "elpher"))
1999    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2000   (org-link-set-parameters
2001    "gemini"
2002    :export (lambda (link description format _plist)
2003              (elpher-org-export-link link description format "gemini"))
2004    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2005   (org-link-set-parameters
2006    "gopher"
2007    :export (lambda (link description format _plist)
2008              (elpher-org-export-link link description format "gopher"))
2009    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2010   (org-link-set-parameters
2011    "finger"
2012    :export (lambda (link description format _plist)
2013              (elpher-org-export-link link description format "finger"))
2014    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2015
2016 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2017
2018 ;;; Browse URL
2019
2020 ;;;###autoload
2021 (defun elpher-browse-url-elpher (url &rest _args)
2022   "Browse URL using Elpher.  This function is used by `browse-url'."
2023   (interactive (browse-url-interactive-arg "Elpher URL: "))
2024   (elpher-go url))
2025
2026 ;; Use elpher to open gopher, finger and gemini links
2027 ;; For recent version of `browse-url' package
2028 (if (boundp 'browse-url-default-handlers)
2029     (add-to-list
2030      'browse-url-default-handlers
2031      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2032   ;; Patch `browse-url-browser-function' for older ones. The value of
2033   ;; that variable is `browse-url-default-browser' by default, so
2034   ;; that's the function that gets advised.
2035   (advice-add browse-url-browser-function :before-while
2036               (lambda (url &rest _args)
2037                 "Handle gemini, gopher, and finger schemes using Elpher."
2038                 (let ((scheme (downcase (car (split-string url ":" t)))))
2039                   (if (member scheme '("gemini" "gopher" "finger"))
2040                       ;; `elpher-go' always returns nil, which will stop the
2041                       ;; advice chain here in a before-while
2042                       (elpher-go url)
2043                     ;; chain must continue, then return t.
2044                     t)))))
2045
2046 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2047 (with-eval-after-load 'thingatpt
2048   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2049
2050 ;;; Mu4e:
2051
2052 ;; Make mu4e aware of the gemini world
2053 (setq mu4e~view-beginning-of-url-regexp
2054       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2055
2056 ;;; eww:
2057
2058 ;; Let elpher handle gemini, gopher links in eww buffer.
2059 (setq eww-use-browse-url
2060       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2061
2062
2063 ;;; Interactive procedures
2064 ;;
2065
2066 (defun elpher-next-link ()
2067   "Move point to the next link on the current page."
2068   (interactive)
2069   (forward-button 1))
2070
2071 (defun elpher-prev-link ()
2072   "Move point to the previous link on the current page."
2073   (interactive)
2074   (backward-button 1))
2075
2076 (defun elpher-follow-current-link ()
2077   "Open the link or url at point."
2078   (interactive)
2079   (push-button))
2080
2081 ;;;###autoload
2082 (defun elpher-go (host-or-url)
2083   "Go to a particular gopher site HOST-OR-URL.
2084 When run interactively HOST-OR-URL is read from the minibuffer."
2085   (interactive "sGopher or Gemini URL: ")
2086   (let ((trimmed-host-or-url (string-trim host-or-url)))
2087     (unless (string-empty-p trimmed-host-or-url)
2088       (let* ((address (elpher-address-from-url trimmed-host-or-url))
2089              (page (elpher-make-page trimmed-host-or-url address)))
2090         (switch-to-buffer elpher-buffer-name)
2091         (elpher-with-clean-buffer
2092          (elpher-visit-page page))
2093         nil)))) ; non-nil value is displayed by eshell
2094
2095 (defun elpher-go-current ()
2096   "Go to a particular site read from the minibuffer, initialized with the current URL."
2097   (interactive)
2098   (let* ((address (elpher-page-address elpher-current-page))
2099          (url (read-string "Gopher or Gemini URL: "
2100                            (unless (elpher-address-about-p address)
2101                              (elpher-address-to-url address)))))
2102     (unless (string-empty-p (string-trim url))
2103       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
2104
2105 (defun elpher-redraw ()
2106   "Redraw current page."
2107   (interactive)
2108   (elpher-visit-page elpher-current-page))
2109
2110 (defun elpher-reload ()
2111   "Reload current page."
2112   (interactive)
2113   (elpher-reload-current-page))
2114
2115 (defun elpher-toggle-tls ()
2116   "Toggle TLS encryption mode for gopher."
2117   (interactive)
2118   (setq elpher-use-tls (not elpher-use-tls))
2119   (if elpher-use-tls
2120       (if (gnutls-available-p)
2121           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2122         (setq elpher-use-tls nil)
2123         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2124     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2125
2126 (defun elpher-view-raw ()
2127   "View raw server response for current page."
2128   (interactive)
2129   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2130       (error "This page was not generated by a server")
2131     (elpher-visit-page elpher-current-page
2132                        #'elpher-render-raw)))
2133
2134 (defun elpher-back ()
2135   "Go to previous site."
2136   (interactive)
2137   (elpher-visit-previous-page))
2138
2139 (defun elpher-back-to-start ()
2140   "Go all the way back to the start page."
2141   (interactive)
2142   (setq-local elpher-current-page nil)
2143   (setq-local elpher-history nil)
2144   (elpher-visit-page (elpher-make-start-page)))
2145
2146 (defun elpher-download ()
2147   "Download the link at point."
2148   (interactive)
2149   (let ((button (button-at (point))))
2150     (if button
2151         (let ((page (button-get button 'elpher-page)))
2152           (unless page
2153             (error "Not an elpher page"))
2154           (when (elpher-address-about-p (elpher-page-address page))
2155             (error "Cannot download %s" (elpher-page-display-string page)))
2156           (elpher-visit-page (button-get button 'elpher-page)
2157                              #'elpher-render-download))
2158       (error "No link selected"))))
2159
2160 (defun elpher-download-current ()
2161   "Download the current page."
2162   (interactive)
2163   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2164       (error "Cannot download %s"
2165              (elpher-page-display-string elpher-current-page))
2166     (elpher-visit-page (elpher-make-page
2167                         (elpher-page-display-string elpher-current-page)
2168                         (elpher-page-address elpher-current-page))
2169                        #'elpher-render-download
2170                        t)))
2171
2172 (defun elpher--build-link-map ()
2173   "Build alist mapping link names to destination pages in current buffer."
2174   (let ((link-map nil)
2175         (b (next-button (point-min) t)))
2176     (while b
2177       (push (cons (button-label b) b) link-map)
2178       (setq b (next-button (button-start b))))
2179     link-map))
2180
2181 (defun elpher-jump ()
2182   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2183   (interactive)
2184   (let* ((link-map (elpher--build-link-map)))
2185     (if link-map
2186         (let ((key (let ((completion-ignore-case t))
2187                      (completing-read "Directory item/link: "
2188                                       link-map nil t))))
2189           (if (and key (> (length key) 0))
2190               (let ((b (cdr (assoc key link-map))))
2191                 (goto-char (button-start b))
2192                 (button-activate b)))))))
2193
2194 (defun elpher-root-dir ()
2195   "Visit root of current server."
2196   (interactive)
2197   (let ((address (elpher-page-address elpher-current-page)))
2198     (if (not (elpher-address-about-p address))
2199         (if (or (member (url-filename address) '("/" ""))
2200                 (and (elpher-address-gopher-p address)
2201                      (= (length (elpher-gopher-address-selector address)) 0)))
2202             (error "Already at root directory of current server")
2203           (let ((address-copy (elpher-address-from-url
2204                                (elpher-address-to-url address))))
2205             (setf (url-filename address-copy) "")
2206             (elpher-go (elpher-address-to-url address-copy))))
2207       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2208
2209 (defun elpher-info-page (page)
2210   "Display URL of PAGE in minibuffer."
2211   (let ((address (elpher-page-address page)))
2212     (message "%s" (elpher-address-to-url address))))
2213
2214 (defun elpher-info-link ()
2215   "Display information on page corresponding to link at point."
2216   (interactive)
2217   (let ((button (button-at (point))))
2218     (unless button
2219       (error "No item selected"))
2220     (let ((page (button-get button 'elpher-page)))
2221       (unless page
2222         (error "Not an elpher page"))
2223       (elpher-info-page page))))
2224
2225 (defun elpher-info-current ()
2226   "Display information on current page."
2227   (interactive)
2228   (elpher-info-page elpher-current-page))
2229
2230 (defun elpher-copy-page-url (page)
2231   "Copy URL representation of address of PAGE to `kill-ring'."
2232   (let* ((address (elpher-page-address page))
2233          (url (elpher-address-to-url address)))
2234     (message "Copied \"%s\" to kill-ring/clipboard." url)
2235     (kill-new url)))
2236
2237 (defun elpher-copy-link-url ()
2238   "Copy URL of item at point to `kill-ring'."
2239   (interactive)
2240   (let ((button (button-at (point))))
2241     (unless button
2242       (error "No item selected"))
2243     (let ((page (button-get button 'elpher-page)))
2244       (unless page
2245         (error "Not an elpher page"))
2246       (elpher-copy-page-url page))))
2247
2248 (defun elpher-copy-current-url ()
2249   "Copy URL of current page to `kill-ring'."
2250   (interactive)
2251   (elpher-copy-page-url elpher-current-page))
2252
2253 (defun elpher-set-gopher-coding-system ()
2254   "Specify an explicit character coding system for gopher selectors."
2255   (interactive)
2256   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2257     (setq elpher-user-coding-system system)
2258     (if system
2259         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2260       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2261
2262
2263 ;;; Mode and keymap
2264 ;;
2265
2266 (defvar elpher-mode-map
2267   (let ((map (make-sparse-keymap)))
2268     (define-key map (kbd "TAB") 'elpher-next-link)
2269     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2270     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2271     (define-key map (kbd "u") 'elpher-back)
2272     (define-key map (kbd "-") 'elpher-back)
2273     (define-key map (kbd "^") 'elpher-back)
2274     (define-key map [mouse-3] 'elpher-back)
2275     (define-key map (kbd "U") 'elpher-back-to-start)
2276     (define-key map (kbd "g") 'elpher-go)
2277     (define-key map (kbd "o") 'elpher-go-current)
2278     (define-key map (kbd "O") 'elpher-root-dir)
2279     (define-key map (kbd "s") 'elpher-show-history)
2280     (define-key map (kbd "S") 'elpher-show-visited-pages)
2281     (define-key map (kbd "r") 'elpher-redraw)
2282     (define-key map (kbd "R") 'elpher-reload)
2283     (define-key map (kbd "T") 'elpher-toggle-tls)
2284     (define-key map (kbd ".") 'elpher-view-raw)
2285     (define-key map (kbd "d") 'elpher-download)
2286     (define-key map (kbd "D") 'elpher-download-current)
2287     (define-key map (kbd "m") 'elpher-jump)
2288     (define-key map (kbd "i") 'elpher-info-link)
2289     (define-key map (kbd "I") 'elpher-info-current)
2290     (define-key map (kbd "c") 'elpher-copy-link-url)
2291     (define-key map (kbd "C") 'elpher-copy-current-url)
2292     (define-key map (kbd "a") 'elpher-bookmark-link)
2293     (define-key map (kbd "A") 'elpher-bookmark-current)
2294     (define-key map (kbd "B") 'elpher-show-bookmarks)
2295     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2296     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2297     (when (fboundp 'evil-define-key*)
2298       (evil-define-key*
2299        'motion map
2300        (kbd "TAB") 'elpher-next-link
2301        (kbd "C-") 'elpher-follow-current-link
2302        (kbd "C-t") 'elpher-back
2303        (kbd "u") 'elpher-back
2304        (kbd "-") 'elpher-back
2305        (kbd "^") 'elpher-back
2306        [mouse-3] 'elpher-back
2307        (kbd "U") 'elpher-back-to-start
2308        (kbd "g") 'elpher-go
2309        (kbd "o") 'elpher-go-current
2310        (kbd "O") 'elpher-root-dir
2311        (kbd "s") 'elpher-show-history
2312        (kbd "S") 'elpher-show-visited-pages
2313        (kbd "r") 'elpher-redraw
2314        (kbd "R") 'elpher-reload
2315        (kbd "T") 'elpher-toggle-tls
2316        (kbd ".") 'elpher-view-raw
2317        (kbd "d") 'elpher-download
2318        (kbd "D") 'elpher-download-current
2319        (kbd "m") 'elpher-jump
2320        (kbd "i") 'elpher-info-link
2321        (kbd "I") 'elpher-info-current
2322        (kbd "c") 'elpher-copy-link-url
2323        (kbd "C") 'elpher-copy-current-url
2324        (kbd "a") 'elpher-bookmark-link
2325        (kbd "A") 'elpher-bookmark-current
2326        (kbd "B") 'elpher-show-bookmarks
2327        (kbd "!") 'elpher-set-gopher-coding-system
2328        (kbd "F") 'elpher-forget-current-certificate))
2329     map)
2330   "Keymap for gopher client.")
2331
2332 (define-derived-mode elpher-mode special-mode "elpher"
2333   "Major mode for elpher, an elisp gopher client.
2334
2335 This mode is automatically enabled by the interactive
2336 functions which initialize the client, namely
2337 `elpher', and `elpher-go'."
2338   (setq-local elpher--gemini-page-headings nil)
2339   (setq-local elpher-current-page nil)
2340   (setq-local elpher-history nil)
2341   (setq-local elpher-buffer-name (buffer-name))
2342   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2343   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2344   (setq-local xterm-color-preserve-properties t))
2345
2346 (when (fboundp 'evil-set-initial-state)
2347   (evil-set-initial-state 'elpher-mode 'motion))
2348
2349
2350 ;;; Main start procedure
2351 ;;
2352
2353 ;;;###autoload
2354 (defun elpher (&optional arg)
2355   "Start elpher with default landing page.
2356 The buffer used for Elpher sessions is determined by the value of
2357 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2358 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2359 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2360 \\[execute-extended-command] elpher RET’) switches to the session with
2361 that number, creating it if necessary.  A non numeric prefix ARG means
2362 to create a new session.  Returns the buffer selected (or created)."
2363   (interactive "P")
2364   (let* ((name (default-value 'elpher-buffer-name))
2365          (buf (cond ((numberp arg)
2366                      (get-buffer-create (format "%s<%d>" name arg)))
2367                     (arg
2368                      (generate-new-buffer name))
2369                     (t
2370                      (get-buffer-create name)))))
2371     (pop-to-buffer-same-window buf)
2372     (unless (buffer-modified-p)
2373       (elpher-mode)
2374       (elpher-visit-page (elpher-make-start-page))
2375       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2376
2377 ;;; elpher.el ends here