elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.2.2
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.2.2"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((about history) elpher-get-history-page nil "E" elpher-index)
 116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page-url "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen is \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 232
 233 Beware that using \"about:bookmarks\" as a start page in combination with
 234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 236 the start page."
 237   :type '(string))
 238
 239 ;; Face customizations
 240
 241 (defgroup elpher-faces nil
 242   "Elpher face customizations."
 243   :group 'elpher)
 244
 245 (defface elpher-index
 246   '((t :inherit font-lock-keyword-face))
 247   "Face used for directory type directory records.")
 248
 249 (defface elpher-text
 250   '((t :inherit bold))
 251   "Face used for text type directory records.")
 252
 253 (defface elpher-info
 254   '((t :inherit default))
 255   "Face used for info type directory records.")
 256
 257 (defface elpher-image
 258   '((t :inherit font-lock-string-face))
 259   "Face used for image type directory records.")
 260
 261 (defface elpher-search
 262   '((t :inherit warning))
 263   "Face used for search type directory records.")
 264
 265 (defface elpher-html
 266   '((t :inherit font-lock-comment-face))
 267   "Face used for html type directory records.")
 268
 269 (defface elpher-gemini
 270   '((t :inherit font-lock-constant-face))
 271   "Face used for Gemini type directory records.")
 272
 273 (defface elpher-other-url
 274   '((t :inherit font-lock-comment-face))
 275   "Face used for other URL type links records.")
 276
 277 (defface elpher-telnet
 278   '((t :inherit font-lock-function-name-face))
 279   "Face used for telnet type directory records.")
 280
 281 (defface elpher-binary
 282   '((t :inherit font-lock-doc-face))
 283   "Face used for binary type directory records.")
 284
 285 (defface elpher-unknown
 286   '((t :inherit error))
 287   "Face used for directory records with unknown/unsupported types.")
 288
 289 (defface elpher-margin-key
 290   '((t :inherit bold))
 291   "Face used for directory margin key.")
 292
 293 (defface elpher-margin-brackets
 294   '((t :inherit shadow))
 295   "Face used for brackets around directory margin key.")
 296
 297 (defface elpher-gemini-heading1
 298   '((t :inherit bold :height 1.8))
 299   "Face used for gemini heading level 1.")
 300
 301 (defface elpher-gemini-heading2
 302   '((t :inherit bold :height 1.5))
 303   "Face used for gemini heading level 2.")
 304
 305 (defface elpher-gemini-heading3
 306   '((t :inherit bold :height 1.2))
 307   "Face used for gemini heading level 3.")
 308
 309 (defface elpher-gemini-preformatted
 310   '((t :inherit fixed-pitch))
 311   "Face used for pre-formatted gemini text blocks.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 ;;; Model
 318 ;;
 319
 320 ;; Address
 321
 322 ;; An elpher "address" object is either a url object or a symbol.
 323 ;; Addresses with the "about" type, corresponding to pages generated
 324 ;; dynamically for and by elpher.  All others represent pages which
 325 ;; rely on content retrieved over the network.
 326
 327 (defun elpher-address-from-url (url-string &optional default-scheme)
 328   "Create a ADDRESS object corresponding to the given URL-STRING.
 329 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 330 is not explicitly given."
 331   (let ((data (match-data))) ; Prevent parsing clobbering match data
 332     (unwind-protect
 333         (let ((url (url-generic-parse-url url-string)))
 334           (unless (and (not (url-fullness url)) (url-type url))
 335             (setf (url-fullness url) t)
 336             (unless (url-type url)
 337               (setf (url-type url) default-scheme))
 338             (unless (url-host url)
 339               (let ((p (split-string (url-filename url) "/" nil nil)))
 340                 (setf (url-host url) (car p))
 341                 (setf (url-filename url)
 342                       (if (cdr p)
 343                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 344                         ""))))
 345             (when (url-host url)
 346               (setf (url-host url) (puny-encode-domain (url-host url))))
 347             (when (or (equal "gopher" (url-type url))
 348                       (equal "gophers" (url-type url)))
 349               ;; Gopher defaults
 350               (when (or (equal (url-filename url) "")
 351                         (equal (url-filename url) "/"))
 352                 (setf (url-filename url) "/1")))
 353             (when (equal "gemini" (url-type url))
 354               ;; Gemini defaults
 355               (if (equal (url-filename url) "")
 356                   (setf (url-filename url) "/"))))
 357           (elpher-remove-redundant-ports url))
 358       (set-match-data data))))
 359
 360 (defun elpher-remove-redundant-ports (address)
 361   "Remove redundant port specifiers from ADDRESS.
 362 Here 'redundant' means that the specified port matches the default
 363 for that protocol, eg 70 for gopher."
 364   (if (and (not (elpher-address-about-p address))
 365            (eq (url-portspec address) ; (url-port) is too slow!
 366                (pcase (url-type address)
 367                  ("gemini" 1965)
 368                  ((or "gopher" "gophers") 70)
 369                  ("finger" 79)
 370                  (_ -1))))
 371       (setf (url-portspec address) nil))
 372   address)
 373
 374 (defun elpher-make-gopher-address (type selector host port &optional tls)
 375   "Create an ADDRESS object using gopher directory record attributes.
 376 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 377 If the optional attribute TLS is non-nil, the address will be marked as
 378 requiring gopher-over-TLS."
 379   (cond
 380    ((equal type ?i) nil)
 381    ((and (equal type ?h)
 382          (string-prefix-p "URL:" selector))
 383     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 384    ((equal type ?8)
 385     (elpher-address-from-url
 386      (concat "telnet"
 387              "://" host
 388              ":" (number-to-string port))))
 389    (t
 390     (elpher-address-from-url
 391      (concat "gopher" (if tls "s" "")
 392              "://" host
 393              ":" (number-to-string port)
 394              "/" (string type)
 395              selector)))))
 396
 397 (defun elpher-make-about-address (type)
 398   "Create an ADDRESS object corresponding to the given about address TYPE."
 399   (elpher-address-from-url (concat "about:" (symbol-name type))))
 400
 401 (defun elpher-address-to-url (address)
 402   "Get string representation of ADDRESS."
 403   (url-encode-url (url-recreate-url address)))
 404
 405 (defun elpher-address-type (address)
 406   "Retrieve type of ADDRESS object.
 407 This is used to determine how to retrieve and render the document the
 408 address refers to, via the table `elpher-type-map'."
 409   (pcase (url-type address)
 410     ("about"
 411      (list 'about (intern (url-filename address))))
 412     ((or "gopher" "gophers")
 413      (list 'gopher
 414            (if (member (url-filename address) '("" "/"))
 415                ?1
 416              (string-to-char (substring (url-filename address) 1)))))
 417     ("gemini" 'gemini)
 418     ("telnet" 'telnet)
 419     ("finger" 'finger)
 420     ("file" 'file)
 421     (_ 'other-url)))
 422
 423 (defun elpher-address-about-p (address)
 424   "Return non-nil if ADDRESS is an  about address."
 425   (pcase (elpher-address-type address) (`(about ,_) t)))
 426
 427 (defun elpher-address-gopher-p (address)
 428   "Return non-nill if ADDRESS object is a gopher address."
 429   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 430
 431 (defun elpher-address-protocol (address)
 432   "Retrieve the transport protocol for ADDRESS."
 433   (url-type address))
 434
 435 (defun elpher-address-filename (address)
 436   "Retrieve the filename component of ADDRESS.
 437 For gopher addresses this is a combination of the selector type and selector."
 438   (url-unhex-string (url-filename address)))
 439
 440 (defun elpher-address-host (address)
 441   "Retrieve host from ADDRESS object."
 442   (url-host address))
 443
 444 (defun elpher-address-user (address)
 445   "Retrieve user from ADDRESS object."
 446   (url-user address))
 447
 448 (defun elpher-address-port (address)
 449   "Retrieve port from ADDRESS object.
 450 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 451   (url-port address))
 452
 453 (defun elpher-gopher-address-selector (address)
 454   "Retrieve gopher selector from ADDRESS object."
 455   (if (member (url-filename address) '("" "/"))
 456       ""
 457     (url-unhex-string (substring (url-filename address) 2))))
 458
 459
 460 ;; Cache
 461
 462 (defvar elpher-content-cache (make-hash-table :test 'equal))
 463 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 464
 465 (defun elpher-get-cached-content (address)
 466   "Retrieve the cached content for ADDRESS, or nil if none exists."
 467   (gethash address elpher-content-cache))
 468
 469 (defun elpher-cache-content (address content)
 470   "Set the content cache for ADDRESS to CONTENT."
 471   (puthash address content elpher-content-cache))
 472
 473 (defun elpher-get-cached-pos (address)
 474   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 475   (gethash address elpher-pos-cache))
 476
 477 (defun elpher-cache-pos (address pos)
 478   "Set the cursor position cache for ADDRESS to POS."
 479   (puthash address pos elpher-pos-cache))
 480
 481
 482 ;; Page
 483
 484 (defun elpher-make-page (display-string address)
 485   "Create a page with DISPLAY-STRING and ADDRESS."
 486   (list display-string address))
 487
 488 (defun elpher-make-start-page ()
 489   "Create the start page."
 490   (elpher-make-page "Start Page"
 491                     (elpher-address-from-url elpher-start-page-url)))
 492
 493 (defun elpher-page-display-string (page)
 494   "Retrieve the display string corresponding to PAGE."
 495   (elt page 0))
 496
 497 (defun elpher-page-address (page)
 498   "Retrieve the address corresponding to PAGE."
 499   (elt page 1))
 500
 501 (defun elpher-page-set-address (page new-address)
 502   "Set the address corresponding to PAGE to NEW-ADDRESS."
 503   (setcar (cdr page) new-address))
 504
 505 (defun elpher-page-from-url (url &optional default-scheme)
 506   "Create a page with address and display string defined by URL.
 507 The URL is unhexed prior to its use as a display string to improve
 508 readability.
 509
 510 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 511 in the instance that URL itself doesn't specify one."
 512   (let ((address (elpher-address-from-url url default-scheme)))
 513     (elpher-make-page (elpher-address-to-iri address) address)))
 514
 515 (defun elpher-address-to-iri (address)
 516   "Return an IRI for ADDRESS.
 517 Decode percent-escapes and handle punycode in the domain name.
 518 Drop the password, if any."
 519   (let ((data (match-data))) ; Prevent parsing clobbering match data
 520     (unwind-protect
 521         (let* ((host (url-host address))
 522                (pass (url-password address)))
 523           (when host
 524             (setf (url-host address) (puny-decode-domain host)))
 525           (when pass                             ; RFC 3986 says we should not render
 526             (setf (url-password address) nil)) ; the password as clear text
 527           (url-recreate-url address))
 528       (set-match-data data))))
 529
 530 (defvar elpher-current-page nil
 531   "The current page for this Elpher buffer.")
 532
 533 (defvar elpher-history nil
 534   "The local history stack for this Elpher buffer.
 535 This variable is used by `elpher-back' and
 536 `elpher-show-history'.")
 537
 538 (defvar elpher-visited-pages nil
 539   "The global history for all Elpher buffers.
 540 This variable is used by `elpher-show-visited-pages'.")
 541
 542 (defun elpher-visit-page (page &optional renderer no-history)
 543   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 544 Additionally, push PAGE onto the history stack and the list of
 545 previously-visited pages,unless NO-HISTORY is non-nil."
 546   (elpher-save-pos)
 547   (elpher-process-cleanup)
 548   (unless no-history
 549     (unless (or (not elpher-current-page)
 550                  (equal (elpher-page-address elpher-current-page)
 551                         (elpher-page-address page)))
 552       (push elpher-current-page elpher-history)
 553       (unless (or (elpher-address-about-p (elpher-page-address page))
 554                   (and elpher-visited-pages
 555                        (equal page (car elpher-visited-pages))))
 556         (push page elpher-visited-pages))))
 557   (setq-local elpher-current-page page)
 558   (let* ((address (elpher-page-address page))
 559          (type (elpher-address-type address))
 560          (type-record (cdr (assoc type elpher-type-map))))
 561     (if type-record
 562         (funcall (car type-record)
 563                  (if renderer
 564                      renderer
 565                    (cadr type-record)))
 566       (elpher-visit-previous-page)
 567       (pcase type
 568         (`(gopher ,type-char)
 569          (error "Unsupported gopher selector type '%c' for '%s'"
 570                 type-char (elpher-address-to-url address)))
 571         (other
 572          (error "Unsupported address type '%S' for '%s'"
 573                 other (elpher-address-to-url address)))))))
 574
 575 (defun elpher-visit-previous-page ()
 576   "Visit the previous page in the history."
 577   (if elpher-history
 578       (elpher-visit-page (pop elpher-history) nil t)
 579     (error "No previous page")))
 580
 581 (defun elpher-reload-current-page ()
 582   "Reload the current page, discarding any existing cached content."
 583   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 584   (elpher-visit-page elpher-current-page))
 585
 586 (defun elpher-save-pos ()
 587   "Save the current position of point to the current page."
 588   (when elpher-current-page
 589     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 590
 591 (defun elpher-restore-pos ()
 592   "Restore the position of point to that cached in the current page."
 593   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 594     (if pos
 595         (goto-char pos)
 596       (goto-char (point-min)))))
 597
 598 (defun elpher-get-default-url-scheme ()
 599   "Suggest a default URL scheme to use for visiting addresses based on the current page."
 600   (if elpher-current-page
 601       (let* ((address (elpher-page-address elpher-current-page))
 602              (current-type (elpher-address-type address)))
 603         (pcase current-type
 604           ((or (and 'file (guard (not elpher-history)))
 605                `(about ,_))
 606            elpher-default-url-type)
 607           (`(about ,_)
 608            elpher-default-url-type)
 609           (_
 610            (url-type address))))
 611       elpher-default-url-type))
 612
 613
 614 ;;; Buffer preparation
 615 ;;
 616
 617 (defvar elpher-buffer-name "*elpher*"
 618   "The default name of the Elpher buffer.")
 619
 620 (defun elpher-update-header ()
 621   "If `elpher-use-header' is true, display current page info in window header."
 622   (if (and elpher-use-header elpher-current-page)
 623       (let* ((display-string (elpher-page-display-string elpher-current-page))
 624              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 625              (address (elpher-page-address elpher-current-page))
 626              (tls-string (if (and (not (elpher-address-about-p address))
 627                                   (member (elpher-address-protocol address)
 628                                           '("gophers" "gemini")))
 629                              " [TLS encryption]"
 630                            ""))
 631              (header (concat sanitized-display-string
 632                              (propertize tls-string 'face 'bold))))
 633         (setq header-line-format header))))
 634
 635 (defmacro elpher-with-clean-buffer (&rest args)
 636   "Evaluate ARGS with a clean *elpher* buffer as current."
 637   (declare (debug (body))) ;; Allow edebug to step through body
 638   `(with-current-buffer elpher-buffer-name
 639      (unless (eq major-mode 'elpher-mode)
 640        ;; avoid resetting buffer-local variables
 641        (elpher-mode))
 642      (let ((inhibit-read-only t)
 643            (ansi-color-context nil)) ;; clean ansi interpreter state
 644        (setq-local network-security-level
 645                    (default-value 'network-security-level))
 646        (erase-buffer)
 647        (elpher-update-header)
 648        ,@args)))
 649
 650 (defun elpher-buffer-message (string &optional line)
 651   "Replace first line in elpher buffer with STRING.
 652 If LINE is non-nil, replace that line instead."
 653   (with-current-buffer elpher-buffer-name
 654     (let ((inhibit-read-only t))
 655       (goto-char (point-min))
 656       (if line
 657           (forward-line line))
 658       (let ((data (match-data)))
 659         (unwind-protect
 660             (progn
 661               (re-search-forward "^.*$")
 662               (replace-match string))
 663           (set-match-data data))))))
 664
 665
 666 ;;; Text Processing
 667 ;;
 668
 669 (defvar elpher-user-coding-system nil
 670   "User-specified coding system to use for decoding text responses.")
 671
 672 (defun elpher-decode (string)
 673   "Decode STRING using autodetected or user-specified coding system."
 674   (decode-coding-string string
 675                         (if elpher-user-coding-system
 676                             elpher-user-coding-system
 677                           (detect-coding-string string t))))
 678
 679 (defun elpher-preprocess-text-response (string)
 680   "Preprocess text selector response contained in STRING.
 681 This involes decoding the character representation, and clearing
 682 away CRs and any terminating period."
 683   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 684                                            (replace-regexp-in-string "\r" "" string))))
 685
 686 ;;; Buttonify urls
 687
 688 (defconst elpher-url-regex
 689   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 690   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 691
 692 (defun elpher-buttonify-urls (string)
 693   "Turn substrings which look like urls in STRING into clickable buttons."
 694   (with-temp-buffer
 695     (insert string)
 696     (goto-char (point-min))
 697     (while (re-search-forward elpher-url-regex nil t)
 698       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 699         (make-text-button (match-beginning 0)
 700                           (match-end 0)
 701                           'elpher-page  page
 702                           'action #'elpher-click-link
 703                           'follow-link t
 704                           'help-echo #'elpher--page-button-help
 705                           'face 'button)))
 706     (buffer-string)))
 707
 708 ;;; ANSI colors or XTerm colors (application and filtering)
 709
 710 (or (require 'xterm-color nil t)
 711     (require 'ansi-color))
 712
 713 (defalias 'elpher-color-filter-apply
 714   (if (fboundp 'xterm-color-filter)
 715       (lambda (s)
 716         (let ((_xterm-color-render nil))
 717           (xterm-color-filter s)))
 718     #'ansi-color-filter-apply)
 719   "A function to filter out ANSI escape sequences.")
 720
 721 (defalias 'elpher-color-apply
 722   (if (fboundp 'xterm-color-filter)
 723       #'xterm-color-filter
 724     #'ansi-color-apply)
 725   "A function to apply ANSI escape sequences.")
 726
 727 ;;; Processing text for display
 728
 729 (defun elpher-process-text-for-display (string)
 730   "Perform any desired processing of STRING prior to display as text.
 731 Currently includes buttonifying URLs and processing ANSI escape codes."
 732   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 733                              (elpher-color-filter-apply string)
 734                            (elpher-color-apply string))))
 735
 736
 737 ;;; Network error reporting
 738 ;;
 739
 740 (defun elpher-network-error (address error)
 741   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 742 ERROR can be either an error object or a string."
 743   (elpher-with-clean-buffer
 744    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 745            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 746            (if (stringp error) error (error-message-string error)) "\n"
 747            (propertize "\n----------------\n\n" 'face 'error)
 748            "Press 'u' to return to the previous page.")))
 749
 750
 751 ;;; General network communication
 752 ;;
 753
 754 (defvar elpher-network-timer nil
 755   "Timer used for network connections.")
 756
 757 (defvar elpher-use-tls nil
 758   "If non-nil, use TLS to communicate with gopher servers.")
 759
 760 (defvar elpher-client-certificate nil
 761   "If non-nil, contains client certificate details to use for TLS connections.")
 762
 763 (defun elpher-process-cleanup ()
 764   "Immediately shut down any extant elpher process and timers."
 765   (let ((p (get-process "elpher-process")))
 766     (if p (delete-process p)))
 767   (if (timerp elpher-network-timer)
 768       (cancel-timer elpher-network-timer)))
 769
 770 (defun elpher-make-network-timer (thunk)
 771   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 772 This is just a wraper around `run-at-time' which additionally sets the
 773 buffer-local variable `elpher-network-timer' to allow
 774 `elpher-process-cleanup' to also clear the timer."
 775   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 776     (setq-local elpher-network-timer timer)
 777     timer))
 778
 779 (defun elpher-get-host-response (address default-port query-string response-processor
 780                                          &optional use-tls force-ipv4)
 781   "Generic function for retrieving data from ADDRESS.
 782
 783 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 784 QUERY-STRING is a string sent to the host specified by ADDRESS to
 785 illicet a response.  This response is passed as an argument to the
 786 function RESPONSE-PROCESSOR.
 787
 788 If non-nil, USE-TLS specifies that the connection is to be made over
 789 TLS.  If set to gemini, the certificate verification will be disabled
 790 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 791
 792 If non-nil, FORCE-IPV4 causes the network connection to be made over
 793 ipv4 only.  (The default behaviour when this is not set depends on
 794 the host operating system and the local network capabilities.)"
 795   (if (and use-tls (not (gnutls-available-p)))
 796       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 797     (unless (< (elpher-address-port address) 65536)
 798       (error "Cannot establish network connection: port number > 65536"))
 799     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 800       (setq-local network-security-level 'low)
 801       (setq-local gnutls-verify-error nil))
 802     (condition-case nil
 803         (let* ((kill-buffer-query-functions nil)
 804                (port (elpher-address-port address))
 805                (host (elpher-address-host address))
 806                (service (if (> port 0) port default-port))
 807                (response-string-parts nil)
 808                (bytes-received 0)
 809                (hkbytes-received 0)
 810                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 811                (gnutls-params (list :type 'gnutls-x509pki
 812                                     :hostname host
 813                                     :keylist
 814                                     (elpher-get-current-keylist address)))
 815                (timer (elpher-make-network-timer
 816                                    (lambda ()
 817                                      (elpher-process-cleanup)
 818                                      (cond
 819                                         ; Try again with IPv4
 820                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 821                                        (message "Connection timed out.  Retrying with IPv4.")
 822                                        (elpher-get-host-response address default-port
 823                                                                  query-string
 824                                                                  response-processor
 825                                                                  use-tls t))
 826                                       ((and use-tls
 827                                             (not (eq use-tls 'gemini))
 828                                             (or elpher-auto-disengage-TLS
 829                                                 (y-or-n-p
 830                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 831                                        (setq elpher-use-tls nil)
 832                                        (elpher-get-host-response address default-port
 833                                                                  query-string
 834                                                                  response-processor
 835                                                                  nil force-ipv4))
 836                                       (t
 837                                        (elpher-network-error address "Connection time-out."))))))
 838                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 839                        (make-network-process :name "elpher-process"
 840                                              :host host
 841                                              :family (and (or force-ipv4
 842                                                               elpher-ipv4-always)
 843                                                           'ipv4)
 844                                              :service service
 845                                              :buffer nil
 846                                              :nowait t
 847                                              :tls-parameters
 848                                              (and use-tls
 849                                                   (cons 'gnutls-x509pki
 850                                                         (apply #'gnutls-boot-parameters
 851                                                                gnutls-params)))))))
 852           (setq elpher-network-timer timer)
 853           (set-process-coding-system proc 'binary 'binary)
 854           (set-process-query-on-exit-flag proc nil)
 855           (elpher-buffer-message (concat "Connecting to " host "..."
 856                                          " (press 'u' to abort)"))
 857           (set-process-filter proc
 858                               (lambda (_proc string)
 859                                 (when timer
 860                                   (cancel-timer timer)
 861                                   (setq timer nil))
 862                                 (setq bytes-received (+ bytes-received (length string)))
 863                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 864                                   (when (> new-hkbytes-received hkbytes-received)
 865                                     (setq hkbytes-received new-hkbytes-received)
 866                                     (elpher-buffer-message
 867                                      (concat "("
 868                                              (number-to-string (/ hkbytes-received 10.0))
 869                                              " MB read)")
 870                                      1)))
 871                                 (setq response-string-parts
 872                                       (cons string response-string-parts))))
 873           (set-process-sentinel proc
 874                                 (lambda (proc event)
 875                                   (when timer
 876                                     (cancel-timer timer))
 877                                   (condition-case the-error
 878                                       (cond
 879                                        ((string-prefix-p "open" event)    ; request URL
 880                                         (elpher-buffer-message
 881                                          (concat "Connected to " host ". Receiving data..."
 882                                                  " (press 'u' to abort)"))
 883                                         (let ((inhibit-eol-conversion t))
 884                                           (process-send-string proc query-string)))
 885                                        ((string-prefix-p "deleted" event)) ; do nothing
 886                                        ((and (not response-string-parts)
 887                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 888                                         ; Try again with IPv4
 889                                         (message "Connection failed. Retrying with IPv4.")
 890                                         (elpher-get-host-response address default-port
 891                                                                   query-string
 892                                                                   response-processor
 893                                                                   use-tls t))
 894                                        (response-string-parts
 895                                         (elpher-with-clean-buffer
 896                                          (insert "Data received.  Rendering..."))
 897                                         (funcall response-processor
 898                                                  (apply #'concat (reverse response-string-parts)))
 899                                         (elpher-restore-pos))
 900                                        (t
 901                                         (error "No response from server")))
 902                                     (error
 903                                      (elpher-network-error address the-error)))))
 904           (when socks
 905             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 906             (funcall (process-sentinel proc) proc "open\n")))
 907       (error
 908        (elpher-process-cleanup)
 909        (error "Error initiating connection to server")))))
 910
 911
 912 ;;; Client-side TLS Certificate Management
 913 ;;
 914
 915 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 916   "Generate a key and a self-signed client TLS certificate using openssl.
 917
 918 The Common Name field of the certificate is set to COMMON-NAME.  The
 919 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 920 the key and certificate files to write.
 921
 922 If TEMPORARY is non-nil, the certificate will be given an exporation
 923 period of one day, and the key and certificate files will be deleted
 924 when the certificate is no longer needed for the current session.
 925
 926 Otherwise, the certificate will be given a 100 year expiration period
 927 and the files will not be deleted.
 928
 929 The function returns a list containing the current host name, the
 930 temporary flag, and the key and cert file names in the form required
 931 by `gnutls-boot-parameters`."
 932   (let ((exp-key-file (expand-file-name key-file))
 933         (exp-cert-file (expand-file-name cert-file)))
 934     (condition-case nil
 935         (progn
 936           (call-process elpher-openssl-command nil nil nil
 937                         "req" "-x509" "-newkey" "rsa:2048"
 938                         "-days" (if temporary "1" "36500")
 939                         "-nodes"
 940                         "-subj" (concat "/CN=" common-name)
 941                         "-keyout" exp-key-file
 942                         "-out" exp-cert-file)
 943           (list (elpher-address-host (elpher-page-address elpher-current-page))
 944                 temporary exp-key-file exp-cert-file))
 945       (error
 946        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 947        (error "Program 'openssl', required for certificate generation, not found")))))
 948
 949 (defun elpher-generate-throwaway-certificate ()
 950   "Generate and return details of a throwaway certificate.
 951 The key and certificate files will be deleted when they are no
 952 longer needed for this session."
 953   (let* ((file-base (make-temp-name "elpher"))
 954          (key-file (concat temporary-file-directory file-base ".key"))
 955          (cert-file (concat temporary-file-directory file-base ".crt")))
 956     (elpher-generate-certificate file-base key-file cert-file t)))
 957
 958 (defun elpher-generate-persistent-certificate (file-base common-name)
 959   "Generate and return details of a persistent certificate.
 960 The argument FILE-BASE is used as the base for the key and certificate
 961 files, while COMMON-NAME specifies the common name field of the
 962 certificate.
 963
 964 The key and certificate files are written to in `elpher-certificate-directory'."
 965   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 966          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 967     (elpher-generate-certificate common-name key-file cert-file)))
 968
 969 (defun elpher-get-existing-certificate (file-base)
 970   "Return a certificate object corresponding to an existing certificate.
 971 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 972 the directory `elpher-certificate-directory'."
 973   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 974          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 975     (list (elpher-address-host (elpher-page-address elpher-current-page))
 976           nil
 977           (expand-file-name key-file)
 978           (expand-file-name cert-file))))
 979
 980 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 981   "Install a key+certificate file pair in `elpher-certificate-directory'.
 982 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 983 certificate files to install.  The argument FILE-BASE is used as the
 984 base for the installed key and certificate files."
 985   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 986          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 987     (if (or (file-exists-p key-file)
 988             (file-exists-p cert-file))
 989         (error "A certificate with base name %s is already installed" file-base))
 990     (copy-file key-file-src key-file)
 991     (copy-file cert-file-src cert-file)
 992     (list (elpher-address-host (elpher-page-address elpher-current-page))
 993           nil
 994           (expand-file-name key-file)
 995           (expand-file-name cert-file))))
 996
 997 (defun elpher-list-existing-certificates ()
 998   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 999   (unless (file-directory-p elpher-certificate-directory)
1000     (make-directory elpher-certificate-directory))
1001   (mapcar
1002    (lambda (file)
1003      (file-name-sans-extension file))
1004    (directory-files elpher-certificate-directory nil "\\.key$")))
1005
1006 (defun elpher-forget-current-certificate ()
1007   "Causes any current certificate to be forgotten.)
1008 In the case of throwaway certificates, the key and certificate files
1009 are also deleted."
1010   (interactive)
1011   (when elpher-client-certificate
1012     (unless (and (called-interactively-p 'any)
1013                  (not (y-or-n-p (concat "Really forget client certificate? "
1014                                         "(Throwaway certificates will be deleted.)"))))
1015       (when (cadr elpher-client-certificate)
1016         (delete-file (elt elpher-client-certificate 2))
1017         (delete-file (elt elpher-client-certificate 3)))
1018       (setq elpher-client-certificate nil)
1019       (if (called-interactively-p 'any)
1020           (message "Client certificate forgotten.")))))
1021
1022 (defun elpher-get-current-keylist (address)
1023   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1024
1025 This is obtained from the client certificate described by
1026 `elpher-current-certificate', if one is available and the host for
1027 that certificate matches the host in ADDRESS.
1028
1029 If `elpher-current-certificate' is non-nil, and its host name doesn't
1030 match that of ADDRESS, the certificate is forgotten."
1031   (if elpher-client-certificate
1032       (if (string= (car elpher-client-certificate)
1033                    (elpher-address-host address))
1034           (list (cddr elpher-client-certificate))
1035         (elpher-forget-current-certificate)
1036         (message "Disabling client certificate for new host")
1037         nil)
1038     nil))
1039
1040
1041 ;;; Gopher selector retrieval
1042 ;;
1043
1044 (defun elpher-get-gopher-response (address renderer)
1045   "Get response string from gopher server at ADDRESS and render using RENDERER."
1046   (elpher-get-host-response address 70
1047                             (concat (elpher-gopher-address-selector address) "\r\n")
1048                             renderer
1049                             (or (string= (elpher-address-protocol address) "gophers")
1050                                 elpher-use-tls)))
1051
1052 (defun elpher-get-gopher-page (renderer)
1053   "Getter function for gopher pages.
1054 The RENDERER procedure is used to display the contents of the page
1055 once they are retrieved from the gopher server."
1056   (let* ((address (elpher-page-address elpher-current-page))
1057          (content (elpher-get-cached-content address)))
1058     (if (and content (funcall renderer nil))
1059         (elpher-with-clean-buffer
1060          (insert content)
1061          (elpher-restore-pos))
1062       (elpher-with-clean-buffer
1063        (insert "LOADING... (use 'u' to cancel)\n"))
1064       (condition-case the-error
1065           (elpher-get-gopher-response address renderer)
1066         (error
1067          (elpher-network-error address the-error))))))
1068
1069 ;; Index rendering
1070
1071 (defun elpher-insert-margin (&optional type-name)
1072   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1073   (if type-name
1074       (progn
1075         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1076                         (concat
1077                          (propertize "[" 'face 'elpher-margin-brackets)
1078                          (propertize type-name 'face 'elpher-margin-key)
1079                          (propertize "]" 'face 'elpher-margin-brackets))))
1080         (insert " "))
1081     (insert (make-string elpher-margin-width ?\s))))
1082
1083 (defun elpher--page-button-help (_window buffer pos)
1084   "Function called by Emacs to generate mouse-over text.
1085 The arguments specify the BUFFER and the POS within the buffer of the item
1086 for which help is required.  The function returns the help to be
1087 displayed.  The _WINDOW argument is currently unused."
1088   (with-current-buffer buffer
1089     (let ((button (button-at pos)))
1090       (when button
1091         (let* ((page (button-get button 'elpher-page))
1092                (address (elpher-page-address page)))
1093           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1094
1095 (defun elpher-insert-index-record (display-string &optional address)
1096   "Function to insert an index record into the current buffer.
1097 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1098 If ADDRESS is not supplied or nil the record is rendered as an
1099 'information' line."
1100   (let* ((type (if address (elpher-address-type address) nil))
1101          (type-map-entry (cdr (assoc type elpher-type-map))))
1102     (if type-map-entry
1103         (let* ((margin-code (elt type-map-entry 2))
1104                (face (elt type-map-entry 3))
1105                (filtered-display-string (elpher-color-filter-apply display-string))
1106                (page (elpher-make-page filtered-display-string address)))
1107           (elpher-insert-margin margin-code)
1108           (insert-text-button filtered-display-string
1109                               'face face
1110                               'elpher-page page
1111                               'action #'elpher-click-link
1112                               'follow-link t
1113                               'help-echo #'elpher--page-button-help))
1114       (pcase type
1115         ('nil ;; Information
1116          (elpher-insert-margin)
1117          (let ((propertized-display-string
1118                 (propertize display-string 'face 'elpher-info)))
1119            (insert (elpher-process-text-for-display propertized-display-string))))
1120         (`(gopher ,selector-type) ;; Unknown
1121          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1122          (insert (propertize display-string
1123                              'face 'elpher-unknown)))))
1124     (insert "\n")))
1125
1126 (defun elpher-click-link (button)
1127   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1128   (let ((page (button-get button 'elpher-page)))
1129     (elpher-visit-page page)))
1130
1131 (defun elpher-render-index (data &optional _mime-type-string)
1132   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1133   (elpher-with-clean-buffer
1134    (if (not data)
1135        t
1136      (let ((data-processed (elpher-preprocess-text-response data)))
1137        (dolist (line (split-string data-processed "\n"))
1138          (ignore-errors
1139            (unless (= (length line) 0)
1140              (let* ((type (elt line 0))
1141                     (fields (split-string (substring line 1) "\t"))
1142                     (display-string (elt fields 0))
1143                     (selector (elt fields 1))
1144                     (host (elt fields 2))
1145                     (port (if (elt fields 3)
1146                               (string-to-number (elt fields 3))
1147                             nil))
1148                     (address (elpher-make-gopher-address type selector host port)))
1149                (elpher-insert-index-record display-string address))))))
1150      (elpher-cache-content (elpher-page-address elpher-current-page)
1151                            (buffer-string)))))
1152
1153 ;; Text rendering
1154
1155 (defun elpher-render-text (data &optional _mime-type-string)
1156   "Render DATA as text.  MIME-TYPE-STRING is unused."
1157   (elpher-with-clean-buffer
1158    (if (not data)
1159        t
1160      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1161      (elpher-cache-content
1162       (elpher-page-address elpher-current-page)
1163       (buffer-string)))))
1164
1165 ;; Image retrieval
1166
1167 (defun elpher-render-image (data &optional _mime-type-string)
1168   "Display DATA as image.  MIME-TYPE-STRING is unused."
1169   (if (not data)
1170       nil
1171     (if (display-images-p)
1172         (let* ((image (create-image
1173                        data
1174                        nil t))
1175                (window (get-buffer-window elpher-buffer-name)))
1176           (when window
1177             (setf (image-property image :max-width) (window-body-width window t))
1178             (setf (image-property image :max-height) (window-body-height window t)))
1179           (elpher-with-clean-buffer
1180            (insert-image image)
1181            (elpher-restore-pos)))
1182       (elpher-render-download data))))
1183
1184 ;; Search retrieval and rendering
1185
1186 (defun elpher-get-gopher-query-page (renderer)
1187   "Getter for gopher addresses requiring input.
1188 The response is rendered using the rendering function RENDERER."
1189   (let* ((address (elpher-page-address elpher-current-page))
1190          (content (elpher-get-cached-content address))
1191          (aborted t))
1192     (if (and content (funcall renderer nil))
1193         (elpher-with-clean-buffer
1194          (insert content)
1195          (elpher-restore-pos)
1196          (message "Displaying cached search results.  Reload to perform a new search."))
1197       (unwind-protect
1198           (let* ((query-string (read-string "Query: "))
1199                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1200                  (search-address (elpher-make-gopher-address ?1
1201                                                              query-selector
1202                                                              (elpher-address-host address)
1203                                                              (elpher-address-port address)
1204                                                              (equal (elpher-address-type address) "gophers"))))
1205             (setq aborted nil)
1206
1207             (elpher-with-clean-buffer
1208              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1209             (elpher-get-gopher-response search-address renderer))
1210         (if aborted
1211             (elpher-visit-previous-page))))))
1212
1213 ;; Raw server response rendering
1214
1215 (defun elpher-render-raw (data &optional mime-type-string)
1216   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1217   (if (not data)
1218       nil
1219     (elpher-with-clean-buffer
1220      (when mime-type-string
1221        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1222      (insert data)
1223      (goto-char (point-min)))
1224     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1225
1226 ;; File save "rendering"
1227
1228 (defun elpher-render-download (data &optional _mime-type-string)
1229   "Save DATA to file.  MIME-TYPE-STRING is unused."
1230   (if (not data)
1231       nil
1232     (let* ((address (elpher-page-address elpher-current-page))
1233            (selector (if (elpher-address-gopher-p address)
1234                          (elpher-gopher-address-selector address)
1235                        (elpher-address-filename address))))
1236       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1237       (let* ((filename-proposal (file-name-nondirectory selector))
1238              (filename (read-file-name "Download complete. Save file as: "
1239                                        nil nil nil
1240                                        (if (> (length filename-proposal) 0)
1241                                            filename-proposal
1242                                          "download.file"))))
1243         (let ((coding-system-for-write 'binary))
1244           (with-temp-file filename
1245             (insert data)))
1246         (message (format "Saved to file %s." filename))))))
1247
1248 ;; HTML rendering
1249
1250 (defun elpher-render-html (data &optional _mime-type-string)
1251   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1252   (elpher-with-clean-buffer
1253    (if (not data)
1254        t
1255      (let ((dom (with-temp-buffer
1256                   (insert data)
1257                   (libxml-parse-html-region (point-min) (point-max)))))
1258        (shr-insert-document dom)))))
1259
1260 ;; Gemini page retrieval
1261
1262 (defvar elpher-gemini-redirect-chain)
1263
1264 (defun elpher-get-gemini-response (address renderer)
1265   "Get response string from gemini server at ADDRESS and render using RENDERER."
1266   (elpher-get-host-response address 1965
1267                             (concat (elpher-address-to-url address) "\r\n")
1268                             (lambda (response-string)
1269                               (elpher-process-gemini-response response-string renderer))
1270                             'gemini))
1271
1272 (defun elpher-parse-gemini-response (response)
1273   "Parse the RESPONSE string and return a list of components.
1274 The list is of the form (code meta body).  A response of nil implies
1275 that the response was malformed."
1276   (let ((header-end-idx (string-match "\r\n" response)))
1277     (if header-end-idx
1278         (let ((header (string-trim (substring response 0 header-end-idx)))
1279               (body (substring response (+ header-end-idx 2))))
1280           (if (>= (length header) 2)
1281               (let ((code (substring header 0 2))
1282                     (meta (string-trim (substring header 2))))
1283                 (list code meta body))
1284             (error "Malformed response: No response status found in header %s" header)))
1285       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1286
1287 (defun elpher-process-gemini-response (response-string renderer)
1288   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1289   (let ((response-components (elpher-parse-gemini-response response-string)))
1290     (let ((response-code (elt response-components 0))
1291           (response-meta (elt response-components 1))
1292           (response-body (elt response-components 2)))
1293       (pcase (elt response-code 0)
1294         (?1 ; Input required
1295          (elpher-with-clean-buffer
1296           (insert "Gemini server is requesting input."))
1297          (let* ((query-string
1298                  (if (eq (elt response-code 1) ?1)
1299                      (read-passwd (concat response-meta ": "))
1300                    (read-string (concat response-meta ": "))))
1301                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1302                 (old-fname (url-filename query-address)))
1303            (setf (url-filename query-address)
1304                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1305            (elpher-get-gemini-response query-address renderer)))
1306         (?2 ; Normal response
1307          (funcall renderer response-body response-meta))
1308         (?3 ; Redirect
1309          (message "Following redirect to %s" response-meta)
1310          (if (>= (length elpher-gemini-redirect-chain) 5)
1311              (error "More than 5 consecutive redirects followed"))
1312          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1313            (if (member redirect-address elpher-gemini-redirect-chain)
1314                (error "Redirect loop detected"))
1315            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1316                (error "Server tried to automatically redirect to non-gemini URL: %s"
1317                       response-meta))
1318            (elpher-page-set-address elpher-current-page redirect-address)
1319            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1320            (elpher-get-gemini-response redirect-address renderer)))
1321         (?4 ; Temporary failure
1322          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1323                 response-code response-meta))
1324         (?5 ; Permanent failure
1325          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1326                 response-code response-meta))
1327         (?6 ; Client certificate required
1328          (elpher-with-clean-buffer
1329           (if elpher-client-certificate
1330               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1331             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1332           (auto-fill-mode 1)
1333           (elpher-gemini-insert-text response-meta))
1334          (let ((chosen-certificate (elpher-choose-client-certificate)))
1335            (unless chosen-certificate
1336              (error "Gemini server requires a client certificate and none was provided"))
1337            (setq elpher-client-certificate chosen-certificate))
1338          (elpher-with-clean-buffer)
1339          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1340         (_other
1341          (error "Gemini server response unknown: %s %s"
1342                 response-code response-meta))))))
1343
1344 (defun elpher--read-answer-polyfill (question answers)
1345   "Polyfill for `read-answer' in Emacs 26.1.
1346 QUESTION is a string containing a question, and ANSWERS
1347 is a list of possible answers."
1348     (completing-read question (mapcar 'identity answers)))
1349
1350 (if (fboundp 'read-answer)
1351     (defalias 'elpher-read-answer 'read-answer)
1352   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1353
1354 (defun elpher-choose-client-certificate ()
1355   "Prompt for a client certificate to use to establish a TLS connection."
1356   (let* ((read-answer-short t))
1357     (pcase (read-answer "What do you want to do? "
1358                         '(("throwaway" ?t
1359                            "generate and use throw-away certificate")
1360                           ("persistent" ?p
1361                            "generate new or use existing persistent certificate")
1362                           ("abort" ?a
1363                            "stop immediately")))
1364       ("throwaway"
1365        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1366       ("persistent"
1367        (let* ((existing-certificates (elpher-list-existing-certificates))
1368               (file-base (completing-read
1369                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1370                           existing-certificates)))
1371          (if (string-empty-p (string-trim file-base))
1372              nil
1373            (if (member file-base existing-certificates)
1374                (setq elpher-client-certificate
1375                      (elpher-get-existing-certificate file-base))
1376              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1377                                  '(("new" ?n
1378                                     "generate new certificate")
1379                                    ("install" ?i
1380                                     "install existing certificate")
1381                                    ("abort" ?a
1382                                     "stop immediately")))
1383                ("new"
1384                 (let ((common-name (read-string "Common Name field for new certificate: "
1385                                                 file-base)))
1386                   (message "New key and self-signed certificate written to %s"
1387                            elpher-certificate-directory)
1388                   (elpher-generate-persistent-certificate file-base common-name)))
1389                ("install"
1390                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1391                        (key-file (read-file-name "Key file: " nil nil t)))
1392                   (message "Key and certificate installed in %s for future use"
1393                            elpher-certificate-directory)
1394                   (elpher-install-and-use-existing-certificate key-file
1395                                                                cert-file
1396                                                                file-base)))
1397                ("abort" nil))))))
1398       ("abort" nil))))
1399
1400 (defun elpher-get-gemini-page (renderer)
1401   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1402   (let* ((address (elpher-page-address elpher-current-page))
1403          (content (elpher-get-cached-content address)))
1404     (condition-case the-error
1405         (if (and content (funcall renderer nil))
1406             (elpher-with-clean-buffer
1407              (insert content)
1408              (elpher-restore-pos))
1409           (elpher-with-clean-buffer
1410            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1411           (setq elpher-gemini-redirect-chain nil)
1412           (elpher-get-gemini-response address renderer))
1413       (error
1414        (elpher-network-error address the-error)))))
1415
1416 (defun elpher-render-gemini (body &optional mime-type-string)
1417   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1418   (if (not body)
1419       t
1420     (let* ((mime-type-string* (if (or (not mime-type-string)
1421                                       (string-empty-p mime-type-string))
1422                                   "text/gemini; charset=utf-8"
1423                                 mime-type-string))
1424            (mime-type-split (split-string mime-type-string* ";" t))
1425            (mime-type (string-trim (car mime-type-split)))
1426            (parameters (mapcar (lambda (s)
1427                                  (let ((key-val (split-string s "=")))
1428                                    (list (downcase (string-trim (car key-val)))
1429                                          (downcase (string-trim (cadr key-val))))))
1430                                (cdr mime-type-split))))
1431       (when (string-prefix-p "text/" mime-type)
1432         (setq body (decode-coding-string
1433                     body
1434                     (if (assoc "charset" parameters)
1435                         (intern (cadr (assoc "charset" parameters)))
1436                       'utf-8)))
1437         (setq body (replace-regexp-in-string "\r" "" body)))
1438       (pcase mime-type
1439         ((or "text/gemini" "")
1440          (elpher-render-gemini-map body parameters))
1441         ("text/html"
1442          (elpher-render-html body))
1443         ((pred (string-prefix-p "text/"))
1444          (elpher-render-gemini-plain-text body parameters))
1445         ((pred (string-prefix-p "image/"))
1446          (elpher-render-image body))
1447         (_other
1448          (elpher-render-download body))))))
1449
1450 (defun elpher-gemini-get-link-url (link-line)
1451   "Extract the url portion of LINK-LINE, a gemini map file link line.
1452 Returns nil in the event that the contents of the line following the
1453 => prefix are empty."
1454   (let ((l (split-string (substring link-line 2))))
1455     (if l
1456         (string-trim (elt l 0))
1457       nil)))
1458
1459 (defun elpher-gemini-get-link-display-string (link-line)
1460   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1461 Returns the url portion in the event that the display-string portion is empty."
1462   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1463          (idx (string-match "[ \t]" rest)))
1464     (string-trim (if idx
1465                      (substring rest (+ idx 1))
1466                    rest))))
1467
1468 (defun elpher-collapse-dot-sequences (filename)
1469   "Collapse dot sequences in the (absolute) FILENAME.
1470 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1471   (let* ((path (split-string filename "/" t))
1472          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1473          (path-reversed-normalized
1474           (seq-reduce (lambda (a b)
1475                         (cond ((equal b "..") (cdr a))
1476                               ((equal b ".") a)
1477                               (t (cons b a))))
1478                       path nil))
1479          (path-normalized (reverse path-reversed-normalized)))
1480     (if path-normalized
1481         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1482       "/")))
1483
1484 (defun elpher-address-from-gemini-url (url)
1485   "Extract address from URL with defaults as per gemini map files.
1486 While there's obviously some redundancy here between this function and
1487 `elpher-address-from-url', gemini map file URLs require enough special
1488 treatment that a separate function is warranted."
1489   (let ((address (url-generic-parse-url url))
1490         (current-address (elpher-page-address elpher-current-page)))
1491     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1492       (setf (url-fullness address) t)
1493       (if (url-host address) ;if there is an explicit host, filenames are absolute
1494           (if (string-empty-p (url-filename address))
1495               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1496         (setf (url-host address) (url-host current-address))
1497         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1498         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1499           (setf (url-filename address)
1500                 (concat (file-name-directory (url-filename current-address))
1501                         (url-filename address)))))
1502       (when (url-host address)
1503         (setf (url-host address) (puny-encode-domain (url-host address))))
1504       (unless (url-type address)
1505         (setf (url-type address) (url-type current-address)))
1506       (when (equal (url-type address) "gemini")
1507         (setf (url-filename address)
1508               (elpher-collapse-dot-sequences (url-filename address)))))
1509     (elpher-remove-redundant-ports address)))
1510
1511 (defun elpher-gemini-insert-link (link-line)
1512   "Insert link described by LINK-LINE into a text/gemini document."
1513   (let* ((url (elpher-gemini-get-link-url link-line))
1514          (display-string (elpher-gemini-get-link-display-string link-line))
1515          (address (elpher-address-from-gemini-url url))
1516          (type (if address (elpher-address-type address) nil))
1517          (type-map-entry (cdr (assoc type elpher-type-map)))
1518          (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1519     (when display-string
1520       (insert elpher-gemini-link-string)
1521       (if type-map-entry
1522           (let* ((face (elt type-map-entry 3))
1523                  (filtered-display-string (elpher-color-filter-apply display-string))
1524                  (page (elpher-make-page filtered-display-string address)))
1525             (insert-text-button filtered-display-string
1526                                 'face face
1527                                 'elpher-page page
1528                                 'action #'elpher-click-link
1529                                 'follow-link t
1530                                 'help-echo #'elpher--page-button-help))
1531         (insert (propertize display-string 'face 'elpher-unknown)))
1532       (newline))))
1533
1534 (defvar elpher--gemini-page-headings nil
1535   "List of headings on the page.")
1536
1537 (defun elpher-gemini-insert-header (header-line)
1538   "Insert header described by HEADER-LINE into a text/gemini document.
1539 The gemini map file line describing the header is given
1540 by HEADER-LINE."
1541   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1542     (let* ((level (length (match-string 1 header-line)))
1543            (header (substring header-line (match-end 0)))
1544            (face (pcase level
1545                    (1 'elpher-gemini-heading1)
1546                    (2 'elpher-gemini-heading2)
1547                    (3 'elpher-gemini-heading3)
1548                    (_ 'default)))
1549            (fill-column (if (display-graphic-p)
1550                             (/ (* fill-column
1551                                   (font-get (font-spec :name (face-font 'default)) :size))
1552                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1553       (setq elpher--gemini-page-headings (cons (cons header (point))
1554                                                elpher--gemini-page-headings))
1555       (unless (display-graphic-p)
1556         (insert (make-string level ?#) " "))
1557       (insert (propertize header 'face face 'rear-nonsticky t))
1558       (newline))))
1559
1560 (defun elpher-gemini-insert-text (text-line)
1561   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1562 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1563 width defined by `elpher-gemini-max-fill-width'."
1564   (string-match
1565    (rx (: line-start
1566           (* (any " \t"))
1567           (optional
1568            (group (or (: "*" (+ (any " \t")))
1569                       (: ">" (* (any " \t"))))))))
1570    text-line)
1571   (let* ((line-prefix (match-string 1 text-line))
1572          (processed-text-line
1573           (if line-prefix
1574               (cond ((string-prefix-p "*" line-prefix)
1575                      (concat
1576                       (replace-regexp-in-string "\\*"
1577                                                 elpher-gemini-bullet-string
1578                                                 (match-string 0 text-line))
1579                       (substring text-line (match-end 0))))
1580                     ((string-prefix-p ">" line-prefix)
1581                      (propertize text-line 'face 'elpher-gemini-quoted))
1582                     (t text-line))
1583             text-line))
1584          (adaptive-fill-mode t)
1585          ;; fill-prefix is important for adaptive-fill-mode: without
1586          ;; it, multi-line list items are not indented correct
1587          (fill-prefix (if (match-string 1 text-line)
1588                           (make-string (length (match-string 0 text-line)) ?\s)
1589                         nil)))
1590     (insert (elpher-process-text-for-display processed-text-line))
1591     (newline)))
1592
1593 (defun elpher-render-gemini-map (data _parameters)
1594   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1595   (elpher-with-clean-buffer
1596    (setq elpher--gemini-page-headings nil)
1597    (let ((preformatted nil))
1598      (auto-fill-mode 1)
1599      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1600      (dolist (line (split-string data "\n"))
1601        (cond
1602         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1603         (preformatted (insert (elpher-process-text-for-display
1604                                (propertize line 'face 'elpher-gemini-preformatted))
1605                               "\n"))
1606         ((string-prefix-p "=>" line)
1607          (elpher-gemini-insert-link line))
1608         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1609         (t (elpher-gemini-insert-text line)))))
1610    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1611    (elpher-cache-content
1612     (elpher-page-address elpher-current-page)
1613     (buffer-string))))
1614
1615 (defun elpher-render-gemini-plain-text (data _parameters)
1616   "Render DATA as plain text file.  PARAMETERS is currently unused."
1617   (elpher-with-clean-buffer
1618    (insert (elpher-process-text-for-display data))
1619    (elpher-cache-content
1620     (elpher-page-address elpher-current-page)
1621     (buffer-string))))
1622
1623
1624 ;; Finger page connection
1625
1626 (defun elpher-get-finger-page (renderer)
1627   "Opens a finger connection to the current page address.
1628 The result is rendered using RENDERER."
1629   (let* ((address (elpher-page-address elpher-current-page))
1630          (content (elpher-get-cached-content address)))
1631     (if (and content (funcall renderer nil))
1632         (elpher-with-clean-buffer
1633          (insert content)
1634          (elpher-restore-pos))
1635       (elpher-with-clean-buffer
1636        (insert "LOADING... (use 'u' to cancel)\n"))
1637       (condition-case the-error
1638           (let* ((kill-buffer-query-functions nil)
1639                  (user (let ((filename (elpher-address-filename address)))
1640                          (if (> (length filename) 1)
1641                              (substring filename 1)
1642                            (elpher-address-user address)))))
1643             (elpher-get-host-response address 79
1644                                       (concat user "\r\n")
1645                                       renderer))
1646         (error
1647          (elpher-network-error address the-error))))))
1648
1649
1650 ;; Telnet page connection
1651
1652 (defun elpher-get-telnet-page (renderer)
1653   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1654   (when renderer
1655     (elpher-visit-previous-page)
1656     (error "Command not supported for telnet URLs"))
1657   (let* ((address (elpher-page-address elpher-current-page))
1658          (host (elpher-address-host address))
1659          (port (elpher-address-port address)))
1660     (elpher-visit-previous-page)
1661     (if (> port 0)
1662         (telnet host port)
1663       (telnet host))))
1664
1665
1666 ;; Other URL page opening
1667
1668 (defun elpher-get-other-url-page (renderer)
1669   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1670   (when renderer
1671     (elpher-visit-previous-page)
1672     (error "Command not supported for general URLs"))
1673   (let* ((address (elpher-page-address elpher-current-page))
1674          (url (elpher-address-to-url address)))
1675     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1676     (message "Opening URL...")
1677     (if elpher-open-urls-with-eww
1678         (browse-web url)
1679       (browse-url url))))
1680
1681 ;; File page
1682
1683 (defun elpher-get-file-page (renderer)
1684   "Getter which renders a local file using RENDERER.
1685 Assumes UTF-8 encoding for all text files."
1686   (let* ((address (elpher-page-address elpher-current-page))
1687          (filename (elpher-address-filename address)))
1688     (unless (file-exists-p filename)
1689       (elpher-visit-previous-page)
1690         (error "File not found"))
1691     (unless (file-readable-p filename)
1692       (elpher-visit-previous-page)
1693         (error "Could not read from file"))
1694     (let ((body (with-temp-buffer
1695        (let ((coding-system-for-read 'binary)
1696              (coding-system-for-write 'binary))
1697          (insert-file-contents-literally filename)
1698          (encode-coding-string (buffer-string) 'raw-text)))))
1699        (if renderer
1700            (funcall renderer body nil)
1701          (pcase (file-name-extension filename)
1702            ((or  "gmi" "gemini")
1703             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1704            ((or "htm" "html")
1705             (elpher-render-html (decode-coding-string body 'utf-8)))
1706            ((or "txt" "")
1707             (elpher-render-text (decode-coding-string body 'utf-8)))
1708            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1709             (elpher-render-image body))
1710            ((or "gopher" "gophermap")
1711             (elpher-render-index (elpher-decode body)))
1712            (_
1713             (elpher-render-download body))))
1714        (elpher-restore-pos))))
1715
1716
1717 ;; Welcome page retrieval
1718
1719 (defun elpher-get-welcome-page (renderer)
1720   "Getter which displays the welcome page (RENDERER must be nil)."
1721   (when renderer
1722     (elpher-visit-previous-page)
1723     (error "Command not supported for welcome page"))
1724   (elpher-with-clean-buffer
1725    (insert "     --------------------------------------------\n"
1726            "           Elpher Gopher and Gemini Client       \n"
1727            "                   version " elpher-version "\n"
1728            "     --------------------------------------------\n"
1729            "\n"
1730            "Default bindings:\n"
1731            "\n"
1732            " - TAB/Shift-TAB: next/prev item on current page\n"
1733            " - RET/mouse-1: open item under cursor\n"
1734            " - m: select an item on current page by name (autocompletes)\n"
1735            " - u/mouse-3/U: return to previous page or to the start page\n"
1736            " - g: go to a particular address (gopher, gemini, finger)\n"
1737            " - o/O: open a different address selector or the root menu of the current server\n"
1738            " - d/D: download item under cursor or current page\n"
1739            " - i/I: info on item under cursor or current page\n"
1740            " - c/C: copy URL representation of item under cursor or current page\n"
1741            " - a/A: bookmark the item under cursor or current page\n"
1742            " - B: list all bookmarks\n"
1743            " - s/S: show current history stack or all previously visted pages\n"
1744            " - r: redraw current page (using cached contents if available)\n"
1745            " - R: reload current page (regenerates cache)\n"
1746            " - !: set character coding system for gopher (default is to autodetect)\n"
1747            " - T: toggle TLS gopher mode\n"
1748            " - F: forget/discard current TLS client certificate\n"
1749            " - .: display the raw server response for the current page\n"
1750            "\n"
1751            "Start your exploration of gopher space and gemini:\n")
1752    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1753                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1754    (elpher-insert-index-record "Project Gemini home page"
1755                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1756    (insert "\n"
1757            "Alternatively, select a search engine and enter some search terms:\n")
1758    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1759                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1760    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1761                                (elpher-address-from-url "gemini://geminispace.info/search"))
1762    (insert "\n"
1763            "Your bookmarks are stored in your ")
1764    (insert-text-button "bookmark list"
1765                        'face 'link
1766                        'action #'elpher-click-link
1767                        'follow-link t
1768                        'help-echo #'elpher--page-button-help
1769                        'elpher-page
1770                        (elpher-make-page "Elpher Bookmarks"
1771                                          (elpher-make-about-address 'bookmarks)))
1772    (insert ".\n")
1773    (insert (propertize
1774             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1775             'face 'shadow))
1776    (insert "\n"
1777            "The gopher home of the Elpher project is here:\n")
1778    (elpher-insert-index-record "The Elpher Project Page"
1779                                (elpher-make-gopher-address ?1
1780                                                            "/projects/elpher/"
1781                                                            "thelambdalab.xyz"
1782                                                            70))
1783    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1784      (insert "\n"
1785              "The following info documentation is available:\n"
1786              "   - ")
1787      (insert-text-button "Elpher Manual"
1788                          'face 'link
1789                          'action (lambda (_)
1790                                    (interactive)
1791                                    (info "(elpher)"))
1792                          'follow-link t
1793                          'help-echo help-string)
1794      (insert "\n   - ")
1795      (insert-text-button "Changes introduced by the latest release"
1796                        'face 'link
1797                        'action (lambda (_)
1798                                  (interactive)
1799                                  (info "(elpher)News"))
1800                        'follow-link t
1801                        'help-echo help-string))
1802    (insert "\n")
1803    (insert (propertize
1804             (concat "(These documents should be available if you have installed Elpher \n"
1805                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1806             'face 'shadow))
1807    (elpher-restore-pos)))
1808
1809 ;; History page retrieval
1810
1811 (defun elpher-show-history ()
1812   "Show the current contents of elpher's history stack.
1813 Use \\[elpher-show-visited-pages] to see the entire history.
1814 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1815   (interactive)
1816   (elpher-visit-page
1817    (elpher-make-page "Current History Stack"
1818                      (elpher-make-about-address 'history))))
1819
1820 (defun elpher-show-visited-pages ()
1821   "Show the all the pages you've visited using Elpher.
1822 Use \\[elpher-show-history] to see just the current history stack.
1823 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1824   (interactive)
1825   (elpher-visit-page
1826    (elpher-make-page "Elpher Visted Pages"
1827                      (elpher-make-about-address 'visited-pages))))
1828
1829 (defun elpher-get-history-page (renderer)
1830   "Getter which displays the history page (RENDERER must be nil)."
1831   (when renderer
1832     (elpher-visit-previous-page)
1833     (error "Command not supported for history page"))
1834   (elpher-display-history-links elpher-history "Current history stack"))
1835
1836 (defun elpher-get-visited-pages-page (renderer)
1837   "Getter which displays the list of visited pages (RENDERER must be nil)."
1838   (when renderer
1839     (elpher-visit-previous-page)
1840     (error "Command not supported for history page"))
1841   (elpher-display-history-links
1842    (seq-filter (lambda (page)
1843                  (not (elpher-address-about-p (elpher-page-address page))))
1844                elpher-visited-pages)
1845    "All visited pages"))
1846
1847 (defun elpher-display-history-links (pages title)
1848   "Show all PAGES in an Elpher buffer with a given TITLE."
1849   (let* ((title-line (concat " ---- " title " ----"))
1850          (footer-line (make-string (length title-line) ?-)))
1851     (elpher-with-clean-buffer
1852      (insert title-line "\n\n")
1853      (if pages
1854          (dolist (page pages)
1855            (when page
1856              (let ((display-string (elpher-page-display-string page))
1857                    (address (elpher-page-address page)))
1858                (elpher-insert-index-record display-string address))))
1859        (insert "No history items found.\n"))
1860      (insert "\n " footer-line "\n"
1861              "Select an entry or press 'u' to return to the previous page.")
1862      (elpher-restore-pos))))
1863
1864
1865 ;;; Bookmarks
1866
1867 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1868 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1869 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1870 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1871
1872 (defvar elpher-bookmark-link nil
1873   "Prefer bookmarking a link or the current page.
1874 Bind this variable dynamically, or set it to t.
1875 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1876 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1877
1878 (defun elpher-bookmark-make-record ()
1879   "Return a bookmark record.
1880 If `elpher-bookmark-link' is non-nil and point is on a link button,
1881 return a bookmark record for that link.  Otherwise, return a bookmark
1882 record for the current elpher page."
1883   (let* ((button (and elpher-bookmark-link (button-at (point))))
1884          (page (if button
1885                    (button-get button 'elpher-page)
1886                  elpher-current-page)))
1887     (unless page
1888       (error "Cannot bookmark this link"))
1889     (let* ((address (elpher-page-address page))
1890            (url (elpher-address-to-url address))
1891            (display-string (elpher-page-display-string page))
1892            (pos (if button nil (point))))
1893       (if (elpher-address-about-p address)
1894           (error "Cannot bookmark %s" display-string)
1895         `(,display-string
1896           (defaults . (,display-string))
1897           (position . ,pos)
1898           (location . ,url)
1899           (handler . elpher-bookmark-jump))))))
1900
1901 ;;;###autoload
1902 (defun elpher-bookmark-jump (bookmark)
1903   "Handler used to open a bookmark using elpher.
1904 The argument BOOKMARK is a bookmark record passed to the function.
1905 This handler is responsible for loading the bookmark in some buffer,
1906 then making that buffer the current buffer.  It should not switch
1907 to the buffer."
1908   (let* ((url (cdr (assq 'location bookmark)))
1909          (cleaned-url (string-trim url))
1910          (page (elpher-page-from-url cleaned-url)))
1911     (elpher-with-clean-buffer
1912      (elpher-visit-page page))
1913     (set-buffer (get-buffer elpher-buffer-name))
1914     nil))
1915
1916 (defun elpher-bookmark-link ()
1917   "Bookmark the link at point.
1918 To bookmark the current page, use \\[elpher-bookmark-current]."
1919   (interactive)
1920   (let ((elpher-bookmark-link t))
1921     (bookmark-set-no-overwrite)))
1922
1923 (defun elpher-bookmark-current ()
1924   "Bookmark the current page.
1925 To bookmark the link at point use \\[elpher-bookmark-link]."
1926   (interactive)
1927   (call-interactively #'bookmark-set-no-overwrite))
1928
1929 (defun elpher-bookmark-import (file)
1930   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1931   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1932                               (file-readable-p elpher-bookmarks-file))
1933                          elpher-bookmarks-file
1934                        (read-file-name "Old Elpher bookmarks: "
1935                                        user-emacs-directory nil t
1936                                        "elpher-bookmarks"))))
1937   (dolist (bookmark (with-temp-buffer
1938                       (insert-file-contents file)
1939                       (read (current-buffer))))
1940     (let* ((display-string (car bookmark))
1941            (url (cadr bookmark))
1942            (record `(,display-string
1943                      (location . ,url)
1944                      (handler . elpher-bookmark-jump))))
1945       (bookmark-store display-string (cdr record) t)))
1946   (bookmark-save))
1947
1948 (defun elpher-get-bookmarks-page (renderer)
1949   "Getter which displays the bookmarks (RENDERER must be nil)."
1950   (when renderer
1951     (elpher-visit-previous-page)
1952     (error "Command not supported for bookmarks page"))
1953
1954   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1955                                      elpher-bookmarks-file)
1956                                 (locate-user-emacs-file "elpher-bookmarks"))))
1957     (when (and (file-readable-p old-bookmarks-file)
1958                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1959                                  old-bookmarks-file
1960                                  "\" found. Import now?")))
1961       (elpher-bookmark-import old-bookmarks-file)
1962       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1963
1964   (if (and elpher-use-emacs-bookmark-menu
1965            elpher-history)
1966       (progn
1967         (elpher-visit-previous-page)
1968         (call-interactively #'bookmark-bmenu-list))
1969     (elpher-with-clean-buffer
1970      (insert " ---- Elpher Bookmarks ---- \n\n")
1971      (bookmark-maybe-load-default-file)
1972      (dolist (bookmark (bookmark-maybe-sort-alist))
1973        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1974          (let* ((name (car bookmark))
1975                 (url (alist-get 'location (cdr bookmark)))
1976                 (address (elpher-address-from-url url)))
1977            (elpher-insert-index-record name address))))
1978      (when (<= (line-number-at-pos) 3)
1979        (insert "No bookmarked pages found.\n"))
1980      (insert "\n --------------------------\n\n"
1981              "Select an entry or press 'u' to return to the previous page.\n\n"
1982              "Bookmarks can be renamed or deleted via the ")
1983      (insert-text-button "Emacs bookmark menu"
1984                          'action (lambda (_)
1985                                    (interactive)
1986                                    (call-interactively #'bookmark-bmenu-list))
1987                          'follow-link t
1988                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
1989      (insert (substitute-command-keys
1990               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1991      (elpher-restore-pos))))
1992
1993 (defun elpher-show-bookmarks ()
1994   "Interactive function to display the current list of elpher bookmarks."
1995   (interactive)
1996   (elpher-visit-page
1997    (elpher-make-page "Elpher Bookmarks"
1998                      (elpher-make-about-address 'bookmarks))))
1999
2000
2001 ;;; Integrations
2002 ;;
2003
2004 ;;; Org
2005
2006 (defun elpher-org-export-link (link description format protocol)
2007   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2008
2009 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2010 of gemini, gopher or finger."
2011   (let* ((url (if (equal protocol "elpher")
2012                   (string-remove-prefix "elpher:" link)
2013                 (format "%s:%s" protocol link)))
2014          (desc (or description url)))
2015     (pcase format
2016       (`gemini (format "=> %s %s" url desc))
2017       (`html (format "<a href=\"%s\">%s</a>" url desc))
2018       (`latex (format "\\href{%s}{%s}" url desc))
2019       (_ (if (not description)
2020              url
2021            (format "%s (%s)" desc url))))))
2022
2023 (defun elpher-org-store-link ()
2024   "Store link to an `elpher' page in Org."
2025   (when (eq major-mode 'elpher-mode)
2026     (let* ((url (elpher-info-current))
2027            (desc (car elpher-current-page))
2028            (protocol (cond
2029                       ((string-prefix-p "gemini:" url) "gemini")
2030                       ((string-prefix-p "gopher:" url) "gopher")
2031                       ((string-prefix-p "finger:" url) "finger")
2032                       (t "elpher"))))
2033       (when (equal "elpher" protocol)
2034         ;; Weird link. Or special inner link?
2035         (setq url (concat "elpher:" url)))
2036       (org-link-store-props :type protocol :link url :description desc)
2037       t)))
2038
2039 (defun elpher-org-follow-link (link protocol)
2040   "Visit a LINK for the given PROTOCOL.
2041
2042 PROTOCOL may be one of gemini, gopher or finger.  This method also
2043 supports the old protocol elpher, where the link is self-contained."
2044   (let ((url (if (equal protocol "elpher")
2045                  (string-remove-prefix "elpher:" link)
2046                (format "%s:%s" protocol link))))
2047     (elpher-go url)))
2048
2049 (defun elpher-org-mode-integration ()
2050   "Set up `elpher' integration for `org-mode'."
2051   (org-link-set-parameters
2052    "elpher"
2053    :store #'elpher-org-store-link
2054    :export (lambda (link description format _plist)
2055              (elpher-org-export-link link description format "elpher"))
2056    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2057   (org-link-set-parameters
2058    "gemini"
2059    :export (lambda (link description format _plist)
2060              (elpher-org-export-link link description format "gemini"))
2061    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2062   (org-link-set-parameters
2063    "gopher"
2064    :export (lambda (link description format _plist)
2065              (elpher-org-export-link link description format "gopher"))
2066    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2067   (org-link-set-parameters
2068    "finger"
2069    :export (lambda (link description format _plist)
2070              (elpher-org-export-link link description format "finger"))
2071    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2072
2073 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2074
2075 ;;; Browse URL
2076
2077 ;;;###autoload
2078 (defun elpher-browse-url-elpher (url &rest _args)
2079   "Browse URL using Elpher.  This function is used by `browse-url'."
2080   (interactive (browse-url-interactive-arg "Elpher URL: "))
2081   (elpher-go url))
2082
2083 ;; Use elpher to open gopher, finger and gemini links
2084 ;; For recent version of `browse-url' package
2085 (if (boundp 'browse-url-default-handlers)
2086     (add-to-list
2087      'browse-url-default-handlers
2088      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2089   ;; Patch `browse-url-browser-function' for older ones. The value of
2090   ;; that variable is `browse-url-default-browser' by default, so
2091   ;; that's the function that gets advised.
2092   (advice-add browse-url-browser-function :before-while
2093               (lambda (url &rest _args)
2094                 "Handle gemini, gopher, and finger schemes using Elpher."
2095                 (let ((scheme (downcase (car (split-string url ":" t)))))
2096                   (if (member scheme '("gemini" "gopher" "finger"))
2097                       ;; `elpher-go' always returns nil, which will stop the
2098                       ;; advice chain here in a before-while
2099                       (elpher-go url)
2100                     ;; chain must continue, then return t.
2101                     t)))))
2102
2103 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2104 (with-eval-after-load 'thingatpt
2105   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2106
2107 ;;; Mu4e:
2108
2109 ;; Make mu4e aware of the gemini world
2110 (setq mu4e~view-beginning-of-url-regexp
2111       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2112
2113 ;;; eww:
2114
2115 ;; Let elpher handle gemini, gopher links in eww buffer.
2116 (setq eww-use-browse-url
2117       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2118
2119
2120 ;;; Interactive procedures
2121 ;;
2122
2123 (defun elpher-next-link ()
2124   "Move point to the next link on the current page."
2125   (interactive)
2126   (forward-button 1))
2127
2128 (defun elpher-prev-link ()
2129   "Move point to the previous link on the current page."
2130   (interactive)
2131   (backward-button 1))
2132
2133 (defun elpher-follow-current-link ()
2134   "Open the link or url at point."
2135   (interactive)
2136   (push-button))
2137
2138 ;;;###autoload
2139 (defun elpher-go (host-or-url)
2140   "Go to a particular gopher site HOST-OR-URL.
2141 When run interactively HOST-OR-URL is read from the minibuffer."
2142   (interactive (list
2143                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2144   (let ((trimmed-host-or-url (string-trim host-or-url)))
2145     (unless (string-empty-p trimmed-host-or-url)
2146       (let ((page (elpher-page-from-url trimmed-host-or-url
2147                                         (elpher-get-default-url-scheme))))
2148         (switch-to-buffer elpher-buffer-name)
2149         (elpher-with-clean-buffer
2150          (elpher-visit-page page))
2151         nil)))) ; non-nil value is displayed by eshell
2152
2153 (defun elpher-go-current ()
2154   "Go to a particular site read from the minibuffer, initialized with the current URL."
2155   (interactive)
2156   (let* ((address (elpher-page-address elpher-current-page))
2157          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2158                            (elpher-address-to-url address))))
2159     (unless (string-empty-p (string-trim url))
2160       (elpher-visit-page (elpher-page-from-url url) (elpher-get-default-url-scheme)))))
2161
2162 (defun elpher-redraw ()
2163   "Redraw current page."
2164   (interactive)
2165   (elpher-visit-page elpher-current-page))
2166
2167 (defun elpher-reload ()
2168   "Reload current page."
2169   (interactive)
2170   (elpher-reload-current-page))
2171
2172 (defun elpher-toggle-tls ()
2173   "Toggle TLS encryption mode for gopher."
2174   (interactive)
2175   (setq elpher-use-tls (not elpher-use-tls))
2176   (if elpher-use-tls
2177       (if (gnutls-available-p)
2178           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2179         (setq elpher-use-tls nil)
2180         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2181     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2182
2183 (defun elpher-view-raw ()
2184   "View raw server response for current page."
2185   (interactive)
2186   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2187       (error "This page was not generated by a server")
2188     (elpher-visit-page elpher-current-page
2189                        #'elpher-render-raw)))
2190
2191 (defun elpher-back ()
2192   "Go to previous site."
2193   (interactive)
2194   (elpher-visit-previous-page))
2195
2196 (defun elpher-back-to-start ()
2197   "Go all the way back to the start page."
2198   (interactive)
2199   (setq-local elpher-current-page nil)
2200   (setq-local elpher-history nil)
2201   (elpher-visit-page (elpher-make-start-page)))
2202
2203 (defun elpher-download ()
2204   "Download the link at point."
2205   (interactive)
2206   (let ((button (button-at (point))))
2207     (if button
2208         (let ((page (button-get button 'elpher-page)))
2209           (unless page
2210             (error "Not an elpher page"))
2211           (when (elpher-address-about-p (elpher-page-address page))
2212             (error "Cannot download %s" (elpher-page-display-string page)))
2213           (elpher-visit-page (button-get button 'elpher-page)
2214                              #'elpher-render-download))
2215       (error "No link selected"))))
2216
2217 (defun elpher-download-current ()
2218   "Download the current page."
2219   (interactive)
2220   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2221       (error "Cannot download %s"
2222              (elpher-page-display-string elpher-current-page))
2223     (elpher-visit-page (elpher-make-page
2224                         (elpher-page-display-string elpher-current-page)
2225                         (elpher-page-address elpher-current-page))
2226                        #'elpher-render-download
2227                        t)))
2228
2229 (defun elpher--build-link-map ()
2230   "Build alist mapping link names to destination pages in current buffer."
2231   (let ((link-map nil)
2232         (b (next-button (point-min) t)))
2233     (while b
2234       (push (cons (button-label b) b) link-map)
2235       (setq b (next-button (button-start b))))
2236     link-map))
2237
2238 (defun elpher-jump ()
2239   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2240   (interactive)
2241   (let* ((link-map (elpher--build-link-map)))
2242     (if link-map
2243         (let ((key (let ((completion-ignore-case t))
2244                      (completing-read "Directory item/link: "
2245                                       link-map nil t))))
2246           (if (and key (> (length key) 0))
2247               (let ((b (cdr (assoc key link-map))))
2248                 (goto-char (button-start b))
2249                 (button-activate b)))))))
2250
2251 (defun elpher-root-dir ()
2252   "Visit root of current server."
2253   (interactive)
2254   (let ((address (elpher-page-address elpher-current-page)))
2255     (if (not (elpher-address-about-p address))
2256         (if (or (member (url-filename address) '("/" ""))
2257                 (and (elpher-address-gopher-p address)
2258                      (= (length (elpher-gopher-address-selector address)) 0)))
2259             (error "Already at root directory of current server")
2260           (let ((address-copy (elpher-address-from-url
2261                                (elpher-address-to-url address))))
2262             (setf (url-filename address-copy) "")
2263             (elpher-go (elpher-address-to-url address-copy))))
2264       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2265
2266 (defun elpher-info-page (page)
2267   "Display URL of PAGE in minibuffer."
2268   (let ((address (elpher-page-address page)))
2269     (message "%s" (elpher-address-to-url address))))
2270
2271 (defun elpher-info-link ()
2272   "Display information on page corresponding to link at point."
2273   (interactive)
2274   (let ((button (button-at (point))))
2275     (unless button
2276       (error "No item selected"))
2277     (let ((page (button-get button 'elpher-page)))
2278       (unless page
2279         (error "Not an elpher page"))
2280       (elpher-info-page page))))
2281
2282 (defun elpher-info-current ()
2283   "Display information on current page."
2284   (interactive)
2285   (elpher-info-page elpher-current-page))
2286
2287 (defun elpher-copy-page-url (page)
2288   "Copy URL representation of address of PAGE to `kill-ring'."
2289   (let* ((address (elpher-page-address page))
2290          (url (elpher-address-to-url address)))
2291     (message "Copied \"%s\" to kill-ring/clipboard." url)
2292     (kill-new url)))
2293
2294 (defun elpher-copy-link-url ()
2295   "Copy URL of item at point to `kill-ring'."
2296   (interactive)
2297   (let ((button (button-at (point))))
2298     (unless button
2299       (error "No item selected"))
2300     (let ((page (button-get button 'elpher-page)))
2301       (unless page
2302         (error "Not an elpher page"))
2303       (elpher-copy-page-url page))))
2304
2305 (defun elpher-copy-current-url ()
2306   "Copy URL of current page to `kill-ring'."
2307   (interactive)
2308   (elpher-copy-page-url elpher-current-page))
2309
2310 (defun elpher-set-gopher-coding-system ()
2311   "Specify an explicit character coding system for gopher selectors."
2312   (interactive)
2313   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2314     (setq elpher-user-coding-system system)
2315     (if system
2316         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2317       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2318
2319
2320 ;;; Mode and keymap
2321 ;;
2322
2323 (defvar elpher-mode-map
2324   (let ((map (make-sparse-keymap)))
2325     (define-key map (kbd "TAB") 'elpher-next-link)
2326     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2327     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2328     (define-key map (kbd "u") 'elpher-back)
2329     (define-key map (kbd "-") 'elpher-back)
2330     (define-key map (kbd "^") 'elpher-back)
2331     (define-key map [mouse-3] 'elpher-back)
2332     (define-key map (kbd "U") 'elpher-back-to-start)
2333     (define-key map (kbd "g") 'elpher-go)
2334     (define-key map (kbd "o") 'elpher-go-current)
2335     (define-key map (kbd "O") 'elpher-root-dir)
2336     (define-key map (kbd "s") 'elpher-show-history)
2337     (define-key map (kbd "S") 'elpher-show-visited-pages)
2338     (define-key map (kbd "r") 'elpher-redraw)
2339     (define-key map (kbd "R") 'elpher-reload)
2340     (define-key map (kbd "T") 'elpher-toggle-tls)
2341     (define-key map (kbd ".") 'elpher-view-raw)
2342     (define-key map (kbd "d") 'elpher-download)
2343     (define-key map (kbd "D") 'elpher-download-current)
2344     (define-key map (kbd "m") 'elpher-jump)
2345     (define-key map (kbd "i") 'elpher-info-link)
2346     (define-key map (kbd "I") 'elpher-info-current)
2347     (define-key map (kbd "c") 'elpher-copy-link-url)
2348     (define-key map (kbd "C") 'elpher-copy-current-url)
2349     (define-key map (kbd "a") 'elpher-bookmark-link)
2350     (define-key map (kbd "A") 'elpher-bookmark-current)
2351     (define-key map (kbd "B") 'elpher-show-bookmarks)
2352     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2353     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2354     (when (fboundp 'evil-define-key*)
2355       (evil-define-key*
2356        'motion map
2357        (kbd "TAB") 'elpher-next-link
2358        (kbd "C-") 'elpher-follow-current-link
2359        (kbd "C-t") 'elpher-back
2360        (kbd "u") 'elpher-back
2361        (kbd "-") 'elpher-back
2362        (kbd "^") 'elpher-back
2363        [mouse-3] 'elpher-back
2364        (kbd "U") 'elpher-back-to-start
2365        (kbd "g") 'elpher-go
2366        (kbd "o") 'elpher-go-current
2367        (kbd "O") 'elpher-root-dir
2368        (kbd "s") 'elpher-show-history
2369        (kbd "S") 'elpher-show-visited-pages
2370        (kbd "r") 'elpher-redraw
2371        (kbd "R") 'elpher-reload
2372        (kbd "T") 'elpher-toggle-tls
2373        (kbd ".") 'elpher-view-raw
2374        (kbd "d") 'elpher-download
2375        (kbd "D") 'elpher-download-current
2376        (kbd "m") 'elpher-jump
2377        (kbd "i") 'elpher-info-link
2378        (kbd "I") 'elpher-info-current
2379        (kbd "c") 'elpher-copy-link-url
2380        (kbd "C") 'elpher-copy-current-url
2381        (kbd "a") 'elpher-bookmark-link
2382        (kbd "A") 'elpher-bookmark-current
2383        (kbd "B") 'elpher-show-bookmarks
2384        (kbd "!") 'elpher-set-gopher-coding-system
2385        (kbd "F") 'elpher-forget-current-certificate))
2386     map)
2387   "Keymap for gopher client.")
2388
2389 (define-derived-mode elpher-mode special-mode "elpher"
2390   "Major mode for elpher, an elisp gopher client.
2391
2392 This mode is automatically enabled by the interactive
2393 functions which initialize the client, namely
2394 `elpher', and `elpher-go'."
2395   (setq-local elpher--gemini-page-headings nil)
2396   (setq-local elpher-current-page nil)
2397   (setq-local elpher-history nil)
2398   (setq-local elpher-buffer-name (buffer-name))
2399   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2400   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2401   (setq-local xterm-color-preserve-properties t))
2402
2403 (when (fboundp 'evil-set-initial-state)
2404   (evil-set-initial-state 'elpher-mode 'motion))
2405
2406
2407 ;;; Main start procedure
2408 ;;
2409
2410 ;;;###autoload
2411 (defun elpher (&optional arg)
2412   "Start elpher with default landing page.
2413 The buffer used for Elpher sessions is determined by the value of
2414 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2415 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2416 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2417 \\[execute-extended-command] elpher RET’) switches to the session with
2418 that number, creating it if necessary.  A non numeric prefix ARG means
2419 to create a new session.  Returns the buffer selected (or created)."
2420   (interactive "P")
2421   (let* ((name (default-value 'elpher-buffer-name))
2422          (buf (cond ((numberp arg)
2423                      (get-buffer-create (format "%s<%d>" name arg)))
2424                     (arg
2425                      (generate-new-buffer name))
2426                     (t
2427                      (get-buffer-create name)))))
2428     (pop-to-buffer-same-window buf)
2429     (unless (buffer-modified-p)
2430       (elpher-mode)
2431       (elpher-visit-page (elpher-make-start-page))
2432       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2433
2434 ;;; elpher.el ends here