elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.2.1
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.2.1"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((about history) elpher-get-history-page nil "E" elpher-index)
 116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen is \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 232
 233 Beware that using \"about:bookmarks\" as a start page in combination with
 234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 236 the start page."
 237   :type '(string))
 238
 239 ;; Face customizations
 240
 241 (defgroup elpher-faces nil
 242   "Elpher face customizations."
 243   :group 'elpher)
 244
 245 (defface elpher-index
 246   '((t :inherit font-lock-keyword-face))
 247   "Face used for directory type directory records.")
 248
 249 (defface elpher-text
 250   '((t :inherit bold))
 251   "Face used for text type directory records.")
 252
 253 (defface elpher-info
 254   '((t :inherit default))
 255   "Face used for info type directory records.")
 256
 257 (defface elpher-image
 258   '((t :inherit font-lock-string-face))
 259   "Face used for image type directory records.")
 260
 261 (defface elpher-search
 262   '((t :inherit warning))
 263   "Face used for search type directory records.")
 264
 265 (defface elpher-html
 266   '((t :inherit font-lock-comment-face))
 267   "Face used for html type directory records.")
 268
 269 (defface elpher-gemini
 270   '((t :inherit font-lock-constant-face))
 271   "Face used for Gemini type directory records.")
 272
 273 (defface elpher-other-url
 274   '((t :inherit font-lock-comment-face))
 275   "Face used for other URL type links records.")
 276
 277 (defface elpher-telnet
 278   '((t :inherit font-lock-function-name-face))
 279   "Face used for telnet type directory records.")
 280
 281 (defface elpher-binary
 282   '((t :inherit font-lock-doc-face))
 283   "Face used for binary type directory records.")
 284
 285 (defface elpher-unknown
 286   '((t :inherit error))
 287   "Face used for directory records with unknown/unsupported types.")
 288
 289 (defface elpher-margin-key
 290   '((t :inherit bold))
 291   "Face used for directory margin key.")
 292
 293 (defface elpher-margin-brackets
 294   '((t :inherit shadow))
 295   "Face used for brackets around directory margin key.")
 296
 297 (defface elpher-gemini-heading1
 298   '((t :inherit bold :height 1.8))
 299   "Face used for gemini heading level 1.")
 300
 301 (defface elpher-gemini-heading2
 302   '((t :inherit bold :height 1.5))
 303   "Face used for gemini heading level 2.")
 304
 305 (defface elpher-gemini-heading3
 306   '((t :inherit bold :height 1.2))
 307   "Face used for gemini heading level 3.")
 308
 309 (defface elpher-gemini-preformatted
 310   '((t :inherit fixed-pitch))
 311   "Face used for pre-formatted gemini text blocks.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 ;;; Model
 318 ;;
 319
 320 ;; Address
 321
 322 ;; An elpher "address" object is either a url object or a symbol.
 323 ;; Addresses with the "about" type, corresponding to pages generated
 324 ;; dynamically for and by elpher.  All others represent pages which
 325 ;; rely on content retrieved over the network.
 326
 327 (defun elpher-address-from-url (url-string)
 328   "Create a ADDRESS object corresponding to the given URL-STRING."
 329   (let ((data (match-data))) ; Prevent parsing clobbering match data
 330     (unwind-protect
 331         (let ((url (url-generic-parse-url url-string)))
 332           (unless (and (not (url-fullness url)) (url-type url))
 333             (setf (url-fullness url) t)
 334             (unless (url-type url)
 335               (setf (url-type url) elpher-default-url-type))
 336             (unless (url-host url)
 337               (let ((p (split-string (url-filename url) "/" nil nil)))
 338                 (setf (url-host url) (car p))
 339                 (setf (url-filename url)
 340                       (if (cdr p)
 341                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 342                         ""))))
 343             (when (or (equal "gopher" (url-type url))
 344                       (equal "gophers" (url-type url)))
 345               ;; Gopher defaults
 346               (when (or (equal (url-filename url) "")
 347                         (equal (url-filename url) "/"))
 348                 (setf (url-filename url) "/1")))
 349             (when (equal "gemini" (url-type url))
 350               ;; Gemini defaults
 351               (if (equal (url-filename url) "")
 352                   (setf (url-filename url) "/"))))
 353           (elpher-remove-redundant-ports url))
 354       (set-match-data data))))
 355
 356 (defun elpher-remove-redundant-ports (address)
 357   "Remove redundant port specifiers from ADDRESS.
 358 Here 'redundant' means that the specified port matches the default
 359 for that protocol, eg 70 for gopher."
 360   (if (and (not (elpher-address-about-p address))
 361            (eq (url-portspec address) ; (url-port) is too slow!
 362                (pcase (url-type address)
 363                  ("gemini" 1965)
 364                  ((or "gopher" "gophers") 70)
 365                  ("finger" 79)
 366                  (_ -1))))
 367       (setf (url-portspec address) nil))
 368   address)
 369
 370 (defun elpher-make-gopher-address (type selector host port &optional tls)
 371   "Create an ADDRESS object using gopher directory record attributes.
 372 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 373 If the optional attribute TLS is non-nil, the address will be marked as
 374 requiring gopher-over-TLS."
 375   (cond
 376    ((equal type ?i) nil)
 377    ((and (equal type ?h)
 378          (string-prefix-p "URL:" selector))
 379     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 380    ((equal type ?8)
 381     (elpher-address-from-url
 382      (concat "telnet"
 383              "://" host
 384              ":" (number-to-string port))))
 385    (t
 386     (elpher-address-from-url
 387      (concat "gopher" (if tls "s" "")
 388              "://" host
 389              ":" (number-to-string port)
 390              "/" (string type)
 391              selector)))))
 392
 393 (defun elpher-make-about-address (type)
 394   "Create an ADDRESS object corresponding to the given about address TYPE."
 395   (elpher-address-from-url (concat "about:" (symbol-name type))))
 396
 397 (defun elpher-address-to-url (address)
 398   "Get string representation of ADDRESS."
 399   (url-encode-url (url-recreate-url address)))
 400
 401 (defun elpher-address-type (address)
 402   "Retrieve type of ADDRESS object.
 403 This is used to determine how to retrieve and render the document the
 404 address refers to, via the table `elpher-type-map'."
 405   (pcase (url-type address)
 406     ("about"
 407      (list 'about (intern (url-filename address))))
 408     ((or "gopher" "gophers")
 409      (list 'gopher
 410            (if (member (url-filename address) '("" "/"))
 411                ?1
 412              (string-to-char (substring (url-filename address) 1)))))
 413     ("gemini" 'gemini)
 414     ("telnet" 'telnet)
 415     ("finger" 'finger)
 416     ("file" 'file)
 417     (_ 'other-url)))
 418
 419 (defun elpher-address-about-p (address)
 420   "Return non-nil if ADDRESS is an  about address."
 421   (pcase (elpher-address-type address) (`(about ,_) t)))
 422
 423 (defun elpher-address-gopher-p (address)
 424   "Return non-nill if ADDRESS object is a gopher address."
 425   (eq 'gopher (elpher-address-type address)))
 426
 427 (defun elpher-address-protocol (address)
 428   "Retrieve the transport protocol for ADDRESS."
 429   (url-type address))
 430
 431 (defun elpher-address-filename (address)
 432   "Retrieve the filename component of ADDRESS.
 433 For gopher addresses this is a combination of the selector type and selector."
 434   (url-unhex-string (url-filename address)))
 435
 436 (defun elpher-address-host (address)
 437   "Retrieve host from ADDRESS object."
 438   (url-host address))
 439
 440 (defun elpher-address-user (address)
 441   "Retrieve user from ADDRESS object."
 442   (url-user address))
 443
 444 (defun elpher-address-port (address)
 445   "Retrieve port from ADDRESS object.
 446 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 447   (url-port address))
 448
 449 (defun elpher-gopher-address-selector (address)
 450   "Retrieve gopher selector from ADDRESS object."
 451   (if (member (url-filename address) '("" "/"))
 452       ""
 453     (url-unhex-string (substring (url-filename address) 2))))
 454
 455
 456 ;; Cache
 457
 458 (defvar elpher-content-cache (make-hash-table :test 'equal))
 459 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 460
 461 (defun elpher-get-cached-content (address)
 462   "Retrieve the cached content for ADDRESS, or nil if none exists."
 463   (gethash address elpher-content-cache))
 464
 465 (defun elpher-cache-content (address content)
 466   "Set the content cache for ADDRESS to CONTENT."
 467   (puthash address content elpher-content-cache))
 468
 469 (defun elpher-get-cached-pos (address)
 470   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 471   (gethash address elpher-pos-cache))
 472
 473 (defun elpher-cache-pos (address pos)
 474   "Set the cursor position cache for ADDRESS to POS."
 475   (puthash address pos elpher-pos-cache))
 476
 477
 478 ;; Page
 479
 480 (defun elpher-make-page (display-string address)
 481   "Create a page with DISPLAY-STRING and ADDRESS."
 482   (list display-string address))
 483
 484 (defun elpher-make-start-page ()
 485   "Create the welcome page."
 486   (elpher-make-page "Start Page"
 487                     (elpher-address-from-url elpher-start-page)))
 488
 489 (defun elpher-page-display-string (page)
 490   "Retrieve the display string corresponding to PAGE."
 491   (elt page 0))
 492
 493 (defun elpher-page-address (page)
 494   "Retrieve the address corresponding to PAGE."
 495   (elt page 1))
 496
 497 (defun elpher-page-set-address (page new-address)
 498   "Set the address corresponding to PAGE to NEW-ADDRESS."
 499   (setcar (cdr page) new-address))
 500
 501 (defvar elpher-current-page nil
 502   "The current page for this Elpher buffer.")
 503
 504 (defvar elpher-history nil
 505   "The local history stack for this Elpher buffer.
 506 This variable is used by `elpher-back' and
 507 `elpher-show-history'.")
 508
 509 (defvar elpher-visited-pages nil
 510   "The global history for all Elpher buffers.
 511 This variable is used by `elpher-show-visited-pages'.")
 512
 513 (defun elpher-visit-page (page &optional renderer no-history)
 514   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 515 Additionally, push PAGE onto the history stack and the list of
 516 previously-visited pages,unless NO-HISTORY is non-nil."
 517   (elpher-save-pos)
 518   (elpher-process-cleanup)
 519   (unless no-history
 520     (unless (or (not elpher-current-page)
 521                  (equal (elpher-page-address elpher-current-page)
 522                         (elpher-page-address page)))
 523       (push elpher-current-page elpher-history)
 524       (unless (or (elpher-address-about-p (elpher-page-address page))
 525                   (and elpher-visited-pages
 526                        (equal page (car elpher-visited-pages))))
 527         (push page elpher-visited-pages))))
 528   (setq-local elpher-current-page page)
 529   (let* ((address (elpher-page-address page))
 530          (type (elpher-address-type address))
 531          (type-record (cdr (assoc type elpher-type-map))))
 532     (if type-record
 533         (funcall (car type-record)
 534                  (if renderer
 535                      renderer
 536                    (cadr type-record)))
 537       (elpher-visit-previous-page)
 538       (pcase type
 539         (`(gopher ,type-char)
 540          (error "Unsupported gopher selector type '%c' for '%s'"
 541                 type-char (elpher-address-to-url address)))
 542         (other
 543          (error "Unsupported address type '%S' for '%s'"
 544                 other (elpher-address-to-url address)))))))
 545
 546 (defun elpher-visit-previous-page ()
 547   "Visit the previous page in the history."
 548   (if elpher-history
 549       (elpher-visit-page (pop elpher-history) nil t)
 550     (error "No previous page")))
 551
 552 (defun elpher-reload-current-page ()
 553   "Reload the current page, discarding any existing cached content."
 554   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 555   (elpher-visit-page elpher-current-page))
 556
 557 (defun elpher-save-pos ()
 558   "Save the current position of point to the current page."
 559   (when elpher-current-page
 560     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 561
 562 (defun elpher-restore-pos ()
 563   "Restore the position of point to that cached in the current page."
 564   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 565     (if pos
 566         (goto-char pos)
 567       (goto-char (point-min)))))
 568
 569
 570 ;;; Buffer preparation
 571 ;;
 572
 573 (defvar elpher-buffer-name "*elpher*"
 574   "The default name of the Elpher buffer.")
 575
 576 (defun elpher-update-header ()
 577   "If `elpher-use-header' is true, display current page info in window header."
 578   (if elpher-use-header
 579       (let* ((display-string (elpher-page-display-string elpher-current-page))
 580              (address (elpher-page-address elpher-current-page))
 581              (tls-string (if (and (not (elpher-address-about-p address))
 582                                   (member (elpher-address-protocol address)
 583                                           '("gophers" "gemini")))
 584                              " [TLS encryption]"
 585                            ""))
 586              (header (concat display-string
 587                              (propertize tls-string 'face 'bold))))
 588         (setq header-line-format header))))
 589
 590 (defmacro elpher-with-clean-buffer (&rest args)
 591   "Evaluate ARGS with a clean *elpher* buffer as current."
 592   (declare (debug (body))) ;; Allow edebug to step through body
 593   `(with-current-buffer elpher-buffer-name
 594      (unless (eq major-mode 'elpher-mode)
 595        ;; avoid resetting buffer-local variables
 596        (elpher-mode))
 597      (let ((inhibit-read-only t)
 598            (ansi-color-context nil)) ;; clean ansi interpreter state
 599        (setq-local network-security-level
 600                    (default-value 'network-security-level))
 601        (erase-buffer)
 602        (elpher-update-header)
 603        ,@args)))
 604
 605 (defun elpher-buffer-message (string &optional line)
 606   "Replace first line in elpher buffer with STRING.
 607 If LINE is non-nil, replace that line instead."
 608   (with-current-buffer elpher-buffer-name
 609     (let ((inhibit-read-only t))
 610       (goto-char (point-min))
 611       (if line
 612           (forward-line line))
 613       (let ((data (match-data)))
 614         (unwind-protect
 615             (progn
 616               (re-search-forward "^.*$")
 617               (replace-match string))
 618           (set-match-data data))))))
 619
 620
 621 ;;; Text Processing
 622 ;;
 623
 624 (defvar elpher-user-coding-system nil
 625   "User-specified coding system to use for decoding text responses.")
 626
 627 (defun elpher-decode (string)
 628   "Decode STRING using autodetected or user-specified coding system."
 629   (decode-coding-string string
 630                         (if elpher-user-coding-system
 631                             elpher-user-coding-system
 632                           (detect-coding-string string t))))
 633
 634 (defun elpher-preprocess-text-response (string)
 635   "Preprocess text selector response contained in STRING.
 636 This involes decoding the character representation, and clearing
 637 away CRs and any terminating period."
 638   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 639                                            (replace-regexp-in-string "\r" "" string))))
 640
 641 ;;; Buttonify urls
 642
 643 (defconst elpher-url-regex
 644   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 645   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 646
 647 (defun elpher-buttonify-urls (string)
 648   "Turn substrings which look like urls in STRING into clickable buttons."
 649   (with-temp-buffer
 650     (insert string)
 651     (goto-char (point-min))
 652     (while (re-search-forward elpher-url-regex nil t)
 653       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 654                                     (elpher-address-from-url (match-string 0)))))
 655         (make-text-button (match-beginning 0)
 656                           (match-end 0)
 657                           'elpher-page  page
 658                           'action #'elpher-click-link
 659                           'follow-link t
 660                           'help-echo #'elpher--page-button-help
 661                           'face 'button)))
 662     (buffer-string)))
 663
 664 ;;; ANSI colors or XTerm colors (application and filtering)
 665
 666 (or (require 'xterm-color nil t)
 667     (require 'ansi-color))
 668
 669 (defalias 'elpher-color-filter-apply
 670   (if (fboundp 'xterm-color-filter)
 671       (lambda (s)
 672         (let ((_xterm-color-render nil))
 673           (xterm-color-filter s)))
 674     #'ansi-color-filter-apply)
 675   "A function to filter out ANSI escape sequences.")
 676
 677 (defalias 'elpher-color-apply
 678   (if (fboundp 'xterm-color-filter)
 679       #'xterm-color-filter
 680     #'ansi-color-apply)
 681   "A function to apply ANSI escape sequences.")
 682
 683 ;;; Processing text for display
 684
 685 (defun elpher-process-text-for-display (string)
 686   "Perform any desired processing of STRING prior to display as text.
 687 Currently includes buttonifying URLs and processing ANSI escape codes."
 688   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 689                              (elpher-color-filter-apply string)
 690                            (elpher-color-apply string))))
 691
 692
 693 ;;; Network error reporting
 694 ;;
 695
 696 (defun elpher-network-error (address error)
 697   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 698 ERROR can be either an error object or a string."
 699   (elpher-with-clean-buffer
 700    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 701            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 702            (if (stringp error) error (error-message-string error)) "\n"
 703            (propertize "\n----------------\n\n" 'face 'error)
 704            "Press 'u' to return to the previous page.")))
 705
 706
 707 ;;; General network communication
 708 ;;
 709
 710 (defvar elpher-network-timer nil
 711   "Timer used for network connections.")
 712
 713 (defvar elpher-use-tls nil
 714   "If non-nil, use TLS to communicate with gopher servers.")
 715
 716 (defvar elpher-client-certificate nil
 717   "If non-nil, contains client certificate details to use for TLS connections.")
 718
 719 (defun elpher-process-cleanup ()
 720   "Immediately shut down any extant elpher process and timers."
 721   (let ((p (get-process "elpher-process")))
 722     (if p (delete-process p)))
 723   (if (timerp elpher-network-timer)
 724       (cancel-timer elpher-network-timer)))
 725
 726 (defun elpher-make-network-timer (thunk)
 727   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 728 This is just a wraper around `run-at-time' which additionally sets the
 729 buffer-local variable `elpher-network-timer' to allow
 730 `elpher-process-cleanup' to also clear the timer."
 731   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 732     (setq-local elpher-network-timer timer)
 733     timer))
 734
 735 (defun elpher-get-host-response (address default-port query-string response-processor
 736                                          &optional use-tls force-ipv4)
 737   "Generic function for retrieving data from ADDRESS.
 738
 739 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 740 QUERY-STRING is a string sent to the host specified by ADDRESS to
 741 illicet a response.  This response is passed as an argument to the
 742 function RESPONSE-PROCESSOR.
 743
 744 If non-nil, USE-TLS specifies that the connection is to be made over
 745 TLS.  If set to gemini, the certificate verification will be disabled
 746 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 747
 748 If non-nil, FORCE-IPV4 causes the network connection to be made over
 749 ipv4 only.  (The default behaviour when this is not set depends on
 750 the host operating system and the local network capabilities.)"
 751   (if (and use-tls (not (gnutls-available-p)))
 752       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 753     (unless (< (elpher-address-port address) 65536)
 754       (error "Cannot establish network connection: port number > 65536"))
 755     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 756       (setq-local network-security-level 'low)
 757       (setq-local gnutls-verify-error nil))
 758     (condition-case nil
 759         (let* ((kill-buffer-query-functions nil)
 760                (port (elpher-address-port address))
 761                (host (elpher-address-host address))
 762                (service (if (> port 0) port default-port))
 763                (response-string-parts nil)
 764                (bytes-received 0)
 765                (hkbytes-received 0)
 766                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 767                (gnutls-params (list :type 'gnutls-x509pki
 768                                     :hostname host
 769                                     :keylist
 770                                     (elpher-get-current-keylist address)))
 771                (timer (elpher-make-network-timer
 772                                    (lambda ()
 773                                      (elpher-process-cleanup)
 774                                      (cond
 775                                         ; Try again with IPv4
 776                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 777                                        (message "Connection timed out.  Retrying with IPv4.")
 778                                        (elpher-get-host-response address default-port
 779                                                                  query-string
 780                                                                  response-processor
 781                                                                  use-tls t))
 782                                       ((and use-tls
 783                                             (not (eq use-tls 'gemini))
 784                                             (or elpher-auto-disengage-TLS
 785                                                 (y-or-n-p
 786                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 787                                        (setq elpher-use-tls nil)
 788                                        (elpher-get-host-response address default-port
 789                                                                  query-string
 790                                                                  response-processor
 791                                                                  nil force-ipv4))
 792                                       (t
 793                                        (elpher-network-error address "Connection time-out."))))))
 794                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 795                        (make-network-process :name "elpher-process"
 796                                              :host host
 797                                              :family (and (or force-ipv4
 798                                                               elpher-ipv4-always)
 799                                                           'ipv4)
 800                                              :service service
 801                                              :buffer nil
 802                                              :nowait t
 803                                              :tls-parameters
 804                                              (and use-tls
 805                                                   (cons 'gnutls-x509pki
 806                                                         (apply #'gnutls-boot-parameters
 807                                                                gnutls-params)))))))
 808           (setq elpher-network-timer timer)
 809           (set-process-coding-system proc 'binary 'binary)
 810           (set-process-query-on-exit-flag proc nil)
 811           (elpher-buffer-message (concat "Connecting to " host "..."
 812                                          " (press 'u' to abort)"))
 813           (set-process-filter proc
 814                               (lambda (_proc string)
 815                                 (when timer
 816                                   (cancel-timer timer)
 817                                   (setq timer nil))
 818                                 (setq bytes-received (+ bytes-received (length string)))
 819                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 820                                   (when (> new-hkbytes-received hkbytes-received)
 821                                     (setq hkbytes-received new-hkbytes-received)
 822                                     (elpher-buffer-message
 823                                      (concat "("
 824                                              (number-to-string (/ hkbytes-received 10.0))
 825                                              " MB read)")
 826                                      1)))
 827                                 (setq response-string-parts
 828                                       (cons string response-string-parts))))
 829           (set-process-sentinel proc
 830                                 (lambda (proc event)
 831                                   (when timer
 832                                     (cancel-timer timer))
 833                                   (condition-case the-error
 834                                       (cond
 835                                        ((string-prefix-p "open" event)    ; request URL
 836                                         (elpher-buffer-message
 837                                          (concat "Connected to " host ". Receiving data..."
 838                                                  " (press 'u' to abort)"))
 839                                         (let ((inhibit-eol-conversion t))
 840                                           (process-send-string proc query-string)))
 841                                        ((string-prefix-p "deleted" event)) ; do nothing
 842                                        ((and (not response-string-parts)
 843                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 844                                         ; Try again with IPv4
 845                                         (message "Connection failed. Retrying with IPv4.")
 846                                         (elpher-get-host-response address default-port
 847                                                                   query-string
 848                                                                   response-processor
 849                                                                   use-tls t))
 850                                        (response-string-parts
 851                                         (elpher-with-clean-buffer
 852                                          (insert "Data received.  Rendering..."))
 853                                         (funcall response-processor
 854                                                  (apply #'concat (reverse response-string-parts)))
 855                                         (elpher-restore-pos))
 856                                        (t
 857                                         (error "No response from server")))
 858                                     (error
 859                                      (elpher-network-error address the-error)))))
 860           (when socks
 861             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 862             (funcall (process-sentinel proc) proc "open\n")))
 863       (error
 864        (elpher-process-cleanup)
 865        (error "Error initiating connection to server")))))
 866
 867
 868 ;;; Client-side TLS Certificate Management
 869 ;;
 870
 871 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 872   "Generate a key and a self-signed client TLS certificate using openssl.
 873
 874 The Common Name field of the certificate is set to COMMON-NAME.  The
 875 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 876 the key and certificate files to write.
 877
 878 If TEMPORARY is non-nil, the certificate will be given an exporation
 879 period of one day, and the key and certificate files will be deleted
 880 when the certificate is no longer needed for the current session.
 881
 882 Otherwise, the certificate will be given a 100 year expiration period
 883 and the files will not be deleted.
 884
 885 The function returns a list containing the current host name, the
 886 temporary flag, and the key and cert file names in the form required
 887 by `gnutls-boot-parameters`."
 888   (let ((exp-key-file (expand-file-name key-file))
 889         (exp-cert-file (expand-file-name cert-file)))
 890     (condition-case nil
 891         (progn
 892           (call-process elpher-openssl-command nil nil nil
 893                         "req" "-x509" "-newkey" "rsa:2048"
 894                         "-days" (if temporary "1" "36500")
 895                         "-nodes"
 896                         "-subj" (concat "/CN=" common-name)
 897                         "-keyout" exp-key-file
 898                         "-out" exp-cert-file)
 899           (list (elpher-address-host (elpher-page-address elpher-current-page))
 900                 temporary exp-key-file exp-cert-file))
 901       (error
 902        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 903        (error "Program 'openssl', required for certificate generation, not found")))))
 904
 905 (defun elpher-generate-throwaway-certificate ()
 906   "Generate and return details of a throwaway certificate.
 907 The key and certificate files will be deleted when they are no
 908 longer needed for this session."
 909   (let* ((file-base (make-temp-name "elpher"))
 910          (key-file (concat temporary-file-directory file-base ".key"))
 911          (cert-file (concat temporary-file-directory file-base ".crt")))
 912     (elpher-generate-certificate file-base key-file cert-file t)))
 913
 914 (defun elpher-generate-persistent-certificate (file-base common-name)
 915   "Generate and return details of a persistent certificate.
 916 The argument FILE-BASE is used as the base for the key and certificate
 917 files, while COMMON-NAME specifies the common name field of the
 918 certificate.
 919
 920 The key and certificate files are written to in `elpher-certificate-directory'."
 921   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 922          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 923     (elpher-generate-certificate common-name key-file cert-file)))
 924
 925 (defun elpher-get-existing-certificate (file-base)
 926   "Return a certificate object corresponding to an existing certificate.
 927 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 928 the directory `elpher-certificate-directory'."
 929   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 930          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 931     (list (elpher-address-host (elpher-page-address elpher-current-page))
 932           nil
 933           (expand-file-name key-file)
 934           (expand-file-name cert-file))))
 935
 936 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 937   "Install a key+certificate file pair in `elpher-certificate-directory'.
 938 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 939 certificate files to install.  The argument FILE-BASE is used as the
 940 base for the installed key and certificate files."
 941   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 942          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 943     (if (or (file-exists-p key-file)
 944             (file-exists-p cert-file))
 945         (error "A certificate with base name %s is already installed" file-base))
 946     (copy-file key-file-src key-file)
 947     (copy-file cert-file-src cert-file)
 948     (list (elpher-address-host (elpher-page-address elpher-current-page))
 949           nil
 950           (expand-file-name key-file)
 951           (expand-file-name cert-file))))
 952
 953 (defun elpher-list-existing-certificates ()
 954   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 955   (unless (file-directory-p elpher-certificate-directory)
 956     (make-directory elpher-certificate-directory))
 957   (mapcar
 958    (lambda (file)
 959      (file-name-sans-extension file))
 960    (directory-files elpher-certificate-directory nil "\\.key$")))
 961
 962 (defun elpher-forget-current-certificate ()
 963   "Causes any current certificate to be forgotten.)
 964 In the case of throwaway certificates, the key and certificate files
 965 are also deleted."
 966   (interactive)
 967   (when elpher-client-certificate
 968     (unless (and (called-interactively-p 'any)
 969                  (not (y-or-n-p (concat "Really forget client certificate? "
 970                                         "(Throwaway certificates will be deleted.)"))))
 971       (when (cadr elpher-client-certificate)
 972         (delete-file (elt elpher-client-certificate 2))
 973         (delete-file (elt elpher-client-certificate 3)))
 974       (setq elpher-client-certificate nil)
 975       (if (called-interactively-p 'any)
 976           (message "Client certificate forgotten.")))))
 977
 978 (defun elpher-get-current-keylist (address)
 979   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 980
 981 This is obtained from the client certificate described by
 982 `elpher-current-certificate', if one is available and the host for
 983 that certificate matches the host in ADDRESS.
 984
 985 If `elpher-current-certificate' is non-nil, and its host name doesn't
 986 match that of ADDRESS, the certificate is forgotten."
 987   (if elpher-client-certificate
 988       (if (string= (car elpher-client-certificate)
 989                    (elpher-address-host address))
 990           (list (cddr elpher-client-certificate))
 991         (elpher-forget-current-certificate)
 992         (message "Disabling client certificate for new host")
 993         nil)
 994     nil))
 995
 996
 997 ;;; Gopher selector retrieval
 998 ;;
 999
1000 (defun elpher-get-gopher-response (address renderer)
1001   "Get response string from gopher server at ADDRESS and render using RENDERER."
1002   (elpher-get-host-response address 70
1003                             (concat (elpher-gopher-address-selector address) "\r\n")
1004                             renderer
1005                             (or (string= (elpher-address-protocol address) "gophers")
1006                                 elpher-use-tls)))
1007
1008 (defun elpher-get-gopher-page (renderer)
1009   "Getter function for gopher pages.
1010 The RENDERER procedure is used to display the contents of the page
1011 once they are retrieved from the gopher server."
1012   (let* ((address (elpher-page-address elpher-current-page))
1013          (content (elpher-get-cached-content address)))
1014     (if (and content (funcall renderer nil))
1015         (elpher-with-clean-buffer
1016          (insert content)
1017          (elpher-restore-pos))
1018       (elpher-with-clean-buffer
1019        (insert "LOADING... (use 'u' to cancel)\n"))
1020       (condition-case the-error
1021           (elpher-get-gopher-response address renderer)
1022         (error
1023          (elpher-network-error address the-error))))))
1024
1025 ;; Index rendering
1026
1027 (defun elpher-insert-margin (&optional type-name)
1028   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1029   (if type-name
1030       (progn
1031         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1032                         (concat
1033                          (propertize "[" 'face 'elpher-margin-brackets)
1034                          (propertize type-name 'face 'elpher-margin-key)
1035                          (propertize "]" 'face 'elpher-margin-brackets))))
1036         (insert " "))
1037     (insert (make-string elpher-margin-width ?\s))))
1038
1039 (defun elpher--page-button-help (_window buffer pos)
1040   "Function called by Emacs to generate mouse-over text.
1041 The arguments specify the BUFFER and the POS within the buffer of the item
1042 for which help is required.  The function returns the help to be
1043 displayed.  The _WINDOW argument is currently unused."
1044   (with-current-buffer buffer
1045     (let ((button (button-at pos)))
1046       (when button
1047         (let* ((page (button-get button 'elpher-page))
1048                (address (elpher-page-address page)))
1049           (format "mouse-1, RET: open '%s'" (if (elpher-address-about-p address)
1050                                                 address
1051                                               (elpher-address-to-url address))))))))
1052
1053 (defun elpher-insert-index-record (display-string &optional address)
1054   "Function to insert an index record into the current buffer.
1055 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1056 If ADDRESS is not supplied or nil the record is rendered as an
1057 'information' line."
1058   (let* ((type (if address (elpher-address-type address) nil))
1059          (type-map-entry (cdr (assoc type elpher-type-map))))
1060     (if type-map-entry
1061         (let* ((margin-code (elt type-map-entry 2))
1062                (face (elt type-map-entry 3))
1063                (filtered-display-string (elpher-color-filter-apply display-string))
1064                (page (elpher-make-page filtered-display-string address)))
1065           (elpher-insert-margin margin-code)
1066           (insert-text-button filtered-display-string
1067                               'face face
1068                               'elpher-page page
1069                               'action #'elpher-click-link
1070                               'follow-link t
1071                               'help-echo #'elpher--page-button-help))
1072       (pcase type
1073         ('nil ;; Information
1074          (elpher-insert-margin)
1075          (let ((propertized-display-string
1076                 (propertize display-string 'face 'elpher-info)))
1077            (insert (elpher-process-text-for-display propertized-display-string))))
1078         (`(gopher ,selector-type) ;; Unknown
1079          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1080          (insert (propertize display-string
1081                              'face 'elpher-unknown)))))
1082     (insert "\n")))
1083
1084 (defun elpher-click-link (button)
1085   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1086   (let ((page (button-get button 'elpher-page)))
1087     (elpher-visit-page page)))
1088
1089 (defun elpher-render-index (data &optional _mime-type-string)
1090   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1091   (elpher-with-clean-buffer
1092    (if (not data)
1093        t
1094      (let ((data-processed (elpher-preprocess-text-response data)))
1095        (dolist (line (split-string data-processed "\n"))
1096          (ignore-errors
1097            (unless (= (length line) 0)
1098              (let* ((type (elt line 0))
1099                     (fields (split-string (substring line 1) "\t"))
1100                     (display-string (elt fields 0))
1101                     (selector (elt fields 1))
1102                     (host (elt fields 2))
1103                     (port (if (elt fields 3)
1104                               (string-to-number (elt fields 3))
1105                             nil))
1106                     (address (elpher-make-gopher-address type selector host port)))
1107                (elpher-insert-index-record display-string address))))))
1108      (elpher-cache-content (elpher-page-address elpher-current-page)
1109                            (buffer-string)))))
1110
1111 ;; Text rendering
1112
1113 (defun elpher-render-text (data &optional _mime-type-string)
1114   "Render DATA as text.  MIME-TYPE-STRING is unused."
1115   (elpher-with-clean-buffer
1116    (if (not data)
1117        t
1118      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1119      (elpher-cache-content
1120       (elpher-page-address elpher-current-page)
1121       (buffer-string)))))
1122
1123 ;; Image retrieval
1124
1125 (defun elpher-render-image (data &optional _mime-type-string)
1126   "Display DATA as image.  MIME-TYPE-STRING is unused."
1127   (if (not data)
1128       nil
1129     (if (display-images-p)
1130         (let* ((image (create-image
1131                        data
1132                        nil t))
1133                (window (get-buffer-window elpher-buffer-name)))
1134           (when window
1135             (setf (image-property image :max-width) (window-pixel-width window))
1136             (setf (image-property image :max-height) (window-pixel-height window)))
1137           (elpher-with-clean-buffer
1138            (insert-image image)
1139            (elpher-restore-pos)))
1140       (elpher-render-download data))))
1141
1142 ;; Search retrieval and rendering
1143
1144 (defun elpher-get-gopher-query-page (renderer)
1145   "Getter for gopher addresses requiring input.
1146 The response is rendered using the rendering function RENDERER."
1147   (let* ((address (elpher-page-address elpher-current-page))
1148          (content (elpher-get-cached-content address))
1149          (aborted t))
1150     (if (and content (funcall renderer nil))
1151         (elpher-with-clean-buffer
1152          (insert content)
1153          (elpher-restore-pos)
1154          (message "Displaying cached search results.  Reload to perform a new search."))
1155       (unwind-protect
1156           (let* ((query-string (read-string "Query: "))
1157                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1158                  (search-address (elpher-make-gopher-address ?1
1159                                                              query-selector
1160                                                              (elpher-address-host address)
1161                                                              (elpher-address-port address)
1162                                                              (equal (elpher-address-type address) "gophers"))))
1163             (setq aborted nil)
1164
1165             (elpher-with-clean-buffer
1166              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1167             (elpher-get-gopher-response search-address renderer))
1168         (if aborted
1169             (elpher-visit-previous-page))))))
1170
1171 ;; Raw server response rendering
1172
1173 (defun elpher-render-raw (data &optional mime-type-string)
1174   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1175   (if (not data)
1176       nil
1177     (elpher-with-clean-buffer
1178      (when mime-type-string
1179        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1180      (insert data)
1181      (goto-char (point-min)))
1182     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1183
1184 ;; File save "rendering"
1185
1186 (defun elpher-render-download (data &optional _mime-type-string)
1187   "Save DATA to file.  MIME-TYPE-STRING is unused."
1188   (if (not data)
1189       nil
1190     (let* ((address (elpher-page-address elpher-current-page))
1191            (selector (if (elpher-address-gopher-p address)
1192                          (elpher-gopher-address-selector address)
1193                        (elpher-address-filename address))))
1194       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1195       (let* ((filename-proposal (file-name-nondirectory selector))
1196              (filename (read-file-name "Download complete. Save file as: "
1197                                        nil nil nil
1198                                        (if (> (length filename-proposal) 0)
1199                                            filename-proposal
1200                                          "download.file"))))
1201         (let ((coding-system-for-write 'binary))
1202           (with-temp-file filename
1203             (insert data)))
1204         (message (format "Saved to file %s." filename))))))
1205
1206 ;; HTML rendering
1207
1208 (defun elpher-render-html (data &optional _mime-type-string)
1209   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1210   (elpher-with-clean-buffer
1211    (if (not data)
1212        t
1213      (let ((dom (with-temp-buffer
1214                   (insert data)
1215                   (libxml-parse-html-region (point-min) (point-max)))))
1216        (shr-insert-document dom)))))
1217
1218 ;; Gemini page retrieval
1219
1220 (defvar elpher-gemini-redirect-chain)
1221
1222 (defun elpher-get-gemini-response (address renderer)
1223   "Get response string from gemini server at ADDRESS and render using RENDERER."
1224   (elpher-get-host-response address 1965
1225                             (concat (elpher-address-to-url address) "\r\n")
1226                             (lambda (response-string)
1227                               (elpher-process-gemini-response response-string renderer))
1228                             'gemini))
1229
1230 (defun elpher-parse-gemini-response (response)
1231   "Parse the RESPONSE string and return a list of components.
1232 The list is of the form (code meta body).  A response of nil implies
1233 that the response was malformed."
1234   (let ((header-end-idx (string-match "\r\n" response)))
1235     (if header-end-idx
1236         (let ((header (string-trim (substring response 0 header-end-idx)))
1237               (body (substring response (+ header-end-idx 2))))
1238           (if (>= (length header) 2)
1239               (let ((code (substring header 0 2))
1240                     (meta (string-trim (substring header 2))))
1241                 (list code meta body))
1242             (error "Malformed response: No response status found in header %s" header)))
1243       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1244
1245 (defun elpher-process-gemini-response (response-string renderer)
1246   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1247   (let ((response-components (elpher-parse-gemini-response response-string)))
1248     (let ((response-code (elt response-components 0))
1249           (response-meta (elt response-components 1))
1250           (response-body (elt response-components 2)))
1251       (pcase (elt response-code 0)
1252         (?1 ; Input required
1253          (elpher-with-clean-buffer
1254           (insert "Gemini server is requesting input."))
1255          (let* ((query-string
1256                  (if (eq (elt response-code 1) ?1)
1257                      (read-passwd (concat response-meta ": "))
1258                    (read-string (concat response-meta ": "))))
1259                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1260                 (old-fname (url-filename query-address)))
1261            (setf (url-filename query-address)
1262                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1263            (elpher-get-gemini-response query-address renderer)))
1264         (?2 ; Normal response
1265          (funcall renderer response-body response-meta))
1266         (?3 ; Redirect
1267          (message "Following redirect to %s" response-meta)
1268          (if (>= (length elpher-gemini-redirect-chain) 5)
1269              (error "More than 5 consecutive redirects followed"))
1270          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1271            (if (member redirect-address elpher-gemini-redirect-chain)
1272                (error "Redirect loop detected"))
1273            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1274                (error "Server tried to automatically redirect to non-gemini URL: %s"
1275                       response-meta))
1276            (elpher-page-set-address elpher-current-page redirect-address)
1277            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1278            (elpher-get-gemini-response redirect-address renderer)))
1279         (?4 ; Temporary failure
1280          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1281                 response-code response-meta))
1282         (?5 ; Permanent failure
1283          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1284                 response-code response-meta))
1285         (?6 ; Client certificate required
1286          (elpher-with-clean-buffer
1287           (if elpher-client-certificate
1288               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1289             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1290           (auto-fill-mode 1)
1291           (elpher-gemini-insert-text response-meta))
1292          (let ((chosen-certificate (elpher-choose-client-certificate)))
1293            (unless chosen-certificate
1294              (error "Gemini server requires a client certificate and none was provided"))
1295            (setq elpher-client-certificate chosen-certificate))
1296          (elpher-with-clean-buffer)
1297          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1298         (_other
1299          (error "Gemini server response unknown: %s %s"
1300                 response-code response-meta))))))
1301
1302 (defun elpher--read-answer-polyfill (question answers)
1303   "Polyfill for `read-answer' in Emacs 26.1.
1304 QUESTION is a string containing a question, and ANSWERS
1305 is a list of possible answers."
1306     (completing-read question (mapcar 'identity answers)))
1307
1308 (if (fboundp 'read-answer)
1309     (defalias 'elpher-read-answer 'read-answer)
1310   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1311
1312 (defun elpher-choose-client-certificate ()
1313   "Prompt for a client certificate to use to establish a TLS connection."
1314   (let* ((read-answer-short t))
1315     (pcase (read-answer "What do you want to do? "
1316                         '(("throwaway" ?t
1317                            "generate and use throw-away certificate")
1318                           ("persistent" ?p
1319                            "generate new or use existing persistent certificate")
1320                           ("abort" ?a
1321                            "stop immediately")))
1322       ("throwaway"
1323        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1324       ("persistent"
1325        (let* ((existing-certificates (elpher-list-existing-certificates))
1326               (file-base (completing-read
1327                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1328                           existing-certificates)))
1329          (if (string-empty-p (string-trim file-base))
1330              nil
1331            (if (member file-base existing-certificates)
1332                (setq elpher-client-certificate
1333                      (elpher-get-existing-certificate file-base))
1334              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1335                                  '(("new" ?n
1336                                     "generate new certificate")
1337                                    ("install" ?i
1338                                     "install existing certificate")
1339                                    ("abort" ?a
1340                                     "stop immediately")))
1341                ("new"
1342                 (let ((common-name (read-string "Common Name field for new certificate: "
1343                                                 file-base)))
1344                   (message "New key and self-signed certificate written to %s"
1345                            elpher-certificate-directory)
1346                   (elpher-generate-persistent-certificate file-base common-name)))
1347                ("install"
1348                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1349                        (key-file (read-file-name "Key file: " nil nil t)))
1350                   (message "Key and certificate installed in %s for future use"
1351                            elpher-certificate-directory)
1352                   (elpher-install-and-use-existing-certificate key-file
1353                                                                cert-file
1354                                                                file-base)))
1355                ("abort" nil))))))
1356       ("abort" nil))))
1357
1358 (defun elpher-get-gemini-page (renderer)
1359   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1360   (let* ((address (elpher-page-address elpher-current-page))
1361          (content (elpher-get-cached-content address)))
1362     (condition-case the-error
1363         (if (and content (funcall renderer nil))
1364             (elpher-with-clean-buffer
1365              (insert content)
1366              (elpher-restore-pos))
1367           (elpher-with-clean-buffer
1368            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1369           (setq elpher-gemini-redirect-chain nil)
1370           (elpher-get-gemini-response address renderer))
1371       (error
1372        (elpher-network-error address the-error)))))
1373
1374 (defun elpher-render-gemini (body &optional mime-type-string)
1375   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1376   (if (not body)
1377       t
1378     (let* ((mime-type-string* (if (or (not mime-type-string)
1379                                       (string-empty-p mime-type-string))
1380                                   "text/gemini; charset=utf-8"
1381                                 mime-type-string))
1382            (mime-type-split (split-string mime-type-string* ";" t))
1383            (mime-type (string-trim (car mime-type-split)))
1384            (parameters (mapcar (lambda (s)
1385                                  (let ((key-val (split-string s "=")))
1386                                    (list (downcase (string-trim (car key-val)))
1387                                          (downcase (string-trim (cadr key-val))))))
1388                                (cdr mime-type-split))))
1389       (when (string-prefix-p "text/" mime-type)
1390         (setq body (decode-coding-string
1391                     body
1392                     (if (assoc "charset" parameters)
1393                         (intern (cadr (assoc "charset" parameters)))
1394                       'utf-8)))
1395         (setq body (replace-regexp-in-string "\r" "" body)))
1396       (pcase mime-type
1397         ((or "text/gemini" "")
1398          (elpher-render-gemini-map body parameters))
1399         ("text/html"
1400          (elpher-render-html body))
1401         ((pred (string-prefix-p "text/"))
1402          (elpher-render-gemini-plain-text body parameters))
1403         ((pred (string-prefix-p "image/"))
1404          (elpher-render-image body))
1405         (_other
1406          (elpher-render-download body))))))
1407
1408 (defun elpher-gemini-get-link-url (link-line)
1409   "Extract the url portion of LINK-LINE, a gemini map file link line.
1410 Returns nil in the event that the contents of the line following the
1411 => prefix are empty."
1412   (let ((l (split-string (substring link-line 2))))
1413     (if l
1414         (string-trim (elt l 0))
1415       nil)))
1416
1417 (defun elpher-gemini-get-link-display-string (link-line)
1418   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1419 Returns the url portion in the event that the display-string portion is empty."
1420   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1421          (idx (string-match "[ \t]" rest)))
1422     (string-trim (if idx
1423                      (substring rest (+ idx 1))
1424                    rest))))
1425
1426 (defun elpher-collapse-dot-sequences (filename)
1427   "Collapse dot sequences in FILENAME.
1428 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1429   (let* ((path (split-string filename "/"))
1430          (path-reversed-normalized
1431           (seq-reduce (lambda (a b)
1432                         (cond ((and a (equal b "..") (cdr a)))
1433                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1434                               ((equal b ".") a)
1435                               (t (cons b a))))
1436                       path nil)))
1437     (string-join (reverse path-reversed-normalized) "/")))
1438
1439 (defun elpher-address-from-gemini-url (url)
1440   "Extract address from URL with defaults as per gemini map files.
1441 While there's obviously some redundancy here between this function and
1442 `elpher-address-from-url', gemini map file URLs require enough special
1443 treatment that a separate function is warranted."
1444   (let ((address (url-generic-parse-url url))
1445         (current-address (elpher-page-address elpher-current-page)))
1446     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1447       (setf (url-fullness address) t)
1448       (if (url-host address) ;if there is an explicit host, filenames are absolute
1449           (if (string-empty-p (url-filename address))
1450               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1451         (setf (url-host address) (url-host current-address))
1452         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1453         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1454           (setf (url-filename address)
1455                 (concat (file-name-directory (url-filename current-address))
1456                         (url-filename address)))))
1457       (unless (url-type address)
1458         (setf (url-type address) (url-type current-address)))
1459       (when (equal (url-type address) "gemini")
1460         (setf (url-filename address)
1461               (elpher-collapse-dot-sequences (url-filename address)))))
1462     (elpher-remove-redundant-ports address)))
1463
1464 (defun elpher-gemini-insert-link (link-line)
1465   "Insert link described by LINK-LINE into a text/gemini document."
1466   (let* ((url (elpher-gemini-get-link-url link-line))
1467          (display-string (elpher-gemini-get-link-display-string link-line))
1468          (address (elpher-address-from-gemini-url url))
1469          (type (if address (elpher-address-type address) nil))
1470          (type-map-entry (cdr (assoc type elpher-type-map))))
1471     (when display-string
1472       (insert elpher-gemini-link-string)
1473       (if type-map-entry
1474           (let* ((face (elt type-map-entry 3))
1475                  (filtered-display-string (elpher-color-filter-apply display-string))
1476                  (page (elpher-make-page filtered-display-string address)))
1477             (insert-text-button filtered-display-string
1478                                 'face face
1479                                 'elpher-page page
1480                                 'action #'elpher-click-link
1481                                 'follow-link t
1482                                 'help-echo #'elpher--page-button-help))
1483         (insert (propertize display-string 'face 'elpher-unknown)))
1484       (insert "\n"))))
1485
1486 (defvar elpher--gemini-page-headings nil
1487   "List of headings on the page.")
1488
1489 (defun elpher-gemini-insert-header (header-line)
1490   "Insert header described by HEADER-LINE into a text/gemini document.
1491 The gemini map file line describing the header is given
1492 by HEADER-LINE."
1493   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1494     (let* ((level (length (match-string 1 header-line)))
1495            (header (substring header-line (match-end 0)))
1496            (face (pcase level
1497                    (1 'elpher-gemini-heading1)
1498                    (2 'elpher-gemini-heading2)
1499                    (3 'elpher-gemini-heading3)
1500                    (_ 'default)))
1501            (fill-column (if (display-graphic-p)
1502                             (/ (* fill-column
1503                                   (font-get (font-spec :name (face-font 'default)) :size))
1504                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1505       (setq elpher--gemini-page-headings (cons (cons header (point))
1506                                                elpher--gemini-page-headings))
1507       (unless (display-graphic-p)
1508         (insert (make-string level ?#) " "))
1509       (insert (propertize header 'face face))
1510       (newline))))
1511
1512 (defun elpher-gemini-insert-text (text-line)
1513   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1514 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1515 width defined by `elpher-gemini-max-fill-width'."
1516   (if (string-empty-p text-line)
1517       (insert "\n")
1518     (string-match
1519      (rx (: line-start
1520             (* (any " \t"))
1521             (optional
1522              (group (or (: "*" (+ (any " \t")))
1523                         (: ">" (* (any " \t"))))))))
1524      text-line)
1525     (let* ((line-prefix (match-string 1 text-line))
1526            (processed-text-line
1527             (if line-prefix
1528                 (cond ((string-prefix-p "*" line-prefix)
1529                        (concat
1530                         (replace-regexp-in-string "\\*"
1531                                                   elpher-gemini-bullet-string
1532                                                   (match-string 0 text-line))
1533                         (substring text-line (match-end 0))))
1534                       ((string-prefix-p ">" line-prefix)
1535                        (propertize text-line 'face 'elpher-gemini-quoted))
1536                       (t text-line))
1537               text-line))
1538            (adaptive-fill-mode t)
1539            ;; fill-prefix is important for adaptive-fill-mode: without
1540            ;; it, multi-line list items are not indented correct
1541            (fill-prefix (if (match-string 1 text-line)
1542                             (make-string (length (match-string 0 text-line)) ?\s)
1543                           nil)))
1544       (insert (elpher-process-text-for-display processed-text-line))
1545       (newline))))
1546
1547 (defun elpher-render-gemini-map (data _parameters)
1548   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1549   (elpher-with-clean-buffer
1550    (setq elpher--gemini-page-headings nil)
1551    (let ((preformatted nil))
1552      (auto-fill-mode 1)
1553      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1554      (dolist (line (split-string data "\n"))
1555        (cond
1556         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1557         (preformatted (insert (elpher-process-text-for-display
1558                                (propertize line 'face 'elpher-gemini-preformatted))
1559                               "\n"))
1560         ((string-prefix-p "=>" line)
1561          (elpher-gemini-insert-link line))
1562         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1563         (t (elpher-gemini-insert-text line)))))
1564    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1565    (elpher-cache-content
1566     (elpher-page-address elpher-current-page)
1567     (buffer-string))))
1568
1569 (defun elpher-render-gemini-plain-text (data _parameters)
1570   "Render DATA as plain text file.  PARAMETERS is currently unused."
1571   (elpher-with-clean-buffer
1572    (insert (elpher-process-text-for-display data))
1573    (elpher-cache-content
1574     (elpher-page-address elpher-current-page)
1575     (buffer-string))))
1576
1577
1578 ;; Finger page connection
1579
1580 (defun elpher-get-finger-page (renderer)
1581   "Opens a finger connection to the current page address.
1582 The result is rendered using RENDERER."
1583   (let* ((address (elpher-page-address elpher-current-page))
1584          (content (elpher-get-cached-content address)))
1585     (if (and content (funcall renderer nil))
1586         (elpher-with-clean-buffer
1587          (insert content)
1588          (elpher-restore-pos))
1589       (elpher-with-clean-buffer
1590        (insert "LOADING... (use 'u' to cancel)\n"))
1591       (condition-case the-error
1592           (let* ((kill-buffer-query-functions nil)
1593                  (user (let ((filename (elpher-address-filename address)))
1594                          (if (> (length filename) 1)
1595                              (substring filename 1)
1596                            (elpher-address-user address)))))
1597             (elpher-get-host-response address 79
1598                                       (concat user "\r\n")
1599                                       renderer))
1600         (error
1601          (elpher-network-error address the-error))))))
1602
1603
1604 ;; Telnet page connection
1605
1606 (defun elpher-get-telnet-page (renderer)
1607   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1608   (when renderer
1609     (elpher-visit-previous-page)
1610     (error "Command not supported for telnet URLs"))
1611   (let* ((address (elpher-page-address elpher-current-page))
1612          (host (elpher-address-host address))
1613          (port (elpher-address-port address)))
1614     (elpher-visit-previous-page)
1615     (if (> port 0)
1616         (telnet host port)
1617       (telnet host))))
1618
1619
1620 ;; Other URL page opening
1621
1622 (defun elpher-get-other-url-page (renderer)
1623   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1624   (when renderer
1625     (elpher-visit-previous-page)
1626     (error "Command not supported for general URLs"))
1627   (let* ((address (elpher-page-address elpher-current-page))
1628          (url (elpher-address-to-url address)))
1629     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1630     (message "Opening URL...")
1631     (if elpher-open-urls-with-eww
1632         (browse-web url)
1633       (browse-url url))))
1634
1635 ;; File page
1636
1637 (defun elpher-get-file-page (renderer)
1638   "Getter which renders a local file using RENDERER.
1639 Assumes UTF-8 encoding for all text files."
1640   (let* ((address (elpher-page-address elpher-current-page))
1641          (filename (elpher-address-filename address)))
1642     (unless (file-exists-p filename)
1643       (elpher-visit-previous-page)
1644         (error "File not found"))
1645     (unless (file-readable-p filename)
1646       (elpher-visit-previous-page)
1647         (error "Could not read from file"))
1648     (let ((body (with-temp-buffer
1649        (let ((coding-system-for-read 'binary)
1650              (coding-system-for-write 'binary))
1651          (insert-file-contents-literally filename)
1652          (encode-coding-string (buffer-string) 'raw-text)))))
1653        (if renderer
1654            (funcall renderer body nil)
1655          (pcase (file-name-extension filename)
1656            ((or  "gmi" "gemini")
1657             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1658            ((or "htm" "html")
1659             (elpher-render-html (decode-coding-string body 'utf-8)))
1660            ((or "txt" "")
1661             (elpher-render-text (decode-coding-string body 'utf-8)))
1662            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1663             (elpher-render-image body))
1664            (_
1665             (elpher-render-download body))))
1666        (elpher-restore-pos))))
1667
1668
1669 ;; Welcome page retrieval
1670
1671 (defun elpher-get-welcome-page (renderer)
1672   "Getter which displays the welcome page (RENDERER must be nil)."
1673   (when renderer
1674     (elpher-visit-previous-page)
1675     (error "Command not supported for welcome page"))
1676   (elpher-with-clean-buffer
1677    (insert "     --------------------------------------------\n"
1678            "           Elpher Gopher and Gemini Client       \n"
1679            "                   version " elpher-version "\n"
1680            "     --------------------------------------------\n"
1681            "\n"
1682            "Default bindings:\n"
1683            "\n"
1684            " - TAB/Shift-TAB: next/prev item on current page\n"
1685            " - RET/mouse-1: open item under cursor\n"
1686            " - m: select an item on current page by name (autocompletes)\n"
1687            " - u/mouse-3/U: return to previous page or to the start page\n"
1688            " - g: go to a particular address (gopher, gemini, finger)\n"
1689            " - o/O: open a different address selector or the root menu of the current server\n"
1690            " - d/D: download item under cursor or current page\n"
1691            " - i/I: info on item under cursor or current page\n"
1692            " - c/C: copy URL representation of item under cursor or current page\n"
1693            " - a/A: bookmark the item under cursor or current page\n"
1694            " - B: list all bookmarks\n"
1695            " - s/S: show current history stack or all previously visted pages\n"
1696            " - r: redraw current page (using cached contents if available)\n"
1697            " - R: reload current page (regenerates cache)\n"
1698            " - !: set character coding system for gopher (default is to autodetect)\n"
1699            " - T: toggle TLS gopher mode\n"
1700            " - F: forget/discard current TLS client certificate\n"
1701            " - .: display the raw server response for the current page\n"
1702            "\n"
1703            "Start your exploration of gopher space and gemini:\n")
1704    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1705                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1706    (elpher-insert-index-record "Project Gemini home page"
1707                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1708    (insert "\n"
1709            "Alternatively, select a search engine and enter some search terms:\n")
1710    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1711                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1712    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1713                                (elpher-address-from-url "gemini://geminispace.info/search"))
1714    (insert "\n"
1715            "Your bookmarks are stored in your ")
1716    (let ((help-string "RET,mouse-1: Open bookmark list"))
1717      (insert-text-button "bookmark list"
1718                          'face 'link
1719                          'action (lambda (_)
1720                                    (interactive)
1721                                    (call-interactively #'elpher-show-bookmarks))
1722                          'follow-link t
1723                          'help-echo help-string))
1724    (insert ".\n")
1725    (insert (propertize
1726             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1727             'face 'shadow))
1728    (insert "\n"
1729            "The gopher home of the Elpher project is here:\n")
1730    (elpher-insert-index-record "The Elpher Project Page"
1731                                (elpher-make-gopher-address ?1
1732                                                            "/projects/elpher/"
1733                                                            "thelambdalab.xyz"
1734                                                            70))
1735    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1736      (insert "\n"
1737              "The following info documentation is available:\n"
1738              "   - ")
1739      (insert-text-button "Elpher Manual"
1740                          'face 'link
1741                          'action (lambda (_)
1742                                    (interactive)
1743                                    (info "(elpher)"))
1744                          'follow-link t
1745                          'help-echo help-string)
1746      (insert "\n   - ")
1747      (insert-text-button "Changes introduced by the latest release"
1748                        'face 'link
1749                        'action (lambda (_)
1750                                  (interactive)
1751                                  (info "(elpher)News"))
1752                        'follow-link t
1753                        'help-echo help-string))
1754    (insert "\n")
1755    (insert (propertize
1756             (concat "(These documents should be available if you have installed Elpher \n"
1757                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1758             'face 'shadow))
1759    (elpher-restore-pos)))
1760
1761 ;; History page retrieval
1762
1763 (defun elpher-show-history ()
1764   "Show the current contents of elpher's history stack.
1765 Use \\[elpher-show-visited-pages] to see the entire history.
1766 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1767   (interactive)
1768   (elpher-visit-page
1769    (elpher-make-page "Current History Stack"
1770                      (elpher-make-about-address 'history))))
1771
1772 (defun elpher-show-visited-pages ()
1773   "Show the all the pages you've visited using Elpher.
1774 Use \\[elpher-show-history] to see just the current history stack.
1775 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1776   (interactive)
1777   (elpher-visit-page
1778    (elpher-make-page "Elpher Visted Pages"
1779                      (elpher-make-about-address 'visited-pages))))
1780
1781 (defun elpher-get-history-page (renderer)
1782   "Getter which displays the history page (RENDERER must be nil)."
1783   (when renderer
1784     (elpher-visit-previous-page)
1785     (error "Command not supported for history page"))
1786   (elpher-display-history-links elpher-history "Current history stack"))
1787
1788 (defun elpher-get-visited-pages-page (renderer)
1789   "Getter which displays the list of visited pages (RENDERER must be nil)."
1790   (when renderer
1791     (elpher-visit-previous-page)
1792     (error "Command not supported for history page"))
1793   (elpher-display-history-links
1794    (seq-filter (lambda (page)
1795                  (not (elpher-address-about-p (elpher-page-address page))))
1796                elpher-visited-pages)
1797    "All visited pages"))
1798
1799 (defun elpher-display-history-links (pages title)
1800   "Show all PAGES in an Elpher buffer with a given TITLE."
1801   (let* ((title-line (concat " ---- " title " ----"))
1802          (footer-line (make-string (length title-line) ?-)))
1803     (elpher-with-clean-buffer
1804      (insert title-line "\n\n")
1805      (if pages
1806          (dolist (page pages)
1807            (when page
1808              (let ((display-string (elpher-page-display-string page))
1809                    (address (elpher-page-address page)))
1810                (elpher-insert-index-record display-string address))))
1811        (insert "No history items found.\n"))
1812      (insert "\n " footer-line "\n"
1813              "Select an entry or press 'u' to return to the previous page.")
1814      (elpher-restore-pos))))
1815
1816
1817 ;;; Bookmarks
1818
1819 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1820 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1821 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1822 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1823
1824 (defvar elpher-bookmark-link nil
1825   "Prefer bookmarking a link or the current page.
1826 Bind this variable dynamically, or set it to t.
1827 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1828 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1829
1830 (defun elpher-bookmark-make-record ()
1831   "Return a bookmark record.
1832 If `elpher-bookmark-link' is non-nil and point is on a link button,
1833 return a bookmark record for that link.  Otherwise, return a bookmark
1834 record for the current elpher page."
1835   (let* ((button (and elpher-bookmark-link (button-at (point))))
1836          (page (if button
1837                    (button-get button 'elpher-page)
1838                  elpher-current-page)))
1839     (unless page
1840       (error "Cannot bookmark this link"))
1841     (let* ((address (elpher-page-address page))
1842            (url (elpher-address-to-url address))
1843            (display-string (elpher-page-display-string page))
1844            (pos (if button nil (point))))
1845       (if (elpher-address-about-p address)
1846           (error "Cannot bookmark %s" display-string)
1847         `(,display-string
1848           (defaults . (,display-string))
1849           (position . ,pos)
1850           (location . ,url)
1851           (handler . elpher-bookmark-jump))))))
1852
1853 ;;;###autoload
1854 (defun elpher-bookmark-jump (bookmark)
1855   "Handler used to open a bookmark using elpher.
1856 The argument BOOKMARK is a bookmark record passed to the function.
1857 This handler is responsible for loading the bookmark in some buffer,
1858 then making that buffer the current buffer.  It should not switch
1859 to the buffer."
1860   (let* ((url (cdr (assq 'location bookmark)))
1861          (cleaned-url (string-trim url))
1862          (address (elpher-address-from-url cleaned-url))
1863          (page (elpher-make-page cleaned-url address)))
1864     (elpher-with-clean-buffer
1865      (elpher-visit-page page))
1866     (set-buffer (get-buffer elpher-buffer-name))
1867     nil))
1868
1869 (defun elpher-bookmark-link ()
1870   "Bookmark the link at point.
1871 To bookmark the current page, use \\[elpher-bookmark-current]."
1872   (interactive)
1873   (let ((elpher-bookmark-link t))
1874     (bookmark-set-no-overwrite)))
1875
1876 (defun elpher-bookmark-current ()
1877   "Bookmark the current page.
1878 To bookmark the link at point use \\[elpher-bookmark-link]."
1879   (interactive)
1880   (call-interactively #'bookmark-set-no-overwrite))
1881
1882 (defun elpher-bookmark-import (file)
1883   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1884   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1885                               (file-readable-p elpher-bookmarks-file))
1886                          elpher-bookmarks-file
1887                        (read-file-name "Old Elpher bookmarks: "
1888                                        user-emacs-directory nil t
1889                                        "elpher-bookmarks"))))
1890   (dolist (bookmark (with-temp-buffer
1891                       (insert-file-contents file)
1892                       (read (current-buffer))))
1893     (let* ((display-string (car bookmark))
1894            (url (cadr bookmark))
1895            (record `(,display-string
1896                      (location . ,url)
1897                      (handler . elpher-bookmark-jump))))
1898       (bookmark-store display-string (cdr record) t)))
1899   (bookmark-save))
1900
1901 (defun elpher-get-bookmarks-page (renderer)
1902   "Getter which displays the bookmarks (RENDERER must be nil)."
1903   (when renderer
1904     (elpher-visit-previous-page)
1905     (error "Command not supported for bookmarks page"))
1906
1907   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1908                                      elpher-bookmarks-file)
1909                                 (locate-user-emacs-file "elpher-bookmarks"))))
1910     (when (and (file-readable-p old-bookmarks-file)
1911                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1912                                  old-bookmarks-file
1913                                  "\" found. Import now?")))
1914       (elpher-bookmark-import old-bookmarks-file)
1915       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1916
1917   (if (and elpher-use-emacs-bookmark-menu
1918            elpher-history)
1919       (progn
1920         (elpher-visit-previous-page)
1921         (call-interactively #'bookmark-bmenu-list))
1922     (elpher-with-clean-buffer
1923      (insert " ---- Elpher Bookmarks ---- \n\n")
1924      (bookmark-maybe-load-default-file)
1925      (dolist (bookmark (bookmark-maybe-sort-alist))
1926        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1927          (let* ((name (car bookmark))
1928                 (url (alist-get 'location (cdr bookmark)))
1929                 (address (elpher-address-from-url url)))
1930            (elpher-insert-index-record name address))))
1931      (when (<= (line-number-at-pos) 3)
1932        (insert "No bookmarked pages found.\n"))
1933      (insert "\n --------------------------\n\n"
1934              "Select an entry or press 'u' to return to the previous page.\n\n"
1935              "Bookmarks can be renamed or deleted via the ")
1936      (insert-text-button "Emacs bookmark menu"
1937                          'action (lambda (_)
1938                                    (interactive)
1939                                    (call-interactively #'bookmark-bmenu-list))
1940                          'follow-link t
1941                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
1942      (insert (substitute-command-keys
1943               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1944      (elpher-restore-pos))))
1945
1946 (defun elpher-show-bookmarks ()
1947   "Interactive function to display the current list of elpher bookmarks."
1948   (interactive)
1949   (elpher-visit-page
1950    (elpher-make-page "Elpher Bookmarks"
1951                      (elpher-make-about-address 'bookmarks))))
1952
1953
1954 ;;; Integrations
1955 ;;
1956
1957 ;;; Org
1958
1959 (defun elpher-org-export-link (link description format protocol)
1960   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1961
1962 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1963 of gemini, gopher or finger."
1964   (let* ((url (if (equal protocol "elpher")
1965                   (string-remove-prefix "elpher:" link)
1966                 (format "%s:%s" protocol link)))
1967          (desc (or description url)))
1968     (pcase format
1969       (`gemini (format "=> %s %s" url desc))
1970       (`html (format "<a href=\"%s\">%s</a>" url desc))
1971       (`latex (format "\\href{%s}{%s}" url desc))
1972       (_ (if (not description)
1973              url
1974            (format "%s (%s)" desc url))))))
1975
1976 (defun elpher-org-store-link ()
1977   "Store link to an `elpher' page in Org."
1978   (when (eq major-mode 'elpher-mode)
1979     (let* ((url (elpher-info-current))
1980            (desc (car elpher-current-page))
1981            (protocol (cond
1982                       ((string-prefix-p "gemini:" url) "gemini")
1983                       ((string-prefix-p "gopher:" url) "gopher")
1984                       ((string-prefix-p "finger:" url) "finger")
1985                       (t "elpher"))))
1986       (when (equal "elpher" protocol)
1987         ;; Weird link. Or special inner link?
1988         (setq url (concat "elpher:" url)))
1989       (org-link-store-props :type protocol :link url :description desc)
1990       t)))
1991
1992 (defun elpher-org-follow-link (link protocol)
1993   "Visit a LINK for the given PROTOCOL.
1994
1995 PROTOCOL may be one of gemini, gopher or finger.  This method also
1996 supports the old protocol elpher, where the link is self-contained."
1997   (let ((url (if (equal protocol "elpher")
1998                  (string-remove-prefix "elpher:" link)
1999                (format "%s:%s" protocol link))))
2000     (elpher-go url)))
2001
2002 (defun elpher-org-mode-integration ()
2003   "Set up `elpher' integration for `org-mode'."
2004   (org-link-set-parameters
2005    "elpher"
2006    :store #'elpher-org-store-link
2007    :export (lambda (link description format _plist)
2008              (elpher-org-export-link link description format "elpher"))
2009    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2010   (org-link-set-parameters
2011    "gemini"
2012    :export (lambda (link description format _plist)
2013              (elpher-org-export-link link description format "gemini"))
2014    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2015   (org-link-set-parameters
2016    "gopher"
2017    :export (lambda (link description format _plist)
2018              (elpher-org-export-link link description format "gopher"))
2019    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2020   (org-link-set-parameters
2021    "finger"
2022    :export (lambda (link description format _plist)
2023              (elpher-org-export-link link description format "finger"))
2024    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2025
2026 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2027
2028 ;;; Browse URL
2029
2030 ;;;###autoload
2031 (defun elpher-browse-url-elpher (url &rest _args)
2032   "Browse URL using Elpher.  This function is used by `browse-url'."
2033   (interactive (browse-url-interactive-arg "Elpher URL: "))
2034   (elpher-go url))
2035
2036 ;; Use elpher to open gopher, finger and gemini links
2037 ;; For recent version of `browse-url' package
2038 (if (boundp 'browse-url-default-handlers)
2039     (add-to-list
2040      'browse-url-default-handlers
2041      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2042   ;; Patch `browse-url-browser-function' for older ones. The value of
2043   ;; that variable is `browse-url-default-browser' by default, so
2044   ;; that's the function that gets advised.
2045   (advice-add browse-url-browser-function :before-while
2046               (lambda (url &rest _args)
2047                 "Handle gemini, gopher, and finger schemes using Elpher."
2048                 (let ((scheme (downcase (car (split-string url ":" t)))))
2049                   (if (member scheme '("gemini" "gopher" "finger"))
2050                       ;; `elpher-go' always returns nil, which will stop the
2051                       ;; advice chain here in a before-while
2052                       (elpher-go url)
2053                     ;; chain must continue, then return t.
2054                     t)))))
2055
2056 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2057 (with-eval-after-load 'thingatpt
2058   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2059
2060 ;;; Mu4e:
2061
2062 ;; Make mu4e aware of the gemini world
2063 (setq mu4e~view-beginning-of-url-regexp
2064       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2065
2066 ;;; eww:
2067
2068 ;; Let elpher handle gemini, gopher links in eww buffer.
2069 (setq eww-use-browse-url
2070       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2071
2072
2073 ;;; Interactive procedures
2074 ;;
2075
2076 (defun elpher-next-link ()
2077   "Move point to the next link on the current page."
2078   (interactive)
2079   (forward-button 1))
2080
2081 (defun elpher-prev-link ()
2082   "Move point to the previous link on the current page."
2083   (interactive)
2084   (backward-button 1))
2085
2086 (defun elpher-follow-current-link ()
2087   "Open the link or url at point."
2088   (interactive)
2089   (push-button))
2090
2091 ;;;###autoload
2092 (defun elpher-go (host-or-url)
2093   "Go to a particular gopher site HOST-OR-URL.
2094 When run interactively HOST-OR-URL is read from the minibuffer."
2095   (interactive "sGopher or Gemini URL: ")
2096   (let ((trimmed-host-or-url (string-trim host-or-url)))
2097     (unless (string-empty-p trimmed-host-or-url)
2098       (let* ((address (elpher-address-from-url trimmed-host-or-url))
2099              (page (elpher-make-page trimmed-host-or-url address)))
2100         (switch-to-buffer elpher-buffer-name)
2101         (elpher-with-clean-buffer
2102          (elpher-visit-page page))
2103         nil)))) ; non-nil value is displayed by eshell
2104
2105 (defun elpher-go-current ()
2106   "Go to a particular site read from the minibuffer, initialized with the current URL."
2107   (interactive)
2108   (let* ((address (elpher-page-address elpher-current-page))
2109          (url (read-string "Gopher or Gemini URL: "
2110                            (unless (elpher-address-about-p address)
2111                              (elpher-address-to-url address)))))
2112     (unless (string-empty-p (string-trim url))
2113       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
2114
2115 (defun elpher-redraw ()
2116   "Redraw current page."
2117   (interactive)
2118   (elpher-visit-page elpher-current-page))
2119
2120 (defun elpher-reload ()
2121   "Reload current page."
2122   (interactive)
2123   (elpher-reload-current-page))
2124
2125 (defun elpher-toggle-tls ()
2126   "Toggle TLS encryption mode for gopher."
2127   (interactive)
2128   (setq elpher-use-tls (not elpher-use-tls))
2129   (if elpher-use-tls
2130       (if (gnutls-available-p)
2131           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2132         (setq elpher-use-tls nil)
2133         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2134     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2135
2136 (defun elpher-view-raw ()
2137   "View raw server response for current page."
2138   (interactive)
2139   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2140       (error "This page was not generated by a server")
2141     (elpher-visit-page elpher-current-page
2142                        #'elpher-render-raw)))
2143
2144 (defun elpher-back ()
2145   "Go to previous site."
2146   (interactive)
2147   (elpher-visit-previous-page))
2148
2149 (defun elpher-back-to-start ()
2150   "Go all the way back to the start page."
2151   (interactive)
2152   (setq-local elpher-current-page nil)
2153   (setq-local elpher-history nil)
2154   (elpher-visit-page (elpher-make-start-page)))
2155
2156 (defun elpher-download ()
2157   "Download the link at point."
2158   (interactive)
2159   (let ((button (button-at (point))))
2160     (if button
2161         (let ((page (button-get button 'elpher-page)))
2162           (unless page
2163             (error "Not an elpher page"))
2164           (when (elpher-address-about-p (elpher-page-address page))
2165             (error "Cannot download %s" (elpher-page-display-string page)))
2166           (elpher-visit-page (button-get button 'elpher-page)
2167                              #'elpher-render-download))
2168       (error "No link selected"))))
2169
2170 (defun elpher-download-current ()
2171   "Download the current page."
2172   (interactive)
2173   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2174       (error "Cannot download %s"
2175              (elpher-page-display-string elpher-current-page))
2176     (elpher-visit-page (elpher-make-page
2177                         (elpher-page-display-string elpher-current-page)
2178                         (elpher-page-address elpher-current-page))
2179                        #'elpher-render-download
2180                        t)))
2181
2182 (defun elpher--build-link-map ()
2183   "Build alist mapping link names to destination pages in current buffer."
2184   (let ((link-map nil)
2185         (b (next-button (point-min) t)))
2186     (while b
2187       (push (cons (button-label b) b) link-map)
2188       (setq b (next-button (button-start b))))
2189     link-map))
2190
2191 (defun elpher-jump ()
2192   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2193   (interactive)
2194   (let* ((link-map (elpher--build-link-map)))
2195     (if link-map
2196         (let ((key (let ((completion-ignore-case t))
2197                      (completing-read "Directory item/link: "
2198                                       link-map nil t))))
2199           (if (and key (> (length key) 0))
2200               (let ((b (cdr (assoc key link-map))))
2201                 (goto-char (button-start b))
2202                 (button-activate b)))))))
2203
2204 (defun elpher-root-dir ()
2205   "Visit root of current server."
2206   (interactive)
2207   (let ((address (elpher-page-address elpher-current-page)))
2208     (if (not (elpher-address-about-p address))
2209         (if (or (member (url-filename address) '("/" ""))
2210                 (and (elpher-address-gopher-p address)
2211                      (= (length (elpher-gopher-address-selector address)) 0)))
2212             (error "Already at root directory of current server")
2213           (let ((address-copy (elpher-address-from-url
2214                                (elpher-address-to-url address))))
2215             (setf (url-filename address-copy) "")
2216             (elpher-go (elpher-address-to-url address-copy))))
2217       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2218
2219 (defun elpher-info-page (page)
2220   "Display URL of PAGE in minibuffer."
2221   (let ((address (elpher-page-address page)))
2222     (message "%s" (elpher-address-to-url address))))
2223
2224 (defun elpher-info-link ()
2225   "Display information on page corresponding to link at point."
2226   (interactive)
2227   (let ((button (button-at (point))))
2228     (unless button
2229       (error "No item selected"))
2230     (let ((page (button-get button 'elpher-page)))
2231       (unless page
2232         (error "Not an elpher page"))
2233       (elpher-info-page page))))
2234
2235 (defun elpher-info-current ()
2236   "Display information on current page."
2237   (interactive)
2238   (elpher-info-page elpher-current-page))
2239
2240 (defun elpher-copy-page-url (page)
2241   "Copy URL representation of address of PAGE to `kill-ring'."
2242   (let* ((address (elpher-page-address page))
2243          (url (elpher-address-to-url address)))
2244     (message "Copied \"%s\" to kill-ring/clipboard." url)
2245     (kill-new url)))
2246
2247 (defun elpher-copy-link-url ()
2248   "Copy URL of item at point to `kill-ring'."
2249   (interactive)
2250   (let ((button (button-at (point))))
2251     (unless button
2252       (error "No item selected"))
2253     (let ((page (button-get button 'elpher-page)))
2254       (unless page
2255         (error "Not an elpher page"))
2256       (elpher-copy-page-url page))))
2257
2258 (defun elpher-copy-current-url ()
2259   "Copy URL of current page to `kill-ring'."
2260   (interactive)
2261   (elpher-copy-page-url elpher-current-page))
2262
2263 (defun elpher-set-gopher-coding-system ()
2264   "Specify an explicit character coding system for gopher selectors."
2265   (interactive)
2266   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2267     (setq elpher-user-coding-system system)
2268     (if system
2269         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2270       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2271
2272
2273 ;;; Mode and keymap
2274 ;;
2275
2276 (defvar elpher-mode-map
2277   (let ((map (make-sparse-keymap)))
2278     (define-key map (kbd "TAB") 'elpher-next-link)
2279     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2280     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2281     (define-key map (kbd "u") 'elpher-back)
2282     (define-key map (kbd "-") 'elpher-back)
2283     (define-key map (kbd "^") 'elpher-back)
2284     (define-key map [mouse-3] 'elpher-back)
2285     (define-key map (kbd "U") 'elpher-back-to-start)
2286     (define-key map (kbd "g") 'elpher-go)
2287     (define-key map (kbd "o") 'elpher-go-current)
2288     (define-key map (kbd "O") 'elpher-root-dir)
2289     (define-key map (kbd "s") 'elpher-show-history)
2290     (define-key map (kbd "S") 'elpher-show-visited-pages)
2291     (define-key map (kbd "r") 'elpher-redraw)
2292     (define-key map (kbd "R") 'elpher-reload)
2293     (define-key map (kbd "T") 'elpher-toggle-tls)
2294     (define-key map (kbd ".") 'elpher-view-raw)
2295     (define-key map (kbd "d") 'elpher-download)
2296     (define-key map (kbd "D") 'elpher-download-current)
2297     (define-key map (kbd "m") 'elpher-jump)
2298     (define-key map (kbd "i") 'elpher-info-link)
2299     (define-key map (kbd "I") 'elpher-info-current)
2300     (define-key map (kbd "c") 'elpher-copy-link-url)
2301     (define-key map (kbd "C") 'elpher-copy-current-url)
2302     (define-key map (kbd "a") 'elpher-bookmark-link)
2303     (define-key map (kbd "A") 'elpher-bookmark-current)
2304     (define-key map (kbd "B") 'elpher-show-bookmarks)
2305     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2306     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2307     (when (fboundp 'evil-define-key*)
2308       (evil-define-key*
2309        'motion map
2310        (kbd "TAB") 'elpher-next-link
2311        (kbd "C-") 'elpher-follow-current-link
2312        (kbd "C-t") 'elpher-back
2313        (kbd "u") 'elpher-back
2314        (kbd "-") 'elpher-back
2315        (kbd "^") 'elpher-back
2316        [mouse-3] 'elpher-back
2317        (kbd "U") 'elpher-back-to-start
2318        (kbd "g") 'elpher-go
2319        (kbd "o") 'elpher-go-current
2320        (kbd "O") 'elpher-root-dir
2321        (kbd "s") 'elpher-show-history
2322        (kbd "S") 'elpher-show-visited-pages
2323        (kbd "r") 'elpher-redraw
2324        (kbd "R") 'elpher-reload
2325        (kbd "T") 'elpher-toggle-tls
2326        (kbd ".") 'elpher-view-raw
2327        (kbd "d") 'elpher-download
2328        (kbd "D") 'elpher-download-current
2329        (kbd "m") 'elpher-jump
2330        (kbd "i") 'elpher-info-link
2331        (kbd "I") 'elpher-info-current
2332        (kbd "c") 'elpher-copy-link-url
2333        (kbd "C") 'elpher-copy-current-url
2334        (kbd "a") 'elpher-bookmark-link
2335        (kbd "A") 'elpher-bookmark-current
2336        (kbd "B") 'elpher-show-bookmarks
2337        (kbd "!") 'elpher-set-gopher-coding-system
2338        (kbd "F") 'elpher-forget-current-certificate))
2339     map)
2340   "Keymap for gopher client.")
2341
2342 (define-derived-mode elpher-mode special-mode "elpher"
2343   "Major mode for elpher, an elisp gopher client.
2344
2345 This mode is automatically enabled by the interactive
2346 functions which initialize the client, namely
2347 `elpher', and `elpher-go'."
2348   (setq-local elpher--gemini-page-headings nil)
2349   (setq-local elpher-current-page nil)
2350   (setq-local elpher-history nil)
2351   (setq-local elpher-buffer-name (buffer-name))
2352   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2353   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2354   (setq-local xterm-color-preserve-properties t))
2355
2356 (when (fboundp 'evil-set-initial-state)
2357   (evil-set-initial-state 'elpher-mode 'motion))
2358
2359
2360 ;;; Main start procedure
2361 ;;
2362
2363 ;;;###autoload
2364 (defun elpher (&optional arg)
2365   "Start elpher with default landing page.
2366 The buffer used for Elpher sessions is determined by the value of
2367 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2368 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2369 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2370 \\[execute-extended-command] elpher RET’) switches to the session with
2371 that number, creating it if necessary.  A non numeric prefix ARG means
2372 to create a new session.  Returns the buffer selected (or created)."
2373   (interactive "P")
2374   (let* ((name (default-value 'elpher-buffer-name))
2375          (buf (cond ((numberp arg)
2376                      (get-buffer-create (format "%s<%d>" name arg)))
2377                     (arg
2378                      (generate-new-buffer name))
2379                     (t
2380                      (get-buffer-create name)))))
2381     (pop-to-buffer-same-window buf)
2382     (unless (buffer-modified-p)
2383       (elpher-mode)
2384       (elpher-visit-page (elpher-make-start-page))
2385       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2386
2387 ;;; elpher.el ends here