elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.1
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.1"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (spartan elpher-get-spartan-page elpher-render-gemini "spt" elpher-spartan)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 ;; Face customizations
 245
 246 (defgroup elpher-faces nil
 247   "Elpher face customizations."
 248   :group 'elpher)
 249
 250 (defface elpher-index
 251   '((t :inherit font-lock-keyword-face))
 252   "Face used for directory type directory records.")
 253
 254 (defface elpher-text
 255   '((t :inherit bold))
 256   "Face used for text type directory records.")
 257
 258 (defface elpher-info
 259   '((t :inherit default))
 260   "Face used for info type directory records.")
 261
 262 (defface elpher-image
 263   '((t :inherit font-lock-string-face))
 264   "Face used for image type directory records.")
 265
 266 (defface elpher-search
 267   '((t :inherit warning))
 268   "Face used for search type directory records.")
 269
 270 (defface elpher-html
 271   '((t :inherit font-lock-comment-face))
 272   "Face used for html type directory records.")
 273
 274 (defface elpher-gemini
 275   '((t :inherit font-lock-constant-face))
 276   "Face used for Gemini type directory records.")
 277
 278 (defface elpher-spartan
 279   '((t :inherit font-lock-type-face))
 280   "Face used for Spartan type directory records.")
 281
 282 (defface elpher-spartan-post
 283   '((t :inherit font-lock-string-face))
 284   "Face used for Spartan type directory records.")
 285
 286 (defface elpher-other-url
 287   '((t :inherit font-lock-comment-face))
 288   "Face used for other URL type links records.")
 289
 290 (defface elpher-telnet
 291   '((t :inherit font-lock-function-name-face))
 292   "Face used for telnet type directory records.")
 293
 294 (defface elpher-binary
 295   '((t :inherit font-lock-doc-face))
 296   "Face used for binary type directory records.")
 297
 298 (defface elpher-unknown
 299   '((t :inherit error))
 300   "Face used for directory records with unknown/unsupported types.")
 301
 302 (defface elpher-margin-key
 303   '((t :inherit bold))
 304   "Face used for directory margin key.")
 305
 306 (defface elpher-margin-brackets
 307   '((t :inherit shadow))
 308   "Face used for brackets around directory margin key.")
 309
 310 (defface elpher-gemini-heading1
 311   '((t :inherit bold :height 1.8))
 312   "Face used for gemini heading level 1.")
 313
 314 (defface elpher-gemini-heading2
 315   '((t :inherit bold :height 1.5))
 316   "Face used for gemini heading level 2.")
 317
 318 (defface elpher-gemini-heading3
 319   '((t :inherit bold :height 1.2))
 320   "Face used for gemini heading level 3.")
 321
 322 (defface elpher-gemini-quoted
 323   '((t :inherit font-lock-doc-face))
 324   "Face used for gemini quoted texts.")
 325
 326 (defface elpher-gemini-preformatted-toggle
 327   '((t :inherit button))
 328   "Face used for buttons used to toggle display of preformatted text.")
 329
 330 ;;; Model
 331 ;;
 332
 333 ;; Address
 334
 335 ;; An elpher "address" object is either a url object or a symbol.
 336 ;; Addresses with the "about" type, corresponding to pages generated
 337 ;; dynamically for and by elpher.  All others represent pages which
 338 ;; rely on content retrieved over the network.
 339
 340 (defun elpher-address-from-url (url-string &optional default-scheme)
 341   "Create a ADDRESS object corresponding to the given URL-STRING.
 342 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 343 is not explicitly given."
 344   (let ((data (match-data))) ; Prevent parsing clobbering match data
 345     (unwind-protect
 346         (let ((url (url-generic-parse-url url-string)))
 347           (unless (and (not (url-fullness url)) (url-type url))
 348             (unless (url-type url)
 349               (setf (url-type url) default-scheme))
 350             (unless (url-host url)
 351               (let ((p (split-string (url-filename url) "/" nil nil)))
 352                 (setf (url-host url) (car p))
 353                 (setf (url-filename url)
 354                       (if (cdr p)
 355                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 356                         ""))))
 357             (when (not (string-empty-p (url-host url)))
 358               (setf (url-fullness url) t)
 359               (setf (url-host url) (puny-encode-domain (url-host url))))
 360             (when (or (equal "gopher" (url-type url))
 361                       (equal "gophers" (url-type url)))
 362               ;; Gopher defaults
 363               (when (or (equal (url-filename url) "")
 364                         (equal (url-filename url) "/"))
 365                 (setf (url-filename url) "/1")))
 366             (when (member (url-type url) '("gemini" "spartan"))
 367               ;; Gemini and Spartan defaults
 368               (if (equal (url-filename url) "")
 369                   (setf (url-filename url) "/"))))
 370           (elpher-remove-redundant-ports url))
 371       (set-match-data data))))
 372
 373 (defun elpher-remove-redundant-ports (address)
 374   "Remove redundant port specifiers from ADDRESS.
 375 Here 'redundant' means that the specified port matches the default
 376 for that protocol, eg 70 for gopher."
 377   (if (and (not (elpher-address-about-p address))
 378            (eq (url-portspec address) ; (url-port) is too slow!
 379                (pcase (url-type address)
 380                  ("gemini" 1965)
 381                  ((or "gopher" "gophers") 70)
 382                  ("finger" 79)
 383                  (_ -1))))
 384       (setf (url-portspec address) nil))
 385   address)
 386
 387 (defun elpher-make-gopher-address (type selector host port &optional tls)
 388   "Create an ADDRESS object using gopher directory record attributes.
 389 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 390 If the optional attribute TLS is non-nil, the address will be marked as
 391 requiring gopher-over-TLS."
 392   (cond
 393    ((equal type ?i) nil)
 394    ((and (equal type ?h)
 395          (string-prefix-p "URL:" selector))
 396     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 397    ((equal type ?8)
 398     (elpher-address-from-url
 399      (concat "telnet"
 400              "://" host
 401              ":" (number-to-string port))))
 402    (t
 403     (elpher-address-from-url
 404      (concat "gopher" (if tls "s" "")
 405              "://" host
 406              ":" (number-to-string port)
 407              "/" (string type)
 408              selector)))))
 409
 410 (defun elpher-make-about-address (type)
 411   "Create an ADDRESS object corresponding to the given about address TYPE."
 412   (elpher-address-from-url (concat "about:" (symbol-name type))))
 413
 414 (defun elpher-address-to-url (address)
 415   "Get string representation of ADDRESS."
 416   (url-encode-url (url-recreate-url address)))
 417
 418 (defun elpher-address-type (address)
 419   "Retrieve type of ADDRESS object.
 420 This is used to determine how to retrieve and render the document the
 421 address refers to, via the table `elpher-type-map'."
 422   (pcase (url-type address)
 423     ("about"
 424      (list 'about (intern (url-filename address))))
 425     ((or "gopher" "gophers")
 426      (list 'gopher
 427            (if (member (url-filename address) '("" "/"))
 428                ?1
 429              (string-to-char (substring (url-filename address) 1)))))
 430     ("gemini" 'gemini)
 431     ("spartan" 'spartan)
 432     ("telnet" 'telnet)
 433     ("finger" 'finger)
 434     ("file" 'file)
 435     (_ 'other-url)))
 436
 437 (defun elpher-address-about-p (address)
 438   "Return non-nil if ADDRESS is an  about address."
 439   (pcase (elpher-address-type address) (`(about ,_) t)))
 440
 441 (defun elpher-address-gopher-p (address)
 442   "Return non-nill if ADDRESS object is a gopher address."
 443   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 444
 445 (defun elpher-address-protocol (address)
 446   "Retrieve the transport protocol for ADDRESS."
 447   (url-type address))
 448
 449 (defun elpher-address-filename (address)
 450   "Retrieve the filename component of ADDRESS.
 451 For gopher addresses this is a combination of the selector type and selector."
 452   (url-unhex-string (url-filename address)))
 453
 454 (defun elpher-address-host (address)
 455   "Retrieve host from ADDRESS object."
 456   (let ((host-pre (url-host address)))
 457     ;; The following strips out square brackets which sometimes enclose IPv6
 458     ;; addresses.  Doing this here rather than at the parsing stage may seem
 459     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 460     ;; and reconstruction.  It's also more efficient, as this method is not
 461     ;; called during page rendering.
 462     (if (and (> (length host-pre) 2)
 463              (eq (elt host-pre 0) ?\[)
 464              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 465         (substring host-pre 1 (- (length host-pre) 1))
 466       host-pre)))
 467
 468 (defun elpher-address-user (address)
 469   "Retrieve user from ADDRESS object."
 470   (url-user address))
 471
 472 (defun elpher-address-port (address)
 473   "Retrieve port from ADDRESS object.
 474 If no address is defined, returns 0.  (This is for compatibility with
 475 the URL library.)"
 476   (url-port address))
 477
 478 (defun elpher-gopher-address-selector (address)
 479   "Retrieve gopher selector from ADDRESS object."
 480   (if (member (url-filename address) '("" "/"))
 481       ""
 482     (url-unhex-string (substring (url-filename address) 2))))
 483
 484
 485 ;; Cache
 486
 487 (defvar elpher-content-cache (make-hash-table :test 'equal))
 488 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 489
 490 (defun elpher-get-cached-content (address)
 491   "Retrieve the cached content for ADDRESS, or nil if none exists."
 492   (gethash address elpher-content-cache))
 493
 494 (defun elpher-cache-content (address content)
 495   "Set the content cache for ADDRESS to CONTENT."
 496   (puthash address content elpher-content-cache))
 497
 498 (defun elpher-get-cached-pos (address)
 499   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 500   (gethash address elpher-pos-cache))
 501
 502 (defun elpher-cache-pos (address pos)
 503   "Set the cursor position cache for ADDRESS to POS."
 504   (puthash address pos elpher-pos-cache))
 505
 506
 507 ;; Page
 508
 509 (defun elpher-make-page (display-string address)
 510   "Create a page with DISPLAY-STRING and ADDRESS."
 511   (list display-string address))
 512
 513 (defun elpher-make-start-page ()
 514   "Create the start page."
 515   (elpher-make-page "Start Page"
 516                     (elpher-address-from-url elpher-start-page-url)))
 517
 518 (defun elpher-page-display-string (page)
 519   "Retrieve the display string corresponding to PAGE."
 520   (elt page 0))
 521
 522 (defun elpher-page-address (page)
 523   "Retrieve the address corresponding to PAGE."
 524   (elt page 1))
 525
 526 (defun elpher-page-set-address (page new-address)
 527   "Set the address corresponding to PAGE to NEW-ADDRESS."
 528   (setcar (cdr page) new-address))
 529
 530 (defun elpher-page-from-url (url &optional default-scheme)
 531   "Create a page with address and display string defined by URL.
 532 The URL is unhexed prior to its use as a display string to improve
 533 readability.
 534
 535 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 536 in the instance that URL itself doesn't specify one."
 537   (let ((address (elpher-address-from-url url default-scheme)))
 538     (elpher-make-page (elpher-address-to-iri address) address)))
 539
 540 (defun elpher-address-to-iri (address)
 541   "Return an IRI for ADDRESS.
 542 Decode percent-escapes and handle punycode in the domain name.
 543 Drop the password, if any."
 544   (let ((data (match-data)) ; Prevent parsing clobbering match data
 545         (host (url-host address))
 546         (pass (url-password address)))
 547     (unwind-protect
 548         (let* ((host (url-host address))
 549                (pass (url-password address)))
 550           (when host
 551             (setf (url-host address) (puny-decode-domain host)))
 552           (when pass                             ; RFC 3986 says we should not render
 553             (setf (url-password address) nil)) ; the password as clear text
 554           (elpher-decode (url-unhex-string (url-recreate-url address))))
 555       (setf (url-host address) host)
 556       (setf (url-password address) pass)
 557       (set-match-data data))))
 558
 559 (defvar elpher-current-page nil
 560   "The current page for this Elpher buffer.")
 561
 562 (defvar elpher-history nil
 563   "The local history stack for this Elpher buffer.
 564 This variable is used by `elpher-back' and
 565 `elpher-show-history'.")
 566
 567 (defvar elpher-visited-pages nil
 568   "The global history for all Elpher buffers.
 569 This variable is used by `elpher-show-visited-pages'.")
 570
 571 (defun elpher-visit-page (page &optional renderer no-history)
 572   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 573 Additionally, push PAGE onto the history stack and the list of
 574 previously-visited pages,unless NO-HISTORY is non-nil."
 575   (elpher-save-pos)
 576   (elpher-process-cleanup)
 577   (unless no-history
 578     (unless (or (not elpher-current-page)
 579                  (equal (elpher-page-address elpher-current-page)
 580                         (elpher-page-address page)))
 581       (push elpher-current-page elpher-history)
 582       (unless (or (elpher-address-about-p (elpher-page-address page))
 583                   (and elpher-visited-pages
 584                        (equal page (car elpher-visited-pages))))
 585         (push page elpher-visited-pages))))
 586   (setq-local elpher-current-page page)
 587   (let* ((address (elpher-page-address page))
 588          (type (elpher-address-type address))
 589          (type-record (cdr (assoc type elpher-type-map))))
 590     (if type-record
 591         (funcall (car type-record)
 592                  (if renderer
 593                      renderer
 594                    (cadr type-record)))
 595       (elpher-visit-previous-page)
 596       (pcase type
 597         (`(gopher ,type-char)
 598          (error "Unsupported gopher selector type '%c' for '%s'"
 599                 type-char (elpher-address-to-url address)))
 600         (other
 601          (error "Unsupported address type '%S' for '%s'"
 602                 other (elpher-address-to-url address)))))))
 603
 604 (defun elpher-visit-previous-page ()
 605   "Visit the previous page in the history."
 606   (if elpher-history
 607       (elpher-visit-page (pop elpher-history) nil t)
 608     (error "No previous page")))
 609
 610 (defun elpher-reload-current-page ()
 611   "Reload the current page, discarding any existing cached content."
 612   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 613   (elpher-visit-page elpher-current-page))
 614
 615 (defun elpher-save-pos ()
 616   "Save the current position of point to the current page."
 617   (when elpher-current-page
 618     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 619
 620 (defun elpher-restore-pos ()
 621   "Restore the position of point to that cached in the current page."
 622   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 623     (if pos
 624         (goto-char pos)
 625       (goto-char (point-min)))))
 626
 627 (defun elpher-get-default-url-scheme ()
 628   "Suggest default URL scheme for visiting addresses based on the current page."
 629   (if elpher-current-page
 630       (let* ((address (elpher-page-address elpher-current-page))
 631              (current-type (elpher-address-type address)))
 632         (pcase current-type
 633           ((or (and 'file (guard (not elpher-history)))
 634                `(about ,_))
 635            elpher-default-url-type)
 636           (_
 637            (url-type address))))
 638       elpher-default-url-type))
 639
 640
 641 ;;; Buffer preparation
 642 ;;
 643
 644 (defvar elpher-buffer-name "*elpher*"
 645   "The default name of the Elpher buffer.")
 646
 647 (defun elpher-update-header ()
 648   "If `elpher-use-header' is true, display current page info in window header."
 649   (if (and elpher-use-header elpher-current-page)
 650       (let* ((display-string (elpher-page-display-string elpher-current-page))
 651              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 652              (address (elpher-page-address elpher-current-page))
 653              (tls-string (if (and (not (elpher-address-about-p address))
 654                                   (member (elpher-address-protocol address)
 655                                           '("gophers" "gemini")))
 656                              " [TLS encryption]"
 657                            ""))
 658              (header (concat sanitized-display-string
 659                              (propertize tls-string 'face 'bold))))
 660         (setq header-line-format header))))
 661
 662 (defmacro elpher-with-clean-buffer (&rest args)
 663   "Evaluate ARGS with a clean *elpher* buffer as current."
 664   (declare (debug (body))) ;; Allow edebug to step through body
 665   `(with-current-buffer elpher-buffer-name
 666      (unless (eq major-mode 'elpher-mode)
 667        ;; avoid resetting buffer-local variables
 668        (elpher-mode))
 669      (let ((inhibit-read-only t)
 670            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 671        (setq-local xterm-color--current-fg nil)
 672        (setq-local xterm-color--current-bg nil)
 673        (setq-local network-security-level
 674                    (default-value 'network-security-level))
 675        (erase-buffer)
 676        (elpher-update-header)
 677        ,@args)))
 678
 679 (defun elpher-buffer-message (string &optional line)
 680   "Replace first line in elpher buffer with STRING.
 681 If LINE is non-nil, replace that line instead."
 682   (with-current-buffer elpher-buffer-name
 683     (let ((inhibit-read-only t))
 684       (goto-char (point-min))
 685       (if line
 686           (forward-line line))
 687       (let ((data (match-data)))
 688         (unwind-protect
 689             (progn
 690               (re-search-forward "^.*$")
 691               (replace-match string))
 692           (set-match-data data))))))
 693
 694
 695 ;;; Text Processing
 696 ;;
 697
 698 (defvar elpher-user-coding-system nil
 699   "User-specified coding system to use for decoding text responses.")
 700
 701 (defun elpher-decode (string)
 702   "Decode STRING using autodetected or user-specified coding system."
 703   (decode-coding-string string
 704                         (if elpher-user-coding-system
 705                             elpher-user-coding-system
 706                           (detect-coding-string string t))))
 707
 708 (defun elpher-preprocess-text-response (string)
 709   "Preprocess text selector response contained in STRING.
 710 This involes decoding the character representation, and clearing
 711 away CRs and any terminating period."
 712   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 713                                            (replace-regexp-in-string "\r" "" string))))
 714
 715 ;;; Buttonify urls
 716
 717 (defconst elpher-url-regex
 718   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 719   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 720
 721 (defun elpher-buttonify-urls (string)
 722   "Turn substrings which look like urls in STRING into clickable buttons."
 723   (with-temp-buffer
 724     (insert string)
 725     (goto-char (point-min))
 726     (while (re-search-forward elpher-url-regex nil t)
 727       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 728         (make-text-button (match-beginning 0)
 729                           (match-end 0)
 730                           'elpher-page  page
 731                           'action #'elpher-click-link
 732                           'follow-link t
 733                           'help-echo #'elpher--page-button-help
 734                           'face 'button)))
 735     (buffer-string)))
 736
 737 ;;; ANSI colors or XTerm colors (application and filtering)
 738
 739 (or (require 'xterm-color nil t)
 740     (require 'ansi-color))
 741
 742 (defalias 'elpher-color-filter-apply
 743   (if (fboundp 'xterm-color-filter)
 744       (lambda (s)
 745         (let ((_xterm-color-render nil))
 746           (xterm-color-filter s)))
 747     #'ansi-color-filter-apply)
 748   "A function to filter out ANSI escape sequences.")
 749
 750 (defalias 'elpher-color-apply
 751   (if (fboundp 'xterm-color-filter)
 752       #'xterm-color-filter
 753     #'ansi-color-apply)
 754   "A function to apply ANSI escape sequences.")
 755
 756 ;;; Processing text for display
 757
 758 (defun elpher-process-text-for-display (string)
 759   "Perform any desired processing of STRING prior to display as text.
 760 Currently includes buttonifying URLs and processing ANSI escape codes."
 761   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 762                              (elpher-color-filter-apply string)
 763                            (elpher-color-apply string))))
 764
 765
 766 ;;; Network error reporting
 767 ;;
 768
 769 (defun elpher-network-error (address error)
 770   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 771 ERROR can be either an error object or a string."
 772   (elpher-with-clean-buffer
 773    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 774            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 775            (if (stringp error) error (error-message-string error)) "\n"
 776            (propertize "\n----------------\n\n" 'face 'error)
 777            "Press 'u' to return to the previous page.")))
 778
 779
 780 ;;; General network communication
 781 ;;
 782
 783 (defvar elpher-network-timer nil
 784   "Timer used for network connections.")
 785
 786 (defvar elpher-use-tls nil
 787   "If non-nil, use TLS to communicate with gopher servers.")
 788
 789 (defvar elpher-client-certificate nil
 790   "If non-nil, contains client certificate details to use for TLS connections.")
 791
 792 (defun elpher-process-cleanup ()
 793   "Immediately shut down any extant elpher process and timers."
 794   (let ((p (get-process "elpher-process")))
 795     (if p (delete-process p)))
 796   (if (timerp elpher-network-timer)
 797       (cancel-timer elpher-network-timer)))
 798
 799 (defun elpher-make-network-timer (thunk)
 800   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 801 This is just a wraper around `run-at-time' which additionally sets the
 802 buffer-local variable `elpher-network-timer' to allow
 803 `elpher-process-cleanup' to also clear the timer."
 804   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 805     (setq-local elpher-network-timer timer)
 806     timer))
 807
 808 (defun elpher-get-host-response (address default-port query-string response-processor
 809                                          &optional use-tls force-ipv4)
 810   "Generic function for retrieving data from ADDRESS.
 811
 812 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 813 QUERY-STRING is a string sent to the host specified by ADDRESS to
 814 illicet a response.  This response is passed as an argument to the
 815 function RESPONSE-PROCESSOR.
 816
 817 If non-nil, USE-TLS specifies that the connection is to be made over
 818 TLS.  If set to gemini, the certificate verification will be disabled
 819 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 820
 821 If non-nil, FORCE-IPV4 causes the network connection to be made over
 822 ipv4 only.  (The default behaviour when this is not set depends on
 823 the host operating system and the local network capabilities.)"
 824   (if (and use-tls (not (gnutls-available-p)))
 825       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 826     (unless (< (elpher-address-port address) 65536)
 827       (error "Cannot establish network connection: port number > 65536"))
 828     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 829       (setq-local network-security-level 'low)
 830       (setq-local gnutls-verify-error nil))
 831     (condition-case nil
 832         (let* ((kill-buffer-query-functions nil)
 833                (port (elpher-address-port address))
 834                (host (elpher-address-host address))
 835                (service (if (> port 0) port default-port))
 836                (response-string-parts nil)
 837                (bytes-received 0)
 838                (hkbytes-received 0)
 839                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 840                (gnutls-params (list :type 'gnutls-x509pki
 841                                     :hostname host
 842                                     :keylist
 843                                     (elpher-get-current-keylist address)))
 844                (timer (elpher-make-network-timer
 845                                    (lambda ()
 846                                      (elpher-process-cleanup)
 847                                      (cond
 848                                         ; Try again with IPv4
 849                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 850                                        (message "Connection timed out.  Retrying with IPv4.")
 851                                        (elpher-get-host-response address default-port
 852                                                                  query-string
 853                                                                  response-processor
 854                                                                  use-tls t))
 855                                       ((and use-tls
 856                                             (not (eq use-tls 'gemini))
 857                                             (or elpher-auto-disengage-TLS
 858                                                 (y-or-n-p
 859                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 860                                        (setq elpher-use-tls nil)
 861                                        (elpher-get-host-response address default-port
 862                                                                  query-string
 863                                                                  response-processor
 864                                                                  nil force-ipv4))
 865                                       (t
 866                                        (elpher-network-error address "Connection time-out."))))))
 867                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 868                        (make-network-process :name "elpher-process"
 869                                              :host host
 870                                              :family (and (or force-ipv4
 871                                                               elpher-ipv4-always)
 872                                                           'ipv4)
 873                                              :service service
 874                                              :buffer nil
 875                                              :nowait t
 876                                              :tls-parameters
 877                                              (and use-tls
 878                                                   (cons 'gnutls-x509pki
 879                                                         (apply #'gnutls-boot-parameters
 880                                                                gnutls-params)))))))
 881           (setq elpher-network-timer timer)
 882           (set-process-coding-system proc 'binary 'binary)
 883           (set-process-query-on-exit-flag proc nil)
 884           (elpher-buffer-message (concat "Connecting to " host "..."
 885                                          " (press 'u' to abort)"))
 886           (set-process-filter proc
 887                               (lambda (_proc string)
 888                                 (when timer
 889                                   (cancel-timer timer)
 890                                   (setq timer nil))
 891                                 (setq bytes-received (+ bytes-received (length string)))
 892                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 893                                   (when (> new-hkbytes-received hkbytes-received)
 894                                     (setq hkbytes-received new-hkbytes-received)
 895                                     (elpher-buffer-message
 896                                      (concat "("
 897                                              (number-to-string (/ hkbytes-received 10.0))
 898                                              " MB read)")
 899                                      1)))
 900                                 (setq response-string-parts
 901                                       (cons string response-string-parts))))
 902           (set-process-sentinel proc
 903                                 (lambda (proc event)
 904                                   (when timer
 905                                     (cancel-timer timer))
 906                                   (condition-case the-error
 907                                       (cond
 908                                        ((string-prefix-p "open" event)    ; request URL
 909                                         (elpher-buffer-message
 910                                          (concat "Connected to " host ". Receiving data..."
 911                                                  " (press 'u' to abort)"))
 912                                         (let ((inhibit-eol-conversion t))
 913                                           (process-send-string proc query-string)))
 914                                        ((string-prefix-p "deleted" event)) ; do nothing
 915                                        ((and (not response-string-parts)
 916                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 917                                         ; Try again with IPv4
 918                                         (message "Connection failed. Retrying with IPv4.")
 919                                         (elpher-get-host-response address default-port
 920                                                                   query-string
 921                                                                   response-processor
 922                                                                   use-tls t))
 923                                        (response-string-parts
 924                                         (elpher-with-clean-buffer
 925                                          (insert "Data received.  Rendering..."))
 926                                         (funcall response-processor
 927                                                  (apply #'concat (reverse response-string-parts)))
 928                                         (elpher-restore-pos))
 929                                        (t
 930                                         (error "No response from server")))
 931                                     (error
 932                                      (elpher-network-error address the-error)))))
 933           (when socks
 934             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 935             (funcall (process-sentinel proc) proc "open\n")))
 936       (error
 937        (elpher-process-cleanup)
 938        (error "Error initiating connection to server")))))
 939
 940
 941 ;;; Client-side TLS Certificate Management
 942 ;;
 943
 944 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 945   "Generate a key and a self-signed client TLS certificate using openssl.
 946
 947 The Common Name field of the certificate is set to COMMON-NAME.  The
 948 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 949 the key and certificate files to write.
 950
 951 If TEMPORARY is non-nil, the certificate will be given an exporation
 952 period of one day, and the key and certificate files will be deleted
 953 when the certificate is no longer needed for the current session.
 954
 955 Otherwise, the certificate will be given a 100 year expiration period
 956 and the files will not be deleted.
 957
 958 The function returns a list containing the current host name, the
 959 temporary flag, and the key and cert file names in the form required
 960 by `gnutls-boot-parameters`."
 961   (let ((exp-key-file (expand-file-name key-file))
 962         (exp-cert-file (expand-file-name cert-file)))
 963     (condition-case nil
 964         (progn
 965           (call-process elpher-openssl-command nil nil nil
 966                         "req" "-x509" "-newkey" "rsa:2048"
 967                         "-days" (if temporary "1" "36500")
 968                         "-nodes"
 969                         "-subj" (concat "/CN=" common-name)
 970                         "-keyout" exp-key-file
 971                         "-out" exp-cert-file)
 972           (list (elpher-address-host (elpher-page-address elpher-current-page))
 973                 temporary exp-key-file exp-cert-file))
 974       (error
 975        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 976        (error "Program 'openssl', required for certificate generation, not found")))))
 977
 978 (defun elpher-generate-throwaway-certificate ()
 979   "Generate and return details of a throwaway certificate.
 980 The key and certificate files will be deleted when they are no
 981 longer needed for this session."
 982   (let* ((file-base (make-temp-name "elpher"))
 983          (key-file (concat temporary-file-directory file-base ".key"))
 984          (cert-file (concat temporary-file-directory file-base ".crt")))
 985     (elpher-generate-certificate file-base key-file cert-file t)))
 986
 987 (defun elpher-generate-persistent-certificate (file-base common-name)
 988   "Generate and return details of a persistent certificate.
 989 The argument FILE-BASE is used as the base for the key and certificate
 990 files, while COMMON-NAME specifies the common name field of the
 991 certificate.
 992
 993 The key and certificate files are written to in `elpher-certificate-directory'."
 994   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 995          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 996     (elpher-generate-certificate common-name key-file cert-file)))
 997
 998 (defun elpher-get-existing-certificate (file-base)
 999   "Return a certificate object corresponding to an existing certificate.
1000 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1001 the directory `elpher-certificate-directory'."
1002   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1003          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1004     (list (elpher-address-host (elpher-page-address elpher-current-page))
1005           nil
1006           (expand-file-name key-file)
1007           (expand-file-name cert-file))))
1008
1009 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1010   "Install a key+certificate file pair in `elpher-certificate-directory'.
1011 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1012 certificate files to install.  The argument FILE-BASE is used as the
1013 base for the installed key and certificate files."
1014   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1015          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1016     (if (or (file-exists-p key-file)
1017             (file-exists-p cert-file))
1018         (error "A certificate with base name %s is already installed" file-base))
1019     (copy-file key-file-src key-file)
1020     (copy-file cert-file-src cert-file)
1021     (list (elpher-address-host (elpher-page-address elpher-current-page))
1022           nil
1023           (expand-file-name key-file)
1024           (expand-file-name cert-file))))
1025
1026 (defun elpher-list-existing-certificates ()
1027   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1028   (unless (file-directory-p elpher-certificate-directory)
1029     (make-directory elpher-certificate-directory))
1030   (mapcar
1031    (lambda (file)
1032      (file-name-sans-extension file))
1033    (directory-files elpher-certificate-directory nil "\\.key$")))
1034
1035 (defun elpher-forget-current-certificate ()
1036   "Causes any current certificate to be forgotten.)
1037 In the case of throwaway certificates, the key and certificate files
1038 are also deleted."
1039   (interactive)
1040   (when elpher-client-certificate
1041     (unless (and (called-interactively-p 'any)
1042                  (not (y-or-n-p (concat "Really forget client certificate? "
1043                                         "(Throwaway certificates will be deleted.)"))))
1044       (when (cadr elpher-client-certificate)
1045         (delete-file (elt elpher-client-certificate 2))
1046         (delete-file (elt elpher-client-certificate 3)))
1047       (setq elpher-client-certificate nil)
1048       (if (called-interactively-p 'any)
1049           (message "Client certificate forgotten.")))))
1050
1051 (defun elpher-get-current-keylist (address)
1052   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1053
1054 This is obtained from the client certificate described by
1055 `elpher-current-certificate', if one is available and the host for
1056 that certificate matches the host in ADDRESS.
1057
1058 If `elpher-current-certificate' is non-nil, and its host name doesn't
1059 match that of ADDRESS, the certificate is forgotten."
1060   (if elpher-client-certificate
1061       (if (string= (car elpher-client-certificate)
1062                    (elpher-address-host address))
1063           (list (cddr elpher-client-certificate))
1064         (elpher-forget-current-certificate)
1065         (message "Disabling client certificate for new host")
1066         nil)
1067     nil))
1068
1069
1070 ;;; Gopher selector retrieval
1071 ;;
1072
1073 (defun elpher-get-gopher-response (address renderer)
1074   "Get response string from gopher server at ADDRESS and render using RENDERER."
1075   (elpher-get-host-response address 70
1076                             (concat (elpher-gopher-address-selector address) "\r\n")
1077                             renderer
1078                             (or (string= (elpher-address-protocol address) "gophers")
1079                                 elpher-use-tls)))
1080
1081 (defun elpher-get-gopher-page (renderer)
1082   "Getter function for gopher pages.
1083 The RENDERER procedure is used to display the contents of the page
1084 once they are retrieved from the gopher server."
1085   (let* ((address (elpher-page-address elpher-current-page))
1086          (content (elpher-get-cached-content address)))
1087     (if (and content (funcall renderer nil))
1088         (elpher-with-clean-buffer
1089          (insert content)
1090          (elpher-restore-pos))
1091       (elpher-with-clean-buffer
1092        (insert "LOADING... (use 'u' to cancel)\n"))
1093       (condition-case the-error
1094           (elpher-get-gopher-response address renderer)
1095         (error
1096          (elpher-network-error address the-error))))))
1097
1098 ;; Index rendering
1099
1100 (defun elpher-insert-margin (&optional type-name)
1101   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1102   (if type-name
1103       (progn
1104         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1105                         (concat
1106                          (propertize "[" 'face 'elpher-margin-brackets)
1107                          (propertize type-name 'face 'elpher-margin-key)
1108                          (propertize "]" 'face 'elpher-margin-brackets))))
1109         (insert " "))
1110     (insert (make-string elpher-margin-width ?\s))))
1111
1112 (defun elpher--page-button-help (_window buffer pos)
1113   "Function called by Emacs to generate mouse-over text.
1114 The arguments specify the BUFFER and the POS within the buffer of the item
1115 for which help is required.  The function returns the help to be
1116 displayed.  The _WINDOW argument is currently unused."
1117   (with-current-buffer buffer
1118     (let ((button (button-at pos)))
1119       (when button
1120         (let* ((page (button-get button 'elpher-page))
1121                (address (elpher-page-address page)))
1122           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1123
1124 (defun elpher-insert-index-record (display-string &optional address)
1125   "Function to insert an index record into the current buffer.
1126 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1127 If ADDRESS is not supplied or nil the record is rendered as an
1128 'information' line."
1129   (let* ((type (if address (elpher-address-type address) nil))
1130          (type-map-entry (cdr (assoc type elpher-type-map))))
1131     (if type-map-entry
1132         (let* ((margin-code (elt type-map-entry 2))
1133                (face (elt type-map-entry 3))
1134                (filtered-display-string (elpher-color-filter-apply display-string))
1135                (page (elpher-make-page filtered-display-string address)))
1136           (elpher-insert-margin margin-code)
1137           (insert-text-button filtered-display-string
1138                               'face face
1139                               'elpher-page page
1140                               'action #'elpher-click-link
1141                               'follow-link t
1142                               'help-echo #'elpher--page-button-help))
1143       (pcase type
1144         ('nil ;; Information
1145          (elpher-insert-margin)
1146          (let ((propertized-display-string
1147                 (propertize display-string 'face 'elpher-info)))
1148            (insert (elpher-process-text-for-display propertized-display-string))))
1149         (`(gopher ,selector-type) ;; Unknown
1150          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1151          (insert (propertize display-string
1152                              'face 'elpher-unknown)))))
1153     (insert "\n")))
1154
1155 (defun elpher-click-link (button)
1156   "Function called when the gopher link BUTTON is activated."
1157   (let ((page (button-get button 'elpher-page)))
1158     (elpher-visit-page page)))
1159
1160 (defun elpher-render-index (data &optional _mime-type-string)
1161   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1162   (elpher-with-clean-buffer
1163    (if (not data)
1164        t
1165      (let ((data-processed (elpher-preprocess-text-response data)))
1166        (dolist (line (split-string data-processed "\n"))
1167          (ignore-errors
1168            (unless (= (length line) 0)
1169              (let* ((type (elt line 0))
1170                     (fields (split-string (substring line 1) "\t"))
1171                     (display-string (elt fields 0))
1172                     (selector (elt fields 1))
1173                     (host (elt fields 2))
1174                     (port (if (elt fields 3)
1175                               (string-to-number (elt fields 3))
1176                             nil))
1177                     (address (elpher-make-gopher-address type selector host port)))
1178                (elpher-insert-index-record display-string address))))))
1179      (elpher-cache-content (elpher-page-address elpher-current-page)
1180                            (buffer-string)))))
1181
1182 ;; Text rendering
1183
1184 (defun elpher-render-text (data &optional _mime-type-string)
1185   "Render DATA as text.  MIME-TYPE-STRING is unused."
1186   (elpher-with-clean-buffer
1187    (if (not data)
1188        t
1189      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1190      (elpher-cache-content
1191       (elpher-page-address elpher-current-page)
1192       (buffer-string)))))
1193
1194 ;; Image retrieval
1195
1196 (defun elpher-render-image (data &optional _mime-type-string)
1197   "Display DATA as image.  MIME-TYPE-STRING is unused."
1198   (if (not data)
1199       nil
1200     (if (display-images-p)
1201         (let* ((image (create-image
1202                        data
1203                        nil t)))
1204           (if (not image)
1205               (error "Unsupported image format")
1206             (let ((window (get-buffer-window elpher-buffer-name)))
1207               (when window
1208                 (setf (image-property image :max-width) (window-body-width window t))
1209                 (setf (image-property image :max-height) (window-body-height window t))))
1210             (elpher-with-clean-buffer
1211              (insert-image image)
1212              (elpher-restore-pos))))
1213       (elpher-render-download data))))
1214
1215 ;; Search retrieval and rendering
1216
1217 (defun elpher-get-gopher-query-page (renderer)
1218   "Getter for gopher addresses requiring input.
1219 The response is rendered using the rendering function RENDERER."
1220   (let* ((address (elpher-page-address elpher-current-page))
1221          (content (elpher-get-cached-content address))
1222          (aborted t))
1223     (if (and content (funcall renderer nil))
1224         (elpher-with-clean-buffer
1225          (insert content)
1226          (elpher-restore-pos)
1227          (message "Displaying cached search results.  Reload to perform a new search."))
1228       (unwind-protect
1229           (let* ((query-string (read-string "Query: "))
1230                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1231                  (search-address (elpher-make-gopher-address ?1
1232                                                              query-selector
1233                                                              (elpher-address-host address)
1234                                                              (elpher-address-port address)
1235                                                              (equal (elpher-address-type address) "gophers"))))
1236             (setq aborted nil)
1237
1238             (elpher-with-clean-buffer
1239              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1240             (elpher-get-gopher-response search-address renderer))
1241         (if aborted
1242             (elpher-visit-previous-page))))))
1243
1244 ;; Raw server response rendering
1245
1246 (defun elpher-render-raw (data &optional mime-type-string)
1247   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1248   (if (not data)
1249       nil
1250     (elpher-with-clean-buffer
1251      (when mime-type-string
1252        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1253      (insert data)
1254      (goto-char (point-min)))
1255     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1256
1257 ;; File save "rendering"
1258
1259 (defun elpher-render-download (data &optional _mime-type-string)
1260   "Save DATA to file.  MIME-TYPE-STRING is unused."
1261   (if (not data)
1262       nil
1263     (let* ((address (elpher-page-address elpher-current-page))
1264            (selector (if (elpher-address-gopher-p address)
1265                          (elpher-gopher-address-selector address)
1266                        (elpher-address-filename address))))
1267       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1268       (let* ((filename-proposal (file-name-nondirectory selector))
1269              (filename (read-file-name "Download complete. Save file as: "
1270                                        nil nil nil
1271                                        (if (> (length filename-proposal) 0)
1272                                            filename-proposal
1273                                          "download.file"))))
1274         (let ((coding-system-for-write 'binary))
1275           (with-temp-file filename
1276             (insert data)))
1277         (message (format "Saved to file %s." filename))))))
1278
1279 ;; HTML rendering
1280
1281 (defun elpher-render-html (data &optional _mime-type-string)
1282   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1283   (elpher-with-clean-buffer
1284    (if (not data)
1285        t
1286      (let ((dom (with-temp-buffer
1287                   (insert data)
1288                   (libxml-parse-html-region (point-min) (point-max)))))
1289        (shr-insert-document dom)))))
1290
1291 ;; Gemini page retrieval
1292
1293 (defvar elpher-gemini-redirect-chain)
1294
1295 (defun elpher-get-gemini-response (address renderer)
1296   "Get response string from gemini server at ADDRESS and render using RENDERER."
1297   (elpher-get-host-response address 1965
1298                             (concat (elpher-address-to-url address) "\r\n")
1299                             (lambda (response-string)
1300                               (elpher-process-gemini-response response-string renderer))
1301                             'gemini))
1302
1303 (defun elpher-parse-gemini-response (response)
1304   "Parse the RESPONSE string and return a list of components.
1305 The list is of the form (code meta body).  A response of nil implies
1306 that the response was malformed."
1307   (let ((header-end-idx (string-match "\r\n" response)))
1308     (if header-end-idx
1309         (let ((header (string-trim (substring response 0 header-end-idx)))
1310               (body (substring response (+ header-end-idx 2))))
1311           (if (>= (length header) 2)
1312               (let ((code (substring header 0 2))
1313                     (meta (string-trim (substring header 2))))
1314                 (list code meta body))
1315             (error "Malformed response: No response status found in header %s" header)))
1316       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1317
1318 (defun elpher-process-gemini-response (response-string renderer)
1319   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1320   (let ((response-components (elpher-parse-gemini-response response-string)))
1321     (let ((response-code (elt response-components 0))
1322           (response-meta (elt response-components 1))
1323           (response-body (elt response-components 2)))
1324       (pcase (elt response-code 0)
1325         (?1 ; Input required
1326          (elpher-with-clean-buffer
1327           (insert "Gemini server is requesting input."))
1328          (let* ((query-string
1329                  (if (eq (elt response-code 1) ?1)
1330                      (read-passwd (concat response-meta ": "))
1331                    (read-string (concat response-meta ": "))))
1332                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1333                 (old-fname (url-filename query-address)))
1334            (setf (url-filename query-address)
1335                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1336            (elpher-get-gemini-response query-address renderer)))
1337         (?2 ; Normal response
1338          (funcall renderer response-body response-meta))
1339         (?3 ; Redirect
1340          (message "Following redirect to %s" response-meta)
1341          (if (>= (length elpher-gemini-redirect-chain) 5)
1342              (error "More than 5 consecutive redirects followed"))
1343          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1344            (if (member redirect-address elpher-gemini-redirect-chain)
1345                (error "Redirect loop detected"))
1346            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1347                (error "Server tried to automatically redirect to non-gemini URL: %s"
1348                       response-meta))
1349            (elpher-page-set-address elpher-current-page redirect-address)
1350            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1351            (elpher-get-gemini-response redirect-address renderer)))
1352         (?4 ; Temporary failure
1353          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1354                 response-code response-meta))
1355         (?5 ; Permanent failure
1356          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1357                 response-code response-meta))
1358         (?6 ; Client certificate required
1359          (elpher-with-clean-buffer
1360           (if elpher-client-certificate
1361               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1362             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1363           (auto-fill-mode 1)
1364           (elpher-gemini-insert-text response-meta))
1365          (let ((chosen-certificate (elpher-choose-client-certificate)))
1366            (unless chosen-certificate
1367              (error "Gemini server requires a client certificate and none was provided"))
1368            (setq elpher-client-certificate chosen-certificate))
1369          (elpher-with-clean-buffer)
1370          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1371         (_other
1372          (error "Gemini server response unknown: %s %s"
1373                 response-code response-meta))))))
1374
1375 (defun elpher--read-answer-polyfill (question answers)
1376   "Polyfill for `read-answer' in Emacs 26.1.
1377 QUESTION is a string containing a question, and ANSWERS
1378 is a list of possible answers."
1379     (completing-read question (mapcar 'identity answers)))
1380
1381 (if (fboundp 'read-answer)
1382     (defalias 'elpher-read-answer 'read-answer)
1383   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1384
1385 (defun elpher-choose-client-certificate ()
1386   "Prompt for a client certificate to use to establish a TLS connection."
1387   (let* ((read-answer-short t))
1388     (pcase (read-answer "What do you want to do? "
1389                         '(("throwaway" ?t
1390                            "generate and use throw-away certificate")
1391                           ("persistent" ?p
1392                            "generate new or use existing persistent certificate")
1393                           ("abort" ?a
1394                            "stop immediately")))
1395       ("throwaway"
1396        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1397       ("persistent"
1398        (let* ((existing-certificates (elpher-list-existing-certificates))
1399               (file-base (completing-read
1400                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1401                           existing-certificates)))
1402          (if (string-empty-p (string-trim file-base))
1403              nil
1404            (if (member file-base existing-certificates)
1405                (setq elpher-client-certificate
1406                      (elpher-get-existing-certificate file-base))
1407              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1408                                  '(("new" ?n
1409                                     "generate new certificate")
1410                                    ("install" ?i
1411                                     "install existing certificate")
1412                                    ("abort" ?a
1413                                     "stop immediately")))
1414                ("new"
1415                 (let ((common-name (read-string "Common Name field for new certificate: "
1416                                                 file-base)))
1417                   (message "New key and self-signed certificate written to %s"
1418                            elpher-certificate-directory)
1419                   (elpher-generate-persistent-certificate file-base common-name)))
1420                ("install"
1421                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1422                        (key-file (read-file-name "Key file: " nil nil t)))
1423                   (message "Key and certificate installed in %s for future use"
1424                            elpher-certificate-directory)
1425                   (elpher-install-and-use-existing-certificate key-file
1426                                                                cert-file
1427                                                                file-base)))
1428                ("abort" nil))))))
1429       ("abort" nil))))
1430
1431 (defun elpher-get-gemini-page (renderer)
1432   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1433   (let* ((address (elpher-page-address elpher-current-page))
1434          (content (elpher-get-cached-content address)))
1435     (condition-case the-error
1436         (if (and content (funcall renderer nil))
1437             (elpher-with-clean-buffer
1438              (insert content)
1439              (elpher-restore-pos))
1440           (elpher-with-clean-buffer
1441            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1442           (setq elpher-gemini-redirect-chain nil)
1443           (elpher-get-gemini-response address renderer))
1444       (error
1445        (elpher-network-error address the-error)))))
1446
1447 (defun elpher-render-gemini (body &optional mime-type-string)
1448   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1449   (if (not body)
1450       t
1451     (let* ((mime-type-string* (if (or (not mime-type-string)
1452                                       (string-empty-p mime-type-string))
1453                                   "text/gemini; charset=utf-8"
1454                                 mime-type-string))
1455            (mime-type-split (split-string mime-type-string* ";" t))
1456            (mime-type (string-trim (car mime-type-split)))
1457            (parameters (mapcar (lambda (s)
1458                                  (let ((key-val (split-string s "=")))
1459                                    (list (downcase (string-trim (car key-val)))
1460                                          (downcase (string-trim (cadr key-val))))))
1461                                (cdr mime-type-split))))
1462       (when (string-prefix-p "text/" mime-type)
1463         (setq body (decode-coding-string
1464                     body
1465                     (if (assoc "charset" parameters)
1466                         (intern (cadr (assoc "charset" parameters)))
1467                       'utf-8)))
1468         (setq body (replace-regexp-in-string "\r" "" body)))
1469       (pcase mime-type
1470         ((or "text/gemini" "")
1471          (elpher-render-gemini-map body parameters))
1472         ("text/html"
1473          (elpher-render-html body))
1474         ((pred (string-prefix-p "text/"))
1475          (elpher-render-gemini-plain-text body parameters))
1476         ((pred (string-prefix-p "image/"))
1477          (elpher-render-image body))
1478         (_other
1479          (elpher-render-download body))))))
1480
1481 (defun elpher-gemini-get-link-url (link-line)
1482   "Extract the url portion of LINK-LINE, a gemini map file link line.
1483 Returns nil in the event that the contents of the line following the
1484 => prefix are empty."
1485   (let ((l (split-string (substring link-line 2))))
1486     (if l
1487         (string-trim (elt l 0))
1488       nil)))
1489
1490 (defun elpher-gemini-get-link-display-string (link-line)
1491   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1492 Return nil if this portion is not provided."
1493   (let* ((rest (string-trim (substring link-line 2)))
1494          (idx (string-match "[ \t]" rest)))
1495     (and idx
1496          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1497
1498 (defun elpher-collapse-dot-sequences (filename)
1499   "Collapse dot sequences in the (absolute) FILENAME.
1500 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1501   (let* ((path (split-string filename "/" t))
1502          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1503          (path-reversed-normalized
1504           (seq-reduce (lambda (a b)
1505                         (cond ((equal b "..") (cdr a))
1506                               ((equal b ".") a)
1507                               (t (cons b a))))
1508                       path nil))
1509          (path-normalized (reverse path-reversed-normalized)))
1510     (if path-normalized
1511         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1512       "/")))
1513
1514 (defun elpher-address-from-gemini-url (url)
1515   "Extract address from URL with defaults as per gemini map files.
1516 While there's obviously some redundancy here between this function and
1517 `elpher-address-from-url', gemini map file URLs require enough special
1518 treatment that a separate function is warranted."
1519   (let ((address (url-generic-parse-url url))
1520         (current-address (elpher-page-address elpher-current-page)))
1521     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1522       (if (url-host address) ;if there is an explicit host, filenames are absolute
1523           (if (string-empty-p (url-filename address))
1524               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1525         (setf (url-host address) (url-host current-address))
1526         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1527         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1528         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1529           (setf (url-filename address)
1530                 (concat (file-name-directory (url-filename current-address))
1531                         (url-filename address)))))
1532       (when (url-host address)
1533         (setf (url-host address) (puny-encode-domain (url-host address))))
1534       (unless (url-type address)
1535         (setf (url-type address) (url-type current-address)))
1536       (when (member (url-type address) '("gemini" "spartan"))
1537         (setf (url-filename address)
1538               (elpher-collapse-dot-sequences (url-filename address)))))
1539     (elpher-remove-redundant-ports address)))
1540
1541 (defun elpher-gemini-insert-link (link-line)
1542   "Insert link described by LINK-LINE into a text/gemini document."
1543   (let ((url (elpher-gemini-get-link-url link-line)))
1544     (when url
1545       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1546              (address (elpher-address-from-gemini-url url))
1547              (type (if address (elpher-address-type address) nil))
1548              (type-map-entry (cdr (assoc type elpher-type-map)))
1549              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1550         (when type-map-entry
1551           (insert elpher-gemini-link-string)
1552           (let* ((face (elt type-map-entry 3))
1553                  (display-string (or given-display-string
1554                                      (elpher-address-to-iri address)))
1555                  (page (elpher-make-page display-string
1556                                          address)))
1557             (insert-text-button display-string
1558                                 'face face
1559                                 'elpher-page page
1560                                 'action #'elpher-click-link
1561                                 'follow-link t
1562                                 'help-echo #'elpher--page-button-help))
1563           (newline))))))
1564
1565 (defun elpher-gemini-insert-header (header-line)
1566   "Insert header described by HEADER-LINE into a text/gemini document.
1567 The gemini map file line describing the header is given
1568 by HEADER-LINE."
1569   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1570     (let* ((level (length (match-string 1 header-line)))
1571            (header (substring header-line (match-end 0)))
1572            (face (pcase level
1573                    (1 'elpher-gemini-heading1)
1574                    (2 'elpher-gemini-heading2)
1575                    (3 'elpher-gemini-heading3)
1576                    (_ 'default)))
1577            (fill-column (if (display-graphic-p)
1578                             (/ (* fill-column
1579                                   (font-get (font-spec :name (face-font 'default)) :size))
1580                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1581       (unless (display-graphic-p)
1582         (insert (make-string level ?#) " "))
1583       (insert (propertize header
1584                           'face face
1585                           'gemini-heading t
1586                           'rear-nonsticky t))
1587       (newline))))
1588
1589 (defun elpher-gemini-insert-text (text-line)
1590   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1591 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1592 width defined by `elpher-gemini-max-fill-width'."
1593   (string-match
1594    (rx (: line-start
1595           (optional
1596            (group (or (: "*" (+ (any " \t")))
1597                       (: ">" (* (any " \t"))))))))
1598    text-line)
1599   (let* ((line-prefix (match-string 1 text-line))
1600          (processed-text-line
1601           (if line-prefix
1602               (cond ((string-prefix-p "*" line-prefix)
1603                      (concat
1604                       (replace-regexp-in-string "\\*"
1605                                                 elpher-gemini-bullet-string
1606                                                 (match-string 0 text-line))
1607                       (substring text-line (match-end 0))))
1608                     ((string-prefix-p ">" line-prefix)
1609                      (propertize text-line 'face 'elpher-gemini-quoted))
1610                     (t text-line))
1611             text-line))
1612          (fill-prefix (if line-prefix
1613                           (make-string (length (match-string 0 text-line)) ?\s)
1614                         "")))
1615     (insert (elpher-process-text-for-display processed-text-line))
1616     (newline)))
1617
1618 (defun elpher-gemini-pref-expand-collapse (button)
1619   "Function called when the preformatted text toggle BUTTON is activated."
1620   (let ((id (button-get button 'pref-id)))
1621     (if (invisible-p id)
1622         (remove-from-invisibility-spec id)
1623       (add-to-invisibility-spec id))
1624     (redraw-display)))
1625
1626 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1627   "Insert a button for toggling the visibility of preformatted text.
1628 If non-nil, ALT-TEXT is displayed alongside the button."
1629   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1630          (pref-id (intern (concat "pref-"
1631                                   (number-to-string (point))
1632                                   "-"
1633                                   url-string))))
1634     (insert elpher-gemini-preformatted-toggle-bullet)
1635     (when alt-text
1636       (insert (propertize (concat alt-text " ")
1637                           'face 'elpher-gemin-preformatted)))
1638     (insert-text-button elpher-gemini-preformatted-toggle-label
1639                         'action #'elpher-gemini-pref-expand-collapse
1640                         'pref-id pref-id
1641                         'face 'elpher-gemini-preformatted-toggle)
1642     (add-to-invisibility-spec pref-id)
1643     (newline)
1644     pref-id))
1645
1646 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1647   "Insert a LINE of preformatted text.
1648 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1649 can be used to toggle the display of the preformatted text."
1650   (insert (propertize (concat (elpher-process-text-for-display line) "\n")
1651                       'invisible pref-id
1652                       'rear-nonsticky t)))
1653
1654 (defun elpher-render-gemini-map (data _parameters)
1655   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1656   (elpher-with-clean-buffer
1657    (auto-fill-mode 1)
1658    (setq-local buffer-invisibility-spec nil)
1659    (let ((preformatted nil)
1660          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1661      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1662      (dolist (line (split-string data "\n"))
1663        (pcase line
1664          ((rx (: "```" (opt (let alt-text (+ any)))))
1665           (setq preformatted
1666                 (if preformatted
1667                     nil
1668                   (if elpher-gemini-hide-preformatted
1669                       (elpher-gemini-insert-preformatted-toggler alt-text)
1670                     t))))
1671          ((guard  preformatted)
1672           (elpher-gemini-insert-preformatted-line line preformatted))
1673          ((pred (string-prefix-p "=>"))
1674           (elpher-gemini-insert-link line))
1675          ((pred (string-prefix-p "=:"))
1676           (elpher-spartan-insert-query line))
1677          ((pred (string-prefix-p "#"))
1678           (elpher-gemini-insert-header line))
1679          (_ (elpher-gemini-insert-text line))))
1680    (elpher-cache-content
1681     (elpher-page-address elpher-current-page)
1682     (buffer-string)))))
1683
1684 (defun elpher-render-gemini-plain-text (data _parameters)
1685   "Render DATA as plain text file.  PARAMETERS is currently unused."
1686   (elpher-with-clean-buffer
1687    (insert (elpher-process-text-for-display data))
1688    (elpher-cache-content
1689     (elpher-page-address elpher-current-page)
1690     (buffer-string))))
1691
1692 (defun elpher-build-current-imenu-index ()
1693   "Build imenu index for current elpher buffer."
1694   (save-excursion
1695     (goto-char (point-min))
1696     (let ((match nil)
1697           (headers nil))
1698       (while (setq match (text-property-search-forward 'gemini-heading t t))
1699         (push (cons
1700                (buffer-substring-no-properties (prop-match-beginning match)
1701                                                (prop-match-end match))
1702                (prop-match-beginning match))
1703               headers))
1704       (reverse headers))))
1705
1706
1707 ;; Spartan page retrieval
1708
1709 (defvar elpher-spartan-redirect-chain)
1710
1711 (defun elpher-get-spartan-page (renderer)
1712   "Getter which retrieves and renders a Spartan page and renders it using RENDERER."
1713   (let* ((address (elpher-page-address elpher-current-page))
1714          (content (elpher-get-cached-content address)))
1715     (condition-case the-error
1716         (if (and content (funcall renderer nil))
1717             (elpher-with-clean-buffer
1718              (insert content)
1719              (elpher-restore-pos))
1720           (elpher-with-clean-buffer
1721            (insert "LOADING SPARTAN... (use 'u' to cancel)\n"))
1722           (setq elpher-spartan-redirect-chain nil)
1723           (elpher-get-spartan-response address renderer))
1724       (error
1725        (elpher-network-error address the-error)))))
1726
1727 (defun elpher-get-spartan-response (address renderer)
1728   "Get response string from spartan server at ADDRESS and render using RENDERER."
1729   (let* ((host (elpher-address-host address))
1730          (path-and-query (url-path-and-query address))
1731          (filename (car path-and-query))
1732          (data (cdr path-and-query))
1733          (data-len (length data)))
1734     (elpher-get-host-response address 300
1735                               (concat host " "
1736                                       filename " "
1737                                       (number-to-string data-len) "\r\n"
1738                                       data)
1739                               (lambda (response-string)
1740                                 (elpher-process-spartan-response response-string renderer)))))
1741
1742 (defun elpher-parse-spartan-response (response)
1743   "Parse the RESPONSE string and return a list of components.
1744 The list is of the form (code meta body).  A response of nil implies
1745 that the response was malformed."
1746   (let ((header-end-idx (string-match "\r\n" response)))
1747     (if header-end-idx
1748         (let ((header (string-trim (substring response 0 header-end-idx)))
1749               (body (substring response (+ header-end-idx 2))))
1750           (if (>= (length header) 2)
1751               (let ((code (substring header 0 1))
1752                     (meta (string-trim (substring header 1))))
1753                 (list code meta body))
1754             (error "Malformed response: No response status found in header %s" header)))
1755       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1756
1757 (defun elpher-process-spartan-response (response-string renderer)
1758   "Process the spartan response RESPONSE-STRING and pass the result to RENDERER."
1759   (let ((response-components (elpher-parse-spartan-response response-string)))
1760     (let ((response-code (elt response-components 0))
1761           (response-meta (elt response-components 1))
1762           (response-body (elt response-components 2)))
1763       (pcase (elt response-code 0)
1764         (?2 ; Normal response
1765          (funcall renderer response-body response-meta))
1766         (?3 ; Redirect
1767          (message "Following redirect to %s" response-meta)
1768          (if (>= (length elpher-spartan-redirect-chain) 5)
1769              (error "More than 5 consecutive redirects followed"))
1770          (let* ((current-address (elpher-page-address elpher-current-page))
1771                 (redirect-address (elpher-address-from-url
1772                                    (concat "spartan://"
1773                                            (elpher-address-host current-address)
1774                                            ":"
1775                                            (elpher-address-port current-address)
1776                                            "/"
1777                                            response-meta))))
1778            (if (member redirect-address elpher-spartan-redirect-chain)
1779                (error "Redirect loop detected"))
1780            (elpher-page-set-address elpher-current-page redirect-address)
1781            (add-to-list 'elpher-spartan-redirect-chain redirect-address)
1782            (elpher-get-spartan-response redirect-address renderer)))
1783         (?4 ; Client error
1784          (error "Spartan server reports CLIENT ERROR for this request: %s %s"
1785                 response-code response-meta))
1786         (?5 ; Server error
1787          (error "Spartan server reports SERVER ERROR for this request: %s %s"
1788                 response-code response-meta))
1789         (_other
1790          (error "Spartan server response unknown: %s %s"
1791                 response-code response-meta))))))
1792
1793 (defun elpher-spartan-insert-query (query-line)
1794   "Insert link described by QUERY-LINE into a text/gemini document."
1795   (let ((url (elpher-gemini-get-link-url query-line)))
1796     (when url
1797       (let* ((address (elpher-address-from-gemini-url url))
1798              (given-display-string (elpher-gemini-get-link-display-string query-line))
1799              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1800         (insert elpher-gemini-link-string)
1801         (let ((display-string (or given-display-string url)))
1802           (insert-text-button display-string
1803                               'face 'elpher-spartan-post
1804                               'display-string display-string
1805                               'url (elpher-address-to-url address)
1806                               'action #'elpher-spartan-post
1807                               'follow-link t
1808                               'help-echo #'elpher--page-button-help))
1809         (newline)))))
1810
1811 (defun elpher-spartan-post (button)
1812   "Function called when the spartan post link BUTTON is clicked."
1813   (let* ((display-string (button-get button 'display-string))
1814          (url (button-get button 'url))
1815          (post-url (concat url "?" (url-hexify-string (read-string "Text to post: ")))))
1816     (elpher-visit-page (elpher-make-page
1817                         display-string
1818                         (elpher-address-from-url post-url)))))
1819
1820 ;; Finger page connection
1821
1822 (defun elpher-get-finger-page (renderer)
1823   "Opens a finger connection to the current page address.
1824 The result is rendered using RENDERER."
1825   (let* ((address (elpher-page-address elpher-current-page))
1826          (content (elpher-get-cached-content address)))
1827     (if (and content (funcall renderer nil))
1828         (elpher-with-clean-buffer
1829          (insert content)
1830          (elpher-restore-pos))
1831       (elpher-with-clean-buffer
1832        (insert "LOADING... (use 'u' to cancel)\n"))
1833       (condition-case the-error
1834           (let* ((kill-buffer-query-functions nil)
1835                  (user (let ((filename (elpher-address-filename address)))
1836                          (if (> (length filename) 1)
1837                              (substring filename 1)
1838                            (elpher-address-user address)))))
1839             (elpher-get-host-response address 79
1840                                       (concat user "\r\n")
1841                                       renderer))
1842         (error
1843          (elpher-network-error address the-error))))))
1844
1845
1846 ;; Telnet page connection
1847
1848 (defun elpher-get-telnet-page (renderer)
1849   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1850   (when renderer
1851     (elpher-visit-previous-page)
1852     (error "Command not supported for telnet URLs"))
1853   (let* ((address (elpher-page-address elpher-current-page))
1854          (host (elpher-address-host address))
1855          (port (elpher-address-port address)))
1856     (elpher-visit-previous-page)
1857     (if (> port 0)
1858         (telnet host port)
1859       (telnet host))))
1860
1861
1862 ;; Other URL page opening
1863
1864 (defun elpher-get-other-url-page (renderer)
1865   "Getter which attempts to open the URL specified by the current page.
1866 The RENDERER argument to this getter must be nil."
1867   (when renderer
1868     (elpher-visit-previous-page)
1869     (error "Command not supported for general URLs"))
1870   (let* ((address (elpher-page-address elpher-current-page))
1871          (url (elpher-address-to-url address)))
1872     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1873     (message "Opening URL...")
1874     (if elpher-open-urls-with-eww
1875         (browse-web url)
1876       (browse-url url))))
1877
1878
1879 ;; File page
1880
1881 (defun elpher-get-file-page (renderer)
1882   "Getter which renders a local file using RENDERER.
1883 Assumes UTF-8 encoding for all text files."
1884   (let* ((address (elpher-page-address elpher-current-page))
1885          (filename (elpher-address-filename address)))
1886     (unless (file-exists-p filename)
1887       (elpher-visit-previous-page)
1888         (error "File not found"))
1889     (unless (file-readable-p filename)
1890       (elpher-visit-previous-page)
1891         (error "Could not read from file"))
1892     (let ((body (with-temp-buffer
1893        (let ((coding-system-for-read 'binary)
1894              (coding-system-for-write 'binary))
1895          (insert-file-contents-literally filename)
1896          (encode-coding-string (buffer-string) 'raw-text)))))
1897        (if renderer
1898            (funcall renderer body nil)
1899          (pcase (file-name-extension filename)
1900            ((or  "gmi" "gemini")
1901             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1902            ((or "htm" "html")
1903             (elpher-render-html (decode-coding-string body 'utf-8)))
1904            ((or "txt" "")
1905             (elpher-render-text (decode-coding-string body 'utf-8)))
1906            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1907             (elpher-render-image body))
1908            ((or "gopher" "gophermap")
1909             (elpher-render-index (elpher-decode body)))
1910            (_
1911             (elpher-render-download body))))
1912        (elpher-restore-pos))))
1913
1914
1915 ;; Welcome page retrieval
1916
1917 (defun elpher-get-welcome-page (renderer)
1918   "Getter which displays the welcome page (RENDERER must be nil)."
1919   (when renderer
1920     (elpher-visit-previous-page)
1921     (error "Command not supported for welcome page"))
1922   (elpher-with-clean-buffer
1923    (insert "     --------------------------------------------\n"
1924            "           Elpher Gopher and Gemini Client       \n"
1925            "                   version " elpher-version "\n"
1926            "     --------------------------------------------\n"
1927            "\n"
1928            "Default bindings:\n"
1929            "\n"
1930            " - TAB/Shift-TAB: next/prev item on current page\n"
1931            " - RET/mouse-1: open item under cursor\n"
1932            " - m: select an item on current page by name (autocompletes)\n"
1933            " - u/mouse-3/U: return to previous page or to the start page\n"
1934            " - g: go to a particular address (gopher, gemini, finger)\n"
1935            " - o/O: open a different address selector or the root menu of the current server\n"
1936            " - d/D: download item under cursor or current page\n"
1937            " - i/I: info on item under cursor or current page\n"
1938            " - c/C: copy URL representation of item under cursor or current page\n"
1939            " - a/A: bookmark the item under cursor or current page\n"
1940            " - B: list all bookmarks\n"
1941            " - s/S: show current history stack or all previously visted pages\n"
1942            " - r: redraw current page (using cached contents if available)\n"
1943            " - R: reload current page (regenerates cache)\n"
1944            " - !: set character coding system for gopher (default is to autodetect)\n"
1945            " - T: toggle TLS gopher mode\n"
1946            " - F: forget/discard current TLS client certificate\n"
1947            " - .: display the raw server response for the current page\n"
1948            "\n"
1949            "Start your exploration of gopher space and gemini:\n")
1950    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1951                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1952    (elpher-insert-index-record "Project Gemini home page"
1953                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1954    (insert "\n"
1955            "Alternatively, select a search engine and enter some search terms:\n")
1956    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1957                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1958    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1959                                (elpher-address-from-url "gemini://geminispace.info/search"))
1960    (insert "\n"
1961            "Your bookmarks are stored in your ")
1962    (insert-text-button "bookmark list"
1963                        'face 'link
1964                        'action #'elpher-click-link
1965                        'follow-link t
1966                        'help-echo #'elpher--page-button-help
1967                        'elpher-page
1968                        (elpher-make-page "Elpher Bookmarks"
1969                                          (elpher-make-about-address 'bookmarks)))
1970    (insert ".\n")
1971    (insert (propertize
1972             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1973             'face 'shadow))
1974    (insert "\n"
1975            "The gopher home of the Elpher project is here:\n")
1976    (elpher-insert-index-record "The Elpher Project Page"
1977                                (elpher-make-gopher-address ?1
1978                                                            "/projects/elpher/"
1979                                                            "thelambdalab.xyz"
1980                                                            70))
1981    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1982      (insert "\n"
1983              "The following info documentation is available:\n"
1984              "   - ")
1985      (insert-text-button "Elpher Manual"
1986                          'face 'link
1987                          'action (lambda (_)
1988                                    (interactive)
1989                                    (info "(elpher)"))
1990                          'follow-link t
1991                          'help-echo help-string)
1992      (insert "\n   - ")
1993      (insert-text-button "Changes introduced by the latest release"
1994                        'face 'link
1995                        'action (lambda (_)
1996                                  (interactive)
1997                                  (info "(elpher)News"))
1998                        'follow-link t
1999                        'help-echo help-string))
2000    (insert "\n")
2001    (insert (propertize
2002             (concat "(These documents should be available if you have installed Elpher\n"
2003                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
2004                     " manual yourself.)\n")
2005             'face 'shadow))
2006    (elpher-restore-pos)))
2007
2008
2009 ;; History page retrieval
2010
2011 (defun elpher-show-history ()
2012   "Show the current contents of elpher's history stack.
2013 Use \\[elpher-show-visited-pages] to see the entire history.
2014 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
2015   (interactive)
2016   (elpher-visit-page
2017    (elpher-make-page "Current History Stack"
2018                      (elpher-make-about-address 'history))))
2019
2020 (defun elpher-show-visited-pages ()
2021   "Show the all the pages you've visited using Elpher.
2022 Use \\[elpher-show-history] to see just the current history stack.
2023 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
2024   (interactive)
2025   (elpher-visit-page
2026    (elpher-make-page "Elpher Visted Pages"
2027                      (elpher-make-about-address 'visited-pages))))
2028
2029 (defun elpher-get-history-page (renderer)
2030   "Getter which displays the history page (RENDERER must be nil)."
2031   (when renderer
2032     (elpher-visit-previous-page)
2033     (error "Command not supported for history page"))
2034   (elpher-display-history-links elpher-history "Current history stack"))
2035
2036 (defun elpher-get-visited-pages-page (renderer)
2037   "Getter which displays the list of visited pages (RENDERER must be nil)."
2038   (when renderer
2039     (elpher-visit-previous-page)
2040     (error "Command not supported for history page"))
2041   (elpher-display-history-links
2042    (seq-filter (lambda (page)
2043                  (not (elpher-address-about-p (elpher-page-address page))))
2044                elpher-visited-pages)
2045    "All visited pages"))
2046
2047 (defun elpher-display-history-links (pages title)
2048   "Show all PAGES in an Elpher buffer with a given TITLE."
2049   (let* ((title-line (concat " ---- " title " ----"))
2050          (footer-line (make-string (length title-line) ?-)))
2051     (elpher-with-clean-buffer
2052      (insert title-line "\n\n")
2053      (if pages
2054          (dolist (page pages)
2055            (when page
2056              (let ((display-string (elpher-page-display-string page))
2057                    (address (elpher-page-address page)))
2058                (elpher-insert-index-record display-string address))))
2059        (insert "No history items found.\n"))
2060      (insert "\n " footer-line "\n"
2061              "Select an entry or press 'u' to return to the previous page.")
2062      (elpher-restore-pos))))
2063
2064
2065 ;;; Bookmarks
2066
2067 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
2068 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
2069 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
2070 ;; so on. See the Bookmarks section in the Emacs info manual for more.
2071
2072 (defvar elpher-bookmark-link nil
2073   "Prefer bookmarking a link or the current page.
2074 Bind this variable dynamically, or set it to t.
2075 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2076 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2077
2078 (defun elpher-bookmark-make-record ()
2079   "Return a bookmark record.
2080 If `elpher-bookmark-link' is non-nil and point is on a link button,
2081 return a bookmark record for that link.  Otherwise, return a bookmark
2082 record for the current elpher page."
2083   (let* ((button (and elpher-bookmark-link (button-at (point))))
2084          (page (if button
2085                    (button-get button 'elpher-page)
2086                  elpher-current-page)))
2087     (unless page
2088       (error "Cannot bookmark this link"))
2089     (let* ((address (elpher-page-address page))
2090            (url (elpher-address-to-url address))
2091            (display-string (elpher-page-display-string page))
2092            (pos (if button nil (point))))
2093       (if (elpher-address-about-p address)
2094           (error "Cannot bookmark %s" display-string)
2095         `(,display-string
2096           (defaults . (,display-string))
2097           (position . ,pos)
2098           (location . ,url)
2099           (handler . elpher-bookmark-jump))))))
2100
2101 ;;;###autoload
2102 (defun elpher-bookmark-jump (bookmark)
2103   "Handler used to open a bookmark using elpher.
2104 The argument BOOKMARK is a bookmark record passed to the function.
2105 This handler is responsible for loading the bookmark in some buffer,
2106 then making that buffer the current buffer.  It should not switch
2107 to the buffer."
2108   (let* ((url (cdr (assq 'location bookmark)))
2109          (cleaned-url (string-trim url))
2110          (page (elpher-page-from-url cleaned-url))
2111          (buffer (get-buffer-create elpher-buffer-name)))
2112     (elpher-with-clean-buffer
2113      (elpher-visit-page page))
2114     (set-buffer buffer)
2115     nil))
2116
2117 (defun elpher-bookmark-link ()
2118   "Bookmark the link at point.
2119 To bookmark the current page, use \\[elpher-bookmark-current]."
2120   (interactive)
2121   (let ((elpher-bookmark-link t))
2122     (bookmark-set-no-overwrite)))
2123
2124 (defun elpher-bookmark-current ()
2125   "Bookmark the current page.
2126 To bookmark the link at point use \\[elpher-bookmark-link]."
2127   (interactive)
2128   (call-interactively #'bookmark-set-no-overwrite))
2129
2130 (defun elpher-bookmark-import (file)
2131   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2132   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2133                               (file-readable-p elpher-bookmarks-file))
2134                          elpher-bookmarks-file
2135                        (read-file-name "Old Elpher bookmarks: "
2136                                        user-emacs-directory nil t
2137                                        "elpher-bookmarks"))))
2138   (dolist (bookmark (with-temp-buffer
2139                       (insert-file-contents file)
2140                       (read (current-buffer))))
2141     (let* ((display-string (car bookmark))
2142            (url (cadr bookmark))
2143            (record `(,display-string
2144                      (location . ,url)
2145                      (handler . elpher-bookmark-jump))))
2146       (bookmark-store display-string (cdr record) t)))
2147   (bookmark-save))
2148
2149 (defun elpher-get-bookmarks-page (renderer)
2150   "Getter which displays the bookmarks (RENDERER must be nil)."
2151   (when renderer
2152     (elpher-visit-previous-page)
2153     (error "Command not supported for bookmarks page"))
2154
2155   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2156                                      elpher-bookmarks-file)
2157                                 (locate-user-emacs-file "elpher-bookmarks"))))
2158     (when (and (file-readable-p old-bookmarks-file)
2159                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2160                                  old-bookmarks-file
2161                                  "\" found. Import now?")))
2162       (elpher-bookmark-import old-bookmarks-file)
2163       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2164
2165   (if (and elpher-use-emacs-bookmark-menu
2166            elpher-history)
2167       (progn
2168         (elpher-visit-previous-page)
2169         (call-interactively #'bookmark-bmenu-list))
2170     (elpher-with-clean-buffer
2171      (insert " ---- Elpher Bookmarks ---- \n\n")
2172      (bookmark-maybe-load-default-file)
2173      (dolist (bookmark (bookmark-maybe-sort-alist))
2174        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2175          (let* ((name (car bookmark))
2176                 (url (alist-get 'location (cdr bookmark)))
2177                 (address (elpher-address-from-url url)))
2178            (elpher-insert-index-record name address))))
2179      (when (<= (line-number-at-pos) 3)
2180        (insert "No bookmarked pages found.\n"))
2181      (insert "\n --------------------------\n\n"
2182              "Select an entry or press 'u' to return to the previous page.\n\n"
2183              "Bookmarks can be renamed or deleted via the ")
2184      (insert-text-button "Emacs bookmark menu"
2185                          'action (lambda (_)
2186                                    (interactive)
2187                                    (call-interactively #'bookmark-bmenu-list))
2188                          'follow-link t
2189                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2190      (insert (substitute-command-keys
2191               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2192      (elpher-restore-pos))))
2193
2194 (defun elpher-show-bookmarks ()
2195   "Interactive function to display the current list of elpher bookmarks."
2196   (interactive)
2197   (elpher-visit-page
2198    (elpher-make-page "Elpher Bookmarks"
2199                      (elpher-make-about-address 'bookmarks))))
2200
2201
2202 ;;; Integrations
2203 ;;
2204
2205 ;;; Org
2206
2207 (defun elpher-org-export-link (link description format protocol)
2208   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2209
2210 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2211 of gemini, gopher or finger."
2212   (let* ((url (if (equal protocol "elpher")
2213                   (string-remove-prefix "elpher:" link)
2214                 (format "%s:%s" protocol link)))
2215          (desc (or description url)))
2216     (pcase format
2217       (`gemini (format "=> %s %s" url desc))
2218       (`html (format "<a href=\"%s\">%s</a>" url desc))
2219       (`latex (format "\\href{%s}{%s}" url desc))
2220       (_ (if (not description)
2221              url
2222            (format "%s (%s)" desc url))))))
2223
2224 (defun elpher-org-store-link ()
2225   "Store link to an `elpher' page in Org."
2226   (when (eq major-mode 'elpher-mode)
2227     (let* ((url (elpher-info-current))
2228            (desc (car elpher-current-page))
2229            (protocol (cond
2230                       ((string-prefix-p "gopher:" url) "gopher")
2231                       ((string-prefix-p "finger:" url) "finger")
2232                       ((string-prefix-p "gemini:" url) "gemini")
2233                       ((string-prefix-p "spartan:" url) "spartan")
2234                       (t "elpher"))))
2235       (when (equal "elpher" protocol)
2236         ;; Weird link. Or special inner link?
2237         (setq url (concat "elpher:" url)))
2238       (org-link-store-props :type protocol :link url :description desc)
2239       t)))
2240
2241 (defun elpher-org-follow-link (link protocol)
2242   "Visit a LINK for the given PROTOCOL.
2243
2244 PROTOCOL may be one of gemini, gopher or finger.  This method also
2245 supports the old protocol elpher, where the link is self-contained."
2246   (let ((url (if (equal protocol "elpher")
2247                  (string-remove-prefix "elpher:" link)
2248                (format "%s:%s" protocol link))))
2249     (elpher-go url)))
2250
2251 (defun elpher-org-mode-integration ()
2252   "Set up `elpher' integration for `org-mode'."
2253   (org-link-set-parameters
2254    "elpher"
2255    :store #'elpher-org-store-link
2256    :export (lambda (link description format _plist)
2257              (elpher-org-export-link link description format "elpher"))
2258    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2259   (org-link-set-parameters
2260    "gemini"
2261    :export (lambda (link description format _plist)
2262              (elpher-org-export-link link description format "gemini"))
2263    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2264   (org-link-set-parameters
2265    "gopher"
2266    :export (lambda (link description format _plist)
2267              (elpher-org-export-link link description format "gopher"))
2268    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2269   (org-link-set-parameters
2270    "spartan"
2271    :export (lambda (link description format _plist)
2272              (elpher-org-export-link link description format "spartan"))
2273    :follow (lambda (link _arg) (elpher-org-follow-link link "spartan")))
2274   (org-link-set-parameters
2275    "finger"
2276    :export (lambda (link description format _plist)
2277              (elpher-org-export-link link description format "finger"))
2278    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2279
2280 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2281
2282 ;;; Browse URL
2283
2284 ;;;###autoload
2285 (defun elpher-browse-url-elpher (url &rest _args)
2286   "Browse URL using Elpher.  This function is used by `browse-url'."
2287   (interactive (browse-url-interactive-arg "Elpher URL: "))
2288   (elpher-go url))
2289
2290 ;; Use elpher to open gopher, finger and gemini links
2291 ;; For recent version of `browse-url' package
2292 (if (boundp 'browse-url-default-handlers)
2293     (add-to-list
2294      'browse-url-default-handlers
2295      '("^\\(gopher\\|finger\\|gemini\\|spartan\\)://" . elpher-browse-url-elpher))
2296   ;; Patch `browse-url-browser-function' for older ones. The value of
2297   ;; that variable is `browse-url-default-browser' by default, so
2298   ;; that's the function that gets advised. If the value is an alist,
2299   ;; however, we don't know what to do. Better not interfere?
2300   (when (and (symbolp browse-url-browser-function)
2301              (fboundp browse-url-browser-function))
2302     (advice-add browse-url-browser-function :before-while
2303                 (lambda (url &rest _args)
2304                   "Handle gemini, gopher, and finger schemes using Elpher."
2305                   (let ((scheme (downcase (car (split-string url ":" t)))))
2306                     (if (member scheme '("gopher" "gemini" "spartan" "finger"))
2307                         ;; `elpher-go' always returns nil, which will stop the
2308                         ;; advice chain here in a before-while
2309                         (elpher-go url)
2310                       ;; chain must continue, then return t.
2311                       t))))))
2312
2313 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2314 (with-eval-after-load 'thingatpt
2315   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2316
2317 ;;; Mu4e:
2318
2319 ;; Make mu4e aware of the gemini world
2320 (setq mu4e~view-beginning-of-url-regexp
2321       "\\(?:https?\\|gopher\\|finger\\|gemini\\|spartan\\)://\\|mailto:")
2322
2323 ;;; eww:
2324
2325 ;; Let elpher handle gemini, gopher links in eww buffer.
2326 (setq eww-use-browse-url
2327       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\|\\`spartan\\)://")
2328
2329
2330 ;;; Interactive procedures
2331 ;;
2332
2333 (defun elpher-next-link ()
2334   "Move point to the next link on the current page."
2335   (interactive)
2336   (forward-button 1))
2337
2338 (defun elpher-prev-link ()
2339   "Move point to the previous link on the current page."
2340   (interactive)
2341   (backward-button 1))
2342
2343 (defun elpher-follow-current-link ()
2344   "Open the link or url at point."
2345   (interactive)
2346   (push-button))
2347
2348 ;;;###autoload
2349 (defun elpher-go (host-or-url)
2350   "Go to a particular gopher site HOST-OR-URL.
2351 When run interactively HOST-OR-URL is read from the minibuffer."
2352   (interactive (list
2353                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2354   (let ((trimmed-host-or-url (string-trim host-or-url)))
2355     (unless (string-empty-p trimmed-host-or-url)
2356       (let ((page (elpher-page-from-url trimmed-host-or-url
2357                                         (elpher-get-default-url-scheme))))
2358         (unless (get-buffer-window elpher-buffer-name t)
2359           (switch-to-buffer elpher-buffer-name))
2360         (elpher-with-clean-buffer
2361          (elpher-visit-page page))
2362         nil)))) ; non-nil value is displayed by eshell
2363
2364 (defun elpher-go-current ()
2365   "Go to a particular URL which is read from the minibuffer.
2366 Unlike `elpher-go', the reader is initialized with the URL of the
2367 current page."
2368   (interactive)
2369   (let* ((address (elpher-page-address elpher-current-page))
2370          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2371                            (elpher-address-to-url address))))
2372     (unless (string-empty-p (string-trim url))
2373       (elpher-visit-page (elpher-page-from-url url)))))
2374
2375 (defun elpher-redraw ()
2376   "Redraw current page."
2377   (interactive)
2378   (elpher-visit-page elpher-current-page))
2379
2380 (defun elpher-reload ()
2381   "Reload current page."
2382   (interactive)
2383   (elpher-reload-current-page))
2384
2385 (defun elpher-toggle-tls ()
2386   "Toggle TLS encryption mode for gopher."
2387   (interactive)
2388   (setq elpher-use-tls (not elpher-use-tls))
2389   (if elpher-use-tls
2390       (if (gnutls-available-p)
2391           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2392         (setq elpher-use-tls nil)
2393         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2394     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2395
2396 (defun elpher-view-raw ()
2397   "View raw server response for current page."
2398   (interactive)
2399   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2400       (error "This page was not generated by a server")
2401     (elpher-visit-page elpher-current-page
2402                        #'elpher-render-raw)))
2403
2404 (defun elpher-back ()
2405   "Go to previous site."
2406   (interactive)
2407   (elpher-visit-previous-page))
2408
2409 (defun elpher-back-to-start ()
2410   "Go all the way back to the start page."
2411   (interactive)
2412   (setq-local elpher-current-page nil)
2413   (setq-local elpher-history nil)
2414   (elpher-visit-page (elpher-make-start-page)))
2415
2416 (defun elpher-download ()
2417   "Download the link at point."
2418   (interactive)
2419   (let ((button (button-at (point))))
2420     (if button
2421         (let ((page (button-get button 'elpher-page)))
2422           (unless page
2423             (error "Not an elpher page"))
2424           (when (elpher-address-about-p (elpher-page-address page))
2425             (error "Cannot download %s" (elpher-page-display-string page)))
2426           (elpher-visit-page (button-get button 'elpher-page)
2427                              #'elpher-render-download))
2428       (error "No link selected"))))
2429
2430 (defun elpher-download-current ()
2431   "Download the current page."
2432   (interactive)
2433   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2434       (error "Cannot download %s"
2435              (elpher-page-display-string elpher-current-page))
2436     (elpher-visit-page (elpher-make-page
2437                         (elpher-page-display-string elpher-current-page)
2438                         (elpher-page-address elpher-current-page))
2439                        #'elpher-render-download
2440                        t)))
2441
2442 (defun elpher--build-link-map ()
2443   "Build alist mapping link names to destination pages in current buffer."
2444   (let ((link-map nil)
2445         (b (next-button (point-min) t)))
2446     (while b
2447       (push (cons (button-label b) b) link-map)
2448       (setq b (next-button (button-start b))))
2449     link-map))
2450
2451 (defun elpher-jump ()
2452   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2453   (interactive)
2454   (let* ((link-map (elpher--build-link-map)))
2455     (if link-map
2456         (let ((key (let ((completion-ignore-case t))
2457                      (completing-read "Directory item/link: "
2458                                       link-map nil t))))
2459           (if (and key (> (length key) 0))
2460               (let ((b (cdr (assoc key link-map))))
2461                 (goto-char (button-start b))
2462                 (button-activate b)))))))
2463
2464 (defun elpher-root-dir ()
2465   "Visit root of current server."
2466   (interactive)
2467   (let ((address (elpher-page-address elpher-current-page)))
2468     (if (not (elpher-address-about-p address))
2469         (if (or (member (url-filename address) '("/" ""))
2470                 (and (elpher-address-gopher-p address)
2471                      (= (length (elpher-gopher-address-selector address)) 0)))
2472             (error "Already at root directory of current server")
2473           (let ((address-copy (elpher-address-from-url
2474                                (elpher-address-to-url address))))
2475             (setf (url-filename address-copy) "")
2476             (elpher-go (elpher-address-to-url address-copy))))
2477       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2478
2479 (defun elpher-info-page (page)
2480   "Display URL of PAGE in minibuffer."
2481   (let* ((address (elpher-page-address page))
2482          (url (elpher-address-to-url address))
2483          (iri (elpher-address-to-iri address)))
2484     (if (equal url iri)
2485         (message "%s" url)
2486       (message "%s (Raw: %s)" iri url))))
2487
2488 (defun elpher-info-link ()
2489   "Display information on page corresponding to link at point."
2490   (interactive)
2491   (let ((button (button-at (point))))
2492     (unless button
2493       (error "No item selected"))
2494     (let ((page (button-get button 'elpher-page)))
2495       (unless page
2496         (error "Not an elpher page"))
2497       (elpher-info-page page))))
2498
2499 (defun elpher-info-current ()
2500   "Display information on current page."
2501   (interactive)
2502   (elpher-info-page elpher-current-page))
2503
2504 (defun elpher-copy-page-url (page)
2505   "Copy URL representation of address of PAGE to `kill-ring'."
2506   (let* ((address (elpher-page-address page))
2507          (url (elpher-address-to-url address)))
2508     (message "Copied \"%s\" to kill-ring/clipboard." url)
2509     (kill-new url)))
2510
2511 (defun elpher-copy-link-url ()
2512   "Copy URL of item at point to `kill-ring'."
2513   (interactive)
2514   (let ((button (button-at (point))))
2515     (unless button
2516       (error "No item selected"))
2517     (let ((page (button-get button 'elpher-page)))
2518       (unless page
2519         (error "Not an elpher page"))
2520       (elpher-copy-page-url page))))
2521
2522 (defun elpher-copy-current-url ()
2523   "Copy URL of current page to `kill-ring'."
2524   (interactive)
2525   (elpher-copy-page-url elpher-current-page))
2526
2527 (defun elpher-set-gopher-coding-system ()
2528   "Specify an explicit character coding system for gopher selectors."
2529   (interactive)
2530   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2531     (setq elpher-user-coding-system system)
2532     (if system
2533         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2534       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2535
2536
2537 ;;; Mode and keymap
2538 ;;
2539
2540 (defvar elpher-mode-map
2541   (let ((map (make-sparse-keymap)))
2542     (define-key map (kbd "TAB") 'elpher-next-link)
2543     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2544     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2545     (define-key map (kbd "u") 'elpher-back)
2546     (define-key map (kbd "-") 'elpher-back)
2547     (define-key map (kbd "^") 'elpher-back)
2548     (define-key map [mouse-3] 'elpher-back)
2549     (define-key map (kbd "U") 'elpher-back-to-start)
2550     (define-key map (kbd "g") 'elpher-go)
2551     (define-key map (kbd "o") 'elpher-go-current)
2552     (define-key map (kbd "O") 'elpher-root-dir)
2553     (define-key map (kbd "s") 'elpher-show-history)
2554     (define-key map (kbd "S") 'elpher-show-visited-pages)
2555     (define-key map (kbd "r") 'elpher-redraw)
2556     (define-key map (kbd "R") 'elpher-reload)
2557     (define-key map (kbd "T") 'elpher-toggle-tls)
2558     (define-key map (kbd ".") 'elpher-view-raw)
2559     (define-key map (kbd "d") 'elpher-download)
2560     (define-key map (kbd "D") 'elpher-download-current)
2561     (define-key map (kbd "m") 'elpher-jump)
2562     (define-key map (kbd "i") 'elpher-info-link)
2563     (define-key map (kbd "I") 'elpher-info-current)
2564     (define-key map (kbd "c") 'elpher-copy-link-url)
2565     (define-key map (kbd "C") 'elpher-copy-current-url)
2566     (define-key map (kbd "a") 'elpher-bookmark-link)
2567     (define-key map (kbd "A") 'elpher-bookmark-current)
2568     (define-key map (kbd "B") 'elpher-show-bookmarks)
2569     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2570     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2571     (when (fboundp 'evil-define-key*)
2572       (evil-define-key*
2573        'motion map
2574        (kbd "TAB") 'elpher-next-link
2575        (kbd "C-") 'elpher-follow-current-link
2576        (kbd "C-t") 'elpher-back
2577        (kbd "u") 'elpher-back
2578        (kbd "-") 'elpher-back
2579        (kbd "^") 'elpher-back
2580        [mouse-3] 'elpher-back
2581        (kbd "U") 'elpher-back-to-start
2582        (kbd "g") 'elpher-go
2583        (kbd "o") 'elpher-go-current
2584        (kbd "O") 'elpher-root-dir
2585        (kbd "s") 'elpher-show-history
2586        (kbd "S") 'elpher-show-visited-pages
2587        (kbd "r") 'elpher-redraw
2588        (kbd "R") 'elpher-reload
2589        (kbd "T") 'elpher-toggle-tls
2590        (kbd ".") 'elpher-view-raw
2591        (kbd "d") 'elpher-download
2592        (kbd "D") 'elpher-download-current
2593        (kbd "m") 'elpher-jump
2594        (kbd "i") 'elpher-info-link
2595        (kbd "I") 'elpher-info-current
2596        (kbd "c") 'elpher-copy-link-url
2597        (kbd "C") 'elpher-copy-current-url
2598        (kbd "a") 'elpher-bookmark-link
2599        (kbd "A") 'elpher-bookmark-current
2600        (kbd "B") 'elpher-show-bookmarks
2601        (kbd "!") 'elpher-set-gopher-coding-system
2602        (kbd "F") 'elpher-forget-current-certificate))
2603     map)
2604   "Keymap for gopher client.")
2605
2606 (define-derived-mode elpher-mode special-mode "elpher"
2607   "Major mode for elpher, an elisp gopher client.
2608
2609 This mode is automatically enabled by the interactive
2610 functions which initialize the client, namely
2611 `elpher', and `elpher-go'."
2612   (setq-local elpher-current-page nil)
2613   (setq-local elpher-history nil)
2614   (setq-local elpher-buffer-name (buffer-name))
2615   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2616   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2617
2618 (when (fboundp 'evil-set-initial-state)
2619   (evil-set-initial-state 'elpher-mode 'motion))
2620
2621
2622 ;;; Main start procedure
2623 ;;
2624
2625 ;;;###autoload
2626 (defun elpher (&optional arg)
2627   "Start elpher with default landing page.
2628 The buffer used for Elpher sessions is determined by the value of
2629 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2630 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2631 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2632 \\[execute-extended-command] elpher RET’) switches to the session with
2633 that number, creating it if necessary.  A non numeric prefix ARG means
2634 to create a new session.  Returns the buffer selected (or created)."
2635   (interactive "P")
2636   (let* ((name (default-value 'elpher-buffer-name))
2637          (buf (cond ((numberp arg)
2638                      (get-buffer-create (format "%s<%d>" name arg)))
2639                     (arg
2640                      (generate-new-buffer name))
2641                     (t
2642                      (get-buffer-create name)))))
2643     (pop-to-buffer-same-window buf)
2644     (unless (buffer-modified-p)
2645       (elpher-mode)
2646       (elpher-visit-page (elpher-make-start-page))
2647       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2648
2649 ;;; elpher.el ends here