elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 2.11.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: https://alexschroeder.ch/cgit/elpher
  25 ;; Package-Requires: ((emacs "27.1"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - gopher connections using TLS encryption,
  54 ;; - the fledgling Gemini protocol,
  55 ;; - the greybeard Finger protocol.
  56
  57 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  58 ;; page containing information on key bindings and suggested starting
  59 ;; points for your gopher exploration.
  60
  61 ;; Full instructions can be found in the Elpher info manual.
  62
  63 ;; Elpher is under active development.  Any suggestions for
  64 ;; improvements are welcome, and can be made on the official
  65 ;; project page, https://alexschroeder.ch/cgit/elpher.
  66
  67 ;;; Code:
  68
  69 (provide 'elpher)
  70
  71 ;;; Dependencies
  72 ;;
  73
  74 (require 'seq)
  75 (require 'pp)
  76 (require 'shr)
  77 (require 'url-util)
  78 (require 'subr-x)
  79 (require 'dns)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83
  84 ;;; ANSI colors or XTerm colors
  85
  86 (or (require 'xterm-color nil t)
  87     (require 'ansi-color))
  88
  89 (defalias 'elpher-color-filter-apply
  90   (if (fboundp 'xterm-color-filter)
  91       (lambda (s)
  92         (let ((_xterm-color-render nil))
  93           (xterm-color-filter s)))
  94     'ansi-color-filter-apply)
  95   "A function to filter out ANSI escape sequences.")
  96
  97 (defalias 'elpher-color-apply
  98   (if (fboundp 'xterm-color-filter)
  99       'xterm-color-filter
 100     'ansi-color-apply)
 101   "A function to apply ANSI escape sequences.")
 102
 103 ;;; Global constants
 104 ;;
 105
 106 (defconst elpher-version "2.11.0"
 107   "Current version of elpher.")
 108
 109 (defconst elpher-margin-width 6
 110   "Width of left-hand margin used when rendering indicies.")
 111
 112 (defconst elpher-type-map
 113   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 114     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 115     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 116     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 117     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 118     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 119     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 120     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 122     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 123     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 124     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 125     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 126     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 127     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 128     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 129     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 130     ((special start) elpher-get-start-page nil)
 131     ((special history) elpher-get-history-page nil)
 132     ((special history-all) elpher-get-history-all-page nil))
 133   "Association list from types to getters, renderers, margin codes and index faces.")
 134
 135
 136 ;;; Internal variables
 137 ;;
 138
 139 ;; buffer-local
 140 (defvar elpher--gemini-page-headings nil
 141   "List of headings on the page.")
 142
 143
 144 ;;; Customization group
 145 ;;
 146
 147 (defgroup elpher nil
 148   "A gopher and gemini client."
 149   :group 'applications)
 150
 151 ;; General appearance and customizations
 152
 153 (defcustom elpher-open-urls-with-eww nil
 154   "If non-nil, open URL selectors using eww.
 155 Otherwise, use the system browser via the `browse-url' function."
 156   :type '(boolean))
 157
 158 (defcustom elpher-use-header t
 159   "If non-nil, display current page information in buffer header."
 160   :type '(boolean))
 161
 162 (defcustom elpher-auto-disengage-TLS nil
 163   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 164 While enabling this may seem convenient, it is also potentially
 165 dangerous as it allows switching from an encrypted channel back to
 166 plain text without user input."
 167   :type '(boolean))
 168
 169 (defcustom elpher-connection-timeout 5
 170   "Specifies the number of seconds to wait for a network connection to time out."
 171   :type '(integer))
 172
 173 (defcustom elpher-filter-ansi-from-text nil
 174   "If non-nil, filter ANSI escape sequences from text.
 175 The default behaviour is to use the ansi-color package to interpret these
 176 sequences."
 177   :type '(boolean))
 178
 179 (defcustom elpher-certificate-directory
 180   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 181   "Specify the name of the directory where client certificates will be stored.
 182 These certificates may be used for establishing authenticated TLS connections."
 183   :type '(directory))
 184
 185 (defcustom elpher-openssl-command "openssl"
 186   "The command used to launch openssl when generating TLS client certificates."
 187   :type '(file))
 188
 189 (defcustom elpher-default-url-type "gopher"
 190   "Default URL type (i.e. scheme) to assume if not explicitly given."
 191   :type '(choice (const "gopher")
 192                  (const "gemini")))
 193
 194 (defcustom elpher-gemini-TLS-cert-checks nil
 195   "If non-nil, verify gemini server TLS certs using the default security level.
 196 Otherwise, certificate verification is disabled.
 197
 198 This defaults to off because it is standard practice for Gemini servers
 199 to use self-signed certificates, meaning that most servers provide what
 200 EMACS considers to be an invalid certificate."
 201   :type '(boolean))
 202
 203 (defcustom elpher-gemini-max-fill-width 80
 204   "Specify the maximum default width (in columns) of text/gemini documents.
 205 The actual width used is the minimum of this value and the window width at
 206 the time when the text is rendered."
 207   :type '(integer))
 208
 209 (defcustom elpher-gemini-link-string "→ "
 210   "Specify the string used to indicate links when rendering gemini maps.
 211 May be empty."
 212   :type '(string))
 213
 214 (defcustom elpher-gemini-bullet-string "•"
 215   "Specify the string used for bullets when rendering gemini maps."
 216   :type '(string))
 217
 218 (defcustom elpher-ipv4-always nil
 219   "If non-nil, elpher will always use IPv4 to establish network connections.
 220 This can be useful when browsing from a computer that supports IPv6, because
 221 some servers which do not support IPv6 can take a long time to time-out."
 222   :type '(boolean))
 223
 224 (defcustom elpher-socks-always nil
 225   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 226 Otherwise, the SOCKS proxy is only used for connections to onion services."
 227   :type '(boolean))
 228
 229 (defcustom elpher-number-links nil
 230   "If non-nil, number links in pages when rendering.
 231 Links can be followed numerically by pressing `M' and entering by the link number."
 232   :type '(boolean))
 233
 234 ;; Face customizations
 235
 236 (defgroup elpher-faces nil
 237   "Elpher face customizations."
 238   :group 'elpher)
 239
 240 (defface elpher-index
 241   '((t :inherit font-lock-keyword-face))
 242   "Face used for directory type directory records.")
 243
 244 (defface elpher-text
 245   '((t :inherit bold))
 246   "Face used for text type directory records.")
 247
 248 (defface elpher-info
 249   '((t :inherit default))
 250   "Face used for info type directory records.")
 251
 252 (defface elpher-image
 253   '((t :inherit font-lock-string-face))
 254   "Face used for image type directory records.")
 255
 256 (defface elpher-search
 257   '((t :inherit warning))
 258   "Face used for search type directory records.")
 259
 260 (defface elpher-html
 261   '((t :inherit font-lock-comment-face))
 262   "Face used for html type directory records.")
 263
 264 (defface elpher-gemini
 265   '((t :inherit font-lock-constant-face))
 266   "Face used for Gemini type directory records.")
 267
 268 (defface elpher-other-url
 269   '((t :inherit font-lock-comment-face))
 270   "Face used for other URL type links records.")
 271
 272 (defface elpher-telnet
 273   '((t :inherit font-lock-function-name-face))
 274   "Face used for telnet type directory records.")
 275
 276 (defface elpher-binary
 277   '((t :inherit font-lock-doc-face))
 278   "Face used for binary type directory records.")
 279
 280 (defface elpher-unknown
 281   '((t :inherit error))
 282   "Face used for directory records with unknown/unsupported types.")
 283
 284 (defface elpher-margin-key
 285   '((t :inherit bold))
 286   "Face used for directory margin key.")
 287
 288 (defface elpher-margin-brackets
 289   '((t :inherit shadow))
 290   "Face used for brackets around directory margin key.")
 291
 292 (defface elpher-gemini-heading1
 293   '((t :inherit bold :height 1.8))
 294   "Face used for gemini heading level 1.")
 295
 296 (defface elpher-gemini-heading2
 297   '((t :inherit bold :height 1.5))
 298   "Face used for gemini heading level 2.")
 299
 300 (defface elpher-gemini-heading3
 301   '((t :inherit bold :height 1.2))
 302   "Face used for gemini heading level 3.")
 303
 304 (defface elpher-gemini-preformatted
 305   '((t :inherit fixed-pitch))
 306   "Face used for pre-formatted gemini text blocks.")
 307
 308 (defface elpher-gemini-quoted
 309   '((t :inherit font-lock-doc-face))
 310   "Face used for gemini quoted texts.")
 311
 312 ;;; Model
 313 ;;
 314
 315 ;; Address
 316
 317 ;; An elpher "address" object is either a url object or a symbol.
 318 ;; Symbol addresses are "special", corresponding to pages generated
 319 ;; dynamically for and by elpher.  All others represent pages which
 320 ;; rely on content retrieved over the network.
 321
 322 (defun elpher-address-from-url (url-string)
 323   "Create a ADDRESS object corresponding to the given URL-STRING."
 324   (let ((data (match-data))) ; Prevent parsing clobbering match data
 325     (unwind-protect
 326         (let ((url (url-generic-parse-url url-string)))
 327           (unless (and (not (url-fullness url)) (url-type url))
 328             (setf (url-fullness url) t)
 329             (unless (url-type url)
 330               (setf (url-type url) elpher-default-url-type))
 331             (unless (url-host url)
 332               (let ((p (split-string (url-filename url) "/" nil nil)))
 333                 (setf (url-host url) (car p))
 334                 (setf (url-filename url)
 335                       (if (cdr p)
 336                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 337                         ""))))
 338             (when (or (equal "gopher" (url-type url))
 339                       (equal "gophers" (url-type url)))
 340               ;; Gopher defaults
 341               (when (or (equal (url-filename url) "")
 342                         (equal (url-filename url) "/"))
 343                 (setf (url-filename url) "/1")))
 344             (when (equal "gemini" (url-type url))
 345               ;; Gemini defaults
 346               (if (equal (url-filename url) "")
 347                   (setf (url-filename url) "/"))))
 348           (elpher-remove-redundant-ports url))
 349       (set-match-data data))))
 350
 351 (defun elpher-remove-redundant-ports (address)
 352   "Remove redundant port specifiers from ADDRESS.
 353 Here 'redundant' means that the specified port matches the default
 354 for that protocol, eg 70 for gopher."
 355   (if (and (not (elpher-address-special-p address))
 356            (eq (url-portspec address) ; (url-port) is too slow!
 357                (pcase (url-type address)
 358                  ("gemini" 1965)
 359                  ((or "gopher" "gophers") 70)
 360                  ("finger" 79)
 361                  (_ -1))))
 362       (setf (url-portspec address) nil))
 363   address)
 364
 365 (defun elpher-make-gopher-address (type selector host port &optional tls)
 366   "Create an ADDRESS object using gopher directory record attributes.
 367 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 368 If the optional attribute TLS is non-nil, the address will be marked as
 369 requiring gopher-over-TLS."
 370   (cond
 371    ((equal type ?i) nil)
 372    ((and (equal type ?h)
 373          (string-prefix-p "URL:" selector))
 374     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 375    ((equal type ?8)
 376     (elpher-address-from-url
 377      (concat "telnet"
 378              "://" host
 379              ":" (number-to-string port))))
 380    (t
 381     (elpher-address-from-url
 382      (concat "gopher" (if tls "s" "")
 383              "://" host
 384              ":" (number-to-string port)
 385              "/" (string type)
 386              selector)))))
 387
 388 (defun elpher-make-special-address (type)
 389   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 390   type)
 391
 392 (defun elpher-make-start-page ()
 393   "Create the start page."
 394   (elpher-make-page "Elpher Start Page"
 395                     (elpher-make-special-address 'start)))
 396
 397 (defun elpher-address-to-url (address)
 398   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 399   (if (elpher-address-special-p address)
 400       nil
 401     (url-encode-url (url-recreate-url address))))
 402
 403 (defun elpher-address-type (address)
 404   "Retrieve type of ADDRESS object.
 405 This is used to determine how to retrieve and render the document the
 406 address refers to, via the table `elpher-type-map'."
 407   (if (symbolp address)
 408       (list 'special address)
 409     (let ((protocol (url-type address)))
 410       (cond ((or (equal protocol "gopher")
 411                  (equal protocol "gophers"))
 412              (list 'gopher
 413                    (if (member (url-filename address) '("" "/"))
 414                        ?1
 415                      (string-to-char (substring (url-filename address) 1)))))
 416             ((equal protocol "gemini")
 417              'gemini)
 418             ((equal protocol "telnet")
 419              'telnet)
 420             ((equal protocol "finger")
 421              'finger)
 422             (t 'other-url)))))
 423
 424 (defun elpher-address-protocol (address)
 425   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 426   (if (symbolp address)
 427       nil
 428     (url-type address)))
 429
 430 (defun elpher-address-filename (address)
 431   "Retrieve the filename component of ADDRESS.
 432 For gopher addresses this is a combination of the selector type and selector."
 433   (if (symbolp address)
 434       nil
 435     (url-unhex-string (url-filename address))))
 436
 437 (defun elpher-address-host (address)
 438   "Retrieve host from ADDRESS object."
 439   (url-host address))
 440
 441 (defun elpher-address-user (address)
 442   "Retrieve user from ADDRESS object."
 443   (url-user address))
 444
 445 (defun elpher-address-port (address)
 446   "Retrieve port from ADDRESS object.
 447 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 448   (if (symbolp address)
 449       0
 450     (url-port address)))
 451
 452 (defun elpher-address-special-p (address)
 453   "Return non-nil if ADDRESS object is special (e.g. start page page)."
 454   (symbolp address))
 455
 456 (defun elpher-address-gopher-p (address)
 457   "Return non-nill if ADDRESS object is a gopher address."
 458   (and (not (elpher-address-special-p address))
 459        (member (elpher-address-protocol address) '("gopher" "gophers"))))
 460
 461 (defun elpher-gopher-address-selector (address)
 462   "Retrieve gopher selector from ADDRESS object."
 463   (if (member (url-filename address) '("" "/"))
 464       ""
 465     (url-unhex-string (substring (url-filename address) 2))))
 466
 467
 468 ;; Cache
 469
 470 (defvar elpher-content-cache (make-hash-table :test 'equal))
 471 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 472
 473 (defun elpher-get-cached-content (address)
 474   "Retrieve the cached content for ADDRESS, or nil if none exists."
 475   (gethash address elpher-content-cache))
 476
 477 (defun elpher-cache-content (address content)
 478   "Set the content cache for ADDRESS to CONTENT."
 479   (puthash address content elpher-content-cache))
 480
 481 (defun elpher-get-cached-pos (address)
 482   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 483   (gethash address elpher-pos-cache))
 484
 485 (defun elpher-cache-pos (address pos)
 486   "Set the cursor position cache for ADDRESS to POS."
 487   (puthash address pos elpher-pos-cache))
 488
 489
 490 ;; Page
 491
 492 (defun elpher-make-page (display-string address)
 493   "Create a page with DISPLAY-STRING and ADDRESS."
 494   (list display-string address))
 495
 496 (defun elpher-page-display-string (page)
 497   "Retrieve the display string corresponding to PAGE."
 498   (elt page 0))
 499
 500 (defun elpher-page-address (page)
 501   "Retrieve the address corresponding to PAGE."
 502   (elt page 1))
 503
 504 (defun elpher-page-set-address (page new-address)
 505   "Set the address corresponding to PAGE to NEW-ADDRESS."
 506   (setcar (cdr page) new-address))
 507
 508 (defvar elpher-current-page nil
 509   "The current page for this Elpher buffer.")
 510
 511 (defvar elpher-history nil
 512   "The local history for this Elpher buffer.
 513 This variable is used by `elpher-back' and
 514 `elpher-show-history'.")
 515
 516 (defvar elpher-history-all nil
 517   "The global history for all Elpher buffers.
 518 This variable is used by `elpher-show-history-all'.")
 519
 520 (defun elpher-visit-page (page &optional renderer no-history)
 521   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 522 Additionally, push PAGE onto the stack of previously-visited pages,
 523 unless NO-HISTORY is non-nil."
 524   (elpher-save-pos)
 525   (elpher-process-cleanup)
 526   (elpher-reset-link-number-counter)
 527   (unless (or no-history
 528               (equal (elpher-page-address elpher-current-page)
 529                      (elpher-page-address page)))
 530     (push elpher-current-page elpher-history)
 531     (push elpher-current-page elpher-history-all))
 532   (setq-local elpher-current-page page)
 533   (let* ((address (elpher-page-address page))
 534          (type (elpher-address-type address))
 535          (type-record (cdr (assoc type elpher-type-map))))
 536     (if type-record
 537         (funcall (car type-record)
 538                  (if renderer
 539                      renderer
 540                    (cadr type-record)))
 541       (elpher-visit-previous-page)
 542       (pcase type
 543         (`(gopher ,type-char)
 544          (error "Unsupported gopher selector type '%c' for '%s'"
 545                 type-char (elpher-address-to-url address)))
 546         (other
 547          (error "Unsupported address type '%S' for '%s'"
 548                 other (elpher-address-to-url address)))))))
 549
 550 (defun elpher-visit-previous-page ()
 551   "Visit the previous page in the history."
 552   (let ((previous-page (pop elpher-history)))
 553     (if previous-page
 554         (elpher-visit-page previous-page nil t)
 555       (error "No previous page"))))
 556
 557 (defun elpher-reload-current-page ()
 558   "Reload the current page, discarding any existing cached content."
 559   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 560   (elpher-visit-page elpher-current-page))
 561
 562 (defun elpher-save-pos ()
 563   "Save the current position of point to the current page."
 564   (when elpher-current-page
 565     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 566
 567 (defun elpher-restore-pos ()
 568   "Restore the position of point to that cached in the current page."
 569   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 570     (if pos
 571         (goto-char pos)
 572       (goto-char (point-min)))))
 573
 574
 575 ;;; Buffer preparation
 576 ;;
 577
 578 (defvar elpher-buffer-name "*elpher*"
 579   "The default name of the Elpher buffer.")
 580
 581 (defun elpher-update-header ()
 582   "If `elpher-use-header' is true, display current page info in window header."
 583   (if elpher-use-header
 584       (let* ((display-string (elpher-page-display-string elpher-current-page))
 585              (address (elpher-page-address elpher-current-page))
 586              (tls-string (if (and (not (elpher-address-special-p address))
 587                                   (member (elpher-address-protocol address)
 588                                           '("gophers" "gemini")))
 589                              " [TLS encryption]"
 590                            ""))
 591              (header (concat display-string
 592                              (propertize tls-string 'face 'bold))))
 593         (setq header-line-format header))))
 594
 595 (defmacro elpher-with-clean-buffer (&rest args)
 596   "Evaluate ARGS with a clean *elpher* buffer as current."
 597   `(with-current-buffer elpher-buffer-name
 598      (unless (eq major-mode 'elpher-mode)
 599        ;; avoid resetting buffer-local variables
 600        (elpher-mode))
 601      (let ((inhibit-read-only t))
 602        (setq-local network-security-level
 603                    (default-value 'network-security-level))
 604        (erase-buffer)
 605        (elpher-update-header)
 606        ,@args)))
 607
 608 (defun elpher-buffer-message (string &optional line)
 609   "Replace first line in elpher buffer with STRING.
 610 If LINE is non-nil, replace that line instead."
 611   (with-current-buffer elpher-buffer-name
 612     (let ((inhibit-read-only t))
 613       (goto-char (point-min))
 614       (if line
 615           (forward-line line))
 616       (let ((data (match-data)))
 617         (unwind-protect
 618             (progn
 619               (re-search-forward "^.*$")
 620               (replace-match string))
 621           (set-match-data data))))))
 622
 623
 624 ;;; Text Processing
 625 ;;
 626
 627 (defvar elpher-user-coding-system nil
 628   "User-specified coding system to use for decoding text responses.")
 629
 630 (defun elpher-decode (string)
 631   "Decode STRING using autodetected or user-specified coding system."
 632   (decode-coding-string string
 633                         (if elpher-user-coding-system
 634                             elpher-user-coding-system
 635                           (detect-coding-string string t))))
 636
 637 (defun elpher-preprocess-text-response (string)
 638   "Preprocess text selector response contained in STRING.
 639 This involes decoding the character representation, and clearing
 640 away CRs and any terminating period."
 641   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 642                                            (replace-regexp-in-string "\r" "" string))))
 643
 644
 645 ;;; Network error reporting
 646 ;;
 647
 648 (defun elpher-network-error (address error)
 649   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 650 ERROR can be either an error object or a string."
 651   (elpher-with-clean-buffer
 652    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 653            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 654            (if (stringp error) error (error-message-string error)) "\n"
 655            (propertize "\n----------------\n\n" 'face 'error)
 656            "Press 'u' to return to the previous page.")))
 657
 658
 659 ;;; General network communication
 660 ;;
 661
 662 (defvar elpher-network-timer nil
 663   "Timer used for network connections.")
 664
 665 (defvar elpher-use-tls nil
 666   "If non-nil, use TLS to communicate with gopher servers.")
 667
 668 (defvar elpher-client-certificate nil
 669   "If non-nil, contains client certificate details to use for TLS connections.")
 670
 671 (defun elpher-process-cleanup ()
 672   "Immediately shut down any extant elpher process and timers."
 673   (let ((p (get-process "elpher-process")))
 674     (if p (delete-process p)))
 675   (if (timerp elpher-network-timer)
 676       (cancel-timer elpher-network-timer)))
 677
 678 (defun elpher-get-host-response (address default-port query-string response-processor
 679                                          &optional use-tls force-ipv4)
 680   "Generic function for retrieving data from ADDRESS.
 681
 682 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 683 QUERY-STRING is a string sent to the host specified by ADDRESS to
 684 illicet a response.  This response is passed as an argument to the
 685 function RESPONSE-PROCESSOR.
 686
 687 If non-nil, USE-TLS specifies that the connection is to be made over
 688 TLS.  If set to gemini, the certificate verification will be disabled
 689 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 690
 691 If non-nil, FORCE-IPV4 causes the network connection to be made over
 692 ipv4 only.  (The default behaviour when this is not set depends on
 693 the host operating system and the local network capabilities.)"
 694   (if (and use-tls (not (gnutls-available-p)))
 695       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 696     (unless (< (elpher-address-port address) 65536)
 697       (error "Cannot establish network connection: port number > 65536"))
 698     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 699       (setq-local network-security-level 'low)
 700       (setq-local gnutls-verify-error nil))
 701     (condition-case nil
 702         (let* ((kill-buffer-query-functions nil)
 703                (port (elpher-address-port address))
 704                (service (if (> port 0) port default-port))
 705                (host (elpher-address-host address))
 706                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 707                (response-string-parts nil)
 708                (bytes-received 0)
 709                (hkbytes-received 0)
 710                (timer (run-at-time elpher-connection-timeout nil
 711                                    (lambda ()
 712                                      (elpher-process-cleanup)
 713                                      (cond
 714                                         ; Try again with IPv4
 715                                       ((not (or force-ipv4 socks))
 716                                        (message "Connection timed out.  Retrying with IPv4.")
 717                                        (elpher-get-host-response address default-port
 718                                                                  query-string
 719                                                                  response-processor
 720                                                                  use-tls t))
 721                                       ((and use-tls
 722                                             (not (eq use-tls 'gemini))
 723                                             (or elpher-auto-disengage-TLS
 724                                                 (y-or-n-p
 725                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 726                                        (setq elpher-use-tls nil)
 727                                        (elpher-get-host-response address default-port
 728                                                                  query-string
 729                                                                  response-processor
 730                                                                  nil force-ipv4))
 731                                       (t
 732                                        (elpher-network-error address "Connection time-out."))))))
 733                (gnutls-params (list :type 'gnutls-x509pki :hostname host
 734                                     :keylist (elpher-get-current-keylist address)))
 735                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 736                        (make-network-process :name "elpher-process"
 737                                              :host host
 738                                              :family (and force-ipv4 'ipv4)
 739                                              :service service
 740                                              :buffer nil
 741                                              :nowait t
 742                                              :tls-parameters
 743                                              (and use-tls
 744                                                   (cons 'gnutls-x509pki
 745                                                         (apply #'gnutls-boot-parameters
 746                                                                gnutls-params)))))))
 747           (setq elpher-network-timer timer)
 748           (set-process-coding-system proc 'binary 'binary)
 749           (set-process-query-on-exit-flag proc nil)
 750           (elpher-buffer-message (concat "Connecting to " host "..."
 751                                          " (press 'u' to abort)"))
 752           (set-process-filter proc
 753                               (lambda (_proc string)
 754                                 (when timer
 755                                   (cancel-timer timer)
 756                                   (setq timer nil))
 757                                 (setq bytes-received (+ bytes-received (length string)))
 758                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 759                                   (when (> new-hkbytes-received hkbytes-received)
 760                                     (setq hkbytes-received new-hkbytes-received)
 761                                     (elpher-buffer-message
 762                                      (concat "("
 763                                              (number-to-string (/ hkbytes-received 10.0))
 764                                              " MB read)")
 765                                      1)))
 766                                 (setq response-string-parts
 767                                       (cons string response-string-parts))))
 768           (set-process-sentinel proc
 769                                 (lambda (proc event)
 770                                   (when timer
 771                                     (cancel-timer timer))
 772                                   (condition-case the-error
 773                                       (cond
 774                                        ((string-prefix-p "open" event)    ; request URL
 775                                         (elpher-buffer-message
 776                                          (concat "Connected to " host ". Receiving data..."
 777                                                  " (press 'u' to abort)"))
 778                                         (let ((inhibit-eol-conversion t))
 779                                           (process-send-string proc query-string)))
 780                                        ((string-prefix-p "deleted" event)) ; do nothing
 781                                        ((and (not response-string-parts)
 782                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 783                                         ; Try again with IPv4
 784                                         (message "Connection failed. Retrying with IPv4.")
 785                                         (elpher-get-host-response address default-port
 786                                                                   query-string
 787                                                                   response-processor
 788                                                                   use-tls t))
 789                                        (response-string-parts
 790                                         (elpher-with-clean-buffer
 791                                          (insert "Data received.  Rendering..."))
 792                                         (funcall response-processor
 793                                                  (apply #'concat (reverse response-string-parts)))
 794                                         (elpher-restore-pos))
 795                                        (t
 796                                         (error "No response from server")))
 797                                     (error
 798                                      (elpher-network-error address the-error)))))
 799           (when socks
 800             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 801             (funcall (process-sentinel proc) proc "open\n")))
 802       (error
 803        (error "Error initiating connection to server")))))
 804
 805
 806 ;;; Client-side TLS Certificate Management
 807 ;;
 808
 809 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 810   "Generate a key and a self-signed client TLS certificate using openssl.
 811
 812 The Common Name field of the certificate is set to COMMON-NAME.  The
 813 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 814 the key and certificate files to write.
 815
 816 If TEMPORARY is non-nil, the certificate will be given an exporation
 817 period of one day, and the key and certificate files will be deleted
 818 when the certificate is no longer needed for the current session.
 819
 820 Otherwise, the certificate will be given a 100 year expiration period
 821 and the files will not be deleted.
 822
 823 The function returns a list containing the current host name, the
 824 temporary flag, and the key and cert file names in the form required
 825 by `gnutls-boot-parameters`."
 826   (let ((exp-key-file (expand-file-name key-file))
 827         (exp-cert-file (expand-file-name cert-file)))
 828     (condition-case nil
 829         (progn
 830           (call-process elpher-openssl-command nil nil nil
 831                         "req" "-x509" "-newkey" "rsa:2048"
 832                         "-days" (if temporary "1" "36500")
 833                         "-nodes"
 834                         "-subj" (concat "/CN=" common-name)
 835                         "-keyout" exp-key-file
 836                         "-out" exp-cert-file)
 837           (list (elpher-address-host (elpher-page-address elpher-current-page))
 838                 temporary exp-key-file exp-cert-file))
 839       (error
 840        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 841        (error "Program 'openssl', required for certificate generation, not found")))))
 842
 843 (defun elpher-generate-throwaway-certificate ()
 844   "Generate and return details of a throwaway certificate.
 845 The key and certificate files will be deleted when they are no
 846 longer needed for this session."
 847   (let* ((file-base (make-temp-name "elpher"))
 848          (key-file (concat temporary-file-directory file-base ".key"))
 849          (cert-file (concat temporary-file-directory file-base ".crt")))
 850     (elpher-generate-certificate file-base key-file cert-file t)))
 851
 852 (defun elpher-generate-persistent-certificate (file-base common-name)
 853   "Generate and return details of a persistent certificate.
 854 The argument FILE-BASE is used as the base for the key and certificate
 855 files, while COMMON-NAME specifies the common name field of the
 856 certificate.
 857
 858 The key and certificate files are written to in `elpher-certificate-directory'."
 859   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 860          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 861     (elpher-generate-certificate common-name key-file cert-file)))
 862
 863 (defun elpher-get-existing-certificate (file-base)
 864   "Return a certificate object corresponding to an existing certificate.
 865 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 866 the directory `elpher-certificate-directory'."
 867   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 868          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 869     (list (elpher-address-host (elpher-page-address elpher-current-page))
 870           nil
 871           (expand-file-name key-file)
 872           (expand-file-name cert-file))))
 873
 874 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 875   "Install a key+certificate file pair in `elpher-certificate-directory'.
 876 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 877 certificate files to install.  The argument FILE-BASE is used as the
 878 base for the installed key and certificate files."
 879   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 880          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 881     (if (or (file-exists-p key-file)
 882             (file-exists-p cert-file))
 883         (error "A certificate with base name %s is already installed" file-base))
 884     (copy-file key-file-src key-file)
 885     (copy-file cert-file-src cert-file)
 886     (list (elpher-address-host (elpher-page-address elpher-current-page))
 887           nil
 888           (expand-file-name key-file)
 889           (expand-file-name cert-file))))
 890
 891 (defun elpher-list-existing-certificates ()
 892   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 893   (unless (file-directory-p elpher-certificate-directory)
 894     (make-directory elpher-certificate-directory))
 895   (mapcar
 896    (lambda (file)
 897      (file-name-sans-extension file))
 898    (directory-files elpher-certificate-directory nil "\\.key$")))
 899
 900 (defun elpher-forget-current-certificate ()
 901   "Causes any current certificate to be forgotten.)
 902 In the case of throwaway certificates, the key and certificate files
 903 are also deleted."
 904   (interactive)
 905   (when elpher-client-certificate
 906     (unless (and (called-interactively-p 'any)
 907                  (not (y-or-n-p (concat "Really forget client certificate? "
 908                                         "(Throwaway certificates will be deleted.)"))))
 909       (when (cadr elpher-client-certificate)
 910         (delete-file (elt elpher-client-certificate 2))
 911         (delete-file (elt elpher-client-certificate 3)))
 912       (setq elpher-client-certificate nil)
 913       (if (called-interactively-p 'any)
 914           (message "Client certificate forgotten.")))))
 915
 916 (defun elpher-get-current-keylist (address)
 917   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 918
 919 This is obtained from the client certificate described by
 920 `elpher-current-certificate', if one is available and the host for
 921 that certificate matches the host in ADDRESS.
 922
 923 If `elpher-current-certificate' is non-nil, and its host name doesn't
 924 match that of ADDRESS, the certificate is forgotten."
 925   (if elpher-client-certificate
 926       (if (string= (car elpher-client-certificate)
 927                    (elpher-address-host address))
 928           (list (cddr elpher-client-certificate))
 929         (elpher-forget-current-certificate)
 930         (message "Disabling client certificate for new host")
 931         nil)
 932     nil))
 933
 934
 935 ;;; Gopher selector retrieval
 936 ;;
 937
 938 (defun elpher-get-gopher-response (address renderer)
 939   "Get response string from gopher server at ADDRESS and render using RENDERER."
 940   (elpher-get-host-response address 70
 941                             (concat (elpher-gopher-address-selector address) "\r\n")
 942                             renderer
 943                             (or (string= (elpher-address-protocol address) "gophers")
 944                                 elpher-use-tls)))
 945
 946 (defun elpher-get-gopher-page (renderer)
 947   "Getter function for gopher pages.
 948 The RENDERER procedure is used to display the contents of the page
 949 once they are retrieved from the gopher server."
 950   (let* ((address (elpher-page-address elpher-current-page))
 951          (content (elpher-get-cached-content address)))
 952     (if (and content (funcall renderer nil))
 953         (elpher-with-clean-buffer
 954          (insert content)
 955          (elpher-restore-pos))
 956       (elpher-with-clean-buffer
 957        (insert "LOADING... (use 'u' to cancel)\n"))
 958       (condition-case the-error
 959           (elpher-get-gopher-response address renderer)
 960         (error
 961          (elpher-network-error address the-error))))))
 962
 963 ;; Index rendering
 964
 965 (defun elpher-insert-index (string)
 966   "Insert the index corresponding to STRING into the current buffer."
 967   ;; Should be able to split directly on CRLF, but some non-conformant
 968   ;; LF-only servers sadly exist, hence the following.
 969   (let ((str-processed (elpher-preprocess-text-response string)))
 970     (dolist (line (split-string str-processed "\n"))
 971       (ignore-errors
 972         (unless (= (length line) 0)
 973           (let* ((type (elt line 0))
 974                  (fields (split-string (substring line 1) "\t"))
 975                  (display-string (elt fields 0))
 976                  (selector (elt fields 1))
 977                  (host (elt fields 2))
 978                  (port (if (elt fields 3)
 979                            (string-to-number (elt fields 3))
 980                          nil))
 981                  (address (elpher-make-gopher-address type selector host port)))
 982             (elpher-insert-index-record display-string address)))))))
 983
 984 (defun elpher-insert-margin (&optional type-name)
 985   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 986   (if type-name
 987       (progn
 988         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 989                         (concat
 990                          (propertize "[" 'face 'elpher-margin-brackets)
 991                          (propertize type-name 'face 'elpher-margin-key)
 992                          (propertize "]" 'face 'elpher-margin-brackets))))
 993         (insert " "))
 994     (insert (make-string elpher-margin-width ?\s))))
 995
 996 (defun elpher--page-button-help (_window buffer pos)
 997   "Function called by Emacs to generate mouse-over text.
 998 The arguments specify the BUFFER and the POS within the buffer of the item
 999 for which help is required.  The function returns the help to be
1000 displayed.  The _WINDOW argument is currently unused."
1001   (with-current-buffer buffer
1002     (let ((button (button-at pos)))
1003       (when button
1004         (let* ((page (button-get button 'elpher-page))
1005                (address (elpher-page-address page)))
1006           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1007                                                 address
1008                                               (elpher-address-to-url address))))))))
1009
1010 (defvar elpher--link-number-counter 0
1011   "Used to number links on elpher pages.")
1012 (defun elpher-reset-link-number-counter ()
1013   "Reset the link number counter."
1014   (setq-local elpher--link-number-counter 0))
1015
1016 (defun elpher--insert-text-button (label &rest properties)
1017   "Insert a potentially-numbered button into the current buffer.
1018 The text for the button is provided by LABEL, while the button
1019 properties in PROPERTIES are as per `insert-text-button'."
1020
1021   (if elpher-number-links
1022       (setq-local elpher--link-number-counter (+ elpher--link-number-counter 1)))
1023   (let ((pref (if elpher-number-links
1024                   (concat "[" (number-to-string elpher--link-number-counter) "] ")
1025                 "")))
1026     (apply #'insert-text-button (cons (concat pref label) properties))))
1027
1028 (defun elpher-insert-index-record (display-string &optional address)
1029   "Function to insert an index record into the current buffer.
1030 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1031 If ADDRESS is not supplied or nil the record is rendered as an
1032 'information' line."
1033   (let* ((type (if address (elpher-address-type address) nil))
1034          (type-map-entry (cdr (assoc type elpher-type-map))))
1035     (if type-map-entry
1036         (let* ((margin-code (elt type-map-entry 2))
1037                (face (elt type-map-entry 3))
1038                (filtered-display-string (elpher-color-filter-apply display-string))
1039                (page (elpher-make-page filtered-display-string address)))
1040           (elpher-insert-margin margin-code)
1041           (elpher--insert-text-button filtered-display-string
1042                                       'face face
1043                                       'elpher-page page
1044                                       'action #'elpher-click-link
1045                                       'follow-link t
1046                                       'help-echo #'elpher--page-button-help))
1047       (pcase type
1048         ('nil ;; Information
1049          (elpher-insert-margin)
1050          (let ((propertized-display-string
1051                 (propertize display-string 'face 'elpher-info)))
1052            (insert (elpher-process-text-for-display propertized-display-string))))
1053         (`(gopher ,selector-type) ;; Unknown
1054          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1055          (insert (propertize display-string
1056                              'face 'elpher-unknown)))))
1057     (insert "\n")))
1058
1059 (defun elpher-click-link (button)
1060   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1061   (let ((page (button-get button 'elpher-page)))
1062     (elpher-visit-page page)))
1063
1064 (defun elpher-render-index (data &optional _mime-type-string)
1065   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1066   (elpher-with-clean-buffer
1067    (if (not data)
1068        t
1069      (elpher-insert-index data)
1070      (elpher-cache-content (elpher-page-address elpher-current-page)
1071                            (buffer-string)))))
1072
1073 ;; Text rendering
1074
1075 (defconst elpher-url-regex
1076   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
1077   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
1078
1079 (defun elpher-buttonify-urls (string)
1080   "Turn substrings which look like urls in STRING into clickable buttons."
1081   (with-temp-buffer
1082     (insert string)
1083     (goto-char (point-min))
1084     (while (re-search-forward elpher-url-regex nil t)
1085       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1086                                     (elpher-address-from-url (match-string 0)))))
1087         (make-text-button (match-beginning 0)
1088                           (match-end 0)
1089                           'elpher-page  page
1090                           'action #'elpher-click-link
1091                           'follow-link t
1092                           'help-echo #'elpher--page-button-help
1093                           'face 'button)))
1094     (buffer-string)))
1095
1096 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
1097   "Incomplete regexp used to strip out some troublesome ANSI escape sequences.")
1098
1099 (defun elpher-process-text-for-display (string)
1100   "Perform any desired processing of STRING prior to display as text.
1101 Currently includes buttonifying URLs and processing ANSI escape codes."
1102   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1103                              (elpher-color-filter-apply string)
1104                            (elpher-color-apply string))))
1105
1106 (defun elpher-render-text (data &optional _mime-type-string)
1107   "Render DATA as text.  MIME-TYPE-STRING is unused."
1108   (elpher-with-clean-buffer
1109    (if (not data)
1110        t
1111      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1112      (elpher-cache-content
1113       (elpher-page-address elpher-current-page)
1114       (buffer-string)))))
1115
1116 ;; Image retrieval
1117
1118 (defun elpher-render-image (data &optional _mime-type-string)
1119   "Display DATA as image.  MIME-TYPE-STRING is unused."
1120   (if (not data)
1121       nil
1122     (if (display-images-p)
1123         (progn
1124           (let ((image (create-image
1125                         data
1126                         nil t)))
1127             (elpher-with-clean-buffer
1128              (insert-image image)
1129              (elpher-restore-pos))))
1130       (elpher-render-download data))))
1131
1132 ;; Search retrieval and rendering
1133
1134 (defun elpher-get-gopher-query-page (renderer)
1135   "Getter for gopher addresses requiring input.
1136 The response is rendered using the rendering function RENDERER."
1137   (let* ((address (elpher-page-address elpher-current-page))
1138          (content (elpher-get-cached-content address))
1139          (aborted t))
1140     (if (and content (funcall renderer nil))
1141         (elpher-with-clean-buffer
1142          (insert content)
1143          (elpher-restore-pos)
1144          (message "Displaying cached search results.  Reload to perform a new search."))
1145       (unwind-protect
1146           (let* ((query-string (read-string "Query: "))
1147                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1148                  (search-address (elpher-make-gopher-address ?1
1149                                                              query-selector
1150                                                              (elpher-address-host address)
1151                                                              (elpher-address-port address)
1152                                                              (equal (elpher-address-type address) "gophers"))))
1153             (setq aborted nil)
1154
1155             (elpher-with-clean-buffer
1156              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1157             (elpher-get-gopher-response search-address renderer))
1158         (if aborted
1159             (elpher-visit-previous-page))))))
1160
1161 ;; Raw server response rendering
1162
1163 (defun elpher-render-raw (data &optional mime-type-string)
1164   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1165   (if (not data)
1166       nil
1167     (elpher-with-clean-buffer
1168      (when mime-type-string
1169        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1170      (insert data)
1171      (goto-char (point-min)))
1172     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1173
1174 ;; File save "rendering"
1175
1176 (defun elpher-render-download (data &optional _mime-type-string)
1177   "Save DATA to file.  MIME-TYPE-STRING is unused."
1178   (if (not data)
1179       nil
1180     (let* ((address (elpher-page-address elpher-current-page))
1181            (selector (if (elpher-address-gopher-p address)
1182                          (elpher-gopher-address-selector address)
1183                        (elpher-address-filename address))))
1184       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1185       (let* ((filename-proposal (file-name-nondirectory selector))
1186              (filename (read-file-name "Download complete. Save file as: "
1187                                        nil nil nil
1188                                        (if (> (length filename-proposal) 0)
1189                                            filename-proposal
1190                                          "download.file"))))
1191         (let ((coding-system-for-write 'binary))
1192           (with-temp-file filename
1193             (insert data)))
1194         (message (format "Saved to file %s." filename))))))
1195
1196 ;; HTML rendering
1197
1198 (defun elpher-render-html (data &optional _mime-type-string)
1199   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1200   (elpher-with-clean-buffer
1201    (if (not data)
1202        t
1203      (let ((dom (with-temp-buffer
1204                   (insert data)
1205                   (libxml-parse-html-region (point-min) (point-max)))))
1206        (shr-insert-document dom)))))
1207
1208 ;; Gemini page retrieval
1209
1210 (defvar elpher-gemini-redirect-chain)
1211
1212 (defun elpher-get-gemini-response (address renderer)
1213   "Get response string from gemini server at ADDRESS and render using RENDERER."
1214   (elpher-get-host-response address 1965
1215                             (concat (elpher-address-to-url address) "\r\n")
1216                             (lambda (response-string)
1217                               (elpher-process-gemini-response response-string renderer))
1218                             'gemini))
1219
1220 (defun elpher-parse-gemini-response (response)
1221   "Parse the RESPONSE string and return a list of components.
1222 The list is of the form (code meta body).  A response of nil implies
1223 that the response was malformed."
1224   (let ((header-end-idx (string-match "\r\n" response)))
1225     (if header-end-idx
1226         (let ((header (string-trim (substring response 0 header-end-idx)))
1227               (body (substring response (+ header-end-idx 2))))
1228           (if (>= (length header) 2)
1229               (let ((code (substring header 0 2))
1230                     (meta (string-trim (substring header 2))))
1231                 (list code meta body))
1232             (error "Malformed response: No response status found in header %s" header)))
1233       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1234
1235 (defun elpher-process-gemini-response (response-string renderer)
1236   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1237   (let ((response-components (elpher-parse-gemini-response response-string)))
1238     (let ((response-code (elt response-components 0))
1239           (response-meta (elt response-components 1))
1240           (response-body (elt response-components 2)))
1241       (pcase (elt response-code 0)
1242         (?1 ; Input required
1243          (elpher-with-clean-buffer
1244           (insert "Gemini server is requesting input."))
1245          (let* ((query-string
1246                  (if (eq (elt response-code 1) ?1)
1247                      (read-passwd (concat response-meta ": "))
1248                    (read-string (concat response-meta ": "))))
1249                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1250                 (old-fname (url-filename query-address)))
1251            (setf (url-filename query-address)
1252                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1253            (elpher-get-gemini-response query-address renderer)))
1254         (?2 ; Normal response
1255          (funcall renderer response-body response-meta))
1256         (?3 ; Redirect
1257          (message "Following redirect to %s" response-meta)
1258          (if (>= (length elpher-gemini-redirect-chain) 5)
1259              (error "More than 5 consecutive redirects followed"))
1260          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1261            (if (member redirect-address elpher-gemini-redirect-chain)
1262                (error "Redirect loop detected"))
1263            (if (not (string= (elpher-address-protocol redirect-address)
1264                              "gemini"))
1265                (error "Server tried to automatically redirect to non-gemini URL: %s"
1266                       response-meta))
1267            (elpher-page-set-address elpher-current-page redirect-address)
1268            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1269            (elpher-get-gemini-response redirect-address renderer)))
1270         (?4 ; Temporary failure
1271          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1272                 response-code response-meta))
1273         (?5 ; Permanent failure
1274          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1275                 response-code response-meta))
1276         (?6 ; Client certificate required
1277          (elpher-with-clean-buffer
1278           (if elpher-client-certificate
1279               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1280             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1281           (auto-fill-mode 1)
1282           (elpher-gemini-insert-text response-meta))
1283          (let ((chosen-certificate (elpher-choose-client-certificate)))
1284            (unless chosen-certificate
1285              (error "Gemini server requires a client certificate and none was provided"))
1286            (setq elpher-client-certificate chosen-certificate))
1287          (elpher-with-clean-buffer)
1288          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1289         (_other
1290          (error "Gemini server response unknown: %s %s"
1291                 response-code response-meta))))))
1292
1293 (defun elpher--read-answer-polyfill (question answers)
1294   "Polyfill for `read-answer' in Emacs 26.1.
1295 QUESTION is a string containing a question, and ANSWERS
1296 is a list of possible answers."
1297     (completing-read question (mapcar 'identity answers)))
1298
1299 (if (fboundp 'read-answer)
1300     (defalias 'elpher-read-answer 'read-answer)
1301   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1302
1303 (defun elpher-choose-client-certificate ()
1304   "Prompt for a client certificate to use to establish a TLS connection."
1305   (let* ((read-answer-short t))
1306     (pcase (read-answer "What do you want to do? "
1307                         '(("throwaway" ?t
1308                            "generate and use throw-away certificate")
1309                           ("persistent" ?p
1310                            "generate new or use existing persistent certificate")
1311                           ("abort" ?a
1312                            "stop immediately")))
1313       ("throwaway"
1314        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1315       ("persistent"
1316        (let* ((existing-certificates (elpher-list-existing-certificates))
1317               (file-base (completing-read
1318                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1319                           existing-certificates)))
1320          (if (string-empty-p (string-trim file-base))
1321              nil
1322            (if (member file-base existing-certificates)
1323                (setq elpher-client-certificate
1324                      (elpher-get-existing-certificate file-base))
1325              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1326                                  '(("new" ?n
1327                                     "generate new certificate")
1328                                    ("install" ?i
1329                                     "install existing certificate")
1330                                    ("abort" ?a
1331                                     "stop immediately")))
1332                ("new"
1333                 (let ((common-name (read-string "Common Name field for new certificate: "
1334                                                 file-base)))
1335                   (message "New key and self-signed certificate written to %s"
1336                            elpher-certificate-directory)
1337                   (elpher-generate-persistent-certificate file-base common-name)))
1338                ("install"
1339                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1340                        (key-file (read-file-name "Key file: " nil nil t)))
1341                   (message "Key and certificate installed in %s for future use"
1342                            elpher-certificate-directory)
1343                   (elpher-install-and-use-existing-certificate key-file
1344                                                                cert-file
1345                                                                file-base)))
1346                ("abort" nil))))))
1347       ("abort" nil))))
1348
1349 (defun elpher-get-gemini-page (renderer)
1350   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1351   (let* ((address (elpher-page-address elpher-current-page))
1352          (content (elpher-get-cached-content address)))
1353     (condition-case the-error
1354         (if (and content (funcall renderer nil))
1355             (elpher-with-clean-buffer
1356              (insert content)
1357              (elpher-restore-pos))
1358           (elpher-with-clean-buffer
1359            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1360           (setq elpher-gemini-redirect-chain nil)
1361           (elpher-get-gemini-response address renderer))
1362       (error
1363        (elpher-network-error address the-error)))))
1364
1365 (defun elpher-render-gemini (body &optional mime-type-string)
1366   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1367   (if (not body)
1368       t
1369     (let* ((mime-type-string* (if (or (not mime-type-string)
1370                                       (string-empty-p mime-type-string))
1371                                   "text/gemini; charset=utf-8"
1372                                 mime-type-string))
1373            (mime-type-split (split-string mime-type-string* ";" t))
1374            (mime-type (string-trim (car mime-type-split)))
1375            (parameters (mapcar (lambda (s)
1376                                  (let ((key-val (split-string s "=")))
1377                                    (list (downcase (string-trim (car key-val)))
1378                                          (downcase (string-trim (cadr key-val))))))
1379                                (cdr mime-type-split))))
1380       (when (string-prefix-p "text/" mime-type)
1381         (setq body (decode-coding-string
1382                     body
1383                     (if (assoc "charset" parameters)
1384                         (intern (cadr (assoc "charset" parameters)))
1385                       'utf-8)))
1386         (setq body (replace-regexp-in-string "\r" "" body)))
1387       (pcase mime-type
1388         ((or "text/gemini" "")
1389          (elpher-render-gemini-map body parameters))
1390         ("text/html"
1391          (elpher-render-html body))
1392         ((pred (string-prefix-p "text/"))
1393          (elpher-render-gemini-plain-text body parameters))
1394         ((pred (string-prefix-p "image/"))
1395          (elpher-render-image body))
1396         (_other
1397          (elpher-render-download body))))))
1398
1399 (defun elpher-gemini-get-link-url (link-line)
1400   "Extract the url portion of LINK-LINE, a gemini map file link line.
1401 Returns nil in the event that the contents of the line following the
1402 => prefix are empty."
1403   (let ((l (split-string (substring link-line 2))))
1404     (if l
1405         (string-trim (elt l 0))
1406       nil)))
1407
1408 (defun elpher-gemini-get-link-display-string (link-line)
1409   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1410 Returns the url portion in the event that the display-string portion is empty."
1411   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1412          (idx (string-match "[ \t]" rest)))
1413     (string-trim (if idx
1414                      (substring rest (+ idx 1))
1415                    rest))))
1416
1417 (defun elpher-collapse-dot-sequences (filename)
1418   "Collapse dot sequences in FILENAME.
1419 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1420   (let* ((path (split-string filename "/"))
1421          (path-reversed-normalized
1422           (seq-reduce (lambda (a b)
1423                         (cond ((and a (equal b "..") (cdr a)))
1424                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1425                               ((equal b ".") a)
1426                               (t (cons b a))))
1427                       path nil)))
1428     (string-join (reverse path-reversed-normalized) "/")))
1429
1430 (defun elpher-address-from-gemini-url (url)
1431   "Extract address from URL with defaults as per gemini map files.
1432 While there's obviously some redundancy here between this function and
1433 `elpher-address-from-url', gemini map file URLs require enough special
1434 treatment that a separate function is warranted."
1435   (let ((address (url-generic-parse-url url))
1436         (current-address (elpher-page-address elpher-current-page)))
1437     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1438       (setf (url-fullness address) t)
1439       (if (url-host address) ;if there is an explicit host, filenames are absolute
1440           (if (string-empty-p (url-filename address))
1441               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1442         (setf (url-host address) (url-host current-address))
1443         (setf (url-port address) (url-port current-address))
1444         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1445           (setf (url-filename address)
1446                 (concat (file-name-directory (url-filename current-address))
1447                         (url-filename address)))))
1448       (unless (url-type address)
1449         (setf (url-type address) "gemini"))
1450       (when (equal (url-type address) "gemini")
1451         (setf (url-filename address)
1452               (elpher-collapse-dot-sequences (url-filename address)))))
1453     (elpher-remove-redundant-ports address)))
1454
1455 (defun elpher-gemini-insert-link (link-line)
1456   "Insert link described by LINK-LINE into a text/gemini document."
1457   (let* ((url (elpher-gemini-get-link-url link-line))
1458          (display-string (elpher-gemini-get-link-display-string link-line))
1459          (address (elpher-address-from-gemini-url url))
1460          (type (if address (elpher-address-type address) nil))
1461          (type-map-entry (cdr (assoc type elpher-type-map))))
1462     (when display-string
1463       (insert elpher-gemini-link-string)
1464       (if type-map-entry
1465           (let* ((face (elt type-map-entry 3))
1466                  (filtered-display-string (elpher-color-filter-apply display-string))
1467                  (page (elpher-make-page filtered-display-string address)))
1468             (elpher--insert-text-button filtered-display-string
1469                                         'face face
1470                                         'elpher-page page
1471                                         'action #'elpher-click-link
1472                                         'follow-link t
1473                                         'help-echo #'elpher--page-button-help))
1474         (insert (propertize display-string 'face 'elpher-unknown)))
1475       (insert "\n"))))
1476
1477 (defun elpher-gemini-insert-header (header-line)
1478   "Insert header described by HEADER-LINE into a text/gemini document.
1479 The gemini map file line describing the header is given
1480 by HEADER-LINE."
1481   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1482     (let* ((level (length (match-string 1 header-line)))
1483            (header (substring header-line (match-end 0)))
1484            (face (pcase level
1485                    (1 'elpher-gemini-heading1)
1486                    (2 'elpher-gemini-heading2)
1487                    (3 'elpher-gemini-heading3)
1488                    (_ 'default)))
1489            (fill-column (if (display-graphic-p)
1490                             (/ (* fill-column
1491                                   (font-get (font-spec :name (face-font 'default)) :size))
1492                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1493       (setq elpher--gemini-page-headings (cons (cons header (point))
1494                                                elpher--gemini-page-headings))
1495       (unless (display-graphic-p)
1496         (insert (make-string level ?#) " "))
1497       (insert (propertize header 'face face))
1498       (newline))))
1499
1500 (defun elpher-gemini-insert-text (text-line)
1501   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1502 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1503 width defined by `elpher-gemini-max-fill-width'."
1504   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1505   (let* ((line-prefix (match-string 2 text-line))
1506          (processed-text-line
1507           (if line-prefix
1508               (cond ((string-prefix-p "*" line-prefix)
1509                      (concat
1510                       (replace-regexp-in-string "\\*"
1511                                                 elpher-gemini-bullet-string
1512                                                 (match-string 0 text-line))
1513                       (substring text-line (match-end 0))))
1514                     ((string-prefix-p ">" line-prefix)
1515                      (propertize text-line 'face 'elpher-gemini-quoted))
1516                     (t text-line))
1517             text-line))
1518          (adaptive-fill-mode t)
1519          ;; fill-prefix is important for adaptive-fill-mode: without
1520          ;; it, multi-line list items are not indented correct
1521          (fill-prefix (if (match-string 2 text-line)
1522                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1523                         nil)))
1524     (insert (elpher-process-text-for-display processed-text-line))
1525     (newline)))
1526
1527 (defun elpher-render-gemini-map (data _parameters)
1528   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1529   (elpher-with-clean-buffer
1530    (setq elpher--gemini-page-headings nil)
1531    (let ((preformatted nil))
1532      (auto-fill-mode 1)
1533      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1534      (dolist (line (split-string data "\n"))
1535        (cond
1536         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1537         (preformatted (insert (elpher-process-text-for-display
1538                                (propertize line 'face 'elpher-gemini-preformatted))
1539                               "\n"))
1540         ((string-prefix-p "=>" line)
1541          (elpher-gemini-insert-link line))
1542         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1543         (t (elpher-gemini-insert-text line)))))
1544    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1545    (elpher-cache-content
1546     (elpher-page-address elpher-current-page)
1547     (buffer-string))))
1548
1549 (defun elpher-render-gemini-plain-text (data _parameters)
1550   "Render DATA as plain text file.  PARAMETERS is currently unused."
1551   (elpher-with-clean-buffer
1552    (insert (elpher-process-text-for-display data))
1553    (elpher-cache-content
1554     (elpher-page-address elpher-current-page)
1555     (buffer-string))))
1556
1557
1558 ;; Finger page connection
1559
1560 (defun elpher-get-finger-page (renderer)
1561   "Opens a finger connection to the current page address.
1562 The result is rendered using RENDERER."
1563   (let* ((address (elpher-page-address elpher-current-page))
1564          (content (elpher-get-cached-content address)))
1565     (if (and content (funcall renderer nil))
1566         (elpher-with-clean-buffer
1567          (insert content)
1568          (elpher-restore-pos))
1569       (elpher-with-clean-buffer
1570        (insert "LOADING... (use 'u' to cancel)\n"))
1571       (condition-case the-error
1572           (let* ((kill-buffer-query-functions nil)
1573                  (user (let ((filename (elpher-address-filename address)))
1574                          (if (> (length filename) 1)
1575                              (substring filename 1)
1576                            (elpher-address-user address)))))
1577             (elpher-get-host-response address 79
1578                                       (concat user "\r\n")
1579                                       renderer))
1580         (error
1581          (elpher-network-error address the-error))))))
1582
1583
1584 ;; Telnet page connection
1585
1586 (defun elpher-get-telnet-page (renderer)
1587   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1588   (when renderer
1589     (elpher-visit-previous-page)
1590     (error "Command not supported for telnet URLs"))
1591   (let* ((address (elpher-page-address elpher-current-page))
1592          (host (elpher-address-host address))
1593          (port (elpher-address-port address)))
1594     (elpher-visit-previous-page)
1595     (if (> port 0)
1596         (telnet host port)
1597       (telnet host))))
1598
1599
1600 ;; Other URL page opening
1601
1602 (defun elpher-get-other-url-page (renderer)
1603   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1604   (when renderer
1605     (elpher-visit-previous-page)
1606     (error "Command not supported for general URLs"))
1607   (let* ((address (elpher-page-address elpher-current-page))
1608          (url (elpher-address-to-url address)))
1609     (progn
1610       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1611       (message "Opening URL...")
1612       (if elpher-open-urls-with-eww
1613           (browse-web url)
1614         (browse-url url)))))
1615
1616
1617 ;; Start page page retrieval
1618
1619 (defun elpher-get-start-page (renderer)
1620   "Getter which displays the start page (RENDERER must be nil)."
1621   (when renderer
1622     (elpher-visit-previous-page)
1623     (error "Command not supported for start page"))
1624   (elpher-with-clean-buffer
1625    (insert "     --------------------------------------------\n"
1626            "           Elpher Gopher and Gemini Client       \n"
1627            "                   version " elpher-version "\n"
1628            "     --------------------------------------------\n"
1629            "\n"
1630            "Default bindings:\n"
1631            "\n"
1632            " - TAB/Shift-TAB: next/prev item on current page\n"
1633            " - RET/mouse-1: open item under cursor\n"
1634            " - m/M: select an item on current page by name (autocompletes) or number\n"
1635            " - u/mouse-3/U: return to previous page or to the start page\n"
1636            " - o/O: visit different selector or the root menu of the current server\n"
1637            " - g: go to a particular address (gopher, gemini, finger)\n"
1638            " - d/D: download item under cursor or current page\n"
1639            " - i/I: info on item under cursor or current page\n"
1640            " - c/C: copy URL representation of item under cursor or current page\n"
1641            " - a/A: bookmark the item under cursor or current page\n"
1642            " - B: list all bookmarks\n"
1643            " - s/S: show history of current buffer or for all buffers\n"
1644            " - r: redraw current page (using cached contents if available)\n"
1645            " - R: reload current page (regenerates cache)\n"
1646            " - !: set character coding system for gopher (default is to autodetect)\n"
1647            " - T: toggle TLS gopher mode\n"
1648            " - F: forget/discard current TLS client certificate\n"
1649            " - .: display the raw server response for the current page\n"
1650            "\n"
1651            "Start your exploration of gopher space and gemini:\n")
1652    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1653                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1654    (elpher-insert-index-record "Project Gemini home page"
1655                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1656    (insert "\n"
1657            "Alternatively, select a search engine and enter some search terms:\n")
1658    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1659                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1660    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1661                                (elpher-address-from-url "gemini://geminispace.info/search"))
1662    (insert "\n"
1663            "For Elpher release news or to leave feedback, visit:\n")
1664    (elpher-insert-index-record "The Elpher Project Page"
1665                                (elpher-make-gopher-address ?1
1666                                                            "/projects/elpher/"
1667                                                            "thelambdalab.xyz"
1668                                                            70))
1669    (insert "\n"
1670            "** Refer to the ")
1671    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1672      (elpher--insert-text-button "Elpher info manual"
1673                                  'face 'link
1674                                  'action (lambda (_)
1675                                            (interactive)
1676                                            (info "(elpher)"))
1677                                  'follow-link t
1678                                  'help-echo help-string))
1679    (insert " for the full documentation. **\n")
1680    (insert (propertize
1681             (concat "  (This should be available if you have installed Elpher using\n"
1682                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1683             'face 'shadow))
1684    (elpher-restore-pos)))
1685
1686 ;; History page retrieval
1687
1688 (defun elpher-history ()
1689   "Show the history of pages leading to the current page in this buffer.
1690 Use \\[elpher-history-all] to see the entire history.
1691 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1692   (interactive)
1693   (elpher-visit-page
1694    (elpher-make-page "Elpher History Page"
1695                      (elpher-make-special-address 'history))))
1696
1697 (defun elpher-history-all ()
1698   "Show the all the pages you've visited using Elpher.
1699 Use \\[elpher-history] to see just the history for the current buffer.
1700 This is rendered using `elpher-get-history-all-page' via `elpher-type-map'."
1701   (interactive)
1702   (elpher-visit-page
1703    (elpher-make-page "Elpher History Of All Seen Pages"
1704                      (elpher-make-special-address 'history-all))))
1705
1706 (defun elpher-get-history-page (renderer)
1707   "Getter which displays the history page (RENDERER must be nil)."
1708   (when renderer
1709     (elpher-visit-previous-page)
1710     (error "Command not supported for history page"))
1711   (elpher-show-history elpher-history))
1712
1713 (defun elpher-get-history-all-page (renderer)
1714   "Getter which displays the history page (RENDERER must be nil)."
1715   (when renderer
1716     (elpher-visit-previous-page)
1717     (error "Command not supported for history page"))
1718   (elpher-show-history elpher-history-all))
1719
1720 (defun elpher-show-history (pages)
1721   "Show all PAGES in the Elpher buffer."
1722   (elpher-with-clean-buffer
1723    (insert "---- Visited link history ----\n\n")
1724    (if pages
1725        (dolist (page pages)
1726          (when page
1727            (let ((display-string (elpher-page-display-string page))
1728                  (address (elpher-page-address page)))
1729              (elpher-insert-index-record display-string address))))
1730      (insert "No history items found.\n"))
1731    (insert "\n----------------------------")))
1732
1733
1734 ;;; Bookmarks
1735
1736 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1737 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1738 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1739 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1740
1741 (defvar elpher-bookmark-link nil
1742   "Prefer bookmarking a link or the current page.
1743 Bind this variable dynamically, or set it to t.
1744 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1745 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1746
1747 (defun elpher-bookmark-make-record ()
1748   "Return a bookmark record.
1749 If `elpher-bookmark-link' is non-nil and point is on a link button,
1750 return a bookmark record for that link.  Otherwise, return a bookmark
1751 record for the current elpher page."
1752   (let* ((button (and elpher-bookmark-link (button-at (point))))
1753          (page (if button
1754                    (button-get button 'elpher-page)
1755                  elpher-current-page))
1756          (address (elpher-page-address page))
1757          (url (elpher-address-to-url address))
1758          (display-string (elpher-page-display-string page))
1759          (pos (if button nil (point))))
1760     (if (elpher-address-special-p address)
1761         (error "Cannot bookmark %s" display-string)
1762       `(,display-string
1763         (defaults . (,display-string))
1764         (position . ,pos)
1765         (location . ,url)
1766         (handler . elpher-bookmark-jump)))))
1767
1768 ;;;###autoload
1769 (defun elpher-bookmark-jump (bookmark)
1770   "Go to a particular BOOKMARK."
1771   (let* ((url (cdr (assq 'location bookmark))))
1772     (elpher-go url)))
1773
1774 (defun elpher-set-bookmark-no-overwrite ()
1775   "Bookmark the link at point.
1776 To bookmark the current page, use \\[bookmark-set-no-overwrite]."
1777   (interactive)
1778   (let ((elpher-bookmark-link t))
1779     (bookmark-set-no-overwrite)))
1780
1781 (defun elpher-bookmark-import (file)
1782   "Import Elpher bookmarks file FILE into Emacs bookmarks."
1783   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1784                               (file-readable-p elpher-bookmarks-file))
1785                          elpher-bookmarks-file
1786                        (read-file-name "Old Elpher bookmarks: "
1787                                        user-emacs-directory nil t
1788                                        "elpher-bookmarks"))))
1789   (require 'bookmark)
1790   (dolist (bookmark (with-temp-buffer
1791                       (insert-file-contents file)
1792                       (read (current-buffer))))
1793     (let* ((display-string (car bookmark))
1794            (url (cadr bookmark))
1795            (record `(,display-string
1796                      (location . ,url)
1797                      (handler . elpher-bookmark-jump))))
1798       (bookmark-store display-string (cdr record) t)))
1799   (bookmark-save))
1800
1801 ;;; Integrations
1802 ;;
1803
1804 ;;; Org
1805
1806 ;; Avoid byte compilation warnings.
1807 (eval-when-compile
1808   (declare-function org-link-store-props "ol")
1809   (declare-function org-link-set-parameters "ol"))
1810
1811 (defun elpher-org-export-link (link description format protocol)
1812   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1813
1814 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1815 of gemini, gopher or finger."
1816   (let* ((url (if (equal protocol "elpher")
1817                   (string-remove-prefix "elpher:" link)
1818                 (format "%s:%s" protocol link)))
1819          (desc (or description url)))
1820     (pcase format
1821       (`gemini (format "=> %s %s" url desc))
1822       (`html (format "<a href=\"%s\">%s</a>" url desc))
1823       (`latex (format "\\href{%s}{%s}" url desc))
1824       (_ (if (not description)
1825              url
1826            (format "%s (%s)" desc url))))))
1827
1828 (defun elpher-org-store-link ()
1829   "Store link to an `elpher' page in Org."
1830   (when (eq major-mode 'elpher-mode)
1831     (let* ((url (elpher-info-current))
1832            (desc (car elpher-current-page))
1833            (protocol (cond
1834                       ((string-prefix-p "gemini:" url) "gemini")
1835                       ((string-prefix-p "gopher:" url) "gopher")
1836                       ((string-prefix-p "finger:" url) "finger")
1837                       (t "elpher"))))
1838       (when (equal "elpher" protocol)
1839         ;; Weird link. Or special inner link?
1840         (setq url (concat "elpher:" url)))
1841       (org-link-store-props :type protocol :link url :description desc)
1842       t)))
1843
1844 (defun elpher-org-follow-link (link protocol)
1845   "Visit a LINK for the given PROTOCOL.
1846
1847 PROTOCOL may be one of gemini, gopher or finger.  This method also
1848 supports the old protocol elpher, where the link is self-contained."
1849   (let ((url (if (equal protocol "elpher")
1850                  (string-remove-prefix "elpher:" link)
1851                (format "%s:%s" protocol link))))
1852     (elpher-go url)))
1853
1854 (with-eval-after-load 'org
1855   (org-link-set-parameters
1856    "elpher"
1857    :store #'elpher-org-store-link
1858    :export (lambda (link description format _plist)
1859              (elpher-org-export-link link description format "elpher"))
1860    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1861   (org-link-set-parameters
1862    "gemini"
1863    :export (lambda (link description format _plist)
1864              (elpher-org-export-link link description format "gemini"))
1865    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
1866   (org-link-set-parameters
1867    "gopher"
1868    :export (lambda (link description format _plist)
1869              (elpher-org-export-link link description format "gopher"))
1870    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
1871   (org-link-set-parameters
1872    "finger"
1873    :export (lambda (link description format _plist)
1874              (elpher-org-export-link link description format "finger"))
1875    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
1876
1877 ;;; Browse URL
1878
1879 ;; Avoid byte compilation warnings.
1880 (eval-when-compile
1881   (defvar thing-at-point-uri-schemes))
1882
1883 ;;;###autoload
1884 (defun elpher-browse-url-elpher (url &rest _args)
1885   "Browse URL using Elpher.  This function is used by `browse-url'."
1886   (interactive (browse-url-interactive-arg "Elpher URL: "))
1887   (elpher-go url))
1888
1889 ;; Use elpher to open gopher, finger and gemini links
1890 ;; For recent version of `browse-url' package
1891 (if (boundp 'browse-url-default-handlers)
1892     (add-to-list
1893      'browse-url-default-handlers
1894      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
1895   ;; Patch `browse-url-browser-function' for older ones. The value of
1896   ;; that variable is `browse-url-default-browser' by default, so
1897   ;; that's the function that gets advised.
1898   (advice-add browse-url-browser-function :before-while
1899               (lambda (url &rest _args)
1900                 "Handle gemini, gopher, and finger schemes using Elpher."
1901                 (let ((scheme (downcase (car (split-string url ":" t)))))
1902                   (if (member scheme '("gemini" "gopher" "finger"))
1903                       ;; `elpher-go' always returns nil, which will stop the
1904                       ;; advice chain here in a before-while
1905                       (elpher-go url)
1906                     ;; chain must continue, then return t.
1907                     t)))))
1908
1909 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1910 (with-eval-after-load 'thingatpt
1911   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
1912
1913 ;;; Mu4e:
1914
1915 (eval-when-compile
1916   (defvar mu4e~view-beginning-of-url-regexp))
1917
1918 (with-eval-after-load 'mu4e-view
1919   ;; Make mu4e aware of the gemini world
1920   (setq mu4e~view-beginning-of-url-regexp
1921         "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:"))
1922
1923 ;;; Interactive procedures
1924 ;;
1925
1926 (defun elpher-next-link ()
1927   "Move point to the next link on the current page."
1928   (interactive)
1929   (forward-button 1))
1930
1931 (defun elpher-prev-link ()
1932   "Move point to the previous link on the current page."
1933   (interactive)
1934   (backward-button 1))
1935
1936 (defun elpher-follow-current-link ()
1937   "Open the link or url at point."
1938   (interactive)
1939   (push-button))
1940
1941 ;;;###autoload
1942 (defun elpher-go (host-or-url)
1943   "Go to a particular gopher site HOST-OR-URL.
1944 When run interactively HOST-OR-URL is read from the minibuffer."
1945   (interactive "sGopher or Gemini URL: ")
1946   (let* ((cleaned-host-or-url (string-trim host-or-url))
1947          (address (elpher-address-from-url cleaned-host-or-url))
1948          (page (elpher-make-page cleaned-host-or-url address)))
1949     (switch-to-buffer elpher-buffer-name)
1950     (elpher-with-clean-buffer
1951      (elpher-visit-page page))
1952     nil))
1953
1954 (defun elpher-go-current ()
1955   "Go to a particular site read from the minibuffer, initialized with the current URL."
1956   (interactive)
1957   (let ((address (elpher-page-address elpher-current-page)))
1958     (let ((url (read-string "Gopher or Gemini URL: "
1959                             (unless (elpher-address-special-p address)
1960                               (elpher-address-to-url address)))))
1961       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
1962
1963 (defun elpher-redraw ()
1964   "Redraw current page."
1965   (interactive)
1966   (elpher-visit-page elpher-current-page))
1967
1968 (defun elpher-reload ()
1969   "Reload current page."
1970   (interactive)
1971   (elpher-reload-current-page))
1972
1973 (defun elpher-toggle-tls ()
1974   "Toggle TLS encryption mode for gopher."
1975   (interactive)
1976   (setq elpher-use-tls (not elpher-use-tls))
1977   (if elpher-use-tls
1978       (if (gnutls-available-p)
1979           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1980         (setq elpher-use-tls nil)
1981         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1982     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1983
1984 (defun elpher-view-raw ()
1985   "View raw server response for current page."
1986   (interactive)
1987   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1988       (error "This page was not generated by a server")
1989     (elpher-visit-page elpher-current-page
1990                        #'elpher-render-raw)))
1991
1992 (defun elpher-back ()
1993   "Go to previous site."
1994   (interactive)
1995   (elpher-visit-previous-page))
1996
1997 (defun elpher-back-to-start ()
1998   "Go all the way back to the start page."
1999   (interactive)
2000   (setq-local elpher-current-page nil)
2001   (setq-local elpher-history nil)
2002   (elpher-visit-page (elpher-make-start-page)))
2003
2004 (defun elpher-download ()
2005   "Download the link at point."
2006   (interactive)
2007   (let ((button (button-at (point))))
2008     (if button
2009         (let ((page (button-get button 'elpher-page)))
2010           (if (elpher-address-special-p (elpher-page-address page))
2011               (error "Cannot download %s"
2012                      (elpher-page-display-string page))
2013             (elpher-visit-page (button-get button 'elpher-page)
2014                                #'elpher-render-download)))
2015       (error "No link selected"))))
2016
2017 (defun elpher-download-current ()
2018   "Download the current page."
2019   (interactive)
2020   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2021       (error "Cannot download %s"
2022              (elpher-page-display-string elpher-current-page))
2023     (elpher-visit-page (elpher-make-page
2024                         (elpher-page-display-string elpher-current-page)
2025                         (elpher-page-address elpher-current-page))
2026                        #'elpher-render-download
2027                        t)))
2028
2029 (defun elpher-build-link-map ()
2030   "Build alist mapping link names to destination pages in current buffer."
2031   (let ((link-map nil)
2032         (b (next-button (point-min) t)))
2033     (while b
2034       (push (cons (button-label b) b) link-map)
2035       (setq b (next-button (button-start b))))
2036     link-map))
2037
2038 (defun elpher-jump ()
2039   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2040   (interactive)
2041   (let* ((link-map (elpher-build-link-map)))
2042     (if link-map
2043         (let ((key (let ((completion-ignore-case t))
2044                      (completing-read "Directory item/link: "
2045                                       link-map nil t))))
2046           (if (and key (> (length key) 0))
2047               (let ((b (cdr (assoc key link-map))))
2048                 (goto-char (button-start b))
2049                 (button-activate b)))))))
2050
2051 (defun elpher-jump-to-number (n)
2052   "Jump to directory entry number N."
2053   (interactive "nDirectory item/link number: ")
2054   (let* ((link-map (reverse (elpher-build-link-map))))
2055     (if link-map
2056         (if (<= 1 n (length link-map))
2057             (let ((b (cdr (elt link-map (- n 1)))))
2058               (goto-char (button-start b))
2059               (button-activate b))
2060           (error "No link with that number")))))
2061
2062 (defun elpher-root-dir ()
2063   "Visit root of current server."
2064   (interactive)
2065   (let ((address (elpher-page-address elpher-current-page)))
2066     (if (not (elpher-address-special-p address))
2067         (if (or (member (url-filename address) '("/" ""))
2068                 (and (elpher-address-gopher-p address)
2069                      (= (length (elpher-gopher-address-selector address)) 0)))
2070             (error "Already at root directory of current server")
2071           (let ((address-copy (elpher-address-from-url
2072                                (elpher-address-to-url address))))
2073             (setf (url-filename address-copy) "")
2074             (elpher-go (elpher-address-to-url address-copy))))
2075       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2076
2077 (defun elpher-info-page (page)
2078   "Display information on PAGE."
2079   (let ((display-string (elpher-page-display-string page))
2080         (address (elpher-page-address page)))
2081     (if (elpher-address-special-p address)
2082         (message "Special page: %s" display-string)
2083       (message "%s" (elpher-address-to-url address)))))
2084
2085 (defun elpher-info-link ()
2086   "Display information on page corresponding to link at point."
2087   (interactive)
2088   (let ((button (button-at (point))))
2089     (if button
2090         (elpher-info-page (button-get button 'elpher-page))
2091       (error "No item selected"))))
2092
2093 (defun elpher-info-current ()
2094   "Display information on current page."
2095   (interactive)
2096   (elpher-info-page elpher-current-page))
2097
2098 (defun elpher-copy-page-url (page)
2099   "Copy URL representation of address of PAGE to `kill-ring'."
2100   (let ((address (elpher-page-address page)))
2101     (if (elpher-address-special-p address)
2102         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2103       (let ((url (elpher-address-to-url address)))
2104         (message "Copied \"%s\" to kill-ring/clipboard." url)
2105         (kill-new url)))))
2106
2107 (defun elpher-copy-link-url ()
2108   "Copy URL of item at point to `kill-ring'."
2109   (interactive)
2110   (let ((button (button-at (point))))
2111     (if button
2112         (elpher-copy-page-url (button-get button 'elpher-page))
2113       (error "No item selected"))))
2114
2115 (defun elpher-copy-current-url ()
2116   "Copy URL of current page to `kill-ring'."
2117   (interactive)
2118   (elpher-copy-page-url elpher-current-page))
2119
2120 (defun elpher-set-gopher-coding-system ()
2121   "Specify an explicit character coding system for gopher selectors."
2122   (interactive)
2123   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2124     (setq elpher-user-coding-system system)
2125     (if system
2126         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2127       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2128
2129
2130 ;;; Mode and keymap
2131 ;;
2132
2133 (defvar elpher-mode-map
2134   (let ((map (make-sparse-keymap)))
2135     (define-key map (kbd "TAB") 'elpher-next-link)
2136     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2137     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2138     (define-key map (kbd "u") 'elpher-back)
2139     (define-key map (kbd "-") 'elpher-back)
2140     (define-key map (kbd "^") 'elpher-back)
2141     (define-key map [mouse-3] 'elpher-back)
2142     (define-key map (kbd "U") 'elpher-back-to-start)
2143     (define-key map (kbd "O") 'elpher-root-dir)
2144     (define-key map (kbd "g") 'elpher-go)
2145     (define-key map (kbd "o") 'elpher-go-current)
2146     (define-key map (kbd "s") 'elpher-history)
2147     (define-key map (kbd "S") 'elpher-history-all)
2148     (define-key map (kbd "r") 'elpher-redraw)
2149     (define-key map (kbd "R") 'elpher-reload)
2150     (define-key map (kbd "T") 'elpher-toggle-tls)
2151     (define-key map (kbd ".") 'elpher-view-raw)
2152     (define-key map (kbd "d") 'elpher-download)
2153     (define-key map (kbd "D") 'elpher-download-current)
2154     (define-key map (kbd "m") 'elpher-jump)
2155     (define-key map (kbd "M") 'elpher-jump-to-number)
2156     (define-key map (kbd "i") 'elpher-info-link)
2157     (define-key map (kbd "I") 'elpher-info-current)
2158     (define-key map (kbd "c") 'elpher-copy-link-url)
2159     (define-key map (kbd "C") 'elpher-copy-current-url)
2160     (define-key map (kbd "a") 'elpher-set-bookmark-no-overwrite)
2161     (define-key map (kbd "A") 'bookmark-set-no-overwrite)
2162     (define-key map (kbd "B") 'bookmark-bmenu-list)
2163     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2164     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2165     (when (fboundp 'evil-define-key*)
2166       (evil-define-key*
2167        'motion map
2168        (kbd "TAB") 'elpher-next-link
2169        (kbd "C-") 'elpher-follow-current-link
2170        (kbd "C-t") 'elpher-back
2171        (kbd "u") 'elpher-back
2172        (kbd "-") 'elpher-back
2173        (kbd "^") 'elpher-back
2174        [mouse-3] 'elpher-back
2175        (kbd "U") 'elpher-back-to-start
2176        (kbd "o") 'elpher-go
2177        (kbd "O") 'elpher-go-current
2178        (kbd "r") 'elpher-redraw
2179        (kbd "R") 'elpher-reload
2180        (kbd "T") 'elpher-toggle-tls
2181        (kbd ".") 'elpher-view-raw
2182        (kbd "d") 'elpher-download
2183        (kbd "D") 'elpher-download-current
2184        (kbd "m") 'elpher-jump
2185        (kbd "M") 'elpher-jump-to-number
2186        (kbd "i") 'elpher-info-link
2187        (kbd "I") 'elpher-info-current
2188        (kbd "c") 'elpher-copy-link-url
2189        (kbd "C") 'elpher-copy-current-url
2190        (kbd "a") 'elpher-set-bookmark-no-overwrite
2191        (kbd "A") 'bookmark-set-no-overwrite
2192        (kbd "B") 'bookmark-bmenu-list
2193        (kbd "!") 'elpher-set-gopher-coding-system
2194        (kbd "F") 'elpher-forget-current-certificate))
2195     map)
2196   "Keymap for gopher client.")
2197
2198 (define-derived-mode elpher-mode special-mode "elpher"
2199   "Major mode for elpher, an elisp gopher client.
2200
2201 This mode is automatically enabled by the interactive
2202 functions which initialize the client, namely
2203 `elpher', and `elpher-go'."
2204   (setq-local elpher--gemini-page-headings nil)
2205   (setq-local elpher-current-page nil)
2206   (setq-local elpher-history nil)
2207   (setq-local elpher-buffer-name (buffer-name))
2208   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2209   (setq-local imenu-create-index-function #'elpher--gemini-page-headings))
2210
2211 (when (fboundp 'evil-set-initial-state)
2212   (evil-set-initial-state 'elpher-mode 'motion))
2213
2214
2215 ;;; Main start procedure
2216 ;;
2217
2218 ;;;###autoload
2219 (defun elpher (&optional arg)
2220   "Start elpher with default landing page.
2221 The buffer used for Elpher sessions is determined by the value of
2222 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2223 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2224 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2225 \\[execute-extended-command] elpher RET’) switches to the session with
2226 that number, creating it if necessary.  A non numeric prefix ARG means
2227 to create a new session.  Returns the buffer selected (or created)."
2228   (interactive "P")
2229   (let* ((name (default-value 'elpher-buffer-name))
2230          (buf (cond ((numberp arg)
2231                      (get-buffer-create (format "%s<%d>" name arg)))
2232                     (arg
2233                      (generate-new-buffer name))
2234                     (t
2235                      (get-buffer-create name)))))
2236     (pop-to-buffer-same-window buf)
2237     (unless (buffer-modified-p)
2238       (elpher-mode)
2239       (elpher-visit-page (elpher-make-start-page))
2240       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2241
2242 ;;; elpher.el ends here