elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.7.8
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "2.7.8"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  95     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  96     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  97     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  98     ((special start) elpher-get-start-page nil))
  99   "Association list from types to getters, renderers, margin codes and index faces.")
 100
 101
 102 ;;; Customization group
 103 ;;
 104
 105 (defgroup elpher nil
 106   "A gopher client."
 107   :group 'applications)
 108
 109 ;; General appearance and customizations
 110
 111 (defcustom elpher-open-urls-with-eww nil
 112   "If non-nil, open URL selectors using eww.
 113 Otherwise, use the system browser via the BROWSE-URL function."
 114   :type '(boolean))
 115
 116 (defcustom elpher-use-header t
 117   "If non-nil, display current page information in buffer header."
 118   :type '(boolean))
 119
 120 (defcustom elpher-auto-disengage-TLS nil
 121   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 122 While enabling this may seem convenient, it is also potentially dangerous as it
 123 allows switching from an encrypted channel back to plain text without user input."
 124   :type '(boolean))
 125
 126 (defcustom elpher-connection-timeout 5
 127   "Specifies the number of seconds to wait for a network connection to time out."
 128   :type '(integer))
 129
 130 (defcustom elpher-filter-ansi-from-text nil
 131   "If non-nil, filter ANSI escape sequences from text.
 132 The default behaviour is to use the ansi-color package to interpret these
 133 sequences."
 134   :type '(boolean))
 135
 136 (defcustom elpher-gemini-TLS-cert-checks nil
 137   "If non-nil, verify gemini server TLS certs using the default security level.
 138 Otherwise, certificate verification is disabled.
 139
 140 This defaults to off because it is standard practice for Gemini servers
 141 to use self-signed certificates, meaning that most servers provide what
 142 EMACS considers to be an invalid certificate."
 143   :type '(boolean))
 144
 145 (defcustom elpher-gemini-max-fill-width 80
 146   "Specify the maximum default width (in columns) of text/gemini documents.
 147 The actual width used is the minimum of this value and the window width at
 148 the time when the text is rendered."
 149   :type '(integer))
 150
 151 (defcustom elpher-gemini-link-string "→ "
 152   "Specify the string used to indicate links when rendering gemini maps.
 153 May be empty."
 154   :type '(string))
 155
 156 (defcustom elpher-gemini-bullet-string "•"
 157   "Specify the string used for bullets when rendering gemini maps."
 158   :type '(string))
 159
 160 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 161   "Specify the name of the file where elpher bookmarks will be saved."
 162   :type '(file))
 163
 164 ;; Face customizations
 165
 166 (defgroup elpher-faces nil
 167   "Elpher face customizations."
 168   :group 'elpher)
 169
 170 (defface elpher-index
 171   '((t :inherit font-lock-keyword-face))
 172   "Face used for directory type directory records.")
 173
 174 (defface elpher-text
 175   '((t :inherit bold))
 176   "Face used for text type directory records.")
 177
 178 (defface elpher-info
 179   '((t :inherit default))
 180   "Face used for info type directory records.")
 181
 182 (defface elpher-image
 183   '((t :inherit font-lock-string-face))
 184   "Face used for image type directory records.")
 185
 186 (defface elpher-search
 187   '((t :inherit warning))
 188   "Face used for search type directory records.")
 189
 190 (defface elpher-html
 191   '((t :inherit font-lock-comment-face))
 192   "Face used for html type directory records.")
 193
 194 (defface elpher-gemini
 195   '((t :inherit font-lock-regexp-grouping-backslash))
 196   "Face used for Gemini type directory records.")
 197
 198 (defface elpher-other-url
 199   '((t :inherit font-lock-comment-face))
 200   "Face used for other URL type links records.")
 201
 202 (defface elpher-telnet
 203   '((t :inherit font-lock-function-name-face))
 204   "Face used for telnet type directory records.")
 205
 206 (defface elpher-binary
 207   '((t :inherit font-lock-doc-face))
 208   "Face used for binary type directory records.")
 209
 210 (defface elpher-unknown
 211   '((t :inherit error))
 212   "Face used for directory records with unknown/unsupported types.")
 213
 214 (defface elpher-margin-key
 215   '((t :inherit bold))
 216   "Face used for directory margin key.")
 217
 218 (defface elpher-margin-brackets
 219   '((t :inherit shadow))
 220   "Face used for brackets around directory margin key.")
 221
 222 (defface elpher-gemini-heading1
 223   '((t :inherit bold :height 1.8))
 224   "Face used for gemini heading level 1.")
 225
 226 (defface elpher-gemini-heading2
 227   '((t :inherit bold :height 1.5))
 228   "Face used for gemini heading level 2.")
 229
 230 (defface elpher-gemini-heading3
 231   '((t :inherit bold :height 1.2))
 232   "Face used for gemini heading level 3.")
 233
 234 (defface elpher-gemini-preformatted
 235   '((t :inherit fixed-pitch))
 236   "Face used for pre-formatted gemini text blocks.")
 237
 238 ;;; Model
 239 ;;
 240
 241 ;; Address
 242
 243 ;; An elpher "address" object is either a url object or a symbol.
 244 ;; Symbol addresses are "special", corresponding to pages generated
 245 ;; dynamically for and by elpher.  All others represent pages which
 246 ;; rely on content retrieved over the network.
 247
 248 (defun elpher-address-from-url (url-string)
 249   "Create a ADDRESS object corresponding to the given URL-STRING."
 250   (let ((data (match-data))) ; Prevent parsing clobbering match data
 251     (unwind-protect
 252         (let ((url (url-generic-parse-url url-string)))
 253           (unless (and (not (url-fullness url)) (url-type url))
 254             (setf (url-fullness url) t)
 255             (setf (url-filename url)
 256                   (url-unhex-string (url-filename url)))
 257             (unless (url-type url)
 258               (setf (url-type url) "gopher"))
 259             (when (or (equal "gopher" (url-type url))
 260                       (equal "gophers" (url-type url)))
 261               ;; Gopher defaults
 262               (unless (url-host url)
 263                 (setf (url-host url) (url-filename url))
 264                 (setf (url-filename url) ""))
 265               (when (or (equal (url-filename url) "")
 266                         (equal (url-filename url) "/"))
 267                 (setf (url-filename url) "/1")))
 268             (when (equal "gemini" (url-type url))
 269               ;; Gemini defaults
 270               (if (equal (url-filename url) "")
 271                   (setf (url-filename url) "/"))))
 272           url)
 273       (set-match-data data))))
 274
 275 (defun elpher-make-gopher-address (type selector host port &optional tls)
 276   "Create an ADDRESS object using gopher directory record attributes.
 277 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 278 If the optional attribute TLS is non-nil, the address will be marked as
 279 requiring gopher-over-TLS."
 280   (cond
 281    ((equal type ?i) nil)
 282    ((and (equal type ?h)
 283          (string-prefix-p "URL:" selector))
 284     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 285    ((equal type ?8)
 286     (elpher-address-from-url
 287      (concat "telnet"
 288              "://" host
 289              ":" (number-to-string port))))
 290    (t
 291     (elpher-address-from-url
 292      (concat "gopher" (if tls "s" "")
 293              "://" host
 294              ":" (number-to-string port)
 295              "/" (string type)
 296              selector)))))
 297
 298 (defun elpher-make-special-address (type)
 299   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 300   type)
 301
 302 (defun elpher-address-to-url (address)
 303   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 304   (if (not (elpher-address-special-p address))
 305       (url-encode-url (url-recreate-url address))
 306     nil))
 307
 308 (defun elpher-address-type (address)
 309   "Retrieve type of ADDRESS object.
 310 This is used to determine how to retrieve and render the document the
 311 address refers to, via the table `elpher-type-map'."
 312   (if (symbolp address)
 313       (list 'special address)
 314     (let ((protocol (url-type address)))
 315       (cond ((or (equal protocol "gopher")
 316                  (equal protocol "gophers"))
 317              (list 'gopher
 318                    (if (member (url-filename address) '("" "/"))
 319                        ?1
 320                      (string-to-char (substring (url-filename address) 1)))))
 321             ((equal protocol "gemini")
 322              'gemini)
 323             ((equal protocol "telnet")
 324              'telnet)
 325             ((equal protocol "finger")
 326              'finger)
 327             (t 'other-url)))))
 328
 329 (defun elpher-address-protocol (address)
 330   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 331   (if (symbolp address)
 332       nil
 333     (url-type address)))
 334
 335 (defun elpher-address-filename (address)
 336   "Retrieve the filename component of ADDRESS.
 337 For gopher addresses this is a combination of the selector type and selector."
 338   (if (symbolp address)
 339       nil
 340     (url-filename address)))
 341
 342 (defun elpher-address-host (address)
 343   "Retrieve host from ADDRESS object."
 344   (url-host address))
 345
 346 (defun elpher-address-user (address)
 347   "Retrieve user from ADDRESS object."
 348   (url-user address))
 349
 350 (defun elpher-address-port (address)
 351   "Retrieve port from ADDRESS object.
 352 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 353   (if (symbolp address)
 354       0
 355     (url-port address)))
 356
 357 (defun elpher-address-special-p (address)
 358   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 359   (symbolp address))
 360
 361 (defun elpher-address-gopher-p (address)
 362   "Return non-nill if ADDRESS object is a gopher address."
 363   (and (not (elpher-address-special-p address))
 364        (member (elpher-address-protocol address) '("gopher gophers"))))
 365
 366 (defun elpher-gopher-address-selector (address)
 367   "Retrieve gopher selector from ADDRESS object."
 368   (if (member (url-filename address) '("" "/"))
 369       ""
 370     (url-unhex-string (substring (url-filename address) 2))))
 371
 372
 373 ;; Cache
 374
 375 (defvar elpher-content-cache (make-hash-table :test 'equal))
 376 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 377
 378 (defun elpher-get-cached-content (address)
 379   "Retrieve the cached content for ADDRESS, or nil if none exists."
 380   (gethash address elpher-content-cache))
 381
 382 (defun elpher-cache-content (address content)
 383   "Set the content cache for ADDRESS to CONTENT."
 384   (puthash address content elpher-content-cache))
 385
 386 (defun elpher-get-cached-pos (address)
 387   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 388   (gethash address elpher-pos-cache))
 389
 390 (defun elpher-cache-pos (address pos)
 391   "Set the cursor position cache for ADDRESS to POS."
 392   (puthash address pos elpher-pos-cache))
 393
 394
 395 ;; Page
 396
 397 (defun elpher-make-page (display-string address)
 398   "Create a page with DISPLAY-STRING and ADDRESS."
 399   (list display-string address))
 400
 401 (defun elpher-page-display-string (page)
 402   "Retrieve the display string corresponding to PAGE."
 403   (elt page 0))
 404
 405 (defun elpher-page-address (page)
 406   "Retrieve the address corresponding to PAGE."
 407   (elt page 1))
 408
 409 (defun elpher-page-set-address (page new-address)
 410   "Set the address corresponding to PAGE to NEW-ADDRESS."
 411   (setcar (cdr page) new-address))
 412
 413 (defvar elpher-current-page nil)
 414 (defvar elpher-history nil)
 415
 416 (defun elpher-visit-page (page &optional renderer no-history)
 417   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 418 Additionally, push PAGE onto the stack of previously-visited pages,
 419 unless NO-HISTORY is non-nil."
 420   (elpher-save-pos)
 421   (elpher-process-cleanup)
 422   (unless (or no-history
 423               (equal (elpher-page-address elpher-current-page)
 424                      (elpher-page-address page)))
 425     (push elpher-current-page elpher-history))
 426   (setq elpher-current-page page)
 427   (let* ((address (elpher-page-address page))
 428          (type (elpher-address-type address))
 429          (type-record (cdr (assoc type elpher-type-map))))
 430     (if type-record
 431         (funcall (car type-record)
 432                  (if renderer
 433                      renderer
 434                    (cadr type-record)))
 435       (elpher-visit-previous-page)
 436       (pcase type
 437         (`(gopher ,type-char)
 438          (error "Unsupported gopher selector type '%c' for '%s'"
 439                 type-char (elpher-address-to-url address)))
 440         (other
 441          (error "Unsupported address type '%S' for '%s'"
 442                 other (elpher-address-to-url address)))))))
 443
 444 (defun elpher-visit-previous-page ()
 445   "Visit the previous page in the history."
 446   (let ((previous-page (pop elpher-history)))
 447     (if previous-page
 448         (elpher-visit-page previous-page nil t)
 449       (error "No previous page"))))
 450
 451 (defun elpher-reload-current-page ()
 452   "Reload the current page, discarding any existing cached content."
 453   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 454   (elpher-visit-page elpher-current-page))
 455
 456 (defun elpher-save-pos ()
 457   "Save the current position of point to the current page."
 458   (when elpher-current-page
 459     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 460
 461 (defun elpher-restore-pos ()
 462   "Restore the position of point to that cached in the current page."
 463   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 464     (if pos
 465         (goto-char pos)
 466       (goto-char (point-min)))))
 467
 468
 469 ;;; Buffer preparation
 470 ;;
 471
 472 (defun elpher-update-header ()
 473   "If `elpher-use-header' is true, display current page info in window header."
 474   (if elpher-use-header
 475       (let* ((display-string (elpher-page-display-string elpher-current-page))
 476              (address (elpher-page-address elpher-current-page))
 477              (tls-string (if (and (not (elpher-address-special-p address))
 478                                   (member (elpher-address-protocol address)
 479                                           '("gophers" "gemini")))
 480                              " [TLS encryption]"
 481                            ""))
 482              (header (concat display-string
 483                              (propertize tls-string 'face 'bold))))
 484         (setq header-line-format header))))
 485
 486 (defmacro elpher-with-clean-buffer (&rest args)
 487   "Evaluate ARGS with a clean *elpher* buffer as current."
 488   (list 'with-current-buffer "*elpher*"
 489         '(elpher-mode)
 490         (append (list 'let '((inhibit-read-only t))
 491                       '(setq-local network-security-level
 492                                    (default-value 'network-security-level))
 493                       '(erase-buffer)
 494                       '(elpher-update-header))
 495                 args)))
 496
 497
 498 ;;; Text Processing
 499 ;;
 500
 501 (defvar elpher-user-coding-system nil
 502   "User-specified coding system to use for decoding text responses.")
 503
 504 (defun elpher-decode (string)
 505   "Decode STRING using autodetected or user-specified coding system."
 506   (decode-coding-string string
 507                         (if elpher-user-coding-system
 508                             elpher-user-coding-system
 509                           (detect-coding-string string t))))
 510
 511 (defun elpher-preprocess-text-response (string)
 512   "Preprocess text selector response contained in STRING.
 513 This involes decoding the character representation, and clearing
 514 away CRs and any terminating period."
 515   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 516                                            (replace-regexp-in-string "\r" "" string))))
 517
 518
 519 ;;; Network error reporting
 520 ;;
 521
 522 (defun elpher-network-error (address error)
 523   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 524 ERROR can be either an error object or a string."
 525   (elpher-with-clean-buffer
 526    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 527            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 528            (if (stringp error) error (error-message-string error)) "\n"
 529            (propertize "\n----------------\n\n" 'face 'error)
 530            "Press 'u' to return to the previous page.")))
 531
 532
 533 ;;; Gopher selector retrieval
 534 ;;
 535
 536 (defvar elpher-network-timer nil
 537   "Timer used for network connections.")
 538
 539 (defun elpher-process-cleanup ()
 540   "Immediately shut down any extant elpher process and timers."
 541   (let ((p (get-process "elpher-process")))
 542     (if p (delete-process p)))
 543   (if (timerp elpher-network-timer)
 544       (cancel-timer elpher-network-timer)))
 545
 546 (defvar elpher-use-tls nil
 547   "If non-nil, use TLS to communicate with gopher servers.")
 548
 549 (defun elpher-get-selector (address renderer &optional force-ipv4)
 550   "Retrieve selector specified by ADDRESS, then render it using RENDERER.
 551 If FORCE-IPV4 is non-nil, explicitly look up and use IPv4 address corresponding
 552 to ADDRESS."
 553   (when (equal (elpher-address-protocol address) "gophers")
 554     (if (gnutls-available-p)
 555         (when (not elpher-use-tls)
 556           (setq elpher-use-tls t)
 557           (message "Engaging TLS gopher mode."))
 558       (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 559   (unless (< (elpher-address-port address) 65536)
 560     (error "Cannot retrieve gopher selector: port number > 65536"))
 561   (condition-case nil
 562       (let* ((kill-buffer-query-functions nil)
 563              (gnutls-verify-error nil) ; We use the NSM for verification
 564              (port (elpher-address-port address))
 565              (host (elpher-address-host address))
 566              (selector-string-parts nil)
 567              (bytes-received 0)
 568              (hkbytes-received 0)
 569              (proc (open-network-stream "elpher-process"
 570                                         nil
 571                                         (if force-ipv4 (dns-query host) host)
 572                                         (if (> port 0) port 70)
 573                                         :type (if elpher-use-tls 'tls 'plain)
 574                                         :nowait t))
 575              (timer (run-at-time elpher-connection-timeout
 576                                  nil
 577                                  (lambda ()
 578                                    (pcase (process-status proc)
 579                                      ('failed
 580                                       (if (and (not (equal (elpher-address-protocol address)
 581                                                            "gophers"))
 582                                                elpher-use-tls
 583                                                (or elpher-auto-disengage-TLS
 584                                                    (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode?")))
 585                                           (progn
 586                                             (message "Disabling TLS mode.")
 587                                             (setq elpher-use-tls nil)
 588                                             (elpher-get-selector address renderer))
 589                                         (elpher-network-error address "Could not establish encrypted connection")))
 590                                      ('connect
 591                                       (elpher-process-cleanup)
 592                                       (unless force-ipv4
 593                                         (message "Connection timed out. Retrying with IPv4 address.")
 594                                         (elpher-get-selector address renderer t))))))))
 595         (setq elpher-network-timer timer)
 596         (set-process-coding-system proc 'binary)
 597         (set-process-filter proc
 598                             (lambda (_proc string)
 599                               (when timer
 600                                 (cancel-timer timer)
 601                                 (setq timer nil))
 602                               (setq bytes-received (+ bytes-received (length string)))
 603                               (let ((new-hkbytes-received (/ bytes-received 102400)))
 604                                 (when (> new-hkbytes-received hkbytes-received)
 605                                   (setq hkbytes-received new-hkbytes-received)
 606                                   (with-current-buffer "*elpher*"
 607                                     (let ((inhibit-read-only t))
 608                                       (goto-char (point-min))
 609                                       (beginning-of-line 2)
 610                                       (delete-region (point) (point-max))
 611                                       (insert "("
 612                                               (number-to-string (/ hkbytes-received 10.0))
 613                                               " MB read)")))))
 614                               (setq selector-string-parts
 615                                     (cons string selector-string-parts))))
 616         (set-process-sentinel proc
 617                               (lambda (_proc event)
 618                                 (condition-case the-error
 619                                     (cond
 620                                      ((string-prefix-p "deleted" event))
 621                                      ((string-prefix-p "open" event)
 622                                       (let ((inhibit-eol-conversion t))
 623                                         (process-send-string
 624                                          proc
 625                                          (concat (elpher-gopher-address-selector address)
 626                                                  "\r\n"))))
 627                                      (t
 628                                       (when timer
 629                                         (cancel-timer timer)
 630                                         (setq timer nil))
 631                                       (funcall renderer (apply #'concat
 632                                                                (reverse selector-string-parts)))
 633                                       (elpher-restore-pos)))
 634                                   (error
 635                                    (elpher-network-error address the-error))))))
 636     (error
 637      (error "Error initiating connection to server"))))
 638
 639 (defun elpher-get-gopher-page (renderer)
 640   "Getter function for gopher pages.
 641 The RENDERER procedure is used to display the contents of the page
 642 once they are retrieved from the gopher server."
 643   (let* ((address (elpher-page-address elpher-current-page))
 644          (content (elpher-get-cached-content address)))
 645     (if (and content (funcall renderer nil))
 646         (elpher-with-clean-buffer
 647          (insert content)
 648          (elpher-restore-pos))
 649       (elpher-with-clean-buffer
 650        (insert "LOADING... (use 'u' to cancel)\n"))
 651       (condition-case the-error
 652           (elpher-get-selector address renderer)
 653         (error
 654          (elpher-network-error address the-error))))))
 655
 656 ;; Index rendering
 657
 658 (defun elpher-insert-index (string)
 659   "Insert the index corresponding to STRING into the current buffer."
 660   ;; Should be able to split directly on CRLF, but some non-conformant
 661   ;; LF-only servers sadly exist, hence the following.
 662   (let ((str-processed (elpher-preprocess-text-response string)))
 663     (dolist (line (split-string str-processed "\n"))
 664       (ignore-errors
 665         (unless (= (length line) 0)
 666           (let* ((type (elt line 0))
 667                  (fields (split-string (substring line 1) "\t"))
 668                  (display-string (elt fields 0))
 669                  (selector (elt fields 1))
 670                  (host (elt fields 2))
 671                  (port (if (elt fields 3)
 672                            (string-to-number (elt fields 3))
 673                          nil))
 674                  (address (elpher-make-gopher-address type selector host port)))
 675             (elpher-insert-index-record display-string address)))))))
 676
 677 (defun elpher-insert-margin (&optional type-name)
 678   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 679   (if type-name
 680       (progn
 681         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 682                         (concat
 683                          (propertize "[" 'face 'elpher-margin-brackets)
 684                          (propertize type-name 'face 'elpher-margin-key)
 685                          (propertize "]" 'face 'elpher-margin-brackets))))
 686         (insert " "))
 687     (insert (make-string elpher-margin-width ?\s))))
 688
 689 (defun elpher--page-button-help (_window buffer pos)
 690   "Function called by Emacs to generate mouse-over text.
 691 The arguments specify the BUFFER and the POS within the buffer of the item
 692 for which help is required.  The function returns the help to be
 693 displayed.  The _WINDOW argument is currently unused."
 694   (with-current-buffer buffer
 695     (let ((button (button-at pos)))
 696       (when button
 697         (let* ((page (button-get button 'elpher-page))
 698                (address (elpher-page-address page)))
 699           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 700                                                 address
 701                                               (url-recreate-url address))))))))
 702
 703 (defun elpher-insert-index-record (display-string &optional address)
 704   "Function to insert an index record into the current buffer.
 705 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 706 If ADDRESS is not supplied or nil the record is rendered as an
 707 'information' line."
 708   (let* ((type (if address (elpher-address-type address) nil))
 709          (type-map-entry (cdr (assoc type elpher-type-map))))
 710     (if type-map-entry
 711         (let* ((margin-code (elt type-map-entry 2))
 712                (face (elt type-map-entry 3))
 713                (filtered-display-string (ansi-color-filter-apply display-string))
 714                (page (elpher-make-page filtered-display-string address)))
 715           (elpher-insert-margin margin-code)
 716           (insert-text-button filtered-display-string
 717                               'face face
 718                               'elpher-page page
 719                               'action #'elpher-click-link
 720                               'follow-link t
 721                               'help-echo #'elpher--page-button-help))
 722       (pcase type
 723         ('nil ;; Information
 724          (elpher-insert-margin)
 725          (let ((propertized-display-string
 726                 (propertize display-string 'face 'elpher-info)))
 727            (insert (elpher-process-text-for-display propertized-display-string))))
 728         (`(gopher ,selector-type) ;; Unknown
 729          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 730          (insert (propertize display-string
 731                              'face 'elpher-unknown)))))
 732     (insert "\n")))
 733
 734 (defun elpher-click-link (button)
 735   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 736   (let ((page (button-get button 'elpher-page)))
 737     (elpher-visit-page page)))
 738
 739 (defun elpher-render-index (data &optional _mime-type-string)
 740   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 741   (elpher-with-clean-buffer
 742    (if (not data)
 743        t
 744      (elpher-insert-index data)
 745      (elpher-cache-content (elpher-page-address elpher-current-page)
 746                            (buffer-string)))))
 747
 748 ;; Text rendering
 749
 750 (defconst elpher-url-regex
 751   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 752   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 753
 754 (defun elpher-buttonify-urls (string)
 755   "Turn substrings which look like urls in STRING into clickable buttons."
 756   (with-temp-buffer
 757     (insert string)
 758     (goto-char (point-min))
 759     (while (re-search-forward elpher-url-regex nil t)
 760       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 761                                     (elpher-address-from-url (match-string 0)))))
 762           (make-text-button (match-beginning 0)
 763                             (match-end 0)
 764                             'elpher-page  page
 765                             'action #'elpher-click-link
 766                             'follow-link t
 767                             'help-echo #'elpher--page-button-help
 768                             'face 'button)))
 769     (buffer-string)))
 770
 771 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 772   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 773
 774 (defun elpher-process-text-for-display (string)
 775   "Perform any desired processing of STRING prior to display as text.
 776 Currently includes buttonifying URLs and processing ANSI escape codes."
 777   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 778                              (ansi-color-filter-apply string)
 779                            (ansi-color-apply string))))
 780
 781 (defun elpher-render-text (data &optional _mime-type-string)
 782   "Render DATA as text.  MIME-TYPE-STRING is unused."
 783   (elpher-with-clean-buffer
 784    (if (not data)
 785        t
 786      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
 787      (elpher-cache-content
 788       (elpher-page-address elpher-current-page)
 789       (buffer-string)))))
 790
 791 ;; Image retrieval
 792
 793 (defun elpher-render-image (data &optional _mime-type-string)
 794   "Display DATA as image.  MIME-TYPE-STRING is unused."
 795   (if (not data)
 796       nil
 797     (if (display-images-p)
 798         (progn
 799           (let ((image (create-image
 800                         data
 801                         nil t)))
 802             (elpher-with-clean-buffer
 803              (insert-image image)
 804              (elpher-restore-pos))))
 805       (elpher-render-download data))))
 806
 807 ;; Search retrieval and rendering
 808
 809 (defun elpher-get-gopher-query-page (renderer)
 810   "Getter for gopher addresses requiring input.
 811 The response is rendered using the rendering function RENDERER."
 812    (let* ((address (elpher-page-address elpher-current-page))
 813           (content (elpher-get-cached-content address))
 814           (aborted t))
 815     (if (and content (funcall renderer nil))
 816         (elpher-with-clean-buffer
 817          (insert content)
 818          (elpher-restore-pos)
 819          (message "Displaying cached search results.  Reload to perform a new search."))
 820       (unwind-protect
 821           (let* ((query-string (read-string "Query: "))
 822                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 823                  (search-address (elpher-make-gopher-address ?1
 824                                                              query-selector
 825                                                              (elpher-address-host address)
 826                                                              (elpher-address-port address)
 827                                                              (equal (elpher-address-type address) "gophers"))))
 828             (setq aborted nil)
 829
 830             (elpher-with-clean-buffer
 831              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 832             (elpher-get-selector search-address renderer))
 833         (if aborted
 834             (elpher-visit-previous-page))))))
 835
 836 ;; Raw server response rendering
 837
 838 (defun elpher-render-raw (data &optional mime-type-string)
 839   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
 840   (if (not data)
 841       nil
 842     (elpher-with-clean-buffer
 843      (when mime-type-string
 844        (insert "MIME type specified by server: '" mime-type-string "'\n"))
 845      (insert data)
 846      (goto-char (point-min)))
 847     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 848
 849 ;; File save "rendering"
 850
 851 (defun elpher-render-download (data &optional _mime-type-string)
 852   "Save DATA to file.  MIME-TYPE-STRING is unused."
 853   (if (not data)
 854       nil
 855     (let* ((address (elpher-page-address elpher-current-page))
 856            (selector (if (elpher-address-gopher-p address)
 857                          (elpher-gopher-address-selector address)
 858                        (elpher-address-filename address))))
 859       (elpher-visit-previous-page) ; Do first in case of non-local exits.
 860       (let* ((filename-proposal (file-name-nondirectory selector))
 861              (filename (read-file-name "Download complete. Save file as: "
 862                                        nil nil nil
 863                                        (if (> (length filename-proposal) 0)
 864                                            filename-proposal
 865                                          "download.file"))))
 866         (let ((coding-system-for-write 'binary))
 867           (with-temp-file filename
 868             (insert data)))
 869         (message (format "Saved to file %s." filename))))))
 870
 871 ;; HTML rendering
 872
 873 (defun elpher-render-html (data &optional _mime-type-string)
 874   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 875   (elpher-with-clean-buffer
 876    (if (not data)
 877        t
 878      (let ((dom (with-temp-buffer
 879                   (insert data)
 880                   (libxml-parse-html-region (point-min) (point-max)))))
 881        (shr-insert-document dom)))))
 882
 883 ;; Gemini page retrieval
 884
 885 (defvar elpher-gemini-redirect-chain)
 886
 887 (defun elpher-get-gemini-response (address renderer &optional force-ipv4)
 888   "Retrieve gemini ADDRESS, then render using RENDERER.
 889 If FORCE-IPV4 is non-nil, explicitly look up and use IPv4 address corresponding
 890 to ADDRESS."
 891   (unless elpher-gemini-TLS-cert-checks
 892     (setq-local network-security-level 'low))
 893   (if (not (gnutls-available-p))
 894       (error "Cannot establish gemini connection: GnuTLS not available")
 895     (unless (< (elpher-address-port address) 65536)
 896       (error "Cannot establish gemini connection: port number > 65536"))
 897     (condition-case nil
 898         (let* ((kill-buffer-query-functions nil)
 899                (gnutls-verify-error nil) ; We use the NSM for verification
 900                (port (elpher-address-port address))
 901                (host (elpher-address-host address))
 902                (response-string-parts nil)
 903                (bytes-received 0)
 904                (hkbytes-received 0)
 905                (proc (open-network-stream "elpher-process"
 906                                           nil
 907                                           (if force-ipv4 (dns-query host) host)
 908                                           (if (> port 0) port 1965)
 909                                           :type 'tls
 910                                           :nowait t))
 911                (timer (run-at-time elpher-connection-timeout nil
 912                                    (lambda ()
 913                                      (elpher-process-cleanup)
 914                                      (unless force-ipv4
 915                                         ; Try again with IPv4
 916                                        (message "Connection timed out.  Retrying with IPv4.")
 917                                        (elpher-get-gemini-response address renderer t))))))
 918           (setq elpher-network-timer timer)
 919           (set-process-coding-system proc 'binary)
 920           (set-process-filter proc
 921                               (lambda (_proc string)
 922                                 (when timer
 923                                   (cancel-timer timer)
 924                                   (setq timer nil))
 925                                 (setq bytes-received (+ bytes-received (length string)))
 926                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 927                                   (when (> new-hkbytes-received hkbytes-received)
 928                                     (setq hkbytes-received new-hkbytes-received)
 929                                     (with-current-buffer "*elpher*"
 930                                       (let ((inhibit-read-only t))
 931                                         (goto-char (point-min))
 932                                         (beginning-of-line 2)
 933                                         (delete-region (point) (point-max))
 934                                         (insert "("
 935                                                 (number-to-string (/ hkbytes-received 10.0))
 936                                                 " MB read)")))))
 937                                 (setq response-string-parts
 938                                       (cons string response-string-parts))))
 939           (set-process-sentinel proc
 940                                 (lambda (proc event)
 941                                   (condition-case the-error
 942                                       (cond
 943                                        ((string-prefix-p "open" event)    ; request URL
 944                                         (let ((inhibit-eol-conversion t))
 945                                           (process-send-string
 946                                            proc
 947                                            (concat (elpher-address-to-url address)
 948                                                    "\r\n"))))
 949                                        ((string-prefix-p "deleted" event)) ; do nothing
 950                                        ((and (not response-string-parts)
 951                                              (not force-ipv4))
 952                                         ; Try again with IPv4
 953                                         (message "Connection failed. Retrying with IPv4.")
 954                                         (cancel-timer timer)
 955                                         (elpher-get-gemini-response address renderer t))
 956                                        (t
 957                                         (funcall #'elpher-process-gemini-response
 958                                                  (apply #'concat (reverse response-string-parts))
 959                                                  renderer)
 960                                         (elpher-restore-pos)))
 961                                     (error
 962                                      (elpher-network-error address the-error))))))
 963       (error
 964        (error "Error initiating connection to server")))))
 965
 966 (defun elpher-parse-gemini-response (response)
 967   "Parse the RESPONSE string and return a list of components.
 968 The list is of the form (code meta body).  A response of nil implies
 969 that the response was malformed."
 970   (let ((header-end-idx (string-match "\r\n" response)))
 971     (if header-end-idx
 972         (let ((header (string-trim (substring response 0 header-end-idx)))
 973               (body (substring response (+ header-end-idx 2))))
 974           (if (>= (length header) 2)
 975               (let ((code (substring header 0 2))
 976                     (meta (string-trim (substring header 2))))
 977                 (list code meta body))
 978             (error "Malformed response: No response status found in header %s" header)))
 979       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
 980
 981 (defun elpher-process-gemini-response (response-string renderer)
 982   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
 983   (let ((response-components (elpher-parse-gemini-response response-string)))
 984     (let ((response-code (elt response-components 0))
 985           (response-meta (elt response-components 1))
 986           (response-body (elt response-components 2)))
 987       (pcase (elt response-code 0)
 988         (?1 ; Input required
 989          (elpher-with-clean-buffer
 990           (insert "Gemini server is requesting input."))
 991          (let* ((query-string (read-string (concat response-meta ": ")))
 992                 (url (elpher-address-to-url (elpher-page-address elpher-current-page)))
 993                 (query-address (elpher-address-from-url (concat url "?" query-string))))
 994            (elpher-get-gemini-response query-address renderer)))
 995         (?2 ; Normal response
 996          (funcall renderer response-body response-meta))
 997         (?3 ; Redirect
 998          (message "Following redirect to %s" response-meta)
 999          (if (>= (length elpher-gemini-redirect-chain) 5)
1000              (error "More than 5 consecutive redirects followed"))
1001          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1002            (if (member redirect-address elpher-gemini-redirect-chain)
1003                (error "Redirect loop detected"))
1004            (if (not (string= (elpher-address-protocol redirect-address)
1005                              "gemini"))
1006                (error "Server tried to automatically redirect to non-gemini URL: %s"
1007                       response-meta))
1008            (elpher-page-set-address elpher-current-page redirect-address)
1009            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1010            (elpher-get-gemini-response redirect-address renderer)))
1011         (?4 ; Temporary failure
1012          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1013                 response-code response-meta))
1014         (?5 ; Permanent failure
1015          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1016                 response-code response-meta))
1017         (?6 ; Client certificate required
1018          (error "Gemini server requires client certificate (unsupported at this time)"))
1019         (_other
1020          (error "Gemini server response unknown: %s %s"
1021                 response-code response-meta))))))
1022
1023 (defun elpher-get-gemini-page (renderer)
1024   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1025   (let* ((address (elpher-page-address elpher-current-page))
1026          (content (elpher-get-cached-content address)))
1027     (condition-case the-error
1028         (if (and content (funcall renderer nil))
1029             (elpher-with-clean-buffer
1030               (insert content)
1031               (elpher-restore-pos))
1032           (elpher-with-clean-buffer
1033            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1034           (setq elpher-gemini-redirect-chain nil)
1035           (elpher-get-gemini-response address renderer))
1036       (error
1037        (elpher-network-error address the-error)))))
1038
1039
1040 (defun elpher-render-gemini (body &optional mime-type-string)
1041   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1042   (if (not body)
1043       t
1044     (let* ((mime-type-string* (if (or (not mime-type-string)
1045                                       (string-empty-p mime-type-string))
1046                                   "text/gemini; charset=utf-8"
1047                                 mime-type-string))
1048            (mime-type-split (split-string mime-type-string* ";" t))
1049            (mime-type (string-trim (car mime-type-split)))
1050            (parameters (mapcar (lambda (s)
1051                                  (let ((key-val (split-string s "=")))
1052                                    (list (downcase (string-trim (car key-val)))
1053                                          (downcase (string-trim (cadr key-val))))))
1054                                (cdr mime-type-split))))
1055       (when (string-prefix-p "text/" mime-type)
1056         (setq body (decode-coding-string
1057                     body
1058                     (if (assoc "charset" parameters)
1059                         (intern (cadr (assoc "charset" parameters)))
1060                       'utf-8)))
1061         (setq body (replace-regexp-in-string "\r" "" body)))
1062       (pcase mime-type
1063         ((or "text/gemini" "")
1064          (elpher-render-gemini-map body parameters))
1065         ("text/html"
1066          (elpher-render-html body))
1067         ((pred (string-prefix-p "text/"))
1068          (elpher-render-gemini-plain-text body parameters))
1069         ((pred (string-prefix-p "image/"))
1070          (elpher-render-image body))
1071         (_other
1072          (elpher-render-download body))))))
1073
1074 (defun elpher-gemini-get-link-url (link-line)
1075   "Extract the url portion of LINK-LINE, a gemini map file link line.
1076 Returns nil in the event that the contents of the line following the
1077 => prefix are empty."
1078   (let ((l (split-string (substring link-line 2))))
1079     (if l
1080         (string-trim (elt l 0))
1081       nil)))
1082
1083 (defun elpher-gemini-get-link-display-string (link-line)
1084   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1085 Returns the url portion in the event that the display-string portion is empty."
1086   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1087          (idx (string-match "[ \t]" rest)))
1088     (string-trim (if idx
1089                      (substring rest (+ idx 1))
1090                    rest))))
1091
1092 (defun elpher-collapse-dot-sequences (filename)
1093   "Collapse dot sequences in FILENAME.
1094 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1095   (let* ((path (split-string filename "/"))
1096          (path-reversed-normalized
1097           (seq-reduce (lambda (a b)
1098                         (cond ((and a (equal b "..") (cdr a)))
1099                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1100                               ((equal b ".") a)
1101                               (t (cons b a))))
1102                       path nil)))
1103     (string-join (reverse path-reversed-normalized) "/")))
1104
1105 (defun elpher-address-from-gemini-url (url)
1106   "Extract address from URL with defaults as per gemini map files."
1107   (let ((address (url-generic-parse-url url)))
1108     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1109       (setf (url-fullness address) t)
1110       (if (url-host address) ;if there is an explicit host, filenames are absolute
1111           (if (string-empty-p (url-filename address))
1112               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1113         (setf (url-host address) (url-host (elpher-page-address elpher-current-page)))
1114         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1115           (setf (url-filename address)
1116                 (concat (file-name-directory
1117                          (url-filename (elpher-page-address elpher-current-page)))
1118                         (url-filename address)))))
1119       (unless (url-type address)
1120         (setf (url-type address) "gemini"))
1121       (if (equal (url-type address) "gemini")
1122           (setf (url-filename address)
1123                 (elpher-collapse-dot-sequences (url-filename address)))))
1124     address))
1125
1126 (defun elpher-gemini-insert-link (link-line)
1127   "Insert link described by LINK-LINE into a text/gemini document."
1128   (let* ((url (elpher-gemini-get-link-url link-line))
1129          (display-string (elpher-gemini-get-link-display-string link-line))
1130          (address (elpher-address-from-gemini-url url))
1131          (type (if address (elpher-address-type address) nil))
1132          (type-map-entry (cdr (assoc type elpher-type-map))))
1133     (when display-string
1134       (insert elpher-gemini-link-string)
1135       (if type-map-entry
1136           (let* ((face (elt type-map-entry 3))
1137                  (filtered-display-string (ansi-color-filter-apply display-string))
1138                  (page (elpher-make-page filtered-display-string address)))
1139             (insert-text-button filtered-display-string
1140                                 'face face
1141                                 'elpher-page page
1142                                 'action #'elpher-click-link
1143                                 'follow-link t
1144                                 'help-echo #'elpher--page-button-help))
1145         (insert (propertize display-string 'face 'elpher-unknown)))
1146       (insert "\n"))))
1147
1148 (defun elpher-gemini-insert-header (header-line)
1149   "Insert header described by HEADER-LINE into a text/gemini document.
1150 The gemini map file line describing the header is given
1151 by HEADER-LINE."
1152   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1153     (let ((level (length (match-string 1 header-line)))
1154           (header (substring header-line (match-end 0))))
1155       (unless (display-graphic-p)
1156         (insert (make-string level ?#) " "))
1157       (insert (propertize header 'face
1158                           (pcase level
1159                             (1 'elpher-gemini-heading1)
1160                             (2 'elpher-gemini-heading2)
1161                             (3 'elpher-gemini-heading3)
1162                             (_ 'default)))
1163               "\n"))))
1164
1165 (defun elpher-gemini-insert-text (text-line)
1166   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1167 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1168 width defined by elpher-gemini-max-fill-width."
1169   (string-match "\\(^[ \t]*\\)\\(\*[ \t]\\)?" text-line)
1170   (let* ((processed-text-line (if (match-string 2 text-line)
1171                                   (concat
1172                                    (replace-regexp-in-string "\*"
1173                                                              elpher-gemini-bullet-string
1174                                                              (match-string 0 text-line))
1175                                    (substring text-line (match-end 0)))
1176                                 text-line))
1177          (fill-prefix (if (match-string 1 text-line)
1178                           (replace-regexp-in-string "\*" " " (match-string 0 text-line))
1179                         nil)))
1180     (insert (elpher-process-text-for-display processed-text-line))
1181     (newline)))
1182
1183 (defun elpher-render-gemini-map (data _parameters)
1184   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1185   (elpher-with-clean-buffer
1186    (let ((preformatted nil))
1187      (auto-fill-mode 1)
1188      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1189      (dolist (line (split-string data "\n"))
1190        (cond
1191         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1192         (preformatted (insert (elpher-process-text-for-display
1193                                (propertize line 'face 'elpher-gemini-preformatted))
1194                               "\n"))
1195         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1196         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1197         (t (elpher-gemini-insert-text line)))))
1198    (elpher-cache-content
1199     (elpher-page-address elpher-current-page)
1200     (buffer-string))))
1201
1202 (defun elpher-render-gemini-plain-text (data _parameters)
1203   "Render DATA as plain text file.  PARAMETERS is currently unused."
1204   (elpher-with-clean-buffer
1205    (insert (elpher-process-text-for-display data))
1206    (elpher-cache-content
1207     (elpher-page-address elpher-current-page)
1208     (buffer-string))))
1209
1210 ;; Finger page connection
1211
1212 (defun elpher-get-finger-page (renderer &optional force-ipv4)
1213   "Opens a finger connection to the current page address and renders it using RENDERER."
1214   (let* ((address (elpher-page-address elpher-current-page))
1215          (content (elpher-get-cached-content address)))
1216     (if (and content (funcall renderer nil))
1217         (elpher-with-clean-buffer
1218          (insert content)
1219          (elpher-restore-pos))
1220       (elpher-with-clean-buffer
1221        (insert "LOADING... (use 'u' to cancel)\n"))
1222       (condition-case the-error
1223           (let* ((kill-buffer-query-functions nil)
1224                  (user (let ((filename (elpher-address-filename address)))
1225                          (if (> (length filename) 1)
1226                              (substring filename 1)
1227                            (elpher-address-user address))))
1228                  (port (let ((given-port (elpher-address-port address)))
1229                          (if (> given-port 0) given-port 79)))
1230                  (host (elpher-address-host address))
1231                  (selector-string-parts nil)
1232                  (proc (open-network-stream "elpher-process"
1233                                             nil
1234                                             (if force-ipv4 (dns-query host) host)
1235                                             port
1236                                             :type 'plain
1237                                             :nowait t))
1238                  (timer (run-at-time elpher-connection-timeout
1239                                      nil
1240                                      (lambda ()
1241                                        (pcase (process-status proc)
1242                                          ('connect
1243                                           (elpher-process-cleanup)
1244                                           (unless force-ipv4
1245                                             (message "Connection timed out. Retrying with IPv4 address.")
1246                                             (elpher-get-finger-page renderer t))))))))
1247             (setq elpher-network-timer timer)
1248             (set-process-coding-system proc 'binary)
1249             (set-process-filter proc
1250                                 (lambda (_proc string)
1251                                   (when timer
1252                                     (cancel-timer timer)
1253                                     (setq timer nil))
1254                                   (setq selector-string-parts
1255                                         (cons string selector-string-parts))))
1256             (set-process-sentinel proc
1257                                   (lambda (_proc event)
1258                                     (condition-case the-error
1259                                         (cond
1260                                          ((string-prefix-p "deleted" event))
1261                                          ((string-prefix-p "open" event)
1262                                           (let ((inhibit-eol-conversion t))
1263                                             (process-send-string
1264                                              proc
1265                                              (concat user "\r\n"))))
1266                                          (t
1267                                           (when timer
1268                                             (cancel-timer timer)
1269                                             (setq timer nil))
1270                                           (funcall renderer (apply #'concat
1271                                                                    (reverse selector-string-parts)))
1272                                           (elpher-restore-pos)))))))
1273         (error
1274          (elpher-network-error address the-error))))))
1275
1276
1277 ;; Other URL page opening
1278
1279 (defun elpher-get-other-url-page (renderer)
1280   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1281   (when renderer
1282     (elpher-visit-previous-page)
1283     (error "Command not supported for general URLs"))
1284   (let* ((address (elpher-page-address elpher-current-page))
1285          (url (elpher-address-to-url address)))
1286     (progn
1287       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1288       (message "Opening URL...")
1289       (if elpher-open-urls-with-eww
1290           (browse-web url)
1291         (browse-url url)))))
1292
1293 ;; Telnet page connection
1294
1295 (defun elpher-get-telnet-page (renderer)
1296   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1297   (when renderer
1298     (elpher-visit-previous-page)
1299     (error "Command not supported for telnet URLs"))
1300   (let* ((address (elpher-page-address elpher-current-page))
1301          (host (elpher-address-host address))
1302          (port (elpher-address-port address)))
1303     (elpher-visit-previous-page)
1304     (if (> port 0)
1305         (telnet host port)
1306       (telnet host))))
1307
1308 ;; Start page page retrieval
1309
1310 (defun elpher-get-start-page (renderer)
1311   "Getter which displays the start page (RENDERER must be nil)."
1312   (when renderer
1313     (elpher-visit-previous-page)
1314     (error "Command not supported for start page"))
1315   (elpher-with-clean-buffer
1316    (insert "     --------------------------------------------\n"
1317            "           Elpher Gopher and Gemini Client       \n"
1318            "                   version " elpher-version "\n"
1319            "     --------------------------------------------\n"
1320            "\n"
1321            "Default bindings:\n"
1322            "\n"
1323            " - TAB/Shift-TAB: next/prev item on current page\n"
1324            " - RET/mouse-1: open item under cursor\n"
1325            " - m: select an item on current page by name (autocompletes)\n"
1326            " - u/mouse-3: return to previous page\n"
1327            " - o/O: visit different selector or the root menu of the current server\n"
1328            " - g: go to a particular address (gopher, gemini, finger)\n"
1329            " - d/D: download item under cursor or current page\n"
1330            " - i/I: info on item under cursor or current page\n"
1331            " - c/C: copy URL representation of item under cursor or current page\n"
1332            " - a/A: bookmark the item under cursor or current page\n"
1333            " - x/X: remove bookmark for item under cursor or current page\n"
1334            " - B: visit the bookmarks page\n"
1335            " - r: redraw current page (using cached contents if available)\n"
1336            " - R: reload current page (regenerates cache)\n"
1337            " - S: set character coding system for gopher (default is to autodetect)\n"
1338            " - T: toggle TLS gopher mode\n"
1339            " - .: display the raw server response for the current page\n"
1340            "\n"
1341            "Start your exploration of gopher space and gemini:\n")
1342    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1343                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1344    (elpher-insert-index-record "Project Gemini home page"
1345                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1346    (insert "\n"
1347            "Alternatively, select a search engine and enter some search terms:\n")
1348    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1349                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1350    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1351                                (elpher-address-from-url "gemini://gus.guru/search"))
1352    (insert "\n"
1353            "This page contains your bookmarked sites (also visit with B):\n")
1354    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1355    (insert "\n"
1356            "For Elpher release news or to leave feedback, visit:\n")
1357    (elpher-insert-index-record "The Elpher Project Page"
1358                                (elpher-make-gopher-address ?1
1359                                                            "/projects/elpher/"
1360                                                            "thelambdalab.xyz"
1361                                                            70))
1362    (insert "\n"
1363            "** Refer to the ")
1364    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1365      (insert-text-button "Elpher info manual"
1366                          'face 'link
1367                          'action (lambda (_)
1368                                    (interactive)
1369                                    (info "(elpher)"))
1370                          'follow-link t
1371                          'help-echo help-string))
1372    (insert " for the full documentation. **\n")
1373    (insert (propertize
1374             (concat "  (This should be available if you have installed Elpher using\n"
1375                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1376             'face 'shadow))
1377    (elpher-restore-pos)))
1378
1379 ;; Bookmarks page page retrieval
1380
1381 (defun elpher-get-bookmarks-page (renderer)
1382   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1383   (when renderer
1384     (elpher-visit-previous-page)
1385     (error "Command not supported for bookmarks page"))
1386   (elpher-with-clean-buffer
1387    (insert "---- Bookmark list ----\n\n")
1388    (let ((bookmarks (elpher-load-bookmarks)))
1389      (if bookmarks
1390          (dolist (bookmark bookmarks)
1391            (let ((display-string (elpher-bookmark-display-string bookmark))
1392                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1393              (elpher-insert-index-record display-string address)))
1394        (insert "No bookmarks found.\n")))
1395    (insert "\n-----------------------\n"
1396            "\n"
1397            "- u: return to previous page\n"
1398            "- x: delete selected bookmark\n"
1399            "- a: rename selected bookmark\n"
1400            "\n"
1401            "Bookmarks are stored in the file ")
1402    (let ((filename elpher-bookmarks-file)
1403          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1404      (insert-text-button filename
1405                          'face 'link
1406                          'action (lambda (_)
1407                                    (interactive)
1408                                    (find-file filename))
1409                          'follow-link t
1410                          'help-echo help-string))
1411    (insert "\n")
1412    (elpher-restore-pos)))
1413
1414
1415 ;;; Bookmarks
1416 ;;
1417
1418 (defun elpher-make-bookmark (display-string url)
1419   "Make an elpher bookmark.
1420 DISPLAY-STRING determines how the bookmark will appear in the
1421 bookmark list, while URL is the url of the entry."
1422   (list display-string url))
1423
1424 (defun elpher-bookmark-display-string (bookmark)
1425   "Get the display string of BOOKMARK."
1426   (elt bookmark 0))
1427
1428 (defun elpher-set-bookmark-display-string (bookmark display-string)
1429   "Set the display string of BOOKMARK to DISPLAY-STRING."
1430   (setcar bookmark display-string))
1431
1432 (defun elpher-bookmark-url (bookmark)
1433   "Get the address for BOOKMARK."
1434   (elt bookmark 1))
1435
1436 (defun elpher-save-bookmarks (bookmarks)
1437   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1438 Beware that this completely replaces the existing contents of the file."
1439   (with-temp-file elpher-bookmarks-file
1440     (erase-buffer)
1441     (insert "; Elpher bookmarks file\n\n"
1442             "; Bookmarks are stored as a list of (label URL) items.\n"
1443             "; Feel free to edit by hand, but take care to ensure\n"
1444             "; the list structure remains intact.\n\n")
1445     (pp bookmarks (current-buffer))))
1446
1447 (defun elpher-load-bookmarks ()
1448   "Get the list of bookmarks from the users's bookmark file."
1449   (let ((bookmarks
1450          (with-temp-buffer
1451            (ignore-errors
1452              (insert-file-contents elpher-bookmarks-file)
1453              (goto-char (point-min))
1454              (read (current-buffer))))))
1455     (if (and bookmarks (listp (cadar bookmarks)))
1456         (progn
1457           (message "Reading old bookmark file. (Will be updated on write.)")
1458           (mapcar (lambda (old-bm)
1459                     (list (car old-bm)
1460                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1461                                                         (cadr old-bm)))))
1462                   bookmarks))
1463       bookmarks)))
1464
1465 (defun elpher-add-address-bookmark (address display-string)
1466   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1467 If ADDRESS is already bookmarked, update the label only."
1468   (let ((bookmarks (elpher-load-bookmarks))
1469         (url (elpher-address-to-url address)))
1470     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1471       (if existing-bookmark
1472           (elpher-set-bookmark-display-string existing-bookmark display-string)
1473         (push (elpher-make-bookmark display-string url) bookmarks)))
1474     (elpher-save-bookmarks bookmarks)))
1475
1476 (defun elpher-remove-address-bookmark (address)
1477   "Remove any bookmark to ADDRESS."
1478   (let ((url (elpher-address-to-url address)))
1479     (elpher-save-bookmarks
1480      (seq-filter (lambda (bookmark)
1481                    (not (equal (elpher-bookmark-url bookmark) url)))
1482                  (elpher-load-bookmarks)))))
1483
1484 ;;; Interactive procedures
1485 ;;
1486
1487 (defun elpher-next-link ()
1488   "Move point to the next link on the current page."
1489   (interactive)
1490   (forward-button 1))
1491
1492 (defun elpher-prev-link ()
1493   "Move point to the previous link on the current page."
1494   (interactive)
1495   (backward-button 1))
1496
1497 (defun elpher-follow-current-link ()
1498   "Open the link or url at point."
1499   (interactive)
1500   (push-button))
1501
1502 (defun elpher-go (host-or-url)
1503   "Go to a particular gopher site HOST-OR-URL.
1504 When run interactively HOST-OR-URL is read from the minibuffer."
1505   (interactive "sGopher or Gemini URL: ")
1506   (let ((page (elpher-make-page host-or-url
1507                                 (elpher-address-from-url host-or-url))))
1508     (switch-to-buffer "*elpher*")
1509     (elpher-visit-page page)
1510     '()))
1511
1512 (defun elpher-go-current ()
1513   "Go to a particular site read from the minibuffer, initialized with the current URL."
1514   (interactive)
1515   (let ((address (elpher-page-address elpher-current-page)))
1516     (if (elpher-address-special-p address)
1517         (error "Command invalid for this page")
1518       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1519         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1520
1521 (defun elpher-redraw ()
1522   "Redraw current page."
1523   (interactive)
1524   (elpher-visit-page elpher-current-page))
1525
1526 (defun elpher-reload ()
1527   "Reload current page."
1528   (interactive)
1529   (elpher-reload-current-page))
1530
1531 (defun elpher-toggle-tls ()
1532   "Toggle TLS encryption mode for gopher."
1533   (interactive)
1534   (setq elpher-use-tls (not elpher-use-tls))
1535   (if elpher-use-tls
1536       (if (gnutls-available-p)
1537           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1538         (setq elpher-use-tls nil)
1539         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1540     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1541
1542 (defun elpher-view-raw ()
1543   "View raw server response for current page."
1544   (interactive)
1545   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1546       (error "This page was not generated by a server")
1547     (elpher-visit-page elpher-current-page
1548                        #'elpher-render-raw)))
1549
1550 (defun elpher-back ()
1551   "Go to previous site."
1552   (interactive)
1553   (elpher-visit-previous-page))
1554
1555 (defun elpher-download ()
1556   "Download the link at point."
1557   (interactive)
1558   (let ((button (button-at (point))))
1559     (if button
1560         (let ((page (button-get button 'elpher-page)))
1561           (if (elpher-address-special-p (elpher-page-address page))
1562               (error "Cannot download %s"
1563                      (elpher-page-display-string page))
1564             (elpher-visit-page (button-get button 'elpher-page)
1565                                #'elpher-render-download)))
1566       (error "No link selected"))))
1567
1568 (defun elpher-download-current ()
1569   "Download the current page."
1570   (interactive)
1571   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1572       (error "Cannot download %s"
1573              (elpher-page-display-string elpher-current-page))
1574     (elpher-visit-page (elpher-make-page
1575                         (elpher-page-display-string elpher-current-page)
1576                         (elpher-page-address elpher-current-page))
1577                        #'elpher-render-download
1578                        t)))
1579
1580 (defun elpher-build-link-map ()
1581   "Build alist mapping link names to destination pages in current buffer."
1582   (let ((link-map nil)
1583         (b (next-button (point-min) t)))
1584     (while b
1585       (push (cons (button-label b) b) link-map)
1586       (setq b (next-button (button-start b))))
1587     link-map))
1588
1589 (defun elpher-jump ()
1590   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1591   (interactive)
1592   (let* ((link-map (elpher-build-link-map)))
1593     (if link-map
1594         (let ((key (let ((completion-ignore-case t))
1595                      (completing-read "Directory item/link: "
1596                                       link-map nil t))))
1597           (if (and key (> (length key) 0))
1598               (let ((b (cdr (assoc key link-map))))
1599                 (goto-char (button-start b))
1600                 (button-activate b)))))))
1601
1602 (defun elpher-root-dir ()
1603   "Visit root of current server."
1604   (interactive)
1605   (let ((address (elpher-page-address elpher-current-page)))
1606     (if (not (elpher-address-special-p address))
1607         (if (or (member (url-filename address) '("/" ""))
1608                 (and (elpher-address-gopher-p address)
1609                      (= (length (elpher-gopher-address-selector address)) 0)))
1610             (error "Already at root directory of current server")
1611           (let ((address-copy (elpher-address-from-url
1612                                (elpher-address-to-url address))))
1613             (setf (url-filename address-copy) "")
1614             (elpher-go (elpher-address-to-url address-copy))))
1615       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1616
1617 (defun elpher-bookmarks-current-p ()
1618   "Return non-nil if current page is a bookmarks page."
1619   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1620          '(special bookmarks)))
1621
1622 (defun elpher-reload-bookmarks ()
1623   "Reload bookmarks if current page is a bookmarks page."
1624   (if (elpher-bookmarks-current-p)
1625       (elpher-reload-current-page)))
1626
1627 (defun elpher-bookmark-current ()
1628   "Bookmark the current page."
1629   (interactive)
1630   (let ((address (elpher-page-address elpher-current-page))
1631         (display-string (elpher-page-display-string elpher-current-page)))
1632     (if (not (elpher-address-special-p address))
1633         (let ((bookmark-display-string (read-string "Bookmark display string: "
1634                                                     display-string)))
1635           (elpher-add-address-bookmark address bookmark-display-string)
1636           (message "Bookmark added."))
1637       (error "Cannot bookmark %s" display-string))))
1638
1639 (defun elpher-bookmark-link ()
1640   "Bookmark the link at point."
1641   (interactive)
1642   (let ((button (button-at (point))))
1643     (if button
1644         (let* ((page (button-get button 'elpher-page))
1645                (address (elpher-page-address page))
1646                (display-string (elpher-page-display-string page)))
1647           (if (not (elpher-address-special-p address))
1648               (let ((bookmark-display-string (read-string "Bookmark display string: "
1649                                                           display-string)))
1650                 (elpher-add-address-bookmark address bookmark-display-string)
1651                 (elpher-reload-bookmarks)
1652                 (message "Bookmark added."))
1653             (error "Cannot bookmark %s" display-string)))
1654       (error "No link selected"))))
1655
1656 (defun elpher-unbookmark-current ()
1657   "Remove bookmark for the current page."
1658   (interactive)
1659   (let ((address (elpher-page-address elpher-current-page)))
1660     (unless (elpher-address-special-p address)
1661       (elpher-remove-address-bookmark address)
1662       (message "Bookmark removed."))))
1663
1664 (defun elpher-unbookmark-link ()
1665   "Remove bookmark for the link at point."
1666   (interactive)
1667   (let ((button (button-at (point))))
1668     (if button
1669         (let ((page (button-get button 'elpher-page)))
1670           (elpher-remove-address-bookmark (elpher-page-address page))
1671           (elpher-reload-bookmarks)
1672           (message "Bookmark removed."))
1673       (error "No link selected"))))
1674
1675 (defun elpher-bookmarks ()
1676   "Visit bookmarks page."
1677   (interactive)
1678   (switch-to-buffer "*elpher*")
1679   (elpher-visit-page
1680    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1681
1682 (defun elpher-info-page (page)
1683   "Display information on PAGE."
1684   (let ((display-string (elpher-page-display-string page))
1685         (address (elpher-page-address page)))
1686     (if (elpher-address-special-p address)
1687         (message "Special page: %s" display-string)
1688       (message "%s" (elpher-address-to-url address)))))
1689
1690 (defun elpher-info-link ()
1691   "Display information on page corresponding to link at point."
1692   (interactive)
1693   (let ((button (button-at (point))))
1694     (if button
1695         (elpher-info-page (button-get button 'elpher-page))
1696       (error "No item selected"))))
1697
1698 (defun elpher-info-current ()
1699   "Display information on current page."
1700   (interactive)
1701   (elpher-info-page elpher-current-page))
1702
1703 (defun elpher-copy-page-url (page)
1704   "Copy URL representation of address of PAGE to `kill-ring'."
1705   (let ((address (elpher-page-address page)))
1706     (if (elpher-address-special-p address)
1707         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1708       (let ((url (elpher-address-to-url address)))
1709         (message "Copied \"%s\" to kill-ring/clipboard." url)
1710         (kill-new url)))))
1711
1712 (defun elpher-copy-link-url ()
1713   "Copy URL of item at point to `kill-ring'."
1714   (interactive)
1715   (let ((button (button-at (point))))
1716     (if button
1717         (elpher-copy-page-url (button-get button 'elpher-page))
1718       (error "No item selected"))))
1719
1720 (defun elpher-copy-current-url ()
1721   "Copy URL of current page to `kill-ring'."
1722   (interactive)
1723   (elpher-copy-page-url elpher-current-page))
1724
1725 (defun elpher-set-gopher-coding-system ()
1726   "Specify an explicit character coding system for gopher selectors."
1727   (interactive)
1728   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1729     (setq elpher-user-coding-system system)
1730     (if system
1731         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1732       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1733
1734
1735 ;;; Mode and keymap
1736 ;;
1737
1738 (defvar elpher-mode-map
1739   (let ((map (make-sparse-keymap)))
1740     (define-key map (kbd "TAB") 'elpher-next-link)
1741     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1742     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1743     (define-key map (kbd "u") 'elpher-back)
1744     (define-key map [mouse-3] 'elpher-back)
1745     (define-key map (kbd "O") 'elpher-root-dir)
1746     (define-key map (kbd "g") 'elpher-go)
1747     (define-key map (kbd "o") 'elpher-go-current)
1748     (define-key map (kbd "r") 'elpher-redraw)
1749     (define-key map (kbd "R") 'elpher-reload)
1750     (define-key map (kbd "T") 'elpher-toggle-tls)
1751     (define-key map (kbd ".") 'elpher-view-raw)
1752     (define-key map (kbd "d") 'elpher-download)
1753     (define-key map (kbd "D") 'elpher-download-current)
1754     (define-key map (kbd "m") 'elpher-jump)
1755     (define-key map (kbd "i") 'elpher-info-link)
1756     (define-key map (kbd "I") 'elpher-info-current)
1757     (define-key map (kbd "c") 'elpher-copy-link-url)
1758     (define-key map (kbd "C") 'elpher-copy-current-url)
1759     (define-key map (kbd "a") 'elpher-bookmark-link)
1760     (define-key map (kbd "A") 'elpher-bookmark-current)
1761     (define-key map (kbd "x") 'elpher-unbookmark-link)
1762     (define-key map (kbd "X") 'elpher-unbookmark-current)
1763     (define-key map (kbd "B") 'elpher-bookmarks)
1764     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1765     (when (fboundp 'evil-define-key*)
1766       (evil-define-key* 'motion map
1767         (kbd "TAB") 'elpher-next-link
1768         (kbd "C-") 'elpher-follow-current-link
1769         (kbd "C-t") 'elpher-back
1770         (kbd "u") 'elpher-back
1771         [mouse-3] 'elpher-back
1772         (kbd "g") 'elpher-go
1773         (kbd "o") 'elpher-go-current
1774         (kbd "r") 'elpher-redraw
1775         (kbd "R") 'elpher-reload
1776         (kbd "T") 'elpher-toggle-tls
1777         (kbd ".") 'elpher-view-raw
1778         (kbd "d") 'elpher-download
1779         (kbd "D") 'elpher-download-current
1780         (kbd "m") 'elpher-jump
1781         (kbd "i") 'elpher-info-link
1782         (kbd "I") 'elpher-info-current
1783         (kbd "c") 'elpher-copy-link-url
1784         (kbd "C") 'elpher-copy-current-url
1785         (kbd "a") 'elpher-bookmark-link
1786         (kbd "A") 'elpher-bookmark-current
1787         (kbd "x") 'elpher-unbookmark-link
1788         (kbd "X") 'elpher-unbookmark-current
1789         (kbd "B") 'elpher-bookmarks
1790         (kbd "S") 'elpher-set-gopher-coding-system))
1791     map)
1792   "Keymap for gopher client.")
1793
1794 (define-derived-mode elpher-mode special-mode "elpher"
1795   "Major mode for elpher, an elisp gopher client.
1796
1797 This mode is automatically enabled by the interactive
1798 functions which initialize the gopher client, namely
1799 `elpher', `elpher-go' and `elpher-bookmarks'.")
1800
1801 (when (fboundp 'evil-set-initial-state)
1802   (evil-set-initial-state 'elpher-mode 'motion))
1803
1804
1805 ;;; Main start procedure
1806 ;;
1807
1808 ;;;###autoload
1809 (defun elpher ()
1810   "Start elpher with default landing page."
1811   (interactive)
1812   (if (get-buffer "*elpher*")
1813       (switch-to-buffer "*elpher*")
1814     (switch-to-buffer "*elpher*")
1815     (setq elpher-current-page nil)
1816     (setq elpher-history nil)
1817     (let ((start-page (elpher-make-page "Elpher Start Page"
1818                                         (elpher-make-special-address 'start))))
1819       (elpher-visit-page start-page)))
1820   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1821
1822 ;;; elpher.el ends here