elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2020 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 2.11.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: https://alexschroeder.ch/cgit/elpher
  25 ;; Package-Requires: ((emacs "27.1"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - gopher connections using TLS encryption,
  54 ;; - the fledgling Gemini protocol,
  55 ;; - the greybeard Finger protocol.
  56
  57 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  58 ;; page containing information on key bindings and suggested starting
  59 ;; points for your gopher exploration.
  60
  61 ;; Full instructions can be found in the Elpher info manual.
  62
  63 ;; Elpher is under active development.  Any suggestions for
  64 ;; improvements are welcome, and can be made on the official
  65 ;; project page, https://alexschroeder.ch/cgit/elpher.
  66
  67 ;;; Code:
  68
  69 (provide 'elpher)
  70
  71 ;;; Dependencies
  72 ;;
  73
  74 (require 'seq)
  75 (require 'pp)
  76 (require 'shr)
  77 (require 'url-util)
  78 (require 'subr-x)
  79 (require 'dns)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83
  84 ;;; ANSI colors or XTerm colors
  85
  86 (or (require 'xterm-color nil t)
  87     (require 'ansi-color))
  88
  89 (defalias 'elpher-color-filter-apply
  90   (if (fboundp 'xterm-color-filter)
  91       (lambda (s)
  92         (let ((xterm-color-render nil))
  93           (xterm-color-filter s)))
  94     'ansi-color-filter-apply)
  95   "A function to filter out ANSI escape sequences.")
  96 (defalias 'elpher-color-apply
  97   (if (fboundp 'xterm-color-filter)
  98       'xterm-color-filter
  99     'ansi-color-apply)
 100   "A function to apply ANSI escape sequences.")
 101
 102 ;;; Global constants
 103 ;;
 104
 105 (defconst elpher-version "2.11.0"
 106   "Current version of elpher.")
 107
 108 (defconst elpher-margin-width 6
 109   "Width of left-hand margin used when rendering indicies.")
 110
 111 (defconst elpher-type-map
 112   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 113     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 114     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 115     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 116     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 117     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 118     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 119     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 120     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 122     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 123     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 124     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 125     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 126     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 127     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 128     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 129     ((special start) elpher-get-start-page nil))
 130   "Association list from types to getters, renderers, margin codes and index faces.")
 131
 132
 133 ;;; Internal variables
 134 ;;
 135
 136 ;; buffer-local
 137 (defvar elpher--gemini-page-headings nil
 138   "List of headings on the page.")
 139
 140 (defvar elpher--gemini-page-links nil
 141   "List of links on the page.")
 142
 143 (defvar elpher--gemini-page-links-cache (make-hash-table :test 'equal)
 144   "Hash of addresses and page links.")
 145
 146 ;;; Customization group
 147 ;;
 148
 149 (defgroup elpher nil
 150   "A gopher and gemini client."
 151   :group 'applications)
 152
 153 ;; General appearance and customizations
 154
 155 (defcustom elpher-open-urls-with-eww nil
 156   "If non-nil, open URL selectors using eww.
 157 Otherwise, use the system browser via the `browse-url' function."
 158   :type '(boolean))
 159
 160 (defcustom elpher-use-header t
 161   "If non-nil, display current page information in buffer header."
 162   :type '(boolean))
 163
 164 (defcustom elpher-auto-disengage-TLS nil
 165   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 166 While enabling this may seem convenient, it is also potentially
 167 dangerous as it allows switching from an encrypted channel back to
 168 plain text without user input."
 169   :type '(boolean))
 170
 171 (defcustom elpher-connection-timeout 5
 172   "Specifies the number of seconds to wait for a network connection to time out."
 173   :type '(integer))
 174
 175 (defcustom elpher-filter-ansi-from-text nil
 176   "If non-nil, filter ANSI escape sequences from text.
 177 The default behaviour is to use the ansi-color package to interpret these
 178 sequences."
 179   :type '(boolean))
 180
 181 (defcustom elpher-certificate-directory
 182   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 183   "Specify the name of the directory where client certificates will be stored.
 184 These certificates may be used for establishing authenticated TLS connections."
 185   :type '(directory))
 186
 187 (defcustom elpher-openssl-command "openssl"
 188   "The command used to launch openssl when generating TLS client certificates."
 189   :type '(file))
 190
 191 (defcustom elpher-default-url-type "gopher"
 192   "Default URL type (i.e. scheme) to assume if not explicitly given."
 193   :type '(choice (const "gopher")
 194                  (const "gemini")))
 195
 196 (defcustom elpher-gemini-TLS-cert-checks nil
 197   "If non-nil, verify gemini server TLS certs using the default security level.
 198 Otherwise, certificate verification is disabled.
 199
 200 This defaults to off because it is standard practice for Gemini servers
 201 to use self-signed certificates, meaning that most servers provide what
 202 EMACS considers to be an invalid certificate."
 203   :type '(boolean))
 204
 205 (defcustom elpher-gemini-max-fill-width 80
 206   "Specify the maximum default width (in columns) of text/gemini documents.
 207 The actual width used is the minimum of this value and the window width at
 208 the time when the text is rendered."
 209   :type '(integer))
 210
 211 (defcustom elpher-gemini-link-string "→ "
 212   "Specify the string used to indicate links when rendering gemini maps.
 213 May be empty."
 214   :type '(string))
 215
 216 (defcustom elpher-gemini-bullet-string "•"
 217   "Specify the string used for bullets when rendering gemini maps."
 218   :type '(string))
 219
 220 (defcustom elpher-ipv4-always nil
 221   "If non-nil, elpher will always use IPv4 to establish network connections.
 222 This can be useful when browsing from a computer that supports IPv6, because
 223 some servers which do not support IPv6 can take a long time to time-out."
 224   :type '(boolean))
 225
 226 (defcustom elpher-socks-always nil
 227   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 228 Otherwise, the SOCKS proxy is only used for connections to onion services."
 229   :type '(boolean))
 230
 231 (defcustom elpher-gemini-number-links nil
 232   "If non-nil, number links in gemini pages when rendering.
 233 Links can be accessed by pressing `v' ('visit') followed by the link number."
 234   :type '(boolean))
 235
 236 ;; Face customizations
 237
 238 (defgroup elpher-faces nil
 239   "Elpher face customizations."
 240   :group 'elpher)
 241
 242 (defface elpher-index
 243   '((t :inherit font-lock-keyword-face))
 244   "Face used for directory type directory records.")
 245
 246 (defface elpher-text
 247   '((t :inherit bold))
 248   "Face used for text type directory records.")
 249
 250 (defface elpher-info
 251   '((t :inherit default))
 252   "Face used for info type directory records.")
 253
 254 (defface elpher-image
 255   '((t :inherit font-lock-string-face))
 256   "Face used for image type directory records.")
 257
 258 (defface elpher-search
 259   '((t :inherit warning))
 260   "Face used for search type directory records.")
 261
 262 (defface elpher-html
 263   '((t :inherit font-lock-comment-face))
 264   "Face used for html type directory records.")
 265
 266 (defface elpher-gemini
 267   '((t :inherit font-lock-constant-face))
 268   "Face used for Gemini type directory records.")
 269
 270 (defface elpher-other-url
 271   '((t :inherit font-lock-comment-face))
 272   "Face used for other URL type links records.")
 273
 274 (defface elpher-telnet
 275   '((t :inherit font-lock-function-name-face))
 276   "Face used for telnet type directory records.")
 277
 278 (defface elpher-binary
 279   '((t :inherit font-lock-doc-face))
 280   "Face used for binary type directory records.")
 281
 282 (defface elpher-unknown
 283   '((t :inherit error))
 284   "Face used for directory records with unknown/unsupported types.")
 285
 286 (defface elpher-margin-key
 287   '((t :inherit bold))
 288   "Face used for directory margin key.")
 289
 290 (defface elpher-margin-brackets
 291   '((t :inherit shadow))
 292   "Face used for brackets around directory margin key.")
 293
 294 (defface elpher-gemini-heading1
 295   '((t :inherit bold :height 1.8))
 296   "Face used for gemini heading level 1.")
 297
 298 (defface elpher-gemini-heading2
 299   '((t :inherit bold :height 1.5))
 300   "Face used for gemini heading level 2.")
 301
 302 (defface elpher-gemini-heading3
 303   '((t :inherit bold :height 1.2))
 304   "Face used for gemini heading level 3.")
 305
 306 (defface elpher-gemini-preformatted
 307   '((t :inherit fixed-pitch))
 308   "Face used for pre-formatted gemini text blocks.")
 309
 310 (defface elpher-gemini-quoted
 311   '((t :inherit font-lock-doc-face))
 312   "Face used for gemini quoted texts.")
 313
 314 ;;; Model
 315 ;;
 316
 317 ;; Address
 318
 319 ;; An elpher "address" object is either a url object or a symbol.
 320 ;; Symbol addresses are "special", corresponding to pages generated
 321 ;; dynamically for and by elpher.  All others represent pages which
 322 ;; rely on content retrieved over the network.
 323
 324 (defun elpher-address-from-url (url-string)
 325   "Create a ADDRESS object corresponding to the given URL-STRING."
 326   (let ((data (match-data))) ; Prevent parsing clobbering match data
 327     (unwind-protect
 328         (let ((url (url-generic-parse-url url-string)))
 329           (unless (and (not (url-fullness url)) (url-type url))
 330             (setf (url-fullness url) t)
 331             (setf (url-filename url)
 332                   (url-unhex-string (url-filename url)))
 333             (unless (url-type url)
 334               (setf (url-type url) elpher-default-url-type))
 335             (unless (url-host url)
 336               (let ((p (split-string (url-filename url) "/" nil nil)))
 337                 (setf (url-host url) (car p))
 338                 (setf (url-filename url)
 339                       (if (cdr p)
 340                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 341                         ""))))
 342             (when (or (equal "gopher" (url-type url))
 343                       (equal "gophers" (url-type url)))
 344               ;; Gopher defaults
 345               (when (or (equal (url-filename url) "")
 346                         (equal (url-filename url) "/"))
 347                 (setf (url-filename url) "/1")))
 348             (when (equal "gemini" (url-type url))
 349               ;; Gemini defaults
 350               (if (equal (url-filename url) "")
 351                   (setf (url-filename url) "/"))))
 352           (elpher-remove-redundant-ports url))
 353       (set-match-data data))))
 354
 355 (defun elpher-remove-redundant-ports (address)
 356   "Remove redundant port specifiers from ADDRESS.
 357 Here 'redundant' means that the specified port matches the default
 358 for that protocol, eg 70 for gopher."
 359   (if (and (not (elpher-address-special-p address))
 360            (eq (url-portspec address) ; (url-port) is too slow!
 361                (pcase (url-type address)
 362                  ("gemini" 1965)
 363                  ((or "gopher" "gophers") 70)
 364                  ("finger" 79)
 365                  (_ -1))))
 366       (setf (url-portspec address) nil))
 367   address)
 368
 369 (defun elpher-make-gopher-address (type selector host port &optional tls)
 370   "Create an ADDRESS object using gopher directory record attributes.
 371 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 372 If the optional attribute TLS is non-nil, the address will be marked as
 373 requiring gopher-over-TLS."
 374   (cond
 375    ((equal type ?i) nil)
 376    ((and (equal type ?h)
 377          (string-prefix-p "URL:" selector))
 378     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 379    ((equal type ?8)
 380     (elpher-address-from-url
 381      (concat "telnet"
 382              "://" host
 383              ":" (number-to-string port))))
 384    (t
 385     (elpher-address-from-url
 386      (concat "gopher" (if tls "s" "")
 387              "://" host
 388              ":" (number-to-string port)
 389              "/" (string type)
 390              selector)))))
 391
 392 (defun elpher-make-special-address (type)
 393   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 394   type)
 395
 396 (defun elpher-make-start-page ()
 397   "Create the start page."
 398   (elpher-make-page "Elpher Start Page"
 399                     (elpher-make-special-address 'start)))
 400
 401 (defun elpher-address-to-url (address)
 402   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 403   (if (elpher-address-special-p address)
 404       nil
 405     (url-encode-url (url-recreate-url address))))
 406
 407 (defun elpher-address-type (address)
 408   "Retrieve type of ADDRESS object.
 409 This is used to determine how to retrieve and render the document the
 410 address refers to, via the table `elpher-type-map'."
 411   (if (symbolp address)
 412       (list 'special address)
 413     (let ((protocol (url-type address)))
 414       (cond ((or (equal protocol "gopher")
 415                  (equal protocol "gophers"))
 416              (list 'gopher
 417                    (if (member (url-filename address) '("" "/"))
 418                        ?1
 419                      (string-to-char (substring (url-filename address) 1)))))
 420             ((equal protocol "gemini")
 421              'gemini)
 422             ((equal protocol "telnet")
 423              'telnet)
 424             ((equal protocol "finger")
 425              'finger)
 426             (t 'other-url)))))
 427
 428 (defun elpher-address-protocol (address)
 429   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 430   (if (symbolp address)
 431       nil
 432     (url-type address)))
 433
 434 (defun elpher-address-filename (address)
 435   "Retrieve the filename component of ADDRESS.
 436 For gopher addresses this is a combination of the selector type and selector."
 437   (if (symbolp address)
 438       nil
 439     (url-filename address)))
 440
 441 (defun elpher-address-host (address)
 442   "Retrieve host from ADDRESS object."
 443   (url-host address))
 444
 445 (defun elpher-address-user (address)
 446   "Retrieve user from ADDRESS object."
 447   (url-user address))
 448
 449 (defun elpher-address-port (address)
 450   "Retrieve port from ADDRESS object.
 451 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 452   (if (symbolp address)
 453       0
 454     (url-port address)))
 455
 456 (defun elpher-address-special-p (address)
 457   "Return non-nil if ADDRESS object is special (e.g. start page page)."
 458   (symbolp address))
 459
 460 (defun elpher-address-gopher-p (address)
 461   "Return non-nill if ADDRESS object is a gopher address."
 462   (and (not (elpher-address-special-p address))
 463        (member (elpher-address-protocol address) '("gopher gophers"))))
 464
 465 (defun elpher-gopher-address-selector (address)
 466   "Retrieve gopher selector from ADDRESS object."
 467   (if (member (url-filename address) '("" "/"))
 468       ""
 469     (url-unhex-string (substring (url-filename address) 2))))
 470
 471
 472 ;; Cache
 473
 474 (defvar elpher-content-cache (make-hash-table :test 'equal))
 475 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 476
 477 (defun elpher-get-cached-content (address)
 478   "Retrieve the cached content for ADDRESS, or nil if none exists."
 479   (gethash address elpher-content-cache))
 480
 481 (defun elpher-cache-content (address content)
 482   "Set the content cache for ADDRESS to CONTENT."
 483   (puthash address content elpher-content-cache))
 484
 485 (defun elpher-get-cached-pos (address)
 486   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 487   (gethash address elpher-pos-cache))
 488
 489 (defun elpher-cache-pos (address pos)
 490   "Set the cursor position cache for ADDRESS to POS."
 491   (puthash address pos elpher-pos-cache))
 492
 493
 494 ;; Page
 495
 496 (defun elpher-make-page (display-string address)
 497   "Create a page with DISPLAY-STRING and ADDRESS."
 498   (list display-string address))
 499
 500 (defun elpher-page-display-string (page)
 501   "Retrieve the display string corresponding to PAGE."
 502   (elt page 0))
 503
 504 (defun elpher-page-address (page)
 505   "Retrieve the address corresponding to PAGE."
 506   (elt page 1))
 507
 508 (defun elpher-page-set-address (page new-address)
 509   "Set the address corresponding to PAGE to NEW-ADDRESS."
 510   (setcar (cdr page) new-address))
 511
 512 (defvar elpher-current-page nil) ; buffer local
 513 (defvar elpher-history nil)      ; buffer local
 514
 515 (defun elpher-visit-page (page &optional renderer no-history)
 516   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 517 Additionally, push PAGE onto the stack of previously-visited pages,
 518 unless NO-HISTORY is non-nil."
 519   (elpher-save-pos)
 520   (elpher-process-cleanup)
 521   (unless (or no-history
 522               (equal (elpher-page-address elpher-current-page)
 523                      (elpher-page-address page)))
 524     (push elpher-current-page elpher-history))
 525   (setq-local elpher-current-page page)
 526   (let* ((address (elpher-page-address page))
 527          (type (elpher-address-type address))
 528          (type-record (cdr (assoc type elpher-type-map)))
 529          (page-links nil))
 530     (if type-record
 531         (progn
 532           (funcall (car type-record)
 533                    (if renderer
 534                        renderer
 535                      (cadr type-record)))
 536           (setq page-links (gethash address elpher--gemini-page-links-cache))
 537           (if page-links
 538               (setq elpher--gemini-page-links page-links)))
 539       (elpher-visit-previous-page)
 540       (pcase type
 541         (`(gopher ,type-char)
 542          (error "Unsupported gopher selector type '%c' for '%s'"
 543                 type-char (elpher-address-to-url address)))
 544         (other
 545          (error "Unsupported address type '%S' for '%s'"
 546                 other (elpher-address-to-url address)))))))
 547
 548 (defun elpher-visit-previous-page ()
 549   "Visit the previous page in the history."
 550   (let ((previous-page (pop elpher-history)))
 551     (if previous-page
 552         (elpher-visit-page previous-page nil t)
 553       (error "No previous page"))))
 554
 555 (defun elpher-reload-current-page ()
 556   "Reload the current page, discarding any existing cached content."
 557   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 558   (elpher-visit-page elpher-current-page))
 559
 560 (defun elpher-save-pos ()
 561   "Save the current position of point to the current page."
 562   (when elpher-current-page
 563     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 564
 565 (defun elpher-restore-pos ()
 566   "Restore the position of point to that cached in the current page."
 567   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 568     (if pos
 569         (goto-char pos)
 570       (goto-char (point-min)))))
 571
 572
 573 ;;; Buffer preparation
 574 ;;
 575
 576 (defvar elpher-buffer-name "*elpher*"
 577   "The default name of the Elpher buffer.")
 578
 579 (defun elpher-update-header ()
 580   "If `elpher-use-header' is true, display current page info in window header."
 581   (if elpher-use-header
 582       (let* ((display-string (elpher-page-display-string elpher-current-page))
 583              (address (elpher-page-address elpher-current-page))
 584              (tls-string (if (and (not (elpher-address-special-p address))
 585                                   (member (elpher-address-protocol address)
 586                                           '("gophers" "gemini")))
 587                              " [TLS encryption]"
 588                            ""))
 589              (header (concat display-string
 590                              (propertize tls-string 'face 'bold))))
 591         (setq header-line-format header))))
 592
 593 (defmacro elpher-with-clean-buffer (&rest args)
 594   "Evaluate ARGS with a clean *elpher* buffer as current."
 595   `(with-current-buffer elpher-buffer-name
 596      (unless (eq major-mode 'elpher-mode)
 597        ;; avoid resetting buffer-local variables
 598        (elpher-mode))
 599      (let ((inhibit-read-only t))
 600        (setq-local network-security-level
 601                    (default-value 'network-security-level))
 602        (erase-buffer)
 603        (elpher-update-header)
 604        ,@args)))
 605
 606 (defun elpher-buffer-message (string &optional line)
 607   "Replace first line in elpher buffer with STRING.
 608 If LINE is non-nil, replace that line instead."
 609   (with-current-buffer elpher-buffer-name
 610     (let ((inhibit-read-only t))
 611       (goto-char (point-min))
 612       (if line
 613           (forward-line line))
 614       (let ((data (match-data)))
 615         (unwind-protect
 616             (progn
 617               (re-search-forward "^.*$")
 618               (replace-match string))
 619           (set-match-data data))))))
 620
 621
 622 ;;; Text Processing
 623 ;;
 624
 625 (defvar elpher-user-coding-system nil
 626   "User-specified coding system to use for decoding text responses.")
 627
 628 (defun elpher-decode (string)
 629   "Decode STRING using autodetected or user-specified coding system."
 630   (decode-coding-string string
 631                         (if elpher-user-coding-system
 632                             elpher-user-coding-system
 633                           (detect-coding-string string t))))
 634
 635 (defun elpher-preprocess-text-response (string)
 636   "Preprocess text selector response contained in STRING.
 637 This involes decoding the character representation, and clearing
 638 away CRs and any terminating period."
 639   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 640                                            (replace-regexp-in-string "\r" "" string))))
 641
 642
 643 ;;; Network error reporting
 644 ;;
 645
 646 (defun elpher-network-error (address error)
 647   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 648 ERROR can be either an error object or a string."
 649   (elpher-with-clean-buffer
 650    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 651            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 652            (if (stringp error) error (error-message-string error)) "\n"
 653            (propertize "\n----------------\n\n" 'face 'error)
 654            "Press 'u' to return to the previous page.")))
 655
 656
 657 ;;; General network communication
 658 ;;
 659
 660 (defvar elpher-network-timer nil
 661   "Timer used for network connections.")
 662
 663 (defvar elpher-use-tls nil
 664   "If non-nil, use TLS to communicate with gopher servers.")
 665
 666 (defvar elpher-client-certificate nil
 667   "If non-nil, contains client certificate details to use for TLS connections.")
 668
 669 (defun elpher-process-cleanup ()
 670   "Immediately shut down any extant elpher process and timers."
 671   (let ((p (get-process "elpher-process")))
 672     (if p (delete-process p)))
 673   (if (timerp elpher-network-timer)
 674       (cancel-timer elpher-network-timer)))
 675
 676 (defun elpher-get-host-response (address default-port query-string response-processor
 677                                          &optional use-tls force-ipv4)
 678   "Generic function for retrieving data from ADDRESS.
 679
 680 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 681 QUERY-STRING is a string sent to the host specified by ADDRESS to
 682 illicet a response.  This response is passed as an argument to the
 683 function RESPONSE-PROCESSOR.
 684
 685 If non-nil, USE-TLS specifies that the connection is to be made over
 686 TLS.  If set to gemini, the certificate verification will be disabled
 687 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 688
 689 If non-nil, FORCE-IPV4 causes the network connection to be made over
 690 ipv4 only.  (The default behaviour when this is not set depends on
 691 the host operating system and the local network capabilities."
 692   (if (and use-tls (not (gnutls-available-p)))
 693       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 694     (unless (< (elpher-address-port address) 65536)
 695       (error "Cannot establish network connection: port number > 65536"))
 696     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 697       (setq-local network-security-level 'low)
 698       (setq-local gnutls-verify-error nil))
 699     (condition-case nil
 700         (let* ((kill-buffer-query-functions nil)
 701                (port (elpher-address-port address))
 702                (service (if (> port 0) port default-port))
 703                (host (elpher-address-host address))
 704                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 705                (response-string-parts nil)
 706                (bytes-received 0)
 707                (hkbytes-received 0)
 708                (timer (run-at-time elpher-connection-timeout nil
 709                                    (lambda ()
 710                                      (elpher-process-cleanup)
 711                                      (cond
 712                                         ; Try again with IPv4
 713                                       ((not (or force-ipv4 socks))
 714                                        (message "Connection timed out.  Retrying with IPv4.")
 715                                        (elpher-get-host-response address default-port
 716                                                                  query-string
 717                                                                  response-processor
 718                                                                  use-tls t))
 719                                       ((and use-tls
 720                                             (not (eq use-tls 'gemini))
 721                                             (or elpher-auto-disengage-TLS
 722                                                 (y-or-n-p
 723                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 724                                        (setq elpher-use-tls nil)
 725                                        (elpher-get-host-response address default-port
 726                                                                  query-string
 727                                                                  response-processor
 728                                                                  nil force-ipv4))
 729                                       (t
 730                                        (elpher-network-error address "Connection time-out."))))))
 731                (gnutls-params (list :type 'gnutls-x509pki :hostname host
 732                                     :keylist (elpher-get-current-keylist address)))
 733                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 734                        (make-network-process :name "elpher-process"
 735                                              :host host
 736                                              :family (and force-ipv4 'ipv4)
 737                                              :service service
 738                                              :buffer nil
 739                                              :nowait t
 740                                              :tls-parameters
 741                                              (and use-tls
 742                                                   (cons 'gnutls-x509pki
 743                                                         (apply #'gnutls-boot-parameters
 744                                                                gnutls-params)))))))
 745           (setq elpher-network-timer timer)
 746           (set-process-coding-system proc 'binary 'binary)
 747           (set-process-query-on-exit-flag proc nil)
 748           (elpher-buffer-message (concat "Connecting to " host "..."
 749                                          " (press 'u' to abort)"))
 750           (set-process-filter proc
 751                               (lambda (_proc string)
 752                                 (when timer
 753                                   (cancel-timer timer)
 754                                   (setq timer nil))
 755                                 (setq bytes-received (+ bytes-received (length string)))
 756                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 757                                   (when (> new-hkbytes-received hkbytes-received)
 758                                     (setq hkbytes-received new-hkbytes-received)
 759                                     (elpher-buffer-message
 760                                      (concat "("
 761                                              (number-to-string (/ hkbytes-received 10.0))
 762                                              " MB read)")
 763                                      1)))
 764                                 (setq response-string-parts
 765                                       (cons string response-string-parts))))
 766           (set-process-sentinel proc
 767                                 (lambda (proc event)
 768                                   (when timer
 769                                     (cancel-timer timer))
 770                                   (condition-case the-error
 771                                       (cond
 772                                        ((string-prefix-p "open" event)    ; request URL
 773                                         (elpher-buffer-message
 774                                          (concat "Connected to " host ". Receiving data..."
 775                                                  " (press 'u' to abort)"))
 776                                         (let ((inhibit-eol-conversion t))
 777                                           (process-send-string proc query-string)))
 778                                        ((string-prefix-p "deleted" event)) ; do nothing
 779                                        ((and (not response-string-parts)
 780                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 781                                         ; Try again with IPv4
 782                                         (message "Connection failed. Retrying with IPv4.")
 783                                         (elpher-get-host-response address default-port
 784                                                                   query-string
 785                                                                   response-processor
 786                                                                   use-tls t))
 787                                        (response-string-parts
 788                                         (elpher-with-clean-buffer
 789                                          (insert "Data received.  Rendering..."))
 790                                         (funcall response-processor
 791                                                  (apply #'concat (reverse response-string-parts)))
 792                                         (elpher-restore-pos))
 793                                        (t
 794                                         (error "No response from server")))
 795                                     (error
 796                                      (elpher-network-error address the-error)))))
 797           (when socks
 798             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 799             (funcall (process-sentinel proc) proc "open\n")))
 800       (error
 801        (error "Error initiating connection to server")))))
 802
 803
 804 ;;; Client-side TLS Certificate Management
 805 ;;
 806
 807 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 808   "Generate a key and a self-signed client TLS certificate using openssl.
 809
 810 The Common Name field of the certificate is set to COMMON-NAME.  The
 811 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 812 the key and certificate files to write.
 813
 814 If TEMPORARY is non-nil, the certificate will be given an exporation
 815 period of one day, and the key and certificate files will be deleted
 816 when the certificate is no longer needed for the current session.
 817
 818 Otherwise, the certificate will be given a 100 year expiration period
 819 and the files will not be deleted.
 820
 821 The function returns a list containing the current host name, the
 822 temporary flag, and the key and cert file names in the form required
 823 by `gnutls-boot-parameters`."
 824   (let ((exp-key-file (expand-file-name key-file))
 825         (exp-cert-file (expand-file-name cert-file)))
 826     (condition-case nil
 827         (progn
 828           (call-process elpher-openssl-command nil nil nil
 829                         "req" "-x509" "-newkey" "rsa:2048"
 830                         "-days" (if temporary "1" "36500")
 831                         "-nodes"
 832                         "-subj" (concat "/CN=" common-name)
 833                         "-keyout" exp-key-file
 834                         "-out" exp-cert-file)
 835           (list (elpher-address-host (elpher-page-address elpher-current-page))
 836                 temporary exp-key-file exp-cert-file))
 837       (error
 838        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 839        (error "Program 'openssl', required for certificate generation, not found")))))
 840
 841 (defun elpher-generate-throwaway-certificate ()
 842   "Generate and return details of a throwaway certificate.
 843 The key and certificate files will be deleted when they are no
 844 longer needed for this session."
 845   (let* ((file-base (make-temp-name "elpher"))
 846          (key-file (concat temporary-file-directory file-base ".key"))
 847          (cert-file (concat temporary-file-directory file-base ".crt")))
 848     (elpher-generate-certificate file-base key-file cert-file t)))
 849
 850 (defun elpher-generate-persistent-certificate (file-base common-name)
 851   "Generate and return details of a persistent certificate.
 852 The argument FILE-BASE is used as the base for the key and certificate
 853 files, while COMMON-NAME specifies the common name field of the
 854 certificate.
 855
 856 The key and certificate files are written to in `elpher-certificate-directory'."
 857   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 858          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 859     (elpher-generate-certificate common-name key-file cert-file)))
 860
 861 (defun elpher-get-existing-certificate (file-base)
 862   "Return a certificate object corresponding to an existing certificate.
 863 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 864 the directory `elpher-certificate-directory'."
 865   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 866          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 867     (list (elpher-address-host (elpher-page-address elpher-current-page))
 868           nil
 869           (expand-file-name key-file)
 870           (expand-file-name cert-file))))
 871
 872 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 873   "Install a key+certificate file pair in `elpher-certificate-directory'.
 874 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 875 certificate files to install.  The argument FILE-BASE is used as the
 876 base for the installed key and certificate files."
 877   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 878          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 879     (if (or (file-exists-p key-file)
 880             (file-exists-p cert-file))
 881         (error "A certificate with base name %s is already installed" file-base))
 882     (copy-file key-file-src key-file)
 883     (copy-file cert-file-src cert-file)
 884     (list (elpher-address-host (elpher-page-address elpher-current-page))
 885           nil
 886           (expand-file-name key-file)
 887           (expand-file-name cert-file))))
 888
 889 (defun elpher-list-existing-certificates ()
 890   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 891   (unless (file-directory-p elpher-certificate-directory)
 892     (make-directory elpher-certificate-directory))
 893   (mapcar
 894    (lambda (file)
 895      (file-name-sans-extension file))
 896    (directory-files elpher-certificate-directory nil "\\.key$")))
 897
 898 (defun elpher-forget-current-certificate ()
 899   "Causes any current certificate to be forgotten.)
 900 In the case of throwaway certificates, the key and certificate files
 901 are also deleted."
 902   (interactive)
 903   (when elpher-client-certificate
 904     (unless (and (called-interactively-p 'any)
 905                  (not (y-or-n-p (concat "Really forget client certificate? "
 906                                         "(Throwaway certificates will be deleted.)"))))
 907       (when (cadr elpher-client-certificate)
 908         (delete-file (elt elpher-client-certificate 2))
 909         (delete-file (elt elpher-client-certificate 3)))
 910       (setq elpher-client-certificate nil)
 911       (if (called-interactively-p 'any)
 912           (message "Client certificate forgotten.")))))
 913
 914 (defun elpher-get-current-keylist (address)
 915   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 916
 917 This is obtained from the client certificate described by
 918 `elpher-current-certificate', if one is available and the host for
 919 that certificate matches the host in ADDRESS.
 920
 921 If `elpher-current-certificate' is non-nil, and its host name doesn't
 922 match that of ADDRESS, the certificate is forgotten."
 923   (if elpher-client-certificate
 924       (if (string= (car elpher-client-certificate)
 925                    (elpher-address-host address))
 926           (list (cddr elpher-client-certificate))
 927         (elpher-forget-current-certificate)
 928         (message "Disabling client certificate for new host")
 929         nil)
 930     nil))
 931
 932
 933 ;;; Gopher selector retrieval
 934 ;;
 935
 936 (defun elpher-get-gopher-response (address renderer)
 937   "Get response string from gopher server at ADDRESS and render using RENDERER."
 938   (elpher-get-host-response address 70
 939                             (concat (elpher-gopher-address-selector address) "\r\n")
 940                             renderer
 941                             (or (string= (elpher-address-protocol address) "gophers")
 942                                 elpher-use-tls)))
 943
 944 (defun elpher-get-gopher-page (renderer)
 945   "Getter function for gopher pages.
 946 The RENDERER procedure is used to display the contents of the page
 947 once they are retrieved from the gopher server."
 948   (let* ((address (elpher-page-address elpher-current-page))
 949          (content (elpher-get-cached-content address)))
 950     (if (and content (funcall renderer nil))
 951         (elpher-with-clean-buffer
 952          (insert content)
 953          (elpher-restore-pos))
 954       (elpher-with-clean-buffer
 955        (insert "LOADING... (use 'u' to cancel)\n"))
 956       (condition-case the-error
 957           (elpher-get-gopher-response address renderer)
 958         (error
 959          (elpher-network-error address the-error))))))
 960
 961 ;; Index rendering
 962
 963 (defun elpher-insert-index (string)
 964   "Insert the index corresponding to STRING into the current buffer."
 965   ;; Should be able to split directly on CRLF, but some non-conformant
 966   ;; LF-only servers sadly exist, hence the following.
 967   (let ((str-processed (elpher-preprocess-text-response string)))
 968     (dolist (line (split-string str-processed "\n"))
 969       (ignore-errors
 970         (unless (= (length line) 0)
 971           (let* ((type (elt line 0))
 972                  (fields (split-string (substring line 1) "\t"))
 973                  (display-string (elt fields 0))
 974                  (selector (elt fields 1))
 975                  (host (elt fields 2))
 976                  (port (if (elt fields 3)
 977                            (string-to-number (elt fields 3))
 978                          nil))
 979                  (address (elpher-make-gopher-address type selector host port)))
 980             (elpher-insert-index-record display-string address)))))))
 981
 982 (defun elpher-insert-margin (&optional type-name)
 983   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 984   (if type-name
 985       (progn
 986         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 987                         (concat
 988                          (propertize "[" 'face 'elpher-margin-brackets)
 989                          (propertize type-name 'face 'elpher-margin-key)
 990                          (propertize "]" 'face 'elpher-margin-brackets))))
 991         (insert " "))
 992     (insert (make-string elpher-margin-width ?\s))))
 993
 994 (defun elpher--page-button-help (_window buffer pos)
 995   "Function called by Emacs to generate mouse-over text.
 996 The arguments specify the BUFFER and the POS within the buffer of the item
 997 for which help is required.  The function returns the help to be
 998 displayed.  The _WINDOW argument is currently unused."
 999   (with-current-buffer buffer
1000     (let ((button (button-at pos)))
1001       (when button
1002         (let* ((page (button-get button 'elpher-page))
1003                (address (elpher-page-address page)))
1004           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1005                                                 address
1006                                               (elpher-address-to-url address))))))))
1007
1008 (defun elpher-insert-index-record (display-string &optional address)
1009   "Function to insert an index record into the current buffer.
1010 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1011 If ADDRESS is not supplied or nil the record is rendered as an
1012 'information' line."
1013   (let* ((type (if address (elpher-address-type address) nil))
1014          (type-map-entry (cdr (assoc type elpher-type-map))))
1015     (if type-map-entry
1016         (let* ((margin-code (elt type-map-entry 2))
1017                (face (elt type-map-entry 3))
1018                (filtered-display-string (elpher-color-filter-apply display-string))
1019                (page (elpher-make-page filtered-display-string address)))
1020           (elpher-insert-margin margin-code)
1021           (insert-text-button filtered-display-string
1022                               'face face
1023                               'elpher-page page
1024                               'action #'elpher-click-link
1025                               'follow-link t
1026                               'help-echo #'elpher--page-button-help))
1027       (pcase type
1028         ('nil ;; Information
1029          (elpher-insert-margin)
1030          (let ((propertized-display-string
1031                 (propertize display-string 'face 'elpher-info)))
1032            (insert (elpher-process-text-for-display propertized-display-string))))
1033         (`(gopher ,selector-type) ;; Unknown
1034          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1035          (insert (propertize display-string
1036                              'face 'elpher-unknown)))))
1037     (insert "\n")))
1038
1039 (defun elpher-click-link (button)
1040   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1041   (let ((page (button-get button 'elpher-page)))
1042     (elpher-visit-page page)))
1043
1044 (defun elpher-render-index (data &optional _mime-type-string)
1045   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1046   (elpher-with-clean-buffer
1047    (if (not data)
1048        t
1049      (elpher-insert-index data)
1050      (elpher-cache-content (elpher-page-address elpher-current-page)
1051                            (buffer-string)))))
1052
1053 ;; Text rendering
1054
1055 (defconst elpher-url-regex
1056   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
1057   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
1058
1059 (defun elpher-buttonify-urls (string)
1060   "Turn substrings which look like urls in STRING into clickable buttons."
1061   (with-temp-buffer
1062     (insert string)
1063     (goto-char (point-min))
1064     (while (re-search-forward elpher-url-regex nil t)
1065       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1066                                     (elpher-address-from-url (match-string 0)))))
1067         (make-text-button (match-beginning 0)
1068                           (match-end 0)
1069                           'elpher-page  page
1070                           'action #'elpher-click-link
1071                           'follow-link t
1072                           'help-echo #'elpher--page-button-help
1073                           'face 'button)))
1074     (buffer-string)))
1075
1076 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
1077   "Incomplete regexp used to strip out some troublesome ANSI escape sequences.")
1078
1079 (defun elpher-process-text-for-display (string)
1080   "Perform any desired processing of STRING prior to display as text.
1081 Currently includes buttonifying URLs and processing ANSI escape codes."
1082   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1083                              (elpher-color-filter-apply string)
1084                            (elpher-color-apply string))))
1085
1086 (defun elpher-render-text (data &optional _mime-type-string)
1087   "Render DATA as text.  MIME-TYPE-STRING is unused."
1088   (elpher-with-clean-buffer
1089    (if (not data)
1090        t
1091      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1092      (elpher-cache-content
1093       (elpher-page-address elpher-current-page)
1094       (buffer-string)))))
1095
1096 ;; Image retrieval
1097
1098 (defun elpher-render-image (data &optional _mime-type-string)
1099   "Display DATA as image.  MIME-TYPE-STRING is unused."
1100   (if (not data)
1101       nil
1102     (if (display-images-p)
1103         (progn
1104           (let ((image (create-image
1105                         data
1106                         nil t)))
1107             (elpher-with-clean-buffer
1108              (insert-image image)
1109              (elpher-restore-pos))))
1110       (elpher-render-download data))))
1111
1112 ;; Search retrieval and rendering
1113
1114 (defun elpher-get-gopher-query-page (renderer)
1115   "Getter for gopher addresses requiring input.
1116 The response is rendered using the rendering function RENDERER."
1117   (let* ((address (elpher-page-address elpher-current-page))
1118          (content (elpher-get-cached-content address))
1119          (aborted t))
1120     (if (and content (funcall renderer nil))
1121         (elpher-with-clean-buffer
1122          (insert content)
1123          (elpher-restore-pos)
1124          (message "Displaying cached search results.  Reload to perform a new search."))
1125       (unwind-protect
1126           (let* ((query-string (read-string "Query: "))
1127                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1128                  (search-address (elpher-make-gopher-address ?1
1129                                                              query-selector
1130                                                              (elpher-address-host address)
1131                                                              (elpher-address-port address)
1132                                                              (equal (elpher-address-type address) "gophers"))))
1133             (setq aborted nil)
1134
1135             (elpher-with-clean-buffer
1136              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1137             (elpher-get-gopher-response search-address renderer))
1138         (if aborted
1139             (elpher-visit-previous-page))))))
1140
1141 ;; Raw server response rendering
1142
1143 (defun elpher-render-raw (data &optional mime-type-string)
1144   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1145   (if (not data)
1146       nil
1147     (elpher-with-clean-buffer
1148      (when mime-type-string
1149        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1150      (insert data)
1151      (goto-char (point-min)))
1152     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1153
1154 ;; File save "rendering"
1155
1156 (defun elpher-render-download (data &optional _mime-type-string)
1157   "Save DATA to file.  MIME-TYPE-STRING is unused."
1158   (if (not data)
1159       nil
1160     (let* ((address (elpher-page-address elpher-current-page))
1161            (selector (if (elpher-address-gopher-p address)
1162                          (elpher-gopher-address-selector address)
1163                        (elpher-address-filename address))))
1164       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1165       (let* ((filename-proposal (file-name-nondirectory selector))
1166              (filename (read-file-name "Download complete. Save file as: "
1167                                        nil nil nil
1168                                        (if (> (length filename-proposal) 0)
1169                                            filename-proposal
1170                                          "download.file"))))
1171         (let ((coding-system-for-write 'binary))
1172           (with-temp-file filename
1173             (insert data)))
1174         (message (format "Saved to file %s." filename))))))
1175
1176 ;; HTML rendering
1177
1178 (defun elpher-render-html (data &optional _mime-type-string)
1179   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1180   (elpher-with-clean-buffer
1181    (if (not data)
1182        t
1183      (let ((dom (with-temp-buffer
1184                   (insert data)
1185                   (libxml-parse-html-region (point-min) (point-max)))))
1186        (shr-insert-document dom)))))
1187
1188 ;; Gemini page retrieval
1189
1190 (defvar elpher-gemini-redirect-chain)
1191
1192 (defun elpher-get-gemini-response (address renderer)
1193   "Get response string from gemini server at ADDRESS and render using RENDERER."
1194   (elpher-get-host-response address 1965
1195                             (concat (elpher-address-to-url address) "\r\n")
1196                             (lambda (response-string)
1197                               (elpher-process-gemini-response response-string renderer))
1198                             'gemini))
1199
1200 (defun elpher-parse-gemini-response (response)
1201   "Parse the RESPONSE string and return a list of components.
1202 The list is of the form (code meta body).  A response of nil implies
1203 that the response was malformed."
1204   (let ((header-end-idx (string-match "\r\n" response)))
1205     (if header-end-idx
1206         (let ((header (string-trim (substring response 0 header-end-idx)))
1207               (body (substring response (+ header-end-idx 2))))
1208           (if (>= (length header) 2)
1209               (let ((code (substring header 0 2))
1210                     (meta (string-trim (substring header 2))))
1211                 (list code meta body))
1212             (error "Malformed response: No response status found in header %s" header)))
1213       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1214
1215 (defun elpher-process-gemini-response (response-string renderer)
1216   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1217   (let ((response-components (elpher-parse-gemini-response response-string)))
1218     (let ((response-code (elt response-components 0))
1219           (response-meta (elt response-components 1))
1220           (response-body (elt response-components 2)))
1221       (pcase (elt response-code 0)
1222         (?1 ; Input required
1223          (elpher-with-clean-buffer
1224           (insert "Gemini server is requesting input."))
1225          (let* ((query-string
1226                  (if (eq (elt response-code 1) ?1)
1227                      (read-passwd (concat response-meta ": "))
1228                    (read-string (concat response-meta ": "))))
1229                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1230                 (old-fname (url-filename query-address)))
1231            (setf (url-filename query-address)
1232                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1233            (elpher-get-gemini-response query-address renderer)))
1234         (?2 ; Normal response
1235          (funcall renderer response-body response-meta))
1236         (?3 ; Redirect
1237          (message "Following redirect to %s" response-meta)
1238          (if (>= (length elpher-gemini-redirect-chain) 5)
1239              (error "More than 5 consecutive redirects followed"))
1240          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1241            (if (member redirect-address elpher-gemini-redirect-chain)
1242                (error "Redirect loop detected"))
1243            (if (not (string= (elpher-address-protocol redirect-address)
1244                              "gemini"))
1245                (error "Server tried to automatically redirect to non-gemini URL: %s"
1246                       response-meta))
1247            (elpher-page-set-address elpher-current-page redirect-address)
1248            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1249            (elpher-get-gemini-response redirect-address renderer)))
1250         (?4 ; Temporary failure
1251          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1252                 response-code response-meta))
1253         (?5 ; Permanent failure
1254          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1255                 response-code response-meta))
1256         (?6 ; Client certificate required
1257          (elpher-with-clean-buffer
1258           (if elpher-client-certificate
1259               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1260             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1261           (auto-fill-mode 1)
1262           (elpher-gemini-insert-text response-meta))
1263          (let ((chosen-certificate (elpher-choose-client-certificate)))
1264            (unless chosen-certificate
1265              (error "Gemini server requires a client certificate and none was provided"))
1266            (setq elpher-client-certificate chosen-certificate))
1267          (elpher-with-clean-buffer)
1268          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1269         (_other
1270          (error "Gemini server response unknown: %s %s"
1271                 response-code response-meta))))))
1272
1273 (unless (fboundp 'read-answer)
1274   (defun read-answer (question answers)
1275     "Backfill for the new read-answer code."
1276     (completing-read question (mapcar 'identity answers))))
1277
1278 (defun elpher-choose-client-certificate ()
1279   "Prompt for a client certificate to use to establish a TLS connection."
1280   (let* ((read-answer-short t))
1281     (pcase (read-answer "What do you want to do? "
1282                         '(("throwaway" ?t
1283                            "generate and use throw-away certificate")
1284                           ("persistent" ?p
1285                            "generate new or use existing persistent certificate")
1286                           ("abort" ?a
1287                            "stop immediately")))
1288       ("throwaway"
1289        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1290       ("persistent"
1291        (let* ((existing-certificates (elpher-list-existing-certificates))
1292               (file-base (completing-read
1293                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1294                           existing-certificates)))
1295          (if (string-empty-p (string-trim file-base))
1296              nil
1297            (if (member file-base existing-certificates)
1298                (setq elpher-client-certificate
1299                      (elpher-get-existing-certificate file-base))
1300              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1301                                  '(("new" ?n
1302                                     "generate new certificate")
1303                                    ("install" ?i
1304                                     "install existing certificate")
1305                                    ("abort" ?a
1306                                     "stop immediately")))
1307                ("new"
1308                 (let ((common-name (read-string "Common Name field for new certificate: "
1309                                                 file-base)))
1310                   (message "New key and self-signed certificate written to %s"
1311                            elpher-certificate-directory)
1312                   (elpher-generate-persistent-certificate file-base common-name)))
1313                ("install"
1314                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1315                        (key-file (read-file-name "Key file: " nil nil t)))
1316                   (message "Key and certificate installed in %s for future use"
1317                            elpher-certificate-directory)
1318                   (elpher-install-and-use-existing-certificate key-file
1319                                                                cert-file
1320                                                                file-base)))
1321                ("abort" nil))))))
1322       ("abort" nil))))
1323
1324 (defun elpher-get-gemini-page (renderer)
1325   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1326   (let* ((address (elpher-page-address elpher-current-page))
1327          (content (elpher-get-cached-content address)))
1328     (condition-case the-error
1329         (if (and content (funcall renderer nil))
1330             (elpher-with-clean-buffer
1331              (insert content)
1332              (elpher-restore-pos))
1333           (elpher-with-clean-buffer
1334            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1335           (setq elpher-gemini-redirect-chain nil)
1336           (elpher-get-gemini-response address renderer))
1337       (error
1338        (elpher-network-error address the-error)))))
1339
1340 (defun elpher-render-gemini (body &optional mime-type-string)
1341   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1342   (if (not body)
1343       t
1344     (let* ((mime-type-string* (if (or (not mime-type-string)
1345                                       (string-empty-p mime-type-string))
1346                                   "text/gemini; charset=utf-8"
1347                                 mime-type-string))
1348            (mime-type-split (split-string mime-type-string* ";" t))
1349            (mime-type (string-trim (car mime-type-split)))
1350            (parameters (mapcar (lambda (s)
1351                                  (let ((key-val (split-string s "=")))
1352                                    (list (downcase (string-trim (car key-val)))
1353                                          (downcase (string-trim (cadr key-val))))))
1354                                (cdr mime-type-split))))
1355       (when (string-prefix-p "text/" mime-type)
1356         (setq body (decode-coding-string
1357                     body
1358                     (if (assoc "charset" parameters)
1359                         (intern (cadr (assoc "charset" parameters)))
1360                       'utf-8)))
1361         (setq body (replace-regexp-in-string "\r" "" body)))
1362       (pcase mime-type
1363         ((or "text/gemini" "")
1364          (elpher-render-gemini-map body parameters))
1365         ("text/html"
1366          (elpher-render-html body))
1367         ((pred (string-prefix-p "text/"))
1368          (elpher-render-gemini-plain-text body parameters))
1369         ((pred (string-prefix-p "image/"))
1370          (elpher-render-image body))
1371         (_other
1372          (elpher-render-download body))))))
1373
1374 (defun elpher-gemini-get-link-url (link-line)
1375   "Extract the url portion of LINK-LINE, a gemini map file link line.
1376 Returns nil in the event that the contents of the line following the
1377 => prefix are empty."
1378   (let ((l (split-string (substring link-line 2))))
1379     (if l
1380         (string-trim (elt l 0))
1381       nil)))
1382
1383 (defun elpher-gemini-get-link-display-string (link-line)
1384   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1385 Returns the url portion in the event that the display-string portion is empty."
1386   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1387          (idx (string-match "[ \t]" rest)))
1388     (string-trim (if idx
1389                      (substring rest (+ idx 1))
1390                    rest))))
1391
1392 (defun elpher-collapse-dot-sequences (filename)
1393   "Collapse dot sequences in FILENAME.
1394 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1395   (let* ((path (split-string filename "/"))
1396          (path-reversed-normalized
1397           (seq-reduce (lambda (a b)
1398                         (cond ((and a (equal b "..") (cdr a)))
1399                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1400                               ((equal b ".") a)
1401                               (t (cons b a))))
1402                       path nil)))
1403     (string-join (reverse path-reversed-normalized) "/")))
1404
1405 (defun elpher-address-from-gemini-url (url)
1406   "Extract address from URL with defaults as per gemini map files.
1407 While there's obviously some redundancy here between this function and
1408 `elpher-address-from-url', gemini map file URLs require enough special
1409 treatment that a separate function is warranted."
1410   (let ((address (url-generic-parse-url url))
1411         (current-address (elpher-page-address elpher-current-page)))
1412     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1413       (setf (url-fullness address) t)
1414       (if (url-host address) ;if there is an explicit host, filenames are absolute
1415           (if (string-empty-p (url-filename address))
1416               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1417         (setf (url-host address) (url-host current-address))
1418         (setf (url-port address) (url-port current-address))
1419         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1420           (setf (url-filename address)
1421                 (concat (file-name-directory (url-filename current-address))
1422                         (url-filename address)))))
1423       (unless (url-type address)
1424         (setf (url-type address) "gemini"))
1425       (when (equal (url-type address) "gemini")
1426         (setf (url-filename address)
1427               (elpher-collapse-dot-sequences (url-filename address)))))
1428     (elpher-remove-redundant-ports address)))
1429
1430 (defun elpher-gemini-insert-link (link-line)
1431   "Insert link described by LINK-LINE into a text/gemini document."
1432   (let* ((url (elpher-gemini-get-link-url link-line))
1433          (display-string (elpher-gemini-get-link-display-string link-line))
1434          (address (elpher-address-from-gemini-url url))
1435          (type (if address (elpher-address-type address) nil))
1436          (type-map-entry (cdr (assoc type elpher-type-map))))
1437     (setq elpher--gemini-page-links (append elpher--gemini-page-links `(,address)))
1438     (when display-string
1439       (insert elpher-gemini-link-string)
1440       (if type-map-entry
1441           (let* ((face (elt type-map-entry 3))
1442                  (filtered-display-string (elpher-color-filter-apply display-string))
1443                  (page (elpher-make-page filtered-display-string address)))
1444             (insert-text-button filtered-display-string
1445                                 'face face
1446                                 'elpher-page page
1447                                 'action #'elpher-click-link
1448                                 'follow-link t
1449                                 'help-echo #'elpher--page-button-help))
1450         (insert (propertize display-string 'face 'elpher-unknown)))
1451       (insert "\n"))))
1452
1453 (defun elpher-gemini-insert-header (header-line)
1454   "Insert header described by HEADER-LINE into a text/gemini document.
1455 The gemini map file line describing the header is given
1456 by HEADER-LINE."
1457   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1458     (let* ((level (length (match-string 1 header-line)))
1459            (header (substring header-line (match-end 0)))
1460            (face (pcase level
1461                    (1 'elpher-gemini-heading1)
1462                    (2 'elpher-gemini-heading2)
1463                    (3 'elpher-gemini-heading3)
1464                    (_ 'default)))
1465            (fill-column (if (display-graphic-p)
1466                             (/ (* fill-column
1467                                   (font-get (font-spec :name (face-font 'default)) :size))
1468                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1469       (setq elpher--gemini-page-headings (cons (cons header (point))
1470                                                elpher--gemini-page-headings))
1471       (unless (display-graphic-p)
1472         (insert (make-string level ?#) " "))
1473       (insert (propertize header 'face face))
1474       (newline))))
1475
1476 (defun elpher-gemini-insert-text (text-line)
1477   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1478 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1479 width defined by `elpher-gemini-max-fill-width'."
1480   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1481   (let* ((line-prefix (match-string 2 text-line))
1482          (processed-text-line
1483           (if line-prefix
1484               (cond ((string-prefix-p "*" line-prefix)
1485                      (concat
1486                       (replace-regexp-in-string "\\*"
1487                                                 elpher-gemini-bullet-string
1488                                                 (match-string 0 text-line))
1489                       (substring text-line (match-end 0))))
1490                     ((string-prefix-p ">" line-prefix)
1491                      (propertize text-line 'face 'elpher-gemini-quoted))
1492                     (t text-line))
1493             text-line))
1494          (adaptive-fill-mode t)
1495          ;; fill-prefix is important for adaptive-fill-mode: without
1496          ;; it, multi-line list items are not indented correct
1497          (fill-prefix (if (match-string 2 text-line)
1498                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1499                         nil)))
1500     (insert (elpher-process-text-for-display processed-text-line))
1501     (newline)))
1502
1503 (defun elpher-render-gemini-map (data _parameters)
1504   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1505   (elpher-with-clean-buffer
1506    (setq elpher--gemini-page-headings nil)
1507    (let ((preformatted nil)
1508          (link-counter 1))
1509      (auto-fill-mode 1)
1510      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1511      (setq elpher--gemini-page-links '())
1512      (dolist (line (split-string data "\n"))
1513        (cond
1514         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1515         (preformatted (insert (elpher-process-text-for-display
1516                                (propertize line 'face 'elpher-gemini-preformatted))
1517                               "\n"))
1518         ((string-prefix-p "=>" line)
1519          (progn
1520            (if elpher-gemini-number-links
1521                (insert
1522                 (concat
1523                  "["
1524                  (number-to-string link-counter)
1525                  "] ")))
1526            (setq link-counter (1+ link-counter))
1527            (elpher-gemini-insert-link line)))
1528         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1529         (t (elpher-gemini-insert-text line)))))
1530    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1531    (elpher-cache-content
1532     (elpher-page-address elpher-current-page)
1533     (buffer-string))
1534    (puthash
1535     (elpher-page-address elpher-current-page)
1536     elpher--gemini-page-links
1537     elpher--gemini-page-links-cache)))
1538
1539 (defun elpher-render-gemini-plain-text (data _parameters)
1540   "Render DATA as plain text file.  PARAMETERS is currently unused."
1541   (elpher-with-clean-buffer
1542    (insert (elpher-process-text-for-display data))
1543    (elpher-cache-content
1544     (elpher-page-address elpher-current-page)
1545     (buffer-string))))
1546
1547
1548 ;; Finger page connection
1549
1550 (defun elpher-get-finger-page (renderer)
1551   "Opens a finger connection to the current page address.
1552 The result is rendered using RENDERER."
1553   (let* ((address (elpher-page-address elpher-current-page))
1554          (content (elpher-get-cached-content address)))
1555     (if (and content (funcall renderer nil))
1556         (elpher-with-clean-buffer
1557          (insert content)
1558          (elpher-restore-pos))
1559       (elpher-with-clean-buffer
1560        (insert "LOADING... (use 'u' to cancel)\n"))
1561       (condition-case the-error
1562           (let* ((kill-buffer-query-functions nil)
1563                  (user (let ((filename (elpher-address-filename address)))
1564                          (if (> (length filename) 1)
1565                              (substring filename 1)
1566                            (elpher-address-user address)))))
1567             (elpher-get-host-response address 79
1568                                       (concat user "\r\n")
1569                                       renderer))
1570         (error
1571          (elpher-network-error address the-error))))))
1572
1573
1574 ;; Telnet page connection
1575
1576 (defun elpher-get-telnet-page (renderer)
1577   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1578   (when renderer
1579     (elpher-visit-previous-page)
1580     (error "Command not supported for telnet URLs"))
1581   (let* ((address (elpher-page-address elpher-current-page))
1582          (host (elpher-address-host address))
1583          (port (elpher-address-port address)))
1584     (elpher-visit-previous-page)
1585     (if (> port 0)
1586         (telnet host port)
1587       (telnet host))))
1588
1589
1590 ;; Other URL page opening
1591
1592 (defun elpher-get-other-url-page (renderer)
1593   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1594   (when renderer
1595     (elpher-visit-previous-page)
1596     (error "Command not supported for general URLs"))
1597   (let* ((address (elpher-page-address elpher-current-page))
1598          (url (elpher-address-to-url address)))
1599     (progn
1600       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1601       (message "Opening URL...")
1602       (if elpher-open-urls-with-eww
1603           (browse-web url)
1604         (browse-url url)))))
1605
1606
1607 ;; Start page page retrieval
1608
1609 (defun elpher-get-start-page (renderer)
1610   "Getter which displays the start page (RENDERER must be nil)."
1611   (when renderer
1612     (elpher-visit-previous-page)
1613     (error "Command not supported for start page"))
1614   (elpher-with-clean-buffer
1615    (insert "     --------------------------------------------\n"
1616            "           Elpher Gopher and Gemini Client       \n"
1617            "                   version " elpher-version "\n"
1618            "     --------------------------------------------\n"
1619            "\n"
1620            "Default bindings:\n"
1621            "\n"
1622            " - TAB/Shift-TAB: next/prev item on current page\n"
1623            " - RET/mouse-1: open item under cursor\n"
1624            " - m: select an item on current page by name (autocompletes)\n"
1625            " - u/mouse-3/U: return to previous page or to the start page\n"
1626            " - o/O: visit different selector or the root menu of the current server\n"
1627            " - g: go to a particular address (gopher, gemini, finger)\n"
1628            " - v: visit a numbered link on a gemini page\n"
1629            " - d/D: download item under cursor or current page\n"
1630            " - i/I: info on item under cursor or current page\n"
1631            " - c/C: copy URL representation of item under cursor or current page\n"
1632            " - a/A: bookmark the item under cursor or current page\n"
1633            " - B: list all bookmarks\n"
1634            " - r: redraw current page (using cached contents if available)\n"
1635            " - R: reload current page (regenerates cache)\n"
1636            " - S: set character coding system for gopher (default is to autodetect)\n"
1637            " - T: toggle TLS gopher mode\n"
1638            " - F: forget/discard current TLS client certificate\n"
1639            " - .: display the raw server response for the current page\n"
1640            "\n"
1641            "Start your exploration of gopher space and gemini:\n")
1642    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1643                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1644    (elpher-insert-index-record "Project Gemini home page"
1645                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1646    (insert "\n"
1647            "Alternatively, select a search engine and enter some search terms:\n")
1648    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1649                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1650    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1651                                (elpher-address-from-url "gemini://geminispace.info/search"))
1652    (insert "\n"
1653            "For Elpher release news or to leave feedback, visit:\n")
1654    (elpher-insert-index-record "The Elpher Project Page"
1655                                (elpher-make-gopher-address ?1
1656                                                            "/projects/elpher/"
1657                                                            "thelambdalab.xyz"
1658                                                            70))
1659    (insert "\n"
1660            "** Refer to the ")
1661    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1662      (insert-text-button "Elpher info manual"
1663                          'face 'link
1664                          'action (lambda (_)
1665                                    (interactive)
1666                                    (info "(elpher)"))
1667                          'follow-link t
1668                          'help-echo help-string))
1669    (insert " for the full documentation. **\n")
1670    (insert (propertize
1671             (concat "  (This should be available if you have installed Elpher using\n"
1672                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1673             'face 'shadow))
1674    (elpher-restore-pos)))
1675
1676 ;;; Bookmarks
1677
1678 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1679 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1680 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1681 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1682
1683 (defvar elpher-bookmark-link nil
1684   "Prefer bookmarking a link or the current page.
1685 Bind this variable dynamically, or set it to t.
1686 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1687 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1688
1689 (defun elpher-bookmark-make-record ()
1690   "Return a bookmark record.
1691 If `elpher-bookmark-link' is non-nil and point is on a link button,
1692 return a bookmark record for that link. Otherwise, return a bookmark
1693 record for the current elpher page."
1694   (let* ((button (and elpher-bookmark-link (button-at (point))))
1695          (page (if button
1696                    (button-get button 'elpher-page)
1697                  elpher-current-page))
1698          (address (elpher-page-address page))
1699          (url (elpher-address-to-url address))
1700          (display-string (elpher-page-display-string page))
1701          (pos (if button nil (point))))
1702     (if (elpher-address-special-p address)
1703         (error "Cannot bookmark %s" display-string)
1704       `(,display-string
1705         (defaults . (,display-string))
1706         (position . ,pos)
1707         (location . ,url)
1708         (handler . elpher-bookmark-jump)))))
1709
1710 ;;;###autoload
1711 (defun elpher-bookmark-jump (bookmark)
1712   "Go to a particular BOOKMARK."
1713   (let* ((url (cdr (assq 'location bookmark))))
1714     (elpher-go url)))
1715
1716 (defun elpher-set-bookmark-no-overwrite ()
1717   "Bookmark the link at point.
1718 To bookmark the current page, use \\[bookmark-set-no-overwrite]."
1719   (interactive)
1720   (let ((elpher-bookmark-link t))
1721     (bookmark-set-no-overwrite)))
1722
1723 (defun elpher-bookmark-import (file)
1724   "Import Elpher bookmarks into Emacs bookmarks."
1725   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1726                               (file-readable-p elpher-bookmarks-file))
1727                          elpher-bookmarks-file
1728                        (read-file-name "Old Elpher bookmarks: "
1729                                        user-emacs-directory nil t
1730                                        "elpher-bookmarks"))))
1731   (require 'bookmark)
1732   (dolist (bookmark (with-temp-buffer
1733                       (insert-file-contents file)
1734                       (read (current-buffer))))
1735     (let* ((display-string (car bookmark))
1736            (url (cadr bookmark))
1737            (record `(,display-string
1738                      (location . ,url)
1739                      (handler . elpher-bookmark-jump))))
1740       (bookmark-store display-string (cdr record) t)))
1741   (bookmark-save))
1742
1743 ;;; Integrations
1744 ;;
1745
1746 ;;; Org
1747
1748 ;; Avoid byte compilation warnings.
1749 (eval-when-compile
1750   (declare-function org-link-store-props "ol")
1751   (declare-function org-link-set-parameters "ol"))
1752
1753 (defun elpher-org-export-link (link description format protocol)
1754   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1755
1756 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1757 of gemini, gopher or finger."
1758   (let* ((url (if (equal protocol "elpher")
1759                   (string-remove-prefix "elpher:" link)
1760                 (format "%s:%s" protocol link)))
1761          (desc (or description url)))
1762     (pcase format
1763       (`gemini (format "=> %s %s" url desc))
1764       (`html (format "<a href=\"%s\">%s</a>" url desc))
1765       (`latex (format "\\href{%s}{%s}" url desc))
1766       (_ (if (not description)
1767              url
1768            (format "%s (%s)" desc url))))))
1769
1770 (defun elpher-org-store-link ()
1771   "Store link to an `elpher' page in Org."
1772   (when (eq major-mode 'elpher-mode)
1773     (let* ((url (elpher-info-current))
1774            (desc (car elpher-current-page))
1775            (protocol (cond
1776                       ((string-prefix-p "gemini:" url) "gemini")
1777                       ((string-prefix-p "gopher:" url) "gopher")
1778                       ((string-prefix-p "finger:" url) "finger")
1779                       (t "elpher"))))
1780       (when (equal "elpher" protocol)
1781         ;; Weird link. Or special inner link?
1782         (setq url (concat "elpher:" url)))
1783       (org-link-store-props :type protocol :link url :description desc)
1784       t)))
1785
1786 (defun elpher-org-follow-link (link protocol)
1787   "Visit a LINK for the given PROTOCOL.
1788
1789 PROTOCOL may be one of gemini, gopher or finger.  This method also
1790 supports the old protocol elpher, where the link is self-contained."
1791   (let ((url (if (equal protocol "elpher")
1792                  (string-remove-prefix "elpher:" link)
1793                (format "%s:%s" protocol link))))
1794     (elpher-go url)))
1795
1796 (with-eval-after-load 'org
1797   (org-link-set-parameters
1798    "elpher"
1799    :store #'elpher-org-store-link
1800    :export (lambda (link description format _plist)
1801              (elpher-org-export-link link description format "elpher"))
1802    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1803   (org-link-set-parameters
1804    "gemini"
1805    :export (lambda (link description format _plist)
1806              (elpher-org-export-link link description format "gemini"))
1807    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
1808   (org-link-set-parameters
1809    "gopher"
1810    :export (lambda (link description format _plist)
1811              (elpher-org-export-link link description format "gopher"))
1812    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
1813   (org-link-set-parameters
1814    "finger"
1815    :export (lambda (link description format _plist)
1816              (elpher-org-export-link link description format "finger"))
1817    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
1818
1819 ;;; Browse URL
1820
1821 ;; Avoid byte compilation warnings.
1822 (eval-when-compile
1823   (defvar thing-at-point-uri-schemes))
1824
1825 ;;;###autoload
1826 (defun elpher-browse-url-elpher (url &rest _args)
1827   "Browse URL using Elpher.  This function is used by `browse-url'."
1828   (interactive (browse-url-interactive-arg "Elpher URL: "))
1829   (elpher-go url))
1830
1831 ;; Use elpher to open gopher, finger and gemini links
1832 ;; For recent version of `browse-url' package
1833 (if (boundp 'browse-url-default-handlers)
1834     (add-to-list
1835      'browse-url-default-handlers
1836      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
1837   ;; Patch `browse-url-browser-function' for older ones. The value of
1838   ;; that variable is `browse-url-default-browser' by default, so
1839   ;; that's the function that gets advised.
1840   (advice-add browse-url-browser-function :before-while
1841               (lambda (url &rest _args)
1842                 "Handle gemini, gopher, and finger schemes using Elpher."
1843                 (let ((scheme (downcase (car (split-string url ":" t)))))
1844                   (if (member scheme '("gemini" "gopher" "finger"))
1845                       ;; `elpher-go' always returns nil, which will stop the
1846                       ;; advice chain here in a before-while
1847                       (elpher-go url)
1848                     ;; chain must continue, then return t.
1849                     t)))))
1850
1851 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1852 (with-eval-after-load 'thingatpt
1853   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
1854
1855 ;;; Mu4e:
1856
1857 (eval-when-compile
1858   (defvar mu4e~view-beginning-of-url-regexp))
1859
1860 (with-eval-after-load 'mu4e-view
1861   ;; Make mu4e aware of the gemini world
1862   (setq mu4e~view-beginning-of-url-regexp
1863         "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:"))
1864
1865 ;;; Interactive procedures
1866 ;;
1867
1868 (defun elpher-next-link ()
1869   "Move point to the next link on the current page."
1870   (interactive)
1871   (forward-button 1))
1872
1873 (defun elpher-prev-link ()
1874   "Move point to the previous link on the current page."
1875   (interactive)
1876   (backward-button 1))
1877
1878 (defun elpher-follow-current-link ()
1879   "Open the link or url at point."
1880   (interactive)
1881   (push-button))
1882
1883 ;;;###autoload
1884 (defun elpher-go (host-or-url)
1885   "Go to a particular gopher site HOST-OR-URL.
1886 When run interactively HOST-OR-URL is read from the minibuffer."
1887   (interactive "sGopher or Gemini URL: ")
1888   (let* ((cleaned-host-or-url (string-trim host-or-url))
1889          (address (elpher-address-from-url cleaned-host-or-url))
1890          (page (elpher-make-page cleaned-host-or-url address)))
1891     (switch-to-buffer elpher-buffer-name)
1892     (elpher-with-clean-buffer
1893      (elpher-visit-page page))
1894     nil))
1895
1896 (defun elpher-go-current ()
1897   "Go to a particular site read from the minibuffer, initialized with the current URL."
1898   (interactive)
1899   (let ((address (elpher-page-address elpher-current-page)))
1900     (let ((url (read-string "Gopher or Gemini URL: "
1901                             (unless (elpher-address-special-p address)
1902                               (elpher-address-to-url address)))))
1903       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
1904
1905 (defun elpher-visit-gemini-numbered-link (n)
1906   "Visit link designated by a number N."
1907   (interactive "nLink number: ")
1908   (if (or (> n (length elpher--gemini-page-links))
1909           (< n 1))
1910       (user-error "Invalid link number"))
1911   (let ((address (nth (1- n) elpher--gemini-page-links)))
1912     (elpher-go (url-recreate-url address))))
1913
1914 (defun elpher-redraw ()
1915   "Redraw current page."
1916   (interactive)
1917   (elpher-visit-page elpher-current-page))
1918
1919 (defun elpher-reload ()
1920   "Reload current page."
1921   (interactive)
1922   (elpher-reload-current-page))
1923
1924 (defun elpher-toggle-tls ()
1925   "Toggle TLS encryption mode for gopher."
1926   (interactive)
1927   (setq elpher-use-tls (not elpher-use-tls))
1928   (if elpher-use-tls
1929       (if (gnutls-available-p)
1930           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1931         (setq elpher-use-tls nil)
1932         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1933     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1934
1935 (defun elpher-view-raw ()
1936   "View raw server response for current page."
1937   (interactive)
1938   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1939       (error "This page was not generated by a server")
1940     (elpher-visit-page elpher-current-page
1941                        #'elpher-render-raw)))
1942
1943 (defun elpher-back ()
1944   "Go to previous site."
1945   (interactive)
1946   (elpher-visit-previous-page))
1947
1948 (defun elpher-back-to-start ()
1949   "Go all the way back to the start page."
1950   (interactive)
1951   (setq-local elpher-current-page nil)
1952   (setq-local elpher-history nil)
1953   (elpher-visit-page (elpher-make-start-page)))
1954
1955 (defun elpher-download ()
1956   "Download the link at point."
1957   (interactive)
1958   (let ((button (button-at (point))))
1959     (if button
1960         (let ((page (button-get button 'elpher-page)))
1961           (if (elpher-address-special-p (elpher-page-address page))
1962               (error "Cannot download %s"
1963                      (elpher-page-display-string page))
1964             (elpher-visit-page (button-get button 'elpher-page)
1965                                #'elpher-render-download)))
1966       (error "No link selected"))))
1967
1968 (defun elpher-download-current ()
1969   "Download the current page."
1970   (interactive)
1971   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1972       (error "Cannot download %s"
1973              (elpher-page-display-string elpher-current-page))
1974     (elpher-visit-page (elpher-make-page
1975                         (elpher-page-display-string elpher-current-page)
1976                         (elpher-page-address elpher-current-page))
1977                        #'elpher-render-download
1978                        t)))
1979
1980 (defun elpher-build-link-map ()
1981   "Build alist mapping link names to destination pages in current buffer."
1982   (let ((link-map nil)
1983         (b (next-button (point-min) t)))
1984     (while b
1985       (push (cons (button-label b) b) link-map)
1986       (setq b (next-button (button-start b))))
1987     link-map))
1988
1989 (defun elpher-jump ()
1990   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1991   (interactive)
1992   (let* ((link-map (elpher-build-link-map)))
1993     (if link-map
1994         (let ((key (let ((completion-ignore-case t))
1995                      (completing-read "Directory item/link: "
1996                                       link-map nil t))))
1997           (if (and key (> (length key) 0))
1998               (let ((b (cdr (assoc key link-map))))
1999                 (goto-char (button-start b))
2000                 (button-activate b)))))))
2001
2002 (defun elpher-root-dir ()
2003   "Visit root of current server."
2004   (interactive)
2005   (let ((address (elpher-page-address elpher-current-page)))
2006     (if (not (elpher-address-special-p address))
2007         (if (or (member (url-filename address) '("/" ""))
2008                 (and (elpher-address-gopher-p address)
2009                      (= (length (elpher-gopher-address-selector address)) 0)))
2010             (error "Already at root directory of current server")
2011           (let ((address-copy (elpher-address-from-url
2012                                (elpher-address-to-url address))))
2013             (setf (url-filename address-copy) "")
2014             (elpher-go (elpher-address-to-url address-copy))))
2015       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2016
2017 (defun elpher-info-page (page)
2018   "Display information on PAGE."
2019   (let ((display-string (elpher-page-display-string page))
2020         (address (elpher-page-address page)))
2021     (if (elpher-address-special-p address)
2022         (message "Special page: %s" display-string)
2023       (message "%s" (elpher-address-to-url address)))))
2024
2025 (defun elpher-info-link ()
2026   "Display information on page corresponding to link at point."
2027   (interactive)
2028   (let ((button (button-at (point))))
2029     (if button
2030         (elpher-info-page (button-get button 'elpher-page))
2031       (error "No item selected"))))
2032
2033 (defun elpher-info-current ()
2034   "Display information on current page."
2035   (interactive)
2036   (elpher-info-page elpher-current-page))
2037
2038 (defun elpher-copy-page-url (page)
2039   "Copy URL representation of address of PAGE to `kill-ring'."
2040   (let ((address (elpher-page-address page)))
2041     (if (elpher-address-special-p address)
2042         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2043       (let ((url (elpher-address-to-url address)))
2044         (message "Copied \"%s\" to kill-ring/clipboard." url)
2045         (kill-new url)))))
2046
2047 (defun elpher-copy-link-url ()
2048   "Copy URL of item at point to `kill-ring'."
2049   (interactive)
2050   (let ((button (button-at (point))))
2051     (if button
2052         (elpher-copy-page-url (button-get button 'elpher-page))
2053       (error "No item selected"))))
2054
2055 (defun elpher-copy-current-url ()
2056   "Copy URL of current page to `kill-ring'."
2057   (interactive)
2058   (elpher-copy-page-url elpher-current-page))
2059
2060 (defun elpher-set-gopher-coding-system ()
2061   "Specify an explicit character coding system for gopher selectors."
2062   (interactive)
2063   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2064     (setq elpher-user-coding-system system)
2065     (if system
2066         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2067       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2068
2069
2070 ;;; Mode and keymap
2071 ;;
2072
2073 (defvar elpher-mode-map
2074   (let ((map (make-sparse-keymap)))
2075     (define-key map (kbd "TAB") 'elpher-next-link)
2076     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2077     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2078     (define-key map (kbd "u") 'elpher-back)
2079     (define-key map (kbd "U") 'elpher-back-to-start)
2080     (define-key map [mouse-3] 'elpher-back)
2081     (define-key map (kbd "O") 'elpher-root-dir)
2082     (define-key map (kbd "g") 'elpher-go)
2083     (define-key map (kbd "o") 'elpher-go-current)
2084     (define-key map (kbd "r") 'elpher-redraw)
2085     (define-key map (kbd "R") 'elpher-reload)
2086     (define-key map (kbd "T") 'elpher-toggle-tls)
2087     (define-key map (kbd ".") 'elpher-view-raw)
2088     (define-key map (kbd "d") 'elpher-download)
2089     (define-key map (kbd "D") 'elpher-download-current)
2090     (define-key map (kbd "m") 'elpher-jump)
2091     (define-key map (kbd "i") 'elpher-info-link)
2092     (define-key map (kbd "I") 'elpher-info-current)
2093     (define-key map (kbd "c") 'elpher-copy-link-url)
2094     (define-key map (kbd "C") 'elpher-copy-current-url)
2095     (define-key map (kbd "a") 'elpher-set-bookmark-no-overwrite)
2096     (define-key map (kbd "A") 'bookmark-set-no-overwrite)
2097     (define-key map (kbd "B") 'bookmark-bmenu-list)
2098     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
2099     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2100     (define-key map (kbd "v") 'elpher-visit-gemini-numbered-link)
2101     (when (fboundp 'evil-define-key*)
2102       (evil-define-key*
2103        'motion map
2104        (kbd "TAB") 'elpher-next-link
2105        (kbd "C-") 'elpher-follow-current-link
2106        (kbd "C-t") 'elpher-back
2107        (kbd "u") 'elpher-back
2108        (kbd "-") 'elpher-back
2109        (kbd "^") 'elpher-back
2110        (kbd "U") 'elpher-back-to-start
2111        [mouse-3] 'elpher-back
2112        (kbd "o") 'elpher-go
2113        (kbd "O") 'elpher-go-current
2114        (kbd "r") 'elpher-redraw
2115        (kbd "R") 'elpher-reload
2116        (kbd "T") 'elpher-toggle-tls
2117        (kbd ".") 'elpher-view-raw
2118        (kbd "d") 'elpher-download
2119        (kbd "D") 'elpher-download-current
2120        (kbd "J") 'elpher-jump
2121        (kbd "i") 'elpher-info-link
2122        (kbd "I") 'elpher-info-current
2123        (kbd "c") 'elpher-copy-link-url
2124        (kbd "C") 'elpher-copy-current-url
2125        (kbd "a") 'elpher-set-bookmark-no-overwrite
2126        (kbd "A") 'bookmark-set-no-overwrite
2127        (kbd "B") 'bookmark-bmenu-list
2128        (kbd "S") 'elpher-set-gopher-coding-system
2129        (kbd "F") 'elpher-forget-current-certificate
2130        (kbd "v") 'elpher-visit-gemini-numbered-link))
2131     map)
2132   "Keymap for gopher client.")
2133
2134 (define-derived-mode elpher-mode special-mode "elpher"
2135   "Major mode for elpher, an elisp gopher client.
2136
2137 This mode is automatically enabled by the interactive
2138 functions which initialize the client, namely
2139 `elpher', and `elpher-go'."
2140   (setq-local elpher--gemini-page-headings nil)
2141   (setq-local elpher-current-page nil)
2142   (setq-local elpher-history nil)
2143   (setq-local elpher-buffer-name (buffer-name))
2144   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2145   (setq-local imenu-create-index-function #'elpher--gemini-page-headings))
2146
2147 (when (fboundp 'evil-set-initial-state)
2148   (evil-set-initial-state 'elpher-mode 'motion))
2149
2150
2151 ;;; Main start procedure
2152 ;;
2153
2154 ;;;###autoload
2155 (defun elpher (&optional arg)
2156   "Start elpher with default landing page.
2157 The buffer used for Elpher sessions is determined by the value of
2158 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2159 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2160 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2161 \\[execute-extended-command] elpher RET’) switches to the session with
2162 that number, creating it if necessary.  A non numeric prefix ARG means
2163 to create a new session.  Returns the buffer selected (or created)."
2164   (interactive "P")
2165   (let* ((name (default-value 'elpher-buffer-name))
2166          (buf (cond ((numberp arg)
2167                      (get-buffer-create (format "%s<%d>" name arg)))
2168                     (arg
2169                      (generate-new-buffer name))
2170                     (t
2171                      (get-buffer-create name)))))
2172     (pop-to-buffer-same-window buf)
2173     (unless (buffer-modified-p)
2174       (elpher-mode)
2175       (elpher-visit-page (elpher-make-start-page))
2176       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2177
2178 ;;; elpher.el ends here