elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.10.0
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "2.10.0"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  99     ((special start) elpher-get-start-page nil))
 100   "Association list from types to getters, renderers, margin codes and index faces.")
 101
 102
 103 ;;; Customization group
 104 ;;
 105
 106 (defgroup elpher nil
 107   "A gopher and gemini client."
 108   :group 'applications)
 109
 110 ;; General appearance and customizations
 111
 112 (defcustom elpher-open-urls-with-eww nil
 113   "If non-nil, open URL selectors using eww.
 114 Otherwise, use the system browser via the BROWSE-URL function."
 115   :type '(boolean))
 116
 117 (defcustom elpher-use-header t
 118   "If non-nil, display current page information in buffer header."
 119   :type '(boolean))
 120
 121 (defcustom elpher-auto-disengage-TLS nil
 122   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 123 While enabling this may seem convenient, it is also potentially dangerous as it
 124 allows switching from an encrypted channel back to plain text without user input."
 125   :type '(boolean))
 126
 127 (defcustom elpher-connection-timeout 5
 128   "Specifies the number of seconds to wait for a network connection to time out."
 129   :type '(integer))
 130
 131 (defcustom elpher-filter-ansi-from-text nil
 132   "If non-nil, filter ANSI escape sequences from text.
 133 The default behaviour is to use the ansi-color package to interpret these
 134 sequences."
 135   :type '(boolean))
 136
 137 (defcustom elpher-certificate-directory
 138   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 139   "Specify the name of the directory where client certificates will be stored.
 140 These certificates may be used for establishing authenticated TLS connections."
 141   :type '(directory))
 142
 143 (defcustom elpher-openssl-command "openssl"
 144   "The command used to launch openssl when generating TLS client certificates."
 145   :type '(file))
 146
 147 (defcustom elpher-gemini-TLS-cert-checks nil
 148   "If non-nil, verify gemini server TLS certs using the default security level.
 149 Otherwise, certificate verification is disabled.
 150
 151 This defaults to off because it is standard practice for Gemini servers
 152 to use self-signed certificates, meaning that most servers provide what
 153 EMACS considers to be an invalid certificate."
 154   :type '(boolean))
 155
 156 (defcustom elpher-gemini-max-fill-width 80
 157   "Specify the maximum default width (in columns) of text/gemini documents.
 158 The actual width used is the minimum of this value and the window width at
 159 the time when the text is rendered."
 160   :type '(integer))
 161
 162 (defcustom elpher-gemini-link-string "→ "
 163   "Specify the string used to indicate links when rendering gemini maps.
 164 May be empty."
 165   :type '(string))
 166
 167 (defcustom elpher-gemini-bullet-string "•"
 168   "Specify the string used for bullets when rendering gemini maps."
 169   :type '(string))
 170
 171 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 172   "Specify the name of the file where elpher bookmarks will be saved."
 173   :type '(file))
 174
 175 (defcustom elpher-ipv4-always nil
 176   "If non-nil, elpher will always use IPv4 to establish network connections.
 177 This can be useful when browsing from a computer that supports IPv6, because
 178 some servers which do not support IPv6 can take a long time to time-out."
 179   :type '(boolean))
 180
 181 ;; Face customizations
 182
 183 (defgroup elpher-faces nil
 184   "Elpher face customizations."
 185   :group 'elpher)
 186
 187 (defface elpher-index
 188   '((t :inherit font-lock-keyword-face))
 189   "Face used for directory type directory records.")
 190
 191 (defface elpher-text
 192   '((t :inherit bold))
 193   "Face used for text type directory records.")
 194
 195 (defface elpher-info
 196   '((t :inherit default))
 197   "Face used for info type directory records.")
 198
 199 (defface elpher-image
 200   '((t :inherit font-lock-string-face))
 201   "Face used for image type directory records.")
 202
 203 (defface elpher-search
 204   '((t :inherit warning))
 205   "Face used for search type directory records.")
 206
 207 (defface elpher-html
 208   '((t :inherit font-lock-comment-face))
 209   "Face used for html type directory records.")
 210
 211 (defface elpher-gemini
 212   '((t :inherit font-lock-constant-face))
 213   "Face used for Gemini type directory records.")
 214
 215 (defface elpher-other-url
 216   '((t :inherit font-lock-comment-face))
 217   "Face used for other URL type links records.")
 218
 219 (defface elpher-telnet
 220   '((t :inherit font-lock-function-name-face))
 221   "Face used for telnet type directory records.")
 222
 223 (defface elpher-binary
 224   '((t :inherit font-lock-doc-face))
 225   "Face used for binary type directory records.")
 226
 227 (defface elpher-unknown
 228   '((t :inherit error))
 229   "Face used for directory records with unknown/unsupported types.")
 230
 231 (defface elpher-margin-key
 232   '((t :inherit bold))
 233   "Face used for directory margin key.")
 234
 235 (defface elpher-margin-brackets
 236   '((t :inherit shadow))
 237   "Face used for brackets around directory margin key.")
 238
 239 (defface elpher-gemini-heading1
 240   '((t :inherit bold :height 1.8))
 241   "Face used for gemini heading level 1.")
 242
 243 (defface elpher-gemini-heading2
 244   '((t :inherit bold :height 1.5))
 245   "Face used for gemini heading level 2.")
 246
 247 (defface elpher-gemini-heading3
 248   '((t :inherit bold :height 1.2))
 249   "Face used for gemini heading level 3.")
 250
 251 (defface elpher-gemini-preformatted
 252   '((t :inherit fixed-pitch))
 253   "Face used for pre-formatted gemini text blocks.")
 254
 255 ;;; Model
 256 ;;
 257
 258 ;; Address
 259
 260 ;; An elpher "address" object is either a url object or a symbol.
 261 ;; Symbol addresses are "special", corresponding to pages generated
 262 ;; dynamically for and by elpher.  All others represent pages which
 263 ;; rely on content retrieved over the network.
 264
 265 (defun elpher-address-from-url (url-string)
 266   "Create a ADDRESS object corresponding to the given URL-STRING."
 267   (let ((data (match-data))) ; Prevent parsing clobbering match data
 268     (unwind-protect
 269         (let ((url (url-generic-parse-url url-string)))
 270           (unless (and (not (url-fullness url)) (url-type url))
 271             (setf (url-fullness url) t)
 272             (setf (url-filename url)
 273                   (url-unhex-string (url-filename url)))
 274             (unless (url-type url)
 275               (setf (url-type url) "gopher"))
 276             (when (or (equal "gopher" (url-type url))
 277                       (equal "gophers" (url-type url)))
 278               ;; Gopher defaults
 279               (unless (url-host url)
 280                 (setf (url-host url) (url-filename url))
 281                 (setf (url-filename url) ""))
 282               (when (or (equal (url-filename url) "")
 283                         (equal (url-filename url) "/"))
 284                 (setf (url-filename url) "/1")))
 285             (when (equal "gemini" (url-type url))
 286               ;; Gemini defaults
 287               (if (equal (url-filename url) "")
 288                   (setf (url-filename url) "/"))))
 289           (elpher-remove-redundant-ports url))
 290       (set-match-data data))))
 291
 292 (defun elpher-remove-redundant-ports (address)
 293   "Remove redundant port specifiers from ADDRESS.
 294 Here 'redundant' means that the specified port matches the default
 295 for that protocol, eg 70 for gopher."
 296   (if (and (not (elpher-address-special-p address))
 297            (eq (url-portspec address) ; (url-port) is too slow!
 298                (pcase (url-type address)
 299                  ("gemini" 1965)
 300                  ((or "gopher" "gophers") 70)
 301                  ("finger" 79)
 302                  (_ -1))))
 303       (setf (url-portspec address) nil))
 304   address)
 305
 306 (defun elpher-make-gopher-address (type selector host port &optional tls)
 307   "Create an ADDRESS object using gopher directory record attributes.
 308 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 309 If the optional attribute TLS is non-nil, the address will be marked as
 310 requiring gopher-over-TLS."
 311   (cond
 312    ((equal type ?i) nil)
 313    ((and (equal type ?h)
 314          (string-prefix-p "URL:" selector))
 315     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 316    ((equal type ?8)
 317     (elpher-address-from-url
 318      (concat "telnet"
 319              "://" host
 320              ":" (number-to-string port))))
 321    (t
 322     (elpher-address-from-url
 323      (concat "gopher" (if tls "s" "")
 324              "://" host
 325              ":" (number-to-string port)
 326              "/" (string type)
 327              selector)))))
 328
 329 (defun elpher-make-special-address (type)
 330   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 331   type)
 332
 333 (defun elpher-address-to-url (address)
 334   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 335   (if (elpher-address-special-p address)
 336       nil
 337     (url-encode-url (url-recreate-url address))))
 338
 339 (defun elpher-address-type (address)
 340   "Retrieve type of ADDRESS object.
 341 This is used to determine how to retrieve and render the document the
 342 address refers to, via the table `elpher-type-map'."
 343   (if (symbolp address)
 344       (list 'special address)
 345     (let ((protocol (url-type address)))
 346       (cond ((or (equal protocol "gopher")
 347                  (equal protocol "gophers"))
 348              (list 'gopher
 349                    (if (member (url-filename address) '("" "/"))
 350                        ?1
 351                      (string-to-char (substring (url-filename address) 1)))))
 352             ((equal protocol "gemini")
 353              'gemini)
 354             ((equal protocol "telnet")
 355              'telnet)
 356             ((equal protocol "finger")
 357              'finger)
 358             (t 'other-url)))))
 359
 360 (defun elpher-address-protocol (address)
 361   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 362   (if (symbolp address)
 363       nil
 364     (url-type address)))
 365
 366 (defun elpher-address-filename (address)
 367   "Retrieve the filename component of ADDRESS.
 368 For gopher addresses this is a combination of the selector type and selector."
 369   (if (symbolp address)
 370       nil
 371     (url-filename address)))
 372
 373 (defun elpher-address-host (address)
 374   "Retrieve host from ADDRESS object."
 375   (url-host address))
 376
 377 (defun elpher-address-user (address)
 378   "Retrieve user from ADDRESS object."
 379   (url-user address))
 380
 381 (defun elpher-address-port (address)
 382   "Retrieve port from ADDRESS object.
 383 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 384   (if (symbolp address)
 385       0
 386     (url-port address)))
 387
 388 (defun elpher-address-special-p (address)
 389   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 390   (symbolp address))
 391
 392 (defun elpher-address-gopher-p (address)
 393   "Return non-nill if ADDRESS object is a gopher address."
 394   (and (not (elpher-address-special-p address))
 395        (member (elpher-address-protocol address) '("gopher gophers"))))
 396
 397 (defun elpher-gopher-address-selector (address)
 398   "Retrieve gopher selector from ADDRESS object."
 399   (if (member (url-filename address) '("" "/"))
 400       ""
 401     (url-unhex-string (substring (url-filename address) 2))))
 402
 403
 404 ;; Cache
 405
 406 (defvar elpher-content-cache (make-hash-table :test 'equal))
 407 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 408
 409 (defun elpher-get-cached-content (address)
 410   "Retrieve the cached content for ADDRESS, or nil if none exists."
 411   (gethash address elpher-content-cache))
 412
 413 (defun elpher-cache-content (address content)
 414   "Set the content cache for ADDRESS to CONTENT."
 415   (puthash address content elpher-content-cache))
 416
 417 (defun elpher-get-cached-pos (address)
 418   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 419   (gethash address elpher-pos-cache))
 420
 421 (defun elpher-cache-pos (address pos)
 422   "Set the cursor position cache for ADDRESS to POS."
 423   (puthash address pos elpher-pos-cache))
 424
 425
 426 ;; Page
 427
 428 (defun elpher-make-page (display-string address)
 429   "Create a page with DISPLAY-STRING and ADDRESS."
 430   (list display-string address))
 431
 432 (defun elpher-page-display-string (page)
 433   "Retrieve the display string corresponding to PAGE."
 434   (elt page 0))
 435
 436 (defun elpher-page-address (page)
 437   "Retrieve the address corresponding to PAGE."
 438   (elt page 1))
 439
 440 (defun elpher-page-set-address (page new-address)
 441   "Set the address corresponding to PAGE to NEW-ADDRESS."
 442   (setcar (cdr page) new-address))
 443
 444 (defvar elpher-current-page nil)
 445 (defvar elpher-history nil)
 446
 447 (defun elpher-visit-page (page &optional renderer no-history)
 448   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 449 Additionally, push PAGE onto the stack of previously-visited pages,
 450 unless NO-HISTORY is non-nil."
 451   (elpher-save-pos)
 452   (elpher-process-cleanup)
 453   (unless (or no-history
 454               (equal (elpher-page-address elpher-current-page)
 455                      (elpher-page-address page)))
 456     (push elpher-current-page elpher-history))
 457   (setq elpher-current-page page)
 458   (let* ((address (elpher-page-address page))
 459          (type (elpher-address-type address))
 460          (type-record (cdr (assoc type elpher-type-map))))
 461     (if type-record
 462         (funcall (car type-record)
 463                  (if renderer
 464                      renderer
 465                    (cadr type-record)))
 466       (elpher-visit-previous-page)
 467       (pcase type
 468         (`(gopher ,type-char)
 469          (error "Unsupported gopher selector type '%c' for '%s'"
 470                 type-char (elpher-address-to-url address)))
 471         (other
 472          (error "Unsupported address type '%S' for '%s'"
 473                 other (elpher-address-to-url address)))))))
 474
 475 (defun elpher-visit-previous-page ()
 476   "Visit the previous page in the history."
 477   (let ((previous-page (pop elpher-history)))
 478     (if previous-page
 479         (elpher-visit-page previous-page nil t)
 480       (error "No previous page"))))
 481
 482 (defun elpher-reload-current-page ()
 483   "Reload the current page, discarding any existing cached content."
 484   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 485   (elpher-visit-page elpher-current-page))
 486
 487 (defun elpher-save-pos ()
 488   "Save the current position of point to the current page."
 489   (when elpher-current-page
 490     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 491
 492 (defun elpher-restore-pos ()
 493   "Restore the position of point to that cached in the current page."
 494   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 495     (if pos
 496         (goto-char pos)
 497       (goto-char (point-min)))))
 498
 499
 500 ;;; Buffer preparation
 501 ;;
 502
 503 (defun elpher-update-header ()
 504   "If `elpher-use-header' is true, display current page info in window header."
 505   (if elpher-use-header
 506       (let* ((display-string (elpher-page-display-string elpher-current-page))
 507              (address (elpher-page-address elpher-current-page))
 508              (tls-string (if (and (not (elpher-address-special-p address))
 509                                   (member (elpher-address-protocol address)
 510                                           '("gophers" "gemini")))
 511                              " [TLS encryption]"
 512                            ""))
 513              (header (concat display-string
 514                              (propertize tls-string 'face 'bold))))
 515         (setq header-line-format header))))
 516
 517 (defmacro elpher-with-clean-buffer (&rest args)
 518   "Evaluate ARGS with a clean *elpher* buffer as current."
 519   (list 'with-current-buffer "*elpher*"
 520         '(elpher-mode)
 521         (append (list 'let '((inhibit-read-only t))
 522                       '(setq-local network-security-level
 523                                    (default-value 'network-security-level))
 524                       '(erase-buffer)
 525                       '(elpher-update-header))
 526                 args)))
 527
 528 (defun elpher-buffer-message (string &optional line)
 529   "Replace first line in elpher buffer with STRING.
 530 If LINE is non-nil, replace that line instead."
 531   (with-current-buffer "*elpher*"
 532     (let ((inhibit-read-only t))
 533       (goto-char (point-min))
 534       (if line
 535           (forward-line line))
 536       (let ((data (match-data)))
 537         (unwind-protect
 538             (progn
 539               (re-search-forward "^.*$")
 540               (replace-match string))
 541           (set-match-data data))))))
 542
 543
 544 ;;; Text Processing
 545 ;;
 546
 547 (defvar elpher-user-coding-system nil
 548   "User-specified coding system to use for decoding text responses.")
 549
 550 (defun elpher-decode (string)
 551   "Decode STRING using autodetected or user-specified coding system."
 552   (decode-coding-string string
 553                         (if elpher-user-coding-system
 554                             elpher-user-coding-system
 555                           (detect-coding-string string t))))
 556
 557 (defun elpher-preprocess-text-response (string)
 558   "Preprocess text selector response contained in STRING.
 559 This involes decoding the character representation, and clearing
 560 away CRs and any terminating period."
 561   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 562                                            (replace-regexp-in-string "\r" "" string))))
 563
 564
 565 ;;; Network error reporting
 566 ;;
 567
 568 (defun elpher-network-error (address error)
 569   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 570 ERROR can be either an error object or a string."
 571   (elpher-with-clean-buffer
 572    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 573            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 574            (if (stringp error) error (error-message-string error)) "\n"
 575            (propertize "\n----------------\n\n" 'face 'error)
 576            "Press 'u' to return to the previous page.")))
 577
 578
 579 ;;; General network communication
 580 ;;
 581
 582 (defvar elpher-network-timer nil
 583   "Timer used for network connections.")
 584
 585 (defvar elpher-use-tls nil
 586   "If non-nil, use TLS to communicate with gopher servers.")
 587
 588 (defvar elpher-client-certificate nil
 589   "If non-nil, contains client certificate details to use for TLS connections.")
 590
 591 (defun elpher-process-cleanup ()
 592   "Immediately shut down any extant elpher process and timers."
 593   (let ((p (get-process "elpher-process")))
 594     (if p (delete-process p)))
 595   (if (timerp elpher-network-timer)
 596       (cancel-timer elpher-network-timer)))
 597
 598 (defun elpher-get-host-response (address default-port query-string response-processor
 599                                          &optional use-tls force-ipv4)
 600   "Generic function for retrieving data from ADDRESS.
 601
 602 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 603 QUERY-STRING is a string sent to the host specified by ADDRESS to
 604 illicet a response.  This response is passed as an argument to the
 605 function RESPONSE-PROCESSOR.
 606
 607 If non-nil, USE-TLS specifies that the connection is to be made over
 608 TLS.  If set to gemini, the certificate verification will be disabled
 609 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 610
 611 If non-nil, FORCE-IPV4 causes the network connection to be made over
 612 ipv4 only.  (The default behaviour when this is not set depends on
 613 the host operating system and the local network capabilities."
 614   (if (and use-tls (not (gnutls-available-p)))
 615       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 616     (unless (< (elpher-address-port address) 65536)
 617       (error "Cannot establish network connection: port number > 65536"))
 618     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 619       (setq-local network-security-level 'low))
 620     (condition-case nil
 621         (let* ((kill-buffer-query-functions nil)
 622                (port (elpher-address-port address))
 623                (host (elpher-address-host address))
 624                (response-string-parts nil)
 625                (bytes-received 0)
 626                (hkbytes-received 0)
 627                (proc (make-network-process :name "elpher-process"
 628                                            :host host
 629                                            :family (and force-ipv4 'ipv4)
 630                                            :service (if (> port 0) port default-port)
 631                                            :buffer nil
 632                                            :coding 'binary
 633                                            :noquery t
 634                                            :nowait t
 635                                            :tls-parameters
 636                                            (and use-tls
 637                                                 (cons 'gnutls-x509pki
 638                                                       (gnutls-boot-parameters
 639                                                        :type 'gnutls-x509pki
 640                                                        :hostname host
 641                                                        :keylist
 642                                                        (elpher-get-current-keylist address))))))
 643                (timer (run-at-time elpher-connection-timeout nil
 644                                    (lambda ()
 645                                      (elpher-process-cleanup)
 646                                      (cond
 647                                         ; Try again with IPv4
 648                                       ((not force-ipv4)
 649                                        (message "Connection timed out.  Retrying with IPv4.")
 650                                        (elpher-get-host-response address default-port
 651                                                                  query-string
 652                                                                  response-processor
 653                                                                  use-tls t))
 654                                       ((and use-tls
 655                                             (not (eq use-tls 'gemini))
 656                                             (or elpher-auto-disengage-TLS
 657                                                 (y-or-n-p
 658                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 659                                        (setq elpher-use-tls nil)
 660                                        (elpher-get-host-response address default-port
 661                                                                  query-string
 662                                                                  response-processor
 663                                                                  nil force-ipv4))
 664                                       (t
 665                                        (elpher-network-error address "Connection time-out.")))))))
 666           (setq elpher-network-timer timer)
 667           (elpher-buffer-message (concat "Connecting to " host "..."
 668                                          " (press 'u' to abort)"))
 669           (set-process-filter proc
 670                               (lambda (_proc string)
 671                                 (when timer
 672                                   (cancel-timer timer)
 673                                   (setq timer nil))
 674                                 (setq bytes-received (+ bytes-received (length string)))
 675                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 676                                   (when (> new-hkbytes-received hkbytes-received)
 677                                     (setq hkbytes-received new-hkbytes-received)
 678                                     (elpher-buffer-message
 679                                         (concat "("
 680                                                 (number-to-string (/ hkbytes-received 10.0))
 681                                                 " MB read)")
 682                                         1)))
 683                                 (setq response-string-parts
 684                                       (cons string response-string-parts))))
 685           (set-process-sentinel proc
 686                                 (lambda (proc event)
 687                                   (when timer
 688                                     (cancel-timer timer))
 689                                   (condition-case the-error
 690                                       (cond
 691                                        ((string-prefix-p "open" event)    ; request URL
 692                                         (elpher-buffer-message
 693                                          (concat "Connected to " host ". Receiving data..."
 694                                                  " (press 'u' to abort)"))
 695                                         (let ((inhibit-eol-conversion t))
 696                                           (process-send-string proc query-string)))
 697                                        ((string-prefix-p "deleted" event)) ; do nothing
 698                                        ((and (not response-string-parts)
 699                                              (not (or elpher-ipv4-always force-ipv4)))
 700                                         ; Try again with IPv4
 701                                         (message "Connection failed. Retrying with IPv4.")
 702                                         (elpher-get-host-response address default-port
 703                                                                   query-string
 704                                                                   response-processor
 705                                                                   use-tls t))
 706                                        (response-string-parts
 707                                         (elpher-with-clean-buffer
 708                                          (insert "Data received.  Rendering..."))
 709                                         (funcall response-processor
 710                                                  (apply #'concat (reverse response-string-parts)))
 711                                         (elpher-restore-pos))
 712                                        (t
 713                                         (error "No response from server")))
 714                                     (error
 715                                      (elpher-network-error address the-error))))))
 716       (error
 717        (error "Error initiating connection to server")))))
 718
 719
 720 ;;; Client-side TLS Certificate Management
 721 ;;
 722
 723 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 724   "Generate a key and a self-signed client TLS certificate using openssl.
 725
 726 The Common Name field of the certificate is set to COMMON-NAME.  The
 727 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 728 the key and certificate files to write.
 729
 730 If TEMPORARY is non-nil, the certificate will be given an exporation
 731 period of one day, and the key and certificate files will be deleted
 732 when the certificate is no longer needed for the current session.
 733
 734 Otherwise, the certificate will be given a 100 year expiration period
 735 and the files will not be deleted.
 736
 737 The function returns a list containing the current host name, the
 738 temporary flag, and the key and cert file names in the form required
 739 by `gnutls-boot-parameters`."
 740   (let ((exp-key-file (expand-file-name key-file))
 741         (exp-cert-file (expand-file-name cert-file)))
 742     (condition-case nil
 743         (progn
 744           (call-process elpher-openssl-command nil nil nil
 745                         "req" "-x509" "-newkey" "rsa:2048"
 746                         "-days" (if temporary "1" "36500")
 747                         "-nodes"
 748                         "-subj" (concat "/CN=" common-name)
 749                         "-keyout" exp-key-file
 750                         "-out" exp-cert-file)
 751           (list (elpher-address-host (elpher-page-address elpher-current-page))
 752                 temporary exp-key-file exp-cert-file))
 753       (error
 754        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 755        (error "Program 'openssl', required for certificate generation, not found")))))
 756
 757 (defun elpher-generate-throwaway-certificate ()
 758   "Generate and return details of a throwaway certificate.
 759 The key and certificate files will be deleted when they are no
 760 longer needed for this session."
 761   (let* ((file-base (make-temp-name "elpher"))
 762          (key-file (concat temporary-file-directory file-base ".key"))
 763          (cert-file (concat temporary-file-directory file-base ".crt")))
 764     (elpher-generate-certificate file-base key-file cert-file t)))
 765
 766 (defun elpher-generate-persistent-certificate (file-base common-name)
 767   "Generate and return details of a persistent certificate.
 768 The argument FILE-BASE is used as the base for the key and certificate
 769 files, while COMMON-NAME specifies the common name field of the
 770 certificate.
 771
 772 The key and certificate files are written to in `elpher-certificate-directory'."
 773   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 774          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 775     (elpher-generate-certificate common-name key-file cert-file)))
 776
 777 (defun elpher-get-existing-certificate (file-base)
 778   "Return a certificate object corresponding to an existing certificate.
 779 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 780 the directory `elpher-certificate-directory'."
 781   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 782          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 783     (list (elpher-address-host (elpher-page-address elpher-current-page))
 784           nil
 785           (expand-file-name key-file)
 786           (expand-file-name cert-file))))
 787
 788 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 789   "Install a key+certificate file pair in `elpher-certificate-directory'.
 790 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 791 certificate files to install.  The argument FILE-BASE is used as the
 792 base for the installed key and certificate files."
 793   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 794          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 795     (if (or (file-exists-p key-file)
 796             (file-exists-p cert-file))
 797         (error "A certificate with base name %s is already installed" file-base))
 798     (copy-file key-file-src key-file)
 799     (copy-file cert-file-src cert-file)
 800     (list (elpher-address-host (elpher-page-address elpher-current-page))
 801           nil
 802           (expand-file-name key-file)
 803           (expand-file-name cert-file))))
 804
 805 (defun elpher-list-existing-certificates ()
 806   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 807   (mapcar
 808    (lambda (file)
 809      (file-name-sans-extension file))
 810    (directory-files elpher-certificate-directory nil "\.key$")))
 811
 812 (defun elpher-forget-current-certificate ()
 813   "Causes any current certificate to be forgotten.)
 814 In the case of throwaway certificates, the key and certificate files
 815 are also deleted."
 816   (interactive)
 817   (when elpher-client-certificate
 818     (unless (and (called-interactively-p 'any)
 819                  (not (y-or-n-p (concat "Really forget client certificate? "
 820                                         "(Throwaway certificates will be deleted.)"))))
 821       (when (cadr elpher-client-certificate)
 822         (delete-file (elt elpher-client-certificate 2))
 823         (delete-file (elt elpher-client-certificate 3)))
 824       (setq elpher-client-certificate nil)
 825       (if (called-interactively-p 'any)
 826           (message "Client certificate forgotten.")))))
 827
 828 (defun elpher-get-current-keylist (address)
 829   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 830
 831 This is obtained from the client certificate described by
 832 `elpher-current-certificate', if one is available and the host for
 833 that certificate matches the host in ADDRESS.
 834
 835 If `elpher-current-certificate' is non-nil, and its host name doesn't
 836 match that of ADDRESS, the certificate is forgotten."
 837   (if elpher-client-certificate
 838       (if (string= (car elpher-client-certificate)
 839                    (elpher-address-host address))
 840           (list (cddr elpher-client-certificate))
 841         (elpher-forget-current-certificate)
 842         (message "Disabling client certificate for new host")
 843         nil)
 844     nil))
 845
 846
 847 ;;; Gopher selector retrieval
 848 ;;
 849
 850 (defun elpher-get-gopher-response (address renderer)
 851   "Get response string from gopher server at ADDRESS and render using RENDERER."
 852   (elpher-get-host-response address 70
 853                             (concat (elpher-gopher-address-selector address) "\r\n")
 854                             renderer
 855                             (or (string= (elpher-address-protocol address) "gophers")
 856                                 elpher-use-tls)))
 857
 858 (defun elpher-get-gopher-page (renderer)
 859   "Getter function for gopher pages.
 860 The RENDERER procedure is used to display the contents of the page
 861 once they are retrieved from the gopher server."
 862   (let* ((address (elpher-page-address elpher-current-page))
 863          (content (elpher-get-cached-content address)))
 864     (if (and content (funcall renderer nil))
 865         (elpher-with-clean-buffer
 866          (insert content)
 867          (elpher-restore-pos))
 868       (elpher-with-clean-buffer
 869        (insert "LOADING... (use 'u' to cancel)\n"))
 870       (condition-case the-error
 871           (elpher-get-gopher-response address renderer)
 872         (error
 873          (elpher-network-error address the-error))))))
 874
 875 ;; Index rendering
 876
 877 (defun elpher-insert-index (string)
 878   "Insert the index corresponding to STRING into the current buffer."
 879   ;; Should be able to split directly on CRLF, but some non-conformant
 880   ;; LF-only servers sadly exist, hence the following.
 881   (let ((str-processed (elpher-preprocess-text-response string)))
 882     (dolist (line (split-string str-processed "\n"))
 883       (ignore-errors
 884         (unless (= (length line) 0)
 885           (let* ((type (elt line 0))
 886                  (fields (split-string (substring line 1) "\t"))
 887                  (display-string (elt fields 0))
 888                  (selector (elt fields 1))
 889                  (host (elt fields 2))
 890                  (port (if (elt fields 3)
 891                            (string-to-number (elt fields 3))
 892                          nil))
 893                  (address (elpher-make-gopher-address type selector host port)))
 894             (elpher-insert-index-record display-string address)))))))
 895
 896 (defun elpher-insert-margin (&optional type-name)
 897   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 898   (if type-name
 899       (progn
 900         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 901                         (concat
 902                          (propertize "[" 'face 'elpher-margin-brackets)
 903                          (propertize type-name 'face 'elpher-margin-key)
 904                          (propertize "]" 'face 'elpher-margin-brackets))))
 905         (insert " "))
 906     (insert (make-string elpher-margin-width ?\s))))
 907
 908 (defun elpher--page-button-help (_window buffer pos)
 909   "Function called by Emacs to generate mouse-over text.
 910 The arguments specify the BUFFER and the POS within the buffer of the item
 911 for which help is required.  The function returns the help to be
 912 displayed.  The _WINDOW argument is currently unused."
 913   (with-current-buffer buffer
 914     (let ((button (button-at pos)))
 915       (when button
 916         (let* ((page (button-get button 'elpher-page))
 917                (address (elpher-page-address page)))
 918           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 919                                                 address
 920                                               (elpher-address-to-url address))))))))
 921
 922 (defun elpher-insert-index-record (display-string &optional address)
 923   "Function to insert an index record into the current buffer.
 924 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 925 If ADDRESS is not supplied or nil the record is rendered as an
 926 'information' line."
 927   (let* ((type (if address (elpher-address-type address) nil))
 928          (type-map-entry (cdr (assoc type elpher-type-map))))
 929     (if type-map-entry
 930         (let* ((margin-code (elt type-map-entry 2))
 931                (face (elt type-map-entry 3))
 932                (filtered-display-string (ansi-color-filter-apply display-string))
 933                (page (elpher-make-page filtered-display-string address)))
 934           (elpher-insert-margin margin-code)
 935           (insert-text-button filtered-display-string
 936                               'face face
 937                               'elpher-page page
 938                               'action #'elpher-click-link
 939                               'follow-link t
 940                               'help-echo #'elpher--page-button-help))
 941       (pcase type
 942         ('nil ;; Information
 943          (elpher-insert-margin)
 944          (let ((propertized-display-string
 945                 (propertize display-string 'face 'elpher-info)))
 946            (insert (elpher-process-text-for-display propertized-display-string))))
 947         (`(gopher ,selector-type) ;; Unknown
 948          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 949          (insert (propertize display-string
 950                              'face 'elpher-unknown)))))
 951     (insert "\n")))
 952
 953 (defun elpher-click-link (button)
 954   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 955   (let ((page (button-get button 'elpher-page)))
 956     (elpher-visit-page page)))
 957
 958 (defun elpher-render-index (data &optional _mime-type-string)
 959   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 960   (elpher-with-clean-buffer
 961    (if (not data)
 962        t
 963      (elpher-insert-index data)
 964      (elpher-cache-content (elpher-page-address elpher-current-page)
 965                            (buffer-string)))))
 966
 967 ;; Text rendering
 968
 969 (defconst elpher-url-regex
 970   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 971   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 972
 973 (defun elpher-buttonify-urls (string)
 974   "Turn substrings which look like urls in STRING into clickable buttons."
 975   (with-temp-buffer
 976     (insert string)
 977     (goto-char (point-min))
 978     (while (re-search-forward elpher-url-regex nil t)
 979       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 980                                     (elpher-address-from-url (match-string 0)))))
 981           (make-text-button (match-beginning 0)
 982                             (match-end 0)
 983                             'elpher-page  page
 984                             'action #'elpher-click-link
 985                             'follow-link t
 986                             'help-echo #'elpher--page-button-help
 987                             'face 'button)))
 988     (buffer-string)))
 989
 990 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 991   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 992
 993 (defun elpher-process-text-for-display (string)
 994   "Perform any desired processing of STRING prior to display as text.
 995 Currently includes buttonifying URLs and processing ANSI escape codes."
 996   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 997                              (ansi-color-filter-apply string)
 998                            (ansi-color-apply string))))
 999
1000 (defun elpher-render-text (data &optional _mime-type-string)
1001   "Render DATA as text.  MIME-TYPE-STRING is unused."
1002   (elpher-with-clean-buffer
1003    (if (not data)
1004        t
1005      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1006      (elpher-cache-content
1007       (elpher-page-address elpher-current-page)
1008       (buffer-string)))))
1009
1010 ;; Image retrieval
1011
1012 (defun elpher-render-image (data &optional _mime-type-string)
1013   "Display DATA as image.  MIME-TYPE-STRING is unused."
1014   (if (not data)
1015       nil
1016     (if (display-images-p)
1017         (progn
1018           (let ((image (create-image
1019                         data
1020                         nil t)))
1021             (elpher-with-clean-buffer
1022              (insert-image image)
1023              (elpher-restore-pos))))
1024       (elpher-render-download data))))
1025
1026 ;; Search retrieval and rendering
1027
1028 (defun elpher-get-gopher-query-page (renderer)
1029   "Getter for gopher addresses requiring input.
1030 The response is rendered using the rendering function RENDERER."
1031    (let* ((address (elpher-page-address elpher-current-page))
1032           (content (elpher-get-cached-content address))
1033           (aborted t))
1034     (if (and content (funcall renderer nil))
1035         (elpher-with-clean-buffer
1036          (insert content)
1037          (elpher-restore-pos)
1038          (message "Displaying cached search results.  Reload to perform a new search."))
1039       (unwind-protect
1040           (let* ((query-string (read-string "Query: "))
1041                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1042                  (search-address (elpher-make-gopher-address ?1
1043                                                              query-selector
1044                                                              (elpher-address-host address)
1045                                                              (elpher-address-port address)
1046                                                              (equal (elpher-address-type address) "gophers"))))
1047             (setq aborted nil)
1048
1049             (elpher-with-clean-buffer
1050              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1051             (elpher-get-gopher-response search-address renderer))
1052         (if aborted
1053             (elpher-visit-previous-page))))))
1054
1055 ;; Raw server response rendering
1056
1057 (defun elpher-render-raw (data &optional mime-type-string)
1058   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1059   (if (not data)
1060       nil
1061     (elpher-with-clean-buffer
1062      (when mime-type-string
1063        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1064      (insert data)
1065      (goto-char (point-min)))
1066     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1067
1068 ;; File save "rendering"
1069
1070 (defun elpher-render-download (data &optional _mime-type-string)
1071   "Save DATA to file.  MIME-TYPE-STRING is unused."
1072   (if (not data)
1073       nil
1074     (let* ((address (elpher-page-address elpher-current-page))
1075            (selector (if (elpher-address-gopher-p address)
1076                          (elpher-gopher-address-selector address)
1077                        (elpher-address-filename address))))
1078       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1079       (let* ((filename-proposal (file-name-nondirectory selector))
1080              (filename (read-file-name "Download complete. Save file as: "
1081                                        nil nil nil
1082                                        (if (> (length filename-proposal) 0)
1083                                            filename-proposal
1084                                          "download.file"))))
1085         (let ((coding-system-for-write 'binary))
1086           (with-temp-file filename
1087             (insert data)))
1088         (message (format "Saved to file %s." filename))))))
1089
1090 ;; HTML rendering
1091
1092 (defun elpher-render-html (data &optional _mime-type-string)
1093   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1094   (elpher-with-clean-buffer
1095    (if (not data)
1096        t
1097      (let ((dom (with-temp-buffer
1098                   (insert data)
1099                   (libxml-parse-html-region (point-min) (point-max)))))
1100        (shr-insert-document dom)))))
1101
1102 ;; Gemini page retrieval
1103
1104 (defvar elpher-gemini-redirect-chain)
1105
1106 (defun elpher-get-gemini-response (address renderer)
1107   "Get response string from gemini server at ADDRESS and render using RENDERER."
1108   (elpher-get-host-response address 1965
1109                             (concat (elpher-address-to-url address) "\r\n")
1110                             (lambda (response-string)
1111                               (elpher-process-gemini-response response-string renderer))
1112                             'gemini))
1113
1114 (defun elpher-parse-gemini-response (response)
1115   "Parse the RESPONSE string and return a list of components.
1116 The list is of the form (code meta body).  A response of nil implies
1117 that the response was malformed."
1118   (let ((header-end-idx (string-match "\r\n" response)))
1119     (if header-end-idx
1120         (let ((header (string-trim (substring response 0 header-end-idx)))
1121               (body (substring response (+ header-end-idx 2))))
1122           (if (>= (length header) 2)
1123               (let ((code (substring header 0 2))
1124                     (meta (string-trim (substring header 2))))
1125                 (list code meta body))
1126             (error "Malformed response: No response status found in header %s" header)))
1127       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1128
1129 (defun elpher-process-gemini-response (response-string renderer)
1130   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1131   (let ((response-components (elpher-parse-gemini-response response-string)))
1132     (let ((response-code (elt response-components 0))
1133           (response-meta (elt response-components 1))
1134           (response-body (elt response-components 2)))
1135       (pcase (elt response-code 0)
1136         (?1 ; Input required
1137          (elpher-with-clean-buffer
1138           (insert "Gemini server is requesting input."))
1139          (let* ((query-string
1140                  (if (eq (elt response-code 1) ?1)
1141                      (read-passwd (concat response-meta ": "))
1142                    (read-string (concat response-meta ": "))))
1143                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1144                 (old-fname (url-filename query-address)))
1145            (setf (url-filename query-address)
1146                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1147            (elpher-get-gemini-response query-address renderer)))
1148         (?2 ; Normal response
1149          (funcall renderer response-body response-meta))
1150         (?3 ; Redirect
1151          (message "Following redirect to %s" response-meta)
1152          (if (>= (length elpher-gemini-redirect-chain) 5)
1153              (error "More than 5 consecutive redirects followed"))
1154          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1155            (if (member redirect-address elpher-gemini-redirect-chain)
1156                (error "Redirect loop detected"))
1157            (if (not (string= (elpher-address-protocol redirect-address)
1158                              "gemini"))
1159                (error "Server tried to automatically redirect to non-gemini URL: %s"
1160                       response-meta))
1161            (elpher-page-set-address elpher-current-page redirect-address)
1162            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1163            (elpher-get-gemini-response redirect-address renderer)))
1164         (?4 ; Temporary failure
1165          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1166                 response-code response-meta))
1167         (?5 ; Permanent failure
1168          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1169                 response-code response-meta))
1170         (?6 ; Client certificate required
1171          (elpher-with-clean-buffer
1172           (if elpher-client-certificate
1173               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1174             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1175           (auto-fill-mode 1)
1176           (elpher-gemini-insert-text response-meta))
1177          (let ((chosen-certificate (elpher-choose-client-certificate)))
1178            (unless chosen-certificate
1179              (error "Gemini server requires a client certificate and none was provided"))
1180            (setq elpher-client-certificate chosen-certificate))
1181          (elpher-with-clean-buffer)
1182          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1183         (_other
1184          (error "Gemini server response unknown: %s %s"
1185                 response-code response-meta))))))
1186
1187 (defun elpher-choose-client-certificate ()
1188   "Prompt for a client certificate to use to establish a TLS connection."
1189   (let* ((read-answer-short t))
1190     (pcase (read-answer "What do you want to do? "
1191                         '(("throwaway" ?t
1192                            "generate and use throw-away certificate")
1193                           ("persistent" ?p
1194                            "generate new or use existing persistent certificate")
1195                           ("abort" ?a
1196                            "stop immediately")))
1197       ("throwaway"
1198        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1199       ("persistent"
1200        (let* ((existing-certificates (elpher-list-existing-certificates))
1201               (file-base (completing-read
1202                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1203                           existing-certificates)))
1204          (if (string-empty-p (string-trim file-base))
1205              nil
1206            (if (member file-base existing-certificates)
1207                (setq elpher-client-certificate
1208                      (elpher-get-existing-certificate file-base))
1209              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1210                                  '(("new" ?n
1211                                     "generate new certificate")
1212                                    ("install" ?i
1213                                     "install existing certificate")
1214                                    ("abort" ?a
1215                                     "stop immediately")))
1216                ("new"
1217                 (let ((common-name (read-string "Common Name field for new certificate: "
1218                                                 file-base)))
1219                   (message "New key and self-signed certificate written to %s"
1220                            elpher-certificate-directory)
1221                   (elpher-generate-persistent-certificate file-base common-name)))
1222                ("install"
1223                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1224                        (key-file (read-file-name "Key file: " nil nil t)))
1225                   (message "Key and certificate installed in %s for future use"
1226                            elpher-certificate-directory)
1227                   (elpher-install-and-use-existing-certificate key-file
1228                                                                cert-file
1229                                                                file-base)))
1230                ("abort" nil))))))
1231       ("abort" nil))))
1232
1233 (defun elpher-get-gemini-page (renderer)
1234   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1235   (let* ((address (elpher-page-address elpher-current-page))
1236          (content (elpher-get-cached-content address)))
1237     (condition-case the-error
1238         (if (and content (funcall renderer nil))
1239             (elpher-with-clean-buffer
1240               (insert content)
1241               (elpher-restore-pos))
1242           (elpher-with-clean-buffer
1243            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1244           (setq elpher-gemini-redirect-chain nil)
1245           (elpher-get-gemini-response address renderer))
1246       (error
1247        (elpher-network-error address the-error)))))
1248
1249 (defun elpher-render-gemini (body &optional mime-type-string)
1250   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1251   (if (not body)
1252       t
1253     (let* ((mime-type-string* (if (or (not mime-type-string)
1254                                       (string-empty-p mime-type-string))
1255                                   "text/gemini; charset=utf-8"
1256                                 mime-type-string))
1257            (mime-type-split (split-string mime-type-string* ";" t))
1258            (mime-type (string-trim (car mime-type-split)))
1259            (parameters (mapcar (lambda (s)
1260                                  (let ((key-val (split-string s "=")))
1261                                    (list (downcase (string-trim (car key-val)))
1262                                          (downcase (string-trim (cadr key-val))))))
1263                                (cdr mime-type-split))))
1264       (when (string-prefix-p "text/" mime-type)
1265         (setq body (decode-coding-string
1266                     body
1267                     (if (assoc "charset" parameters)
1268                         (intern (cadr (assoc "charset" parameters)))
1269                       'utf-8)))
1270         (setq body (replace-regexp-in-string "\r" "" body)))
1271       (pcase mime-type
1272         ((or "text/gemini" "")
1273          (elpher-render-gemini-map body parameters))
1274         ("text/html"
1275          (elpher-render-html body))
1276         ((pred (string-prefix-p "text/"))
1277          (elpher-render-gemini-plain-text body parameters))
1278         ((pred (string-prefix-p "image/"))
1279          (elpher-render-image body))
1280         (_other
1281          (elpher-render-download body))))))
1282
1283 (defun elpher-gemini-get-link-url (link-line)
1284   "Extract the url portion of LINK-LINE, a gemini map file link line.
1285 Returns nil in the event that the contents of the line following the
1286 => prefix are empty."
1287   (let ((l (split-string (substring link-line 2))))
1288     (if l
1289         (string-trim (elt l 0))
1290       nil)))
1291
1292 (defun elpher-gemini-get-link-display-string (link-line)
1293   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1294 Returns the url portion in the event that the display-string portion is empty."
1295   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1296          (idx (string-match "[ \t]" rest)))
1297     (string-trim (if idx
1298                      (substring rest (+ idx 1))
1299                    rest))))
1300
1301 (defun elpher-collapse-dot-sequences (filename)
1302   "Collapse dot sequences in FILENAME.
1303 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1304   (let* ((path (split-string filename "/"))
1305          (path-reversed-normalized
1306           (seq-reduce (lambda (a b)
1307                         (cond ((and a (equal b "..") (cdr a)))
1308                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1309                               ((equal b ".") a)
1310                               (t (cons b a))))
1311                       path nil)))
1312     (string-join (reverse path-reversed-normalized) "/")))
1313
1314 (defun elpher-address-from-gemini-url (url)
1315   "Extract address from URL with defaults as per gemini map files.
1316 While there's obviously some redundancy here between this function and
1317 `elpher-address-from-url', gemini map file URLs require enough special
1318 treatment that a separate function is warranted."
1319   (let ((address (url-generic-parse-url url))
1320         (current-address (elpher-page-address elpher-current-page)))
1321     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1322       (setf (url-fullness address) t)
1323       (if (url-host address) ;if there is an explicit host, filenames are absolute
1324           (if (string-empty-p (url-filename address))
1325               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1326         (setf (url-host address) (url-host current-address))
1327         (setf (url-port address) (url-port current-address))
1328         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1329           (setf (url-filename address)
1330                 (concat (file-name-directory (url-filename current-address))
1331                         (url-filename address)))))
1332       (unless (url-type address)
1333         (setf (url-type address) "gemini"))
1334       (when (equal (url-type address) "gemini")
1335         (setf (url-filename address)
1336               (elpher-collapse-dot-sequences (url-filename address)))))
1337     (elpher-remove-redundant-ports address)))
1338
1339 (defun elpher-gemini-insert-link (link-line)
1340   "Insert link described by LINK-LINE into a text/gemini document."
1341   (let* ((url (elpher-gemini-get-link-url link-line))
1342          (display-string (elpher-gemini-get-link-display-string link-line))
1343          (address (elpher-address-from-gemini-url url))
1344          (type (if address (elpher-address-type address) nil))
1345          (type-map-entry (cdr (assoc type elpher-type-map))))
1346     (when display-string
1347       (insert elpher-gemini-link-string)
1348       (if type-map-entry
1349           (let* ((face (elt type-map-entry 3))
1350                  (filtered-display-string (ansi-color-filter-apply display-string))
1351                  (page (elpher-make-page filtered-display-string address)))
1352             (insert-text-button filtered-display-string
1353                                 'face face
1354                                 'elpher-page page
1355                                 'action #'elpher-click-link
1356                                 'follow-link t
1357                                 'help-echo #'elpher--page-button-help))
1358         (insert (propertize display-string 'face 'elpher-unknown)))
1359       (insert "\n"))))
1360
1361 (defun elpher-gemini-insert-header (header-line)
1362   "Insert header described by HEADER-LINE into a text/gemini document.
1363 The gemini map file line describing the header is given
1364 by HEADER-LINE."
1365   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1366     (let ((level (length (match-string 1 header-line)))
1367           (header (substring header-line (match-end 0))))
1368       (unless (display-graphic-p)
1369         (insert (make-string level ?#) " "))
1370       (insert (propertize header 'face
1371                           (pcase level
1372                             (1 'elpher-gemini-heading1)
1373                             (2 'elpher-gemini-heading2)
1374                             (3 'elpher-gemini-heading3)
1375                             (_ 'default)))
1376               "\n"))))
1377
1378 (defun elpher-gemini-insert-text (text-line)
1379   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1380 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1381 width defined by elpher-gemini-max-fill-width."
1382   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1383   (let* ((processed-text-line (if (match-string 2 text-line)
1384                                   (concat
1385                                    (replace-regexp-in-string "\*"
1386                                                              elpher-gemini-bullet-string
1387                                                              (match-string 0 text-line))
1388                                    (substring text-line (match-end 0)))
1389                                 text-line))
1390          (adaptive-fill-mode nil)
1391          (fill-prefix (if (match-string 2 text-line)
1392                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1393                         nil)))
1394     (insert (elpher-process-text-for-display processed-text-line))
1395     (newline)))
1396
1397 (defun elpher-render-gemini-map (data _parameters)
1398   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1399   (elpher-with-clean-buffer
1400    (let ((preformatted nil))
1401      (auto-fill-mode 1)
1402      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1403      (dolist (line (split-string data "\n"))
1404        (cond
1405         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1406         (preformatted (insert (elpher-process-text-for-display
1407                                (propertize line 'face 'elpher-gemini-preformatted))
1408                               "\n"))
1409         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1410         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1411         (t (elpher-gemini-insert-text line)))))
1412    (elpher-cache-content
1413     (elpher-page-address elpher-current-page)
1414     (buffer-string))))
1415
1416 (defun elpher-render-gemini-plain-text (data _parameters)
1417   "Render DATA as plain text file.  PARAMETERS is currently unused."
1418   (elpher-with-clean-buffer
1419    (insert (elpher-process-text-for-display data))
1420    (elpher-cache-content
1421     (elpher-page-address elpher-current-page)
1422     (buffer-string))))
1423
1424
1425 ;; Finger page connection
1426
1427 (defun elpher-get-finger-page (renderer)
1428   "Opens a finger connection to the current page address.
1429 The result is rendered using RENDERER."
1430   (let* ((address (elpher-page-address elpher-current-page))
1431          (content (elpher-get-cached-content address)))
1432     (if (and content (funcall renderer nil))
1433         (elpher-with-clean-buffer
1434          (insert content)
1435          (elpher-restore-pos))
1436       (elpher-with-clean-buffer
1437        (insert "LOADING... (use 'u' to cancel)\n"))
1438       (condition-case the-error
1439           (let* ((kill-buffer-query-functions nil)
1440                  (user (let ((filename (elpher-address-filename address)))
1441                          (if (> (length filename) 1)
1442                              (substring filename 1)
1443                            (elpher-address-user address)))))
1444             (elpher-get-host-response address 79
1445                                       (concat user "\r\n")
1446                                       renderer))
1447         (error
1448          (elpher-network-error address the-error))))))
1449
1450
1451 ;; Telnet page connection
1452
1453 (defun elpher-get-telnet-page (renderer)
1454   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1455   (when renderer
1456     (elpher-visit-previous-page)
1457     (error "Command not supported for telnet URLs"))
1458   (let* ((address (elpher-page-address elpher-current-page))
1459          (host (elpher-address-host address))
1460          (port (elpher-address-port address)))
1461     (elpher-visit-previous-page)
1462     (if (> port 0)
1463         (telnet host port)
1464       (telnet host))))
1465
1466
1467 ;; Other URL page opening
1468
1469 (defun elpher-get-other-url-page (renderer)
1470   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1471   (when renderer
1472     (elpher-visit-previous-page)
1473     (error "Command not supported for general URLs"))
1474   (let* ((address (elpher-page-address elpher-current-page))
1475          (url (elpher-address-to-url address)))
1476     (progn
1477       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1478       (message "Opening URL...")
1479       (if elpher-open-urls-with-eww
1480           (browse-web url)
1481         (browse-url url)))))
1482
1483
1484 ;; Start page page retrieval
1485
1486 (defun elpher-get-start-page (renderer)
1487   "Getter which displays the start page (RENDERER must be nil)."
1488   (when renderer
1489     (elpher-visit-previous-page)
1490     (error "Command not supported for start page"))
1491   (elpher-with-clean-buffer
1492    (insert "     --------------------------------------------\n"
1493            "           Elpher Gopher and Gemini Client       \n"
1494            "                   version " elpher-version "\n"
1495            "     --------------------------------------------\n"
1496            "\n"
1497            "Default bindings:\n"
1498            "\n"
1499            " - TAB/Shift-TAB: next/prev item on current page\n"
1500            " - RET/mouse-1: open item under cursor\n"
1501            " - m: select an item on current page by name (autocompletes)\n"
1502            " - u/mouse-3/U: return to previous page or to the start page\n"
1503            " - o/O: visit different selector or the root menu of the current server\n"
1504            " - g: go to a particular address (gopher, gemini, finger)\n"
1505            " - d/D: download item under cursor or current page\n"
1506            " - i/I: info on item under cursor or current page\n"
1507            " - c/C: copy URL representation of item under cursor or current page\n"
1508            " - a/A: bookmark the item under cursor or current page\n"
1509            " - x/X: remove bookmark for item under cursor or current page\n"
1510            " - B: visit the bookmarks page\n"
1511            " - r: redraw current page (using cached contents if available)\n"
1512            " - R: reload current page (regenerates cache)\n"
1513            " - S: set character coding system for gopher (default is to autodetect)\n"
1514            " - T: toggle TLS gopher mode\n"
1515            " - F: forget/discard current TLS client certificate\n"
1516            " - .: display the raw server response for the current page\n"
1517            "\n"
1518            "Start your exploration of gopher space and gemini:\n")
1519    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1520                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1521    (elpher-insert-index-record "Project Gemini home page"
1522                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1523    (insert "\n"
1524            "Alternatively, select a search engine and enter some search terms:\n")
1525    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1526                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1527    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1528                                (elpher-address-from-url "gemini://gus.guru/search"))
1529    (insert "\n"
1530            "This page contains your bookmarked sites (also visit with B):\n")
1531    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1532    (insert "\n"
1533            "For Elpher release news or to leave feedback, visit:\n")
1534    (elpher-insert-index-record "The Elpher Project Page"
1535                                (elpher-make-gopher-address ?1
1536                                                            "/projects/elpher/"
1537                                                            "thelambdalab.xyz"
1538                                                            70))
1539    (insert "\n"
1540            "** Refer to the ")
1541    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1542      (insert-text-button "Elpher info manual"
1543                          'face 'link
1544                          'action (lambda (_)
1545                                    (interactive)
1546                                    (info "(elpher)"))
1547                          'follow-link t
1548                          'help-echo help-string))
1549    (insert " for the full documentation. **\n")
1550    (insert (propertize
1551             (concat "  (This should be available if you have installed Elpher using\n"
1552                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1553             'face 'shadow))
1554    (elpher-restore-pos)))
1555
1556 ;; Bookmarks page page retrieval
1557
1558 (defun elpher-get-bookmarks-page (renderer)
1559   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1560   (when renderer
1561     (elpher-visit-previous-page)
1562     (error "Command not supported for bookmarks page"))
1563   (elpher-with-clean-buffer
1564    (insert "---- Bookmark list ----\n\n")
1565    (let ((bookmarks (elpher-load-bookmarks)))
1566      (if bookmarks
1567          (dolist (bookmark bookmarks)
1568            (let ((display-string (elpher-bookmark-display-string bookmark))
1569                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1570              (elpher-insert-index-record display-string address)))
1571        (insert "No bookmarks found.\n")))
1572    (insert "\n-----------------------\n"
1573            "\n"
1574            "- u: return to previous page\n"
1575            "- x: delete selected bookmark\n"
1576            "- a: rename selected bookmark\n"
1577            "\n"
1578            "Bookmarks are stored in the file ")
1579    (let ((filename elpher-bookmarks-file)
1580          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1581      (insert-text-button filename
1582                          'face 'link
1583                          'action (lambda (_)
1584                                    (interactive)
1585                                    (find-file filename))
1586                          'follow-link t
1587                          'help-echo help-string))
1588    (insert "\n")
1589    (elpher-restore-pos)))
1590
1591
1592 ;;; Bookmarks
1593 ;;
1594
1595 (defun elpher-make-bookmark (display-string url)
1596   "Make an elpher bookmark.
1597 DISPLAY-STRING determines how the bookmark will appear in the
1598 bookmark list, while URL is the url of the entry."
1599   (list display-string url))
1600
1601 (defun elpher-bookmark-display-string (bookmark)
1602   "Get the display string of BOOKMARK."
1603   (elt bookmark 0))
1604
1605 (defun elpher-set-bookmark-display-string (bookmark display-string)
1606   "Set the display string of BOOKMARK to DISPLAY-STRING."
1607   (setcar bookmark display-string))
1608
1609 (defun elpher-bookmark-url (bookmark)
1610   "Get the address for BOOKMARK."
1611   (elt bookmark 1))
1612
1613 (defun elpher-save-bookmarks (bookmarks)
1614   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1615 Beware that this completely replaces the existing contents of the file."
1616   (with-temp-file elpher-bookmarks-file
1617     (erase-buffer)
1618     (insert "; Elpher bookmarks file\n\n"
1619             "; Bookmarks are stored as a list of (label URL) items.\n"
1620             "; Feel free to edit by hand, but take care to ensure\n"
1621             "; the list structure remains intact.\n\n")
1622     (pp bookmarks (current-buffer))))
1623
1624 (defun elpher-load-bookmarks ()
1625   "Get the list of bookmarks from the users's bookmark file."
1626   (let ((bookmarks
1627          (with-temp-buffer
1628            (ignore-errors
1629              (insert-file-contents elpher-bookmarks-file)
1630              (goto-char (point-min))
1631              (read (current-buffer))))))
1632     (if (and bookmarks (listp (cadar bookmarks)))
1633         (progn
1634           (message "Reading old bookmark file. (Will be updated on write.)")
1635           (mapcar (lambda (old-bm)
1636                     (list (car old-bm)
1637                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1638                                                         (cadr old-bm)))))
1639                   bookmarks))
1640       bookmarks)))
1641
1642 (defun elpher-add-address-bookmark (address display-string)
1643   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1644 If ADDRESS is already bookmarked, update the label only."
1645   (let ((bookmarks (elpher-load-bookmarks))
1646         (url (elpher-address-to-url address)))
1647     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1648       (if existing-bookmark
1649           (elpher-set-bookmark-display-string existing-bookmark display-string)
1650         (push (elpher-make-bookmark display-string url) bookmarks)))
1651     (elpher-save-bookmarks bookmarks)))
1652
1653 (defun elpher-remove-address-bookmark (address)
1654   "Remove any bookmark to ADDRESS."
1655   (let ((url (elpher-address-to-url address)))
1656     (elpher-save-bookmarks
1657      (seq-filter (lambda (bookmark)
1658                    (not (equal (elpher-bookmark-url bookmark) url)))
1659                  (elpher-load-bookmarks)))))
1660
1661 ;;; Interactive procedures
1662 ;;
1663
1664 (defun elpher-next-link ()
1665   "Move point to the next link on the current page."
1666   (interactive)
1667   (forward-button 1))
1668
1669 (defun elpher-prev-link ()
1670   "Move point to the previous link on the current page."
1671   (interactive)
1672   (backward-button 1))
1673
1674 (defun elpher-follow-current-link ()
1675   "Open the link or url at point."
1676   (interactive)
1677   (push-button))
1678
1679 (defun elpher-go (host-or-url)
1680   "Go to a particular gopher site HOST-OR-URL.
1681 When run interactively HOST-OR-URL is read from the minibuffer."
1682   (interactive "sGopher or Gemini URL: ")
1683   (let* ((cleaned-host-or-url (string-trim host-or-url))
1684          (address (elpher-address-from-url cleaned-host-or-url))
1685          (page (elpher-make-page cleaned-host-or-url address)))
1686     (switch-to-buffer "*elpher*")
1687     (elpher-visit-page page)
1688     nil))
1689
1690 (defun elpher-go-current ()
1691   "Go to a particular site read from the minibuffer, initialized with the current URL."
1692   (interactive)
1693   (let ((address (elpher-page-address elpher-current-page)))
1694     (if (elpher-address-special-p address)
1695         (error "Command invalid for this page")
1696       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1697         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1698
1699 (defun elpher-redraw ()
1700   "Redraw current page."
1701   (interactive)
1702   (elpher-visit-page elpher-current-page))
1703
1704 (defun elpher-reload ()
1705   "Reload current page."
1706   (interactive)
1707   (elpher-reload-current-page))
1708
1709 (defun elpher-toggle-tls ()
1710   "Toggle TLS encryption mode for gopher."
1711   (interactive)
1712   (setq elpher-use-tls (not elpher-use-tls))
1713   (if elpher-use-tls
1714       (if (gnutls-available-p)
1715           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1716         (setq elpher-use-tls nil)
1717         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1718     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1719
1720 (defun elpher-view-raw ()
1721   "View raw server response for current page."
1722   (interactive)
1723   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1724       (error "This page was not generated by a server")
1725     (elpher-visit-page elpher-current-page
1726                        #'elpher-render-raw)))
1727
1728 (defun elpher-back ()
1729   "Go to previous site."
1730   (interactive)
1731   (elpher-visit-previous-page))
1732
1733 (defun elpher-back-to-start ()
1734   "Go all the way back to the start page."
1735   (interactive)
1736   (setq elpher-current-page nil)
1737   (setq elpher-history nil)
1738   (let ((start-page (elpher-make-page "Elpher Start Page"
1739                                       (elpher-make-special-address 'start))))
1740     (elpher-visit-page start-page)))
1741
1742 (defun elpher-download ()
1743   "Download the link at point."
1744   (interactive)
1745   (let ((button (button-at (point))))
1746     (if button
1747         (let ((page (button-get button 'elpher-page)))
1748           (if (elpher-address-special-p (elpher-page-address page))
1749               (error "Cannot download %s"
1750                      (elpher-page-display-string page))
1751             (elpher-visit-page (button-get button 'elpher-page)
1752                                #'elpher-render-download)))
1753       (error "No link selected"))))
1754
1755 (defun elpher-download-current ()
1756   "Download the current page."
1757   (interactive)
1758   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1759       (error "Cannot download %s"
1760              (elpher-page-display-string elpher-current-page))
1761     (elpher-visit-page (elpher-make-page
1762                         (elpher-page-display-string elpher-current-page)
1763                         (elpher-page-address elpher-current-page))
1764                        #'elpher-render-download
1765                        t)))
1766
1767 (defun elpher-build-link-map ()
1768   "Build alist mapping link names to destination pages in current buffer."
1769   (let ((link-map nil)
1770         (b (next-button (point-min) t)))
1771     (while b
1772       (push (cons (button-label b) b) link-map)
1773       (setq b (next-button (button-start b))))
1774     link-map))
1775
1776 (defun elpher-jump ()
1777   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1778   (interactive)
1779   (let* ((link-map (elpher-build-link-map)))
1780     (if link-map
1781         (let ((key (let ((completion-ignore-case t))
1782                      (completing-read "Directory item/link: "
1783                                       link-map nil t))))
1784           (if (and key (> (length key) 0))
1785               (let ((b (cdr (assoc key link-map))))
1786                 (goto-char (button-start b))
1787                 (button-activate b)))))))
1788
1789 (defun elpher-root-dir ()
1790   "Visit root of current server."
1791   (interactive)
1792   (let ((address (elpher-page-address elpher-current-page)))
1793     (if (not (elpher-address-special-p address))
1794         (if (or (member (url-filename address) '("/" ""))
1795                 (and (elpher-address-gopher-p address)
1796                      (= (length (elpher-gopher-address-selector address)) 0)))
1797             (error "Already at root directory of current server")
1798           (let ((address-copy (elpher-address-from-url
1799                                (elpher-address-to-url address))))
1800             (setf (url-filename address-copy) "")
1801             (elpher-go (elpher-address-to-url address-copy))))
1802       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1803
1804 (defun elpher-bookmarks-current-p ()
1805   "Return non-nil if current page is a bookmarks page."
1806   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1807          '(special bookmarks)))
1808
1809 (defun elpher-reload-bookmarks ()
1810   "Reload bookmarks if current page is a bookmarks page."
1811   (if (elpher-bookmarks-current-p)
1812       (elpher-reload-current-page)))
1813
1814 (defun elpher-bookmark-current ()
1815   "Bookmark the current page."
1816   (interactive)
1817   (let ((address (elpher-page-address elpher-current-page))
1818         (display-string (elpher-page-display-string elpher-current-page)))
1819     (if (not (elpher-address-special-p address))
1820         (let ((bookmark-display-string (read-string "Bookmark display string: "
1821                                                     display-string)))
1822           (elpher-add-address-bookmark address bookmark-display-string)
1823           (message "Bookmark added."))
1824       (error "Cannot bookmark %s" display-string))))
1825
1826 (defun elpher-bookmark-link ()
1827   "Bookmark the link at point."
1828   (interactive)
1829   (let ((button (button-at (point))))
1830     (if button
1831         (let* ((page (button-get button 'elpher-page))
1832                (address (elpher-page-address page))
1833                (display-string (elpher-page-display-string page)))
1834           (if (not (elpher-address-special-p address))
1835               (let ((bookmark-display-string (read-string "Bookmark display string: "
1836                                                           display-string)))
1837                 (elpher-add-address-bookmark address bookmark-display-string)
1838                 (elpher-reload-bookmarks)
1839                 (message "Bookmark added."))
1840             (error "Cannot bookmark %s" display-string)))
1841       (error "No link selected"))))
1842
1843 (defun elpher-unbookmark-current ()
1844   "Remove bookmark for the current page."
1845   (interactive)
1846   (let ((address (elpher-page-address elpher-current-page)))
1847     (when (and (not (elpher-address-special-p address))
1848                (y-or-n-p "Really remove bookmark for the current page? "))
1849       (elpher-remove-address-bookmark address)
1850       (message "Bookmark removed."))))
1851
1852 (defun elpher-unbookmark-link ()
1853   "Remove bookmark for the link at point."
1854   (interactive)
1855   (let ((button (button-at (point))))
1856     (if button
1857         (when (y-or-n-p "Really remove bookmark for this link? ")
1858           (let ((page (button-get button 'elpher-page)))
1859             (elpher-remove-address-bookmark (elpher-page-address page))
1860             (elpher-reload-bookmarks)
1861             (message "Bookmark removed.")))
1862       (error "No link selected"))))
1863
1864 (defun elpher-bookmarks ()
1865   "Visit bookmarks page."
1866   (interactive)
1867   (switch-to-buffer "*elpher*")
1868   (elpher-visit-page
1869    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1870
1871 (defun elpher-info-page (page)
1872   "Display information on PAGE."
1873   (let ((display-string (elpher-page-display-string page))
1874         (address (elpher-page-address page)))
1875     (if (elpher-address-special-p address)
1876         (message "Special page: %s" display-string)
1877       (message "%s" (elpher-address-to-url address)))))
1878
1879 (defun elpher-info-link ()
1880   "Display information on page corresponding to link at point."
1881   (interactive)
1882   (let ((button (button-at (point))))
1883     (if button
1884         (elpher-info-page (button-get button 'elpher-page))
1885       (error "No item selected"))))
1886
1887 (defun elpher-info-current ()
1888   "Display information on current page."
1889   (interactive)
1890   (elpher-info-page elpher-current-page))
1891
1892 (defun elpher-copy-page-url (page)
1893   "Copy URL representation of address of PAGE to `kill-ring'."
1894   (let ((address (elpher-page-address page)))
1895     (if (elpher-address-special-p address)
1896         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1897       (let ((url (elpher-address-to-url address)))
1898         (message "Copied \"%s\" to kill-ring/clipboard." url)
1899         (kill-new url)))))
1900
1901 (defun elpher-copy-link-url ()
1902   "Copy URL of item at point to `kill-ring'."
1903   (interactive)
1904   (let ((button (button-at (point))))
1905     (if button
1906         (elpher-copy-page-url (button-get button 'elpher-page))
1907       (error "No item selected"))))
1908
1909 (defun elpher-copy-current-url ()
1910   "Copy URL of current page to `kill-ring'."
1911   (interactive)
1912   (elpher-copy-page-url elpher-current-page))
1913
1914 (defun elpher-set-gopher-coding-system ()
1915   "Specify an explicit character coding system for gopher selectors."
1916   (interactive)
1917   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1918     (setq elpher-user-coding-system system)
1919     (if system
1920         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1921       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1922
1923
1924 ;;; Mode and keymap
1925 ;;
1926
1927 (defvar elpher-mode-map
1928   (let ((map (make-sparse-keymap)))
1929     (define-key map (kbd "TAB") 'elpher-next-link)
1930     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1931     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1932     (define-key map (kbd "u") 'elpher-back)
1933     (define-key map (kbd "U") 'elpher-back-to-start)
1934     (define-key map [mouse-3] 'elpher-back)
1935     (define-key map (kbd "O") 'elpher-root-dir)
1936     (define-key map (kbd "g") 'elpher-go)
1937     (define-key map (kbd "o") 'elpher-go-current)
1938     (define-key map (kbd "r") 'elpher-redraw)
1939     (define-key map (kbd "R") 'elpher-reload)
1940     (define-key map (kbd "T") 'elpher-toggle-tls)
1941     (define-key map (kbd ".") 'elpher-view-raw)
1942     (define-key map (kbd "d") 'elpher-download)
1943     (define-key map (kbd "D") 'elpher-download-current)
1944     (define-key map (kbd "m") 'elpher-jump)
1945     (define-key map (kbd "i") 'elpher-info-link)
1946     (define-key map (kbd "I") 'elpher-info-current)
1947     (define-key map (kbd "c") 'elpher-copy-link-url)
1948     (define-key map (kbd "C") 'elpher-copy-current-url)
1949     (define-key map (kbd "a") 'elpher-bookmark-link)
1950     (define-key map (kbd "A") 'elpher-bookmark-current)
1951     (define-key map (kbd "x") 'elpher-unbookmark-link)
1952     (define-key map (kbd "X") 'elpher-unbookmark-current)
1953     (define-key map (kbd "B") 'elpher-bookmarks)
1954     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1955     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1956     (when (fboundp 'evil-define-key*)
1957       (evil-define-key* 'motion map
1958         (kbd "TAB") 'elpher-next-link
1959         (kbd "C-") 'elpher-follow-current-link
1960         (kbd "C-t") 'elpher-back
1961         (kbd "u") 'elpher-back
1962         (kbd "U") 'elpher-back-to-start
1963         [mouse-3] 'elpher-back
1964         (kbd "g") 'elpher-go
1965         (kbd "o") 'elpher-go-current
1966         (kbd "r") 'elpher-redraw
1967         (kbd "R") 'elpher-reload
1968         (kbd "T") 'elpher-toggle-tls
1969         (kbd ".") 'elpher-view-raw
1970         (kbd "d") 'elpher-download
1971         (kbd "D") 'elpher-download-current
1972         (kbd "m") 'elpher-jump
1973         (kbd "i") 'elpher-info-link
1974         (kbd "I") 'elpher-info-current
1975         (kbd "c") 'elpher-copy-link-url
1976         (kbd "C") 'elpher-copy-current-url
1977         (kbd "a") 'elpher-bookmark-link
1978         (kbd "A") 'elpher-bookmark-current
1979         (kbd "x") 'elpher-unbookmark-link
1980         (kbd "X") 'elpher-unbookmark-current
1981         (kbd "B") 'elpher-bookmarks
1982         (kbd "S") 'elpher-set-gopher-coding-system
1983         (kbd "F") 'elpher-forget-current-certificate))
1984     map)
1985   "Keymap for gopher client.")
1986
1987 (define-derived-mode elpher-mode special-mode "elpher"
1988   "Major mode for elpher, an elisp gopher client.
1989
1990 This mode is automatically enabled by the interactive
1991 functions which initialize the gopher client, namely
1992 `elpher', `elpher-go' and `elpher-bookmarks'.")
1993
1994 (when (fboundp 'evil-set-initial-state)
1995   (evil-set-initial-state 'elpher-mode 'motion))
1996
1997
1998 ;;; Main start procedure
1999 ;;
2000
2001 ;;;###autoload
2002 (defun elpher ()
2003   "Start elpher with default landing page."
2004   (interactive)
2005   (if (get-buffer "*elpher*")
2006       (switch-to-buffer "*elpher*")
2007     (switch-to-buffer "*elpher*")
2008     (setq elpher-current-page nil)
2009     (setq elpher-history nil)
2010     (let ((start-page (elpher-make-page "Elpher Start Page"
2011                                         (elpher-make-special-address 'start))))
2012       (elpher-visit-page start-page)))
2013   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
2014
2015 ;;; elpher.el ends here