elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 3.0.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: https://thelambdalab.xyz/elpher
  25 ;; Package-Requires: ((emacs "27.1"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - gopher connections using TLS encryption,
  54 ;; - the fledgling Gemini protocol,
  55 ;; - the greybeard Finger protocol.
  56
  57 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  58 ;; page containing information on key bindings and suggested starting
  59 ;; points for your gopher exploration.
  60
  61 ;; Full instructions can be found in the Elpher info manual.
  62
  63 ;; Elpher is under active development.  Any suggestions for
  64 ;; improvements are welcome, and can be made on the official
  65 ;; project page, gopher://thelambdalab.xyz/elpher, or via the
  66 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  67
  68 ;;; Code:
  69
  70 (provide 'elpher)
  71
  72 ;;; Dependencies
  73 ;;
  74
  75 (require 'seq)
  76 (require 'pp)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'dns)
  81 (require 'nsm)
  82 (require 'gnutls)
  83 (require 'socks)
  84
  85 ;;; ANSI colors or XTerm colors
  86
  87 (or (require 'xterm-color nil t)
  88     (require 'ansi-color))
  89
  90 (defalias 'elpher-color-filter-apply
  91   (if (fboundp 'xterm-color-filter)
  92       (lambda (s)
  93         (let ((_xterm-color-render nil))
  94           (xterm-color-filter s)))
  95     'ansi-color-filter-apply)
  96   "A function to filter out ANSI escape sequences.")
  97
  98 (defalias 'elpher-color-apply
  99   (if (fboundp 'xterm-color-filter)
 100       'xterm-color-filter
 101     'ansi-color-apply)
 102   "A function to apply ANSI escape sequences.")
 103
 104 ;;; Global constants
 105 ;;
 106
 107 (defconst elpher-version "3.0.0"
 108   "Current version of elpher.")
 109
 110 (defconst elpher-margin-width 6
 111   "Width of left-hand margin used when rendering indicies.")
 112
 113 (defconst elpher-type-map
 114   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 115     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 116     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 117     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 118     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 119     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 120     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 122     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 123     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 124     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 125     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 126     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 127     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 128     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 129     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 130     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 131     ((special start) elpher-get-start-page nil "E" elpher-index)
 132     ((special history) elpher-get-history-page nil "E" elpher-index)
 133     ((special visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 134   "Association list from types to getters, renderers, margin codes and index faces.")
 135
 136
 137 ;;; Internal variables
 138 ;;
 139
 140 ;; buffer-local
 141 (defvar elpher--gemini-page-headings nil
 142   "List of headings on the page.")
 143
 144
 145 ;;; Declarations to avoid compiler warnings.
 146 ;;
 147
 148 (eval-when-compile
 149   (defvar bookmark-make-record-function)
 150   (declare-function bookmark-store "bookmark")
 151   (declare-function org-link-store-props "ol")
 152   (declare-function org-link-set-parameters "ol")
 153   (defvar thing-at-point-uri-schemes)
 154   (defvar mu4e~view-beginning-of-url-regexp))
 155
 156
 157 ;;; Customization group
 158 ;;
 159
 160 (defgroup elpher nil
 161   "A gopher and gemini client."
 162   :group 'applications)
 163
 164 ;; General appearance and customizations
 165
 166 (defcustom elpher-open-urls-with-eww nil
 167   "If non-nil, open URL selectors using eww.
 168 Otherwise, use the system browser via the `browse-url' function."
 169   :type '(boolean))
 170
 171 (defcustom elpher-use-header t
 172   "If non-nil, display current page information in buffer header."
 173   :type '(boolean))
 174
 175 (defcustom elpher-auto-disengage-TLS nil
 176   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 177 While enabling this may seem convenient, it is also potentially
 178 dangerous as it allows switching from an encrypted channel back to
 179 plain text without user input."
 180   :type '(boolean))
 181
 182 (defcustom elpher-connection-timeout 5
 183   "Specifies the number of seconds to wait for a network connection to time out."
 184   :type '(integer))
 185
 186 (defcustom elpher-filter-ansi-from-text nil
 187   "If non-nil, filter ANSI escape sequences from text.
 188 The default behaviour is to use the ansi-color package to interpret these
 189 sequences."
 190   :type '(boolean))
 191
 192 (defcustom elpher-certificate-directory
 193   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 194   "Specify the name of the directory where client certificates will be stored.
 195 These certificates may be used for establishing authenticated TLS connections."
 196   :type '(directory))
 197
 198 (defcustom elpher-openssl-command "openssl"
 199   "The command used to launch openssl when generating TLS client certificates."
 200   :type '(file))
 201
 202 (defcustom elpher-default-url-type "gopher"
 203   "Default URL type (i.e. scheme) to assume if not explicitly given."
 204   :type '(choice (const "gopher")
 205                  (const "gemini")))
 206
 207 (defcustom elpher-gemini-TLS-cert-checks nil
 208   "If non-nil, verify gemini server TLS certs using the default security level.
 209 Otherwise, certificate verification is disabled.
 210
 211 This defaults to off because it is standard practice for Gemini servers
 212 to use self-signed certificates, meaning that most servers provide what
 213 EMACS considers to be an invalid certificate."
 214   :type '(boolean))
 215
 216 (defcustom elpher-gemini-max-fill-width 80
 217   "Specify the maximum default width (in columns) of text/gemini documents.
 218 The actual width used is the minimum of this value and the window width at
 219 the time when the text is rendered."
 220   :type '(integer))
 221
 222 (defcustom elpher-gemini-link-string "→ "
 223   "Specify the string used to indicate links when rendering gemini maps.
 224 May be empty."
 225   :type '(string))
 226
 227 (defcustom elpher-gemini-bullet-string "•"
 228   "Specify the string used for bullets when rendering gemini maps."
 229   :type '(string))
 230
 231 (defcustom elpher-ipv4-always nil
 232   "If non-nil, elpher will always use IPv4 to establish network connections.
 233 This can be useful when browsing from a computer that supports IPv6, because
 234 some servers which do not support IPv6 can take a long time to time-out."
 235   :type '(boolean))
 236
 237 (defcustom elpher-socks-always nil
 238   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 239 Otherwise, the SOCKS proxy is only used for connections to onion services."
 240   :type '(boolean))
 241
 242 ;; Face customizations
 243
 244 (defgroup elpher-faces nil
 245   "Elpher face customizations."
 246   :group 'elpher)
 247
 248 (defface elpher-index
 249   '((t :inherit font-lock-keyword-face))
 250   "Face used for directory type directory records.")
 251
 252 (defface elpher-text
 253   '((t :inherit bold))
 254   "Face used for text type directory records.")
 255
 256 (defface elpher-info
 257   '((t :inherit default))
 258   "Face used for info type directory records.")
 259
 260 (defface elpher-image
 261   '((t :inherit font-lock-string-face))
 262   "Face used for image type directory records.")
 263
 264 (defface elpher-search
 265   '((t :inherit warning))
 266   "Face used for search type directory records.")
 267
 268 (defface elpher-html
 269   '((t :inherit font-lock-comment-face))
 270   "Face used for html type directory records.")
 271
 272 (defface elpher-gemini
 273   '((t :inherit font-lock-constant-face))
 274   "Face used for Gemini type directory records.")
 275
 276 (defface elpher-other-url
 277   '((t :inherit font-lock-comment-face))
 278   "Face used for other URL type links records.")
 279
 280 (defface elpher-telnet
 281   '((t :inherit font-lock-function-name-face))
 282   "Face used for telnet type directory records.")
 283
 284 (defface elpher-binary
 285   '((t :inherit font-lock-doc-face))
 286   "Face used for binary type directory records.")
 287
 288 (defface elpher-unknown
 289   '((t :inherit error))
 290   "Face used for directory records with unknown/unsupported types.")
 291
 292 (defface elpher-margin-key
 293   '((t :inherit bold))
 294   "Face used for directory margin key.")
 295
 296 (defface elpher-margin-brackets
 297   '((t :inherit shadow))
 298   "Face used for brackets around directory margin key.")
 299
 300 (defface elpher-gemini-heading1
 301   '((t :inherit bold :height 1.8))
 302   "Face used for gemini heading level 1.")
 303
 304 (defface elpher-gemini-heading2
 305   '((t :inherit bold :height 1.5))
 306   "Face used for gemini heading level 2.")
 307
 308 (defface elpher-gemini-heading3
 309   '((t :inherit bold :height 1.2))
 310   "Face used for gemini heading level 3.")
 311
 312 (defface elpher-gemini-preformatted
 313   '((t :inherit fixed-pitch))
 314   "Face used for pre-formatted gemini text blocks.")
 315
 316 (defface elpher-gemini-quoted
 317   '((t :inherit font-lock-doc-face))
 318   "Face used for gemini quoted texts.")
 319
 320 ;;; Model
 321 ;;
 322
 323 ;; Address
 324
 325 ;; An elpher "address" object is either a url object or a symbol.
 326 ;; Symbol addresses are "special", corresponding to pages generated
 327 ;; dynamically for and by elpher.  All others represent pages which
 328 ;; rely on content retrieved over the network.
 329
 330 (defun elpher-address-from-url (url-string)
 331   "Create a ADDRESS object corresponding to the given URL-STRING."
 332   (let ((data (match-data))) ; Prevent parsing clobbering match data
 333     (unwind-protect
 334         (let ((url (url-generic-parse-url url-string)))
 335           (unless (and (not (url-fullness url)) (url-type url))
 336             (setf (url-fullness url) t)
 337             (unless (url-type url)
 338               (setf (url-type url) elpher-default-url-type))
 339             (unless (url-host url)
 340               (let ((p (split-string (url-filename url) "/" nil nil)))
 341                 (setf (url-host url) (car p))
 342                 (setf (url-filename url)
 343                       (if (cdr p)
 344                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 345                         ""))))
 346             (when (or (equal "gopher" (url-type url))
 347                       (equal "gophers" (url-type url)))
 348               ;; Gopher defaults
 349               (when (or (equal (url-filename url) "")
 350                         (equal (url-filename url) "/"))
 351                 (setf (url-filename url) "/1")))
 352             (when (equal "gemini" (url-type url))
 353               ;; Gemini defaults
 354               (if (equal (url-filename url) "")
 355                   (setf (url-filename url) "/"))))
 356           (elpher-remove-redundant-ports url))
 357       (set-match-data data))))
 358
 359 (defun elpher-remove-redundant-ports (address)
 360   "Remove redundant port specifiers from ADDRESS.
 361 Here 'redundant' means that the specified port matches the default
 362 for that protocol, eg 70 for gopher."
 363   (if (and (not (elpher-address-special-p address))
 364            (eq (url-portspec address) ; (url-port) is too slow!
 365                (pcase (url-type address)
 366                  ("gemini" 1965)
 367                  ((or "gopher" "gophers") 70)
 368                  ("finger" 79)
 369                  (_ -1))))
 370       (setf (url-portspec address) nil))
 371   address)
 372
 373 (defun elpher-make-gopher-address (type selector host port &optional tls)
 374   "Create an ADDRESS object using gopher directory record attributes.
 375 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 376 If the optional attribute TLS is non-nil, the address will be marked as
 377 requiring gopher-over-TLS."
 378   (cond
 379    ((equal type ?i) nil)
 380    ((and (equal type ?h)
 381          (string-prefix-p "URL:" selector))
 382     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 383    ((equal type ?8)
 384     (elpher-address-from-url
 385      (concat "telnet"
 386              "://" host
 387              ":" (number-to-string port))))
 388    (t
 389     (elpher-address-from-url
 390      (concat "gopher" (if tls "s" "")
 391              "://" host
 392              ":" (number-to-string port)
 393              "/" (string type)
 394              selector)))))
 395
 396 (defun elpher-make-special-address (type)
 397   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 398   type)
 399
 400 (defun elpher-make-start-page ()
 401   "Create the start page."
 402   (elpher-make-page "Elpher Start Page"
 403                     (elpher-make-special-address 'start)))
 404
 405 (defun elpher-address-to-url (address)
 406   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 407   (if (elpher-address-special-p address)
 408       nil
 409     (url-encode-url (url-recreate-url address))))
 410
 411 (defun elpher-address-type (address)
 412   "Retrieve type of ADDRESS object.
 413 This is used to determine how to retrieve and render the document the
 414 address refers to, via the table `elpher-type-map'."
 415   (if (symbolp address)
 416       (list 'special address)
 417     (let ((protocol (url-type address)))
 418       (cond ((or (equal protocol "gopher")
 419                  (equal protocol "gophers"))
 420              (list 'gopher
 421                    (if (member (url-filename address) '("" "/"))
 422                        ?1
 423                      (string-to-char (substring (url-filename address) 1)))))
 424             ((equal protocol "gemini")
 425              'gemini)
 426             ((equal protocol "telnet")
 427              'telnet)
 428             ((equal protocol "finger")
 429              'finger)
 430             (t 'other-url)))))
 431
 432 (defun elpher-address-protocol (address)
 433   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 434   (if (symbolp address)
 435       nil
 436     (url-type address)))
 437
 438 (defun elpher-address-filename (address)
 439   "Retrieve the filename component of ADDRESS.
 440 For gopher addresses this is a combination of the selector type and selector."
 441   (if (symbolp address)
 442       nil
 443     (url-unhex-string (url-filename address))))
 444
 445 (defun elpher-address-host (address)
 446   "Retrieve host from ADDRESS object."
 447   (url-host address))
 448
 449 (defun elpher-address-user (address)
 450   "Retrieve user from ADDRESS object."
 451   (url-user address))
 452
 453 (defun elpher-address-port (address)
 454   "Retrieve port from ADDRESS object.
 455 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 456   (if (symbolp address)
 457       0
 458     (url-port address)))
 459
 460 (defun elpher-address-special-p (address)
 461   "Return non-nil if ADDRESS object is special (e.g. start page page)."
 462   (symbolp address))
 463
 464 (defun elpher-address-gopher-p (address)
 465   "Return non-nill if ADDRESS object is a gopher address."
 466   (and (not (elpher-address-special-p address))
 467        (member (elpher-address-protocol address) '("gopher" "gophers"))))
 468
 469 (defun elpher-gopher-address-selector (address)
 470   "Retrieve gopher selector from ADDRESS object."
 471   (if (member (url-filename address) '("" "/"))
 472       ""
 473     (url-unhex-string (substring (url-filename address) 2))))
 474
 475
 476 ;; Cache
 477
 478 (defvar elpher-content-cache (make-hash-table :test 'equal))
 479 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 480
 481 (defun elpher-get-cached-content (address)
 482   "Retrieve the cached content for ADDRESS, or nil if none exists."
 483   (gethash address elpher-content-cache))
 484
 485 (defun elpher-cache-content (address content)
 486   "Set the content cache for ADDRESS to CONTENT."
 487   (puthash address content elpher-content-cache))
 488
 489 (defun elpher-get-cached-pos (address)
 490   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 491   (gethash address elpher-pos-cache))
 492
 493 (defun elpher-cache-pos (address pos)
 494   "Set the cursor position cache for ADDRESS to POS."
 495   (puthash address pos elpher-pos-cache))
 496
 497
 498 ;; Page
 499
 500 (defun elpher-make-page (display-string address)
 501   "Create a page with DISPLAY-STRING and ADDRESS."
 502   (list display-string address))
 503
 504 (defun elpher-page-display-string (page)
 505   "Retrieve the display string corresponding to PAGE."
 506   (elt page 0))
 507
 508 (defun elpher-page-address (page)
 509   "Retrieve the address corresponding to PAGE."
 510   (elt page 1))
 511
 512 (defun elpher-page-set-address (page new-address)
 513   "Set the address corresponding to PAGE to NEW-ADDRESS."
 514   (setcar (cdr page) new-address))
 515
 516 (defvar elpher-current-page nil
 517   "The current page for this Elpher buffer.")
 518
 519 (defvar elpher-history nil
 520   "The local history stack for this Elpher buffer.
 521 This variable is used by `elpher-back' and
 522 `elpher-show-history'.")
 523
 524 (defvar elpher-visited-pages nil
 525   "The global history for all Elpher buffers.
 526 This variable is used by `elpher-show-visited-pages'.")
 527
 528 (defun elpher-visit-page (page &optional renderer no-history)
 529   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 530 Additionally, push PAGE onto the history stack and the list of
 531 previously-visited pages,unless NO-HISTORY is non-nil."
 532   (elpher-save-pos)
 533   (elpher-process-cleanup)
 534   (unless no-history
 535     (unless (equal (elpher-page-address elpher-current-page)
 536                    (elpher-page-address page))
 537       (push elpher-current-page elpher-history)
 538       (unless (or (elpher-address-special-p (elpher-page-address page))
 539                   (and elpher-visited-pages
 540                        (equal page (car elpher-visited-pages))))
 541         (push page elpher-visited-pages))))
 542   (setq-local elpher-current-page page)
 543   (let* ((address (elpher-page-address page))
 544          (type (elpher-address-type address))
 545          (type-record (cdr (assoc type elpher-type-map))))
 546     (if type-record
 547         (funcall (car type-record)
 548                  (if renderer
 549                      renderer
 550                    (cadr type-record)))
 551       (elpher-visit-previous-page)
 552       (pcase type
 553         (`(gopher ,type-char)
 554          (error "Unsupported gopher selector type '%c' for '%s'"
 555                 type-char (elpher-address-to-url address)))
 556         (other
 557          (error "Unsupported address type '%S' for '%s'"
 558                 other (elpher-address-to-url address)))))))
 559
 560 (defun elpher-visit-previous-page ()
 561   "Visit the previous page in the history."
 562   (let ((previous-page (pop elpher-history)))
 563     (if previous-page
 564         (elpher-visit-page previous-page nil t)
 565       (error "No previous page"))))
 566
 567 (defun elpher-reload-current-page ()
 568   "Reload the current page, discarding any existing cached content."
 569   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 570   (elpher-visit-page elpher-current-page))
 571
 572 (defun elpher-save-pos ()
 573   "Save the current position of point to the current page."
 574   (when elpher-current-page
 575     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 576
 577 (defun elpher-restore-pos ()
 578   "Restore the position of point to that cached in the current page."
 579   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 580     (if pos
 581         (goto-char pos)
 582       (goto-char (point-min)))))
 583
 584
 585 ;;; Buffer preparation
 586 ;;
 587
 588 (defvar elpher-buffer-name "*elpher*"
 589   "The default name of the Elpher buffer.")
 590
 591 (defun elpher-update-header ()
 592   "If `elpher-use-header' is true, display current page info in window header."
 593   (if elpher-use-header
 594       (let* ((display-string (elpher-page-display-string elpher-current-page))
 595              (address (elpher-page-address elpher-current-page))
 596              (tls-string (if (and (not (elpher-address-special-p address))
 597                                   (member (elpher-address-protocol address)
 598                                           '("gophers" "gemini")))
 599                              " [TLS encryption]"
 600                            ""))
 601              (header (concat display-string
 602                              (propertize tls-string 'face 'bold))))
 603         (setq header-line-format header))))
 604
 605 (defmacro elpher-with-clean-buffer (&rest args)
 606   "Evaluate ARGS with a clean *elpher* buffer as current."
 607   `(with-current-buffer elpher-buffer-name
 608      (unless (eq major-mode 'elpher-mode)
 609        ;; avoid resetting buffer-local variables
 610        (elpher-mode))
 611      (let ((inhibit-read-only t))
 612        (setq-local network-security-level
 613                    (default-value 'network-security-level))
 614        (erase-buffer)
 615        (elpher-update-header)
 616        ,@args)))
 617
 618 (defun elpher-buffer-message (string &optional line)
 619   "Replace first line in elpher buffer with STRING.
 620 If LINE is non-nil, replace that line instead."
 621   (with-current-buffer elpher-buffer-name
 622     (let ((inhibit-read-only t))
 623       (goto-char (point-min))
 624       (if line
 625           (forward-line line))
 626       (let ((data (match-data)))
 627         (unwind-protect
 628             (progn
 629               (re-search-forward "^.*$")
 630               (replace-match string))
 631           (set-match-data data))))))
 632
 633
 634 ;;; Text Processing
 635 ;;
 636
 637 (defvar elpher-user-coding-system nil
 638   "User-specified coding system to use for decoding text responses.")
 639
 640 (defun elpher-decode (string)
 641   "Decode STRING using autodetected or user-specified coding system."
 642   (decode-coding-string string
 643                         (if elpher-user-coding-system
 644                             elpher-user-coding-system
 645                           (detect-coding-string string t))))
 646
 647 (defun elpher-preprocess-text-response (string)
 648   "Preprocess text selector response contained in STRING.
 649 This involes decoding the character representation, and clearing
 650 away CRs and any terminating period."
 651   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 652                                            (replace-regexp-in-string "\r" "" string))))
 653
 654
 655 ;;; Network error reporting
 656 ;;
 657
 658 (defun elpher-network-error (address error)
 659   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 660 ERROR can be either an error object or a string."
 661   (elpher-with-clean-buffer
 662    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 663            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 664            (if (stringp error) error (error-message-string error)) "\n"
 665            (propertize "\n----------------\n\n" 'face 'error)
 666            "Press 'u' to return to the previous page.")))
 667
 668
 669 ;;; General network communication
 670 ;;
 671
 672 (defvar elpher-network-timer nil
 673   "Timer used for network connections.")
 674
 675 (defvar elpher-use-tls nil
 676   "If non-nil, use TLS to communicate with gopher servers.")
 677
 678 (defvar elpher-client-certificate nil
 679   "If non-nil, contains client certificate details to use for TLS connections.")
 680
 681 (defun elpher-process-cleanup ()
 682   "Immediately shut down any extant elpher process and timers."
 683   (let ((p (get-process "elpher-process")))
 684     (if p (delete-process p)))
 685   (if (timerp elpher-network-timer)
 686       (cancel-timer elpher-network-timer)))
 687
 688 (defun elpher-get-host-response (address default-port query-string response-processor
 689                                          &optional use-tls force-ipv4)
 690   "Generic function for retrieving data from ADDRESS.
 691
 692 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 693 QUERY-STRING is a string sent to the host specified by ADDRESS to
 694 illicet a response.  This response is passed as an argument to the
 695 function RESPONSE-PROCESSOR.
 696
 697 If non-nil, USE-TLS specifies that the connection is to be made over
 698 TLS.  If set to gemini, the certificate verification will be disabled
 699 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 700
 701 If non-nil, FORCE-IPV4 causes the network connection to be made over
 702 ipv4 only.  (The default behaviour when this is not set depends on
 703 the host operating system and the local network capabilities.)"
 704   (if (and use-tls (not (gnutls-available-p)))
 705       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 706     (unless (< (elpher-address-port address) 65536)
 707       (error "Cannot establish network connection: port number > 65536"))
 708     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 709       (setq-local network-security-level 'low)
 710       (setq-local gnutls-verify-error nil))
 711     (condition-case nil
 712         (let* ((kill-buffer-query-functions nil)
 713                (port (elpher-address-port address))
 714                (host (elpher-address-host address))
 715                (service (if (> port 0) port default-port))
 716                (response-string-parts nil)
 717                (bytes-received 0)
 718                (hkbytes-received 0)
 719                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 720                (gnutls-params (list :type 'gnutls-x509pki
 721                                     :hostname host
 722                                     :keylist
 723                                     (elpher-get-current-keylist address)))
 724                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 725                        (make-network-process :name "elpher-process"
 726                                              :host host
 727                                              :family (and force-ipv4 'ipv4)
 728                                              :service service
 729                                              :buffer nil
 730                                              :nowait t
 731                                              :tls-parameters
 732                                              (and use-tls
 733                                                   (cons 'gnutls-x509pki
 734                                                         (apply #'gnutls-boot-parameters
 735                                                                gnutls-params))))))
 736                (timer (run-at-time elpher-connection-timeout nil
 737                                    (lambda ()
 738                                      (elpher-process-cleanup)
 739                                      (cond
 740                                         ; Try again with IPv4
 741                                       ((not (or force-ipv4 socks))
 742                                        (message "Connection timed out.  Retrying with IPv4.")
 743                                        (elpher-get-host-response address default-port
 744                                                                  query-string
 745                                                                  response-processor
 746                                                                  use-tls t))
 747                                       ((and use-tls
 748                                             (not (eq use-tls 'gemini))
 749                                             (or elpher-auto-disengage-TLS
 750                                                 (y-or-n-p
 751                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 752                                        (setq elpher-use-tls nil)
 753                                        (elpher-get-host-response address default-port
 754                                                                  query-string
 755                                                                  response-processor
 756                                                                  nil force-ipv4))
 757                                       (t
 758                                        (elpher-network-error address "Connection time-out.")))))))
 759           (setq elpher-network-timer timer)
 760           (set-process-coding-system proc 'binary 'binary)
 761           (set-process-query-on-exit-flag proc nil)
 762           (elpher-buffer-message (concat "Connecting to " host "..."
 763                                          " (press 'u' to abort)"))
 764           (set-process-filter proc
 765                               (lambda (_proc string)
 766                                 (when timer
 767                                   (cancel-timer timer)
 768                                   (setq timer nil))
 769                                 (setq bytes-received (+ bytes-received (length string)))
 770                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 771                                   (when (> new-hkbytes-received hkbytes-received)
 772                                     (setq hkbytes-received new-hkbytes-received)
 773                                     (elpher-buffer-message
 774                                      (concat "("
 775                                              (number-to-string (/ hkbytes-received 10.0))
 776                                              " MB read)")
 777                                      1)))
 778                                 (setq response-string-parts
 779                                       (cons string response-string-parts))))
 780           (set-process-sentinel proc
 781                                 (lambda (proc event)
 782                                   (when timer
 783                                     (cancel-timer timer))
 784                                   (condition-case the-error
 785                                       (cond
 786                                        ((string-prefix-p "open" event)    ; request URL
 787                                         (elpher-buffer-message
 788                                          (concat "Connected to " host ". Receiving data..."
 789                                                  " (press 'u' to abort)"))
 790                                         (let ((inhibit-eol-conversion t))
 791                                           (process-send-string proc query-string)))
 792                                        ((string-prefix-p "deleted" event)) ; do nothing
 793                                        ((and (not response-string-parts)
 794                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 795                                         ; Try again with IPv4
 796                                         (message "Connection failed. Retrying with IPv4.")
 797                                         (elpher-get-host-response address default-port
 798                                                                   query-string
 799                                                                   response-processor
 800                                                                   use-tls t))
 801                                        (response-string-parts
 802                                         (elpher-with-clean-buffer
 803                                          (insert "Data received.  Rendering..."))
 804                                         (funcall response-processor
 805                                                  (apply #'concat (reverse response-string-parts)))
 806                                         (elpher-restore-pos))
 807                                        (t
 808                                         (error "No response from server")))
 809                                     (error
 810                                      (elpher-network-error address the-error)))))
 811           (when socks
 812             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 813             (funcall (process-sentinel proc) proc "open\n")))
 814       (error
 815        (error "Error initiating connection to server")))))
 816
 817
 818 ;;; Client-side TLS Certificate Management
 819 ;;
 820
 821 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 822   "Generate a key and a self-signed client TLS certificate using openssl.
 823
 824 The Common Name field of the certificate is set to COMMON-NAME.  The
 825 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 826 the key and certificate files to write.
 827
 828 If TEMPORARY is non-nil, the certificate will be given an exporation
 829 period of one day, and the key and certificate files will be deleted
 830 when the certificate is no longer needed for the current session.
 831
 832 Otherwise, the certificate will be given a 100 year expiration period
 833 and the files will not be deleted.
 834
 835 The function returns a list containing the current host name, the
 836 temporary flag, and the key and cert file names in the form required
 837 by `gnutls-boot-parameters`."
 838   (let ((exp-key-file (expand-file-name key-file))
 839         (exp-cert-file (expand-file-name cert-file)))
 840     (condition-case nil
 841         (progn
 842           (call-process elpher-openssl-command nil nil nil
 843                         "req" "-x509" "-newkey" "rsa:2048"
 844                         "-days" (if temporary "1" "36500")
 845                         "-nodes"
 846                         "-subj" (concat "/CN=" common-name)
 847                         "-keyout" exp-key-file
 848                         "-out" exp-cert-file)
 849           (list (elpher-address-host (elpher-page-address elpher-current-page))
 850                 temporary exp-key-file exp-cert-file))
 851       (error
 852        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 853        (error "Program 'openssl', required for certificate generation, not found")))))
 854
 855 (defun elpher-generate-throwaway-certificate ()
 856   "Generate and return details of a throwaway certificate.
 857 The key and certificate files will be deleted when they are no
 858 longer needed for this session."
 859   (let* ((file-base (make-temp-name "elpher"))
 860          (key-file (concat temporary-file-directory file-base ".key"))
 861          (cert-file (concat temporary-file-directory file-base ".crt")))
 862     (elpher-generate-certificate file-base key-file cert-file t)))
 863
 864 (defun elpher-generate-persistent-certificate (file-base common-name)
 865   "Generate and return details of a persistent certificate.
 866 The argument FILE-BASE is used as the base for the key and certificate
 867 files, while COMMON-NAME specifies the common name field of the
 868 certificate.
 869
 870 The key and certificate files are written to in `elpher-certificate-directory'."
 871   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 872          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 873     (elpher-generate-certificate common-name key-file cert-file)))
 874
 875 (defun elpher-get-existing-certificate (file-base)
 876   "Return a certificate object corresponding to an existing certificate.
 877 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 878 the directory `elpher-certificate-directory'."
 879   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 880          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 881     (list (elpher-address-host (elpher-page-address elpher-current-page))
 882           nil
 883           (expand-file-name key-file)
 884           (expand-file-name cert-file))))
 885
 886 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 887   "Install a key+certificate file pair in `elpher-certificate-directory'.
 888 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 889 certificate files to install.  The argument FILE-BASE is used as the
 890 base for the installed key and certificate files."
 891   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 892          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 893     (if (or (file-exists-p key-file)
 894             (file-exists-p cert-file))
 895         (error "A certificate with base name %s is already installed" file-base))
 896     (copy-file key-file-src key-file)
 897     (copy-file cert-file-src cert-file)
 898     (list (elpher-address-host (elpher-page-address elpher-current-page))
 899           nil
 900           (expand-file-name key-file)
 901           (expand-file-name cert-file))))
 902
 903 (defun elpher-list-existing-certificates ()
 904   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 905   (unless (file-directory-p elpher-certificate-directory)
 906     (make-directory elpher-certificate-directory))
 907   (mapcar
 908    (lambda (file)
 909      (file-name-sans-extension file))
 910    (directory-files elpher-certificate-directory nil "\\.key$")))
 911
 912 (defun elpher-forget-current-certificate ()
 913   "Causes any current certificate to be forgotten.)
 914 In the case of throwaway certificates, the key and certificate files
 915 are also deleted."
 916   (interactive)
 917   (when elpher-client-certificate
 918     (unless (and (called-interactively-p 'any)
 919                  (not (y-or-n-p (concat "Really forget client certificate? "
 920                                         "(Throwaway certificates will be deleted.)"))))
 921       (when (cadr elpher-client-certificate)
 922         (delete-file (elt elpher-client-certificate 2))
 923         (delete-file (elt elpher-client-certificate 3)))
 924       (setq elpher-client-certificate nil)
 925       (if (called-interactively-p 'any)
 926           (message "Client certificate forgotten.")))))
 927
 928 (defun elpher-get-current-keylist (address)
 929   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 930
 931 This is obtained from the client certificate described by
 932 `elpher-current-certificate', if one is available and the host for
 933 that certificate matches the host in ADDRESS.
 934
 935 If `elpher-current-certificate' is non-nil, and its host name doesn't
 936 match that of ADDRESS, the certificate is forgotten."
 937   (if elpher-client-certificate
 938       (if (string= (car elpher-client-certificate)
 939                    (elpher-address-host address))
 940           (list (cddr elpher-client-certificate))
 941         (elpher-forget-current-certificate)
 942         (message "Disabling client certificate for new host")
 943         nil)
 944     nil))
 945
 946
 947 ;;; Gopher selector retrieval
 948 ;;
 949
 950 (defun elpher-get-gopher-response (address renderer)
 951   "Get response string from gopher server at ADDRESS and render using RENDERER."
 952   (elpher-get-host-response address 70
 953                             (concat (elpher-gopher-address-selector address) "\r\n")
 954                             renderer
 955                             (or (string= (elpher-address-protocol address) "gophers")
 956                                 elpher-use-tls)))
 957
 958 (defun elpher-get-gopher-page (renderer)
 959   "Getter function for gopher pages.
 960 The RENDERER procedure is used to display the contents of the page
 961 once they are retrieved from the gopher server."
 962   (let* ((address (elpher-page-address elpher-current-page))
 963          (content (elpher-get-cached-content address)))
 964     (if (and content (funcall renderer nil))
 965         (elpher-with-clean-buffer
 966          (insert content)
 967          (elpher-restore-pos))
 968       (elpher-with-clean-buffer
 969        (insert "LOADING... (use 'u' to cancel)\n"))
 970       (condition-case the-error
 971           (elpher-get-gopher-response address renderer)
 972         (error
 973          (elpher-network-error address the-error))))))
 974
 975 ;; Index rendering
 976
 977 (defun elpher-insert-index (string)
 978   "Insert the index corresponding to STRING into the current buffer."
 979   ;; Should be able to split directly on CRLF, but some non-conformant
 980   ;; LF-only servers sadly exist, hence the following.
 981   (let ((str-processed (elpher-preprocess-text-response string)))
 982     (dolist (line (split-string str-processed "\n"))
 983       (ignore-errors
 984         (unless (= (length line) 0)
 985           (let* ((type (elt line 0))
 986                  (fields (split-string (substring line 1) "\t"))
 987                  (display-string (elt fields 0))
 988                  (selector (elt fields 1))
 989                  (host (elt fields 2))
 990                  (port (if (elt fields 3)
 991                            (string-to-number (elt fields 3))
 992                          nil))
 993                  (address (elpher-make-gopher-address type selector host port)))
 994             (elpher-insert-index-record display-string address)))))))
 995
 996 (defun elpher-insert-margin (&optional type-name)
 997   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 998   (if type-name
 999       (progn
1000         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1001                         (concat
1002                          (propertize "[" 'face 'elpher-margin-brackets)
1003                          (propertize type-name 'face 'elpher-margin-key)
1004                          (propertize "]" 'face 'elpher-margin-brackets))))
1005         (insert " "))
1006     (insert (make-string elpher-margin-width ?\s))))
1007
1008 (defun elpher--page-button-help (_window buffer pos)
1009   "Function called by Emacs to generate mouse-over text.
1010 The arguments specify the BUFFER and the POS within the buffer of the item
1011 for which help is required.  The function returns the help to be
1012 displayed.  The _WINDOW argument is currently unused."
1013   (with-current-buffer buffer
1014     (let ((button (button-at pos)))
1015       (when button
1016         (let* ((page (button-get button 'elpher-page))
1017                (address (elpher-page-address page)))
1018           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1019                                                 address
1020                                               (elpher-address-to-url address))))))))
1021
1022 (defun elpher-insert-index-record (display-string &optional address)
1023   "Function to insert an index record into the current buffer.
1024 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1025 If ADDRESS is not supplied or nil the record is rendered as an
1026 'information' line."
1027   (let* ((type (if address (elpher-address-type address) nil))
1028          (type-map-entry (cdr (assoc type elpher-type-map))))
1029     (if type-map-entry
1030         (let* ((margin-code (elt type-map-entry 2))
1031                (face (elt type-map-entry 3))
1032                (filtered-display-string (elpher-color-filter-apply display-string))
1033                (page (elpher-make-page filtered-display-string address)))
1034           (elpher-insert-margin margin-code)
1035           (insert-text-button filtered-display-string
1036                               'face face
1037                               'elpher-page page
1038                               'action #'elpher-click-link
1039                               'follow-link t
1040                               'help-echo #'elpher--page-button-help))
1041       (pcase type
1042         ('nil ;; Information
1043          (elpher-insert-margin)
1044          (let ((propertized-display-string
1045                 (propertize display-string 'face 'elpher-info)))
1046            (insert (elpher-process-text-for-display propertized-display-string))))
1047         (`(gopher ,selector-type) ;; Unknown
1048          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1049          (insert (propertize display-string
1050                              'face 'elpher-unknown)))))
1051     (insert "\n")))
1052
1053 (defun elpher-click-link (button)
1054   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1055   (let ((page (button-get button 'elpher-page)))
1056     (elpher-visit-page page)))
1057
1058 (defun elpher-render-index (data &optional _mime-type-string)
1059   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1060   (elpher-with-clean-buffer
1061    (if (not data)
1062        t
1063      (elpher-insert-index data)
1064      (elpher-cache-content (elpher-page-address elpher-current-page)
1065                            (buffer-string)))))
1066
1067 ;; Text rendering
1068
1069 (defconst elpher-url-regex
1070   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
1071   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
1072
1073 (defun elpher-buttonify-urls (string)
1074   "Turn substrings which look like urls in STRING into clickable buttons."
1075   (with-temp-buffer
1076     (insert string)
1077     (goto-char (point-min))
1078     (while (re-search-forward elpher-url-regex nil t)
1079       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1080                                     (elpher-address-from-url (match-string 0)))))
1081         (make-text-button (match-beginning 0)
1082                           (match-end 0)
1083                           'elpher-page  page
1084                           'action #'elpher-click-link
1085                           'follow-link t
1086                           'help-echo #'elpher--page-button-help
1087                           'face 'button)))
1088     (buffer-string)))
1089
1090 (defun elpher-process-text-for-display (string)
1091   "Perform any desired processing of STRING prior to display as text.
1092 Currently includes buttonifying URLs and processing ANSI escape codes."
1093   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1094                              (elpher-color-filter-apply string)
1095                            (elpher-color-apply string))))
1096
1097 (defun elpher-render-text (data &optional _mime-type-string)
1098   "Render DATA as text.  MIME-TYPE-STRING is unused."
1099   (elpher-with-clean-buffer
1100    (if (not data)
1101        t
1102      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1103      (elpher-cache-content
1104       (elpher-page-address elpher-current-page)
1105       (buffer-string)))))
1106
1107 ;; Image retrieval
1108
1109 (defun elpher-render-image (data &optional _mime-type-string)
1110   "Display DATA as image.  MIME-TYPE-STRING is unused."
1111   (if (not data)
1112       nil
1113     (if (display-images-p)
1114         (progn
1115           (let ((image (create-image
1116                         data
1117                         nil t)))
1118             (elpher-with-clean-buffer
1119              (insert-image image)
1120              (elpher-restore-pos))))
1121       (elpher-render-download data))))
1122
1123 ;; Search retrieval and rendering
1124
1125 (defun elpher-get-gopher-query-page (renderer)
1126   "Getter for gopher addresses requiring input.
1127 The response is rendered using the rendering function RENDERER."
1128   (let* ((address (elpher-page-address elpher-current-page))
1129          (content (elpher-get-cached-content address))
1130          (aborted t))
1131     (if (and content (funcall renderer nil))
1132         (elpher-with-clean-buffer
1133          (insert content)
1134          (elpher-restore-pos)
1135          (message "Displaying cached search results.  Reload to perform a new search."))
1136       (unwind-protect
1137           (let* ((query-string (read-string "Query: "))
1138                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1139                  (search-address (elpher-make-gopher-address ?1
1140                                                              query-selector
1141                                                              (elpher-address-host address)
1142                                                              (elpher-address-port address)
1143                                                              (equal (elpher-address-type address) "gophers"))))
1144             (setq aborted nil)
1145
1146             (elpher-with-clean-buffer
1147              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1148             (elpher-get-gopher-response search-address renderer))
1149         (if aborted
1150             (elpher-visit-previous-page))))))
1151
1152 ;; Raw server response rendering
1153
1154 (defun elpher-render-raw (data &optional mime-type-string)
1155   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1156   (if (not data)
1157       nil
1158     (elpher-with-clean-buffer
1159      (when mime-type-string
1160        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1161      (insert data)
1162      (goto-char (point-min)))
1163     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1164
1165 ;; File save "rendering"
1166
1167 (defun elpher-render-download (data &optional _mime-type-string)
1168   "Save DATA to file.  MIME-TYPE-STRING is unused."
1169   (if (not data)
1170       nil
1171     (let* ((address (elpher-page-address elpher-current-page))
1172            (selector (if (elpher-address-gopher-p address)
1173                          (elpher-gopher-address-selector address)
1174                        (elpher-address-filename address))))
1175       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1176       (let* ((filename-proposal (file-name-nondirectory selector))
1177              (filename (read-file-name "Download complete. Save file as: "
1178                                        nil nil nil
1179                                        (if (> (length filename-proposal) 0)
1180                                            filename-proposal
1181                                          "download.file"))))
1182         (let ((coding-system-for-write 'binary))
1183           (with-temp-file filename
1184             (insert data)))
1185         (message (format "Saved to file %s." filename))))))
1186
1187 ;; HTML rendering
1188
1189 (defun elpher-render-html (data &optional _mime-type-string)
1190   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1191   (elpher-with-clean-buffer
1192    (if (not data)
1193        t
1194      (let ((dom (with-temp-buffer
1195                   (insert data)
1196                   (libxml-parse-html-region (point-min) (point-max)))))
1197        (shr-insert-document dom)))))
1198
1199 ;; Gemini page retrieval
1200
1201 (defvar elpher-gemini-redirect-chain)
1202
1203 (defun elpher-get-gemini-response (address renderer)
1204   "Get response string from gemini server at ADDRESS and render using RENDERER."
1205   (elpher-get-host-response address 1965
1206                             (concat (elpher-address-to-url address) "\r\n")
1207                             (lambda (response-string)
1208                               (elpher-process-gemini-response response-string renderer))
1209                             'gemini))
1210
1211 (defun elpher-parse-gemini-response (response)
1212   "Parse the RESPONSE string and return a list of components.
1213 The list is of the form (code meta body).  A response of nil implies
1214 that the response was malformed."
1215   (let ((header-end-idx (string-match "\r\n" response)))
1216     (if header-end-idx
1217         (let ((header (string-trim (substring response 0 header-end-idx)))
1218               (body (substring response (+ header-end-idx 2))))
1219           (if (>= (length header) 2)
1220               (let ((code (substring header 0 2))
1221                     (meta (string-trim (substring header 2))))
1222                 (list code meta body))
1223             (error "Malformed response: No response status found in header %s" header)))
1224       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1225
1226 (defun elpher-process-gemini-response (response-string renderer)
1227   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1228   (let ((response-components (elpher-parse-gemini-response response-string)))
1229     (let ((response-code (elt response-components 0))
1230           (response-meta (elt response-components 1))
1231           (response-body (elt response-components 2)))
1232       (pcase (elt response-code 0)
1233         (?1 ; Input required
1234          (elpher-with-clean-buffer
1235           (insert "Gemini server is requesting input."))
1236          (let* ((query-string
1237                  (if (eq (elt response-code 1) ?1)
1238                      (read-passwd (concat response-meta ": "))
1239                    (read-string (concat response-meta ": "))))
1240                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1241                 (old-fname (url-filename query-address)))
1242            (setf (url-filename query-address)
1243                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1244            (elpher-get-gemini-response query-address renderer)))
1245         (?2 ; Normal response
1246          (funcall renderer response-body response-meta))
1247         (?3 ; Redirect
1248          (message "Following redirect to %s" response-meta)
1249          (if (>= (length elpher-gemini-redirect-chain) 5)
1250              (error "More than 5 consecutive redirects followed"))
1251          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1252            (if (member redirect-address elpher-gemini-redirect-chain)
1253                (error "Redirect loop detected"))
1254            (if (not (string= (elpher-address-protocol redirect-address)
1255                              "gemini"))
1256                (error "Server tried to automatically redirect to non-gemini URL: %s"
1257                       response-meta))
1258            (elpher-page-set-address elpher-current-page redirect-address)
1259            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1260            (elpher-get-gemini-response redirect-address renderer)))
1261         (?4 ; Temporary failure
1262          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1263                 response-code response-meta))
1264         (?5 ; Permanent failure
1265          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1266                 response-code response-meta))
1267         (?6 ; Client certificate required
1268          (elpher-with-clean-buffer
1269           (if elpher-client-certificate
1270               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1271             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1272           (auto-fill-mode 1)
1273           (elpher-gemini-insert-text response-meta))
1274          (let ((chosen-certificate (elpher-choose-client-certificate)))
1275            (unless chosen-certificate
1276              (error "Gemini server requires a client certificate and none was provided"))
1277            (setq elpher-client-certificate chosen-certificate))
1278          (elpher-with-clean-buffer)
1279          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1280         (_other
1281          (error "Gemini server response unknown: %s %s"
1282                 response-code response-meta))))))
1283
1284 (defun elpher--read-answer-polyfill (question answers)
1285   "Polyfill for `read-answer' in Emacs 26.1.
1286 QUESTION is a string containing a question, and ANSWERS
1287 is a list of possible answers."
1288     (completing-read question (mapcar 'identity answers)))
1289
1290 (if (fboundp 'read-answer)
1291     (defalias 'elpher-read-answer 'read-answer)
1292   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1293
1294 (defun elpher-choose-client-certificate ()
1295   "Prompt for a client certificate to use to establish a TLS connection."
1296   (let* ((read-answer-short t))
1297     (pcase (read-answer "What do you want to do? "
1298                         '(("throwaway" ?t
1299                            "generate and use throw-away certificate")
1300                           ("persistent" ?p
1301                            "generate new or use existing persistent certificate")
1302                           ("abort" ?a
1303                            "stop immediately")))
1304       ("throwaway"
1305        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1306       ("persistent"
1307        (let* ((existing-certificates (elpher-list-existing-certificates))
1308               (file-base (completing-read
1309                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1310                           existing-certificates)))
1311          (if (string-empty-p (string-trim file-base))
1312              nil
1313            (if (member file-base existing-certificates)
1314                (setq elpher-client-certificate
1315                      (elpher-get-existing-certificate file-base))
1316              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1317                                  '(("new" ?n
1318                                     "generate new certificate")
1319                                    ("install" ?i
1320                                     "install existing certificate")
1321                                    ("abort" ?a
1322                                     "stop immediately")))
1323                ("new"
1324                 (let ((common-name (read-string "Common Name field for new certificate: "
1325                                                 file-base)))
1326                   (message "New key and self-signed certificate written to %s"
1327                            elpher-certificate-directory)
1328                   (elpher-generate-persistent-certificate file-base common-name)))
1329                ("install"
1330                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1331                        (key-file (read-file-name "Key file: " nil nil t)))
1332                   (message "Key and certificate installed in %s for future use"
1333                            elpher-certificate-directory)
1334                   (elpher-install-and-use-existing-certificate key-file
1335                                                                cert-file
1336                                                                file-base)))
1337                ("abort" nil))))))
1338       ("abort" nil))))
1339
1340 (defun elpher-get-gemini-page (renderer)
1341   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1342   (let* ((address (elpher-page-address elpher-current-page))
1343          (content (elpher-get-cached-content address)))
1344     (condition-case the-error
1345         (if (and content (funcall renderer nil))
1346             (elpher-with-clean-buffer
1347              (insert content)
1348              (elpher-restore-pos))
1349           (elpher-with-clean-buffer
1350            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1351           (setq elpher-gemini-redirect-chain nil)
1352           (elpher-get-gemini-response address renderer))
1353       (error
1354        (elpher-network-error address the-error)))))
1355
1356 (defun elpher-render-gemini (body &optional mime-type-string)
1357   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1358   (if (not body)
1359       t
1360     (let* ((mime-type-string* (if (or (not mime-type-string)
1361                                       (string-empty-p mime-type-string))
1362                                   "text/gemini; charset=utf-8"
1363                                 mime-type-string))
1364            (mime-type-split (split-string mime-type-string* ";" t))
1365            (mime-type (string-trim (car mime-type-split)))
1366            (parameters (mapcar (lambda (s)
1367                                  (let ((key-val (split-string s "=")))
1368                                    (list (downcase (string-trim (car key-val)))
1369                                          (downcase (string-trim (cadr key-val))))))
1370                                (cdr mime-type-split))))
1371       (when (string-prefix-p "text/" mime-type)
1372         (setq body (decode-coding-string
1373                     body
1374                     (if (assoc "charset" parameters)
1375                         (intern (cadr (assoc "charset" parameters)))
1376                       'utf-8)))
1377         (setq body (replace-regexp-in-string "\r" "" body)))
1378       (pcase mime-type
1379         ((or "text/gemini" "")
1380          (elpher-render-gemini-map body parameters))
1381         ("text/html"
1382          (elpher-render-html body))
1383         ((pred (string-prefix-p "text/"))
1384          (elpher-render-gemini-plain-text body parameters))
1385         ((pred (string-prefix-p "image/"))
1386          (elpher-render-image body))
1387         (_other
1388          (elpher-render-download body))))))
1389
1390 (defun elpher-gemini-get-link-url (link-line)
1391   "Extract the url portion of LINK-LINE, a gemini map file link line.
1392 Returns nil in the event that the contents of the line following the
1393 => prefix are empty."
1394   (let ((l (split-string (substring link-line 2))))
1395     (if l
1396         (string-trim (elt l 0))
1397       nil)))
1398
1399 (defun elpher-gemini-get-link-display-string (link-line)
1400   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1401 Returns the url portion in the event that the display-string portion is empty."
1402   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1403          (idx (string-match "[ \t]" rest)))
1404     (string-trim (if idx
1405                      (substring rest (+ idx 1))
1406                    rest))))
1407
1408 (defun elpher-collapse-dot-sequences (filename)
1409   "Collapse dot sequences in FILENAME.
1410 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1411   (let* ((path (split-string filename "/"))
1412          (path-reversed-normalized
1413           (seq-reduce (lambda (a b)
1414                         (cond ((and a (equal b "..") (cdr a)))
1415                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1416                               ((equal b ".") a)
1417                               (t (cons b a))))
1418                       path nil)))
1419     (string-join (reverse path-reversed-normalized) "/")))
1420
1421 (defun elpher-address-from-gemini-url (url)
1422   "Extract address from URL with defaults as per gemini map files.
1423 While there's obviously some redundancy here between this function and
1424 `elpher-address-from-url', gemini map file URLs require enough special
1425 treatment that a separate function is warranted."
1426   (let ((address (url-generic-parse-url url))
1427         (current-address (elpher-page-address elpher-current-page)))
1428     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1429       (setf (url-fullness address) t)
1430       (if (url-host address) ;if there is an explicit host, filenames are absolute
1431           (if (string-empty-p (url-filename address))
1432               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1433         (setf (url-host address) (url-host current-address))
1434         (setf (url-port address) (url-port current-address))
1435         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1436           (setf (url-filename address)
1437                 (concat (file-name-directory (url-filename current-address))
1438                         (url-filename address)))))
1439       (unless (url-type address)
1440         (setf (url-type address) "gemini"))
1441       (when (equal (url-type address) "gemini")
1442         (setf (url-filename address)
1443               (elpher-collapse-dot-sequences (url-filename address)))))
1444     (elpher-remove-redundant-ports address)))
1445
1446 (defun elpher-gemini-insert-link (link-line)
1447   "Insert link described by LINK-LINE into a text/gemini document."
1448   (let* ((url (elpher-gemini-get-link-url link-line))
1449          (display-string (elpher-gemini-get-link-display-string link-line))
1450          (address (elpher-address-from-gemini-url url))
1451          (type (if address (elpher-address-type address) nil))
1452          (type-map-entry (cdr (assoc type elpher-type-map))))
1453     (when display-string
1454       (insert elpher-gemini-link-string)
1455       (if type-map-entry
1456           (let* ((face (elt type-map-entry 3))
1457                  (filtered-display-string (elpher-color-filter-apply display-string))
1458                  (page (elpher-make-page filtered-display-string address)))
1459             (insert-text-button filtered-display-string
1460                                 'face face
1461                                 'elpher-page page
1462                                 'action #'elpher-click-link
1463                                 'follow-link t
1464                                 'help-echo #'elpher--page-button-help))
1465         (insert (propertize display-string 'face 'elpher-unknown)))
1466       (insert "\n"))))
1467
1468 (defun elpher-gemini-insert-header (header-line)
1469   "Insert header described by HEADER-LINE into a text/gemini document.
1470 The gemini map file line describing the header is given
1471 by HEADER-LINE."
1472   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1473     (let* ((level (length (match-string 1 header-line)))
1474            (header (substring header-line (match-end 0)))
1475            (face (pcase level
1476                    (1 'elpher-gemini-heading1)
1477                    (2 'elpher-gemini-heading2)
1478                    (3 'elpher-gemini-heading3)
1479                    (_ 'default)))
1480            (fill-column (if (display-graphic-p)
1481                             (/ (* fill-column
1482                                   (font-get (font-spec :name (face-font 'default)) :size))
1483                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1484       (setq elpher--gemini-page-headings (cons (cons header (point))
1485                                                elpher--gemini-page-headings))
1486       (unless (display-graphic-p)
1487         (insert (make-string level ?#) " "))
1488       (insert (propertize header 'face face))
1489       (newline))))
1490
1491 (defun elpher-gemini-insert-text (text-line)
1492   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1493 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1494 width defined by `elpher-gemini-max-fill-width'."
1495   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1496   (let* ((line-prefix (match-string 2 text-line))
1497          (processed-text-line
1498           (if line-prefix
1499               (cond ((string-prefix-p "*" line-prefix)
1500                      (concat
1501                       (replace-regexp-in-string "\\*"
1502                                                 elpher-gemini-bullet-string
1503                                                 (match-string 0 text-line))
1504                       (substring text-line (match-end 0))))
1505                     ((string-prefix-p ">" line-prefix)
1506                      (propertize text-line 'face 'elpher-gemini-quoted))
1507                     (t text-line))
1508             text-line))
1509          (adaptive-fill-mode t)
1510          ;; fill-prefix is important for adaptive-fill-mode: without
1511          ;; it, multi-line list items are not indented correct
1512          (fill-prefix (if (match-string 2 text-line)
1513                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1514                         nil)))
1515     (insert (elpher-process-text-for-display processed-text-line))
1516     (newline)))
1517
1518 (defun elpher-render-gemini-map (data _parameters)
1519   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1520   (elpher-with-clean-buffer
1521    (setq elpher--gemini-page-headings nil)
1522    (let ((preformatted nil))
1523      (auto-fill-mode 1)
1524      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1525      (dolist (line (split-string data "\n"))
1526        (cond
1527         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1528         (preformatted (insert (elpher-process-text-for-display
1529                                (propertize line 'face 'elpher-gemini-preformatted))
1530                               "\n"))
1531         ((string-prefix-p "=>" line)
1532          (elpher-gemini-insert-link line))
1533         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1534         (t (elpher-gemini-insert-text line)))))
1535    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1536    (elpher-cache-content
1537     (elpher-page-address elpher-current-page)
1538     (buffer-string))))
1539
1540 (defun elpher-render-gemini-plain-text (data _parameters)
1541   "Render DATA as plain text file.  PARAMETERS is currently unused."
1542   (elpher-with-clean-buffer
1543    (insert (elpher-process-text-for-display data))
1544    (elpher-cache-content
1545     (elpher-page-address elpher-current-page)
1546     (buffer-string))))
1547
1548
1549 ;; Finger page connection
1550
1551 (defun elpher-get-finger-page (renderer)
1552   "Opens a finger connection to the current page address.
1553 The result is rendered using RENDERER."
1554   (let* ((address (elpher-page-address elpher-current-page))
1555          (content (elpher-get-cached-content address)))
1556     (if (and content (funcall renderer nil))
1557         (elpher-with-clean-buffer
1558          (insert content)
1559          (elpher-restore-pos))
1560       (elpher-with-clean-buffer
1561        (insert "LOADING... (use 'u' to cancel)\n"))
1562       (condition-case the-error
1563           (let* ((kill-buffer-query-functions nil)
1564                  (user (let ((filename (elpher-address-filename address)))
1565                          (if (> (length filename) 1)
1566                              (substring filename 1)
1567                            (elpher-address-user address)))))
1568             (elpher-get-host-response address 79
1569                                       (concat user "\r\n")
1570                                       renderer))
1571         (error
1572          (elpher-network-error address the-error))))))
1573
1574
1575 ;; Telnet page connection
1576
1577 (defun elpher-get-telnet-page (renderer)
1578   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1579   (when renderer
1580     (elpher-visit-previous-page)
1581     (error "Command not supported for telnet URLs"))
1582   (let* ((address (elpher-page-address elpher-current-page))
1583          (host (elpher-address-host address))
1584          (port (elpher-address-port address)))
1585     (elpher-visit-previous-page)
1586     (if (> port 0)
1587         (telnet host port)
1588       (telnet host))))
1589
1590
1591 ;; Other URL page opening
1592
1593 (defun elpher-get-other-url-page (renderer)
1594   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1595   (when renderer
1596     (elpher-visit-previous-page)
1597     (error "Command not supported for general URLs"))
1598   (let* ((address (elpher-page-address elpher-current-page))
1599          (url (elpher-address-to-url address)))
1600     (progn
1601       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1602       (message "Opening URL...")
1603       (if elpher-open-urls-with-eww
1604           (browse-web url)
1605         (browse-url url)))))
1606
1607
1608 ;; Start page retrieval
1609
1610 (defun elpher-get-start-page (renderer)
1611   "Getter which displays the start page (RENDERER must be nil)."
1612   (when renderer
1613     (elpher-visit-previous-page)
1614     (error "Command not supported for start page"))
1615   (elpher-with-clean-buffer
1616    (insert "     --------------------------------------------\n"
1617            "           Elpher Gopher and Gemini Client       \n"
1618            "                   version " elpher-version "\n"
1619            "     --------------------------------------------\n"
1620            "\n"
1621            "Default bindings:\n"
1622            "\n"
1623            " - TAB/Shift-TAB: next/prev item on current page\n"
1624            " - RET/mouse-1: open item under cursor\n"
1625            " - m: select an item on current page by name (autocompletes)\n"
1626            " - u/mouse-3/U: return to previous page or to the start page\n"
1627            " - g: go to a particular address (gopher, gemini, finger)\n"
1628            " - o/O: open a different address selector or the root menu of the current server\n"
1629            " - d/D: download item under cursor or current page\n"
1630            " - i/I: info on item under cursor or current page\n"
1631            " - c/C: copy URL representation of item under cursor or current page\n"
1632            " - a/A: bookmark the item under cursor or current page\n"
1633            " - B: list all bookmarks\n"
1634            " - s/S: show current history stack or all previously visted pages\n"
1635            " - r: redraw current page (using cached contents if available)\n"
1636            " - R: reload current page (regenerates cache)\n"
1637            " - !: set character coding system for gopher (default is to autodetect)\n"
1638            " - T: toggle TLS gopher mode\n"
1639            " - F: forget/discard current TLS client certificate\n"
1640            " - .: display the raw server response for the current page\n"
1641            "\n"
1642            "Start your exploration of gopher space and gemini:\n")
1643    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1644                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1645    (elpher-insert-index-record "Project Gemini home page"
1646                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1647    (insert "\n"
1648            "Alternatively, select a search engine and enter some search terms:\n")
1649    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1650                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1651    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1652                                (elpher-address-from-url "gemini://geminispace.info/search"))
1653    (insert "\n"
1654            "Your bookmarks are stored in your ")
1655    (let ((help-string "RET,mouse-1: Open Emacs bookmark list"))
1656      (insert-text-button "Emacs bookmark list"
1657                          'face 'link
1658                          'action (lambda (_)
1659                                    (interactive)
1660                                    (call-interactively #'elpher-open-bookmarks))
1661                          'follow-link t
1662                          'help-echo help-string))
1663    (insert ".\n")
1664    (insert (propertize
1665             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1666             'face 'shadow))
1667    (insert "\n"
1668            "For Elpher release news or to leave feedback, visit:\n")
1669    (elpher-insert-index-record "The Elpher Project Page"
1670                                (elpher-make-gopher-address ?1
1671                                                            "/projects/elpher/"
1672                                                            "thelambdalab.xyz"
1673                                                            70))
1674    (insert "\n"
1675            "** Refer to the ")
1676    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1677      (insert-text-button "Elpher info manual"
1678                          'face 'link
1679                          'action (lambda (_)
1680                                    (interactive)
1681                                    (info "(elpher)"))
1682                          'follow-link t
1683                          'help-echo help-string))
1684    (insert " for the full documentation. **\n")
1685    (insert (propertize
1686             (concat "  (This should be available if you have installed Elpher using\n"
1687                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1688             'face 'shadow))
1689    (elpher-restore-pos)))
1690
1691 ;; History page retrieval
1692
1693 (defun elpher-show-history ()
1694   "Show the current contents of elpher's history stack.
1695 Use \\[elpher-show-visited-pages] to see the entire history.
1696 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1697   (interactive)
1698   (elpher-visit-page
1699    (elpher-make-page "Current History Stack"
1700                      (elpher-make-special-address 'history))))
1701
1702 (defun elpher-show-visited-pages ()
1703   "Show the all the pages you've visited using Elpher.
1704 Use \\[elpher-show-history] to see just the current history stack.
1705 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1706   (interactive)
1707   (elpher-visit-page
1708    (elpher-make-page "Elpher Visted Pages"
1709                      (elpher-make-special-address 'visited-pages))))
1710
1711 (defun elpher-get-history-page (renderer)
1712   "Getter which displays the history page (RENDERER must be nil)."
1713   (when renderer
1714     (elpher-visit-previous-page)
1715     (error "Command not supported for history page"))
1716   (elpher-display-history-links elpher-history "Current history stack"))
1717
1718 (defun elpher-get-visited-pages-page (renderer)
1719   "Getter which displays the list of visited pages (RENDERER must be nil)."
1720   (when renderer
1721     (elpher-visit-previous-page)
1722     (error "Command not supported for history page"))
1723   (elpher-display-history-links
1724    (seq-filter (lambda (page)
1725                  (not (elpher-address-special-p (elpher-page-address page))))
1726                elpher-visited-pages)
1727    "All visited pages"))
1728
1729 (defun elpher-display-history-links (pages title)
1730   "Show all PAGES in an Elpher buffer with a given TITLE."
1731   (let* ((title-line (concat "---- " title " ----"))
1732          (footer-line (make-string (length title-line) ?-)))
1733     (elpher-with-clean-buffer
1734      (insert title-line "\n\n")
1735      (if pages
1736          (dolist (page pages)
1737            (when page
1738              (let ((display-string (elpher-page-display-string page))
1739                    (address (elpher-page-address page)))
1740                (elpher-insert-index-record display-string address))))
1741        (insert "No history items found.\n"))
1742      (insert "\n" footer-line "\n"
1743              "Select and entry or press 'u' to return to the previous page.")
1744      (elpher-restore-pos))))
1745
1746
1747 ;;; Bookmarks
1748
1749 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1750 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1751 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1752 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1753
1754 (defvar elpher-bookmark-link nil
1755   "Prefer bookmarking a link or the current page.
1756 Bind this variable dynamically, or set it to t.
1757 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1758 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1759
1760 (defun elpher-bookmark-make-record ()
1761   "Return a bookmark record.
1762 If `elpher-bookmark-link' is non-nil and point is on a link button,
1763 return a bookmark record for that link.  Otherwise, return a bookmark
1764 record for the current elpher page."
1765   (let* ((button (and elpher-bookmark-link (button-at (point))))
1766          (page (if button
1767                    (button-get button 'elpher-page)
1768                  elpher-current-page))
1769          (address (elpher-page-address page))
1770          (url (elpher-address-to-url address))
1771          (display-string (elpher-page-display-string page))
1772          (pos (if button nil (point))))
1773     (if (elpher-address-special-p address)
1774         (error "Cannot bookmark %s" display-string)
1775       `(,display-string
1776         (defaults . (,display-string))
1777         (position . ,pos)
1778         (location . ,url)
1779         (handler . elpher-bookmark-jump)))))
1780
1781 ;;;###autoload
1782 (defun elpher-bookmark-jump (bookmark)
1783   "Go to a particular BOOKMARK."
1784   (let* ((url (cdr (assq 'location bookmark))))
1785     (elpher-go url)))
1786
1787 (defun elpher-bookmark-link ()
1788   "Bookmark the link at point.
1789 To bookmark the current page, use \\[elpher-bookmark-current]."
1790   (interactive)
1791   (let ((elpher-bookmark-link t))
1792     (bookmark-set-no-overwrite)))
1793
1794 (defun elpher-bookmark-current ()
1795   "Bookmark the current page.
1796 To bookmark the link at point use \\[elpher-bookmark-link]."
1797   (interactive)
1798   (call-interactively #'bookmark-set-no-overwrite))
1799
1800 (defun elpher-bookmark-import (file)
1801   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1802   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1803                               (file-readable-p elpher-bookmarks-file))
1804                          elpher-bookmarks-file
1805                        (read-file-name "Old Elpher bookmarks: "
1806                                        user-emacs-directory nil t
1807                                        "elpher-bookmarks"))))
1808   (require 'bookmark)
1809   (dolist (bookmark (with-temp-buffer
1810                       (insert-file-contents file)
1811                       (read (current-buffer))))
1812     (let* ((display-string (car bookmark))
1813            (url (cadr bookmark))
1814            (record `(,display-string
1815                      (location . ,url)
1816                      (handler . elpher-bookmark-jump))))
1817       (bookmark-store display-string (cdr record) t)))
1818   (bookmark-save))
1819
1820 (defun elpher-open-bookmarks ()
1821   "Display the current list of elpher bookmarks.
1822 This is just a call to `bookmark-bmenu-list', but we also check for a legacy
1823 bookmark file and offer to import it."
1824   (interactive)
1825   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1826                                      elpher-bookmarks-file)
1827                                 (locate-user-emacs-file "elpher-bookmarks"))))
1828     (when (and (file-readable-p old-bookmarks-file)
1829                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1830                                  old-bookmarks-file
1831                                  "\" found. Import now?")))
1832       (elpher-bookmark-import old-bookmarks-file)
1833       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1834   (call-interactively #'bookmark-bmenu-list))
1835
1836
1837 ;;; Integrations
1838 ;;
1839
1840 ;;; Org
1841
1842 (defun elpher-org-export-link (link description format protocol)
1843   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1844
1845 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1846 of gemini, gopher or finger."
1847   (let* ((url (if (equal protocol "elpher")
1848                   (string-remove-prefix "elpher:" link)
1849                 (format "%s:%s" protocol link)))
1850          (desc (or description url)))
1851     (pcase format
1852       (`gemini (format "=> %s %s" url desc))
1853       (`html (format "<a href=\"%s\">%s</a>" url desc))
1854       (`latex (format "\\href{%s}{%s}" url desc))
1855       (_ (if (not description)
1856              url
1857            (format "%s (%s)" desc url))))))
1858
1859 (defun elpher-org-store-link ()
1860   "Store link to an `elpher' page in Org."
1861   (when (eq major-mode 'elpher-mode)
1862     (let* ((url (elpher-info-current))
1863            (desc (car elpher-current-page))
1864            (protocol (cond
1865                       ((string-prefix-p "gemini:" url) "gemini")
1866                       ((string-prefix-p "gopher:" url) "gopher")
1867                       ((string-prefix-p "finger:" url) "finger")
1868                       (t "elpher"))))
1869       (when (equal "elpher" protocol)
1870         ;; Weird link. Or special inner link?
1871         (setq url (concat "elpher:" url)))
1872       (org-link-store-props :type protocol :link url :description desc)
1873       t)))
1874
1875 (defun elpher-org-follow-link (link protocol)
1876   "Visit a LINK for the given PROTOCOL.
1877
1878 PROTOCOL may be one of gemini, gopher or finger.  This method also
1879 supports the old protocol elpher, where the link is self-contained."
1880   (let ((url (if (equal protocol "elpher")
1881                  (string-remove-prefix "elpher:" link)
1882                (format "%s:%s" protocol link))))
1883     (elpher-go url)))
1884
1885 (defun elpher-org-mode-integration ()
1886   "Set up `elpher' integration for `org-mode'."
1887   (org-link-set-parameters
1888    "elpher"
1889    :store #'elpher-org-store-link
1890    :export (lambda (link description format _plist)
1891              (elpher-org-export-link link description format "elpher"))
1892    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1893   (org-link-set-parameters
1894    "gemini"
1895    :export (lambda (link description format _plist)
1896              (elpher-org-export-link link description format "gemini"))
1897    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
1898   (org-link-set-parameters
1899    "gopher"
1900    :export (lambda (link description format _plist)
1901              (elpher-org-export-link link description format "gopher"))
1902    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
1903   (org-link-set-parameters
1904    "finger"
1905    :export (lambda (link description format _plist)
1906              (elpher-org-export-link link description format "finger"))
1907    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
1908
1909 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
1910
1911 ;;; Browse URL
1912
1913 ;;;###autoload
1914 (defun elpher-browse-url-elpher (url &rest _args)
1915   "Browse URL using Elpher.  This function is used by `browse-url'."
1916   (interactive (browse-url-interactive-arg "Elpher URL: "))
1917   (elpher-go url))
1918
1919 ;; Use elpher to open gopher, finger and gemini links
1920 ;; For recent version of `browse-url' package
1921 (if (boundp 'browse-url-default-handlers)
1922     (add-to-list
1923      'browse-url-default-handlers
1924      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
1925   ;; Patch `browse-url-browser-function' for older ones. The value of
1926   ;; that variable is `browse-url-default-browser' by default, so
1927   ;; that's the function that gets advised.
1928   (advice-add browse-url-browser-function :before-while
1929               (lambda (url &rest _args)
1930                 "Handle gemini, gopher, and finger schemes using Elpher."
1931                 (let ((scheme (downcase (car (split-string url ":" t)))))
1932                   (if (member scheme '("gemini" "gopher" "finger"))
1933                       ;; `elpher-go' always returns nil, which will stop the
1934                       ;; advice chain here in a before-while
1935                       (elpher-go url)
1936                     ;; chain must continue, then return t.
1937                     t)))))
1938
1939 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1940 (with-eval-after-load 'thingatpt
1941   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
1942
1943 ;;; Mu4e:
1944
1945 ;; Make mu4e aware of the gemini world
1946 (setq mu4e~view-beginning-of-url-regexp
1947       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
1948
1949 ;;; Interactive procedures
1950 ;;
1951
1952 (defun elpher-next-link ()
1953   "Move point to the next link on the current page."
1954   (interactive)
1955   (forward-button 1))
1956
1957 (defun elpher-prev-link ()
1958   "Move point to the previous link on the current page."
1959   (interactive)
1960   (backward-button 1))
1961
1962 (defun elpher-follow-current-link ()
1963   "Open the link or url at point."
1964   (interactive)
1965   (push-button))
1966
1967 ;;;###autoload
1968 (defun elpher-go (host-or-url)
1969   "Go to a particular gopher site HOST-OR-URL.
1970 When run interactively HOST-OR-URL is read from the minibuffer."
1971   (interactive "sGopher or Gemini URL: ")
1972   (let* ((cleaned-host-or-url (string-trim host-or-url))
1973          (address (elpher-address-from-url cleaned-host-or-url))
1974          (page (elpher-make-page cleaned-host-or-url address)))
1975     (switch-to-buffer elpher-buffer-name)
1976     (elpher-with-clean-buffer
1977      (elpher-visit-page page))
1978     nil))
1979
1980 (defun elpher-go-current ()
1981   "Go to a particular site read from the minibuffer, initialized with the current URL."
1982   (interactive)
1983   (let ((address (elpher-page-address elpher-current-page)))
1984     (let ((url (read-string "Gopher or Gemini URL: "
1985                             (unless (elpher-address-special-p address)
1986                               (elpher-address-to-url address)))))
1987       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
1988
1989 (defun elpher-redraw ()
1990   "Redraw current page."
1991   (interactive)
1992   (elpher-visit-page elpher-current-page))
1993
1994 (defun elpher-reload ()
1995   "Reload current page."
1996   (interactive)
1997   (elpher-reload-current-page))
1998
1999 (defun elpher-toggle-tls ()
2000   "Toggle TLS encryption mode for gopher."
2001   (interactive)
2002   (setq elpher-use-tls (not elpher-use-tls))
2003   (if elpher-use-tls
2004       (if (gnutls-available-p)
2005           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2006         (setq elpher-use-tls nil)
2007         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2008     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2009
2010 (defun elpher-view-raw ()
2011   "View raw server response for current page."
2012   (interactive)
2013   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2014       (error "This page was not generated by a server")
2015     (elpher-visit-page elpher-current-page
2016                        #'elpher-render-raw)))
2017
2018 (defun elpher-back ()
2019   "Go to previous site."
2020   (interactive)
2021   (elpher-visit-previous-page))
2022
2023 (defun elpher-back-to-start ()
2024   "Go all the way back to the start page."
2025   (interactive)
2026   (setq-local elpher-current-page nil)
2027   (setq-local elpher-history nil)
2028   (elpher-visit-page (elpher-make-start-page)))
2029
2030 (defun elpher-download ()
2031   "Download the link at point."
2032   (interactive)
2033   (let ((button (button-at (point))))
2034     (if button
2035         (let ((page (button-get button 'elpher-page)))
2036           (if (elpher-address-special-p (elpher-page-address page))
2037               (error "Cannot download %s"
2038                      (elpher-page-display-string page))
2039             (elpher-visit-page (button-get button 'elpher-page)
2040                                #'elpher-render-download)))
2041       (error "No link selected"))))
2042
2043 (defun elpher-download-current ()
2044   "Download the current page."
2045   (interactive)
2046   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2047       (error "Cannot download %s"
2048              (elpher-page-display-string elpher-current-page))
2049     (elpher-visit-page (elpher-make-page
2050                         (elpher-page-display-string elpher-current-page)
2051                         (elpher-page-address elpher-current-page))
2052                        #'elpher-render-download
2053                        t)))
2054
2055 (defun elpher--build-link-map ()
2056   "Build alist mapping link names to destination pages in current buffer."
2057   (let ((link-map nil)
2058         (b (next-button (point-min) t)))
2059     (while b
2060       (push (cons (button-label b) b) link-map)
2061       (setq b (next-button (button-start b))))
2062     link-map))
2063
2064 (defun elpher-jump ()
2065   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2066   (interactive)
2067   (let* ((link-map (elpher--build-link-map)))
2068     (if link-map
2069         (let ((key (let ((completion-ignore-case t))
2070                      (completing-read "Directory item/link: "
2071                                       link-map nil t))))
2072           (if (and key (> (length key) 0))
2073               (let ((b (cdr (assoc key link-map))))
2074                 (goto-char (button-start b))
2075                 (button-activate b)))))))
2076
2077 (defun elpher-root-dir ()
2078   "Visit root of current server."
2079   (interactive)
2080   (let ((address (elpher-page-address elpher-current-page)))
2081     (if (not (elpher-address-special-p address))
2082         (if (or (member (url-filename address) '("/" ""))
2083                 (and (elpher-address-gopher-p address)
2084                      (= (length (elpher-gopher-address-selector address)) 0)))
2085             (error "Already at root directory of current server")
2086           (let ((address-copy (elpher-address-from-url
2087                                (elpher-address-to-url address))))
2088             (setf (url-filename address-copy) "")
2089             (elpher-go (elpher-address-to-url address-copy))))
2090       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2091
2092 (defun elpher-info-page (page)
2093   "Display information on PAGE."
2094   (let ((display-string (elpher-page-display-string page))
2095         (address (elpher-page-address page)))
2096     (if (elpher-address-special-p address)
2097         (message "Special page: %s" display-string)
2098       (message "%s" (elpher-address-to-url address)))))
2099
2100 (defun elpher-info-link ()
2101   "Display information on page corresponding to link at point."
2102   (interactive)
2103   (let ((button (button-at (point))))
2104     (if button
2105         (elpher-info-page (button-get button 'elpher-page))
2106       (error "No item selected"))))
2107
2108 (defun elpher-info-current ()
2109   "Display information on current page."
2110   (interactive)
2111   (elpher-info-page elpher-current-page))
2112
2113 (defun elpher-copy-page-url (page)
2114   "Copy URL representation of address of PAGE to `kill-ring'."
2115   (let ((address (elpher-page-address page)))
2116     (if (elpher-address-special-p address)
2117         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2118       (let ((url (elpher-address-to-url address)))
2119         (message "Copied \"%s\" to kill-ring/clipboard." url)
2120         (kill-new url)))))
2121
2122 (defun elpher-copy-link-url ()
2123   "Copy URL of item at point to `kill-ring'."
2124   (interactive)
2125   (let ((button (button-at (point))))
2126     (if button
2127         (elpher-copy-page-url (button-get button 'elpher-page))
2128       (error "No item selected"))))
2129
2130 (defun elpher-copy-current-url ()
2131   "Copy URL of current page to `kill-ring'."
2132   (interactive)
2133   (elpher-copy-page-url elpher-current-page))
2134
2135 (defun elpher-set-gopher-coding-system ()
2136   "Specify an explicit character coding system for gopher selectors."
2137   (interactive)
2138   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2139     (setq elpher-user-coding-system system)
2140     (if system
2141         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2142       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2143
2144
2145 ;;; Mode and keymap
2146 ;;
2147
2148 (defvar elpher-mode-map
2149   (let ((map (make-sparse-keymap)))
2150     (define-key map (kbd "TAB") 'elpher-next-link)
2151     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2152     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2153     (define-key map (kbd "u") 'elpher-back)
2154     (define-key map (kbd "-") 'elpher-back)
2155     (define-key map (kbd "^") 'elpher-back)
2156     (define-key map [mouse-3] 'elpher-back)
2157     (define-key map (kbd "U") 'elpher-back-to-start)
2158     (define-key map (kbd "g") 'elpher-go)
2159     (define-key map (kbd "o") 'elpher-go-current)
2160     (define-key map (kbd "O") 'elpher-root-dir)
2161     (define-key map (kbd "s") 'elpher-show-history)
2162     (define-key map (kbd "S") 'elpher-show-visited-pages)
2163     (define-key map (kbd "r") 'elpher-redraw)
2164     (define-key map (kbd "R") 'elpher-reload)
2165     (define-key map (kbd "T") 'elpher-toggle-tls)
2166     (define-key map (kbd ".") 'elpher-view-raw)
2167     (define-key map (kbd "d") 'elpher-download)
2168     (define-key map (kbd "D") 'elpher-download-current)
2169     (define-key map (kbd "m") 'elpher-jump)
2170     (define-key map (kbd "i") 'elpher-info-link)
2171     (define-key map (kbd "I") 'elpher-info-current)
2172     (define-key map (kbd "c") 'elpher-copy-link-url)
2173     (define-key map (kbd "C") 'elpher-copy-current-url)
2174     (define-key map (kbd "a") 'elpher-bookmark-link)
2175     (define-key map (kbd "A") 'elpher-bookmark-current)
2176     (define-key map (kbd "B") 'elpher-open-bookmarks)
2177     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2178     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2179     (when (fboundp 'evil-define-key*)
2180       (evil-define-key*
2181        'motion map
2182        (kbd "TAB") 'elpher-next-link
2183        (kbd "C-") 'elpher-follow-current-link
2184        (kbd "C-t") 'elpher-back
2185        (kbd "u") 'elpher-back
2186        (kbd "-") 'elpher-back
2187        (kbd "^") 'elpher-back
2188        [mouse-3] 'elpher-back
2189        (kbd "U") 'elpher-back-to-start
2190        (kbd "g") 'elpher-go
2191        (kbd "o") 'elpher-go-current
2192        (kbd "O") 'elpher-root-dir
2193        (kbd "s") 'elpher-show-history
2194        (kbd "S") 'elpher-show-visited-pages
2195        (kbd "r") 'elpher-redraw
2196        (kbd "R") 'elpher-reload
2197        (kbd "T") 'elpher-toggle-tls
2198        (kbd ".") 'elpher-view-raw
2199        (kbd "d") 'elpher-download
2200        (kbd "D") 'elpher-download-current
2201        (kbd "m") 'elpher-jump
2202        (kbd "i") 'elpher-info-link
2203        (kbd "I") 'elpher-info-current
2204        (kbd "c") 'elpher-copy-link-url
2205        (kbd "C") 'elpher-copy-current-url
2206        (kbd "a") 'elpher-bookmark-link
2207        (kbd "A") 'elpher-bookmark-current
2208        (kbd "B") 'elpher-open-bookmarks
2209        (kbd "!") 'elpher-set-gopher-coding-system
2210        (kbd "F") 'elpher-forget-current-certificate))
2211     map)
2212   "Keymap for gopher client.")
2213
2214 (define-derived-mode elpher-mode special-mode "elpher"
2215   "Major mode for elpher, an elisp gopher client.
2216
2217 This mode is automatically enabled by the interactive
2218 functions which initialize the client, namely
2219 `elpher', and `elpher-go'."
2220   (setq-local elpher--gemini-page-headings nil)
2221   (setq-local elpher-current-page nil)
2222   (setq-local elpher-history nil)
2223   (setq-local elpher-buffer-name (buffer-name))
2224   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2225   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings)))
2226
2227 (when (fboundp 'evil-set-initial-state)
2228   (evil-set-initial-state 'elpher-mode 'motion))
2229
2230
2231 ;;; Main start procedure
2232 ;;
2233
2234 ;;;###autoload
2235 (defun elpher (&optional arg)
2236   "Start elpher with default landing page.
2237 The buffer used for Elpher sessions is determined by the value of
2238 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2239 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2240 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2241 \\[execute-extended-command] elpher RET’) switches to the session with
2242 that number, creating it if necessary.  A non numeric prefix ARG means
2243 to create a new session.  Returns the buffer selected (or created)."
2244   (interactive "P")
2245   (let* ((name (default-value 'elpher-buffer-name))
2246          (buf (cond ((numberp arg)
2247                      (get-buffer-create (format "%s<%d>" name arg)))
2248                     (arg
2249                      (generate-new-buffer name))
2250                     (t
2251                      (get-buffer-create name)))))
2252     (pop-to-buffer-same-window buf)
2253     (unless (buffer-modified-p)
2254       (elpher-mode)
2255       (elpher-visit-page (elpher-make-start-page))
2256       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2257
2258 ;;; elpher.el ends here