elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.2.2
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.2.2"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((about history) elpher-get-history-page nil "E" elpher-index)
 116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page-url "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen is \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 232
 233 Beware that using \"about:bookmarks\" as a start page in combination with
 234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 236 the start page."
 237   :type '(string))
 238
 239 ;; Face customizations
 240
 241 (defgroup elpher-faces nil
 242   "Elpher face customizations."
 243   :group 'elpher)
 244
 245 (defface elpher-index
 246   '((t :inherit font-lock-keyword-face))
 247   "Face used for directory type directory records.")
 248
 249 (defface elpher-text
 250   '((t :inherit bold))
 251   "Face used for text type directory records.")
 252
 253 (defface elpher-info
 254   '((t :inherit default))
 255   "Face used for info type directory records.")
 256
 257 (defface elpher-image
 258   '((t :inherit font-lock-string-face))
 259   "Face used for image type directory records.")
 260
 261 (defface elpher-search
 262   '((t :inherit warning))
 263   "Face used for search type directory records.")
 264
 265 (defface elpher-html
 266   '((t :inherit font-lock-comment-face))
 267   "Face used for html type directory records.")
 268
 269 (defface elpher-gemini
 270   '((t :inherit font-lock-constant-face))
 271   "Face used for Gemini type directory records.")
 272
 273 (defface elpher-other-url
 274   '((t :inherit font-lock-comment-face))
 275   "Face used for other URL type links records.")
 276
 277 (defface elpher-telnet
 278   '((t :inherit font-lock-function-name-face))
 279   "Face used for telnet type directory records.")
 280
 281 (defface elpher-binary
 282   '((t :inherit font-lock-doc-face))
 283   "Face used for binary type directory records.")
 284
 285 (defface elpher-unknown
 286   '((t :inherit error))
 287   "Face used for directory records with unknown/unsupported types.")
 288
 289 (defface elpher-margin-key
 290   '((t :inherit bold))
 291   "Face used for directory margin key.")
 292
 293 (defface elpher-margin-brackets
 294   '((t :inherit shadow))
 295   "Face used for brackets around directory margin key.")
 296
 297 (defface elpher-gemini-heading1
 298   '((t :inherit bold :height 1.8))
 299   "Face used for gemini heading level 1.")
 300
 301 (defface elpher-gemini-heading2
 302   '((t :inherit bold :height 1.5))
 303   "Face used for gemini heading level 2.")
 304
 305 (defface elpher-gemini-heading3
 306   '((t :inherit bold :height 1.2))
 307   "Face used for gemini heading level 3.")
 308
 309 (defface elpher-gemini-preformatted
 310   '((t :inherit fixed-pitch))
 311   "Face used for pre-formatted gemini text blocks.")
 312
 313 (defface elpher-gemini-quoted
 314   '((t :inherit font-lock-doc-face))
 315   "Face used for gemini quoted texts.")
 316
 317 ;;; Model
 318 ;;
 319
 320 ;; Address
 321
 322 ;; An elpher "address" object is either a url object or a symbol.
 323 ;; Addresses with the "about" type, corresponding to pages generated
 324 ;; dynamically for and by elpher.  All others represent pages which
 325 ;; rely on content retrieved over the network.
 326
 327 (defun elpher-address-from-url (url-string)
 328   "Create a ADDRESS object corresponding to the given URL-STRING."
 329   (let ((data (match-data))) ; Prevent parsing clobbering match data
 330     (unwind-protect
 331         (let ((url (url-generic-parse-url url-string)))
 332           (unless (and (not (url-fullness url)) (url-type url))
 333             (setf (url-fullness url) t)
 334             (unless (url-type url)
 335               (setf (url-type url) (elpher-get-default-url-type)))
 336             (unless (url-host url)
 337               (let ((p (split-string (url-filename url) "/" nil nil)))
 338                 (setf (url-host url) (car p))
 339                 (setf (url-filename url)
 340                       (if (cdr p)
 341                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 342                         ""))))
 343             (when (or (equal "gopher" (url-type url))
 344                       (equal "gophers" (url-type url)))
 345               ;; Gopher defaults
 346               (when (or (equal (url-filename url) "")
 347                         (equal (url-filename url) "/"))
 348                 (setf (url-filename url) "/1")))
 349             (when (equal "gemini" (url-type url))
 350               ;; Gemini defaults
 351               (if (equal (url-filename url) "")
 352                   (setf (url-filename url) "/"))))
 353           (elpher-remove-redundant-ports url))
 354       (set-match-data data))))
 355
 356 (defun elpher-get-default-url-type ()
 357   "Get the current URL type or `elpher-default-url-type'.
 358 If no scheme is provided for a URL, the current context specifies
 359 the scheme to use, so if we're looking at a gemini page, then the
 360 default type is \"gemini\" even if `elpher-default-url-type' is
 361 \"gopher\"."
 362   (or (and elpher-current-page
 363            (symbol-name
 364             (elpher-address-type
 365              (elpher-page-address elpher-current-page))))
 366       elpher-default-url-type))
 367
 368 (defun elpher-remove-redundant-ports (address)
 369   "Remove redundant port specifiers from ADDRESS.
 370 Here 'redundant' means that the specified port matches the default
 371 for that protocol, eg 70 for gopher."
 372   (if (and (not (elpher-address-about-p address))
 373            (eq (url-portspec address) ; (url-port) is too slow!
 374                (pcase (url-type address)
 375                  ("gemini" 1965)
 376                  ((or "gopher" "gophers") 70)
 377                  ("finger" 79)
 378                  (_ -1))))
 379       (setf (url-portspec address) nil))
 380   address)
 381
 382 (defun elpher-make-gopher-address (type selector host port &optional tls)
 383   "Create an ADDRESS object using gopher directory record attributes.
 384 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 385 If the optional attribute TLS is non-nil, the address will be marked as
 386 requiring gopher-over-TLS."
 387   (cond
 388    ((equal type ?i) nil)
 389    ((and (equal type ?h)
 390          (string-prefix-p "URL:" selector))
 391     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 392    ((equal type ?8)
 393     (elpher-address-from-url
 394      (concat "telnet"
 395              "://" host
 396              ":" (number-to-string port))))
 397    (t
 398     (elpher-address-from-url
 399      (concat "gopher" (if tls "s" "")
 400              "://" host
 401              ":" (number-to-string port)
 402              "/" (string type)
 403              selector)))))
 404
 405 (defun elpher-make-about-address (type)
 406   "Create an ADDRESS object corresponding to the given about address TYPE."
 407   (elpher-address-from-url (concat "about:" (symbol-name type))))
 408
 409 (defun elpher-address-to-url (address)
 410   "Get string representation of ADDRESS."
 411   (url-encode-url (url-recreate-url address)))
 412
 413 (defun elpher-address-type (address)
 414   "Retrieve type of ADDRESS object.
 415 This is used to determine how to retrieve and render the document the
 416 address refers to, via the table `elpher-type-map'."
 417   (pcase (url-type address)
 418     ("about"
 419      (list 'about (intern (url-filename address))))
 420     ((or "gopher" "gophers")
 421      (list 'gopher
 422            (if (member (url-filename address) '("" "/"))
 423                ?1
 424              (string-to-char (substring (url-filename address) 1)))))
 425     ("gemini" 'gemini)
 426     ("telnet" 'telnet)
 427     ("finger" 'finger)
 428     ("file" 'file)
 429     (_ 'other-url)))
 430
 431 (defun elpher-address-about-p (address)
 432   "Return non-nil if ADDRESS is an  about address."
 433   (pcase (elpher-address-type address) (`(about ,_) t)))
 434
 435 (defun elpher-address-gopher-p (address)
 436   "Return non-nill if ADDRESS object is a gopher address."
 437   (eq 'gopher (elpher-address-type address)))
 438
 439 (defun elpher-address-protocol (address)
 440   "Retrieve the transport protocol for ADDRESS."
 441   (url-type address))
 442
 443 (defun elpher-address-filename (address)
 444   "Retrieve the filename component of ADDRESS.
 445 For gopher addresses this is a combination of the selector type and selector."
 446   (url-unhex-string (url-filename address)))
 447
 448 (defun elpher-address-host (address)
 449   "Retrieve host from ADDRESS object."
 450   (url-host address))
 451
 452 (defun elpher-address-user (address)
 453   "Retrieve user from ADDRESS object."
 454   (url-user address))
 455
 456 (defun elpher-address-port (address)
 457   "Retrieve port from ADDRESS object.
 458 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 459   (url-port address))
 460
 461 (defun elpher-gopher-address-selector (address)
 462   "Retrieve gopher selector from ADDRESS object."
 463   (if (member (url-filename address) '("" "/"))
 464       ""
 465     (url-unhex-string (substring (url-filename address) 2))))
 466
 467
 468 ;; Cache
 469
 470 (defvar elpher-content-cache (make-hash-table :test 'equal))
 471 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 472
 473 (defun elpher-get-cached-content (address)
 474   "Retrieve the cached content for ADDRESS, or nil if none exists."
 475   (gethash address elpher-content-cache))
 476
 477 (defun elpher-cache-content (address content)
 478   "Set the content cache for ADDRESS to CONTENT."
 479   (puthash address content elpher-content-cache))
 480
 481 (defun elpher-get-cached-pos (address)
 482   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 483   (gethash address elpher-pos-cache))
 484
 485 (defun elpher-cache-pos (address pos)
 486   "Set the cursor position cache for ADDRESS to POS."
 487   (puthash address pos elpher-pos-cache))
 488
 489
 490 ;; Page
 491
 492 (defun elpher-make-page (display-string address)
 493   "Create a page with DISPLAY-STRING and ADDRESS."
 494   (list display-string address))
 495
 496 (defun elpher-make-start-page ()
 497   "Create the start page."
 498   (elpher-make-page "Start Page"
 499                     (elpher-address-from-url elpher-start-page-url)))
 500
 501 (defun elpher-page-display-string (page)
 502   "Retrieve the display string corresponding to PAGE."
 503   (elt page 0))
 504
 505 (defun elpher-page-address (page)
 506   "Retrieve the address corresponding to PAGE."
 507   (elt page 1))
 508
 509 (defun elpher-page-set-address (page new-address)
 510   "Set the address corresponding to PAGE to NEW-ADDRESS."
 511   (setcar (cdr page) new-address))
 512
 513 (defun elpher-page-from-url (url)
 514   "Create a page with address and display string defined by URL.
 515 The URL is unhexed prior to its use as a display string to improve
 516 readability."
 517   (elpher-make-page (elpher-url-to-iri url)
 518                     (elpher-address-from-url url)))
 519
 520 (defun elpher-url-to-iri (url)
 521   "Return an IRI for URL.
 522 Decode percent-escapes and handle punycode in the domain name.
 523 Drop the password, if any."
 524   (let* ((address (elpher-address-from-url (elpher-decode (url-unhex-string url))))
 525          (host (url-host address))
 526          (pass (url-password address)))
 527     (when host
 528       (setf (url-host address) (puny-decode-domain host)))
 529     (when pass                           ; RFC 3986 says we should not render
 530       (setf (url-password address) nil)) ; the password as clear text
 531     (url-recreate-url address)))
 532
 533 (defun elpher-encode-url (iri)
 534   "Return an URL for the IRI.
 535 Encode and use percent-escapes, use punycode for the domain name
 536 if necessary."
 537   (let* ((address (url-generic-parse-url iri))
 538          (host (url-host address)))
 539     (when host
 540       (setf (url-host address) (puny-encode-domain host)))
 541     (url-recreate-url address)))
 542
 543 (defvar elpher-current-page nil
 544   "The current page for this Elpher buffer.")
 545
 546 (defvar elpher-history nil
 547   "The local history stack for this Elpher buffer.
 548 This variable is used by `elpher-back' and
 549 `elpher-show-history'.")
 550
 551 (defvar elpher-visited-pages nil
 552   "The global history for all Elpher buffers.
 553 This variable is used by `elpher-show-visited-pages'.")
 554
 555 (defun elpher-visit-page (page &optional renderer no-history)
 556   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 557 Additionally, push PAGE onto the history stack and the list of
 558 previously-visited pages,unless NO-HISTORY is non-nil."
 559   (elpher-save-pos)
 560   (elpher-process-cleanup)
 561   (unless no-history
 562     (unless (or (not elpher-current-page)
 563                  (equal (elpher-page-address elpher-current-page)
 564                         (elpher-page-address page)))
 565       (push elpher-current-page elpher-history)
 566       (unless (or (elpher-address-about-p (elpher-page-address page))
 567                   (and elpher-visited-pages
 568                        (equal page (car elpher-visited-pages))))
 569         (push page elpher-visited-pages))))
 570   (setq-local elpher-current-page page)
 571   (let* ((address (elpher-page-address page))
 572          (type (elpher-address-type address))
 573          (type-record (cdr (assoc type elpher-type-map))))
 574     (if type-record
 575         (funcall (car type-record)
 576                  (if renderer
 577                      renderer
 578                    (cadr type-record)))
 579       (elpher-visit-previous-page)
 580       (pcase type
 581         (`(gopher ,type-char)
 582          (error "Unsupported gopher selector type '%c' for '%s'"
 583                 type-char (elpher-address-to-url address)))
 584         (other
 585          (error "Unsupported address type '%S' for '%s'"
 586                 other (elpher-address-to-url address)))))))
 587
 588 (defun elpher-visit-previous-page ()
 589   "Visit the previous page in the history."
 590   (if elpher-history
 591       (elpher-visit-page (pop elpher-history) nil t)
 592     (error "No previous page")))
 593
 594 (defun elpher-reload-current-page ()
 595   "Reload the current page, discarding any existing cached content."
 596   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 597   (elpher-visit-page elpher-current-page))
 598
 599 (defun elpher-save-pos ()
 600   "Save the current position of point to the current page."
 601   (when elpher-current-page
 602     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 603
 604 (defun elpher-restore-pos ()
 605   "Restore the position of point to that cached in the current page."
 606   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 607     (if pos
 608         (goto-char pos)
 609       (goto-char (point-min)))))
 610
 611
 612 ;;; Buffer preparation
 613 ;;
 614
 615 (defvar elpher-buffer-name "*elpher*"
 616   "The default name of the Elpher buffer.")
 617
 618 (defun elpher-update-header ()
 619   "If `elpher-use-header' is true, display current page info in window header."
 620   (if (and elpher-use-header elpher-current-page)
 621       (let* ((display-string (elpher-page-display-string elpher-current-page))
 622              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 623              (address (elpher-page-address elpher-current-page))
 624              (tls-string (if (and (not (elpher-address-about-p address))
 625                                   (member (elpher-address-protocol address)
 626                                           '("gophers" "gemini")))
 627                              " [TLS encryption]"
 628                            ""))
 629              (header (concat sanitized-display-string
 630                              (propertize tls-string 'face 'bold))))
 631         (setq header-line-format header))))
 632
 633 (defmacro elpher-with-clean-buffer (&rest args)
 634   "Evaluate ARGS with a clean *elpher* buffer as current."
 635   (declare (debug (body))) ;; Allow edebug to step through body
 636   `(with-current-buffer elpher-buffer-name
 637      (unless (eq major-mode 'elpher-mode)
 638        ;; avoid resetting buffer-local variables
 639        (elpher-mode))
 640      (let ((inhibit-read-only t)
 641            (ansi-color-context nil)) ;; clean ansi interpreter state
 642        (setq-local network-security-level
 643                    (default-value 'network-security-level))
 644        (erase-buffer)
 645        (elpher-update-header)
 646        ,@args)))
 647
 648 (defun elpher-buffer-message (string &optional line)
 649   "Replace first line in elpher buffer with STRING.
 650 If LINE is non-nil, replace that line instead."
 651   (with-current-buffer elpher-buffer-name
 652     (let ((inhibit-read-only t))
 653       (goto-char (point-min))
 654       (if line
 655           (forward-line line))
 656       (let ((data (match-data)))
 657         (unwind-protect
 658             (progn
 659               (re-search-forward "^.*$")
 660               (replace-match string))
 661           (set-match-data data))))))
 662
 663
 664 ;;; Text Processing
 665 ;;
 666
 667 (defvar elpher-user-coding-system nil
 668   "User-specified coding system to use for decoding text responses.")
 669
 670 (defun elpher-decode (string)
 671   "Decode STRING using autodetected or user-specified coding system."
 672   (decode-coding-string string
 673                         (if elpher-user-coding-system
 674                             elpher-user-coding-system
 675                           (detect-coding-string string t))))
 676
 677 (defun elpher-preprocess-text-response (string)
 678   "Preprocess text selector response contained in STRING.
 679 This involes decoding the character representation, and clearing
 680 away CRs and any terminating period."
 681   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 682                                            (replace-regexp-in-string "\r" "" string))))
 683
 684 ;;; Buttonify urls
 685
 686 (defconst elpher-url-regex
 687   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 688   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 689
 690 (defun elpher-buttonify-urls (string)
 691   "Turn substrings which look like urls in STRING into clickable buttons."
 692   (with-temp-buffer
 693     (insert string)
 694     (goto-char (point-min))
 695     (while (re-search-forward elpher-url-regex nil t)
 696       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 697         (make-text-button (match-beginning 0)
 698                           (match-end 0)
 699                           'elpher-page  page
 700                           'action #'elpher-click-link
 701                           'follow-link t
 702                           'help-echo #'elpher--page-button-help
 703                           'face 'button)))
 704     (buffer-string)))
 705
 706 ;;; ANSI colors or XTerm colors (application and filtering)
 707
 708 (or (require 'xterm-color nil t)
 709     (require 'ansi-color))
 710
 711 (defalias 'elpher-color-filter-apply
 712   (if (fboundp 'xterm-color-filter)
 713       (lambda (s)
 714         (let ((_xterm-color-render nil))
 715           (xterm-color-filter s)))
 716     #'ansi-color-filter-apply)
 717   "A function to filter out ANSI escape sequences.")
 718
 719 (defalias 'elpher-color-apply
 720   (if (fboundp 'xterm-color-filter)
 721       #'xterm-color-filter
 722     #'ansi-color-apply)
 723   "A function to apply ANSI escape sequences.")
 724
 725 ;;; Processing text for display
 726
 727 (defun elpher-process-text-for-display (string)
 728   "Perform any desired processing of STRING prior to display as text.
 729 Currently includes buttonifying URLs and processing ANSI escape codes."
 730   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 731                              (elpher-color-filter-apply string)
 732                            (elpher-color-apply string))))
 733
 734
 735 ;;; Network error reporting
 736 ;;
 737
 738 (defun elpher-network-error (address error)
 739   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 740 ERROR can be either an error object or a string."
 741   (elpher-with-clean-buffer
 742    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 743            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 744            (if (stringp error) error (error-message-string error)) "\n"
 745            (propertize "\n----------------\n\n" 'face 'error)
 746            "Press 'u' to return to the previous page.")))
 747
 748
 749 ;;; General network communication
 750 ;;
 751
 752 (defvar elpher-network-timer nil
 753   "Timer used for network connections.")
 754
 755 (defvar elpher-use-tls nil
 756   "If non-nil, use TLS to communicate with gopher servers.")
 757
 758 (defvar elpher-client-certificate nil
 759   "If non-nil, contains client certificate details to use for TLS connections.")
 760
 761 (defun elpher-process-cleanup ()
 762   "Immediately shut down any extant elpher process and timers."
 763   (let ((p (get-process "elpher-process")))
 764     (if p (delete-process p)))
 765   (if (timerp elpher-network-timer)
 766       (cancel-timer elpher-network-timer)))
 767
 768 (defun elpher-make-network-timer (thunk)
 769   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 770 This is just a wraper around `run-at-time' which additionally sets the
 771 buffer-local variable `elpher-network-timer' to allow
 772 `elpher-process-cleanup' to also clear the timer."
 773   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 774     (setq-local elpher-network-timer timer)
 775     timer))
 776
 777 (defun elpher-get-host-response (address default-port query-string response-processor
 778                                          &optional use-tls force-ipv4)
 779   "Generic function for retrieving data from ADDRESS.
 780
 781 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 782 QUERY-STRING is a string sent to the host specified by ADDRESS to
 783 illicet a response.  This response is passed as an argument to the
 784 function RESPONSE-PROCESSOR.
 785
 786 If non-nil, USE-TLS specifies that the connection is to be made over
 787 TLS.  If set to gemini, the certificate verification will be disabled
 788 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 789
 790 If non-nil, FORCE-IPV4 causes the network connection to be made over
 791 ipv4 only.  (The default behaviour when this is not set depends on
 792 the host operating system and the local network capabilities.)"
 793   (if (and use-tls (not (gnutls-available-p)))
 794       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 795     (unless (< (elpher-address-port address) 65536)
 796       (error "Cannot establish network connection: port number > 65536"))
 797     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 798       (setq-local network-security-level 'low)
 799       (setq-local gnutls-verify-error nil))
 800     (condition-case nil
 801         (let* ((kill-buffer-query-functions nil)
 802                (port (elpher-address-port address))
 803                (host (elpher-address-host address))
 804                (service (if (> port 0) port default-port))
 805                (response-string-parts nil)
 806                (bytes-received 0)
 807                (hkbytes-received 0)
 808                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 809                (gnutls-params (list :type 'gnutls-x509pki
 810                                     :hostname host
 811                                     :keylist
 812                                     (elpher-get-current-keylist address)))
 813                (timer (elpher-make-network-timer
 814                                    (lambda ()
 815                                      (elpher-process-cleanup)
 816                                      (cond
 817                                         ; Try again with IPv4
 818                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 819                                        (message "Connection timed out.  Retrying with IPv4.")
 820                                        (elpher-get-host-response address default-port
 821                                                                  query-string
 822                                                                  response-processor
 823                                                                  use-tls t))
 824                                       ((and use-tls
 825                                             (not (eq use-tls 'gemini))
 826                                             (or elpher-auto-disengage-TLS
 827                                                 (y-or-n-p
 828                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 829                                        (setq elpher-use-tls nil)
 830                                        (elpher-get-host-response address default-port
 831                                                                  query-string
 832                                                                  response-processor
 833                                                                  nil force-ipv4))
 834                                       (t
 835                                        (elpher-network-error address "Connection time-out."))))))
 836                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 837                        (make-network-process :name "elpher-process"
 838                                              :host host
 839                                              :family (and (or force-ipv4
 840                                                               elpher-ipv4-always)
 841                                                           'ipv4)
 842                                              :service service
 843                                              :buffer nil
 844                                              :nowait t
 845                                              :tls-parameters
 846                                              (and use-tls
 847                                                   (cons 'gnutls-x509pki
 848                                                         (apply #'gnutls-boot-parameters
 849                                                                gnutls-params)))))))
 850           (setq elpher-network-timer timer)
 851           (set-process-coding-system proc 'binary 'binary)
 852           (set-process-query-on-exit-flag proc nil)
 853           (elpher-buffer-message (concat "Connecting to " host "..."
 854                                          " (press 'u' to abort)"))
 855           (set-process-filter proc
 856                               (lambda (_proc string)
 857                                 (when timer
 858                                   (cancel-timer timer)
 859                                   (setq timer nil))
 860                                 (setq bytes-received (+ bytes-received (length string)))
 861                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 862                                   (when (> new-hkbytes-received hkbytes-received)
 863                                     (setq hkbytes-received new-hkbytes-received)
 864                                     (elpher-buffer-message
 865                                      (concat "("
 866                                              (number-to-string (/ hkbytes-received 10.0))
 867                                              " MB read)")
 868                                      1)))
 869                                 (setq response-string-parts
 870                                       (cons string response-string-parts))))
 871           (set-process-sentinel proc
 872                                 (lambda (proc event)
 873                                   (when timer
 874                                     (cancel-timer timer))
 875                                   (condition-case the-error
 876                                       (cond
 877                                        ((string-prefix-p "open" event)    ; request URL
 878                                         (elpher-buffer-message
 879                                          (concat "Connected to " host ". Receiving data..."
 880                                                  " (press 'u' to abort)"))
 881                                         (let ((inhibit-eol-conversion t))
 882                                           (process-send-string proc query-string)))
 883                                        ((string-prefix-p "deleted" event)) ; do nothing
 884                                        ((and (not response-string-parts)
 885                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 886                                         ; Try again with IPv4
 887                                         (message "Connection failed. Retrying with IPv4.")
 888                                         (elpher-get-host-response address default-port
 889                                                                   query-string
 890                                                                   response-processor
 891                                                                   use-tls t))
 892                                        (response-string-parts
 893                                         (elpher-with-clean-buffer
 894                                          (insert "Data received.  Rendering..."))
 895                                         (funcall response-processor
 896                                                  (apply #'concat (reverse response-string-parts)))
 897                                         (elpher-restore-pos))
 898                                        (t
 899                                         (error "No response from server")))
 900                                     (error
 901                                      (elpher-network-error address the-error)))))
 902           (when socks
 903             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 904             (funcall (process-sentinel proc) proc "open\n")))
 905       (error
 906        (elpher-process-cleanup)
 907        (error "Error initiating connection to server")))))
 908
 909
 910 ;;; Client-side TLS Certificate Management
 911 ;;
 912
 913 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 914   "Generate a key and a self-signed client TLS certificate using openssl.
 915
 916 The Common Name field of the certificate is set to COMMON-NAME.  The
 917 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 918 the key and certificate files to write.
 919
 920 If TEMPORARY is non-nil, the certificate will be given an exporation
 921 period of one day, and the key and certificate files will be deleted
 922 when the certificate is no longer needed for the current session.
 923
 924 Otherwise, the certificate will be given a 100 year expiration period
 925 and the files will not be deleted.
 926
 927 The function returns a list containing the current host name, the
 928 temporary flag, and the key and cert file names in the form required
 929 by `gnutls-boot-parameters`."
 930   (let ((exp-key-file (expand-file-name key-file))
 931         (exp-cert-file (expand-file-name cert-file)))
 932     (condition-case nil
 933         (progn
 934           (call-process elpher-openssl-command nil nil nil
 935                         "req" "-x509" "-newkey" "rsa:2048"
 936                         "-days" (if temporary "1" "36500")
 937                         "-nodes"
 938                         "-subj" (concat "/CN=" common-name)
 939                         "-keyout" exp-key-file
 940                         "-out" exp-cert-file)
 941           (list (elpher-address-host (elpher-page-address elpher-current-page))
 942                 temporary exp-key-file exp-cert-file))
 943       (error
 944        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 945        (error "Program 'openssl', required for certificate generation, not found")))))
 946
 947 (defun elpher-generate-throwaway-certificate ()
 948   "Generate and return details of a throwaway certificate.
 949 The key and certificate files will be deleted when they are no
 950 longer needed for this session."
 951   (let* ((file-base (make-temp-name "elpher"))
 952          (key-file (concat temporary-file-directory file-base ".key"))
 953          (cert-file (concat temporary-file-directory file-base ".crt")))
 954     (elpher-generate-certificate file-base key-file cert-file t)))
 955
 956 (defun elpher-generate-persistent-certificate (file-base common-name)
 957   "Generate and return details of a persistent certificate.
 958 The argument FILE-BASE is used as the base for the key and certificate
 959 files, while COMMON-NAME specifies the common name field of the
 960 certificate.
 961
 962 The key and certificate files are written to in `elpher-certificate-directory'."
 963   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 964          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 965     (elpher-generate-certificate common-name key-file cert-file)))
 966
 967 (defun elpher-get-existing-certificate (file-base)
 968   "Return a certificate object corresponding to an existing certificate.
 969 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 970 the directory `elpher-certificate-directory'."
 971   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 972          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 973     (list (elpher-address-host (elpher-page-address elpher-current-page))
 974           nil
 975           (expand-file-name key-file)
 976           (expand-file-name cert-file))))
 977
 978 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 979   "Install a key+certificate file pair in `elpher-certificate-directory'.
 980 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 981 certificate files to install.  The argument FILE-BASE is used as the
 982 base for the installed key and certificate files."
 983   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 984          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 985     (if (or (file-exists-p key-file)
 986             (file-exists-p cert-file))
 987         (error "A certificate with base name %s is already installed" file-base))
 988     (copy-file key-file-src key-file)
 989     (copy-file cert-file-src cert-file)
 990     (list (elpher-address-host (elpher-page-address elpher-current-page))
 991           nil
 992           (expand-file-name key-file)
 993           (expand-file-name cert-file))))
 994
 995 (defun elpher-list-existing-certificates ()
 996   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 997   (unless (file-directory-p elpher-certificate-directory)
 998     (make-directory elpher-certificate-directory))
 999   (mapcar
1000    (lambda (file)
1001      (file-name-sans-extension file))
1002    (directory-files elpher-certificate-directory nil "\\.key$")))
1003
1004 (defun elpher-forget-current-certificate ()
1005   "Causes any current certificate to be forgotten.)
1006 In the case of throwaway certificates, the key and certificate files
1007 are also deleted."
1008   (interactive)
1009   (when elpher-client-certificate
1010     (unless (and (called-interactively-p 'any)
1011                  (not (y-or-n-p (concat "Really forget client certificate? "
1012                                         "(Throwaway certificates will be deleted.)"))))
1013       (when (cadr elpher-client-certificate)
1014         (delete-file (elt elpher-client-certificate 2))
1015         (delete-file (elt elpher-client-certificate 3)))
1016       (setq elpher-client-certificate nil)
1017       (if (called-interactively-p 'any)
1018           (message "Client certificate forgotten.")))))
1019
1020 (defun elpher-get-current-keylist (address)
1021   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1022
1023 This is obtained from the client certificate described by
1024 `elpher-current-certificate', if one is available and the host for
1025 that certificate matches the host in ADDRESS.
1026
1027 If `elpher-current-certificate' is non-nil, and its host name doesn't
1028 match that of ADDRESS, the certificate is forgotten."
1029   (if elpher-client-certificate
1030       (if (string= (car elpher-client-certificate)
1031                    (elpher-address-host address))
1032           (list (cddr elpher-client-certificate))
1033         (elpher-forget-current-certificate)
1034         (message "Disabling client certificate for new host")
1035         nil)
1036     nil))
1037
1038
1039 ;;; Gopher selector retrieval
1040 ;;
1041
1042 (defun elpher-get-gopher-response (address renderer)
1043   "Get response string from gopher server at ADDRESS and render using RENDERER."
1044   (elpher-get-host-response address 70
1045                             (concat (elpher-gopher-address-selector address) "\r\n")
1046                             renderer
1047                             (or (string= (elpher-address-protocol address) "gophers")
1048                                 elpher-use-tls)))
1049
1050 (defun elpher-get-gopher-page (renderer)
1051   "Getter function for gopher pages.
1052 The RENDERER procedure is used to display the contents of the page
1053 once they are retrieved from the gopher server."
1054   (let* ((address (elpher-page-address elpher-current-page))
1055          (content (elpher-get-cached-content address)))
1056     (if (and content (funcall renderer nil))
1057         (elpher-with-clean-buffer
1058          (insert content)
1059          (elpher-restore-pos))
1060       (elpher-with-clean-buffer
1061        (insert "LOADING... (use 'u' to cancel)\n"))
1062       (condition-case the-error
1063           (elpher-get-gopher-response address renderer)
1064         (error
1065          (elpher-network-error address the-error))))))
1066
1067 ;; Index rendering
1068
1069 (defun elpher-insert-margin (&optional type-name)
1070   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1071   (if type-name
1072       (progn
1073         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1074                         (concat
1075                          (propertize "[" 'face 'elpher-margin-brackets)
1076                          (propertize type-name 'face 'elpher-margin-key)
1077                          (propertize "]" 'face 'elpher-margin-brackets))))
1078         (insert " "))
1079     (insert (make-string elpher-margin-width ?\s))))
1080
1081 (defun elpher--page-button-help (_window buffer pos)
1082   "Function called by Emacs to generate mouse-over text.
1083 The arguments specify the BUFFER and the POS within the buffer of the item
1084 for which help is required.  The function returns the help to be
1085 displayed.  The _WINDOW argument is currently unused."
1086   (with-current-buffer buffer
1087     (let ((button (button-at pos)))
1088       (when button
1089         (let* ((page (button-get button 'elpher-page))
1090                (address (elpher-page-address page)))
1091           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1092
1093 (defun elpher-insert-index-record (display-string &optional address)
1094   "Function to insert an index record into the current buffer.
1095 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1096 If ADDRESS is not supplied or nil the record is rendered as an
1097 'information' line."
1098   (let* ((type (if address (elpher-address-type address) nil))
1099          (type-map-entry (cdr (assoc type elpher-type-map))))
1100     (if type-map-entry
1101         (let* ((margin-code (elt type-map-entry 2))
1102                (face (elt type-map-entry 3))
1103                (filtered-display-string (elpher-color-filter-apply display-string))
1104                (page (elpher-make-page filtered-display-string address)))
1105           (elpher-insert-margin margin-code)
1106           (insert-text-button filtered-display-string
1107                               'face face
1108                               'elpher-page page
1109                               'action #'elpher-click-link
1110                               'follow-link t
1111                               'help-echo #'elpher--page-button-help))
1112       (pcase type
1113         ('nil ;; Information
1114          (elpher-insert-margin)
1115          (let ((propertized-display-string
1116                 (propertize display-string 'face 'elpher-info)))
1117            (insert (elpher-process-text-for-display propertized-display-string))))
1118         (`(gopher ,selector-type) ;; Unknown
1119          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1120          (insert (propertize display-string
1121                              'face 'elpher-unknown)))))
1122     (insert "\n")))
1123
1124 (defun elpher-click-link (button)
1125   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1126   (let ((page (button-get button 'elpher-page)))
1127     (elpher-visit-page page)))
1128
1129 (defun elpher-render-index (data &optional _mime-type-string)
1130   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1131   (elpher-with-clean-buffer
1132    (if (not data)
1133        t
1134      (let ((data-processed (elpher-preprocess-text-response data)))
1135        (dolist (line (split-string data-processed "\n"))
1136          (ignore-errors
1137            (unless (= (length line) 0)
1138              (let* ((type (elt line 0))
1139                     (fields (split-string (substring line 1) "\t"))
1140                     (display-string (elt fields 0))
1141                     (selector (elt fields 1))
1142                     (host (elt fields 2))
1143                     (port (if (elt fields 3)
1144                               (string-to-number (elt fields 3))
1145                             nil))
1146                     (address (elpher-make-gopher-address type selector host port)))
1147                (elpher-insert-index-record display-string address))))))
1148      (elpher-cache-content (elpher-page-address elpher-current-page)
1149                            (buffer-string)))))
1150
1151 ;; Text rendering
1152
1153 (defun elpher-render-text (data &optional _mime-type-string)
1154   "Render DATA as text.  MIME-TYPE-STRING is unused."
1155   (elpher-with-clean-buffer
1156    (if (not data)
1157        t
1158      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1159      (elpher-cache-content
1160       (elpher-page-address elpher-current-page)
1161       (buffer-string)))))
1162
1163 ;; Image retrieval
1164
1165 (defun elpher-render-image (data &optional _mime-type-string)
1166   "Display DATA as image.  MIME-TYPE-STRING is unused."
1167   (if (not data)
1168       nil
1169     (if (display-images-p)
1170         (let* ((image (create-image
1171                        data
1172                        nil t))
1173                (window (get-buffer-window elpher-buffer-name)))
1174           (when window
1175             (setf (image-property image :max-width) (window-body-width window t))
1176             (setf (image-property image :max-height) (window-body-height window t)))
1177           (elpher-with-clean-buffer
1178            (insert-image image)
1179            (elpher-restore-pos)))
1180       (elpher-render-download data))))
1181
1182 ;; Search retrieval and rendering
1183
1184 (defun elpher-get-gopher-query-page (renderer)
1185   "Getter for gopher addresses requiring input.
1186 The response is rendered using the rendering function RENDERER."
1187   (let* ((address (elpher-page-address elpher-current-page))
1188          (content (elpher-get-cached-content address))
1189          (aborted t))
1190     (if (and content (funcall renderer nil))
1191         (elpher-with-clean-buffer
1192          (insert content)
1193          (elpher-restore-pos)
1194          (message "Displaying cached search results.  Reload to perform a new search."))
1195       (unwind-protect
1196           (let* ((query-string (read-string "Query: "))
1197                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1198                  (search-address (elpher-make-gopher-address ?1
1199                                                              query-selector
1200                                                              (elpher-address-host address)
1201                                                              (elpher-address-port address)
1202                                                              (equal (elpher-address-type address) "gophers"))))
1203             (setq aborted nil)
1204
1205             (elpher-with-clean-buffer
1206              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1207             (elpher-get-gopher-response search-address renderer))
1208         (if aborted
1209             (elpher-visit-previous-page))))))
1210
1211 ;; Raw server response rendering
1212
1213 (defun elpher-render-raw (data &optional mime-type-string)
1214   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1215   (if (not data)
1216       nil
1217     (elpher-with-clean-buffer
1218      (when mime-type-string
1219        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1220      (insert data)
1221      (goto-char (point-min)))
1222     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1223
1224 ;; File save "rendering"
1225
1226 (defun elpher-render-download (data &optional _mime-type-string)
1227   "Save DATA to file.  MIME-TYPE-STRING is unused."
1228   (if (not data)
1229       nil
1230     (let* ((address (elpher-page-address elpher-current-page))
1231            (selector (if (elpher-address-gopher-p address)
1232                          (elpher-gopher-address-selector address)
1233                        (elpher-address-filename address))))
1234       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1235       (let* ((filename-proposal (file-name-nondirectory selector))
1236              (filename (read-file-name "Download complete. Save file as: "
1237                                        nil nil nil
1238                                        (if (> (length filename-proposal) 0)
1239                                            filename-proposal
1240                                          "download.file"))))
1241         (let ((coding-system-for-write 'binary))
1242           (with-temp-file filename
1243             (insert data)))
1244         (message (format "Saved to file %s." filename))))))
1245
1246 ;; HTML rendering
1247
1248 (defun elpher-render-html (data &optional _mime-type-string)
1249   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1250   (elpher-with-clean-buffer
1251    (if (not data)
1252        t
1253      (let ((dom (with-temp-buffer
1254                   (insert data)
1255                   (libxml-parse-html-region (point-min) (point-max)))))
1256        (shr-insert-document dom)))))
1257
1258 ;; Gemini page retrieval
1259
1260 (defvar elpher-gemini-redirect-chain)
1261
1262 (defun elpher-get-gemini-response (address renderer)
1263   "Get response string from gemini server at ADDRESS and render using RENDERER."
1264   (elpher-get-host-response address 1965
1265                             (concat (elpher-address-to-url address) "\r\n")
1266                             (lambda (response-string)
1267                               (elpher-process-gemini-response response-string renderer))
1268                             'gemini))
1269
1270 (defun elpher-parse-gemini-response (response)
1271   "Parse the RESPONSE string and return a list of components.
1272 The list is of the form (code meta body).  A response of nil implies
1273 that the response was malformed."
1274   (let ((header-end-idx (string-match "\r\n" response)))
1275     (if header-end-idx
1276         (let ((header (string-trim (substring response 0 header-end-idx)))
1277               (body (substring response (+ header-end-idx 2))))
1278           (if (>= (length header) 2)
1279               (let ((code (substring header 0 2))
1280                     (meta (string-trim (substring header 2))))
1281                 (list code meta body))
1282             (error "Malformed response: No response status found in header %s" header)))
1283       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1284
1285 (defun elpher-process-gemini-response (response-string renderer)
1286   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1287   (let ((response-components (elpher-parse-gemini-response response-string)))
1288     (let ((response-code (elt response-components 0))
1289           (response-meta (elt response-components 1))
1290           (response-body (elt response-components 2)))
1291       (pcase (elt response-code 0)
1292         (?1 ; Input required
1293          (elpher-with-clean-buffer
1294           (insert "Gemini server is requesting input."))
1295          (let* ((query-string
1296                  (if (eq (elt response-code 1) ?1)
1297                      (read-passwd (concat response-meta ": "))
1298                    (read-string (concat response-meta ": "))))
1299                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1300                 (old-fname (url-filename query-address)))
1301            (setf (url-filename query-address)
1302                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1303            (elpher-get-gemini-response query-address renderer)))
1304         (?2 ; Normal response
1305          (funcall renderer response-body response-meta))
1306         (?3 ; Redirect
1307          (message "Following redirect to %s" response-meta)
1308          (if (>= (length elpher-gemini-redirect-chain) 5)
1309              (error "More than 5 consecutive redirects followed"))
1310          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1311            (if (member redirect-address elpher-gemini-redirect-chain)
1312                (error "Redirect loop detected"))
1313            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1314                (error "Server tried to automatically redirect to non-gemini URL: %s"
1315                       response-meta))
1316            (elpher-page-set-address elpher-current-page redirect-address)
1317            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1318            (elpher-get-gemini-response redirect-address renderer)))
1319         (?4 ; Temporary failure
1320          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1321                 response-code response-meta))
1322         (?5 ; Permanent failure
1323          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1324                 response-code response-meta))
1325         (?6 ; Client certificate required
1326          (elpher-with-clean-buffer
1327           (if elpher-client-certificate
1328               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1329             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1330           (auto-fill-mode 1)
1331           (elpher-gemini-insert-text response-meta))
1332          (let ((chosen-certificate (elpher-choose-client-certificate)))
1333            (unless chosen-certificate
1334              (error "Gemini server requires a client certificate and none was provided"))
1335            (setq elpher-client-certificate chosen-certificate))
1336          (elpher-with-clean-buffer)
1337          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1338         (_other
1339          (error "Gemini server response unknown: %s %s"
1340                 response-code response-meta))))))
1341
1342 (defun elpher--read-answer-polyfill (question answers)
1343   "Polyfill for `read-answer' in Emacs 26.1.
1344 QUESTION is a string containing a question, and ANSWERS
1345 is a list of possible answers."
1346     (completing-read question (mapcar 'identity answers)))
1347
1348 (if (fboundp 'read-answer)
1349     (defalias 'elpher-read-answer 'read-answer)
1350   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1351
1352 (defun elpher-choose-client-certificate ()
1353   "Prompt for a client certificate to use to establish a TLS connection."
1354   (let* ((read-answer-short t))
1355     (pcase (read-answer "What do you want to do? "
1356                         '(("throwaway" ?t
1357                            "generate and use throw-away certificate")
1358                           ("persistent" ?p
1359                            "generate new or use existing persistent certificate")
1360                           ("abort" ?a
1361                            "stop immediately")))
1362       ("throwaway"
1363        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1364       ("persistent"
1365        (let* ((existing-certificates (elpher-list-existing-certificates))
1366               (file-base (completing-read
1367                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1368                           existing-certificates)))
1369          (if (string-empty-p (string-trim file-base))
1370              nil
1371            (if (member file-base existing-certificates)
1372                (setq elpher-client-certificate
1373                      (elpher-get-existing-certificate file-base))
1374              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1375                                  '(("new" ?n
1376                                     "generate new certificate")
1377                                    ("install" ?i
1378                                     "install existing certificate")
1379                                    ("abort" ?a
1380                                     "stop immediately")))
1381                ("new"
1382                 (let ((common-name (read-string "Common Name field for new certificate: "
1383                                                 file-base)))
1384                   (message "New key and self-signed certificate written to %s"
1385                            elpher-certificate-directory)
1386                   (elpher-generate-persistent-certificate file-base common-name)))
1387                ("install"
1388                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1389                        (key-file (read-file-name "Key file: " nil nil t)))
1390                   (message "Key and certificate installed in %s for future use"
1391                            elpher-certificate-directory)
1392                   (elpher-install-and-use-existing-certificate key-file
1393                                                                cert-file
1394                                                                file-base)))
1395                ("abort" nil))))))
1396       ("abort" nil))))
1397
1398 (defun elpher-get-gemini-page (renderer)
1399   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1400   (let* ((address (elpher-page-address elpher-current-page))
1401          (content (elpher-get-cached-content address)))
1402     (condition-case the-error
1403         (if (and content (funcall renderer nil))
1404             (elpher-with-clean-buffer
1405              (insert content)
1406              (elpher-restore-pos))
1407           (elpher-with-clean-buffer
1408            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1409           (setq elpher-gemini-redirect-chain nil)
1410           (elpher-get-gemini-response address renderer))
1411       (error
1412        (elpher-network-error address the-error)))))
1413
1414 (defun elpher-render-gemini (body &optional mime-type-string)
1415   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1416   (if (not body)
1417       t
1418     (let* ((mime-type-string* (if (or (not mime-type-string)
1419                                       (string-empty-p mime-type-string))
1420                                   "text/gemini; charset=utf-8"
1421                                 mime-type-string))
1422            (mime-type-split (split-string mime-type-string* ";" t))
1423            (mime-type (string-trim (car mime-type-split)))
1424            (parameters (mapcar (lambda (s)
1425                                  (let ((key-val (split-string s "=")))
1426                                    (list (downcase (string-trim (car key-val)))
1427                                          (downcase (string-trim (cadr key-val))))))
1428                                (cdr mime-type-split))))
1429       (when (string-prefix-p "text/" mime-type)
1430         (setq body (decode-coding-string
1431                     body
1432                     (if (assoc "charset" parameters)
1433                         (intern (cadr (assoc "charset" parameters)))
1434                       'utf-8)))
1435         (setq body (replace-regexp-in-string "\r" "" body)))
1436       (pcase mime-type
1437         ((or "text/gemini" "")
1438          (elpher-render-gemini-map body parameters))
1439         ("text/html"
1440          (elpher-render-html body))
1441         ((pred (string-prefix-p "text/"))
1442          (elpher-render-gemini-plain-text body parameters))
1443         ((pred (string-prefix-p "image/"))
1444          (elpher-render-image body))
1445         (_other
1446          (elpher-render-download body))))))
1447
1448 (defun elpher-gemini-get-link-url (link-line)
1449   "Extract the url portion of LINK-LINE, a gemini map file link line.
1450 Returns nil in the event that the contents of the line following the
1451 => prefix are empty."
1452   (let ((l (split-string (substring link-line 2))))
1453     (if l
1454         (elpher-encode-url (string-trim (elt l 0)))
1455       nil)))
1456
1457 (defun elpher-gemini-get-link-display-string (link-line)
1458   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1459 Returns the url portion in the event that the display-string portion is empty."
1460   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1461          (idx (string-match "[ \t]" rest)))
1462     (string-trim (if idx
1463                      (substring rest (+ idx 1))
1464                    (elpher-url-to-iri rest)))))
1465
1466 (defun elpher-collapse-dot-sequences (filename)
1467   "Collapse dot sequences in FILENAME.
1468 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1469   (let* ((path (split-string filename "/"))
1470          (path-reversed-normalized
1471           (seq-reduce (lambda (a b)
1472                         (cond ((and a (equal b "..") (cdr a)))
1473                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1474                               ((equal b ".") a)
1475                               (t (cons b a))))
1476                       path nil)))
1477     (string-join (reverse path-reversed-normalized) "/")))
1478
1479 (defun elpher-address-from-gemini-url (url)
1480   "Extract address from URL with defaults as per gemini map files.
1481 While there's obviously some redundancy here between this function and
1482 `elpher-address-from-url', gemini map file URLs require enough special
1483 treatment that a separate function is warranted."
1484   (let ((address (url-generic-parse-url url))
1485         (current-address (elpher-page-address elpher-current-page)))
1486     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1487       (setf (url-fullness address) t)
1488       (if (url-host address) ;if there is an explicit host, filenames are absolute
1489           (if (string-empty-p (url-filename address))
1490               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1491         (setf (url-host address) (url-host current-address))
1492         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1493         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1494           (setf (url-filename address)
1495                 (concat (file-name-directory (url-filename current-address))
1496                         (url-filename address)))))
1497       (unless (url-type address)
1498         (setf (url-type address) (url-type current-address)))
1499       (when (equal (url-type address) "gemini")
1500         (setf (url-filename address)
1501               (elpher-collapse-dot-sequences (url-filename address)))))
1502     (elpher-remove-redundant-ports address)))
1503
1504 (defun elpher-gemini-insert-link (link-line)
1505   "Insert link described by LINK-LINE into a text/gemini document."
1506   (let* ((url (elpher-gemini-get-link-url link-line))
1507          (display-string (elpher-gemini-get-link-display-string link-line))
1508          (address (elpher-address-from-gemini-url url))
1509          (type (if address (elpher-address-type address) nil))
1510          (type-map-entry (cdr (assoc type elpher-type-map))))
1511     (when display-string
1512       (insert elpher-gemini-link-string)
1513       (if type-map-entry
1514           (let* ((face (elt type-map-entry 3))
1515                  (filtered-display-string (elpher-color-filter-apply display-string))
1516                  (page (elpher-make-page filtered-display-string address)))
1517             (insert-text-button filtered-display-string
1518                                 'face face
1519                                 'elpher-page page
1520                                 'action #'elpher-click-link
1521                                 'follow-link t
1522                                 'help-echo #'elpher--page-button-help))
1523         (insert (propertize display-string 'face 'elpher-unknown)))
1524       (insert "\n"))))
1525
1526 (defvar elpher--gemini-page-headings nil
1527   "List of headings on the page.")
1528
1529 (defun elpher-gemini-insert-header (header-line)
1530   "Insert header described by HEADER-LINE into a text/gemini document.
1531 The gemini map file line describing the header is given
1532 by HEADER-LINE."
1533   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1534     (let* ((level (length (match-string 1 header-line)))
1535            (header (substring header-line (match-end 0)))
1536            (face (pcase level
1537                    (1 'elpher-gemini-heading1)
1538                    (2 'elpher-gemini-heading2)
1539                    (3 'elpher-gemini-heading3)
1540                    (_ 'default)))
1541            (fill-column (if (display-graphic-p)
1542                             (/ (* fill-column
1543                                   (font-get (font-spec :name (face-font 'default)) :size))
1544                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1545       (setq elpher--gemini-page-headings (cons (cons header (point))
1546                                                elpher--gemini-page-headings))
1547       (unless (display-graphic-p)
1548         (insert (make-string level ?#) " "))
1549       (insert (propertize header 'face face 'rear-nonsticky t))
1550       (newline))))
1551
1552 (defun elpher-gemini-insert-text (text-line)
1553   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1554 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1555 width defined by `elpher-gemini-max-fill-width'."
1556   (string-match
1557    (rx (: line-start
1558           (* (any " \t"))
1559           (optional
1560            (group (or (: "*" (+ (any " \t")))
1561                       (: ">" (* (any " \t"))))))))
1562    text-line)
1563   (let* ((line-prefix (match-string 1 text-line))
1564          (processed-text-line
1565           (if line-prefix
1566               (cond ((string-prefix-p "*" line-prefix)
1567                      (concat
1568                       (replace-regexp-in-string "\\*"
1569                                                 elpher-gemini-bullet-string
1570                                                 (match-string 0 text-line))
1571                       (substring text-line (match-end 0))))
1572                     ((string-prefix-p ">" line-prefix)
1573                      (propertize text-line 'face 'elpher-gemini-quoted))
1574                     (t text-line))
1575             text-line))
1576          (adaptive-fill-mode t)
1577          ;; fill-prefix is important for adaptive-fill-mode: without
1578          ;; it, multi-line list items are not indented correct
1579          (fill-prefix (if (match-string 1 text-line)
1580                           (make-string (length (match-string 0 text-line)) ?\s)
1581                         nil)))
1582     (insert (elpher-process-text-for-display processed-text-line))
1583     (newline)))
1584
1585 (defun elpher-render-gemini-map (data _parameters)
1586   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1587   (elpher-with-clean-buffer
1588    (setq elpher--gemini-page-headings nil)
1589    (let ((preformatted nil))
1590      (auto-fill-mode 1)
1591      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1592      (dolist (line (split-string data "\n"))
1593        (cond
1594         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1595         (preformatted (insert (elpher-process-text-for-display
1596                                (propertize line 'face 'elpher-gemini-preformatted))
1597                               "\n"))
1598         ((string-prefix-p "=>" line)
1599          (elpher-gemini-insert-link line))
1600         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1601         (t (elpher-gemini-insert-text line)))))
1602    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1603    (elpher-cache-content
1604     (elpher-page-address elpher-current-page)
1605     (buffer-string))))
1606
1607 (defun elpher-render-gemini-plain-text (data _parameters)
1608   "Render DATA as plain text file.  PARAMETERS is currently unused."
1609   (elpher-with-clean-buffer
1610    (insert (elpher-process-text-for-display data))
1611    (elpher-cache-content
1612     (elpher-page-address elpher-current-page)
1613     (buffer-string))))
1614
1615
1616 ;; Finger page connection
1617
1618 (defun elpher-get-finger-page (renderer)
1619   "Opens a finger connection to the current page address.
1620 The result is rendered using RENDERER."
1621   (let* ((address (elpher-page-address elpher-current-page))
1622          (content (elpher-get-cached-content address)))
1623     (if (and content (funcall renderer nil))
1624         (elpher-with-clean-buffer
1625          (insert content)
1626          (elpher-restore-pos))
1627       (elpher-with-clean-buffer
1628        (insert "LOADING... (use 'u' to cancel)\n"))
1629       (condition-case the-error
1630           (let* ((kill-buffer-query-functions nil)
1631                  (user (let ((filename (elpher-address-filename address)))
1632                          (if (> (length filename) 1)
1633                              (substring filename 1)
1634                            (elpher-address-user address)))))
1635             (elpher-get-host-response address 79
1636                                       (concat user "\r\n")
1637                                       renderer))
1638         (error
1639          (elpher-network-error address the-error))))))
1640
1641
1642 ;; Telnet page connection
1643
1644 (defun elpher-get-telnet-page (renderer)
1645   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1646   (when renderer
1647     (elpher-visit-previous-page)
1648     (error "Command not supported for telnet URLs"))
1649   (let* ((address (elpher-page-address elpher-current-page))
1650          (host (elpher-address-host address))
1651          (port (elpher-address-port address)))
1652     (elpher-visit-previous-page)
1653     (if (> port 0)
1654         (telnet host port)
1655       (telnet host))))
1656
1657
1658 ;; Other URL page opening
1659
1660 (defun elpher-get-other-url-page (renderer)
1661   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1662   (when renderer
1663     (elpher-visit-previous-page)
1664     (error "Command not supported for general URLs"))
1665   (let* ((address (elpher-page-address elpher-current-page))
1666          (url (elpher-address-to-url address)))
1667     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1668     (message "Opening URL...")
1669     (if elpher-open-urls-with-eww
1670         (browse-web url)
1671       (browse-url url))))
1672
1673 ;; File page
1674
1675 (defun elpher-get-file-page (renderer)
1676   "Getter which renders a local file using RENDERER.
1677 Assumes UTF-8 encoding for all text files."
1678   (let* ((address (elpher-page-address elpher-current-page))
1679          (filename (elpher-address-filename address)))
1680     (unless (file-exists-p filename)
1681       (elpher-visit-previous-page)
1682         (error "File not found"))
1683     (unless (file-readable-p filename)
1684       (elpher-visit-previous-page)
1685         (error "Could not read from file"))
1686     (let ((body (with-temp-buffer
1687        (let ((coding-system-for-read 'binary)
1688              (coding-system-for-write 'binary))
1689          (insert-file-contents-literally filename)
1690          (encode-coding-string (buffer-string) 'raw-text)))))
1691        (if renderer
1692            (funcall renderer body nil)
1693          (pcase (file-name-extension filename)
1694            ((or  "gmi" "gemini")
1695             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1696            ((or "htm" "html")
1697             (elpher-render-html (decode-coding-string body 'utf-8)))
1698            ((or "txt" "")
1699             (elpher-render-text (decode-coding-string body 'utf-8)))
1700            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1701             (elpher-render-image body))
1702            (_
1703             (elpher-render-download body))))
1704        (elpher-restore-pos))))
1705
1706
1707 ;; Welcome page retrieval
1708
1709 (defun elpher-get-welcome-page (renderer)
1710   "Getter which displays the welcome page (RENDERER must be nil)."
1711   (when renderer
1712     (elpher-visit-previous-page)
1713     (error "Command not supported for welcome page"))
1714   (elpher-with-clean-buffer
1715    (insert "     --------------------------------------------\n"
1716            "           Elpher Gopher and Gemini Client       \n"
1717            "                   version " elpher-version "\n"
1718            "     --------------------------------------------\n"
1719            "\n"
1720            "Default bindings:\n"
1721            "\n"
1722            " - TAB/Shift-TAB: next/prev item on current page\n"
1723            " - RET/mouse-1: open item under cursor\n"
1724            " - m: select an item on current page by name (autocompletes)\n"
1725            " - u/mouse-3/U: return to previous page or to the start page\n"
1726            " - g: go to a particular address (gopher, gemini, finger)\n"
1727            " - o/O: open a different address selector or the root menu of the current server\n"
1728            " - d/D: download item under cursor or current page\n"
1729            " - i/I: info on item under cursor or current page\n"
1730            " - c/C: copy URL representation of item under cursor or current page\n"
1731            " - a/A: bookmark the item under cursor or current page\n"
1732            " - B: list all bookmarks\n"
1733            " - s/S: show current history stack or all previously visted pages\n"
1734            " - r: redraw current page (using cached contents if available)\n"
1735            " - R: reload current page (regenerates cache)\n"
1736            " - !: set character coding system for gopher (default is to autodetect)\n"
1737            " - T: toggle TLS gopher mode\n"
1738            " - F: forget/discard current TLS client certificate\n"
1739            " - .: display the raw server response for the current page\n"
1740            "\n"
1741            "Start your exploration of gopher space and gemini:\n")
1742    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1743                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1744    (elpher-insert-index-record "Project Gemini home page"
1745                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1746    (insert "\n"
1747            "Alternatively, select a search engine and enter some search terms:\n")
1748    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1749                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1750    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1751                                (elpher-address-from-url "gemini://geminispace.info/search"))
1752    (insert "\n"
1753            "Your bookmarks are stored in your ")
1754    (let ((help-string "RET,mouse-1: Open bookmark list"))
1755      (insert-text-button "bookmark list"
1756                          'face 'link
1757                          'action #'elpher-click-link
1758                          'follow-link t
1759                          'help-echo #'elpher--page-button-help
1760                          'elpher-page
1761                          (elpher-make-page "Elpher Bookmarks"
1762                                            (elpher-make-about-address 'bookmarks))))
1763    (insert ".\n")
1764    (insert (propertize
1765             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1766             'face 'shadow))
1767    (insert "\n"
1768            "The gopher home of the Elpher project is here:\n")
1769    (elpher-insert-index-record "The Elpher Project Page"
1770                                (elpher-make-gopher-address ?1
1771                                                            "/projects/elpher/"
1772                                                            "thelambdalab.xyz"
1773                                                            70))
1774    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1775      (insert "\n"
1776              "The following info documentation is available:\n"
1777              "   - ")
1778      (insert-text-button "Elpher Manual"
1779                          'face 'link
1780                          'action (lambda (_)
1781                                    (interactive)
1782                                    (info "(elpher)"))
1783                          'follow-link t
1784                          'help-echo help-string)
1785      (insert "\n   - ")
1786      (insert-text-button "Changes introduced by the latest release"
1787                        'face 'link
1788                        'action (lambda (_)
1789                                  (interactive)
1790                                  (info "(elpher)News"))
1791                        'follow-link t
1792                        'help-echo help-string))
1793    (insert "\n")
1794    (insert (propertize
1795             (concat "(These documents should be available if you have installed Elpher \n"
1796                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1797             'face 'shadow))
1798    (elpher-restore-pos)))
1799
1800 ;; History page retrieval
1801
1802 (defun elpher-show-history ()
1803   "Show the current contents of elpher's history stack.
1804 Use \\[elpher-show-visited-pages] to see the entire history.
1805 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1806   (interactive)
1807   (elpher-visit-page
1808    (elpher-make-page "Current History Stack"
1809                      (elpher-make-about-address 'history))))
1810
1811 (defun elpher-show-visited-pages ()
1812   "Show the all the pages you've visited using Elpher.
1813 Use \\[elpher-show-history] to see just the current history stack.
1814 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1815   (interactive)
1816   (elpher-visit-page
1817    (elpher-make-page "Elpher Visted Pages"
1818                      (elpher-make-about-address 'visited-pages))))
1819
1820 (defun elpher-get-history-page (renderer)
1821   "Getter which displays the history page (RENDERER must be nil)."
1822   (when renderer
1823     (elpher-visit-previous-page)
1824     (error "Command not supported for history page"))
1825   (elpher-display-history-links elpher-history "Current history stack"))
1826
1827 (defun elpher-get-visited-pages-page (renderer)
1828   "Getter which displays the list of visited pages (RENDERER must be nil)."
1829   (when renderer
1830     (elpher-visit-previous-page)
1831     (error "Command not supported for history page"))
1832   (elpher-display-history-links
1833    (seq-filter (lambda (page)
1834                  (not (elpher-address-about-p (elpher-page-address page))))
1835                elpher-visited-pages)
1836    "All visited pages"))
1837
1838 (defun elpher-display-history-links (pages title)
1839   "Show all PAGES in an Elpher buffer with a given TITLE."
1840   (let* ((title-line (concat " ---- " title " ----"))
1841          (footer-line (make-string (length title-line) ?-)))
1842     (elpher-with-clean-buffer
1843      (insert title-line "\n\n")
1844      (if pages
1845          (dolist (page pages)
1846            (when page
1847              (let ((display-string (elpher-page-display-string page))
1848                    (address (elpher-page-address page)))
1849                (elpher-insert-index-record display-string address))))
1850        (insert "No history items found.\n"))
1851      (insert "\n " footer-line "\n"
1852              "Select an entry or press 'u' to return to the previous page.")
1853      (elpher-restore-pos))))
1854
1855
1856 ;;; Bookmarks
1857
1858 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1859 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1860 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1861 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1862
1863 (defvar elpher-bookmark-link nil
1864   "Prefer bookmarking a link or the current page.
1865 Bind this variable dynamically, or set it to t.
1866 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1867 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1868
1869 (defun elpher-bookmark-make-record ()
1870   "Return a bookmark record.
1871 If `elpher-bookmark-link' is non-nil and point is on a link button,
1872 return a bookmark record for that link.  Otherwise, return a bookmark
1873 record for the current elpher page."
1874   (let* ((button (and elpher-bookmark-link (button-at (point))))
1875          (page (if button
1876                    (button-get button 'elpher-page)
1877                  elpher-current-page)))
1878     (unless page
1879       (error "Cannot bookmark this link"))
1880     (let* ((address (elpher-page-address page))
1881            (url (elpher-address-to-url address))
1882            (display-string (elpher-page-display-string page))
1883            (pos (if button nil (point))))
1884       (if (elpher-address-about-p address)
1885           (error "Cannot bookmark %s" display-string)
1886         `(,display-string
1887           (defaults . (,display-string))
1888           (position . ,pos)
1889           (location . ,url)
1890           (handler . elpher-bookmark-jump))))))
1891
1892 ;;;###autoload
1893 (defun elpher-bookmark-jump (bookmark)
1894   "Handler used to open a bookmark using elpher.
1895 The argument BOOKMARK is a bookmark record passed to the function.
1896 This handler is responsible for loading the bookmark in some buffer,
1897 then making that buffer the current buffer.  It should not switch
1898 to the buffer."
1899   (let* ((url (cdr (assq 'location bookmark)))
1900          (cleaned-url (string-trim url))
1901          (page (elpher-page-from-url cleaned-url)))
1902     (elpher-with-clean-buffer
1903      (elpher-visit-page page))
1904     (set-buffer (get-buffer elpher-buffer-name))
1905     nil))
1906
1907 (defun elpher-bookmark-link ()
1908   "Bookmark the link at point.
1909 To bookmark the current page, use \\[elpher-bookmark-current]."
1910   (interactive)
1911   (let ((elpher-bookmark-link t))
1912     (bookmark-set-no-overwrite)))
1913
1914 (defun elpher-bookmark-current ()
1915   "Bookmark the current page.
1916 To bookmark the link at point use \\[elpher-bookmark-link]."
1917   (interactive)
1918   (call-interactively #'bookmark-set-no-overwrite))
1919
1920 (defun elpher-bookmark-import (file)
1921   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1922   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1923                               (file-readable-p elpher-bookmarks-file))
1924                          elpher-bookmarks-file
1925                        (read-file-name "Old Elpher bookmarks: "
1926                                        user-emacs-directory nil t
1927                                        "elpher-bookmarks"))))
1928   (dolist (bookmark (with-temp-buffer
1929                       (insert-file-contents file)
1930                       (read (current-buffer))))
1931     (let* ((display-string (car bookmark))
1932            (url (cadr bookmark))
1933            (record `(,display-string
1934                      (location . ,url)
1935                      (handler . elpher-bookmark-jump))))
1936       (bookmark-store display-string (cdr record) t)))
1937   (bookmark-save))
1938
1939 (defun elpher-get-bookmarks-page (renderer)
1940   "Getter which displays the bookmarks (RENDERER must be nil)."
1941   (when renderer
1942     (elpher-visit-previous-page)
1943     (error "Command not supported for bookmarks page"))
1944
1945   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1946                                      elpher-bookmarks-file)
1947                                 (locate-user-emacs-file "elpher-bookmarks"))))
1948     (when (and (file-readable-p old-bookmarks-file)
1949                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1950                                  old-bookmarks-file
1951                                  "\" found. Import now?")))
1952       (elpher-bookmark-import old-bookmarks-file)
1953       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1954
1955   (if (and elpher-use-emacs-bookmark-menu
1956            elpher-history)
1957       (progn
1958         (elpher-visit-previous-page)
1959         (call-interactively #'bookmark-bmenu-list))
1960     (elpher-with-clean-buffer
1961      (insert " ---- Elpher Bookmarks ---- \n\n")
1962      (bookmark-maybe-load-default-file)
1963      (dolist (bookmark (bookmark-maybe-sort-alist))
1964        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1965          (let* ((name (car bookmark))
1966                 (url (alist-get 'location (cdr bookmark)))
1967                 (address (elpher-address-from-url url)))
1968            (elpher-insert-index-record name address))))
1969      (when (<= (line-number-at-pos) 3)
1970        (insert "No bookmarked pages found.\n"))
1971      (insert "\n --------------------------\n\n"
1972              "Select an entry or press 'u' to return to the previous page.\n\n"
1973              "Bookmarks can be renamed or deleted via the ")
1974      (insert-text-button "Emacs bookmark menu"
1975                          'action (lambda (_)
1976                                    (interactive)
1977                                    (call-interactively #'bookmark-bmenu-list))
1978                          'follow-link t
1979                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
1980      (insert (substitute-command-keys
1981               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1982      (elpher-restore-pos))))
1983
1984 (defun elpher-show-bookmarks ()
1985   "Interactive function to display the current list of elpher bookmarks."
1986   (interactive)
1987   (elpher-visit-page
1988    (elpher-make-page "Elpher Bookmarks"
1989                      (elpher-make-about-address 'bookmarks))))
1990
1991
1992 ;;; Integrations
1993 ;;
1994
1995 ;;; Org
1996
1997 (defun elpher-org-export-link (link description format protocol)
1998   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1999
2000 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2001 of gemini, gopher or finger."
2002   (let* ((url (if (equal protocol "elpher")
2003                   (string-remove-prefix "elpher:" link)
2004                 (format "%s:%s" protocol link)))
2005          (desc (or description url)))
2006     (pcase format
2007       (`gemini (format "=> %s %s" url desc))
2008       (`html (format "<a href=\"%s\">%s</a>" url desc))
2009       (`latex (format "\\href{%s}{%s}" url desc))
2010       (_ (if (not description)
2011              url
2012            (format "%s (%s)" desc url))))))
2013
2014 (defun elpher-org-store-link ()
2015   "Store link to an `elpher' page in Org."
2016   (when (eq major-mode 'elpher-mode)
2017     (let* ((url (elpher-info-current))
2018            (desc (car elpher-current-page))
2019            (protocol (cond
2020                       ((string-prefix-p "gemini:" url) "gemini")
2021                       ((string-prefix-p "gopher:" url) "gopher")
2022                       ((string-prefix-p "finger:" url) "finger")
2023                       (t "elpher"))))
2024       (when (equal "elpher" protocol)
2025         ;; Weird link. Or special inner link?
2026         (setq url (concat "elpher:" url)))
2027       (org-link-store-props :type protocol :link url :description desc)
2028       t)))
2029
2030 (defun elpher-org-follow-link (link protocol)
2031   "Visit a LINK for the given PROTOCOL.
2032
2033 PROTOCOL may be one of gemini, gopher or finger.  This method also
2034 supports the old protocol elpher, where the link is self-contained."
2035   (let ((url (if (equal protocol "elpher")
2036                  (string-remove-prefix "elpher:" link)
2037                (format "%s:%s" protocol link))))
2038     (elpher-go url)))
2039
2040 (defun elpher-org-mode-integration ()
2041   "Set up `elpher' integration for `org-mode'."
2042   (org-link-set-parameters
2043    "elpher"
2044    :store #'elpher-org-store-link
2045    :export (lambda (link description format _plist)
2046              (elpher-org-export-link link description format "elpher"))
2047    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2048   (org-link-set-parameters
2049    "gemini"
2050    :export (lambda (link description format _plist)
2051              (elpher-org-export-link link description format "gemini"))
2052    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2053   (org-link-set-parameters
2054    "gopher"
2055    :export (lambda (link description format _plist)
2056              (elpher-org-export-link link description format "gopher"))
2057    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2058   (org-link-set-parameters
2059    "finger"
2060    :export (lambda (link description format _plist)
2061              (elpher-org-export-link link description format "finger"))
2062    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2063
2064 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2065
2066 ;;; Browse URL
2067
2068 ;;;###autoload
2069 (defun elpher-browse-url-elpher (url &rest _args)
2070   "Browse URL using Elpher.  This function is used by `browse-url'."
2071   (interactive (browse-url-interactive-arg "Elpher URL: "))
2072   (elpher-go url))
2073
2074 ;; Use elpher to open gopher, finger and gemini links
2075 ;; For recent version of `browse-url' package
2076 (if (boundp 'browse-url-default-handlers)
2077     (add-to-list
2078      'browse-url-default-handlers
2079      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2080   ;; Patch `browse-url-browser-function' for older ones. The value of
2081   ;; that variable is `browse-url-default-browser' by default, so
2082   ;; that's the function that gets advised.
2083   (advice-add browse-url-browser-function :before-while
2084               (lambda (url &rest _args)
2085                 "Handle gemini, gopher, and finger schemes using Elpher."
2086                 (let ((scheme (downcase (car (split-string url ":" t)))))
2087                   (if (member scheme '("gemini" "gopher" "finger"))
2088                       ;; `elpher-go' always returns nil, which will stop the
2089                       ;; advice chain here in a before-while
2090                       (elpher-go url)
2091                     ;; chain must continue, then return t.
2092                     t)))))
2093
2094 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2095 (with-eval-after-load 'thingatpt
2096   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2097
2098 ;;; Mu4e:
2099
2100 ;; Make mu4e aware of the gemini world
2101 (setq mu4e~view-beginning-of-url-regexp
2102       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2103
2104 ;;; eww:
2105
2106 ;; Let elpher handle gemini, gopher links in eww buffer.
2107 (setq eww-use-browse-url
2108       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2109
2110
2111 ;;; Interactive procedures
2112 ;;
2113
2114 (defun elpher-next-link ()
2115   "Move point to the next link on the current page."
2116   (interactive)
2117   (forward-button 1))
2118
2119 (defun elpher-prev-link ()
2120   "Move point to the previous link on the current page."
2121   (interactive)
2122   (backward-button 1))
2123
2124 (defun elpher-follow-current-link ()
2125   "Open the link or url at point."
2126   (interactive)
2127   (push-button))
2128
2129 ;;;###autoload
2130 (defun elpher-go (host-or-url)
2131   "Go to a particular gopher site HOST-OR-URL.
2132 When run interactively HOST-OR-URL is read from the minibuffer."
2133   (interactive "sGopher or Gemini URL: ")
2134   (let ((trimmed-host-or-url (string-trim host-or-url)))
2135     (unless (string-empty-p trimmed-host-or-url)
2136       (let ((page (elpher-page-from-url trimmed-host-or-url)))
2137         (switch-to-buffer elpher-buffer-name)
2138         (elpher-with-clean-buffer
2139          (elpher-visit-page page))
2140         nil)))) ; non-nil value is displayed by eshell
2141
2142 (defun elpher-go-current ()
2143   "Go to a particular site read from the minibuffer, initialized with the current URL."
2144   (interactive)
2145   (let* ((address (elpher-page-address elpher-current-page))
2146          (url (read-string "Gopher or Gemini URL: "
2147                            (unless (elpher-address-about-p address)
2148                              (elpher-address-to-url address)))))
2149     (unless (string-empty-p (string-trim url))
2150       (elpher-visit-page (elpher-page-from-url url)))))
2151
2152 (defun elpher-redraw ()
2153   "Redraw current page."
2154   (interactive)
2155   (elpher-visit-page elpher-current-page))
2156
2157 (defun elpher-reload ()
2158   "Reload current page."
2159   (interactive)
2160   (elpher-reload-current-page))
2161
2162 (defun elpher-toggle-tls ()
2163   "Toggle TLS encryption mode for gopher."
2164   (interactive)
2165   (setq elpher-use-tls (not elpher-use-tls))
2166   (if elpher-use-tls
2167       (if (gnutls-available-p)
2168           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2169         (setq elpher-use-tls nil)
2170         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2171     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2172
2173 (defun elpher-view-raw ()
2174   "View raw server response for current page."
2175   (interactive)
2176   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2177       (error "This page was not generated by a server")
2178     (elpher-visit-page elpher-current-page
2179                        #'elpher-render-raw)))
2180
2181 (defun elpher-back ()
2182   "Go to previous site."
2183   (interactive)
2184   (elpher-visit-previous-page))
2185
2186 (defun elpher-back-to-start ()
2187   "Go all the way back to the start page."
2188   (interactive)
2189   (setq-local elpher-current-page nil)
2190   (setq-local elpher-history nil)
2191   (elpher-visit-page (elpher-make-start-page)))
2192
2193 (defun elpher-download ()
2194   "Download the link at point."
2195   (interactive)
2196   (let ((button (button-at (point))))
2197     (if button
2198         (let ((page (button-get button 'elpher-page)))
2199           (unless page
2200             (error "Not an elpher page"))
2201           (when (elpher-address-about-p (elpher-page-address page))
2202             (error "Cannot download %s" (elpher-page-display-string page)))
2203           (elpher-visit-page (button-get button 'elpher-page)
2204                              #'elpher-render-download))
2205       (error "No link selected"))))
2206
2207 (defun elpher-download-current ()
2208   "Download the current page."
2209   (interactive)
2210   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2211       (error "Cannot download %s"
2212              (elpher-page-display-string elpher-current-page))
2213     (elpher-visit-page (elpher-make-page
2214                         (elpher-page-display-string elpher-current-page)
2215                         (elpher-page-address elpher-current-page))
2216                        #'elpher-render-download
2217                        t)))
2218
2219 (defun elpher--build-link-map ()
2220   "Build alist mapping link names to destination pages in current buffer."
2221   (let ((link-map nil)
2222         (b (next-button (point-min) t)))
2223     (while b
2224       (push (cons (button-label b) b) link-map)
2225       (setq b (next-button (button-start b))))
2226     link-map))
2227
2228 (defun elpher-jump ()
2229   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2230   (interactive)
2231   (let* ((link-map (elpher--build-link-map)))
2232     (if link-map
2233         (let ((key (let ((completion-ignore-case t))
2234                      (completing-read "Directory item/link: "
2235                                       link-map nil t))))
2236           (if (and key (> (length key) 0))
2237               (let ((b (cdr (assoc key link-map))))
2238                 (goto-char (button-start b))
2239                 (button-activate b)))))))
2240
2241 (defun elpher-root-dir ()
2242   "Visit root of current server."
2243   (interactive)
2244   (let ((address (elpher-page-address elpher-current-page)))
2245     (if (not (elpher-address-about-p address))
2246         (if (or (member (url-filename address) '("/" ""))
2247                 (and (elpher-address-gopher-p address)
2248                      (= (length (elpher-gopher-address-selector address)) 0)))
2249             (error "Already at root directory of current server")
2250           (let ((address-copy (elpher-address-from-url
2251                                (elpher-address-to-url address))))
2252             (setf (url-filename address-copy) "")
2253             (elpher-go (elpher-address-to-url address-copy))))
2254       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2255
2256 (defun elpher-info-page (page)
2257   "Display URL of PAGE in minibuffer."
2258   (let ((address (elpher-page-address page)))
2259     (message "%s" (elpher-address-to-url address))))
2260
2261 (defun elpher-info-link ()
2262   "Display information on page corresponding to link at point."
2263   (interactive)
2264   (let ((button (button-at (point))))
2265     (unless button
2266       (error "No item selected"))
2267     (let ((page (button-get button 'elpher-page)))
2268       (unless page
2269         (error "Not an elpher page"))
2270       (elpher-info-page page))))
2271
2272 (defun elpher-info-current ()
2273   "Display information on current page."
2274   (interactive)
2275   (elpher-info-page elpher-current-page))
2276
2277 (defun elpher-copy-page-url (page)
2278   "Copy URL representation of address of PAGE to `kill-ring'."
2279   (let* ((address (elpher-page-address page))
2280          (url (elpher-address-to-url address)))
2281     (message "Copied \"%s\" to kill-ring/clipboard." url)
2282     (kill-new url)))
2283
2284 (defun elpher-copy-link-url ()
2285   "Copy URL of item at point to `kill-ring'."
2286   (interactive)
2287   (let ((button (button-at (point))))
2288     (unless button
2289       (error "No item selected"))
2290     (let ((page (button-get button 'elpher-page)))
2291       (unless page
2292         (error "Not an elpher page"))
2293       (elpher-copy-page-url page))))
2294
2295 (defun elpher-copy-current-url ()
2296   "Copy URL of current page to `kill-ring'."
2297   (interactive)
2298   (elpher-copy-page-url elpher-current-page))
2299
2300 (defun elpher-set-gopher-coding-system ()
2301   "Specify an explicit character coding system for gopher selectors."
2302   (interactive)
2303   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2304     (setq elpher-user-coding-system system)
2305     (if system
2306         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2307       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2308
2309
2310 ;;; Mode and keymap
2311 ;;
2312
2313 (defvar elpher-mode-map
2314   (let ((map (make-sparse-keymap)))
2315     (define-key map (kbd "TAB") 'elpher-next-link)
2316     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2317     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2318     (define-key map (kbd "u") 'elpher-back)
2319     (define-key map (kbd "-") 'elpher-back)
2320     (define-key map (kbd "^") 'elpher-back)
2321     (define-key map [mouse-3] 'elpher-back)
2322     (define-key map (kbd "U") 'elpher-back-to-start)
2323     (define-key map (kbd "g") 'elpher-go)
2324     (define-key map (kbd "o") 'elpher-go-current)
2325     (define-key map (kbd "O") 'elpher-root-dir)
2326     (define-key map (kbd "s") 'elpher-show-history)
2327     (define-key map (kbd "S") 'elpher-show-visited-pages)
2328     (define-key map (kbd "r") 'elpher-redraw)
2329     (define-key map (kbd "R") 'elpher-reload)
2330     (define-key map (kbd "T") 'elpher-toggle-tls)
2331     (define-key map (kbd ".") 'elpher-view-raw)
2332     (define-key map (kbd "d") 'elpher-download)
2333     (define-key map (kbd "D") 'elpher-download-current)
2334     (define-key map (kbd "m") 'elpher-jump)
2335     (define-key map (kbd "i") 'elpher-info-link)
2336     (define-key map (kbd "I") 'elpher-info-current)
2337     (define-key map (kbd "c") 'elpher-copy-link-url)
2338     (define-key map (kbd "C") 'elpher-copy-current-url)
2339     (define-key map (kbd "a") 'elpher-bookmark-link)
2340     (define-key map (kbd "A") 'elpher-bookmark-current)
2341     (define-key map (kbd "B") 'elpher-show-bookmarks)
2342     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2343     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2344     (when (fboundp 'evil-define-key*)
2345       (evil-define-key*
2346        'motion map
2347        (kbd "TAB") 'elpher-next-link
2348        (kbd "C-") 'elpher-follow-current-link
2349        (kbd "C-t") 'elpher-back
2350        (kbd "u") 'elpher-back
2351        (kbd "-") 'elpher-back
2352        (kbd "^") 'elpher-back
2353        [mouse-3] 'elpher-back
2354        (kbd "U") 'elpher-back-to-start
2355        (kbd "g") 'elpher-go
2356        (kbd "o") 'elpher-go-current
2357        (kbd "O") 'elpher-root-dir
2358        (kbd "s") 'elpher-show-history
2359        (kbd "S") 'elpher-show-visited-pages
2360        (kbd "r") 'elpher-redraw
2361        (kbd "R") 'elpher-reload
2362        (kbd "T") 'elpher-toggle-tls
2363        (kbd ".") 'elpher-view-raw
2364        (kbd "d") 'elpher-download
2365        (kbd "D") 'elpher-download-current
2366        (kbd "m") 'elpher-jump
2367        (kbd "i") 'elpher-info-link
2368        (kbd "I") 'elpher-info-current
2369        (kbd "c") 'elpher-copy-link-url
2370        (kbd "C") 'elpher-copy-current-url
2371        (kbd "a") 'elpher-bookmark-link
2372        (kbd "A") 'elpher-bookmark-current
2373        (kbd "B") 'elpher-show-bookmarks
2374        (kbd "!") 'elpher-set-gopher-coding-system
2375        (kbd "F") 'elpher-forget-current-certificate))
2376     map)
2377   "Keymap for gopher client.")
2378
2379 (define-derived-mode elpher-mode special-mode "elpher"
2380   "Major mode for elpher, an elisp gopher client.
2381
2382 This mode is automatically enabled by the interactive
2383 functions which initialize the client, namely
2384 `elpher', and `elpher-go'."
2385   (setq-local elpher--gemini-page-headings nil)
2386   (setq-local elpher-current-page nil)
2387   (setq-local elpher-history nil)
2388   (setq-local elpher-buffer-name (buffer-name))
2389   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2390   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2391   (setq-local xterm-color-preserve-properties t))
2392
2393 (when (fboundp 'evil-set-initial-state)
2394   (evil-set-initial-state 'elpher-mode 'motion))
2395
2396
2397 ;;; Main start procedure
2398 ;;
2399
2400 ;;;###autoload
2401 (defun elpher (&optional arg)
2402   "Start elpher with default landing page.
2403 The buffer used for Elpher sessions is determined by the value of
2404 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2405 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2406 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2407 \\[execute-extended-command] elpher RET’) switches to the session with
2408 that number, creating it if necessary.  A non numeric prefix ARG means
2409 to create a new session.  Returns the buffer selected (or created)."
2410   (interactive "P")
2411   (let* ((name (default-value 'elpher-buffer-name))
2412          (buf (cond ((numberp arg)
2413                      (get-buffer-create (format "%s<%d>" name arg)))
2414                     (arg
2415                      (generate-new-buffer name))
2416                     (t
2417                      (get-buffer-create name)))))
2418     (pop-to-buffer-same-window buf)
2419     (unless (buffer-modified-p)
2420       (elpher-mode)
2421       (elpher-visit-page (elpher-make-start-page))
2422       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2423
2424 ;;; elpher.el ends here