elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.3.2
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.3.2"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     (file elpher-get-file-page nil "~" elpher-gemini)
  98     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
  99     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 100     ((about history) elpher-get-history-page nil "E" elpher-index)
 101     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 102   "Association list from types to getters, renderers, margin codes and index faces.")
 103
 104
 105 ;;; Declarations to avoid compiler warnings.
 106 ;;
 107
 108 (eval-when-compile
 109   (declare-function ansi-color-filter-apply "ansi-color")
 110   (declare-function ansi-color-apply "ansi-color")
 111   (declare-function bookmark-store "bookmark")
 112   (declare-function org-link-store-props "ol")
 113   (declare-function org-link-set-parameters "ol")
 114   (defvar ansi-color-context)
 115   (defvar xterm-color--current-fg)
 116   (defvar xterm-color--current-bg)
 117   (defvar bookmark-make-record-function)
 118   (defvar mu4e~view-beginning-of-url-regexp)
 119   (defvar eww-use-browse-url)
 120   (defvar thing-at-point-uri-schemes))
 121
 122
 123 ;;; Customization group
 124 ;;
 125
 126 (defgroup elpher nil
 127   "A gopher and gemini client."
 128   :group 'applications)
 129
 130 ;; General appearance and customizations
 131
 132 (defcustom elpher-open-urls-with-eww nil
 133   "If non-nil, open URL selectors using eww.
 134 Otherwise, use the system browser via the `browse-url' function."
 135   :type '(boolean))
 136
 137 (defcustom elpher-use-header t
 138   "If non-nil, display current page information in buffer header."
 139   :type '(boolean))
 140
 141 (defcustom elpher-auto-disengage-TLS nil
 142   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 143 While enabling this may seem convenient, it is also potentially
 144 dangerous as it allows switching from an encrypted channel back to
 145 plain text without user input."
 146   :type '(boolean))
 147
 148 (defcustom elpher-connection-timeout 5
 149   "Specifies the number of seconds to wait for a network connection to time out."
 150   :type '(integer))
 151
 152 (defcustom elpher-filter-ansi-from-text nil
 153   "If non-nil, filter ANSI escape sequences from text.
 154 The default behaviour is to use the ansi-color package (or xterm-color if it is
 155 available) to interpret these sequences."
 156   :type '(boolean))
 157
 158 (defcustom elpher-certificate-directory
 159   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 160   "Specify the name of the directory where client certificates will be stored.
 161 These certificates may be used for establishing authenticated TLS connections."
 162   :type '(directory))
 163
 164 (defcustom elpher-openssl-command "openssl"
 165   "The command used to launch openssl when generating TLS client certificates."
 166   :type '(file))
 167
 168 (defcustom elpher-default-url-type "gopher"
 169   "Default URL type (i.e. scheme) to assume if not explicitly given."
 170   :type '(choice (const "gopher")
 171                  (const "gemini")))
 172
 173 (defcustom elpher-gemini-TLS-cert-checks nil
 174   "If non-nil, verify gemini server TLS certs using the default security level.
 175 Otherwise, certificate verification is disabled.
 176
 177 This defaults to off because it is standard practice for Gemini servers
 178 to use self-signed certificates, meaning that most servers provide what
 179 EMACS considers to be an invalid certificate."
 180   :type '(boolean))
 181
 182 (defcustom elpher-gemini-max-fill-width 80
 183   "Specify the maximum default width (in columns) of text/gemini documents.
 184 The actual width used is the minimum of this value and the window width at
 185 the time when the text is rendered."
 186   :type '(integer))
 187
 188 (defcustom elpher-gemini-link-string "→ "
 189   "Specify the string used to indicate links when rendering gemini maps.
 190 May be empty."
 191   :type '(string))
 192
 193 (defcustom elpher-gemini-bullet-string "•"
 194   "Specify the string used for bullets when rendering gemini maps."
 195   :type '(string))
 196
 197 (defcustom elpher-ipv4-always nil
 198   "If non-nil, elpher will always use IPv4 to establish network connections.
 199 This can be useful when browsing from a computer that supports IPv6, because
 200 some servers which do not support IPv6 can take a long time to time-out."
 201   :type '(boolean))
 202
 203 (defcustom elpher-socks-always nil
 204   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 205 Otherwise, the SOCKS proxy is only used for connections to onion services."
 206   :type '(boolean))
 207
 208 (defcustom elpher-use-emacs-bookmark-menu nil
 209   "If non-nil, elpher will only use the native Emacs bookmark menu.
 210 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 211 page within which all of the standard elpher keybindings are active."
 212   :type '(boolean))
 213
 214 (defcustom elpher-start-page-url "about:welcome"
 215   "Specify the page displayed initially by elpher.
 216 The default welcome screen is \"about:welcome\", while the bookmarks list
 217 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 218
 219 Beware that using \"about:bookmarks\" as a start page in combination with
 220 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 221 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 222 the start page."
 223   :type '(string))
 224
 225 ;; Face customizations
 226
 227 (defgroup elpher-faces nil
 228   "Elpher face customizations."
 229   :group 'elpher)
 230
 231 (defface elpher-index
 232   '((t :inherit font-lock-keyword-face))
 233   "Face used for directory type directory records.")
 234
 235 (defface elpher-text
 236   '((t :inherit bold))
 237   "Face used for text type directory records.")
 238
 239 (defface elpher-info
 240   '((t :inherit default))
 241   "Face used for info type directory records.")
 242
 243 (defface elpher-image
 244   '((t :inherit font-lock-string-face))
 245   "Face used for image type directory records.")
 246
 247 (defface elpher-search
 248   '((t :inherit warning))
 249   "Face used for search type directory records.")
 250
 251 (defface elpher-html
 252   '((t :inherit font-lock-comment-face))
 253   "Face used for html type directory records.")
 254
 255 (defface elpher-gemini
 256   '((t :inherit font-lock-constant-face))
 257   "Face used for Gemini type directory records.")
 258
 259 (defface elpher-other-url
 260   '((t :inherit font-lock-comment-face))
 261   "Face used for other URL type links records.")
 262
 263 (defface elpher-telnet
 264   '((t :inherit font-lock-function-name-face))
 265   "Face used for telnet type directory records.")
 266
 267 (defface elpher-binary
 268   '((t :inherit font-lock-doc-face))
 269   "Face used for binary type directory records.")
 270
 271 (defface elpher-unknown
 272   '((t :inherit error))
 273   "Face used for directory records with unknown/unsupported types.")
 274
 275 (defface elpher-margin-key
 276   '((t :inherit bold))
 277   "Face used for directory margin key.")
 278
 279 (defface elpher-margin-brackets
 280   '((t :inherit shadow))
 281   "Face used for brackets around directory margin key.")
 282
 283 (defface elpher-gemini-heading1
 284   '((t :inherit bold :height 1.8))
 285   "Face used for gemini heading level 1.")
 286
 287 (defface elpher-gemini-heading2
 288   '((t :inherit bold :height 1.5))
 289   "Face used for gemini heading level 2.")
 290
 291 (defface elpher-gemini-heading3
 292   '((t :inherit bold :height 1.2))
 293   "Face used for gemini heading level 3.")
 294
 295 (defface elpher-gemini-preformatted
 296   '((t :inherit fixed-pitch))
 297   "Face used for pre-formatted gemini text blocks.")
 298
 299 (defface elpher-gemini-quoted
 300   '((t :inherit font-lock-doc-face))
 301   "Face used for gemini quoted texts.")
 302
 303 ;;; Model
 304 ;;
 305
 306 ;; Address
 307
 308 ;; An elpher "address" object is either a url object or a symbol.
 309 ;; Addresses with the "about" type, corresponding to pages generated
 310 ;; dynamically for and by elpher.  All others represent pages which
 311 ;; rely on content retrieved over the network.
 312
 313 (defun elpher-address-from-url (url-string &optional default-scheme)
 314   "Create a ADDRESS object corresponding to the given URL-STRING.
 315 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 316 is not explicitly given."
 317   (let ((data (match-data))) ; Prevent parsing clobbering match data
 318     (unwind-protect
 319         (let ((url (url-generic-parse-url url-string)))
 320           (unless (and (not (url-fullness url)) (url-type url))
 321             (unless (url-type url)
 322               (setf (url-type url) default-scheme))
 323             (unless (url-host url)
 324               (let ((p (split-string (url-filename url) "/" nil nil)))
 325                 (setf (url-host url) (car p))
 326                 (setf (url-filename url)
 327                       (if (cdr p)
 328                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 329                         ""))))
 330             (when (not (string-empty-p (url-host url)))
 331               (setf (url-fullness url) t)
 332               (setf (url-host url) (puny-encode-domain (url-host url))))
 333             (when (or (equal "gopher" (url-type url))
 334                       (equal "gophers" (url-type url)))
 335               ;; Gopher defaults
 336               (when (or (equal (url-filename url) "")
 337                         (equal (url-filename url) "/"))
 338                 (setf (url-filename url) "/1")))
 339             (when (equal "gemini" (url-type url))
 340               ;; Gemini defaults
 341               (if (equal (url-filename url) "")
 342                   (setf (url-filename url) "/"))))
 343           (elpher-remove-redundant-ports url))
 344       (set-match-data data))))
 345
 346 (defun elpher-remove-redundant-ports (address)
 347   "Remove redundant port specifiers from ADDRESS.
 348 Here 'redundant' means that the specified port matches the default
 349 for that protocol, eg 70 for gopher."
 350   (if (and (not (elpher-address-about-p address))
 351            (eq (url-portspec address) ; (url-port) is too slow!
 352                (pcase (url-type address)
 353                  ("gemini" 1965)
 354                  ((or "gopher" "gophers") 70)
 355                  ("finger" 79)
 356                  (_ -1))))
 357       (setf (url-portspec address) nil))
 358   address)
 359
 360 (defun elpher-make-gopher-address (type selector host port &optional tls)
 361   "Create an ADDRESS object using gopher directory record attributes.
 362 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 363 If the optional attribute TLS is non-nil, the address will be marked as
 364 requiring gopher-over-TLS."
 365   (cond
 366    ((equal type ?i) nil)
 367    ((and (equal type ?h)
 368          (string-prefix-p "URL:" selector))
 369     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 370    ((equal type ?8)
 371     (elpher-address-from-url
 372      (concat "telnet"
 373              "://" host
 374              ":" (number-to-string port))))
 375    (t
 376     (elpher-address-from-url
 377      (concat "gopher" (if tls "s" "")
 378              "://" host
 379              ":" (number-to-string port)
 380              "/" (string type)
 381              selector)))))
 382
 383 (defun elpher-make-about-address (type)
 384   "Create an ADDRESS object corresponding to the given about address TYPE."
 385   (elpher-address-from-url (concat "about:" (symbol-name type))))
 386
 387 (defun elpher-address-to-url (address)
 388   "Get string representation of ADDRESS."
 389   (url-encode-url (url-recreate-url address)))
 390
 391 (defun elpher-address-type (address)
 392   "Retrieve type of ADDRESS object.
 393 This is used to determine how to retrieve and render the document the
 394 address refers to, via the table `elpher-type-map'."
 395   (pcase (url-type address)
 396     ("about"
 397      (list 'about (intern (url-filename address))))
 398     ((or "gopher" "gophers")
 399      (list 'gopher
 400            (if (member (url-filename address) '("" "/"))
 401                ?1
 402              (string-to-char (substring (url-filename address) 1)))))
 403     ("gemini" 'gemini)
 404     ("telnet" 'telnet)
 405     ("finger" 'finger)
 406     ("file" 'file)
 407     (_ 'other-url)))
 408
 409 (defun elpher-address-about-p (address)
 410   "Return non-nil if ADDRESS is an  about address."
 411   (pcase (elpher-address-type address) (`(about ,_) t)))
 412
 413 (defun elpher-address-gopher-p (address)
 414   "Return non-nill if ADDRESS object is a gopher address."
 415   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 416
 417 (defun elpher-address-protocol (address)
 418   "Retrieve the transport protocol for ADDRESS."
 419   (url-type address))
 420
 421 (defun elpher-address-filename (address)
 422   "Retrieve the filename component of ADDRESS.
 423 For gopher addresses this is a combination of the selector type and selector."
 424   (url-unhex-string (url-filename address)))
 425
 426 (defun elpher-address-host (address)
 427   "Retrieve host from ADDRESS object."
 428   (let ((host-pre (url-host address)))
 429     ;; The following strips out square brackets which sometimes enclose IPv6
 430     ;; addresses.  Doing this here rather than at the parsing stage may seem
 431     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 432     ;; and reconstruction.  It's also more efficient, as this method is not
 433     ;; called during page rendering.
 434     (if (and (> (length host-pre) 2)
 435              (eq (elt host-pre 0) ?\[)
 436              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 437         (substring host-pre 1 (- (length host-pre) 1))
 438       host-pre)))
 439
 440 (defun elpher-address-user (address)
 441   "Retrieve user from ADDRESS object."
 442   (url-user address))
 443
 444 (defun elpher-address-port (address)
 445   "Retrieve port from ADDRESS object.
 446 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 447   (url-port address))
 448
 449 (defun elpher-gopher-address-selector (address)
 450   "Retrieve gopher selector from ADDRESS object."
 451   (if (member (url-filename address) '("" "/"))
 452       ""
 453     (url-unhex-string (substring (url-filename address) 2))))
 454
 455
 456 ;; Cache
 457
 458 (defvar elpher-content-cache (make-hash-table :test 'equal))
 459 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 460
 461 (defun elpher-get-cached-content (address)
 462   "Retrieve the cached content for ADDRESS, or nil if none exists."
 463   (gethash address elpher-content-cache))
 464
 465 (defun elpher-cache-content (address content)
 466   "Set the content cache for ADDRESS to CONTENT."
 467   (puthash address content elpher-content-cache))
 468
 469 (defun elpher-get-cached-pos (address)
 470   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 471   (gethash address elpher-pos-cache))
 472
 473 (defun elpher-cache-pos (address pos)
 474   "Set the cursor position cache for ADDRESS to POS."
 475   (puthash address pos elpher-pos-cache))
 476
 477
 478 ;; Page
 479
 480 (defun elpher-make-page (display-string address)
 481   "Create a page with DISPLAY-STRING and ADDRESS."
 482   (list display-string address))
 483
 484 (defun elpher-make-start-page ()
 485   "Create the start page."
 486   (elpher-make-page "Start Page"
 487                     (elpher-address-from-url elpher-start-page-url)))
 488
 489 (defun elpher-page-display-string (page)
 490   "Retrieve the display string corresponding to PAGE."
 491   (elt page 0))
 492
 493 (defun elpher-page-address (page)
 494   "Retrieve the address corresponding to PAGE."
 495   (elt page 1))
 496
 497 (defun elpher-page-set-address (page new-address)
 498   "Set the address corresponding to PAGE to NEW-ADDRESS."
 499   (setcar (cdr page) new-address))
 500
 501 (defun elpher-page-from-url (url &optional default-scheme)
 502   "Create a page with address and display string defined by URL.
 503 The URL is unhexed prior to its use as a display string to improve
 504 readability.
 505
 506 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 507 in the instance that URL itself doesn't specify one."
 508   (let ((address (elpher-address-from-url url default-scheme)))
 509     (elpher-make-page (elpher-address-to-iri address) address)))
 510
 511 (defun elpher-address-to-iri (address)
 512   "Return an IRI for ADDRESS.
 513 Decode percent-escapes and handle punycode in the domain name.
 514 Drop the password, if any."
 515   (let ((data (match-data)) ; Prevent parsing clobbering match data
 516         (host (url-host address))
 517         (pass (url-password address)))
 518     (unwind-protect
 519         (let* ((host (url-host address))
 520                (pass (url-password address)))
 521           (when host
 522             (setf (url-host address) (puny-decode-domain host)))
 523           (when pass                             ; RFC 3986 says we should not render
 524             (setf (url-password address) nil)) ; the password as clear text
 525           (elpher-decode (url-unhex-string (url-recreate-url address))))
 526       (setf (url-host address) host)
 527       (setf (url-password address) pass)
 528       (set-match-data data))))
 529
 530 (defvar elpher-current-page nil
 531   "The current page for this Elpher buffer.")
 532
 533 (defvar elpher-history nil
 534   "The local history stack for this Elpher buffer.
 535 This variable is used by `elpher-back' and
 536 `elpher-show-history'.")
 537
 538 (defvar elpher-visited-pages nil
 539   "The global history for all Elpher buffers.
 540 This variable is used by `elpher-show-visited-pages'.")
 541
 542 (defun elpher-visit-page (page &optional renderer no-history)
 543   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 544 Additionally, push PAGE onto the history stack and the list of
 545 previously-visited pages,unless NO-HISTORY is non-nil."
 546   (elpher-save-pos)
 547   (elpher-process-cleanup)
 548   (unless no-history
 549     (unless (or (not elpher-current-page)
 550                  (equal (elpher-page-address elpher-current-page)
 551                         (elpher-page-address page)))
 552       (push elpher-current-page elpher-history)
 553       (unless (or (elpher-address-about-p (elpher-page-address page))
 554                   (and elpher-visited-pages
 555                        (equal page (car elpher-visited-pages))))
 556         (push page elpher-visited-pages))))
 557   (setq-local elpher-current-page page)
 558   (let* ((address (elpher-page-address page))
 559          (type (elpher-address-type address))
 560          (type-record (cdr (assoc type elpher-type-map))))
 561     (if type-record
 562         (funcall (car type-record)
 563                  (if renderer
 564                      renderer
 565                    (cadr type-record)))
 566       (elpher-visit-previous-page)
 567       (pcase type
 568         (`(gopher ,type-char)
 569          (error "Unsupported gopher selector type '%c' for '%s'"
 570                 type-char (elpher-address-to-url address)))
 571         (other
 572          (error "Unsupported address type '%S' for '%s'"
 573                 other (elpher-address-to-url address)))))))
 574
 575 (defun elpher-visit-previous-page ()
 576   "Visit the previous page in the history."
 577   (if elpher-history
 578       (elpher-visit-page (pop elpher-history) nil t)
 579     (error "No previous page")))
 580
 581 (defun elpher-reload-current-page ()
 582   "Reload the current page, discarding any existing cached content."
 583   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 584   (elpher-visit-page elpher-current-page))
 585
 586 (defun elpher-save-pos ()
 587   "Save the current position of point to the current page."
 588   (when elpher-current-page
 589     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 590
 591 (defun elpher-restore-pos ()
 592   "Restore the position of point to that cached in the current page."
 593   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 594     (if pos
 595         (goto-char pos)
 596       (goto-char (point-min)))))
 597
 598 (defun elpher-get-default-url-scheme ()
 599   "Suggest a default URL scheme to use for visiting addresses based on the current page."
 600   (if elpher-current-page
 601       (let* ((address (elpher-page-address elpher-current-page))
 602              (current-type (elpher-address-type address)))
 603         (pcase current-type
 604           ((or (and 'file (guard (not elpher-history)))
 605                `(about ,_))
 606            elpher-default-url-type)
 607           (`(about ,_)
 608            elpher-default-url-type)
 609           (_
 610            (url-type address))))
 611       elpher-default-url-type))
 612
 613
 614 ;;; Buffer preparation
 615 ;;
 616
 617 (defvar elpher-buffer-name "*elpher*"
 618   "The default name of the Elpher buffer.")
 619
 620 (defun elpher-update-header ()
 621   "If `elpher-use-header' is true, display current page info in window header."
 622   (if (and elpher-use-header elpher-current-page)
 623       (let* ((display-string (elpher-page-display-string elpher-current-page))
 624              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 625              (address (elpher-page-address elpher-current-page))
 626              (tls-string (if (and (not (elpher-address-about-p address))
 627                                   (member (elpher-address-protocol address)
 628                                           '("gophers" "gemini")))
 629                              " [TLS encryption]"
 630                            ""))
 631              (header (concat sanitized-display-string
 632                              (propertize tls-string 'face 'bold))))
 633         (setq header-line-format header))))
 634
 635 (defmacro elpher-with-clean-buffer (&rest args)
 636   "Evaluate ARGS with a clean *elpher* buffer as current."
 637   (declare (debug (body))) ;; Allow edebug to step through body
 638   `(with-current-buffer elpher-buffer-name
 639      (unless (eq major-mode 'elpher-mode)
 640        ;; avoid resetting buffer-local variables
 641        (elpher-mode))
 642      (let ((inhibit-read-only t)
 643            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 644        (setq-local xterm-color--current-fg nil)
 645        (setq-local xterm-color--current-bg nil)
 646        (setq-local network-security-level
 647                    (default-value 'network-security-level))
 648        (erase-buffer)
 649        (elpher-update-header)
 650        ,@args)))
 651
 652 (defun elpher-buffer-message (string &optional line)
 653   "Replace first line in elpher buffer with STRING.
 654 If LINE is non-nil, replace that line instead."
 655   (with-current-buffer elpher-buffer-name
 656     (let ((inhibit-read-only t))
 657       (goto-char (point-min))
 658       (if line
 659           (forward-line line))
 660       (let ((data (match-data)))
 661         (unwind-protect
 662             (progn
 663               (re-search-forward "^.*$")
 664               (replace-match string))
 665           (set-match-data data))))))
 666
 667
 668 ;;; Text Processing
 669 ;;
 670
 671 (defvar elpher-user-coding-system nil
 672   "User-specified coding system to use for decoding text responses.")
 673
 674 (defun elpher-decode (string)
 675   "Decode STRING using autodetected or user-specified coding system."
 676   (decode-coding-string string
 677                         (if elpher-user-coding-system
 678                             elpher-user-coding-system
 679                           (detect-coding-string string t))))
 680
 681 (defun elpher-preprocess-text-response (string)
 682   "Preprocess text selector response contained in STRING.
 683 This involes decoding the character representation, and clearing
 684 away CRs and any terminating period."
 685   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 686                                            (replace-regexp-in-string "\r" "" string))))
 687
 688 ;;; Buttonify urls
 689
 690 (defconst elpher-url-regex
 691   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 692   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 693
 694 (defun elpher-buttonify-urls (string)
 695   "Turn substrings which look like urls in STRING into clickable buttons."
 696   (with-temp-buffer
 697     (insert string)
 698     (goto-char (point-min))
 699     (while (re-search-forward elpher-url-regex nil t)
 700       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 701         (make-text-button (match-beginning 0)
 702                           (match-end 0)
 703                           'elpher-page  page
 704                           'action #'elpher-click-link
 705                           'follow-link t
 706                           'help-echo #'elpher--page-button-help
 707                           'face 'button)))
 708     (buffer-string)))
 709
 710 ;;; ANSI colors or XTerm colors (application and filtering)
 711
 712 (or (require 'xterm-color nil t)
 713     (require 'ansi-color))
 714
 715 (defalias 'elpher-color-filter-apply
 716   (if (fboundp 'xterm-color-filter)
 717       (lambda (s)
 718         (let ((_xterm-color-render nil))
 719           (xterm-color-filter s)))
 720     #'ansi-color-filter-apply)
 721   "A function to filter out ANSI escape sequences.")
 722
 723 (defalias 'elpher-color-apply
 724   (if (fboundp 'xterm-color-filter)
 725       #'xterm-color-filter
 726     #'ansi-color-apply)
 727   "A function to apply ANSI escape sequences.")
 728
 729 ;;; Processing text for display
 730
 731 (defun elpher-process-text-for-display (string)
 732   "Perform any desired processing of STRING prior to display as text.
 733 Currently includes buttonifying URLs and processing ANSI escape codes."
 734   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 735                              (elpher-color-filter-apply string)
 736                            (elpher-color-apply string))))
 737
 738
 739 ;;; Network error reporting
 740 ;;
 741
 742 (defun elpher-network-error (address error)
 743   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 744 ERROR can be either an error object or a string."
 745   (elpher-with-clean-buffer
 746    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 747            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 748            (if (stringp error) error (error-message-string error)) "\n"
 749            (propertize "\n----------------\n\n" 'face 'error)
 750            "Press 'u' to return to the previous page.")))
 751
 752
 753 ;;; General network communication
 754 ;;
 755
 756 (defvar elpher-network-timer nil
 757   "Timer used for network connections.")
 758
 759 (defvar elpher-use-tls nil
 760   "If non-nil, use TLS to communicate with gopher servers.")
 761
 762 (defvar elpher-client-certificate nil
 763   "If non-nil, contains client certificate details to use for TLS connections.")
 764
 765 (defun elpher-process-cleanup ()
 766   "Immediately shut down any extant elpher process and timers."
 767   (let ((p (get-process "elpher-process")))
 768     (if p (delete-process p)))
 769   (if (timerp elpher-network-timer)
 770       (cancel-timer elpher-network-timer)))
 771
 772 (defun elpher-make-network-timer (thunk)
 773   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 774 This is just a wraper around `run-at-time' which additionally sets the
 775 buffer-local variable `elpher-network-timer' to allow
 776 `elpher-process-cleanup' to also clear the timer."
 777   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 778     (setq-local elpher-network-timer timer)
 779     timer))
 780
 781 (defun elpher-get-host-response (address default-port query-string response-processor
 782                                          &optional use-tls force-ipv4)
 783   "Generic function for retrieving data from ADDRESS.
 784
 785 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 786 QUERY-STRING is a string sent to the host specified by ADDRESS to
 787 illicet a response.  This response is passed as an argument to the
 788 function RESPONSE-PROCESSOR.
 789
 790 If non-nil, USE-TLS specifies that the connection is to be made over
 791 TLS.  If set to gemini, the certificate verification will be disabled
 792 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 793
 794 If non-nil, FORCE-IPV4 causes the network connection to be made over
 795 ipv4 only.  (The default behaviour when this is not set depends on
 796 the host operating system and the local network capabilities.)"
 797   (if (and use-tls (not (gnutls-available-p)))
 798       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 799     (unless (< (elpher-address-port address) 65536)
 800       (error "Cannot establish network connection: port number > 65536"))
 801     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 802       (setq-local network-security-level 'low)
 803       (setq-local gnutls-verify-error nil))
 804     (condition-case nil
 805         (let* ((kill-buffer-query-functions nil)
 806                (port (elpher-address-port address))
 807                (host (elpher-address-host address))
 808                (service (if (> port 0) port default-port))
 809                (response-string-parts nil)
 810                (bytes-received 0)
 811                (hkbytes-received 0)
 812                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 813                (gnutls-params (list :type 'gnutls-x509pki
 814                                     :hostname host
 815                                     :keylist
 816                                     (elpher-get-current-keylist address)))
 817                (timer (elpher-make-network-timer
 818                                    (lambda ()
 819                                      (elpher-process-cleanup)
 820                                      (cond
 821                                         ; Try again with IPv4
 822                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 823                                        (message "Connection timed out.  Retrying with IPv4.")
 824                                        (elpher-get-host-response address default-port
 825                                                                  query-string
 826                                                                  response-processor
 827                                                                  use-tls t))
 828                                       ((and use-tls
 829                                             (not (eq use-tls 'gemini))
 830                                             (or elpher-auto-disengage-TLS
 831                                                 (y-or-n-p
 832                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 833                                        (setq elpher-use-tls nil)
 834                                        (elpher-get-host-response address default-port
 835                                                                  query-string
 836                                                                  response-processor
 837                                                                  nil force-ipv4))
 838                                       (t
 839                                        (elpher-network-error address "Connection time-out."))))))
 840                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 841                        (make-network-process :name "elpher-process"
 842                                              :host host
 843                                              :family (and (or force-ipv4
 844                                                               elpher-ipv4-always)
 845                                                           'ipv4)
 846                                              :service service
 847                                              :buffer nil
 848                                              :nowait t
 849                                              :tls-parameters
 850                                              (and use-tls
 851                                                   (cons 'gnutls-x509pki
 852                                                         (apply #'gnutls-boot-parameters
 853                                                                gnutls-params)))))))
 854           (setq elpher-network-timer timer)
 855           (set-process-coding-system proc 'binary 'binary)
 856           (set-process-query-on-exit-flag proc nil)
 857           (elpher-buffer-message (concat "Connecting to " host "..."
 858                                          " (press 'u' to abort)"))
 859           (set-process-filter proc
 860                               (lambda (_proc string)
 861                                 (when timer
 862                                   (cancel-timer timer)
 863                                   (setq timer nil))
 864                                 (setq bytes-received (+ bytes-received (length string)))
 865                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 866                                   (when (> new-hkbytes-received hkbytes-received)
 867                                     (setq hkbytes-received new-hkbytes-received)
 868                                     (elpher-buffer-message
 869                                      (concat "("
 870                                              (number-to-string (/ hkbytes-received 10.0))
 871                                              " MB read)")
 872                                      1)))
 873                                 (setq response-string-parts
 874                                       (cons string response-string-parts))))
 875           (set-process-sentinel proc
 876                                 (lambda (proc event)
 877                                   (when timer
 878                                     (cancel-timer timer))
 879                                   (condition-case the-error
 880                                       (cond
 881                                        ((string-prefix-p "open" event)    ; request URL
 882                                         (elpher-buffer-message
 883                                          (concat "Connected to " host ". Receiving data..."
 884                                                  " (press 'u' to abort)"))
 885                                         (let ((inhibit-eol-conversion t))
 886                                           (process-send-string proc query-string)))
 887                                        ((string-prefix-p "deleted" event)) ; do nothing
 888                                        ((and (not response-string-parts)
 889                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 890                                         ; Try again with IPv4
 891                                         (message "Connection failed. Retrying with IPv4.")
 892                                         (elpher-get-host-response address default-port
 893                                                                   query-string
 894                                                                   response-processor
 895                                                                   use-tls t))
 896                                        (response-string-parts
 897                                         (elpher-with-clean-buffer
 898                                          (insert "Data received.  Rendering..."))
 899                                         (funcall response-processor
 900                                                  (apply #'concat (reverse response-string-parts)))
 901                                         (elpher-restore-pos))
 902                                        (t
 903                                         (error "No response from server")))
 904                                     (error
 905                                      (elpher-network-error address the-error)))))
 906           (when socks
 907             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 908             (funcall (process-sentinel proc) proc "open\n")))
 909       (error
 910        (elpher-process-cleanup)
 911        (error "Error initiating connection to server")))))
 912
 913
 914 ;;; Client-side TLS Certificate Management
 915 ;;
 916
 917 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 918   "Generate a key and a self-signed client TLS certificate using openssl.
 919
 920 The Common Name field of the certificate is set to COMMON-NAME.  The
 921 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 922 the key and certificate files to write.
 923
 924 If TEMPORARY is non-nil, the certificate will be given an exporation
 925 period of one day, and the key and certificate files will be deleted
 926 when the certificate is no longer needed for the current session.
 927
 928 Otherwise, the certificate will be given a 100 year expiration period
 929 and the files will not be deleted.
 930
 931 The function returns a list containing the current host name, the
 932 temporary flag, and the key and cert file names in the form required
 933 by `gnutls-boot-parameters`."
 934   (let ((exp-key-file (expand-file-name key-file))
 935         (exp-cert-file (expand-file-name cert-file)))
 936     (condition-case nil
 937         (progn
 938           (call-process elpher-openssl-command nil nil nil
 939                         "req" "-x509" "-newkey" "rsa:2048"
 940                         "-days" (if temporary "1" "36500")
 941                         "-nodes"
 942                         "-subj" (concat "/CN=" common-name)
 943                         "-keyout" exp-key-file
 944                         "-out" exp-cert-file)
 945           (list (elpher-address-host (elpher-page-address elpher-current-page))
 946                 temporary exp-key-file exp-cert-file))
 947       (error
 948        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 949        (error "Program 'openssl', required for certificate generation, not found")))))
 950
 951 (defun elpher-generate-throwaway-certificate ()
 952   "Generate and return details of a throwaway certificate.
 953 The key and certificate files will be deleted when they are no
 954 longer needed for this session."
 955   (let* ((file-base (make-temp-name "elpher"))
 956          (key-file (concat temporary-file-directory file-base ".key"))
 957          (cert-file (concat temporary-file-directory file-base ".crt")))
 958     (elpher-generate-certificate file-base key-file cert-file t)))
 959
 960 (defun elpher-generate-persistent-certificate (file-base common-name)
 961   "Generate and return details of a persistent certificate.
 962 The argument FILE-BASE is used as the base for the key and certificate
 963 files, while COMMON-NAME specifies the common name field of the
 964 certificate.
 965
 966 The key and certificate files are written to in `elpher-certificate-directory'."
 967   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 968          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 969     (elpher-generate-certificate common-name key-file cert-file)))
 970
 971 (defun elpher-get-existing-certificate (file-base)
 972   "Return a certificate object corresponding to an existing certificate.
 973 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 974 the directory `elpher-certificate-directory'."
 975   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 976          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 977     (list (elpher-address-host (elpher-page-address elpher-current-page))
 978           nil
 979           (expand-file-name key-file)
 980           (expand-file-name cert-file))))
 981
 982 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 983   "Install a key+certificate file pair in `elpher-certificate-directory'.
 984 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 985 certificate files to install.  The argument FILE-BASE is used as the
 986 base for the installed key and certificate files."
 987   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 988          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 989     (if (or (file-exists-p key-file)
 990             (file-exists-p cert-file))
 991         (error "A certificate with base name %s is already installed" file-base))
 992     (copy-file key-file-src key-file)
 993     (copy-file cert-file-src cert-file)
 994     (list (elpher-address-host (elpher-page-address elpher-current-page))
 995           nil
 996           (expand-file-name key-file)
 997           (expand-file-name cert-file))))
 998
 999 (defun elpher-list-existing-certificates ()
1000   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1001   (unless (file-directory-p elpher-certificate-directory)
1002     (make-directory elpher-certificate-directory))
1003   (mapcar
1004    (lambda (file)
1005      (file-name-sans-extension file))
1006    (directory-files elpher-certificate-directory nil "\\.key$")))
1007
1008 (defun elpher-forget-current-certificate ()
1009   "Causes any current certificate to be forgotten.)
1010 In the case of throwaway certificates, the key and certificate files
1011 are also deleted."
1012   (interactive)
1013   (when elpher-client-certificate
1014     (unless (and (called-interactively-p 'any)
1015                  (not (y-or-n-p (concat "Really forget client certificate? "
1016                                         "(Throwaway certificates will be deleted.)"))))
1017       (when (cadr elpher-client-certificate)
1018         (delete-file (elt elpher-client-certificate 2))
1019         (delete-file (elt elpher-client-certificate 3)))
1020       (setq elpher-client-certificate nil)
1021       (if (called-interactively-p 'any)
1022           (message "Client certificate forgotten.")))))
1023
1024 (defun elpher-get-current-keylist (address)
1025   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1026
1027 This is obtained from the client certificate described by
1028 `elpher-current-certificate', if one is available and the host for
1029 that certificate matches the host in ADDRESS.
1030
1031 If `elpher-current-certificate' is non-nil, and its host name doesn't
1032 match that of ADDRESS, the certificate is forgotten."
1033   (if elpher-client-certificate
1034       (if (string= (car elpher-client-certificate)
1035                    (elpher-address-host address))
1036           (list (cddr elpher-client-certificate))
1037         (elpher-forget-current-certificate)
1038         (message "Disabling client certificate for new host")
1039         nil)
1040     nil))
1041
1042
1043 ;;; Gopher selector retrieval
1044 ;;
1045
1046 (defun elpher-get-gopher-response (address renderer)
1047   "Get response string from gopher server at ADDRESS and render using RENDERER."
1048   (elpher-get-host-response address 70
1049                             (concat (elpher-gopher-address-selector address) "\r\n")
1050                             renderer
1051                             (or (string= (elpher-address-protocol address) "gophers")
1052                                 elpher-use-tls)))
1053
1054 (defun elpher-get-gopher-page (renderer)
1055   "Getter function for gopher pages.
1056 The RENDERER procedure is used to display the contents of the page
1057 once they are retrieved from the gopher server."
1058   (let* ((address (elpher-page-address elpher-current-page))
1059          (content (elpher-get-cached-content address)))
1060     (if (and content (funcall renderer nil))
1061         (elpher-with-clean-buffer
1062          (insert content)
1063          (elpher-restore-pos))
1064       (elpher-with-clean-buffer
1065        (insert "LOADING... (use 'u' to cancel)\n"))
1066       (condition-case the-error
1067           (elpher-get-gopher-response address renderer)
1068         (error
1069          (elpher-network-error address the-error))))))
1070
1071 ;; Index rendering
1072
1073 (defun elpher-insert-margin (&optional type-name)
1074   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1075   (if type-name
1076       (progn
1077         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1078                         (concat
1079                          (propertize "[" 'face 'elpher-margin-brackets)
1080                          (propertize type-name 'face 'elpher-margin-key)
1081                          (propertize "]" 'face 'elpher-margin-brackets))))
1082         (insert " "))
1083     (insert (make-string elpher-margin-width ?\s))))
1084
1085 (defun elpher--page-button-help (_window buffer pos)
1086   "Function called by Emacs to generate mouse-over text.
1087 The arguments specify the BUFFER and the POS within the buffer of the item
1088 for which help is required.  The function returns the help to be
1089 displayed.  The _WINDOW argument is currently unused."
1090   (with-current-buffer buffer
1091     (let ((button (button-at pos)))
1092       (when button
1093         (let* ((page (button-get button 'elpher-page))
1094                (address (elpher-page-address page)))
1095           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1096
1097 (defun elpher-insert-index-record (display-string &optional address)
1098   "Function to insert an index record into the current buffer.
1099 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1100 If ADDRESS is not supplied or nil the record is rendered as an
1101 'information' line."
1102   (let* ((type (if address (elpher-address-type address) nil))
1103          (type-map-entry (cdr (assoc type elpher-type-map))))
1104     (if type-map-entry
1105         (let* ((margin-code (elt type-map-entry 2))
1106                (face (elt type-map-entry 3))
1107                (filtered-display-string (elpher-color-filter-apply display-string))
1108                (page (elpher-make-page filtered-display-string address)))
1109           (elpher-insert-margin margin-code)
1110           (insert-text-button filtered-display-string
1111                               'face face
1112                               'elpher-page page
1113                               'action #'elpher-click-link
1114                               'follow-link t
1115                               'help-echo #'elpher--page-button-help))
1116       (pcase type
1117         ('nil ;; Information
1118          (elpher-insert-margin)
1119          (let ((propertized-display-string
1120                 (propertize display-string 'face 'elpher-info)))
1121            (insert (elpher-process-text-for-display propertized-display-string))))
1122         (`(gopher ,selector-type) ;; Unknown
1123          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1124          (insert (propertize display-string
1125                              'face 'elpher-unknown)))))
1126     (insert "\n")))
1127
1128 (defun elpher-click-link (button)
1129   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1130   (let ((page (button-get button 'elpher-page)))
1131     (elpher-visit-page page)))
1132
1133 (defun elpher-render-index (data &optional _mime-type-string)
1134   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1135   (elpher-with-clean-buffer
1136    (if (not data)
1137        t
1138      (let ((data-processed (elpher-preprocess-text-response data)))
1139        (dolist (line (split-string data-processed "\n"))
1140          (ignore-errors
1141            (unless (= (length line) 0)
1142              (let* ((type (elt line 0))
1143                     (fields (split-string (substring line 1) "\t"))
1144                     (display-string (elt fields 0))
1145                     (selector (elt fields 1))
1146                     (host (elt fields 2))
1147                     (port (if (elt fields 3)
1148                               (string-to-number (elt fields 3))
1149                             nil))
1150                     (address (elpher-make-gopher-address type selector host port)))
1151                (elpher-insert-index-record display-string address))))))
1152      (elpher-cache-content (elpher-page-address elpher-current-page)
1153                            (buffer-string)))))
1154
1155 ;; Text rendering
1156
1157 (defun elpher-render-text (data &optional _mime-type-string)
1158   "Render DATA as text.  MIME-TYPE-STRING is unused."
1159   (elpher-with-clean-buffer
1160    (if (not data)
1161        t
1162      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1163      (elpher-cache-content
1164       (elpher-page-address elpher-current-page)
1165       (buffer-string)))))
1166
1167 ;; Image retrieval
1168
1169 (defun elpher-render-image (data &optional _mime-type-string)
1170   "Display DATA as image.  MIME-TYPE-STRING is unused."
1171   (if (not data)
1172       nil
1173     (if (display-images-p)
1174         (let* ((image (create-image
1175                        data
1176                        nil t)))
1177           (if (not image)
1178               (error "Unsupported image format")
1179             (let ((window (get-buffer-window elpher-buffer-name)))
1180               (when window
1181                 (setf (image-property image :max-width) (window-body-width window t))
1182                 (setf (image-property image :max-height) (window-body-height window t))))
1183             (elpher-with-clean-buffer
1184              (insert-image image)
1185              (elpher-restore-pos))))
1186       (elpher-render-download data))))
1187
1188 ;; Search retrieval and rendering
1189
1190 (defun elpher-get-gopher-query-page (renderer)
1191   "Getter for gopher addresses requiring input.
1192 The response is rendered using the rendering function RENDERER."
1193   (let* ((address (elpher-page-address elpher-current-page))
1194          (content (elpher-get-cached-content address))
1195          (aborted t))
1196     (if (and content (funcall renderer nil))
1197         (elpher-with-clean-buffer
1198          (insert content)
1199          (elpher-restore-pos)
1200          (message "Displaying cached search results.  Reload to perform a new search."))
1201       (unwind-protect
1202           (let* ((query-string (read-string "Query: "))
1203                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1204                  (search-address (elpher-make-gopher-address ?1
1205                                                              query-selector
1206                                                              (elpher-address-host address)
1207                                                              (elpher-address-port address)
1208                                                              (equal (elpher-address-type address) "gophers"))))
1209             (setq aborted nil)
1210
1211             (elpher-with-clean-buffer
1212              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1213             (elpher-get-gopher-response search-address renderer))
1214         (if aborted
1215             (elpher-visit-previous-page))))))
1216
1217 ;; Raw server response rendering
1218
1219 (defun elpher-render-raw (data &optional mime-type-string)
1220   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1221   (if (not data)
1222       nil
1223     (elpher-with-clean-buffer
1224      (when mime-type-string
1225        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1226      (insert data)
1227      (goto-char (point-min)))
1228     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1229
1230 ;; File save "rendering"
1231
1232 (defun elpher-render-download (data &optional _mime-type-string)
1233   "Save DATA to file.  MIME-TYPE-STRING is unused."
1234   (if (not data)
1235       nil
1236     (let* ((address (elpher-page-address elpher-current-page))
1237            (selector (if (elpher-address-gopher-p address)
1238                          (elpher-gopher-address-selector address)
1239                        (elpher-address-filename address))))
1240       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1241       (let* ((filename-proposal (file-name-nondirectory selector))
1242              (filename (read-file-name "Download complete. Save file as: "
1243                                        nil nil nil
1244                                        (if (> (length filename-proposal) 0)
1245                                            filename-proposal
1246                                          "download.file"))))
1247         (let ((coding-system-for-write 'binary))
1248           (with-temp-file filename
1249             (insert data)))
1250         (message (format "Saved to file %s." filename))))))
1251
1252 ;; HTML rendering
1253
1254 (defun elpher-render-html (data &optional _mime-type-string)
1255   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1256   (elpher-with-clean-buffer
1257    (if (not data)
1258        t
1259      (let ((dom (with-temp-buffer
1260                   (insert data)
1261                   (libxml-parse-html-region (point-min) (point-max)))))
1262        (shr-insert-document dom)))))
1263
1264 ;; Gemini page retrieval
1265
1266 (defvar elpher-gemini-redirect-chain)
1267
1268 (defun elpher-get-gemini-response (address renderer)
1269   "Get response string from gemini server at ADDRESS and render using RENDERER."
1270   (elpher-get-host-response address 1965
1271                             (concat (elpher-address-to-url address) "\r\n")
1272                             (lambda (response-string)
1273                               (elpher-process-gemini-response response-string renderer))
1274                             'gemini))
1275
1276 (defun elpher-parse-gemini-response (response)
1277   "Parse the RESPONSE string and return a list of components.
1278 The list is of the form (code meta body).  A response of nil implies
1279 that the response was malformed."
1280   (let ((header-end-idx (string-match "\r\n" response)))
1281     (if header-end-idx
1282         (let ((header (string-trim (substring response 0 header-end-idx)))
1283               (body (substring response (+ header-end-idx 2))))
1284           (if (>= (length header) 2)
1285               (let ((code (substring header 0 2))
1286                     (meta (string-trim (substring header 2))))
1287                 (list code meta body))
1288             (error "Malformed response: No response status found in header %s" header)))
1289       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1290
1291 (defun elpher-process-gemini-response (response-string renderer)
1292   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1293   (let ((response-components (elpher-parse-gemini-response response-string)))
1294     (let ((response-code (elt response-components 0))
1295           (response-meta (elt response-components 1))
1296           (response-body (elt response-components 2)))
1297       (pcase (elt response-code 0)
1298         (?1 ; Input required
1299          (elpher-with-clean-buffer
1300           (insert "Gemini server is requesting input."))
1301          (let* ((query-string
1302                  (if (eq (elt response-code 1) ?1)
1303                      (read-passwd (concat response-meta ": "))
1304                    (read-string (concat response-meta ": "))))
1305                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1306                 (old-fname (url-filename query-address)))
1307            (setf (url-filename query-address)
1308                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1309            (elpher-get-gemini-response query-address renderer)))
1310         (?2 ; Normal response
1311          (funcall renderer response-body response-meta))
1312         (?3 ; Redirect
1313          (message "Following redirect to %s" response-meta)
1314          (if (>= (length elpher-gemini-redirect-chain) 5)
1315              (error "More than 5 consecutive redirects followed"))
1316          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1317            (if (member redirect-address elpher-gemini-redirect-chain)
1318                (error "Redirect loop detected"))
1319            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1320                (error "Server tried to automatically redirect to non-gemini URL: %s"
1321                       response-meta))
1322            (elpher-page-set-address elpher-current-page redirect-address)
1323            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1324            (elpher-get-gemini-response redirect-address renderer)))
1325         (?4 ; Temporary failure
1326          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1327                 response-code response-meta))
1328         (?5 ; Permanent failure
1329          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1330                 response-code response-meta))
1331         (?6 ; Client certificate required
1332          (elpher-with-clean-buffer
1333           (if elpher-client-certificate
1334               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1335             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1336           (auto-fill-mode 1)
1337           (elpher-gemini-insert-text response-meta))
1338          (let ((chosen-certificate (elpher-choose-client-certificate)))
1339            (unless chosen-certificate
1340              (error "Gemini server requires a client certificate and none was provided"))
1341            (setq elpher-client-certificate chosen-certificate))
1342          (elpher-with-clean-buffer)
1343          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1344         (_other
1345          (error "Gemini server response unknown: %s %s"
1346                 response-code response-meta))))))
1347
1348 (defun elpher--read-answer-polyfill (question answers)
1349   "Polyfill for `read-answer' in Emacs 26.1.
1350 QUESTION is a string containing a question, and ANSWERS
1351 is a list of possible answers."
1352     (completing-read question (mapcar 'identity answers)))
1353
1354 (if (fboundp 'read-answer)
1355     (defalias 'elpher-read-answer 'read-answer)
1356   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1357
1358 (defun elpher-choose-client-certificate ()
1359   "Prompt for a client certificate to use to establish a TLS connection."
1360   (let* ((read-answer-short t))
1361     (pcase (read-answer "What do you want to do? "
1362                         '(("throwaway" ?t
1363                            "generate and use throw-away certificate")
1364                           ("persistent" ?p
1365                            "generate new or use existing persistent certificate")
1366                           ("abort" ?a
1367                            "stop immediately")))
1368       ("throwaway"
1369        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1370       ("persistent"
1371        (let* ((existing-certificates (elpher-list-existing-certificates))
1372               (file-base (completing-read
1373                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1374                           existing-certificates)))
1375          (if (string-empty-p (string-trim file-base))
1376              nil
1377            (if (member file-base existing-certificates)
1378                (setq elpher-client-certificate
1379                      (elpher-get-existing-certificate file-base))
1380              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1381                                  '(("new" ?n
1382                                     "generate new certificate")
1383                                    ("install" ?i
1384                                     "install existing certificate")
1385                                    ("abort" ?a
1386                                     "stop immediately")))
1387                ("new"
1388                 (let ((common-name (read-string "Common Name field for new certificate: "
1389                                                 file-base)))
1390                   (message "New key and self-signed certificate written to %s"
1391                            elpher-certificate-directory)
1392                   (elpher-generate-persistent-certificate file-base common-name)))
1393                ("install"
1394                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1395                        (key-file (read-file-name "Key file: " nil nil t)))
1396                   (message "Key and certificate installed in %s for future use"
1397                            elpher-certificate-directory)
1398                   (elpher-install-and-use-existing-certificate key-file
1399                                                                cert-file
1400                                                                file-base)))
1401                ("abort" nil))))))
1402       ("abort" nil))))
1403
1404 (defun elpher-get-gemini-page (renderer)
1405   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1406   (let* ((address (elpher-page-address elpher-current-page))
1407          (content (elpher-get-cached-content address)))
1408     (condition-case the-error
1409         (if (and content (funcall renderer nil))
1410             (elpher-with-clean-buffer
1411              (insert content)
1412              (elpher-restore-pos))
1413           (elpher-with-clean-buffer
1414            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1415           (setq elpher-gemini-redirect-chain nil)
1416           (elpher-get-gemini-response address renderer))
1417       (error
1418        (elpher-network-error address the-error)))))
1419
1420 (defun elpher-render-gemini (body &optional mime-type-string)
1421   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1422   (if (not body)
1423       t
1424     (let* ((mime-type-string* (if (or (not mime-type-string)
1425                                       (string-empty-p mime-type-string))
1426                                   "text/gemini; charset=utf-8"
1427                                 mime-type-string))
1428            (mime-type-split (split-string mime-type-string* ";" t))
1429            (mime-type (string-trim (car mime-type-split)))
1430            (parameters (mapcar (lambda (s)
1431                                  (let ((key-val (split-string s "=")))
1432                                    (list (downcase (string-trim (car key-val)))
1433                                          (downcase (string-trim (cadr key-val))))))
1434                                (cdr mime-type-split))))
1435       (when (string-prefix-p "text/" mime-type)
1436         (setq body (decode-coding-string
1437                     body
1438                     (if (assoc "charset" parameters)
1439                         (intern (cadr (assoc "charset" parameters)))
1440                       'utf-8)))
1441         (setq body (replace-regexp-in-string "\r" "" body)))
1442       (pcase mime-type
1443         ((or "text/gemini" "")
1444          (elpher-render-gemini-map body parameters))
1445         ("text/html"
1446          (elpher-render-html body))
1447         ((pred (string-prefix-p "text/"))
1448          (elpher-render-gemini-plain-text body parameters))
1449         ((pred (string-prefix-p "image/"))
1450          (elpher-render-image body))
1451         (_other
1452          (elpher-render-download body))))))
1453
1454 (defun elpher-gemini-get-link-url (link-line)
1455   "Extract the url portion of LINK-LINE, a gemini map file link line.
1456 Returns nil in the event that the contents of the line following the
1457 => prefix are empty."
1458   (let ((l (split-string (substring link-line 2))))
1459     (if l
1460         (string-trim (elt l 0))
1461       nil)))
1462
1463 (defun elpher-gemini-get-link-display-string (link-line)
1464   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1465 Return nil if this portion is not provided."
1466   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1467          (idx (string-match "[ \t]" rest)))
1468     (and idx
1469          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1470
1471 (defun elpher-collapse-dot-sequences (filename)
1472   "Collapse dot sequences in the (absolute) FILENAME.
1473 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1474   (let* ((path (split-string filename "/" t))
1475          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1476          (path-reversed-normalized
1477           (seq-reduce (lambda (a b)
1478                         (cond ((equal b "..") (cdr a))
1479                               ((equal b ".") a)
1480                               (t (cons b a))))
1481                       path nil))
1482          (path-normalized (reverse path-reversed-normalized)))
1483     (if path-normalized
1484         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1485       "/")))
1486
1487 (defun elpher-address-from-gemini-url (url)
1488   "Extract address from URL with defaults as per gemini map files.
1489 While there's obviously some redundancy here between this function and
1490 `elpher-address-from-url', gemini map file URLs require enough special
1491 treatment that a separate function is warranted."
1492   (let ((address (url-generic-parse-url url))
1493         (current-address (elpher-page-address elpher-current-page)))
1494     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1495       (if (url-host address) ;if there is an explicit host, filenames are absolute
1496           (if (string-empty-p (url-filename address))
1497               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1498         (setf (url-host address) (url-host current-address))
1499         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1500         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1501         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1502           (setf (url-filename address)
1503                 (concat (file-name-directory (url-filename current-address))
1504                         (url-filename address)))))
1505       (when (url-host address)
1506         (setf (url-host address) (puny-encode-domain (url-host address))))
1507       (unless (url-type address)
1508         (setf (url-type address) (url-type current-address)))
1509       (when (equal (url-type address) "gemini")
1510         (setf (url-filename address)
1511               (elpher-collapse-dot-sequences (url-filename address)))))
1512     (elpher-remove-redundant-ports address)))
1513
1514 (defun elpher-gemini-insert-link (link-line)
1515   "Insert link described by LINK-LINE into a text/gemini document."
1516   (let ((url (elpher-gemini-get-link-url link-line)))
1517     (when url
1518       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1519              (address (elpher-address-from-gemini-url url))
1520              (type (if address (elpher-address-type address) nil))
1521              (type-map-entry (cdr (assoc type elpher-type-map)))
1522              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1523         (when type-map-entry
1524           (insert elpher-gemini-link-string)
1525           (let* ((face (elt type-map-entry 3))
1526                  (display-string (or given-display-string
1527                                      (elpher-address-to-iri address)))
1528                  (page (elpher-make-page display-string
1529                                          address)))
1530             (insert-text-button display-string
1531                                 'face face
1532                                 'elpher-page page
1533                                 'action #'elpher-click-link
1534                                 'follow-link t
1535                                 'help-echo #'elpher--page-button-help))
1536           (newline))))))
1537
1538 (defun elpher-gemini-insert-header (header-line)
1539   "Insert header described by HEADER-LINE into a text/gemini document.
1540 The gemini map file line describing the header is given
1541 by HEADER-LINE."
1542   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1543     (let* ((level (length (match-string 1 header-line)))
1544            (header (substring header-line (match-end 0)))
1545            (face (pcase level
1546                    (1 'elpher-gemini-heading1)
1547                    (2 'elpher-gemini-heading2)
1548                    (3 'elpher-gemini-heading3)
1549                    (_ 'default)))
1550            (fill-column (if (display-graphic-p)
1551                             (/ (* fill-column
1552                                   (font-get (font-spec :name (face-font 'default)) :size))
1553                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1554       (unless (display-graphic-p)
1555         (insert (make-string level ?#) " "))
1556       (insert (propertize header
1557                           'face face
1558                           'gemini-heading t
1559                           'rear-nonsticky t))
1560       (newline))))
1561
1562 (defun elpher-gemini-insert-text (text-line)
1563   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1564 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1565 width defined by `elpher-gemini-max-fill-width'."
1566   (string-match
1567    (rx (: line-start
1568           (optional
1569            (group (or (: "*" (+ (any " \t")))
1570                       (: ">" (* (any " \t"))))))))
1571    text-line)
1572   (let* ((line-prefix (match-string 1 text-line))
1573          (processed-text-line
1574           (if line-prefix
1575               (cond ((string-prefix-p "*" line-prefix)
1576                      (concat
1577                       (replace-regexp-in-string "\\*"
1578                                                 elpher-gemini-bullet-string
1579                                                 (match-string 0 text-line))
1580                       (substring text-line (match-end 0))))
1581                     ((string-prefix-p ">" line-prefix)
1582                      (propertize text-line 'face 'elpher-gemini-quoted))
1583                     (t text-line))
1584             text-line))
1585          (fill-prefix (if line-prefix
1586                           (make-string (length (match-string 0 text-line)) ?\s)
1587                         nil)))
1588     (insert (elpher-process-text-for-display processed-text-line))
1589     (newline)))
1590
1591 (defun elpher-render-gemini-map (data _parameters)
1592   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1593   (elpher-with-clean-buffer
1594    (auto-fill-mode 1)
1595    (let ((preformatted nil)
1596          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1597      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1598      (dolist (line (split-string data "\n"))
1599        (cond
1600         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1601         (preformatted (insert (elpher-process-text-for-display
1602                                (propertize line 'face 'elpher-gemini-preformatted))
1603                               "\n"))
1604         ((string-prefix-p "=>" line)
1605          (elpher-gemini-insert-link line))
1606         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1607         (t (elpher-gemini-insert-text line)))))
1608    (elpher-cache-content
1609     (elpher-page-address elpher-current-page)
1610     (buffer-string))))
1611
1612 (defun elpher-render-gemini-plain-text (data _parameters)
1613   "Render DATA as plain text file.  PARAMETERS is currently unused."
1614   (elpher-with-clean-buffer
1615    (insert (elpher-process-text-for-display data))
1616    (elpher-cache-content
1617     (elpher-page-address elpher-current-page)
1618     (buffer-string))))
1619
1620 (defun elpher-build-current-imenu-index ()
1621   "Build imenu index for current elpher buffer."
1622   (save-excursion
1623     (goto-char (point-min))
1624     (let ((match nil)
1625           (headers nil))
1626       (while (setq match (text-property-search-forward 'gemini-heading t t))
1627         (push (cons
1628                (buffer-substring-no-properties (prop-match-beginning match)
1629                                                (prop-match-end match))
1630                (prop-match-beginning match))
1631               headers))
1632       (reverse headers))))
1633
1634 ;; Finger page connection
1635
1636 (defun elpher-get-finger-page (renderer)
1637   "Opens a finger connection to the current page address.
1638 The result is rendered using RENDERER."
1639   (let* ((address (elpher-page-address elpher-current-page))
1640          (content (elpher-get-cached-content address)))
1641     (if (and content (funcall renderer nil))
1642         (elpher-with-clean-buffer
1643          (insert content)
1644          (elpher-restore-pos))
1645       (elpher-with-clean-buffer
1646        (insert "LOADING... (use 'u' to cancel)\n"))
1647       (condition-case the-error
1648           (let* ((kill-buffer-query-functions nil)
1649                  (user (let ((filename (elpher-address-filename address)))
1650                          (if (> (length filename) 1)
1651                              (substring filename 1)
1652                            (elpher-address-user address)))))
1653             (elpher-get-host-response address 79
1654                                       (concat user "\r\n")
1655                                       renderer))
1656         (error
1657          (elpher-network-error address the-error))))))
1658
1659
1660 ;; Telnet page connection
1661
1662 (defun elpher-get-telnet-page (renderer)
1663   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1664   (when renderer
1665     (elpher-visit-previous-page)
1666     (error "Command not supported for telnet URLs"))
1667   (let* ((address (elpher-page-address elpher-current-page))
1668          (host (elpher-address-host address))
1669          (port (elpher-address-port address)))
1670     (elpher-visit-previous-page)
1671     (if (> port 0)
1672         (telnet host port)
1673       (telnet host))))
1674
1675
1676 ;; Other URL page opening
1677
1678 (defun elpher-get-other-url-page (renderer)
1679   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1680   (when renderer
1681     (elpher-visit-previous-page)
1682     (error "Command not supported for general URLs"))
1683   (let* ((address (elpher-page-address elpher-current-page))
1684          (url (elpher-address-to-url address)))
1685     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1686     (message "Opening URL...")
1687     (if elpher-open-urls-with-eww
1688         (browse-web url)
1689       (browse-url url))))
1690
1691 ;; File page
1692
1693 (defun elpher-get-file-page (renderer)
1694   "Getter which renders a local file using RENDERER.
1695 Assumes UTF-8 encoding for all text files."
1696   (let* ((address (elpher-page-address elpher-current-page))
1697          (filename (elpher-address-filename address)))
1698     (unless (file-exists-p filename)
1699       (elpher-visit-previous-page)
1700         (error "File not found"))
1701     (unless (file-readable-p filename)
1702       (elpher-visit-previous-page)
1703         (error "Could not read from file"))
1704     (let ((body (with-temp-buffer
1705        (let ((coding-system-for-read 'binary)
1706              (coding-system-for-write 'binary))
1707          (insert-file-contents-literally filename)
1708          (encode-coding-string (buffer-string) 'raw-text)))))
1709        (if renderer
1710            (funcall renderer body nil)
1711          (pcase (file-name-extension filename)
1712            ((or  "gmi" "gemini")
1713             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1714            ((or "htm" "html")
1715             (elpher-render-html (decode-coding-string body 'utf-8)))
1716            ((or "txt" "")
1717             (elpher-render-text (decode-coding-string body 'utf-8)))
1718            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1719             (elpher-render-image body))
1720            ((or "gopher" "gophermap")
1721             (elpher-render-index (elpher-decode body)))
1722            (_
1723             (elpher-render-download body))))
1724        (elpher-restore-pos))))
1725
1726
1727 ;; Welcome page retrieval
1728
1729 (defun elpher-get-welcome-page (renderer)
1730   "Getter which displays the welcome page (RENDERER must be nil)."
1731   (when renderer
1732     (elpher-visit-previous-page)
1733     (error "Command not supported for welcome page"))
1734   (elpher-with-clean-buffer
1735    (insert "     --------------------------------------------\n"
1736            "           Elpher Gopher and Gemini Client       \n"
1737            "                   version " elpher-version "\n"
1738            "     --------------------------------------------\n"
1739            "\n"
1740            "Default bindings:\n"
1741            "\n"
1742            " - TAB/Shift-TAB: next/prev item on current page\n"
1743            " - RET/mouse-1: open item under cursor\n"
1744            " - m: select an item on current page by name (autocompletes)\n"
1745            " - u/mouse-3/U: return to previous page or to the start page\n"
1746            " - g: go to a particular address (gopher, gemini, finger)\n"
1747            " - o/O: open a different address selector or the root menu of the current server\n"
1748            " - d/D: download item under cursor or current page\n"
1749            " - i/I: info on item under cursor or current page\n"
1750            " - c/C: copy URL representation of item under cursor or current page\n"
1751            " - a/A: bookmark the item under cursor or current page\n"
1752            " - B: list all bookmarks\n"
1753            " - s/S: show current history stack or all previously visted pages\n"
1754            " - r: redraw current page (using cached contents if available)\n"
1755            " - R: reload current page (regenerates cache)\n"
1756            " - !: set character coding system for gopher (default is to autodetect)\n"
1757            " - T: toggle TLS gopher mode\n"
1758            " - F: forget/discard current TLS client certificate\n"
1759            " - .: display the raw server response for the current page\n"
1760            "\n"
1761            "Start your exploration of gopher space and gemini:\n")
1762    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1763                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1764    (elpher-insert-index-record "Project Gemini home page"
1765                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1766    (insert "\n"
1767            "Alternatively, select a search engine and enter some search terms:\n")
1768    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1769                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1770    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1771                                (elpher-address-from-url "gemini://geminispace.info/search"))
1772    (insert "\n"
1773            "Your bookmarks are stored in your ")
1774    (insert-text-button "bookmark list"
1775                        'face 'link
1776                        'action #'elpher-click-link
1777                        'follow-link t
1778                        'help-echo #'elpher--page-button-help
1779                        'elpher-page
1780                        (elpher-make-page "Elpher Bookmarks"
1781                                          (elpher-make-about-address 'bookmarks)))
1782    (insert ".\n")
1783    (insert (propertize
1784             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1785             'face 'shadow))
1786    (insert "\n"
1787            "The gopher home of the Elpher project is here:\n")
1788    (elpher-insert-index-record "The Elpher Project Page"
1789                                (elpher-make-gopher-address ?1
1790                                                            "/projects/elpher/"
1791                                                            "thelambdalab.xyz"
1792                                                            70))
1793    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1794      (insert "\n"
1795              "The following info documentation is available:\n"
1796              "   - ")
1797      (insert-text-button "Elpher Manual"
1798                          'face 'link
1799                          'action (lambda (_)
1800                                    (interactive)
1801                                    (info "(elpher)"))
1802                          'follow-link t
1803                          'help-echo help-string)
1804      (insert "\n   - ")
1805      (insert-text-button "Changes introduced by the latest release"
1806                        'face 'link
1807                        'action (lambda (_)
1808                                  (interactive)
1809                                  (info "(elpher)News"))
1810                        'follow-link t
1811                        'help-echo help-string))
1812    (insert "\n")
1813    (insert (propertize
1814             (concat "(These documents should be available if you have installed Elpher \n"
1815                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1816             'face 'shadow))
1817    (elpher-restore-pos)))
1818
1819 ;; History page retrieval
1820
1821 (defun elpher-show-history ()
1822   "Show the current contents of elpher's history stack.
1823 Use \\[elpher-show-visited-pages] to see the entire history.
1824 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1825   (interactive)
1826   (elpher-visit-page
1827    (elpher-make-page "Current History Stack"
1828                      (elpher-make-about-address 'history))))
1829
1830 (defun elpher-show-visited-pages ()
1831   "Show the all the pages you've visited using Elpher.
1832 Use \\[elpher-show-history] to see just the current history stack.
1833 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1834   (interactive)
1835   (elpher-visit-page
1836    (elpher-make-page "Elpher Visted Pages"
1837                      (elpher-make-about-address 'visited-pages))))
1838
1839 (defun elpher-get-history-page (renderer)
1840   "Getter which displays the history page (RENDERER must be nil)."
1841   (when renderer
1842     (elpher-visit-previous-page)
1843     (error "Command not supported for history page"))
1844   (elpher-display-history-links elpher-history "Current history stack"))
1845
1846 (defun elpher-get-visited-pages-page (renderer)
1847   "Getter which displays the list of visited pages (RENDERER must be nil)."
1848   (when renderer
1849     (elpher-visit-previous-page)
1850     (error "Command not supported for history page"))
1851   (elpher-display-history-links
1852    (seq-filter (lambda (page)
1853                  (not (elpher-address-about-p (elpher-page-address page))))
1854                elpher-visited-pages)
1855    "All visited pages"))
1856
1857 (defun elpher-display-history-links (pages title)
1858   "Show all PAGES in an Elpher buffer with a given TITLE."
1859   (let* ((title-line (concat " ---- " title " ----"))
1860          (footer-line (make-string (length title-line) ?-)))
1861     (elpher-with-clean-buffer
1862      (insert title-line "\n\n")
1863      (if pages
1864          (dolist (page pages)
1865            (when page
1866              (let ((display-string (elpher-page-display-string page))
1867                    (address (elpher-page-address page)))
1868                (elpher-insert-index-record display-string address))))
1869        (insert "No history items found.\n"))
1870      (insert "\n " footer-line "\n"
1871              "Select an entry or press 'u' to return to the previous page.")
1872      (elpher-restore-pos))))
1873
1874
1875 ;;; Bookmarks
1876
1877 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1878 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1879 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1880 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1881
1882 (defvar elpher-bookmark-link nil
1883   "Prefer bookmarking a link or the current page.
1884 Bind this variable dynamically, or set it to t.
1885 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1886 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1887
1888 (defun elpher-bookmark-make-record ()
1889   "Return a bookmark record.
1890 If `elpher-bookmark-link' is non-nil and point is on a link button,
1891 return a bookmark record for that link.  Otherwise, return a bookmark
1892 record for the current elpher page."
1893   (let* ((button (and elpher-bookmark-link (button-at (point))))
1894          (page (if button
1895                    (button-get button 'elpher-page)
1896                  elpher-current-page)))
1897     (unless page
1898       (error "Cannot bookmark this link"))
1899     (let* ((address (elpher-page-address page))
1900            (url (elpher-address-to-url address))
1901            (display-string (elpher-page-display-string page))
1902            (pos (if button nil (point))))
1903       (if (elpher-address-about-p address)
1904           (error "Cannot bookmark %s" display-string)
1905         `(,display-string
1906           (defaults . (,display-string))
1907           (position . ,pos)
1908           (location . ,url)
1909           (handler . elpher-bookmark-jump))))))
1910
1911 ;;;###autoload
1912 (defun elpher-bookmark-jump (bookmark)
1913   "Handler used to open a bookmark using elpher.
1914 The argument BOOKMARK is a bookmark record passed to the function.
1915 This handler is responsible for loading the bookmark in some buffer,
1916 then making that buffer the current buffer.  It should not switch
1917 to the buffer."
1918   (let* ((url (cdr (assq 'location bookmark)))
1919          (cleaned-url (string-trim url))
1920          (page (elpher-page-from-url cleaned-url))
1921          (buffer (get-buffer-create elpher-buffer-name)))
1922     (elpher-with-clean-buffer
1923      (elpher-visit-page page))
1924     (set-buffer buffer)
1925     nil))
1926
1927 (defun elpher-bookmark-link ()
1928   "Bookmark the link at point.
1929 To bookmark the current page, use \\[elpher-bookmark-current]."
1930   (interactive)
1931   (let ((elpher-bookmark-link t))
1932     (bookmark-set-no-overwrite)))
1933
1934 (defun elpher-bookmark-current ()
1935   "Bookmark the current page.
1936 To bookmark the link at point use \\[elpher-bookmark-link]."
1937   (interactive)
1938   (call-interactively #'bookmark-set-no-overwrite))
1939
1940 (defun elpher-bookmark-import (file)
1941   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1942   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1943                               (file-readable-p elpher-bookmarks-file))
1944                          elpher-bookmarks-file
1945                        (read-file-name "Old Elpher bookmarks: "
1946                                        user-emacs-directory nil t
1947                                        "elpher-bookmarks"))))
1948   (dolist (bookmark (with-temp-buffer
1949                       (insert-file-contents file)
1950                       (read (current-buffer))))
1951     (let* ((display-string (car bookmark))
1952            (url (cadr bookmark))
1953            (record `(,display-string
1954                      (location . ,url)
1955                      (handler . elpher-bookmark-jump))))
1956       (bookmark-store display-string (cdr record) t)))
1957   (bookmark-save))
1958
1959 (defun elpher-get-bookmarks-page (renderer)
1960   "Getter which displays the bookmarks (RENDERER must be nil)."
1961   (when renderer
1962     (elpher-visit-previous-page)
1963     (error "Command not supported for bookmarks page"))
1964
1965   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1966                                      elpher-bookmarks-file)
1967                                 (locate-user-emacs-file "elpher-bookmarks"))))
1968     (when (and (file-readable-p old-bookmarks-file)
1969                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1970                                  old-bookmarks-file
1971                                  "\" found. Import now?")))
1972       (elpher-bookmark-import old-bookmarks-file)
1973       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1974
1975   (if (and elpher-use-emacs-bookmark-menu
1976            elpher-history)
1977       (progn
1978         (elpher-visit-previous-page)
1979         (call-interactively #'bookmark-bmenu-list))
1980     (elpher-with-clean-buffer
1981      (insert " ---- Elpher Bookmarks ---- \n\n")
1982      (bookmark-maybe-load-default-file)
1983      (dolist (bookmark (bookmark-maybe-sort-alist))
1984        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1985          (let* ((name (car bookmark))
1986                 (url (alist-get 'location (cdr bookmark)))
1987                 (address (elpher-address-from-url url)))
1988            (elpher-insert-index-record name address))))
1989      (when (<= (line-number-at-pos) 3)
1990        (insert "No bookmarked pages found.\n"))
1991      (insert "\n --------------------------\n\n"
1992              "Select an entry or press 'u' to return to the previous page.\n\n"
1993              "Bookmarks can be renamed or deleted via the ")
1994      (insert-text-button "Emacs bookmark menu"
1995                          'action (lambda (_)
1996                                    (interactive)
1997                                    (call-interactively #'bookmark-bmenu-list))
1998                          'follow-link t
1999                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2000      (insert (substitute-command-keys
2001               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2002      (elpher-restore-pos))))
2003
2004 (defun elpher-show-bookmarks ()
2005   "Interactive function to display the current list of elpher bookmarks."
2006   (interactive)
2007   (elpher-visit-page
2008    (elpher-make-page "Elpher Bookmarks"
2009                      (elpher-make-about-address 'bookmarks))))
2010
2011
2012 ;;; Integrations
2013 ;;
2014
2015 ;;; Org
2016
2017 (defun elpher-org-export-link (link description format protocol)
2018   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2019
2020 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2021 of gemini, gopher or finger."
2022   (let* ((url (if (equal protocol "elpher")
2023                   (string-remove-prefix "elpher:" link)
2024                 (format "%s:%s" protocol link)))
2025          (desc (or description url)))
2026     (pcase format
2027       (`gemini (format "=> %s %s" url desc))
2028       (`html (format "<a href=\"%s\">%s</a>" url desc))
2029       (`latex (format "\\href{%s}{%s}" url desc))
2030       (_ (if (not description)
2031              url
2032            (format "%s (%s)" desc url))))))
2033
2034 (defun elpher-org-store-link ()
2035   "Store link to an `elpher' page in Org."
2036   (when (eq major-mode 'elpher-mode)
2037     (let* ((url (elpher-info-current))
2038            (desc (car elpher-current-page))
2039            (protocol (cond
2040                       ((string-prefix-p "gemini:" url) "gemini")
2041                       ((string-prefix-p "gopher:" url) "gopher")
2042                       ((string-prefix-p "finger:" url) "finger")
2043                       (t "elpher"))))
2044       (when (equal "elpher" protocol)
2045         ;; Weird link. Or special inner link?
2046         (setq url (concat "elpher:" url)))
2047       (org-link-store-props :type protocol :link url :description desc)
2048       t)))
2049
2050 (defun elpher-org-follow-link (link protocol)
2051   "Visit a LINK for the given PROTOCOL.
2052
2053 PROTOCOL may be one of gemini, gopher or finger.  This method also
2054 supports the old protocol elpher, where the link is self-contained."
2055   (let ((url (if (equal protocol "elpher")
2056                  (string-remove-prefix "elpher:" link)
2057                (format "%s:%s" protocol link))))
2058     (elpher-go url)))
2059
2060 (defun elpher-org-mode-integration ()
2061   "Set up `elpher' integration for `org-mode'."
2062   (org-link-set-parameters
2063    "elpher"
2064    :store #'elpher-org-store-link
2065    :export (lambda (link description format _plist)
2066              (elpher-org-export-link link description format "elpher"))
2067    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2068   (org-link-set-parameters
2069    "gemini"
2070    :export (lambda (link description format _plist)
2071              (elpher-org-export-link link description format "gemini"))
2072    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2073   (org-link-set-parameters
2074    "gopher"
2075    :export (lambda (link description format _plist)
2076              (elpher-org-export-link link description format "gopher"))
2077    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2078   (org-link-set-parameters
2079    "finger"
2080    :export (lambda (link description format _plist)
2081              (elpher-org-export-link link description format "finger"))
2082    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2083
2084 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2085
2086 ;;; Browse URL
2087
2088 ;;;###autoload
2089 (defun elpher-browse-url-elpher (url &rest _args)
2090   "Browse URL using Elpher.  This function is used by `browse-url'."
2091   (interactive (browse-url-interactive-arg "Elpher URL: "))
2092   (elpher-go url))
2093
2094 ;; Use elpher to open gopher, finger and gemini links
2095 ;; For recent version of `browse-url' package
2096 (if (boundp 'browse-url-default-handlers)
2097     (add-to-list
2098      'browse-url-default-handlers
2099      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2100   ;; Patch `browse-url-browser-function' for older ones. The value of
2101   ;; that variable is `browse-url-default-browser' by default, so
2102   ;; that's the function that gets advised. If the value is an alist,
2103   ;; however, we don't know what to do. Better not interfere?
2104   (when (and (symbolp browse-url-browser-function)
2105              (fboundp browse-url-browser-function))
2106     (advice-add browse-url-browser-function :before-while
2107                 (lambda (url &rest _args)
2108                   "Handle gemini, gopher, and finger schemes using Elpher."
2109                   (let ((scheme (downcase (car (split-string url ":" t)))))
2110                     (if (member scheme '("gemini" "gopher" "finger"))
2111                         ;; `elpher-go' always returns nil, which will stop the
2112                         ;; advice chain here in a before-while
2113                         (elpher-go url)
2114                       ;; chain must continue, then return t.
2115                       t))))))
2116
2117 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2118 (with-eval-after-load 'thingatpt
2119   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2120
2121 ;;; Mu4e:
2122
2123 ;; Make mu4e aware of the gemini world
2124 (setq mu4e~view-beginning-of-url-regexp
2125       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2126
2127 ;;; eww:
2128
2129 ;; Let elpher handle gemini, gopher links in eww buffer.
2130 (setq eww-use-browse-url
2131       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2132
2133
2134 ;;; Interactive procedures
2135 ;;
2136
2137 (defun elpher-next-link ()
2138   "Move point to the next link on the current page."
2139   (interactive)
2140   (forward-button 1))
2141
2142 (defun elpher-prev-link ()
2143   "Move point to the previous link on the current page."
2144   (interactive)
2145   (backward-button 1))
2146
2147 (defun elpher-follow-current-link ()
2148   "Open the link or url at point."
2149   (interactive)
2150   (push-button))
2151
2152 ;;;###autoload
2153 (defun elpher-go (host-or-url)
2154   "Go to a particular gopher site HOST-OR-URL.
2155 When run interactively HOST-OR-URL is read from the minibuffer."
2156   (interactive (list
2157                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2158   (let ((trimmed-host-or-url (string-trim host-or-url)))
2159     (unless (string-empty-p trimmed-host-or-url)
2160       (let ((page (elpher-page-from-url trimmed-host-or-url
2161                                         (elpher-get-default-url-scheme))))
2162         (unless (get-buffer-window elpher-buffer-name t)
2163           (switch-to-buffer elpher-buffer-name))
2164         (elpher-with-clean-buffer
2165          (elpher-visit-page page))
2166         nil)))) ; non-nil value is displayed by eshell
2167
2168 (defun elpher-go-current ()
2169   "Go to a particular site read from the minibuffer, initialized with the current URL."
2170   (interactive)
2171   (let* ((address (elpher-page-address elpher-current-page))
2172          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2173                            (elpher-address-to-url address))))
2174     (unless (string-empty-p (string-trim url))
2175       (elpher-visit-page (elpher-page-from-url url)))))
2176
2177 (defun elpher-redraw ()
2178   "Redraw current page."
2179   (interactive)
2180   (elpher-visit-page elpher-current-page))
2181
2182 (defun elpher-reload ()
2183   "Reload current page."
2184   (interactive)
2185   (elpher-reload-current-page))
2186
2187 (defun elpher-toggle-tls ()
2188   "Toggle TLS encryption mode for gopher."
2189   (interactive)
2190   (setq elpher-use-tls (not elpher-use-tls))
2191   (if elpher-use-tls
2192       (if (gnutls-available-p)
2193           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2194         (setq elpher-use-tls nil)
2195         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2196     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2197
2198 (defun elpher-view-raw ()
2199   "View raw server response for current page."
2200   (interactive)
2201   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2202       (error "This page was not generated by a server")
2203     (elpher-visit-page elpher-current-page
2204                        #'elpher-render-raw)))
2205
2206 (defun elpher-back ()
2207   "Go to previous site."
2208   (interactive)
2209   (elpher-visit-previous-page))
2210
2211 (defun elpher-back-to-start ()
2212   "Go all the way back to the start page."
2213   (interactive)
2214   (setq-local elpher-current-page nil)
2215   (setq-local elpher-history nil)
2216   (elpher-visit-page (elpher-make-start-page)))
2217
2218 (defun elpher-download ()
2219   "Download the link at point."
2220   (interactive)
2221   (let ((button (button-at (point))))
2222     (if button
2223         (let ((page (button-get button 'elpher-page)))
2224           (unless page
2225             (error "Not an elpher page"))
2226           (when (elpher-address-about-p (elpher-page-address page))
2227             (error "Cannot download %s" (elpher-page-display-string page)))
2228           (elpher-visit-page (button-get button 'elpher-page)
2229                              #'elpher-render-download))
2230       (error "No link selected"))))
2231
2232 (defun elpher-download-current ()
2233   "Download the current page."
2234   (interactive)
2235   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2236       (error "Cannot download %s"
2237              (elpher-page-display-string elpher-current-page))
2238     (elpher-visit-page (elpher-make-page
2239                         (elpher-page-display-string elpher-current-page)
2240                         (elpher-page-address elpher-current-page))
2241                        #'elpher-render-download
2242                        t)))
2243
2244 (defun elpher--build-link-map ()
2245   "Build alist mapping link names to destination pages in current buffer."
2246   (let ((link-map nil)
2247         (b (next-button (point-min) t)))
2248     (while b
2249       (push (cons (button-label b) b) link-map)
2250       (setq b (next-button (button-start b))))
2251     link-map))
2252
2253 (defun elpher-jump ()
2254   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2255   (interactive)
2256   (let* ((link-map (elpher--build-link-map)))
2257     (if link-map
2258         (let ((key (let ((completion-ignore-case t))
2259                      (completing-read "Directory item/link: "
2260                                       link-map nil t))))
2261           (if (and key (> (length key) 0))
2262               (let ((b (cdr (assoc key link-map))))
2263                 (goto-char (button-start b))
2264                 (button-activate b)))))))
2265
2266 (defun elpher-root-dir ()
2267   "Visit root of current server."
2268   (interactive)
2269   (let ((address (elpher-page-address elpher-current-page)))
2270     (if (not (elpher-address-about-p address))
2271         (if (or (member (url-filename address) '("/" ""))
2272                 (and (elpher-address-gopher-p address)
2273                      (= (length (elpher-gopher-address-selector address)) 0)))
2274             (error "Already at root directory of current server")
2275           (let ((address-copy (elpher-address-from-url
2276                                (elpher-address-to-url address))))
2277             (setf (url-filename address-copy) "")
2278             (elpher-go (elpher-address-to-url address-copy))))
2279       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2280
2281 (defun elpher-info-page (page)
2282   "Display URL of PAGE in minibuffer."
2283   (let* ((address (elpher-page-address page))
2284          (url (elpher-address-to-url address))
2285          (iri (elpher-address-to-iri address)))
2286     (if (equal url iri)
2287         (message "%s" url)
2288       (message "%s (Raw: %s)" iri url))))
2289
2290 (defun elpher-info-link ()
2291   "Display information on page corresponding to link at point."
2292   (interactive)
2293   (let ((button (button-at (point))))
2294     (unless button
2295       (error "No item selected"))
2296     (let ((page (button-get button 'elpher-page)))
2297       (unless page
2298         (error "Not an elpher page"))
2299       (elpher-info-page page))))
2300
2301 (defun elpher-info-current ()
2302   "Display information on current page."
2303   (interactive)
2304   (elpher-info-page elpher-current-page))
2305
2306 (defun elpher-copy-page-url (page)
2307   "Copy URL representation of address of PAGE to `kill-ring'."
2308   (let* ((address (elpher-page-address page))
2309          (url (elpher-address-to-url address)))
2310     (message "Copied \"%s\" to kill-ring/clipboard." url)
2311     (kill-new url)))
2312
2313 (defun elpher-copy-link-url ()
2314   "Copy URL of item at point to `kill-ring'."
2315   (interactive)
2316   (let ((button (button-at (point))))
2317     (unless button
2318       (error "No item selected"))
2319     (let ((page (button-get button 'elpher-page)))
2320       (unless page
2321         (error "Not an elpher page"))
2322       (elpher-copy-page-url page))))
2323
2324 (defun elpher-copy-current-url ()
2325   "Copy URL of current page to `kill-ring'."
2326   (interactive)
2327   (elpher-copy-page-url elpher-current-page))
2328
2329 (defun elpher-set-gopher-coding-system ()
2330   "Specify an explicit character coding system for gopher selectors."
2331   (interactive)
2332   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2333     (setq elpher-user-coding-system system)
2334     (if system
2335         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2336       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2337
2338
2339 ;;; Mode and keymap
2340 ;;
2341
2342 (defvar elpher-mode-map
2343   (let ((map (make-sparse-keymap)))
2344     (define-key map (kbd "TAB") 'elpher-next-link)
2345     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2346     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2347     (define-key map (kbd "u") 'elpher-back)
2348     (define-key map (kbd "-") 'elpher-back)
2349     (define-key map (kbd "^") 'elpher-back)
2350     (define-key map [mouse-3] 'elpher-back)
2351     (define-key map (kbd "U") 'elpher-back-to-start)
2352     (define-key map (kbd "g") 'elpher-go)
2353     (define-key map (kbd "o") 'elpher-go-current)
2354     (define-key map (kbd "O") 'elpher-root-dir)
2355     (define-key map (kbd "s") 'elpher-show-history)
2356     (define-key map (kbd "S") 'elpher-show-visited-pages)
2357     (define-key map (kbd "r") 'elpher-redraw)
2358     (define-key map (kbd "R") 'elpher-reload)
2359     (define-key map (kbd "T") 'elpher-toggle-tls)
2360     (define-key map (kbd ".") 'elpher-view-raw)
2361     (define-key map (kbd "d") 'elpher-download)
2362     (define-key map (kbd "D") 'elpher-download-current)
2363     (define-key map (kbd "m") 'elpher-jump)
2364     (define-key map (kbd "i") 'elpher-info-link)
2365     (define-key map (kbd "I") 'elpher-info-current)
2366     (define-key map (kbd "c") 'elpher-copy-link-url)
2367     (define-key map (kbd "C") 'elpher-copy-current-url)
2368     (define-key map (kbd "a") 'elpher-bookmark-link)
2369     (define-key map (kbd "A") 'elpher-bookmark-current)
2370     (define-key map (kbd "B") 'elpher-show-bookmarks)
2371     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2372     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2373     (when (fboundp 'evil-define-key*)
2374       (evil-define-key*
2375        'motion map
2376        (kbd "TAB") 'elpher-next-link
2377        (kbd "C-") 'elpher-follow-current-link
2378        (kbd "C-t") 'elpher-back
2379        (kbd "u") 'elpher-back
2380        (kbd "-") 'elpher-back
2381        (kbd "^") 'elpher-back
2382        [mouse-3] 'elpher-back
2383        (kbd "U") 'elpher-back-to-start
2384        (kbd "g") 'elpher-go
2385        (kbd "o") 'elpher-go-current
2386        (kbd "O") 'elpher-root-dir
2387        (kbd "s") 'elpher-show-history
2388        (kbd "S") 'elpher-show-visited-pages
2389        (kbd "r") 'elpher-redraw
2390        (kbd "R") 'elpher-reload
2391        (kbd "T") 'elpher-toggle-tls
2392        (kbd ".") 'elpher-view-raw
2393        (kbd "d") 'elpher-download
2394        (kbd "D") 'elpher-download-current
2395        (kbd "m") 'elpher-jump
2396        (kbd "i") 'elpher-info-link
2397        (kbd "I") 'elpher-info-current
2398        (kbd "c") 'elpher-copy-link-url
2399        (kbd "C") 'elpher-copy-current-url
2400        (kbd "a") 'elpher-bookmark-link
2401        (kbd "A") 'elpher-bookmark-current
2402        (kbd "B") 'elpher-show-bookmarks
2403        (kbd "!") 'elpher-set-gopher-coding-system
2404        (kbd "F") 'elpher-forget-current-certificate))
2405     map)
2406   "Keymap for gopher client.")
2407
2408 (define-derived-mode elpher-mode special-mode "elpher"
2409   "Major mode for elpher, an elisp gopher client.
2410
2411 This mode is automatically enabled by the interactive
2412 functions which initialize the client, namely
2413 `elpher', and `elpher-go'."
2414   (setq-local elpher-current-page nil)
2415   (setq-local elpher-history nil)
2416   (setq-local elpher-buffer-name (buffer-name))
2417   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2418   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2419
2420 (when (fboundp 'evil-set-initial-state)
2421   (evil-set-initial-state 'elpher-mode 'motion))
2422
2423
2424 ;;; Main start procedure
2425 ;;
2426
2427 ;;;###autoload
2428 (defun elpher (&optional arg)
2429   "Start elpher with default landing page.
2430 The buffer used for Elpher sessions is determined by the value of
2431 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2432 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2433 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2434 \\[execute-extended-command] elpher RET’) switches to the session with
2435 that number, creating it if necessary.  A non numeric prefix ARG means
2436 to create a new session.  Returns the buffer selected (or created)."
2437   (interactive "P")
2438   (let* ((name (default-value 'elpher-buffer-name))
2439          (buf (cond ((numberp arg)
2440                      (get-buffer-create (format "%s<%d>" name arg)))
2441                     (arg
2442                      (generate-new-buffer name))
2443                     (t
2444                      (get-buffer-create name)))))
2445     (pop-to-buffer-same-window buf)
2446     (unless (buffer-modified-p)
2447       (elpher-mode)
2448       (elpher-visit-page (elpher-make-start-page))
2449       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2450
2451 ;;; elpher.el ends here