elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.10.0
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "2.10.0"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  99     ((special start) elpher-get-start-page nil))
 100   "Association list from types to getters, renderers, margin codes and index faces.")
 101
 102
 103 ;;; Customization group
 104 ;;
 105
 106 (defgroup elpher nil
 107   "A gopher and gemini client."
 108   :group 'applications)
 109
 110 ;; General appearance and customizations
 111
 112 (defcustom elpher-open-urls-with-eww nil
 113   "If non-nil, open URL selectors using eww.
 114 Otherwise, use the system browser via the BROWSE-URL function."
 115   :type '(boolean))
 116
 117 (defcustom elpher-use-header t
 118   "If non-nil, display current page information in buffer header."
 119   :type '(boolean))
 120
 121 (defcustom elpher-auto-disengage-TLS nil
 122   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 123 While enabling this may seem convenient, it is also potentially dangerous as it
 124 allows switching from an encrypted channel back to plain text without user input."
 125   :type '(boolean))
 126
 127 (defcustom elpher-connection-timeout 5
 128   "Specifies the number of seconds to wait for a network connection to time out."
 129   :type '(integer))
 130
 131 (defcustom elpher-filter-ansi-from-text nil
 132   "If non-nil, filter ANSI escape sequences from text.
 133 The default behaviour is to use the ansi-color package to interpret these
 134 sequences."
 135   :type '(boolean))
 136
 137 (defcustom elpher-certificate-directory
 138   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 139   "Specify the name of the directory where client certificates will be stored.
 140 These certificates may be used for establishing authenticated TLS connections."
 141   :type '(directory))
 142
 143 (defcustom elpher-openssl-command "openssl"
 144   "The command used to launch openssl when generating TLS client certificates."
 145   :type '(file))
 146
 147 (defcustom elpher-gemini-TLS-cert-checks nil
 148   "If non-nil, verify gemini server TLS certs using the default security level.
 149 Otherwise, certificate verification is disabled.
 150
 151 This defaults to off because it is standard practice for Gemini servers
 152 to use self-signed certificates, meaning that most servers provide what
 153 EMACS considers to be an invalid certificate."
 154   :type '(boolean))
 155
 156 (defcustom elpher-gemini-max-fill-width 80
 157   "Specify the maximum default width (in columns) of text/gemini documents.
 158 The actual width used is the minimum of this value and the window width at
 159 the time when the text is rendered."
 160   :type '(integer))
 161
 162 (defcustom elpher-gemini-link-string "→ "
 163   "Specify the string used to indicate links when rendering gemini maps.
 164 May be empty."
 165   :type '(string))
 166
 167 (defcustom elpher-gemini-bullet-string "•"
 168   "Specify the string used for bullets when rendering gemini maps."
 169   :type '(string))
 170
 171 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 172   "Specify the name of the file where elpher bookmarks will be saved."
 173   :type '(file))
 174
 175 (defcustom elpher-ipv4-always nil
 176   "If non-nil, elpher will always use IPv4 to establish network connections.
 177 This can be useful when browsing from a computer that supports IPv6, because
 178 some servers which do not support IPv6 can take a long time to time-out."
 179   :type '(boolean))
 180
 181 ;; Face customizations
 182
 183 (defgroup elpher-faces nil
 184   "Elpher face customizations."
 185   :group 'elpher)
 186
 187 (defface elpher-index
 188   '((t :inherit font-lock-keyword-face))
 189   "Face used for directory type directory records.")
 190
 191 (defface elpher-text
 192   '((t :inherit bold))
 193   "Face used for text type directory records.")
 194
 195 (defface elpher-info
 196   '((t :inherit default))
 197   "Face used for info type directory records.")
 198
 199 (defface elpher-image
 200   '((t :inherit font-lock-string-face))
 201   "Face used for image type directory records.")
 202
 203 (defface elpher-search
 204   '((t :inherit warning))
 205   "Face used for search type directory records.")
 206
 207 (defface elpher-html
 208   '((t :inherit font-lock-comment-face))
 209   "Face used for html type directory records.")
 210
 211 (defface elpher-gemini
 212   '((t :inherit font-lock-regexp-grouping-backslash))
 213   "Face used for Gemini type directory records.")
 214
 215 (defface elpher-other-url
 216   '((t :inherit font-lock-comment-face))
 217   "Face used for other URL type links records.")
 218
 219 (defface elpher-telnet
 220   '((t :inherit font-lock-function-name-face))
 221   "Face used for telnet type directory records.")
 222
 223 (defface elpher-binary
 224   '((t :inherit font-lock-doc-face))
 225   "Face used for binary type directory records.")
 226
 227 (defface elpher-unknown
 228   '((t :inherit error))
 229   "Face used for directory records with unknown/unsupported types.")
 230
 231 (defface elpher-margin-key
 232   '((t :inherit bold))
 233   "Face used for directory margin key.")
 234
 235 (defface elpher-margin-brackets
 236   '((t :inherit shadow))
 237   "Face used for brackets around directory margin key.")
 238
 239 (defface elpher-gemini-heading1
 240   '((t :inherit bold :height 1.8))
 241   "Face used for gemini heading level 1.")
 242
 243 (defface elpher-gemini-heading2
 244   '((t :inherit bold :height 1.5))
 245   "Face used for gemini heading level 2.")
 246
 247 (defface elpher-gemini-heading3
 248   '((t :inherit bold :height 1.2))
 249   "Face used for gemini heading level 3.")
 250
 251 (defface elpher-gemini-preformatted
 252   '((t :inherit fixed-pitch))
 253   "Face used for pre-formatted gemini text blocks.")
 254
 255 ;;; Model
 256 ;;
 257
 258 ;; Address
 259
 260 ;; An elpher "address" object is either a url object or a symbol.
 261 ;; Symbol addresses are "special", corresponding to pages generated
 262 ;; dynamically for and by elpher.  All others represent pages which
 263 ;; rely on content retrieved over the network.
 264
 265 (defun elpher-address-from-url (url-string)
 266   "Create a ADDRESS object corresponding to the given URL-STRING."
 267   (let ((data (match-data))) ; Prevent parsing clobbering match data
 268     (unwind-protect
 269         (let ((url (url-generic-parse-url url-string)))
 270           (unless (and (not (url-fullness url)) (url-type url))
 271             (setf (url-fullness url) t)
 272             (setf (url-filename url)
 273                   (url-unhex-string (url-filename url)))
 274             (unless (url-type url)
 275               (setf (url-type url) "gopher"))
 276             (when (or (equal "gopher" (url-type url))
 277                       (equal "gophers" (url-type url)))
 278               ;; Gopher defaults
 279               (unless (url-host url)
 280                 (setf (url-host url) (url-filename url))
 281                 (setf (url-filename url) ""))
 282               (when (or (equal (url-filename url) "")
 283                         (equal (url-filename url) "/"))
 284                 (setf (url-filename url) "/1")))
 285             (when (equal "gemini" (url-type url))
 286               ;; Gemini defaults
 287               (if (equal (url-filename url) "")
 288                   (setf (url-filename url) "/"))))
 289           (elpher-remove-redundant-ports url))
 290       (set-match-data data))))
 291
 292 (defun elpher-remove-redundant-ports (address)
 293   "Remove redundant port specifiers from ADDRESS.
 294 Here 'redundant' means that the specified port matches the default
 295 for that protocol, eg 70 for gopher."
 296   (if (and (not (elpher-address-special-p address))
 297            (eq (url-portspec address) ; (url-port) is too slow!
 298                (pcase (url-type address)
 299                  ("gemini" 1965)
 300                  ((or "gopher" "gophers") 70)
 301                  ("finger" 79)
 302                  (_ -1))))
 303       (setf (url-portspec address) nil))
 304   address)
 305
 306 (defun elpher-make-gopher-address (type selector host port &optional tls)
 307   "Create an ADDRESS object using gopher directory record attributes.
 308 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 309 If the optional attribute TLS is non-nil, the address will be marked as
 310 requiring gopher-over-TLS."
 311   (cond
 312    ((equal type ?i) nil)
 313    ((and (equal type ?h)
 314          (string-prefix-p "URL:" selector))
 315     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 316    ((equal type ?8)
 317     (elpher-address-from-url
 318      (concat "telnet"
 319              "://" host
 320              ":" (number-to-string port))))
 321    (t
 322     (elpher-address-from-url
 323      (concat "gopher" (if tls "s" "")
 324              "://" host
 325              ":" (number-to-string port)
 326              "/" (string type)
 327              selector)))))
 328
 329 (defun elpher-make-special-address (type)
 330   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 331   type)
 332
 333 (defun elpher-address-to-url (address)
 334   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 335   (if (elpher-address-special-p address)
 336       nil
 337     (url-encode-url (url-recreate-url address))))
 338
 339 (defun elpher-address-type (address)
 340   "Retrieve type of ADDRESS object.
 341 This is used to determine how to retrieve and render the document the
 342 address refers to, via the table `elpher-type-map'."
 343   (if (symbolp address)
 344       (list 'special address)
 345     (let ((protocol (url-type address)))
 346       (cond ((or (equal protocol "gopher")
 347                  (equal protocol "gophers"))
 348              (list 'gopher
 349                    (if (member (url-filename address) '("" "/"))
 350                        ?1
 351                      (string-to-char (substring (url-filename address) 1)))))
 352             ((equal protocol "gemini")
 353              'gemini)
 354             ((equal protocol "telnet")
 355              'telnet)
 356             ((equal protocol "finger")
 357              'finger)
 358             (t 'other-url)))))
 359
 360 (defun elpher-address-protocol (address)
 361   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 362   (if (symbolp address)
 363       nil
 364     (url-type address)))
 365
 366 (defun elpher-address-filename (address)
 367   "Retrieve the filename component of ADDRESS.
 368 For gopher addresses this is a combination of the selector type and selector."
 369   (if (symbolp address)
 370       nil
 371     (url-filename address)))
 372
 373 (defun elpher-address-host (address)
 374   "Retrieve host from ADDRESS object."
 375   (url-host address))
 376
 377 (defun elpher-address-user (address)
 378   "Retrieve user from ADDRESS object."
 379   (url-user address))
 380
 381 (defun elpher-address-port (address)
 382   "Retrieve port from ADDRESS object.
 383 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 384   (if (symbolp address)
 385       0
 386     (url-port address)))
 387
 388 (defun elpher-address-special-p (address)
 389   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 390   (symbolp address))
 391
 392 (defun elpher-address-gopher-p (address)
 393   "Return non-nill if ADDRESS object is a gopher address."
 394   (and (not (elpher-address-special-p address))
 395        (member (elpher-address-protocol address) '("gopher gophers"))))
 396
 397 (defun elpher-gopher-address-selector (address)
 398   "Retrieve gopher selector from ADDRESS object."
 399   (if (member (url-filename address) '("" "/"))
 400       ""
 401     (url-unhex-string (substring (url-filename address) 2))))
 402
 403
 404 ;; Cache
 405
 406 (defvar elpher-content-cache (make-hash-table :test 'equal))
 407 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 408
 409 (defun elpher-get-cached-content (address)
 410   "Retrieve the cached content for ADDRESS, or nil if none exists."
 411   (gethash address elpher-content-cache))
 412
 413 (defun elpher-cache-content (address content)
 414   "Set the content cache for ADDRESS to CONTENT."
 415   (puthash address content elpher-content-cache))
 416
 417 (defun elpher-get-cached-pos (address)
 418   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 419   (gethash address elpher-pos-cache))
 420
 421 (defun elpher-cache-pos (address pos)
 422   "Set the cursor position cache for ADDRESS to POS."
 423   (puthash address pos elpher-pos-cache))
 424
 425
 426 ;; Page
 427
 428 (defun elpher-make-page (display-string address)
 429   "Create a page with DISPLAY-STRING and ADDRESS."
 430   (list display-string address))
 431
 432 (defun elpher-page-display-string (page)
 433   "Retrieve the display string corresponding to PAGE."
 434   (elt page 0))
 435
 436 (defun elpher-page-address (page)
 437   "Retrieve the address corresponding to PAGE."
 438   (elt page 1))
 439
 440 (defun elpher-page-set-address (page new-address)
 441   "Set the address corresponding to PAGE to NEW-ADDRESS."
 442   (setcar (cdr page) new-address))
 443
 444 (defvar elpher-current-page nil)        ; buffer local
 445 (defvar elpher-history nil)             ; buffer local
 446
 447 (defun elpher-visit-page (page &optional renderer no-history)
 448   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 449 Additionally, push PAGE onto the stack of previously-visited pages,
 450 unless NO-HISTORY is non-nil."
 451   (elpher-save-pos)
 452   (elpher-process-cleanup)
 453   (unless (or no-history
 454               (equal (elpher-page-address elpher-current-page)
 455                      (elpher-page-address page)))
 456     (push elpher-current-page elpher-history))
 457   (setq elpher-current-page page)
 458   (let* ((address (elpher-page-address page))
 459          (type (elpher-address-type address))
 460          (type-record (cdr (assoc type elpher-type-map))))
 461     (if type-record
 462         (funcall (car type-record)
 463                  (if renderer
 464                      renderer
 465                    (cadr type-record)))
 466       (elpher-visit-previous-page)
 467       (pcase type
 468         (`(gopher ,type-char)
 469          (error "Unsupported gopher selector type '%c' for '%s'"
 470                 type-char (elpher-address-to-url address)))
 471         (other
 472          (error "Unsupported address type '%S' for '%s'"
 473                 other (elpher-address-to-url address)))))))
 474
 475 (defun elpher-visit-previous-page ()
 476   "Visit the previous page in the history."
 477   (let ((previous-page (pop elpher-history)))
 478     (if previous-page
 479         (elpher-visit-page previous-page nil t)
 480       (error "No previous page"))))
 481
 482 (defun elpher-reload-current-page ()
 483   "Reload the current page, discarding any existing cached content."
 484   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 485   (elpher-visit-page elpher-current-page))
 486
 487 (defun elpher-save-pos ()
 488   "Save the current position of point to the current page."
 489   (when elpher-current-page
 490     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 491
 492 (defun elpher-restore-pos ()
 493   "Restore the position of point to that cached in the current page."
 494   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 495     (if pos
 496         (goto-char pos)
 497       (goto-char (point-min)))))
 498
 499
 500 ;;; Buffer preparation
 501 ;;
 502
 503 (defvar elpher-buffer-name "*elpher*"
 504   "The default name of the Elpher buffer.")
 505
 506 (defun elpher-update-header ()
 507   "If `elpher-use-header' is true, display current page info in window header."
 508   (if elpher-use-header
 509       (let* ((display-string (elpher-page-display-string elpher-current-page))
 510              (address (elpher-page-address elpher-current-page))
 511              (tls-string (if (and (not (elpher-address-special-p address))
 512                                   (member (elpher-address-protocol address)
 513                                           '("gophers" "gemini")))
 514                              " [TLS encryption]"
 515                            ""))
 516              (header (concat display-string
 517                              (propertize tls-string 'face 'bold))))
 518         (setq header-line-format header))))
 519
 520 (defmacro elpher-with-clean-buffer (&rest args)
 521   "Evaluate ARGS with a clean *elpher* buffer as current."
 522   `(with-current-buffer elpher-buffer-name
 523      (unless (eq major-mode 'elpher-mode)
 524        (elpher-mode))
 525      (let ((inhibit-read-only t))
 526        (setq-local network-security-level
 527                    (default-value 'network-security-level))
 528        (erase-buffer)
 529        (elpher-update-header)
 530        ,@args)))
 531
 532 (defun elpher-buffer-message (string &optional line)
 533   "Replace first line in elpher buffer with STRING.
 534 If LINE is non-nil, replace that line instead."
 535   (with-current-buffer elpher-buffer-name
 536     (let ((inhibit-read-only t))
 537       (goto-char (point-min))
 538       (if line
 539           (forward-line line))
 540       (let ((data (match-data)))
 541         (unwind-protect
 542             (progn
 543               (re-search-forward "^.*$")
 544               (replace-match string))
 545           (set-match-data data))))))
 546
 547
 548 ;;; Text Processing
 549 ;;
 550
 551 (defvar elpher-user-coding-system nil
 552   "User-specified coding system to use for decoding text responses.")
 553
 554 (defun elpher-decode (string)
 555   "Decode STRING using autodetected or user-specified coding system."
 556   (decode-coding-string string
 557                         (if elpher-user-coding-system
 558                             elpher-user-coding-system
 559                           (detect-coding-string string t))))
 560
 561 (defun elpher-preprocess-text-response (string)
 562   "Preprocess text selector response contained in STRING.
 563 This involes decoding the character representation, and clearing
 564 away CRs and any terminating period."
 565   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 566                                            (replace-regexp-in-string "\r" "" string))))
 567
 568
 569 ;;; Network error reporting
 570 ;;
 571
 572 (defun elpher-network-error (address error)
 573   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 574 ERROR can be either an error object or a string."
 575   (elpher-with-clean-buffer
 576    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 577            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 578            (if (stringp error) error (error-message-string error)) "\n"
 579            (propertize "\n----------------\n\n" 'face 'error)
 580            "Press 'u' to return to the previous page.")))
 581
 582
 583 ;;; General network communication
 584 ;;
 585
 586 (defvar elpher-network-timer nil
 587   "Timer used for network connections.")
 588
 589 (defvar elpher-use-tls nil
 590   "If non-nil, use TLS to communicate with gopher servers.")
 591
 592 (defvar elpher-client-certificate nil
 593   "If non-nil, contains client certificate details to use for TLS connections.")
 594
 595 (defun elpher-process-cleanup ()
 596   "Immediately shut down any extant elpher process and timers."
 597   (let ((p (get-process "elpher-process")))
 598     (if p (delete-process p)))
 599   (if (timerp elpher-network-timer)
 600       (cancel-timer elpher-network-timer)))
 601
 602 (defun elpher-get-host-response (address default-port query-string response-processor
 603                                          &optional use-tls force-ipv4)
 604   "Generic function for retrieving data from ADDRESS.
 605
 606 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 607 QUERY-STRING is a string sent to the host specified by ADDRESS to
 608 illicet a response.  This response is passed as an argument to the
 609 function RESPONSE-PROCESSOR.
 610
 611 If non-nil, USE-TLS specifies that the connection is to be made over
 612 TLS.  If set to gemini, the certificate verification will be disabled
 613 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 614
 615 If non-nil, FORCE-IPV4 causes the network connection to be made over
 616 ipv4 only.  (The default behaviour when this is not set depends on
 617 the host operating system and the local network capabilities."
 618   (if (and use-tls (not (gnutls-available-p)))
 619       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 620     (unless (< (elpher-address-port address) 65536)
 621       (error "Cannot establish network connection: port number > 65536"))
 622     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 623       (setq-local network-security-level 'low))
 624     (condition-case nil
 625         (let* ((kill-buffer-query-functions nil)
 626                (port (elpher-address-port address))
 627                (host (elpher-address-host address))
 628                (response-string-parts nil)
 629                (bytes-received 0)
 630                (hkbytes-received 0)
 631                (proc (make-network-process :name "elpher-process"
 632                                            :host host
 633                                            :family (and force-ipv4 'ipv4)
 634                                            :service (if (> port 0) port default-port)
 635                                            :buffer nil
 636                                            :coding 'binary
 637                                            :noquery t
 638                                            :nowait t
 639                                            :tls-parameters
 640                                            (and use-tls
 641                                                 (cons 'gnutls-x509pki
 642                                                       (gnutls-boot-parameters
 643                                                        :type 'gnutls-x509pki
 644                                                        :hostname host
 645                                                        :keylist
 646                                                        (elpher-get-current-keylist address))))))
 647                (timer (run-at-time elpher-connection-timeout nil
 648                                    (lambda ()
 649                                      (elpher-process-cleanup)
 650                                      (cond
 651                                         ; Try again with IPv4
 652                                       ((not force-ipv4)
 653                                        (message "Connection timed out.  Retrying with IPv4.")
 654                                        (elpher-get-host-response address default-port
 655                                                                  query-string
 656                                                                  response-processor
 657                                                                  use-tls t))
 658                                       ((and use-tls
 659                                             (not (eq use-tls 'gemini))
 660                                             (or elpher-auto-disengage-TLS
 661                                                 (y-or-n-p
 662                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 663                                        (setq elpher-use-tls nil)
 664                                        (elpher-get-host-response address default-port
 665                                                                  query-string
 666                                                                  response-processor
 667                                                                  nil force-ipv4))
 668                                       (t
 669                                        (elpher-network-error address "Connection time-out.")))))))
 670           (setq elpher-network-timer timer)
 671           (elpher-buffer-message (concat "Connecting to " host "..."
 672                                          " (press 'u' to abort)"))
 673           (set-process-filter proc
 674                               (lambda (_proc string)
 675                                 (when timer
 676                                   (cancel-timer timer)
 677                                   (setq timer nil))
 678                                 (setq bytes-received (+ bytes-received (length string)))
 679                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 680                                   (when (> new-hkbytes-received hkbytes-received)
 681                                     (setq hkbytes-received new-hkbytes-received)
 682                                     (elpher-buffer-message
 683                                         (concat "("
 684                                                 (number-to-string (/ hkbytes-received 10.0))
 685                                                 " MB read)")
 686                                         1)))
 687                                 (setq response-string-parts
 688                                       (cons string response-string-parts))))
 689           (set-process-sentinel proc
 690                                 (lambda (proc event)
 691                                   (when timer
 692                                     (cancel-timer timer))
 693                                   (condition-case the-error
 694                                       (cond
 695                                        ((string-prefix-p "open" event)    ; request URL
 696                                         (elpher-buffer-message
 697                                          (concat "Connected to " host ". Receiving data..."
 698                                                  " (press 'u' to abort)"))
 699                                         (let ((inhibit-eol-conversion t))
 700                                           (process-send-string proc query-string)))
 701                                        ((string-prefix-p "deleted" event)) ; do nothing
 702                                        ((and (not response-string-parts)
 703                                              (not (or elpher-ipv4-always force-ipv4)))
 704                                         ; Try again with IPv4
 705                                         (message "Connection failed. Retrying with IPv4.")
 706                                         (elpher-get-host-response address default-port
 707                                                                   query-string
 708                                                                   response-processor
 709                                                                   use-tls t))
 710                                        (response-string-parts
 711                                         (elpher-with-clean-buffer
 712                                          (insert "Data received.  Rendering..."))
 713                                         (funcall response-processor
 714                                                  (apply #'concat (reverse response-string-parts)))
 715                                         (elpher-restore-pos))
 716                                        (t
 717                                         (error "No response from server")))
 718                                     (error
 719                                      (elpher-network-error address the-error))))))
 720       (error
 721        (error "Error initiating connection to server")))))
 722
 723
 724 ;;; Client-side TLS Certificate Management
 725 ;;
 726
 727 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 728   "Generate a key and a self-signed client TLS certificate using openssl.
 729
 730 The Common Name field of the certificate is set to COMMON-NAME.  The
 731 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 732 the key and certificate files to write.
 733
 734 If TEMPORARY is non-nil, the certificate will be given an exporation
 735 period of one day, and the key and certificate files will be deleted
 736 when the certificate is no longer needed for the current session.
 737
 738 Otherwise, the certificate will be given a 100 year expiration period
 739 and the files will not be deleted.
 740
 741 The function returns a list containing the current host name, the
 742 temporary flag, and the key and cert file names in the form required
 743 by `gnutls-boot-parameters`."
 744   (let ((exp-key-file (expand-file-name key-file))
 745         (exp-cert-file (expand-file-name cert-file)))
 746     (condition-case nil
 747         (progn
 748           (call-process elpher-openssl-command nil nil nil
 749                         "req" "-x509" "-newkey" "rsa:2048"
 750                         "-days" (if temporary "1" "36500")
 751                         "-nodes"
 752                         "-subj" (concat "/CN=" common-name)
 753                         "-keyout" exp-key-file
 754                         "-out" exp-cert-file)
 755           (list (elpher-address-host (elpher-page-address elpher-current-page))
 756                 temporary exp-key-file exp-cert-file))
 757       (error
 758        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 759        (error "Program 'openssl', required for certificate generation, not found")))))
 760
 761 (defun elpher-generate-throwaway-certificate ()
 762   "Generate and return details of a throwaway certificate.
 763 The key and certificate files will be deleted when they are no
 764 longer needed for this session."
 765   (let* ((file-base (make-temp-name "elpher"))
 766          (key-file (concat temporary-file-directory file-base ".key"))
 767          (cert-file (concat temporary-file-directory file-base ".crt")))
 768     (elpher-generate-certificate file-base key-file cert-file t)))
 769
 770 (defun elpher-generate-persistent-certificate (file-base common-name)
 771   "Generate and return details of a persistent certificate.
 772 The argument FILE-BASE is used as the base for the key and certificate
 773 files, while COMMON-NAME specifies the common name field of the
 774 certificate.
 775
 776 The key and certificate files are written to in `elpher-certificate-directory'."
 777   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 778          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 779     (elpher-generate-certificate common-name key-file cert-file)))
 780
 781 (defun elpher-get-existing-certificate (file-base)
 782   "Return a certificate object corresponding to an existing certificate.
 783 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 784 the directory `elpher-certificate-directory'."
 785   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 786          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 787     (list (elpher-address-host (elpher-page-address elpher-current-page))
 788           nil
 789           (expand-file-name key-file)
 790           (expand-file-name cert-file))))
 791
 792 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 793   "Install a key+certificate file pair in `elpher-certificate-directory'.
 794 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 795 certificate files to install.  The argument FILE-BASE is used as the
 796 base for the installed key and certificate files."
 797   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 798          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 799     (if (or (file-exists-p key-file)
 800             (file-exists-p cert-file))
 801         (error "A certificate with base name %s is already installed" file-base))
 802     (copy-file key-file-src key-file)
 803     (copy-file cert-file-src cert-file)
 804     (list (elpher-address-host (elpher-page-address elpher-current-page))
 805           nil
 806           (expand-file-name key-file)
 807           (expand-file-name cert-file))))
 808
 809 (defun elpher-list-existing-certificates ()
 810   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 811   (mapcar
 812    (lambda (file)
 813      (file-name-sans-extension file))
 814    (directory-files elpher-certificate-directory nil "\.key$")))
 815
 816 (defun elpher-forget-current-certificate ()
 817   "Causes any current certificate to be forgotten.)
 818 In the case of throwaway certificates, the key and certificate files
 819 are also deleted."
 820   (interactive)
 821   (when elpher-client-certificate
 822     (unless (and (called-interactively-p 'any)
 823                  (not (y-or-n-p (concat "Really forget client certificate? "
 824                                         "(Throwaway certificates will be deleted.)"))))
 825       (when (cadr elpher-client-certificate)
 826         (delete-file (elt elpher-client-certificate 2))
 827         (delete-file (elt elpher-client-certificate 3)))
 828       (setq elpher-client-certificate nil)
 829       (if (called-interactively-p 'any)
 830           (message "Client certificate forgotten.")))))
 831
 832 (defun elpher-get-current-keylist (address)
 833   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 834
 835 This is obtained from the client certificate described by
 836 `elpher-current-certificate', if one is available and the host for
 837 that certificate matches the host in ADDRESS.
 838
 839 If `elpher-current-certificate' is non-nil, and its host name doesn't
 840 match that of ADDRESS, the certificate is forgotten."
 841   (if elpher-client-certificate
 842       (if (string= (car elpher-client-certificate)
 843                    (elpher-address-host address))
 844           (list (cddr elpher-client-certificate))
 845         (elpher-forget-current-certificate)
 846         (message "Disabling client certificate for new host")
 847         nil)
 848     nil))
 849
 850
 851 ;;; Gopher selector retrieval
 852 ;;
 853
 854 (defun elpher-get-gopher-response (address renderer)
 855   "Get response string from gopher server at ADDRESS and render using RENDERER."
 856   (elpher-get-host-response address 70
 857                             (concat (elpher-gopher-address-selector address) "\r\n")
 858                             renderer
 859                             (or (string= (elpher-address-protocol address) "gophers")
 860                                 elpher-use-tls)))
 861
 862 (defun elpher-get-gopher-page (renderer)
 863   "Getter function for gopher pages.
 864 The RENDERER procedure is used to display the contents of the page
 865 once they are retrieved from the gopher server."
 866   (let* ((address (elpher-page-address elpher-current-page))
 867          (content (elpher-get-cached-content address)))
 868     (if (and content (funcall renderer nil))
 869         (elpher-with-clean-buffer
 870          (insert content)
 871          (elpher-restore-pos))
 872       (elpher-with-clean-buffer
 873        (insert "LOADING... (use 'u' to cancel)\n"))
 874       (condition-case the-error
 875           (elpher-get-gopher-response address renderer)
 876         (error
 877          (elpher-network-error address the-error))))))
 878
 879 ;; Index rendering
 880
 881 (defun elpher-insert-index (string)
 882   "Insert the index corresponding to STRING into the current buffer."
 883   ;; Should be able to split directly on CRLF, but some non-conformant
 884   ;; LF-only servers sadly exist, hence the following.
 885   (let ((str-processed (elpher-preprocess-text-response string)))
 886     (dolist (line (split-string str-processed "\n"))
 887       (ignore-errors
 888         (unless (= (length line) 0)
 889           (let* ((type (elt line 0))
 890                  (fields (split-string (substring line 1) "\t"))
 891                  (display-string (elt fields 0))
 892                  (selector (elt fields 1))
 893                  (host (elt fields 2))
 894                  (port (if (elt fields 3)
 895                            (string-to-number (elt fields 3))
 896                          nil))
 897                  (address (elpher-make-gopher-address type selector host port)))
 898             (elpher-insert-index-record display-string address)))))))
 899
 900 (defun elpher-insert-margin (&optional type-name)
 901   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 902   (if type-name
 903       (progn
 904         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 905                         (concat
 906                          (propertize "[" 'face 'elpher-margin-brackets)
 907                          (propertize type-name 'face 'elpher-margin-key)
 908                          (propertize "]" 'face 'elpher-margin-brackets))))
 909         (insert " "))
 910     (insert (make-string elpher-margin-width ?\s))))
 911
 912 (defun elpher--page-button-help (_window buffer pos)
 913   "Function called by Emacs to generate mouse-over text.
 914 The arguments specify the BUFFER and the POS within the buffer of the item
 915 for which help is required.  The function returns the help to be
 916 displayed.  The _WINDOW argument is currently unused."
 917   (with-current-buffer buffer
 918     (let ((button (button-at pos)))
 919       (when button
 920         (let* ((page (button-get button 'elpher-page))
 921                (address (elpher-page-address page)))
 922           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 923                                                 address
 924                                               (elpher-address-to-url address))))))))
 925
 926 (defun elpher-insert-index-record (display-string &optional address)
 927   "Function to insert an index record into the current buffer.
 928 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 929 If ADDRESS is not supplied or nil the record is rendered as an
 930 'information' line."
 931   (let* ((type (if address (elpher-address-type address) nil))
 932          (type-map-entry (cdr (assoc type elpher-type-map))))
 933     (if type-map-entry
 934         (let* ((margin-code (elt type-map-entry 2))
 935                (face (elt type-map-entry 3))
 936                (filtered-display-string (ansi-color-filter-apply display-string))
 937                (page (elpher-make-page filtered-display-string address)))
 938           (elpher-insert-margin margin-code)
 939           (insert-text-button filtered-display-string
 940                               'face face
 941                               'elpher-page page
 942                               'action #'elpher-click-link
 943                               'follow-link t
 944                               'help-echo #'elpher--page-button-help))
 945       (pcase type
 946         ('nil ;; Information
 947          (elpher-insert-margin)
 948          (let ((propertized-display-string
 949                 (propertize display-string 'face 'elpher-info)))
 950            (insert (elpher-process-text-for-display propertized-display-string))))
 951         (`(gopher ,selector-type) ;; Unknown
 952          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 953          (insert (propertize display-string
 954                              'face 'elpher-unknown)))))
 955     (insert "\n")))
 956
 957 (defun elpher-click-link (button)
 958   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 959   (let ((page (button-get button 'elpher-page)))
 960     (elpher-visit-page page)))
 961
 962 (defun elpher-render-index (data &optional _mime-type-string)
 963   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 964   (elpher-with-clean-buffer
 965    (if (not data)
 966        t
 967      (elpher-insert-index data)
 968      (elpher-cache-content (elpher-page-address elpher-current-page)
 969                            (buffer-string)))))
 970
 971 ;; Text rendering
 972
 973 (defconst elpher-url-regex
 974   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 975   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 976
 977 (defun elpher-buttonify-urls (string)
 978   "Turn substrings which look like urls in STRING into clickable buttons."
 979   (with-temp-buffer
 980     (insert string)
 981     (goto-char (point-min))
 982     (while (re-search-forward elpher-url-regex nil t)
 983       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 984                                     (elpher-address-from-url (match-string 0)))))
 985           (make-text-button (match-beginning 0)
 986                             (match-end 0)
 987                             'elpher-page  page
 988                             'action #'elpher-click-link
 989                             'follow-link t
 990                             'help-echo #'elpher--page-button-help
 991                             'face 'button)))
 992     (buffer-string)))
 993
 994 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 995   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 996
 997 (defun elpher-process-text-for-display (string)
 998   "Perform any desired processing of STRING prior to display as text.
 999 Currently includes buttonifying URLs and processing ANSI escape codes."
1000   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1001                              (ansi-color-filter-apply string)
1002                            (ansi-color-apply string))))
1003
1004 (defun elpher-render-text (data &optional _mime-type-string)
1005   "Render DATA as text.  MIME-TYPE-STRING is unused."
1006   (elpher-with-clean-buffer
1007    (if (not data)
1008        t
1009      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1010      (elpher-cache-content
1011       (elpher-page-address elpher-current-page)
1012       (buffer-string)))))
1013
1014 ;; Image retrieval
1015
1016 (defun elpher-render-image (data &optional _mime-type-string)
1017   "Display DATA as image.  MIME-TYPE-STRING is unused."
1018   (if (not data)
1019       nil
1020     (if (display-images-p)
1021         (progn
1022           (let ((image (create-image
1023                         data
1024                         nil t)))
1025             (elpher-with-clean-buffer
1026              (insert-image image)
1027              (elpher-restore-pos))))
1028       (elpher-render-download data))))
1029
1030 ;; Search retrieval and rendering
1031
1032 (defun elpher-get-gopher-query-page (renderer)
1033   "Getter for gopher addresses requiring input.
1034 The response is rendered using the rendering function RENDERER."
1035    (let* ((address (elpher-page-address elpher-current-page))
1036           (content (elpher-get-cached-content address))
1037           (aborted t))
1038     (if (and content (funcall renderer nil))
1039         (elpher-with-clean-buffer
1040          (insert content)
1041          (elpher-restore-pos)
1042          (message "Displaying cached search results.  Reload to perform a new search."))
1043       (unwind-protect
1044           (let* ((query-string (read-string "Query: "))
1045                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1046                  (search-address (elpher-make-gopher-address ?1
1047                                                              query-selector
1048                                                              (elpher-address-host address)
1049                                                              (elpher-address-port address)
1050                                                              (equal (elpher-address-type address) "gophers"))))
1051             (setq aborted nil)
1052
1053             (elpher-with-clean-buffer
1054              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1055             (elpher-get-gopher-response search-address renderer))
1056         (if aborted
1057             (elpher-visit-previous-page))))))
1058
1059 ;; Raw server response rendering
1060
1061 (defun elpher-render-raw (data &optional mime-type-string)
1062   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1063   (if (not data)
1064       nil
1065     (elpher-with-clean-buffer
1066      (when mime-type-string
1067        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1068      (insert data)
1069      (goto-char (point-min)))
1070     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1071
1072 ;; File save "rendering"
1073
1074 (defun elpher-render-download (data &optional _mime-type-string)
1075   "Save DATA to file.  MIME-TYPE-STRING is unused."
1076   (if (not data)
1077       nil
1078     (let* ((address (elpher-page-address elpher-current-page))
1079            (selector (if (elpher-address-gopher-p address)
1080                          (elpher-gopher-address-selector address)
1081                        (elpher-address-filename address))))
1082       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1083       (let* ((filename-proposal (file-name-nondirectory selector))
1084              (filename (read-file-name "Download complete. Save file as: "
1085                                        nil nil nil
1086                                        (if (> (length filename-proposal) 0)
1087                                            filename-proposal
1088                                          "download.file"))))
1089         (let ((coding-system-for-write 'binary))
1090           (with-temp-file filename
1091             (insert data)))
1092         (message (format "Saved to file %s." filename))))))
1093
1094 ;; HTML rendering
1095
1096 (defun elpher-render-html (data &optional _mime-type-string)
1097   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1098   (elpher-with-clean-buffer
1099    (if (not data)
1100        t
1101      (let ((dom (with-temp-buffer
1102                   (insert data)
1103                   (libxml-parse-html-region (point-min) (point-max)))))
1104        (shr-insert-document dom)))))
1105
1106 ;; Gemini page retrieval
1107
1108 (defvar elpher-gemini-redirect-chain)
1109
1110 (defun elpher-get-gemini-response (address renderer)
1111   "Get response string from gemini server at ADDRESS and render using RENDERER."
1112   (elpher-get-host-response address 1965
1113                             (concat (elpher-address-to-url address) "\r\n")
1114                             (lambda (response-string)
1115                               (elpher-process-gemini-response response-string renderer))
1116                             'gemini))
1117
1118 (defun elpher-parse-gemini-response (response)
1119   "Parse the RESPONSE string and return a list of components.
1120 The list is of the form (code meta body).  A response of nil implies
1121 that the response was malformed."
1122   (let ((header-end-idx (string-match "\r\n" response)))
1123     (if header-end-idx
1124         (let ((header (string-trim (substring response 0 header-end-idx)))
1125               (body (substring response (+ header-end-idx 2))))
1126           (if (>= (length header) 2)
1127               (let ((code (substring header 0 2))
1128                     (meta (string-trim (substring header 2))))
1129                 (list code meta body))
1130             (error "Malformed response: No response status found in header %s" header)))
1131       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1132
1133 (defun elpher-process-gemini-response (response-string renderer)
1134   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1135   (let ((response-components (elpher-parse-gemini-response response-string)))
1136     (let ((response-code (elt response-components 0))
1137           (response-meta (elt response-components 1))
1138           (response-body (elt response-components 2)))
1139       (pcase (elt response-code 0)
1140         (?1 ; Input required
1141          (elpher-with-clean-buffer
1142           (insert "Gemini server is requesting input."))
1143          (let* ((query-string
1144                  (if (eq (elt response-code 1) ?1)
1145                      (read-passwd (concat response-meta ": "))
1146                    (read-string (concat response-meta ": "))))
1147                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1148                 (old-fname (url-filename query-address)))
1149            (setf (url-filename query-address)
1150                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1151            (elpher-get-gemini-response query-address renderer)))
1152         (?2 ; Normal response
1153          (funcall renderer response-body response-meta))
1154         (?3 ; Redirect
1155          (message "Following redirect to %s" response-meta)
1156          (if (>= (length elpher-gemini-redirect-chain) 5)
1157              (error "More than 5 consecutive redirects followed"))
1158          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1159            (if (member redirect-address elpher-gemini-redirect-chain)
1160                (error "Redirect loop detected"))
1161            (if (not (string= (elpher-address-protocol redirect-address)
1162                              "gemini"))
1163                (error "Server tried to automatically redirect to non-gemini URL: %s"
1164                       response-meta))
1165            (elpher-page-set-address elpher-current-page redirect-address)
1166            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1167            (elpher-get-gemini-response redirect-address renderer)))
1168         (?4 ; Temporary failure
1169          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1170                 response-code response-meta))
1171         (?5 ; Permanent failure
1172          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1173                 response-code response-meta))
1174         (?6 ; Client certificate required
1175          (elpher-with-clean-buffer
1176           (if elpher-client-certificate
1177               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1178             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1179           (auto-fill-mode 1)
1180           (elpher-gemini-insert-text response-meta))
1181          (let ((chosen-certificate (elpher-choose-client-certificate)))
1182            (unless chosen-certificate
1183              (error "Gemini server requires a client certificate and none was provided"))
1184            (setq elpher-client-certificate chosen-certificate))
1185          (elpher-with-clean-buffer)
1186          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1187         (_other
1188          (error "Gemini server response unknown: %s %s"
1189                 response-code response-meta))))))
1190
1191 (defun elpher-choose-client-certificate ()
1192   "Prompt for a client certificate to use to establish a TLS connection."
1193   (let* ((read-answer-short t))
1194     (pcase (read-answer "What do you want to do? "
1195                         '(("throwaway" ?t
1196                            "generate and use throw-away certificate")
1197                           ("persistent" ?p
1198                            "generate new or use existing persistent certificate")
1199                           ("abort" ?a
1200                            "stop immediately")))
1201       ("throwaway"
1202        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1203       ("persistent"
1204        (let* ((existing-certificates (elpher-list-existing-certificates))
1205               (file-base (completing-read
1206                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1207                           existing-certificates)))
1208          (if (string-empty-p (string-trim file-base))
1209              nil
1210            (if (member file-base existing-certificates)
1211                (setq elpher-client-certificate
1212                      (elpher-get-existing-certificate file-base))
1213              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1214                                  '(("new" ?n
1215                                     "generate new certificate")
1216                                    ("install" ?i
1217                                     "install existing certificate")
1218                                    ("abort" ?a
1219                                     "stop immediately")))
1220                ("new"
1221                 (let ((common-name (read-string "Common Name field for new certificate: "
1222                                                 file-base)))
1223                   (message "New key and self-signed certificate written to %s"
1224                            elpher-certificate-directory)
1225                   (elpher-generate-persistent-certificate file-base common-name)))
1226                ("install"
1227                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1228                        (key-file (read-file-name "Key file: " nil nil t)))
1229                   (message "Key and certificate installed in %s for future use"
1230                            elpher-certificate-directory)
1231                   (elpher-install-and-use-existing-certificate key-file
1232                                                                cert-file
1233                                                                file-base)))
1234                ("abort" nil))))))
1235       ("abort" nil))))
1236
1237 (defun elpher-get-gemini-page (renderer)
1238   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1239   (let* ((address (elpher-page-address elpher-current-page))
1240          (content (elpher-get-cached-content address)))
1241     (condition-case the-error
1242         (if (and content (funcall renderer nil))
1243             (elpher-with-clean-buffer
1244               (insert content)
1245               (elpher-restore-pos))
1246           (elpher-with-clean-buffer
1247            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1248           (setq elpher-gemini-redirect-chain nil)
1249           (elpher-get-gemini-response address renderer))
1250       (error
1251        (elpher-network-error address the-error)))))
1252
1253 (defun elpher-render-gemini (body &optional mime-type-string)
1254   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1255   (if (not body)
1256       t
1257     (let* ((mime-type-string* (if (or (not mime-type-string)
1258                                       (string-empty-p mime-type-string))
1259                                   "text/gemini; charset=utf-8"
1260                                 mime-type-string))
1261            (mime-type-split (split-string mime-type-string* ";" t))
1262            (mime-type (string-trim (car mime-type-split)))
1263            (parameters (mapcar (lambda (s)
1264                                  (let ((key-val (split-string s "=")))
1265                                    (list (downcase (string-trim (car key-val)))
1266                                          (downcase (string-trim (cadr key-val))))))
1267                                (cdr mime-type-split))))
1268       (when (string-prefix-p "text/" mime-type)
1269         (setq body (decode-coding-string
1270                     body
1271                     (if (assoc "charset" parameters)
1272                         (intern (cadr (assoc "charset" parameters)))
1273                       'utf-8)))
1274         (setq body (replace-regexp-in-string "\r" "" body)))
1275       (pcase mime-type
1276         ((or "text/gemini" "")
1277          (elpher-render-gemini-map body parameters))
1278         ("text/html"
1279          (elpher-render-html body))
1280         ((pred (string-prefix-p "text/"))
1281          (elpher-render-gemini-plain-text body parameters))
1282         ((pred (string-prefix-p "image/"))
1283          (elpher-render-image body))
1284         (_other
1285          (elpher-render-download body))))))
1286
1287 (defun elpher-gemini-get-link-url (link-line)
1288   "Extract the url portion of LINK-LINE, a gemini map file link line.
1289 Returns nil in the event that the contents of the line following the
1290 => prefix are empty."
1291   (let ((l (split-string (substring link-line 2))))
1292     (if l
1293         (string-trim (elt l 0))
1294       nil)))
1295
1296 (defun elpher-gemini-get-link-display-string (link-line)
1297   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1298 Returns the url portion in the event that the display-string portion is empty."
1299   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1300          (idx (string-match "[ \t]" rest)))
1301     (string-trim (if idx
1302                      (substring rest (+ idx 1))
1303                    rest))))
1304
1305 (defun elpher-collapse-dot-sequences (filename)
1306   "Collapse dot sequences in FILENAME.
1307 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1308   (let* ((path (split-string filename "/"))
1309          (path-reversed-normalized
1310           (seq-reduce (lambda (a b)
1311                         (cond ((and a (equal b "..") (cdr a)))
1312                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1313                               ((equal b ".") a)
1314                               (t (cons b a))))
1315                       path nil)))
1316     (string-join (reverse path-reversed-normalized) "/")))
1317
1318 (defun elpher-address-from-gemini-url (url)
1319   "Extract address from URL with defaults as per gemini map files.
1320 While there's obviously some redundancy here between this function and
1321 `elpher-address-from-url', gemini map file URLs require enough special
1322 treatment that a separate function is warranted."
1323   (let ((address (url-generic-parse-url url))
1324         (current-address (elpher-page-address elpher-current-page)))
1325     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1326       (setf (url-fullness address) t)
1327       (if (url-host address) ;if there is an explicit host, filenames are absolute
1328           (if (string-empty-p (url-filename address))
1329               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1330         (setf (url-host address) (url-host current-address))
1331         (setf (url-port address) (url-port current-address))
1332         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1333           (setf (url-filename address)
1334                 (concat (file-name-directory (url-filename current-address))
1335                         (url-filename address)))))
1336       (unless (url-type address)
1337         (setf (url-type address) "gemini"))
1338       (when (equal (url-type address) "gemini")
1339         (setf (url-filename address)
1340               (elpher-collapse-dot-sequences (url-filename address)))))
1341     (elpher-remove-redundant-ports address)))
1342
1343 (defun elpher-gemini-insert-link (link-line)
1344   "Insert link described by LINK-LINE into a text/gemini document."
1345   (let* ((url (elpher-gemini-get-link-url link-line))
1346          (display-string (elpher-gemini-get-link-display-string link-line))
1347          (address (elpher-address-from-gemini-url url))
1348          (type (if address (elpher-address-type address) nil))
1349          (type-map-entry (cdr (assoc type elpher-type-map))))
1350     (when display-string
1351       (insert elpher-gemini-link-string)
1352       (if type-map-entry
1353           (let* ((face (elt type-map-entry 3))
1354                  (filtered-display-string (ansi-color-filter-apply display-string))
1355                  (page (elpher-make-page filtered-display-string address)))
1356             (insert-text-button filtered-display-string
1357                                 'face face
1358                                 'elpher-page page
1359                                 'action #'elpher-click-link
1360                                 'follow-link t
1361                                 'help-echo #'elpher--page-button-help))
1362         (insert (propertize display-string 'face 'elpher-unknown)))
1363       (insert "\n"))))
1364
1365 (defun elpher-gemini-insert-header (header-line)
1366   "Insert header described by HEADER-LINE into a text/gemini document.
1367 The gemini map file line describing the header is given
1368 by HEADER-LINE."
1369   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1370     (let ((level (length (match-string 1 header-line)))
1371           (header (substring header-line (match-end 0))))
1372       (unless (display-graphic-p)
1373         (insert (make-string level ?#) " "))
1374       (insert (propertize header 'face
1375                           (pcase level
1376                             (1 'elpher-gemini-heading1)
1377                             (2 'elpher-gemini-heading2)
1378                             (3 'elpher-gemini-heading3)
1379                             (_ 'default)))
1380               "\n"))))
1381
1382 (defun elpher-gemini-insert-text (text-line)
1383   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1384 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1385 width defined by elpher-gemini-max-fill-width."
1386   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1387   (let* ((processed-text-line (if (match-string 2 text-line)
1388                                   (concat
1389                                    (replace-regexp-in-string "\*"
1390                                                              elpher-gemini-bullet-string
1391                                                              (match-string 0 text-line))
1392                                    (substring text-line (match-end 0)))
1393                                 text-line))
1394          (adaptive-fill-mode nil)
1395          (fill-prefix (if (match-string 2 text-line)
1396                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1397                         nil)))
1398     (insert (elpher-process-text-for-display processed-text-line))
1399     (newline)))
1400
1401 (defun elpher-render-gemini-map (data _parameters)
1402   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1403   (elpher-with-clean-buffer
1404    (let ((preformatted nil))
1405      (auto-fill-mode 1)
1406      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1407      (dolist (line (split-string data "\n"))
1408        (cond
1409         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1410         (preformatted (insert (elpher-process-text-for-display
1411                                (propertize line 'face 'elpher-gemini-preformatted))
1412                               "\n"))
1413         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1414         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1415         (t (elpher-gemini-insert-text line)))))
1416    (elpher-cache-content
1417     (elpher-page-address elpher-current-page)
1418     (buffer-string))))
1419
1420 (defun elpher-render-gemini-plain-text (data _parameters)
1421   "Render DATA as plain text file.  PARAMETERS is currently unused."
1422   (elpher-with-clean-buffer
1423    (insert (elpher-process-text-for-display data))
1424    (elpher-cache-content
1425     (elpher-page-address elpher-current-page)
1426     (buffer-string))))
1427
1428
1429 ;; Finger page connection
1430
1431 (defun elpher-get-finger-page (renderer)
1432   "Opens a finger connection to the current page address.
1433 The result is rendered using RENDERER."
1434   (let* ((address (elpher-page-address elpher-current-page))
1435          (content (elpher-get-cached-content address)))
1436     (if (and content (funcall renderer nil))
1437         (elpher-with-clean-buffer
1438          (insert content)
1439          (elpher-restore-pos))
1440       (elpher-with-clean-buffer
1441        (insert "LOADING... (use 'u' to cancel)\n"))
1442       (condition-case the-error
1443           (let* ((kill-buffer-query-functions nil)
1444                  (user (let ((filename (elpher-address-filename address)))
1445                          (if (> (length filename) 1)
1446                              (substring filename 1)
1447                            (elpher-address-user address)))))
1448             (elpher-get-host-response address 79
1449                                       (concat user "\r\n")
1450                                       renderer))
1451         (error
1452          (elpher-network-error address the-error))))))
1453
1454
1455 ;; Telnet page connection
1456
1457 (defun elpher-get-telnet-page (renderer)
1458   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1459   (when renderer
1460     (elpher-visit-previous-page)
1461     (error "Command not supported for telnet URLs"))
1462   (let* ((address (elpher-page-address elpher-current-page))
1463          (host (elpher-address-host address))
1464          (port (elpher-address-port address)))
1465     (elpher-visit-previous-page)
1466     (if (> port 0)
1467         (telnet host port)
1468       (telnet host))))
1469
1470
1471 ;; Other URL page opening
1472
1473 (defun elpher-get-other-url-page (renderer)
1474   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1475   (when renderer
1476     (elpher-visit-previous-page)
1477     (error "Command not supported for general URLs"))
1478   (let* ((address (elpher-page-address elpher-current-page))
1479          (url (elpher-address-to-url address)))
1480     (progn
1481       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1482       (message "Opening URL...")
1483       (if elpher-open-urls-with-eww
1484           (browse-web url)
1485         (browse-url url)))))
1486
1487
1488 ;; Start page page retrieval
1489
1490 (defun elpher-get-start-page (renderer)
1491   "Getter which displays the start page (RENDERER must be nil)."
1492   (when renderer
1493     (elpher-visit-previous-page)
1494     (error "Command not supported for start page"))
1495   (elpher-with-clean-buffer
1496    (insert "     --------------------------------------------\n"
1497            "           Elpher Gopher and Gemini Client       \n"
1498            "                   version " elpher-version "\n"
1499            "     --------------------------------------------\n"
1500            "\n"
1501            "Default bindings:\n"
1502            "\n"
1503            " - TAB/Shift-TAB: next/prev item on current page\n"
1504            " - RET/mouse-1: open item under cursor\n"
1505            " - m: select an item on current page by name (autocompletes)\n"
1506            " - u/mouse-3/U: return to previous page or to the start page\n"
1507            " - o/O: visit different selector or the root menu of the current server\n"
1508            " - g: go to a particular address (gopher, gemini, finger)\n"
1509            " - d/D: download item under cursor or current page\n"
1510            " - i/I: info on item under cursor or current page\n"
1511            " - c/C: copy URL representation of item under cursor or current page\n"
1512            " - a/A: bookmark the item under cursor or current page\n"
1513            " - x/X: remove bookmark for item under cursor or current page\n"
1514            " - B: visit the bookmarks page\n"
1515            " - r: redraw current page (using cached contents if available)\n"
1516            " - R: reload current page (regenerates cache)\n"
1517            " - S: set character coding system for gopher (default is to autodetect)\n"
1518            " - T: toggle TLS gopher mode\n"
1519            " - F: forget/discard current TLS client certificate\n"
1520            " - .: display the raw server response for the current page\n"
1521            "\n"
1522            "Start your exploration of gopher space and gemini:\n")
1523    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1524                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1525    (elpher-insert-index-record "Project Gemini home page"
1526                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1527    (insert "\n"
1528            "Alternatively, select a search engine and enter some search terms:\n")
1529    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1530                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1531    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1532                                (elpher-address-from-url "gemini://gus.guru/search"))
1533    (insert "\n"
1534            "This page contains your bookmarked sites (also visit with B):\n")
1535    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1536    (insert "\n"
1537            "For Elpher release news or to leave feedback, visit:\n")
1538    (elpher-insert-index-record "The Elpher Project Page"
1539                                (elpher-make-gopher-address ?1
1540                                                            "/projects/elpher/"
1541                                                            "thelambdalab.xyz"
1542                                                            70))
1543    (insert "\n"
1544            "** Refer to the ")
1545    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1546      (insert-text-button "Elpher info manual"
1547                          'face 'link
1548                          'action (lambda (_)
1549                                    (interactive)
1550                                    (info "(elpher)"))
1551                          'follow-link t
1552                          'help-echo help-string))
1553    (insert " for the full documentation. **\n")
1554    (insert (propertize
1555             (concat "  (This should be available if you have installed Elpher using\n"
1556                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1557             'face 'shadow))
1558    (elpher-restore-pos)))
1559
1560 ;; Bookmarks page page retrieval
1561
1562 (defun elpher-get-bookmarks-page (renderer)
1563   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1564   (when renderer
1565     (elpher-visit-previous-page)
1566     (error "Command not supported for bookmarks page"))
1567   (elpher-with-clean-buffer
1568    (insert "---- Bookmark list ----\n\n")
1569    (let ((bookmarks (elpher-load-bookmarks)))
1570      (if bookmarks
1571          (dolist (bookmark bookmarks)
1572            (let ((display-string (elpher-bookmark-display-string bookmark))
1573                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1574              (elpher-insert-index-record display-string address)))
1575        (insert "No bookmarks found.\n")))
1576    (insert "\n-----------------------\n"
1577            "\n"
1578            "- u: return to previous page\n"
1579            "- x: delete selected bookmark\n"
1580            "- a: rename selected bookmark\n"
1581            "\n"
1582            "Bookmarks are stored in the file ")
1583    (let ((filename elpher-bookmarks-file)
1584          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1585      (insert-text-button filename
1586                          'face 'link
1587                          'action (lambda (_)
1588                                    (interactive)
1589                                    (find-file filename))
1590                          'follow-link t
1591                          'help-echo help-string))
1592    (insert "\n")
1593    (elpher-restore-pos)))
1594
1595
1596 ;;; Bookmarks
1597 ;;
1598
1599 (defun elpher-make-bookmark (display-string url)
1600   "Make an elpher bookmark.
1601 DISPLAY-STRING determines how the bookmark will appear in the
1602 bookmark list, while URL is the url of the entry."
1603   (list display-string url))
1604
1605 (defun elpher-bookmark-display-string (bookmark)
1606   "Get the display string of BOOKMARK."
1607   (elt bookmark 0))
1608
1609 (defun elpher-set-bookmark-display-string (bookmark display-string)
1610   "Set the display string of BOOKMARK to DISPLAY-STRING."
1611   (setcar bookmark display-string))
1612
1613 (defun elpher-bookmark-url (bookmark)
1614   "Get the address for BOOKMARK."
1615   (elt bookmark 1))
1616
1617 (defun elpher-save-bookmarks (bookmarks)
1618   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1619 Beware that this completely replaces the existing contents of the file."
1620   (with-temp-file elpher-bookmarks-file
1621     (erase-buffer)
1622     (insert "; Elpher bookmarks file\n\n"
1623             "; Bookmarks are stored as a list of (label URL) items.\n"
1624             "; Feel free to edit by hand, but take care to ensure\n"
1625             "; the list structure remains intact.\n\n")
1626     (pp bookmarks (current-buffer))))
1627
1628 (defun elpher-load-bookmarks ()
1629   "Get the list of bookmarks from the users's bookmark file."
1630   (let ((bookmarks
1631          (with-temp-buffer
1632            (ignore-errors
1633              (insert-file-contents elpher-bookmarks-file)
1634              (goto-char (point-min))
1635              (read (current-buffer))))))
1636     (if (and bookmarks (listp (cadar bookmarks)))
1637         (progn
1638           (message "Reading old bookmark file. (Will be updated on write.)")
1639           (mapcar (lambda (old-bm)
1640                     (list (car old-bm)
1641                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1642                                                         (cadr old-bm)))))
1643                   bookmarks))
1644       bookmarks)))
1645
1646 (defun elpher-add-address-bookmark (address display-string)
1647   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1648 If ADDRESS is already bookmarked, update the label only."
1649   (let ((bookmarks (elpher-load-bookmarks))
1650         (url (elpher-address-to-url address)))
1651     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1652       (if existing-bookmark
1653           (elpher-set-bookmark-display-string existing-bookmark display-string)
1654         (push (elpher-make-bookmark display-string url) bookmarks)))
1655     (elpher-save-bookmarks bookmarks)))
1656
1657 (defun elpher-remove-address-bookmark (address)
1658   "Remove any bookmark to ADDRESS."
1659   (let ((url (elpher-address-to-url address)))
1660     (elpher-save-bookmarks
1661      (seq-filter (lambda (bookmark)
1662                    (not (equal (elpher-bookmark-url bookmark) url)))
1663                  (elpher-load-bookmarks)))))
1664
1665 ;;; Interactive procedures
1666 ;;
1667
1668 (defun elpher-next-link ()
1669   "Move point to the next link on the current page."
1670   (interactive)
1671   (forward-button 1))
1672
1673 (defun elpher-prev-link ()
1674   "Move point to the previous link on the current page."
1675   (interactive)
1676   (backward-button 1))
1677
1678 (defun elpher-follow-current-link ()
1679   "Open the link or url at point."
1680   (interactive)
1681   (push-button))
1682
1683 (defun elpher-go (host-or-url)
1684   "Go to a particular gopher site HOST-OR-URL.
1685 When run interactively HOST-OR-URL is read from the minibuffer."
1686   (interactive "sGopher or Gemini URL: ")
1687   (let* ((cleaned-host-or-url (string-trim host-or-url))
1688          (address (elpher-address-from-url cleaned-host-or-url))
1689          (page (elpher-make-page cleaned-host-or-url address)))
1690     (switch-to-buffer elpher-buffer-name)
1691     (elpher-visit-page page)
1692     nil))
1693
1694 (defun elpher-go-current ()
1695   "Go to a particular site read from the minibuffer, initialized with the current URL."
1696   (interactive)
1697   (let ((address (elpher-page-address elpher-current-page)))
1698     (if (elpher-address-special-p address)
1699         (error "Command invalid for this page")
1700       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1701         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1702
1703 (defun elpher-redraw ()
1704   "Redraw current page."
1705   (interactive)
1706   (elpher-visit-page elpher-current-page))
1707
1708 (defun elpher-reload ()
1709   "Reload current page."
1710   (interactive)
1711   (elpher-reload-current-page))
1712
1713 (defun elpher-toggle-tls ()
1714   "Toggle TLS encryption mode for gopher."
1715   (interactive)
1716   (setq elpher-use-tls (not elpher-use-tls))
1717   (if elpher-use-tls
1718       (if (gnutls-available-p)
1719           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1720         (setq elpher-use-tls nil)
1721         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1722     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1723
1724 (defun elpher-view-raw ()
1725   "View raw server response for current page."
1726   (interactive)
1727   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1728       (error "This page was not generated by a server")
1729     (elpher-visit-page elpher-current-page
1730                        #'elpher-render-raw)))
1731
1732 (defun elpher-back ()
1733   "Go to previous site."
1734   (interactive)
1735   (elpher-visit-previous-page))
1736
1737 (defun elpher-back-to-start ()
1738   "Go all the way back to the start page."
1739   (interactive)
1740   (setq elpher-current-page nil)
1741   (setq elpher-history nil)
1742   (let ((start-page (elpher-make-page "Elpher Start Page"
1743                                       (elpher-make-special-address 'start))))
1744     (elpher-visit-page start-page)))
1745
1746 (defun elpher-download ()
1747   "Download the link at point."
1748   (interactive)
1749   (let ((button (button-at (point))))
1750     (if button
1751         (let ((page (button-get button 'elpher-page)))
1752           (if (elpher-address-special-p (elpher-page-address page))
1753               (error "Cannot download %s"
1754                      (elpher-page-display-string page))
1755             (elpher-visit-page (button-get button 'elpher-page)
1756                                #'elpher-render-download)))
1757       (error "No link selected"))))
1758
1759 (defun elpher-download-current ()
1760   "Download the current page."
1761   (interactive)
1762   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1763       (error "Cannot download %s"
1764              (elpher-page-display-string elpher-current-page))
1765     (elpher-visit-page (elpher-make-page
1766                         (elpher-page-display-string elpher-current-page)
1767                         (elpher-page-address elpher-current-page))
1768                        #'elpher-render-download
1769                        t)))
1770
1771 (defun elpher-build-link-map ()
1772   "Build alist mapping link names to destination pages in current buffer."
1773   (let ((link-map nil)
1774         (b (next-button (point-min) t)))
1775     (while b
1776       (push (cons (button-label b) b) link-map)
1777       (setq b (next-button (button-start b))))
1778     link-map))
1779
1780 (defun elpher-jump ()
1781   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1782   (interactive)
1783   (let* ((link-map (elpher-build-link-map)))
1784     (if link-map
1785         (let ((key (let ((completion-ignore-case t))
1786                      (completing-read "Directory item/link: "
1787                                       link-map nil t))))
1788           (if (and key (> (length key) 0))
1789               (let ((b (cdr (assoc key link-map))))
1790                 (goto-char (button-start b))
1791                 (button-activate b)))))))
1792
1793 (defun elpher-root-dir ()
1794   "Visit root of current server."
1795   (interactive)
1796   (let ((address (elpher-page-address elpher-current-page)))
1797     (if (not (elpher-address-special-p address))
1798         (if (or (member (url-filename address) '("/" ""))
1799                 (and (elpher-address-gopher-p address)
1800                      (= (length (elpher-gopher-address-selector address)) 0)))
1801             (error "Already at root directory of current server")
1802           (let ((address-copy (elpher-address-from-url
1803                                (elpher-address-to-url address))))
1804             (setf (url-filename address-copy) "")
1805             (elpher-go (elpher-address-to-url address-copy))))
1806       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1807
1808 (defun elpher-bookmarks-current-p ()
1809   "Return non-nil if current page is a bookmarks page."
1810   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1811          '(special bookmarks)))
1812
1813 (defun elpher-reload-bookmarks ()
1814   "Reload bookmarks if current page is a bookmarks page."
1815   (if (elpher-bookmarks-current-p)
1816       (elpher-reload-current-page)))
1817
1818 (defun elpher-bookmark-current ()
1819   "Bookmark the current page."
1820   (interactive)
1821   (let ((address (elpher-page-address elpher-current-page))
1822         (display-string (elpher-page-display-string elpher-current-page)))
1823     (if (not (elpher-address-special-p address))
1824         (let ((bookmark-display-string (read-string "Bookmark display string: "
1825                                                     display-string)))
1826           (elpher-add-address-bookmark address bookmark-display-string)
1827           (message "Bookmark added."))
1828       (error "Cannot bookmark %s" display-string))))
1829
1830 (defun elpher-bookmark-link ()
1831   "Bookmark the link at point."
1832   (interactive)
1833   (let ((button (button-at (point))))
1834     (if button
1835         (let* ((page (button-get button 'elpher-page))
1836                (address (elpher-page-address page))
1837                (display-string (elpher-page-display-string page)))
1838           (if (not (elpher-address-special-p address))
1839               (let ((bookmark-display-string (read-string "Bookmark display string: "
1840                                                           display-string)))
1841                 (elpher-add-address-bookmark address bookmark-display-string)
1842                 (elpher-reload-bookmarks)
1843                 (message "Bookmark added."))
1844             (error "Cannot bookmark %s" display-string)))
1845       (error "No link selected"))))
1846
1847 (defun elpher-unbookmark-current ()
1848   "Remove bookmark for the current page."
1849   (interactive)
1850   (let ((address (elpher-page-address elpher-current-page)))
1851     (when (and (not (elpher-address-special-p address))
1852                (y-or-n-p "Really remove bookmark for the current page? "))
1853       (elpher-remove-address-bookmark address)
1854       (message "Bookmark removed."))))
1855
1856 (defun elpher-unbookmark-link ()
1857   "Remove bookmark for the link at point."
1858   (interactive)
1859   (let ((button (button-at (point))))
1860     (if button
1861         (when (y-or-n-p "Really remove bookmark for this link? ")
1862           (let ((page (button-get button 'elpher-page)))
1863             (elpher-remove-address-bookmark (elpher-page-address page))
1864             (elpher-reload-bookmarks)
1865             (message "Bookmark removed.")))
1866       (error "No link selected"))))
1867
1868 (defun elpher-bookmarks ()
1869   "Visit bookmarks page."
1870   (interactive)
1871   (switch-to-buffer elpher-buffer-name)
1872   (elpher-visit-page
1873    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1874
1875 (defun elpher-info-page (page)
1876   "Display information on PAGE."
1877   (let ((display-string (elpher-page-display-string page))
1878         (address (elpher-page-address page)))
1879     (if (elpher-address-special-p address)
1880         (message "Special page: %s" display-string)
1881       (message "%s" (elpher-address-to-url address)))))
1882
1883 (defun elpher-info-link ()
1884   "Display information on page corresponding to link at point."
1885   (interactive)
1886   (let ((button (button-at (point))))
1887     (if button
1888         (elpher-info-page (button-get button 'elpher-page))
1889       (error "No item selected"))))
1890
1891 (defun elpher-info-current ()
1892   "Display information on current page."
1893   (interactive)
1894   (elpher-info-page elpher-current-page))
1895
1896 (defun elpher-copy-page-url (page)
1897   "Copy URL representation of address of PAGE to `kill-ring'."
1898   (let ((address (elpher-page-address page)))
1899     (if (elpher-address-special-p address)
1900         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1901       (let ((url (elpher-address-to-url address)))
1902         (message "Copied \"%s\" to kill-ring/clipboard." url)
1903         (kill-new url)))))
1904
1905 (defun elpher-copy-link-url ()
1906   "Copy URL of item at point to `kill-ring'."
1907   (interactive)
1908   (let ((button (button-at (point))))
1909     (if button
1910         (elpher-copy-page-url (button-get button 'elpher-page))
1911       (error "No item selected"))))
1912
1913 (defun elpher-copy-current-url ()
1914   "Copy URL of current page to `kill-ring'."
1915   (interactive)
1916   (elpher-copy-page-url elpher-current-page))
1917
1918 (defun elpher-set-gopher-coding-system ()
1919   "Specify an explicit character coding system for gopher selectors."
1920   (interactive)
1921   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1922     (setq elpher-user-coding-system system)
1923     (if system
1924         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1925       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1926
1927
1928 ;;; Mode and keymap
1929 ;;
1930
1931 (defvar elpher-mode-map
1932   (let ((map (make-sparse-keymap)))
1933     (define-key map (kbd "TAB") 'elpher-next-link)
1934     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1935     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1936     (define-key map (kbd "u") 'elpher-back)
1937     (define-key map (kbd "U") 'elpher-back-to-start)
1938     (define-key map [mouse-3] 'elpher-back)
1939     (define-key map (kbd "O") 'elpher-root-dir)
1940     (define-key map (kbd "g") 'elpher-go)
1941     (define-key map (kbd "o") 'elpher-go-current)
1942     (define-key map (kbd "r") 'elpher-redraw)
1943     (define-key map (kbd "R") 'elpher-reload)
1944     (define-key map (kbd "T") 'elpher-toggle-tls)
1945     (define-key map (kbd ".") 'elpher-view-raw)
1946     (define-key map (kbd "d") 'elpher-download)
1947     (define-key map (kbd "D") 'elpher-download-current)
1948     (define-key map (kbd "m") 'elpher-jump)
1949     (define-key map (kbd "i") 'elpher-info-link)
1950     (define-key map (kbd "I") 'elpher-info-current)
1951     (define-key map (kbd "c") 'elpher-copy-link-url)
1952     (define-key map (kbd "C") 'elpher-copy-current-url)
1953     (define-key map (kbd "a") 'elpher-bookmark-link)
1954     (define-key map (kbd "A") 'elpher-bookmark-current)
1955     (define-key map (kbd "x") 'elpher-unbookmark-link)
1956     (define-key map (kbd "X") 'elpher-unbookmark-current)
1957     (define-key map (kbd "B") 'elpher-bookmarks)
1958     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1959     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1960     (when (fboundp 'evil-define-key*)
1961       (evil-define-key* 'motion map
1962         (kbd "TAB") 'elpher-next-link
1963         (kbd "C-") 'elpher-follow-current-link
1964         (kbd "C-t") 'elpher-back
1965         (kbd "u") 'elpher-back
1966         (kbd "U") 'elpher-back-to-start
1967         [mouse-3] 'elpher-back
1968         (kbd "g") 'elpher-go
1969         (kbd "o") 'elpher-go-current
1970         (kbd "r") 'elpher-redraw
1971         (kbd "R") 'elpher-reload
1972         (kbd "T") 'elpher-toggle-tls
1973         (kbd ".") 'elpher-view-raw
1974         (kbd "d") 'elpher-download
1975         (kbd "D") 'elpher-download-current
1976         (kbd "m") 'elpher-jump
1977         (kbd "i") 'elpher-info-link
1978         (kbd "I") 'elpher-info-current
1979         (kbd "c") 'elpher-copy-link-url
1980         (kbd "C") 'elpher-copy-current-url
1981         (kbd "a") 'elpher-bookmark-link
1982         (kbd "A") 'elpher-bookmark-current
1983         (kbd "x") 'elpher-unbookmark-link
1984         (kbd "X") 'elpher-unbookmark-current
1985         (kbd "B") 'elpher-bookmarks
1986         (kbd "S") 'elpher-set-gopher-coding-system
1987         (kbd "F") 'elpher-forget-current-certificate))
1988     map)
1989   "Keymap for gopher client.")
1990
1991 (define-derived-mode elpher-mode special-mode "elpher"
1992   "Major mode for elpher, an elisp gopher client.
1993
1994 This mode is automatically enabled by the interactive
1995 functions which initialize the gopher client, namely
1996 `elpher', `elpher-go' and `elpher-bookmarks'."
1997   (setq-local elpher-current-page nil)
1998   (setq-local elpher-history nil)
1999   (setq-local elpher-buffer-name (buffer-name)))
2000
2001 (when (fboundp 'evil-set-initial-state)
2002   (evil-set-initial-state 'elpher-mode 'motion))
2003
2004
2005 ;;; Main start procedure
2006 ;;
2007
2008 ;;;###autoload
2009 (defun elpher (&optional arg)
2010   "Start elpher with default landing page.
2011 The buffer used for Elpher sessions is determined by the value of
2012 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2013 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2014 will begin.  A numeric prefix arg (as in ‘C-u 42 M-x elpher RET’)
2015 switches to the session with that number, creating it if necessary.  A
2016 nonnumeric prefix arg means to create a new session.  Returns the
2017 buffer selected (or created)."
2018   (interactive "P")
2019   (let* ((name (default-value 'elpher-buffer-name))
2020          (buf (cond ((numberp arg)
2021                      (get-buffer-create (format "%s<%d>" name arg)))
2022                     (arg
2023                      (generate-new-buffer name))
2024                     (t
2025                      (get-buffer-create name)))))
2026     (pop-to-buffer-same-window buf)
2027     (unless (buffer-modified-p)
2028       (let ((elpher-buffer-name (buffer-name)); for elpher-with-clean-buffer
2029             (start-page (elpher-make-page "Elpher Start Page"
2030                                           (elpher-make-special-address 'start))))
2031         (elpher-visit-page start-page))
2032       "Started Elpher."))) ; Otherwise (elpher) evaluates to start page string.
2033
2034 ;;; elpher.el ends here