elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.9.1
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "2.9.1"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  99     ((special start) elpher-get-start-page nil))
 100   "Association list from types to getters, renderers, margin codes and index faces.")
 101
 102
 103 ;;; Customization group
 104 ;;
 105
 106 (defgroup elpher nil
 107   "A gopher and gemini client."
 108   :group 'applications)
 109
 110 ;; General appearance and customizations
 111
 112 (defcustom elpher-open-urls-with-eww nil
 113   "If non-nil, open URL selectors using eww.
 114 Otherwise, use the system browser via the BROWSE-URL function."
 115   :type '(boolean))
 116
 117 (defcustom elpher-use-header t
 118   "If non-nil, display current page information in buffer header."
 119   :type '(boolean))
 120
 121 (defcustom elpher-auto-disengage-TLS nil
 122   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 123 While enabling this may seem convenient, it is also potentially dangerous as it
 124 allows switching from an encrypted channel back to plain text without user input."
 125   :type '(boolean))
 126
 127 (defcustom elpher-connection-timeout 5
 128   "Specifies the number of seconds to wait for a network connection to time out."
 129   :type '(integer))
 130
 131 (defcustom elpher-filter-ansi-from-text nil
 132   "If non-nil, filter ANSI escape sequences from text.
 133 The default behaviour is to use the ansi-color package to interpret these
 134 sequences."
 135   :type '(boolean))
 136
 137 (defcustom elpher-certificate-directory
 138   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 139   "Specify the name of the directory where client certificates will be stored.
 140 These certificates may be used for establishing authenticated TLS connections."
 141   :type '(directory))
 142
 143 (defcustom elpher-openssl-command "openssl"
 144   "The command used to launch openssl when generating TLS client certificates."
 145   :type '(file))
 146
 147 (defcustom elpher-gemini-TLS-cert-checks nil
 148   "If non-nil, verify gemini server TLS certs using the default security level.
 149 Otherwise, certificate verification is disabled.
 150
 151 This defaults to off because it is standard practice for Gemini servers
 152 to use self-signed certificates, meaning that most servers provide what
 153 EMACS considers to be an invalid certificate."
 154   :type '(boolean))
 155
 156 (defcustom elpher-gemini-max-fill-width 80
 157   "Specify the maximum default width (in columns) of text/gemini documents.
 158 The actual width used is the minimum of this value and the window width at
 159 the time when the text is rendered."
 160   :type '(integer))
 161
 162 (defcustom elpher-gemini-link-string "→ "
 163   "Specify the string used to indicate links when rendering gemini maps.
 164 May be empty."
 165   :type '(string))
 166
 167 (defcustom elpher-gemini-bullet-string "•"
 168   "Specify the string used for bullets when rendering gemini maps."
 169   :type '(string))
 170
 171 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 172   "Specify the name of the file where elpher bookmarks will be saved."
 173   :type '(file))
 174
 175 (defcustom elpher-ipv4-always nil
 176   "If non-nil, elpher will always use IPv4 to establish network connections.
 177 This can be useful when browsing from a computer that supports IPv6, because
 178 some servers which do not support IPv6 can take a long time to time-out."
 179   :type '(boolean))
 180
 181 ;; Face customizations
 182
 183 (defgroup elpher-faces nil
 184   "Elpher face customizations."
 185   :group 'elpher)
 186
 187 (defface elpher-index
 188   '((t :inherit font-lock-keyword-face))
 189   "Face used for directory type directory records.")
 190
 191 (defface elpher-text
 192   '((t :inherit bold))
 193   "Face used for text type directory records.")
 194
 195 (defface elpher-info
 196   '((t :inherit default))
 197   "Face used for info type directory records.")
 198
 199 (defface elpher-image
 200   '((t :inherit font-lock-string-face))
 201   "Face used for image type directory records.")
 202
 203 (defface elpher-search
 204   '((t :inherit warning))
 205   "Face used for search type directory records.")
 206
 207 (defface elpher-html
 208   '((t :inherit font-lock-comment-face))
 209   "Face used for html type directory records.")
 210
 211 (defface elpher-gemini
 212   '((t :inherit font-lock-regexp-grouping-backslash))
 213   "Face used for Gemini type directory records.")
 214
 215 (defface elpher-other-url
 216   '((t :inherit font-lock-comment-face))
 217   "Face used for other URL type links records.")
 218
 219 (defface elpher-telnet
 220   '((t :inherit font-lock-function-name-face))
 221   "Face used for telnet type directory records.")
 222
 223 (defface elpher-binary
 224   '((t :inherit font-lock-doc-face))
 225   "Face used for binary type directory records.")
 226
 227 (defface elpher-unknown
 228   '((t :inherit error))
 229   "Face used for directory records with unknown/unsupported types.")
 230
 231 (defface elpher-margin-key
 232   '((t :inherit bold))
 233   "Face used for directory margin key.")
 234
 235 (defface elpher-margin-brackets
 236   '((t :inherit shadow))
 237   "Face used for brackets around directory margin key.")
 238
 239 (defface elpher-gemini-heading1
 240   '((t :inherit bold :height 1.8))
 241   "Face used for gemini heading level 1.")
 242
 243 (defface elpher-gemini-heading2
 244   '((t :inherit bold :height 1.5))
 245   "Face used for gemini heading level 2.")
 246
 247 (defface elpher-gemini-heading3
 248   '((t :inherit bold :height 1.2))
 249   "Face used for gemini heading level 3.")
 250
 251 (defface elpher-gemini-preformatted
 252   '((t :inherit fixed-pitch))
 253   "Face used for pre-formatted gemini text blocks.")
 254
 255 ;;; Model
 256 ;;
 257
 258 ;; Address
 259
 260 ;; An elpher "address" object is either a url object or a symbol.
 261 ;; Symbol addresses are "special", corresponding to pages generated
 262 ;; dynamically for and by elpher.  All others represent pages which
 263 ;; rely on content retrieved over the network.
 264
 265 (defun elpher-address-from-url (url-string)
 266   "Create a ADDRESS object corresponding to the given URL-STRING."
 267   (let ((data (match-data))) ; Prevent parsing clobbering match data
 268     (unwind-protect
 269         (let ((url (url-generic-parse-url url-string)))
 270           (unless (and (not (url-fullness url)) (url-type url))
 271             (setf (url-fullness url) t)
 272             (setf (url-filename url)
 273                   (url-unhex-string (url-filename url)))
 274             (unless (url-type url)
 275               (setf (url-type url) "gopher"))
 276             (when (or (equal "gopher" (url-type url))
 277                       (equal "gophers" (url-type url)))
 278               ;; Gopher defaults
 279               (unless (url-host url)
 280                 (setf (url-host url) (url-filename url))
 281                 (setf (url-filename url) ""))
 282               (when (or (equal (url-filename url) "")
 283                         (equal (url-filename url) "/"))
 284                 (setf (url-filename url) "/1")))
 285             (when (equal "gemini" (url-type url))
 286               ;; Gemini defaults
 287               (if (equal (url-filename url) "")
 288                   (setf (url-filename url) "/"))))
 289           (elpher-remove-redundant-ports url))
 290       (set-match-data data))))
 291
 292 (defun elpher-remove-redundant-ports (address)
 293   "Remove redundant port specifiers from ADDRESS.
 294 Here 'redundant' means that the specified port matches the default
 295 for that protocol, eg 70 for gopher."
 296   (if (and (not (elpher-address-special-p address))
 297            (eq (url-portspec address) ; (url-port) is too slow!
 298                (pcase (url-type address)
 299                  ("gemini" 1965)
 300                  ((or "gopher" "gophers") 70)
 301                  ("finger" 79)
 302                  (_ -1))))
 303       (setf (url-portspec address) nil))
 304   address)
 305
 306 (defun elpher-make-gopher-address (type selector host port &optional tls)
 307   "Create an ADDRESS object using gopher directory record attributes.
 308 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 309 If the optional attribute TLS is non-nil, the address will be marked as
 310 requiring gopher-over-TLS."
 311   (cond
 312    ((equal type ?i) nil)
 313    ((and (equal type ?h)
 314          (string-prefix-p "URL:" selector))
 315     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 316    ((equal type ?8)
 317     (elpher-address-from-url
 318      (concat "telnet"
 319              "://" host
 320              ":" (number-to-string port))))
 321    (t
 322     (elpher-address-from-url
 323      (concat "gopher" (if tls "s" "")
 324              "://" host
 325              ":" (number-to-string port)
 326              "/" (string type)
 327              selector)))))
 328
 329 (defun elpher-make-special-address (type)
 330   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 331   type)
 332
 333 (defun elpher-address-to-url (address)
 334   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 335   (if (elpher-address-special-p address)
 336       nil
 337     (url-encode-url (url-recreate-url address))))
 338
 339 (defun elpher-address-type (address)
 340   "Retrieve type of ADDRESS object.
 341 This is used to determine how to retrieve and render the document the
 342 address refers to, via the table `elpher-type-map'."
 343   (if (symbolp address)
 344       (list 'special address)
 345     (let ((protocol (url-type address)))
 346       (cond ((or (equal protocol "gopher")
 347                  (equal protocol "gophers"))
 348              (list 'gopher
 349                    (if (member (url-filename address) '("" "/"))
 350                        ?1
 351                      (string-to-char (substring (url-filename address) 1)))))
 352             ((equal protocol "gemini")
 353              'gemini)
 354             ((equal protocol "telnet")
 355              'telnet)
 356             ((equal protocol "finger")
 357              'finger)
 358             (t 'other-url)))))
 359
 360 (defun elpher-address-protocol (address)
 361   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 362   (if (symbolp address)
 363       nil
 364     (url-type address)))
 365
 366 (defun elpher-address-filename (address)
 367   "Retrieve the filename component of ADDRESS.
 368 For gopher addresses this is a combination of the selector type and selector."
 369   (if (symbolp address)
 370       nil
 371     (url-filename address)))
 372
 373 (defun elpher-address-host (address)
 374   "Retrieve host from ADDRESS object."
 375   (url-host address))
 376
 377 (defun elpher-address-user (address)
 378   "Retrieve user from ADDRESS object."
 379   (url-user address))
 380
 381 (defun elpher-address-port (address)
 382   "Retrieve port from ADDRESS object.
 383 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 384   (if (symbolp address)
 385       0
 386     (url-port address)))
 387
 388 (defun elpher-address-special-p (address)
 389   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 390   (symbolp address))
 391
 392 (defun elpher-address-gopher-p (address)
 393   "Return non-nill if ADDRESS object is a gopher address."
 394   (and (not (elpher-address-special-p address))
 395        (member (elpher-address-protocol address) '("gopher gophers"))))
 396
 397 (defun elpher-gopher-address-selector (address)
 398   "Retrieve gopher selector from ADDRESS object."
 399   (if (member (url-filename address) '("" "/"))
 400       ""
 401     (url-unhex-string (substring (url-filename address) 2))))
 402
 403
 404 ;; Cache
 405
 406 (defvar elpher-content-cache (make-hash-table :test 'equal))
 407 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 408
 409 (defun elpher-get-cached-content (address)
 410   "Retrieve the cached content for ADDRESS, or nil if none exists."
 411   (gethash address elpher-content-cache))
 412
 413 (defun elpher-cache-content (address content)
 414   "Set the content cache for ADDRESS to CONTENT."
 415   (puthash address content elpher-content-cache))
 416
 417 (defun elpher-get-cached-pos (address)
 418   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 419   (gethash address elpher-pos-cache))
 420
 421 (defun elpher-cache-pos (address pos)
 422   "Set the cursor position cache for ADDRESS to POS."
 423   (puthash address pos elpher-pos-cache))
 424
 425
 426 ;; Page
 427
 428 (defun elpher-make-page (display-string address)
 429   "Create a page with DISPLAY-STRING and ADDRESS."
 430   (list display-string address))
 431
 432 (defun elpher-page-display-string (page)
 433   "Retrieve the display string corresponding to PAGE."
 434   (elt page 0))
 435
 436 (defun elpher-page-address (page)
 437   "Retrieve the address corresponding to PAGE."
 438   (elt page 1))
 439
 440 (defun elpher-page-set-address (page new-address)
 441   "Set the address corresponding to PAGE to NEW-ADDRESS."
 442   (setcar (cdr page) new-address))
 443
 444 (defvar elpher-current-page nil)
 445 (defvar elpher-history nil)
 446
 447 (defun elpher-visit-page (page &optional renderer no-history)
 448   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 449 Additionally, push PAGE onto the stack of previously-visited pages,
 450 unless NO-HISTORY is non-nil."
 451   (elpher-save-pos)
 452   (elpher-process-cleanup)
 453   (unless (or no-history
 454               (equal (elpher-page-address elpher-current-page)
 455                      (elpher-page-address page)))
 456     (push elpher-current-page elpher-history))
 457   (setq elpher-current-page page)
 458   (let* ((address (elpher-page-address page))
 459          (type (elpher-address-type address))
 460          (type-record (cdr (assoc type elpher-type-map))))
 461     (if type-record
 462         (funcall (car type-record)
 463                  (if renderer
 464                      renderer
 465                    (cadr type-record)))
 466       (elpher-visit-previous-page)
 467       (pcase type
 468         (`(gopher ,type-char)
 469          (error "Unsupported gopher selector type '%c' for '%s'"
 470                 type-char (elpher-address-to-url address)))
 471         (other
 472          (error "Unsupported address type '%S' for '%s'"
 473                 other (elpher-address-to-url address)))))))
 474
 475 (defun elpher-visit-previous-page ()
 476   "Visit the previous page in the history."
 477   (let ((previous-page (pop elpher-history)))
 478     (if previous-page
 479         (elpher-visit-page previous-page nil t)
 480       (error "No previous page"))))
 481
 482 (defun elpher-reload-current-page ()
 483   "Reload the current page, discarding any existing cached content."
 484   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 485   (elpher-visit-page elpher-current-page))
 486
 487 (defun elpher-save-pos ()
 488   "Save the current position of point to the current page."
 489   (when elpher-current-page
 490     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 491
 492 (defun elpher-restore-pos ()
 493   "Restore the position of point to that cached in the current page."
 494   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 495     (if pos
 496         (goto-char pos)
 497       (goto-char (point-min)))))
 498
 499
 500 ;;; Buffer preparation
 501 ;;
 502
 503 (defun elpher-update-header ()
 504   "If `elpher-use-header' is true, display current page info in window header."
 505   (if elpher-use-header
 506       (let* ((display-string (elpher-page-display-string elpher-current-page))
 507              (address (elpher-page-address elpher-current-page))
 508              (tls-string (if (and (not (elpher-address-special-p address))
 509                                   (member (elpher-address-protocol address)
 510                                           '("gophers" "gemini")))
 511                              " [TLS encryption]"
 512                            ""))
 513              (header (concat display-string
 514                              (propertize tls-string 'face 'bold))))
 515         (setq header-line-format header))))
 516
 517 (defmacro elpher-with-clean-buffer (&rest args)
 518   "Evaluate ARGS with a clean *elpher* buffer as current."
 519   (list 'with-current-buffer "*elpher*"
 520         '(elpher-mode)
 521         (append (list 'let '((inhibit-read-only t))
 522                       '(setq-local network-security-level
 523                                    (default-value 'network-security-level))
 524                       '(erase-buffer)
 525                       '(elpher-update-header))
 526                 args)))
 527
 528 (defun elpher-buffer-message (string &optional line)
 529   "Replace first line in elpher buffer with STRING.
 530 If LINE is non-nil, replace that line instead."
 531   (with-current-buffer "*elpher*"
 532     (let ((inhibit-read-only t))
 533       (goto-char (point-min))
 534       (if line
 535           (forward-line line))
 536       (let ((data (match-data)))
 537         (unwind-protect
 538             (progn
 539               (re-search-forward "^.*$")
 540               (replace-match string))
 541           (set-match-data data))))))
 542
 543
 544 ;;; Text Processing
 545 ;;
 546
 547 (defvar elpher-user-coding-system nil
 548   "User-specified coding system to use for decoding text responses.")
 549
 550 (defun elpher-decode (string)
 551   "Decode STRING using autodetected or user-specified coding system."
 552   (decode-coding-string string
 553                         (if elpher-user-coding-system
 554                             elpher-user-coding-system
 555                           (detect-coding-string string t))))
 556
 557 (defun elpher-preprocess-text-response (string)
 558   "Preprocess text selector response contained in STRING.
 559 This involes decoding the character representation, and clearing
 560 away CRs and any terminating period."
 561   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 562                                            (replace-regexp-in-string "\r" "" string))))
 563
 564
 565 ;;; Network error reporting
 566 ;;
 567
 568 (defun elpher-network-error (address error)
 569   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 570 ERROR can be either an error object or a string."
 571   (elpher-with-clean-buffer
 572    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 573            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 574            (if (stringp error) error (error-message-string error)) "\n"
 575            (propertize "\n----------------\n\n" 'face 'error)
 576            "Press 'u' to return to the previous page.")))
 577
 578
 579 ;;; General network communication
 580 ;;
 581
 582 (defvar elpher-network-timer nil
 583   "Timer used for network connections.")
 584
 585 (defvar elpher-use-tls nil
 586   "If non-nil, use TLS to communicate with gopher servers.")
 587
 588 (defvar elpher-client-certificate nil
 589   "If non-nil, contains client certificate details to use for TLS connections.")
 590
 591 (defun elpher-process-cleanup ()
 592   "Immediately shut down any extant elpher process and timers."
 593   (let ((p (get-process "elpher-process")))
 594     (if p (delete-process p)))
 595   (if (timerp elpher-network-timer)
 596       (cancel-timer elpher-network-timer)))
 597
 598 (defun elpher-get-host-response (address default-port query-string response-processor
 599                                          &optional use-tls force-ipv4)
 600   "Generic function for retrieving data from ADDRESS.
 601
 602 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 603 QUERY-STRING is a string sent to the host specified by ADDRESS to
 604 illicet a response.  This response is passed as an argument to the
 605 function RESPONSE-PROCESSOR.
 606
 607 If non-nil, USE-TLS specifies that the connection is to be made over
 608 TLS.  If set to gemini, the certificate verification will be disabled
 609 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 610
 611 If non-nil, FORCE-IPV4 causes the network connection to be made over
 612 ipv4 only.  (The default behaviour when this is not set depends on
 613 the host operating system and the local network capabilities."
 614   (if (and use-tls (not (gnutls-available-p)))
 615       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 616     (unless (< (elpher-address-port address) 65536)
 617       (error "Cannot establish network connection: port number > 65536"))
 618     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 619       (setq-local network-security-level 'low))
 620     (condition-case nil
 621         (let* ((kill-buffer-query-functions nil)
 622                (port (elpher-address-port address))
 623                (host (elpher-address-host address))
 624                (response-string-parts nil)
 625                (bytes-received 0)
 626                (hkbytes-received 0)
 627                (proc (make-network-process :name "elpher-process"
 628                                            :host host
 629                                            :family (and force-ipv4 'ipv4)
 630                                            :service (if (> port 0) port default-port)
 631                                            :buffer nil
 632                                            :coding 'binary
 633                                            :noquery t
 634                                            :nowait t
 635                                            :tls-parameters
 636                                            (and use-tls
 637                                                 (cons 'gnutls-x509pki
 638                                                       (gnutls-boot-parameters
 639                                                        :type 'gnutls-x509pki
 640                                                        :hostname host
 641                                                        :keylist
 642                                                        (elpher-get-current-keylist address))))))
 643                (timer (run-at-time elpher-connection-timeout nil
 644                                    (lambda ()
 645                                      (elpher-process-cleanup)
 646                                      (cond
 647                                         ; Try again with IPv4
 648                                       ((not force-ipv4)
 649                                        (message "Connection timed out.  Retrying with IPv4.")
 650                                        (elpher-get-host-response address default-port
 651                                                                  query-string
 652                                                                  response-processor
 653                                                                  use-tls t))
 654                                       ((and use-tls
 655                                             (not (eq use-tls 'gemini))
 656                                             (or elpher-auto-disengage-TLS
 657                                                 (y-or-n-p
 658                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 659                                        (setq elpher-use-tls nil)
 660                                        (elpher-get-host-response address default-port
 661                                                                  query-string
 662                                                                  response-processor
 663                                                                  nil force-ipv4))
 664                                       (t
 665                                        (elpher-network-error address "Connection time-out.")))))))
 666           (setq elpher-network-timer timer)
 667           (elpher-buffer-message (concat "Connecting to " host "..."
 668                                          " (press 'u' to abort)"))
 669           (set-process-filter proc
 670                               (lambda (_proc string)
 671                                 (when timer
 672                                   (cancel-timer timer)
 673                                   (setq timer nil))
 674                                 (setq bytes-received (+ bytes-received (length string)))
 675                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 676                                   (when (> new-hkbytes-received hkbytes-received)
 677                                     (setq hkbytes-received new-hkbytes-received)
 678                                     (elpher-buffer-message
 679                                         (concat "("
 680                                                 (number-to-string (/ hkbytes-received 10.0))
 681                                                 " MB read)")
 682                                         1)))
 683                                 (setq response-string-parts
 684                                       (cons string response-string-parts))))
 685           (set-process-sentinel proc
 686                                 (lambda (proc event)
 687                                   (when timer
 688                                     (cancel-timer timer))
 689                                   (condition-case the-error
 690                                       (cond
 691                                        ((string-prefix-p "open" event)    ; request URL
 692                                         (elpher-buffer-message
 693                                          (concat "Connected to " host ". Receiving data..."
 694                                                  " (press 'u' to abort)"))
 695                                         (let ((inhibit-eol-conversion t))
 696                                           (process-send-string proc query-string)))
 697                                        ((string-prefix-p "deleted" event)) ; do nothing
 698                                        ((and (not response-string-parts)
 699                                              (not (or elpher-ipv4-always force-ipv4)))
 700                                         ; Try again with IPv4
 701                                         (message "Connection failed. Retrying with IPv4.")
 702                                         (elpher-get-host-response address default-port
 703                                                                   query-string
 704                                                                   response-processor
 705                                                                   use-tls t))
 706                                        (response-string-parts
 707                                         (elpher-with-clean-buffer
 708                                          (insert "Data received.  Rendering..."))
 709                                         (funcall response-processor
 710                                                  (apply #'concat (reverse response-string-parts)))
 711                                         (elpher-restore-pos))
 712                                        (t
 713                                         (error "No response from server")))
 714                                     (error
 715                                      (elpher-network-error address the-error))))))
 716       (error
 717        (error "Error initiating connection to server")))))
 718
 719
 720 ;;; Client-side TLS Certificate Management
 721 ;;
 722
 723 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 724   "Generate a key and a self-signed client TLS certificate using openssl.
 725
 726 The Common Name field of the certificate is set to COMMON-NAME.  The
 727 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 728 the key and certificate files to write.
 729
 730 If TEMPORARY is non-nil, the certificate will be given an exporation
 731 period of one day, and the key and certificate files will be deleted
 732 when the certificate is no longer needed for the current session.
 733
 734 Otherwise, the certificate will be given a 100 year expiration period
 735 and the files will not be deleted.
 736
 737 The function returns a list containing the current host name, the
 738 temporary flag, and the key and cert file names in the form required
 739 by `gnutls-boot-parameters`."
 740   (let ((exp-key-file (expand-file-name key-file))
 741         (exp-cert-file (expand-file-name cert-file)))
 742     (condition-case nil
 743         (progn
 744           (call-process elpher-openssl-command nil nil nil
 745                         "req" "-x509" "-newkey" "rsa:2048"
 746                         "-days" (if temporary "1" "36500")
 747                         "-nodes"
 748                         "-subj" (concat "/CN=" common-name)
 749                         "-keyout" exp-key-file
 750                         "-out" exp-cert-file)
 751           (list (elpher-address-host (elpher-page-address elpher-current-page))
 752                 temporary exp-key-file exp-cert-file))
 753       (error
 754        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 755        (error "Program 'openssl', required for certificate generation, not found")))))
 756
 757 (defun elpher-generate-throwaway-certificate ()
 758   "Generate and return details of a throwaway certificate.
 759 The key and certificate files will be deleted when they are no
 760 longer needed for this session."
 761   (let* ((file-base (make-temp-name "elpher"))
 762          (key-file (concat temporary-file-directory file-base ".key"))
 763          (cert-file (concat temporary-file-directory file-base ".crt")))
 764     (elpher-generate-certificate file-base key-file cert-file t)))
 765
 766 (defun elpher-generate-permanent-certificate (file-base common-name)
 767   "Generate and return details of a persistant certificate.
 768 The argument FILE-BASE is used as the base for the key and certificate
 769 files, while COMMON-NAME specifies the common name field of the
 770 certificate.
 771
 772 The key and certificate files are written to in `elpher-certificate-directory'."
 773   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 774          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 775     (elpher-generate-certificate common-name key-file cert-file)))
 776
 777 (defun elpher-get-existing-certificate (file-base)
 778   "Return a certificate object corresponding to an existing certificate.
 779 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 780 the directory `elpher-certificate-directory'."
 781   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 782          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 783     (list (elpher-address-host (elpher-page-address elpher-current-page))
 784           nil
 785           (expand-file-name key-file)
 786           (expand-file-name cert-file))))
 787
 788 (defun elpher-list-existing-certificates ()
 789   "Return a list of the persistant certificates in `elpher-certificate-directory'."
 790   (mapcar
 791    (lambda (file)
 792      (file-name-sans-extension file))
 793    (directory-files elpher-certificate-directory nil "\.key$")))
 794
 795 (defun elpher-forget-current-certificate ()
 796   "Causes any current certificate to be forgotten.
 797 In the case of throwaway certificates, the key and certificate files
 798 are also deleted."
 799   (interactive)
 800   (when elpher-client-certificate
 801     (unless (and (called-interactively-p 'any)
 802                  (not (y-or-n-p (concat "Really forget client certificate? "
 803                                         "(Throwaway certificates will be deleted.)"))))
 804       (when (cadr elpher-client-certificate)
 805         (delete-file (elt elpher-client-certificate 2))
 806         (delete-file (elt elpher-client-certificate 3)))
 807       (setq elpher-client-certificate nil)
 808       (if (called-interactively-p 'any)
 809           (message "Client certificate forgotten.")))))
 810
 811 (defun elpher-get-current-keylist (address)
 812   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 813
 814 This is obtained from the client certificate described by
 815 `elpher-current-certificate', if one is available and the host for
 816 that certificate matches the host in ADDRESS.
 817
 818 If `elpher-current-certificate' is non-nil, and its host name doesn't
 819 match that of ADDRESS, the certificate is forgotten."
 820   (if elpher-client-certificate
 821       (if (string= (car elpher-client-certificate)
 822                    (elpher-address-host address))
 823           (list (cddr elpher-client-certificate))
 824         (elpher-forget-current-certificate)
 825         (message "Disabling client certificate for new host")
 826         nil)
 827     nil))
 828
 829
 830 ;;; Gopher selector retrieval
 831 ;;
 832
 833 (defun elpher-get-gopher-response (address renderer)
 834   "Get response string from gopher server at ADDRESS and render using RENDERER."
 835   (elpher-get-host-response address 70
 836                             (concat (elpher-gopher-address-selector address) "\r\n")
 837                             renderer
 838                             (or (string= (elpher-address-protocol address) "gophers")
 839                                 elpher-use-tls)))
 840
 841 (defun elpher-get-gopher-page (renderer)
 842   "Getter function for gopher pages.
 843 The RENDERER procedure is used to display the contents of the page
 844 once they are retrieved from the gopher server."
 845   (let* ((address (elpher-page-address elpher-current-page))
 846          (content (elpher-get-cached-content address)))
 847     (if (and content (funcall renderer nil))
 848         (elpher-with-clean-buffer
 849          (insert content)
 850          (elpher-restore-pos))
 851       (elpher-with-clean-buffer
 852        (insert "LOADING... (use 'u' to cancel)\n"))
 853       (condition-case the-error
 854           (elpher-get-gopher-response address renderer)
 855         (error
 856          (elpher-network-error address the-error))))))
 857
 858 ;; Index rendering
 859
 860 (defun elpher-insert-index (string)
 861   "Insert the index corresponding to STRING into the current buffer."
 862   ;; Should be able to split directly on CRLF, but some non-conformant
 863   ;; LF-only servers sadly exist, hence the following.
 864   (let ((str-processed (elpher-preprocess-text-response string)))
 865     (dolist (line (split-string str-processed "\n"))
 866       (ignore-errors
 867         (unless (= (length line) 0)
 868           (let* ((type (elt line 0))
 869                  (fields (split-string (substring line 1) "\t"))
 870                  (display-string (elt fields 0))
 871                  (selector (elt fields 1))
 872                  (host (elt fields 2))
 873                  (port (if (elt fields 3)
 874                            (string-to-number (elt fields 3))
 875                          nil))
 876                  (address (elpher-make-gopher-address type selector host port)))
 877             (elpher-insert-index-record display-string address)))))))
 878
 879 (defun elpher-insert-margin (&optional type-name)
 880   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 881   (if type-name
 882       (progn
 883         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 884                         (concat
 885                          (propertize "[" 'face 'elpher-margin-brackets)
 886                          (propertize type-name 'face 'elpher-margin-key)
 887                          (propertize "]" 'face 'elpher-margin-brackets))))
 888         (insert " "))
 889     (insert (make-string elpher-margin-width ?\s))))
 890
 891 (defun elpher--page-button-help (_window buffer pos)
 892   "Function called by Emacs to generate mouse-over text.
 893 The arguments specify the BUFFER and the POS within the buffer of the item
 894 for which help is required.  The function returns the help to be
 895 displayed.  The _WINDOW argument is currently unused."
 896   (with-current-buffer buffer
 897     (let ((button (button-at pos)))
 898       (when button
 899         (let* ((page (button-get button 'elpher-page))
 900                (address (elpher-page-address page)))
 901           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 902                                                 address
 903                                               (elpher-address-to-url address))))))))
 904
 905 (defun elpher-insert-index-record (display-string &optional address)
 906   "Function to insert an index record into the current buffer.
 907 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 908 If ADDRESS is not supplied or nil the record is rendered as an
 909 'information' line."
 910   (let* ((type (if address (elpher-address-type address) nil))
 911          (type-map-entry (cdr (assoc type elpher-type-map))))
 912     (if type-map-entry
 913         (let* ((margin-code (elt type-map-entry 2))
 914                (face (elt type-map-entry 3))
 915                (filtered-display-string (ansi-color-filter-apply display-string))
 916                (page (elpher-make-page filtered-display-string address)))
 917           (elpher-insert-margin margin-code)
 918           (insert-text-button filtered-display-string
 919                               'face face
 920                               'elpher-page page
 921                               'action #'elpher-click-link
 922                               'follow-link t
 923                               'help-echo #'elpher--page-button-help))
 924       (pcase type
 925         ('nil ;; Information
 926          (elpher-insert-margin)
 927          (let ((propertized-display-string
 928                 (propertize display-string 'face 'elpher-info)))
 929            (insert (elpher-process-text-for-display propertized-display-string))))
 930         (`(gopher ,selector-type) ;; Unknown
 931          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 932          (insert (propertize display-string
 933                              'face 'elpher-unknown)))))
 934     (insert "\n")))
 935
 936 (defun elpher-click-link (button)
 937   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 938   (let ((page (button-get button 'elpher-page)))
 939     (elpher-visit-page page)))
 940
 941 (defun elpher-render-index (data &optional _mime-type-string)
 942   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 943   (elpher-with-clean-buffer
 944    (if (not data)
 945        t
 946      (elpher-insert-index data)
 947      (elpher-cache-content (elpher-page-address elpher-current-page)
 948                            (buffer-string)))))
 949
 950 ;; Text rendering
 951
 952 (defconst elpher-url-regex
 953   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 954   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 955
 956 (defun elpher-buttonify-urls (string)
 957   "Turn substrings which look like urls in STRING into clickable buttons."
 958   (with-temp-buffer
 959     (insert string)
 960     (goto-char (point-min))
 961     (while (re-search-forward elpher-url-regex nil t)
 962       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 963                                     (elpher-address-from-url (match-string 0)))))
 964           (make-text-button (match-beginning 0)
 965                             (match-end 0)
 966                             'elpher-page  page
 967                             'action #'elpher-click-link
 968                             'follow-link t
 969                             'help-echo #'elpher--page-button-help
 970                             'face 'button)))
 971     (buffer-string)))
 972
 973 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 974   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 975
 976 (defun elpher-process-text-for-display (string)
 977   "Perform any desired processing of STRING prior to display as text.
 978 Currently includes buttonifying URLs and processing ANSI escape codes."
 979   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 980                              (ansi-color-filter-apply string)
 981                            (ansi-color-apply string))))
 982
 983 (defun elpher-render-text (data &optional _mime-type-string)
 984   "Render DATA as text.  MIME-TYPE-STRING is unused."
 985   (elpher-with-clean-buffer
 986    (if (not data)
 987        t
 988      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
 989      (elpher-cache-content
 990       (elpher-page-address elpher-current-page)
 991       (buffer-string)))))
 992
 993 ;; Image retrieval
 994
 995 (defun elpher-render-image (data &optional _mime-type-string)
 996   "Display DATA as image.  MIME-TYPE-STRING is unused."
 997   (if (not data)
 998       nil
 999     (if (display-images-p)
1000         (progn
1001           (let ((image (create-image
1002                         data
1003                         nil t)))
1004             (elpher-with-clean-buffer
1005              (insert-image image)
1006              (elpher-restore-pos))))
1007       (elpher-render-download data))))
1008
1009 ;; Search retrieval and rendering
1010
1011 (defun elpher-get-gopher-query-page (renderer)
1012   "Getter for gopher addresses requiring input.
1013 The response is rendered using the rendering function RENDERER."
1014    (let* ((address (elpher-page-address elpher-current-page))
1015           (content (elpher-get-cached-content address))
1016           (aborted t))
1017     (if (and content (funcall renderer nil))
1018         (elpher-with-clean-buffer
1019          (insert content)
1020          (elpher-restore-pos)
1021          (message "Displaying cached search results.  Reload to perform a new search."))
1022       (unwind-protect
1023           (let* ((query-string (read-string "Query: "))
1024                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1025                  (search-address (elpher-make-gopher-address ?1
1026                                                              query-selector
1027                                                              (elpher-address-host address)
1028                                                              (elpher-address-port address)
1029                                                              (equal (elpher-address-type address) "gophers"))))
1030             (setq aborted nil)
1031
1032             (elpher-with-clean-buffer
1033              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1034             (elpher-get-gopher-response search-address renderer))
1035         (if aborted
1036             (elpher-visit-previous-page))))))
1037
1038 ;; Raw server response rendering
1039
1040 (defun elpher-render-raw (data &optional mime-type-string)
1041   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1042   (if (not data)
1043       nil
1044     (elpher-with-clean-buffer
1045      (when mime-type-string
1046        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1047      (insert data)
1048      (goto-char (point-min)))
1049     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1050
1051 ;; File save "rendering"
1052
1053 (defun elpher-render-download (data &optional _mime-type-string)
1054   "Save DATA to file.  MIME-TYPE-STRING is unused."
1055   (if (not data)
1056       nil
1057     (let* ((address (elpher-page-address elpher-current-page))
1058            (selector (if (elpher-address-gopher-p address)
1059                          (elpher-gopher-address-selector address)
1060                        (elpher-address-filename address))))
1061       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1062       (let* ((filename-proposal (file-name-nondirectory selector))
1063              (filename (read-file-name "Download complete. Save file as: "
1064                                        nil nil nil
1065                                        (if (> (length filename-proposal) 0)
1066                                            filename-proposal
1067                                          "download.file"))))
1068         (let ((coding-system-for-write 'binary))
1069           (with-temp-file filename
1070             (insert data)))
1071         (message (format "Saved to file %s." filename))))))
1072
1073 ;; HTML rendering
1074
1075 (defun elpher-render-html (data &optional _mime-type-string)
1076   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1077   (elpher-with-clean-buffer
1078    (if (not data)
1079        t
1080      (let ((dom (with-temp-buffer
1081                   (insert data)
1082                   (libxml-parse-html-region (point-min) (point-max)))))
1083        (shr-insert-document dom)))))
1084
1085 ;; Gemini page retrieval
1086
1087 (defvar elpher-gemini-redirect-chain)
1088
1089 (defun elpher-get-gemini-response (address renderer)
1090   "Get response string from gemini server at ADDRESS and render using RENDERER."
1091   (elpher-get-host-response address 1965
1092                             (concat (elpher-address-to-url address) "\r\n")
1093                             (lambda (response-string)
1094                               (elpher-process-gemini-response response-string renderer))
1095                             'gemini))
1096
1097 (defun elpher-parse-gemini-response (response)
1098   "Parse the RESPONSE string and return a list of components.
1099 The list is of the form (code meta body).  A response of nil implies
1100 that the response was malformed."
1101   (let ((header-end-idx (string-match "\r\n" response)))
1102     (if header-end-idx
1103         (let ((header (string-trim (substring response 0 header-end-idx)))
1104               (body (substring response (+ header-end-idx 2))))
1105           (if (>= (length header) 2)
1106               (let ((code (substring header 0 2))
1107                     (meta (string-trim (substring header 2))))
1108                 (list code meta body))
1109             (error "Malformed response: No response status found in header %s" header)))
1110       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1111
1112 (defun elpher-process-gemini-response (response-string renderer)
1113   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1114   (let ((response-components (elpher-parse-gemini-response response-string)))
1115     (let ((response-code (elt response-components 0))
1116           (response-meta (elt response-components 1))
1117           (response-body (elt response-components 2)))
1118       (pcase (elt response-code 0)
1119         (?1 ; Input required
1120          (elpher-with-clean-buffer
1121           (insert "Gemini server is requesting input."))
1122          (let* ((query-string
1123                  (if (eq (elt response-code 1) ?1)
1124                      (read-passwd (concat response-meta ": "))
1125                    (read-string (concat response-meta ": "))))
1126                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1127                 (old-fname (url-filename query-address)))
1128            (setf (url-filename query-address)
1129                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1130            (elpher-get-gemini-response query-address renderer)))
1131         (?2 ; Normal response
1132          (funcall renderer response-body response-meta))
1133         (?3 ; Redirect
1134          (message "Following redirect to %s" response-meta)
1135          (if (>= (length elpher-gemini-redirect-chain) 5)
1136              (error "More than 5 consecutive redirects followed"))
1137          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1138            (if (member redirect-address elpher-gemini-redirect-chain)
1139                (error "Redirect loop detected"))
1140            (if (not (string= (elpher-address-protocol redirect-address)
1141                              "gemini"))
1142                (error "Server tried to automatically redirect to non-gemini URL: %s"
1143                       response-meta))
1144            (elpher-page-set-address elpher-current-page redirect-address)
1145            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1146            (elpher-get-gemini-response redirect-address renderer)))
1147         (?4 ; Temporary failure
1148          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1149                 response-code response-meta))
1150         (?5 ; Permanent failure
1151          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1152                 response-code response-meta))
1153         (?6 ; Client certificate required
1154          (elpher-with-clean-buffer
1155           (if elpher-client-certificate
1156               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1157             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1158           (auto-fill-mode 1)
1159           (elpher-gemini-insert-text response-meta))
1160          (let* ((read-answer-short t))
1161            (pcase (read-answer "What do you want to do? "
1162                                '(("throwaway" ?t
1163                                   "generate and use throw-away certificate")
1164                                  ("permanent" ?p
1165                                   "generate new or use existing permanent certificate")
1166                                  ("abort" ?a
1167                                   "stop immediately")))
1168              ("throwaway"
1169               (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1170              ("permanent"
1171               (let* ((existing-certificates (elpher-list-existing-certificates))
1172                      (file-base (completing-read
1173                                  "Name of new or existing certificate (autocompletes, empty response aborts): "
1174                                  existing-certificates)))
1175                 (if (string-empty-p (string-trim file-base))
1176                     (error "Gemini server requires certificate and none was provided")
1177                   (if (member file-base existing-certificates)
1178                       (setq elpher-client-certificate
1179                             (elpher-get-existing-certificate file-base))
1180                     (let ((common-name (read-string "Common Name field for new certificate: "
1181                                                     file-base)))
1182                       (setq elpher-client-certificate
1183                             (elpher-generate-permanent-certificate file-base common-name))
1184                       (message "New key and self-signed certificate written to %s"
1185                                elpher-certificate-directory))))))
1186              ("abort"
1187               (error "Gemini server requires a client certificate and none was provided")))
1188            (elpher-with-clean-buffer)
1189            (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer)))
1190         (_other
1191          (error "Gemini server response unknown: %s %s"
1192                 response-code response-meta))))))
1193
1194 (defun elpher-get-gemini-page (renderer)
1195   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1196   (let* ((address (elpher-page-address elpher-current-page))
1197          (content (elpher-get-cached-content address)))
1198     (condition-case the-error
1199         (if (and content (funcall renderer nil))
1200             (elpher-with-clean-buffer
1201               (insert content)
1202               (elpher-restore-pos))
1203           (elpher-with-clean-buffer
1204            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1205           (setq elpher-gemini-redirect-chain nil)
1206           (elpher-get-gemini-response address renderer))
1207       (error
1208        (elpher-network-error address the-error)))))
1209
1210
1211 (defun elpher-render-gemini (body &optional mime-type-string)
1212   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1213   (if (not body)
1214       t
1215     (let* ((mime-type-string* (if (or (not mime-type-string)
1216                                       (string-empty-p mime-type-string))
1217                                   "text/gemini; charset=utf-8"
1218                                 mime-type-string))
1219            (mime-type-split (split-string mime-type-string* ";" t))
1220            (mime-type (string-trim (car mime-type-split)))
1221            (parameters (mapcar (lambda (s)
1222                                  (let ((key-val (split-string s "=")))
1223                                    (list (downcase (string-trim (car key-val)))
1224                                          (downcase (string-trim (cadr key-val))))))
1225                                (cdr mime-type-split))))
1226       (when (string-prefix-p "text/" mime-type)
1227         (setq body (decode-coding-string
1228                     body
1229                     (if (assoc "charset" parameters)
1230                         (intern (cadr (assoc "charset" parameters)))
1231                       'utf-8)))
1232         (setq body (replace-regexp-in-string "\r" "" body)))
1233       (pcase mime-type
1234         ((or "text/gemini" "")
1235          (elpher-render-gemini-map body parameters))
1236         ("text/html"
1237          (elpher-render-html body))
1238         ((pred (string-prefix-p "text/"))
1239          (elpher-render-gemini-plain-text body parameters))
1240         ((pred (string-prefix-p "image/"))
1241          (elpher-render-image body))
1242         (_other
1243          (elpher-render-download body))))))
1244
1245 (defun elpher-gemini-get-link-url (link-line)
1246   "Extract the url portion of LINK-LINE, a gemini map file link line.
1247 Returns nil in the event that the contents of the line following the
1248 => prefix are empty."
1249   (let ((l (split-string (substring link-line 2))))
1250     (if l
1251         (string-trim (elt l 0))
1252       nil)))
1253
1254 (defun elpher-gemini-get-link-display-string (link-line)
1255   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1256 Returns the url portion in the event that the display-string portion is empty."
1257   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1258          (idx (string-match "[ \t]" rest)))
1259     (string-trim (if idx
1260                      (substring rest (+ idx 1))
1261                    rest))))
1262
1263 (defun elpher-collapse-dot-sequences (filename)
1264   "Collapse dot sequences in FILENAME.
1265 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1266   (let* ((path (split-string filename "/"))
1267          (path-reversed-normalized
1268           (seq-reduce (lambda (a b)
1269                         (cond ((and a (equal b "..") (cdr a)))
1270                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1271                               ((equal b ".") a)
1272                               (t (cons b a))))
1273                       path nil)))
1274     (string-join (reverse path-reversed-normalized) "/")))
1275
1276 (defun elpher-address-from-gemini-url (url)
1277   "Extract address from URL with defaults as per gemini map files.
1278 While there's obviously some redundancy here between this function and
1279 `elpher-address-from-url', gemini map file URLs require enough special
1280 treatment that a separate function is warranted."
1281   (let ((address (url-generic-parse-url url))
1282         (current-address (elpher-page-address elpher-current-page)))
1283     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1284       (setf (url-fullness address) t)
1285       (if (url-host address) ;if there is an explicit host, filenames are absolute
1286           (if (string-empty-p (url-filename address))
1287               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1288         (setf (url-host address) (url-host current-address))
1289         (setf (url-port address) (url-port current-address))
1290         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1291           (setf (url-filename address)
1292                 (concat (file-name-directory (url-filename current-address))
1293                         (url-filename address)))))
1294       (unless (url-type address)
1295         (setf (url-type address) "gemini"))
1296       (when (equal (url-type address) "gemini")
1297         (setf (url-filename address)
1298               (elpher-collapse-dot-sequences (url-filename address)))))
1299     (elpher-remove-redundant-ports address)))
1300
1301 (defun elpher-gemini-insert-link (link-line)
1302   "Insert link described by LINK-LINE into a text/gemini document."
1303   (let* ((url (elpher-gemini-get-link-url link-line))
1304          (display-string (elpher-gemini-get-link-display-string link-line))
1305          (address (elpher-address-from-gemini-url url))
1306          (type (if address (elpher-address-type address) nil))
1307          (type-map-entry (cdr (assoc type elpher-type-map))))
1308     (when display-string
1309       (insert elpher-gemini-link-string)
1310       (if type-map-entry
1311           (let* ((face (elt type-map-entry 3))
1312                  (filtered-display-string (ansi-color-filter-apply display-string))
1313                  (page (elpher-make-page filtered-display-string address)))
1314             (insert-text-button filtered-display-string
1315                                 'face face
1316                                 'elpher-page page
1317                                 'action #'elpher-click-link
1318                                 'follow-link t
1319                                 'help-echo #'elpher--page-button-help))
1320         (insert (propertize display-string 'face 'elpher-unknown)))
1321       (insert "\n"))))
1322
1323 (defun elpher-gemini-insert-header (header-line)
1324   "Insert header described by HEADER-LINE into a text/gemini document.
1325 The gemini map file line describing the header is given
1326 by HEADER-LINE."
1327   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1328     (let ((level (length (match-string 1 header-line)))
1329           (header (substring header-line (match-end 0))))
1330       (unless (display-graphic-p)
1331         (insert (make-string level ?#) " "))
1332       (insert (propertize header 'face
1333                           (pcase level
1334                             (1 'elpher-gemini-heading1)
1335                             (2 'elpher-gemini-heading2)
1336                             (3 'elpher-gemini-heading3)
1337                             (_ 'default)))
1338               "\n"))))
1339
1340 (defun elpher-gemini-insert-text (text-line)
1341   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1342 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1343 width defined by elpher-gemini-max-fill-width."
1344   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1345   (let* ((processed-text-line (if (match-string 2 text-line)
1346                                   (concat
1347                                    (replace-regexp-in-string "\*"
1348                                                              elpher-gemini-bullet-string
1349                                                              (match-string 0 text-line))
1350                                    (substring text-line (match-end 0)))
1351                                 text-line))
1352          (adaptive-fill-mode nil)
1353          (fill-prefix (if (match-string 2 text-line)
1354                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1355                         nil)))
1356     (insert (elpher-process-text-for-display processed-text-line))
1357     (newline)))
1358
1359 (defun elpher-render-gemini-map (data _parameters)
1360   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1361   (elpher-with-clean-buffer
1362    (let ((preformatted nil))
1363      (auto-fill-mode 1)
1364      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1365      (dolist (line (split-string data "\n"))
1366        (cond
1367         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1368         (preformatted (insert (elpher-process-text-for-display
1369                                (propertize line 'face 'elpher-gemini-preformatted))
1370                               "\n"))
1371         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1372         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1373         (t (elpher-gemini-insert-text line)))))
1374    (elpher-cache-content
1375     (elpher-page-address elpher-current-page)
1376     (buffer-string))))
1377
1378 (defun elpher-render-gemini-plain-text (data _parameters)
1379   "Render DATA as plain text file.  PARAMETERS is currently unused."
1380   (elpher-with-clean-buffer
1381    (insert (elpher-process-text-for-display data))
1382    (elpher-cache-content
1383     (elpher-page-address elpher-current-page)
1384     (buffer-string))))
1385
1386
1387 ;; Finger page connection
1388
1389 (defun elpher-get-finger-page (renderer)
1390   "Opens a finger connection to the current page address.
1391 The result is rendered using RENDERER."
1392   (let* ((address (elpher-page-address elpher-current-page))
1393          (content (elpher-get-cached-content address)))
1394     (if (and content (funcall renderer nil))
1395         (elpher-with-clean-buffer
1396          (insert content)
1397          (elpher-restore-pos))
1398       (elpher-with-clean-buffer
1399        (insert "LOADING... (use 'u' to cancel)\n"))
1400       (condition-case the-error
1401           (let* ((kill-buffer-query-functions nil)
1402                  (user (let ((filename (elpher-address-filename address)))
1403                          (if (> (length filename) 1)
1404                              (substring filename 1)
1405                            (elpher-address-user address)))))
1406             (elpher-get-host-response address 79
1407                                       (concat user "\r\n")
1408                                       renderer))
1409         (error
1410          (elpher-network-error address the-error))))))
1411
1412
1413 ;; Telnet page connection
1414
1415 (defun elpher-get-telnet-page (renderer)
1416   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1417   (when renderer
1418     (elpher-visit-previous-page)
1419     (error "Command not supported for telnet URLs"))
1420   (let* ((address (elpher-page-address elpher-current-page))
1421          (host (elpher-address-host address))
1422          (port (elpher-address-port address)))
1423     (elpher-visit-previous-page)
1424     (if (> port 0)
1425         (telnet host port)
1426       (telnet host))))
1427
1428
1429 ;; Other URL page opening
1430
1431 (defun elpher-get-other-url-page (renderer)
1432   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1433   (when renderer
1434     (elpher-visit-previous-page)
1435     (error "Command not supported for general URLs"))
1436   (let* ((address (elpher-page-address elpher-current-page))
1437          (url (elpher-address-to-url address)))
1438     (progn
1439       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1440       (message "Opening URL...")
1441       (if elpher-open-urls-with-eww
1442           (browse-web url)
1443         (browse-url url)))))
1444
1445
1446 ;; Start page page retrieval
1447
1448 (defun elpher-get-start-page (renderer)
1449   "Getter which displays the start page (RENDERER must be nil)."
1450   (when renderer
1451     (elpher-visit-previous-page)
1452     (error "Command not supported for start page"))
1453   (elpher-with-clean-buffer
1454    (insert "     --------------------------------------------\n"
1455            "           Elpher Gopher and Gemini Client       \n"
1456            "                   version " elpher-version "\n"
1457            "     --------------------------------------------\n"
1458            "\n"
1459            "Default bindings:\n"
1460            "\n"
1461            " - TAB/Shift-TAB: next/prev item on current page\n"
1462            " - RET/mouse-1: open item under cursor\n"
1463            " - m: select an item on current page by name (autocompletes)\n"
1464            " - u/mouse-3/U: return to previous page or to the start page\n"
1465            " - o/O: visit different selector or the root menu of the current server\n"
1466            " - g: go to a particular address (gopher, gemini, finger)\n"
1467            " - d/D: download item under cursor or current page\n"
1468            " - i/I: info on item under cursor or current page\n"
1469            " - c/C: copy URL representation of item under cursor or current page\n"
1470            " - a/A: bookmark the item under cursor or current page\n"
1471            " - x/X: remove bookmark for item under cursor or current page\n"
1472            " - B: visit the bookmarks page\n"
1473            " - r: redraw current page (using cached contents if available)\n"
1474            " - R: reload current page (regenerates cache)\n"
1475            " - S: set character coding system for gopher (default is to autodetect)\n"
1476            " - T: toggle TLS gopher mode\n"
1477            " - F: forget/discard current TLS client certificate\n"
1478            " - .: display the raw server response for the current page\n"
1479            "\n"
1480            "Start your exploration of gopher space and gemini:\n")
1481    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1482                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1483    (elpher-insert-index-record "Project Gemini home page"
1484                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1485    (insert "\n"
1486            "Alternatively, select a search engine and enter some search terms:\n")
1487    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1488                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1489    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1490                                (elpher-address-from-url "gemini://gus.guru/search"))
1491    (insert "\n"
1492            "This page contains your bookmarked sites (also visit with B):\n")
1493    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1494    (insert "\n"
1495            "For Elpher release news or to leave feedback, visit:\n")
1496    (elpher-insert-index-record "The Elpher Project Page"
1497                                (elpher-make-gopher-address ?1
1498                                                            "/projects/elpher/"
1499                                                            "thelambdalab.xyz"
1500                                                            70))
1501    (insert "\n"
1502            "** Refer to the ")
1503    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1504      (insert-text-button "Elpher info manual"
1505                          'face 'link
1506                          'action (lambda (_)
1507                                    (interactive)
1508                                    (info "(elpher)"))
1509                          'follow-link t
1510                          'help-echo help-string))
1511    (insert " for the full documentation. **\n")
1512    (insert (propertize
1513             (concat "  (This should be available if you have installed Elpher using\n"
1514                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1515             'face 'shadow))
1516    (elpher-restore-pos)))
1517
1518 ;; Bookmarks page page retrieval
1519
1520 (defun elpher-get-bookmarks-page (renderer)
1521   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1522   (when renderer
1523     (elpher-visit-previous-page)
1524     (error "Command not supported for bookmarks page"))
1525   (elpher-with-clean-buffer
1526    (insert "---- Bookmark list ----\n\n")
1527    (let ((bookmarks (elpher-load-bookmarks)))
1528      (if bookmarks
1529          (dolist (bookmark bookmarks)
1530            (let ((display-string (elpher-bookmark-display-string bookmark))
1531                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1532              (elpher-insert-index-record display-string address)))
1533        (insert "No bookmarks found.\n")))
1534    (insert "\n-----------------------\n"
1535            "\n"
1536            "- u: return to previous page\n"
1537            "- x: delete selected bookmark\n"
1538            "- a: rename selected bookmark\n"
1539            "\n"
1540            "Bookmarks are stored in the file ")
1541    (let ((filename elpher-bookmarks-file)
1542          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1543      (insert-text-button filename
1544                          'face 'link
1545                          'action (lambda (_)
1546                                    (interactive)
1547                                    (find-file filename))
1548                          'follow-link t
1549                          'help-echo help-string))
1550    (insert "\n")
1551    (elpher-restore-pos)))
1552
1553
1554 ;;; Bookmarks
1555 ;;
1556
1557 (defun elpher-make-bookmark (display-string url)
1558   "Make an elpher bookmark.
1559 DISPLAY-STRING determines how the bookmark will appear in the
1560 bookmark list, while URL is the url of the entry."
1561   (list display-string url))
1562
1563 (defun elpher-bookmark-display-string (bookmark)
1564   "Get the display string of BOOKMARK."
1565   (elt bookmark 0))
1566
1567 (defun elpher-set-bookmark-display-string (bookmark display-string)
1568   "Set the display string of BOOKMARK to DISPLAY-STRING."
1569   (setcar bookmark display-string))
1570
1571 (defun elpher-bookmark-url (bookmark)
1572   "Get the address for BOOKMARK."
1573   (elt bookmark 1))
1574
1575 (defun elpher-save-bookmarks (bookmarks)
1576   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1577 Beware that this completely replaces the existing contents of the file."
1578   (with-temp-file elpher-bookmarks-file
1579     (erase-buffer)
1580     (insert "; Elpher bookmarks file\n\n"
1581             "; Bookmarks are stored as a list of (label URL) items.\n"
1582             "; Feel free to edit by hand, but take care to ensure\n"
1583             "; the list structure remains intact.\n\n")
1584     (pp bookmarks (current-buffer))))
1585
1586 (defun elpher-load-bookmarks ()
1587   "Get the list of bookmarks from the users's bookmark file."
1588   (let ((bookmarks
1589          (with-temp-buffer
1590            (ignore-errors
1591              (insert-file-contents elpher-bookmarks-file)
1592              (goto-char (point-min))
1593              (read (current-buffer))))))
1594     (if (and bookmarks (listp (cadar bookmarks)))
1595         (progn
1596           (message "Reading old bookmark file. (Will be updated on write.)")
1597           (mapcar (lambda (old-bm)
1598                     (list (car old-bm)
1599                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1600                                                         (cadr old-bm)))))
1601                   bookmarks))
1602       bookmarks)))
1603
1604 (defun elpher-add-address-bookmark (address display-string)
1605   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1606 If ADDRESS is already bookmarked, update the label only."
1607   (let ((bookmarks (elpher-load-bookmarks))
1608         (url (elpher-address-to-url address)))
1609     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1610       (if existing-bookmark
1611           (elpher-set-bookmark-display-string existing-bookmark display-string)
1612         (push (elpher-make-bookmark display-string url) bookmarks)))
1613     (elpher-save-bookmarks bookmarks)))
1614
1615 (defun elpher-remove-address-bookmark (address)
1616   "Remove any bookmark to ADDRESS."
1617   (let ((url (elpher-address-to-url address)))
1618     (elpher-save-bookmarks
1619      (seq-filter (lambda (bookmark)
1620                    (not (equal (elpher-bookmark-url bookmark) url)))
1621                  (elpher-load-bookmarks)))))
1622
1623 ;;; Interactive procedures
1624 ;;
1625
1626 (defun elpher-next-link ()
1627   "Move point to the next link on the current page."
1628   (interactive)
1629   (forward-button 1))
1630
1631 (defun elpher-prev-link ()
1632   "Move point to the previous link on the current page."
1633   (interactive)
1634   (backward-button 1))
1635
1636 (defun elpher-follow-current-link ()
1637   "Open the link or url at point."
1638   (interactive)
1639   (push-button))
1640
1641 (defun elpher-go (host-or-url)
1642   "Go to a particular gopher site HOST-OR-URL.
1643 When run interactively HOST-OR-URL is read from the minibuffer."
1644   (interactive "sGopher or Gemini URL: ")
1645   (let* ((cleaned-host-or-url (string-trim host-or-url))
1646          (address (elpher-address-from-url cleaned-host-or-url))
1647          (page (elpher-make-page cleaned-host-or-url address)))
1648     (switch-to-buffer "*elpher*")
1649     (elpher-visit-page page)
1650     nil))
1651
1652 (defun elpher-go-current ()
1653   "Go to a particular site read from the minibuffer, initialized with the current URL."
1654   (interactive)
1655   (let ((address (elpher-page-address elpher-current-page)))
1656     (if (elpher-address-special-p address)
1657         (error "Command invalid for this page")
1658       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1659         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1660
1661 (defun elpher-redraw ()
1662   "Redraw current page."
1663   (interactive)
1664   (elpher-visit-page elpher-current-page))
1665
1666 (defun elpher-reload ()
1667   "Reload current page."
1668   (interactive)
1669   (elpher-reload-current-page))
1670
1671 (defun elpher-toggle-tls ()
1672   "Toggle TLS encryption mode for gopher."
1673   (interactive)
1674   (setq elpher-use-tls (not elpher-use-tls))
1675   (if elpher-use-tls
1676       (if (gnutls-available-p)
1677           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1678         (setq elpher-use-tls nil)
1679         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1680     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1681
1682 (defun elpher-view-raw ()
1683   "View raw server response for current page."
1684   (interactive)
1685   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1686       (error "This page was not generated by a server")
1687     (elpher-visit-page elpher-current-page
1688                        #'elpher-render-raw)))
1689
1690 (defun elpher-back ()
1691   "Go to previous site."
1692   (interactive)
1693   (elpher-visit-previous-page))
1694
1695 (defun elpher-back-to-start ()
1696   "Go all the way back to the start page."
1697   (interactive)
1698   (setq elpher-current-page nil)
1699   (setq elpher-history nil)
1700   (let ((start-page (elpher-make-page "Elpher Start Page"
1701                                       (elpher-make-special-address 'start))))
1702     (elpher-visit-page start-page)))
1703
1704 (defun elpher-download ()
1705   "Download the link at point."
1706   (interactive)
1707   (let ((button (button-at (point))))
1708     (if button
1709         (let ((page (button-get button 'elpher-page)))
1710           (if (elpher-address-special-p (elpher-page-address page))
1711               (error "Cannot download %s"
1712                      (elpher-page-display-string page))
1713             (elpher-visit-page (button-get button 'elpher-page)
1714                                #'elpher-render-download)))
1715       (error "No link selected"))))
1716
1717 (defun elpher-download-current ()
1718   "Download the current page."
1719   (interactive)
1720   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1721       (error "Cannot download %s"
1722              (elpher-page-display-string elpher-current-page))
1723     (elpher-visit-page (elpher-make-page
1724                         (elpher-page-display-string elpher-current-page)
1725                         (elpher-page-address elpher-current-page))
1726                        #'elpher-render-download
1727                        t)))
1728
1729 (defun elpher-build-link-map ()
1730   "Build alist mapping link names to destination pages in current buffer."
1731   (let ((link-map nil)
1732         (b (next-button (point-min) t)))
1733     (while b
1734       (push (cons (button-label b) b) link-map)
1735       (setq b (next-button (button-start b))))
1736     link-map))
1737
1738 (defun elpher-jump ()
1739   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1740   (interactive)
1741   (let* ((link-map (elpher-build-link-map)))
1742     (if link-map
1743         (let ((key (let ((completion-ignore-case t))
1744                      (completing-read "Directory item/link: "
1745                                       link-map nil t))))
1746           (if (and key (> (length key) 0))
1747               (let ((b (cdr (assoc key link-map))))
1748                 (goto-char (button-start b))
1749                 (button-activate b)))))))
1750
1751 (defun elpher-root-dir ()
1752   "Visit root of current server."
1753   (interactive)
1754   (let ((address (elpher-page-address elpher-current-page)))
1755     (if (not (elpher-address-special-p address))
1756         (if (or (member (url-filename address) '("/" ""))
1757                 (and (elpher-address-gopher-p address)
1758                      (= (length (elpher-gopher-address-selector address)) 0)))
1759             (error "Already at root directory of current server")
1760           (let ((address-copy (elpher-address-from-url
1761                                (elpher-address-to-url address))))
1762             (setf (url-filename address-copy) "")
1763             (elpher-go (elpher-address-to-url address-copy))))
1764       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1765
1766 (defun elpher-bookmarks-current-p ()
1767   "Return non-nil if current page is a bookmarks page."
1768   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1769          '(special bookmarks)))
1770
1771 (defun elpher-reload-bookmarks ()
1772   "Reload bookmarks if current page is a bookmarks page."
1773   (if (elpher-bookmarks-current-p)
1774       (elpher-reload-current-page)))
1775
1776 (defun elpher-bookmark-current ()
1777   "Bookmark the current page."
1778   (interactive)
1779   (let ((address (elpher-page-address elpher-current-page))
1780         (display-string (elpher-page-display-string elpher-current-page)))
1781     (if (not (elpher-address-special-p address))
1782         (let ((bookmark-display-string (read-string "Bookmark display string: "
1783                                                     display-string)))
1784           (elpher-add-address-bookmark address bookmark-display-string)
1785           (message "Bookmark added."))
1786       (error "Cannot bookmark %s" display-string))))
1787
1788 (defun elpher-bookmark-link ()
1789   "Bookmark the link at point."
1790   (interactive)
1791   (let ((button (button-at (point))))
1792     (if button
1793         (let* ((page (button-get button 'elpher-page))
1794                (address (elpher-page-address page))
1795                (display-string (elpher-page-display-string page)))
1796           (if (not (elpher-address-special-p address))
1797               (let ((bookmark-display-string (read-string "Bookmark display string: "
1798                                                           display-string)))
1799                 (elpher-add-address-bookmark address bookmark-display-string)
1800                 (elpher-reload-bookmarks)
1801                 (message "Bookmark added."))
1802             (error "Cannot bookmark %s" display-string)))
1803       (error "No link selected"))))
1804
1805 (defun elpher-unbookmark-current ()
1806   "Remove bookmark for the current page."
1807   (interactive)
1808   (let ((address (elpher-page-address elpher-current-page)))
1809     (when (and (not (elpher-address-special-p address))
1810                (y-or-n-p "Really remove bookmark for the current page? "))
1811       (elpher-remove-address-bookmark address)
1812       (message "Bookmark removed."))))
1813
1814 (defun elpher-unbookmark-link ()
1815   "Remove bookmark for the link at point."
1816   (interactive)
1817   (let ((button (button-at (point))))
1818     (if button
1819         (when (y-or-n-p "Really remove bookmark for this link? ")
1820           (let ((page (button-get button 'elpher-page)))
1821             (elpher-remove-address-bookmark (elpher-page-address page))
1822             (elpher-reload-bookmarks)
1823             (message "Bookmark removed.")))
1824       (error "No link selected"))))
1825
1826 (defun elpher-bookmarks ()
1827   "Visit bookmarks page."
1828   (interactive)
1829   (switch-to-buffer "*elpher*")
1830   (elpher-visit-page
1831    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1832
1833 (defun elpher-info-page (page)
1834   "Display information on PAGE."
1835   (let ((display-string (elpher-page-display-string page))
1836         (address (elpher-page-address page)))
1837     (if (elpher-address-special-p address)
1838         (message "Special page: %s" display-string)
1839       (message "%s" (elpher-address-to-url address)))))
1840
1841 (defun elpher-info-link ()
1842   "Display information on page corresponding to link at point."
1843   (interactive)
1844   (let ((button (button-at (point))))
1845     (if button
1846         (elpher-info-page (button-get button 'elpher-page))
1847       (error "No item selected"))))
1848
1849 (defun elpher-info-current ()
1850   "Display information on current page."
1851   (interactive)
1852   (elpher-info-page elpher-current-page))
1853
1854 (defun elpher-copy-page-url (page)
1855   "Copy URL representation of address of PAGE to `kill-ring'."
1856   (let ((address (elpher-page-address page)))
1857     (if (elpher-address-special-p address)
1858         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1859       (let ((url (elpher-address-to-url address)))
1860         (message "Copied \"%s\" to kill-ring/clipboard." url)
1861         (kill-new url)))))
1862
1863 (defun elpher-copy-link-url ()
1864   "Copy URL of item at point to `kill-ring'."
1865   (interactive)
1866   (let ((button (button-at (point))))
1867     (if button
1868         (elpher-copy-page-url (button-get button 'elpher-page))
1869       (error "No item selected"))))
1870
1871 (defun elpher-copy-current-url ()
1872   "Copy URL of current page to `kill-ring'."
1873   (interactive)
1874   (elpher-copy-page-url elpher-current-page))
1875
1876 (defun elpher-set-gopher-coding-system ()
1877   "Specify an explicit character coding system for gopher selectors."
1878   (interactive)
1879   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1880     (setq elpher-user-coding-system system)
1881     (if system
1882         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1883       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1884
1885
1886 ;;; Mode and keymap
1887 ;;
1888
1889 (defvar elpher-mode-map
1890   (let ((map (make-sparse-keymap)))
1891     (define-key map (kbd "TAB") 'elpher-next-link)
1892     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1893     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1894     (define-key map (kbd "u") 'elpher-back)
1895     (define-key map (kbd "U") 'elpher-back-to-start)
1896     (define-key map [mouse-3] 'elpher-back)
1897     (define-key map (kbd "O") 'elpher-root-dir)
1898     (define-key map (kbd "g") 'elpher-go)
1899     (define-key map (kbd "o") 'elpher-go-current)
1900     (define-key map (kbd "r") 'elpher-redraw)
1901     (define-key map (kbd "R") 'elpher-reload)
1902     (define-key map (kbd "T") 'elpher-toggle-tls)
1903     (define-key map (kbd ".") 'elpher-view-raw)
1904     (define-key map (kbd "d") 'elpher-download)
1905     (define-key map (kbd "D") 'elpher-download-current)
1906     (define-key map (kbd "m") 'elpher-jump)
1907     (define-key map (kbd "i") 'elpher-info-link)
1908     (define-key map (kbd "I") 'elpher-info-current)
1909     (define-key map (kbd "c") 'elpher-copy-link-url)
1910     (define-key map (kbd "C") 'elpher-copy-current-url)
1911     (define-key map (kbd "a") 'elpher-bookmark-link)
1912     (define-key map (kbd "A") 'elpher-bookmark-current)
1913     (define-key map (kbd "x") 'elpher-unbookmark-link)
1914     (define-key map (kbd "X") 'elpher-unbookmark-current)
1915     (define-key map (kbd "B") 'elpher-bookmarks)
1916     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1917     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1918     (when (fboundp 'evil-define-key*)
1919       (evil-define-key* 'motion map
1920         (kbd "TAB") 'elpher-next-link
1921         (kbd "C-") 'elpher-follow-current-link
1922         (kbd "C-t") 'elpher-back
1923         (kbd "u") 'elpher-back
1924         (kbd "U") 'elpher-back-to-start
1925         [mouse-3] 'elpher-back
1926         (kbd "g") 'elpher-go
1927         (kbd "o") 'elpher-go-current
1928         (kbd "r") 'elpher-redraw
1929         (kbd "R") 'elpher-reload
1930         (kbd "T") 'elpher-toggle-tls
1931         (kbd ".") 'elpher-view-raw
1932         (kbd "d") 'elpher-download
1933         (kbd "D") 'elpher-download-current
1934         (kbd "m") 'elpher-jump
1935         (kbd "i") 'elpher-info-link
1936         (kbd "I") 'elpher-info-current
1937         (kbd "c") 'elpher-copy-link-url
1938         (kbd "C") 'elpher-copy-current-url
1939         (kbd "a") 'elpher-bookmark-link
1940         (kbd "A") 'elpher-bookmark-current
1941         (kbd "x") 'elpher-unbookmark-link
1942         (kbd "X") 'elpher-unbookmark-current
1943         (kbd "B") 'elpher-bookmarks
1944         (kbd "S") 'elpher-set-gopher-coding-system
1945         (kbd "F") 'elpher-forget-current-certificate))
1946     map)
1947   "Keymap for gopher client.")
1948
1949 (define-derived-mode elpher-mode special-mode "elpher"
1950   "Major mode for elpher, an elisp gopher client.
1951
1952 This mode is automatically enabled by the interactive
1953 functions which initialize the gopher client, namely
1954 `elpher', `elpher-go' and `elpher-bookmarks'.")
1955
1956 (when (fboundp 'evil-set-initial-state)
1957   (evil-set-initial-state 'elpher-mode 'motion))
1958
1959
1960 ;;; Main start procedure
1961 ;;
1962
1963 ;;;###autoload
1964 (defun elpher ()
1965   "Start elpher with default landing page."
1966   (interactive)
1967   (if (get-buffer "*elpher*")
1968       (switch-to-buffer "*elpher*")
1969     (switch-to-buffer "*elpher*")
1970     (setq elpher-current-page nil)
1971     (setq elpher-history nil)
1972     (let ((start-page (elpher-make-page "Elpher Start Page"
1973                                         (elpher-make-special-address 'start))))
1974       (elpher-visit-page start-page)))
1975   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1976
1977 ;;; elpher.el ends here