elpher.el

   1 ;;; elpher.el --- A friendly gopher client.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.3.5
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption,
  40 ;; - basic support for the fledgling Gemini protocol.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Full instructions can be found in the Elpher info manual.
  47
  48 ;; Elpher is under active development.  Any suggestions for
  49 ;; improvements are welcome!
  50
  51 ;;; Code:
  52
  53 (provide 'elpher)
  54
  55 ;;; Dependencies
  56 ;;
  57
  58 (require 'seq)
  59 (require 'pp)
  60 (require 'shr)
  61 (require 'url-util)
  62 (require 'subr-x)
  63
  64
  65 ;;; Global constants
  66 ;;
  67
  68 (defconst elpher-version "2.3.5"
  69   "Current version of elpher.")
  70
  71 (defconst elpher-margin-width 6
  72   "Width of left-hand margin used when rendering indicies.")
  73
  74 (defconst elpher-type-map
  75   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  76     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  77     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  78     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  79     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  80     ((gopher ?9) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  81     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  83     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  84     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  85     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  86     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  87     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  88     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  89     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  90     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  91     ((special bookmarks) elpher-get-bookmarks-node nil)
  92     ((special start) elpher-get-start-node nil))
  93   "Association list from types to getters, renderers, margin codes and index faces.")
  94
  95
  96 ;;; Customization group
  97 ;;
  98
  99 (defgroup elpher nil
 100   "A gopher client."
 101   :group 'applications)
 102
 103 ;; Face customizations
 104
 105 (defface elpher-index
 106   '((t :inherit font-lock-keyword-face))
 107   "Face used for directory type directory records.")
 108
 109 (defface elpher-text
 110   '((t :inherit bold))
 111   "Face used for text type directory records.")
 112
 113 (defface elpher-info
 114   '((t :inherit default))
 115   "Face used for info type directory records.")
 116
 117 (defface elpher-image
 118   '((t :inherit font-lock-string-face))
 119   "Face used for image type directory records.")
 120
 121 (defface elpher-search
 122   '((t :inherit warning))
 123   "Face used for search type directory records.")
 124
 125 (defface elpher-html
 126   '((t :inherit font-lock-comment-face))
 127   "Face used for html type directory records.")
 128
 129 (defface elpher-gemini
 130   '((t :inherit font-lock-regexp-grouping-backslash))
 131   "Face used for html type directory records.")
 132
 133 (defface elpher-other-url
 134   '((t :inherit font-lock-comment-face))
 135   "Face used for other URL type links records.")
 136
 137 (defface elpher-telnet
 138   '((t :inherit font-lock-function-name-face))
 139   "Face used for telnet type directory records.")
 140
 141 (defface elpher-binary
 142   '((t :inherit font-lock-doc-face))
 143   "Face used for binary type directory records.")
 144
 145 (defface elpher-unknown
 146   '((t :inherit error))
 147   "Face used for directory records with unknown/unsupported types.")
 148
 149 (defface elpher-margin-key
 150   '((t :inherit bold))
 151   "Face used for directory margin key.")
 152
 153 (defface elpher-margin-brackets
 154   '((t :inherit shadow))
 155   "Face used for brackets around directory margin key.")
 156
 157 ;; Other customizations
 158
 159 (defcustom elpher-open-urls-with-eww nil
 160   "If non-nil, open URL selectors using eww.
 161 Otherwise, use the system browser via the BROWSE-URL function."
 162   :type '(boolean))
 163
 164 (defcustom elpher-buttonify-urls-in-directories t
 165   "If non-nil, turns URLs matched in directories into clickable buttons."
 166   :type '(boolean))
 167
 168 (defcustom elpher-use-header t
 169   "If non-nil, display current node information in buffer header."
 170   :type '(boolean))
 171
 172 (defcustom elpher-auto-disengage-TLS nil
 173   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 174 While enabling this may seem convenient, it is also potentially dangerous as it
 175 allows switching from an encrypted channel back to plain text without user input."
 176   :type '(boolean))
 177
 178
 179 ;;; Model
 180 ;;
 181
 182 ;; Address
 183
 184 ;; An elpher "address" object is either a url object or a symbol.
 185 ;; Symbol addresses are "special", corresponding to pages generated
 186 ;; dynamically for and by elpher.  All others represent pages which
 187 ;; rely on content retrieved over the network.
 188
 189 (defun elpher-address-from-url (url-string)
 190   "Create a ADDRESS object corresponding to the given URL-STRING."
 191   (let ((data (match-data))) ; Prevent parsing clobbering match data
 192     (unwind-protect
 193         (let ((url (url-generic-parse-url url-string)))
 194           (unless (and (not (url-fullness url)) (url-type url))
 195             (setf (url-fullness url) t)
 196             (setf (url-filename url)
 197                   (url-unhex-string (url-filename url)))
 198             (unless (url-type url)
 199               (setf (url-type url) "gopher"))
 200             (when (or (equal "gopher" (url-type url))
 201                       (equal "gophers" (url-type url)))
 202               ;; Gopher defaults
 203               (unless (url-host url)
 204                 (setf (url-host url) (url-filename url))
 205                 (setf (url-filename url) ""))
 206               (when (or (equal (url-filename url) "")
 207                         (equal (url-filename url) "/"))
 208                 (setf (url-filename url) "/1")))
 209             (when (equal "gemini" (url-type url))
 210               ;; Gemini defaults
 211               (if (equal (url-filename url) "")
 212                   (setf (url-filename url) "/"))))
 213           url)
 214       (set-match-data data))))
 215
 216 (defun elpher-make-gopher-address (type selector host port &optional tls)
 217   "Create an ADDRESS object using gopher directory record attributes.
 218 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 219 If the optional attribute TLS is non-nil, the address will be marked as
 220 requiring gopher-over-TLS."
 221   (cond
 222    ((and (equal type ?h)
 223          (string-prefix-p "URL:" selector))
 224     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 225    ((equal type ?8)
 226     (elpher-address-from-url
 227      (concat "telnet"
 228              "://" host
 229              ":" (number-to-string port))))
 230    (t
 231     (elpher-address-from-url
 232      (concat "gopher" (if tls "s" "")
 233              "://" host
 234              ":" (number-to-string port)
 235              "/" (string type)
 236              selector)))))
 237
 238 (defun elpher-make-special-address (type)
 239   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 240   type)
 241
 242 (defun elpher-address-to-url (address)
 243   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 244   (if (not (elpher-address-special-p address))
 245       (url-encode-url (url-recreate-url address))
 246     nil))
 247
 248 (defun elpher-address-type (address)
 249   "Retrieve type of ADDRESS object.
 250 This is used to determine how to retrieve and render the document the
 251 address refers to, via the table `elpher-type-map'."
 252   (if (symbolp address)
 253       (list 'special address)
 254     (let ((protocol (url-type address)))
 255       (cond ((or (equal protocol "gopher")
 256                  (equal protocol "gophers"))
 257              (list 'gopher
 258                    (if (member (url-filename address) '("" "/"))
 259                        ?1
 260                      (string-to-char (substring (url-filename address) 1)))))
 261             ((equal protocol "gemini")
 262              'gemini)
 263             ((equal protocol "telnet")
 264              'telnet)
 265             (t 'other-url)))))
 266
 267 (defun elpher-address-protocol (address)
 268   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 269   (if (symbolp address)
 270       nil
 271     (url-type address)))
 272
 273 (defun elpher-address-filename (address)
 274   "Retrieve the filename component of ADDRESS.
 275 For gopher addresses this is a combination of the selector type and selector."
 276   (if (symbolp address)
 277       nil
 278     (url-filename address)))
 279
 280 (defun elpher-address-host (address)
 281   "Retrieve host from ADDRESS object."
 282   (url-host address))
 283
 284 (defun elpher-address-port (address)
 285   "Retrieve port from ADDRESS object."
 286   (if (symbolp address)
 287       nil)
 288   (if (> (url-port address) 0)
 289       (url-port address)
 290     (or (and (or (equal (url-type address) "gopher")
 291                  (equal (url-type address) "gophers"))
 292              70)
 293         (and (equal (url-type address) "gemini")
 294              1965))))
 295
 296 (defun elpher-address-special-p (address)
 297   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 298   (symbolp address))
 299
 300 (defun elpher-address-gopher-p (address)
 301   "Return non-nill if ADDRESS object is a gopher address."
 302   (and (not (elpher-address-special-p address))
 303        (member (elpher-address-protocol address) '("gopher gophers"))))
 304
 305 (defun elpher-gopher-address-selector (address)
 306   "Retrieve gopher selector from ADDRESS object."
 307   (if (member (url-filename address) '("" "/"))
 308       ""
 309     (substring (url-filename address) 2)))
 310
 311 ;; Node
 312
 313 (defun elpher-make-node (display-string address &optional parent)
 314   "Create a node in the page hierarchy.
 315
 316 DISPLAY-STRING records the display string used for the page.
 317
 318 ADDRESS specifies the address object of the page.
 319
 320 The optional PARENT specifies the parent node in the hierarchy.
 321 This is set every time the node is visited, so while it forms
 322 an important part of the node data there is no need to set it
 323 initially."
 324   (list display-string address parent))
 325
 326 (defun elpher-node-display-string (node)
 327   "Retrieve the display string of NODE."
 328   (elt node 0))
 329
 330 (defun elpher-node-address (node)
 331   "Retrieve the ADDRESS object of NODE."
 332   (elt node 1))
 333
 334 (defun elpher-node-parent (node)
 335   "Retrieve the parent node of NODE."
 336   (elt node 2))
 337
 338 (defun elpher-set-node-parent (node parent)
 339   "Set the parent node of NODE to be PARENT."
 340   (setcar (cdr (cdr node)) parent))
 341
 342 ;; Cache
 343
 344 (defvar elpher-content-cache (make-hash-table :test 'equal))
 345 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 346
 347 (defun elpher-get-cached-content (address)
 348   "Retrieve the cached content for ADDRESS, or nil if none exists."
 349   (gethash address elpher-content-cache))
 350
 351 (defun elpher-cache-content (address content)
 352   "Set the content cache for ADDRESS to CONTENT."
 353   (puthash address content elpher-content-cache))
 354
 355 (defun elpher-get-cached-pos (address)
 356   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 357   (gethash address elpher-pos-cache))
 358
 359 (defun elpher-cache-pos (address pos)
 360   "Set the cursor position cache for ADDRESS to POS."
 361   (puthash address pos elpher-pos-cache))
 362
 363 ;; Node graph traversal
 364
 365 (defvar elpher-current-node nil)
 366
 367 (defun elpher-visit-node (node &optional renderer preserve-parent)
 368   "Visit NODE using its own renderer or RENDERER, if non-nil.
 369 Additionally, set the parent of NODE to `elpher-current-node',
 370 unless PRESERVE-PARENT is non-nil."
 371   (elpher-save-pos)
 372   (elpher-process-cleanup)
 373   (unless preserve-parent
 374     (if (and (elpher-node-parent elpher-current-node)
 375              (equal (elpher-node-address elpher-current-node)
 376                     (elpher-node-address node)))
 377         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 378       (elpher-set-node-parent node elpher-current-node)))
 379   (setq elpher-current-node node)
 380   (let* ((address (elpher-node-address node))
 381          (type (elpher-address-type address))
 382          (type-record (cdr (assoc type elpher-type-map))))
 383     (if type-record
 384         (funcall (car type-record)
 385                  (if renderer
 386                      renderer
 387                    (cadr type-record)))
 388       (elpher-visit-parent-node)
 389       (pcase type
 390         (`(gopher ,type-char)
 391          (error "Unsupported gopher selector type '%c' for '%s'"
 392                 type-char (elpher-address-to-url address)))
 393         (other
 394          (error "Unsupported address type '%S' for '%s'"
 395                 other (elpher-address-to-url address)))))))
 396
 397 (defun elpher-visit-parent-node ()
 398   "Visit the parent of the current node."
 399   (let ((parent-node (elpher-node-parent elpher-current-node)))
 400     (when parent-node
 401       (elpher-visit-node parent-node nil t))))
 402
 403 (defun elpher-reload-current-node ()
 404   "Reload the current node, discarding any existing cached content."
 405   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 406   (elpher-visit-node elpher-current-node))
 407
 408 (defun elpher-save-pos ()
 409   "Save the current position of point to the current node."
 410   (when elpher-current-node
 411     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 412
 413 (defun elpher-restore-pos ()
 414   "Restore the position of point to that cached in the current node."
 415   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 416     (if pos
 417         (goto-char pos)
 418       (goto-char (point-min)))))
 419
 420
 421 ;;; Buffer preparation
 422 ;;
 423
 424 (defun elpher-update-header ()
 425   "If `elpher-use-header' is true, display current node info in window header."
 426   (if elpher-use-header
 427       (let* ((display-string (elpher-node-display-string elpher-current-node))
 428              (address (elpher-node-address elpher-current-node))
 429              (tls-string (if (and (not (elpher-address-special-p address))
 430                                   (member (elpher-address-protocol address)
 431                                           '("gophers" "gemini")))
 432                              " [TLS]"
 433                            ""))
 434              (header (concat display-string
 435                              (propertize tls-string 'face 'bold))))
 436         (setq header-line-format header))))
 437
 438 (defmacro elpher-with-clean-buffer (&rest args)
 439   "Evaluate ARGS with a clean *elpher* buffer as current."
 440   (list 'with-current-buffer "*elpher*"
 441         '(elpher-mode)
 442         (append (list 'let '((inhibit-read-only t))
 443                       '(erase-buffer)
 444                       '(elpher-update-header))
 445                 args)))
 446
 447
 448 ;;; Text Processing
 449 ;;
 450
 451 (defvar elpher-user-coding-system nil
 452   "User-specified coding system to use for decoding text responses.")
 453
 454 (defun elpher-decode (string)
 455   "Decode STRING using autodetected or user-specified coding system."
 456   (decode-coding-string string
 457                         (if elpher-user-coding-system
 458                             elpher-user-coding-system
 459                           (detect-coding-string string t))))
 460
 461 (defun elpher-preprocess-text-response (string)
 462   "Preprocess text selector response contained in STRING.
 463 This involes decoding the character representation, and clearing
 464 away CRs and any terminating period."
 465   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 466                                            (replace-regexp-in-string "\r" "" string))))
 467
 468
 469 ;;; Network error reporting
 470 ;;
 471
 472 (defun elpher-network-error (address error)
 473   "Display ERROR message following unsuccessful negotiation with ADDRESS."
 474   (elpher-with-clean-buffer
 475    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 476            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 477            (error-message-string error) "\n"
 478            (propertize "\n----------------\n\n" 'face 'error)
 479            "Press 'u' to return to the previous page.")))
 480
 481
 482 ;;; Gopher selector retrieval
 483 ;;
 484
 485 (defun elpher-process-cleanup ()
 486   "Immediately shut down any extant elpher process."
 487   (let ((p (get-process "elpher-process")))
 488     (if p (delete-process p))))
 489
 490 (defvar elpher-use-tls nil
 491   "If non-nil, use TLS to communicate with gopher servers.")
 492
 493 (defvar elpher-selector-string)
 494
 495 (defun elpher-get-selector (address after &optional propagate-error)
 496   "Retrieve selector specified by ADDRESS, then execute AFTER.
 497 The result is stored as a string in the variable ‘elpher-selector-string’.
 498
 499 Usually errors result in an error page being displayed.  This is only
 500 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 501 is non-nil, this message is not displayed.  Instead, the error propagates
 502 up to the calling function."
 503   (setq elpher-selector-string "")
 504   (when (equal (elpher-address-protocol address) "gophers")
 505       (if (gnutls-available-p)
 506           (when (not elpher-use-tls)
 507             (setq elpher-use-tls t)
 508             (message "Engaging TLS gopher mode."))
 509         (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 510   (condition-case the-error
 511       (let* ((kill-buffer-query-functions nil)
 512              (proc (open-network-stream "elpher-process"
 513                                        nil
 514                                        (elpher-address-host address)
 515                                        (elpher-address-port address)
 516                                        :type (if elpher-use-tls 'tls 'plain))))
 517         (set-process-coding-system proc 'binary)
 518         (set-process-filter proc
 519                             (lambda (_proc string)
 520                               (setq elpher-selector-string
 521                                     (concat elpher-selector-string string))))
 522         (set-process-sentinel proc after)
 523         (let ((inhibit-eol-conversion t))
 524           (process-send-string proc
 525                                (concat (elpher-gopher-address-selector address) "\r\n"))))
 526     (error
 527      (if (and (consp the-error)
 528               (eq (car the-error) 'gnutls-error)
 529               (not (equal (elpher-address-protocol address) "gophers"))
 530               (or elpher-auto-disengage-TLS
 531                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 532          (progn
 533            (message "Disengaging TLS gopher mode.")
 534            (setq elpher-use-tls nil)
 535            (elpher-get-selector address after))
 536        (elpher-process-cleanup)
 537        (if propagate-error
 538            (error the-error)
 539          (elpher-with-clean-buffer
 540           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 541                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 542                   (propertize "\n----------------\n\n" 'face 'error)
 543                   "Press 'u' to return to the previous page.")))))))
 544
 545 (defun elpher-get-gopher-node (renderer)
 546   "Getter function for gopher nodes.
 547 The RENDERER procedure is used to display the contents of the node
 548 once they are retrieved from the gopher server."
 549   (let* ((address (elpher-node-address elpher-current-node))
 550          (content (elpher-get-cached-content address)))
 551     (if (and content (funcall renderer nil))
 552         (elpher-with-clean-buffer
 553          (insert content)
 554          (elpher-restore-pos))
 555       (elpher-with-clean-buffer
 556        (insert "LOADING... (use 'u' to cancel)"))
 557       (elpher-get-selector address
 558                            (lambda (_proc event)
 559                              (unless (string-prefix-p "deleted" event)
 560                                (funcall renderer elpher-selector-string)
 561                                (elpher-restore-pos)))))))
 562
 563 ;; Index rendering
 564
 565 (defun elpher-insert-index (string)
 566   "Insert the index corresponding to STRING into the current buffer."
 567   ;; Should be able to split directly on CRLF, but some non-conformant
 568   ;; LF-only servers sadly exist, hence the following.
 569   (let ((str-processed (elpher-preprocess-text-response string)))
 570     (dolist (line (split-string str-processed "\n"))
 571       (ignore-errors
 572         (unless (= (length line) 0)
 573           (let* ((type (elt line 0))
 574                  (fields (split-string (substring line 1) "\t"))
 575                  (display-string (elt fields 0))
 576                  (selector (elt fields 1))
 577                  (host (elt fields 2))
 578                  (port (if (elt fields 3)
 579                            (string-to-number (elt fields 3))
 580                          nil))
 581                  (address (elpher-make-gopher-address type selector host port)))
 582             (elpher-insert-index-record display-string address)))))))
 583
 584 (defun elpher-insert-margin (&optional type-name)
 585   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 586   (if type-name
 587       (progn
 588         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 589                         (concat
 590                          (propertize "[" 'face 'elpher-margin-brackets)
 591                          (propertize type-name 'face 'elpher-margin-key)
 592                          (propertize "]" 'face 'elpher-margin-brackets))))
 593         (insert " "))
 594     (insert (make-string elpher-margin-width ?\s))))
 595
 596 (defun elpher-node-button-help (node)
 597   "Return a string containing the help text for a button corresponding to NODE."
 598   (let ((address (elpher-node-address node)))
 599     (format "mouse-1, RET: open '%s'" (elpher-address-to-url address))))
 600
 601 (defun elpher-insert-index-record (display-string &optional address)
 602   "Function to insert an index record into the current buffer.
 603 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 604 If ADDRESS is not supplied or nil the record is rendered as an
 605 'information' line."
 606   (let* ((type (if address (elpher-address-type address) nil))
 607          (type-map-entry (cdr (assoc type elpher-type-map))))
 608     (if type-map-entry
 609         (let* ((margin-code (elt type-map-entry 2))
 610                (face (elt type-map-entry 3))
 611                (node (elpher-make-node display-string address)))
 612           (elpher-insert-margin margin-code)
 613           (insert-text-button display-string
 614                               'face face
 615                               'elpher-node node
 616                               'action #'elpher-click-link
 617                               'follow-link t
 618                               'help-echo (elpher-node-button-help node)))
 619       (pcase type
 620         ((or '(gopher ?i) 'nil) ;; Information
 621          (elpher-insert-margin)
 622          (let ((propertized-display-string
 623                 (propertize display-string 'face 'elpher-info)))
 624            (insert (if elpher-buttonify-urls-in-directories
 625                        (elpher-buttonify-urls propertized-display-string)
 626                      propertized-display-string))))
 627         (`(gopher ,selector-type) ;; Unknown
 628          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 629          (insert (propertize display-string
 630                              'face 'elpher-unknown)))))
 631     (insert "\n")))
 632
 633 (defun elpher-click-link (button)
 634   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 635   (let ((node (button-get button 'elpher-node)))
 636     (elpher-visit-node node)))
 637
 638 (defun elpher-render-index (data &optional _mime-type-string)
 639   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 640   (elpher-with-clean-buffer
 641    (if (not data)
 642        t
 643      (elpher-insert-index data)
 644      (elpher-cache-content (elpher-node-address elpher-current-node)
 645                            (buffer-string)))))
 646
 647 ;; Text rendering
 648
 649 (defconst elpher-url-regex
 650   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.]*[0-9a-zA-Z\-_~?/@|]\\)?\\)?"
 651   "Regexp used to locate and buttniofy URLs in text files loaded by elpher.")
 652
 653 (defun elpher-buttonify-urls (string)
 654   "Turn substrings which look like urls in STRING into clickable buttons."
 655   (with-temp-buffer
 656     (insert string)
 657     (goto-char (point-min))
 658     (while (re-search-forward elpher-url-regex nil t)
 659       (let ((node (elpher-make-node (substring-no-properties (match-string 0))
 660                                     (elpher-address-from-url (match-string 0)))))
 661           (make-text-button (match-beginning 0)
 662                             (match-end 0)
 663                             'elpher-node  node
 664                             'action #'elpher-click-link
 665                             'follow-link t
 666                             'help-echo (elpher-node-button-help node)
 667                             'face 'button)))
 668     (buffer-string)))
 669
 670 (defun elpher-render-text (data &optional _mime-type-string)
 671   "Render DATA as text.  MIME-TYPE-STRING is unused."
 672   (elpher-with-clean-buffer
 673    (if (not data)
 674        t
 675      (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 676      (elpher-cache-content
 677       (elpher-node-address elpher-current-node)
 678       (buffer-string)))))
 679
 680 ;; Image retrieval
 681
 682 (defun elpher-render-image (data &optional _mime-type-string)
 683   "Display DATA as image.  MIME-TYPE-STRING is unused."
 684   (if (not data)
 685       nil
 686     (if (display-images-p)
 687         (progn
 688           (let ((image (create-image
 689                         data
 690                         nil t)))
 691             (elpher-with-clean-buffer
 692              (insert-image image)
 693              (elpher-restore-pos))))
 694       (elpher-render-download data))))
 695
 696 ;; Search retrieval and rendering
 697
 698 (defun elpher-get-gopher-query-node (renderer)
 699   "Getter for gopher addresses requiring input.
 700 The response is rendered using the rendering function RENDERER."
 701    (let* ((address (elpher-node-address elpher-current-node))
 702           (content (elpher-get-cached-content address))
 703           (aborted t))
 704     (if (and content (funcall renderer nil))
 705         (elpher-with-clean-buffer
 706          (insert content)
 707          (elpher-restore-pos)
 708          (message "Displaying cached search results.  Reload to perform a new search."))
 709       (unwind-protect
 710           (let* ((query-string (read-string "Query: "))
 711                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 712                  (search-address (elpher-make-gopher-address ?1
 713                                                              query-selector
 714                                                              (elpher-address-host address)
 715                                                              (elpher-address-port address)
 716                                                              (equal (elpher-address-type address) "gophers"))))
 717             (setq aborted nil)
 718
 719             (elpher-with-clean-buffer
 720              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 721             (elpher-get-selector search-address
 722                                  (lambda (_proc event)
 723                                    (unless (string-prefix-p "deleted" event)
 724                                      (funcall renderer elpher-selector-string)
 725                                      (elpher-restore-pos)))))
 726         (if aborted
 727             (elpher-visit-parent-node))))))
 728
 729 ;; Raw server response rendering
 730
 731 (defun elpher-render-raw (data &optional _mime-type-string)
 732   "Display raw DATA in buffer.  MIME-TYPE-STRING is unused."
 733   (if (not data)
 734       nil
 735     (elpher-with-clean-buffer
 736      (insert data)
 737      (goto-char (point-min)))
 738     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 739
 740 ;; File save "rendering"
 741
 742 (defun elpher-render-download (data &optional _mime-type-string)
 743   "Save DATA to file.  MIME-TYPE-STRING is unused."
 744   (if (not data)
 745       nil
 746     (let* ((address (elpher-node-address elpher-current-node))
 747            (selector (elpher-gopher-address-selector address)))
 748       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 749       (let* ((filename-proposal (file-name-nondirectory selector))
 750              (filename (read-file-name "Download complete. Save file as: "
 751                                        nil nil nil
 752                                        (if (> (length filename-proposal) 0)
 753                                            filename-proposal
 754                                          "download.file"))))
 755         (let ((coding-system-for-write 'binary))
 756           (with-temp-file filename
 757             (insert data)))
 758         (message (format "Saved to file %s." filename))))))
 759
 760 ;; HTML rendering
 761
 762 (defun elpher-render-html (data &optional _mime-type-string)
 763   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 764   (elpher-with-clean-buffer
 765    (if (not data)
 766        t
 767      (let ((dom (with-temp-buffer
 768                   (insert data)
 769                   (libxml-parse-html-region (point-min) (point-max)))))
 770        (shr-insert-document dom)))))
 771
 772 ;; Gemini node retrieval
 773
 774 (defvar elpher-gemini-response)
 775
 776 (defun elpher-get-gemini-response (address after)
 777   "Retrieve gemini ADDRESS, then execute AFTER.
 778 The response is stored in the variable ‘elpher-gemini-response’."
 779   (setq elpher-gemini-response "")
 780   (if (not (gnutls-available-p))
 781       (error "Cannot establish gemini connection: GnuTLS not available")
 782     (condition-case the-error
 783         (let* ((kill-buffer-query-functions nil)
 784                (proc (open-network-stream "elpher-process"
 785                                           nil
 786                                           (elpher-address-host address)
 787                                           (elpher-address-port address)
 788                                           :type 'tls)))
 789           (set-process-coding-system proc 'binary)
 790           (set-process-filter proc
 791                               (lambda (_proc string)
 792                                 (setq elpher-gemini-response
 793                                       (concat elpher-gemini-response string))))
 794           (set-process-sentinel proc after)
 795           (let ((inhibit-eol-conversion t))
 796             (process-send-string proc
 797                                  (concat (elpher-address-to-url address) "\r\n"))))
 798       (error
 799        (error "Error initiating connection to server")))))
 800
 801 (defun elpher-parse-gemini-response (response)
 802   "Parse the RESPONSE string and return a list of components
 803 The list is of the form (code meta body). A response of nil implies
 804 that the response was malformed."
 805   (let ((header-end-idx (string-match "\r\n" response)))
 806     (if header-end-idx
 807         (let ((header (string-trim (substring response 0 header-end-idx)))
 808               (body (substring response (+ header-end-idx 2))))
 809           (if (>= (length header) 2)
 810               (let ((code (substring header 0 2))
 811                     (meta (string-trim (substring header 2))))
 812                 (list code meta body))
 813             (error "Malformed response: No response status found in header %s" header)))
 814       (error "Malformed response: No CRLF-delimited header found"))))
 815
 816
 817 (defun elpher-process-gemini-response (renderer)
 818   "Process the gemini response and pass the result to RENDERER.
 819 The response is assumed to be in the variable `elpher-gemini-response'."
 820   (condition-case the-error
 821       (let ((response-components (elpher-parse-gemini-response elpher-gemini-response)))
 822         (let ((response-code (elt response-components 0))
 823               (response-meta (elt response-components 1))
 824               (response-body (elt response-components 2)))
 825           (pcase (elt response-code 0)
 826             (?1 ; Input required
 827              (elpher-with-clean-buffer
 828               (insert "Gemini server is requesting input."))
 829              (let* ((query-string (read-string (concat response-meta ": ")))
 830                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 831                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 832                (elpher-get-gemini-response query-address
 833                                            (lambda (_proc event)
 834                                              (unless (string-prefix-p "deleted" event)
 835                                                (funcall #'elpher-process-gemini-response
 836                                                         renderer)
 837                                                (elpher-restore-pos))))))
 838             (?2 ; Normal response
 839              ;; (message response-header)
 840              (funcall renderer response-body response-meta))
 841             (?3 ; Redirect
 842              (message "Following redirect to %s" response-meta)
 843              (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 844                (elpher-get-gemini-response redirect-address
 845                                            (lambda (_proc event)
 846                                              (unless (string-prefix-p "deleted" event)
 847                                                (funcall #'elpher-process-gemini-response
 848                                                         renderer)
 849                                                (elpher-restore-pos))))))
 850             (?4 ; Temporary failure
 851              (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
 852                     response-code response-meta))
 853             (?5 ; Permanent failure
 854              (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
 855                     response-code response-meta))
 856             (?6 ; Client certificate required
 857              (error "Gemini server requires client certificate (unsupported at this time)"))
 858             (_other
 859              (error "Gemini server response unknown: %s %s"
 860                     response-code response-meta)))))
 861     (error
 862      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 863
 864 (defun elpher-get-gemini-node (renderer)
 865   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 866   (let* ((address (elpher-node-address elpher-current-node))
 867          (content (elpher-get-cached-content address)))
 868     (condition-case the-error
 869         (if (and content (funcall renderer nil))
 870             (elpher-with-clean-buffer
 871               (insert content)
 872               (elpher-restore-pos))
 873           (elpher-with-clean-buffer
 874            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 875           (elpher-get-gemini-response address
 876                                       (lambda (_proc event)
 877                                         (unless (string-prefix-p "deleted" event)
 878                                           (funcall #'elpher-process-gemini-response
 879                                                    renderer)
 880                                           (elpher-restore-pos)))))
 881       (error
 882        (elpher-network-error address the-error)))))
 883
 884
 885 (defun elpher-render-gemini (body &optional mime-type-string)
 886   "Render gemini response BODY with rendering MIME-TYPE-STRING."
 887   (if (not body)
 888       t
 889     (let* ((mime-type-string* (if (or (not mime-type-string)
 890                                       (string-empty-p mime-type-string))
 891                                   "text/gemini; charset=utf-8"
 892                                 mime-type-string))
 893            (mime-type-split (split-string mime-type-string* ";" t))
 894            (mime-type (string-trim (car mime-type-split)))
 895            (parameters (mapcar (lambda (s)
 896                                  (let ((key-val (split-string s "=")))
 897                                    (list (downcase (string-trim (car key-val)))
 898                                          (downcase (string-trim (cadr key-val))))))
 899                                (cdr mime-type-split))))
 900       (when (string-prefix-p "text/" mime-type)
 901         (setq body (decode-coding-string
 902                     body
 903                     (if (assoc "charset" parameters)
 904                         (intern (cadr (assoc "charset" parameters)))
 905                       'utf-8)))
 906         (setq body (replace-regexp-in-string "\r" "" body)))
 907       (pcase mime-type
 908         ((or "text/gemini" "")
 909          (elpher-render-gemini-map body parameters))
 910         ((pred (string-prefix-p "text/"))
 911          (elpher-render-gemini-plain-text body parameters))
 912         ((pred (string-prefix-p "image/"))
 913          (elpher-render-image body))
 914         (_other
 915          (error "Unsupported MIME type %S" mime-type))))))
 916
 917 (defun elpher-gemini-get-link-url (line)
 918   "Extract the url portion of LINE, a gemini map file link line."
 919   (string-trim (elt (split-string (substring line 2)) 0)))
 920
 921 (defun elpher-gemini-get-link-display-string (line)
 922   "Extract the display string portion of LINE, a gemini map file link line."
 923   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 924          (idx (string-match "[ \t]" rest)))
 925     (if idx
 926         (string-trim (substring rest (+ idx 1)))
 927       "")))
 928
 929 (defun elpher-collapse-dot-sequences (filename)
 930   "Collapse dot sequences in FILENAME.
 931 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
 932   (let* ((path (split-string filename "/"))
 933          (path-reversed-normalized
 934           (seq-reduce (lambda (a b)
 935                         (cond ((and a (equal b "..") (cdr a)))
 936                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
 937                               ((equal b ".") a)
 938                               (t (cons b a))))
 939                       path nil)))
 940     (string-join (reverse path-reversed-normalized) "/")))
 941
 942 (defun elpher-address-from-gemini-url (url)
 943   "Extract address from URL with defaults as per gemini map files."
 944   (let ((address (url-generic-parse-url url)))
 945     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 946       (setf (url-fullness address) t)
 947       (unless (url-host address) ;if there is an explicit host, filenames are absolute
 948         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 949         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 950           (setf (url-filename address)
 951                 (concat (file-name-directory
 952                          (url-filename (elpher-node-address elpher-current-node)))
 953                         (url-filename address)))))
 954       (unless (url-type address)
 955         (setf (url-type address) "gemini"))
 956       (if (equal (url-type address) "gemini")
 957           (setf (url-filename address)
 958                 (elpher-collapse-dot-sequences (url-filename address)))))
 959     address))
 960
 961 (defun elpher-render-gemini-map (data _parameters)
 962   "Render DATA as a gemini map file, PARAMETERS is currently unused."
 963   (elpher-with-clean-buffer
 964    (dolist (line (split-string data "\n"))
 965      (if (string-prefix-p "=>" line)
 966          (let* ((url (elpher-gemini-get-link-url line))
 967                 (display-string (elpher-gemini-get-link-display-string line))
 968                 (address (elpher-address-from-gemini-url url)))
 969            (if (> (length display-string) 0)
 970                (elpher-insert-index-record display-string address)
 971              (elpher-insert-index-record url address)))
 972        (elpher-insert-index-record line)))
 973    (elpher-cache-content
 974     (elpher-node-address elpher-current-node)
 975     (buffer-string))))
 976
 977 (defun elpher-render-gemini-plain-text (data _parameters)
 978   "Render DATA as plain text file.  PARAMETERS is currently unused."
 979   (elpher-with-clean-buffer
 980    (insert (elpher-buttonify-urls data))
 981    (elpher-cache-content
 982     (elpher-node-address elpher-current-node)
 983     (buffer-string))))
 984
 985 ;; Other URL node opening
 986
 987 (defun elpher-get-other-url-node (renderer)
 988   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 989   (when renderer
 990     (elpher-visit-parent-node)
 991     (error "Command not supported for general URLs"))
 992   (let* ((address (elpher-node-address elpher-current-node))
 993          (url (elpher-address-to-url address)))
 994     (progn
 995       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 996       (message "Opening URL...")
 997       (if elpher-open-urls-with-eww
 998           (browse-web url)
 999         (browse-url url)))))
1000
1001 ;; Telnet node connection
1002
1003 (defun elpher-get-telnet-node (renderer)
1004   "Opens a telnet connection to the current node address (RENDERER must be nil)."
1005   (when renderer
1006     (elpher-visit-parent-node)
1007     (error "Command not supported for telnet URLs"))
1008   (let* ((address (elpher-node-address elpher-current-node))
1009          (host (elpher-address-host address))
1010          (port (elpher-address-port address)))
1011     (elpher-visit-parent-node)
1012     (telnet host port)))
1013
1014 ;; Start page node retrieval
1015
1016 (defun elpher-get-start-node (renderer)
1017   "Getter which displays the start page (RENDERER must be nil)."
1018   (when renderer
1019     (elpher-visit-parent-node)
1020     (error "Command not supported for start page"))
1021   (elpher-with-clean-buffer
1022    (insert "     --------------------------------------------\n"
1023            "                Elpher Gopher Client             \n"
1024            "                   version " elpher-version "\n"
1025            "     --------------------------------------------\n"
1026            "\n"
1027            "Default bindings:\n"
1028            "\n"
1029            " - TAB/Shift-TAB: next/prev item on current page\n"
1030            " - RET/mouse-1: open item under cursor\n"
1031            " - m: select an item on current page by name (autocompletes)\n"
1032            " - u/mouse-3: return to previous page\n"
1033            " - o/O: visit different selector or the root menu of the current server\n"
1034            " - g: go to a particular gopher address\n"
1035            " - d/D: download item under cursor or current page\n"
1036            " - i/I: info on item under cursor or current page\n"
1037            " - c/C: copy URL representation of item under cursor or current page\n"
1038            " - a/A: bookmark the item under cursor or current page\n"
1039            " - x/X: remove bookmark for item under cursor or current page\n"
1040            " - B: visit the bookmarks page\n"
1041            " - r: redraw current page (using cached contents if available)\n"
1042            " - R: reload current page (regenerates cache)\n"
1043            " - S: set character coding system for gopher (default is to autodetect)\n"
1044            " - T: toggle TLS gopher mode\n"
1045            " - .: display the raw server response for the current page\n"
1046            "\n"
1047            "Start your exploration of gopher space:\n")
1048    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1049                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1050    (insert "\n"
1051            "Alternatively, select the following item and enter some search terms:\n")
1052    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
1053                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1054    (insert "\n"
1055            "** Refer to the ")
1056    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1057      (insert-text-button "Elpher info manual"
1058                          'face 'link
1059                          'action (lambda (_)
1060                                    (interactive)
1061                                    (info "(elpher)"))
1062                          'follow-link t
1063                          'help-echo help-string))
1064    (insert " for the full documentation. **\n")
1065    (insert (propertize
1066             (concat "  (This should be available if you have installed Elpher using\n"
1067                     "   MELPA. Otherwise you will have to install the manual yourself.)")
1068             'face 'shadow))
1069    (elpher-restore-pos)))
1070
1071 ;; Bookmarks page node retrieval
1072
1073 (defun elpher-get-bookmarks-node (renderer)
1074   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1075   (when renderer
1076     (elpher-visit-parent-node)
1077     (error "Command not supported for bookmarks page"))
1078   (elpher-with-clean-buffer
1079    (insert "---- Bookmark list ----\n\n")
1080    (let ((bookmarks (elpher-load-bookmarks)))
1081      (if bookmarks
1082          (dolist (bookmark bookmarks)
1083            (let ((display-string (elpher-bookmark-display-string bookmark))
1084                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1085              (elpher-insert-index-record display-string address)))
1086        (insert "No bookmarks found.\n")))
1087    (insert "\n-----------------------\n\n"
1088            "- u: return to previous page\n"
1089            "- x: delete selected bookmark\n"
1090            "- a: rename selected bookmark\n\n"
1091            "Bookmarks are stored in the file "
1092            (locate-user-emacs-file "elpher-bookmarks"))
1093    (elpher-restore-pos)))
1094
1095
1096 ;;; Bookmarks
1097 ;;
1098
1099 (defun elpher-make-bookmark (display-string url)
1100   "Make an elpher bookmark.
1101 DISPLAY-STRING determines how the bookmark will appear in the
1102 bookmark list, while URL is the url of the entry."
1103   (list display-string url))
1104
1105 (defun elpher-bookmark-display-string (bookmark)
1106   "Get the display string of BOOKMARK."
1107   (elt bookmark 0))
1108
1109 (defun elpher-set-bookmark-display-string (bookmark display-string)
1110   "Set the display string of BOOKMARK to DISPLAY-STRING."
1111   (setcar bookmark display-string))
1112
1113 (defun elpher-bookmark-url (bookmark)
1114   "Get the address for BOOKMARK."
1115   (elt bookmark 1))
1116
1117 (defun elpher-save-bookmarks (bookmarks)
1118   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1119 Beware that this completely replaces the existing contents of the file."
1120   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
1121     (erase-buffer)
1122     (insert "; Elpher bookmarks file\n\n"
1123             "; Bookmarks are stored as a list of (label URL) items.\n"
1124             "; Feel free to edit by hand, but take care to ensure\n"
1125             "; the list structure remains intact.\n\n")
1126     (pp bookmarks (current-buffer))))
1127
1128 (defun elpher-load-bookmarks ()
1129   "Get the list of bookmarks from the users's bookmark file."
1130   (let ((bookmarks
1131          (with-temp-buffer
1132            (ignore-errors
1133              (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
1134              (goto-char (point-min))
1135              (read (current-buffer))))))
1136     (if (and bookmarks (listp (cadar bookmarks)))
1137         (progn
1138           (message "Reading old bookmark file. (Will be updated on write.)")
1139           (mapcar (lambda (old-bm)
1140                     (list (car old-bm)
1141                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1142                                                         (cadr old-bm)))))
1143                   bookmarks))
1144       bookmarks)))
1145
1146 (defun elpher-add-address-bookmark (address display-string)
1147   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1148 If ADDRESS is already bookmarked, update the label only."
1149   (let ((bookmarks (elpher-load-bookmarks))
1150         (url (elpher-address-to-url address)))
1151     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1152       (if existing-bookmark
1153           (elpher-set-bookmark-display-string existing-bookmark display-string)
1154         (push (elpher-make-bookmark display-string url) bookmarks)))
1155     (elpher-save-bookmarks bookmarks)))
1156
1157 (defun elpher-remove-address-bookmark (address)
1158   "Remove any bookmark to ADDRESS."
1159   (let ((url (elpher-address-to-url address)))
1160     (elpher-save-bookmarks
1161      (seq-filter (lambda (bookmark)
1162                    (not (equal (elpher-bookmark-url bookmark) url)))
1163                  (elpher-load-bookmarks)))))
1164
1165 ;;; Interactive procedures
1166 ;;
1167
1168 (defun elpher-next-link ()
1169   "Move point to the next link on the current page."
1170   (interactive)
1171   (forward-button 1))
1172
1173 (defun elpher-prev-link ()
1174   "Move point to the previous link on the current page."
1175   (interactive)
1176   (backward-button 1))
1177
1178 (defun elpher-follow-current-link ()
1179   "Open the link or url at point."
1180   (interactive)
1181   (push-button))
1182
1183 (defun elpher-go ()
1184   "Go to a particular gopher site read from the minibuffer."
1185   (interactive)
1186   (let ((node
1187          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1188            (elpher-make-node host-or-url
1189                              (elpher-address-from-url host-or-url)))))
1190     (switch-to-buffer "*elpher*")
1191     (elpher-visit-node node)))
1192
1193 (defun elpher-go-current ()
1194   "Go to a particular site read from the minibuffer, initialized with the current URL."
1195   (interactive)
1196   (let ((address (elpher-node-address elpher-current-node)))
1197     (if (elpher-address-special-p address)
1198         (error "Command invalid for this page")
1199       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1200         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1201
1202 (defun elpher-redraw ()
1203   "Redraw current page."
1204   (interactive)
1205   (if elpher-current-node
1206       (elpher-visit-node elpher-current-node)
1207     (message "No current site.")))
1208
1209 (defun elpher-reload ()
1210   "Reload current page."
1211   (interactive)
1212   (if elpher-current-node
1213       (elpher-reload-current-node)
1214     (message "No current site.")))
1215
1216 (defun elpher-toggle-tls ()
1217   "Toggle TLS encryption mode for gopher."
1218   (interactive)
1219   (setq elpher-use-tls (not elpher-use-tls))
1220   (if elpher-use-tls
1221       (if (gnutls-available-p)
1222           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1223         (setq elpher-use-tls nil)
1224         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1225     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1226
1227 (defun elpher-view-raw ()
1228   "View raw server response for current page."
1229   (interactive)
1230   (if elpher-current-node
1231       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1232           (error "This page was not generated by a server")
1233         (elpher-visit-node elpher-current-node
1234                            #'elpher-render-raw))
1235     (message "No current site.")))
1236
1237 (defun elpher-back ()
1238   "Go to previous site."
1239   (interactive)
1240   (if (elpher-node-parent elpher-current-node)
1241       (elpher-visit-parent-node)
1242     (error "No previous site")))
1243
1244 (defun elpher-download ()
1245   "Download the link at point."
1246   (interactive)
1247   (let ((button (button-at (point))))
1248     (if button
1249         (let ((node (button-get button 'elpher-node)))
1250           (if (elpher-address-special-p (elpher-node-address node))
1251               (error "Cannot download %s"
1252                      (elpher-node-display-string node))
1253             (elpher-visit-node (button-get button 'elpher-node)
1254                                #'elpher-render-download)))
1255       (error "No link selected"))))
1256
1257 (defun elpher-download-current ()
1258   "Download the current page."
1259   (interactive)
1260   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1261       (error "Cannot download %s"
1262              (elpher-node-display-string elpher-current-node))
1263     (elpher-visit-node (elpher-make-node
1264                         (elpher-node-display-string elpher-current-node)
1265                         (elpher-node-address elpher-current-node)
1266                         elpher-current-node)
1267                        #'elpher-render-download
1268                        t)))
1269
1270 (defun elpher-build-link-map ()
1271   "Build alist mapping link names to destination nodes in current buffer."
1272   (let ((link-map nil)
1273         (b (next-button (point-min) t)))
1274     (while b
1275       (push (cons (button-label b) b) link-map)
1276       (setq b (next-button (button-start b))))
1277     link-map))
1278
1279 (defun elpher-jump ()
1280   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1281   (interactive)
1282   (let* ((link-map (elpher-build-link-map)))
1283     (if link-map
1284         (let ((key (let ((completion-ignore-case t))
1285                      (completing-read "Directory item/link: "
1286                                       link-map nil t))))
1287           (if (and key (> (length key) 0))
1288               (let ((b (cdr (assoc key link-map))))
1289                 (goto-char (button-start b))
1290                 (button-activate b)))))))
1291
1292 (defun elpher-root-dir ()
1293   "Visit root of current server."
1294   (interactive)
1295   (let ((address (elpher-node-address elpher-current-node)))
1296     (if (not (elpher-address-special-p address))
1297         (if (or (member (url-filename address) '("/" ""))
1298                 (and (elpher-address-gopher-p address)
1299                      (= (length (elpher-gopher-address-selector address)) 0)))
1300             (error "Already at root directory of current server")
1301           (let ((address-copy (elpher-address-from-url
1302                                (elpher-address-to-url address))))
1303             (setf (url-filename address-copy) "")
1304             (elpher-visit-node
1305              (elpher-make-node (elpher-address-to-url address-copy)
1306                                address-copy))))
1307       (error "Command invalid for %s" (elpher-node-display-string elpher-current-node)))))
1308
1309 (defun elpher-bookmarks-current-p ()
1310   "Return non-nil if current node is a bookmarks page."
1311   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1312          '(special bookmarks)))
1313
1314 (defun elpher-reload-bookmarks ()
1315   "Reload bookmarks if current node is a bookmarks page."
1316   (if (elpher-bookmarks-current-p)
1317       (elpher-reload-current-node)))
1318
1319 (defun elpher-bookmark-current ()
1320   "Bookmark the current node."
1321   (interactive)
1322   (let ((address (elpher-node-address elpher-current-node))
1323         (display-string (elpher-node-display-string elpher-current-node)))
1324     (if (not (elpher-address-special-p address))
1325         (let ((bookmark-display-string (read-string "Bookmark display string: "
1326                                                     display-string)))
1327           (elpher-add-address-bookmark address bookmark-display-string)
1328           (message "Bookmark added."))
1329       (error "Cannot bookmark %s" display-string))))
1330
1331 (defun elpher-bookmark-link ()
1332   "Bookmark the link at point."
1333   (interactive)
1334   (let ((button (button-at (point))))
1335     (if button
1336         (let* ((node (button-get button 'elpher-node))
1337                (address (elpher-node-address node))
1338                (display-string (elpher-node-display-string node)))
1339           (if (not (elpher-address-special-p address))
1340               (let ((bookmark-display-string (read-string "Bookmark display string: "
1341                                                           display-string)))
1342                 (elpher-add-address-bookmark address bookmark-display-string)
1343                 (elpher-reload-bookmarks)
1344                 (message "Bookmark added."))
1345             (error "Cannot bookmark %s" display-string)))
1346       (error "No link selected"))))
1347
1348 (defun elpher-unbookmark-current ()
1349   "Remove bookmark for the current node."
1350   (interactive)
1351   (let ((address (elpher-node-address elpher-current-node)))
1352     (unless (elpher-address-special-p address)
1353       (elpher-remove-address-bookmark address)
1354       (message "Bookmark removed."))))
1355
1356 (defun elpher-unbookmark-link ()
1357   "Remove bookmark for the link at point."
1358   (interactive)
1359   (let ((button (button-at (point))))
1360     (if button
1361         (let ((node (button-get button 'elpher-node)))
1362           (elpher-remove-address-bookmark (elpher-node-address node))
1363           (elpher-reload-bookmarks)
1364           (message "Bookmark removed."))
1365       (error "No link selected"))))
1366
1367 (defun elpher-bookmarks ()
1368   "Visit bookmarks page."
1369   (interactive)
1370   (switch-to-buffer "*elpher*")
1371   (elpher-visit-node
1372    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1373
1374 (defun elpher-info-node (node)
1375   "Display information on NODE."
1376   (let ((display-string (elpher-node-display-string node))
1377         (address (elpher-node-address node)))
1378     (if (elpher-address-special-p address)
1379         (message "Special page: %s" display-string)
1380       (message "%s" (elpher-address-to-url address)))))
1381
1382 (defun elpher-info-link ()
1383   "Display information on node corresponding to link at point."
1384   (interactive)
1385   (let ((button (button-at (point))))
1386     (if button
1387         (elpher-info-node (button-get button 'elpher-node))
1388       (error "No item selected"))))
1389
1390 (defun elpher-info-current ()
1391   "Display information on current node."
1392   (interactive)
1393   (elpher-info-node elpher-current-node))
1394
1395 (defun elpher-copy-node-url (node)
1396   "Copy URL representation of address of NODE to `kill-ring'."
1397   (let ((address (elpher-node-address node)))
1398     (if (elpher-address-special-p address)
1399         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1400       (let ((url (elpher-address-to-url address)))
1401         (message "Copied \"%s\" to kill-ring/clipboard." url)
1402         (kill-new url)))))
1403
1404 (defun elpher-copy-link-url ()
1405   "Copy URL of item at point to `kill-ring'."
1406   (interactive)
1407   (let ((button (button-at (point))))
1408     (if button
1409         (elpher-copy-node-url (button-get button 'elpher-node))
1410       (error "No item selected"))))
1411
1412 (defun elpher-copy-current-url ()
1413   "Copy URL of current node to `kill-ring'."
1414   (interactive)
1415   (elpher-copy-node-url elpher-current-node))
1416
1417 (defun elpher-set-gopher-coding-system ()
1418   "Specify an explicit character coding system for gopher selectors."
1419   (interactive)
1420   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1421     (setq elpher-user-coding-system system)
1422     (if system
1423         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1424       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1425
1426
1427 ;;; Mode and keymap
1428 ;;
1429
1430 (defvar elpher-mode-map
1431   (let ((map (make-sparse-keymap)))
1432     (define-key map (kbd "TAB") 'elpher-next-link)
1433     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1434     (define-key map (kbd "u") 'elpher-back)
1435     (define-key map [mouse-3] 'elpher-back)
1436     (define-key map (kbd "O") 'elpher-root-dir)
1437     (define-key map (kbd "g") 'elpher-go)
1438     (define-key map (kbd "o") 'elpher-go-current)
1439     (define-key map (kbd "r") 'elpher-redraw)
1440     (define-key map (kbd "R") 'elpher-reload)
1441     (define-key map (kbd "T") 'elpher-toggle-tls)
1442     (define-key map (kbd ".") 'elpher-view-raw)
1443     (define-key map (kbd "d") 'elpher-download)
1444     (define-key map (kbd "D") 'elpher-download-current)
1445     (define-key map (kbd "m") 'elpher-jump)
1446     (define-key map (kbd "i") 'elpher-info-link)
1447     (define-key map (kbd "I") 'elpher-info-current)
1448     (define-key map (kbd "c") 'elpher-copy-link-url)
1449     (define-key map (kbd "C") 'elpher-copy-current-url)
1450     (define-key map (kbd "a") 'elpher-bookmark-link)
1451     (define-key map (kbd "A") 'elpher-bookmark-current)
1452     (define-key map (kbd "x") 'elpher-unbookmark-link)
1453     (define-key map (kbd "X") 'elpher-unbookmark-current)
1454     (define-key map (kbd "B") 'elpher-bookmarks)
1455     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1456     (when (fboundp 'evil-define-key*)
1457       (evil-define-key* 'motion map
1458         (kbd "TAB") 'elpher-next-link
1459         (kbd "C-") 'elpher-follow-current-link
1460         (kbd "C-t") 'elpher-back
1461         (kbd "u") 'elpher-back
1462         [mouse-3] 'elpher-back
1463         (kbd "g") 'elpher-go
1464         (kbd "o") 'elpher-go-current
1465         (kbd "r") 'elpher-redraw
1466         (kbd "R") 'elpher-reload
1467         (kbd "T") 'elpher-toggle-tls
1468         (kbd ".") 'elpher-view-raw
1469         (kbd "d") 'elpher-download
1470         (kbd "D") 'elpher-download-current
1471         (kbd "m") 'elpher-jump
1472         (kbd "i") 'elpher-info-link
1473         (kbd "I") 'elpher-info-current
1474         (kbd "c") 'elpher-copy-link-url
1475         (kbd "C") 'elpher-copy-current-url
1476         (kbd "a") 'elpher-bookmark-link
1477         (kbd "A") 'elpher-bookmark-current
1478         (kbd "x") 'elpher-unbookmark-link
1479         (kbd "X") 'elpher-unbookmark-current
1480         (kbd "B") 'elpher-bookmarks
1481         (kbd "S") 'elpher-set-gopher-coding-system))
1482     map)
1483   "Keymap for gopher client.")
1484
1485 (define-derived-mode elpher-mode special-mode "elpher"
1486   "Major mode for elpher, an elisp gopher client.
1487
1488 This mode is automatically enabled by the interactive
1489 functions which initialize the gopher client, namely
1490 `elpher', `elpher-go' and `elpher-bookmarks'.")
1491
1492 (when (fboundp 'evil-set-initial-state)
1493   (evil-set-initial-state 'elpher-mode 'motion))
1494
1495
1496 ;;; Main start procedure
1497 ;;
1498
1499 ;;;###autoload
1500 (defun elpher ()
1501   "Start elpher with default landing page."
1502   (interactive)
1503   (if (get-buffer "*elpher*")
1504       (switch-to-buffer "*elpher*")
1505     (switch-to-buffer "*elpher*")
1506     (setq elpher-current-node nil)
1507     (let ((start-node (elpher-make-node "Elpher Start Page"
1508                                         (elpher-make-special-address 'start))))
1509       (elpher-visit-node start-node)))
1510   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1511
1512 ;;; elpher.el ends here