elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.2.2
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.2.2"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((about history) elpher-get-history-page nil "E" elpher-index)
 116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page-url "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen is \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 232
 233 Beware that using \"about:bookmarks\" as a start page in combination with
 234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 236 the start page."
 237   :type '(string))
 238
 239 ;; Face customizations
 240
 241 (defgroup elpher-faces nil
 242   "Elpher face customizations."
 243   :group 'elpher)
 244
 245 (defface elpher-index
 246   '((t :inherit font-lock-keyword-face))
 247   "Face used for directory type directory records.")
 248
 249 (defface elpher-text
 250   '((t :inherit bold))
 251   "Face used for text type directory records.")
 252
 253 (defface elpher-info
 254   '((t :inherit default))
 255   "Face used for info type directory records.")
 256
 257 (defface elpher-image
 258   '((t :inherit font-lock-string-face))
 259   "Face used for image type directory records.")
 260
 261 (defface elpher-search
 262   '((t :inherit warning))
 263   "Face used for search type directory records.")
 264
 265 (defface elpher-html
 266   '((t :inherit font-lock-comment-face))
 267   "Face used for html type directory records.")
 268
 269 (defface elpher-gemini
 270   '((t :inherit font-lock-constant-face))
 271   "Face used for Gemini type directory records.")
 272
 273 (defface elpher-other-url
 274   '((t :inherit font-lock-comment-face))
 275   "Face used for other URL type links records.")
 276
 277 (defface elpher-telnet
 278   '((t :inherit font-lock-function-name-face))
 279   "Face used for telnet type directory records.")
 280
 281 (defface elpher-binary
 282   '((t :inherit font-lock-doc-face))
 283   "Face used for binary type directory records.")
 284
 285 (defface elpher-unknown
 286   '((t :inherit error))
 287   "Face used for directory records with unknown/unsupported types.")
 288
 289 (defface elpher-margin-key
 290   '((t :inherit bold))
 291   "Face used for directory margin key.")
 292
 293 (defface elpher-margin-brackets
 294   '((t :inherit shadow))
 295   "Face used for brackets around directory margin key.")
 296
 297 (defface elpher-gemini-heading1
 298   '((t :inherit bold :height 1.8))
 299   "Face used for gemini heading level 1.")
 300
 301 (defface elpher-gemini-heading2
 302   '((t :inherit bold :height 1.5))
 303   "Face used for gemini heading level 2.")
 304
 305 (defface elpher-gemini-heading3
 306   '((t :inherit bold :height 1.2))
 307   "Face used for gemini heading level 3.")
 308
 309 (defface elpher-gemini-preformatted
 310   '((t :inherit fixed-pitch))
 311   "Face used for pre-formatted gemini text blocks.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 ;;; Model
 318 ;;
 319
 320 ;; Address
 321
 322 ;; An elpher "address" object is either a url object or a symbol.
 323 ;; Addresses with the "about" type, corresponding to pages generated
 324 ;; dynamically for and by elpher.  All others represent pages which
 325 ;; rely on content retrieved over the network.
 326
 327 (defun elpher-address-from-url (url-string &optional default-scheme)
 328   "Create a ADDRESS object corresponding to the given URL-STRING.
 329 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 330 is not explicitly given."
 331   (let ((data (match-data))) ; Prevent parsing clobbering match data
 332     (unwind-protect
 333         (let ((url (url-generic-parse-url url-string)))
 334           (unless (and (not (url-fullness url)) (url-type url))
 335             (unless (url-type url)
 336               (setf (url-type url) default-scheme))
 337             (unless (url-host url)
 338               (let ((p (split-string (url-filename url) "/" nil nil)))
 339                 (setf (url-host url) (car p))
 340                 (setf (url-filename url)
 341                       (if (cdr p)
 342                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 343                         ""))))
 344             (when (not (string-empty-p (url-host url)))
 345               (setf (url-fullness url) t)
 346               (setf (url-host url) (puny-encode-domain (url-host url))))
 347             (when (or (equal "gopher" (url-type url))
 348                       (equal "gophers" (url-type url)))
 349               ;; Gopher defaults
 350               (when (or (equal (url-filename url) "")
 351                         (equal (url-filename url) "/"))
 352                 (setf (url-filename url) "/1")))
 353             (when (equal "gemini" (url-type url))
 354               ;; Gemini defaults
 355               (if (equal (url-filename url) "")
 356                   (setf (url-filename url) "/"))))
 357           (elpher-remove-redundant-ports url))
 358       (set-match-data data))))
 359
 360 (defun elpher-remove-redundant-ports (address)
 361   "Remove redundant port specifiers from ADDRESS.
 362 Here 'redundant' means that the specified port matches the default
 363 for that protocol, eg 70 for gopher."
 364   (if (and (not (elpher-address-about-p address))
 365            (eq (url-portspec address) ; (url-port) is too slow!
 366                (pcase (url-type address)
 367                  ("gemini" 1965)
 368                  ((or "gopher" "gophers") 70)
 369                  ("finger" 79)
 370                  (_ -1))))
 371       (setf (url-portspec address) nil))
 372   address)
 373
 374 (defun elpher-make-gopher-address (type selector host port &optional tls)
 375   "Create an ADDRESS object using gopher directory record attributes.
 376 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 377 If the optional attribute TLS is non-nil, the address will be marked as
 378 requiring gopher-over-TLS."
 379   (cond
 380    ((equal type ?i) nil)
 381    ((and (equal type ?h)
 382          (string-prefix-p "URL:" selector))
 383     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 384    ((equal type ?8)
 385     (elpher-address-from-url
 386      (concat "telnet"
 387              "://" host
 388              ":" (number-to-string port))))
 389    (t
 390     (elpher-address-from-url
 391      (concat "gopher" (if tls "s" "")
 392              "://" host
 393              ":" (number-to-string port)
 394              "/" (string type)
 395              selector)))))
 396
 397 (defun elpher-make-about-address (type)
 398   "Create an ADDRESS object corresponding to the given about address TYPE."
 399   (elpher-address-from-url (concat "about:" (symbol-name type))))
 400
 401 (defun elpher-address-to-url (address)
 402   "Get string representation of ADDRESS."
 403   (url-encode-url (url-recreate-url address)))
 404
 405 (defun elpher-address-type (address)
 406   "Retrieve type of ADDRESS object.
 407 This is used to determine how to retrieve and render the document the
 408 address refers to, via the table `elpher-type-map'."
 409   (pcase (url-type address)
 410     ("about"
 411      (list 'about (intern (url-filename address))))
 412     ((or "gopher" "gophers")
 413      (list 'gopher
 414            (if (member (url-filename address) '("" "/"))
 415                ?1
 416              (string-to-char (substring (url-filename address) 1)))))
 417     ("gemini" 'gemini)
 418     ("telnet" 'telnet)
 419     ("finger" 'finger)
 420     ("file" 'file)
 421     (_ 'other-url)))
 422
 423 (defun elpher-address-about-p (address)
 424   "Return non-nil if ADDRESS is an  about address."
 425   (pcase (elpher-address-type address) (`(about ,_) t)))
 426
 427 (defun elpher-address-gopher-p (address)
 428   "Return non-nill if ADDRESS object is a gopher address."
 429   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 430
 431 (defun elpher-address-protocol (address)
 432   "Retrieve the transport protocol for ADDRESS."
 433   (url-type address))
 434
 435 (defun elpher-address-filename (address)
 436   "Retrieve the filename component of ADDRESS.
 437 For gopher addresses this is a combination of the selector type and selector."
 438   (url-unhex-string (url-filename address)))
 439
 440 (defun elpher-address-host (address)
 441   "Retrieve host from ADDRESS object."
 442   (url-host address))
 443
 444 (defun elpher-address-user (address)
 445   "Retrieve user from ADDRESS object."
 446   (url-user address))
 447
 448 (defun elpher-address-port (address)
 449   "Retrieve port from ADDRESS object.
 450 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 451   (url-port address))
 452
 453 (defun elpher-gopher-address-selector (address)
 454   "Retrieve gopher selector from ADDRESS object."
 455   (if (member (url-filename address) '("" "/"))
 456       ""
 457     (url-unhex-string (substring (url-filename address) 2))))
 458
 459
 460 ;; Cache
 461
 462 (defvar elpher-content-cache (make-hash-table :test 'equal))
 463 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 464
 465 (defun elpher-get-cached-content (address)
 466   "Retrieve the cached content for ADDRESS, or nil if none exists."
 467   (gethash address elpher-content-cache))
 468
 469 (defun elpher-cache-content (address content)
 470   "Set the content cache for ADDRESS to CONTENT."
 471   (puthash address content elpher-content-cache))
 472
 473 (defun elpher-get-cached-pos (address)
 474   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 475   (gethash address elpher-pos-cache))
 476
 477 (defun elpher-cache-pos (address pos)
 478   "Set the cursor position cache for ADDRESS to POS."
 479   (puthash address pos elpher-pos-cache))
 480
 481
 482 ;; Page
 483
 484 (defun elpher-make-page (display-string address)
 485   "Create a page with DISPLAY-STRING and ADDRESS."
 486   (list display-string address))
 487
 488 (defun elpher-make-start-page ()
 489   "Create the start page."
 490   (elpher-make-page "Start Page"
 491                     (elpher-address-from-url elpher-start-page-url)))
 492
 493 (defun elpher-page-display-string (page)
 494   "Retrieve the display string corresponding to PAGE."
 495   (elt page 0))
 496
 497 (defun elpher-page-address (page)
 498   "Retrieve the address corresponding to PAGE."
 499   (elt page 1))
 500
 501 (defun elpher-page-set-address (page new-address)
 502   "Set the address corresponding to PAGE to NEW-ADDRESS."
 503   (setcar (cdr page) new-address))
 504
 505 (defun elpher-page-from-url (url &optional default-scheme)
 506   "Create a page with address and display string defined by URL.
 507 The URL is unhexed prior to its use as a display string to improve
 508 readability.
 509
 510 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 511 in the instance that URL itself doesn't specify one."
 512   (let ((address (elpher-address-from-url url default-scheme)))
 513     (elpher-make-page (elpher-address-to-iri address) address)))
 514
 515 (defun elpher-address-to-iri (address)
 516   "Return an IRI for ADDRESS.
 517 Decode percent-escapes and handle punycode in the domain name.
 518 Drop the password, if any."
 519   (let ((data (match-data)) ; Prevent parsing clobbering match data
 520         (host (url-host address))
 521         (pass (url-password address)))
 522     (unwind-protect
 523         (let* ((host (url-host address))
 524                (pass (url-password address)))
 525           (when host
 526             (setf (url-host address) (puny-decode-domain host)))
 527           (when pass                             ; RFC 3986 says we should not render
 528             (setf (url-password address) nil)) ; the password as clear text
 529           (elpher-decode (url-unhex-string (url-recreate-url address))))
 530       (setf (url-host address) host)
 531       (setf (url-password address) pass)
 532       (set-match-data data))))
 533
 534 (defvar elpher-current-page nil
 535   "The current page for this Elpher buffer.")
 536
 537 (defvar elpher-history nil
 538   "The local history stack for this Elpher buffer.
 539 This variable is used by `elpher-back' and
 540 `elpher-show-history'.")
 541
 542 (defvar elpher-visited-pages nil
 543   "The global history for all Elpher buffers.
 544 This variable is used by `elpher-show-visited-pages'.")
 545
 546 (defun elpher-visit-page (page &optional renderer no-history)
 547   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 548 Additionally, push PAGE onto the history stack and the list of
 549 previously-visited pages,unless NO-HISTORY is non-nil."
 550   (elpher-save-pos)
 551   (elpher-process-cleanup)
 552   (unless no-history
 553     (unless (or (not elpher-current-page)
 554                  (equal (elpher-page-address elpher-current-page)
 555                         (elpher-page-address page)))
 556       (push elpher-current-page elpher-history)
 557       (unless (or (elpher-address-about-p (elpher-page-address page))
 558                   (and elpher-visited-pages
 559                        (equal page (car elpher-visited-pages))))
 560         (push page elpher-visited-pages))))
 561   (setq-local elpher-current-page page)
 562   (let* ((address (elpher-page-address page))
 563          (type (elpher-address-type address))
 564          (type-record (cdr (assoc type elpher-type-map))))
 565     (if type-record
 566         (funcall (car type-record)
 567                  (if renderer
 568                      renderer
 569                    (cadr type-record)))
 570       (elpher-visit-previous-page)
 571       (pcase type
 572         (`(gopher ,type-char)
 573          (error "Unsupported gopher selector type '%c' for '%s'"
 574                 type-char (elpher-address-to-url address)))
 575         (other
 576          (error "Unsupported address type '%S' for '%s'"
 577                 other (elpher-address-to-url address)))))))
 578
 579 (defun elpher-visit-previous-page ()
 580   "Visit the previous page in the history."
 581   (if elpher-history
 582       (elpher-visit-page (pop elpher-history) nil t)
 583     (error "No previous page")))
 584
 585 (defun elpher-reload-current-page ()
 586   "Reload the current page, discarding any existing cached content."
 587   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 588   (elpher-visit-page elpher-current-page))
 589
 590 (defun elpher-save-pos ()
 591   "Save the current position of point to the current page."
 592   (when elpher-current-page
 593     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 594
 595 (defun elpher-restore-pos ()
 596   "Restore the position of point to that cached in the current page."
 597   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 598     (if pos
 599         (goto-char pos)
 600       (goto-char (point-min)))))
 601
 602 (defun elpher-get-default-url-scheme ()
 603   "Suggest a default URL scheme to use for visiting addresses based on the current page."
 604   (if elpher-current-page
 605       (let* ((address (elpher-page-address elpher-current-page))
 606              (current-type (elpher-address-type address)))
 607         (pcase current-type
 608           ((or (and 'file (guard (not elpher-history)))
 609                `(about ,_))
 610            elpher-default-url-type)
 611           (`(about ,_)
 612            elpher-default-url-type)
 613           (_
 614            (url-type address))))
 615       elpher-default-url-type))
 616
 617
 618 ;;; Buffer preparation
 619 ;;
 620
 621 (defvar elpher-buffer-name "*elpher*"
 622   "The default name of the Elpher buffer.")
 623
 624 (defun elpher-update-header ()
 625   "If `elpher-use-header' is true, display current page info in window header."
 626   (if (and elpher-use-header elpher-current-page)
 627       (let* ((display-string (elpher-page-display-string elpher-current-page))
 628              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 629              (address (elpher-page-address elpher-current-page))
 630              (tls-string (if (and (not (elpher-address-about-p address))
 631                                   (member (elpher-address-protocol address)
 632                                           '("gophers" "gemini")))
 633                              " [TLS encryption]"
 634                            ""))
 635              (header (concat sanitized-display-string
 636                              (propertize tls-string 'face 'bold))))
 637         (setq header-line-format header))))
 638
 639 (defmacro elpher-with-clean-buffer (&rest args)
 640   "Evaluate ARGS with a clean *elpher* buffer as current."
 641   (declare (debug (body))) ;; Allow edebug to step through body
 642   `(with-current-buffer elpher-buffer-name
 643      (unless (eq major-mode 'elpher-mode)
 644        ;; avoid resetting buffer-local variables
 645        (elpher-mode))
 646      (let ((inhibit-read-only t)
 647            (ansi-color-context nil)) ;; clean ansi interpreter state
 648        (setq-local network-security-level
 649                    (default-value 'network-security-level))
 650        (erase-buffer)
 651        (elpher-update-header)
 652        ,@args)))
 653
 654 (defun elpher-buffer-message (string &optional line)
 655   "Replace first line in elpher buffer with STRING.
 656 If LINE is non-nil, replace that line instead."
 657   (with-current-buffer elpher-buffer-name
 658     (let ((inhibit-read-only t))
 659       (goto-char (point-min))
 660       (if line
 661           (forward-line line))
 662       (let ((data (match-data)))
 663         (unwind-protect
 664             (progn
 665               (re-search-forward "^.*$")
 666               (replace-match string))
 667           (set-match-data data))))))
 668
 669
 670 ;;; Text Processing
 671 ;;
 672
 673 (defvar elpher-user-coding-system nil
 674   "User-specified coding system to use for decoding text responses.")
 675
 676 (defun elpher-decode (string)
 677   "Decode STRING using autodetected or user-specified coding system."
 678   (decode-coding-string string
 679                         (if elpher-user-coding-system
 680                             elpher-user-coding-system
 681                           (detect-coding-string string t))))
 682
 683 (defun elpher-preprocess-text-response (string)
 684   "Preprocess text selector response contained in STRING.
 685 This involes decoding the character representation, and clearing
 686 away CRs and any terminating period."
 687   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 688                                            (replace-regexp-in-string "\r" "" string))))
 689
 690 ;;; Buttonify urls
 691
 692 (defconst elpher-url-regex
 693   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 694   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 695
 696 (defun elpher-buttonify-urls (string)
 697   "Turn substrings which look like urls in STRING into clickable buttons."
 698   (with-temp-buffer
 699     (insert string)
 700     (goto-char (point-min))
 701     (while (re-search-forward elpher-url-regex nil t)
 702       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 703         (make-text-button (match-beginning 0)
 704                           (match-end 0)
 705                           'elpher-page  page
 706                           'action #'elpher-click-link
 707                           'follow-link t
 708                           'help-echo #'elpher--page-button-help
 709                           'face 'button)))
 710     (buffer-string)))
 711
 712 ;;; ANSI colors or XTerm colors (application and filtering)
 713
 714 (or (require 'xterm-color nil t)
 715     (require 'ansi-color))
 716
 717 (defalias 'elpher-color-filter-apply
 718   (if (fboundp 'xterm-color-filter)
 719       (lambda (s)
 720         (let ((_xterm-color-render nil))
 721           (xterm-color-filter s)))
 722     #'ansi-color-filter-apply)
 723   "A function to filter out ANSI escape sequences.")
 724
 725 (defalias 'elpher-color-apply
 726   (if (fboundp 'xterm-color-filter)
 727       #'xterm-color-filter
 728     #'ansi-color-apply)
 729   "A function to apply ANSI escape sequences.")
 730
 731 ;;; Processing text for display
 732
 733 (defun elpher-process-text-for-display (string)
 734   "Perform any desired processing of STRING prior to display as text.
 735 Currently includes buttonifying URLs and processing ANSI escape codes."
 736   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 737                              (elpher-color-filter-apply string)
 738                            (elpher-color-apply string))))
 739
 740
 741 ;;; Network error reporting
 742 ;;
 743
 744 (defun elpher-network-error (address error)
 745   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 746 ERROR can be either an error object or a string."
 747   (elpher-with-clean-buffer
 748    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 749            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 750            (if (stringp error) error (error-message-string error)) "\n"
 751            (propertize "\n----------------\n\n" 'face 'error)
 752            "Press 'u' to return to the previous page.")))
 753
 754
 755 ;;; General network communication
 756 ;;
 757
 758 (defvar elpher-network-timer nil
 759   "Timer used for network connections.")
 760
 761 (defvar elpher-use-tls nil
 762   "If non-nil, use TLS to communicate with gopher servers.")
 763
 764 (defvar elpher-client-certificate nil
 765   "If non-nil, contains client certificate details to use for TLS connections.")
 766
 767 (defun elpher-process-cleanup ()
 768   "Immediately shut down any extant elpher process and timers."
 769   (let ((p (get-process "elpher-process")))
 770     (if p (delete-process p)))
 771   (if (timerp elpher-network-timer)
 772       (cancel-timer elpher-network-timer)))
 773
 774 (defun elpher-make-network-timer (thunk)
 775   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 776 This is just a wraper around `run-at-time' which additionally sets the
 777 buffer-local variable `elpher-network-timer' to allow
 778 `elpher-process-cleanup' to also clear the timer."
 779   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 780     (setq-local elpher-network-timer timer)
 781     timer))
 782
 783 (defun elpher-get-host-response (address default-port query-string response-processor
 784                                          &optional use-tls force-ipv4)
 785   "Generic function for retrieving data from ADDRESS.
 786
 787 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 788 QUERY-STRING is a string sent to the host specified by ADDRESS to
 789 illicet a response.  This response is passed as an argument to the
 790 function RESPONSE-PROCESSOR.
 791
 792 If non-nil, USE-TLS specifies that the connection is to be made over
 793 TLS.  If set to gemini, the certificate verification will be disabled
 794 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 795
 796 If non-nil, FORCE-IPV4 causes the network connection to be made over
 797 ipv4 only.  (The default behaviour when this is not set depends on
 798 the host operating system and the local network capabilities.)"
 799   (if (and use-tls (not (gnutls-available-p)))
 800       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 801     (unless (< (elpher-address-port address) 65536)
 802       (error "Cannot establish network connection: port number > 65536"))
 803     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 804       (setq-local network-security-level 'low)
 805       (setq-local gnutls-verify-error nil))
 806     (condition-case nil
 807         (let* ((kill-buffer-query-functions nil)
 808                (port (elpher-address-port address))
 809                (host (elpher-address-host address))
 810                (service (if (> port 0) port default-port))
 811                (response-string-parts nil)
 812                (bytes-received 0)
 813                (hkbytes-received 0)
 814                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 815                (gnutls-params (list :type 'gnutls-x509pki
 816                                     :hostname host
 817                                     :keylist
 818                                     (elpher-get-current-keylist address)))
 819                (timer (elpher-make-network-timer
 820                                    (lambda ()
 821                                      (elpher-process-cleanup)
 822                                      (cond
 823                                         ; Try again with IPv4
 824                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 825                                        (message "Connection timed out.  Retrying with IPv4.")
 826                                        (elpher-get-host-response address default-port
 827                                                                  query-string
 828                                                                  response-processor
 829                                                                  use-tls t))
 830                                       ((and use-tls
 831                                             (not (eq use-tls 'gemini))
 832                                             (or elpher-auto-disengage-TLS
 833                                                 (y-or-n-p
 834                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 835                                        (setq elpher-use-tls nil)
 836                                        (elpher-get-host-response address default-port
 837                                                                  query-string
 838                                                                  response-processor
 839                                                                  nil force-ipv4))
 840                                       (t
 841                                        (elpher-network-error address "Connection time-out."))))))
 842                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 843                        (make-network-process :name "elpher-process"
 844                                              :host host
 845                                              :family (and (or force-ipv4
 846                                                               elpher-ipv4-always)
 847                                                           'ipv4)
 848                                              :service service
 849                                              :buffer nil
 850                                              :nowait t
 851                                              :tls-parameters
 852                                              (and use-tls
 853                                                   (cons 'gnutls-x509pki
 854                                                         (apply #'gnutls-boot-parameters
 855                                                                gnutls-params)))))))
 856           (setq elpher-network-timer timer)
 857           (set-process-coding-system proc 'binary 'binary)
 858           (set-process-query-on-exit-flag proc nil)
 859           (elpher-buffer-message (concat "Connecting to " host "..."
 860                                          " (press 'u' to abort)"))
 861           (set-process-filter proc
 862                               (lambda (_proc string)
 863                                 (when timer
 864                                   (cancel-timer timer)
 865                                   (setq timer nil))
 866                                 (setq bytes-received (+ bytes-received (length string)))
 867                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 868                                   (when (> new-hkbytes-received hkbytes-received)
 869                                     (setq hkbytes-received new-hkbytes-received)
 870                                     (elpher-buffer-message
 871                                      (concat "("
 872                                              (number-to-string (/ hkbytes-received 10.0))
 873                                              " MB read)")
 874                                      1)))
 875                                 (setq response-string-parts
 876                                       (cons string response-string-parts))))
 877           (set-process-sentinel proc
 878                                 (lambda (proc event)
 879                                   (when timer
 880                                     (cancel-timer timer))
 881                                   (condition-case the-error
 882                                       (cond
 883                                        ((string-prefix-p "open" event)    ; request URL
 884                                         (elpher-buffer-message
 885                                          (concat "Connected to " host ". Receiving data..."
 886                                                  " (press 'u' to abort)"))
 887                                         (let ((inhibit-eol-conversion t))
 888                                           (process-send-string proc query-string)))
 889                                        ((string-prefix-p "deleted" event)) ; do nothing
 890                                        ((and (not response-string-parts)
 891                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 892                                         ; Try again with IPv4
 893                                         (message "Connection failed. Retrying with IPv4.")
 894                                         (elpher-get-host-response address default-port
 895                                                                   query-string
 896                                                                   response-processor
 897                                                                   use-tls t))
 898                                        (response-string-parts
 899                                         (elpher-with-clean-buffer
 900                                          (insert "Data received.  Rendering..."))
 901                                         (funcall response-processor
 902                                                  (apply #'concat (reverse response-string-parts)))
 903                                         (elpher-restore-pos))
 904                                        (t
 905                                         (error "No response from server")))
 906                                     (error
 907                                      (elpher-network-error address the-error)))))
 908           (when socks
 909             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 910             (funcall (process-sentinel proc) proc "open\n")))
 911       (error
 912        (elpher-process-cleanup)
 913        (error "Error initiating connection to server")))))
 914
 915
 916 ;;; Client-side TLS Certificate Management
 917 ;;
 918
 919 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 920   "Generate a key and a self-signed client TLS certificate using openssl.
 921
 922 The Common Name field of the certificate is set to COMMON-NAME.  The
 923 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 924 the key and certificate files to write.
 925
 926 If TEMPORARY is non-nil, the certificate will be given an exporation
 927 period of one day, and the key and certificate files will be deleted
 928 when the certificate is no longer needed for the current session.
 929
 930 Otherwise, the certificate will be given a 100 year expiration period
 931 and the files will not be deleted.
 932
 933 The function returns a list containing the current host name, the
 934 temporary flag, and the key and cert file names in the form required
 935 by `gnutls-boot-parameters`."
 936   (let ((exp-key-file (expand-file-name key-file))
 937         (exp-cert-file (expand-file-name cert-file)))
 938     (condition-case nil
 939         (progn
 940           (call-process elpher-openssl-command nil nil nil
 941                         "req" "-x509" "-newkey" "rsa:2048"
 942                         "-days" (if temporary "1" "36500")
 943                         "-nodes"
 944                         "-subj" (concat "/CN=" common-name)
 945                         "-keyout" exp-key-file
 946                         "-out" exp-cert-file)
 947           (list (elpher-address-host (elpher-page-address elpher-current-page))
 948                 temporary exp-key-file exp-cert-file))
 949       (error
 950        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 951        (error "Program 'openssl', required for certificate generation, not found")))))
 952
 953 (defun elpher-generate-throwaway-certificate ()
 954   "Generate and return details of a throwaway certificate.
 955 The key and certificate files will be deleted when they are no
 956 longer needed for this session."
 957   (let* ((file-base (make-temp-name "elpher"))
 958          (key-file (concat temporary-file-directory file-base ".key"))
 959          (cert-file (concat temporary-file-directory file-base ".crt")))
 960     (elpher-generate-certificate file-base key-file cert-file t)))
 961
 962 (defun elpher-generate-persistent-certificate (file-base common-name)
 963   "Generate and return details of a persistent certificate.
 964 The argument FILE-BASE is used as the base for the key and certificate
 965 files, while COMMON-NAME specifies the common name field of the
 966 certificate.
 967
 968 The key and certificate files are written to in `elpher-certificate-directory'."
 969   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 970          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 971     (elpher-generate-certificate common-name key-file cert-file)))
 972
 973 (defun elpher-get-existing-certificate (file-base)
 974   "Return a certificate object corresponding to an existing certificate.
 975 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 976 the directory `elpher-certificate-directory'."
 977   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 978          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 979     (list (elpher-address-host (elpher-page-address elpher-current-page))
 980           nil
 981           (expand-file-name key-file)
 982           (expand-file-name cert-file))))
 983
 984 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 985   "Install a key+certificate file pair in `elpher-certificate-directory'.
 986 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 987 certificate files to install.  The argument FILE-BASE is used as the
 988 base for the installed key and certificate files."
 989   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 990          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 991     (if (or (file-exists-p key-file)
 992             (file-exists-p cert-file))
 993         (error "A certificate with base name %s is already installed" file-base))
 994     (copy-file key-file-src key-file)
 995     (copy-file cert-file-src cert-file)
 996     (list (elpher-address-host (elpher-page-address elpher-current-page))
 997           nil
 998           (expand-file-name key-file)
 999           (expand-file-name cert-file))))
1000
1001 (defun elpher-list-existing-certificates ()
1002   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1003   (unless (file-directory-p elpher-certificate-directory)
1004     (make-directory elpher-certificate-directory))
1005   (mapcar
1006    (lambda (file)
1007      (file-name-sans-extension file))
1008    (directory-files elpher-certificate-directory nil "\\.key$")))
1009
1010 (defun elpher-forget-current-certificate ()
1011   "Causes any current certificate to be forgotten.)
1012 In the case of throwaway certificates, the key and certificate files
1013 are also deleted."
1014   (interactive)
1015   (when elpher-client-certificate
1016     (unless (and (called-interactively-p 'any)
1017                  (not (y-or-n-p (concat "Really forget client certificate? "
1018                                         "(Throwaway certificates will be deleted.)"))))
1019       (when (cadr elpher-client-certificate)
1020         (delete-file (elt elpher-client-certificate 2))
1021         (delete-file (elt elpher-client-certificate 3)))
1022       (setq elpher-client-certificate nil)
1023       (if (called-interactively-p 'any)
1024           (message "Client certificate forgotten.")))))
1025
1026 (defun elpher-get-current-keylist (address)
1027   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1028
1029 This is obtained from the client certificate described by
1030 `elpher-current-certificate', if one is available and the host for
1031 that certificate matches the host in ADDRESS.
1032
1033 If `elpher-current-certificate' is non-nil, and its host name doesn't
1034 match that of ADDRESS, the certificate is forgotten."
1035   (if elpher-client-certificate
1036       (if (string= (car elpher-client-certificate)
1037                    (elpher-address-host address))
1038           (list (cddr elpher-client-certificate))
1039         (elpher-forget-current-certificate)
1040         (message "Disabling client certificate for new host")
1041         nil)
1042     nil))
1043
1044
1045 ;;; Gopher selector retrieval
1046 ;;
1047
1048 (defun elpher-get-gopher-response (address renderer)
1049   "Get response string from gopher server at ADDRESS and render using RENDERER."
1050   (elpher-get-host-response address 70
1051                             (concat (elpher-gopher-address-selector address) "\r\n")
1052                             renderer
1053                             (or (string= (elpher-address-protocol address) "gophers")
1054                                 elpher-use-tls)))
1055
1056 (defun elpher-get-gopher-page (renderer)
1057   "Getter function for gopher pages.
1058 The RENDERER procedure is used to display the contents of the page
1059 once they are retrieved from the gopher server."
1060   (let* ((address (elpher-page-address elpher-current-page))
1061          (content (elpher-get-cached-content address)))
1062     (if (and content (funcall renderer nil))
1063         (elpher-with-clean-buffer
1064          (insert content)
1065          (elpher-restore-pos))
1066       (elpher-with-clean-buffer
1067        (insert "LOADING... (use 'u' to cancel)\n"))
1068       (condition-case the-error
1069           (elpher-get-gopher-response address renderer)
1070         (error
1071          (elpher-network-error address the-error))))))
1072
1073 ;; Index rendering
1074
1075 (defun elpher-insert-margin (&optional type-name)
1076   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1077   (if type-name
1078       (progn
1079         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1080                         (concat
1081                          (propertize "[" 'face 'elpher-margin-brackets)
1082                          (propertize type-name 'face 'elpher-margin-key)
1083                          (propertize "]" 'face 'elpher-margin-brackets))))
1084         (insert " "))
1085     (insert (make-string elpher-margin-width ?\s))))
1086
1087 (defun elpher--page-button-help (_window buffer pos)
1088   "Function called by Emacs to generate mouse-over text.
1089 The arguments specify the BUFFER and the POS within the buffer of the item
1090 for which help is required.  The function returns the help to be
1091 displayed.  The _WINDOW argument is currently unused."
1092   (with-current-buffer buffer
1093     (let ((button (button-at pos)))
1094       (when button
1095         (let* ((page (button-get button 'elpher-page))
1096                (address (elpher-page-address page)))
1097           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1098
1099 (defun elpher-insert-index-record (display-string &optional address)
1100   "Function to insert an index record into the current buffer.
1101 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1102 If ADDRESS is not supplied or nil the record is rendered as an
1103 'information' line."
1104   (let* ((type (if address (elpher-address-type address) nil))
1105          (type-map-entry (cdr (assoc type elpher-type-map))))
1106     (if type-map-entry
1107         (let* ((margin-code (elt type-map-entry 2))
1108                (face (elt type-map-entry 3))
1109                (filtered-display-string (elpher-color-filter-apply display-string))
1110                (page (elpher-make-page filtered-display-string address)))
1111           (elpher-insert-margin margin-code)
1112           (insert-text-button filtered-display-string
1113                               'face face
1114                               'elpher-page page
1115                               'action #'elpher-click-link
1116                               'follow-link t
1117                               'help-echo #'elpher--page-button-help))
1118       (pcase type
1119         ('nil ;; Information
1120          (elpher-insert-margin)
1121          (let ((propertized-display-string
1122                 (propertize display-string 'face 'elpher-info)))
1123            (insert (elpher-process-text-for-display propertized-display-string))))
1124         (`(gopher ,selector-type) ;; Unknown
1125          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1126          (insert (propertize display-string
1127                              'face 'elpher-unknown)))))
1128     (insert "\n")))
1129
1130 (defun elpher-click-link (button)
1131   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1132   (let ((page (button-get button 'elpher-page)))
1133     (elpher-visit-page page)))
1134
1135 (defun elpher-render-index (data &optional _mime-type-string)
1136   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1137   (elpher-with-clean-buffer
1138    (if (not data)
1139        t
1140      (let ((data-processed (elpher-preprocess-text-response data)))
1141        (dolist (line (split-string data-processed "\n"))
1142          (ignore-errors
1143            (unless (= (length line) 0)
1144              (let* ((type (elt line 0))
1145                     (fields (split-string (substring line 1) "\t"))
1146                     (display-string (elt fields 0))
1147                     (selector (elt fields 1))
1148                     (host (elt fields 2))
1149                     (port (if (elt fields 3)
1150                               (string-to-number (elt fields 3))
1151                             nil))
1152                     (address (elpher-make-gopher-address type selector host port)))
1153                (elpher-insert-index-record display-string address))))))
1154      (elpher-cache-content (elpher-page-address elpher-current-page)
1155                            (buffer-string)))))
1156
1157 ;; Text rendering
1158
1159 (defun elpher-render-text (data &optional _mime-type-string)
1160   "Render DATA as text.  MIME-TYPE-STRING is unused."
1161   (elpher-with-clean-buffer
1162    (if (not data)
1163        t
1164      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1165      (elpher-cache-content
1166       (elpher-page-address elpher-current-page)
1167       (buffer-string)))))
1168
1169 ;; Image retrieval
1170
1171 (defun elpher-render-image (data &optional _mime-type-string)
1172   "Display DATA as image.  MIME-TYPE-STRING is unused."
1173   (if (not data)
1174       nil
1175     (if (display-images-p)
1176         (let* ((image (create-image
1177                        data
1178                        nil t)))
1179           (if (not image)
1180               (error "Unsupported image format")
1181             (let ((window (get-buffer-window elpher-buffer-name)))
1182               (when window
1183                 (setf (image-property image :max-width) (window-body-width window t))
1184                 (setf (image-property image :max-height) (window-body-height window t))))
1185             (elpher-with-clean-buffer
1186              (insert-image image)
1187              (elpher-restore-pos))))
1188       (elpher-render-download data))))
1189
1190 ;; Search retrieval and rendering
1191
1192 (defun elpher-get-gopher-query-page (renderer)
1193   "Getter for gopher addresses requiring input.
1194 The response is rendered using the rendering function RENDERER."
1195   (let* ((address (elpher-page-address elpher-current-page))
1196          (content (elpher-get-cached-content address))
1197          (aborted t))
1198     (if (and content (funcall renderer nil))
1199         (elpher-with-clean-buffer
1200          (insert content)
1201          (elpher-restore-pos)
1202          (message "Displaying cached search results.  Reload to perform a new search."))
1203       (unwind-protect
1204           (let* ((query-string (read-string "Query: "))
1205                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1206                  (search-address (elpher-make-gopher-address ?1
1207                                                              query-selector
1208                                                              (elpher-address-host address)
1209                                                              (elpher-address-port address)
1210                                                              (equal (elpher-address-type address) "gophers"))))
1211             (setq aborted nil)
1212
1213             (elpher-with-clean-buffer
1214              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1215             (elpher-get-gopher-response search-address renderer))
1216         (if aborted
1217             (elpher-visit-previous-page))))))
1218
1219 ;; Raw server response rendering
1220
1221 (defun elpher-render-raw (data &optional mime-type-string)
1222   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1223   (if (not data)
1224       nil
1225     (elpher-with-clean-buffer
1226      (when mime-type-string
1227        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1228      (insert data)
1229      (goto-char (point-min)))
1230     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1231
1232 ;; File save "rendering"
1233
1234 (defun elpher-render-download (data &optional _mime-type-string)
1235   "Save DATA to file.  MIME-TYPE-STRING is unused."
1236   (if (not data)
1237       nil
1238     (let* ((address (elpher-page-address elpher-current-page))
1239            (selector (if (elpher-address-gopher-p address)
1240                          (elpher-gopher-address-selector address)
1241                        (elpher-address-filename address))))
1242       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1243       (let* ((filename-proposal (file-name-nondirectory selector))
1244              (filename (read-file-name "Download complete. Save file as: "
1245                                        nil nil nil
1246                                        (if (> (length filename-proposal) 0)
1247                                            filename-proposal
1248                                          "download.file"))))
1249         (let ((coding-system-for-write 'binary))
1250           (with-temp-file filename
1251             (insert data)))
1252         (message (format "Saved to file %s." filename))))))
1253
1254 ;; HTML rendering
1255
1256 (defun elpher-render-html (data &optional _mime-type-string)
1257   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1258   (elpher-with-clean-buffer
1259    (if (not data)
1260        t
1261      (let ((dom (with-temp-buffer
1262                   (insert data)
1263                   (libxml-parse-html-region (point-min) (point-max)))))
1264        (shr-insert-document dom)))))
1265
1266 ;; Gemini page retrieval
1267
1268 (defvar elpher-gemini-redirect-chain)
1269
1270 (defun elpher-get-gemini-response (address renderer)
1271   "Get response string from gemini server at ADDRESS and render using RENDERER."
1272   (elpher-get-host-response address 1965
1273                             (concat (elpher-address-to-url address) "\r\n")
1274                             (lambda (response-string)
1275                               (elpher-process-gemini-response response-string renderer))
1276                             'gemini))
1277
1278 (defun elpher-parse-gemini-response (response)
1279   "Parse the RESPONSE string and return a list of components.
1280 The list is of the form (code meta body).  A response of nil implies
1281 that the response was malformed."
1282   (let ((header-end-idx (string-match "\r\n" response)))
1283     (if header-end-idx
1284         (let ((header (string-trim (substring response 0 header-end-idx)))
1285               (body (substring response (+ header-end-idx 2))))
1286           (if (>= (length header) 2)
1287               (let ((code (substring header 0 2))
1288                     (meta (string-trim (substring header 2))))
1289                 (list code meta body))
1290             (error "Malformed response: No response status found in header %s" header)))
1291       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1292
1293 (defun elpher-process-gemini-response (response-string renderer)
1294   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1295   (let ((response-components (elpher-parse-gemini-response response-string)))
1296     (let ((response-code (elt response-components 0))
1297           (response-meta (elt response-components 1))
1298           (response-body (elt response-components 2)))
1299       (pcase (elt response-code 0)
1300         (?1 ; Input required
1301          (elpher-with-clean-buffer
1302           (insert "Gemini server is requesting input."))
1303          (let* ((query-string
1304                  (if (eq (elt response-code 1) ?1)
1305                      (read-passwd (concat response-meta ": "))
1306                    (read-string (concat response-meta ": "))))
1307                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1308                 (old-fname (url-filename query-address)))
1309            (setf (url-filename query-address)
1310                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1311            (elpher-get-gemini-response query-address renderer)))
1312         (?2 ; Normal response
1313          (funcall renderer response-body response-meta))
1314         (?3 ; Redirect
1315          (message "Following redirect to %s" response-meta)
1316          (if (>= (length elpher-gemini-redirect-chain) 5)
1317              (error "More than 5 consecutive redirects followed"))
1318          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1319            (if (member redirect-address elpher-gemini-redirect-chain)
1320                (error "Redirect loop detected"))
1321            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1322                (error "Server tried to automatically redirect to non-gemini URL: %s"
1323                       response-meta))
1324            (elpher-page-set-address elpher-current-page redirect-address)
1325            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1326            (elpher-get-gemini-response redirect-address renderer)))
1327         (?4 ; Temporary failure
1328          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1329                 response-code response-meta))
1330         (?5 ; Permanent failure
1331          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1332                 response-code response-meta))
1333         (?6 ; Client certificate required
1334          (elpher-with-clean-buffer
1335           (if elpher-client-certificate
1336               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1337             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1338           (auto-fill-mode 1)
1339           (elpher-gemini-insert-text response-meta))
1340          (let ((chosen-certificate (elpher-choose-client-certificate)))
1341            (unless chosen-certificate
1342              (error "Gemini server requires a client certificate and none was provided"))
1343            (setq elpher-client-certificate chosen-certificate))
1344          (elpher-with-clean-buffer)
1345          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1346         (_other
1347          (error "Gemini server response unknown: %s %s"
1348                 response-code response-meta))))))
1349
1350 (defun elpher--read-answer-polyfill (question answers)
1351   "Polyfill for `read-answer' in Emacs 26.1.
1352 QUESTION is a string containing a question, and ANSWERS
1353 is a list of possible answers."
1354     (completing-read question (mapcar 'identity answers)))
1355
1356 (if (fboundp 'read-answer)
1357     (defalias 'elpher-read-answer 'read-answer)
1358   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1359
1360 (defun elpher-choose-client-certificate ()
1361   "Prompt for a client certificate to use to establish a TLS connection."
1362   (let* ((read-answer-short t))
1363     (pcase (read-answer "What do you want to do? "
1364                         '(("throwaway" ?t
1365                            "generate and use throw-away certificate")
1366                           ("persistent" ?p
1367                            "generate new or use existing persistent certificate")
1368                           ("abort" ?a
1369                            "stop immediately")))
1370       ("throwaway"
1371        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1372       ("persistent"
1373        (let* ((existing-certificates (elpher-list-existing-certificates))
1374               (file-base (completing-read
1375                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1376                           existing-certificates)))
1377          (if (string-empty-p (string-trim file-base))
1378              nil
1379            (if (member file-base existing-certificates)
1380                (setq elpher-client-certificate
1381                      (elpher-get-existing-certificate file-base))
1382              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1383                                  '(("new" ?n
1384                                     "generate new certificate")
1385                                    ("install" ?i
1386                                     "install existing certificate")
1387                                    ("abort" ?a
1388                                     "stop immediately")))
1389                ("new"
1390                 (let ((common-name (read-string "Common Name field for new certificate: "
1391                                                 file-base)))
1392                   (message "New key and self-signed certificate written to %s"
1393                            elpher-certificate-directory)
1394                   (elpher-generate-persistent-certificate file-base common-name)))
1395                ("install"
1396                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1397                        (key-file (read-file-name "Key file: " nil nil t)))
1398                   (message "Key and certificate installed in %s for future use"
1399                            elpher-certificate-directory)
1400                   (elpher-install-and-use-existing-certificate key-file
1401                                                                cert-file
1402                                                                file-base)))
1403                ("abort" nil))))))
1404       ("abort" nil))))
1405
1406 (defun elpher-get-gemini-page (renderer)
1407   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1408   (let* ((address (elpher-page-address elpher-current-page))
1409          (content (elpher-get-cached-content address)))
1410     (condition-case the-error
1411         (if (and content (funcall renderer nil))
1412             (elpher-with-clean-buffer
1413              (insert content)
1414              (elpher-restore-pos))
1415           (elpher-with-clean-buffer
1416            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1417           (setq elpher-gemini-redirect-chain nil)
1418           (elpher-get-gemini-response address renderer))
1419       (error
1420        (elpher-network-error address the-error)))))
1421
1422 (defun elpher-render-gemini (body &optional mime-type-string)
1423   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1424   (if (not body)
1425       t
1426     (let* ((mime-type-string* (if (or (not mime-type-string)
1427                                       (string-empty-p mime-type-string))
1428                                   "text/gemini; charset=utf-8"
1429                                 mime-type-string))
1430            (mime-type-split (split-string mime-type-string* ";" t))
1431            (mime-type (string-trim (car mime-type-split)))
1432            (parameters (mapcar (lambda (s)
1433                                  (let ((key-val (split-string s "=")))
1434                                    (list (downcase (string-trim (car key-val)))
1435                                          (downcase (string-trim (cadr key-val))))))
1436                                (cdr mime-type-split))))
1437       (when (string-prefix-p "text/" mime-type)
1438         (setq body (decode-coding-string
1439                     body
1440                     (if (assoc "charset" parameters)
1441                         (intern (cadr (assoc "charset" parameters)))
1442                       'utf-8)))
1443         (setq body (replace-regexp-in-string "\r" "" body)))
1444       (pcase mime-type
1445         ((or "text/gemini" "")
1446          (elpher-render-gemini-map body parameters))
1447         ("text/html"
1448          (elpher-render-html body))
1449         ((pred (string-prefix-p "text/"))
1450          (elpher-render-gemini-plain-text body parameters))
1451         ((pred (string-prefix-p "image/"))
1452          (elpher-render-image body))
1453         (_other
1454          (elpher-render-download body))))))
1455
1456 (defun elpher-gemini-get-link-url (link-line)
1457   "Extract the url portion of LINK-LINE, a gemini map file link line.
1458 Returns nil in the event that the contents of the line following the
1459 => prefix are empty."
1460   (let ((l (split-string (substring link-line 2))))
1461     (if l
1462         (string-trim (elt l 0))
1463       nil)))
1464
1465 (defun elpher-gemini-get-link-display-string (link-line)
1466   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1467 Return nil if this portion is not provided."
1468   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1469          (idx (string-match "[ \t]" rest)))
1470     (and idx
1471          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1472
1473 (defun elpher-collapse-dot-sequences (filename)
1474   "Collapse dot sequences in the (absolute) FILENAME.
1475 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1476   (let* ((path (split-string filename "/" t))
1477          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1478          (path-reversed-normalized
1479           (seq-reduce (lambda (a b)
1480                         (cond ((equal b "..") (cdr a))
1481                               ((equal b ".") a)
1482                               (t (cons b a))))
1483                       path nil))
1484          (path-normalized (reverse path-reversed-normalized)))
1485     (if path-normalized
1486         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1487       "/")))
1488
1489 (defun elpher-address-from-gemini-url (url)
1490   "Extract address from URL with defaults as per gemini map files.
1491 While there's obviously some redundancy here between this function and
1492 `elpher-address-from-url', gemini map file URLs require enough special
1493 treatment that a separate function is warranted."
1494   (let ((address (url-generic-parse-url url))
1495         (current-address (elpher-page-address elpher-current-page)))
1496     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1497       (if (url-host address) ;if there is an explicit host, filenames are absolute
1498           (if (string-empty-p (url-filename address))
1499               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1500         (setf (url-host address) (url-host current-address))
1501         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1502         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1503         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1504           (setf (url-filename address)
1505                 (concat (file-name-directory (url-filename current-address))
1506                         (url-filename address)))))
1507       (when (url-host address)
1508         (setf (url-host address) (puny-encode-domain (url-host address))))
1509       (unless (url-type address)
1510         (setf (url-type address) (url-type current-address)))
1511       (when (equal (url-type address) "gemini")
1512         (setf (url-filename address)
1513               (elpher-collapse-dot-sequences (url-filename address)))))
1514     (elpher-remove-redundant-ports address)))
1515
1516 (defun elpher-gemini-insert-link (link-line)
1517   "Insert link described by LINK-LINE into a text/gemini document."
1518   (let ((url (elpher-gemini-get-link-url link-line)))
1519     (when url
1520       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1521              (address (elpher-address-from-gemini-url url))
1522              (type (if address (elpher-address-type address) nil))
1523              (type-map-entry (cdr (assoc type elpher-type-map)))
1524              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1525         (insert elpher-gemini-link-string)
1526         (if type-map-entry
1527             (let* ((face (elt type-map-entry 3))
1528                    (display-string (or given-display-string
1529                                        (elpher-address-to-iri address)))
1530                    (page (elpher-make-page display-string
1531                                            address)))
1532               (insert-text-button display-string
1533                                   'face face
1534                                   'elpher-page page
1535                                   'action #'elpher-click-link
1536                                   'follow-link t
1537                                   'help-echo #'elpher--page-button-help))
1538           (insert (propertize display-string 'face 'elpher-unknown)))
1539         (newline)))))
1540
1541 (defun elpher-gemini-insert-header (header-line)
1542   "Insert header described by HEADER-LINE into a text/gemini document.
1543 The gemini map file line describing the header is given
1544 by HEADER-LINE."
1545   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1546     (let* ((level (length (match-string 1 header-line)))
1547            (header (substring header-line (match-end 0)))
1548            (face (pcase level
1549                    (1 'elpher-gemini-heading1)
1550                    (2 'elpher-gemini-heading2)
1551                    (3 'elpher-gemini-heading3)
1552                    (_ 'default)))
1553            (fill-column (if (display-graphic-p)
1554                             (/ (* fill-column
1555                                   (font-get (font-spec :name (face-font 'default)) :size))
1556                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1557       (unless (display-graphic-p)
1558         (insert (make-string level ?#) " "))
1559       (insert (propertize header
1560                           'face face
1561                           'gemini-heading t
1562                           'rear-nonsticky t))
1563       (newline))))
1564
1565 (defun elpher-gemini-insert-text (text-line)
1566   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1567 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1568 width defined by `elpher-gemini-max-fill-width'."
1569   (string-match
1570    (rx (: line-start
1571           (* (any " \t"))
1572           (optional
1573            (group (or (: "*" (+ (any " \t")))
1574                       (: ">" (* (any " \t"))))))))
1575    text-line)
1576   (let* ((line-prefix (match-string 1 text-line))
1577          (processed-text-line
1578           (if line-prefix
1579               (cond ((string-prefix-p "*" line-prefix)
1580                      (concat
1581                       (replace-regexp-in-string "\\*"
1582                                                 elpher-gemini-bullet-string
1583                                                 (match-string 0 text-line))
1584                       (substring text-line (match-end 0))))
1585                     ((string-prefix-p ">" line-prefix)
1586                      (propertize text-line 'face 'elpher-gemini-quoted))
1587                     (t text-line))
1588             text-line))
1589          (adaptive-fill-mode t)
1590          ;; fill-prefix is important for adaptive-fill-mode: without
1591          ;; it, multi-line list items are not indented correct
1592          (fill-prefix (if (match-string 1 text-line)
1593                           (make-string (length (match-string 0 text-line)) ?\s)
1594                         nil)))
1595     (insert (elpher-process-text-for-display processed-text-line))
1596     (newline)))
1597
1598 (defun elpher-render-gemini-map (data _parameters)
1599   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1600   (elpher-with-clean-buffer
1601    (let ((preformatted nil))
1602      (auto-fill-mode 1)
1603      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1604      (dolist (line (split-string data "\n"))
1605        (cond
1606         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1607         (preformatted (insert (elpher-process-text-for-display
1608                                (propertize line 'face 'elpher-gemini-preformatted))
1609                               "\n"))
1610         ((string-prefix-p "=>" line)
1611          (elpher-gemini-insert-link line))
1612         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1613         (t (elpher-gemini-insert-text line)))))
1614    (elpher-cache-content
1615     (elpher-page-address elpher-current-page)
1616     (buffer-string))))
1617
1618 (defun elpher-render-gemini-plain-text (data _parameters)
1619   "Render DATA as plain text file.  PARAMETERS is currently unused."
1620   (elpher-with-clean-buffer
1621    (insert (elpher-process-text-for-display data))
1622    (elpher-cache-content
1623     (elpher-page-address elpher-current-page)
1624     (buffer-string))))
1625
1626 (defun elpher-build-current-imenu-index ()
1627   (save-excursion
1628     (goto-char (point-min))
1629     (let ((match nil)
1630           (headers nil))
1631       (while (setq match (text-property-search-forward 'gemini-heading t t))
1632         (push (cons
1633                (buffer-substring-no-properties (prop-match-beginning match)
1634                                                (prop-match-end match))
1635                (prop-match-beginning match))
1636               headers))
1637       (reverse headers))))
1638
1639 ;; Finger page connection
1640
1641 (defun elpher-get-finger-page (renderer)
1642   "Opens a finger connection to the current page address.
1643 The result is rendered using RENDERER."
1644   (let* ((address (elpher-page-address elpher-current-page))
1645          (content (elpher-get-cached-content address)))
1646     (if (and content (funcall renderer nil))
1647         (elpher-with-clean-buffer
1648          (insert content)
1649          (elpher-restore-pos))
1650       (elpher-with-clean-buffer
1651        (insert "LOADING... (use 'u' to cancel)\n"))
1652       (condition-case the-error
1653           (let* ((kill-buffer-query-functions nil)
1654                  (user (let ((filename (elpher-address-filename address)))
1655                          (if (> (length filename) 1)
1656                              (substring filename 1)
1657                            (elpher-address-user address)))))
1658             (elpher-get-host-response address 79
1659                                       (concat user "\r\n")
1660                                       renderer))
1661         (error
1662          (elpher-network-error address the-error))))))
1663
1664
1665 ;; Telnet page connection
1666
1667 (defun elpher-get-telnet-page (renderer)
1668   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1669   (when renderer
1670     (elpher-visit-previous-page)
1671     (error "Command not supported for telnet URLs"))
1672   (let* ((address (elpher-page-address elpher-current-page))
1673          (host (elpher-address-host address))
1674          (port (elpher-address-port address)))
1675     (elpher-visit-previous-page)
1676     (if (> port 0)
1677         (telnet host port)
1678       (telnet host))))
1679
1680
1681 ;; Other URL page opening
1682
1683 (defun elpher-get-other-url-page (renderer)
1684   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1685   (when renderer
1686     (elpher-visit-previous-page)
1687     (error "Command not supported for general URLs"))
1688   (let* ((address (elpher-page-address elpher-current-page))
1689          (url (elpher-address-to-url address)))
1690     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1691     (message "Opening URL...")
1692     (if elpher-open-urls-with-eww
1693         (browse-web url)
1694       (browse-url url))))
1695
1696 ;; File page
1697
1698 (defun elpher-get-file-page (renderer)
1699   "Getter which renders a local file using RENDERER.
1700 Assumes UTF-8 encoding for all text files."
1701   (let* ((address (elpher-page-address elpher-current-page))
1702          (filename (elpher-address-filename address)))
1703     (unless (file-exists-p filename)
1704       (elpher-visit-previous-page)
1705         (error "File not found"))
1706     (unless (file-readable-p filename)
1707       (elpher-visit-previous-page)
1708         (error "Could not read from file"))
1709     (let ((body (with-temp-buffer
1710        (let ((coding-system-for-read 'binary)
1711              (coding-system-for-write 'binary))
1712          (insert-file-contents-literally filename)
1713          (encode-coding-string (buffer-string) 'raw-text)))))
1714        (if renderer
1715            (funcall renderer body nil)
1716          (pcase (file-name-extension filename)
1717            ((or  "gmi" "gemini")
1718             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1719            ((or "htm" "html")
1720             (elpher-render-html (decode-coding-string body 'utf-8)))
1721            ((or "txt" "")
1722             (elpher-render-text (decode-coding-string body 'utf-8)))
1723            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1724             (elpher-render-image body))
1725            ((or "gopher" "gophermap")
1726             (elpher-render-index (elpher-decode body)))
1727            (_
1728             (elpher-render-download body))))
1729        (elpher-restore-pos))))
1730
1731
1732 ;; Welcome page retrieval
1733
1734 (defun elpher-get-welcome-page (renderer)
1735   "Getter which displays the welcome page (RENDERER must be nil)."
1736   (when renderer
1737     (elpher-visit-previous-page)
1738     (error "Command not supported for welcome page"))
1739   (elpher-with-clean-buffer
1740    (insert "     --------------------------------------------\n"
1741            "           Elpher Gopher and Gemini Client       \n"
1742            "                   version " elpher-version "\n"
1743            "     --------------------------------------------\n"
1744            "\n"
1745            "Default bindings:\n"
1746            "\n"
1747            " - TAB/Shift-TAB: next/prev item on current page\n"
1748            " - RET/mouse-1: open item under cursor\n"
1749            " - m: select an item on current page by name (autocompletes)\n"
1750            " - u/mouse-3/U: return to previous page or to the start page\n"
1751            " - g: go to a particular address (gopher, gemini, finger)\n"
1752            " - o/O: open a different address selector or the root menu of the current server\n"
1753            " - d/D: download item under cursor or current page\n"
1754            " - i/I: info on item under cursor or current page\n"
1755            " - c/C: copy URL representation of item under cursor or current page\n"
1756            " - a/A: bookmark the item under cursor or current page\n"
1757            " - B: list all bookmarks\n"
1758            " - s/S: show current history stack or all previously visted pages\n"
1759            " - r: redraw current page (using cached contents if available)\n"
1760            " - R: reload current page (regenerates cache)\n"
1761            " - !: set character coding system for gopher (default is to autodetect)\n"
1762            " - T: toggle TLS gopher mode\n"
1763            " - F: forget/discard current TLS client certificate\n"
1764            " - .: display the raw server response for the current page\n"
1765            "\n"
1766            "Start your exploration of gopher space and gemini:\n")
1767    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1768                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1769    (elpher-insert-index-record "Project Gemini home page"
1770                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1771    (insert "\n"
1772            "Alternatively, select a search engine and enter some search terms:\n")
1773    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1774                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1775    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1776                                (elpher-address-from-url "gemini://geminispace.info/search"))
1777    (insert "\n"
1778            "Your bookmarks are stored in your ")
1779    (insert-text-button "bookmark list"
1780                        'face 'link
1781                        'action #'elpher-click-link
1782                        'follow-link t
1783                        'help-echo #'elpher--page-button-help
1784                        'elpher-page
1785                        (elpher-make-page "Elpher Bookmarks"
1786                                          (elpher-make-about-address 'bookmarks)))
1787    (insert ".\n")
1788    (insert (propertize
1789             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1790             'face 'shadow))
1791    (insert "\n"
1792            "The gopher home of the Elpher project is here:\n")
1793    (elpher-insert-index-record "The Elpher Project Page"
1794                                (elpher-make-gopher-address ?1
1795                                                            "/projects/elpher/"
1796                                                            "thelambdalab.xyz"
1797                                                            70))
1798    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1799      (insert "\n"
1800              "The following info documentation is available:\n"
1801              "   - ")
1802      (insert-text-button "Elpher Manual"
1803                          'face 'link
1804                          'action (lambda (_)
1805                                    (interactive)
1806                                    (info "(elpher)"))
1807                          'follow-link t
1808                          'help-echo help-string)
1809      (insert "\n   - ")
1810      (insert-text-button "Changes introduced by the latest release"
1811                        'face 'link
1812                        'action (lambda (_)
1813                                  (interactive)
1814                                  (info "(elpher)News"))
1815                        'follow-link t
1816                        'help-echo help-string))
1817    (insert "\n")
1818    (insert (propertize
1819             (concat "(These documents should be available if you have installed Elpher \n"
1820                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1821             'face 'shadow))
1822    (elpher-restore-pos)))
1823
1824 ;; History page retrieval
1825
1826 (defun elpher-show-history ()
1827   "Show the current contents of elpher's history stack.
1828 Use \\[elpher-show-visited-pages] to see the entire history.
1829 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1830   (interactive)
1831   (elpher-visit-page
1832    (elpher-make-page "Current History Stack"
1833                      (elpher-make-about-address 'history))))
1834
1835 (defun elpher-show-visited-pages ()
1836   "Show the all the pages you've visited using Elpher.
1837 Use \\[elpher-show-history] to see just the current history stack.
1838 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1839   (interactive)
1840   (elpher-visit-page
1841    (elpher-make-page "Elpher Visted Pages"
1842                      (elpher-make-about-address 'visited-pages))))
1843
1844 (defun elpher-get-history-page (renderer)
1845   "Getter which displays the history page (RENDERER must be nil)."
1846   (when renderer
1847     (elpher-visit-previous-page)
1848     (error "Command not supported for history page"))
1849   (elpher-display-history-links elpher-history "Current history stack"))
1850
1851 (defun elpher-get-visited-pages-page (renderer)
1852   "Getter which displays the list of visited pages (RENDERER must be nil)."
1853   (when renderer
1854     (elpher-visit-previous-page)
1855     (error "Command not supported for history page"))
1856   (elpher-display-history-links
1857    (seq-filter (lambda (page)
1858                  (not (elpher-address-about-p (elpher-page-address page))))
1859                elpher-visited-pages)
1860    "All visited pages"))
1861
1862 (defun elpher-display-history-links (pages title)
1863   "Show all PAGES in an Elpher buffer with a given TITLE."
1864   (let* ((title-line (concat " ---- " title " ----"))
1865          (footer-line (make-string (length title-line) ?-)))
1866     (elpher-with-clean-buffer
1867      (insert title-line "\n\n")
1868      (if pages
1869          (dolist (page pages)
1870            (when page
1871              (let ((display-string (elpher-page-display-string page))
1872                    (address (elpher-page-address page)))
1873                (elpher-insert-index-record display-string address))))
1874        (insert "No history items found.\n"))
1875      (insert "\n " footer-line "\n"
1876              "Select an entry or press 'u' to return to the previous page.")
1877      (elpher-restore-pos))))
1878
1879
1880 ;;; Bookmarks
1881
1882 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1883 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1884 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1885 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1886
1887 (defvar elpher-bookmark-link nil
1888   "Prefer bookmarking a link or the current page.
1889 Bind this variable dynamically, or set it to t.
1890 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1891 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1892
1893 (defun elpher-bookmark-make-record ()
1894   "Return a bookmark record.
1895 If `elpher-bookmark-link' is non-nil and point is on a link button,
1896 return a bookmark record for that link.  Otherwise, return a bookmark
1897 record for the current elpher page."
1898   (let* ((button (and elpher-bookmark-link (button-at (point))))
1899          (page (if button
1900                    (button-get button 'elpher-page)
1901                  elpher-current-page)))
1902     (unless page
1903       (error "Cannot bookmark this link"))
1904     (let* ((address (elpher-page-address page))
1905            (url (elpher-address-to-url address))
1906            (display-string (elpher-page-display-string page))
1907            (pos (if button nil (point))))
1908       (if (elpher-address-about-p address)
1909           (error "Cannot bookmark %s" display-string)
1910         `(,display-string
1911           (defaults . (,display-string))
1912           (position . ,pos)
1913           (location . ,url)
1914           (handler . elpher-bookmark-jump))))))
1915
1916 ;;;###autoload
1917 (defun elpher-bookmark-jump (bookmark)
1918   "Handler used to open a bookmark using elpher.
1919 The argument BOOKMARK is a bookmark record passed to the function.
1920 This handler is responsible for loading the bookmark in some buffer,
1921 then making that buffer the current buffer.  It should not switch
1922 to the buffer."
1923   (let* ((url (cdr (assq 'location bookmark)))
1924          (cleaned-url (string-trim url))
1925          (page (elpher-page-from-url cleaned-url)))
1926     (elpher-with-clean-buffer
1927      (elpher-visit-page page))
1928     (set-buffer (get-buffer elpher-buffer-name))
1929     nil))
1930
1931 (defun elpher-bookmark-link ()
1932   "Bookmark the link at point.
1933 To bookmark the current page, use \\[elpher-bookmark-current]."
1934   (interactive)
1935   (let ((elpher-bookmark-link t))
1936     (bookmark-set-no-overwrite)))
1937
1938 (defun elpher-bookmark-current ()
1939   "Bookmark the current page.
1940 To bookmark the link at point use \\[elpher-bookmark-link]."
1941   (interactive)
1942   (call-interactively #'bookmark-set-no-overwrite))
1943
1944 (defun elpher-bookmark-import (file)
1945   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1946   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1947                               (file-readable-p elpher-bookmarks-file))
1948                          elpher-bookmarks-file
1949                        (read-file-name "Old Elpher bookmarks: "
1950                                        user-emacs-directory nil t
1951                                        "elpher-bookmarks"))))
1952   (dolist (bookmark (with-temp-buffer
1953                       (insert-file-contents file)
1954                       (read (current-buffer))))
1955     (let* ((display-string (car bookmark))
1956            (url (cadr bookmark))
1957            (record `(,display-string
1958                      (location . ,url)
1959                      (handler . elpher-bookmark-jump))))
1960       (bookmark-store display-string (cdr record) t)))
1961   (bookmark-save))
1962
1963 (defun elpher-get-bookmarks-page (renderer)
1964   "Getter which displays the bookmarks (RENDERER must be nil)."
1965   (when renderer
1966     (elpher-visit-previous-page)
1967     (error "Command not supported for bookmarks page"))
1968
1969   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1970                                      elpher-bookmarks-file)
1971                                 (locate-user-emacs-file "elpher-bookmarks"))))
1972     (when (and (file-readable-p old-bookmarks-file)
1973                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1974                                  old-bookmarks-file
1975                                  "\" found. Import now?")))
1976       (elpher-bookmark-import old-bookmarks-file)
1977       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1978
1979   (if (and elpher-use-emacs-bookmark-menu
1980            elpher-history)
1981       (progn
1982         (elpher-visit-previous-page)
1983         (call-interactively #'bookmark-bmenu-list))
1984     (elpher-with-clean-buffer
1985      (insert " ---- Elpher Bookmarks ---- \n\n")
1986      (bookmark-maybe-load-default-file)
1987      (dolist (bookmark (bookmark-maybe-sort-alist))
1988        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1989          (let* ((name (car bookmark))
1990                 (url (alist-get 'location (cdr bookmark)))
1991                 (address (elpher-address-from-url url)))
1992            (elpher-insert-index-record name address))))
1993      (when (<= (line-number-at-pos) 3)
1994        (insert "No bookmarked pages found.\n"))
1995      (insert "\n --------------------------\n\n"
1996              "Select an entry or press 'u' to return to the previous page.\n\n"
1997              "Bookmarks can be renamed or deleted via the ")
1998      (insert-text-button "Emacs bookmark menu"
1999                          'action (lambda (_)
2000                                    (interactive)
2001                                    (call-interactively #'bookmark-bmenu-list))
2002                          'follow-link t
2003                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2004      (insert (substitute-command-keys
2005               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2006      (elpher-restore-pos))))
2007
2008 (defun elpher-show-bookmarks ()
2009   "Interactive function to display the current list of elpher bookmarks."
2010   (interactive)
2011   (elpher-visit-page
2012    (elpher-make-page "Elpher Bookmarks"
2013                      (elpher-make-about-address 'bookmarks))))
2014
2015
2016 ;;; Integrations
2017 ;;
2018
2019 ;;; Org
2020
2021 (defun elpher-org-export-link (link description format protocol)
2022   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2023
2024 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2025 of gemini, gopher or finger."
2026   (let* ((url (if (equal protocol "elpher")
2027                   (string-remove-prefix "elpher:" link)
2028                 (format "%s:%s" protocol link)))
2029          (desc (or description url)))
2030     (pcase format
2031       (`gemini (format "=> %s %s" url desc))
2032       (`html (format "<a href=\"%s\">%s</a>" url desc))
2033       (`latex (format "\\href{%s}{%s}" url desc))
2034       (_ (if (not description)
2035              url
2036            (format "%s (%s)" desc url))))))
2037
2038 (defun elpher-org-store-link ()
2039   "Store link to an `elpher' page in Org."
2040   (when (eq major-mode 'elpher-mode)
2041     (let* ((url (elpher-info-current))
2042            (desc (car elpher-current-page))
2043            (protocol (cond
2044                       ((string-prefix-p "gemini:" url) "gemini")
2045                       ((string-prefix-p "gopher:" url) "gopher")
2046                       ((string-prefix-p "finger:" url) "finger")
2047                       (t "elpher"))))
2048       (when (equal "elpher" protocol)
2049         ;; Weird link. Or special inner link?
2050         (setq url (concat "elpher:" url)))
2051       (org-link-store-props :type protocol :link url :description desc)
2052       t)))
2053
2054 (defun elpher-org-follow-link (link protocol)
2055   "Visit a LINK for the given PROTOCOL.
2056
2057 PROTOCOL may be one of gemini, gopher or finger.  This method also
2058 supports the old protocol elpher, where the link is self-contained."
2059   (let ((url (if (equal protocol "elpher")
2060                  (string-remove-prefix "elpher:" link)
2061                (format "%s:%s" protocol link))))
2062     (elpher-go url)))
2063
2064 (defun elpher-org-mode-integration ()
2065   "Set up `elpher' integration for `org-mode'."
2066   (org-link-set-parameters
2067    "elpher"
2068    :store #'elpher-org-store-link
2069    :export (lambda (link description format _plist)
2070              (elpher-org-export-link link description format "elpher"))
2071    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2072   (org-link-set-parameters
2073    "gemini"
2074    :export (lambda (link description format _plist)
2075              (elpher-org-export-link link description format "gemini"))
2076    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2077   (org-link-set-parameters
2078    "gopher"
2079    :export (lambda (link description format _plist)
2080              (elpher-org-export-link link description format "gopher"))
2081    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2082   (org-link-set-parameters
2083    "finger"
2084    :export (lambda (link description format _plist)
2085              (elpher-org-export-link link description format "finger"))
2086    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2087
2088 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2089
2090 ;;; Browse URL
2091
2092 ;;;###autoload
2093 (defun elpher-browse-url-elpher (url &rest _args)
2094   "Browse URL using Elpher.  This function is used by `browse-url'."
2095   (interactive (browse-url-interactive-arg "Elpher URL: "))
2096   (elpher-go url))
2097
2098 ;; Use elpher to open gopher, finger and gemini links
2099 ;; For recent version of `browse-url' package
2100 (if (boundp 'browse-url-default-handlers)
2101     (add-to-list
2102      'browse-url-default-handlers
2103      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2104   ;; Patch `browse-url-browser-function' for older ones. The value of
2105   ;; that variable is `browse-url-default-browser' by default, so
2106   ;; that's the function that gets advised.
2107   (advice-add browse-url-browser-function :before-while
2108               (lambda (url &rest _args)
2109                 "Handle gemini, gopher, and finger schemes using Elpher."
2110                 (let ((scheme (downcase (car (split-string url ":" t)))))
2111                   (if (member scheme '("gemini" "gopher" "finger"))
2112                       ;; `elpher-go' always returns nil, which will stop the
2113                       ;; advice chain here in a before-while
2114                       (elpher-go url)
2115                     ;; chain must continue, then return t.
2116                     t)))))
2117
2118 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2119 (with-eval-after-load 'thingatpt
2120   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2121
2122 ;;; Mu4e:
2123
2124 ;; Make mu4e aware of the gemini world
2125 (setq mu4e~view-beginning-of-url-regexp
2126       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2127
2128 ;;; eww:
2129
2130 ;; Let elpher handle gemini, gopher links in eww buffer.
2131 (setq eww-use-browse-url
2132       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2133
2134
2135 ;;; Interactive procedures
2136 ;;
2137
2138 (defun elpher-next-link ()
2139   "Move point to the next link on the current page."
2140   (interactive)
2141   (forward-button 1))
2142
2143 (defun elpher-prev-link ()
2144   "Move point to the previous link on the current page."
2145   (interactive)
2146   (backward-button 1))
2147
2148 (defun elpher-follow-current-link ()
2149   "Open the link or url at point."
2150   (interactive)
2151   (push-button))
2152
2153 ;;;###autoload
2154 (defun elpher-go (host-or-url)
2155   "Go to a particular gopher site HOST-OR-URL.
2156 When run interactively HOST-OR-URL is read from the minibuffer."
2157   (interactive (list
2158                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2159   (let ((trimmed-host-or-url (string-trim host-or-url)))
2160     (unless (string-empty-p trimmed-host-or-url)
2161       (let ((page (elpher-page-from-url trimmed-host-or-url
2162                                         (elpher-get-default-url-scheme))))
2163         (switch-to-buffer elpher-buffer-name)
2164         (elpher-with-clean-buffer
2165          (elpher-visit-page page))
2166         nil)))) ; non-nil value is displayed by eshell
2167
2168 (defun elpher-go-current ()
2169   "Go to a particular site read from the minibuffer, initialized with the current URL."
2170   (interactive)
2171   (let* ((address (elpher-page-address elpher-current-page))
2172          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2173                            (elpher-address-to-url address))))
2174     (unless (string-empty-p (string-trim url))
2175       (elpher-visit-page (elpher-page-from-url url)))))
2176
2177 (defun elpher-redraw ()
2178   "Redraw current page."
2179   (interactive)
2180   (elpher-visit-page elpher-current-page))
2181
2182 (defun elpher-reload ()
2183   "Reload current page."
2184   (interactive)
2185   (elpher-reload-current-page))
2186
2187 (defun elpher-toggle-tls ()
2188   "Toggle TLS encryption mode for gopher."
2189   (interactive)
2190   (setq elpher-use-tls (not elpher-use-tls))
2191   (if elpher-use-tls
2192       (if (gnutls-available-p)
2193           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2194         (setq elpher-use-tls nil)
2195         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2196     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2197
2198 (defun elpher-view-raw ()
2199   "View raw server response for current page."
2200   (interactive)
2201   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2202       (error "This page was not generated by a server")
2203     (elpher-visit-page elpher-current-page
2204                        #'elpher-render-raw)))
2205
2206 (defun elpher-back ()
2207   "Go to previous site."
2208   (interactive)
2209   (elpher-visit-previous-page))
2210
2211 (defun elpher-back-to-start ()
2212   "Go all the way back to the start page."
2213   (interactive)
2214   (setq-local elpher-current-page nil)
2215   (setq-local elpher-history nil)
2216   (elpher-visit-page (elpher-make-start-page)))
2217
2218 (defun elpher-download ()
2219   "Download the link at point."
2220   (interactive)
2221   (let ((button (button-at (point))))
2222     (if button
2223         (let ((page (button-get button 'elpher-page)))
2224           (unless page
2225             (error "Not an elpher page"))
2226           (when (elpher-address-about-p (elpher-page-address page))
2227             (error "Cannot download %s" (elpher-page-display-string page)))
2228           (elpher-visit-page (button-get button 'elpher-page)
2229                              #'elpher-render-download))
2230       (error "No link selected"))))
2231
2232 (defun elpher-download-current ()
2233   "Download the current page."
2234   (interactive)
2235   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2236       (error "Cannot download %s"
2237              (elpher-page-display-string elpher-current-page))
2238     (elpher-visit-page (elpher-make-page
2239                         (elpher-page-display-string elpher-current-page)
2240                         (elpher-page-address elpher-current-page))
2241                        #'elpher-render-download
2242                        t)))
2243
2244 (defun elpher--build-link-map ()
2245   "Build alist mapping link names to destination pages in current buffer."
2246   (let ((link-map nil)
2247         (b (next-button (point-min) t)))
2248     (while b
2249       (push (cons (button-label b) b) link-map)
2250       (setq b (next-button (button-start b))))
2251     link-map))
2252
2253 (defun elpher-jump ()
2254   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2255   (interactive)
2256   (let* ((link-map (elpher--build-link-map)))
2257     (if link-map
2258         (let ((key (let ((completion-ignore-case t))
2259                      (completing-read "Directory item/link: "
2260                                       link-map nil t))))
2261           (if (and key (> (length key) 0))
2262               (let ((b (cdr (assoc key link-map))))
2263                 (goto-char (button-start b))
2264                 (button-activate b)))))))
2265
2266 (defun elpher-root-dir ()
2267   "Visit root of current server."
2268   (interactive)
2269   (let ((address (elpher-page-address elpher-current-page)))
2270     (if (not (elpher-address-about-p address))
2271         (if (or (member (url-filename address) '("/" ""))
2272                 (and (elpher-address-gopher-p address)
2273                      (= (length (elpher-gopher-address-selector address)) 0)))
2274             (error "Already at root directory of current server")
2275           (let ((address-copy (elpher-address-from-url
2276                                (elpher-address-to-url address))))
2277             (setf (url-filename address-copy) "")
2278             (elpher-go (elpher-address-to-url address-copy))))
2279       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2280
2281 (defun elpher-info-page (page)
2282   "Display URL of PAGE in minibuffer."
2283   (let ((address (elpher-page-address page)))
2284     (message "%s" (elpher-address-to-url address))))
2285
2286 (defun elpher-info-link ()
2287   "Display information on page corresponding to link at point."
2288   (interactive)
2289   (let ((button (button-at (point))))
2290     (unless button
2291       (error "No item selected"))
2292     (let ((page (button-get button 'elpher-page)))
2293       (unless page
2294         (error "Not an elpher page"))
2295       (elpher-info-page page))))
2296
2297 (defun elpher-info-current ()
2298   "Display information on current page."
2299   (interactive)
2300   (elpher-info-page elpher-current-page))
2301
2302 (defun elpher-copy-page-url (page)
2303   "Copy URL representation of address of PAGE to `kill-ring'."
2304   (let* ((address (elpher-page-address page))
2305          (url (elpher-address-to-url address)))
2306     (message "Copied \"%s\" to kill-ring/clipboard." url)
2307     (kill-new url)))
2308
2309 (defun elpher-copy-link-url ()
2310   "Copy URL of item at point to `kill-ring'."
2311   (interactive)
2312   (let ((button (button-at (point))))
2313     (unless button
2314       (error "No item selected"))
2315     (let ((page (button-get button 'elpher-page)))
2316       (unless page
2317         (error "Not an elpher page"))
2318       (elpher-copy-page-url page))))
2319
2320 (defun elpher-copy-current-url ()
2321   "Copy URL of current page to `kill-ring'."
2322   (interactive)
2323   (elpher-copy-page-url elpher-current-page))
2324
2325 (defun elpher-set-gopher-coding-system ()
2326   "Specify an explicit character coding system for gopher selectors."
2327   (interactive)
2328   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2329     (setq elpher-user-coding-system system)
2330     (if system
2331         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2332       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2333
2334
2335 ;;; Mode and keymap
2336 ;;
2337
2338 (defvar elpher-mode-map
2339   (let ((map (make-sparse-keymap)))
2340     (define-key map (kbd "TAB") 'elpher-next-link)
2341     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2342     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2343     (define-key map (kbd "u") 'elpher-back)
2344     (define-key map (kbd "-") 'elpher-back)
2345     (define-key map (kbd "^") 'elpher-back)
2346     (define-key map [mouse-3] 'elpher-back)
2347     (define-key map (kbd "U") 'elpher-back-to-start)
2348     (define-key map (kbd "g") 'elpher-go)
2349     (define-key map (kbd "o") 'elpher-go-current)
2350     (define-key map (kbd "O") 'elpher-root-dir)
2351     (define-key map (kbd "s") 'elpher-show-history)
2352     (define-key map (kbd "S") 'elpher-show-visited-pages)
2353     (define-key map (kbd "r") 'elpher-redraw)
2354     (define-key map (kbd "R") 'elpher-reload)
2355     (define-key map (kbd "T") 'elpher-toggle-tls)
2356     (define-key map (kbd ".") 'elpher-view-raw)
2357     (define-key map (kbd "d") 'elpher-download)
2358     (define-key map (kbd "D") 'elpher-download-current)
2359     (define-key map (kbd "m") 'elpher-jump)
2360     (define-key map (kbd "i") 'elpher-info-link)
2361     (define-key map (kbd "I") 'elpher-info-current)
2362     (define-key map (kbd "c") 'elpher-copy-link-url)
2363     (define-key map (kbd "C") 'elpher-copy-current-url)
2364     (define-key map (kbd "a") 'elpher-bookmark-link)
2365     (define-key map (kbd "A") 'elpher-bookmark-current)
2366     (define-key map (kbd "B") 'elpher-show-bookmarks)
2367     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2368     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2369     (when (fboundp 'evil-define-key*)
2370       (evil-define-key*
2371        'motion map
2372        (kbd "TAB") 'elpher-next-link
2373        (kbd "C-") 'elpher-follow-current-link
2374        (kbd "C-t") 'elpher-back
2375        (kbd "u") 'elpher-back
2376        (kbd "-") 'elpher-back
2377        (kbd "^") 'elpher-back
2378        [mouse-3] 'elpher-back
2379        (kbd "U") 'elpher-back-to-start
2380        (kbd "g") 'elpher-go
2381        (kbd "o") 'elpher-go-current
2382        (kbd "O") 'elpher-root-dir
2383        (kbd "s") 'elpher-show-history
2384        (kbd "S") 'elpher-show-visited-pages
2385        (kbd "r") 'elpher-redraw
2386        (kbd "R") 'elpher-reload
2387        (kbd "T") 'elpher-toggle-tls
2388        (kbd ".") 'elpher-view-raw
2389        (kbd "d") 'elpher-download
2390        (kbd "D") 'elpher-download-current
2391        (kbd "m") 'elpher-jump
2392        (kbd "i") 'elpher-info-link
2393        (kbd "I") 'elpher-info-current
2394        (kbd "c") 'elpher-copy-link-url
2395        (kbd "C") 'elpher-copy-current-url
2396        (kbd "a") 'elpher-bookmark-link
2397        (kbd "A") 'elpher-bookmark-current
2398        (kbd "B") 'elpher-show-bookmarks
2399        (kbd "!") 'elpher-set-gopher-coding-system
2400        (kbd "F") 'elpher-forget-current-certificate))
2401     map)
2402   "Keymap for gopher client.")
2403
2404 (define-derived-mode elpher-mode special-mode "elpher"
2405   "Major mode for elpher, an elisp gopher client.
2406
2407 This mode is automatically enabled by the interactive
2408 functions which initialize the client, namely
2409 `elpher', and `elpher-go'."
2410   (setq-local elpher-current-page nil)
2411   (setq-local elpher-history nil)
2412   (setq-local elpher-buffer-name (buffer-name))
2413   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2414   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index)
2415   (setq-local xterm-color-preserve-properties t))
2416
2417 (when (fboundp 'evil-set-initial-state)
2418   (evil-set-initial-state 'elpher-mode 'motion))
2419
2420
2421 ;;; Main start procedure
2422 ;;
2423
2424 ;;;###autoload
2425 (defun elpher (&optional arg)
2426   "Start elpher with default landing page.
2427 The buffer used for Elpher sessions is determined by the value of
2428 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2429 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2430 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2431 \\[execute-extended-command] elpher RET’) switches to the session with
2432 that number, creating it if necessary.  A non numeric prefix ARG means
2433 to create a new session.  Returns the buffer selected (or created)."
2434   (interactive "P")
2435   (let* ((name (default-value 'elpher-buffer-name))
2436          (buf (cond ((numberp arg)
2437                      (get-buffer-create (format "%s<%d>" name arg)))
2438                     (arg
2439                      (generate-new-buffer name))
2440                     (t
2441                      (get-buffer-create name)))))
2442     (pop-to-buffer-same-window buf)
2443     (unless (buffer-modified-p)
2444       (elpher-mode)
2445       (elpher-visit-page (elpher-make-start-page))
2446       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2447
2448 ;;; elpher.el ends here