elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.7.8
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "2.7.8"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  98     ((special start) elpher-get-start-page nil))
  99   "Association list from types to getters, renderers, margin codes and index faces.")
 100
 101
 102 ;;; Customization group
 103 ;;
 104
 105 (defgroup elpher nil
 106   "A gopher client."
 107   :group 'applications)
 108
 109 ;; General appearance and customizations
 110
 111 (defcustom elpher-open-urls-with-eww nil
 112   "If non-nil, open URL selectors using eww.
 113 Otherwise, use the system browser via the BROWSE-URL function."
 114   :type '(boolean))
 115
 116 (defcustom elpher-use-header t
 117   "If non-nil, display current page information in buffer header."
 118   :type '(boolean))
 119
 120 (defcustom elpher-auto-disengage-TLS nil
 121   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 122 While enabling this may seem convenient, it is also potentially dangerous as it
 123 allows switching from an encrypted channel back to plain text without user input."
 124   :type '(boolean))
 125
 126 (defcustom elpher-connection-timeout 5
 127   "Specifies the number of seconds to wait for a network connection to time out."
 128   :type '(integer))
 129
 130 (defcustom elpher-filter-ansi-from-text nil
 131   "If non-nil, filter ANSI escape sequences from text.
 132 The default behaviour is to use the ansi-color package to interpret these
 133 sequences."
 134   :type '(boolean))
 135
 136 (defcustom elpher-gemini-TLS-cert-checks nil
 137   "If non-nil, verify gemini server TLS certs using the default security level.
 138 Otherwise, certificate verification is disabled.
 139
 140 This defaults to off because it is standard practice for Gemini servers
 141 to use self-signed certificates, meaning that most servers provide what
 142 EMACS considers to be an invalid certificate."
 143   :type '(boolean))
 144
 145 (defcustom elpher-gemini-max-fill-width 80
 146   "Specify the maximum default width (in columns) of text/gemini documents.
 147 The actual width used is the minimum of this value and the window width at
 148 the time when the text is rendered."
 149   :type '(integer))
 150
 151 (defcustom elpher-gemini-link-string "→ "
 152   "Specify the string used to indicate links when rendering gemini maps.
 153 May be empty."
 154   :type '(string))
 155
 156 (defcustom elpher-gemini-bullet-string "•"
 157   "Specify the string used for bullets when rendering gemini maps."
 158   :type '(string))
 159
 160 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 161   "Specify the name of the file where elpher bookmarks will be saved."
 162   :type '(file))
 163
 164 ;; Face customizations
 165
 166 (defgroup elpher-faces nil
 167   "Elpher face customizations."
 168   :group 'elpher)
 169
 170 (defface elpher-index
 171   '((t :inherit font-lock-keyword-face))
 172   "Face used for directory type directory records.")
 173
 174 (defface elpher-text
 175   '((t :inherit bold))
 176   "Face used for text type directory records.")
 177
 178 (defface elpher-info
 179   '((t :inherit default))
 180   "Face used for info type directory records.")
 181
 182 (defface elpher-image
 183   '((t :inherit font-lock-string-face))
 184   "Face used for image type directory records.")
 185
 186 (defface elpher-search
 187   '((t :inherit warning))
 188   "Face used for search type directory records.")
 189
 190 (defface elpher-html
 191   '((t :inherit font-lock-comment-face))
 192   "Face used for html type directory records.")
 193
 194 (defface elpher-gemini
 195   '((t :inherit font-lock-regexp-grouping-backslash))
 196   "Face used for Gemini type directory records.")
 197
 198 (defface elpher-other-url
 199   '((t :inherit font-lock-comment-face))
 200   "Face used for other URL type links records.")
 201
 202 (defface elpher-telnet
 203   '((t :inherit font-lock-function-name-face))
 204   "Face used for telnet type directory records.")
 205
 206 (defface elpher-binary
 207   '((t :inherit font-lock-doc-face))
 208   "Face used for binary type directory records.")
 209
 210 (defface elpher-unknown
 211   '((t :inherit error))
 212   "Face used for directory records with unknown/unsupported types.")
 213
 214 (defface elpher-margin-key
 215   '((t :inherit bold))
 216   "Face used for directory margin key.")
 217
 218 (defface elpher-margin-brackets
 219   '((t :inherit shadow))
 220   "Face used for brackets around directory margin key.")
 221
 222 (defface elpher-gemini-heading1
 223   '((t :inherit bold :height 1.8))
 224   "Face used for gemini heading level 1.")
 225
 226 (defface elpher-gemini-heading2
 227   '((t :inherit bold :height 1.5))
 228   "Face used for gemini heading level 2.")
 229
 230 (defface elpher-gemini-heading3
 231   '((t :inherit bold :height 1.2))
 232   "Face used for gemini heading level 3.")
 233
 234 (defface elpher-gemini-preformatted
 235   '((t :inherit fixed-pitch))
 236   "Face used for pre-formatted gemini text blocks.")
 237
 238 ;;; Model
 239 ;;
 240
 241 ;; Address
 242
 243 ;; An elpher "address" object is either a url object or a symbol.
 244 ;; Symbol addresses are "special", corresponding to pages generated
 245 ;; dynamically for and by elpher.  All others represent pages which
 246 ;; rely on content retrieved over the network.
 247
 248 (defun elpher-address-from-url (url-string)
 249   "Create a ADDRESS object corresponding to the given URL-STRING."
 250   (let ((data (match-data))) ; Prevent parsing clobbering match data
 251     (unwind-protect
 252         (let ((url (url-generic-parse-url url-string)))
 253           (unless (and (not (url-fullness url)) (url-type url))
 254             (setf (url-fullness url) t)
 255             (setf (url-filename url)
 256                   (url-unhex-string (url-filename url)))
 257             (unless (url-type url)
 258               (setf (url-type url) "gopher"))
 259             (when (or (equal "gopher" (url-type url))
 260                       (equal "gophers" (url-type url)))
 261               ;; Gopher defaults
 262               (unless (url-host url)
 263                 (setf (url-host url) (url-filename url))
 264                 (setf (url-filename url) ""))
 265               (when (or (equal (url-filename url) "")
 266                         (equal (url-filename url) "/"))
 267                 (setf (url-filename url) "/1")))
 268             (when (equal "gemini" (url-type url))
 269               ;; Gemini defaults
 270               (if (equal (url-filename url) "")
 271                   (setf (url-filename url) "/"))))
 272           url)
 273       (set-match-data data))))
 274
 275 (defun elpher-make-gopher-address (type selector host port &optional tls)
 276   "Create an ADDRESS object using gopher directory record attributes.
 277 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 278 If the optional attribute TLS is non-nil, the address will be marked as
 279 requiring gopher-over-TLS."
 280   (cond
 281    ((equal type ?i) nil)
 282    ((and (equal type ?h)
 283          (string-prefix-p "URL:" selector))
 284     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 285    ((equal type ?8)
 286     (elpher-address-from-url
 287      (concat "telnet"
 288              "://" host
 289              ":" (number-to-string port))))
 290    (t
 291     (elpher-address-from-url
 292      (concat "gopher" (if tls "s" "")
 293              "://" host
 294              ":" (number-to-string port)
 295              "/" (string type)
 296              selector)))))
 297
 298 (defun elpher-make-special-address (type)
 299   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 300   type)
 301
 302 (defun elpher-address-to-url (address)
 303   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 304   (if (not (elpher-address-special-p address))
 305       (url-encode-url (url-recreate-url address))
 306     nil))
 307
 308 (defun elpher-address-type (address)
 309   "Retrieve type of ADDRESS object.
 310 This is used to determine how to retrieve and render the document the
 311 address refers to, via the table `elpher-type-map'."
 312   (if (symbolp address)
 313       (list 'special address)
 314     (let ((protocol (url-type address)))
 315       (cond ((or (equal protocol "gopher")
 316                  (equal protocol "gophers"))
 317              (list 'gopher
 318                    (if (member (url-filename address) '("" "/"))
 319                        ?1
 320                      (string-to-char (substring (url-filename address) 1)))))
 321             ((equal protocol "gemini")
 322              'gemini)
 323             ((equal protocol "telnet")
 324              'telnet)
 325             ((equal protocol "finger")
 326              'finger)
 327             (t 'other-url)))))
 328
 329 (defun elpher-address-protocol (address)
 330   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 331   (if (symbolp address)
 332       nil
 333     (url-type address)))
 334
 335 (defun elpher-address-filename (address)
 336   "Retrieve the filename component of ADDRESS.
 337 For gopher addresses this is a combination of the selector type and selector."
 338   (if (symbolp address)
 339       nil
 340     (url-filename address)))
 341
 342 (defun elpher-address-host (address)
 343   "Retrieve host from ADDRESS object."
 344   (url-host address))
 345
 346 (defun elpher-address-user (address)
 347   "Retrieve user from ADDRESS object."
 348   (url-user address))
 349
 350 (defun elpher-address-port (address)
 351   "Retrieve port from ADDRESS object.
 352 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 353   (if (symbolp address)
 354       0
 355     (url-port address)))
 356
 357 (defun elpher-address-special-p (address)
 358   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 359   (symbolp address))
 360
 361 (defun elpher-address-gopher-p (address)
 362   "Return non-nill if ADDRESS object is a gopher address."
 363   (and (not (elpher-address-special-p address))
 364        (member (elpher-address-protocol address) '("gopher gophers"))))
 365
 366 (defun elpher-gopher-address-selector (address)
 367   "Retrieve gopher selector from ADDRESS object."
 368   (if (member (url-filename address) '("" "/"))
 369       ""
 370     (url-unhex-string (substring (url-filename address) 2))))
 371
 372
 373 ;; Cache
 374
 375 (defvar elpher-content-cache (make-hash-table :test 'equal))
 376 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 377
 378 (defun elpher-get-cached-content (address)
 379   "Retrieve the cached content for ADDRESS, or nil if none exists."
 380   (gethash address elpher-content-cache))
 381
 382 (defun elpher-cache-content (address content)
 383   "Set the content cache for ADDRESS to CONTENT."
 384   (puthash address content elpher-content-cache))
 385
 386 (defun elpher-get-cached-pos (address)
 387   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 388   (gethash address elpher-pos-cache))
 389
 390 (defun elpher-cache-pos (address pos)
 391   "Set the cursor position cache for ADDRESS to POS."
 392   (puthash address pos elpher-pos-cache))
 393
 394
 395 ;; Page
 396
 397 (defun elpher-make-page (display-string address)
 398   "Create a page with DISPLAY-STRING and ADDRESS."
 399   (list display-string address))
 400
 401 (defun elpher-page-display-string (page)
 402   "Retrieve the display string corresponding to PAGE."
 403   (elt page 0))
 404
 405 (defun elpher-page-address (page)
 406   "Retrieve the address corresponding to PAGE."
 407   (elt page 1))
 408
 409 (defun elpher-page-set-address (page new-address)
 410   "Set the address corresponding to PAGE to NEW-ADDRESS."
 411   (setcar (cdr page) new-address))
 412
 413 (defvar elpher-current-page nil)
 414 (defvar elpher-history nil)
 415
 416 (defun elpher-visit-page (page &optional renderer no-history)
 417   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 418 Additionally, push PAGE onto the stack of previously-visited pages,
 419 unless NO-HISTORY is non-nil."
 420   (elpher-save-pos)
 421   (elpher-process-cleanup)
 422   (unless (or no-history
 423               (equal (elpher-page-address elpher-current-page)
 424                      (elpher-page-address page)))
 425     (push elpher-current-page elpher-history))
 426   (setq elpher-current-page page)
 427   (let* ((address (elpher-page-address page))
 428          (type (elpher-address-type address))
 429          (type-record (cdr (assoc type elpher-type-map))))
 430     (if type-record
 431         (funcall (car type-record)
 432                  (if renderer
 433                      renderer
 434                    (cadr type-record)))
 435       (elpher-visit-previous-page)
 436       (pcase type
 437         (`(gopher ,type-char)
 438          (error "Unsupported gopher selector type '%c' for '%s'"
 439                 type-char (elpher-address-to-url address)))
 440         (other
 441          (error "Unsupported address type '%S' for '%s'"
 442                 other (elpher-address-to-url address)))))))
 443
 444 (defun elpher-visit-previous-page ()
 445   "Visit the previous page in the history."
 446   (let ((previous-page (pop elpher-history)))
 447     (if previous-page
 448         (elpher-visit-page previous-page nil t)
 449       (error "No previous page"))))
 450
 451 (defun elpher-reload-current-page ()
 452   "Reload the current page, discarding any existing cached content."
 453   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 454   (elpher-visit-page elpher-current-page))
 455
 456 (defun elpher-save-pos ()
 457   "Save the current position of point to the current page."
 458   (when elpher-current-page
 459     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 460
 461 (defun elpher-restore-pos ()
 462   "Restore the position of point to that cached in the current page."
 463   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 464     (if pos
 465         (goto-char pos)
 466       (goto-char (point-min)))))
 467
 468
 469 ;;; Buffer preparation
 470 ;;
 471
 472 (defun elpher-update-header ()
 473   "If `elpher-use-header' is true, display current page info in window header."
 474   (if elpher-use-header
 475       (let* ((display-string (elpher-page-display-string elpher-current-page))
 476              (address (elpher-page-address elpher-current-page))
 477              (tls-string (if (and (not (elpher-address-special-p address))
 478                                   (member (elpher-address-protocol address)
 479                                           '("gophers" "gemini")))
 480                              " [TLS encryption]"
 481                            ""))
 482              (header (concat display-string
 483                              (propertize tls-string 'face 'bold))))
 484         (setq header-line-format header))))
 485
 486 (defmacro elpher-with-clean-buffer (&rest args)
 487   "Evaluate ARGS with a clean *elpher* buffer as current."
 488   (list 'with-current-buffer "*elpher*"
 489         '(elpher-mode)
 490         (append (list 'let '((inhibit-read-only t))
 491                       '(setq-local network-security-level
 492                                    (default-value 'network-security-level))
 493                       '(erase-buffer)
 494                       '(elpher-update-header))
 495                 args)))
 496
 497
 498 ;;; Text Processing
 499 ;;
 500
 501 (defvar elpher-user-coding-system nil
 502   "User-specified coding system to use for decoding text responses.")
 503
 504 (defun elpher-decode (string)
 505   "Decode STRING using autodetected or user-specified coding system."
 506   (decode-coding-string string
 507                         (if elpher-user-coding-system
 508                             elpher-user-coding-system
 509                           (detect-coding-string string t))))
 510
 511 (defun elpher-preprocess-text-response (string)
 512   "Preprocess text selector response contained in STRING.
 513 This involes decoding the character representation, and clearing
 514 away CRs and any terminating period."
 515   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 516                                            (replace-regexp-in-string "\r" "" string))))
 517
 518
 519 ;;; Network error reporting
 520 ;;
 521
 522 (defun elpher-network-error (address error)
 523   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 524 ERROR can be either an error object or a string."
 525   (elpher-with-clean-buffer
 526    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 527            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 528            (if (stringp error) error (error-message-string error)) "\n"
 529            (propertize "\n----------------\n\n" 'face 'error)
 530            "Press 'u' to return to the previous page.")))
 531
 532
 533 ;;; Gopher selector retrieval
 534 ;;
 535
 536 (defvar elpher-network-timer nil
 537   "Timer used for network connections.")
 538
 539 (defun elpher-process-cleanup ()
 540   "Immediately shut down any extant elpher process and timers."
 541   (let ((p (get-process "elpher-process")))
 542     (if p (delete-process p)))
 543   (if (timerp elpher-network-timer)
 544       (cancel-timer elpher-network-timer)))
 545
 546 (defvar elpher-use-tls nil
 547   "If non-nil, use TLS to communicate with gopher servers.")
 548
 549 (defun elpher-get-selector (address renderer &optional force-ipv4)
 550   "Retrieve selector specified by ADDRESS, then render it using RENDERER.
 551 If FORCE-IPV4 is non-nil, explicitly look up and use IPv4 address corresponding
 552 to ADDRESS."
 553   (when (equal (elpher-address-protocol address) "gophers")
 554     (if (gnutls-available-p)
 555         (when (not elpher-use-tls)
 556           (setq elpher-use-tls t)
 557           (message "Engaging TLS gopher mode."))
 558       (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 559   (unless (< (elpher-address-port address) 65536)
 560     (error "Cannot retrieve gopher selector: port number > 65536"))
 561   (condition-case nil
 562       (let* ((kill-buffer-query-functions nil)
 563              (gnutls-verify-error nil) ; We use the NSM for verification
 564              (port (elpher-address-port address))
 565              (host (elpher-address-host address))
 566              (selector-string-parts nil)
 567              (bytes-received 0)
 568              (hkbytes-received 0)
 569              (proc (open-network-stream "elpher-process"
 570                                         nil
 571                                         (if force-ipv4 (dns-query host) host)
 572                                         (if (> port 0) port 70)
 573                                         :type (if elpher-use-tls 'tls 'plain)
 574                                         :nowait t))
 575              (timer (run-at-time elpher-connection-timeout
 576                                  nil
 577                                  (lambda ()
 578                                    (pcase (process-status proc)
 579                                      ('failed
 580                                       (if (and (not (equal (elpher-address-protocol address)
 581                                                            "gophers"))
 582                                                elpher-use-tls
 583                                                (or elpher-auto-disengage-TLS
 584                                                    (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode?")))
 585                                           (progn
 586                                             (message "Disabling TLS mode.")
 587                                             (setq elpher-use-tls nil)
 588                                             (elpher-get-selector address renderer))
 589                                         (elpher-network-error address "Could not establish encrypted connection")))
 590                                      ('connect
 591                                       (elpher-process-cleanup)
 592                                       (unless force-ipv4
 593                                         (message "Connection timed out. Retrying with IPv4 address.")
 594                                         (elpher-get-selector address renderer t))))))))
 595         (setq elpher-network-timer timer)
 596         (set-process-coding-system proc 'binary)
 597         (set-process-filter proc
 598                             (lambda (_proc string)
 599                               (when timer
 600                                 (cancel-timer timer)
 601                                 (setq timer nil))
 602                               (setq bytes-received (+ bytes-received (length string)))
 603                               (let ((new-hkbytes-received (/ bytes-received 102400)))
 604                                 (when (> new-hkbytes-received hkbytes-received)
 605                                   (setq hkbytes-received new-hkbytes-received)
 606                                   (with-current-buffer "*elpher*"
 607                                     (let ((inhibit-read-only t))
 608                                       (goto-char (point-min))
 609                                       (beginning-of-line 2)
 610                                       (delete-region (point) (point-max))
 611                                       (insert "("
 612                                               (number-to-string (/ hkbytes-received 10.0))
 613                                               " MB read)")))))
 614                               (setq selector-string-parts
 615                                     (cons string selector-string-parts))))
 616         (set-process-sentinel proc
 617                               (lambda (_proc event)
 618                                 (condition-case the-error
 619                                     (cond
 620                                      ((string-prefix-p "deleted" event))
 621                                      ((string-prefix-p "open" event)
 622                                       (let ((inhibit-eol-conversion t))
 623                                         (process-send-string
 624                                          proc
 625                                          (concat (elpher-gopher-address-selector address)
 626                                                  "\r\n"))))
 627                                      (t
 628                                       (when timer
 629                                         (cancel-timer timer)
 630                                         (setq timer nil))
 631                                       (funcall renderer (apply #'concat
 632                                                                (reverse selector-string-parts)))
 633                                       (elpher-restore-pos)))
 634                                   (error
 635                                    (elpher-network-error address the-error))))))
 636     (error
 637      (error "Error initiating connection to server"))))
 638
 639 (defun elpher-get-gopher-page (renderer)
 640   "Getter function for gopher pages.
 641 The RENDERER procedure is used to display the contents of the page
 642 once they are retrieved from the gopher server."
 643   (let* ((address (elpher-page-address elpher-current-page))
 644          (content (elpher-get-cached-content address)))
 645     (if (and content (funcall renderer nil))
 646         (elpher-with-clean-buffer
 647          (insert content)
 648          (elpher-restore-pos))
 649       (elpher-with-clean-buffer
 650        (insert "LOADING... (use 'u' to cancel)\n"))
 651       (condition-case the-error
 652           (elpher-get-selector address renderer)
 653         (error
 654          (elpher-network-error address the-error))))))
 655
 656 ;; Index rendering
 657
 658 (defun elpher-insert-index (string)
 659   "Insert the index corresponding to STRING into the current buffer."
 660   ;; Should be able to split directly on CRLF, but some non-conformant
 661   ;; LF-only servers sadly exist, hence the following.
 662   (let ((str-processed (elpher-preprocess-text-response string)))
 663     (dolist (line (split-string str-processed "\n"))
 664       (ignore-errors
 665         (unless (= (length line) 0)
 666           (let* ((type (elt line 0))
 667                  (fields (split-string (substring line 1) "\t"))
 668                  (display-string (elt fields 0))
 669                  (selector (elt fields 1))
 670                  (host (elt fields 2))
 671                  (port (if (elt fields 3)
 672                            (string-to-number (elt fields 3))
 673                          nil))
 674                  (address (elpher-make-gopher-address type selector host port)))
 675             (elpher-insert-index-record display-string address)))))))
 676
 677 (defun elpher-insert-margin (&optional type-name)
 678   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 679   (if type-name
 680       (progn
 681         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 682                         (concat
 683                          (propertize "[" 'face 'elpher-margin-brackets)
 684                          (propertize type-name 'face 'elpher-margin-key)
 685                          (propertize "]" 'face 'elpher-margin-brackets))))
 686         (insert " "))
 687     (insert (make-string elpher-margin-width ?\s))))
 688
 689 (defun elpher-page-button-help (page)
 690   "Return a string containing the help text for a button corresponding to PAGE."
 691   (let ((address (elpher-page-address page)))
 692     (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 693                                           address
 694                                         (elpher-address-to-url address)))))
 695
 696 (defun elpher-insert-index-record (display-string &optional address)
 697   "Function to insert an index record into the current buffer.
 698 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 699 If ADDRESS is not supplied or nil the record is rendered as an
 700 'information' line."
 701   (let* ((type (if address (elpher-address-type address) nil))
 702          (type-map-entry (cdr (assoc type elpher-type-map))))
 703     (if type-map-entry
 704         (let* ((margin-code (elt type-map-entry 2))
 705                (face (elt type-map-entry 3))
 706                (filtered-display-string (ansi-color-filter-apply display-string))
 707                (page (elpher-make-page filtered-display-string address)))
 708           (elpher-insert-margin margin-code)
 709           (insert-text-button filtered-display-string
 710                               'face face
 711                               'elpher-page page
 712                               'action #'elpher-click-link
 713                               'follow-link t
 714                               'help-echo (elpher-page-button-help page)))
 715       (pcase type
 716         ('nil ;; Information
 717          (elpher-insert-margin)
 718          (let ((propertized-display-string
 719                 (propertize display-string 'face 'elpher-info)))
 720            (insert (elpher-process-text-for-display propertized-display-string))))
 721         (`(gopher ,selector-type) ;; Unknown
 722          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 723          (insert (propertize display-string
 724                              'face 'elpher-unknown)))))
 725     (insert "\n")))
 726
 727 (defun elpher-click-link (button)
 728   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 729   (let ((page (button-get button 'elpher-page)))
 730     (elpher-visit-page page)))
 731
 732 (defun elpher-render-index (data &optional _mime-type-string)
 733   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 734   (elpher-with-clean-buffer
 735    (if (not data)
 736        t
 737      (elpher-insert-index data)
 738      (elpher-cache-content (elpher-page-address elpher-current-page)
 739                            (buffer-string)))))
 740
 741 ;; Text rendering
 742
 743 (defconst elpher-url-regex
 744   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 745   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 746
 747 (defun elpher-buttonify-urls (string)
 748   "Turn substrings which look like urls in STRING into clickable buttons."
 749   (with-temp-buffer
 750     (insert string)
 751     (goto-char (point-min))
 752     (while (re-search-forward elpher-url-regex nil t)
 753       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 754                                     (elpher-address-from-url (match-string 0)))))
 755           (make-text-button (match-beginning 0)
 756                             (match-end 0)
 757                             'elpher-page  page
 758                             'action #'elpher-click-link
 759                             'follow-link t
 760                             'help-echo (elpher-page-button-help page)
 761                             'face 'button)))
 762     (buffer-string)))
 763
 764 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 765   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 766
 767 (defun elpher-process-text-for-display (string)
 768   "Perform any desired processing of STRING prior to display as text.
 769 Currently includes buttonifying URLs and processing ANSI escape codes."
 770   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 771                              (ansi-color-filter-apply string)
 772                            (ansi-color-apply string))))
 773
 774 (defun elpher-render-text (data &optional _mime-type-string)
 775   "Render DATA as text.  MIME-TYPE-STRING is unused."
 776   (elpher-with-clean-buffer
 777    (if (not data)
 778        t
 779      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
 780      (elpher-cache-content
 781       (elpher-page-address elpher-current-page)
 782       (buffer-string)))))
 783
 784 ;; Image retrieval
 785
 786 (defun elpher-render-image (data &optional _mime-type-string)
 787   "Display DATA as image.  MIME-TYPE-STRING is unused."
 788   (if (not data)
 789       nil
 790     (if (display-images-p)
 791         (progn
 792           (let ((image (create-image
 793                         data
 794                         nil t)))
 795             (elpher-with-clean-buffer
 796              (insert-image image)
 797              (elpher-restore-pos))))
 798       (elpher-render-download data))))
 799
 800 ;; Search retrieval and rendering
 801
 802 (defun elpher-get-gopher-query-page (renderer)
 803   "Getter for gopher addresses requiring input.
 804 The response is rendered using the rendering function RENDERER."
 805    (let* ((address (elpher-page-address elpher-current-page))
 806           (content (elpher-get-cached-content address))
 807           (aborted t))
 808     (if (and content (funcall renderer nil))
 809         (elpher-with-clean-buffer
 810          (insert content)
 811          (elpher-restore-pos)
 812          (message "Displaying cached search results.  Reload to perform a new search."))
 813       (unwind-protect
 814           (let* ((query-string (read-string "Query: "))
 815                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 816                  (search-address (elpher-make-gopher-address ?1
 817                                                              query-selector
 818                                                              (elpher-address-host address)
 819                                                              (elpher-address-port address)
 820                                                              (equal (elpher-address-type address) "gophers"))))
 821             (setq aborted nil)
 822
 823             (elpher-with-clean-buffer
 824              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 825             (elpher-get-selector search-address renderer))
 826         (if aborted
 827             (elpher-visit-previous-page))))))
 828
 829 ;; Raw server response rendering
 830
 831 (defun elpher-render-raw (data &optional mime-type-string)
 832   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
 833   (if (not data)
 834       nil
 835     (elpher-with-clean-buffer
 836      (when mime-type-string
 837        (insert "MIME type specified by server: '" mime-type-string "'\n"))
 838      (insert data)
 839      (goto-char (point-min)))
 840     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 841
 842 ;; File save "rendering"
 843
 844 (defun elpher-render-download (data &optional _mime-type-string)
 845   "Save DATA to file.  MIME-TYPE-STRING is unused."
 846   (if (not data)
 847       nil
 848     (let* ((address (elpher-page-address elpher-current-page))
 849            (selector (if (elpher-address-gopher-p address)
 850                          (elpher-gopher-address-selector address)
 851                        (elpher-address-filename address))))
 852       (elpher-visit-previous-page) ; Do first in case of non-local exits.
 853       (let* ((filename-proposal (file-name-nondirectory selector))
 854              (filename (read-file-name "Download complete. Save file as: "
 855                                        nil nil nil
 856                                        (if (> (length filename-proposal) 0)
 857                                            filename-proposal
 858                                          "download.file"))))
 859         (let ((coding-system-for-write 'binary))
 860           (with-temp-file filename
 861             (insert data)))
 862         (message (format "Saved to file %s." filename))))))
 863
 864 ;; HTML rendering
 865
 866 (defun elpher-render-html (data &optional _mime-type-string)
 867   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 868   (elpher-with-clean-buffer
 869    (if (not data)
 870        t
 871      (let ((dom (with-temp-buffer
 872                   (insert data)
 873                   (libxml-parse-html-region (point-min) (point-max)))))
 874        (shr-insert-document dom)))))
 875
 876 ;; Gemini page retrieval
 877
 878 (defvar elpher-gemini-redirect-chain)
 879
 880 (defun elpher-get-gemini-response (address renderer &optional force-ipv4)
 881   "Retrieve gemini ADDRESS, then render using RENDERER.
 882 If FORCE-IPV4 is non-nil, explicitly look up and use IPv4 address corresponding
 883 to ADDRESS."
 884   (unless elpher-gemini-TLS-cert-checks
 885     (setq-local network-security-level 'low))
 886   (if (not (gnutls-available-p))
 887       (error "Cannot establish gemini connection: GnuTLS not available")
 888     (unless (< (elpher-address-port address) 65536)
 889       (error "Cannot establish gemini connection: port number > 65536"))
 890     (condition-case nil
 891         (let* ((kill-buffer-query-functions nil)
 892                (gnutls-verify-error nil) ; We use the NSM for verification
 893                (port (elpher-address-port address))
 894                (host (elpher-address-host address))
 895                (response-string-parts nil)
 896                (bytes-received 0)
 897                (hkbytes-received 0)
 898                (proc (open-network-stream "elpher-process"
 899                                           nil
 900                                           (if force-ipv4 (dns-query host) host)
 901                                           (if (> port 0) port 1965)
 902                                           :type 'tls
 903                                           :nowait t))
 904                (timer (run-at-time elpher-connection-timeout nil
 905                                    (lambda ()
 906                                      (elpher-process-cleanup)
 907                                      (unless force-ipv4
 908                                         ; Try again with IPv4
 909                                        (message "Connection timed out.  Retrying with IPv4.")
 910                                        (elpher-get-gemini-response address renderer t))))))
 911           (setq elpher-network-timer timer)
 912           (set-process-coding-system proc 'binary)
 913           (set-process-filter proc
 914                               (lambda (_proc string)
 915                                 (when timer
 916                                   (cancel-timer timer)
 917                                   (setq timer nil))
 918                                 (setq bytes-received (+ bytes-received (length string)))
 919                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 920                                   (when (> new-hkbytes-received hkbytes-received)
 921                                     (setq hkbytes-received new-hkbytes-received)
 922                                     (with-current-buffer "*elpher*"
 923                                       (let ((inhibit-read-only t))
 924                                         (goto-char (point-min))
 925                                         (beginning-of-line 2)
 926                                         (delete-region (point) (point-max))
 927                                         (insert "("
 928                                                 (number-to-string (/ hkbytes-received 10.0))
 929                                                 " MB read)")))))
 930                                 (setq response-string-parts
 931                                       (cons string response-string-parts))))
 932           (set-process-sentinel proc
 933                                 (lambda (proc event)
 934                                   (condition-case the-error
 935                                       (cond
 936                                        ((string-prefix-p "open" event)    ; request URL
 937                                         (let ((inhibit-eol-conversion t))
 938                                           (process-send-string
 939                                            proc
 940                                            (concat (elpher-address-to-url address)
 941                                                    "\r\n"))))
 942                                        ((string-prefix-p "deleted" event)) ; do nothing
 943                                        ((and (not response-string-parts)
 944                                              (not force-ipv4))
 945                                         ; Try again with IPv4
 946                                         (message "Connection failed. Retrying with IPv4.")
 947                                         (cancel-timer timer)
 948                                         (elpher-get-gemini-response address renderer t))
 949                                        (t
 950                                         (funcall #'elpher-process-gemini-response
 951                                                  (apply #'concat (reverse response-string-parts))
 952                                                  renderer)
 953                                         (elpher-restore-pos)))
 954                                     (error
 955                                      (elpher-network-error address the-error))))))
 956       (error
 957        (error "Error initiating connection to server")))))
 958
 959 (defun elpher-parse-gemini-response (response)
 960   "Parse the RESPONSE string and return a list of components.
 961 The list is of the form (code meta body).  A response of nil implies
 962 that the response was malformed."
 963   (let ((header-end-idx (string-match "\r\n" response)))
 964     (if header-end-idx
 965         (let ((header (string-trim (substring response 0 header-end-idx)))
 966               (body (substring response (+ header-end-idx 2))))
 967           (if (>= (length header) 2)
 968               (let ((code (substring header 0 2))
 969                     (meta (string-trim (substring header 2))))
 970                 (list code meta body))
 971             (error "Malformed response: No response status found in header %s" header)))
 972       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
 973
 974 (defun elpher-process-gemini-response (response-string renderer)
 975   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
 976   (let ((response-components (elpher-parse-gemini-response response-string)))
 977     (let ((response-code (elt response-components 0))
 978           (response-meta (elt response-components 1))
 979           (response-body (elt response-components 2)))
 980       (pcase (elt response-code 0)
 981         (?1 ; Input required
 982          (elpher-with-clean-buffer
 983           (insert "Gemini server is requesting input."))
 984          (let* ((query-string (read-string (concat response-meta ": ")))
 985                 (url (elpher-address-to-url (elpher-page-address elpher-current-page)))
 986                 (query-address (elpher-address-from-url (concat url "?" query-string))))
 987            (elpher-get-gemini-response query-address renderer)))
 988         (?2 ; Normal response
 989          (funcall renderer response-body response-meta))
 990         (?3 ; Redirect
 991          (message "Following redirect to %s" response-meta)
 992          (if (>= (length elpher-gemini-redirect-chain) 5)
 993              (error "More than 5 consecutive redirects followed"))
 994          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 995            (if (member redirect-address elpher-gemini-redirect-chain)
 996                (error "Redirect loop detected"))
 997            (if (not (string= (elpher-address-protocol redirect-address)
 998                              "gemini"))
 999                (error "Server tried to automatically redirect to non-gemini URL: %s"
1000                       response-meta))
1001            (elpher-page-set-address elpher-current-page redirect-address)
1002            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1003            (elpher-get-gemini-response redirect-address renderer)))
1004         (?4 ; Temporary failure
1005          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1006                 response-code response-meta))
1007         (?5 ; Permanent failure
1008          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1009                 response-code response-meta))
1010         (?6 ; Client certificate required
1011          (error "Gemini server requires client certificate (unsupported at this time)"))
1012         (_other
1013          (error "Gemini server response unknown: %s %s"
1014                 response-code response-meta))))))
1015
1016 (defun elpher-get-gemini-page (renderer)
1017   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1018   (let* ((address (elpher-page-address elpher-current-page))
1019          (content (elpher-get-cached-content address)))
1020     (condition-case the-error
1021         (if (and content (funcall renderer nil))
1022             (elpher-with-clean-buffer
1023               (insert content)
1024               (elpher-restore-pos))
1025           (elpher-with-clean-buffer
1026            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1027           (setq elpher-gemini-redirect-chain nil)
1028           (elpher-get-gemini-response address renderer))
1029       (error
1030        (elpher-network-error address the-error)))))
1031
1032
1033 (defun elpher-render-gemini (body &optional mime-type-string)
1034   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1035   (if (not body)
1036       t
1037     (let* ((mime-type-string* (if (or (not mime-type-string)
1038                                       (string-empty-p mime-type-string))
1039                                   "text/gemini; charset=utf-8"
1040                                 mime-type-string))
1041            (mime-type-split (split-string mime-type-string* ";" t))
1042            (mime-type (string-trim (car mime-type-split)))
1043            (parameters (mapcar (lambda (s)
1044                                  (let ((key-val (split-string s "=")))
1045                                    (list (downcase (string-trim (car key-val)))
1046                                          (downcase (string-trim (cadr key-val))))))
1047                                (cdr mime-type-split))))
1048       (when (string-prefix-p "text/" mime-type)
1049         (setq body (decode-coding-string
1050                     body
1051                     (if (assoc "charset" parameters)
1052                         (intern (cadr (assoc "charset" parameters)))
1053                       'utf-8)))
1054         (setq body (replace-regexp-in-string "\r" "" body)))
1055       (pcase mime-type
1056         ((or "text/gemini" "")
1057          (elpher-render-gemini-map body parameters))
1058         ("text/html"
1059          (elpher-render-html body))
1060         ((pred (string-prefix-p "text/"))
1061          (elpher-render-gemini-plain-text body parameters))
1062         ((pred (string-prefix-p "image/"))
1063          (elpher-render-image body))
1064         (_other
1065          (elpher-render-download body))))))
1066
1067 (defun elpher-gemini-get-link-url (link-line)
1068   "Extract the url portion of LINK-LINE, a gemini map file link line.
1069 Returns nil in the event that the contents of the line following the
1070 => prefix are empty."
1071   (let ((l (split-string (substring link-line 2))))
1072     (if l
1073         (string-trim (elt l 0))
1074       nil)))
1075
1076 (defun elpher-gemini-get-link-display-string (link-line)
1077   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1078 Returns the url portion in the event that the display-string portion is empty."
1079   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1080          (idx (string-match "[ \t]" rest)))
1081     (string-trim (if idx
1082                      (substring rest (+ idx 1))
1083                    rest))))
1084
1085 (defun elpher-collapse-dot-sequences (filename)
1086   "Collapse dot sequences in FILENAME.
1087 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1088   (let* ((path (split-string filename "/"))
1089          (path-reversed-normalized
1090           (seq-reduce (lambda (a b)
1091                         (cond ((and a (equal b "..") (cdr a)))
1092                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1093                               ((equal b ".") a)
1094                               (t (cons b a))))
1095                       path nil)))
1096     (string-join (reverse path-reversed-normalized) "/")))
1097
1098 (defun elpher-address-from-gemini-url (url)
1099   "Extract address from URL with defaults as per gemini map files."
1100   (let ((address (url-generic-parse-url url)))
1101     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1102       (setf (url-fullness address) t)
1103       (if (url-host address) ;if there is an explicit host, filenames are absolute
1104           (if (string-empty-p (url-filename address))
1105               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1106         (setf (url-host address) (url-host (elpher-page-address elpher-current-page)))
1107         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1108           (setf (url-filename address)
1109                 (concat (file-name-directory
1110                          (url-filename (elpher-page-address elpher-current-page)))
1111                         (url-filename address)))))
1112       (unless (url-type address)
1113         (setf (url-type address) "gemini"))
1114       (if (equal (url-type address) "gemini")
1115           (setf (url-filename address)
1116                 (elpher-collapse-dot-sequences (url-filename address)))))
1117     address))
1118
1119 (defun elpher-gemini-insert-link (link-line)
1120   "Insert link described by LINK-LINE into a text/gemini document."
1121   (let* ((url (elpher-gemini-get-link-url link-line))
1122          (display-string (elpher-gemini-get-link-display-string link-line))
1123          (address (elpher-address-from-gemini-url url))
1124          (type (if address (elpher-address-type address) nil))
1125          (type-map-entry (cdr (assoc type elpher-type-map))))
1126     (when display-string
1127       (insert elpher-gemini-link-string)
1128       (if type-map-entry
1129           (let* ((face (elt type-map-entry 3))
1130                  (filtered-display-string (ansi-color-filter-apply display-string))
1131                  (page (elpher-make-page filtered-display-string address)))
1132             (insert-text-button filtered-display-string
1133                                 'face face
1134                                 'elpher-page page
1135                                 'action #'elpher-click-link
1136                                 'follow-link t
1137                                 'help-echo (elpher-page-button-help page)))
1138         (insert (propertize display-string 'face 'elpher-unknown)))
1139       (insert "\n"))))
1140
1141 (defun elpher-gemini-insert-header (header-line)
1142   "Insert header described by HEADER-LINE into a text/gemini document.
1143 The gemini map file line describing the header is given
1144 by HEADER-LINE."
1145   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1146     (let ((level (length (match-string 1 header-line)))
1147           (header (substring header-line (match-end 0))))
1148       (unless (display-graphic-p)
1149         (insert (make-string level ?#) " "))
1150       (insert (propertize header 'face
1151                           (pcase level
1152                             (1 'elpher-gemini-heading1)
1153                             (2 'elpher-gemini-heading2)
1154                             (3 'elpher-gemini-heading3)
1155                             (_ 'default)))
1156               "\n"))))
1157
1158 (defun elpher-gemini-insert-text (text-line)
1159   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1160 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1161 width defined by elpher-gemini-max-fill-width."
1162   (string-match "\\(^[ \t]*\\)\\(\*[ \t]\\)?" text-line)
1163   (let* ((processed-text-line (if (match-string 2 text-line)
1164                                   (concat
1165                                    (replace-regexp-in-string "\*"
1166                                                              elpher-gemini-bullet-string
1167                                                              (match-string 0 text-line))
1168                                    (substring text-line (match-end 0)))
1169                                 text-line))
1170          (fill-prefix (if (match-string 1 text-line)
1171                           (replace-regexp-in-string "\*" " " (match-string 0 text-line))
1172                         nil)))
1173     (insert (elpher-process-text-for-display processed-text-line))
1174     (newline)))
1175
1176 (defun elpher-render-gemini-map (data _parameters)
1177   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1178   (elpher-with-clean-buffer
1179    (let ((preformatted nil))
1180      (auto-fill-mode 1)
1181      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1182      (dolist (line (split-string data "\n"))
1183        (cond
1184         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1185         (preformatted (insert (elpher-process-text-for-display
1186                                (propertize line 'face 'elpher-gemini-preformatted))
1187                               "\n"))
1188         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1189         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1190         (t (elpher-gemini-insert-text line)))))
1191    (elpher-cache-content
1192     (elpher-page-address elpher-current-page)
1193     (buffer-string))))
1194
1195 (defun elpher-render-gemini-plain-text (data _parameters)
1196   "Render DATA as plain text file.  PARAMETERS is currently unused."
1197   (elpher-with-clean-buffer
1198    (insert (elpher-process-text-for-display data))
1199    (elpher-cache-content
1200     (elpher-page-address elpher-current-page)
1201     (buffer-string))))
1202
1203 ;; Finger page connection
1204
1205 (defun elpher-get-finger-page (renderer &optional force-ipv4)
1206   "Opens a finger connection to the current page address and renders it using RENDERER."
1207   (let* ((address (elpher-page-address elpher-current-page))
1208          (content (elpher-get-cached-content address)))
1209     (if (and content (funcall renderer nil))
1210         (elpher-with-clean-buffer
1211          (insert content)
1212          (elpher-restore-pos))
1213       (elpher-with-clean-buffer
1214        (insert "LOADING... (use 'u' to cancel)\n"))
1215       (condition-case the-error
1216           (let* ((kill-buffer-query-functions nil)
1217                  (user (let ((filename (elpher-address-filename address)))
1218                          (if (> (length filename) 1)
1219                              (substring filename 1)
1220                            (elpher-address-user address))))
1221                  (port (let ((given-port (elpher-address-port address)))
1222                          (if (> given-port 0) given-port 79)))
1223                  (host (elpher-address-host address))
1224                  (selector-string-parts nil)
1225                  (proc (open-network-stream "elpher-process"
1226                                             nil
1227                                             (if force-ipv4 (dns-query host) host)
1228                                             port
1229                                             :type 'plain
1230                                             :nowait t))
1231                  (timer (run-at-time elpher-connection-timeout
1232                                      nil
1233                                      (lambda ()
1234                                        (pcase (process-status proc)
1235                                          ('connect
1236                                           (elpher-process-cleanup)
1237                                           (unless force-ipv4
1238                                             (message "Connection timed out. Retrying with IPv4 address.")
1239                                             (elpher-get-finger-page renderer t))))))))
1240             (setq elpher-network-timer timer)
1241             (set-process-coding-system proc 'binary)
1242             (set-process-filter proc
1243                                 (lambda (_proc string)
1244                                   (when timer
1245                                     (cancel-timer timer)
1246                                     (setq timer nil))
1247                                   (setq selector-string-parts
1248                                         (cons string selector-string-parts))))
1249             (set-process-sentinel proc
1250                                   (lambda (_proc event)
1251                                     (condition-case the-error
1252                                         (cond
1253                                          ((string-prefix-p "deleted" event))
1254                                          ((string-prefix-p "open" event)
1255                                           (let ((inhibit-eol-conversion t))
1256                                             (process-send-string
1257                                              proc
1258                                              (concat user "\r\n"))))
1259                                          (t
1260                                           (when timer
1261                                             (cancel-timer timer)
1262                                             (setq timer nil))
1263                                           (funcall renderer (apply #'concat
1264                                                                    (reverse selector-string-parts)))
1265                                           (elpher-restore-pos)))))))
1266         (error
1267          (elpher-network-error address the-error))))))
1268
1269
1270 ;; Other URL page opening
1271
1272 (defun elpher-get-other-url-page (renderer)
1273   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1274   (when renderer
1275     (elpher-visit-previous-page)
1276     (error "Command not supported for general URLs"))
1277   (let* ((address (elpher-page-address elpher-current-page))
1278          (url (elpher-address-to-url address)))
1279     (progn
1280       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1281       (message "Opening URL...")
1282       (if elpher-open-urls-with-eww
1283           (browse-web url)
1284         (browse-url url)))))
1285
1286 ;; Telnet page connection
1287
1288 (defun elpher-get-telnet-page (renderer)
1289   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1290   (when renderer
1291     (elpher-visit-previous-page)
1292     (error "Command not supported for telnet URLs"))
1293   (let* ((address (elpher-page-address elpher-current-page))
1294          (host (elpher-address-host address))
1295          (port (elpher-address-port address)))
1296     (elpher-visit-previous-page)
1297     (if (> port 0)
1298         (telnet host port)
1299       (telnet host))))
1300
1301 ;; Start page page retrieval
1302
1303 (defun elpher-get-start-page (renderer)
1304   "Getter which displays the start page (RENDERER must be nil)."
1305   (when renderer
1306     (elpher-visit-previous-page)
1307     (error "Command not supported for start page"))
1308   (elpher-with-clean-buffer
1309    (insert "     --------------------------------------------\n"
1310            "           Elpher Gopher and Gemini Client       \n"
1311            "                   version " elpher-version "\n"
1312            "     --------------------------------------------\n"
1313            "\n"
1314            "Default bindings:\n"
1315            "\n"
1316            " - TAB/Shift-TAB: next/prev item on current page\n"
1317            " - RET/mouse-1: open item under cursor\n"
1318            " - m: select an item on current page by name (autocompletes)\n"
1319            " - u/mouse-3: return to previous page\n"
1320            " - o/O: visit different selector or the root menu of the current server\n"
1321            " - g: go to a particular address (gopher, gemini, finger)\n"
1322            " - d/D: download item under cursor or current page\n"
1323            " - i/I: info on item under cursor or current page\n"
1324            " - c/C: copy URL representation of item under cursor or current page\n"
1325            " - a/A: bookmark the item under cursor or current page\n"
1326            " - x/X: remove bookmark for item under cursor or current page\n"
1327            " - B: visit the bookmarks page\n"
1328            " - r: redraw current page (using cached contents if available)\n"
1329            " - R: reload current page (regenerates cache)\n"
1330            " - S: set character coding system for gopher (default is to autodetect)\n"
1331            " - T: toggle TLS gopher mode\n"
1332            " - .: display the raw server response for the current page\n"
1333            "\n"
1334            "Start your exploration of gopher space and gemini:\n")
1335    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1336                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1337    (elpher-insert-index-record "Project Gemini home page"
1338                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1339    (insert "\n"
1340            "Alternatively, select a search engine and enter some search terms:\n")
1341    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1342                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1343    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1344                                (elpher-address-from-url "gemini://gus.guru/search"))
1345    (insert "\n"
1346            "This page contains your bookmarked sites (also visit with B):\n")
1347    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1348    (insert "\n"
1349            "For Elpher release news or to leave feedback, visit:\n")
1350    (elpher-insert-index-record "The Elpher Project Page"
1351                                (elpher-make-gopher-address ?1
1352                                                            "/projects/elpher/"
1353                                                            "thelambdalab.xyz"
1354                                                            70))
1355    (insert "\n"
1356            "** Refer to the ")
1357    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1358      (insert-text-button "Elpher info manual"
1359                          'face 'link
1360                          'action (lambda (_)
1361                                    (interactive)
1362                                    (info "(elpher)"))
1363                          'follow-link t
1364                          'help-echo help-string))
1365    (insert " for the full documentation. **\n")
1366    (insert (propertize
1367             (concat "  (This should be available if you have installed Elpher using\n"
1368                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1369             'face 'shadow))
1370    (elpher-restore-pos)))
1371
1372 ;; Bookmarks page page retrieval
1373
1374 (defun elpher-get-bookmarks-page (renderer)
1375   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1376   (when renderer
1377     (elpher-visit-previous-page)
1378     (error "Command not supported for bookmarks page"))
1379   (elpher-with-clean-buffer
1380    (insert "---- Bookmark list ----\n\n")
1381    (let ((bookmarks (elpher-load-bookmarks)))
1382      (if bookmarks
1383          (dolist (bookmark bookmarks)
1384            (let ((display-string (elpher-bookmark-display-string bookmark))
1385                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1386              (elpher-insert-index-record display-string address)))
1387        (insert "No bookmarks found.\n")))
1388    (insert "\n-----------------------\n"
1389            "\n"
1390            "- u: return to previous page\n"
1391            "- x: delete selected bookmark\n"
1392            "- a: rename selected bookmark\n"
1393            "\n"
1394            "Bookmarks are stored in the file ")
1395    (let ((filename elpher-bookmarks-file)
1396          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1397      (insert-text-button filename
1398                          'face 'link
1399                          'action (lambda (_)
1400                                    (interactive)
1401                                    (find-file filename))
1402                          'follow-link t
1403                          'help-echo help-string))
1404    (insert "\n")
1405    (elpher-restore-pos)))
1406
1407
1408 ;;; Bookmarks
1409 ;;
1410
1411 (defun elpher-make-bookmark (display-string url)
1412   "Make an elpher bookmark.
1413 DISPLAY-STRING determines how the bookmark will appear in the
1414 bookmark list, while URL is the url of the entry."
1415   (list display-string url))
1416
1417 (defun elpher-bookmark-display-string (bookmark)
1418   "Get the display string of BOOKMARK."
1419   (elt bookmark 0))
1420
1421 (defun elpher-set-bookmark-display-string (bookmark display-string)
1422   "Set the display string of BOOKMARK to DISPLAY-STRING."
1423   (setcar bookmark display-string))
1424
1425 (defun elpher-bookmark-url (bookmark)
1426   "Get the address for BOOKMARK."
1427   (elt bookmark 1))
1428
1429 (defun elpher-save-bookmarks (bookmarks)
1430   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1431 Beware that this completely replaces the existing contents of the file."
1432   (with-temp-file elpher-bookmarks-file
1433     (erase-buffer)
1434     (insert "; Elpher bookmarks file\n\n"
1435             "; Bookmarks are stored as a list of (label URL) items.\n"
1436             "; Feel free to edit by hand, but take care to ensure\n"
1437             "; the list structure remains intact.\n\n")
1438     (pp bookmarks (current-buffer))))
1439
1440 (defun elpher-load-bookmarks ()
1441   "Get the list of bookmarks from the users's bookmark file."
1442   (let ((bookmarks
1443          (with-temp-buffer
1444            (ignore-errors
1445              (insert-file-contents elpher-bookmarks-file)
1446              (goto-char (point-min))
1447              (read (current-buffer))))))
1448     (if (and bookmarks (listp (cadar bookmarks)))
1449         (progn
1450           (message "Reading old bookmark file. (Will be updated on write.)")
1451           (mapcar (lambda (old-bm)
1452                     (list (car old-bm)
1453                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1454                                                         (cadr old-bm)))))
1455                   bookmarks))
1456       bookmarks)))
1457
1458 (defun elpher-add-address-bookmark (address display-string)
1459   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1460 If ADDRESS is already bookmarked, update the label only."
1461   (let ((bookmarks (elpher-load-bookmarks))
1462         (url (elpher-address-to-url address)))
1463     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1464       (if existing-bookmark
1465           (elpher-set-bookmark-display-string existing-bookmark display-string)
1466         (push (elpher-make-bookmark display-string url) bookmarks)))
1467     (elpher-save-bookmarks bookmarks)))
1468
1469 (defun elpher-remove-address-bookmark (address)
1470   "Remove any bookmark to ADDRESS."
1471   (let ((url (elpher-address-to-url address)))
1472     (elpher-save-bookmarks
1473      (seq-filter (lambda (bookmark)
1474                    (not (equal (elpher-bookmark-url bookmark) url)))
1475                  (elpher-load-bookmarks)))))
1476
1477 ;;; Interactive procedures
1478 ;;
1479
1480 (defun elpher-next-link ()
1481   "Move point to the next link on the current page."
1482   (interactive)
1483   (forward-button 1))
1484
1485 (defun elpher-prev-link ()
1486   "Move point to the previous link on the current page."
1487   (interactive)
1488   (backward-button 1))
1489
1490 (defun elpher-follow-current-link ()
1491   "Open the link or url at point."
1492   (interactive)
1493   (push-button))
1494
1495 (defun elpher-go (host-or-url)
1496   "Go to a particular gopher site HOST-OR-URL.
1497 When run interactively HOST-OR-URL is read from the minibuffer."
1498   (interactive "sGopher or Gemini URL: ")
1499   (let ((page (elpher-make-page host-or-url
1500                                 (elpher-address-from-url host-or-url))))
1501     (switch-to-buffer "*elpher*")
1502     (elpher-visit-page page)
1503     '()))
1504
1505 (defun elpher-go-current ()
1506   "Go to a particular site read from the minibuffer, initialized with the current URL."
1507   (interactive)
1508   (let ((address (elpher-page-address elpher-current-page)))
1509     (if (elpher-address-special-p address)
1510         (error "Command invalid for this page")
1511       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1512         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1513
1514 (defun elpher-redraw ()
1515   "Redraw current page."
1516   (interactive)
1517   (elpher-visit-page elpher-current-page))
1518
1519 (defun elpher-reload ()
1520   "Reload current page."
1521   (interactive)
1522   (elpher-reload-current-page))
1523
1524 (defun elpher-toggle-tls ()
1525   "Toggle TLS encryption mode for gopher."
1526   (interactive)
1527   (setq elpher-use-tls (not elpher-use-tls))
1528   (if elpher-use-tls
1529       (if (gnutls-available-p)
1530           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1531         (setq elpher-use-tls nil)
1532         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1533     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1534
1535 (defun elpher-view-raw ()
1536   "View raw server response for current page."
1537   (interactive)
1538   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1539       (error "This page was not generated by a server")
1540     (elpher-visit-page elpher-current-page
1541                        #'elpher-render-raw)))
1542
1543 (defun elpher-back ()
1544   "Go to previous site."
1545   (interactive)
1546   (elpher-visit-previous-page))
1547
1548 (defun elpher-download ()
1549   "Download the link at point."
1550   (interactive)
1551   (let ((button (button-at (point))))
1552     (if button
1553         (let ((page (button-get button 'elpher-page)))
1554           (if (elpher-address-special-p (elpher-page-address page))
1555               (error "Cannot download %s"
1556                      (elpher-page-display-string page))
1557             (elpher-visit-page (button-get button 'elpher-page)
1558                                #'elpher-render-download)))
1559       (error "No link selected"))))
1560
1561 (defun elpher-download-current ()
1562   "Download the current page."
1563   (interactive)
1564   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1565       (error "Cannot download %s"
1566              (elpher-page-display-string elpher-current-page))
1567     (elpher-visit-page (elpher-make-page
1568                         (elpher-page-display-string elpher-current-page)
1569                         (elpher-page-address elpher-current-page))
1570                        #'elpher-render-download
1571                        t)))
1572
1573 (defun elpher-build-link-map ()
1574   "Build alist mapping link names to destination pages in current buffer."
1575   (let ((link-map nil)
1576         (b (next-button (point-min) t)))
1577     (while b
1578       (push (cons (button-label b) b) link-map)
1579       (setq b (next-button (button-start b))))
1580     link-map))
1581
1582 (defun elpher-jump ()
1583   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1584   (interactive)
1585   (let* ((link-map (elpher-build-link-map)))
1586     (if link-map
1587         (let ((key (let ((completion-ignore-case t))
1588                      (completing-read "Directory item/link: "
1589                                       link-map nil t))))
1590           (if (and key (> (length key) 0))
1591               (let ((b (cdr (assoc key link-map))))
1592                 (goto-char (button-start b))
1593                 (button-activate b)))))))
1594
1595 (defun elpher-root-dir ()
1596   "Visit root of current server."
1597   (interactive)
1598   (let ((address (elpher-page-address elpher-current-page)))
1599     (if (not (elpher-address-special-p address))
1600         (if (or (member (url-filename address) '("/" ""))
1601                 (and (elpher-address-gopher-p address)
1602                      (= (length (elpher-gopher-address-selector address)) 0)))
1603             (error "Already at root directory of current server")
1604           (let ((address-copy (elpher-address-from-url
1605                                (elpher-address-to-url address))))
1606             (setf (url-filename address-copy) "")
1607             (elpher-go (elpher-address-to-url address-copy))))
1608       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1609
1610 (defun elpher-bookmarks-current-p ()
1611   "Return non-nil if current page is a bookmarks page."
1612   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1613          '(special bookmarks)))
1614
1615 (defun elpher-reload-bookmarks ()
1616   "Reload bookmarks if current page is a bookmarks page."
1617   (if (elpher-bookmarks-current-p)
1618       (elpher-reload-current-page)))
1619
1620 (defun elpher-bookmark-current ()
1621   "Bookmark the current page."
1622   (interactive)
1623   (let ((address (elpher-page-address elpher-current-page))
1624         (display-string (elpher-page-display-string elpher-current-page)))
1625     (if (not (elpher-address-special-p address))
1626         (let ((bookmark-display-string (read-string "Bookmark display string: "
1627                                                     display-string)))
1628           (elpher-add-address-bookmark address bookmark-display-string)
1629           (message "Bookmark added."))
1630       (error "Cannot bookmark %s" display-string))))
1631
1632 (defun elpher-bookmark-link ()
1633   "Bookmark the link at point."
1634   (interactive)
1635   (let ((button (button-at (point))))
1636     (if button
1637         (let* ((page (button-get button 'elpher-page))
1638                (address (elpher-page-address page))
1639                (display-string (elpher-page-display-string page)))
1640           (if (not (elpher-address-special-p address))
1641               (let ((bookmark-display-string (read-string "Bookmark display string: "
1642                                                           display-string)))
1643                 (elpher-add-address-bookmark address bookmark-display-string)
1644                 (elpher-reload-bookmarks)
1645                 (message "Bookmark added."))
1646             (error "Cannot bookmark %s" display-string)))
1647       (error "No link selected"))))
1648
1649 (defun elpher-unbookmark-current ()
1650   "Remove bookmark for the current page."
1651   (interactive)
1652   (let ((address (elpher-page-address elpher-current-page)))
1653     (unless (elpher-address-special-p address)
1654       (elpher-remove-address-bookmark address)
1655       (message "Bookmark removed."))))
1656
1657 (defun elpher-unbookmark-link ()
1658   "Remove bookmark for the link at point."
1659   (interactive)
1660   (let ((button (button-at (point))))
1661     (if button
1662         (let ((page (button-get button 'elpher-page)))
1663           (elpher-remove-address-bookmark (elpher-page-address page))
1664           (elpher-reload-bookmarks)
1665           (message "Bookmark removed."))
1666       (error "No link selected"))))
1667
1668 (defun elpher-bookmarks ()
1669   "Visit bookmarks page."
1670   (interactive)
1671   (switch-to-buffer "*elpher*")
1672   (elpher-visit-page
1673    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1674
1675 (defun elpher-info-page (page)
1676   "Display information on PAGE."
1677   (let ((display-string (elpher-page-display-string page))
1678         (address (elpher-page-address page)))
1679     (if (elpher-address-special-p address)
1680         (message "Special page: %s" display-string)
1681       (message "%s" (elpher-address-to-url address)))))
1682
1683 (defun elpher-info-link ()
1684   "Display information on page corresponding to link at point."
1685   (interactive)
1686   (let ((button (button-at (point))))
1687     (if button
1688         (elpher-info-page (button-get button 'elpher-page))
1689       (error "No item selected"))))
1690
1691 (defun elpher-info-current ()
1692   "Display information on current page."
1693   (interactive)
1694   (elpher-info-page elpher-current-page))
1695
1696 (defun elpher-copy-page-url (page)
1697   "Copy URL representation of address of PAGE to `kill-ring'."
1698   (let ((address (elpher-page-address page)))
1699     (if (elpher-address-special-p address)
1700         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1701       (let ((url (elpher-address-to-url address)))
1702         (message "Copied \"%s\" to kill-ring/clipboard." url)
1703         (kill-new url)))))
1704
1705 (defun elpher-copy-link-url ()
1706   "Copy URL of item at point to `kill-ring'."
1707   (interactive)
1708   (let ((button (button-at (point))))
1709     (if button
1710         (elpher-copy-page-url (button-get button 'elpher-page))
1711       (error "No item selected"))))
1712
1713 (defun elpher-copy-current-url ()
1714   "Copy URL of current page to `kill-ring'."
1715   (interactive)
1716   (elpher-copy-page-url elpher-current-page))
1717
1718 (defun elpher-set-gopher-coding-system ()
1719   "Specify an explicit character coding system for gopher selectors."
1720   (interactive)
1721   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1722     (setq elpher-user-coding-system system)
1723     (if system
1724         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1725       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1726
1727
1728 ;;; Mode and keymap
1729 ;;
1730
1731 (defvar elpher-mode-map
1732   (let ((map (make-sparse-keymap)))
1733     (define-key map (kbd "TAB") 'elpher-next-link)
1734     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1735     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1736     (define-key map (kbd "u") 'elpher-back)
1737     (define-key map [mouse-3] 'elpher-back)
1738     (define-key map (kbd "O") 'elpher-root-dir)
1739     (define-key map (kbd "g") 'elpher-go)
1740     (define-key map (kbd "o") 'elpher-go-current)
1741     (define-key map (kbd "r") 'elpher-redraw)
1742     (define-key map (kbd "R") 'elpher-reload)
1743     (define-key map (kbd "T") 'elpher-toggle-tls)
1744     (define-key map (kbd ".") 'elpher-view-raw)
1745     (define-key map (kbd "d") 'elpher-download)
1746     (define-key map (kbd "D") 'elpher-download-current)
1747     (define-key map (kbd "m") 'elpher-jump)
1748     (define-key map (kbd "i") 'elpher-info-link)
1749     (define-key map (kbd "I") 'elpher-info-current)
1750     (define-key map (kbd "c") 'elpher-copy-link-url)
1751     (define-key map (kbd "C") 'elpher-copy-current-url)
1752     (define-key map (kbd "a") 'elpher-bookmark-link)
1753     (define-key map (kbd "A") 'elpher-bookmark-current)
1754     (define-key map (kbd "x") 'elpher-unbookmark-link)
1755     (define-key map (kbd "X") 'elpher-unbookmark-current)
1756     (define-key map (kbd "B") 'elpher-bookmarks)
1757     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1758     (when (fboundp 'evil-define-key*)
1759       (evil-define-key* 'motion map
1760         (kbd "TAB") 'elpher-next-link
1761         (kbd "C-") 'elpher-follow-current-link
1762         (kbd "C-t") 'elpher-back
1763         (kbd "u") 'elpher-back
1764         [mouse-3] 'elpher-back
1765         (kbd "g") 'elpher-go
1766         (kbd "o") 'elpher-go-current
1767         (kbd "r") 'elpher-redraw
1768         (kbd "R") 'elpher-reload
1769         (kbd "T") 'elpher-toggle-tls
1770         (kbd ".") 'elpher-view-raw
1771         (kbd "d") 'elpher-download
1772         (kbd "D") 'elpher-download-current
1773         (kbd "m") 'elpher-jump
1774         (kbd "i") 'elpher-info-link
1775         (kbd "I") 'elpher-info-current
1776         (kbd "c") 'elpher-copy-link-url
1777         (kbd "C") 'elpher-copy-current-url
1778         (kbd "a") 'elpher-bookmark-link
1779         (kbd "A") 'elpher-bookmark-current
1780         (kbd "x") 'elpher-unbookmark-link
1781         (kbd "X") 'elpher-unbookmark-current
1782         (kbd "B") 'elpher-bookmarks
1783         (kbd "S") 'elpher-set-gopher-coding-system))
1784     map)
1785   "Keymap for gopher client.")
1786
1787 (define-derived-mode elpher-mode special-mode "elpher"
1788   "Major mode for elpher, an elisp gopher client.
1789
1790 This mode is automatically enabled by the interactive
1791 functions which initialize the gopher client, namely
1792 `elpher', `elpher-go' and `elpher-bookmarks'.")
1793
1794 (when (fboundp 'evil-set-initial-state)
1795   (evil-set-initial-state 'elpher-mode 'motion))
1796
1797
1798 ;;; Main start procedure
1799 ;;
1800
1801 ;;;###autoload
1802 (defun elpher ()
1803   "Start elpher with default landing page."
1804   (interactive)
1805   (if (get-buffer "*elpher*")
1806       (switch-to-buffer "*elpher*")
1807     (switch-to-buffer "*elpher*")
1808     (setq elpher-current-page nil)
1809     (setq elpher-history nil)
1810     (let ((start-page (elpher-make-page "Elpher Start Page"
1811                                         (elpher-make-special-address 'start))))
1812       (elpher-visit-page start-page)))
1813   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1814
1815 ;;; elpher.el ends here