elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.1.0
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.1.0"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((about history) elpher-get-history-page nil "E" elpher-index)
 116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen is \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 232
 233 Beware that using \"about:bookmarks\" as a start page in combination with
 234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 236 the start page."
 237   :type '(string))
 238
 239 ;; Face customizations
 240
 241 (defgroup elpher-faces nil
 242   "Elpher face customizations."
 243   :group 'elpher)
 244
 245 (defface elpher-index
 246   '((t :inherit font-lock-keyword-face))
 247   "Face used for directory type directory records.")
 248
 249 (defface elpher-text
 250   '((t :inherit bold))
 251   "Face used for text type directory records.")
 252
 253 (defface elpher-info
 254   '((t :inherit default))
 255   "Face used for info type directory records.")
 256
 257 (defface elpher-image
 258   '((t :inherit font-lock-string-face))
 259   "Face used for image type directory records.")
 260
 261 (defface elpher-search
 262   '((t :inherit warning))
 263   "Face used for search type directory records.")
 264
 265 (defface elpher-html
 266   '((t :inherit font-lock-comment-face))
 267   "Face used for html type directory records.")
 268
 269 (defface elpher-gemini
 270   '((t :inherit font-lock-constant-face))
 271   "Face used for Gemini type directory records.")
 272
 273 (defface elpher-other-url
 274   '((t :inherit font-lock-comment-face))
 275   "Face used for other URL type links records.")
 276
 277 (defface elpher-telnet
 278   '((t :inherit font-lock-function-name-face))
 279   "Face used for telnet type directory records.")
 280
 281 (defface elpher-binary
 282   '((t :inherit font-lock-doc-face))
 283   "Face used for binary type directory records.")
 284
 285 (defface elpher-unknown
 286   '((t :inherit error))
 287   "Face used for directory records with unknown/unsupported types.")
 288
 289 (defface elpher-margin-key
 290   '((t :inherit bold))
 291   "Face used for directory margin key.")
 292
 293 (defface elpher-margin-brackets
 294   '((t :inherit shadow))
 295   "Face used for brackets around directory margin key.")
 296
 297 (defface elpher-gemini-heading1
 298   '((t :inherit bold :height 1.8))
 299   "Face used for gemini heading level 1.")
 300
 301 (defface elpher-gemini-heading2
 302   '((t :inherit bold :height 1.5))
 303   "Face used for gemini heading level 2.")
 304
 305 (defface elpher-gemini-heading3
 306   '((t :inherit bold :height 1.2))
 307   "Face used for gemini heading level 3.")
 308
 309 (defface elpher-gemini-preformatted
 310   '((t :inherit fixed-pitch))
 311   "Face used for pre-formatted gemini text blocks.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 ;;; Model
 318 ;;
 319
 320 ;; Address
 321
 322 ;; An elpher "address" object is either a url object or a symbol.
 323 ;; Addresses with the "about" type, corresponding to pages generated
 324 ;; dynamically for and by elpher.  All others represent pages which
 325 ;; rely on content retrieved over the network.
 326
 327 (defun elpher-address-from-url (url-string)
 328   "Create a ADDRESS object corresponding to the given URL-STRING."
 329   (let ((data (match-data))) ; Prevent parsing clobbering match data
 330     (unwind-protect
 331         (let ((url (url-generic-parse-url url-string)))
 332           (unless (and (not (url-fullness url)) (url-type url))
 333             (setf (url-fullness url) t)
 334             (unless (url-type url)
 335               (setf (url-type url) elpher-default-url-type))
 336             (unless (url-host url)
 337               (let ((p (split-string (url-filename url) "/" nil nil)))
 338                 (setf (url-host url) (car p))
 339                 (setf (url-filename url)
 340                       (if (cdr p)
 341                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 342                         ""))))
 343             (when (or (equal "gopher" (url-type url))
 344                       (equal "gophers" (url-type url)))
 345               ;; Gopher defaults
 346               (when (or (equal (url-filename url) "")
 347                         (equal (url-filename url) "/"))
 348                 (setf (url-filename url) "/1")))
 349             (when (equal "gemini" (url-type url))
 350               ;; Gemini defaults
 351               (if (equal (url-filename url) "")
 352                   (setf (url-filename url) "/"))))
 353           (elpher-remove-redundant-ports url))
 354       (set-match-data data))))
 355
 356 (defun elpher-remove-redundant-ports (address)
 357   "Remove redundant port specifiers from ADDRESS.
 358 Here 'redundant' means that the specified port matches the default
 359 for that protocol, eg 70 for gopher."
 360   (if (and (not (elpher-address-about-p address))
 361            (eq (url-portspec address) ; (url-port) is too slow!
 362                (pcase (url-type address)
 363                  ("gemini" 1965)
 364                  ((or "gopher" "gophers") 70)
 365                  ("finger" 79)
 366                  (_ -1))))
 367       (setf (url-portspec address) nil))
 368   address)
 369
 370 (defun elpher-make-gopher-address (type selector host port &optional tls)
 371   "Create an ADDRESS object using gopher directory record attributes.
 372 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 373 If the optional attribute TLS is non-nil, the address will be marked as
 374 requiring gopher-over-TLS."
 375   (cond
 376    ((equal type ?i) nil)
 377    ((and (equal type ?h)
 378          (string-prefix-p "URL:" selector))
 379     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 380    ((equal type ?8)
 381     (elpher-address-from-url
 382      (concat "telnet"
 383              "://" host
 384              ":" (number-to-string port))))
 385    (t
 386     (elpher-address-from-url
 387      (concat "gopher" (if tls "s" "")
 388              "://" host
 389              ":" (number-to-string port)
 390              "/" (string type)
 391              selector)))))
 392
 393 (defun elpher-make-about-address (type)
 394   "Create an ADDRESS object corresponding to the given about address TYPE."
 395   (elpher-address-from-url (concat "about:" (symbol-name type))))
 396
 397 (defun elpher-address-to-url (address)
 398   "Get string representation of ADDRESS."
 399   (url-encode-url (url-recreate-url address)))
 400
 401 (defun elpher-address-type (address)
 402   "Retrieve type of ADDRESS object.
 403 This is used to determine how to retrieve and render the document the
 404 address refers to, via the table `elpher-type-map'."
 405   (pcase (url-type address)
 406     ("about"
 407      (list 'about (intern (url-filename address))))
 408     ((or "gopher" "gophers")
 409      (list 'gopher
 410            (if (member (url-filename address) '("" "/"))
 411                ?1
 412              (string-to-char (substring (url-filename address) 1)))))
 413     ("gemini" 'gemini)
 414     ("telnet" 'telnet)
 415     ("finger" 'finger)
 416     ("file" 'file)
 417     (_ 'other-url)))
 418
 419 (defun elpher-address-about-p (address)
 420   "Return non-nil if ADDRESS is an  about address."
 421   (pcase (elpher-address-type address) (`(about ,_) t)))
 422
 423 (defun elpher-address-gopher-p (address)
 424   "Return non-nill if ADDRESS object is a gopher address."
 425   (eq 'gopher (elpher-address-type address)))
 426
 427 (defun elpher-address-protocol (address)
 428   "Retrieve the transport protocol for ADDRESS."
 429   (url-type address))
 430
 431 (defun elpher-address-filename (address)
 432   "Retrieve the filename component of ADDRESS.
 433 For gopher addresses this is a combination of the selector type and selector."
 434   (url-unhex-string (url-filename address)))
 435
 436 (defun elpher-address-host (address)
 437   "Retrieve host from ADDRESS object."
 438   (url-host address))
 439
 440 (defun elpher-address-user (address)
 441   "Retrieve user from ADDRESS object."
 442   (url-user address))
 443
 444 (defun elpher-address-port (address)
 445   "Retrieve port from ADDRESS object.
 446 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 447   (url-port address))
 448
 449 (defun elpher-gopher-address-selector (address)
 450   "Retrieve gopher selector from ADDRESS object."
 451   (if (member (url-filename address) '("" "/"))
 452       ""
 453     (url-unhex-string (substring (url-filename address) 2))))
 454
 455
 456 ;; Cache
 457
 458 (defvar elpher-content-cache (make-hash-table :test 'equal))
 459 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 460
 461 (defun elpher-get-cached-content (address)
 462   "Retrieve the cached content for ADDRESS, or nil if none exists."
 463   (gethash address elpher-content-cache))
 464
 465 (defun elpher-cache-content (address content)
 466   "Set the content cache for ADDRESS to CONTENT."
 467   (puthash address content elpher-content-cache))
 468
 469 (defun elpher-get-cached-pos (address)
 470   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 471   (gethash address elpher-pos-cache))
 472
 473 (defun elpher-cache-pos (address pos)
 474   "Set the cursor position cache for ADDRESS to POS."
 475   (puthash address pos elpher-pos-cache))
 476
 477
 478 ;; Page
 479
 480 (defun elpher-make-page (display-string address)
 481   "Create a page with DISPLAY-STRING and ADDRESS."
 482   (list display-string address))
 483
 484 (defun elpher-make-start-page ()
 485   "Create the welcome page."
 486   (elpher-make-page "Start Page"
 487                     (elpher-address-from-url elpher-start-page)))
 488
 489 (defun elpher-page-display-string (page)
 490   "Retrieve the display string corresponding to PAGE."
 491   (elt page 0))
 492
 493 (defun elpher-page-address (page)
 494   "Retrieve the address corresponding to PAGE."
 495   (elt page 1))
 496
 497 (defun elpher-page-set-address (page new-address)
 498   "Set the address corresponding to PAGE to NEW-ADDRESS."
 499   (setcar (cdr page) new-address))
 500
 501 (defvar elpher-current-page nil
 502   "The current page for this Elpher buffer.")
 503
 504 (defvar elpher-history nil
 505   "The local history stack for this Elpher buffer.
 506 This variable is used by `elpher-back' and
 507 `elpher-show-history'.")
 508
 509 (defvar elpher-visited-pages nil
 510   "The global history for all Elpher buffers.
 511 This variable is used by `elpher-show-visited-pages'.")
 512
 513 (defun elpher-visit-page (page &optional renderer no-history)
 514   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 515 Additionally, push PAGE onto the history stack and the list of
 516 previously-visited pages,unless NO-HISTORY is non-nil."
 517   (elpher-save-pos)
 518   (elpher-process-cleanup)
 519   (unless no-history
 520     (unless (or (not elpher-current-page)
 521                  (equal (elpher-page-address elpher-current-page)
 522                         (elpher-page-address page)))
 523       (push elpher-current-page elpher-history)
 524       (unless (or (elpher-address-about-p (elpher-page-address page))
 525                   (and elpher-visited-pages
 526                        (equal page (car elpher-visited-pages))))
 527         (push page elpher-visited-pages))))
 528   (setq-local elpher-current-page page)
 529   (let* ((address (elpher-page-address page))
 530          (type (elpher-address-type address))
 531          (type-record (cdr (assoc type elpher-type-map))))
 532     (if type-record
 533         (funcall (car type-record)
 534                  (if renderer
 535                      renderer
 536                    (cadr type-record)))
 537       (elpher-visit-previous-page)
 538       (pcase type
 539         (`(gopher ,type-char)
 540          (error "Unsupported gopher selector type '%c' for '%s'"
 541                 type-char (elpher-address-to-url address)))
 542         (other
 543          (error "Unsupported address type '%S' for '%s'"
 544                 other (elpher-address-to-url address)))))))
 545
 546 (defun elpher-visit-previous-page ()
 547   "Visit the previous page in the history."
 548   (if elpher-history
 549       (elpher-visit-page (pop elpher-history) nil t)
 550     (error "No previous page")))
 551
 552 (defun elpher-reload-current-page ()
 553   "Reload the current page, discarding any existing cached content."
 554   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 555   (elpher-visit-page elpher-current-page))
 556
 557 (defun elpher-save-pos ()
 558   "Save the current position of point to the current page."
 559   (when elpher-current-page
 560     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 561
 562 (defun elpher-restore-pos ()
 563   "Restore the position of point to that cached in the current page."
 564   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 565     (if pos
 566         (goto-char pos)
 567       (goto-char (point-min)))))
 568
 569
 570 ;;; Buffer preparation
 571 ;;
 572
 573 (defvar elpher-buffer-name "*elpher*"
 574   "The default name of the Elpher buffer.")
 575
 576 (defun elpher-update-header ()
 577   "If `elpher-use-header' is true, display current page info in window header."
 578   (if elpher-use-header
 579       (let* ((display-string (elpher-page-display-string elpher-current-page))
 580              (address (elpher-page-address elpher-current-page))
 581              (tls-string (if (and (not (elpher-address-about-p address))
 582                                   (member (elpher-address-protocol address)
 583                                           '("gophers" "gemini")))
 584                              " [TLS encryption]"
 585                            ""))
 586              (header (concat display-string
 587                              (propertize tls-string 'face 'bold))))
 588         (setq header-line-format header))))
 589
 590 (defmacro elpher-with-clean-buffer (&rest args)
 591   "Evaluate ARGS with a clean *elpher* buffer as current."
 592   (declare (debug (body))) ;; Allow edebug to step through body
 593   `(with-current-buffer elpher-buffer-name
 594      (unless (eq major-mode 'elpher-mode)
 595        ;; avoid resetting buffer-local variables
 596        (elpher-mode))
 597      (let ((inhibit-read-only t)
 598            (ansi-color-context nil)) ;; clean ansi interpreter state
 599        (setq-local network-security-level
 600                    (default-value 'network-security-level))
 601        (erase-buffer)
 602        (elpher-update-header)
 603        ,@args)))
 604
 605 (defun elpher-buffer-message (string &optional line)
 606   "Replace first line in elpher buffer with STRING.
 607 If LINE is non-nil, replace that line instead."
 608   (with-current-buffer elpher-buffer-name
 609     (let ((inhibit-read-only t))
 610       (goto-char (point-min))
 611       (if line
 612           (forward-line line))
 613       (let ((data (match-data)))
 614         (unwind-protect
 615             (progn
 616               (re-search-forward "^.*$")
 617               (replace-match string))
 618           (set-match-data data))))))
 619
 620
 621 ;;; Text Processing
 622 ;;
 623
 624 (defvar elpher-user-coding-system nil
 625   "User-specified coding system to use for decoding text responses.")
 626
 627 (defun elpher-decode (string)
 628   "Decode STRING using autodetected or user-specified coding system."
 629   (decode-coding-string string
 630                         (if elpher-user-coding-system
 631                             elpher-user-coding-system
 632                           (detect-coding-string string t))))
 633
 634 (defun elpher-preprocess-text-response (string)
 635   "Preprocess text selector response contained in STRING.
 636 This involes decoding the character representation, and clearing
 637 away CRs and any terminating period."
 638   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 639                                            (replace-regexp-in-string "\r" "" string))))
 640
 641 ;;; Buttonify urls
 642
 643 (defconst elpher-url-regex
 644   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 645   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 646
 647 (defun elpher-buttonify-urls (string)
 648   "Turn substrings which look like urls in STRING into clickable buttons."
 649   (with-temp-buffer
 650     (insert string)
 651     (goto-char (point-min))
 652     (while (re-search-forward elpher-url-regex nil t)
 653       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 654                                     (elpher-address-from-url (match-string 0)))))
 655         (make-text-button (match-beginning 0)
 656                           (match-end 0)
 657                           'elpher-page  page
 658                           'action #'elpher-click-link
 659                           'follow-link t
 660                           'help-echo #'elpher--page-button-help
 661                           'face 'button)))
 662     (buffer-string)))
 663
 664 ;;; ANSI colors or XTerm colors (application and filtering)
 665
 666 (or (require 'xterm-color nil t)
 667     (require 'ansi-color))
 668
 669 (defalias 'elpher-color-filter-apply
 670   (if (fboundp 'xterm-color-filter)
 671       (lambda (s)
 672         (let ((_xterm-color-render nil))
 673           (xterm-color-filter s)))
 674     #'ansi-color-filter-apply)
 675   "A function to filter out ANSI escape sequences.")
 676
 677 (defalias 'elpher-color-apply
 678   (if (fboundp 'xterm-color-filter)
 679       #'xterm-color-filter
 680     #'ansi-color-apply)
 681   "A function to apply ANSI escape sequences.")
 682
 683 ;;; Processing text for display
 684
 685 (defun elpher-process-text-for-display (string)
 686   "Perform any desired processing of STRING prior to display as text.
 687 Currently includes buttonifying URLs and processing ANSI escape codes."
 688   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 689                              (elpher-color-filter-apply string)
 690                            (elpher-color-apply string))))
 691
 692
 693 ;;; Network error reporting
 694 ;;
 695
 696 (defun elpher-network-error (address error)
 697   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 698 ERROR can be either an error object or a string."
 699   (elpher-with-clean-buffer
 700    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 701            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 702            (if (stringp error) error (error-message-string error)) "\n"
 703            (propertize "\n----------------\n\n" 'face 'error)
 704            "Press 'u' to return to the previous page.")))
 705
 706
 707 ;;; General network communication
 708 ;;
 709
 710 (defvar elpher-network-timer nil
 711   "Timer used for network connections.")
 712
 713 (defvar elpher-use-tls nil
 714   "If non-nil, use TLS to communicate with gopher servers.")
 715
 716 (defvar elpher-client-certificate nil
 717   "If non-nil, contains client certificate details to use for TLS connections.")
 718
 719 (defun elpher-process-cleanup ()
 720   "Immediately shut down any extant elpher process and timers."
 721   (let ((p (get-process "elpher-process")))
 722     (if p (delete-process p)))
 723   (if (timerp elpher-network-timer)
 724       (cancel-timer elpher-network-timer)))
 725
 726 (defun elpher-make-network-timer (thunk)
 727   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 728 This is just a wraper around `run-at-time' which additionally sets the
 729 buffer-local variable `elpher-network-timer' to allow
 730 `elpher-process-cleanup' to also clear the timer."
 731   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 732     (setq-local elpher-network-timer timer)
 733     timer))
 734
 735 (defun elpher-get-host-response (address default-port query-string response-processor
 736                                          &optional use-tls force-ipv4)
 737   "Generic function for retrieving data from ADDRESS.
 738
 739 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 740 QUERY-STRING is a string sent to the host specified by ADDRESS to
 741 illicet a response.  This response is passed as an argument to the
 742 function RESPONSE-PROCESSOR.
 743
 744 If non-nil, USE-TLS specifies that the connection is to be made over
 745 TLS.  If set to gemini, the certificate verification will be disabled
 746 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 747
 748 If non-nil, FORCE-IPV4 causes the network connection to be made over
 749 ipv4 only.  (The default behaviour when this is not set depends on
 750 the host operating system and the local network capabilities.)"
 751   (if (and use-tls (not (gnutls-available-p)))
 752       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 753     (unless (< (elpher-address-port address) 65536)
 754       (error "Cannot establish network connection: port number > 65536"))
 755     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 756       (setq-local network-security-level 'low)
 757       (setq-local gnutls-verify-error nil))
 758     (condition-case nil
 759         (let* ((kill-buffer-query-functions nil)
 760                (port (elpher-address-port address))
 761                (host (elpher-address-host address))
 762                (service (if (> port 0) port default-port))
 763                (response-string-parts nil)
 764                (bytes-received 0)
 765                (hkbytes-received 0)
 766                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 767                (gnutls-params (list :type 'gnutls-x509pki
 768                                     :hostname host
 769                                     :keylist
 770                                     (elpher-get-current-keylist address)))
 771                (timer (elpher-make-network-timer
 772                                    (lambda ()
 773                                      (elpher-process-cleanup)
 774                                      (cond
 775                                         ; Try again with IPv4
 776                                       ((not (or force-ipv4 socks))
 777                                        (message "Connection timed out.  Retrying with IPv4.")
 778                                        (elpher-get-host-response address default-port
 779                                                                  query-string
 780                                                                  response-processor
 781                                                                  use-tls t))
 782                                       ((and use-tls
 783                                             (not (eq use-tls 'gemini))
 784                                             (or elpher-auto-disengage-TLS
 785                                                 (y-or-n-p
 786                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 787                                        (setq elpher-use-tls nil)
 788                                        (elpher-get-host-response address default-port
 789                                                                  query-string
 790                                                                  response-processor
 791                                                                  nil force-ipv4))
 792                                       (t
 793                                        (elpher-network-error address "Connection time-out."))))))
 794                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 795                        (make-network-process :name "elpher-process"
 796                                              :host host
 797                                              :family (and force-ipv4 'ipv4)
 798                                              :service service
 799                                              :buffer nil
 800                                              :nowait t
 801                                              :tls-parameters
 802                                              (and use-tls
 803                                                   (cons 'gnutls-x509pki
 804                                                         (apply #'gnutls-boot-parameters
 805                                                                gnutls-params)))))))
 806           (setq elpher-network-timer timer)
 807           (set-process-coding-system proc 'binary 'binary)
 808           (set-process-query-on-exit-flag proc nil)
 809           (elpher-buffer-message (concat "Connecting to " host "..."
 810                                          " (press 'u' to abort)"))
 811           (set-process-filter proc
 812                               (lambda (_proc string)
 813                                 (when timer
 814                                   (cancel-timer timer)
 815                                   (setq timer nil))
 816                                 (setq bytes-received (+ bytes-received (length string)))
 817                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 818                                   (when (> new-hkbytes-received hkbytes-received)
 819                                     (setq hkbytes-received new-hkbytes-received)
 820                                     (elpher-buffer-message
 821                                      (concat "("
 822                                              (number-to-string (/ hkbytes-received 10.0))
 823                                              " MB read)")
 824                                      1)))
 825                                 (setq response-string-parts
 826                                       (cons string response-string-parts))))
 827           (set-process-sentinel proc
 828                                 (lambda (proc event)
 829                                   (when timer
 830                                     (cancel-timer timer))
 831                                   (condition-case the-error
 832                                       (cond
 833                                        ((string-prefix-p "open" event)    ; request URL
 834                                         (elpher-buffer-message
 835                                          (concat "Connected to " host ". Receiving data..."
 836                                                  " (press 'u' to abort)"))
 837                                         (let ((inhibit-eol-conversion t))
 838                                           (process-send-string proc query-string)))
 839                                        ((string-prefix-p "deleted" event)) ; do nothing
 840                                        ((and (not response-string-parts)
 841                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 842                                         ; Try again with IPv4
 843                                         (message "Connection failed. Retrying with IPv4.")
 844                                         (elpher-get-host-response address default-port
 845                                                                   query-string
 846                                                                   response-processor
 847                                                                   use-tls t))
 848                                        (response-string-parts
 849                                         (elpher-with-clean-buffer
 850                                          (insert "Data received.  Rendering..."))
 851                                         (funcall response-processor
 852                                                  (apply #'concat (reverse response-string-parts)))
 853                                         (elpher-restore-pos))
 854                                        (t
 855                                         (error "No response from server")))
 856                                     (error
 857                                      (elpher-network-error address the-error)))))
 858           (when socks
 859             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 860             (funcall (process-sentinel proc) proc "open\n")))
 861       (error
 862        (elpher-process-cleanup)
 863        (error "Error initiating connection to server")))))
 864
 865
 866 ;;; Client-side TLS Certificate Management
 867 ;;
 868
 869 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 870   "Generate a key and a self-signed client TLS certificate using openssl.
 871
 872 The Common Name field of the certificate is set to COMMON-NAME.  The
 873 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 874 the key and certificate files to write.
 875
 876 If TEMPORARY is non-nil, the certificate will be given an exporation
 877 period of one day, and the key and certificate files will be deleted
 878 when the certificate is no longer needed for the current session.
 879
 880 Otherwise, the certificate will be given a 100 year expiration period
 881 and the files will not be deleted.
 882
 883 The function returns a list containing the current host name, the
 884 temporary flag, and the key and cert file names in the form required
 885 by `gnutls-boot-parameters`."
 886   (let ((exp-key-file (expand-file-name key-file))
 887         (exp-cert-file (expand-file-name cert-file)))
 888     (condition-case nil
 889         (progn
 890           (call-process elpher-openssl-command nil nil nil
 891                         "req" "-x509" "-newkey" "rsa:2048"
 892                         "-days" (if temporary "1" "36500")
 893                         "-nodes"
 894                         "-subj" (concat "/CN=" common-name)
 895                         "-keyout" exp-key-file
 896                         "-out" exp-cert-file)
 897           (list (elpher-address-host (elpher-page-address elpher-current-page))
 898                 temporary exp-key-file exp-cert-file))
 899       (error
 900        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 901        (error "Program 'openssl', required for certificate generation, not found")))))
 902
 903 (defun elpher-generate-throwaway-certificate ()
 904   "Generate and return details of a throwaway certificate.
 905 The key and certificate files will be deleted when they are no
 906 longer needed for this session."
 907   (let* ((file-base (make-temp-name "elpher"))
 908          (key-file (concat temporary-file-directory file-base ".key"))
 909          (cert-file (concat temporary-file-directory file-base ".crt")))
 910     (elpher-generate-certificate file-base key-file cert-file t)))
 911
 912 (defun elpher-generate-persistent-certificate (file-base common-name)
 913   "Generate and return details of a persistent certificate.
 914 The argument FILE-BASE is used as the base for the key and certificate
 915 files, while COMMON-NAME specifies the common name field of the
 916 certificate.
 917
 918 The key and certificate files are written to in `elpher-certificate-directory'."
 919   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 920          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 921     (elpher-generate-certificate common-name key-file cert-file)))
 922
 923 (defun elpher-get-existing-certificate (file-base)
 924   "Return a certificate object corresponding to an existing certificate.
 925 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 926 the directory `elpher-certificate-directory'."
 927   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 928          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 929     (list (elpher-address-host (elpher-page-address elpher-current-page))
 930           nil
 931           (expand-file-name key-file)
 932           (expand-file-name cert-file))))
 933
 934 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 935   "Install a key+certificate file pair in `elpher-certificate-directory'.
 936 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 937 certificate files to install.  The argument FILE-BASE is used as the
 938 base for the installed key and certificate files."
 939   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 940          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 941     (if (or (file-exists-p key-file)
 942             (file-exists-p cert-file))
 943         (error "A certificate with base name %s is already installed" file-base))
 944     (copy-file key-file-src key-file)
 945     (copy-file cert-file-src cert-file)
 946     (list (elpher-address-host (elpher-page-address elpher-current-page))
 947           nil
 948           (expand-file-name key-file)
 949           (expand-file-name cert-file))))
 950
 951 (defun elpher-list-existing-certificates ()
 952   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 953   (unless (file-directory-p elpher-certificate-directory)
 954     (make-directory elpher-certificate-directory))
 955   (mapcar
 956    (lambda (file)
 957      (file-name-sans-extension file))
 958    (directory-files elpher-certificate-directory nil "\\.key$")))
 959
 960 (defun elpher-forget-current-certificate ()
 961   "Causes any current certificate to be forgotten.)
 962 In the case of throwaway certificates, the key and certificate files
 963 are also deleted."
 964   (interactive)
 965   (when elpher-client-certificate
 966     (unless (and (called-interactively-p 'any)
 967                  (not (y-or-n-p (concat "Really forget client certificate? "
 968                                         "(Throwaway certificates will be deleted.)"))))
 969       (when (cadr elpher-client-certificate)
 970         (delete-file (elt elpher-client-certificate 2))
 971         (delete-file (elt elpher-client-certificate 3)))
 972       (setq elpher-client-certificate nil)
 973       (if (called-interactively-p 'any)
 974           (message "Client certificate forgotten.")))))
 975
 976 (defun elpher-get-current-keylist (address)
 977   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 978
 979 This is obtained from the client certificate described by
 980 `elpher-current-certificate', if one is available and the host for
 981 that certificate matches the host in ADDRESS.
 982
 983 If `elpher-current-certificate' is non-nil, and its host name doesn't
 984 match that of ADDRESS, the certificate is forgotten."
 985   (if elpher-client-certificate
 986       (if (string= (car elpher-client-certificate)
 987                    (elpher-address-host address))
 988           (list (cddr elpher-client-certificate))
 989         (elpher-forget-current-certificate)
 990         (message "Disabling client certificate for new host")
 991         nil)
 992     nil))
 993
 994
 995 ;;; Gopher selector retrieval
 996 ;;
 997
 998 (defun elpher-get-gopher-response (address renderer)
 999   "Get response string from gopher server at ADDRESS and render using RENDERER."
1000   (elpher-get-host-response address 70
1001                             (concat (elpher-gopher-address-selector address) "\r\n")
1002                             renderer
1003                             (or (string= (elpher-address-protocol address) "gophers")
1004                                 elpher-use-tls)))
1005
1006 (defun elpher-get-gopher-page (renderer)
1007   "Getter function for gopher pages.
1008 The RENDERER procedure is used to display the contents of the page
1009 once they are retrieved from the gopher server."
1010   (let* ((address (elpher-page-address elpher-current-page))
1011          (content (elpher-get-cached-content address)))
1012     (if (and content (funcall renderer nil))
1013         (elpher-with-clean-buffer
1014          (insert content)
1015          (elpher-restore-pos))
1016       (elpher-with-clean-buffer
1017        (insert "LOADING... (use 'u' to cancel)\n"))
1018       (condition-case the-error
1019           (elpher-get-gopher-response address renderer)
1020         (error
1021          (elpher-network-error address the-error))))))
1022
1023 ;; Index rendering
1024
1025 (defun elpher-insert-index (string)
1026   "Insert the index corresponding to STRING into the current buffer."
1027   ;; Should be able to split directly on CRLF, but some non-conformant
1028   ;; LF-only servers sadly exist, hence the following.
1029   (let ((str-processed (elpher-preprocess-text-response string)))
1030     (dolist (line (split-string str-processed "\n"))
1031       (ignore-errors
1032         (unless (= (length line) 0)
1033           (let* ((type (elt line 0))
1034                  (fields (split-string (substring line 1) "\t"))
1035                  (display-string (elt fields 0))
1036                  (selector (elt fields 1))
1037                  (host (elt fields 2))
1038                  (port (if (elt fields 3)
1039                            (string-to-number (elt fields 3))
1040                          nil))
1041                  (address (elpher-make-gopher-address type selector host port)))
1042             (elpher-insert-index-record display-string address)))))))
1043
1044 (defun elpher-insert-margin (&optional type-name)
1045   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1046   (if type-name
1047       (progn
1048         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1049                         (concat
1050                          (propertize "[" 'face 'elpher-margin-brackets)
1051                          (propertize type-name 'face 'elpher-margin-key)
1052                          (propertize "]" 'face 'elpher-margin-brackets))))
1053         (insert " "))
1054     (insert (make-string elpher-margin-width ?\s))))
1055
1056 (defun elpher--page-button-help (_window buffer pos)
1057   "Function called by Emacs to generate mouse-over text.
1058 The arguments specify the BUFFER and the POS within the buffer of the item
1059 for which help is required.  The function returns the help to be
1060 displayed.  The _WINDOW argument is currently unused."
1061   (with-current-buffer buffer
1062     (let ((button (button-at pos)))
1063       (when button
1064         (let* ((page (button-get button 'elpher-page))
1065                (address (elpher-page-address page)))
1066           (format "mouse-1, RET: open '%s'" (if (elpher-address-about-p address)
1067                                                 address
1068                                               (elpher-address-to-url address))))))))
1069
1070 (defun elpher-insert-index-record (display-string &optional address)
1071   "Function to insert an index record into the current buffer.
1072 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1073 If ADDRESS is not supplied or nil the record is rendered as an
1074 'information' line."
1075   (let* ((type (if address (elpher-address-type address) nil))
1076          (type-map-entry (cdr (assoc type elpher-type-map))))
1077     (if type-map-entry
1078         (let* ((margin-code (elt type-map-entry 2))
1079                (face (elt type-map-entry 3))
1080                (filtered-display-string (elpher-color-filter-apply display-string))
1081                (page (elpher-make-page filtered-display-string address)))
1082           (elpher-insert-margin margin-code)
1083           (insert-text-button filtered-display-string
1084                               'face face
1085                               'elpher-page page
1086                               'action #'elpher-click-link
1087                               'follow-link t
1088                               'help-echo #'elpher--page-button-help))
1089       (pcase type
1090         ('nil ;; Information
1091          (elpher-insert-margin)
1092          (let ((propertized-display-string
1093                 (propertize display-string 'face 'elpher-info)))
1094            (insert (elpher-process-text-for-display propertized-display-string))))
1095         (`(gopher ,selector-type) ;; Unknown
1096          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1097          (insert (propertize display-string
1098                              'face 'elpher-unknown)))))
1099     (insert "\n")))
1100
1101 (defun elpher-click-link (button)
1102   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1103   (let ((page (button-get button 'elpher-page)))
1104     (elpher-visit-page page)))
1105
1106 (defun elpher-render-index (data &optional _mime-type-string)
1107   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1108   (elpher-with-clean-buffer
1109    (if (not data)
1110        t
1111      (elpher-insert-index data)
1112      (elpher-cache-content (elpher-page-address elpher-current-page)
1113                            (buffer-string)))))
1114
1115 ;; Text rendering
1116
1117 (defun elpher-render-text (data &optional _mime-type-string)
1118   "Render DATA as text.  MIME-TYPE-STRING is unused."
1119   (elpher-with-clean-buffer
1120    (if (not data)
1121        t
1122      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1123      (elpher-cache-content
1124       (elpher-page-address elpher-current-page)
1125       (buffer-string)))))
1126
1127 ;; Image retrieval
1128
1129 (defun elpher-render-image (data &optional _mime-type-string)
1130   "Display DATA as image.  MIME-TYPE-STRING is unused."
1131   (if (not data)
1132       nil
1133     (if (display-images-p)
1134         (let* ((image (create-image
1135                        data
1136                        nil t))
1137                (window (get-buffer-window elpher-buffer-name)))
1138           (when window
1139             (setf (image-property image :max-width) (window-pixel-width window))
1140             (setf (image-property image :max-height) (window-pixel-height window)))
1141           (elpher-with-clean-buffer
1142            (insert-image image)
1143            (elpher-restore-pos)))
1144       (elpher-render-download data))))
1145
1146 ;; Search retrieval and rendering
1147
1148 (defun elpher-get-gopher-query-page (renderer)
1149   "Getter for gopher addresses requiring input.
1150 The response is rendered using the rendering function RENDERER."
1151   (let* ((address (elpher-page-address elpher-current-page))
1152          (content (elpher-get-cached-content address))
1153          (aborted t))
1154     (if (and content (funcall renderer nil))
1155         (elpher-with-clean-buffer
1156          (insert content)
1157          (elpher-restore-pos)
1158          (message "Displaying cached search results.  Reload to perform a new search."))
1159       (unwind-protect
1160           (let* ((query-string (read-string "Query: "))
1161                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1162                  (search-address (elpher-make-gopher-address ?1
1163                                                              query-selector
1164                                                              (elpher-address-host address)
1165                                                              (elpher-address-port address)
1166                                                              (equal (elpher-address-type address) "gophers"))))
1167             (setq aborted nil)
1168
1169             (elpher-with-clean-buffer
1170              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1171             (elpher-get-gopher-response search-address renderer))
1172         (if aborted
1173             (elpher-visit-previous-page))))))
1174
1175 ;; Raw server response rendering
1176
1177 (defun elpher-render-raw (data &optional mime-type-string)
1178   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1179   (if (not data)
1180       nil
1181     (elpher-with-clean-buffer
1182      (when mime-type-string
1183        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1184      (insert data)
1185      (goto-char (point-min)))
1186     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1187
1188 ;; File save "rendering"
1189
1190 (defun elpher-render-download (data &optional _mime-type-string)
1191   "Save DATA to file.  MIME-TYPE-STRING is unused."
1192   (if (not data)
1193       nil
1194     (let* ((address (elpher-page-address elpher-current-page))
1195            (selector (if (elpher-address-gopher-p address)
1196                          (elpher-gopher-address-selector address)
1197                        (elpher-address-filename address))))
1198       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1199       (let* ((filename-proposal (file-name-nondirectory selector))
1200              (filename (read-file-name "Download complete. Save file as: "
1201                                        nil nil nil
1202                                        (if (> (length filename-proposal) 0)
1203                                            filename-proposal
1204                                          "download.file"))))
1205         (let ((coding-system-for-write 'binary))
1206           (with-temp-file filename
1207             (insert data)))
1208         (message (format "Saved to file %s." filename))))))
1209
1210 ;; HTML rendering
1211
1212 (defun elpher-render-html (data &optional _mime-type-string)
1213   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1214   (elpher-with-clean-buffer
1215    (if (not data)
1216        t
1217      (let ((dom (with-temp-buffer
1218                   (insert data)
1219                   (libxml-parse-html-region (point-min) (point-max)))))
1220        (shr-insert-document dom)))))
1221
1222 ;; Gemini page retrieval
1223
1224 (defvar elpher-gemini-redirect-chain)
1225
1226 (defun elpher-get-gemini-response (address renderer)
1227   "Get response string from gemini server at ADDRESS and render using RENDERER."
1228   (elpher-get-host-response address 1965
1229                             (concat (elpher-address-to-url address) "\r\n")
1230                             (lambda (response-string)
1231                               (elpher-process-gemini-response response-string renderer))
1232                             'gemini))
1233
1234 (defun elpher-parse-gemini-response (response)
1235   "Parse the RESPONSE string and return a list of components.
1236 The list is of the form (code meta body).  A response of nil implies
1237 that the response was malformed."
1238   (let ((header-end-idx (string-match "\r\n" response)))
1239     (if header-end-idx
1240         (let ((header (string-trim (substring response 0 header-end-idx)))
1241               (body (substring response (+ header-end-idx 2))))
1242           (if (>= (length header) 2)
1243               (let ((code (substring header 0 2))
1244                     (meta (string-trim (substring header 2))))
1245                 (list code meta body))
1246             (error "Malformed response: No response status found in header %s" header)))
1247       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1248
1249 (defun elpher-process-gemini-response (response-string renderer)
1250   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1251   (let ((response-components (elpher-parse-gemini-response response-string)))
1252     (let ((response-code (elt response-components 0))
1253           (response-meta (elt response-components 1))
1254           (response-body (elt response-components 2)))
1255       (pcase (elt response-code 0)
1256         (?1 ; Input required
1257          (elpher-with-clean-buffer
1258           (insert "Gemini server is requesting input."))
1259          (let* ((query-string
1260                  (if (eq (elt response-code 1) ?1)
1261                      (read-passwd (concat response-meta ": "))
1262                    (read-string (concat response-meta ": "))))
1263                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1264                 (old-fname (url-filename query-address)))
1265            (setf (url-filename query-address)
1266                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1267            (elpher-get-gemini-response query-address renderer)))
1268         (?2 ; Normal response
1269          (funcall renderer response-body response-meta))
1270         (?3 ; Redirect
1271          (message "Following redirect to %s" response-meta)
1272          (if (>= (length elpher-gemini-redirect-chain) 5)
1273              (error "More than 5 consecutive redirects followed"))
1274          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1275            (if (member redirect-address elpher-gemini-redirect-chain)
1276                (error "Redirect loop detected"))
1277            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1278                (error "Server tried to automatically redirect to non-gemini URL: %s"
1279                       response-meta))
1280            (elpher-page-set-address elpher-current-page redirect-address)
1281            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1282            (elpher-get-gemini-response redirect-address renderer)))
1283         (?4 ; Temporary failure
1284          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1285                 response-code response-meta))
1286         (?5 ; Permanent failure
1287          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1288                 response-code response-meta))
1289         (?6 ; Client certificate required
1290          (elpher-with-clean-buffer
1291           (if elpher-client-certificate
1292               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1293             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1294           (auto-fill-mode 1)
1295           (elpher-gemini-insert-text response-meta))
1296          (let ((chosen-certificate (elpher-choose-client-certificate)))
1297            (unless chosen-certificate
1298              (error "Gemini server requires a client certificate and none was provided"))
1299            (setq elpher-client-certificate chosen-certificate))
1300          (elpher-with-clean-buffer)
1301          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1302         (_other
1303          (error "Gemini server response unknown: %s %s"
1304                 response-code response-meta))))))
1305
1306 (defun elpher--read-answer-polyfill (question answers)
1307   "Polyfill for `read-answer' in Emacs 26.1.
1308 QUESTION is a string containing a question, and ANSWERS
1309 is a list of possible answers."
1310     (completing-read question (mapcar 'identity answers)))
1311
1312 (if (fboundp 'read-answer)
1313     (defalias 'elpher-read-answer 'read-answer)
1314   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1315
1316 (defun elpher-choose-client-certificate ()
1317   "Prompt for a client certificate to use to establish a TLS connection."
1318   (let* ((read-answer-short t))
1319     (pcase (read-answer "What do you want to do? "
1320                         '(("throwaway" ?t
1321                            "generate and use throw-away certificate")
1322                           ("persistent" ?p
1323                            "generate new or use existing persistent certificate")
1324                           ("abort" ?a
1325                            "stop immediately")))
1326       ("throwaway"
1327        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1328       ("persistent"
1329        (let* ((existing-certificates (elpher-list-existing-certificates))
1330               (file-base (completing-read
1331                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1332                           existing-certificates)))
1333          (if (string-empty-p (string-trim file-base))
1334              nil
1335            (if (member file-base existing-certificates)
1336                (setq elpher-client-certificate
1337                      (elpher-get-existing-certificate file-base))
1338              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1339                                  '(("new" ?n
1340                                     "generate new certificate")
1341                                    ("install" ?i
1342                                     "install existing certificate")
1343                                    ("abort" ?a
1344                                     "stop immediately")))
1345                ("new"
1346                 (let ((common-name (read-string "Common Name field for new certificate: "
1347                                                 file-base)))
1348                   (message "New key and self-signed certificate written to %s"
1349                            elpher-certificate-directory)
1350                   (elpher-generate-persistent-certificate file-base common-name)))
1351                ("install"
1352                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1353                        (key-file (read-file-name "Key file: " nil nil t)))
1354                   (message "Key and certificate installed in %s for future use"
1355                            elpher-certificate-directory)
1356                   (elpher-install-and-use-existing-certificate key-file
1357                                                                cert-file
1358                                                                file-base)))
1359                ("abort" nil))))))
1360       ("abort" nil))))
1361
1362 (defun elpher-get-gemini-page (renderer)
1363   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1364   (let* ((address (elpher-page-address elpher-current-page))
1365          (content (elpher-get-cached-content address)))
1366     (condition-case the-error
1367         (if (and content (funcall renderer nil))
1368             (elpher-with-clean-buffer
1369              (insert content)
1370              (elpher-restore-pos))
1371           (elpher-with-clean-buffer
1372            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1373           (setq elpher-gemini-redirect-chain nil)
1374           (elpher-get-gemini-response address renderer))
1375       (error
1376        (elpher-network-error address the-error)))))
1377
1378 (defun elpher-render-gemini (body &optional mime-type-string)
1379   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1380   (if (not body)
1381       t
1382     (let* ((mime-type-string* (if (or (not mime-type-string)
1383                                       (string-empty-p mime-type-string))
1384                                   "text/gemini; charset=utf-8"
1385                                 mime-type-string))
1386            (mime-type-split (split-string mime-type-string* ";" t))
1387            (mime-type (string-trim (car mime-type-split)))
1388            (parameters (mapcar (lambda (s)
1389                                  (let ((key-val (split-string s "=")))
1390                                    (list (downcase (string-trim (car key-val)))
1391                                          (downcase (string-trim (cadr key-val))))))
1392                                (cdr mime-type-split))))
1393       (when (string-prefix-p "text/" mime-type)
1394         (setq body (decode-coding-string
1395                     body
1396                     (if (assoc "charset" parameters)
1397                         (intern (cadr (assoc "charset" parameters)))
1398                       'utf-8)))
1399         (setq body (replace-regexp-in-string "\r" "" body)))
1400       (pcase mime-type
1401         ((or "text/gemini" "")
1402          (elpher-render-gemini-map body parameters))
1403         ("text/html"
1404          (elpher-render-html body))
1405         ((pred (string-prefix-p "text/"))
1406          (elpher-render-gemini-plain-text body parameters))
1407         ((pred (string-prefix-p "image/"))
1408          (elpher-render-image body))
1409         (_other
1410          (elpher-render-download body))))))
1411
1412 (defun elpher-gemini-get-link-url (link-line)
1413   "Extract the url portion of LINK-LINE, a gemini map file link line.
1414 Returns nil in the event that the contents of the line following the
1415 => prefix are empty."
1416   (let ((l (split-string (substring link-line 2))))
1417     (if l
1418         (string-trim (elt l 0))
1419       nil)))
1420
1421 (defun elpher-gemini-get-link-display-string (link-line)
1422   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1423 Returns the url portion in the event that the display-string portion is empty."
1424   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1425          (idx (string-match "[ \t]" rest)))
1426     (string-trim (if idx
1427                      (substring rest (+ idx 1))
1428                    rest))))
1429
1430 (defun elpher-collapse-dot-sequences (filename)
1431   "Collapse dot sequences in FILENAME.
1432 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1433   (let* ((path (split-string filename "/"))
1434          (path-reversed-normalized
1435           (seq-reduce (lambda (a b)
1436                         (cond ((and a (equal b "..") (cdr a)))
1437                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1438                               ((equal b ".") a)
1439                               (t (cons b a))))
1440                       path nil)))
1441     (string-join (reverse path-reversed-normalized) "/")))
1442
1443 (defun elpher-address-from-gemini-url (url)
1444   "Extract address from URL with defaults as per gemini map files.
1445 While there's obviously some redundancy here between this function and
1446 `elpher-address-from-url', gemini map file URLs require enough special
1447 treatment that a separate function is warranted."
1448   (let ((address (url-generic-parse-url url))
1449         (current-address (elpher-page-address elpher-current-page)))
1450     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1451       (setf (url-fullness address) t)
1452       (if (url-host address) ;if there is an explicit host, filenames are absolute
1453           (if (string-empty-p (url-filename address))
1454               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1455         (setf (url-host address) (url-host current-address))
1456         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1457         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1458           (setf (url-filename address)
1459                 (concat (file-name-directory (url-filename current-address))
1460                         (url-filename address)))))
1461       (unless (url-type address)
1462         (setf (url-type address) (url-type current-address)))
1463       (when (equal (url-type address) "gemini")
1464         (setf (url-filename address)
1465               (elpher-collapse-dot-sequences (url-filename address)))))
1466     (elpher-remove-redundant-ports address)))
1467
1468 (defun elpher-gemini-insert-link (link-line)
1469   "Insert link described by LINK-LINE into a text/gemini document."
1470   (let* ((url (elpher-gemini-get-link-url link-line))
1471          (display-string (elpher-gemini-get-link-display-string link-line))
1472          (address (elpher-address-from-gemini-url url))
1473          (type (if address (elpher-address-type address) nil))
1474          (type-map-entry (cdr (assoc type elpher-type-map))))
1475     (when display-string
1476       (insert elpher-gemini-link-string)
1477       (if type-map-entry
1478           (let* ((face (elt type-map-entry 3))
1479                  (filtered-display-string (elpher-color-filter-apply display-string))
1480                  (page (elpher-make-page filtered-display-string address)))
1481             (insert-text-button filtered-display-string
1482                                 'face face
1483                                 'elpher-page page
1484                                 'action #'elpher-click-link
1485                                 'follow-link t
1486                                 'help-echo #'elpher--page-button-help))
1487         (insert (propertize display-string 'face 'elpher-unknown)))
1488       (insert "\n"))))
1489
1490 (defvar elpher--gemini-page-headings nil
1491   "List of headings on the page.")
1492
1493 (defun elpher-gemini-insert-header (header-line)
1494   "Insert header described by HEADER-LINE into a text/gemini document.
1495 The gemini map file line describing the header is given
1496 by HEADER-LINE."
1497   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1498     (let* ((level (length (match-string 1 header-line)))
1499            (header (substring header-line (match-end 0)))
1500            (face (pcase level
1501                    (1 'elpher-gemini-heading1)
1502                    (2 'elpher-gemini-heading2)
1503                    (3 'elpher-gemini-heading3)
1504                    (_ 'default)))
1505            (fill-column (if (display-graphic-p)
1506                             (/ (* fill-column
1507                                   (font-get (font-spec :name (face-font 'default)) :size))
1508                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1509       (setq elpher--gemini-page-headings (cons (cons header (point))
1510                                                elpher--gemini-page-headings))
1511       (unless (display-graphic-p)
1512         (insert (make-string level ?#) " "))
1513       (insert (propertize header 'face face))
1514       (newline))))
1515
1516 (defun elpher-gemini-insert-text (text-line)
1517   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1518 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1519 width defined by `elpher-gemini-max-fill-width'."
1520   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1521   (let* ((line-prefix (match-string 2 text-line))
1522          (processed-text-line
1523           (if line-prefix
1524               (cond ((string-prefix-p "*" line-prefix)
1525                      (concat
1526                       (replace-regexp-in-string "\\*"
1527                                                 elpher-gemini-bullet-string
1528                                                 (match-string 0 text-line))
1529                       (substring text-line (match-end 0))))
1530                     ((string-prefix-p ">" line-prefix)
1531                      (propertize text-line 'face 'elpher-gemini-quoted))
1532                     (t text-line))
1533             text-line))
1534          (adaptive-fill-mode t)
1535          ;; fill-prefix is important for adaptive-fill-mode: without
1536          ;; it, multi-line list items are not indented correct
1537          (fill-prefix (if (match-string 2 text-line)
1538                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1539                         nil)))
1540     (insert (elpher-process-text-for-display processed-text-line))
1541     (newline)))
1542
1543 (defun elpher-render-gemini-map (data _parameters)
1544   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1545   (elpher-with-clean-buffer
1546    (setq elpher--gemini-page-headings nil)
1547    (let ((preformatted nil))
1548      (auto-fill-mode 1)
1549      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1550      (dolist (line (split-string data "\n"))
1551        (cond
1552         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1553         (preformatted (insert (elpher-process-text-for-display
1554                                (propertize line 'face 'elpher-gemini-preformatted))
1555                               "\n"))
1556         ((string-prefix-p "=>" line)
1557          (elpher-gemini-insert-link line))
1558         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1559         (t (elpher-gemini-insert-text line)))))
1560    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1561    (elpher-cache-content
1562     (elpher-page-address elpher-current-page)
1563     (buffer-string))))
1564
1565 (defun elpher-render-gemini-plain-text (data _parameters)
1566   "Render DATA as plain text file.  PARAMETERS is currently unused."
1567   (elpher-with-clean-buffer
1568    (insert (elpher-process-text-for-display data))
1569    (elpher-cache-content
1570     (elpher-page-address elpher-current-page)
1571     (buffer-string))))
1572
1573
1574 ;; Finger page connection
1575
1576 (defun elpher-get-finger-page (renderer)
1577   "Opens a finger connection to the current page address.
1578 The result is rendered using RENDERER."
1579   (let* ((address (elpher-page-address elpher-current-page))
1580          (content (elpher-get-cached-content address)))
1581     (if (and content (funcall renderer nil))
1582         (elpher-with-clean-buffer
1583          (insert content)
1584          (elpher-restore-pos))
1585       (elpher-with-clean-buffer
1586        (insert "LOADING... (use 'u' to cancel)\n"))
1587       (condition-case the-error
1588           (let* ((kill-buffer-query-functions nil)
1589                  (user (let ((filename (elpher-address-filename address)))
1590                          (if (> (length filename) 1)
1591                              (substring filename 1)
1592                            (elpher-address-user address)))))
1593             (elpher-get-host-response address 79
1594                                       (concat user "\r\n")
1595                                       renderer))
1596         (error
1597          (elpher-network-error address the-error))))))
1598
1599
1600 ;; Telnet page connection
1601
1602 (defun elpher-get-telnet-page (renderer)
1603   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1604   (when renderer
1605     (elpher-visit-previous-page)
1606     (error "Command not supported for telnet URLs"))
1607   (let* ((address (elpher-page-address elpher-current-page))
1608          (host (elpher-address-host address))
1609          (port (elpher-address-port address)))
1610     (elpher-visit-previous-page)
1611     (if (> port 0)
1612         (telnet host port)
1613       (telnet host))))
1614
1615
1616 ;; Other URL page opening
1617
1618 (defun elpher-get-other-url-page (renderer)
1619   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1620   (when renderer
1621     (elpher-visit-previous-page)
1622     (error "Command not supported for general URLs"))
1623   (let* ((address (elpher-page-address elpher-current-page))
1624          (url (elpher-address-to-url address)))
1625     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1626     (message "Opening URL...")
1627     (if elpher-open-urls-with-eww
1628         (browse-web url)
1629       (browse-url url))))
1630
1631 ;; File page
1632
1633 (defun elpher-get-file-page (renderer)
1634   "Getter which renders a local file using RENDERER.
1635 Assumes UTF-8 encoding for all text files."
1636   (let* ((address (elpher-page-address elpher-current-page))
1637          (filename (elpher-address-filename address)))
1638     (unless (file-exists-p filename)
1639       (elpher-visit-previous-page)
1640         (error "File not found"))
1641     (unless (file-readable-p filename)
1642       (elpher-visit-previous-page)
1643         (error "Could not read from file"))
1644     (let ((body (with-temp-buffer
1645        (let ((coding-system-for-read 'binary)
1646              (coding-system-for-write 'binary))
1647          (insert-file-contents-literally filename)
1648          (encode-coding-string (buffer-string) 'raw-text)))))
1649        (if renderer
1650            (funcall renderer body nil)
1651          (pcase (file-name-extension filename)
1652            ((or  "gmi" "gemini")
1653             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1654            ((or "htm" "html")
1655             (elpher-render-html (decode-coding-string body 'utf-8)))
1656            ((or "txt" "")
1657             (elpher-render-text (decode-coding-string body 'utf-8)))
1658            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1659             (elpher-render-image body))
1660            (_
1661             (elpher-render-download body))))
1662        (elpher-restore-pos))))
1663
1664
1665 ;; Welcome page retrieval
1666
1667 (defun elpher-get-welcome-page (renderer)
1668   "Getter which displays the welcome page (RENDERER must be nil)."
1669   (when renderer
1670     (elpher-visit-previous-page)
1671     (error "Command not supported for welcome page"))
1672   (elpher-with-clean-buffer
1673    (insert "     --------------------------------------------\n"
1674            "           Elpher Gopher and Gemini Client       \n"
1675            "                   version " elpher-version "\n"
1676            "     --------------------------------------------\n"
1677            "\n"
1678            "Default bindings:\n"
1679            "\n"
1680            " - TAB/Shift-TAB: next/prev item on current page\n"
1681            " - RET/mouse-1: open item under cursor\n"
1682            " - m: select an item on current page by name (autocompletes)\n"
1683            " - u/mouse-3/U: return to previous page or to the start page\n"
1684            " - g: go to a particular address (gopher, gemini, finger)\n"
1685            " - o/O: open a different address selector or the root menu of the current server\n"
1686            " - d/D: download item under cursor or current page\n"
1687            " - i/I: info on item under cursor or current page\n"
1688            " - c/C: copy URL representation of item under cursor or current page\n"
1689            " - a/A: bookmark the item under cursor or current page\n"
1690            " - B: list all bookmarks\n"
1691            " - s/S: show current history stack or all previously visted pages\n"
1692            " - r: redraw current page (using cached contents if available)\n"
1693            " - R: reload current page (regenerates cache)\n"
1694            " - !: set character coding system for gopher (default is to autodetect)\n"
1695            " - T: toggle TLS gopher mode\n"
1696            " - F: forget/discard current TLS client certificate\n"
1697            " - .: display the raw server response for the current page\n"
1698            "\n"
1699            "Start your exploration of gopher space and gemini:\n")
1700    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1701                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1702    (elpher-insert-index-record "Project Gemini home page"
1703                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1704    (insert "\n"
1705            "Alternatively, select a search engine and enter some search terms:\n")
1706    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1707                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1708    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1709                                (elpher-address-from-url "gemini://geminispace.info/search"))
1710    (insert "\n"
1711            "Your bookmarks are stored in your ")
1712    (let ((help-string "RET,mouse-1: Open bookmark list"))
1713      (insert-text-button "bookmark list"
1714                          'face 'link
1715                          'action (lambda (_)
1716                                    (interactive)
1717                                    (call-interactively #'elpher-show-bookmarks))
1718                          'follow-link t
1719                          'help-echo help-string))
1720    (insert ".\n")
1721    (insert (propertize
1722             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1723             'face 'shadow))
1724    (insert "\n"
1725            "The gopher home of the Elpher project is here:\n")
1726    (elpher-insert-index-record "The Elpher Project Page"
1727                                (elpher-make-gopher-address ?1
1728                                                            "/projects/elpher/"
1729                                                            "thelambdalab.xyz"
1730                                                            70))
1731    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1732      (insert "\n"
1733              "The following info documentation is available:\n"
1734              "   - ")
1735      (insert-text-button "Elpher Manual"
1736                          'face 'link
1737                          'action (lambda (_)
1738                                    (interactive)
1739                                    (info "(elpher)"))
1740                          'follow-link t
1741                          'help-echo help-string)
1742      (insert "\n   - ")
1743      (insert-text-button "Changes introduced by the latest release"
1744                        'face 'link
1745                        'action (lambda (_)
1746                                  (interactive)
1747                                  (info "(elpher)News"))
1748                        'follow-link t
1749                        'help-echo help-string))
1750    (insert "\n")
1751    (insert (propertize
1752             (concat "(These documents should be available if you have installed Elpher \n"
1753                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1754             'face 'shadow))
1755    (elpher-restore-pos)))
1756
1757 ;; History page retrieval
1758
1759 (defun elpher-show-history ()
1760   "Show the current contents of elpher's history stack.
1761 Use \\[elpher-show-visited-pages] to see the entire history.
1762 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1763   (interactive)
1764   (elpher-visit-page
1765    (elpher-make-page "Current History Stack"
1766                      (elpher-make-about-address 'history))))
1767
1768 (defun elpher-show-visited-pages ()
1769   "Show the all the pages you've visited using Elpher.
1770 Use \\[elpher-show-history] to see just the current history stack.
1771 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1772   (interactive)
1773   (elpher-visit-page
1774    (elpher-make-page "Elpher Visted Pages"
1775                      (elpher-make-about-address 'visited-pages))))
1776
1777 (defun elpher-get-history-page (renderer)
1778   "Getter which displays the history page (RENDERER must be nil)."
1779   (when renderer
1780     (elpher-visit-previous-page)
1781     (error "Command not supported for history page"))
1782   (elpher-display-history-links elpher-history "Current history stack"))
1783
1784 (defun elpher-get-visited-pages-page (renderer)
1785   "Getter which displays the list of visited pages (RENDERER must be nil)."
1786   (when renderer
1787     (elpher-visit-previous-page)
1788     (error "Command not supported for history page"))
1789   (elpher-display-history-links
1790    (seq-filter (lambda (page)
1791                  (not (elpher-address-about-p (elpher-page-address page))))
1792                elpher-visited-pages)
1793    "All visited pages"))
1794
1795 (defun elpher-display-history-links (pages title)
1796   "Show all PAGES in an Elpher buffer with a given TITLE."
1797   (let* ((title-line (concat " ---- " title " ----"))
1798          (footer-line (make-string (length title-line) ?-)))
1799     (elpher-with-clean-buffer
1800      (insert title-line "\n\n")
1801      (if pages
1802          (dolist (page pages)
1803            (when page
1804              (let ((display-string (elpher-page-display-string page))
1805                    (address (elpher-page-address page)))
1806                (elpher-insert-index-record display-string address))))
1807        (insert "No history items found.\n"))
1808      (insert "\n " footer-line "\n"
1809              "Select an entry or press 'u' to return to the previous page.")
1810      (elpher-restore-pos))))
1811
1812
1813 ;;; Bookmarks
1814
1815 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1816 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1817 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1818 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1819
1820 (defvar elpher-bookmark-link nil
1821   "Prefer bookmarking a link or the current page.
1822 Bind this variable dynamically, or set it to t.
1823 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1824 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1825
1826 (defun elpher-bookmark-make-record ()
1827   "Return a bookmark record.
1828 If `elpher-bookmark-link' is non-nil and point is on a link button,
1829 return a bookmark record for that link.  Otherwise, return a bookmark
1830 record for the current elpher page."
1831   (let* ((button (and elpher-bookmark-link (button-at (point))))
1832          (page (if button
1833                    (button-get button 'elpher-page)
1834                  elpher-current-page))
1835          (address (elpher-page-address page))
1836          (url (elpher-address-to-url address))
1837          (display-string (elpher-page-display-string page))
1838          (pos (if button nil (point))))
1839     (if (elpher-address-about-p address)
1840         (error "Cannot bookmark %s" display-string)
1841       `(,display-string
1842         (defaults . (,display-string))
1843         (position . ,pos)
1844         (location . ,url)
1845         (handler . elpher-bookmark-jump)))))
1846
1847 ;;;###autoload
1848 (defun elpher-bookmark-jump (bookmark)
1849   "Handler used to open a bookmark using elpher.
1850 The argument BOOKMARK is a bookmark record passed to the function.
1851 This handler is responsible for loading the bookmark in some buffer,
1852 then making that buffer the current buffer.  It should not switch
1853 to the buffer."
1854   (let* ((url (cdr (assq 'location bookmark)))
1855          (cleaned-url (string-trim url))
1856          (address (elpher-address-from-url cleaned-url))
1857          (page (elpher-make-page cleaned-url address)))
1858     (elpher-with-clean-buffer
1859      (elpher-visit-page page))
1860     (set-buffer (get-buffer elpher-buffer-name))
1861     nil))
1862
1863 (defun elpher-bookmark-link ()
1864   "Bookmark the link at point.
1865 To bookmark the current page, use \\[elpher-bookmark-current]."
1866   (interactive)
1867   (let ((elpher-bookmark-link t))
1868     (bookmark-set-no-overwrite)))
1869
1870 (defun elpher-bookmark-current ()
1871   "Bookmark the current page.
1872 To bookmark the link at point use \\[elpher-bookmark-link]."
1873   (interactive)
1874   (call-interactively #'bookmark-set-no-overwrite))
1875
1876 (defun elpher-bookmark-import (file)
1877   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1878   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1879                               (file-readable-p elpher-bookmarks-file))
1880                          elpher-bookmarks-file
1881                        (read-file-name "Old Elpher bookmarks: "
1882                                        user-emacs-directory nil t
1883                                        "elpher-bookmarks"))))
1884   (dolist (bookmark (with-temp-buffer
1885                       (insert-file-contents file)
1886                       (read (current-buffer))))
1887     (let* ((display-string (car bookmark))
1888            (url (cadr bookmark))
1889            (record `(,display-string
1890                      (location . ,url)
1891                      (handler . elpher-bookmark-jump))))
1892       (bookmark-store display-string (cdr record) t)))
1893   (bookmark-save))
1894
1895 (defun elpher-get-bookmarks-page (renderer)
1896   "Getter which displays the bookmarks (RENDERER must be nil)."
1897   (when renderer
1898     (elpher-visit-previous-page)
1899     (error "Command not supported for bookmarks page"))
1900
1901   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1902                                      elpher-bookmarks-file)
1903                                 (locate-user-emacs-file "elpher-bookmarks"))))
1904     (when (and (file-readable-p old-bookmarks-file)
1905                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1906                                  old-bookmarks-file
1907                                  "\" found. Import now?")))
1908       (elpher-bookmark-import old-bookmarks-file)
1909       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1910
1911   (if (and elpher-use-emacs-bookmark-menu
1912            elpher-history)
1913       (progn
1914         (elpher-visit-previous-page)
1915         (call-interactively #'bookmark-bmenu-list))
1916     (elpher-with-clean-buffer
1917      (insert " ---- Elpher Bookmarks ---- \n\n")
1918      (bookmark-maybe-load-default-file)
1919      (dolist (bookmark (bookmark-maybe-sort-alist))
1920        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1921          (let* ((name (car bookmark))
1922                 (url (alist-get 'location (cdr bookmark)))
1923                 (address (elpher-address-from-url url)))
1924            (elpher-insert-index-record name address))))
1925      (when (<= (line-number-at-pos) 3)
1926        (insert "No bookmarked pages found.\n"))
1927      (insert "\n --------------------------\n\n"
1928              "Select an entry or press 'u' to return to the previous page.\n\n"
1929              "Bookmarks can be renamed or deleted via the ")
1930      (insert-text-button "Emacs bookmark menu"
1931                          'action (lambda (_)
1932                                    (interactive)
1933                                    (call-interactively #'bookmark-bmenu-list))
1934                          'follow-link t
1935                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
1936      (insert (substitute-command-keys
1937               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1938      (elpher-restore-pos))))
1939
1940 (defun elpher-show-bookmarks ()
1941   "Interactive function to display the current list of elpher bookmarks."
1942   (interactive)
1943   (elpher-visit-page
1944    (elpher-make-page "Elpher Bookmarks"
1945                      (elpher-make-about-address 'bookmarks))))
1946
1947
1948 ;;; Integrations
1949 ;;
1950
1951 ;;; Org
1952
1953 (defun elpher-org-export-link (link description format protocol)
1954   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1955
1956 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1957 of gemini, gopher or finger."
1958   (let* ((url (if (equal protocol "elpher")
1959                   (string-remove-prefix "elpher:" link)
1960                 (format "%s:%s" protocol link)))
1961          (desc (or description url)))
1962     (pcase format
1963       (`gemini (format "=> %s %s" url desc))
1964       (`html (format "<a href=\"%s\">%s</a>" url desc))
1965       (`latex (format "\\href{%s}{%s}" url desc))
1966       (_ (if (not description)
1967              url
1968            (format "%s (%s)" desc url))))))
1969
1970 (defun elpher-org-store-link ()
1971   "Store link to an `elpher' page in Org."
1972   (when (eq major-mode 'elpher-mode)
1973     (let* ((url (elpher-info-current))
1974            (desc (car elpher-current-page))
1975            (protocol (cond
1976                       ((string-prefix-p "gemini:" url) "gemini")
1977                       ((string-prefix-p "gopher:" url) "gopher")
1978                       ((string-prefix-p "finger:" url) "finger")
1979                       (t "elpher"))))
1980       (when (equal "elpher" protocol)
1981         ;; Weird link. Or special inner link?
1982         (setq url (concat "elpher:" url)))
1983       (org-link-store-props :type protocol :link url :description desc)
1984       t)))
1985
1986 (defun elpher-org-follow-link (link protocol)
1987   "Visit a LINK for the given PROTOCOL.
1988
1989 PROTOCOL may be one of gemini, gopher or finger.  This method also
1990 supports the old protocol elpher, where the link is self-contained."
1991   (let ((url (if (equal protocol "elpher")
1992                  (string-remove-prefix "elpher:" link)
1993                (format "%s:%s" protocol link))))
1994     (elpher-go url)))
1995
1996 (defun elpher-org-mode-integration ()
1997   "Set up `elpher' integration for `org-mode'."
1998   (org-link-set-parameters
1999    "elpher"
2000    :store #'elpher-org-store-link
2001    :export (lambda (link description format _plist)
2002              (elpher-org-export-link link description format "elpher"))
2003    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2004   (org-link-set-parameters
2005    "gemini"
2006    :export (lambda (link description format _plist)
2007              (elpher-org-export-link link description format "gemini"))
2008    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2009   (org-link-set-parameters
2010    "gopher"
2011    :export (lambda (link description format _plist)
2012              (elpher-org-export-link link description format "gopher"))
2013    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2014   (org-link-set-parameters
2015    "finger"
2016    :export (lambda (link description format _plist)
2017              (elpher-org-export-link link description format "finger"))
2018    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2019
2020 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2021
2022 ;;; Browse URL
2023
2024 ;;;###autoload
2025 (defun elpher-browse-url-elpher (url &rest _args)
2026   "Browse URL using Elpher.  This function is used by `browse-url'."
2027   (interactive (browse-url-interactive-arg "Elpher URL: "))
2028   (elpher-go url))
2029
2030 ;; Use elpher to open gopher, finger and gemini links
2031 ;; For recent version of `browse-url' package
2032 (if (boundp 'browse-url-default-handlers)
2033     (add-to-list
2034      'browse-url-default-handlers
2035      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2036   ;; Patch `browse-url-browser-function' for older ones. The value of
2037   ;; that variable is `browse-url-default-browser' by default, so
2038   ;; that's the function that gets advised.
2039   (advice-add browse-url-browser-function :before-while
2040               (lambda (url &rest _args)
2041                 "Handle gemini, gopher, and finger schemes using Elpher."
2042                 (let ((scheme (downcase (car (split-string url ":" t)))))
2043                   (if (member scheme '("gemini" "gopher" "finger"))
2044                       ;; `elpher-go' always returns nil, which will stop the
2045                       ;; advice chain here in a before-while
2046                       (elpher-go url)
2047                     ;; chain must continue, then return t.
2048                     t)))))
2049
2050 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2051 (with-eval-after-load 'thingatpt
2052   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2053
2054 ;;; Mu4e:
2055
2056 ;; Make mu4e aware of the gemini world
2057 (setq mu4e~view-beginning-of-url-regexp
2058       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2059
2060 ;;; eww:
2061
2062 ;; Let elpher handle gemini, gopher links in eww buffer.
2063 (setq eww-use-browse-url
2064       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2065
2066
2067 ;;; Interactive procedures
2068 ;;
2069
2070 (defun elpher-next-link ()
2071   "Move point to the next link on the current page."
2072   (interactive)
2073   (forward-button 1))
2074
2075 (defun elpher-prev-link ()
2076   "Move point to the previous link on the current page."
2077   (interactive)
2078   (backward-button 1))
2079
2080 (defun elpher-follow-current-link ()
2081   "Open the link or url at point."
2082   (interactive)
2083   (push-button))
2084
2085 ;;;###autoload
2086 (defun elpher-go (host-or-url)
2087   "Go to a particular gopher site HOST-OR-URL.
2088 When run interactively HOST-OR-URL is read from the minibuffer."
2089   (interactive "sGopher or Gemini URL: ")
2090   (let ((trimmed-host-or-url (string-trim host-or-url)))
2091     (unless (string-empty-p trimmed-host-or-url)
2092       (let* ((address (elpher-address-from-url trimmed-host-or-url))
2093              (page (elpher-make-page trimmed-host-or-url address)))
2094         (switch-to-buffer elpher-buffer-name)
2095         (elpher-with-clean-buffer
2096          (elpher-visit-page page))
2097         nil)))) ; non-nil value is displayed by eshell
2098
2099 (defun elpher-go-current ()
2100   "Go to a particular site read from the minibuffer, initialized with the current URL."
2101   (interactive)
2102   (let* ((address (elpher-page-address elpher-current-page))
2103          (url (read-string "Gopher or Gemini URL: "
2104                            (unless (elpher-address-about-p address)
2105                              (elpher-address-to-url address)))))
2106     (unless (string-empty-p (string-trim url))
2107       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
2108
2109 (defun elpher-redraw ()
2110   "Redraw current page."
2111   (interactive)
2112   (elpher-visit-page elpher-current-page))
2113
2114 (defun elpher-reload ()
2115   "Reload current page."
2116   (interactive)
2117   (elpher-reload-current-page))
2118
2119 (defun elpher-toggle-tls ()
2120   "Toggle TLS encryption mode for gopher."
2121   (interactive)
2122   (setq elpher-use-tls (not elpher-use-tls))
2123   (if elpher-use-tls
2124       (if (gnutls-available-p)
2125           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2126         (setq elpher-use-tls nil)
2127         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2128     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2129
2130 (defun elpher-view-raw ()
2131   "View raw server response for current page."
2132   (interactive)
2133   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2134       (error "This page was not generated by a server")
2135     (elpher-visit-page elpher-current-page
2136                        #'elpher-render-raw)))
2137
2138 (defun elpher-back ()
2139   "Go to previous site."
2140   (interactive)
2141   (elpher-visit-previous-page))
2142
2143 (defun elpher-back-to-start ()
2144   "Go all the way back to the start page."
2145   (interactive)
2146   (setq-local elpher-current-page nil)
2147   (setq-local elpher-history nil)
2148   (elpher-visit-page (elpher-make-start-page)))
2149
2150 (defun elpher-download ()
2151   "Download the link at point."
2152   (interactive)
2153   (let ((button (button-at (point))))
2154     (if button
2155         (let ((page (button-get button 'elpher-page)))
2156           (unless page
2157             (error "Not an elpher page"))
2158           (when (elpher-address-about-p (elpher-page-address page))
2159             (error "Cannot download %s" (elpher-page-display-string page)))
2160           (elpher-visit-page (button-get button 'elpher-page)
2161                              #'elpher-render-download))
2162       (error "No link selected"))))
2163
2164 (defun elpher-download-current ()
2165   "Download the current page."
2166   (interactive)
2167   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2168       (error "Cannot download %s"
2169              (elpher-page-display-string elpher-current-page))
2170     (elpher-visit-page (elpher-make-page
2171                         (elpher-page-display-string elpher-current-page)
2172                         (elpher-page-address elpher-current-page))
2173                        #'elpher-render-download
2174                        t)))
2175
2176 (defun elpher--build-link-map ()
2177   "Build alist mapping link names to destination pages in current buffer."
2178   (let ((link-map nil)
2179         (b (next-button (point-min) t)))
2180     (while b
2181       (push (cons (button-label b) b) link-map)
2182       (setq b (next-button (button-start b))))
2183     link-map))
2184
2185 (defun elpher-jump ()
2186   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2187   (interactive)
2188   (let* ((link-map (elpher--build-link-map)))
2189     (if link-map
2190         (let ((key (let ((completion-ignore-case t))
2191                      (completing-read "Directory item/link: "
2192                                       link-map nil t))))
2193           (if (and key (> (length key) 0))
2194               (let ((b (cdr (assoc key link-map))))
2195                 (goto-char (button-start b))
2196                 (button-activate b)))))))
2197
2198 (defun elpher-root-dir ()
2199   "Visit root of current server."
2200   (interactive)
2201   (let ((address (elpher-page-address elpher-current-page)))
2202     (if (not (elpher-address-about-p address))
2203         (if (or (member (url-filename address) '("/" ""))
2204                 (and (elpher-address-gopher-p address)
2205                      (= (length (elpher-gopher-address-selector address)) 0)))
2206             (error "Already at root directory of current server")
2207           (let ((address-copy (elpher-address-from-url
2208                                (elpher-address-to-url address))))
2209             (setf (url-filename address-copy) "")
2210             (elpher-go (elpher-address-to-url address-copy))))
2211       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2212
2213 (defun elpher-info-page (page)
2214   "Display URL of PAGE in minibuffer."
2215   (let ((address (elpher-page-address page)))
2216     (message "%s" (elpher-address-to-url address))))
2217
2218 (defun elpher-info-link ()
2219   "Display information on page corresponding to link at point."
2220   (interactive)
2221   (let ((button (button-at (point))))
2222     (unless button
2223       (error "No item selected"))
2224     (let ((page (button-get button 'elpher-page)))
2225       (unless page
2226         (error "Not an elpher page"))
2227       (elpher-info-page page))))
2228
2229 (defun elpher-info-current ()
2230   "Display information on current page."
2231   (interactive)
2232   (elpher-info-page elpher-current-page))
2233
2234 (defun elpher-copy-page-url (page)
2235   "Copy URL representation of address of PAGE to `kill-ring'."
2236   (let* ((address (elpher-page-address page))
2237          (url (elpher-address-to-url address)))
2238     (message "Copied \"%s\" to kill-ring/clipboard." url)
2239     (kill-new url)))
2240
2241 (defun elpher-copy-link-url ()
2242   "Copy URL of item at point to `kill-ring'."
2243   (interactive)
2244   (let ((button (button-at (point))))
2245     (unless button
2246       (error "No item selected"))
2247     (let ((page (button-get button 'elpher-page)))
2248       (unless page
2249         (error "Not an elpher page"))
2250       (elpher-copy-page-url page))))
2251
2252 (defun elpher-copy-current-url ()
2253   "Copy URL of current page to `kill-ring'."
2254   (interactive)
2255   (elpher-copy-page-url elpher-current-page))
2256
2257 (defun elpher-set-gopher-coding-system ()
2258   "Specify an explicit character coding system for gopher selectors."
2259   (interactive)
2260   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2261     (setq elpher-user-coding-system system)
2262     (if system
2263         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2264       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2265
2266
2267 ;;; Mode and keymap
2268 ;;
2269
2270 (defvar elpher-mode-map
2271   (let ((map (make-sparse-keymap)))
2272     (define-key map (kbd "TAB") 'elpher-next-link)
2273     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2274     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2275     (define-key map (kbd "u") 'elpher-back)
2276     (define-key map (kbd "-") 'elpher-back)
2277     (define-key map (kbd "^") 'elpher-back)
2278     (define-key map [mouse-3] 'elpher-back)
2279     (define-key map (kbd "U") 'elpher-back-to-start)
2280     (define-key map (kbd "g") 'elpher-go)
2281     (define-key map (kbd "o") 'elpher-go-current)
2282     (define-key map (kbd "O") 'elpher-root-dir)
2283     (define-key map (kbd "s") 'elpher-show-history)
2284     (define-key map (kbd "S") 'elpher-show-visited-pages)
2285     (define-key map (kbd "r") 'elpher-redraw)
2286     (define-key map (kbd "R") 'elpher-reload)
2287     (define-key map (kbd "T") 'elpher-toggle-tls)
2288     (define-key map (kbd ".") 'elpher-view-raw)
2289     (define-key map (kbd "d") 'elpher-download)
2290     (define-key map (kbd "D") 'elpher-download-current)
2291     (define-key map (kbd "m") 'elpher-jump)
2292     (define-key map (kbd "i") 'elpher-info-link)
2293     (define-key map (kbd "I") 'elpher-info-current)
2294     (define-key map (kbd "c") 'elpher-copy-link-url)
2295     (define-key map (kbd "C") 'elpher-copy-current-url)
2296     (define-key map (kbd "a") 'elpher-bookmark-link)
2297     (define-key map (kbd "A") 'elpher-bookmark-current)
2298     (define-key map (kbd "B") 'elpher-show-bookmarks)
2299     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2300     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2301     (when (fboundp 'evil-define-key*)
2302       (evil-define-key*
2303        'motion map
2304        (kbd "TAB") 'elpher-next-link
2305        (kbd "C-") 'elpher-follow-current-link
2306        (kbd "C-t") 'elpher-back
2307        (kbd "u") 'elpher-back
2308        (kbd "-") 'elpher-back
2309        (kbd "^") 'elpher-back
2310        [mouse-3] 'elpher-back
2311        (kbd "U") 'elpher-back-to-start
2312        (kbd "g") 'elpher-go
2313        (kbd "o") 'elpher-go-current
2314        (kbd "O") 'elpher-root-dir
2315        (kbd "s") 'elpher-show-history
2316        (kbd "S") 'elpher-show-visited-pages
2317        (kbd "r") 'elpher-redraw
2318        (kbd "R") 'elpher-reload
2319        (kbd "T") 'elpher-toggle-tls
2320        (kbd ".") 'elpher-view-raw
2321        (kbd "d") 'elpher-download
2322        (kbd "D") 'elpher-download-current
2323        (kbd "m") 'elpher-jump
2324        (kbd "i") 'elpher-info-link
2325        (kbd "I") 'elpher-info-current
2326        (kbd "c") 'elpher-copy-link-url
2327        (kbd "C") 'elpher-copy-current-url
2328        (kbd "a") 'elpher-bookmark-link
2329        (kbd "A") 'elpher-bookmark-current
2330        (kbd "B") 'elpher-show-bookmarks
2331        (kbd "!") 'elpher-set-gopher-coding-system
2332        (kbd "F") 'elpher-forget-current-certificate))
2333     map)
2334   "Keymap for gopher client.")
2335
2336 (define-derived-mode elpher-mode special-mode "elpher"
2337   "Major mode for elpher, an elisp gopher client.
2338
2339 This mode is automatically enabled by the interactive
2340 functions which initialize the client, namely
2341 `elpher', and `elpher-go'."
2342   (setq-local elpher--gemini-page-headings nil)
2343   (setq-local elpher-current-page nil)
2344   (setq-local elpher-history nil)
2345   (setq-local elpher-buffer-name (buffer-name))
2346   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2347   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2348   (setq-local xterm-color-preserve-properties t))
2349
2350 (when (fboundp 'evil-set-initial-state)
2351   (evil-set-initial-state 'elpher-mode 'motion))
2352
2353
2354 ;;; Main start procedure
2355 ;;
2356
2357 ;;;###autoload
2358 (defun elpher (&optional arg)
2359   "Start elpher with default landing page.
2360 The buffer used for Elpher sessions is determined by the value of
2361 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2362 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2363 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2364 \\[execute-extended-command] elpher RET’) switches to the session with
2365 that number, creating it if necessary.  A non numeric prefix ARG means
2366 to create a new session.  Returns the buffer selected (or created)."
2367   (interactive "P")
2368   (let* ((name (default-value 'elpher-buffer-name))
2369          (buf (cond ((numberp arg)
2370                      (get-buffer-create (format "%s<%d>" name arg)))
2371                     (arg
2372                      (generate-new-buffer name))
2373                     (t
2374                      (get-buffer-create name)))))
2375     (pop-to-buffer-same-window buf)
2376     (unless (buffer-modified-p)
2377       (elpher-mode)
2378       (elpher-visit-page (elpher-make-start-page))
2379       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2380
2381 ;;; elpher.el ends here