elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
   9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
  10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  20
  21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  22 ;; Created: 11 April 2019
  23 ;; Version: 3.1.0
  24 ;; Keywords: comm gopher
  25 ;; Homepage: https://thelambdalab.xyz/elpher
  26 ;; Package-Requires: ((emacs "27.1"))
  27
  28 ;; This file is not part of GNU Emacs.
  29
  30 ;; This program is free software: you can redistribute it and/or modify
  31 ;; it under the terms of the GNU General Public License as published by
  32 ;; the Free Software Foundation, either version 3 of the License, or
  33 ;; (at your option) any later version.
  34
  35 ;; This program is distributed in the hope that it will be useful,
  36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  38 ;; GNU General Public License for more details.
  39
  40 ;; You should have received a copy of the GNU General Public License
  41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  42
  43 ;;; Commentary:
  44
  45 ;; Elpher aims to provide a practical and friendly gopher and gemini
  46 ;; client for GNU Emacs.  It supports:
  47
  48 ;; - intuitive keyboard and mouse-driven browsing,
  49 ;; - out-of-the-box compatibility with evil-mode,
  50 ;; - clickable web and gopher links *in plain text*,
  51 ;; - caching of visited sites,
  52 ;; - pleasant and configurable colouring of Gopher directories,
  53 ;; - direct visualisation of image files,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official project
  66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  68
  69 ;;; Code:
  70
  71 (provide 'elpher)
  72
  73 ;;; Dependencies
  74 ;;
  75
  76 (require 'seq)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'nsm)
  81 (require 'gnutls)
  82 (require 'socks)
  83 (require 'bookmark)
  84
  85 ;;; Global constants
  86 ;;
  87
  88 (defconst elpher-version "3.1.0"
  89   "Current version of elpher.")
  90
  91 (defconst elpher-margin-width 6
  92   "Width of left-hand margin used when rendering indicies.")
  93
  94 (defconst elpher-type-map
  95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 112     (file elpher-get-file-page nil "~" elpher-gemini)
 113     ((special welcome) elpher-get-welcome-page nil "E" elpher-index)
 114     ((special bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 115     ((special history) elpher-get-history-page nil "E" elpher-index)
 116     ((special visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 117   "Association list from types to getters, renderers, margin codes and index faces.")
 118
 119
 120 ;;; Declarations to avoid compiler warnings.
 121 ;;
 122
 123 (eval-when-compile
 124   (declare-function ansi-color-filter-apply "ansi-color")
 125   (declare-function ansi-color-apply "ansi-color")
 126   (declare-function bookmark-store "bookmark")
 127   (declare-function org-link-store-props "ol")
 128   (declare-function org-link-set-parameters "ol")
 129   (defvar ansi-color-context)
 130   (defvar bookmark-make-record-function)
 131   (defvar mu4e~view-beginning-of-url-regexp)
 132   (defvar eww-use-browse-url)
 133   (defvar thing-at-point-uri-schemes)
 134   (defvar xterm-color-preserve-properties))
 135
 136
 137 ;;; Customization group
 138 ;;
 139
 140 (defgroup elpher nil
 141   "A gopher and gemini client."
 142   :group 'applications)
 143
 144 ;; General appearance and customizations
 145
 146 (defcustom elpher-open-urls-with-eww nil
 147   "If non-nil, open URL selectors using eww.
 148 Otherwise, use the system browser via the `browse-url' function."
 149   :type '(boolean))
 150
 151 (defcustom elpher-use-header t
 152   "If non-nil, display current page information in buffer header."
 153   :type '(boolean))
 154
 155 (defcustom elpher-auto-disengage-TLS nil
 156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 157 While enabling this may seem convenient, it is also potentially
 158 dangerous as it allows switching from an encrypted channel back to
 159 plain text without user input."
 160   :type '(boolean))
 161
 162 (defcustom elpher-connection-timeout 5
 163   "Specifies the number of seconds to wait for a network connection to time out."
 164   :type '(integer))
 165
 166 (defcustom elpher-filter-ansi-from-text nil
 167   "If non-nil, filter ANSI escape sequences from text.
 168 The default behaviour is to use the ansi-color package to interpret these
 169 sequences."
 170   :type '(boolean))
 171
 172 (defcustom elpher-certificate-directory
 173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 174   "Specify the name of the directory where client certificates will be stored.
 175 These certificates may be used for establishing authenticated TLS connections."
 176   :type '(directory))
 177
 178 (defcustom elpher-openssl-command "openssl"
 179   "The command used to launch openssl when generating TLS client certificates."
 180   :type '(file))
 181
 182 (defcustom elpher-default-url-type "gopher"
 183   "Default URL type (i.e. scheme) to assume if not explicitly given."
 184   :type '(choice (const "gopher")
 185                  (const "gemini")))
 186
 187 (defcustom elpher-gemini-TLS-cert-checks nil
 188   "If non-nil, verify gemini server TLS certs using the default security level.
 189 Otherwise, certificate verification is disabled.
 190
 191 This defaults to off because it is standard practice for Gemini servers
 192 to use self-signed certificates, meaning that most servers provide what
 193 EMACS considers to be an invalid certificate."
 194   :type '(boolean))
 195
 196 (defcustom elpher-gemini-max-fill-width 80
 197   "Specify the maximum default width (in columns) of text/gemini documents.
 198 The actual width used is the minimum of this value and the window width at
 199 the time when the text is rendered."
 200   :type '(integer))
 201
 202 (defcustom elpher-gemini-link-string "→ "
 203   "Specify the string used to indicate links when rendering gemini maps.
 204 May be empty."
 205   :type '(string))
 206
 207 (defcustom elpher-gemini-bullet-string "•"
 208   "Specify the string used for bullets when rendering gemini maps."
 209   :type '(string))
 210
 211 (defcustom elpher-ipv4-always nil
 212   "If non-nil, elpher will always use IPv4 to establish network connections.
 213 This can be useful when browsing from a computer that supports IPv6, because
 214 some servers which do not support IPv6 can take a long time to time-out."
 215   :type '(boolean))
 216
 217 (defcustom elpher-socks-always nil
 218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 219 Otherwise, the SOCKS proxy is only used for connections to onion services."
 220   :type '(boolean))
 221
 222 (defcustom elpher-use-emacs-bookmark-menu nil
 223   "If non-nil, elpher will only use the native Emacs bookmark menu.
 224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 225 page within which all of the standard elpher keybindings are active."
 226   :type '(boolean))
 227
 228 (defcustom elpher-start-page "about:welcome"
 229   "Specify the page displayed initially by elpher.
 230 The default welcome screen \"about:welcome\", while the bookmarks list
 231 is \"about:bookmarks\".  You can also specify local files via \"file:\".")
 232
 233 ;; Face customizations
 234
 235 (defgroup elpher-faces nil
 236   "Elpher face customizations."
 237   :group 'elpher)
 238
 239 (defface elpher-index
 240   '((t :inherit font-lock-keyword-face))
 241   "Face used for directory type directory records.")
 242
 243 (defface elpher-text
 244   '((t :inherit bold))
 245   "Face used for text type directory records.")
 246
 247 (defface elpher-info
 248   '((t :inherit default))
 249   "Face used for info type directory records.")
 250
 251 (defface elpher-image
 252   '((t :inherit font-lock-string-face))
 253   "Face used for image type directory records.")
 254
 255 (defface elpher-search
 256   '((t :inherit warning))
 257   "Face used for search type directory records.")
 258
 259 (defface elpher-html
 260   '((t :inherit font-lock-comment-face))
 261   "Face used for html type directory records.")
 262
 263 (defface elpher-gemini
 264   '((t :inherit font-lock-constant-face))
 265   "Face used for Gemini type directory records.")
 266
 267 (defface elpher-other-url
 268   '((t :inherit font-lock-comment-face))
 269   "Face used for other URL type links records.")
 270
 271 (defface elpher-telnet
 272   '((t :inherit font-lock-function-name-face))
 273   "Face used for telnet type directory records.")
 274
 275 (defface elpher-binary
 276   '((t :inherit font-lock-doc-face))
 277   "Face used for binary type directory records.")
 278
 279 (defface elpher-unknown
 280   '((t :inherit error))
 281   "Face used for directory records with unknown/unsupported types.")
 282
 283 (defface elpher-margin-key
 284   '((t :inherit bold))
 285   "Face used for directory margin key.")
 286
 287 (defface elpher-margin-brackets
 288   '((t :inherit shadow))
 289   "Face used for brackets around directory margin key.")
 290
 291 (defface elpher-gemini-heading1
 292   '((t :inherit bold :height 1.8))
 293   "Face used for gemini heading level 1.")
 294
 295 (defface elpher-gemini-heading2
 296   '((t :inherit bold :height 1.5))
 297   "Face used for gemini heading level 2.")
 298
 299 (defface elpher-gemini-heading3
 300   '((t :inherit bold :height 1.2))
 301   "Face used for gemini heading level 3.")
 302
 303 (defface elpher-gemini-preformatted
 304   '((t :inherit fixed-pitch))
 305   "Face used for pre-formatted gemini text blocks.")
 306
 307 (defface elpher-gemini-quoted
 308   '((t :inherit font-lock-doc-face))
 309   "Face used for gemini quoted texts.")
 310
 311 ;;; Model
 312 ;;
 313
 314 ;; Address
 315
 316 ;; An elpher "address" object is either a url object or a symbol.
 317 ;; Symbol addresses are "special", corresponding to pages generated
 318 ;; dynamically for and by elpher.  All others represent pages which
 319 ;; rely on content retrieved over the network.
 320
 321 (defun elpher-address-from-url (url-string)
 322   "Create a ADDRESS object corresponding to the given URL-STRING."
 323   (let ((data (match-data))) ; Prevent parsing clobbering match data
 324     (unwind-protect
 325         (let ((url (url-generic-parse-url url-string)))
 326           (unless (and (not (url-fullness url)) (url-type url))
 327             (setf (url-fullness url) t)
 328             (unless (url-type url)
 329               (setf (url-type url) elpher-default-url-type))
 330             (unless (url-host url)
 331               (let ((p (split-string (url-filename url) "/" nil nil)))
 332                 (setf (url-host url) (car p))
 333                 (setf (url-filename url)
 334                       (if (cdr p)
 335                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 336                         ""))))
 337             (when (or (equal "gopher" (url-type url))
 338                       (equal "gophers" (url-type url)))
 339               ;; Gopher defaults
 340               (when (or (equal (url-filename url) "")
 341                         (equal (url-filename url) "/"))
 342                 (setf (url-filename url) "/1")))
 343             (when (equal "gemini" (url-type url))
 344               ;; Gemini defaults
 345               (if (equal (url-filename url) "")
 346                   (setf (url-filename url) "/"))))
 347           (elpher-remove-redundant-ports url))
 348       (set-match-data data))))
 349
 350 (defun elpher-remove-redundant-ports (address)
 351   "Remove redundant port specifiers from ADDRESS.
 352 Here 'redundant' means that the specified port matches the default
 353 for that protocol, eg 70 for gopher."
 354   (if (and (not (elpher-address-special-p address))
 355            (eq (url-portspec address) ; (url-port) is too slow!
 356                (pcase (url-type address)
 357                  ("gemini" 1965)
 358                  ((or "gopher" "gophers") 70)
 359                  ("finger" 79)
 360                  (_ -1))))
 361       (setf (url-portspec address) nil))
 362   address)
 363
 364 (defun elpher-make-gopher-address (type selector host port &optional tls)
 365   "Create an ADDRESS object using gopher directory record attributes.
 366 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 367 If the optional attribute TLS is non-nil, the address will be marked as
 368 requiring gopher-over-TLS."
 369   (cond
 370    ((equal type ?i) nil)
 371    ((and (equal type ?h)
 372          (string-prefix-p "URL:" selector))
 373     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 374    ((equal type ?8)
 375     (elpher-address-from-url
 376      (concat "telnet"
 377              "://" host
 378              ":" (number-to-string port))))
 379    (t
 380     (elpher-address-from-url
 381      (concat "gopher" (if tls "s" "")
 382              "://" host
 383              ":" (number-to-string port)
 384              "/" (string type)
 385              selector)))))
 386
 387 (defun elpher-make-special-address (type)
 388   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 389   (elpher-address-from-url (concat "about:" (symbol-name type))))
 390
 391 (defun elpher-address-to-url (address)
 392   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 393   (url-encode-url (url-recreate-url address)))
 394
 395 (defun elpher-address-type (address)
 396   "Retrieve type of ADDRESS object.
 397 This is used to determine how to retrieve and render the document the
 398 address refers to, via the table `elpher-type-map'."
 399   (let ((protocol (url-type address)))
 400     (pcase (url-type address)
 401       ("about"
 402        (list 'special (intern (url-filename address))))
 403       ((or "gopher" "gophers")
 404        (list 'gopher
 405              (if (member (url-filename address) '("" "/"))
 406                  ?1
 407                (string-to-char (substring (url-filename address) 1)))))
 408       ("gemini" 'gemini)
 409       ("telnet" 'telnet)
 410       ("finger" 'finger)
 411       ("file" 'file)
 412       (_ 'other-url))))
 413
 414 (defun elpher-address-special-p (address)
 415   "Return non-nil if ADDRESS is a  special address."
 416   (pcase (elpher-address-type address) (`(special ,subtype) t)))
 417
 418 (defun elpher-address-protocol (address)
 419   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 420   (if (elpher-address-special-p address)
 421       nil
 422     (url-type address)))
 423
 424 (defun elpher-address-filename (address)
 425   "Retrieve the filename component of ADDRESS.
 426 For gopher addresses this is a combination of the selector type and selector."
 427   (if (symbolp address)
 428       nil
 429     (url-unhex-string (url-filename address))))
 430
 431 (defun elpher-address-host (address)
 432   "Retrieve host from ADDRESS object."
 433   (url-host address))
 434
 435 (defun elpher-address-user (address)
 436   "Retrieve user from ADDRESS object."
 437   (url-user address))
 438
 439 (defun elpher-address-port (address)
 440   "Retrieve port from ADDRESS object.
 441 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 442   (if (elpher-address-special-p address)
 443       0
 444     (url-port address)))
 445
 446 (defun elpher-address-gopher-p (address)
 447   "Return non-nill if ADDRESS object is a gopher address."
 448   (eq 'gopher (elpher-address-type address)))
 449
 450 (defun elpher-gopher-address-selector (address)
 451   "Retrieve gopher selector from ADDRESS object."
 452   (if (member (url-filename address) '("" "/"))
 453       ""
 454     (url-unhex-string (substring (url-filename address) 2))))
 455
 456
 457 ;; Cache
 458
 459 (defvar elpher-content-cache (make-hash-table :test 'equal))
 460 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 461
 462 (defun elpher-get-cached-content (address)
 463   "Retrieve the cached content for ADDRESS, or nil if none exists."
 464   (gethash address elpher-content-cache))
 465
 466 (defun elpher-cache-content (address content)
 467   "Set the content cache for ADDRESS to CONTENT."
 468   (puthash address content elpher-content-cache))
 469
 470 (defun elpher-get-cached-pos (address)
 471   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 472   (gethash address elpher-pos-cache))
 473
 474 (defun elpher-cache-pos (address pos)
 475   "Set the cursor position cache for ADDRESS to POS."
 476   (puthash address pos elpher-pos-cache))
 477
 478
 479 ;; Page
 480
 481 (defun elpher-make-page (display-string address)
 482   "Create a page with DISPLAY-STRING and ADDRESS."
 483   (list display-string address))
 484
 485 (defun elpher-make-start-page ()
 486   "Create the welcome page."
 487   (elpher-make-page "Start Page"
 488                     (elpher-address-from-url elpher-start-page)))
 489
 490 (defun elpher-page-display-string (page)
 491   "Retrieve the display string corresponding to PAGE."
 492   (elt page 0))
 493
 494 (defun elpher-page-address (page)
 495   "Retrieve the address corresponding to PAGE."
 496   (elt page 1))
 497
 498 (defun elpher-page-set-address (page new-address)
 499   "Set the address corresponding to PAGE to NEW-ADDRESS."
 500   (setcar (cdr page) new-address))
 501
 502 (defvar elpher-current-page nil
 503   "The current page for this Elpher buffer.")
 504
 505 (defvar elpher-history nil
 506   "The local history stack for this Elpher buffer.
 507 This variable is used by `elpher-back' and
 508 `elpher-show-history'.")
 509
 510 (defvar elpher-visited-pages nil
 511   "The global history for all Elpher buffers.
 512 This variable is used by `elpher-show-visited-pages'.")
 513
 514 (defun elpher-visit-page (page &optional renderer no-history)
 515   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 516 Additionally, push PAGE onto the history stack and the list of
 517 previously-visited pages,unless NO-HISTORY is non-nil."
 518   (elpher-save-pos)
 519   (elpher-process-cleanup)
 520   (unless no-history
 521     (unless (equal (elpher-page-address elpher-current-page)
 522                    (elpher-page-address page))
 523       (push elpher-current-page elpher-history)
 524       (unless (or (elpher-address-special-p (elpher-page-address page))
 525                   (and elpher-visited-pages
 526                        (equal page (car elpher-visited-pages))))
 527         (push page elpher-visited-pages))))
 528   (setq-local elpher-current-page page)
 529   (let* ((address (elpher-page-address page))
 530          (type (elpher-address-type address))
 531          (type-record (cdr (assoc type elpher-type-map))))
 532     (if type-record
 533         (funcall (car type-record)
 534                  (if renderer
 535                      renderer
 536                    (cadr type-record)))
 537       (elpher-visit-previous-page)
 538       (pcase type
 539         (`(gopher ,type-char)
 540          (error "Unsupported gopher selector type '%c' for '%s'"
 541                 type-char (elpher-address-to-url address)))
 542         (other
 543          (error "Unsupported address type '%S' for '%s'"
 544                 other (elpher-address-to-url address)))))))
 545
 546 (defun elpher-visit-previous-page ()
 547   "Visit the previous page in the history."
 548   (let ((previous-page (pop elpher-history)))
 549     (if previous-page
 550         (elpher-visit-page previous-page nil t)
 551       (error "No previous page"))))
 552
 553 (defun elpher-reload-current-page ()
 554   "Reload the current page, discarding any existing cached content."
 555   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 556   (elpher-visit-page elpher-current-page))
 557
 558 (defun elpher-save-pos ()
 559   "Save the current position of point to the current page."
 560   (when elpher-current-page
 561     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 562
 563 (defun elpher-restore-pos ()
 564   "Restore the position of point to that cached in the current page."
 565   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 566     (if pos
 567         (goto-char pos)
 568       (goto-char (point-min)))))
 569
 570
 571 ;;; Buffer preparation
 572 ;;
 573
 574 (defvar elpher-buffer-name "*elpher*"
 575   "The default name of the Elpher buffer.")
 576
 577 (defun elpher-update-header ()
 578   "If `elpher-use-header' is true, display current page info in window header."
 579   (if elpher-use-header
 580       (let* ((display-string (elpher-page-display-string elpher-current-page))
 581              (address (elpher-page-address elpher-current-page))
 582              (tls-string (if (and (not (elpher-address-special-p address))
 583                                   (member (elpher-address-protocol address)
 584                                           '("gophers" "gemini")))
 585                              " [TLS encryption]"
 586                            ""))
 587              (header (concat display-string
 588                              (propertize tls-string 'face 'bold))))
 589         (setq header-line-format header))))
 590
 591 (defmacro elpher-with-clean-buffer (&rest args)
 592   "Evaluate ARGS with a clean *elpher* buffer as current."
 593   (declare (debug (body))) ;; Allow edebug to step through body
 594   `(with-current-buffer elpher-buffer-name
 595      (unless (eq major-mode 'elpher-mode)
 596        ;; avoid resetting buffer-local variables
 597        (elpher-mode))
 598      (let ((inhibit-read-only t)
 599            (ansi-color-context nil)) ;; clean ansi interpreter state
 600        (setq-local network-security-level
 601                    (default-value 'network-security-level))
 602        (erase-buffer)
 603        (elpher-update-header)
 604        ,@args)))
 605
 606 (defun elpher-buffer-message (string &optional line)
 607   "Replace first line in elpher buffer with STRING.
 608 If LINE is non-nil, replace that line instead."
 609   (with-current-buffer elpher-buffer-name
 610     (let ((inhibit-read-only t))
 611       (goto-char (point-min))
 612       (if line
 613           (forward-line line))
 614       (let ((data (match-data)))
 615         (unwind-protect
 616             (progn
 617               (re-search-forward "^.*$")
 618               (replace-match string))
 619           (set-match-data data))))))
 620
 621
 622 ;;; Text Processing
 623 ;;
 624
 625 (defvar elpher-user-coding-system nil
 626   "User-specified coding system to use for decoding text responses.")
 627
 628 (defun elpher-decode (string)
 629   "Decode STRING using autodetected or user-specified coding system."
 630   (decode-coding-string string
 631                         (if elpher-user-coding-system
 632                             elpher-user-coding-system
 633                           (detect-coding-string string t))))
 634
 635 (defun elpher-preprocess-text-response (string)
 636   "Preprocess text selector response contained in STRING.
 637 This involes decoding the character representation, and clearing
 638 away CRs and any terminating period."
 639   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 640                                            (replace-regexp-in-string "\r" "" string))))
 641
 642 ;;; Buttonify urls
 643
 644 (defconst elpher-url-regex
 645   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 646   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 647
 648 (defun elpher-buttonify-urls (string)
 649   "Turn substrings which look like urls in STRING into clickable buttons."
 650   (with-temp-buffer
 651     (insert string)
 652     (goto-char (point-min))
 653     (while (re-search-forward elpher-url-regex nil t)
 654       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 655                                     (elpher-address-from-url (match-string 0)))))
 656         (make-text-button (match-beginning 0)
 657                           (match-end 0)
 658                           'elpher-page  page
 659                           'action #'elpher-click-link
 660                           'follow-link t
 661                           'help-echo #'elpher--page-button-help
 662                           'face 'button)))
 663     (buffer-string)))
 664
 665 ;;; ANSI colors or XTerm colors (application and filtering)
 666
 667 (or (require 'xterm-color nil t)
 668     (require 'ansi-color))
 669
 670 (defalias 'elpher-color-filter-apply
 671   (if (fboundp 'xterm-color-filter)
 672       (lambda (s)
 673         (let ((_xterm-color-render nil))
 674           (xterm-color-filter s)))
 675     #'ansi-color-filter-apply)
 676   "A function to filter out ANSI escape sequences.")
 677
 678 (defalias 'elpher-color-apply
 679   (if (fboundp 'xterm-color-filter)
 680       #'xterm-color-filter
 681     #'ansi-color-apply)
 682   "A function to apply ANSI escape sequences.")
 683
 684 ;;; Processing text for display
 685
 686 (defun elpher-process-text-for-display (string)
 687   "Perform any desired processing of STRING prior to display as text.
 688 Currently includes buttonifying URLs and processing ANSI escape codes."
 689   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 690                              (elpher-color-filter-apply string)
 691                            (elpher-color-apply string))))
 692
 693
 694 ;;; Network error reporting
 695 ;;
 696
 697 (defun elpher-network-error (address error)
 698   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 699 ERROR can be either an error object or a string."
 700   (elpher-with-clean-buffer
 701    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 702            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 703            (if (stringp error) error (error-message-string error)) "\n"
 704            (propertize "\n----------------\n\n" 'face 'error)
 705            "Press 'u' to return to the previous page.")))
 706
 707
 708 ;;; General network communication
 709 ;;
 710
 711 (defvar elpher-network-timer nil
 712   "Timer used for network connections.")
 713
 714 (defvar elpher-use-tls nil
 715   "If non-nil, use TLS to communicate with gopher servers.")
 716
 717 (defvar elpher-client-certificate nil
 718   "If non-nil, contains client certificate details to use for TLS connections.")
 719
 720 (defun elpher-process-cleanup ()
 721   "Immediately shut down any extant elpher process and timers."
 722   (let ((p (get-process "elpher-process")))
 723     (if p (delete-process p)))
 724   (if (timerp elpher-network-timer)
 725       (cancel-timer elpher-network-timer)))
 726
 727 (defun elpher-make-network-timer (thunk)
 728   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 729 This is just a wraper around `run-at-time' which additionally sets the
 730 buffer-local variable `elpher-network-timer' to allow
 731 `elpher-process-cleanup' to also clear the timer."
 732   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 733     (setq-local elpher-network-timer timer)
 734     timer))
 735
 736 (defun elpher-get-host-response (address default-port query-string response-processor
 737                                          &optional use-tls force-ipv4)
 738   "Generic function for retrieving data from ADDRESS.
 739
 740 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 741 QUERY-STRING is a string sent to the host specified by ADDRESS to
 742 illicet a response.  This response is passed as an argument to the
 743 function RESPONSE-PROCESSOR.
 744
 745 If non-nil, USE-TLS specifies that the connection is to be made over
 746 TLS.  If set to gemini, the certificate verification will be disabled
 747 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 748
 749 If non-nil, FORCE-IPV4 causes the network connection to be made over
 750 ipv4 only.  (The default behaviour when this is not set depends on
 751 the host operating system and the local network capabilities.)"
 752   (if (and use-tls (not (gnutls-available-p)))
 753       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 754     (unless (< (elpher-address-port address) 65536)
 755       (error "Cannot establish network connection: port number > 65536"))
 756     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 757       (setq-local network-security-level 'low)
 758       (setq-local gnutls-verify-error nil))
 759     (condition-case nil
 760         (let* ((kill-buffer-query-functions nil)
 761                (port (elpher-address-port address))
 762                (host (elpher-address-host address))
 763                (service (if (> port 0) port default-port))
 764                (response-string-parts nil)
 765                (bytes-received 0)
 766                (hkbytes-received 0)
 767                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 768                (gnutls-params (list :type 'gnutls-x509pki
 769                                     :hostname host
 770                                     :keylist
 771                                     (elpher-get-current-keylist address)))
 772                (timer (elpher-make-network-timer
 773                                    (lambda ()
 774                                      (elpher-process-cleanup)
 775                                      (cond
 776                                         ; Try again with IPv4
 777                                       ((not (or force-ipv4 socks))
 778                                        (message "Connection timed out.  Retrying with IPv4.")
 779                                        (elpher-get-host-response address default-port
 780                                                                  query-string
 781                                                                  response-processor
 782                                                                  use-tls t))
 783                                       ((and use-tls
 784                                             (not (eq use-tls 'gemini))
 785                                             (or elpher-auto-disengage-TLS
 786                                                 (y-or-n-p
 787                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 788                                        (setq elpher-use-tls nil)
 789                                        (elpher-get-host-response address default-port
 790                                                                  query-string
 791                                                                  response-processor
 792                                                                  nil force-ipv4))
 793                                       (t
 794                                        (elpher-network-error address "Connection time-out."))))))
 795                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 796                        (make-network-process :name "elpher-process"
 797                                              :host host
 798                                              :family (and force-ipv4 'ipv4)
 799                                              :service service
 800                                              :buffer nil
 801                                              :nowait t
 802                                              :tls-parameters
 803                                              (and use-tls
 804                                                   (cons 'gnutls-x509pki
 805                                                         (apply #'gnutls-boot-parameters
 806                                                                gnutls-params)))))))
 807           (setq elpher-network-timer timer)
 808           (set-process-coding-system proc 'binary 'binary)
 809           (set-process-query-on-exit-flag proc nil)
 810           (elpher-buffer-message (concat "Connecting to " host "..."
 811                                          " (press 'u' to abort)"))
 812           (set-process-filter proc
 813                               (lambda (_proc string)
 814                                 (when timer
 815                                   (cancel-timer timer)
 816                                   (setq timer nil))
 817                                 (setq bytes-received (+ bytes-received (length string)))
 818                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 819                                   (when (> new-hkbytes-received hkbytes-received)
 820                                     (setq hkbytes-received new-hkbytes-received)
 821                                     (elpher-buffer-message
 822                                      (concat "("
 823                                              (number-to-string (/ hkbytes-received 10.0))
 824                                              " MB read)")
 825                                      1)))
 826                                 (setq response-string-parts
 827                                       (cons string response-string-parts))))
 828           (set-process-sentinel proc
 829                                 (lambda (proc event)
 830                                   (when timer
 831                                     (cancel-timer timer))
 832                                   (condition-case the-error
 833                                       (cond
 834                                        ((string-prefix-p "open" event)    ; request URL
 835                                         (elpher-buffer-message
 836                                          (concat "Connected to " host ". Receiving data..."
 837                                                  " (press 'u' to abort)"))
 838                                         (let ((inhibit-eol-conversion t))
 839                                           (process-send-string proc query-string)))
 840                                        ((string-prefix-p "deleted" event)) ; do nothing
 841                                        ((and (not response-string-parts)
 842                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 843                                         ; Try again with IPv4
 844                                         (message "Connection failed. Retrying with IPv4.")
 845                                         (elpher-get-host-response address default-port
 846                                                                   query-string
 847                                                                   response-processor
 848                                                                   use-tls t))
 849                                        (response-string-parts
 850                                         (elpher-with-clean-buffer
 851                                          (insert "Data received.  Rendering..."))
 852                                         (funcall response-processor
 853                                                  (apply #'concat (reverse response-string-parts)))
 854                                         (elpher-restore-pos))
 855                                        (t
 856                                         (error "No response from server")))
 857                                     (error
 858                                      (elpher-network-error address the-error)))))
 859           (when socks
 860             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 861             (funcall (process-sentinel proc) proc "open\n")))
 862       (error
 863        (elpher-process-cleanup)
 864        (error "Error initiating connection to server")))))
 865
 866
 867 ;;; Client-side TLS Certificate Management
 868 ;;
 869
 870 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 871   "Generate a key and a self-signed client TLS certificate using openssl.
 872
 873 The Common Name field of the certificate is set to COMMON-NAME.  The
 874 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 875 the key and certificate files to write.
 876
 877 If TEMPORARY is non-nil, the certificate will be given an exporation
 878 period of one day, and the key and certificate files will be deleted
 879 when the certificate is no longer needed for the current session.
 880
 881 Otherwise, the certificate will be given a 100 year expiration period
 882 and the files will not be deleted.
 883
 884 The function returns a list containing the current host name, the
 885 temporary flag, and the key and cert file names in the form required
 886 by `gnutls-boot-parameters`."
 887   (let ((exp-key-file (expand-file-name key-file))
 888         (exp-cert-file (expand-file-name cert-file)))
 889     (condition-case nil
 890         (progn
 891           (call-process elpher-openssl-command nil nil nil
 892                         "req" "-x509" "-newkey" "rsa:2048"
 893                         "-days" (if temporary "1" "36500")
 894                         "-nodes"
 895                         "-subj" (concat "/CN=" common-name)
 896                         "-keyout" exp-key-file
 897                         "-out" exp-cert-file)
 898           (list (elpher-address-host (elpher-page-address elpher-current-page))
 899                 temporary exp-key-file exp-cert-file))
 900       (error
 901        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 902        (error "Program 'openssl', required for certificate generation, not found")))))
 903
 904 (defun elpher-generate-throwaway-certificate ()
 905   "Generate and return details of a throwaway certificate.
 906 The key and certificate files will be deleted when they are no
 907 longer needed for this session."
 908   (let* ((file-base (make-temp-name "elpher"))
 909          (key-file (concat temporary-file-directory file-base ".key"))
 910          (cert-file (concat temporary-file-directory file-base ".crt")))
 911     (elpher-generate-certificate file-base key-file cert-file t)))
 912
 913 (defun elpher-generate-persistent-certificate (file-base common-name)
 914   "Generate and return details of a persistent certificate.
 915 The argument FILE-BASE is used as the base for the key and certificate
 916 files, while COMMON-NAME specifies the common name field of the
 917 certificate.
 918
 919 The key and certificate files are written to in `elpher-certificate-directory'."
 920   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 921          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 922     (elpher-generate-certificate common-name key-file cert-file)))
 923
 924 (defun elpher-get-existing-certificate (file-base)
 925   "Return a certificate object corresponding to an existing certificate.
 926 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 927 the directory `elpher-certificate-directory'."
 928   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 929          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 930     (list (elpher-address-host (elpher-page-address elpher-current-page))
 931           nil
 932           (expand-file-name key-file)
 933           (expand-file-name cert-file))))
 934
 935 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 936   "Install a key+certificate file pair in `elpher-certificate-directory'.
 937 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 938 certificate files to install.  The argument FILE-BASE is used as the
 939 base for the installed key and certificate files."
 940   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 941          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 942     (if (or (file-exists-p key-file)
 943             (file-exists-p cert-file))
 944         (error "A certificate with base name %s is already installed" file-base))
 945     (copy-file key-file-src key-file)
 946     (copy-file cert-file-src cert-file)
 947     (list (elpher-address-host (elpher-page-address elpher-current-page))
 948           nil
 949           (expand-file-name key-file)
 950           (expand-file-name cert-file))))
 951
 952 (defun elpher-list-existing-certificates ()
 953   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 954   (unless (file-directory-p elpher-certificate-directory)
 955     (make-directory elpher-certificate-directory))
 956   (mapcar
 957    (lambda (file)
 958      (file-name-sans-extension file))
 959    (directory-files elpher-certificate-directory nil "\\.key$")))
 960
 961 (defun elpher-forget-current-certificate ()
 962   "Causes any current certificate to be forgotten.)
 963 In the case of throwaway certificates, the key and certificate files
 964 are also deleted."
 965   (interactive)
 966   (when elpher-client-certificate
 967     (unless (and (called-interactively-p 'any)
 968                  (not (y-or-n-p (concat "Really forget client certificate? "
 969                                         "(Throwaway certificates will be deleted.)"))))
 970       (when (cadr elpher-client-certificate)
 971         (delete-file (elt elpher-client-certificate 2))
 972         (delete-file (elt elpher-client-certificate 3)))
 973       (setq elpher-client-certificate nil)
 974       (if (called-interactively-p 'any)
 975           (message "Client certificate forgotten.")))))
 976
 977 (defun elpher-get-current-keylist (address)
 978   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 979
 980 This is obtained from the client certificate described by
 981 `elpher-current-certificate', if one is available and the host for
 982 that certificate matches the host in ADDRESS.
 983
 984 If `elpher-current-certificate' is non-nil, and its host name doesn't
 985 match that of ADDRESS, the certificate is forgotten."
 986   (if elpher-client-certificate
 987       (if (string= (car elpher-client-certificate)
 988                    (elpher-address-host address))
 989           (list (cddr elpher-client-certificate))
 990         (elpher-forget-current-certificate)
 991         (message "Disabling client certificate for new host")
 992         nil)
 993     nil))
 994
 995
 996 ;;; Gopher selector retrieval
 997 ;;
 998
 999 (defun elpher-get-gopher-response (address renderer)
1000   "Get response string from gopher server at ADDRESS and render using RENDERER."
1001   (elpher-get-host-response address 70
1002                             (concat (elpher-gopher-address-selector address) "\r\n")
1003                             renderer
1004                             (or (string= (elpher-address-protocol address) "gophers")
1005                                 elpher-use-tls)))
1006
1007 (defun elpher-get-gopher-page (renderer)
1008   "Getter function for gopher pages.
1009 The RENDERER procedure is used to display the contents of the page
1010 once they are retrieved from the gopher server."
1011   (let* ((address (elpher-page-address elpher-current-page))
1012          (content (elpher-get-cached-content address)))
1013     (if (and content (funcall renderer nil))
1014         (elpher-with-clean-buffer
1015          (insert content)
1016          (elpher-restore-pos))
1017       (elpher-with-clean-buffer
1018        (insert "LOADING... (use 'u' to cancel)\n"))
1019       (condition-case the-error
1020           (elpher-get-gopher-response address renderer)
1021         (error
1022          (elpher-network-error address the-error))))))
1023
1024 ;; Index rendering
1025
1026 (defun elpher-insert-index (string)
1027   "Insert the index corresponding to STRING into the current buffer."
1028   ;; Should be able to split directly on CRLF, but some non-conformant
1029   ;; LF-only servers sadly exist, hence the following.
1030   (let ((str-processed (elpher-preprocess-text-response string)))
1031     (dolist (line (split-string str-processed "\n"))
1032       (ignore-errors
1033         (unless (= (length line) 0)
1034           (let* ((type (elt line 0))
1035                  (fields (split-string (substring line 1) "\t"))
1036                  (display-string (elt fields 0))
1037                  (selector (elt fields 1))
1038                  (host (elt fields 2))
1039                  (port (if (elt fields 3)
1040                            (string-to-number (elt fields 3))
1041                          nil))
1042                  (address (elpher-make-gopher-address type selector host port)))
1043             (elpher-insert-index-record display-string address)))))))
1044
1045 (defun elpher-insert-margin (&optional type-name)
1046   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1047   (if type-name
1048       (progn
1049         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1050                         (concat
1051                          (propertize "[" 'face 'elpher-margin-brackets)
1052                          (propertize type-name 'face 'elpher-margin-key)
1053                          (propertize "]" 'face 'elpher-margin-brackets))))
1054         (insert " "))
1055     (insert (make-string elpher-margin-width ?\s))))
1056
1057 (defun elpher--page-button-help (_window buffer pos)
1058   "Function called by Emacs to generate mouse-over text.
1059 The arguments specify the BUFFER and the POS within the buffer of the item
1060 for which help is required.  The function returns the help to be
1061 displayed.  The _WINDOW argument is currently unused."
1062   (with-current-buffer buffer
1063     (let ((button (button-at pos)))
1064       (when button
1065         (let* ((page (button-get button 'elpher-page))
1066                (address (elpher-page-address page)))
1067           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1068                                                 address
1069                                               (elpher-address-to-url address))))))))
1070
1071 (defun elpher-insert-index-record (display-string &optional address)
1072   "Function to insert an index record into the current buffer.
1073 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1074 If ADDRESS is not supplied or nil the record is rendered as an
1075 'information' line."
1076   (let* ((type (if address (elpher-address-type address) nil))
1077          (type-map-entry (cdr (assoc type elpher-type-map))))
1078     (if type-map-entry
1079         (let* ((margin-code (elt type-map-entry 2))
1080                (face (elt type-map-entry 3))
1081                (filtered-display-string (elpher-color-filter-apply display-string))
1082                (page (elpher-make-page filtered-display-string address)))
1083           (elpher-insert-margin margin-code)
1084           (insert-text-button filtered-display-string
1085                               'face face
1086                               'elpher-page page
1087                               'action #'elpher-click-link
1088                               'follow-link t
1089                               'help-echo #'elpher--page-button-help))
1090       (pcase type
1091         ('nil ;; Information
1092          (elpher-insert-margin)
1093          (let ((propertized-display-string
1094                 (propertize display-string 'face 'elpher-info)))
1095            (insert (elpher-process-text-for-display propertized-display-string))))
1096         (`(gopher ,selector-type) ;; Unknown
1097          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1098          (insert (propertize display-string
1099                              'face 'elpher-unknown)))))
1100     (insert "\n")))
1101
1102 (defun elpher-click-link (button)
1103   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1104   (let ((page (button-get button 'elpher-page)))
1105     (elpher-visit-page page)))
1106
1107 (defun elpher-render-index (data &optional _mime-type-string)
1108   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1109   (elpher-with-clean-buffer
1110    (if (not data)
1111        t
1112      (elpher-insert-index data)
1113      (elpher-cache-content (elpher-page-address elpher-current-page)
1114                            (buffer-string)))))
1115
1116 ;; Text rendering
1117
1118 (defun elpher-render-text (data &optional _mime-type-string)
1119   "Render DATA as text.  MIME-TYPE-STRING is unused."
1120   (elpher-with-clean-buffer
1121    (if (not data)
1122        t
1123      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1124      (elpher-cache-content
1125       (elpher-page-address elpher-current-page)
1126       (buffer-string)))))
1127
1128 ;; Image retrieval
1129
1130 (defun elpher-render-image (data &optional _mime-type-string)
1131   "Display DATA as image.  MIME-TYPE-STRING is unused."
1132   (if (not data)
1133       nil
1134     (if (display-images-p)
1135         (let* ((image (create-image
1136                        data
1137                        nil t))
1138                (window (get-buffer-window elpher-buffer-name)))
1139           (when window
1140             (setf (image-property image :max-width) (window-pixel-width window))
1141             (setf (image-property image :max-height) (window-pixel-height window)))
1142           (elpher-with-clean-buffer
1143            (insert-image image)
1144            (elpher-restore-pos)))
1145       (elpher-render-download data))))
1146
1147 ;; Search retrieval and rendering
1148
1149 (defun elpher-get-gopher-query-page (renderer)
1150   "Getter for gopher addresses requiring input.
1151 The response is rendered using the rendering function RENDERER."
1152   (let* ((address (elpher-page-address elpher-current-page))
1153          (content (elpher-get-cached-content address))
1154          (aborted t))
1155     (if (and content (funcall renderer nil))
1156         (elpher-with-clean-buffer
1157          (insert content)
1158          (elpher-restore-pos)
1159          (message "Displaying cached search results.  Reload to perform a new search."))
1160       (unwind-protect
1161           (let* ((query-string (read-string "Query: "))
1162                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1163                  (search-address (elpher-make-gopher-address ?1
1164                                                              query-selector
1165                                                              (elpher-address-host address)
1166                                                              (elpher-address-port address)
1167                                                              (equal (elpher-address-type address) "gophers"))))
1168             (setq aborted nil)
1169
1170             (elpher-with-clean-buffer
1171              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1172             (elpher-get-gopher-response search-address renderer))
1173         (if aborted
1174             (elpher-visit-previous-page))))))
1175
1176 ;; Raw server response rendering
1177
1178 (defun elpher-render-raw (data &optional mime-type-string)
1179   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1180   (if (not data)
1181       nil
1182     (elpher-with-clean-buffer
1183      (when mime-type-string
1184        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1185      (insert data)
1186      (goto-char (point-min)))
1187     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1188
1189 ;; File save "rendering"
1190
1191 (defun elpher-render-download (data &optional _mime-type-string)
1192   "Save DATA to file.  MIME-TYPE-STRING is unused."
1193   (if (not data)
1194       nil
1195     (let* ((address (elpher-page-address elpher-current-page))
1196            (selector (if (elpher-address-gopher-p address)
1197                          (elpher-gopher-address-selector address)
1198                        (elpher-address-filename address))))
1199       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1200       (let* ((filename-proposal (file-name-nondirectory selector))
1201              (filename (read-file-name "Download complete. Save file as: "
1202                                        nil nil nil
1203                                        (if (> (length filename-proposal) 0)
1204                                            filename-proposal
1205                                          "download.file"))))
1206         (let ((coding-system-for-write 'binary))
1207           (with-temp-file filename
1208             (insert data)))
1209         (message (format "Saved to file %s." filename))))))
1210
1211 ;; HTML rendering
1212
1213 (defun elpher-render-html (data &optional _mime-type-string)
1214   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1215   (elpher-with-clean-buffer
1216    (if (not data)
1217        t
1218      (let ((dom (with-temp-buffer
1219                   (insert data)
1220                   (libxml-parse-html-region (point-min) (point-max)))))
1221        (shr-insert-document dom)))))
1222
1223 ;; Gemini page retrieval
1224
1225 (defvar elpher-gemini-redirect-chain)
1226
1227 (defun elpher-get-gemini-response (address renderer)
1228   "Get response string from gemini server at ADDRESS and render using RENDERER."
1229   (elpher-get-host-response address 1965
1230                             (concat (elpher-address-to-url address) "\r\n")
1231                             (lambda (response-string)
1232                               (elpher-process-gemini-response response-string renderer))
1233                             'gemini))
1234
1235 (defun elpher-parse-gemini-response (response)
1236   "Parse the RESPONSE string and return a list of components.
1237 The list is of the form (code meta body).  A response of nil implies
1238 that the response was malformed."
1239   (let ((header-end-idx (string-match "\r\n" response)))
1240     (if header-end-idx
1241         (let ((header (string-trim (substring response 0 header-end-idx)))
1242               (body (substring response (+ header-end-idx 2))))
1243           (if (>= (length header) 2)
1244               (let ((code (substring header 0 2))
1245                     (meta (string-trim (substring header 2))))
1246                 (list code meta body))
1247             (error "Malformed response: No response status found in header %s" header)))
1248       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1249
1250 (defun elpher-process-gemini-response (response-string renderer)
1251   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1252   (let ((response-components (elpher-parse-gemini-response response-string)))
1253     (let ((response-code (elt response-components 0))
1254           (response-meta (elt response-components 1))
1255           (response-body (elt response-components 2)))
1256       (pcase (elt response-code 0)
1257         (?1 ; Input required
1258          (elpher-with-clean-buffer
1259           (insert "Gemini server is requesting input."))
1260          (let* ((query-string
1261                  (if (eq (elt response-code 1) ?1)
1262                      (read-passwd (concat response-meta ": "))
1263                    (read-string (concat response-meta ": "))))
1264                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1265                 (old-fname (url-filename query-address)))
1266            (setf (url-filename query-address)
1267                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1268            (elpher-get-gemini-response query-address renderer)))
1269         (?2 ; Normal response
1270          (funcall renderer response-body response-meta))
1271         (?3 ; Redirect
1272          (message "Following redirect to %s" response-meta)
1273          (if (>= (length elpher-gemini-redirect-chain) 5)
1274              (error "More than 5 consecutive redirects followed"))
1275          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1276            (if (member redirect-address elpher-gemini-redirect-chain)
1277                (error "Redirect loop detected"))
1278            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1279                (error "Server tried to automatically redirect to non-gemini URL: %s"
1280                       response-meta))
1281            (elpher-page-set-address elpher-current-page redirect-address)
1282            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1283            (elpher-get-gemini-response redirect-address renderer)))
1284         (?4 ; Temporary failure
1285          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1286                 response-code response-meta))
1287         (?5 ; Permanent failure
1288          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1289                 response-code response-meta))
1290         (?6 ; Client certificate required
1291          (elpher-with-clean-buffer
1292           (if elpher-client-certificate
1293               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1294             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1295           (auto-fill-mode 1)
1296           (elpher-gemini-insert-text response-meta))
1297          (let ((chosen-certificate (elpher-choose-client-certificate)))
1298            (unless chosen-certificate
1299              (error "Gemini server requires a client certificate and none was provided"))
1300            (setq elpher-client-certificate chosen-certificate))
1301          (elpher-with-clean-buffer)
1302          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1303         (_other
1304          (error "Gemini server response unknown: %s %s"
1305                 response-code response-meta))))))
1306
1307 (defun elpher--read-answer-polyfill (question answers)
1308   "Polyfill for `read-answer' in Emacs 26.1.
1309 QUESTION is a string containing a question, and ANSWERS
1310 is a list of possible answers."
1311     (completing-read question (mapcar 'identity answers)))
1312
1313 (if (fboundp 'read-answer)
1314     (defalias 'elpher-read-answer 'read-answer)
1315   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1316
1317 (defun elpher-choose-client-certificate ()
1318   "Prompt for a client certificate to use to establish a TLS connection."
1319   (let* ((read-answer-short t))
1320     (pcase (read-answer "What do you want to do? "
1321                         '(("throwaway" ?t
1322                            "generate and use throw-away certificate")
1323                           ("persistent" ?p
1324                            "generate new or use existing persistent certificate")
1325                           ("abort" ?a
1326                            "stop immediately")))
1327       ("throwaway"
1328        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1329       ("persistent"
1330        (let* ((existing-certificates (elpher-list-existing-certificates))
1331               (file-base (completing-read
1332                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1333                           existing-certificates)))
1334          (if (string-empty-p (string-trim file-base))
1335              nil
1336            (if (member file-base existing-certificates)
1337                (setq elpher-client-certificate
1338                      (elpher-get-existing-certificate file-base))
1339              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1340                                  '(("new" ?n
1341                                     "generate new certificate")
1342                                    ("install" ?i
1343                                     "install existing certificate")
1344                                    ("abort" ?a
1345                                     "stop immediately")))
1346                ("new"
1347                 (let ((common-name (read-string "Common Name field for new certificate: "
1348                                                 file-base)))
1349                   (message "New key and self-signed certificate written to %s"
1350                            elpher-certificate-directory)
1351                   (elpher-generate-persistent-certificate file-base common-name)))
1352                ("install"
1353                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1354                        (key-file (read-file-name "Key file: " nil nil t)))
1355                   (message "Key and certificate installed in %s for future use"
1356                            elpher-certificate-directory)
1357                   (elpher-install-and-use-existing-certificate key-file
1358                                                                cert-file
1359                                                                file-base)))
1360                ("abort" nil))))))
1361       ("abort" nil))))
1362
1363 (defun elpher-get-gemini-page (renderer)
1364   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1365   (let* ((address (elpher-page-address elpher-current-page))
1366          (content (elpher-get-cached-content address)))
1367     (condition-case the-error
1368         (if (and content (funcall renderer nil))
1369             (elpher-with-clean-buffer
1370              (insert content)
1371              (elpher-restore-pos))
1372           (elpher-with-clean-buffer
1373            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1374           (setq elpher-gemini-redirect-chain nil)
1375           (elpher-get-gemini-response address renderer))
1376       (error
1377        (elpher-network-error address the-error)))))
1378
1379 (defun elpher-render-gemini (body &optional mime-type-string)
1380   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1381   (if (not body)
1382       t
1383     (let* ((mime-type-string* (if (or (not mime-type-string)
1384                                       (string-empty-p mime-type-string))
1385                                   "text/gemini; charset=utf-8"
1386                                 mime-type-string))
1387            (mime-type-split (split-string mime-type-string* ";" t))
1388            (mime-type (string-trim (car mime-type-split)))
1389            (parameters (mapcar (lambda (s)
1390                                  (let ((key-val (split-string s "=")))
1391                                    (list (downcase (string-trim (car key-val)))
1392                                          (downcase (string-trim (cadr key-val))))))
1393                                (cdr mime-type-split))))
1394       (when (string-prefix-p "text/" mime-type)
1395         (setq body (decode-coding-string
1396                     body
1397                     (if (assoc "charset" parameters)
1398                         (intern (cadr (assoc "charset" parameters)))
1399                       'utf-8)))
1400         (setq body (replace-regexp-in-string "\r" "" body)))
1401       (pcase mime-type
1402         ((or "text/gemini" "")
1403          (elpher-render-gemini-map body parameters))
1404         ("text/html"
1405          (elpher-render-html body))
1406         ((pred (string-prefix-p "text/"))
1407          (elpher-render-gemini-plain-text body parameters))
1408         ((pred (string-prefix-p "image/"))
1409          (elpher-render-image body))
1410         (_other
1411          (elpher-render-download body))))))
1412
1413 (defun elpher-gemini-get-link-url (link-line)
1414   "Extract the url portion of LINK-LINE, a gemini map file link line.
1415 Returns nil in the event that the contents of the line following the
1416 => prefix are empty."
1417   (let ((l (split-string (substring link-line 2))))
1418     (if l
1419         (string-trim (elt l 0))
1420       nil)))
1421
1422 (defun elpher-gemini-get-link-display-string (link-line)
1423   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1424 Returns the url portion in the event that the display-string portion is empty."
1425   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1426          (idx (string-match "[ \t]" rest)))
1427     (string-trim (if idx
1428                      (substring rest (+ idx 1))
1429                    rest))))
1430
1431 (defun elpher-collapse-dot-sequences (filename)
1432   "Collapse dot sequences in FILENAME.
1433 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1434   (let* ((path (split-string filename "/"))
1435          (path-reversed-normalized
1436           (seq-reduce (lambda (a b)
1437                         (cond ((and a (equal b "..") (cdr a)))
1438                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1439                               ((equal b ".") a)
1440                               (t (cons b a))))
1441                       path nil)))
1442     (string-join (reverse path-reversed-normalized) "/")))
1443
1444 (defun elpher-address-from-gemini-url (url)
1445   "Extract address from URL with defaults as per gemini map files.
1446 While there's obviously some redundancy here between this function and
1447 `elpher-address-from-url', gemini map file URLs require enough special
1448 treatment that a separate function is warranted."
1449   (let ((address (url-generic-parse-url url))
1450         (current-address (elpher-page-address elpher-current-page)))
1451     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1452       (setf (url-fullness address) t)
1453       (if (url-host address) ;if there is an explicit host, filenames are absolute
1454           (if (string-empty-p (url-filename address))
1455               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1456         (setf (url-host address) (url-host current-address))
1457         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1458         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1459           (setf (url-filename address)
1460                 (concat (file-name-directory (url-filename current-address))
1461                         (url-filename address)))))
1462       (unless (url-type address)
1463         (setf (url-type address) "gemini"))
1464       (when (equal (url-type address) "gemini")
1465         (setf (url-filename address)
1466               (elpher-collapse-dot-sequences (url-filename address)))))
1467     (elpher-remove-redundant-ports address)))
1468
1469 (defun elpher-gemini-insert-link (link-line)
1470   "Insert link described by LINK-LINE into a text/gemini document."
1471   (let* ((url (elpher-gemini-get-link-url link-line))
1472          (display-string (elpher-gemini-get-link-display-string link-line))
1473          (address (elpher-address-from-gemini-url url))
1474          (type (if address (elpher-address-type address) nil))
1475          (type-map-entry (cdr (assoc type elpher-type-map))))
1476     (when display-string
1477       (insert elpher-gemini-link-string)
1478       (if type-map-entry
1479           (let* ((face (elt type-map-entry 3))
1480                  (filtered-display-string (elpher-color-filter-apply display-string))
1481                  (page (elpher-make-page filtered-display-string address)))
1482             (insert-text-button filtered-display-string
1483                                 'face face
1484                                 'elpher-page page
1485                                 'action #'elpher-click-link
1486                                 'follow-link t
1487                                 'help-echo #'elpher--page-button-help))
1488         (insert (propertize display-string 'face 'elpher-unknown)))
1489       (insert "\n"))))
1490
1491 (defvar elpher--gemini-page-headings nil
1492   "List of headings on the page.")
1493
1494 (defun elpher-gemini-insert-header (header-line)
1495   "Insert header described by HEADER-LINE into a text/gemini document.
1496 The gemini map file line describing the header is given
1497 by HEADER-LINE."
1498   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1499     (let* ((level (length (match-string 1 header-line)))
1500            (header (substring header-line (match-end 0)))
1501            (face (pcase level
1502                    (1 'elpher-gemini-heading1)
1503                    (2 'elpher-gemini-heading2)
1504                    (3 'elpher-gemini-heading3)
1505                    (_ 'default)))
1506            (fill-column (if (display-graphic-p)
1507                             (/ (* fill-column
1508                                   (font-get (font-spec :name (face-font 'default)) :size))
1509                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1510       (setq elpher--gemini-page-headings (cons (cons header (point))
1511                                                elpher--gemini-page-headings))
1512       (unless (display-graphic-p)
1513         (insert (make-string level ?#) " "))
1514       (insert (propertize header 'face face))
1515       (newline))))
1516
1517 (defun elpher-gemini-insert-text (text-line)
1518   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1519 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1520 width defined by `elpher-gemini-max-fill-width'."
1521   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1522   (let* ((line-prefix (match-string 2 text-line))
1523          (processed-text-line
1524           (if line-prefix
1525               (cond ((string-prefix-p "*" line-prefix)
1526                      (concat
1527                       (replace-regexp-in-string "\\*"
1528                                                 elpher-gemini-bullet-string
1529                                                 (match-string 0 text-line))
1530                       (substring text-line (match-end 0))))
1531                     ((string-prefix-p ">" line-prefix)
1532                      (propertize text-line 'face 'elpher-gemini-quoted))
1533                     (t text-line))
1534             text-line))
1535          (adaptive-fill-mode t)
1536          ;; fill-prefix is important for adaptive-fill-mode: without
1537          ;; it, multi-line list items are not indented correct
1538          (fill-prefix (if (match-string 2 text-line)
1539                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1540                         nil)))
1541     (insert (elpher-process-text-for-display processed-text-line))
1542     (newline)))
1543
1544 (defun elpher-render-gemini-map (data _parameters)
1545   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1546   (elpher-with-clean-buffer
1547    (setq elpher--gemini-page-headings nil)
1548    (let ((preformatted nil))
1549      (auto-fill-mode 1)
1550      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1551      (dolist (line (split-string data "\n"))
1552        (cond
1553         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1554         (preformatted (insert (elpher-process-text-for-display
1555                                (propertize line 'face 'elpher-gemini-preformatted))
1556                               "\n"))
1557         ((string-prefix-p "=>" line)
1558          (elpher-gemini-insert-link line))
1559         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1560         (t (elpher-gemini-insert-text line)))))
1561    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1562    (elpher-cache-content
1563     (elpher-page-address elpher-current-page)
1564     (buffer-string))))
1565
1566 (defun elpher-render-gemini-plain-text (data _parameters)
1567   "Render DATA as plain text file.  PARAMETERS is currently unused."
1568   (elpher-with-clean-buffer
1569    (insert (elpher-process-text-for-display data))
1570    (elpher-cache-content
1571     (elpher-page-address elpher-current-page)
1572     (buffer-string))))
1573
1574
1575 ;; Finger page connection
1576
1577 (defun elpher-get-finger-page (renderer)
1578   "Opens a finger connection to the current page address.
1579 The result is rendered using RENDERER."
1580   (let* ((address (elpher-page-address elpher-current-page))
1581          (content (elpher-get-cached-content address)))
1582     (if (and content (funcall renderer nil))
1583         (elpher-with-clean-buffer
1584          (insert content)
1585          (elpher-restore-pos))
1586       (elpher-with-clean-buffer
1587        (insert "LOADING... (use 'u' to cancel)\n"))
1588       (condition-case the-error
1589           (let* ((kill-buffer-query-functions nil)
1590                  (user (let ((filename (elpher-address-filename address)))
1591                          (if (> (length filename) 1)
1592                              (substring filename 1)
1593                            (elpher-address-user address)))))
1594             (elpher-get-host-response address 79
1595                                       (concat user "\r\n")
1596                                       renderer))
1597         (error
1598          (elpher-network-error address the-error))))))
1599
1600
1601 ;; Telnet page connection
1602
1603 (defun elpher-get-telnet-page (renderer)
1604   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1605   (when renderer
1606     (elpher-visit-previous-page)
1607     (error "Command not supported for telnet URLs"))
1608   (let* ((address (elpher-page-address elpher-current-page))
1609          (host (elpher-address-host address))
1610          (port (elpher-address-port address)))
1611     (elpher-visit-previous-page)
1612     (if (> port 0)
1613         (telnet host port)
1614       (telnet host))))
1615
1616
1617 ;; Other URL page opening
1618
1619 (defun elpher-get-other-url-page (renderer)
1620   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1621   (when renderer
1622     (elpher-visit-previous-page)
1623     (error "Command not supported for general URLs"))
1624   (let* ((address (elpher-page-address elpher-current-page))
1625          (url (elpher-address-to-url address)))
1626     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1627     (message "Opening URL...")
1628     (if elpher-open-urls-with-eww
1629         (browse-web url)
1630       (browse-url url))))
1631
1632 ;; File page
1633
1634 (defun elpher-get-file-page (renderer)
1635   "Getter which retrieves the contents of a local file and renders it using RENDERER."
1636   (let* ((address (elpher-page-address elpher-current-page))
1637          (filename (elpher-address-filename address)))
1638     (unless (file-exists-p filename)
1639       (elpher-visit-previous-page)
1640         (error "File not found"))
1641     (unless (file-readable-p filename)
1642       (elpher-visit-previous-page)
1643         (error "Could not read from file"))
1644     (funcall
1645      (if renderer
1646          renderer
1647        (pcase (file-name-extension filename)
1648          ((or  "gmi" "gemini") #'elpher-render-gemini-map)
1649          ((or "htm" "html") #'elpher-render-html)
1650          ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1651           #'elpher-render-image)
1652          ((or "txt" "") #'elpher-render-text)
1653          (t
1654           #'elpher-render-download)))
1655      (with-temp-buffer
1656        (let ((coding-system-for-read 'binary)
1657              (coding-system-for-write 'binary))
1658          (insert-file-contents-literally filename)
1659          (string-as-unibyte (buffer-string))))
1660      nil)))
1661
1662
1663 ;; Welcome page retrieval
1664
1665 (defun elpher-get-welcome-page (renderer)
1666   "Getter which displays the welcome page (RENDERER must be nil)."
1667   (when renderer
1668     (elpher-visit-previous-page)
1669     (error "Command not supported for welcome page"))
1670   (elpher-with-clean-buffer
1671    (insert "     --------------------------------------------\n"
1672            "           Elpher Gopher and Gemini Client       \n"
1673            "                   version " elpher-version "\n"
1674            "     --------------------------------------------\n"
1675            "\n"
1676            "Default bindings:\n"
1677            "\n"
1678            " - TAB/Shift-TAB: next/prev item on current page\n"
1679            " - RET/mouse-1: open item under cursor\n"
1680            " - m: select an item on current page by name (autocompletes)\n"
1681            " - u/mouse-3/U: return to previous page or to the start page\n"
1682            " - g: go to a particular address (gopher, gemini, finger)\n"
1683            " - o/O: open a different address selector or the root menu of the current server\n"
1684            " - d/D: download item under cursor or current page\n"
1685            " - i/I: info on item under cursor or current page\n"
1686            " - c/C: copy URL representation of item under cursor or current page\n"
1687            " - a/A: bookmark the item under cursor or current page\n"
1688            " - B: list all bookmarks\n"
1689            " - s/S: show current history stack or all previously visted pages\n"
1690            " - r: redraw current page (using cached contents if available)\n"
1691            " - R: reload current page (regenerates cache)\n"
1692            " - !: set character coding system for gopher (default is to autodetect)\n"
1693            " - T: toggle TLS gopher mode\n"
1694            " - F: forget/discard current TLS client certificate\n"
1695            " - .: display the raw server response for the current page\n"
1696            "\n"
1697            "Start your exploration of gopher space and gemini:\n")
1698    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1699                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1700    (elpher-insert-index-record "Project Gemini home page"
1701                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1702    (insert "\n"
1703            "Alternatively, select a search engine and enter some search terms:\n")
1704    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1705                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1706    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1707                                (elpher-address-from-url "gemini://geminispace.info/search"))
1708    (insert "\n"
1709            "Your bookmarks are stored in your ")
1710    (let ((help-string "RET,mouse-1: Open bookmark list"))
1711      (insert-text-button "bookmark list"
1712                          'face 'link
1713                          'action (lambda (_)
1714                                    (interactive)
1715                                    (call-interactively #'elpher-show-bookmarks))
1716                          'follow-link t
1717                          'help-echo help-string))
1718    (insert ".\n")
1719    (insert (propertize
1720             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1721             'face 'shadow))
1722    (insert "\n"
1723            "The gopher home of the Elpher project is here:\n")
1724    (elpher-insert-index-record "The Elpher Project Page"
1725                                (elpher-make-gopher-address ?1
1726                                                            "/projects/elpher/"
1727                                                            "thelambdalab.xyz"
1728                                                            70))
1729    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1730      (insert "\n"
1731              "The following info documentation is available:\n"
1732              "   - ")
1733      (insert-text-button "Elpher Manual"
1734                          'face 'link
1735                          'action (lambda (_)
1736                                    (interactive)
1737                                    (info "(elpher)"))
1738                          'follow-link t
1739                          'help-echo help-string)
1740      (insert "\n   - ")
1741      (insert-text-button "Changes introduced by the latest release"
1742                        'face 'link
1743                        'action (lambda (_)
1744                                  (interactive)
1745                                  (info "(elpher)News"))
1746                        'follow-link t
1747                        'help-echo help-string))
1748    (insert "\n")
1749    (insert (propertize
1750             (concat "(These documents should be available if you have installed Elpher \n"
1751                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1752             'face 'shadow))
1753    (elpher-restore-pos)))
1754
1755 ;; History page retrieval
1756
1757 (defun elpher-show-history ()
1758   "Show the current contents of elpher's history stack.
1759 Use \\[elpher-show-visited-pages] to see the entire history.
1760 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1761   (interactive)
1762   (elpher-visit-page
1763    (elpher-make-page "Current History Stack"
1764                      (elpher-make-special-address 'history))))
1765
1766 (defun elpher-show-visited-pages ()
1767   "Show the all the pages you've visited using Elpher.
1768 Use \\[elpher-show-history] to see just the current history stack.
1769 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1770   (interactive)
1771   (elpher-visit-page
1772    (elpher-make-page "Elpher Visted Pages"
1773                      (elpher-make-special-address 'visited-pages))))
1774
1775 (defun elpher-get-history-page (renderer)
1776   "Getter which displays the history page (RENDERER must be nil)."
1777   (when renderer
1778     (elpher-visit-previous-page)
1779     (error "Command not supported for history page"))
1780   (elpher-display-history-links elpher-history "Current history stack"))
1781
1782 (defun elpher-get-visited-pages-page (renderer)
1783   "Getter which displays the list of visited pages (RENDERER must be nil)."
1784   (when renderer
1785     (elpher-visit-previous-page)
1786     (error "Command not supported for history page"))
1787   (elpher-display-history-links
1788    (seq-filter (lambda (page)
1789                  (not (elpher-address-special-p (elpher-page-address page))))
1790                elpher-visited-pages)
1791    "All visited pages"))
1792
1793 (defun elpher-display-history-links (pages title)
1794   "Show all PAGES in an Elpher buffer with a given TITLE."
1795   (let* ((title-line (concat " ---- " title " ----"))
1796          (footer-line (make-string (length title-line) ?-)))
1797     (elpher-with-clean-buffer
1798      (insert title-line "\n\n")
1799      (if pages
1800          (dolist (page pages)
1801            (when page
1802              (let ((display-string (elpher-page-display-string page))
1803                    (address (elpher-page-address page)))
1804                (elpher-insert-index-record display-string address))))
1805        (insert "No history items found.\n"))
1806      (insert "\n " footer-line "\n"
1807              "Select an entry or press 'u' to return to the previous page.")
1808      (elpher-restore-pos))))
1809
1810
1811 ;;; Bookmarks
1812
1813 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1814 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1815 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1816 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1817
1818 (defvar elpher-bookmark-link nil
1819   "Prefer bookmarking a link or the current page.
1820 Bind this variable dynamically, or set it to t.
1821 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1822 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1823
1824 (defun elpher-bookmark-make-record ()
1825   "Return a bookmark record.
1826 If `elpher-bookmark-link' is non-nil and point is on a link button,
1827 return a bookmark record for that link.  Otherwise, return a bookmark
1828 record for the current elpher page."
1829   (let* ((button (and elpher-bookmark-link (button-at (point))))
1830          (page (if button
1831                    (button-get button 'elpher-page)
1832                  elpher-current-page))
1833          (address (elpher-page-address page))
1834          (url (elpher-address-to-url address))
1835          (display-string (elpher-page-display-string page))
1836          (pos (if button nil (point))))
1837     (if (elpher-address-special-p address)
1838         (error "Cannot bookmark %s" display-string)
1839       `(,display-string
1840         (defaults . (,display-string))
1841         (position . ,pos)
1842         (location . ,url)
1843         (handler . elpher-bookmark-jump)))))
1844
1845 ;;;###autoload
1846 (defun elpher-bookmark-jump (bookmark)
1847   "Handler used to open a bookmark using elpher.
1848 The argument BOOKMARK is a bookmark record passed to the function.
1849 This handler is responsible for loading the bookmark in some buffer,
1850 then making that buffer the current buffer.  It should not switch
1851 to the buffer."
1852   (let* ((url (cdr (assq 'location bookmark)))
1853          (cleaned-url (string-trim url))
1854          (address (elpher-address-from-url cleaned-url))
1855          (page (elpher-make-page cleaned-url address)))
1856     (elpher-with-clean-buffer
1857      (elpher-visit-page page))
1858     (set-buffer (get-buffer elpher-buffer-name))
1859     nil))
1860
1861 (defun elpher-bookmark-link ()
1862   "Bookmark the link at point.
1863 To bookmark the current page, use \\[elpher-bookmark-current]."
1864   (interactive)
1865   (let ((elpher-bookmark-link t))
1866     (bookmark-set-no-overwrite)))
1867
1868 (defun elpher-bookmark-current ()
1869   "Bookmark the current page.
1870 To bookmark the link at point use \\[elpher-bookmark-link]."
1871   (interactive)
1872   (call-interactively #'bookmark-set-no-overwrite))
1873
1874 (defun elpher-bookmark-import (file)
1875   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1876   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1877                               (file-readable-p elpher-bookmarks-file))
1878                          elpher-bookmarks-file
1879                        (read-file-name "Old Elpher bookmarks: "
1880                                        user-emacs-directory nil t
1881                                        "elpher-bookmarks"))))
1882   (dolist (bookmark (with-temp-buffer
1883                       (insert-file-contents file)
1884                       (read (current-buffer))))
1885     (let* ((display-string (car bookmark))
1886            (url (cadr bookmark))
1887            (record `(,display-string
1888                      (location . ,url)
1889                      (handler . elpher-bookmark-jump))))
1890       (bookmark-store display-string (cdr record) t)))
1891   (bookmark-save))
1892
1893 (defun elpher-get-bookmarks-page (renderer)
1894   "Getter which displays the history page (RENDERER must be nil)."
1895   (when renderer
1896     (elpher-visit-previous-page)
1897     (error "Command not supported for bookmarks page"))
1898   (elpher-with-clean-buffer
1899    (insert " ---- Elpher Bookmarks ---- \n\n")
1900    (bookmark-maybe-load-default-file)
1901    (dolist (bookmark (bookmark-maybe-sort-alist))
1902      (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1903        (let* ((name (car bookmark))
1904               (url (alist-get 'location (cdr bookmark)))
1905               (address (elpher-address-from-url url)))
1906          (elpher-insert-index-record name address))))
1907    (when (<= (line-number-at-pos) 3)
1908      (insert "No bookmarked pages found.\n"))
1909    (insert "\n --------------------------\n\n"
1910            "Select an entry or press 'u' to return to the previous page.\n\n"
1911            "Bookmarks can be renamed or deleted via the ")
1912    (insert-text-button "Emacs bookmark menu"
1913                        'action (lambda (_)
1914                                  (interactive)
1915                                  (call-interactively #'bookmark-bmenu-list))
1916                        'follow-link t
1917                        'help-echo "RET,mouse-1: open Emacs bookmark menu")
1918    (insert (substitute-command-keys
1919             ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1920    (elpher-restore-pos)))
1921
1922 (defun elpher-show-bookmarks ()
1923   "Display the current list of elpher bookmarks.
1924 This will also check for a legacy bookmark file and offer to import it."
1925   (interactive)
1926   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1927                                      elpher-bookmarks-file)
1928                                 (locate-user-emacs-file "elpher-bookmarks"))))
1929     (when (and (file-readable-p old-bookmarks-file)
1930                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1931                                  old-bookmarks-file
1932                                  "\" found. Import now?")))
1933       (elpher-bookmark-import old-bookmarks-file)
1934       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1935   (if elpher-use-emacs-bookmark-menu
1936       (call-interactively #'bookmark-bmenu-list)
1937     (elpher-visit-page
1938      (elpher-make-page "Elpher Bookmarks"
1939                        (elpher-make-special-address 'bookmarks)))))
1940
1941
1942 ;;; Integrations
1943 ;;
1944
1945 ;;; Org
1946
1947 (defun elpher-org-export-link (link description format protocol)
1948   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1949
1950 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1951 of gemini, gopher or finger."
1952   (let* ((url (if (equal protocol "elpher")
1953                   (string-remove-prefix "elpher:" link)
1954                 (format "%s:%s" protocol link)))
1955          (desc (or description url)))
1956     (pcase format
1957       (`gemini (format "=> %s %s" url desc))
1958       (`html (format "<a href=\"%s\">%s</a>" url desc))
1959       (`latex (format "\\href{%s}{%s}" url desc))
1960       (_ (if (not description)
1961              url
1962            (format "%s (%s)" desc url))))))
1963
1964 (defun elpher-org-store-link ()
1965   "Store link to an `elpher' page in Org."
1966   (when (eq major-mode 'elpher-mode)
1967     (let* ((url (elpher-info-current))
1968            (desc (car elpher-current-page))
1969            (protocol (cond
1970                       ((string-prefix-p "gemini:" url) "gemini")
1971                       ((string-prefix-p "gopher:" url) "gopher")
1972                       ((string-prefix-p "finger:" url) "finger")
1973                       (t "elpher"))))
1974       (when (equal "elpher" protocol)
1975         ;; Weird link. Or special inner link?
1976         (setq url (concat "elpher:" url)))
1977       (org-link-store-props :type protocol :link url :description desc)
1978       t)))
1979
1980 (defun elpher-org-follow-link (link protocol)
1981   "Visit a LINK for the given PROTOCOL.
1982
1983 PROTOCOL may be one of gemini, gopher or finger.  This method also
1984 supports the old protocol elpher, where the link is self-contained."
1985   (let ((url (if (equal protocol "elpher")
1986                  (string-remove-prefix "elpher:" link)
1987                (format "%s:%s" protocol link))))
1988     (elpher-go url)))
1989
1990 (defun elpher-org-mode-integration ()
1991   "Set up `elpher' integration for `org-mode'."
1992   (org-link-set-parameters
1993    "elpher"
1994    :store #'elpher-org-store-link
1995    :export (lambda (link description format _plist)
1996              (elpher-org-export-link link description format "elpher"))
1997    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1998   (org-link-set-parameters
1999    "gemini"
2000    :export (lambda (link description format _plist)
2001              (elpher-org-export-link link description format "gemini"))
2002    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2003   (org-link-set-parameters
2004    "gopher"
2005    :export (lambda (link description format _plist)
2006              (elpher-org-export-link link description format "gopher"))
2007    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2008   (org-link-set-parameters
2009    "finger"
2010    :export (lambda (link description format _plist)
2011              (elpher-org-export-link link description format "finger"))
2012    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2013
2014 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2015
2016 ;;; Browse URL
2017
2018 ;;;###autoload
2019 (defun elpher-browse-url-elpher (url &rest _args)
2020   "Browse URL using Elpher.  This function is used by `browse-url'."
2021   (interactive (browse-url-interactive-arg "Elpher URL: "))
2022   (elpher-go url))
2023
2024 ;; Use elpher to open gopher, finger and gemini links
2025 ;; For recent version of `browse-url' package
2026 (if (boundp 'browse-url-default-handlers)
2027     (add-to-list
2028      'browse-url-default-handlers
2029      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2030   ;; Patch `browse-url-browser-function' for older ones. The value of
2031   ;; that variable is `browse-url-default-browser' by default, so
2032   ;; that's the function that gets advised.
2033   (advice-add browse-url-browser-function :before-while
2034               (lambda (url &rest _args)
2035                 "Handle gemini, gopher, and finger schemes using Elpher."
2036                 (let ((scheme (downcase (car (split-string url ":" t)))))
2037                   (if (member scheme '("gemini" "gopher" "finger"))
2038                       ;; `elpher-go' always returns nil, which will stop the
2039                       ;; advice chain here in a before-while
2040                       (elpher-go url)
2041                     ;; chain must continue, then return t.
2042                     t)))))
2043
2044 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2045 (with-eval-after-load 'thingatpt
2046   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2047
2048 ;;; Mu4e:
2049
2050 ;; Make mu4e aware of the gemini world
2051 (setq mu4e~view-beginning-of-url-regexp
2052       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2053
2054 ;;; eww:
2055
2056 ;; Let elpher handle gemini, gopher links in eww buffer.
2057 (setq eww-use-browse-url
2058       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2059
2060 ;;; Interactive procedures
2061 ;;
2062
2063 (defun elpher-next-link ()
2064   "Move point to the next link on the current page."
2065   (interactive)
2066   (forward-button 1))
2067
2068 (defun elpher-prev-link ()
2069   "Move point to the previous link on the current page."
2070   (interactive)
2071   (backward-button 1))
2072
2073 (defun elpher-follow-current-link ()
2074   "Open the link or url at point."
2075   (interactive)
2076   (push-button))
2077
2078 ;;;###autoload
2079 (defun elpher-go (host-or-url)
2080   "Go to a particular gopher site HOST-OR-URL.
2081 When run interactively HOST-OR-URL is read from the minibuffer."
2082   (interactive "sGopher or Gemini URL: ")
2083   (let ((trimmed-host-or-url (string-trim host-or-url)))
2084     (unless (string-empty-p trimmed-host-or-url)
2085       (let* ((address (elpher-address-from-url trimmed-host-or-url))
2086              (page (elpher-make-page trimmed-host-or-url address)))
2087         (switch-to-buffer elpher-buffer-name)
2088         (elpher-with-clean-buffer
2089          (elpher-visit-page page))
2090         nil)))) ; non-nil value is displayed by eshell
2091
2092 (defun elpher-go-current ()
2093   "Go to a particular site read from the minibuffer, initialized with the current URL."
2094   (interactive)
2095   (let* ((address (elpher-page-address elpher-current-page))
2096          (url (read-string "Gopher or Gemini URL: "
2097                            (unless (elpher-address-special-p address)
2098                              (elpher-address-to-url address)))))
2099     (unless (string-empty-p (string-trim url))
2100       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
2101
2102 (defun elpher-redraw ()
2103   "Redraw current page."
2104   (interactive)
2105   (elpher-visit-page elpher-current-page))
2106
2107 (defun elpher-reload ()
2108   "Reload current page."
2109   (interactive)
2110   (elpher-reload-current-page))
2111
2112 (defun elpher-toggle-tls ()
2113   "Toggle TLS encryption mode for gopher."
2114   (interactive)
2115   (setq elpher-use-tls (not elpher-use-tls))
2116   (if elpher-use-tls
2117       (if (gnutls-available-p)
2118           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2119         (setq elpher-use-tls nil)
2120         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2121     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2122
2123 (defun elpher-view-raw ()
2124   "View raw server response for current page."
2125   (interactive)
2126   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2127       (error "This page was not generated by a server")
2128     (elpher-visit-page elpher-current-page
2129                        #'elpher-render-raw)))
2130
2131 (defun elpher-back ()
2132   "Go to previous site."
2133   (interactive)
2134   (elpher-visit-previous-page))
2135
2136 (defun elpher-back-to-start ()
2137   "Go all the way back to the start page."
2138   (interactive)
2139   (setq-local elpher-current-page nil)
2140   (setq-local elpher-history nil)
2141   (elpher-visit-page (elpher-make-start-page)))
2142
2143 (defun elpher-download ()
2144   "Download the link at point."
2145   (interactive)
2146   (let ((button (button-at (point))))
2147     (if button
2148         (let ((page (button-get button 'elpher-page)))
2149           (unless page
2150             (error "Not an elpher page"))
2151           (when (elpher-address-special-p (elpher-page-address page))
2152             (error "Cannot download %s" (elpher-page-display-string page)))
2153           (elpher-visit-page (button-get button 'elpher-page)
2154                              #'elpher-render-download))
2155       (error "No link selected"))))
2156
2157 (defun elpher-download-current ()
2158   "Download the current page."
2159   (interactive)
2160   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2161       (error "Cannot download %s"
2162              (elpher-page-display-string elpher-current-page))
2163     (elpher-visit-page (elpher-make-page
2164                         (elpher-page-display-string elpher-current-page)
2165                         (elpher-page-address elpher-current-page))
2166                        #'elpher-render-download
2167                        t)))
2168
2169 (defun elpher--build-link-map ()
2170   "Build alist mapping link names to destination pages in current buffer."
2171   (let ((link-map nil)
2172         (b (next-button (point-min) t)))
2173     (while b
2174       (push (cons (button-label b) b) link-map)
2175       (setq b (next-button (button-start b))))
2176     link-map))
2177
2178 (defun elpher-jump ()
2179   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2180   (interactive)
2181   (let* ((link-map (elpher--build-link-map)))
2182     (if link-map
2183         (let ((key (let ((completion-ignore-case t))
2184                      (completing-read "Directory item/link: "
2185                                       link-map nil t))))
2186           (if (and key (> (length key) 0))
2187               (let ((b (cdr (assoc key link-map))))
2188                 (goto-char (button-start b))
2189                 (button-activate b)))))))
2190
2191 (defun elpher-root-dir ()
2192   "Visit root of current server."
2193   (interactive)
2194   (let ((address (elpher-page-address elpher-current-page)))
2195     (if (not (elpher-address-special-p address))
2196         (if (or (member (url-filename address) '("/" ""))
2197                 (and (elpher-address-gopher-p address)
2198                      (= (length (elpher-gopher-address-selector address)) 0)))
2199             (error "Already at root directory of current server")
2200           (let ((address-copy (elpher-address-from-url
2201                                (elpher-address-to-url address))))
2202             (setf (url-filename address-copy) "")
2203             (elpher-go (elpher-address-to-url address-copy))))
2204       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2205
2206 (defun elpher-info-page (page)
2207   "Display information on PAGE."
2208   (let ((display-string (elpher-page-display-string page))
2209         (address (elpher-page-address page)))
2210     (message "%s" (elpher-address-to-url address))))
2211
2212 (defun elpher-info-link ()
2213   "Display information on page corresponding to link at point."
2214   (interactive)
2215   (let ((button (button-at (point))))
2216     (unless button
2217       (error "No item selected"))
2218     (let ((page (button-get button 'elpher-page)))
2219       (unless page
2220         (error "Not an elpher page"))
2221       (elpher-info-page page))))
2222
2223 (defun elpher-info-current ()
2224   "Display information on current page."
2225   (interactive)
2226   (elpher-info-page elpher-current-page))
2227
2228 (defun elpher-copy-page-url (page)
2229   "Copy URL representation of address of PAGE to `kill-ring'."
2230   (let* ((address (elpher-page-address page))
2231          (url (elpher-address-to-url address)))
2232     (message "Copied \"%s\" to kill-ring/clipboard." url)
2233     (kill-new url)))
2234
2235 (defun elpher-copy-link-url ()
2236   "Copy URL of item at point to `kill-ring'."
2237   (interactive)
2238   (let ((button (button-at (point))))
2239     (unless button
2240       (error "No item selected"))
2241     (let ((page (button-get button 'elpher-page)))
2242       (unless page
2243         (error "Not an elpher page"))
2244       (elpher-copy-page-url page))))
2245
2246 (defun elpher-copy-current-url ()
2247   "Copy URL of current page to `kill-ring'."
2248   (interactive)
2249   (elpher-copy-page-url elpher-current-page))
2250
2251 (defun elpher-set-gopher-coding-system ()
2252   "Specify an explicit character coding system for gopher selectors."
2253   (interactive)
2254   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2255     (setq elpher-user-coding-system system)
2256     (if system
2257         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2258       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2259
2260
2261 ;;; Mode and keymap
2262 ;;
2263
2264 (defvar elpher-mode-map
2265   (let ((map (make-sparse-keymap)))
2266     (define-key map (kbd "TAB") 'elpher-next-link)
2267     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2268     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2269     (define-key map (kbd "u") 'elpher-back)
2270     (define-key map (kbd "-") 'elpher-back)
2271     (define-key map (kbd "^") 'elpher-back)
2272     (define-key map [mouse-3] 'elpher-back)
2273     (define-key map (kbd "U") 'elpher-back-to-start)
2274     (define-key map (kbd "g") 'elpher-go)
2275     (define-key map (kbd "o") 'elpher-go-current)
2276     (define-key map (kbd "O") 'elpher-root-dir)
2277     (define-key map (kbd "s") 'elpher-show-history)
2278     (define-key map (kbd "S") 'elpher-show-visited-pages)
2279     (define-key map (kbd "r") 'elpher-redraw)
2280     (define-key map (kbd "R") 'elpher-reload)
2281     (define-key map (kbd "T") 'elpher-toggle-tls)
2282     (define-key map (kbd ".") 'elpher-view-raw)
2283     (define-key map (kbd "d") 'elpher-download)
2284     (define-key map (kbd "D") 'elpher-download-current)
2285     (define-key map (kbd "m") 'elpher-jump)
2286     (define-key map (kbd "i") 'elpher-info-link)
2287     (define-key map (kbd "I") 'elpher-info-current)
2288     (define-key map (kbd "c") 'elpher-copy-link-url)
2289     (define-key map (kbd "C") 'elpher-copy-current-url)
2290     (define-key map (kbd "a") 'elpher-bookmark-link)
2291     (define-key map (kbd "A") 'elpher-bookmark-current)
2292     (define-key map (kbd "B") 'elpher-show-bookmarks)
2293     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2294     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2295     (when (fboundp 'evil-define-key*)
2296       (evil-define-key*
2297        'motion map
2298        (kbd "TAB") 'elpher-next-link
2299        (kbd "C-") 'elpher-follow-current-link
2300        (kbd "C-t") 'elpher-back
2301        (kbd "u") 'elpher-back
2302        (kbd "-") 'elpher-back
2303        (kbd "^") 'elpher-back
2304        [mouse-3] 'elpher-back
2305        (kbd "U") 'elpher-back-to-start
2306        (kbd "g") 'elpher-go
2307        (kbd "o") 'elpher-go-current
2308        (kbd "O") 'elpher-root-dir
2309        (kbd "s") 'elpher-show-history
2310        (kbd "S") 'elpher-show-visited-pages
2311        (kbd "r") 'elpher-redraw
2312        (kbd "R") 'elpher-reload
2313        (kbd "T") 'elpher-toggle-tls
2314        (kbd ".") 'elpher-view-raw
2315        (kbd "d") 'elpher-download
2316        (kbd "D") 'elpher-download-current
2317        (kbd "m") 'elpher-jump
2318        (kbd "i") 'elpher-info-link
2319        (kbd "I") 'elpher-info-current
2320        (kbd "c") 'elpher-copy-link-url
2321        (kbd "C") 'elpher-copy-current-url
2322        (kbd "a") 'elpher-bookmark-link
2323        (kbd "A") 'elpher-bookmark-current
2324        (kbd "B") 'elpher-show-bookmarks
2325        (kbd "!") 'elpher-set-gopher-coding-system
2326        (kbd "F") 'elpher-forget-current-certificate))
2327     map)
2328   "Keymap for gopher client.")
2329
2330 (define-derived-mode elpher-mode special-mode "elpher"
2331   "Major mode for elpher, an elisp gopher client.
2332
2333 This mode is automatically enabled by the interactive
2334 functions which initialize the client, namely
2335 `elpher', and `elpher-go'."
2336   (setq-local elpher--gemini-page-headings nil)
2337   (setq-local elpher-current-page nil)
2338   (setq-local elpher-history nil)
2339   (setq-local elpher-buffer-name (buffer-name))
2340   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2341   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2342   (setq-local xterm-color-preserve-properties t))
2343
2344 (when (fboundp 'evil-set-initial-state)
2345   (evil-set-initial-state 'elpher-mode 'motion))
2346
2347
2348 ;;; Main start procedure
2349 ;;
2350
2351 ;;;###autoload
2352 (defun elpher (&optional arg)
2353   "Start elpher with default landing page.
2354 The buffer used for Elpher sessions is determined by the value of
2355 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2356 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2357 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2358 \\[execute-extended-command] elpher RET’) switches to the session with
2359 that number, creating it if necessary.  A non numeric prefix ARG means
2360 to create a new session.  Returns the buffer selected (or created)."
2361   (interactive "P")
2362   (let* ((name (default-value 'elpher-buffer-name))
2363          (buf (cond ((numberp arg)
2364                      (get-buffer-create (format "%s<%d>" name arg)))
2365                     (arg
2366                      (generate-new-buffer name))
2367                     (t
2368                      (get-buffer-create name)))))
2369     (pop-to-buffer-same-window buf)
2370     (unless (buffer-modified-p)
2371       (elpher-mode)
2372       (elpher-visit-page (elpher-make-start-page))
2373       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2374
2375 ;;; elpher.el ends here