elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.10.0
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "2.10.0"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  99     ((special start) elpher-get-start-page nil))
 100   "Association list from types to getters, renderers, margin codes and index faces.")
 101
 102
 103 ;;; Customization group
 104 ;;
 105
 106 (defgroup elpher nil
 107   "A gopher and gemini client."
 108   :group 'applications)
 109
 110 ;; General appearance and customizations
 111
 112 (defcustom elpher-open-urls-with-eww nil
 113   "If non-nil, open URL selectors using eww.
 114 Otherwise, use the system browser via the BROWSE-URL function."
 115   :type '(boolean))
 116
 117 (defcustom elpher-use-header t
 118   "If non-nil, display current page information in buffer header."
 119   :type '(boolean))
 120
 121 (defcustom elpher-auto-disengage-TLS nil
 122   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 123 While enabling this may seem convenient, it is also potentially dangerous as it
 124 allows switching from an encrypted channel back to plain text without user input."
 125   :type '(boolean))
 126
 127 (defcustom elpher-connection-timeout 5
 128   "Specifies the number of seconds to wait for a network connection to time out."
 129   :type '(integer))
 130
 131 (defcustom elpher-filter-ansi-from-text nil
 132   "If non-nil, filter ANSI escape sequences from text.
 133 The default behaviour is to use the ansi-color package to interpret these
 134 sequences."
 135   :type '(boolean))
 136
 137 (defcustom elpher-certificate-directory
 138   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 139   "Specify the name of the directory where client certificates will be stored.
 140 These certificates may be used for establishing authenticated TLS connections."
 141   :type '(directory))
 142
 143 (defcustom elpher-openssl-command "openssl"
 144   "The command used to launch openssl when generating TLS client certificates."
 145   :type '(file))
 146
 147 (defcustom elpher-gemini-TLS-cert-checks nil
 148   "If non-nil, verify gemini server TLS certs using the default security level.
 149 Otherwise, certificate verification is disabled.
 150
 151 This defaults to off because it is standard practice for Gemini servers
 152 to use self-signed certificates, meaning that most servers provide what
 153 EMACS considers to be an invalid certificate."
 154   :type '(boolean))
 155
 156 (defcustom elpher-gemini-max-fill-width 80
 157   "Specify the maximum default width (in columns) of text/gemini documents.
 158 The actual width used is the minimum of this value and the window width at
 159 the time when the text is rendered."
 160   :type '(integer))
 161
 162 (defcustom elpher-gemini-link-string "→ "
 163   "Specify the string used to indicate links when rendering gemini maps.
 164 May be empty."
 165   :type '(string))
 166
 167 (defcustom elpher-gemini-bullet-string "•"
 168   "Specify the string used for bullets when rendering gemini maps."
 169   :type '(string))
 170
 171 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 172   "Specify the name of the file where elpher bookmarks will be saved."
 173   :type '(file))
 174
 175 (defcustom elpher-ipv4-always nil
 176   "If non-nil, elpher will always use IPv4 to establish network connections.
 177 This can be useful when browsing from a computer that supports IPv6, because
 178 some servers which do not support IPv6 can take a long time to time-out."
 179   :type '(boolean))
 180
 181 ;; Face customizations
 182
 183 (defgroup elpher-faces nil
 184   "Elpher face customizations."
 185   :group 'elpher)
 186
 187 (defface elpher-index
 188   '((t :inherit font-lock-keyword-face))
 189   "Face used for directory type directory records.")
 190
 191 (defface elpher-text
 192   '((t :inherit bold))
 193   "Face used for text type directory records.")
 194
 195 (defface elpher-info
 196   '((t :inherit default))
 197   "Face used for info type directory records.")
 198
 199 (defface elpher-image
 200   '((t :inherit font-lock-string-face))
 201   "Face used for image type directory records.")
 202
 203 (defface elpher-search
 204   '((t :inherit warning))
 205   "Face used for search type directory records.")
 206
 207 (defface elpher-html
 208   '((t :inherit font-lock-comment-face))
 209   "Face used for html type directory records.")
 210
 211 (defface elpher-gemini
 212   '((t :inherit font-lock-constant-face))
 213   "Face used for Gemini type directory records.")
 214
 215 (defface elpher-other-url
 216   '((t :inherit font-lock-comment-face))
 217   "Face used for other URL type links records.")
 218
 219 (defface elpher-telnet
 220   '((t :inherit font-lock-function-name-face))
 221   "Face used for telnet type directory records.")
 222
 223 (defface elpher-binary
 224   '((t :inherit font-lock-doc-face))
 225   "Face used for binary type directory records.")
 226
 227 (defface elpher-unknown
 228   '((t :inherit error))
 229   "Face used for directory records with unknown/unsupported types.")
 230
 231 (defface elpher-margin-key
 232   '((t :inherit bold))
 233   "Face used for directory margin key.")
 234
 235 (defface elpher-margin-brackets
 236   '((t :inherit shadow))
 237   "Face used for brackets around directory margin key.")
 238
 239 (defface elpher-gemini-heading1
 240   '((t :inherit bold :height 1.8))
 241   "Face used for gemini heading level 1.")
 242
 243 (defface elpher-gemini-heading2
 244   '((t :inherit bold :height 1.5))
 245   "Face used for gemini heading level 2.")
 246
 247 (defface elpher-gemini-heading3
 248   '((t :inherit bold :height 1.2))
 249   "Face used for gemini heading level 3.")
 250
 251 (defface elpher-gemini-preformatted
 252   '((t :inherit fixed-pitch))
 253   "Face used for pre-formatted gemini text blocks.")
 254
 255 ;;; Model
 256 ;;
 257
 258 ;; Address
 259
 260 ;; An elpher "address" object is either a url object or a symbol.
 261 ;; Symbol addresses are "special", corresponding to pages generated
 262 ;; dynamically for and by elpher.  All others represent pages which
 263 ;; rely on content retrieved over the network.
 264
 265 (defun elpher-address-from-url (url-string)
 266   "Create a ADDRESS object corresponding to the given URL-STRING."
 267   (let ((data (match-data))) ; Prevent parsing clobbering match data
 268     (unwind-protect
 269         (let ((url (url-generic-parse-url url-string)))
 270           (unless (and (not (url-fullness url)) (url-type url))
 271             (setf (url-fullness url) t)
 272             (setf (url-filename url)
 273                   (url-unhex-string (url-filename url)))
 274             (unless (url-type url)
 275               (setf (url-type url) "gopher"))
 276             (when (or (equal "gopher" (url-type url))
 277                       (equal "gophers" (url-type url)))
 278               ;; Gopher defaults
 279               (unless (url-host url)
 280                 (setf (url-host url) (url-filename url))
 281                 (setf (url-filename url) ""))
 282               (when (or (equal (url-filename url) "")
 283                         (equal (url-filename url) "/"))
 284                 (setf (url-filename url) "/1")))
 285             (when (equal "gemini" (url-type url))
 286               ;; Gemini defaults
 287               (if (equal (url-filename url) "")
 288                   (setf (url-filename url) "/"))))
 289           (elpher-remove-redundant-ports url))
 290       (set-match-data data))))
 291
 292 (defun elpher-remove-redundant-ports (address)
 293   "Remove redundant port specifiers from ADDRESS.
 294 Here 'redundant' means that the specified port matches the default
 295 for that protocol, eg 70 for gopher."
 296   (if (and (not (elpher-address-special-p address))
 297            (eq (url-portspec address) ; (url-port) is too slow!
 298                (pcase (url-type address)
 299                  ("gemini" 1965)
 300                  ((or "gopher" "gophers") 70)
 301                  ("finger" 79)
 302                  (_ -1))))
 303       (setf (url-portspec address) nil))
 304   address)
 305
 306 (defun elpher-make-gopher-address (type selector host port &optional tls)
 307   "Create an ADDRESS object using gopher directory record attributes.
 308 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 309 If the optional attribute TLS is non-nil, the address will be marked as
 310 requiring gopher-over-TLS."
 311   (cond
 312    ((equal type ?i) nil)
 313    ((and (equal type ?h)
 314          (string-prefix-p "URL:" selector))
 315     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 316    ((equal type ?8)
 317     (elpher-address-from-url
 318      (concat "telnet"
 319              "://" host
 320              ":" (number-to-string port))))
 321    (t
 322     (elpher-address-from-url
 323      (concat "gopher" (if tls "s" "")
 324              "://" host
 325              ":" (number-to-string port)
 326              "/" (string type)
 327              selector)))))
 328
 329 (defun elpher-make-special-address (type)
 330   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 331   type)
 332
 333 (defun elpher-address-to-url (address)
 334   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 335   (if (elpher-address-special-p address)
 336       nil
 337     (url-encode-url (url-recreate-url address))))
 338
 339 (defun elpher-address-type (address)
 340   "Retrieve type of ADDRESS object.
 341 This is used to determine how to retrieve and render the document the
 342 address refers to, via the table `elpher-type-map'."
 343   (if (symbolp address)
 344       (list 'special address)
 345     (let ((protocol (url-type address)))
 346       (cond ((or (equal protocol "gopher")
 347                  (equal protocol "gophers"))
 348              (list 'gopher
 349                    (if (member (url-filename address) '("" "/"))
 350                        ?1
 351                      (string-to-char (substring (url-filename address) 1)))))
 352             ((equal protocol "gemini")
 353              'gemini)
 354             ((equal protocol "telnet")
 355              'telnet)
 356             ((equal protocol "finger")
 357              'finger)
 358             (t 'other-url)))))
 359
 360 (defun elpher-address-protocol (address)
 361   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 362   (if (symbolp address)
 363       nil
 364     (url-type address)))
 365
 366 (defun elpher-address-filename (address)
 367   "Retrieve the filename component of ADDRESS.
 368 For gopher addresses this is a combination of the selector type and selector."
 369   (if (symbolp address)
 370       nil
 371     (url-filename address)))
 372
 373 (defun elpher-address-host (address)
 374   "Retrieve host from ADDRESS object."
 375   (url-host address))
 376
 377 (defun elpher-address-user (address)
 378   "Retrieve user from ADDRESS object."
 379   (url-user address))
 380
 381 (defun elpher-address-port (address)
 382   "Retrieve port from ADDRESS object.
 383 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 384   (if (symbolp address)
 385       0
 386     (url-port address)))
 387
 388 (defun elpher-address-special-p (address)
 389   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 390   (symbolp address))
 391
 392 (defun elpher-address-gopher-p (address)
 393   "Return non-nill if ADDRESS object is a gopher address."
 394   (and (not (elpher-address-special-p address))
 395        (member (elpher-address-protocol address) '("gopher gophers"))))
 396
 397 (defun elpher-gopher-address-selector (address)
 398   "Retrieve gopher selector from ADDRESS object."
 399   (if (member (url-filename address) '("" "/"))
 400       ""
 401     (url-unhex-string (substring (url-filename address) 2))))
 402
 403
 404 ;; Cache
 405
 406 (defvar elpher-content-cache (make-hash-table :test 'equal))
 407 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 408
 409 (defun elpher-get-cached-content (address)
 410   "Retrieve the cached content for ADDRESS, or nil if none exists."
 411   (gethash address elpher-content-cache))
 412
 413 (defun elpher-cache-content (address content)
 414   "Set the content cache for ADDRESS to CONTENT."
 415   (puthash address content elpher-content-cache))
 416
 417 (defun elpher-get-cached-pos (address)
 418   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 419   (gethash address elpher-pos-cache))
 420
 421 (defun elpher-cache-pos (address pos)
 422   "Set the cursor position cache for ADDRESS to POS."
 423   (puthash address pos elpher-pos-cache))
 424
 425
 426 ;; Page
 427
 428 (defun elpher-make-page (display-string address)
 429   "Create a page with DISPLAY-STRING and ADDRESS."
 430   (list display-string address))
 431
 432 (defun elpher-page-display-string (page)
 433   "Retrieve the display string corresponding to PAGE."
 434   (elt page 0))
 435
 436 (defun elpher-page-address (page)
 437   "Retrieve the address corresponding to PAGE."
 438   (elt page 1))
 439
 440 (defun elpher-page-set-address (page new-address)
 441   "Set the address corresponding to PAGE to NEW-ADDRESS."
 442   (setcar (cdr page) new-address))
 443
 444 (defvar elpher-current-page nil)
 445 (defvar elpher-history nil)
 446
 447 (defun elpher-visit-page (page &optional renderer no-history)
 448   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 449 Additionally, push PAGE onto the stack of previously-visited pages,
 450 unless NO-HISTORY is non-nil."
 451   (elpher-save-pos)
 452   (elpher-process-cleanup)
 453   (unless (or no-history
 454               (equal (elpher-page-address elpher-current-page)
 455                      (elpher-page-address page)))
 456     (push elpher-current-page elpher-history))
 457   (setq elpher-current-page page)
 458   (let* ((address (elpher-page-address page))
 459          (type (elpher-address-type address))
 460          (type-record (cdr (assoc type elpher-type-map))))
 461     (if type-record
 462         (funcall (car type-record)
 463                  (if renderer
 464                      renderer
 465                    (cadr type-record)))
 466       (elpher-visit-previous-page)
 467       (pcase type
 468         (`(gopher ,type-char)
 469          (error "Unsupported gopher selector type '%c' for '%s'"
 470                 type-char (elpher-address-to-url address)))
 471         (other
 472          (error "Unsupported address type '%S' for '%s'"
 473                 other (elpher-address-to-url address)))))))
 474
 475 (defun elpher-visit-previous-page ()
 476   "Visit the previous page in the history."
 477   (let ((previous-page (pop elpher-history)))
 478     (if previous-page
 479         (elpher-visit-page previous-page nil t)
 480       (error "No previous page"))))
 481
 482 (defun elpher-reload-current-page ()
 483   "Reload the current page, discarding any existing cached content."
 484   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 485   (elpher-visit-page elpher-current-page))
 486
 487 (defun elpher-save-pos ()
 488   "Save the current position of point to the current page."
 489   (when elpher-current-page
 490     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 491
 492 (defun elpher-restore-pos ()
 493   "Restore the position of point to that cached in the current page."
 494   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 495     (if pos
 496         (goto-char pos)
 497       (goto-char (point-min)))))
 498
 499
 500 ;;; Buffer preparation
 501 ;;
 502
 503 (defun elpher-update-header ()
 504   "If `elpher-use-header' is true, display current page info in window header."
 505   (if elpher-use-header
 506       (let* ((display-string (elpher-page-display-string elpher-current-page))
 507              (address (elpher-page-address elpher-current-page))
 508              (tls-string (if (and (not (elpher-address-special-p address))
 509                                   (member (elpher-address-protocol address)
 510                                           '("gophers" "gemini")))
 511                              " [TLS encryption]"
 512                            ""))
 513              (header (concat display-string
 514                              (propertize tls-string 'face 'bold))))
 515         (setq header-line-format header))))
 516
 517 (defmacro elpher-with-clean-buffer (&rest args)
 518   "Evaluate ARGS with a clean *elpher* buffer as current."
 519   (list 'with-current-buffer "*elpher*"
 520         '(elpher-mode)
 521         (append (list 'let '((inhibit-read-only t))
 522                       '(setq-local network-security-level
 523                                    (default-value 'network-security-level))
 524                       '(erase-buffer)
 525                       '(elpher-update-header))
 526                 args)))
 527
 528 (defun elpher-buffer-message (string &optional line)
 529   "Replace first line in elpher buffer with STRING.
 530 If LINE is non-nil, replace that line instead."
 531   (with-current-buffer "*elpher*"
 532     (let ((inhibit-read-only t))
 533       (goto-char (point-min))
 534       (if line
 535           (forward-line line))
 536       (let ((data (match-data)))
 537         (unwind-protect
 538             (progn
 539               (re-search-forward "^.*$")
 540               (replace-match string))
 541           (set-match-data data))))))
 542
 543
 544 ;;; Text Processing
 545 ;;
 546
 547 (defvar elpher-user-coding-system nil
 548   "User-specified coding system to use for decoding text responses.")
 549
 550 (defun elpher-decode (string)
 551   "Decode STRING using autodetected or user-specified coding system."
 552   (decode-coding-string string
 553                         (if elpher-user-coding-system
 554                             elpher-user-coding-system
 555                           (detect-coding-string string t))))
 556
 557 (defun elpher-preprocess-text-response (string)
 558   "Preprocess text selector response contained in STRING.
 559 This involes decoding the character representation, and clearing
 560 away CRs and any terminating period."
 561   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 562                                            (replace-regexp-in-string "\r" "" string))))
 563
 564
 565 ;;; Network error reporting
 566 ;;
 567
 568 (defun elpher-network-error (address error)
 569   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 570 ERROR can be either an error object or a string."
 571   (elpher-with-clean-buffer
 572    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 573            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 574            (if (stringp error) error (error-message-string error)) "\n"
 575            (propertize "\n----------------\n\n" 'face 'error)
 576            "Press 'u' to return to the previous page.")))
 577
 578
 579 ;;; General network communication
 580 ;;
 581
 582 (defvar elpher-network-timer nil
 583   "Timer used for network connections.")
 584
 585 (defvar elpher-use-tls nil
 586   "If non-nil, use TLS to communicate with gopher servers.")
 587
 588 (defvar elpher-client-certificate nil
 589   "If non-nil, contains client certificate details to use for TLS connections.")
 590
 591 (defun elpher-process-cleanup ()
 592   "Immediately shut down any extant elpher process and timers."
 593   (let ((p (get-process "elpher-process")))
 594     (if p (delete-process p)))
 595   (if (timerp elpher-network-timer)
 596       (cancel-timer elpher-network-timer)))
 597
 598 (defun elpher-get-host-response (address default-port query-string response-processor
 599                                          &optional use-tls force-ipv4)
 600   "Generic function for retrieving data from ADDRESS.
 601
 602 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 603 QUERY-STRING is a string sent to the host specified by ADDRESS to
 604 illicet a response.  This response is passed as an argument to the
 605 function RESPONSE-PROCESSOR.
 606
 607 If non-nil, USE-TLS specifies that the connection is to be made over
 608 TLS.  If set to gemini, the certificate verification will be disabled
 609 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 610
 611 If non-nil, FORCE-IPV4 causes the network connection to be made over
 612 ipv4 only.  (The default behaviour when this is not set depends on
 613 the host operating system and the local network capabilities."
 614   (if (and use-tls (not (gnutls-available-p)))
 615       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 616     (unless (< (elpher-address-port address) 65536)
 617       (error "Cannot establish network connection: port number > 65536"))
 618     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 619       (setq-local network-security-level 'low))
 620     (condition-case nil
 621         (let* ((kill-buffer-query-functions nil)
 622                (port (elpher-address-port address))
 623                (host (elpher-address-host address))
 624                (response-string-parts nil)
 625                (bytes-received 0)
 626                (hkbytes-received 0)
 627                (proc (make-network-process :name "elpher-process"
 628                                            :host host
 629                                            :family (and force-ipv4 'ipv4)
 630                                            :service (if (> port 0) port default-port)
 631                                            :buffer nil
 632                                            :coding 'binary
 633                                            :noquery t
 634                                            :nowait t
 635                                            :tls-parameters
 636                                            (and use-tls
 637                                                 (cons 'gnutls-x509pki
 638                                                       (gnutls-boot-parameters
 639                                                        :type 'gnutls-x509pki
 640                                                        :hostname host
 641                                                        :keylist
 642                                                        (elpher-get-current-keylist address))))))
 643                (timer (run-at-time elpher-connection-timeout nil
 644                                    (lambda ()
 645                                      (elpher-process-cleanup)
 646                                      (cond
 647                                         ; Try again with IPv4
 648                                       ((not force-ipv4)
 649                                        (message "Connection timed out.  Retrying with IPv4.")
 650                                        (elpher-get-host-response address default-port
 651                                                                  query-string
 652                                                                  response-processor
 653                                                                  use-tls t))
 654                                       ((and use-tls
 655                                             (not (eq use-tls 'gemini))
 656                                             (or elpher-auto-disengage-TLS
 657                                                 (y-or-n-p
 658                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 659                                        (setq elpher-use-tls nil)
 660                                        (elpher-get-host-response address default-port
 661                                                                  query-string
 662                                                                  response-processor
 663                                                                  nil force-ipv4))
 664                                       (t
 665                                        (elpher-network-error address "Connection time-out.")))))))
 666           (setq elpher-network-timer timer)
 667           (elpher-buffer-message (concat "Connecting to " host "..."
 668                                          " (press 'u' to abort)"))
 669           (set-process-filter proc
 670                               (lambda (_proc string)
 671                                 (when timer
 672                                   (cancel-timer timer)
 673                                   (setq timer nil))
 674                                 (setq bytes-received (+ bytes-received (length string)))
 675                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 676                                   (when (> new-hkbytes-received hkbytes-received)
 677                                     (setq hkbytes-received new-hkbytes-received)
 678                                     (elpher-buffer-message
 679                                         (concat "("
 680                                                 (number-to-string (/ hkbytes-received 10.0))
 681                                                 " MB read)")
 682                                         1)))
 683                                 (setq response-string-parts
 684                                       (cons string response-string-parts))))
 685           (set-process-sentinel proc
 686                                 (lambda (proc event)
 687                                   (when timer
 688                                     (cancel-timer timer))
 689                                   (condition-case the-error
 690                                       (cond
 691                                        ((string-prefix-p "open" event)    ; request URL
 692                                         (elpher-buffer-message
 693                                          (concat "Connected to " host ". Receiving data..."
 694                                                  " (press 'u' to abort)"))
 695                                         (let ((inhibit-eol-conversion t))
 696                                           (process-send-string proc query-string)))
 697                                        ((string-prefix-p "deleted" event)) ; do nothing
 698                                        ((and (not response-string-parts)
 699                                              (not (or elpher-ipv4-always force-ipv4)))
 700                                         ; Try again with IPv4
 701                                         (message "Connection failed. Retrying with IPv4.")
 702                                         (elpher-get-host-response address default-port
 703                                                                   query-string
 704                                                                   response-processor
 705                                                                   use-tls t))
 706                                        (response-string-parts
 707                                         (elpher-with-clean-buffer
 708                                          (insert "Data received.  Rendering..."))
 709                                         (funcall response-processor
 710                                                  (apply #'concat (reverse response-string-parts)))
 711                                         (elpher-restore-pos))
 712                                        (t
 713                                         (error "No response from server")))
 714                                     (error
 715                                      (elpher-network-error address the-error))))))
 716       (error
 717        (error "Error initiating connection to server")))))
 718
 719
 720 ;;; Client-side TLS Certificate Management
 721 ;;
 722
 723 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 724   "Generate a key and a self-signed client TLS certificate using openssl.
 725
 726 The Common Name field of the certificate is set to COMMON-NAME.  The
 727 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 728 the key and certificate files to write.
 729
 730 If TEMPORARY is non-nil, the certificate will be given an exporation
 731 period of one day, and the key and certificate files will be deleted
 732 when the certificate is no longer needed for the current session.
 733
 734 Otherwise, the certificate will be given a 100 year expiration period
 735 and the files will not be deleted.
 736
 737 The function returns a list containing the current host name, the
 738 temporary flag, and the key and cert file names in the form required
 739 by `gnutls-boot-parameters`."
 740   (let ((exp-key-file (expand-file-name key-file))
 741         (exp-cert-file (expand-file-name cert-file)))
 742     (condition-case nil
 743         (progn
 744           (call-process elpher-openssl-command nil nil nil
 745                         "req" "-x509" "-newkey" "rsa:2048"
 746                         "-days" (if temporary "1" "36500")
 747                         "-nodes"
 748                         "-subj" (concat "/CN=" common-name)
 749                         "-keyout" exp-key-file
 750                         "-out" exp-cert-file)
 751           (list (elpher-address-host (elpher-page-address elpher-current-page))
 752                 temporary exp-key-file exp-cert-file))
 753       (error
 754        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 755        (error "Program 'openssl', required for certificate generation, not found")))))
 756
 757 (defun elpher-generate-throwaway-certificate ()
 758   "Generate and return details of a throwaway certificate.
 759 The key and certificate files will be deleted when they are no
 760 longer needed for this session."
 761   (let* ((file-base (make-temp-name "elpher"))
 762          (key-file (concat temporary-file-directory file-base ".key"))
 763          (cert-file (concat temporary-file-directory file-base ".crt")))
 764     (elpher-generate-certificate file-base key-file cert-file t)))
 765
 766 (defun elpher-generate-persistent-certificate (file-base common-name)
 767   "Generate and return details of a persistent certificate.
 768 The argument FILE-BASE is used as the base for the key and certificate
 769 files, while COMMON-NAME specifies the common name field of the
 770 certificate.
 771
 772 The key and certificate files are written to in `elpher-certificate-directory'."
 773   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 774          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 775     (elpher-generate-certificate common-name key-file cert-file)))
 776
 777 (defun elpher-get-existing-certificate (file-base)
 778   "Return a certificate object corresponding to an existing certificate.
 779 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 780 the directory `elpher-certificate-directory'."
 781   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 782          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 783     (list (elpher-address-host (elpher-page-address elpher-current-page))
 784           nil
 785           (expand-file-name key-file)
 786           (expand-file-name cert-file))))
 787
 788 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 789   "Install a key+certificate file pair in `elpher-certificate-directory'.
 790 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 791 certificate files to install.  The argument FILE-BASE is used as the
 792 base for the installed key and certificate files."
 793   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 794          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 795     (if (or (file-exists-p key-file)
 796             (file-exists-p cert-file))
 797         (error "A certificate with base name %s is already installed" file-base))
 798     (copy-file key-file-src key-file)
 799     (copy-file cert-file-src cert-file)
 800     (list (elpher-address-host (elpher-page-address elpher-current-page))
 801           nil
 802           (expand-file-name key-file)
 803           (expand-file-name cert-file))))
 804
 805 (defun elpher-list-existing-certificates ()
 806   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 807   (unless (file-directory-p elpher-certificate-directory)
 808     (make-directory elpher-certificate-directory))
 809   (mapcar
 810    (lambda (file)
 811      (file-name-sans-extension file))
 812    (directory-files elpher-certificate-directory nil "\.key$")))
 813
 814 (defun elpher-forget-current-certificate ()
 815   "Causes any current certificate to be forgotten.)
 816 In the case of throwaway certificates, the key and certificate files
 817 are also deleted."
 818   (interactive)
 819   (when elpher-client-certificate
 820     (unless (and (called-interactively-p 'any)
 821                  (not (y-or-n-p (concat "Really forget client certificate? "
 822                                         "(Throwaway certificates will be deleted.)"))))
 823       (when (cadr elpher-client-certificate)
 824         (delete-file (elt elpher-client-certificate 2))
 825         (delete-file (elt elpher-client-certificate 3)))
 826       (setq elpher-client-certificate nil)
 827       (if (called-interactively-p 'any)
 828           (message "Client certificate forgotten.")))))
 829
 830 (defun elpher-get-current-keylist (address)
 831   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 832
 833 This is obtained from the client certificate described by
 834 `elpher-current-certificate', if one is available and the host for
 835 that certificate matches the host in ADDRESS.
 836
 837 If `elpher-current-certificate' is non-nil, and its host name doesn't
 838 match that of ADDRESS, the certificate is forgotten."
 839   (if elpher-client-certificate
 840       (if (string= (car elpher-client-certificate)
 841                    (elpher-address-host address))
 842           (list (cddr elpher-client-certificate))
 843         (elpher-forget-current-certificate)
 844         (message "Disabling client certificate for new host")
 845         nil)
 846     nil))
 847
 848
 849 ;;; Gopher selector retrieval
 850 ;;
 851
 852 (defun elpher-get-gopher-response (address renderer)
 853   "Get response string from gopher server at ADDRESS and render using RENDERER."
 854   (elpher-get-host-response address 70
 855                             (concat (elpher-gopher-address-selector address) "\r\n")
 856                             renderer
 857                             (or (string= (elpher-address-protocol address) "gophers")
 858                                 elpher-use-tls)))
 859
 860 (defun elpher-get-gopher-page (renderer)
 861   "Getter function for gopher pages.
 862 The RENDERER procedure is used to display the contents of the page
 863 once they are retrieved from the gopher server."
 864   (let* ((address (elpher-page-address elpher-current-page))
 865          (content (elpher-get-cached-content address)))
 866     (if (and content (funcall renderer nil))
 867         (elpher-with-clean-buffer
 868          (insert content)
 869          (elpher-restore-pos))
 870       (elpher-with-clean-buffer
 871        (insert "LOADING... (use 'u' to cancel)\n"))
 872       (condition-case the-error
 873           (elpher-get-gopher-response address renderer)
 874         (error
 875          (elpher-network-error address the-error))))))
 876
 877 ;; Index rendering
 878
 879 (defun elpher-insert-index (string)
 880   "Insert the index corresponding to STRING into the current buffer."
 881   ;; Should be able to split directly on CRLF, but some non-conformant
 882   ;; LF-only servers sadly exist, hence the following.
 883   (let ((str-processed (elpher-preprocess-text-response string)))
 884     (dolist (line (split-string str-processed "\n"))
 885       (ignore-errors
 886         (unless (= (length line) 0)
 887           (let* ((type (elt line 0))
 888                  (fields (split-string (substring line 1) "\t"))
 889                  (display-string (elt fields 0))
 890                  (selector (elt fields 1))
 891                  (host (elt fields 2))
 892                  (port (if (elt fields 3)
 893                            (string-to-number (elt fields 3))
 894                          nil))
 895                  (address (elpher-make-gopher-address type selector host port)))
 896             (elpher-insert-index-record display-string address)))))))
 897
 898 (defun elpher-insert-margin (&optional type-name)
 899   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 900   (if type-name
 901       (progn
 902         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 903                         (concat
 904                          (propertize "[" 'face 'elpher-margin-brackets)
 905                          (propertize type-name 'face 'elpher-margin-key)
 906                          (propertize "]" 'face 'elpher-margin-brackets))))
 907         (insert " "))
 908     (insert (make-string elpher-margin-width ?\s))))
 909
 910 (defun elpher--page-button-help (_window buffer pos)
 911   "Function called by Emacs to generate mouse-over text.
 912 The arguments specify the BUFFER and the POS within the buffer of the item
 913 for which help is required.  The function returns the help to be
 914 displayed.  The _WINDOW argument is currently unused."
 915   (with-current-buffer buffer
 916     (let ((button (button-at pos)))
 917       (when button
 918         (let* ((page (button-get button 'elpher-page))
 919                (address (elpher-page-address page)))
 920           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 921                                                 address
 922                                               (elpher-address-to-url address))))))))
 923
 924 (defun elpher-insert-index-record (display-string &optional address)
 925   "Function to insert an index record into the current buffer.
 926 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 927 If ADDRESS is not supplied or nil the record is rendered as an
 928 'information' line."
 929   (let* ((type (if address (elpher-address-type address) nil))
 930          (type-map-entry (cdr (assoc type elpher-type-map))))
 931     (if type-map-entry
 932         (let* ((margin-code (elt type-map-entry 2))
 933                (face (elt type-map-entry 3))
 934                (filtered-display-string (ansi-color-filter-apply display-string))
 935                (page (elpher-make-page filtered-display-string address)))
 936           (elpher-insert-margin margin-code)
 937           (insert-text-button filtered-display-string
 938                               'face face
 939                               'elpher-page page
 940                               'action #'elpher-click-link
 941                               'follow-link t
 942                               'help-echo #'elpher--page-button-help))
 943       (pcase type
 944         ('nil ;; Information
 945          (elpher-insert-margin)
 946          (let ((propertized-display-string
 947                 (propertize display-string 'face 'elpher-info)))
 948            (insert (elpher-process-text-for-display propertized-display-string))))
 949         (`(gopher ,selector-type) ;; Unknown
 950          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 951          (insert (propertize display-string
 952                              'face 'elpher-unknown)))))
 953     (insert "\n")))
 954
 955 (defun elpher-click-link (button)
 956   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 957   (let ((page (button-get button 'elpher-page)))
 958     (elpher-visit-page page)))
 959
 960 (defun elpher-render-index (data &optional _mime-type-string)
 961   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 962   (elpher-with-clean-buffer
 963    (if (not data)
 964        t
 965      (elpher-insert-index data)
 966      (elpher-cache-content (elpher-page-address elpher-current-page)
 967                            (buffer-string)))))
 968
 969 ;; Text rendering
 970
 971 (defconst elpher-url-regex
 972   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 973   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 974
 975 (defun elpher-buttonify-urls (string)
 976   "Turn substrings which look like urls in STRING into clickable buttons."
 977   (with-temp-buffer
 978     (insert string)
 979     (goto-char (point-min))
 980     (while (re-search-forward elpher-url-regex nil t)
 981       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 982                                     (elpher-address-from-url (match-string 0)))))
 983           (make-text-button (match-beginning 0)
 984                             (match-end 0)
 985                             'elpher-page  page
 986                             'action #'elpher-click-link
 987                             'follow-link t
 988                             'help-echo #'elpher--page-button-help
 989                             'face 'button)))
 990     (buffer-string)))
 991
 992 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 993   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 994
 995 (defun elpher-process-text-for-display (string)
 996   "Perform any desired processing of STRING prior to display as text.
 997 Currently includes buttonifying URLs and processing ANSI escape codes."
 998   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 999                              (ansi-color-filter-apply string)
1000                            (ansi-color-apply string))))
1001
1002 (defun elpher-render-text (data &optional _mime-type-string)
1003   "Render DATA as text.  MIME-TYPE-STRING is unused."
1004   (elpher-with-clean-buffer
1005    (if (not data)
1006        t
1007      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1008      (elpher-cache-content
1009       (elpher-page-address elpher-current-page)
1010       (buffer-string)))))
1011
1012 ;; Image retrieval
1013
1014 (defun elpher-render-image (data &optional _mime-type-string)
1015   "Display DATA as image.  MIME-TYPE-STRING is unused."
1016   (if (not data)
1017       nil
1018     (if (display-images-p)
1019         (progn
1020           (let ((image (create-image
1021                         data
1022                         nil t)))
1023             (elpher-with-clean-buffer
1024              (insert-image image)
1025              (elpher-restore-pos))))
1026       (elpher-render-download data))))
1027
1028 ;; Search retrieval and rendering
1029
1030 (defun elpher-get-gopher-query-page (renderer)
1031   "Getter for gopher addresses requiring input.
1032 The response is rendered using the rendering function RENDERER."
1033    (let* ((address (elpher-page-address elpher-current-page))
1034           (content (elpher-get-cached-content address))
1035           (aborted t))
1036     (if (and content (funcall renderer nil))
1037         (elpher-with-clean-buffer
1038          (insert content)
1039          (elpher-restore-pos)
1040          (message "Displaying cached search results.  Reload to perform a new search."))
1041       (unwind-protect
1042           (let* ((query-string (read-string "Query: "))
1043                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1044                  (search-address (elpher-make-gopher-address ?1
1045                                                              query-selector
1046                                                              (elpher-address-host address)
1047                                                              (elpher-address-port address)
1048                                                              (equal (elpher-address-type address) "gophers"))))
1049             (setq aborted nil)
1050
1051             (elpher-with-clean-buffer
1052              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1053             (elpher-get-gopher-response search-address renderer))
1054         (if aborted
1055             (elpher-visit-previous-page))))))
1056
1057 ;; Raw server response rendering
1058
1059 (defun elpher-render-raw (data &optional mime-type-string)
1060   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1061   (if (not data)
1062       nil
1063     (elpher-with-clean-buffer
1064      (when mime-type-string
1065        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1066      (insert data)
1067      (goto-char (point-min)))
1068     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1069
1070 ;; File save "rendering"
1071
1072 (defun elpher-render-download (data &optional _mime-type-string)
1073   "Save DATA to file.  MIME-TYPE-STRING is unused."
1074   (if (not data)
1075       nil
1076     (let* ((address (elpher-page-address elpher-current-page))
1077            (selector (if (elpher-address-gopher-p address)
1078                          (elpher-gopher-address-selector address)
1079                        (elpher-address-filename address))))
1080       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1081       (let* ((filename-proposal (file-name-nondirectory selector))
1082              (filename (read-file-name "Download complete. Save file as: "
1083                                        nil nil nil
1084                                        (if (> (length filename-proposal) 0)
1085                                            filename-proposal
1086                                          "download.file"))))
1087         (let ((coding-system-for-write 'binary))
1088           (with-temp-file filename
1089             (insert data)))
1090         (message (format "Saved to file %s." filename))))))
1091
1092 ;; HTML rendering
1093
1094 (defun elpher-render-html (data &optional _mime-type-string)
1095   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1096   (elpher-with-clean-buffer
1097    (if (not data)
1098        t
1099      (let ((dom (with-temp-buffer
1100                   (insert data)
1101                   (libxml-parse-html-region (point-min) (point-max)))))
1102        (shr-insert-document dom)))))
1103
1104 ;; Gemini page retrieval
1105
1106 (defvar elpher-gemini-redirect-chain)
1107
1108 (defun elpher-get-gemini-response (address renderer)
1109   "Get response string from gemini server at ADDRESS and render using RENDERER."
1110   (elpher-get-host-response address 1965
1111                             (concat (elpher-address-to-url address) "\r\n")
1112                             (lambda (response-string)
1113                               (elpher-process-gemini-response response-string renderer))
1114                             'gemini))
1115
1116 (defun elpher-parse-gemini-response (response)
1117   "Parse the RESPONSE string and return a list of components.
1118 The list is of the form (code meta body).  A response of nil implies
1119 that the response was malformed."
1120   (let ((header-end-idx (string-match "\r\n" response)))
1121     (if header-end-idx
1122         (let ((header (string-trim (substring response 0 header-end-idx)))
1123               (body (substring response (+ header-end-idx 2))))
1124           (if (>= (length header) 2)
1125               (let ((code (substring header 0 2))
1126                     (meta (string-trim (substring header 2))))
1127                 (list code meta body))
1128             (error "Malformed response: No response status found in header %s" header)))
1129       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1130
1131 (defun elpher-process-gemini-response (response-string renderer)
1132   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1133   (let ((response-components (elpher-parse-gemini-response response-string)))
1134     (let ((response-code (elt response-components 0))
1135           (response-meta (elt response-components 1))
1136           (response-body (elt response-components 2)))
1137       (pcase (elt response-code 0)
1138         (?1 ; Input required
1139          (elpher-with-clean-buffer
1140           (insert "Gemini server is requesting input."))
1141          (let* ((query-string
1142                  (if (eq (elt response-code 1) ?1)
1143                      (read-passwd (concat response-meta ": "))
1144                    (read-string (concat response-meta ": "))))
1145                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1146                 (old-fname (url-filename query-address)))
1147            (setf (url-filename query-address)
1148                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1149            (elpher-get-gemini-response query-address renderer)))
1150         (?2 ; Normal response
1151          (funcall renderer response-body response-meta))
1152         (?3 ; Redirect
1153          (message "Following redirect to %s" response-meta)
1154          (if (>= (length elpher-gemini-redirect-chain) 5)
1155              (error "More than 5 consecutive redirects followed"))
1156          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1157            (if (member redirect-address elpher-gemini-redirect-chain)
1158                (error "Redirect loop detected"))
1159            (if (not (string= (elpher-address-protocol redirect-address)
1160                              "gemini"))
1161                (error "Server tried to automatically redirect to non-gemini URL: %s"
1162                       response-meta))
1163            (elpher-page-set-address elpher-current-page redirect-address)
1164            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1165            (elpher-get-gemini-response redirect-address renderer)))
1166         (?4 ; Temporary failure
1167          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1168                 response-code response-meta))
1169         (?5 ; Permanent failure
1170          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1171                 response-code response-meta))
1172         (?6 ; Client certificate required
1173          (elpher-with-clean-buffer
1174           (if elpher-client-certificate
1175               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1176             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1177           (auto-fill-mode 1)
1178           (elpher-gemini-insert-text response-meta))
1179          (let ((chosen-certificate (elpher-choose-client-certificate)))
1180            (unless chosen-certificate
1181              (error "Gemini server requires a client certificate and none was provided"))
1182            (setq elpher-client-certificate chosen-certificate))
1183          (elpher-with-clean-buffer)
1184          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1185         (_other
1186          (error "Gemini server response unknown: %s %s"
1187                 response-code response-meta))))))
1188
1189 (defun elpher-choose-client-certificate ()
1190   "Prompt for a client certificate to use to establish a TLS connection."
1191   (let* ((read-answer-short t))
1192     (pcase (read-answer "What do you want to do? "
1193                         '(("throwaway" ?t
1194                            "generate and use throw-away certificate")
1195                           ("persistent" ?p
1196                            "generate new or use existing persistent certificate")
1197                           ("abort" ?a
1198                            "stop immediately")))
1199       ("throwaway"
1200        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1201       ("persistent"
1202        (let* ((existing-certificates (elpher-list-existing-certificates))
1203               (file-base (completing-read
1204                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1205                           existing-certificates)))
1206          (if (string-empty-p (string-trim file-base))
1207              nil
1208            (if (member file-base existing-certificates)
1209                (setq elpher-client-certificate
1210                      (elpher-get-existing-certificate file-base))
1211              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1212                                  '(("new" ?n
1213                                     "generate new certificate")
1214                                    ("install" ?i
1215                                     "install existing certificate")
1216                                    ("abort" ?a
1217                                     "stop immediately")))
1218                ("new"
1219                 (let ((common-name (read-string "Common Name field for new certificate: "
1220                                                 file-base)))
1221                   (message "New key and self-signed certificate written to %s"
1222                            elpher-certificate-directory)
1223                   (elpher-generate-persistent-certificate file-base common-name)))
1224                ("install"
1225                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1226                        (key-file (read-file-name "Key file: " nil nil t)))
1227                   (message "Key and certificate installed in %s for future use"
1228                            elpher-certificate-directory)
1229                   (elpher-install-and-use-existing-certificate key-file
1230                                                                cert-file
1231                                                                file-base)))
1232                ("abort" nil))))))
1233       ("abort" nil))))
1234
1235 (defun elpher-get-gemini-page (renderer)
1236   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1237   (let* ((address (elpher-page-address elpher-current-page))
1238          (content (elpher-get-cached-content address)))
1239     (condition-case the-error
1240         (if (and content (funcall renderer nil))
1241             (elpher-with-clean-buffer
1242               (insert content)
1243               (elpher-restore-pos))
1244           (elpher-with-clean-buffer
1245            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1246           (setq elpher-gemini-redirect-chain nil)
1247           (elpher-get-gemini-response address renderer))
1248       (error
1249        (elpher-network-error address the-error)))))
1250
1251 (defun elpher-render-gemini (body &optional mime-type-string)
1252   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1253   (if (not body)
1254       t
1255     (let* ((mime-type-string* (if (or (not mime-type-string)
1256                                       (string-empty-p mime-type-string))
1257                                   "text/gemini; charset=utf-8"
1258                                 mime-type-string))
1259            (mime-type-split (split-string mime-type-string* ";" t))
1260            (mime-type (string-trim (car mime-type-split)))
1261            (parameters (mapcar (lambda (s)
1262                                  (let ((key-val (split-string s "=")))
1263                                    (list (downcase (string-trim (car key-val)))
1264                                          (downcase (string-trim (cadr key-val))))))
1265                                (cdr mime-type-split))))
1266       (when (string-prefix-p "text/" mime-type)
1267         (setq body (decode-coding-string
1268                     body
1269                     (if (assoc "charset" parameters)
1270                         (intern (cadr (assoc "charset" parameters)))
1271                       'utf-8)))
1272         (setq body (replace-regexp-in-string "\r" "" body)))
1273       (pcase mime-type
1274         ((or "text/gemini" "")
1275          (elpher-render-gemini-map body parameters))
1276         ("text/html"
1277          (elpher-render-html body))
1278         ((pred (string-prefix-p "text/"))
1279          (elpher-render-gemini-plain-text body parameters))
1280         ((pred (string-prefix-p "image/"))
1281          (elpher-render-image body))
1282         (_other
1283          (elpher-render-download body))))))
1284
1285 (defun elpher-gemini-get-link-url (link-line)
1286   "Extract the url portion of LINK-LINE, a gemini map file link line.
1287 Returns nil in the event that the contents of the line following the
1288 => prefix are empty."
1289   (let ((l (split-string (substring link-line 2))))
1290     (if l
1291         (string-trim (elt l 0))
1292       nil)))
1293
1294 (defun elpher-gemini-get-link-display-string (link-line)
1295   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1296 Returns the url portion in the event that the display-string portion is empty."
1297   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1298          (idx (string-match "[ \t]" rest)))
1299     (string-trim (if idx
1300                      (substring rest (+ idx 1))
1301                    rest))))
1302
1303 (defun elpher-collapse-dot-sequences (filename)
1304   "Collapse dot sequences in FILENAME.
1305 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1306   (let* ((path (split-string filename "/"))
1307          (path-reversed-normalized
1308           (seq-reduce (lambda (a b)
1309                         (cond ((and a (equal b "..") (cdr a)))
1310                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1311                               ((equal b ".") a)
1312                               (t (cons b a))))
1313                       path nil)))
1314     (string-join (reverse path-reversed-normalized) "/")))
1315
1316 (defun elpher-address-from-gemini-url (url)
1317   "Extract address from URL with defaults as per gemini map files.
1318 While there's obviously some redundancy here between this function and
1319 `elpher-address-from-url', gemini map file URLs require enough special
1320 treatment that a separate function is warranted."
1321   (let ((address (url-generic-parse-url url))
1322         (current-address (elpher-page-address elpher-current-page)))
1323     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1324       (setf (url-fullness address) t)
1325       (if (url-host address) ;if there is an explicit host, filenames are absolute
1326           (if (string-empty-p (url-filename address))
1327               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1328         (setf (url-host address) (url-host current-address))
1329         (setf (url-port address) (url-port current-address))
1330         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1331           (setf (url-filename address)
1332                 (concat (file-name-directory (url-filename current-address))
1333                         (url-filename address)))))
1334       (unless (url-type address)
1335         (setf (url-type address) "gemini"))
1336       (when (equal (url-type address) "gemini")
1337         (setf (url-filename address)
1338               (elpher-collapse-dot-sequences (url-filename address)))))
1339     (elpher-remove-redundant-ports address)))
1340
1341 (defun elpher-gemini-insert-link (link-line)
1342   "Insert link described by LINK-LINE into a text/gemini document."
1343   (let* ((url (elpher-gemini-get-link-url link-line))
1344          (display-string (elpher-gemini-get-link-display-string link-line))
1345          (address (elpher-address-from-gemini-url url))
1346          (type (if address (elpher-address-type address) nil))
1347          (type-map-entry (cdr (assoc type elpher-type-map))))
1348     (when display-string
1349       (insert elpher-gemini-link-string)
1350       (if type-map-entry
1351           (let* ((face (elt type-map-entry 3))
1352                  (filtered-display-string (ansi-color-filter-apply display-string))
1353                  (page (elpher-make-page filtered-display-string address)))
1354             (insert-text-button filtered-display-string
1355                                 'face face
1356                                 'elpher-page page
1357                                 'action #'elpher-click-link
1358                                 'follow-link t
1359                                 'help-echo #'elpher--page-button-help))
1360         (insert (propertize display-string 'face 'elpher-unknown)))
1361       (insert "\n"))))
1362
1363 (defun elpher-gemini-insert-header (header-line)
1364   "Insert header described by HEADER-LINE into a text/gemini document.
1365 The gemini map file line describing the header is given
1366 by HEADER-LINE."
1367   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1368     (let ((level (length (match-string 1 header-line)))
1369           (header (substring header-line (match-end 0))))
1370       (unless (display-graphic-p)
1371         (insert (make-string level ?#) " "))
1372       (insert (propertize header 'face
1373                           (pcase level
1374                             (1 'elpher-gemini-heading1)
1375                             (2 'elpher-gemini-heading2)
1376                             (3 'elpher-gemini-heading3)
1377                             (_ 'default)))
1378               "\n"))))
1379
1380 (defun elpher-gemini-insert-text (text-line)
1381   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1382 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1383 width defined by elpher-gemini-max-fill-width."
1384   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1385   (let* ((processed-text-line (if (match-string 2 text-line)
1386                                   (concat
1387                                    (replace-regexp-in-string "\*"
1388                                                              elpher-gemini-bullet-string
1389                                                              (match-string 0 text-line))
1390                                    (substring text-line (match-end 0)))
1391                                 text-line))
1392          (adaptive-fill-mode nil)
1393          (fill-prefix (if (match-string 2 text-line)
1394                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1395                         nil)))
1396     (insert (elpher-process-text-for-display processed-text-line))
1397     (newline)))
1398
1399 (defun elpher-render-gemini-map (data _parameters)
1400   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1401   (elpher-with-clean-buffer
1402    (let ((preformatted nil))
1403      (auto-fill-mode 1)
1404      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1405      (dolist (line (split-string data "\n"))
1406        (cond
1407         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1408         (preformatted (insert (elpher-process-text-for-display
1409                                (propertize line 'face 'elpher-gemini-preformatted))
1410                               "\n"))
1411         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1412         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1413         (t (elpher-gemini-insert-text line)))))
1414    (elpher-cache-content
1415     (elpher-page-address elpher-current-page)
1416     (buffer-string))))
1417
1418 (defun elpher-render-gemini-plain-text (data _parameters)
1419   "Render DATA as plain text file.  PARAMETERS is currently unused."
1420   (elpher-with-clean-buffer
1421    (insert (elpher-process-text-for-display data))
1422    (elpher-cache-content
1423     (elpher-page-address elpher-current-page)
1424     (buffer-string))))
1425
1426
1427 ;; Finger page connection
1428
1429 (defun elpher-get-finger-page (renderer)
1430   "Opens a finger connection to the current page address.
1431 The result is rendered using RENDERER."
1432   (let* ((address (elpher-page-address elpher-current-page))
1433          (content (elpher-get-cached-content address)))
1434     (if (and content (funcall renderer nil))
1435         (elpher-with-clean-buffer
1436          (insert content)
1437          (elpher-restore-pos))
1438       (elpher-with-clean-buffer
1439        (insert "LOADING... (use 'u' to cancel)\n"))
1440       (condition-case the-error
1441           (let* ((kill-buffer-query-functions nil)
1442                  (user (let ((filename (elpher-address-filename address)))
1443                          (if (> (length filename) 1)
1444                              (substring filename 1)
1445                            (elpher-address-user address)))))
1446             (elpher-get-host-response address 79
1447                                       (concat user "\r\n")
1448                                       renderer))
1449         (error
1450          (elpher-network-error address the-error))))))
1451
1452
1453 ;; Telnet page connection
1454
1455 (defun elpher-get-telnet-page (renderer)
1456   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1457   (when renderer
1458     (elpher-visit-previous-page)
1459     (error "Command not supported for telnet URLs"))
1460   (let* ((address (elpher-page-address elpher-current-page))
1461          (host (elpher-address-host address))
1462          (port (elpher-address-port address)))
1463     (elpher-visit-previous-page)
1464     (if (> port 0)
1465         (telnet host port)
1466       (telnet host))))
1467
1468
1469 ;; Other URL page opening
1470
1471 (defun elpher-get-other-url-page (renderer)
1472   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1473   (when renderer
1474     (elpher-visit-previous-page)
1475     (error "Command not supported for general URLs"))
1476   (let* ((address (elpher-page-address elpher-current-page))
1477          (url (elpher-address-to-url address)))
1478     (progn
1479       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1480       (message "Opening URL...")
1481       (if elpher-open-urls-with-eww
1482           (browse-web url)
1483         (browse-url url)))))
1484
1485
1486 ;; Start page page retrieval
1487
1488 (defun elpher-get-start-page (renderer)
1489   "Getter which displays the start page (RENDERER must be nil)."
1490   (when renderer
1491     (elpher-visit-previous-page)
1492     (error "Command not supported for start page"))
1493   (elpher-with-clean-buffer
1494    (insert "     --------------------------------------------\n"
1495            "           Elpher Gopher and Gemini Client       \n"
1496            "                   version " elpher-version "\n"
1497            "     --------------------------------------------\n"
1498            "\n"
1499            "Default bindings:\n"
1500            "\n"
1501            " - TAB/Shift-TAB: next/prev item on current page\n"
1502            " - RET/mouse-1: open item under cursor\n"
1503            " - m: select an item on current page by name (autocompletes)\n"
1504            " - u/mouse-3/U: return to previous page or to the start page\n"
1505            " - o/O: visit different selector or the root menu of the current server\n"
1506            " - g: go to a particular address (gopher, gemini, finger)\n"
1507            " - d/D: download item under cursor or current page\n"
1508            " - i/I: info on item under cursor or current page\n"
1509            " - c/C: copy URL representation of item under cursor or current page\n"
1510            " - a/A: bookmark the item under cursor or current page\n"
1511            " - x/X: remove bookmark for item under cursor or current page\n"
1512            " - B: visit the bookmarks page\n"
1513            " - r: redraw current page (using cached contents if available)\n"
1514            " - R: reload current page (regenerates cache)\n"
1515            " - S: set character coding system for gopher (default is to autodetect)\n"
1516            " - T: toggle TLS gopher mode\n"
1517            " - F: forget/discard current TLS client certificate\n"
1518            " - .: display the raw server response for the current page\n"
1519            "\n"
1520            "Start your exploration of gopher space and gemini:\n")
1521    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1522                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1523    (elpher-insert-index-record "Project Gemini home page"
1524                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1525    (insert "\n"
1526            "Alternatively, select a search engine and enter some search terms:\n")
1527    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1528                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1529    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1530                                (elpher-address-from-url "gemini://gus.guru/search"))
1531    (insert "\n"
1532            "This page contains your bookmarked sites (also visit with B):\n")
1533    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1534    (insert "\n"
1535            "For Elpher release news or to leave feedback, visit:\n")
1536    (elpher-insert-index-record "The Elpher Project Page"
1537                                (elpher-make-gopher-address ?1
1538                                                            "/projects/elpher/"
1539                                                            "thelambdalab.xyz"
1540                                                            70))
1541    (insert "\n"
1542            "** Refer to the ")
1543    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1544      (insert-text-button "Elpher info manual"
1545                          'face 'link
1546                          'action (lambda (_)
1547                                    (interactive)
1548                                    (info "(elpher)"))
1549                          'follow-link t
1550                          'help-echo help-string))
1551    (insert " for the full documentation. **\n")
1552    (insert (propertize
1553             (concat "  (This should be available if you have installed Elpher using\n"
1554                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1555             'face 'shadow))
1556    (elpher-restore-pos)))
1557
1558 ;; Bookmarks page page retrieval
1559
1560 (defun elpher-get-bookmarks-page (renderer)
1561   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1562   (when renderer
1563     (elpher-visit-previous-page)
1564     (error "Command not supported for bookmarks page"))
1565   (elpher-with-clean-buffer
1566    (insert "---- Bookmark list ----\n\n")
1567    (let ((bookmarks (elpher-load-bookmarks)))
1568      (if bookmarks
1569          (dolist (bookmark bookmarks)
1570            (let ((display-string (elpher-bookmark-display-string bookmark))
1571                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1572              (elpher-insert-index-record display-string address)))
1573        (insert "No bookmarks found.\n")))
1574    (insert "\n-----------------------\n"
1575            "\n"
1576            "- u: return to previous page\n"
1577            "- x: delete selected bookmark\n"
1578            "- a: rename selected bookmark\n"
1579            "\n"
1580            "Bookmarks are stored in the file ")
1581    (let ((filename elpher-bookmarks-file)
1582          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1583      (insert-text-button filename
1584                          'face 'link
1585                          'action (lambda (_)
1586                                    (interactive)
1587                                    (find-file filename))
1588                          'follow-link t
1589                          'help-echo help-string))
1590    (insert "\n")
1591    (elpher-restore-pos)))
1592
1593
1594 ;;; Bookmarks
1595 ;;
1596
1597 (defun elpher-make-bookmark (display-string url)
1598   "Make an elpher bookmark.
1599 DISPLAY-STRING determines how the bookmark will appear in the
1600 bookmark list, while URL is the url of the entry."
1601   (list display-string url))
1602
1603 (defun elpher-bookmark-display-string (bookmark)
1604   "Get the display string of BOOKMARK."
1605   (elt bookmark 0))
1606
1607 (defun elpher-set-bookmark-display-string (bookmark display-string)
1608   "Set the display string of BOOKMARK to DISPLAY-STRING."
1609   (setcar bookmark display-string))
1610
1611 (defun elpher-bookmark-url (bookmark)
1612   "Get the address for BOOKMARK."
1613   (elt bookmark 1))
1614
1615 (defun elpher-save-bookmarks (bookmarks)
1616   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1617 Beware that this completely replaces the existing contents of the file."
1618   (with-temp-file elpher-bookmarks-file
1619     (erase-buffer)
1620     (insert "; Elpher bookmarks file\n\n"
1621             "; Bookmarks are stored as a list of (label URL) items.\n"
1622             "; Feel free to edit by hand, but take care to ensure\n"
1623             "; the list structure remains intact.\n\n")
1624     (pp bookmarks (current-buffer))))
1625
1626 (defun elpher-load-bookmarks ()
1627   "Get the list of bookmarks from the users's bookmark file."
1628   (let ((bookmarks
1629          (with-temp-buffer
1630            (ignore-errors
1631              (insert-file-contents elpher-bookmarks-file)
1632              (goto-char (point-min))
1633              (read (current-buffer))))))
1634     (if (and bookmarks (listp (cadar bookmarks)))
1635         (progn
1636           (message "Reading old bookmark file. (Will be updated on write.)")
1637           (mapcar (lambda (old-bm)
1638                     (list (car old-bm)
1639                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1640                                                         (cadr old-bm)))))
1641                   bookmarks))
1642       bookmarks)))
1643
1644 (defun elpher-add-address-bookmark (address display-string)
1645   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1646 If ADDRESS is already bookmarked, update the label only."
1647   (let ((bookmarks (elpher-load-bookmarks))
1648         (url (elpher-address-to-url address)))
1649     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1650       (if existing-bookmark
1651           (elpher-set-bookmark-display-string existing-bookmark display-string)
1652         (push (elpher-make-bookmark display-string url) bookmarks)))
1653     (elpher-save-bookmarks bookmarks)))
1654
1655 (defun elpher-remove-address-bookmark (address)
1656   "Remove any bookmark to ADDRESS."
1657   (let ((url (elpher-address-to-url address)))
1658     (elpher-save-bookmarks
1659      (seq-filter (lambda (bookmark)
1660                    (not (equal (elpher-bookmark-url bookmark) url)))
1661                  (elpher-load-bookmarks)))))
1662
1663 ;;; Interactive procedures
1664 ;;
1665
1666 (defun elpher-next-link ()
1667   "Move point to the next link on the current page."
1668   (interactive)
1669   (forward-button 1))
1670
1671 (defun elpher-prev-link ()
1672   "Move point to the previous link on the current page."
1673   (interactive)
1674   (backward-button 1))
1675
1676 (defun elpher-follow-current-link ()
1677   "Open the link or url at point."
1678   (interactive)
1679   (push-button))
1680
1681 (defun elpher-go (host-or-url)
1682   "Go to a particular gopher site HOST-OR-URL.
1683 When run interactively HOST-OR-URL is read from the minibuffer."
1684   (interactive "sGopher or Gemini URL: ")
1685   (let* ((cleaned-host-or-url (string-trim host-or-url))
1686          (address (elpher-address-from-url cleaned-host-or-url))
1687          (page (elpher-make-page cleaned-host-or-url address)))
1688     (switch-to-buffer "*elpher*")
1689     (elpher-visit-page page)
1690     nil))
1691
1692 (defun elpher-go-current ()
1693   "Go to a particular site read from the minibuffer, initialized with the current URL."
1694   (interactive)
1695   (let ((address (elpher-page-address elpher-current-page)))
1696     (if (elpher-address-special-p address)
1697         (error "Command invalid for this page")
1698       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1699         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1700
1701 (defun elpher-redraw ()
1702   "Redraw current page."
1703   (interactive)
1704   (elpher-visit-page elpher-current-page))
1705
1706 (defun elpher-reload ()
1707   "Reload current page."
1708   (interactive)
1709   (elpher-reload-current-page))
1710
1711 (defun elpher-toggle-tls ()
1712   "Toggle TLS encryption mode for gopher."
1713   (interactive)
1714   (setq elpher-use-tls (not elpher-use-tls))
1715   (if elpher-use-tls
1716       (if (gnutls-available-p)
1717           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1718         (setq elpher-use-tls nil)
1719         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1720     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1721
1722 (defun elpher-view-raw ()
1723   "View raw server response for current page."
1724   (interactive)
1725   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1726       (error "This page was not generated by a server")
1727     (elpher-visit-page elpher-current-page
1728                        #'elpher-render-raw)))
1729
1730 (defun elpher-back ()
1731   "Go to previous site."
1732   (interactive)
1733   (elpher-visit-previous-page))
1734
1735 (defun elpher-back-to-start ()
1736   "Go all the way back to the start page."
1737   (interactive)
1738   (setq elpher-current-page nil)
1739   (setq elpher-history nil)
1740   (let ((start-page (elpher-make-page "Elpher Start Page"
1741                                       (elpher-make-special-address 'start))))
1742     (elpher-visit-page start-page)))
1743
1744 (defun elpher-download ()
1745   "Download the link at point."
1746   (interactive)
1747   (let ((button (button-at (point))))
1748     (if button
1749         (let ((page (button-get button 'elpher-page)))
1750           (if (elpher-address-special-p (elpher-page-address page))
1751               (error "Cannot download %s"
1752                      (elpher-page-display-string page))
1753             (elpher-visit-page (button-get button 'elpher-page)
1754                                #'elpher-render-download)))
1755       (error "No link selected"))))
1756
1757 (defun elpher-download-current ()
1758   "Download the current page."
1759   (interactive)
1760   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1761       (error "Cannot download %s"
1762              (elpher-page-display-string elpher-current-page))
1763     (elpher-visit-page (elpher-make-page
1764                         (elpher-page-display-string elpher-current-page)
1765                         (elpher-page-address elpher-current-page))
1766                        #'elpher-render-download
1767                        t)))
1768
1769 (defun elpher-build-link-map ()
1770   "Build alist mapping link names to destination pages in current buffer."
1771   (let ((link-map nil)
1772         (b (next-button (point-min) t)))
1773     (while b
1774       (push (cons (button-label b) b) link-map)
1775       (setq b (next-button (button-start b))))
1776     link-map))
1777
1778 (defun elpher-jump ()
1779   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1780   (interactive)
1781   (let* ((link-map (elpher-build-link-map)))
1782     (if link-map
1783         (let ((key (let ((completion-ignore-case t))
1784                      (completing-read "Directory item/link: "
1785                                       link-map nil t))))
1786           (if (and key (> (length key) 0))
1787               (let ((b (cdr (assoc key link-map))))
1788                 (goto-char (button-start b))
1789                 (button-activate b)))))))
1790
1791 (defun elpher-root-dir ()
1792   "Visit root of current server."
1793   (interactive)
1794   (let ((address (elpher-page-address elpher-current-page)))
1795     (if (not (elpher-address-special-p address))
1796         (if (or (member (url-filename address) '("/" ""))
1797                 (and (elpher-address-gopher-p address)
1798                      (= (length (elpher-gopher-address-selector address)) 0)))
1799             (error "Already at root directory of current server")
1800           (let ((address-copy (elpher-address-from-url
1801                                (elpher-address-to-url address))))
1802             (setf (url-filename address-copy) "")
1803             (elpher-go (elpher-address-to-url address-copy))))
1804       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1805
1806 (defun elpher-bookmarks-current-p ()
1807   "Return non-nil if current page is a bookmarks page."
1808   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1809          '(special bookmarks)))
1810
1811 (defun elpher-reload-bookmarks ()
1812   "Reload bookmarks if current page is a bookmarks page."
1813   (if (elpher-bookmarks-current-p)
1814       (elpher-reload-current-page)))
1815
1816 (defun elpher-bookmark-current ()
1817   "Bookmark the current page."
1818   (interactive)
1819   (let ((address (elpher-page-address elpher-current-page))
1820         (display-string (elpher-page-display-string elpher-current-page)))
1821     (if (not (elpher-address-special-p address))
1822         (let ((bookmark-display-string (read-string "Bookmark display string: "
1823                                                     display-string)))
1824           (elpher-add-address-bookmark address bookmark-display-string)
1825           (message "Bookmark added."))
1826       (error "Cannot bookmark %s" display-string))))
1827
1828 (defun elpher-bookmark-link ()
1829   "Bookmark the link at point."
1830   (interactive)
1831   (let ((button (button-at (point))))
1832     (if button
1833         (let* ((page (button-get button 'elpher-page))
1834                (address (elpher-page-address page))
1835                (display-string (elpher-page-display-string page)))
1836           (if (not (elpher-address-special-p address))
1837               (let ((bookmark-display-string (read-string "Bookmark display string: "
1838                                                           display-string)))
1839                 (elpher-add-address-bookmark address bookmark-display-string)
1840                 (elpher-reload-bookmarks)
1841                 (message "Bookmark added."))
1842             (error "Cannot bookmark %s" display-string)))
1843       (error "No link selected"))))
1844
1845 (defun elpher-unbookmark-current ()
1846   "Remove bookmark for the current page."
1847   (interactive)
1848   (let ((address (elpher-page-address elpher-current-page)))
1849     (when (and (not (elpher-address-special-p address))
1850                (y-or-n-p "Really remove bookmark for the current page? "))
1851       (elpher-remove-address-bookmark address)
1852       (message "Bookmark removed."))))
1853
1854 (defun elpher-unbookmark-link ()
1855   "Remove bookmark for the link at point."
1856   (interactive)
1857   (let ((button (button-at (point))))
1858     (if button
1859         (when (y-or-n-p "Really remove bookmark for this link? ")
1860           (let ((page (button-get button 'elpher-page)))
1861             (elpher-remove-address-bookmark (elpher-page-address page))
1862             (elpher-reload-bookmarks)
1863             (message "Bookmark removed.")))
1864       (error "No link selected"))))
1865
1866 (defun elpher-bookmarks ()
1867   "Visit bookmarks page."
1868   (interactive)
1869   (switch-to-buffer "*elpher*")
1870   (elpher-visit-page
1871    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1872
1873 (defun elpher-info-page (page)
1874   "Display information on PAGE."
1875   (let ((display-string (elpher-page-display-string page))
1876         (address (elpher-page-address page)))
1877     (if (elpher-address-special-p address)
1878         (message "Special page: %s" display-string)
1879       (message "%s" (elpher-address-to-url address)))))
1880
1881 (defun elpher-info-link ()
1882   "Display information on page corresponding to link at point."
1883   (interactive)
1884   (let ((button (button-at (point))))
1885     (if button
1886         (elpher-info-page (button-get button 'elpher-page))
1887       (error "No item selected"))))
1888
1889 (defun elpher-info-current ()
1890   "Display information on current page."
1891   (interactive)
1892   (elpher-info-page elpher-current-page))
1893
1894 (defun elpher-copy-page-url (page)
1895   "Copy URL representation of address of PAGE to `kill-ring'."
1896   (let ((address (elpher-page-address page)))
1897     (if (elpher-address-special-p address)
1898         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1899       (let ((url (elpher-address-to-url address)))
1900         (message "Copied \"%s\" to kill-ring/clipboard." url)
1901         (kill-new url)))))
1902
1903 (defun elpher-copy-link-url ()
1904   "Copy URL of item at point to `kill-ring'."
1905   (interactive)
1906   (let ((button (button-at (point))))
1907     (if button
1908         (elpher-copy-page-url (button-get button 'elpher-page))
1909       (error "No item selected"))))
1910
1911 (defun elpher-copy-current-url ()
1912   "Copy URL of current page to `kill-ring'."
1913   (interactive)
1914   (elpher-copy-page-url elpher-current-page))
1915
1916 (defun elpher-set-gopher-coding-system ()
1917   "Specify an explicit character coding system for gopher selectors."
1918   (interactive)
1919   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1920     (setq elpher-user-coding-system system)
1921     (if system
1922         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1923       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1924
1925
1926 ;;; Mode and keymap
1927 ;;
1928
1929 (defvar elpher-mode-map
1930   (let ((map (make-sparse-keymap)))
1931     (define-key map (kbd "TAB") 'elpher-next-link)
1932     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1933     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1934     (define-key map (kbd "u") 'elpher-back)
1935     (define-key map (kbd "U") 'elpher-back-to-start)
1936     (define-key map [mouse-3] 'elpher-back)
1937     (define-key map (kbd "O") 'elpher-root-dir)
1938     (define-key map (kbd "g") 'elpher-go)
1939     (define-key map (kbd "o") 'elpher-go-current)
1940     (define-key map (kbd "r") 'elpher-redraw)
1941     (define-key map (kbd "R") 'elpher-reload)
1942     (define-key map (kbd "T") 'elpher-toggle-tls)
1943     (define-key map (kbd ".") 'elpher-view-raw)
1944     (define-key map (kbd "d") 'elpher-download)
1945     (define-key map (kbd "D") 'elpher-download-current)
1946     (define-key map (kbd "m") 'elpher-jump)
1947     (define-key map (kbd "i") 'elpher-info-link)
1948     (define-key map (kbd "I") 'elpher-info-current)
1949     (define-key map (kbd "c") 'elpher-copy-link-url)
1950     (define-key map (kbd "C") 'elpher-copy-current-url)
1951     (define-key map (kbd "a") 'elpher-bookmark-link)
1952     (define-key map (kbd "A") 'elpher-bookmark-current)
1953     (define-key map (kbd "x") 'elpher-unbookmark-link)
1954     (define-key map (kbd "X") 'elpher-unbookmark-current)
1955     (define-key map (kbd "B") 'elpher-bookmarks)
1956     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1957     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1958     (when (fboundp 'evil-define-key*)
1959       (evil-define-key* 'motion map
1960         (kbd "TAB") 'elpher-next-link
1961         (kbd "C-") 'elpher-follow-current-link
1962         (kbd "C-t") 'elpher-back
1963         (kbd "u") 'elpher-back
1964         (kbd "U") 'elpher-back-to-start
1965         [mouse-3] 'elpher-back
1966         (kbd "g") 'elpher-go
1967         (kbd "o") 'elpher-go-current
1968         (kbd "r") 'elpher-redraw
1969         (kbd "R") 'elpher-reload
1970         (kbd "T") 'elpher-toggle-tls
1971         (kbd ".") 'elpher-view-raw
1972         (kbd "d") 'elpher-download
1973         (kbd "D") 'elpher-download-current
1974         (kbd "m") 'elpher-jump
1975         (kbd "i") 'elpher-info-link
1976         (kbd "I") 'elpher-info-current
1977         (kbd "c") 'elpher-copy-link-url
1978         (kbd "C") 'elpher-copy-current-url
1979         (kbd "a") 'elpher-bookmark-link
1980         (kbd "A") 'elpher-bookmark-current
1981         (kbd "x") 'elpher-unbookmark-link
1982         (kbd "X") 'elpher-unbookmark-current
1983         (kbd "B") 'elpher-bookmarks
1984         (kbd "S") 'elpher-set-gopher-coding-system
1985         (kbd "F") 'elpher-forget-current-certificate))
1986     map)
1987   "Keymap for gopher client.")
1988
1989 (define-derived-mode elpher-mode special-mode "elpher"
1990   "Major mode for elpher, an elisp gopher client.
1991
1992 This mode is automatically enabled by the interactive
1993 functions which initialize the gopher client, namely
1994 `elpher', `elpher-go' and `elpher-bookmarks'.")
1995
1996 (when (fboundp 'evil-set-initial-state)
1997   (evil-set-initial-state 'elpher-mode 'motion))
1998
1999
2000 ;;; Main start procedure
2001 ;;
2002
2003 ;;;###autoload
2004 (defun elpher ()
2005   "Start elpher with default landing page."
2006   (interactive)
2007   (if (get-buffer "*elpher*")
2008       (switch-to-buffer "*elpher*")
2009     (switch-to-buffer "*elpher*")
2010     (setq elpher-current-page nil)
2011     (setq elpher-history nil)
2012     (let ((start-page (elpher-make-page "Elpher Start Page"
2013                                         (elpher-make-special-address 'start))))
2014       (elpher-visit-page start-page)))
2015   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
2016
2017 ;;; elpher.el ends here