elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2020 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 2.11.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: https://alexschroeder.ch/cgit/elpher
  25 ;; Package-Requires: ((emacs "27.1"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - gopher connections using TLS encryption,
  54 ;; - the fledgling Gemini protocol,
  55 ;; - the greybeard Finger protocol.
  56
  57 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  58 ;; page containing information on key bindings and suggested starting
  59 ;; points for your gopher exploration.
  60
  61 ;; Full instructions can be found in the Elpher info manual.
  62
  63 ;; Elpher is under active development.  Any suggestions for
  64 ;; improvements are welcome, and can be made on the official
  65 ;; project page, https://alexschroeder.ch/cgit/elpher.
  66
  67 ;;; Code:
  68
  69 (provide 'elpher)
  70
  71 ;;; Dependencies
  72 ;;
  73
  74 (require 'seq)
  75 (require 'pp)
  76 (require 'shr)
  77 (require 'url-util)
  78 (require 'subr-x)
  79 (require 'dns)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83
  84 ;;; ANSI colors or XTerm colors
  85
  86 (or (require 'xterm-color nil t)
  87     (require 'ansi-color))
  88
  89 (defalias 'elpher-color-filter-apply
  90   (if (fboundp 'xterm-color-filter)
  91       (lambda (s)
  92         (let ((xterm-color-render nil))
  93           (xterm-color-filter s)))
  94     'ansi-color-filter-apply)
  95   "A function to filter out ANSI escape sequences.")
  96 (defalias 'elpher-color-apply
  97   (if (fboundp 'xterm-color-filter)
  98       'xterm-color-filter
  99     'ansi-color-apply)
 100   "A function to apply ANSI escape sequences.")
 101
 102 ;;; Global constants
 103 ;;
 104
 105 (defconst elpher-version "2.11.0"
 106   "Current version of elpher.")
 107
 108 (defconst elpher-margin-width 6
 109   "Width of left-hand margin used when rendering indicies.")
 110
 111 (defconst elpher-type-map
 112   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 113     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 114     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 115     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 116     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 117     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 118     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 119     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 120     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 122     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 123     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 124     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 125     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 126     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 127     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 128     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 129     ((special start) elpher-get-start-page nil)
 130     ((special history) elpher-get-history-page nil)
 131     ((special history-all) elpher-get-history-all-page nil))
 132   "Association list from types to getters, renderers, margin codes and index faces.")
 133
 134
 135 ;;; Internal variables
 136 ;;
 137
 138 ;; buffer-local
 139 (defvar elpher--gemini-page-headings nil
 140   "List of headings on the page.")
 141
 142 (defvar elpher--gemini-page-links nil
 143   "List of links on the page.")
 144
 145 (defvar elpher--gemini-page-links-cache (make-hash-table :test 'equal)
 146   "Hash of addresses and page links.")
 147
 148 ;;; Customization group
 149 ;;
 150
 151 (defgroup elpher nil
 152   "A gopher and gemini client."
 153   :group 'applications)
 154
 155 ;; General appearance and customizations
 156
 157 (defcustom elpher-open-urls-with-eww nil
 158   "If non-nil, open URL selectors using eww.
 159 Otherwise, use the system browser via the `browse-url' function."
 160   :type '(boolean))
 161
 162 (defcustom elpher-use-header t
 163   "If non-nil, display current page information in buffer header."
 164   :type '(boolean))
 165
 166 (defcustom elpher-auto-disengage-TLS nil
 167   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 168 While enabling this may seem convenient, it is also potentially
 169 dangerous as it allows switching from an encrypted channel back to
 170 plain text without user input."
 171   :type '(boolean))
 172
 173 (defcustom elpher-connection-timeout 5
 174   "Specifies the number of seconds to wait for a network connection to time out."
 175   :type '(integer))
 176
 177 (defcustom elpher-filter-ansi-from-text nil
 178   "If non-nil, filter ANSI escape sequences from text.
 179 The default behaviour is to use the ansi-color package to interpret these
 180 sequences."
 181   :type '(boolean))
 182
 183 (defcustom elpher-certificate-directory
 184   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 185   "Specify the name of the directory where client certificates will be stored.
 186 These certificates may be used for establishing authenticated TLS connections."
 187   :type '(directory))
 188
 189 (defcustom elpher-openssl-command "openssl"
 190   "The command used to launch openssl when generating TLS client certificates."
 191   :type '(file))
 192
 193 (defcustom elpher-default-url-type "gopher"
 194   "Default URL type (i.e. scheme) to assume if not explicitly given."
 195   :type '(choice (const "gopher")
 196                  (const "gemini")))
 197
 198 (defcustom elpher-gemini-TLS-cert-checks nil
 199   "If non-nil, verify gemini server TLS certs using the default security level.
 200 Otherwise, certificate verification is disabled.
 201
 202 This defaults to off because it is standard practice for Gemini servers
 203 to use self-signed certificates, meaning that most servers provide what
 204 EMACS considers to be an invalid certificate."
 205   :type '(boolean))
 206
 207 (defcustom elpher-gemini-max-fill-width 80
 208   "Specify the maximum default width (in columns) of text/gemini documents.
 209 The actual width used is the minimum of this value and the window width at
 210 the time when the text is rendered."
 211   :type '(integer))
 212
 213 (defcustom elpher-gemini-link-string "→ "
 214   "Specify the string used to indicate links when rendering gemini maps.
 215 May be empty."
 216   :type '(string))
 217
 218 (defcustom elpher-gemini-bullet-string "•"
 219   "Specify the string used for bullets when rendering gemini maps."
 220   :type '(string))
 221
 222 (defcustom elpher-ipv4-always nil
 223   "If non-nil, elpher will always use IPv4 to establish network connections.
 224 This can be useful when browsing from a computer that supports IPv6, because
 225 some servers which do not support IPv6 can take a long time to time-out."
 226   :type '(boolean))
 227
 228 (defcustom elpher-socks-always nil
 229   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 230 Otherwise, the SOCKS proxy is only used for connections to onion services."
 231   :type '(boolean))
 232
 233 (defcustom elpher-gemini-number-links nil
 234   "If non-nil, number links in gemini pages when rendering.
 235 Links can be accessed by pressing `v' ('visit') followed by the link number."
 236   :type '(boolean))
 237
 238 ;; Face customizations
 239
 240 (defgroup elpher-faces nil
 241   "Elpher face customizations."
 242   :group 'elpher)
 243
 244 (defface elpher-index
 245   '((t :inherit font-lock-keyword-face))
 246   "Face used for directory type directory records.")
 247
 248 (defface elpher-text
 249   '((t :inherit bold))
 250   "Face used for text type directory records.")
 251
 252 (defface elpher-info
 253   '((t :inherit default))
 254   "Face used for info type directory records.")
 255
 256 (defface elpher-image
 257   '((t :inherit font-lock-string-face))
 258   "Face used for image type directory records.")
 259
 260 (defface elpher-search
 261   '((t :inherit warning))
 262   "Face used for search type directory records.")
 263
 264 (defface elpher-html
 265   '((t :inherit font-lock-comment-face))
 266   "Face used for html type directory records.")
 267
 268 (defface elpher-gemini
 269   '((t :inherit font-lock-constant-face))
 270   "Face used for Gemini type directory records.")
 271
 272 (defface elpher-other-url
 273   '((t :inherit font-lock-comment-face))
 274   "Face used for other URL type links records.")
 275
 276 (defface elpher-telnet
 277   '((t :inherit font-lock-function-name-face))
 278   "Face used for telnet type directory records.")
 279
 280 (defface elpher-binary
 281   '((t :inherit font-lock-doc-face))
 282   "Face used for binary type directory records.")
 283
 284 (defface elpher-unknown
 285   '((t :inherit error))
 286   "Face used for directory records with unknown/unsupported types.")
 287
 288 (defface elpher-margin-key
 289   '((t :inherit bold))
 290   "Face used for directory margin key.")
 291
 292 (defface elpher-margin-brackets
 293   '((t :inherit shadow))
 294   "Face used for brackets around directory margin key.")
 295
 296 (defface elpher-gemini-heading1
 297   '((t :inherit bold :height 1.8))
 298   "Face used for gemini heading level 1.")
 299
 300 (defface elpher-gemini-heading2
 301   '((t :inherit bold :height 1.5))
 302   "Face used for gemini heading level 2.")
 303
 304 (defface elpher-gemini-heading3
 305   '((t :inherit bold :height 1.2))
 306   "Face used for gemini heading level 3.")
 307
 308 (defface elpher-gemini-preformatted
 309   '((t :inherit fixed-pitch))
 310   "Face used for pre-formatted gemini text blocks.")
 311
 312 (defface elpher-gemini-quoted
 313   '((t :inherit font-lock-doc-face))
 314   "Face used for gemini quoted texts.")
 315
 316 ;;; Model
 317 ;;
 318
 319 ;; Address
 320
 321 ;; An elpher "address" object is either a url object or a symbol.
 322 ;; Symbol addresses are "special", corresponding to pages generated
 323 ;; dynamically for and by elpher.  All others represent pages which
 324 ;; rely on content retrieved over the network.
 325
 326 (defun elpher-address-from-url (url-string)
 327   "Create a ADDRESS object corresponding to the given URL-STRING."
 328   (let ((data (match-data))) ; Prevent parsing clobbering match data
 329     (unwind-protect
 330         (let ((url (url-generic-parse-url url-string)))
 331           (unless (and (not (url-fullness url)) (url-type url))
 332             (setf (url-fullness url) t)
 333             (setf (url-filename url)
 334                   (url-unhex-string (url-filename url)))
 335             (unless (url-type url)
 336               (setf (url-type url) elpher-default-url-type))
 337             (unless (url-host url)
 338               (let ((p (split-string (url-filename url) "/" nil nil)))
 339                 (setf (url-host url) (car p))
 340                 (setf (url-filename url)
 341                       (if (cdr p)
 342                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 343                         ""))))
 344             (when (or (equal "gopher" (url-type url))
 345                       (equal "gophers" (url-type url)))
 346               ;; Gopher defaults
 347               (when (or (equal (url-filename url) "")
 348                         (equal (url-filename url) "/"))
 349                 (setf (url-filename url) "/1")))
 350             (when (equal "gemini" (url-type url))
 351               ;; Gemini defaults
 352               (if (equal (url-filename url) "")
 353                   (setf (url-filename url) "/"))))
 354           (elpher-remove-redundant-ports url))
 355       (set-match-data data))))
 356
 357 (defun elpher-remove-redundant-ports (address)
 358   "Remove redundant port specifiers from ADDRESS.
 359 Here 'redundant' means that the specified port matches the default
 360 for that protocol, eg 70 for gopher."
 361   (if (and (not (elpher-address-special-p address))
 362            (eq (url-portspec address) ; (url-port) is too slow!
 363                (pcase (url-type address)
 364                  ("gemini" 1965)
 365                  ((or "gopher" "gophers") 70)
 366                  ("finger" 79)
 367                  (_ -1))))
 368       (setf (url-portspec address) nil))
 369   address)
 370
 371 (defun elpher-make-gopher-address (type selector host port &optional tls)
 372   "Create an ADDRESS object using gopher directory record attributes.
 373 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 374 If the optional attribute TLS is non-nil, the address will be marked as
 375 requiring gopher-over-TLS."
 376   (cond
 377    ((equal type ?i) nil)
 378    ((and (equal type ?h)
 379          (string-prefix-p "URL:" selector))
 380     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 381    ((equal type ?8)
 382     (elpher-address-from-url
 383      (concat "telnet"
 384              "://" host
 385              ":" (number-to-string port))))
 386    (t
 387     (elpher-address-from-url
 388      (concat "gopher" (if tls "s" "")
 389              "://" host
 390              ":" (number-to-string port)
 391              "/" (string type)
 392              selector)))))
 393
 394 (defun elpher-make-special-address (type)
 395   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 396   type)
 397
 398 (defun elpher-make-start-page ()
 399   "Create the start page."
 400   (elpher-make-page "Elpher Start Page"
 401                     (elpher-make-special-address 'start)))
 402
 403 (defun elpher-address-to-url (address)
 404   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 405   (if (elpher-address-special-p address)
 406       nil
 407     (url-encode-url (url-recreate-url address))))
 408
 409 (defun elpher-address-type (address)
 410   "Retrieve type of ADDRESS object.
 411 This is used to determine how to retrieve and render the document the
 412 address refers to, via the table `elpher-type-map'."
 413   (if (symbolp address)
 414       (list 'special address)
 415     (let ((protocol (url-type address)))
 416       (cond ((or (equal protocol "gopher")
 417                  (equal protocol "gophers"))
 418              (list 'gopher
 419                    (if (member (url-filename address) '("" "/"))
 420                        ?1
 421                      (string-to-char (substring (url-filename address) 1)))))
 422             ((equal protocol "gemini")
 423              'gemini)
 424             ((equal protocol "telnet")
 425              'telnet)
 426             ((equal protocol "finger")
 427              'finger)
 428             (t 'other-url)))))
 429
 430 (defun elpher-address-protocol (address)
 431   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 432   (if (symbolp address)
 433       nil
 434     (url-type address)))
 435
 436 (defun elpher-address-filename (address)
 437   "Retrieve the filename component of ADDRESS.
 438 For gopher addresses this is a combination of the selector type and selector."
 439   (if (symbolp address)
 440       nil
 441     (url-filename address)))
 442
 443 (defun elpher-address-host (address)
 444   "Retrieve host from ADDRESS object."
 445   (url-host address))
 446
 447 (defun elpher-address-user (address)
 448   "Retrieve user from ADDRESS object."
 449   (url-user address))
 450
 451 (defun elpher-address-port (address)
 452   "Retrieve port from ADDRESS object.
 453 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 454   (if (symbolp address)
 455       0
 456     (url-port address)))
 457
 458 (defun elpher-address-special-p (address)
 459   "Return non-nil if ADDRESS object is special (e.g. start page page)."
 460   (symbolp address))
 461
 462 (defun elpher-address-gopher-p (address)
 463   "Return non-nill if ADDRESS object is a gopher address."
 464   (and (not (elpher-address-special-p address))
 465        (member (elpher-address-protocol address) '("gopher gophers"))))
 466
 467 (defun elpher-gopher-address-selector (address)
 468   "Retrieve gopher selector from ADDRESS object."
 469   (if (member (url-filename address) '("" "/"))
 470       ""
 471     (url-unhex-string (substring (url-filename address) 2))))
 472
 473
 474 ;; Cache
 475
 476 (defvar elpher-content-cache (make-hash-table :test 'equal))
 477 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 478
 479 (defun elpher-get-cached-content (address)
 480   "Retrieve the cached content for ADDRESS, or nil if none exists."
 481   (gethash address elpher-content-cache))
 482
 483 (defun elpher-cache-content (address content)
 484   "Set the content cache for ADDRESS to CONTENT."
 485   (puthash address content elpher-content-cache))
 486
 487 (defun elpher-get-cached-pos (address)
 488   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 489   (gethash address elpher-pos-cache))
 490
 491 (defun elpher-cache-pos (address pos)
 492   "Set the cursor position cache for ADDRESS to POS."
 493   (puthash address pos elpher-pos-cache))
 494
 495
 496 ;; Page
 497
 498 (defun elpher-make-page (display-string address)
 499   "Create a page with DISPLAY-STRING and ADDRESS."
 500   (list display-string address))
 501
 502 (defun elpher-page-display-string (page)
 503   "Retrieve the display string corresponding to PAGE."
 504   (elt page 0))
 505
 506 (defun elpher-page-address (page)
 507   "Retrieve the address corresponding to PAGE."
 508   (elt page 1))
 509
 510 (defun elpher-page-set-address (page new-address)
 511   "Set the address corresponding to PAGE to NEW-ADDRESS."
 512   (setcar (cdr page) new-address))
 513
 514 (defvar elpher-current-page nil
 515   "The current page for this Elpher buffer.")
 516
 517 (defvar elpher-history nil
 518   "The local history for this Elpher buffer.
 519 This variable is used by `elpher-back' and
 520 `elpher-show-history'.")
 521
 522 (defvar elpher-history-all nil
 523   "The global history for all Elpher buffers.
 524 This variable is used by `elpher-show-history-all'.")
 525
 526 (defun elpher-visit-page (page &optional renderer no-history)
 527   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 528 Additionally, push PAGE onto the stack of previously-visited pages,
 529 unless NO-HISTORY is non-nil."
 530   (elpher-save-pos)
 531   (elpher-process-cleanup)
 532   (unless (or no-history
 533               (equal (elpher-page-address elpher-current-page)
 534                      (elpher-page-address page)))
 535     (push elpher-current-page elpher-history)
 536     (push elpher-current-page elpher-history-all))
 537   (setq-local elpher-current-page page)
 538   (let* ((address (elpher-page-address page))
 539          (type (elpher-address-type address))
 540          (type-record (cdr (assoc type elpher-type-map)))
 541          (page-links nil))
 542     (if type-record
 543         (progn
 544           (funcall (car type-record)
 545                    (if renderer
 546                        renderer
 547                      (cadr type-record)))
 548           (setq page-links (gethash address elpher--gemini-page-links-cache))
 549           (if page-links
 550               (setq elpher--gemini-page-links page-links)))
 551       (elpher-visit-previous-page)
 552       (pcase type
 553         (`(gopher ,type-char)
 554          (error "Unsupported gopher selector type '%c' for '%s'"
 555                 type-char (elpher-address-to-url address)))
 556         (other
 557          (error "Unsupported address type '%S' for '%s'"
 558                 other (elpher-address-to-url address)))))))
 559
 560 (defun elpher-visit-previous-page ()
 561   "Visit the previous page in the history."
 562   (let ((previous-page (pop elpher-history)))
 563     (if previous-page
 564         (elpher-visit-page previous-page nil t)
 565       (error "No previous page"))))
 566
 567 (defun elpher-reload-current-page ()
 568   "Reload the current page, discarding any existing cached content."
 569   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 570   (elpher-visit-page elpher-current-page))
 571
 572 (defun elpher-save-pos ()
 573   "Save the current position of point to the current page."
 574   (when elpher-current-page
 575     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 576
 577 (defun elpher-restore-pos ()
 578   "Restore the position of point to that cached in the current page."
 579   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 580     (if pos
 581         (goto-char pos)
 582       (goto-char (point-min)))))
 583
 584
 585 ;;; Buffer preparation
 586 ;;
 587
 588 (defvar elpher-buffer-name "*elpher*"
 589   "The default name of the Elpher buffer.")
 590
 591 (defun elpher-update-header ()
 592   "If `elpher-use-header' is true, display current page info in window header."
 593   (if elpher-use-header
 594       (let* ((display-string (elpher-page-display-string elpher-current-page))
 595              (address (elpher-page-address elpher-current-page))
 596              (tls-string (if (and (not (elpher-address-special-p address))
 597                                   (member (elpher-address-protocol address)
 598                                           '("gophers" "gemini")))
 599                              " [TLS encryption]"
 600                            ""))
 601              (header (concat display-string
 602                              (propertize tls-string 'face 'bold))))
 603         (setq header-line-format header))))
 604
 605 (defmacro elpher-with-clean-buffer (&rest args)
 606   "Evaluate ARGS with a clean *elpher* buffer as current."
 607   `(with-current-buffer elpher-buffer-name
 608      (unless (eq major-mode 'elpher-mode)
 609        ;; avoid resetting buffer-local variables
 610        (elpher-mode))
 611      (let ((inhibit-read-only t))
 612        (setq-local network-security-level
 613                    (default-value 'network-security-level))
 614        (erase-buffer)
 615        (elpher-update-header)
 616        ,@args)))
 617
 618 (defun elpher-buffer-message (string &optional line)
 619   "Replace first line in elpher buffer with STRING.
 620 If LINE is non-nil, replace that line instead."
 621   (with-current-buffer elpher-buffer-name
 622     (let ((inhibit-read-only t))
 623       (goto-char (point-min))
 624       (if line
 625           (forward-line line))
 626       (let ((data (match-data)))
 627         (unwind-protect
 628             (progn
 629               (re-search-forward "^.*$")
 630               (replace-match string))
 631           (set-match-data data))))))
 632
 633
 634 ;;; Text Processing
 635 ;;
 636
 637 (defvar elpher-user-coding-system nil
 638   "User-specified coding system to use for decoding text responses.")
 639
 640 (defun elpher-decode (string)
 641   "Decode STRING using autodetected or user-specified coding system."
 642   (decode-coding-string string
 643                         (if elpher-user-coding-system
 644                             elpher-user-coding-system
 645                           (detect-coding-string string t))))
 646
 647 (defun elpher-preprocess-text-response (string)
 648   "Preprocess text selector response contained in STRING.
 649 This involes decoding the character representation, and clearing
 650 away CRs and any terminating period."
 651   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 652                                            (replace-regexp-in-string "\r" "" string))))
 653
 654
 655 ;;; Network error reporting
 656 ;;
 657
 658 (defun elpher-network-error (address error)
 659   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 660 ERROR can be either an error object or a string."
 661   (elpher-with-clean-buffer
 662    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 663            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 664            (if (stringp error) error (error-message-string error)) "\n"
 665            (propertize "\n----------------\n\n" 'face 'error)
 666            "Press 'u' to return to the previous page.")))
 667
 668
 669 ;;; General network communication
 670 ;;
 671
 672 (defvar elpher-network-timer nil
 673   "Timer used for network connections.")
 674
 675 (defvar elpher-use-tls nil
 676   "If non-nil, use TLS to communicate with gopher servers.")
 677
 678 (defvar elpher-client-certificate nil
 679   "If non-nil, contains client certificate details to use for TLS connections.")
 680
 681 (defun elpher-process-cleanup ()
 682   "Immediately shut down any extant elpher process and timers."
 683   (let ((p (get-process "elpher-process")))
 684     (if p (delete-process p)))
 685   (if (timerp elpher-network-timer)
 686       (cancel-timer elpher-network-timer)))
 687
 688 (defun elpher-get-host-response (address default-port query-string response-processor
 689                                          &optional use-tls force-ipv4)
 690   "Generic function for retrieving data from ADDRESS.
 691
 692 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 693 QUERY-STRING is a string sent to the host specified by ADDRESS to
 694 illicet a response.  This response is passed as an argument to the
 695 function RESPONSE-PROCESSOR.
 696
 697 If non-nil, USE-TLS specifies that the connection is to be made over
 698 TLS.  If set to gemini, the certificate verification will be disabled
 699 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 700
 701 If non-nil, FORCE-IPV4 causes the network connection to be made over
 702 ipv4 only.  (The default behaviour when this is not set depends on
 703 the host operating system and the local network capabilities."
 704   (if (and use-tls (not (gnutls-available-p)))
 705       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 706     (unless (< (elpher-address-port address) 65536)
 707       (error "Cannot establish network connection: port number > 65536"))
 708     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 709       (setq-local network-security-level 'low)
 710       (setq-local gnutls-verify-error nil))
 711     (condition-case nil
 712         (let* ((kill-buffer-query-functions nil)
 713                (port (elpher-address-port address))
 714                (service (if (> port 0) port default-port))
 715                (host (elpher-address-host address))
 716                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 717                (response-string-parts nil)
 718                (bytes-received 0)
 719                (hkbytes-received 0)
 720                (timer (run-at-time elpher-connection-timeout nil
 721                                    (lambda ()
 722                                      (elpher-process-cleanup)
 723                                      (cond
 724                                         ; Try again with IPv4
 725                                       ((not (or force-ipv4 socks))
 726                                        (message "Connection timed out.  Retrying with IPv4.")
 727                                        (elpher-get-host-response address default-port
 728                                                                  query-string
 729                                                                  response-processor
 730                                                                  use-tls t))
 731                                       ((and use-tls
 732                                             (not (eq use-tls 'gemini))
 733                                             (or elpher-auto-disengage-TLS
 734                                                 (y-or-n-p
 735                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 736                                        (setq elpher-use-tls nil)
 737                                        (elpher-get-host-response address default-port
 738                                                                  query-string
 739                                                                  response-processor
 740                                                                  nil force-ipv4))
 741                                       (t
 742                                        (elpher-network-error address "Connection time-out."))))))
 743                (gnutls-params (list :type 'gnutls-x509pki :hostname host
 744                                     :keylist (elpher-get-current-keylist address)))
 745                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 746                        (make-network-process :name "elpher-process"
 747                                              :host host
 748                                              :family (and force-ipv4 'ipv4)
 749                                              :service service
 750                                              :buffer nil
 751                                              :nowait t
 752                                              :tls-parameters
 753                                              (and use-tls
 754                                                   (cons 'gnutls-x509pki
 755                                                         (apply #'gnutls-boot-parameters
 756                                                                gnutls-params)))))))
 757           (setq elpher-network-timer timer)
 758           (set-process-coding-system proc 'binary 'binary)
 759           (set-process-query-on-exit-flag proc nil)
 760           (elpher-buffer-message (concat "Connecting to " host "..."
 761                                          " (press 'u' to abort)"))
 762           (set-process-filter proc
 763                               (lambda (_proc string)
 764                                 (when timer
 765                                   (cancel-timer timer)
 766                                   (setq timer nil))
 767                                 (setq bytes-received (+ bytes-received (length string)))
 768                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 769                                   (when (> new-hkbytes-received hkbytes-received)
 770                                     (setq hkbytes-received new-hkbytes-received)
 771                                     (elpher-buffer-message
 772                                      (concat "("
 773                                              (number-to-string (/ hkbytes-received 10.0))
 774                                              " MB read)")
 775                                      1)))
 776                                 (setq response-string-parts
 777                                       (cons string response-string-parts))))
 778           (set-process-sentinel proc
 779                                 (lambda (proc event)
 780                                   (when timer
 781                                     (cancel-timer timer))
 782                                   (condition-case the-error
 783                                       (cond
 784                                        ((string-prefix-p "open" event)    ; request URL
 785                                         (elpher-buffer-message
 786                                          (concat "Connected to " host ". Receiving data..."
 787                                                  " (press 'u' to abort)"))
 788                                         (let ((inhibit-eol-conversion t))
 789                                           (process-send-string proc query-string)))
 790                                        ((string-prefix-p "deleted" event)) ; do nothing
 791                                        ((and (not response-string-parts)
 792                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 793                                         ; Try again with IPv4
 794                                         (message "Connection failed. Retrying with IPv4.")
 795                                         (elpher-get-host-response address default-port
 796                                                                   query-string
 797                                                                   response-processor
 798                                                                   use-tls t))
 799                                        (response-string-parts
 800                                         (elpher-with-clean-buffer
 801                                          (insert "Data received.  Rendering..."))
 802                                         (funcall response-processor
 803                                                  (apply #'concat (reverse response-string-parts)))
 804                                         (elpher-restore-pos))
 805                                        (t
 806                                         (error "No response from server")))
 807                                     (error
 808                                      (elpher-network-error address the-error)))))
 809           (when socks
 810             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 811             (funcall (process-sentinel proc) proc "open\n")))
 812       (error
 813        (error "Error initiating connection to server")))))
 814
 815
 816 ;;; Client-side TLS Certificate Management
 817 ;;
 818
 819 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 820   "Generate a key and a self-signed client TLS certificate using openssl.
 821
 822 The Common Name field of the certificate is set to COMMON-NAME.  The
 823 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 824 the key and certificate files to write.
 825
 826 If TEMPORARY is non-nil, the certificate will be given an exporation
 827 period of one day, and the key and certificate files will be deleted
 828 when the certificate is no longer needed for the current session.
 829
 830 Otherwise, the certificate will be given a 100 year expiration period
 831 and the files will not be deleted.
 832
 833 The function returns a list containing the current host name, the
 834 temporary flag, and the key and cert file names in the form required
 835 by `gnutls-boot-parameters`."
 836   (let ((exp-key-file (expand-file-name key-file))
 837         (exp-cert-file (expand-file-name cert-file)))
 838     (condition-case nil
 839         (progn
 840           (call-process elpher-openssl-command nil nil nil
 841                         "req" "-x509" "-newkey" "rsa:2048"
 842                         "-days" (if temporary "1" "36500")
 843                         "-nodes"
 844                         "-subj" (concat "/CN=" common-name)
 845                         "-keyout" exp-key-file
 846                         "-out" exp-cert-file)
 847           (list (elpher-address-host (elpher-page-address elpher-current-page))
 848                 temporary exp-key-file exp-cert-file))
 849       (error
 850        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 851        (error "Program 'openssl', required for certificate generation, not found")))))
 852
 853 (defun elpher-generate-throwaway-certificate ()
 854   "Generate and return details of a throwaway certificate.
 855 The key and certificate files will be deleted when they are no
 856 longer needed for this session."
 857   (let* ((file-base (make-temp-name "elpher"))
 858          (key-file (concat temporary-file-directory file-base ".key"))
 859          (cert-file (concat temporary-file-directory file-base ".crt")))
 860     (elpher-generate-certificate file-base key-file cert-file t)))
 861
 862 (defun elpher-generate-persistent-certificate (file-base common-name)
 863   "Generate and return details of a persistent certificate.
 864 The argument FILE-BASE is used as the base for the key and certificate
 865 files, while COMMON-NAME specifies the common name field of the
 866 certificate.
 867
 868 The key and certificate files are written to in `elpher-certificate-directory'."
 869   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 870          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 871     (elpher-generate-certificate common-name key-file cert-file)))
 872
 873 (defun elpher-get-existing-certificate (file-base)
 874   "Return a certificate object corresponding to an existing certificate.
 875 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 876 the directory `elpher-certificate-directory'."
 877   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 878          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 879     (list (elpher-address-host (elpher-page-address elpher-current-page))
 880           nil
 881           (expand-file-name key-file)
 882           (expand-file-name cert-file))))
 883
 884 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 885   "Install a key+certificate file pair in `elpher-certificate-directory'.
 886 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 887 certificate files to install.  The argument FILE-BASE is used as the
 888 base for the installed key and certificate files."
 889   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 890          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 891     (if (or (file-exists-p key-file)
 892             (file-exists-p cert-file))
 893         (error "A certificate with base name %s is already installed" file-base))
 894     (copy-file key-file-src key-file)
 895     (copy-file cert-file-src cert-file)
 896     (list (elpher-address-host (elpher-page-address elpher-current-page))
 897           nil
 898           (expand-file-name key-file)
 899           (expand-file-name cert-file))))
 900
 901 (defun elpher-list-existing-certificates ()
 902   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 903   (unless (file-directory-p elpher-certificate-directory)
 904     (make-directory elpher-certificate-directory))
 905   (mapcar
 906    (lambda (file)
 907      (file-name-sans-extension file))
 908    (directory-files elpher-certificate-directory nil "\\.key$")))
 909
 910 (defun elpher-forget-current-certificate ()
 911   "Causes any current certificate to be forgotten.)
 912 In the case of throwaway certificates, the key and certificate files
 913 are also deleted."
 914   (interactive)
 915   (when elpher-client-certificate
 916     (unless (and (called-interactively-p 'any)
 917                  (not (y-or-n-p (concat "Really forget client certificate? "
 918                                         "(Throwaway certificates will be deleted.)"))))
 919       (when (cadr elpher-client-certificate)
 920         (delete-file (elt elpher-client-certificate 2))
 921         (delete-file (elt elpher-client-certificate 3)))
 922       (setq elpher-client-certificate nil)
 923       (if (called-interactively-p 'any)
 924           (message "Client certificate forgotten.")))))
 925
 926 (defun elpher-get-current-keylist (address)
 927   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 928
 929 This is obtained from the client certificate described by
 930 `elpher-current-certificate', if one is available and the host for
 931 that certificate matches the host in ADDRESS.
 932
 933 If `elpher-current-certificate' is non-nil, and its host name doesn't
 934 match that of ADDRESS, the certificate is forgotten."
 935   (if elpher-client-certificate
 936       (if (string= (car elpher-client-certificate)
 937                    (elpher-address-host address))
 938           (list (cddr elpher-client-certificate))
 939         (elpher-forget-current-certificate)
 940         (message "Disabling client certificate for new host")
 941         nil)
 942     nil))
 943
 944
 945 ;;; Gopher selector retrieval
 946 ;;
 947
 948 (defun elpher-get-gopher-response (address renderer)
 949   "Get response string from gopher server at ADDRESS and render using RENDERER."
 950   (elpher-get-host-response address 70
 951                             (concat (elpher-gopher-address-selector address) "\r\n")
 952                             renderer
 953                             (or (string= (elpher-address-protocol address) "gophers")
 954                                 elpher-use-tls)))
 955
 956 (defun elpher-get-gopher-page (renderer)
 957   "Getter function for gopher pages.
 958 The RENDERER procedure is used to display the contents of the page
 959 once they are retrieved from the gopher server."
 960   (let* ((address (elpher-page-address elpher-current-page))
 961          (content (elpher-get-cached-content address)))
 962     (if (and content (funcall renderer nil))
 963         (elpher-with-clean-buffer
 964          (insert content)
 965          (elpher-restore-pos))
 966       (elpher-with-clean-buffer
 967        (insert "LOADING... (use 'u' to cancel)\n"))
 968       (condition-case the-error
 969           (elpher-get-gopher-response address renderer)
 970         (error
 971          (elpher-network-error address the-error))))))
 972
 973 ;; Index rendering
 974
 975 (defun elpher-insert-index (string)
 976   "Insert the index corresponding to STRING into the current buffer."
 977   ;; Should be able to split directly on CRLF, but some non-conformant
 978   ;; LF-only servers sadly exist, hence the following.
 979   (let ((str-processed (elpher-preprocess-text-response string)))
 980     (dolist (line (split-string str-processed "\n"))
 981       (ignore-errors
 982         (unless (= (length line) 0)
 983           (let* ((type (elt line 0))
 984                  (fields (split-string (substring line 1) "\t"))
 985                  (display-string (elt fields 0))
 986                  (selector (elt fields 1))
 987                  (host (elt fields 2))
 988                  (port (if (elt fields 3)
 989                            (string-to-number (elt fields 3))
 990                          nil))
 991                  (address (elpher-make-gopher-address type selector host port)))
 992             (elpher-insert-index-record display-string address)))))))
 993
 994 (defun elpher-insert-margin (&optional type-name)
 995   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 996   (if type-name
 997       (progn
 998         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 999                         (concat
1000                          (propertize "[" 'face 'elpher-margin-brackets)
1001                          (propertize type-name 'face 'elpher-margin-key)
1002                          (propertize "]" 'face 'elpher-margin-brackets))))
1003         (insert " "))
1004     (insert (make-string elpher-margin-width ?\s))))
1005
1006 (defun elpher--page-button-help (_window buffer pos)
1007   "Function called by Emacs to generate mouse-over text.
1008 The arguments specify the BUFFER and the POS within the buffer of the item
1009 for which help is required.  The function returns the help to be
1010 displayed.  The _WINDOW argument is currently unused."
1011   (with-current-buffer buffer
1012     (let ((button (button-at pos)))
1013       (when button
1014         (let* ((page (button-get button 'elpher-page))
1015                (address (elpher-page-address page)))
1016           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1017                                                 address
1018                                               (elpher-address-to-url address))))))))
1019
1020 (defun elpher-insert-index-record (display-string &optional address)
1021   "Function to insert an index record into the current buffer.
1022 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1023 If ADDRESS is not supplied or nil the record is rendered as an
1024 'information' line."
1025   (let* ((type (if address (elpher-address-type address) nil))
1026          (type-map-entry (cdr (assoc type elpher-type-map))))
1027     (if type-map-entry
1028         (let* ((margin-code (elt type-map-entry 2))
1029                (face (elt type-map-entry 3))
1030                (filtered-display-string (elpher-color-filter-apply display-string))
1031                (page (elpher-make-page filtered-display-string address)))
1032           (elpher-insert-margin margin-code)
1033           (insert-text-button filtered-display-string
1034                               'face face
1035                               'elpher-page page
1036                               'action #'elpher-click-link
1037                               'follow-link t
1038                               'help-echo #'elpher--page-button-help))
1039       (pcase type
1040         ('nil ;; Information
1041          (elpher-insert-margin)
1042          (let ((propertized-display-string
1043                 (propertize display-string 'face 'elpher-info)))
1044            (insert (elpher-process-text-for-display propertized-display-string))))
1045         (`(gopher ,selector-type) ;; Unknown
1046          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1047          (insert (propertize display-string
1048                              'face 'elpher-unknown)))))
1049     (insert "\n")))
1050
1051 (defun elpher-click-link (button)
1052   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1053   (let ((page (button-get button 'elpher-page)))
1054     (elpher-visit-page page)))
1055
1056 (defun elpher-render-index (data &optional _mime-type-string)
1057   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1058   (elpher-with-clean-buffer
1059    (if (not data)
1060        t
1061      (elpher-insert-index data)
1062      (elpher-cache-content (elpher-page-address elpher-current-page)
1063                            (buffer-string)))))
1064
1065 ;; Text rendering
1066
1067 (defconst elpher-url-regex
1068   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
1069   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
1070
1071 (defun elpher-buttonify-urls (string)
1072   "Turn substrings which look like urls in STRING into clickable buttons."
1073   (with-temp-buffer
1074     (insert string)
1075     (goto-char (point-min))
1076     (while (re-search-forward elpher-url-regex nil t)
1077       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1078                                     (elpher-address-from-url (match-string 0)))))
1079         (make-text-button (match-beginning 0)
1080                           (match-end 0)
1081                           'elpher-page  page
1082                           'action #'elpher-click-link
1083                           'follow-link t
1084                           'help-echo #'elpher--page-button-help
1085                           'face 'button)))
1086     (buffer-string)))
1087
1088 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
1089   "Incomplete regexp used to strip out some troublesome ANSI escape sequences.")
1090
1091 (defun elpher-process-text-for-display (string)
1092   "Perform any desired processing of STRING prior to display as text.
1093 Currently includes buttonifying URLs and processing ANSI escape codes."
1094   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1095                              (elpher-color-filter-apply string)
1096                            (elpher-color-apply string))))
1097
1098 (defun elpher-render-text (data &optional _mime-type-string)
1099   "Render DATA as text.  MIME-TYPE-STRING is unused."
1100   (elpher-with-clean-buffer
1101    (if (not data)
1102        t
1103      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1104      (elpher-cache-content
1105       (elpher-page-address elpher-current-page)
1106       (buffer-string)))))
1107
1108 ;; Image retrieval
1109
1110 (defun elpher-render-image (data &optional _mime-type-string)
1111   "Display DATA as image.  MIME-TYPE-STRING is unused."
1112   (if (not data)
1113       nil
1114     (if (display-images-p)
1115         (progn
1116           (let ((image (create-image
1117                         data
1118                         nil t)))
1119             (elpher-with-clean-buffer
1120              (insert-image image)
1121              (elpher-restore-pos))))
1122       (elpher-render-download data))))
1123
1124 ;; Search retrieval and rendering
1125
1126 (defun elpher-get-gopher-query-page (renderer)
1127   "Getter for gopher addresses requiring input.
1128 The response is rendered using the rendering function RENDERER."
1129   (let* ((address (elpher-page-address elpher-current-page))
1130          (content (elpher-get-cached-content address))
1131          (aborted t))
1132     (if (and content (funcall renderer nil))
1133         (elpher-with-clean-buffer
1134          (insert content)
1135          (elpher-restore-pos)
1136          (message "Displaying cached search results.  Reload to perform a new search."))
1137       (unwind-protect
1138           (let* ((query-string (read-string "Query: "))
1139                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1140                  (search-address (elpher-make-gopher-address ?1
1141                                                              query-selector
1142                                                              (elpher-address-host address)
1143                                                              (elpher-address-port address)
1144                                                              (equal (elpher-address-type address) "gophers"))))
1145             (setq aborted nil)
1146
1147             (elpher-with-clean-buffer
1148              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1149             (elpher-get-gopher-response search-address renderer))
1150         (if aborted
1151             (elpher-visit-previous-page))))))
1152
1153 ;; Raw server response rendering
1154
1155 (defun elpher-render-raw (data &optional mime-type-string)
1156   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1157   (if (not data)
1158       nil
1159     (elpher-with-clean-buffer
1160      (when mime-type-string
1161        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1162      (insert data)
1163      (goto-char (point-min)))
1164     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1165
1166 ;; File save "rendering"
1167
1168 (defun elpher-render-download (data &optional _mime-type-string)
1169   "Save DATA to file.  MIME-TYPE-STRING is unused."
1170   (if (not data)
1171       nil
1172     (let* ((address (elpher-page-address elpher-current-page))
1173            (selector (if (elpher-address-gopher-p address)
1174                          (elpher-gopher-address-selector address)
1175                        (elpher-address-filename address))))
1176       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1177       (let* ((filename-proposal (file-name-nondirectory selector))
1178              (filename (read-file-name "Download complete. Save file as: "
1179                                        nil nil nil
1180                                        (if (> (length filename-proposal) 0)
1181                                            filename-proposal
1182                                          "download.file"))))
1183         (let ((coding-system-for-write 'binary))
1184           (with-temp-file filename
1185             (insert data)))
1186         (message (format "Saved to file %s." filename))))))
1187
1188 ;; HTML rendering
1189
1190 (defun elpher-render-html (data &optional _mime-type-string)
1191   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1192   (elpher-with-clean-buffer
1193    (if (not data)
1194        t
1195      (let ((dom (with-temp-buffer
1196                   (insert data)
1197                   (libxml-parse-html-region (point-min) (point-max)))))
1198        (shr-insert-document dom)))))
1199
1200 ;; Gemini page retrieval
1201
1202 (defvar elpher-gemini-redirect-chain)
1203
1204 (defun elpher-get-gemini-response (address renderer)
1205   "Get response string from gemini server at ADDRESS and render using RENDERER."
1206   (elpher-get-host-response address 1965
1207                             (concat (elpher-address-to-url address) "\r\n")
1208                             (lambda (response-string)
1209                               (elpher-process-gemini-response response-string renderer))
1210                             'gemini))
1211
1212 (defun elpher-parse-gemini-response (response)
1213   "Parse the RESPONSE string and return a list of components.
1214 The list is of the form (code meta body).  A response of nil implies
1215 that the response was malformed."
1216   (let ((header-end-idx (string-match "\r\n" response)))
1217     (if header-end-idx
1218         (let ((header (string-trim (substring response 0 header-end-idx)))
1219               (body (substring response (+ header-end-idx 2))))
1220           (if (>= (length header) 2)
1221               (let ((code (substring header 0 2))
1222                     (meta (string-trim (substring header 2))))
1223                 (list code meta body))
1224             (error "Malformed response: No response status found in header %s" header)))
1225       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1226
1227 (defun elpher-process-gemini-response (response-string renderer)
1228   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1229   (let ((response-components (elpher-parse-gemini-response response-string)))
1230     (let ((response-code (elt response-components 0))
1231           (response-meta (elt response-components 1))
1232           (response-body (elt response-components 2)))
1233       (pcase (elt response-code 0)
1234         (?1 ; Input required
1235          (elpher-with-clean-buffer
1236           (insert "Gemini server is requesting input."))
1237          (let* ((query-string
1238                  (if (eq (elt response-code 1) ?1)
1239                      (read-passwd (concat response-meta ": "))
1240                    (read-string (concat response-meta ": "))))
1241                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1242                 (old-fname (url-filename query-address)))
1243            (setf (url-filename query-address)
1244                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1245            (elpher-get-gemini-response query-address renderer)))
1246         (?2 ; Normal response
1247          (funcall renderer response-body response-meta))
1248         (?3 ; Redirect
1249          (message "Following redirect to %s" response-meta)
1250          (if (>= (length elpher-gemini-redirect-chain) 5)
1251              (error "More than 5 consecutive redirects followed"))
1252          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1253            (if (member redirect-address elpher-gemini-redirect-chain)
1254                (error "Redirect loop detected"))
1255            (if (not (string= (elpher-address-protocol redirect-address)
1256                              "gemini"))
1257                (error "Server tried to automatically redirect to non-gemini URL: %s"
1258                       response-meta))
1259            (elpher-page-set-address elpher-current-page redirect-address)
1260            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1261            (elpher-get-gemini-response redirect-address renderer)))
1262         (?4 ; Temporary failure
1263          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1264                 response-code response-meta))
1265         (?5 ; Permanent failure
1266          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1267                 response-code response-meta))
1268         (?6 ; Client certificate required
1269          (elpher-with-clean-buffer
1270           (if elpher-client-certificate
1271               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1272             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1273           (auto-fill-mode 1)
1274           (elpher-gemini-insert-text response-meta))
1275          (let ((chosen-certificate (elpher-choose-client-certificate)))
1276            (unless chosen-certificate
1277              (error "Gemini server requires a client certificate and none was provided"))
1278            (setq elpher-client-certificate chosen-certificate))
1279          (elpher-with-clean-buffer)
1280          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1281         (_other
1282          (error "Gemini server response unknown: %s %s"
1283                 response-code response-meta))))))
1284
1285 (unless (fboundp 'read-answer)
1286   (defun read-answer (question answers)
1287     "Backfill for the new read-answer code."
1288     (completing-read question (mapcar 'identity answers))))
1289
1290 (defun elpher-choose-client-certificate ()
1291   "Prompt for a client certificate to use to establish a TLS connection."
1292   (let* ((read-answer-short t))
1293     (pcase (read-answer "What do you want to do? "
1294                         '(("throwaway" ?t
1295                            "generate and use throw-away certificate")
1296                           ("persistent" ?p
1297                            "generate new or use existing persistent certificate")
1298                           ("abort" ?a
1299                            "stop immediately")))
1300       ("throwaway"
1301        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1302       ("persistent"
1303        (let* ((existing-certificates (elpher-list-existing-certificates))
1304               (file-base (completing-read
1305                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1306                           existing-certificates)))
1307          (if (string-empty-p (string-trim file-base))
1308              nil
1309            (if (member file-base existing-certificates)
1310                (setq elpher-client-certificate
1311                      (elpher-get-existing-certificate file-base))
1312              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1313                                  '(("new" ?n
1314                                     "generate new certificate")
1315                                    ("install" ?i
1316                                     "install existing certificate")
1317                                    ("abort" ?a
1318                                     "stop immediately")))
1319                ("new"
1320                 (let ((common-name (read-string "Common Name field for new certificate: "
1321                                                 file-base)))
1322                   (message "New key and self-signed certificate written to %s"
1323                            elpher-certificate-directory)
1324                   (elpher-generate-persistent-certificate file-base common-name)))
1325                ("install"
1326                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1327                        (key-file (read-file-name "Key file: " nil nil t)))
1328                   (message "Key and certificate installed in %s for future use"
1329                            elpher-certificate-directory)
1330                   (elpher-install-and-use-existing-certificate key-file
1331                                                                cert-file
1332                                                                file-base)))
1333                ("abort" nil))))))
1334       ("abort" nil))))
1335
1336 (defun elpher-get-gemini-page (renderer)
1337   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1338   (let* ((address (elpher-page-address elpher-current-page))
1339          (content (elpher-get-cached-content address)))
1340     (condition-case the-error
1341         (if (and content (funcall renderer nil))
1342             (elpher-with-clean-buffer
1343              (insert content)
1344              (elpher-restore-pos))
1345           (elpher-with-clean-buffer
1346            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1347           (setq elpher-gemini-redirect-chain nil)
1348           (elpher-get-gemini-response address renderer))
1349       (error
1350        (elpher-network-error address the-error)))))
1351
1352 (defun elpher-render-gemini (body &optional mime-type-string)
1353   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1354   (if (not body)
1355       t
1356     (let* ((mime-type-string* (if (or (not mime-type-string)
1357                                       (string-empty-p mime-type-string))
1358                                   "text/gemini; charset=utf-8"
1359                                 mime-type-string))
1360            (mime-type-split (split-string mime-type-string* ";" t))
1361            (mime-type (string-trim (car mime-type-split)))
1362            (parameters (mapcar (lambda (s)
1363                                  (let ((key-val (split-string s "=")))
1364                                    (list (downcase (string-trim (car key-val)))
1365                                          (downcase (string-trim (cadr key-val))))))
1366                                (cdr mime-type-split))))
1367       (when (string-prefix-p "text/" mime-type)
1368         (setq body (decode-coding-string
1369                     body
1370                     (if (assoc "charset" parameters)
1371                         (intern (cadr (assoc "charset" parameters)))
1372                       'utf-8)))
1373         (setq body (replace-regexp-in-string "\r" "" body)))
1374       (pcase mime-type
1375         ((or "text/gemini" "")
1376          (elpher-render-gemini-map body parameters))
1377         ("text/html"
1378          (elpher-render-html body))
1379         ((pred (string-prefix-p "text/"))
1380          (elpher-render-gemini-plain-text body parameters))
1381         ((pred (string-prefix-p "image/"))
1382          (elpher-render-image body))
1383         (_other
1384          (elpher-render-download body))))))
1385
1386 (defun elpher-gemini-get-link-url (link-line)
1387   "Extract the url portion of LINK-LINE, a gemini map file link line.
1388 Returns nil in the event that the contents of the line following the
1389 => prefix are empty."
1390   (let ((l (split-string (substring link-line 2))))
1391     (if l
1392         (string-trim (elt l 0))
1393       nil)))
1394
1395 (defun elpher-gemini-get-link-display-string (link-line)
1396   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1397 Returns the url portion in the event that the display-string portion is empty."
1398   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1399          (idx (string-match "[ \t]" rest)))
1400     (string-trim (if idx
1401                      (substring rest (+ idx 1))
1402                    rest))))
1403
1404 (defun elpher-collapse-dot-sequences (filename)
1405   "Collapse dot sequences in FILENAME.
1406 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1407   (let* ((path (split-string filename "/"))
1408          (path-reversed-normalized
1409           (seq-reduce (lambda (a b)
1410                         (cond ((and a (equal b "..") (cdr a)))
1411                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1412                               ((equal b ".") a)
1413                               (t (cons b a))))
1414                       path nil)))
1415     (string-join (reverse path-reversed-normalized) "/")))
1416
1417 (defun elpher-address-from-gemini-url (url)
1418   "Extract address from URL with defaults as per gemini map files.
1419 While there's obviously some redundancy here between this function and
1420 `elpher-address-from-url', gemini map file URLs require enough special
1421 treatment that a separate function is warranted."
1422   (let ((address (url-generic-parse-url url))
1423         (current-address (elpher-page-address elpher-current-page)))
1424     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1425       (setf (url-fullness address) t)
1426       (if (url-host address) ;if there is an explicit host, filenames are absolute
1427           (if (string-empty-p (url-filename address))
1428               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1429         (setf (url-host address) (url-host current-address))
1430         (setf (url-port address) (url-port current-address))
1431         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1432           (setf (url-filename address)
1433                 (concat (file-name-directory (url-filename current-address))
1434                         (url-filename address)))))
1435       (unless (url-type address)
1436         (setf (url-type address) "gemini"))
1437       (when (equal (url-type address) "gemini")
1438         (setf (url-filename address)
1439               (elpher-collapse-dot-sequences (url-filename address)))))
1440     (elpher-remove-redundant-ports address)))
1441
1442 (defun elpher-gemini-insert-link (link-line)
1443   "Insert link described by LINK-LINE into a text/gemini document."
1444   (let* ((url (elpher-gemini-get-link-url link-line))
1445          (display-string (elpher-gemini-get-link-display-string link-line))
1446          (address (elpher-address-from-gemini-url url))
1447          (type (if address (elpher-address-type address) nil))
1448          (type-map-entry (cdr (assoc type elpher-type-map))))
1449     (setq elpher--gemini-page-links (append elpher--gemini-page-links `(,address)))
1450     (when display-string
1451       (insert elpher-gemini-link-string)
1452       (if type-map-entry
1453           (let* ((face (elt type-map-entry 3))
1454                  (filtered-display-string (elpher-color-filter-apply display-string))
1455                  (page (elpher-make-page filtered-display-string address)))
1456             (insert-text-button filtered-display-string
1457                                 'face face
1458                                 'elpher-page page
1459                                 'action #'elpher-click-link
1460                                 'follow-link t
1461                                 'help-echo #'elpher--page-button-help))
1462         (insert (propertize display-string 'face 'elpher-unknown)))
1463       (insert "\n"))))
1464
1465 (defun elpher-gemini-insert-header (header-line)
1466   "Insert header described by HEADER-LINE into a text/gemini document.
1467 The gemini map file line describing the header is given
1468 by HEADER-LINE."
1469   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1470     (let* ((level (length (match-string 1 header-line)))
1471            (header (substring header-line (match-end 0)))
1472            (face (pcase level
1473                    (1 'elpher-gemini-heading1)
1474                    (2 'elpher-gemini-heading2)
1475                    (3 'elpher-gemini-heading3)
1476                    (_ 'default)))
1477            (fill-column (if (display-graphic-p)
1478                             (/ (* fill-column
1479                                   (font-get (font-spec :name (face-font 'default)) :size))
1480                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1481       (setq elpher--gemini-page-headings (cons (cons header (point))
1482                                                elpher--gemini-page-headings))
1483       (unless (display-graphic-p)
1484         (insert (make-string level ?#) " "))
1485       (insert (propertize header 'face face))
1486       (newline))))
1487
1488 (defun elpher-gemini-insert-text (text-line)
1489   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1490 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1491 width defined by `elpher-gemini-max-fill-width'."
1492   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1493   (let* ((line-prefix (match-string 2 text-line))
1494          (processed-text-line
1495           (if line-prefix
1496               (cond ((string-prefix-p "*" line-prefix)
1497                      (concat
1498                       (replace-regexp-in-string "\\*"
1499                                                 elpher-gemini-bullet-string
1500                                                 (match-string 0 text-line))
1501                       (substring text-line (match-end 0))))
1502                     ((string-prefix-p ">" line-prefix)
1503                      (propertize text-line 'face 'elpher-gemini-quoted))
1504                     (t text-line))
1505             text-line))
1506          (adaptive-fill-mode t)
1507          ;; fill-prefix is important for adaptive-fill-mode: without
1508          ;; it, multi-line list items are not indented correct
1509          (fill-prefix (if (match-string 2 text-line)
1510                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1511                         nil)))
1512     (insert (elpher-process-text-for-display processed-text-line))
1513     (newline)))
1514
1515 (defun elpher-render-gemini-map (data _parameters)
1516   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1517   (elpher-with-clean-buffer
1518    (setq elpher--gemini-page-headings nil)
1519    (let ((preformatted nil)
1520          (link-counter 1))
1521      (auto-fill-mode 1)
1522      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1523      (setq elpher--gemini-page-links '())
1524      (dolist (line (split-string data "\n"))
1525        (cond
1526         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1527         (preformatted (insert (elpher-process-text-for-display
1528                                (propertize line 'face 'elpher-gemini-preformatted))
1529                               "\n"))
1530         ((string-prefix-p "=>" line)
1531          (progn
1532            (if elpher-gemini-number-links
1533                (insert
1534                 (concat
1535                  "["
1536                  (number-to-string link-counter)
1537                  "] ")))
1538            (setq link-counter (1+ link-counter))
1539            (elpher-gemini-insert-link line)))
1540         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1541         (t (elpher-gemini-insert-text line)))))
1542    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1543    (elpher-cache-content
1544     (elpher-page-address elpher-current-page)
1545     (buffer-string))
1546    (puthash
1547     (elpher-page-address elpher-current-page)
1548     elpher--gemini-page-links
1549     elpher--gemini-page-links-cache)))
1550
1551 (defun elpher-render-gemini-plain-text (data _parameters)
1552   "Render DATA as plain text file.  PARAMETERS is currently unused."
1553   (elpher-with-clean-buffer
1554    (insert (elpher-process-text-for-display data))
1555    (elpher-cache-content
1556     (elpher-page-address elpher-current-page)
1557     (buffer-string))))
1558
1559
1560 ;; Finger page connection
1561
1562 (defun elpher-get-finger-page (renderer)
1563   "Opens a finger connection to the current page address.
1564 The result is rendered using RENDERER."
1565   (let* ((address (elpher-page-address elpher-current-page))
1566          (content (elpher-get-cached-content address)))
1567     (if (and content (funcall renderer nil))
1568         (elpher-with-clean-buffer
1569          (insert content)
1570          (elpher-restore-pos))
1571       (elpher-with-clean-buffer
1572        (insert "LOADING... (use 'u' to cancel)\n"))
1573       (condition-case the-error
1574           (let* ((kill-buffer-query-functions nil)
1575                  (user (let ((filename (elpher-address-filename address)))
1576                          (if (> (length filename) 1)
1577                              (substring filename 1)
1578                            (elpher-address-user address)))))
1579             (elpher-get-host-response address 79
1580                                       (concat user "\r\n")
1581                                       renderer))
1582         (error
1583          (elpher-network-error address the-error))))))
1584
1585
1586 ;; Telnet page connection
1587
1588 (defun elpher-get-telnet-page (renderer)
1589   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1590   (when renderer
1591     (elpher-visit-previous-page)
1592     (error "Command not supported for telnet URLs"))
1593   (let* ((address (elpher-page-address elpher-current-page))
1594          (host (elpher-address-host address))
1595          (port (elpher-address-port address)))
1596     (elpher-visit-previous-page)
1597     (if (> port 0)
1598         (telnet host port)
1599       (telnet host))))
1600
1601
1602 ;; Other URL page opening
1603
1604 (defun elpher-get-other-url-page (renderer)
1605   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1606   (when renderer
1607     (elpher-visit-previous-page)
1608     (error "Command not supported for general URLs"))
1609   (let* ((address (elpher-page-address elpher-current-page))
1610          (url (elpher-address-to-url address)))
1611     (progn
1612       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1613       (message "Opening URL...")
1614       (if elpher-open-urls-with-eww
1615           (browse-web url)
1616         (browse-url url)))))
1617
1618
1619 ;; Start page page retrieval
1620
1621 (defun elpher-get-start-page (renderer)
1622   "Getter which displays the start page (RENDERER must be nil)."
1623   (when renderer
1624     (elpher-visit-previous-page)
1625     (error "Command not supported for start page"))
1626   (elpher-with-clean-buffer
1627    (insert "     --------------------------------------------\n"
1628            "           Elpher Gopher and Gemini Client       \n"
1629            "                   version " elpher-version "\n"
1630            "     --------------------------------------------\n"
1631            "\n"
1632            "Default bindings:\n"
1633            "\n"
1634            " - TAB/Shift-TAB: next/prev item on current page\n"
1635            " - RET/mouse-1: open item under cursor\n"
1636            " - m: select an item on current page by name (autocompletes)\n"
1637            " - u/mouse-3/U: return to previous page or to the start page\n"
1638            " - o/O: visit different selector or the root menu of the current server\n"
1639            " - g: go to a particular address (gopher, gemini, finger)\n"
1640            " - v: visit a numbered link on a gemini page\n"
1641            " - d/D: download item under cursor or current page\n"
1642            " - i/I: info on item under cursor or current page\n"
1643            " - c/C: copy URL representation of item under cursor or current page\n"
1644            " - a/A: bookmark the item under cursor or current page\n"
1645            " - B: list all bookmarks\n"
1646            " - h/H: show history of current buffer or for all buffers\n"
1647            " - r: redraw current page (using cached contents if available)\n"
1648            " - R: reload current page (regenerates cache)\n"
1649            " - S: set character coding system for gopher (default is to autodetect)\n"
1650            " - T: toggle TLS gopher mode\n"
1651            " - F: forget/discard current TLS client certificate\n"
1652            " - .: display the raw server response for the current page\n"
1653            "\n"
1654            "Start your exploration of gopher space and gemini:\n")
1655    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1656                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1657    (elpher-insert-index-record "Project Gemini home page"
1658                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1659    (insert "\n"
1660            "Alternatively, select a search engine and enter some search terms:\n")
1661    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1662                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1663    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1664                                (elpher-address-from-url "gemini://geminispace.info/search"))
1665    (insert "\n"
1666            "For Elpher release news or to leave feedback, visit:\n")
1667    (elpher-insert-index-record "The Elpher Project Page"
1668                                (elpher-make-gopher-address ?1
1669                                                            "/projects/elpher/"
1670                                                            "thelambdalab.xyz"
1671                                                            70))
1672    (insert "\n"
1673            "** Refer to the ")
1674    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1675      (insert-text-button "Elpher info manual"
1676                          'face 'link
1677                          'action (lambda (_)
1678                                    (interactive)
1679                                    (info "(elpher)"))
1680                          'follow-link t
1681                          'help-echo help-string))
1682    (insert " for the full documentation. **\n")
1683    (insert (propertize
1684             (concat "  (This should be available if you have installed Elpher using\n"
1685                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1686             'face 'shadow))
1687    (elpher-restore-pos)))
1688
1689 ;; History page retrieval
1690
1691 (defun elpher-history ()
1692   "Show the history of pages leading to the current page
1693 in this buffer. Use \\[elpher-history-all] to see the entire history.
1694 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1695   (interactive)
1696   (elpher-visit-page
1697    (elpher-make-page "Elpher History Page"
1698                      (elpher-make-special-address 'history))))
1699
1700 (defun elpher-history-all ()
1701   "Show the all the pages you've visited using Elpher.
1702 Use \\[elpher-history] to see just the history for the current buffer.
1703 This is rendered using `elpher-get-history-all-page' via `elpher-type-map'."
1704   (interactive)
1705   (elpher-visit-page
1706    (elpher-make-page "Elpher History Of All Seen Pages"
1707                      (elpher-make-special-address 'history-all))))
1708
1709 (defun elpher-get-history-page (renderer)
1710   "Getter which displays the history page (RENDERER must be nil)."
1711   (when renderer
1712     (elpher-visit-previous-page)
1713     (error "Command not supported for history page"))
1714   (elpher-show-history elpher-history))
1715
1716 (defun elpher-get-history-all-page (renderer)
1717   "Getter which displays the history page (RENDERER must be nil)."
1718   (when renderer
1719     (elpher-visit-previous-page)
1720     (error "Command not supported for history page"))
1721   (elpher-show-history elpher-history-all))
1722
1723 (defun elpher-show-history (pages)
1724   "Show all PAGES in the Elpher buffer."
1725   (elpher-with-clean-buffer
1726    (if pages
1727        (dolist (page pages)
1728          (when page
1729            (let ((display-string (elpher-page-display-string page))
1730                  (address (elpher-page-address page)))
1731              (elpher-insert-index-record display-string address))))
1732      (insert "No history items found.\n"))))
1733
1734 ;;; Bookmarks
1735
1736 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1737 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1738 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1739 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1740
1741 (defvar elpher-bookmark-link nil
1742   "Prefer bookmarking a link or the current page.
1743 Bind this variable dynamically, or set it to t.
1744 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1745 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1746
1747 (defun elpher-bookmark-make-record ()
1748   "Return a bookmark record.
1749 If `elpher-bookmark-link' is non-nil and point is on a link button,
1750 return a bookmark record for that link. Otherwise, return a bookmark
1751 record for the current elpher page."
1752   (let* ((button (and elpher-bookmark-link (button-at (point))))
1753          (page (if button
1754                    (button-get button 'elpher-page)
1755                  elpher-current-page))
1756          (address (elpher-page-address page))
1757          (url (elpher-address-to-url address))
1758          (display-string (elpher-page-display-string page))
1759          (pos (if button nil (point))))
1760     (if (elpher-address-special-p address)
1761         (error "Cannot bookmark %s" display-string)
1762       `(,display-string
1763         (defaults . (,display-string))
1764         (position . ,pos)
1765         (location . ,url)
1766         (handler . elpher-bookmark-jump)))))
1767
1768 ;;;###autoload
1769 (defun elpher-bookmark-jump (bookmark)
1770   "Go to a particular BOOKMARK."
1771   (let* ((url (cdr (assq 'location bookmark))))
1772     (elpher-go url)))
1773
1774 (defun elpher-set-bookmark-no-overwrite ()
1775   "Bookmark the link at point.
1776 To bookmark the current page, use \\[bookmark-set-no-overwrite]."
1777   (interactive)
1778   (let ((elpher-bookmark-link t))
1779     (bookmark-set-no-overwrite)))
1780
1781 (defun elpher-bookmark-import (file)
1782   "Import Elpher bookmarks into Emacs bookmarks."
1783   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1784                               (file-readable-p elpher-bookmarks-file))
1785                          elpher-bookmarks-file
1786                        (read-file-name "Old Elpher bookmarks: "
1787                                        user-emacs-directory nil t
1788                                        "elpher-bookmarks"))))
1789   (require 'bookmark)
1790   (dolist (bookmark (with-temp-buffer
1791                       (insert-file-contents file)
1792                       (read (current-buffer))))
1793     (let* ((display-string (car bookmark))
1794            (url (cadr bookmark))
1795            (record `(,display-string
1796                      (location . ,url)
1797                      (handler . elpher-bookmark-jump))))
1798       (bookmark-store display-string (cdr record) t)))
1799   (bookmark-save))
1800
1801 ;;; Integrations
1802 ;;
1803
1804 ;;; Org
1805
1806 ;; Avoid byte compilation warnings.
1807 (eval-when-compile
1808   (declare-function org-link-store-props "ol")
1809   (declare-function org-link-set-parameters "ol"))
1810
1811 (defun elpher-org-export-link (link description format protocol)
1812   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1813
1814 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1815 of gemini, gopher or finger."
1816   (let* ((url (if (equal protocol "elpher")
1817                   (string-remove-prefix "elpher:" link)
1818                 (format "%s:%s" protocol link)))
1819          (desc (or description url)))
1820     (pcase format
1821       (`gemini (format "=> %s %s" url desc))
1822       (`html (format "<a href=\"%s\">%s</a>" url desc))
1823       (`latex (format "\\href{%s}{%s}" url desc))
1824       (_ (if (not description)
1825              url
1826            (format "%s (%s)" desc url))))))
1827
1828 (defun elpher-org-store-link ()
1829   "Store link to an `elpher' page in Org."
1830   (when (eq major-mode 'elpher-mode)
1831     (let* ((url (elpher-info-current))
1832            (desc (car elpher-current-page))
1833            (protocol (cond
1834                       ((string-prefix-p "gemini:" url) "gemini")
1835                       ((string-prefix-p "gopher:" url) "gopher")
1836                       ((string-prefix-p "finger:" url) "finger")
1837                       (t "elpher"))))
1838       (when (equal "elpher" protocol)
1839         ;; Weird link. Or special inner link?
1840         (setq url (concat "elpher:" url)))
1841       (org-link-store-props :type protocol :link url :description desc)
1842       t)))
1843
1844 (defun elpher-org-follow-link (link protocol)
1845   "Visit a LINK for the given PROTOCOL.
1846
1847 PROTOCOL may be one of gemini, gopher or finger.  This method also
1848 supports the old protocol elpher, where the link is self-contained."
1849   (let ((url (if (equal protocol "elpher")
1850                  (string-remove-prefix "elpher:" link)
1851                (format "%s:%s" protocol link))))
1852     (elpher-go url)))
1853
1854 (with-eval-after-load 'org
1855   (org-link-set-parameters
1856    "elpher"
1857    :store #'elpher-org-store-link
1858    :export (lambda (link description format _plist)
1859              (elpher-org-export-link link description format "elpher"))
1860    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1861   (org-link-set-parameters
1862    "gemini"
1863    :export (lambda (link description format _plist)
1864              (elpher-org-export-link link description format "gemini"))
1865    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
1866   (org-link-set-parameters
1867    "gopher"
1868    :export (lambda (link description format _plist)
1869              (elpher-org-export-link link description format "gopher"))
1870    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
1871   (org-link-set-parameters
1872    "finger"
1873    :export (lambda (link description format _plist)
1874              (elpher-org-export-link link description format "finger"))
1875    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
1876
1877 ;;; Browse URL
1878
1879 ;; Avoid byte compilation warnings.
1880 (eval-when-compile
1881   (defvar thing-at-point-uri-schemes))
1882
1883 ;;;###autoload
1884 (defun elpher-browse-url-elpher (url &rest _args)
1885   "Browse URL using Elpher.  This function is used by `browse-url'."
1886   (interactive (browse-url-interactive-arg "Elpher URL: "))
1887   (elpher-go url))
1888
1889 ;; Use elpher to open gopher, finger and gemini links
1890 ;; For recent version of `browse-url' package
1891 (if (boundp 'browse-url-default-handlers)
1892     (add-to-list
1893      'browse-url-default-handlers
1894      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
1895   ;; Patch `browse-url-browser-function' for older ones. The value of
1896   ;; that variable is `browse-url-default-browser' by default, so
1897   ;; that's the function that gets advised.
1898   (advice-add browse-url-browser-function :before-while
1899               (lambda (url &rest _args)
1900                 "Handle gemini, gopher, and finger schemes using Elpher."
1901                 (let ((scheme (downcase (car (split-string url ":" t)))))
1902                   (if (member scheme '("gemini" "gopher" "finger"))
1903                       ;; `elpher-go' always returns nil, which will stop the
1904                       ;; advice chain here in a before-while
1905                       (elpher-go url)
1906                     ;; chain must continue, then return t.
1907                     t)))))
1908
1909 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1910 (with-eval-after-load 'thingatpt
1911   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
1912
1913 ;;; Mu4e:
1914
1915 (eval-when-compile
1916   (defvar mu4e~view-beginning-of-url-regexp))
1917
1918 (with-eval-after-load 'mu4e-view
1919   ;; Make mu4e aware of the gemini world
1920   (setq mu4e~view-beginning-of-url-regexp
1921         "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:"))
1922
1923 ;;; Interactive procedures
1924 ;;
1925
1926 (defun elpher-next-link ()
1927   "Move point to the next link on the current page."
1928   (interactive)
1929   (forward-button 1))
1930
1931 (defun elpher-prev-link ()
1932   "Move point to the previous link on the current page."
1933   (interactive)
1934   (backward-button 1))
1935
1936 (defun elpher-follow-current-link ()
1937   "Open the link or url at point."
1938   (interactive)
1939   (push-button))
1940
1941 ;;;###autoload
1942 (defun elpher-go (host-or-url)
1943   "Go to a particular gopher site HOST-OR-URL.
1944 When run interactively HOST-OR-URL is read from the minibuffer."
1945   (interactive "sGopher or Gemini URL: ")
1946   (let* ((cleaned-host-or-url (string-trim host-or-url))
1947          (address (elpher-address-from-url cleaned-host-or-url))
1948          (page (elpher-make-page cleaned-host-or-url address)))
1949     (switch-to-buffer elpher-buffer-name)
1950     (elpher-with-clean-buffer
1951      (elpher-visit-page page))
1952     nil))
1953
1954 (defun elpher-go-current ()
1955   "Go to a particular site read from the minibuffer, initialized with the current URL."
1956   (interactive)
1957   (let ((address (elpher-page-address elpher-current-page)))
1958     (let ((url (read-string "Gopher or Gemini URL: "
1959                             (unless (elpher-address-special-p address)
1960                               (elpher-address-to-url address)))))
1961       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
1962
1963 (defun elpher-visit-gemini-numbered-link (n)
1964   "Visit link designated by a number N."
1965   (interactive "nLink number: ")
1966   (if (or (> n (length elpher--gemini-page-links))
1967           (< n 1))
1968       (user-error "Invalid link number"))
1969   (let ((address (nth (1- n) elpher--gemini-page-links)))
1970     (elpher-go (url-recreate-url address))))
1971
1972 (defun elpher-redraw ()
1973   "Redraw current page."
1974   (interactive)
1975   (elpher-visit-page elpher-current-page))
1976
1977 (defun elpher-reload ()
1978   "Reload current page."
1979   (interactive)
1980   (elpher-reload-current-page))
1981
1982 (defun elpher-toggle-tls ()
1983   "Toggle TLS encryption mode for gopher."
1984   (interactive)
1985   (setq elpher-use-tls (not elpher-use-tls))
1986   (if elpher-use-tls
1987       (if (gnutls-available-p)
1988           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1989         (setq elpher-use-tls nil)
1990         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1991     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1992
1993 (defun elpher-view-raw ()
1994   "View raw server response for current page."
1995   (interactive)
1996   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1997       (error "This page was not generated by a server")
1998     (elpher-visit-page elpher-current-page
1999                        #'elpher-render-raw)))
2000
2001 (defun elpher-back ()
2002   "Go to previous site."
2003   (interactive)
2004   (elpher-visit-previous-page))
2005
2006 (defun elpher-back-to-start ()
2007   "Go all the way back to the start page."
2008   (interactive)
2009   (setq-local elpher-current-page nil)
2010   (setq-local elpher-history nil)
2011   (elpher-visit-page (elpher-make-start-page)))
2012
2013 (defun elpher-download ()
2014   "Download the link at point."
2015   (interactive)
2016   (let ((button (button-at (point))))
2017     (if button
2018         (let ((page (button-get button 'elpher-page)))
2019           (if (elpher-address-special-p (elpher-page-address page))
2020               (error "Cannot download %s"
2021                      (elpher-page-display-string page))
2022             (elpher-visit-page (button-get button 'elpher-page)
2023                                #'elpher-render-download)))
2024       (error "No link selected"))))
2025
2026 (defun elpher-download-current ()
2027   "Download the current page."
2028   (interactive)
2029   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2030       (error "Cannot download %s"
2031              (elpher-page-display-string elpher-current-page))
2032     (elpher-visit-page (elpher-make-page
2033                         (elpher-page-display-string elpher-current-page)
2034                         (elpher-page-address elpher-current-page))
2035                        #'elpher-render-download
2036                        t)))
2037
2038 (defun elpher-build-link-map ()
2039   "Build alist mapping link names to destination pages in current buffer."
2040   (let ((link-map nil)
2041         (b (next-button (point-min) t)))
2042     (while b
2043       (push (cons (button-label b) b) link-map)
2044       (setq b (next-button (button-start b))))
2045     link-map))
2046
2047 (defun elpher-jump ()
2048   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2049   (interactive)
2050   (let* ((link-map (elpher-build-link-map)))
2051     (if link-map
2052         (let ((key (let ((completion-ignore-case t))
2053                      (completing-read "Directory item/link: "
2054                                       link-map nil t))))
2055           (if (and key (> (length key) 0))
2056               (let ((b (cdr (assoc key link-map))))
2057                 (goto-char (button-start b))
2058                 (button-activate b)))))))
2059
2060 (defun elpher-root-dir ()
2061   "Visit root of current server."
2062   (interactive)
2063   (let ((address (elpher-page-address elpher-current-page)))
2064     (if (not (elpher-address-special-p address))
2065         (if (or (member (url-filename address) '("/" ""))
2066                 (and (elpher-address-gopher-p address)
2067                      (= (length (elpher-gopher-address-selector address)) 0)))
2068             (error "Already at root directory of current server")
2069           (let ((address-copy (elpher-address-from-url
2070                                (elpher-address-to-url address))))
2071             (setf (url-filename address-copy) "")
2072             (elpher-go (elpher-address-to-url address-copy))))
2073       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2074
2075 (defun elpher-info-page (page)
2076   "Display information on PAGE."
2077   (let ((display-string (elpher-page-display-string page))
2078         (address (elpher-page-address page)))
2079     (if (elpher-address-special-p address)
2080         (message "Special page: %s" display-string)
2081       (message "%s" (elpher-address-to-url address)))))
2082
2083 (defun elpher-info-link ()
2084   "Display information on page corresponding to link at point."
2085   (interactive)
2086   (let ((button (button-at (point))))
2087     (if button
2088         (elpher-info-page (button-get button 'elpher-page))
2089       (error "No item selected"))))
2090
2091 (defun elpher-info-current ()
2092   "Display information on current page."
2093   (interactive)
2094   (elpher-info-page elpher-current-page))
2095
2096 (defun elpher-copy-page-url (page)
2097   "Copy URL representation of address of PAGE to `kill-ring'."
2098   (let ((address (elpher-page-address page)))
2099     (if (elpher-address-special-p address)
2100         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2101       (let ((url (elpher-address-to-url address)))
2102         (message "Copied \"%s\" to kill-ring/clipboard." url)
2103         (kill-new url)))))
2104
2105 (defun elpher-copy-link-url ()
2106   "Copy URL of item at point to `kill-ring'."
2107   (interactive)
2108   (let ((button (button-at (point))))
2109     (if button
2110         (elpher-copy-page-url (button-get button 'elpher-page))
2111       (error "No item selected"))))
2112
2113 (defun elpher-copy-current-url ()
2114   "Copy URL of current page to `kill-ring'."
2115   (interactive)
2116   (elpher-copy-page-url elpher-current-page))
2117
2118 (defun elpher-set-gopher-coding-system ()
2119   "Specify an explicit character coding system for gopher selectors."
2120   (interactive)
2121   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2122     (setq elpher-user-coding-system system)
2123     (if system
2124         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2125       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2126
2127
2128 ;;; Mode and keymap
2129 ;;
2130
2131 (defvar elpher-mode-map
2132   (let ((map (make-sparse-keymap)))
2133     (define-key map (kbd "TAB") 'elpher-next-link)
2134     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2135     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2136     (define-key map (kbd "u") 'elpher-back)
2137     (define-key map (kbd "U") 'elpher-back-to-start)
2138     (define-key map [mouse-3] 'elpher-back)
2139     (define-key map (kbd "O") 'elpher-root-dir)
2140     (define-key map (kbd "g") 'elpher-go)
2141     (define-key map (kbd "o") 'elpher-go-current)
2142     (define-key map (kbd "h") 'elpher-history)
2143     (define-key map (kbd "H") 'elpher-history-all)
2144     (define-key map (kbd "r") 'elpher-redraw)
2145     (define-key map (kbd "R") 'elpher-reload)
2146     (define-key map (kbd "T") 'elpher-toggle-tls)
2147     (define-key map (kbd ".") 'elpher-view-raw)
2148     (define-key map (kbd "d") 'elpher-download)
2149     (define-key map (kbd "D") 'elpher-download-current)
2150     (define-key map (kbd "m") 'elpher-jump)
2151     (define-key map (kbd "i") 'elpher-info-link)
2152     (define-key map (kbd "I") 'elpher-info-current)
2153     (define-key map (kbd "c") 'elpher-copy-link-url)
2154     (define-key map (kbd "C") 'elpher-copy-current-url)
2155     (define-key map (kbd "a") 'elpher-set-bookmark-no-overwrite)
2156     (define-key map (kbd "A") 'bookmark-set-no-overwrite)
2157     (define-key map (kbd "B") 'bookmark-bmenu-list)
2158     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
2159     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2160     (define-key map (kbd "v") 'elpher-visit-gemini-numbered-link)
2161     (when (fboundp 'evil-define-key*)
2162       (evil-define-key*
2163        'motion map
2164        (kbd "TAB") 'elpher-next-link
2165        (kbd "C-") 'elpher-follow-current-link
2166        (kbd "C-t") 'elpher-back
2167        (kbd "u") 'elpher-back
2168        (kbd "-") 'elpher-back
2169        (kbd "^") 'elpher-back
2170        (kbd "U") 'elpher-back-to-start
2171        [mouse-3] 'elpher-back
2172        (kbd "o") 'elpher-go
2173        (kbd "O") 'elpher-go-current
2174        (kbd "r") 'elpher-redraw
2175        (kbd "R") 'elpher-reload
2176        (kbd "T") 'elpher-toggle-tls
2177        (kbd ".") 'elpher-view-raw
2178        (kbd "d") 'elpher-download
2179        (kbd "D") 'elpher-download-current
2180        (kbd "J") 'elpher-jump
2181        (kbd "i") 'elpher-info-link
2182        (kbd "I") 'elpher-info-current
2183        (kbd "c") 'elpher-copy-link-url
2184        (kbd "C") 'elpher-copy-current-url
2185        (kbd "a") 'elpher-set-bookmark-no-overwrite
2186        (kbd "A") 'bookmark-set-no-overwrite
2187        (kbd "B") 'bookmark-bmenu-list
2188        (kbd "S") 'elpher-set-gopher-coding-system
2189        (kbd "F") 'elpher-forget-current-certificate
2190        (kbd "v") 'elpher-visit-gemini-numbered-link))
2191     map)
2192   "Keymap for gopher client.")
2193
2194 (define-derived-mode elpher-mode special-mode "elpher"
2195   "Major mode for elpher, an elisp gopher client.
2196
2197 This mode is automatically enabled by the interactive
2198 functions which initialize the client, namely
2199 `elpher', and `elpher-go'."
2200   (setq-local elpher--gemini-page-headings nil)
2201   (setq-local elpher-current-page nil)
2202   (setq-local elpher-history nil)
2203   (setq-local elpher-buffer-name (buffer-name))
2204   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2205   (setq-local imenu-create-index-function #'elpher--gemini-page-headings))
2206
2207 (when (fboundp 'evil-set-initial-state)
2208   (evil-set-initial-state 'elpher-mode 'motion))
2209
2210
2211 ;;; Main start procedure
2212 ;;
2213
2214 ;;;###autoload
2215 (defun elpher (&optional arg)
2216   "Start elpher with default landing page.
2217 The buffer used for Elpher sessions is determined by the value of
2218 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2219 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2220 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2221 \\[execute-extended-command] elpher RET’) switches to the session with
2222 that number, creating it if necessary.  A non numeric prefix ARG means
2223 to create a new session.  Returns the buffer selected (or created)."
2224   (interactive "P")
2225   (let* ((name (default-value 'elpher-buffer-name))
2226          (buf (cond ((numberp arg)
2227                      (get-buffer-create (format "%s<%d>" name arg)))
2228                     (arg
2229                      (generate-new-buffer name))
2230                     (t
2231                      (get-buffer-create name)))))
2232     (pop-to-buffer-same-window buf)
2233     (unless (buffer-modified-p)
2234       (elpher-mode)
2235       (elpher-visit-page (elpher-make-start-page))
2236       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2237
2238 ;;; elpher.el ends here