elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 3.0.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: https://thelambdalab.xyz/elpher
  25 ;; Package-Requires: ((emacs "27.1"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - gopher connections using TLS encryption,
  54 ;; - the fledgling Gemini protocol,
  55 ;; - the greybeard Finger protocol.
  56
  57 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  58 ;; page containing information on key bindings and suggested starting
  59 ;; points for your gopher exploration.
  60
  61 ;; Full instructions can be found in the Elpher info manual.
  62
  63 ;; Elpher is under active development.  Any suggestions for
  64 ;; improvements are welcome, and can be made on the official
  65 ;; project page, gopher://thelambdalab.xyz/elpher, or via the
  66 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  67
  68 ;;; Code:
  69
  70 (provide 'elpher)
  71
  72 ;;; Dependencies
  73 ;;
  74
  75 (require 'seq)
  76 (require 'pp)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'dns)
  81 (require 'nsm)
  82 (require 'gnutls)
  83 (require 'socks)
  84
  85 ;;; ANSI colors or XTerm colors
  86
  87 (or (require 'xterm-color nil t)
  88     (require 'ansi-color))
  89
  90 (defalias 'elpher-color-filter-apply
  91   (if (fboundp 'xterm-color-filter)
  92       (lambda (s)
  93         (let ((_xterm-color-render nil))
  94           (xterm-color-filter s)))
  95     'ansi-color-filter-apply)
  96   "A function to filter out ANSI escape sequences.")
  97
  98 (defalias 'elpher-color-apply
  99   (if (fboundp 'xterm-color-filter)
 100       'xterm-color-filter
 101     'ansi-color-apply)
 102   "A function to apply ANSI escape sequences.")
 103
 104 ;;; Global constants
 105 ;;
 106
 107 (defconst elpher-version "3.0.0"
 108   "Current version of elpher.")
 109
 110 (defconst elpher-margin-width 6
 111   "Width of left-hand margin used when rendering indicies.")
 112
 113 (defconst elpher-type-map
 114   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 115     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 116     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 117     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 118     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 119     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 120     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 122     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 123     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 124     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 125     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 126     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 127     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 128     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 129     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 130     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 131     ((special start) elpher-get-start-page nil)
 132     ((special history) elpher-get-history-page nil)
 133     ((special history-all) elpher-get-history-all-page nil))
 134   "Association list from types to getters, renderers, margin codes and index faces.")
 135
 136
 137 ;;; Internal variables
 138 ;;
 139
 140 ;; buffer-local
 141 (defvar elpher--gemini-page-headings nil
 142   "List of headings on the page.")
 143
 144
 145 ;;; Declarations to avoid compiler warnings.
 146 ;;
 147
 148 (eval-when-compile
 149   (defvar bookmark-make-record-function)
 150   (declare-function bookmark-store "bookmark")
 151   (declare-function org-link-store-props "ol")
 152   (declare-function org-link-set-parameters "ol")
 153   (defvar thing-at-point-uri-schemes)
 154   (defvar mu4e~view-beginning-of-url-regexp))
 155
 156
 157 ;;; Customization group
 158 ;;
 159
 160 (defgroup elpher nil
 161   "A gopher and gemini client."
 162   :group 'applications)
 163
 164 ;; General appearance and customizations
 165
 166 (defcustom elpher-open-urls-with-eww nil
 167   "If non-nil, open URL selectors using eww.
 168 Otherwise, use the system browser via the `browse-url' function."
 169   :type '(boolean))
 170
 171 (defcustom elpher-use-header t
 172   "If non-nil, display current page information in buffer header."
 173   :type '(boolean))
 174
 175 (defcustom elpher-auto-disengage-TLS nil
 176   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 177 While enabling this may seem convenient, it is also potentially
 178 dangerous as it allows switching from an encrypted channel back to
 179 plain text without user input."
 180   :type '(boolean))
 181
 182 (defcustom elpher-connection-timeout 5
 183   "Specifies the number of seconds to wait for a network connection to time out."
 184   :type '(integer))
 185
 186 (defcustom elpher-filter-ansi-from-text nil
 187   "If non-nil, filter ANSI escape sequences from text.
 188 The default behaviour is to use the ansi-color package to interpret these
 189 sequences."
 190   :type '(boolean))
 191
 192 (defcustom elpher-certificate-directory
 193   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 194   "Specify the name of the directory where client certificates will be stored.
 195 These certificates may be used for establishing authenticated TLS connections."
 196   :type '(directory))
 197
 198 (defcustom elpher-openssl-command "openssl"
 199   "The command used to launch openssl when generating TLS client certificates."
 200   :type '(file))
 201
 202 (defcustom elpher-default-url-type "gopher"
 203   "Default URL type (i.e. scheme) to assume if not explicitly given."
 204   :type '(choice (const "gopher")
 205                  (const "gemini")))
 206
 207 (defcustom elpher-gemini-TLS-cert-checks nil
 208   "If non-nil, verify gemini server TLS certs using the default security level.
 209 Otherwise, certificate verification is disabled.
 210
 211 This defaults to off because it is standard practice for Gemini servers
 212 to use self-signed certificates, meaning that most servers provide what
 213 EMACS considers to be an invalid certificate."
 214   :type '(boolean))
 215
 216 (defcustom elpher-gemini-max-fill-width 80
 217   "Specify the maximum default width (in columns) of text/gemini documents.
 218 The actual width used is the minimum of this value and the window width at
 219 the time when the text is rendered."
 220   :type '(integer))
 221
 222 (defcustom elpher-gemini-link-string "→ "
 223   "Specify the string used to indicate links when rendering gemini maps.
 224 May be empty."
 225   :type '(string))
 226
 227 (defcustom elpher-gemini-bullet-string "•"
 228   "Specify the string used for bullets when rendering gemini maps."
 229   :type '(string))
 230
 231 (defcustom elpher-ipv4-always nil
 232   "If non-nil, elpher will always use IPv4 to establish network connections.
 233 This can be useful when browsing from a computer that supports IPv6, because
 234 some servers which do not support IPv6 can take a long time to time-out."
 235   :type '(boolean))
 236
 237 (defcustom elpher-socks-always nil
 238   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 239 Otherwise, the SOCKS proxy is only used for connections to onion services."
 240   :type '(boolean))
 241
 242 ;; Face customizations
 243
 244 (defgroup elpher-faces nil
 245   "Elpher face customizations."
 246   :group 'elpher)
 247
 248 (defface elpher-index
 249   '((t :inherit font-lock-keyword-face))
 250   "Face used for directory type directory records.")
 251
 252 (defface elpher-text
 253   '((t :inherit bold))
 254   "Face used for text type directory records.")
 255
 256 (defface elpher-info
 257   '((t :inherit default))
 258   "Face used for info type directory records.")
 259
 260 (defface elpher-image
 261   '((t :inherit font-lock-string-face))
 262   "Face used for image type directory records.")
 263
 264 (defface elpher-search
 265   '((t :inherit warning))
 266   "Face used for search type directory records.")
 267
 268 (defface elpher-html
 269   '((t :inherit font-lock-comment-face))
 270   "Face used for html type directory records.")
 271
 272 (defface elpher-gemini
 273   '((t :inherit font-lock-constant-face))
 274   "Face used for Gemini type directory records.")
 275
 276 (defface elpher-other-url
 277   '((t :inherit font-lock-comment-face))
 278   "Face used for other URL type links records.")
 279
 280 (defface elpher-telnet
 281   '((t :inherit font-lock-function-name-face))
 282   "Face used for telnet type directory records.")
 283
 284 (defface elpher-binary
 285   '((t :inherit font-lock-doc-face))
 286   "Face used for binary type directory records.")
 287
 288 (defface elpher-unknown
 289   '((t :inherit error))
 290   "Face used for directory records with unknown/unsupported types.")
 291
 292 (defface elpher-margin-key
 293   '((t :inherit bold))
 294   "Face used for directory margin key.")
 295
 296 (defface elpher-margin-brackets
 297   '((t :inherit shadow))
 298   "Face used for brackets around directory margin key.")
 299
 300 (defface elpher-gemini-heading1
 301   '((t :inherit bold :height 1.8))
 302   "Face used for gemini heading level 1.")
 303
 304 (defface elpher-gemini-heading2
 305   '((t :inherit bold :height 1.5))
 306   "Face used for gemini heading level 2.")
 307
 308 (defface elpher-gemini-heading3
 309   '((t :inherit bold :height 1.2))
 310   "Face used for gemini heading level 3.")
 311
 312 (defface elpher-gemini-preformatted
 313   '((t :inherit fixed-pitch))
 314   "Face used for pre-formatted gemini text blocks.")
 315
 316 (defface elpher-gemini-quoted
 317   '((t :inherit font-lock-doc-face))
 318   "Face used for gemini quoted texts.")
 319
 320 ;;; Model
 321 ;;
 322
 323 ;; Address
 324
 325 ;; An elpher "address" object is either a url object or a symbol.
 326 ;; Symbol addresses are "special", corresponding to pages generated
 327 ;; dynamically for and by elpher.  All others represent pages which
 328 ;; rely on content retrieved over the network.
 329
 330 (defun elpher-address-from-url (url-string)
 331   "Create a ADDRESS object corresponding to the given URL-STRING."
 332   (let ((data (match-data))) ; Prevent parsing clobbering match data
 333     (unwind-protect
 334         (let ((url (url-generic-parse-url url-string)))
 335           (unless (and (not (url-fullness url)) (url-type url))
 336             (setf (url-fullness url) t)
 337             (unless (url-type url)
 338               (setf (url-type url) elpher-default-url-type))
 339             (unless (url-host url)
 340               (let ((p (split-string (url-filename url) "/" nil nil)))
 341                 (setf (url-host url) (car p))
 342                 (setf (url-filename url)
 343                       (if (cdr p)
 344                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 345                         ""))))
 346             (when (or (equal "gopher" (url-type url))
 347                       (equal "gophers" (url-type url)))
 348               ;; Gopher defaults
 349               (when (or (equal (url-filename url) "")
 350                         (equal (url-filename url) "/"))
 351                 (setf (url-filename url) "/1")))
 352             (when (equal "gemini" (url-type url))
 353               ;; Gemini defaults
 354               (if (equal (url-filename url) "")
 355                   (setf (url-filename url) "/"))))
 356           (elpher-remove-redundant-ports url))
 357       (set-match-data data))))
 358
 359 (defun elpher-remove-redundant-ports (address)
 360   "Remove redundant port specifiers from ADDRESS.
 361 Here 'redundant' means that the specified port matches the default
 362 for that protocol, eg 70 for gopher."
 363   (if (and (not (elpher-address-special-p address))
 364            (eq (url-portspec address) ; (url-port) is too slow!
 365                (pcase (url-type address)
 366                  ("gemini" 1965)
 367                  ((or "gopher" "gophers") 70)
 368                  ("finger" 79)
 369                  (_ -1))))
 370       (setf (url-portspec address) nil))
 371   address)
 372
 373 (defun elpher-make-gopher-address (type selector host port &optional tls)
 374   "Create an ADDRESS object using gopher directory record attributes.
 375 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 376 If the optional attribute TLS is non-nil, the address will be marked as
 377 requiring gopher-over-TLS."
 378   (cond
 379    ((equal type ?i) nil)
 380    ((and (equal type ?h)
 381          (string-prefix-p "URL:" selector))
 382     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 383    ((equal type ?8)
 384     (elpher-address-from-url
 385      (concat "telnet"
 386              "://" host
 387              ":" (number-to-string port))))
 388    (t
 389     (elpher-address-from-url
 390      (concat "gopher" (if tls "s" "")
 391              "://" host
 392              ":" (number-to-string port)
 393              "/" (string type)
 394              selector)))))
 395
 396 (defun elpher-make-special-address (type)
 397   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 398   type)
 399
 400 (defun elpher-make-start-page ()
 401   "Create the start page."
 402   (elpher-make-page "Elpher Start Page"
 403                     (elpher-make-special-address 'start)))
 404
 405 (defun elpher-address-to-url (address)
 406   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 407   (if (elpher-address-special-p address)
 408       nil
 409     (url-encode-url (url-recreate-url address))))
 410
 411 (defun elpher-address-type (address)
 412   "Retrieve type of ADDRESS object.
 413 This is used to determine how to retrieve and render the document the
 414 address refers to, via the table `elpher-type-map'."
 415   (if (symbolp address)
 416       (list 'special address)
 417     (let ((protocol (url-type address)))
 418       (cond ((or (equal protocol "gopher")
 419                  (equal protocol "gophers"))
 420              (list 'gopher
 421                    (if (member (url-filename address) '("" "/"))
 422                        ?1
 423                      (string-to-char (substring (url-filename address) 1)))))
 424             ((equal protocol "gemini")
 425              'gemini)
 426             ((equal protocol "telnet")
 427              'telnet)
 428             ((equal protocol "finger")
 429              'finger)
 430             (t 'other-url)))))
 431
 432 (defun elpher-address-protocol (address)
 433   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 434   (if (symbolp address)
 435       nil
 436     (url-type address)))
 437
 438 (defun elpher-address-filename (address)
 439   "Retrieve the filename component of ADDRESS.
 440 For gopher addresses this is a combination of the selector type and selector."
 441   (if (symbolp address)
 442       nil
 443     (url-unhex-string (url-filename address))))
 444
 445 (defun elpher-address-host (address)
 446   "Retrieve host from ADDRESS object."
 447   (url-host address))
 448
 449 (defun elpher-address-user (address)
 450   "Retrieve user from ADDRESS object."
 451   (url-user address))
 452
 453 (defun elpher-address-port (address)
 454   "Retrieve port from ADDRESS object.
 455 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 456   (if (symbolp address)
 457       0
 458     (url-port address)))
 459
 460 (defun elpher-address-special-p (address)
 461   "Return non-nil if ADDRESS object is special (e.g. start page page)."
 462   (symbolp address))
 463
 464 (defun elpher-address-gopher-p (address)
 465   "Return non-nill if ADDRESS object is a gopher address."
 466   (and (not (elpher-address-special-p address))
 467        (member (elpher-address-protocol address) '("gopher" "gophers"))))
 468
 469 (defun elpher-gopher-address-selector (address)
 470   "Retrieve gopher selector from ADDRESS object."
 471   (if (member (url-filename address) '("" "/"))
 472       ""
 473     (url-unhex-string (substring (url-filename address) 2))))
 474
 475
 476 ;; Cache
 477
 478 (defvar elpher-content-cache (make-hash-table :test 'equal))
 479 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 480
 481 (defun elpher-get-cached-content (address)
 482   "Retrieve the cached content for ADDRESS, or nil if none exists."
 483   (gethash address elpher-content-cache))
 484
 485 (defun elpher-cache-content (address content)
 486   "Set the content cache for ADDRESS to CONTENT."
 487   (puthash address content elpher-content-cache))
 488
 489 (defun elpher-get-cached-pos (address)
 490   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 491   (gethash address elpher-pos-cache))
 492
 493 (defun elpher-cache-pos (address pos)
 494   "Set the cursor position cache for ADDRESS to POS."
 495   (puthash address pos elpher-pos-cache))
 496
 497
 498 ;; Page
 499
 500 (defun elpher-make-page (display-string address)
 501   "Create a page with DISPLAY-STRING and ADDRESS."
 502   (list display-string address))
 503
 504 (defun elpher-page-display-string (page)
 505   "Retrieve the display string corresponding to PAGE."
 506   (elt page 0))
 507
 508 (defun elpher-page-address (page)
 509   "Retrieve the address corresponding to PAGE."
 510   (elt page 1))
 511
 512 (defun elpher-page-set-address (page new-address)
 513   "Set the address corresponding to PAGE to NEW-ADDRESS."
 514   (setcar (cdr page) new-address))
 515
 516 (defvar elpher-current-page nil
 517   "The current page for this Elpher buffer.")
 518
 519 (defvar elpher-history nil
 520   "The local history for this Elpher buffer.
 521 This variable is used by `elpher-back' and
 522 `elpher-show-history'.")
 523
 524 (defvar elpher-history-all nil
 525   "The global history for all Elpher buffers.
 526 This variable is used by `elpher-show-history-all'.")
 527
 528 (defun elpher-visit-page (page &optional renderer no-history)
 529   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 530 Additionally, push PAGE onto the stack of previously-visited pages,
 531 unless NO-HISTORY is non-nil."
 532   (elpher-save-pos)
 533   (elpher-process-cleanup)
 534   (unless (or no-history
 535               (equal (elpher-page-address elpher-current-page)
 536                      (elpher-page-address page)))
 537     (push elpher-current-page elpher-history)
 538     (push elpher-current-page elpher-history-all))
 539   (setq-local elpher-current-page page)
 540   (let* ((address (elpher-page-address page))
 541          (type (elpher-address-type address))
 542          (type-record (cdr (assoc type elpher-type-map))))
 543     (if type-record
 544         (funcall (car type-record)
 545                  (if renderer
 546                      renderer
 547                    (cadr type-record)))
 548       (elpher-visit-previous-page)
 549       (pcase type
 550         (`(gopher ,type-char)
 551          (error "Unsupported gopher selector type '%c' for '%s'"
 552                 type-char (elpher-address-to-url address)))
 553         (other
 554          (error "Unsupported address type '%S' for '%s'"
 555                 other (elpher-address-to-url address)))))))
 556
 557 (defun elpher-visit-previous-page ()
 558   "Visit the previous page in the history."
 559   (let ((previous-page (pop elpher-history)))
 560     (if previous-page
 561         (elpher-visit-page previous-page nil t)
 562       (error "No previous page"))))
 563
 564 (defun elpher-reload-current-page ()
 565   "Reload the current page, discarding any existing cached content."
 566   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 567   (elpher-visit-page elpher-current-page))
 568
 569 (defun elpher-save-pos ()
 570   "Save the current position of point to the current page."
 571   (when elpher-current-page
 572     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 573
 574 (defun elpher-restore-pos ()
 575   "Restore the position of point to that cached in the current page."
 576   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 577     (if pos
 578         (goto-char pos)
 579       (goto-char (point-min)))))
 580
 581
 582 ;;; Buffer preparation
 583 ;;
 584
 585 (defvar elpher-buffer-name "*elpher*"
 586   "The default name of the Elpher buffer.")
 587
 588 (defun elpher-update-header ()
 589   "If `elpher-use-header' is true, display current page info in window header."
 590   (if elpher-use-header
 591       (let* ((display-string (elpher-page-display-string elpher-current-page))
 592              (address (elpher-page-address elpher-current-page))
 593              (tls-string (if (and (not (elpher-address-special-p address))
 594                                   (member (elpher-address-protocol address)
 595                                           '("gophers" "gemini")))
 596                              " [TLS encryption]"
 597                            ""))
 598              (header (concat display-string
 599                              (propertize tls-string 'face 'bold))))
 600         (setq header-line-format header))))
 601
 602 (defmacro elpher-with-clean-buffer (&rest args)
 603   "Evaluate ARGS with a clean *elpher* buffer as current."
 604   `(with-current-buffer elpher-buffer-name
 605      (unless (eq major-mode 'elpher-mode)
 606        ;; avoid resetting buffer-local variables
 607        (elpher-mode))
 608      (let ((inhibit-read-only t))
 609        (setq-local network-security-level
 610                    (default-value 'network-security-level))
 611        (erase-buffer)
 612        (elpher-update-header)
 613        ,@args)))
 614
 615 (defun elpher-buffer-message (string &optional line)
 616   "Replace first line in elpher buffer with STRING.
 617 If LINE is non-nil, replace that line instead."
 618   (with-current-buffer elpher-buffer-name
 619     (let ((inhibit-read-only t))
 620       (goto-char (point-min))
 621       (if line
 622           (forward-line line))
 623       (let ((data (match-data)))
 624         (unwind-protect
 625             (progn
 626               (re-search-forward "^.*$")
 627               (replace-match string))
 628           (set-match-data data))))))
 629
 630
 631 ;;; Text Processing
 632 ;;
 633
 634 (defvar elpher-user-coding-system nil
 635   "User-specified coding system to use for decoding text responses.")
 636
 637 (defun elpher-decode (string)
 638   "Decode STRING using autodetected or user-specified coding system."
 639   (decode-coding-string string
 640                         (if elpher-user-coding-system
 641                             elpher-user-coding-system
 642                           (detect-coding-string string t))))
 643
 644 (defun elpher-preprocess-text-response (string)
 645   "Preprocess text selector response contained in STRING.
 646 This involes decoding the character representation, and clearing
 647 away CRs and any terminating period."
 648   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 649                                            (replace-regexp-in-string "\r" "" string))))
 650
 651
 652 ;;; Network error reporting
 653 ;;
 654
 655 (defun elpher-network-error (address error)
 656   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 657 ERROR can be either an error object or a string."
 658   (elpher-with-clean-buffer
 659    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 660            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 661            (if (stringp error) error (error-message-string error)) "\n"
 662            (propertize "\n----------------\n\n" 'face 'error)
 663            "Press 'u' to return to the previous page.")))
 664
 665
 666 ;;; General network communication
 667 ;;
 668
 669 (defvar elpher-network-timer nil
 670   "Timer used for network connections.")
 671
 672 (defvar elpher-use-tls nil
 673   "If non-nil, use TLS to communicate with gopher servers.")
 674
 675 (defvar elpher-client-certificate nil
 676   "If non-nil, contains client certificate details to use for TLS connections.")
 677
 678 (defun elpher-process-cleanup ()
 679   "Immediately shut down any extant elpher process and timers."
 680   (let ((p (get-process "elpher-process")))
 681     (if p (delete-process p)))
 682   (if (timerp elpher-network-timer)
 683       (cancel-timer elpher-network-timer)))
 684
 685 (defun elpher-get-host-response (address default-port query-string response-processor
 686                                          &optional use-tls force-ipv4)
 687   "Generic function for retrieving data from ADDRESS.
 688
 689 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 690 QUERY-STRING is a string sent to the host specified by ADDRESS to
 691 illicet a response.  This response is passed as an argument to the
 692 function RESPONSE-PROCESSOR.
 693
 694 If non-nil, USE-TLS specifies that the connection is to be made over
 695 TLS.  If set to gemini, the certificate verification will be disabled
 696 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 697
 698 If non-nil, FORCE-IPV4 causes the network connection to be made over
 699 ipv4 only.  (The default behaviour when this is not set depends on
 700 the host operating system and the local network capabilities.)"
 701   (if (and use-tls (not (gnutls-available-p)))
 702       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 703     (unless (< (elpher-address-port address) 65536)
 704       (error "Cannot establish network connection: port number > 65536"))
 705     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 706       (setq-local network-security-level 'low)
 707       (setq-local gnutls-verify-error nil))
 708     (condition-case nil
 709         (let* ((kill-buffer-query-functions nil)
 710                (port (elpher-address-port address))
 711                (service (if (> port 0) port default-port))
 712                (host (elpher-address-host address))
 713                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 714                (response-string-parts nil)
 715                (bytes-received 0)
 716                (hkbytes-received 0)
 717                (timer (run-at-time elpher-connection-timeout nil
 718                                    (lambda ()
 719                                      (elpher-process-cleanup)
 720                                      (cond
 721                                         ; Try again with IPv4
 722                                       ((not (or force-ipv4 socks))
 723                                        (message "Connection timed out.  Retrying with IPv4.")
 724                                        (elpher-get-host-response address default-port
 725                                                                  query-string
 726                                                                  response-processor
 727                                                                  use-tls t))
 728                                       ((and use-tls
 729                                             (not (eq use-tls 'gemini))
 730                                             (or elpher-auto-disengage-TLS
 731                                                 (y-or-n-p
 732                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 733                                        (setq elpher-use-tls nil)
 734                                        (elpher-get-host-response address default-port
 735                                                                  query-string
 736                                                                  response-processor
 737                                                                  nil force-ipv4))
 738                                       (t
 739                                        (elpher-network-error address "Connection time-out."))))))
 740                (gnutls-params (list :type 'gnutls-x509pki :hostname host
 741                                     :keylist (elpher-get-current-keylist address)))
 742                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 743                        (make-network-process :name "elpher-process"
 744                                              :host host
 745                                              :family (and force-ipv4 'ipv4)
 746                                              :service service
 747                                              :buffer nil
 748                                              :nowait t
 749                                              :tls-parameters
 750                                              (and use-tls
 751                                                   (cons 'gnutls-x509pki
 752                                                         (apply #'gnutls-boot-parameters
 753                                                                gnutls-params)))))))
 754           (setq elpher-network-timer timer)
 755           (set-process-coding-system proc 'binary 'binary)
 756           (set-process-query-on-exit-flag proc nil)
 757           (elpher-buffer-message (concat "Connecting to " host "..."
 758                                          " (press 'u' to abort)"))
 759           (set-process-filter proc
 760                               (lambda (_proc string)
 761                                 (when timer
 762                                   (cancel-timer timer)
 763                                   (setq timer nil))
 764                                 (setq bytes-received (+ bytes-received (length string)))
 765                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 766                                   (when (> new-hkbytes-received hkbytes-received)
 767                                     (setq hkbytes-received new-hkbytes-received)
 768                                     (elpher-buffer-message
 769                                      (concat "("
 770                                              (number-to-string (/ hkbytes-received 10.0))
 771                                              " MB read)")
 772                                      1)))
 773                                 (setq response-string-parts
 774                                       (cons string response-string-parts))))
 775           (set-process-sentinel proc
 776                                 (lambda (proc event)
 777                                   (when timer
 778                                     (cancel-timer timer))
 779                                   (condition-case the-error
 780                                       (cond
 781                                        ((string-prefix-p "open" event)    ; request URL
 782                                         (elpher-buffer-message
 783                                          (concat "Connected to " host ". Receiving data..."
 784                                                  " (press 'u' to abort)"))
 785                                         (let ((inhibit-eol-conversion t))
 786                                           (process-send-string proc query-string)))
 787                                        ((string-prefix-p "deleted" event)) ; do nothing
 788                                        ((and (not response-string-parts)
 789                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 790                                         ; Try again with IPv4
 791                                         (message "Connection failed. Retrying with IPv4.")
 792                                         (elpher-get-host-response address default-port
 793                                                                   query-string
 794                                                                   response-processor
 795                                                                   use-tls t))
 796                                        (response-string-parts
 797                                         (elpher-with-clean-buffer
 798                                          (insert "Data received.  Rendering..."))
 799                                         (funcall response-processor
 800                                                  (apply #'concat (reverse response-string-parts)))
 801                                         (elpher-restore-pos))
 802                                        (t
 803                                         (error "No response from server")))
 804                                     (error
 805                                      (elpher-network-error address the-error)))))
 806           (when socks
 807             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 808             (funcall (process-sentinel proc) proc "open\n")))
 809       (error
 810        (error "Error initiating connection to server")))))
 811
 812
 813 ;;; Client-side TLS Certificate Management
 814 ;;
 815
 816 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 817   "Generate a key and a self-signed client TLS certificate using openssl.
 818
 819 The Common Name field of the certificate is set to COMMON-NAME.  The
 820 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 821 the key and certificate files to write.
 822
 823 If TEMPORARY is non-nil, the certificate will be given an exporation
 824 period of one day, and the key and certificate files will be deleted
 825 when the certificate is no longer needed for the current session.
 826
 827 Otherwise, the certificate will be given a 100 year expiration period
 828 and the files will not be deleted.
 829
 830 The function returns a list containing the current host name, the
 831 temporary flag, and the key and cert file names in the form required
 832 by `gnutls-boot-parameters`."
 833   (let ((exp-key-file (expand-file-name key-file))
 834         (exp-cert-file (expand-file-name cert-file)))
 835     (condition-case nil
 836         (progn
 837           (call-process elpher-openssl-command nil nil nil
 838                         "req" "-x509" "-newkey" "rsa:2048"
 839                         "-days" (if temporary "1" "36500")
 840                         "-nodes"
 841                         "-subj" (concat "/CN=" common-name)
 842                         "-keyout" exp-key-file
 843                         "-out" exp-cert-file)
 844           (list (elpher-address-host (elpher-page-address elpher-current-page))
 845                 temporary exp-key-file exp-cert-file))
 846       (error
 847        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 848        (error "Program 'openssl', required for certificate generation, not found")))))
 849
 850 (defun elpher-generate-throwaway-certificate ()
 851   "Generate and return details of a throwaway certificate.
 852 The key and certificate files will be deleted when they are no
 853 longer needed for this session."
 854   (let* ((file-base (make-temp-name "elpher"))
 855          (key-file (concat temporary-file-directory file-base ".key"))
 856          (cert-file (concat temporary-file-directory file-base ".crt")))
 857     (elpher-generate-certificate file-base key-file cert-file t)))
 858
 859 (defun elpher-generate-persistent-certificate (file-base common-name)
 860   "Generate and return details of a persistent certificate.
 861 The argument FILE-BASE is used as the base for the key and certificate
 862 files, while COMMON-NAME specifies the common name field of the
 863 certificate.
 864
 865 The key and certificate files are written to in `elpher-certificate-directory'."
 866   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 867          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 868     (elpher-generate-certificate common-name key-file cert-file)))
 869
 870 (defun elpher-get-existing-certificate (file-base)
 871   "Return a certificate object corresponding to an existing certificate.
 872 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 873 the directory `elpher-certificate-directory'."
 874   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 875          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 876     (list (elpher-address-host (elpher-page-address elpher-current-page))
 877           nil
 878           (expand-file-name key-file)
 879           (expand-file-name cert-file))))
 880
 881 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 882   "Install a key+certificate file pair in `elpher-certificate-directory'.
 883 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 884 certificate files to install.  The argument FILE-BASE is used as the
 885 base for the installed key and certificate files."
 886   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 887          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 888     (if (or (file-exists-p key-file)
 889             (file-exists-p cert-file))
 890         (error "A certificate with base name %s is already installed" file-base))
 891     (copy-file key-file-src key-file)
 892     (copy-file cert-file-src cert-file)
 893     (list (elpher-address-host (elpher-page-address elpher-current-page))
 894           nil
 895           (expand-file-name key-file)
 896           (expand-file-name cert-file))))
 897
 898 (defun elpher-list-existing-certificates ()
 899   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 900   (unless (file-directory-p elpher-certificate-directory)
 901     (make-directory elpher-certificate-directory))
 902   (mapcar
 903    (lambda (file)
 904      (file-name-sans-extension file))
 905    (directory-files elpher-certificate-directory nil "\\.key$")))
 906
 907 (defun elpher-forget-current-certificate ()
 908   "Causes any current certificate to be forgotten.)
 909 In the case of throwaway certificates, the key and certificate files
 910 are also deleted."
 911   (interactive)
 912   (when elpher-client-certificate
 913     (unless (and (called-interactively-p 'any)
 914                  (not (y-or-n-p (concat "Really forget client certificate? "
 915                                         "(Throwaway certificates will be deleted.)"))))
 916       (when (cadr elpher-client-certificate)
 917         (delete-file (elt elpher-client-certificate 2))
 918         (delete-file (elt elpher-client-certificate 3)))
 919       (setq elpher-client-certificate nil)
 920       (if (called-interactively-p 'any)
 921           (message "Client certificate forgotten.")))))
 922
 923 (defun elpher-get-current-keylist (address)
 924   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 925
 926 This is obtained from the client certificate described by
 927 `elpher-current-certificate', if one is available and the host for
 928 that certificate matches the host in ADDRESS.
 929
 930 If `elpher-current-certificate' is non-nil, and its host name doesn't
 931 match that of ADDRESS, the certificate is forgotten."
 932   (if elpher-client-certificate
 933       (if (string= (car elpher-client-certificate)
 934                    (elpher-address-host address))
 935           (list (cddr elpher-client-certificate))
 936         (elpher-forget-current-certificate)
 937         (message "Disabling client certificate for new host")
 938         nil)
 939     nil))
 940
 941
 942 ;;; Gopher selector retrieval
 943 ;;
 944
 945 (defun elpher-get-gopher-response (address renderer)
 946   "Get response string from gopher server at ADDRESS and render using RENDERER."
 947   (elpher-get-host-response address 70
 948                             (concat (elpher-gopher-address-selector address) "\r\n")
 949                             renderer
 950                             (or (string= (elpher-address-protocol address) "gophers")
 951                                 elpher-use-tls)))
 952
 953 (defun elpher-get-gopher-page (renderer)
 954   "Getter function for gopher pages.
 955 The RENDERER procedure is used to display the contents of the page
 956 once they are retrieved from the gopher server."
 957   (let* ((address (elpher-page-address elpher-current-page))
 958          (content (elpher-get-cached-content address)))
 959     (if (and content (funcall renderer nil))
 960         (elpher-with-clean-buffer
 961          (insert content)
 962          (elpher-restore-pos))
 963       (elpher-with-clean-buffer
 964        (insert "LOADING... (use 'u' to cancel)\n"))
 965       (condition-case the-error
 966           (elpher-get-gopher-response address renderer)
 967         (error
 968          (elpher-network-error address the-error))))))
 969
 970 ;; Index rendering
 971
 972 (defun elpher-insert-index (string)
 973   "Insert the index corresponding to STRING into the current buffer."
 974   ;; Should be able to split directly on CRLF, but some non-conformant
 975   ;; LF-only servers sadly exist, hence the following.
 976   (let ((str-processed (elpher-preprocess-text-response string)))
 977     (dolist (line (split-string str-processed "\n"))
 978       (ignore-errors
 979         (unless (= (length line) 0)
 980           (let* ((type (elt line 0))
 981                  (fields (split-string (substring line 1) "\t"))
 982                  (display-string (elt fields 0))
 983                  (selector (elt fields 1))
 984                  (host (elt fields 2))
 985                  (port (if (elt fields 3)
 986                            (string-to-number (elt fields 3))
 987                          nil))
 988                  (address (elpher-make-gopher-address type selector host port)))
 989             (elpher-insert-index-record display-string address)))))))
 990
 991 (defun elpher-insert-margin (&optional type-name)
 992   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 993   (if type-name
 994       (progn
 995         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 996                         (concat
 997                          (propertize "[" 'face 'elpher-margin-brackets)
 998                          (propertize type-name 'face 'elpher-margin-key)
 999                          (propertize "]" 'face 'elpher-margin-brackets))))
1000         (insert " "))
1001     (insert (make-string elpher-margin-width ?\s))))
1002
1003 (defun elpher--page-button-help (_window buffer pos)
1004   "Function called by Emacs to generate mouse-over text.
1005 The arguments specify the BUFFER and the POS within the buffer of the item
1006 for which help is required.  The function returns the help to be
1007 displayed.  The _WINDOW argument is currently unused."
1008   (with-current-buffer buffer
1009     (let ((button (button-at pos)))
1010       (when button
1011         (let* ((page (button-get button 'elpher-page))
1012                (address (elpher-page-address page)))
1013           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1014                                                 address
1015                                               (elpher-address-to-url address))))))))
1016
1017 (defun elpher-insert-index-record (display-string &optional address)
1018   "Function to insert an index record into the current buffer.
1019 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1020 If ADDRESS is not supplied or nil the record is rendered as an
1021 'information' line."
1022   (let* ((type (if address (elpher-address-type address) nil))
1023          (type-map-entry (cdr (assoc type elpher-type-map))))
1024     (if type-map-entry
1025         (let* ((margin-code (elt type-map-entry 2))
1026                (face (elt type-map-entry 3))
1027                (filtered-display-string (elpher-color-filter-apply display-string))
1028                (page (elpher-make-page filtered-display-string address)))
1029           (elpher-insert-margin margin-code)
1030           (insert-text-button filtered-display-string
1031                               'face face
1032                               'elpher-page page
1033                               'action #'elpher-click-link
1034                               'follow-link t
1035                               'help-echo #'elpher--page-button-help))
1036       (pcase type
1037         ('nil ;; Information
1038          (elpher-insert-margin)
1039          (let ((propertized-display-string
1040                 (propertize display-string 'face 'elpher-info)))
1041            (insert (elpher-process-text-for-display propertized-display-string))))
1042         (`(gopher ,selector-type) ;; Unknown
1043          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1044          (insert (propertize display-string
1045                              'face 'elpher-unknown)))))
1046     (insert "\n")))
1047
1048 (defun elpher-click-link (button)
1049   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1050   (let ((page (button-get button 'elpher-page)))
1051     (elpher-visit-page page)))
1052
1053 (defun elpher-render-index (data &optional _mime-type-string)
1054   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1055   (elpher-with-clean-buffer
1056    (if (not data)
1057        t
1058      (elpher-insert-index data)
1059      (elpher-cache-content (elpher-page-address elpher-current-page)
1060                            (buffer-string)))))
1061
1062 ;; Text rendering
1063
1064 (defconst elpher-url-regex
1065   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
1066   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
1067
1068 (defun elpher-buttonify-urls (string)
1069   "Turn substrings which look like urls in STRING into clickable buttons."
1070   (with-temp-buffer
1071     (insert string)
1072     (goto-char (point-min))
1073     (while (re-search-forward elpher-url-regex nil t)
1074       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1075                                     (elpher-address-from-url (match-string 0)))))
1076         (make-text-button (match-beginning 0)
1077                           (match-end 0)
1078                           'elpher-page  page
1079                           'action #'elpher-click-link
1080                           'follow-link t
1081                           'help-echo #'elpher--page-button-help
1082                           'face 'button)))
1083     (buffer-string)))
1084
1085 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
1086   "Incomplete regexp used to strip out some troublesome ANSI escape sequences.")
1087
1088 (defun elpher-process-text-for-display (string)
1089   "Perform any desired processing of STRING prior to display as text.
1090 Currently includes buttonifying URLs and processing ANSI escape codes."
1091   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1092                              (elpher-color-filter-apply string)
1093                            (elpher-color-apply string))))
1094
1095 (defun elpher-render-text (data &optional _mime-type-string)
1096   "Render DATA as text.  MIME-TYPE-STRING is unused."
1097   (elpher-with-clean-buffer
1098    (if (not data)
1099        t
1100      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1101      (elpher-cache-content
1102       (elpher-page-address elpher-current-page)
1103       (buffer-string)))))
1104
1105 ;; Image retrieval
1106
1107 (defun elpher-render-image (data &optional _mime-type-string)
1108   "Display DATA as image.  MIME-TYPE-STRING is unused."
1109   (if (not data)
1110       nil
1111     (if (display-images-p)
1112         (progn
1113           (let ((image (create-image
1114                         data
1115                         nil t)))
1116             (elpher-with-clean-buffer
1117              (insert-image image)
1118              (elpher-restore-pos))))
1119       (elpher-render-download data))))
1120
1121 ;; Search retrieval and rendering
1122
1123 (defun elpher-get-gopher-query-page (renderer)
1124   "Getter for gopher addresses requiring input.
1125 The response is rendered using the rendering function RENDERER."
1126   (let* ((address (elpher-page-address elpher-current-page))
1127          (content (elpher-get-cached-content address))
1128          (aborted t))
1129     (if (and content (funcall renderer nil))
1130         (elpher-with-clean-buffer
1131          (insert content)
1132          (elpher-restore-pos)
1133          (message "Displaying cached search results.  Reload to perform a new search."))
1134       (unwind-protect
1135           (let* ((query-string (read-string "Query: "))
1136                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1137                  (search-address (elpher-make-gopher-address ?1
1138                                                              query-selector
1139                                                              (elpher-address-host address)
1140                                                              (elpher-address-port address)
1141                                                              (equal (elpher-address-type address) "gophers"))))
1142             (setq aborted nil)
1143
1144             (elpher-with-clean-buffer
1145              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1146             (elpher-get-gopher-response search-address renderer))
1147         (if aborted
1148             (elpher-visit-previous-page))))))
1149
1150 ;; Raw server response rendering
1151
1152 (defun elpher-render-raw (data &optional mime-type-string)
1153   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1154   (if (not data)
1155       nil
1156     (elpher-with-clean-buffer
1157      (when mime-type-string
1158        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1159      (insert data)
1160      (goto-char (point-min)))
1161     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1162
1163 ;; File save "rendering"
1164
1165 (defun elpher-render-download (data &optional _mime-type-string)
1166   "Save DATA to file.  MIME-TYPE-STRING is unused."
1167   (if (not data)
1168       nil
1169     (let* ((address (elpher-page-address elpher-current-page))
1170            (selector (if (elpher-address-gopher-p address)
1171                          (elpher-gopher-address-selector address)
1172                        (elpher-address-filename address))))
1173       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1174       (let* ((filename-proposal (file-name-nondirectory selector))
1175              (filename (read-file-name "Download complete. Save file as: "
1176                                        nil nil nil
1177                                        (if (> (length filename-proposal) 0)
1178                                            filename-proposal
1179                                          "download.file"))))
1180         (let ((coding-system-for-write 'binary))
1181           (with-temp-file filename
1182             (insert data)))
1183         (message (format "Saved to file %s." filename))))))
1184
1185 ;; HTML rendering
1186
1187 (defun elpher-render-html (data &optional _mime-type-string)
1188   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1189   (elpher-with-clean-buffer
1190    (if (not data)
1191        t
1192      (let ((dom (with-temp-buffer
1193                   (insert data)
1194                   (libxml-parse-html-region (point-min) (point-max)))))
1195        (shr-insert-document dom)))))
1196
1197 ;; Gemini page retrieval
1198
1199 (defvar elpher-gemini-redirect-chain)
1200
1201 (defun elpher-get-gemini-response (address renderer)
1202   "Get response string from gemini server at ADDRESS and render using RENDERER."
1203   (elpher-get-host-response address 1965
1204                             (concat (elpher-address-to-url address) "\r\n")
1205                             (lambda (response-string)
1206                               (elpher-process-gemini-response response-string renderer))
1207                             'gemini))
1208
1209 (defun elpher-parse-gemini-response (response)
1210   "Parse the RESPONSE string and return a list of components.
1211 The list is of the form (code meta body).  A response of nil implies
1212 that the response was malformed."
1213   (let ((header-end-idx (string-match "\r\n" response)))
1214     (if header-end-idx
1215         (let ((header (string-trim (substring response 0 header-end-idx)))
1216               (body (substring response (+ header-end-idx 2))))
1217           (if (>= (length header) 2)
1218               (let ((code (substring header 0 2))
1219                     (meta (string-trim (substring header 2))))
1220                 (list code meta body))
1221             (error "Malformed response: No response status found in header %s" header)))
1222       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1223
1224 (defun elpher-process-gemini-response (response-string renderer)
1225   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1226   (let ((response-components (elpher-parse-gemini-response response-string)))
1227     (let ((response-code (elt response-components 0))
1228           (response-meta (elt response-components 1))
1229           (response-body (elt response-components 2)))
1230       (pcase (elt response-code 0)
1231         (?1 ; Input required
1232          (elpher-with-clean-buffer
1233           (insert "Gemini server is requesting input."))
1234          (let* ((query-string
1235                  (if (eq (elt response-code 1) ?1)
1236                      (read-passwd (concat response-meta ": "))
1237                    (read-string (concat response-meta ": "))))
1238                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1239                 (old-fname (url-filename query-address)))
1240            (setf (url-filename query-address)
1241                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1242            (elpher-get-gemini-response query-address renderer)))
1243         (?2 ; Normal response
1244          (funcall renderer response-body response-meta))
1245         (?3 ; Redirect
1246          (message "Following redirect to %s" response-meta)
1247          (if (>= (length elpher-gemini-redirect-chain) 5)
1248              (error "More than 5 consecutive redirects followed"))
1249          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1250            (if (member redirect-address elpher-gemini-redirect-chain)
1251                (error "Redirect loop detected"))
1252            (if (not (string= (elpher-address-protocol redirect-address)
1253                              "gemini"))
1254                (error "Server tried to automatically redirect to non-gemini URL: %s"
1255                       response-meta))
1256            (elpher-page-set-address elpher-current-page redirect-address)
1257            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1258            (elpher-get-gemini-response redirect-address renderer)))
1259         (?4 ; Temporary failure
1260          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1261                 response-code response-meta))
1262         (?5 ; Permanent failure
1263          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1264                 response-code response-meta))
1265         (?6 ; Client certificate required
1266          (elpher-with-clean-buffer
1267           (if elpher-client-certificate
1268               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1269             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1270           (auto-fill-mode 1)
1271           (elpher-gemini-insert-text response-meta))
1272          (let ((chosen-certificate (elpher-choose-client-certificate)))
1273            (unless chosen-certificate
1274              (error "Gemini server requires a client certificate and none was provided"))
1275            (setq elpher-client-certificate chosen-certificate))
1276          (elpher-with-clean-buffer)
1277          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1278         (_other
1279          (error "Gemini server response unknown: %s %s"
1280                 response-code response-meta))))))
1281
1282 (defun elpher--read-answer-polyfill (question answers)
1283   "Polyfill for `read-answer' in Emacs 26.1.
1284 QUESTION is a string containing a question, and ANSWERS
1285 is a list of possible answers."
1286     (completing-read question (mapcar 'identity answers)))
1287
1288 (if (fboundp 'read-answer)
1289     (defalias 'elpher-read-answer 'read-answer)
1290   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1291
1292 (defun elpher-choose-client-certificate ()
1293   "Prompt for a client certificate to use to establish a TLS connection."
1294   (let* ((read-answer-short t))
1295     (pcase (read-answer "What do you want to do? "
1296                         '(("throwaway" ?t
1297                            "generate and use throw-away certificate")
1298                           ("persistent" ?p
1299                            "generate new or use existing persistent certificate")
1300                           ("abort" ?a
1301                            "stop immediately")))
1302       ("throwaway"
1303        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1304       ("persistent"
1305        (let* ((existing-certificates (elpher-list-existing-certificates))
1306               (file-base (completing-read
1307                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1308                           existing-certificates)))
1309          (if (string-empty-p (string-trim file-base))
1310              nil
1311            (if (member file-base existing-certificates)
1312                (setq elpher-client-certificate
1313                      (elpher-get-existing-certificate file-base))
1314              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1315                                  '(("new" ?n
1316                                     "generate new certificate")
1317                                    ("install" ?i
1318                                     "install existing certificate")
1319                                    ("abort" ?a
1320                                     "stop immediately")))
1321                ("new"
1322                 (let ((common-name (read-string "Common Name field for new certificate: "
1323                                                 file-base)))
1324                   (message "New key and self-signed certificate written to %s"
1325                            elpher-certificate-directory)
1326                   (elpher-generate-persistent-certificate file-base common-name)))
1327                ("install"
1328                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1329                        (key-file (read-file-name "Key file: " nil nil t)))
1330                   (message "Key and certificate installed in %s for future use"
1331                            elpher-certificate-directory)
1332                   (elpher-install-and-use-existing-certificate key-file
1333                                                                cert-file
1334                                                                file-base)))
1335                ("abort" nil))))))
1336       ("abort" nil))))
1337
1338 (defun elpher-get-gemini-page (renderer)
1339   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1340   (let* ((address (elpher-page-address elpher-current-page))
1341          (content (elpher-get-cached-content address)))
1342     (condition-case the-error
1343         (if (and content (funcall renderer nil))
1344             (elpher-with-clean-buffer
1345              (insert content)
1346              (elpher-restore-pos))
1347           (elpher-with-clean-buffer
1348            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1349           (setq elpher-gemini-redirect-chain nil)
1350           (elpher-get-gemini-response address renderer))
1351       (error
1352        (elpher-network-error address the-error)))))
1353
1354 (defun elpher-render-gemini (body &optional mime-type-string)
1355   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1356   (if (not body)
1357       t
1358     (let* ((mime-type-string* (if (or (not mime-type-string)
1359                                       (string-empty-p mime-type-string))
1360                                   "text/gemini; charset=utf-8"
1361                                 mime-type-string))
1362            (mime-type-split (split-string mime-type-string* ";" t))
1363            (mime-type (string-trim (car mime-type-split)))
1364            (parameters (mapcar (lambda (s)
1365                                  (let ((key-val (split-string s "=")))
1366                                    (list (downcase (string-trim (car key-val)))
1367                                          (downcase (string-trim (cadr key-val))))))
1368                                (cdr mime-type-split))))
1369       (when (string-prefix-p "text/" mime-type)
1370         (setq body (decode-coding-string
1371                     body
1372                     (if (assoc "charset" parameters)
1373                         (intern (cadr (assoc "charset" parameters)))
1374                       'utf-8)))
1375         (setq body (replace-regexp-in-string "\r" "" body)))
1376       (pcase mime-type
1377         ((or "text/gemini" "")
1378          (elpher-render-gemini-map body parameters))
1379         ("text/html"
1380          (elpher-render-html body))
1381         ((pred (string-prefix-p "text/"))
1382          (elpher-render-gemini-plain-text body parameters))
1383         ((pred (string-prefix-p "image/"))
1384          (elpher-render-image body))
1385         (_other
1386          (elpher-render-download body))))))
1387
1388 (defun elpher-gemini-get-link-url (link-line)
1389   "Extract the url portion of LINK-LINE, a gemini map file link line.
1390 Returns nil in the event that the contents of the line following the
1391 => prefix are empty."
1392   (let ((l (split-string (substring link-line 2))))
1393     (if l
1394         (string-trim (elt l 0))
1395       nil)))
1396
1397 (defun elpher-gemini-get-link-display-string (link-line)
1398   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1399 Returns the url portion in the event that the display-string portion is empty."
1400   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1401          (idx (string-match "[ \t]" rest)))
1402     (string-trim (if idx
1403                      (substring rest (+ idx 1))
1404                    rest))))
1405
1406 (defun elpher-collapse-dot-sequences (filename)
1407   "Collapse dot sequences in FILENAME.
1408 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1409   (let* ((path (split-string filename "/"))
1410          (path-reversed-normalized
1411           (seq-reduce (lambda (a b)
1412                         (cond ((and a (equal b "..") (cdr a)))
1413                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1414                               ((equal b ".") a)
1415                               (t (cons b a))))
1416                       path nil)))
1417     (string-join (reverse path-reversed-normalized) "/")))
1418
1419 (defun elpher-address-from-gemini-url (url)
1420   "Extract address from URL with defaults as per gemini map files.
1421 While there's obviously some redundancy here between this function and
1422 `elpher-address-from-url', gemini map file URLs require enough special
1423 treatment that a separate function is warranted."
1424   (let ((address (url-generic-parse-url url))
1425         (current-address (elpher-page-address elpher-current-page)))
1426     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1427       (setf (url-fullness address) t)
1428       (if (url-host address) ;if there is an explicit host, filenames are absolute
1429           (if (string-empty-p (url-filename address))
1430               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1431         (setf (url-host address) (url-host current-address))
1432         (setf (url-port address) (url-port current-address))
1433         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1434           (setf (url-filename address)
1435                 (concat (file-name-directory (url-filename current-address))
1436                         (url-filename address)))))
1437       (unless (url-type address)
1438         (setf (url-type address) "gemini"))
1439       (when (equal (url-type address) "gemini")
1440         (setf (url-filename address)
1441               (elpher-collapse-dot-sequences (url-filename address)))))
1442     (elpher-remove-redundant-ports address)))
1443
1444 (defun elpher-gemini-insert-link (link-line)
1445   "Insert link described by LINK-LINE into a text/gemini document."
1446   (let* ((url (elpher-gemini-get-link-url link-line))
1447          (display-string (elpher-gemini-get-link-display-string link-line))
1448          (address (elpher-address-from-gemini-url url))
1449          (type (if address (elpher-address-type address) nil))
1450          (type-map-entry (cdr (assoc type elpher-type-map))))
1451     (when display-string
1452       (insert elpher-gemini-link-string)
1453       (if type-map-entry
1454           (let* ((face (elt type-map-entry 3))
1455                  (filtered-display-string (elpher-color-filter-apply display-string))
1456                  (page (elpher-make-page filtered-display-string address)))
1457             (insert-text-button filtered-display-string
1458                                 'face face
1459                                 'elpher-page page
1460                                 'action #'elpher-click-link
1461                                 'follow-link t
1462                                 'help-echo #'elpher--page-button-help))
1463         (insert (propertize display-string 'face 'elpher-unknown)))
1464       (insert "\n"))))
1465
1466 (defun elpher-gemini-insert-header (header-line)
1467   "Insert header described by HEADER-LINE into a text/gemini document.
1468 The gemini map file line describing the header is given
1469 by HEADER-LINE."
1470   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1471     (let* ((level (length (match-string 1 header-line)))
1472            (header (substring header-line (match-end 0)))
1473            (face (pcase level
1474                    (1 'elpher-gemini-heading1)
1475                    (2 'elpher-gemini-heading2)
1476                    (3 'elpher-gemini-heading3)
1477                    (_ 'default)))
1478            (fill-column (if (display-graphic-p)
1479                             (/ (* fill-column
1480                                   (font-get (font-spec :name (face-font 'default)) :size))
1481                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1482       (setq elpher--gemini-page-headings (cons (cons header (point))
1483                                                elpher--gemini-page-headings))
1484       (unless (display-graphic-p)
1485         (insert (make-string level ?#) " "))
1486       (insert (propertize header 'face face))
1487       (newline))))
1488
1489 (defun elpher-gemini-insert-text (text-line)
1490   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1491 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1492 width defined by `elpher-gemini-max-fill-width'."
1493   (string-match "\\(^[ \t]*\\)\\(\\*[ \t]+\\|>[ \t]*\\)?" text-line)
1494   (let* ((line-prefix (match-string 2 text-line))
1495          (processed-text-line
1496           (if line-prefix
1497               (cond ((string-prefix-p "*" line-prefix)
1498                      (concat
1499                       (replace-regexp-in-string "\\*"
1500                                                 elpher-gemini-bullet-string
1501                                                 (match-string 0 text-line))
1502                       (substring text-line (match-end 0))))
1503                     ((string-prefix-p ">" line-prefix)
1504                      (propertize text-line 'face 'elpher-gemini-quoted))
1505                     (t text-line))
1506             text-line))
1507          (adaptive-fill-mode t)
1508          ;; fill-prefix is important for adaptive-fill-mode: without
1509          ;; it, multi-line list items are not indented correct
1510          (fill-prefix (if (match-string 2 text-line)
1511                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1512                         nil)))
1513     (insert (elpher-process-text-for-display processed-text-line))
1514     (newline)))
1515
1516 (defun elpher-render-gemini-map (data _parameters)
1517   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1518   (elpher-with-clean-buffer
1519    (setq elpher--gemini-page-headings nil)
1520    (let ((preformatted nil))
1521      (auto-fill-mode 1)
1522      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1523      (dolist (line (split-string data "\n"))
1524        (cond
1525         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1526         (preformatted (insert (elpher-process-text-for-display
1527                                (propertize line 'face 'elpher-gemini-preformatted))
1528                               "\n"))
1529         ((string-prefix-p "=>" line)
1530          (elpher-gemini-insert-link line))
1531         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1532         (t (elpher-gemini-insert-text line)))))
1533    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1534    (elpher-cache-content
1535     (elpher-page-address elpher-current-page)
1536     (buffer-string))))
1537
1538 (defun elpher-render-gemini-plain-text (data _parameters)
1539   "Render DATA as plain text file.  PARAMETERS is currently unused."
1540   (elpher-with-clean-buffer
1541    (insert (elpher-process-text-for-display data))
1542    (elpher-cache-content
1543     (elpher-page-address elpher-current-page)
1544     (buffer-string))))
1545
1546
1547 ;; Finger page connection
1548
1549 (defun elpher-get-finger-page (renderer)
1550   "Opens a finger connection to the current page address.
1551 The result is rendered using RENDERER."
1552   (let* ((address (elpher-page-address elpher-current-page))
1553          (content (elpher-get-cached-content address)))
1554     (if (and content (funcall renderer nil))
1555         (elpher-with-clean-buffer
1556          (insert content)
1557          (elpher-restore-pos))
1558       (elpher-with-clean-buffer
1559        (insert "LOADING... (use 'u' to cancel)\n"))
1560       (condition-case the-error
1561           (let* ((kill-buffer-query-functions nil)
1562                  (user (let ((filename (elpher-address-filename address)))
1563                          (if (> (length filename) 1)
1564                              (substring filename 1)
1565                            (elpher-address-user address)))))
1566             (elpher-get-host-response address 79
1567                                       (concat user "\r\n")
1568                                       renderer))
1569         (error
1570          (elpher-network-error address the-error))))))
1571
1572
1573 ;; Telnet page connection
1574
1575 (defun elpher-get-telnet-page (renderer)
1576   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1577   (when renderer
1578     (elpher-visit-previous-page)
1579     (error "Command not supported for telnet URLs"))
1580   (let* ((address (elpher-page-address elpher-current-page))
1581          (host (elpher-address-host address))
1582          (port (elpher-address-port address)))
1583     (elpher-visit-previous-page)
1584     (if (> port 0)
1585         (telnet host port)
1586       (telnet host))))
1587
1588
1589 ;; Other URL page opening
1590
1591 (defun elpher-get-other-url-page (renderer)
1592   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1593   (when renderer
1594     (elpher-visit-previous-page)
1595     (error "Command not supported for general URLs"))
1596   (let* ((address (elpher-page-address elpher-current-page))
1597          (url (elpher-address-to-url address)))
1598     (progn
1599       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1600       (message "Opening URL...")
1601       (if elpher-open-urls-with-eww
1602           (browse-web url)
1603         (browse-url url)))))
1604
1605
1606 ;; Start page page retrieval
1607
1608 (defun elpher-get-start-page (renderer)
1609   "Getter which displays the start page (RENDERER must be nil)."
1610   (when renderer
1611     (elpher-visit-previous-page)
1612     (error "Command not supported for start page"))
1613   (elpher-with-clean-buffer
1614    (insert "     --------------------------------------------\n"
1615            "           Elpher Gopher and Gemini Client       \n"
1616            "                   version " elpher-version "\n"
1617            "     --------------------------------------------\n"
1618            "\n"
1619            "Default bindings:\n"
1620            "\n"
1621            " - TAB/Shift-TAB: next/prev item on current page\n"
1622            " - RET/mouse-1: open item under cursor\n"
1623            " - m/M: select an item on current page by name (autocompletes) or number\n"
1624            " - u/mouse-3/U: return to previous page or to the start page\n"
1625            " - g: go to a particular address (gopher, gemini, finger)\n"
1626            " - o/O: open a different address selector or the root menu of the current server\n"
1627            " - d/D: download item under cursor or current page\n"
1628            " - i/I: info on item under cursor or current page\n"
1629            " - c/C: copy URL representation of item under cursor or current page\n"
1630            " - a/A: bookmark the item under cursor or current page\n"
1631            " - B: list all bookmarks\n"
1632            " - s/S: show history of current buffer or for all buffers\n"
1633            " - r: redraw current page (using cached contents if available)\n"
1634            " - R: reload current page (regenerates cache)\n"
1635            " - !: set character coding system for gopher (default is to autodetect)\n"
1636            " - T: toggle TLS gopher mode\n"
1637            " - F: forget/discard current TLS client certificate\n"
1638            " - .: display the raw server response for the current page\n"
1639            "\n"
1640            "Start your exploration of gopher space and gemini:\n")
1641    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1642                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1643    (elpher-insert-index-record "Project Gemini home page"
1644                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1645    (insert "\n"
1646            "Alternatively, select a search engine and enter some search terms:\n")
1647    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1648                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1649    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1650                                (elpher-address-from-url "gemini://geminispace.info/search"))
1651    (insert "\n"
1652            "Your bookmarks are stored in your ")
1653    (let ((help-string "RET,mouse-1: Open Emacs bookmark list"))
1654      (insert-text-button "Emacs bookmark list"
1655                          'face 'link
1656                          'action (lambda (_)
1657                                    (interactive)
1658                                    (call-interactively #'bookmark-bmenu-list))
1659                          'follow-link t
1660                          'help-echo help-string))
1661    (insert ".\n")
1662    (insert (propertize
1663             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1664             'face 'shadow))
1665    (insert "\n"
1666            "For Elpher release news or to leave feedback, visit:\n")
1667    (elpher-insert-index-record "The Elpher Project Page"
1668                                (elpher-make-gopher-address ?1
1669                                                            "/projects/elpher/"
1670                                                            "thelambdalab.xyz"
1671                                                            70))
1672    (insert "\n"
1673            "** Refer to the ")
1674    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1675      (insert-text-button "Elpher info manual"
1676                          'face 'link
1677                          'action (lambda (_)
1678                                    (interactive)
1679                                    (info "(elpher)"))
1680                          'follow-link t
1681                          'help-echo help-string))
1682    (insert " for the full documentation. **\n")
1683    (insert (propertize
1684             (concat "  (This should be available if you have installed Elpher using\n"
1685                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1686             'face 'shadow))
1687    (elpher-restore-pos)))
1688
1689 ;; History page retrieval
1690
1691 (defun elpher-history ()
1692   "Show the history of pages leading to the current page in this buffer.
1693 Use \\[elpher-history-all] to see the entire history.
1694 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1695   (interactive)
1696   (elpher-visit-page
1697    (elpher-make-page "Elpher History Page"
1698                      (elpher-make-special-address 'history))))
1699
1700 (defun elpher-history-all ()
1701   "Show the all the pages you've visited using Elpher.
1702 Use \\[elpher-history] to see just the history for the current buffer.
1703 This is rendered using `elpher-get-history-all-page' via `elpher-type-map'."
1704   (interactive)
1705   (elpher-visit-page
1706    (elpher-make-page "Elpher History Of All Seen Pages"
1707                      (elpher-make-special-address 'history-all))))
1708
1709 (defun elpher-get-history-page (renderer)
1710   "Getter which displays the history page (RENDERER must be nil)."
1711   (when renderer
1712     (elpher-visit-previous-page)
1713     (error "Command not supported for history page"))
1714   (elpher-show-history elpher-history))
1715
1716 (defun elpher-get-history-all-page (renderer)
1717   "Getter which displays the history page (RENDERER must be nil)."
1718   (when renderer
1719     (elpher-visit-previous-page)
1720     (error "Command not supported for history page"))
1721   (elpher-show-history elpher-history-all))
1722
1723 (defun elpher-show-history (pages)
1724   "Show all PAGES in the Elpher buffer."
1725   (elpher-with-clean-buffer
1726    (insert "---- Visited link history ----\n\n")
1727    (if pages
1728        (dolist (page pages)
1729          (when page
1730            (let ((display-string (elpher-page-display-string page))
1731                  (address (elpher-page-address page)))
1732              (elpher-insert-index-record display-string address))))
1733      (insert "No history items found.\n"))
1734    (insert "\n----------------------------")))
1735
1736
1737 ;;; Bookmarks
1738
1739 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1740 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1741 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1742 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1743
1744 (defvar elpher-bookmark-link nil
1745   "Prefer bookmarking a link or the current page.
1746 Bind this variable dynamically, or set it to t.
1747 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1748 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1749
1750 (defun elpher-bookmark-make-record ()
1751   "Return a bookmark record.
1752 If `elpher-bookmark-link' is non-nil and point is on a link button,
1753 return a bookmark record for that link.  Otherwise, return a bookmark
1754 record for the current elpher page."
1755   (let* ((button (and elpher-bookmark-link (button-at (point))))
1756          (page (if button
1757                    (button-get button 'elpher-page)
1758                  elpher-current-page))
1759          (address (elpher-page-address page))
1760          (url (elpher-address-to-url address))
1761          (display-string (elpher-page-display-string page))
1762          (pos (if button nil (point))))
1763     (if (elpher-address-special-p address)
1764         (error "Cannot bookmark %s" display-string)
1765       `(,display-string
1766         (defaults . (,display-string))
1767         (position . ,pos)
1768         (location . ,url)
1769         (handler . elpher-bookmark-jump)))))
1770
1771 ;;;###autoload
1772 (defun elpher-bookmark-jump (bookmark)
1773   "Go to a particular BOOKMARK."
1774   (let* ((url (cdr (assq 'location bookmark))))
1775     (elpher-go url)))
1776
1777 (defun elpher-set-bookmark-no-overwrite ()
1778   "Bookmark the link at point.
1779 To bookmark the current page, use \\[bookmark-set-no-overwrite]."
1780   (interactive)
1781   (let ((elpher-bookmark-link t))
1782     (bookmark-set-no-overwrite)))
1783
1784 (defun elpher-bookmark-import (file)
1785   "Import Elpher bookmarks file FILE into Emacs bookmarks."
1786   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1787                               (file-readable-p elpher-bookmarks-file))
1788                          elpher-bookmarks-file
1789                        (read-file-name "Old Elpher bookmarks: "
1790                                        user-emacs-directory nil t
1791                                        "elpher-bookmarks"))))
1792   (require 'bookmark)
1793   (dolist (bookmark (with-temp-buffer
1794                       (insert-file-contents file)
1795                       (read (current-buffer))))
1796     (let* ((display-string (car bookmark))
1797            (url (cadr bookmark))
1798            (record `(,display-string
1799                      (location . ,url)
1800                      (handler . elpher-bookmark-jump))))
1801       (bookmark-store display-string (cdr record) t)))
1802   (bookmark-save))
1803
1804 ;;; Integrations
1805 ;;
1806
1807 ;;; Org
1808
1809 (defun elpher-org-export-link (link description format protocol)
1810   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1811
1812 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1813 of gemini, gopher or finger."
1814   (let* ((url (if (equal protocol "elpher")
1815                   (string-remove-prefix "elpher:" link)
1816                 (format "%s:%s" protocol link)))
1817          (desc (or description url)))
1818     (pcase format
1819       (`gemini (format "=> %s %s" url desc))
1820       (`html (format "<a href=\"%s\">%s</a>" url desc))
1821       (`latex (format "\\href{%s}{%s}" url desc))
1822       (_ (if (not description)
1823              url
1824            (format "%s (%s)" desc url))))))
1825
1826 (defun elpher-org-store-link ()
1827   "Store link to an `elpher' page in Org."
1828   (when (eq major-mode 'elpher-mode)
1829     (let* ((url (elpher-info-current))
1830            (desc (car elpher-current-page))
1831            (protocol (cond
1832                       ((string-prefix-p "gemini:" url) "gemini")
1833                       ((string-prefix-p "gopher:" url) "gopher")
1834                       ((string-prefix-p "finger:" url) "finger")
1835                       (t "elpher"))))
1836       (when (equal "elpher" protocol)
1837         ;; Weird link. Or special inner link?
1838         (setq url (concat "elpher:" url)))
1839       (org-link-store-props :type protocol :link url :description desc)
1840       t)))
1841
1842 (defun elpher-org-follow-link (link protocol)
1843   "Visit a LINK for the given PROTOCOL.
1844
1845 PROTOCOL may be one of gemini, gopher or finger.  This method also
1846 supports the old protocol elpher, where the link is self-contained."
1847   (let ((url (if (equal protocol "elpher")
1848                  (string-remove-prefix "elpher:" link)
1849                (format "%s:%s" protocol link))))
1850     (elpher-go url)))
1851
1852 (defun elpher-org-mode-integration ()
1853   "Set up `elpher' integration for `org-mode'."
1854   (org-link-set-parameters
1855    "elpher"
1856    :store #'elpher-org-store-link
1857    :export (lambda (link description format _plist)
1858              (elpher-org-export-link link description format "elpher"))
1859    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
1860   (org-link-set-parameters
1861    "gemini"
1862    :export (lambda (link description format _plist)
1863              (elpher-org-export-link link description format "gemini"))
1864    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
1865   (org-link-set-parameters
1866    "gopher"
1867    :export (lambda (link description format _plist)
1868              (elpher-org-export-link link description format "gopher"))
1869    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
1870   (org-link-set-parameters
1871    "finger"
1872    :export (lambda (link description format _plist)
1873              (elpher-org-export-link link description format "finger"))
1874    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
1875
1876 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
1877
1878 ;;; Browse URL
1879
1880 ;;;###autoload
1881 (defun elpher-browse-url-elpher (url &rest _args)
1882   "Browse URL using Elpher.  This function is used by `browse-url'."
1883   (interactive (browse-url-interactive-arg "Elpher URL: "))
1884   (elpher-go url))
1885
1886 ;; Use elpher to open gopher, finger and gemini links
1887 ;; For recent version of `browse-url' package
1888 (if (boundp 'browse-url-default-handlers)
1889     (add-to-list
1890      'browse-url-default-handlers
1891      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
1892   ;; Patch `browse-url-browser-function' for older ones. The value of
1893   ;; that variable is `browse-url-default-browser' by default, so
1894   ;; that's the function that gets advised.
1895   (advice-add browse-url-browser-function :before-while
1896               (lambda (url &rest _args)
1897                 "Handle gemini, gopher, and finger schemes using Elpher."
1898                 (let ((scheme (downcase (car (split-string url ":" t)))))
1899                   (if (member scheme '("gemini" "gopher" "finger"))
1900                       ;; `elpher-go' always returns nil, which will stop the
1901                       ;; advice chain here in a before-while
1902                       (elpher-go url)
1903                     ;; chain must continue, then return t.
1904                     t)))))
1905
1906 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1907 (with-eval-after-load 'thingatpt
1908   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
1909
1910 ;;; Mu4e:
1911
1912 ;; Make mu4e aware of the gemini world
1913 (setq mu4e~view-beginning-of-url-regexp
1914       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
1915
1916 ;;; Interactive procedures
1917 ;;
1918
1919 (defun elpher-next-link ()
1920   "Move point to the next link on the current page."
1921   (interactive)
1922   (forward-button 1))
1923
1924 (defun elpher-prev-link ()
1925   "Move point to the previous link on the current page."
1926   (interactive)
1927   (backward-button 1))
1928
1929 (defun elpher-follow-current-link ()
1930   "Open the link or url at point."
1931   (interactive)
1932   (push-button))
1933
1934 ;;;###autoload
1935 (defun elpher-go (host-or-url)
1936   "Go to a particular gopher site HOST-OR-URL.
1937 When run interactively HOST-OR-URL is read from the minibuffer."
1938   (interactive "sGopher or Gemini URL: ")
1939   (let* ((cleaned-host-or-url (string-trim host-or-url))
1940          (address (elpher-address-from-url cleaned-host-or-url))
1941          (page (elpher-make-page cleaned-host-or-url address)))
1942     (switch-to-buffer elpher-buffer-name)
1943     (elpher-with-clean-buffer
1944      (elpher-visit-page page))
1945     nil))
1946
1947 (defun elpher-go-current ()
1948   "Go to a particular site read from the minibuffer, initialized with the current URL."
1949   (interactive)
1950   (let ((address (elpher-page-address elpher-current-page)))
1951     (let ((url (read-string "Gopher or Gemini URL: "
1952                             (unless (elpher-address-special-p address)
1953                               (elpher-address-to-url address)))))
1954       (elpher-visit-page (elpher-make-page url (elpher-address-from-url url))))))
1955
1956 (defun elpher-redraw ()
1957   "Redraw current page."
1958   (interactive)
1959   (elpher-visit-page elpher-current-page))
1960
1961 (defun elpher-reload ()
1962   "Reload current page."
1963   (interactive)
1964   (elpher-reload-current-page))
1965
1966 (defun elpher-toggle-tls ()
1967   "Toggle TLS encryption mode for gopher."
1968   (interactive)
1969   (setq elpher-use-tls (not elpher-use-tls))
1970   (if elpher-use-tls
1971       (if (gnutls-available-p)
1972           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1973         (setq elpher-use-tls nil)
1974         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1975     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1976
1977 (defun elpher-view-raw ()
1978   "View raw server response for current page."
1979   (interactive)
1980   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1981       (error "This page was not generated by a server")
1982     (elpher-visit-page elpher-current-page
1983                        #'elpher-render-raw)))
1984
1985 (defun elpher-back ()
1986   "Go to previous site."
1987   (interactive)
1988   (elpher-visit-previous-page))
1989
1990 (defun elpher-back-to-start ()
1991   "Go all the way back to the start page."
1992   (interactive)
1993   (setq-local elpher-current-page nil)
1994   (setq-local elpher-history nil)
1995   (elpher-visit-page (elpher-make-start-page)))
1996
1997 (defun elpher-download ()
1998   "Download the link at point."
1999   (interactive)
2000   (let ((button (button-at (point))))
2001     (if button
2002         (let ((page (button-get button 'elpher-page)))
2003           (if (elpher-address-special-p (elpher-page-address page))
2004               (error "Cannot download %s"
2005                      (elpher-page-display-string page))
2006             (elpher-visit-page (button-get button 'elpher-page)
2007                                #'elpher-render-download)))
2008       (error "No link selected"))))
2009
2010 (defun elpher-download-current ()
2011   "Download the current page."
2012   (interactive)
2013   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
2014       (error "Cannot download %s"
2015              (elpher-page-display-string elpher-current-page))
2016     (elpher-visit-page (elpher-make-page
2017                         (elpher-page-display-string elpher-current-page)
2018                         (elpher-page-address elpher-current-page))
2019                        #'elpher-render-download
2020                        t)))
2021
2022 (defun elpher-build-link-map ()
2023   "Build alist mapping link names to destination pages in current buffer."
2024   (let ((link-map nil)
2025         (b (next-button (point-min) t)))
2026     (while b
2027       (push (cons (button-label b) b) link-map)
2028       (setq b (next-button (button-start b))))
2029     link-map))
2030
2031 (defun elpher-jump ()
2032   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2033   (interactive)
2034   (let* ((link-map (elpher-build-link-map)))
2035     (if link-map
2036         (let ((key (let ((completion-ignore-case t))
2037                      (completing-read "Directory item/link: "
2038                                       link-map nil t))))
2039           (if (and key (> (length key) 0))
2040               (let ((b (cdr (assoc key link-map))))
2041                 (goto-char (button-start b))
2042                 (button-activate b)))))))
2043
2044 (defun elpher-root-dir ()
2045   "Visit root of current server."
2046   (interactive)
2047   (let ((address (elpher-page-address elpher-current-page)))
2048     (if (not (elpher-address-special-p address))
2049         (if (or (member (url-filename address) '("/" ""))
2050                 (and (elpher-address-gopher-p address)
2051                      (= (length (elpher-gopher-address-selector address)) 0)))
2052             (error "Already at root directory of current server")
2053           (let ((address-copy (elpher-address-from-url
2054                                (elpher-address-to-url address))))
2055             (setf (url-filename address-copy) "")
2056             (elpher-go (elpher-address-to-url address-copy))))
2057       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2058
2059 (defun elpher-info-page (page)
2060   "Display information on PAGE."
2061   (let ((display-string (elpher-page-display-string page))
2062         (address (elpher-page-address page)))
2063     (if (elpher-address-special-p address)
2064         (message "Special page: %s" display-string)
2065       (message "%s" (elpher-address-to-url address)))))
2066
2067 (defun elpher-info-link ()
2068   "Display information on page corresponding to link at point."
2069   (interactive)
2070   (let ((button (button-at (point))))
2071     (if button
2072         (elpher-info-page (button-get button 'elpher-page))
2073       (error "No item selected"))))
2074
2075 (defun elpher-info-current ()
2076   "Display information on current page."
2077   (interactive)
2078   (elpher-info-page elpher-current-page))
2079
2080 (defun elpher-copy-page-url (page)
2081   "Copy URL representation of address of PAGE to `kill-ring'."
2082   (let ((address (elpher-page-address page)))
2083     (if (elpher-address-special-p address)
2084         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2085       (let ((url (elpher-address-to-url address)))
2086         (message "Copied \"%s\" to kill-ring/clipboard." url)
2087         (kill-new url)))))
2088
2089 (defun elpher-copy-link-url ()
2090   "Copy URL of item at point to `kill-ring'."
2091   (interactive)
2092   (let ((button (button-at (point))))
2093     (if button
2094         (elpher-copy-page-url (button-get button 'elpher-page))
2095       (error "No item selected"))))
2096
2097 (defun elpher-copy-current-url ()
2098   "Copy URL of current page to `kill-ring'."
2099   (interactive)
2100   (elpher-copy-page-url elpher-current-page))
2101
2102 (defun elpher-set-gopher-coding-system ()
2103   "Specify an explicit character coding system for gopher selectors."
2104   (interactive)
2105   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2106     (setq elpher-user-coding-system system)
2107     (if system
2108         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2109       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2110
2111
2112 ;;; Mode and keymap
2113 ;;
2114
2115 (defvar elpher-mode-map
2116   (let ((map (make-sparse-keymap)))
2117     (define-key map (kbd "TAB") 'elpher-next-link)
2118     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2119     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2120     (define-key map (kbd "u") 'elpher-back)
2121     (define-key map (kbd "-") 'elpher-back)
2122     (define-key map (kbd "^") 'elpher-back)
2123     (define-key map [mouse-3] 'elpher-back)
2124     (define-key map (kbd "U") 'elpher-back-to-start)
2125     (define-key map (kbd "g") 'elpher-go)
2126     (define-key map (kbd "o") 'elpher-go-current)
2127     (define-key map (kbd "O") 'elpher-root-dir)
2128     (define-key map (kbd "s") 'elpher-history)
2129     (define-key map (kbd "S") 'elpher-history-all)
2130     (define-key map (kbd "r") 'elpher-redraw)
2131     (define-key map (kbd "R") 'elpher-reload)
2132     (define-key map (kbd "T") 'elpher-toggle-tls)
2133     (define-key map (kbd ".") 'elpher-view-raw)
2134     (define-key map (kbd "d") 'elpher-download)
2135     (define-key map (kbd "D") 'elpher-download-current)
2136     (define-key map (kbd "m") 'elpher-jump)
2137     (define-key map (kbd "i") 'elpher-info-link)
2138     (define-key map (kbd "I") 'elpher-info-current)
2139     (define-key map (kbd "c") 'elpher-copy-link-url)
2140     (define-key map (kbd "C") 'elpher-copy-current-url)
2141     (define-key map (kbd "a") 'elpher-set-bookmark-no-overwrite)
2142     (define-key map (kbd "A") 'bookmark-set-no-overwrite)
2143     (define-key map (kbd "B") 'bookmark-bmenu-list)
2144     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2145     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2146     (when (fboundp 'evil-define-key*)
2147       (evil-define-key*
2148        'motion map
2149        (kbd "TAB") 'elpher-next-link
2150        (kbd "C-") 'elpher-follow-current-link
2151        (kbd "C-t") 'elpher-back
2152        (kbd "u") 'elpher-back
2153        (kbd "-") 'elpher-back
2154        (kbd "^") 'elpher-back
2155        [mouse-3] 'elpher-back
2156        (kbd "U") 'elpher-back-to-start
2157        (kbd "g") 'elpher-go
2158        (kbd "o") 'elpher-go-current
2159        (kbd "O") 'elpher-root-dir
2160        (kbd "r") 'elpher-redraw
2161        (kbd "R") 'elpher-reload
2162        (kbd "T") 'elpher-toggle-tls
2163        (kbd ".") 'elpher-view-raw
2164        (kbd "d") 'elpher-download
2165        (kbd "D") 'elpher-download-current
2166        (kbd "m") 'elpher-jump
2167        (kbd "i") 'elpher-info-link
2168        (kbd "I") 'elpher-info-current
2169        (kbd "c") 'elpher-copy-link-url
2170        (kbd "C") 'elpher-copy-current-url
2171        (kbd "a") 'elpher-set-bookmark-no-overwrite
2172        (kbd "A") 'bookmark-set-no-overwrite
2173        (kbd "B") 'bookmark-bmenu-list
2174        (kbd "!") 'elpher-set-gopher-coding-system
2175        (kbd "F") 'elpher-forget-current-certificate))
2176     map)
2177   "Keymap for gopher client.")
2178
2179 (define-derived-mode elpher-mode special-mode "elpher"
2180   "Major mode for elpher, an elisp gopher client.
2181
2182 This mode is automatically enabled by the interactive
2183 functions which initialize the client, namely
2184 `elpher', and `elpher-go'."
2185   (setq-local elpher--gemini-page-headings nil)
2186   (setq-local elpher-current-page nil)
2187   (setq-local elpher-history nil)
2188   (setq-local elpher-buffer-name (buffer-name))
2189   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2190   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings)))
2191
2192 (when (fboundp 'evil-set-initial-state)
2193   (evil-set-initial-state 'elpher-mode 'motion))
2194
2195
2196 ;;; Main start procedure
2197 ;;
2198
2199 ;;;###autoload
2200 (defun elpher (&optional arg)
2201   "Start elpher with default landing page.
2202 The buffer used for Elpher sessions is determined by the value of
2203 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2204 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2205 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2206 \\[execute-extended-command] elpher RET’) switches to the session with
2207 that number, creating it if necessary.  A non numeric prefix ARG means
2208 to create a new session.  Returns the buffer selected (or created)."
2209   (interactive "P")
2210   (let* ((name (default-value 'elpher-buffer-name))
2211          (buf (cond ((numberp arg)
2212                      (get-buffer-create (format "%s<%d>" name arg)))
2213                     (arg
2214                      (generate-new-buffer name))
2215                     (t
2216                      (get-buffer-create name)))))
2217     (pop-to-buffer-same-window buf)
2218     (unless (buffer-modified-p)
2219       (elpher-mode)
2220       (elpher-visit-page (elpher-make-start-page))
2221       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2222
2223 ;;; elpher.el ends here