elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.10.3
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "2.10.3"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  99     ((special start) elpher-get-start-page nil))
 100   "Association list from types to getters, renderers, margin codes and index faces.")
 101
 102
 103 ;;; Customization group
 104 ;;
 105
 106 (defgroup elpher nil
 107   "A gopher and gemini client."
 108   :group 'applications)
 109
 110 ;; General appearance and customizations
 111
 112 (defcustom elpher-open-urls-with-eww nil
 113   "If non-nil, open URL selectors using eww.
 114 Otherwise, use the system browser via the BROWSE-URL function."
 115   :type '(boolean))
 116
 117 (defcustom elpher-use-header t
 118   "If non-nil, display current page information in buffer header."
 119   :type '(boolean))
 120
 121 (defcustom elpher-auto-disengage-TLS nil
 122   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 123 While enabling this may seem convenient, it is also potentially dangerous as it
 124 allows switching from an encrypted channel back to plain text without user input."
 125   :type '(boolean))
 126
 127 (defcustom elpher-connection-timeout 5
 128   "Specifies the number of seconds to wait for a network connection to time out."
 129   :type '(integer))
 130
 131 (defcustom elpher-filter-ansi-from-text nil
 132   "If non-nil, filter ANSI escape sequences from text.
 133 The default behaviour is to use the ansi-color package to interpret these
 134 sequences."
 135   :type '(boolean))
 136
 137 (defcustom elpher-certificate-directory
 138   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 139   "Specify the name of the directory where client certificates will be stored.
 140 These certificates may be used for establishing authenticated TLS connections."
 141   :type '(directory))
 142
 143 (defcustom elpher-openssl-command "openssl"
 144   "The command used to launch openssl when generating TLS client certificates."
 145   :type '(file))
 146
 147 (defcustom elpher-gemini-TLS-cert-checks nil
 148   "If non-nil, verify gemini server TLS certs using the default security level.
 149 Otherwise, certificate verification is disabled.
 150
 151 This defaults to off because it is standard practice for Gemini servers
 152 to use self-signed certificates, meaning that most servers provide what
 153 EMACS considers to be an invalid certificate."
 154   :type '(boolean))
 155
 156 (defcustom elpher-gemini-max-fill-width 80
 157   "Specify the maximum default width (in columns) of text/gemini documents.
 158 The actual width used is the minimum of this value and the window width at
 159 the time when the text is rendered."
 160   :type '(integer))
 161
 162 (defcustom elpher-gemini-link-string "→ "
 163   "Specify the string used to indicate links when rendering gemini maps.
 164 May be empty."
 165   :type '(string))
 166
 167 (defcustom elpher-gemini-bullet-string "•"
 168   "Specify the string used for bullets when rendering gemini maps."
 169   :type '(string))
 170
 171 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 172   "Specify the name of the file where elpher bookmarks will be saved."
 173   :type '(file))
 174
 175 (defcustom elpher-ipv4-always nil
 176   "If non-nil, elpher will always use IPv4 to establish network connections.
 177 This can be useful when browsing from a computer that supports IPv6, because
 178 some servers which do not support IPv6 can take a long time to time-out."
 179   :type '(boolean))
 180
 181 ;; Face customizations
 182
 183 (defgroup elpher-faces nil
 184   "Elpher face customizations."
 185   :group 'elpher)
 186
 187 (defface elpher-index
 188   '((t :inherit font-lock-keyword-face))
 189   "Face used for directory type directory records.")
 190
 191 (defface elpher-text
 192   '((t :inherit bold))
 193   "Face used for text type directory records.")
 194
 195 (defface elpher-info
 196   '((t :inherit default))
 197   "Face used for info type directory records.")
 198
 199 (defface elpher-image
 200   '((t :inherit font-lock-string-face))
 201   "Face used for image type directory records.")
 202
 203 (defface elpher-search
 204   '((t :inherit warning))
 205   "Face used for search type directory records.")
 206
 207 (defface elpher-html
 208   '((t :inherit font-lock-comment-face))
 209   "Face used for html type directory records.")
 210
 211 (defface elpher-gemini
 212   '((t :inherit font-lock-constant-face))
 213   "Face used for Gemini type directory records.")
 214
 215 (defface elpher-other-url
 216   '((t :inherit font-lock-comment-face))
 217   "Face used for other URL type links records.")
 218
 219 (defface elpher-telnet
 220   '((t :inherit font-lock-function-name-face))
 221   "Face used for telnet type directory records.")
 222
 223 (defface elpher-binary
 224   '((t :inherit font-lock-doc-face))
 225   "Face used for binary type directory records.")
 226
 227 (defface elpher-unknown
 228   '((t :inherit error))
 229   "Face used for directory records with unknown/unsupported types.")
 230
 231 (defface elpher-margin-key
 232   '((t :inherit bold))
 233   "Face used for directory margin key.")
 234
 235 (defface elpher-margin-brackets
 236   '((t :inherit shadow))
 237   "Face used for brackets around directory margin key.")
 238
 239 (defface elpher-gemini-heading1
 240   '((t :inherit bold :height 1.8))
 241   "Face used for gemini heading level 1.")
 242
 243 (defface elpher-gemini-heading2
 244   '((t :inherit bold :height 1.5))
 245   "Face used for gemini heading level 2.")
 246
 247 (defface elpher-gemini-heading3
 248   '((t :inherit bold :height 1.2))
 249   "Face used for gemini heading level 3.")
 250
 251 (defface elpher-gemini-preformatted
 252   '((t :inherit fixed-pitch))
 253   "Face used for pre-formatted gemini text blocks.")
 254
 255 ;;; Model
 256 ;;
 257
 258 ;; Address
 259
 260 ;; An elpher "address" object is either a url object or a symbol.
 261 ;; Symbol addresses are "special", corresponding to pages generated
 262 ;; dynamically for and by elpher.  All others represent pages which
 263 ;; rely on content retrieved over the network.
 264
 265 (defun elpher-address-from-url (url-string)
 266   "Create a ADDRESS object corresponding to the given URL-STRING."
 267   (let ((data (match-data))) ; Prevent parsing clobbering match data
 268     (unwind-protect
 269         (let ((url (url-generic-parse-url url-string)))
 270           (unless (and (not (url-fullness url)) (url-type url))
 271             (setf (url-fullness url) t)
 272             (setf (url-filename url)
 273                   (url-unhex-string (url-filename url)))
 274             (unless (url-type url)
 275               (setf (url-type url) "gopher"))
 276             (when (or (equal "gopher" (url-type url))
 277                       (equal "gophers" (url-type url)))
 278               ;; Gopher defaults
 279               (unless (url-host url)
 280                 (setf (url-host url) (url-filename url))
 281                 (setf (url-filename url) ""))
 282               (when (or (equal (url-filename url) "")
 283                         (equal (url-filename url) "/"))
 284                 (setf (url-filename url) "/1")))
 285             (when (equal "gemini" (url-type url))
 286               ;; Gemini defaults
 287               (if (equal (url-filename url) "")
 288                   (setf (url-filename url) "/"))))
 289           (elpher-remove-redundant-ports url))
 290       (set-match-data data))))
 291
 292 (defun elpher-remove-redundant-ports (address)
 293   "Remove redundant port specifiers from ADDRESS.
 294 Here 'redundant' means that the specified port matches the default
 295 for that protocol, eg 70 for gopher."
 296   (if (and (not (elpher-address-special-p address))
 297            (eq (url-portspec address) ; (url-port) is too slow!
 298                (pcase (url-type address)
 299                  ("gemini" 1965)
 300                  ((or "gopher" "gophers") 70)
 301                  ("finger" 79)
 302                  (_ -1))))
 303       (setf (url-portspec address) nil))
 304   address)
 305
 306 (defun elpher-make-gopher-address (type selector host port &optional tls)
 307   "Create an ADDRESS object using gopher directory record attributes.
 308 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 309 If the optional attribute TLS is non-nil, the address will be marked as
 310 requiring gopher-over-TLS."
 311   (cond
 312    ((equal type ?i) nil)
 313    ((and (equal type ?h)
 314          (string-prefix-p "URL:" selector))
 315     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 316    ((equal type ?8)
 317     (elpher-address-from-url
 318      (concat "telnet"
 319              "://" host
 320              ":" (number-to-string port))))
 321    (t
 322     (elpher-address-from-url
 323      (concat "gopher" (if tls "s" "")
 324              "://" host
 325              ":" (number-to-string port)
 326              "/" (string type)
 327              selector)))))
 328
 329 (defun elpher-make-special-address (type)
 330   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 331   type)
 332
 333 (defun elpher-address-to-url (address)
 334   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 335   (if (elpher-address-special-p address)
 336       nil
 337     (url-encode-url (url-recreate-url address))))
 338
 339 (defun elpher-address-type (address)
 340   "Retrieve type of ADDRESS object.
 341 This is used to determine how to retrieve and render the document the
 342 address refers to, via the table `elpher-type-map'."
 343   (if (symbolp address)
 344       (list 'special address)
 345     (let ((protocol (url-type address)))
 346       (cond ((or (equal protocol "gopher")
 347                  (equal protocol "gophers"))
 348              (list 'gopher
 349                    (if (member (url-filename address) '("" "/"))
 350                        ?1
 351                      (string-to-char (substring (url-filename address) 1)))))
 352             ((equal protocol "gemini")
 353              'gemini)
 354             ((equal protocol "telnet")
 355              'telnet)
 356             ((equal protocol "finger")
 357              'finger)
 358             (t 'other-url)))))
 359
 360 (defun elpher-address-protocol (address)
 361   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 362   (if (symbolp address)
 363       nil
 364     (url-type address)))
 365
 366 (defun elpher-address-filename (address)
 367   "Retrieve the filename component of ADDRESS.
 368 For gopher addresses this is a combination of the selector type and selector."
 369   (if (symbolp address)
 370       nil
 371     (url-filename address)))
 372
 373 (defun elpher-address-host (address)
 374   "Retrieve host from ADDRESS object."
 375   (url-host address))
 376
 377 (defun elpher-address-user (address)
 378   "Retrieve user from ADDRESS object."
 379   (url-user address))
 380
 381 (defun elpher-address-port (address)
 382   "Retrieve port from ADDRESS object.
 383 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 384   (if (symbolp address)
 385       0
 386     (url-port address)))
 387
 388 (defun elpher-address-special-p (address)
 389   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 390   (symbolp address))
 391
 392 (defun elpher-address-gopher-p (address)
 393   "Return non-nill if ADDRESS object is a gopher address."
 394   (and (not (elpher-address-special-p address))
 395        (member (elpher-address-protocol address) '("gopher gophers"))))
 396
 397 (defun elpher-gopher-address-selector (address)
 398   "Retrieve gopher selector from ADDRESS object."
 399   (if (member (url-filename address) '("" "/"))
 400       ""
 401     (url-unhex-string (substring (url-filename address) 2))))
 402
 403
 404 ;; Cache
 405
 406 (defvar elpher-content-cache (make-hash-table :test 'equal))
 407 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 408
 409 (defun elpher-get-cached-content (address)
 410   "Retrieve the cached content for ADDRESS, or nil if none exists."
 411   (gethash address elpher-content-cache))
 412
 413 (defun elpher-cache-content (address content)
 414   "Set the content cache for ADDRESS to CONTENT."
 415   (puthash address content elpher-content-cache))
 416
 417 (defun elpher-get-cached-pos (address)
 418   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 419   (gethash address elpher-pos-cache))
 420
 421 (defun elpher-cache-pos (address pos)
 422   "Set the cursor position cache for ADDRESS to POS."
 423   (puthash address pos elpher-pos-cache))
 424
 425
 426 ;; Page
 427
 428 (defun elpher-make-page (display-string address)
 429   "Create a page with DISPLAY-STRING and ADDRESS."
 430   (list display-string address))
 431
 432 (defun elpher-page-display-string (page)
 433   "Retrieve the display string corresponding to PAGE."
 434   (elt page 0))
 435
 436 (defun elpher-page-address (page)
 437   "Retrieve the address corresponding to PAGE."
 438   (elt page 1))
 439
 440 (defun elpher-page-set-address (page new-address)
 441   "Set the address corresponding to PAGE to NEW-ADDRESS."
 442   (setcar (cdr page) new-address))
 443
 444 (defvar elpher-current-page nil)
 445 (defvar elpher-history nil)
 446
 447 (defun elpher-visit-page (page &optional renderer no-history)
 448   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 449 Additionally, push PAGE onto the stack of previously-visited pages,
 450 unless NO-HISTORY is non-nil."
 451   (elpher-save-pos)
 452   (elpher-process-cleanup)
 453   (unless (or no-history
 454               (equal (elpher-page-address elpher-current-page)
 455                      (elpher-page-address page)))
 456     (push elpher-current-page elpher-history))
 457   (setq elpher-current-page page)
 458   (let* ((address (elpher-page-address page))
 459          (type (elpher-address-type address))
 460          (type-record (cdr (assoc type elpher-type-map))))
 461     (if type-record
 462         (funcall (car type-record)
 463                  (if renderer
 464                      renderer
 465                    (cadr type-record)))
 466       (elpher-visit-previous-page)
 467       (pcase type
 468         (`(gopher ,type-char)
 469          (error "Unsupported gopher selector type '%c' for '%s'"
 470                 type-char (elpher-address-to-url address)))
 471         (other
 472          (error "Unsupported address type '%S' for '%s'"
 473                 other (elpher-address-to-url address)))))))
 474
 475 (defun elpher-visit-previous-page ()
 476   "Visit the previous page in the history."
 477   (let ((previous-page (pop elpher-history)))
 478     (if previous-page
 479         (elpher-visit-page previous-page nil t)
 480       (error "No previous page"))))
 481
 482 (defun elpher-reload-current-page ()
 483   "Reload the current page, discarding any existing cached content."
 484   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 485   (elpher-visit-page elpher-current-page))
 486
 487 (defun elpher-save-pos ()
 488   "Save the current position of point to the current page."
 489   (when elpher-current-page
 490     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 491
 492 (defun elpher-restore-pos ()
 493   "Restore the position of point to that cached in the current page."
 494   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 495     (if pos
 496         (goto-char pos)
 497       (goto-char (point-min)))))
 498
 499
 500 ;;; Buffer preparation
 501 ;;
 502
 503 (defun elpher-update-header ()
 504   "If `elpher-use-header' is true, display current page info in window header."
 505   (if elpher-use-header
 506       (let* ((display-string (elpher-page-display-string elpher-current-page))
 507              (address (elpher-page-address elpher-current-page))
 508              (tls-string (if (and (not (elpher-address-special-p address))
 509                                   (member (elpher-address-protocol address)
 510                                           '("gophers" "gemini")))
 511                              " [TLS encryption]"
 512                            ""))
 513              (header (concat display-string
 514                              (propertize tls-string 'face 'bold))))
 515         (setq header-line-format header))))
 516
 517 (defmacro elpher-with-clean-buffer (&rest args)
 518   "Evaluate ARGS with a clean *elpher* buffer as current."
 519   (declare (debug (body)))
 520   (list 'with-current-buffer "*elpher*"
 521         '(elpher-mode)
 522         (append (list 'let '((inhibit-read-only t))
 523                       '(setq-local network-security-level
 524                                    (default-value 'network-security-level))
 525                       '(erase-buffer)
 526                       '(elpher-update-header))
 527                 args)))
 528
 529 (defun elpher-buffer-message (string &optional line)
 530   "Replace first line in elpher buffer with STRING.
 531 If LINE is non-nil, replace that line instead."
 532   (with-current-buffer "*elpher*"
 533     (let ((inhibit-read-only t))
 534       (goto-char (point-min))
 535       (if line
 536           (forward-line line))
 537       (let ((data (match-data)))
 538         (unwind-protect
 539             (progn
 540               (re-search-forward "^.*$")
 541               (replace-match string))
 542           (set-match-data data))))))
 543
 544
 545 ;;; Text Processing
 546 ;;
 547
 548 (defvar elpher-user-coding-system nil
 549   "User-specified coding system to use for decoding text responses.")
 550
 551 (defun elpher-decode (string)
 552   "Decode STRING using autodetected or user-specified coding system."
 553   (decode-coding-string string
 554                         (if elpher-user-coding-system
 555                             elpher-user-coding-system
 556                           (detect-coding-string string t))))
 557
 558 (defun elpher-preprocess-text-response (string)
 559   "Preprocess text selector response contained in STRING.
 560 This involes decoding the character representation, and clearing
 561 away CRs and any terminating period."
 562   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 563                                            (replace-regexp-in-string "\r" "" string))))
 564
 565
 566 ;;; Network error reporting
 567 ;;
 568
 569 (defun elpher-network-error (address error)
 570   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 571 ERROR can be either an error object or a string."
 572   (elpher-with-clean-buffer
 573    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 574            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 575            (if (stringp error) error (error-message-string error)) "\n"
 576            (propertize "\n----------------\n\n" 'face 'error)
 577            "Press 'u' to return to the previous page.")))
 578
 579
 580 ;;; General network communication
 581 ;;
 582
 583 (defvar elpher-network-timer nil
 584   "Timer used for network connections.")
 585
 586 (defvar elpher-use-tls nil
 587   "If non-nil, use TLS to communicate with gopher servers.")
 588
 589 (defvar elpher-client-certificate nil
 590   "If non-nil, contains client certificate details to use for TLS connections.")
 591
 592 (defun elpher-process-cleanup ()
 593   "Immediately shut down any extant elpher process and timers."
 594   (let ((p (get-process "elpher-process")))
 595     (if p (delete-process p)))
 596   (if (timerp elpher-network-timer)
 597       (cancel-timer elpher-network-timer)))
 598
 599 (defun elpher-get-host-response (address default-port query-string response-processor
 600                                          &optional use-tls force-ipv4)
 601   "Generic function for retrieving data from ADDRESS.
 602
 603 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 604 QUERY-STRING is a string sent to the host specified by ADDRESS to
 605 illicet a response.  This response is passed as an argument to the
 606 function RESPONSE-PROCESSOR.
 607
 608 If non-nil, USE-TLS specifies that the connection is to be made over
 609 TLS.  If set to gemini, the certificate verification will be disabled
 610 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 611
 612 If non-nil, FORCE-IPV4 causes the network connection to be made over
 613 ipv4 only.  (The default behaviour when this is not set depends on
 614 the host operating system and the local network capabilities."
 615   (if (and use-tls (not (gnutls-available-p)))
 616       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 617     (unless (< (elpher-address-port address) 65536)
 618       (error "Cannot establish network connection: port number > 65536"))
 619     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 620       (setq-local network-security-level 'low))
 621     (condition-case nil
 622         (let* ((kill-buffer-query-functions nil)
 623                (port (elpher-address-port address))
 624                (host (elpher-address-host address))
 625                (response-string-parts nil)
 626                (bytes-received 0)
 627                (hkbytes-received 0)
 628                (proc (make-network-process :name "elpher-process"
 629                                            :host host
 630                                            :family (and force-ipv4 'ipv4)
 631                                            :service (if (> port 0) port default-port)
 632                                            :buffer nil
 633                                            :coding 'binary
 634                                            :noquery t
 635                                            :nowait t
 636                                            :tls-parameters
 637                                            (and use-tls
 638                                                 (cons 'gnutls-x509pki
 639                                                       (gnutls-boot-parameters
 640                                                        :type 'gnutls-x509pki
 641                                                        :hostname host
 642                                                        :keylist
 643                                                        (elpher-get-current-keylist address))))))
 644                (timer (run-at-time elpher-connection-timeout nil
 645                                    (lambda ()
 646                                      (elpher-process-cleanup)
 647                                      (cond
 648                                         ; Try again with IPv4
 649                                       ((not force-ipv4)
 650                                        (message "Connection timed out.  Retrying with IPv4.")
 651                                        (elpher-get-host-response address default-port
 652                                                                  query-string
 653                                                                  response-processor
 654                                                                  use-tls t))
 655                                       ((and use-tls
 656                                             (not (eq use-tls 'gemini))
 657                                             (or elpher-auto-disengage-TLS
 658                                                 (y-or-n-p
 659                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 660                                        (setq elpher-use-tls nil)
 661                                        (elpher-get-host-response address default-port
 662                                                                  query-string
 663                                                                  response-processor
 664                                                                  nil force-ipv4))
 665                                       (t
 666                                        (elpher-network-error address "Connection time-out.")))))))
 667           (setq elpher-network-timer timer)
 668           (elpher-buffer-message (concat "Connecting to " host "..."
 669                                          " (press 'u' to abort)"))
 670           (set-process-filter proc
 671                               (lambda (_proc string)
 672                                 (when timer
 673                                   (cancel-timer timer)
 674                                   (setq timer nil))
 675                                 (setq bytes-received (+ bytes-received (length string)))
 676                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 677                                   (when (> new-hkbytes-received hkbytes-received)
 678                                     (setq hkbytes-received new-hkbytes-received)
 679                                     (elpher-buffer-message
 680                                         (concat "("
 681                                                 (number-to-string (/ hkbytes-received 10.0))
 682                                                 " MB read)")
 683                                         1)))
 684                                 (setq response-string-parts
 685                                       (cons string response-string-parts))))
 686           (set-process-sentinel proc
 687                                 (lambda (proc event)
 688                                   (when timer
 689                                     (cancel-timer timer))
 690                                   (condition-case the-error
 691                                       (cond
 692                                        ((string-prefix-p "open" event)    ; request URL
 693                                         (elpher-buffer-message
 694                                          (concat "Connected to " host ". Receiving data..."
 695                                                  " (press 'u' to abort)"))
 696                                         (let ((inhibit-eol-conversion t))
 697                                           (process-send-string proc query-string)))
 698                                        ((string-prefix-p "deleted" event)) ; do nothing
 699                                        ((and (not response-string-parts)
 700                                              (not (or elpher-ipv4-always force-ipv4)))
 701                                         ; Try again with IPv4
 702                                         (message "Connection failed. Retrying with IPv4.")
 703                                         (elpher-get-host-response address default-port
 704                                                                   query-string
 705                                                                   response-processor
 706                                                                   use-tls t))
 707                                        (response-string-parts
 708                                         (elpher-with-clean-buffer
 709                                          (insert "Data received.  Rendering..."))
 710                                         (funcall response-processor
 711                                                  (apply #'concat (reverse response-string-parts)))
 712                                         (elpher-restore-pos))
 713                                        (t
 714                                         (error "No response from server")))
 715                                     (error
 716                                      (elpher-network-error address the-error))))))
 717       (error
 718        (error "Error initiating connection to server")))))
 719
 720
 721 ;;; Client-side TLS Certificate Management
 722 ;;
 723
 724 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 725   "Generate a key and a self-signed client TLS certificate using openssl.
 726
 727 The Common Name field of the certificate is set to COMMON-NAME.  The
 728 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 729 the key and certificate files to write.
 730
 731 If TEMPORARY is non-nil, the certificate will be given an exporation
 732 period of one day, and the key and certificate files will be deleted
 733 when the certificate is no longer needed for the current session.
 734
 735 Otherwise, the certificate will be given a 100 year expiration period
 736 and the files will not be deleted.
 737
 738 The function returns a list containing the current host name, the
 739 temporary flag, and the key and cert file names in the form required
 740 by `gnutls-boot-parameters`."
 741   (let ((exp-key-file (expand-file-name key-file))
 742         (exp-cert-file (expand-file-name cert-file)))
 743     (condition-case nil
 744         (progn
 745           (call-process elpher-openssl-command nil nil nil
 746                         "req" "-x509" "-newkey" "rsa:2048"
 747                         "-days" (if temporary "1" "36500")
 748                         "-nodes"
 749                         "-subj" (concat "/CN=" common-name)
 750                         "-keyout" exp-key-file
 751                         "-out" exp-cert-file)
 752           (list (elpher-address-host (elpher-page-address elpher-current-page))
 753                 temporary exp-key-file exp-cert-file))
 754       (error
 755        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 756        (error "Program 'openssl', required for certificate generation, not found")))))
 757
 758 (defun elpher-generate-throwaway-certificate ()
 759   "Generate and return details of a throwaway certificate.
 760 The key and certificate files will be deleted when they are no
 761 longer needed for this session."
 762   (let* ((file-base (make-temp-name "elpher"))
 763          (key-file (concat temporary-file-directory file-base ".key"))
 764          (cert-file (concat temporary-file-directory file-base ".crt")))
 765     (elpher-generate-certificate file-base key-file cert-file t)))
 766
 767 (defun elpher-generate-persistent-certificate (file-base common-name)
 768   "Generate and return details of a persistent certificate.
 769 The argument FILE-BASE is used as the base for the key and certificate
 770 files, while COMMON-NAME specifies the common name field of the
 771 certificate.
 772
 773 The key and certificate files are written to in `elpher-certificate-directory'."
 774   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 775          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 776     (elpher-generate-certificate common-name key-file cert-file)))
 777
 778 (defun elpher-get-existing-certificate (file-base)
 779   "Return a certificate object corresponding to an existing certificate.
 780 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 781 the directory `elpher-certificate-directory'."
 782   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 783          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 784     (list (elpher-address-host (elpher-page-address elpher-current-page))
 785           nil
 786           (expand-file-name key-file)
 787           (expand-file-name cert-file))))
 788
 789 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 790   "Install a key+certificate file pair in `elpher-certificate-directory'.
 791 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 792 certificate files to install.  The argument FILE-BASE is used as the
 793 base for the installed key and certificate files."
 794   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 795          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 796     (if (or (file-exists-p key-file)
 797             (file-exists-p cert-file))
 798         (error "A certificate with base name %s is already installed" file-base))
 799     (copy-file key-file-src key-file)
 800     (copy-file cert-file-src cert-file)
 801     (list (elpher-address-host (elpher-page-address elpher-current-page))
 802           nil
 803           (expand-file-name key-file)
 804           (expand-file-name cert-file))))
 805
 806 (defun elpher-list-existing-certificates ()
 807   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 808   (unless (file-directory-p elpher-certificate-directory)
 809     (make-directory elpher-certificate-directory))
 810   (mapcar
 811    (lambda (file)
 812      (file-name-sans-extension file))
 813    (directory-files elpher-certificate-directory nil "\.key$")))
 814
 815 (defun elpher-forget-current-certificate ()
 816   "Causes any current certificate to be forgotten.)
 817 In the case of throwaway certificates, the key and certificate files
 818 are also deleted."
 819   (interactive)
 820   (when elpher-client-certificate
 821     (unless (and (called-interactively-p 'any)
 822                  (not (y-or-n-p (concat "Really forget client certificate? "
 823                                         "(Throwaway certificates will be deleted.)"))))
 824       (when (cadr elpher-client-certificate)
 825         (delete-file (elt elpher-client-certificate 2))
 826         (delete-file (elt elpher-client-certificate 3)))
 827       (setq elpher-client-certificate nil)
 828       (if (called-interactively-p 'any)
 829           (message "Client certificate forgotten.")))))
 830
 831 (defun elpher-get-current-keylist (address)
 832   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 833
 834 This is obtained from the client certificate described by
 835 `elpher-current-certificate', if one is available and the host for
 836 that certificate matches the host in ADDRESS.
 837
 838 If `elpher-current-certificate' is non-nil, and its host name doesn't
 839 match that of ADDRESS, the certificate is forgotten."
 840   (if elpher-client-certificate
 841       (if (string= (car elpher-client-certificate)
 842                    (elpher-address-host address))
 843           (list (cddr elpher-client-certificate))
 844         (elpher-forget-current-certificate)
 845         (message "Disabling client certificate for new host")
 846         nil)
 847     nil))
 848
 849
 850 ;;; Gopher selector retrieval
 851 ;;
 852
 853 (defun elpher-get-gopher-response (address renderer)
 854   "Get response string from gopher server at ADDRESS and render using RENDERER."
 855   (elpher-get-host-response address 70
 856                             (concat (elpher-gopher-address-selector address) "\r\n")
 857                             renderer
 858                             (or (string= (elpher-address-protocol address) "gophers")
 859                                 elpher-use-tls)))
 860
 861 (defun elpher-get-gopher-page (renderer)
 862   "Getter function for gopher pages.
 863 The RENDERER procedure is used to display the contents of the page
 864 once they are retrieved from the gopher server."
 865   (let* ((address (elpher-page-address elpher-current-page))
 866          (content (elpher-get-cached-content address)))
 867     (if (and content (funcall renderer nil))
 868         (elpher-with-clean-buffer
 869          (insert content)
 870          (elpher-restore-pos))
 871       (elpher-with-clean-buffer
 872        (insert "LOADING... (use 'u' to cancel)\n"))
 873       (condition-case the-error
 874           (elpher-get-gopher-response address renderer)
 875         (error
 876          (elpher-network-error address the-error))))))
 877
 878 ;; Index rendering
 879
 880 (defun elpher-insert-index (string)
 881   "Insert the index corresponding to STRING into the current buffer."
 882   ;; Should be able to split directly on CRLF, but some non-conformant
 883   ;; LF-only servers sadly exist, hence the following.
 884   (let ((str-processed (elpher-preprocess-text-response string)))
 885     (dolist (line (split-string str-processed "\n"))
 886       (ignore-errors
 887         (unless (= (length line) 0)
 888           (let* ((type (elt line 0))
 889                  (fields (split-string (substring line 1) "\t"))
 890                  (display-string (elt fields 0))
 891                  (selector (elt fields 1))
 892                  (host (elt fields 2))
 893                  (port (if (elt fields 3)
 894                            (string-to-number (elt fields 3))
 895                          nil))
 896                  (address (elpher-make-gopher-address type selector host port)))
 897             (elpher-insert-index-record display-string address)))))))
 898
 899 (defun elpher-insert-margin (&optional type-name)
 900   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 901   (if type-name
 902       (progn
 903         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 904                         (concat
 905                          (propertize "[" 'face 'elpher-margin-brackets)
 906                          (propertize type-name 'face 'elpher-margin-key)
 907                          (propertize "]" 'face 'elpher-margin-brackets))))
 908         (insert " "))
 909     (insert (make-string elpher-margin-width ?\s))))
 910
 911 (defun elpher--page-button-help (_window buffer pos)
 912   "Function called by Emacs to generate mouse-over text.
 913 The arguments specify the BUFFER and the POS within the buffer of the item
 914 for which help is required.  The function returns the help to be
 915 displayed.  The _WINDOW argument is currently unused."
 916   (with-current-buffer buffer
 917     (let ((button (button-at pos)))
 918       (when button
 919         (let* ((page (button-get button 'elpher-page))
 920                (address (elpher-page-address page)))
 921           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 922                                                 address
 923                                               (elpher-address-to-url address))))))))
 924
 925 (defun elpher-insert-index-record (display-string &optional address)
 926   "Function to insert an index record into the current buffer.
 927 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 928 If ADDRESS is not supplied or nil the record is rendered as an
 929 'information' line."
 930   (let* ((type (if address (elpher-address-type address) nil))
 931          (type-map-entry (cdr (assoc type elpher-type-map))))
 932     (if type-map-entry
 933         (let* ((margin-code (elt type-map-entry 2))
 934                (face (elt type-map-entry 3))
 935                (filtered-display-string (ansi-color-filter-apply display-string))
 936                (page (elpher-make-page filtered-display-string address)))
 937           (elpher-insert-margin margin-code)
 938           (insert-text-button filtered-display-string
 939                               'face face
 940                               'elpher-page page
 941                               'action #'elpher-click-link
 942                               'follow-link t
 943                               'help-echo #'elpher--page-button-help))
 944       (pcase type
 945         ('nil ;; Information
 946          (elpher-insert-margin)
 947          (let ((propertized-display-string
 948                 (propertize display-string 'face 'elpher-info)))
 949            (insert (elpher-process-text-for-display propertized-display-string))))
 950         (`(gopher ,selector-type) ;; Unknown
 951          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 952          (insert (propertize display-string
 953                              'face 'elpher-unknown)))))
 954     (insert "\n")))
 955
 956 (defun elpher-click-link (button)
 957   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 958   (let ((page (button-get button 'elpher-page)))
 959     (elpher-visit-page page)))
 960
 961 (defun elpher-render-index (data &optional _mime-type-string)
 962   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 963   (elpher-with-clean-buffer
 964    (if (not data)
 965        t
 966      (elpher-insert-index data)
 967      (elpher-cache-content (elpher-page-address elpher-current-page)
 968                            (buffer-string)))))
 969
 970 ;; Text rendering
 971
 972 (defconst elpher-url-regex
 973   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 974   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 975
 976 (defun elpher-buttonify-urls (string)
 977   "Turn substrings which look like urls in STRING into clickable buttons."
 978   (with-temp-buffer
 979     (insert string)
 980     (goto-char (point-min))
 981     (while (re-search-forward elpher-url-regex nil t)
 982       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 983                                     (elpher-address-from-url (match-string 0)))))
 984           (make-text-button (match-beginning 0)
 985                             (match-end 0)
 986                             'elpher-page  page
 987                             'action #'elpher-click-link
 988                             'follow-link t
 989                             'help-echo #'elpher--page-button-help
 990                             'face 'button)))
 991     (buffer-string)))
 992
 993 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 994   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 995
 996 (defun elpher-process-text-for-display (string)
 997   "Perform any desired processing of STRING prior to display as text.
 998 Currently includes buttonifying URLs and processing ANSI escape codes."
 999   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1000                              (ansi-color-filter-apply string)
1001                            (ansi-color-apply string))))
1002
1003 (defun elpher-render-text (data &optional _mime-type-string)
1004   "Render DATA as text.  MIME-TYPE-STRING is unused."
1005   (elpher-with-clean-buffer
1006    (if (not data)
1007        t
1008      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1009      (elpher-cache-content
1010       (elpher-page-address elpher-current-page)
1011       (buffer-string)))))
1012
1013 ;; Image retrieval
1014
1015 (defun elpher-render-image (data &optional _mime-type-string)
1016   "Display DATA as image.  MIME-TYPE-STRING is unused."
1017   (if (not data)
1018       nil
1019     (if (display-images-p)
1020         (progn
1021           (let ((image (create-image
1022                         data
1023                         nil t)))
1024             (elpher-with-clean-buffer
1025              (insert-image image)
1026              (elpher-restore-pos))))
1027       (elpher-render-download data))))
1028
1029 ;; Search retrieval and rendering
1030
1031 (defun elpher-get-gopher-query-page (renderer)
1032   "Getter for gopher addresses requiring input.
1033 The response is rendered using the rendering function RENDERER."
1034    (let* ((address (elpher-page-address elpher-current-page))
1035           (content (elpher-get-cached-content address))
1036           (aborted t))
1037     (if (and content (funcall renderer nil))
1038         (elpher-with-clean-buffer
1039          (insert content)
1040          (elpher-restore-pos)
1041          (message "Displaying cached search results.  Reload to perform a new search."))
1042       (unwind-protect
1043           (let* ((query-string (read-string "Query: "))
1044                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1045                  (search-address (elpher-make-gopher-address ?1
1046                                                              query-selector
1047                                                              (elpher-address-host address)
1048                                                              (elpher-address-port address)
1049                                                              (equal (elpher-address-type address) "gophers"))))
1050             (setq aborted nil)
1051
1052             (elpher-with-clean-buffer
1053              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1054             (elpher-get-gopher-response search-address renderer))
1055         (if aborted
1056             (elpher-visit-previous-page))))))
1057
1058 ;; Raw server response rendering
1059
1060 (defun elpher-render-raw (data &optional mime-type-string)
1061   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1062   (if (not data)
1063       nil
1064     (elpher-with-clean-buffer
1065      (when mime-type-string
1066        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1067      (insert data)
1068      (goto-char (point-min)))
1069     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1070
1071 ;; File save "rendering"
1072
1073 (defun elpher-render-download (data &optional _mime-type-string)
1074   "Save DATA to file.  MIME-TYPE-STRING is unused."
1075   (if (not data)
1076       nil
1077     (let* ((address (elpher-page-address elpher-current-page))
1078            (selector (if (elpher-address-gopher-p address)
1079                          (elpher-gopher-address-selector address)
1080                        (elpher-address-filename address))))
1081       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1082       (let* ((filename-proposal (file-name-nondirectory selector))
1083              (filename (read-file-name "Download complete. Save file as: "
1084                                        nil nil nil
1085                                        (if (> (length filename-proposal) 0)
1086                                            filename-proposal
1087                                          "download.file"))))
1088         (let ((coding-system-for-write 'binary))
1089           (with-temp-file filename
1090             (insert data)))
1091         (message (format "Saved to file %s." filename))))))
1092
1093 ;; HTML rendering
1094
1095 (defun elpher-render-html (data &optional _mime-type-string)
1096   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1097   (elpher-with-clean-buffer
1098    (if (not data)
1099        t
1100      (let ((dom (with-temp-buffer
1101                   (insert data)
1102                   (libxml-parse-html-region (point-min) (point-max)))))
1103        (shr-insert-document dom)))))
1104
1105 ;; Gemini page retrieval
1106
1107 (defvar elpher-gemini-redirect-chain)
1108
1109 (defun elpher-get-gemini-response (address renderer)
1110   "Get response string from gemini server at ADDRESS and render using RENDERER."
1111   (elpher-get-host-response address 1965
1112                             (concat (elpher-address-to-url address) "\r\n")
1113                             (lambda (response-string)
1114                               (elpher-process-gemini-response response-string renderer))
1115                             'gemini))
1116
1117 (defun elpher-parse-gemini-response (response)
1118   "Parse the RESPONSE string and return a list of components.
1119 The list is of the form (code meta body).  A response of nil implies
1120 that the response was malformed."
1121   (let ((header-end-idx (string-match "\r\n" response)))
1122     (if header-end-idx
1123         (let ((header (string-trim (substring response 0 header-end-idx)))
1124               (body (substring response (+ header-end-idx 2))))
1125           (if (>= (length header) 2)
1126               (let ((code (substring header 0 2))
1127                     (meta (string-trim (substring header 2))))
1128                 (list code meta body))
1129             (error "Malformed response: No response status found in header %s" header)))
1130       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1131
1132 (defun elpher-process-gemini-response (response-string renderer)
1133   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1134   (let ((response-components (elpher-parse-gemini-response response-string)))
1135     (let ((response-code (elt response-components 0))
1136           (response-meta (elt response-components 1))
1137           (response-body (elt response-components 2)))
1138       (pcase (elt response-code 0)
1139         (?1 ; Input required
1140          (elpher-with-clean-buffer
1141           (insert "Gemini server is requesting input."))
1142          (let* ((query-string
1143                  (if (eq (elt response-code 1) ?1)
1144                      (read-passwd (concat response-meta ": "))
1145                    (read-string (concat response-meta ": "))))
1146                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1147                 (old-fname (url-filename query-address)))
1148            (setf (url-filename query-address)
1149                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1150            (elpher-get-gemini-response query-address renderer)))
1151         (?2 ; Normal response
1152          (funcall renderer response-body response-meta))
1153         (?3 ; Redirect
1154          (message "Following redirect to %s" response-meta)
1155          (if (>= (length elpher-gemini-redirect-chain) 5)
1156              (error "More than 5 consecutive redirects followed"))
1157          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1158            (if (member redirect-address elpher-gemini-redirect-chain)
1159                (error "Redirect loop detected"))
1160            (if (not (string= (elpher-address-protocol redirect-address)
1161                              "gemini"))
1162                (error "Server tried to automatically redirect to non-gemini URL: %s"
1163                       response-meta))
1164            (elpher-page-set-address elpher-current-page redirect-address)
1165            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1166            (elpher-get-gemini-response redirect-address renderer)))
1167         (?4 ; Temporary failure
1168          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1169                 response-code response-meta))
1170         (?5 ; Permanent failure
1171          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1172                 response-code response-meta))
1173         (?6 ; Client certificate required
1174          (elpher-with-clean-buffer
1175           (if elpher-client-certificate
1176               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1177             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1178           (auto-fill-mode 1)
1179           (elpher-gemini-insert-text response-meta))
1180          (let ((chosen-certificate (elpher-choose-client-certificate)))
1181            (unless chosen-certificate
1182              (error "Gemini server requires a client certificate and none was provided"))
1183            (setq elpher-client-certificate chosen-certificate))
1184          (elpher-with-clean-buffer)
1185          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1186         (_other
1187          (error "Gemini server response unknown: %s %s"
1188                 response-code response-meta))))))
1189
1190 (defun elpher-choose-client-certificate ()
1191   "Prompt for a client certificate to use to establish a TLS connection."
1192   (let* ((read-answer-short t))
1193     (pcase (read-answer "What do you want to do? "
1194                         '(("throwaway" ?t
1195                            "generate and use throw-away certificate")
1196                           ("persistent" ?p
1197                            "generate new or use existing persistent certificate")
1198                           ("abort" ?a
1199                            "stop immediately")))
1200       ("throwaway"
1201        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1202       ("persistent"
1203        (let* ((existing-certificates (elpher-list-existing-certificates))
1204               (file-base (completing-read
1205                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1206                           existing-certificates)))
1207          (if (string-empty-p (string-trim file-base))
1208              nil
1209            (if (member file-base existing-certificates)
1210                (setq elpher-client-certificate
1211                      (elpher-get-existing-certificate file-base))
1212              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1213                                  '(("new" ?n
1214                                     "generate new certificate")
1215                                    ("install" ?i
1216                                     "install existing certificate")
1217                                    ("abort" ?a
1218                                     "stop immediately")))
1219                ("new"
1220                 (let ((common-name (read-string "Common Name field for new certificate: "
1221                                                 file-base)))
1222                   (message "New key and self-signed certificate written to %s"
1223                            elpher-certificate-directory)
1224                   (elpher-generate-persistent-certificate file-base common-name)))
1225                ("install"
1226                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1227                        (key-file (read-file-name "Key file: " nil nil t)))
1228                   (message "Key and certificate installed in %s for future use"
1229                            elpher-certificate-directory)
1230                   (elpher-install-and-use-existing-certificate key-file
1231                                                                cert-file
1232                                                                file-base)))
1233                ("abort" nil))))))
1234       ("abort" nil))))
1235
1236 (defun elpher-get-gemini-page (renderer)
1237   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1238   (let* ((address (elpher-page-address elpher-current-page))
1239          (content (elpher-get-cached-content address)))
1240     (condition-case the-error
1241         (if (and content (funcall renderer nil))
1242             (elpher-with-clean-buffer
1243               (insert content)
1244               (elpher-restore-pos))
1245           (elpher-with-clean-buffer
1246            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1247           (setq elpher-gemini-redirect-chain nil)
1248           (elpher-get-gemini-response address renderer))
1249       (error
1250        (elpher-network-error address the-error)))))
1251
1252 (defun elpher-render-gemini (body &optional mime-type-string)
1253   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1254   (if (not body)
1255       t
1256     (let* ((mime-type-string* (if (or (not mime-type-string)
1257                                       (string-empty-p mime-type-string))
1258                                   "text/gemini; charset=utf-8"
1259                                 mime-type-string))
1260            (mime-type-split (split-string mime-type-string* ";" t))
1261            (mime-type (string-trim (car mime-type-split)))
1262            (parameters (mapcar (lambda (s)
1263                                  (let ((key-val (split-string s "=")))
1264                                    (list (downcase (string-trim (car key-val)))
1265                                          (downcase (string-trim (cadr key-val))))))
1266                                (cdr mime-type-split))))
1267       (when (string-prefix-p "text/" mime-type)
1268         (setq body (decode-coding-string
1269                     body
1270                     (if (assoc "charset" parameters)
1271                         (intern (cadr (assoc "charset" parameters)))
1272                       'utf-8)))
1273         (setq body (replace-regexp-in-string "\r" "" body)))
1274       (pcase mime-type
1275         ((or "text/gemini" "")
1276          (elpher-render-gemini-map body parameters))
1277         ("text/html"
1278          (elpher-render-html body))
1279         ((pred (string-prefix-p "text/"))
1280          (elpher-render-gemini-plain-text body parameters))
1281         ((pred (string-prefix-p "image/"))
1282          (elpher-render-image body))
1283         (_other
1284          (elpher-render-download body))))))
1285
1286 (defun elpher-gemini-get-link-url (link-line)
1287   "Extract the url portion of LINK-LINE, a gemini map file link line.
1288 Returns nil in the event that the contents of the line following the
1289 => prefix are empty."
1290   (let ((l (split-string (substring link-line 2))))
1291     (if l
1292         (string-trim (elt l 0))
1293       nil)))
1294
1295 (defun elpher-gemini-get-link-display-string (link-line)
1296   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1297 Returns the url portion in the event that the display-string portion is empty."
1298   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1299          (idx (string-match "[ \t]" rest)))
1300     (string-trim (if idx
1301                      (substring rest (+ idx 1))
1302                    rest))))
1303
1304 (defun elpher-collapse-dot-sequences (filename)
1305   "Collapse dot sequences in FILENAME.
1306 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1307   (let* ((path (split-string filename "/"))
1308          (path-reversed-normalized
1309           (seq-reduce (lambda (a b)
1310                         (cond ((and a (equal b "..") (cdr a)))
1311                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1312                               ((equal b ".") a)
1313                               (t (cons b a))))
1314                       path nil)))
1315     (string-join (reverse path-reversed-normalized) "/")))
1316
1317 (defun elpher-address-from-gemini-url (url)
1318   "Extract address from URL with defaults as per gemini map files.
1319 While there's obviously some redundancy here between this function and
1320 `elpher-address-from-url', gemini map file URLs require enough special
1321 treatment that a separate function is warranted."
1322   (let ((address (url-generic-parse-url url))
1323         (current-address (elpher-page-address elpher-current-page)))
1324     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1325       (setf (url-fullness address) t)
1326       (if (url-host address) ;if there is an explicit host, filenames are absolute
1327           (if (string-empty-p (url-filename address))
1328               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1329         (setf (url-host address) (url-host current-address))
1330         (setf (url-port address) (url-port current-address))
1331         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1332           (setf (url-filename address)
1333                 (concat (file-name-directory (url-filename current-address))
1334                         (url-filename address)))))
1335       (unless (url-type address)
1336         (setf (url-type address) "gemini"))
1337       (when (equal (url-type address) "gemini")
1338         (setf (url-filename address)
1339               (elpher-collapse-dot-sequences (url-filename address)))))
1340     (elpher-remove-redundant-ports address)))
1341
1342 (defun elpher-gemini-insert-link (link-line)
1343   "Insert link described by LINK-LINE into a text/gemini document."
1344   (let* ((url (elpher-gemini-get-link-url link-line))
1345          (display-string (elpher-gemini-get-link-display-string link-line))
1346          (address (elpher-address-from-gemini-url url))
1347          (type (if address (elpher-address-type address) nil))
1348          (type-map-entry (cdr (assoc type elpher-type-map))))
1349     (when display-string
1350       (insert elpher-gemini-link-string)
1351       (if type-map-entry
1352           (let* ((face (elt type-map-entry 3))
1353                  (filtered-display-string (ansi-color-filter-apply display-string))
1354                  (page (elpher-make-page filtered-display-string address)))
1355             (insert-text-button filtered-display-string
1356                                 'face face
1357                                 'elpher-page page
1358                                 'action #'elpher-click-link
1359                                 'follow-link t
1360                                 'help-echo #'elpher--page-button-help))
1361         (insert (propertize display-string 'face 'elpher-unknown)))
1362       (insert "\n"))))
1363
1364 (defun elpher-gemini-insert-header (header-line)
1365   "Insert header described by HEADER-LINE into a text/gemini document.
1366 The gemini map file line describing the header is given
1367 by HEADER-LINE."
1368   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1369     (let* ((level (length (match-string 1 header-line)))
1370            (header (substring header-line (match-end 0)))
1371            (face (pcase level
1372                    (1 'elpher-gemini-heading1)
1373                    (2 'elpher-gemini-heading2)
1374                    (3 'elpher-gemini-heading3)
1375                    (_ 'default)))
1376            (fill-column (if (display-graphic-p)
1377                             (/ (* fill-column
1378                                   (font-get (font-spec :name (face-font 'default)) :size))
1379                                (font-get (font-spec :name (face-font face)) :size))
1380                           fill-column)))
1381       (unless (display-graphic-p)
1382         (insert (make-string level ?#) " "))
1383       (insert (propertize header 'face face))
1384       (newline))))
1385
1386 (defun elpher-gemini-insert-text (text-line)
1387   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1388 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1389 width defined by elpher-gemini-max-fill-width."
1390   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1391   (let* ((processed-text-line (if (match-string 2 text-line)
1392                                   (concat
1393                                    (replace-regexp-in-string "\*"
1394                                                              elpher-gemini-bullet-string
1395                                                              (match-string 0 text-line))
1396                                    (substring text-line (match-end 0)))
1397                                 text-line))
1398          (adaptive-fill-mode nil)
1399          (fill-prefix (if (match-string 2 text-line)
1400                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1401                         nil)))
1402     (insert (elpher-process-text-for-display processed-text-line))
1403     (newline)))
1404
1405 (defun elpher-render-gemini-map (data _parameters)
1406   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1407   (elpher-with-clean-buffer
1408    (let ((preformatted nil))
1409      (auto-fill-mode 1)
1410      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1411      (dolist (line (split-string data "\n"))
1412        (cond
1413         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1414         (preformatted (insert (elpher-process-text-for-display
1415                                (propertize line 'face 'elpher-gemini-preformatted))
1416                               "\n"))
1417         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1418         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1419         (t (elpher-gemini-insert-text line)))))
1420    (elpher-cache-content
1421     (elpher-page-address elpher-current-page)
1422     (buffer-string))))
1423
1424 (defun elpher-render-gemini-plain-text (data _parameters)
1425   "Render DATA as plain text file.  PARAMETERS is currently unused."
1426   (elpher-with-clean-buffer
1427    (insert (elpher-process-text-for-display data))
1428    (elpher-cache-content
1429     (elpher-page-address elpher-current-page)
1430     (buffer-string))))
1431
1432
1433 ;; Finger page connection
1434
1435 (defun elpher-get-finger-page (renderer)
1436   "Opens a finger connection to the current page address.
1437 The result is rendered using RENDERER."
1438   (let* ((address (elpher-page-address elpher-current-page))
1439          (content (elpher-get-cached-content address)))
1440     (if (and content (funcall renderer nil))
1441         (elpher-with-clean-buffer
1442          (insert content)
1443          (elpher-restore-pos))
1444       (elpher-with-clean-buffer
1445        (insert "LOADING... (use 'u' to cancel)\n"))
1446       (condition-case the-error
1447           (let* ((kill-buffer-query-functions nil)
1448                  (user (let ((filename (elpher-address-filename address)))
1449                          (if (> (length filename) 1)
1450                              (substring filename 1)
1451                            (elpher-address-user address)))))
1452             (elpher-get-host-response address 79
1453                                       (concat user "\r\n")
1454                                       renderer))
1455         (error
1456          (elpher-network-error address the-error))))))
1457
1458
1459 ;; Telnet page connection
1460
1461 (defun elpher-get-telnet-page (renderer)
1462   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1463   (when renderer
1464     (elpher-visit-previous-page)
1465     (error "Command not supported for telnet URLs"))
1466   (let* ((address (elpher-page-address elpher-current-page))
1467          (host (elpher-address-host address))
1468          (port (elpher-address-port address)))
1469     (elpher-visit-previous-page)
1470     (if (> port 0)
1471         (telnet host port)
1472       (telnet host))))
1473
1474
1475 ;; Other URL page opening
1476
1477 (defun elpher-get-other-url-page (renderer)
1478   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1479   (when renderer
1480     (elpher-visit-previous-page)
1481     (error "Command not supported for general URLs"))
1482   (let* ((address (elpher-page-address elpher-current-page))
1483          (url (elpher-address-to-url address)))
1484     (progn
1485       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1486       (message "Opening URL...")
1487       (if elpher-open-urls-with-eww
1488           (browse-web url)
1489         (browse-url url)))))
1490
1491
1492 ;; Start page page retrieval
1493
1494 (defun elpher-get-start-page (renderer)
1495   "Getter which displays the start page (RENDERER must be nil)."
1496   (when renderer
1497     (elpher-visit-previous-page)
1498     (error "Command not supported for start page"))
1499   (elpher-with-clean-buffer
1500    (insert "     --------------------------------------------\n"
1501            "           Elpher Gopher and Gemini Client       \n"
1502            "                   version " elpher-version "\n"
1503            "     --------------------------------------------\n"
1504            "\n"
1505            "Default bindings:\n"
1506            "\n"
1507            " - TAB/Shift-TAB: next/prev item on current page\n"
1508            " - RET/mouse-1: open item under cursor\n"
1509            " - m: select an item on current page by name (autocompletes)\n"
1510            " - u/mouse-3/U: return to previous page or to the start page\n"
1511            " - o/O: visit different selector or the root menu of the current server\n"
1512            " - g: go to a particular address (gopher, gemini, finger)\n"
1513            " - d/D: download item under cursor or current page\n"
1514            " - i/I: info on item under cursor or current page\n"
1515            " - c/C: copy URL representation of item under cursor or current page\n"
1516            " - a/A: bookmark the item under cursor or current page\n"
1517            " - x/X: remove bookmark for item under cursor or current page\n"
1518            " - B: visit the bookmarks page\n"
1519            " - r: redraw current page (using cached contents if available)\n"
1520            " - R: reload current page (regenerates cache)\n"
1521            " - S: set character coding system for gopher (default is to autodetect)\n"
1522            " - T: toggle TLS gopher mode\n"
1523            " - F: forget/discard current TLS client certificate\n"
1524            " - .: display the raw server response for the current page\n"
1525            "\n"
1526            "Start your exploration of gopher space and gemini:\n")
1527    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1528                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1529    (elpher-insert-index-record "Project Gemini home page"
1530                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1531    (insert "\n"
1532            "Alternatively, select a search engine and enter some search terms:\n")
1533    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1534                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1535    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1536                                (elpher-address-from-url "gemini://geminispace.info/search"))
1537    (insert "\n"
1538            "This page contains your bookmarked sites (also visit with B):\n")
1539    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1540    (insert "\n"
1541            "For Elpher release news or to leave feedback, visit:\n")
1542    (elpher-insert-index-record "The Elpher Project Page"
1543                                (elpher-make-gopher-address ?1
1544                                                            "/projects/elpher/"
1545                                                            "thelambdalab.xyz"
1546                                                            70))
1547    (insert "\n"
1548            "** Refer to the ")
1549    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1550      (insert-text-button "Elpher info manual"
1551                          'face 'link
1552                          'action (lambda (_)
1553                                    (interactive)
1554                                    (info "(elpher)"))
1555                          'follow-link t
1556                          'help-echo help-string))
1557    (insert " for the full documentation. **\n")
1558    (insert (propertize
1559             (concat "  (This should be available if you have installed Elpher using\n"
1560                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1561             'face 'shadow))
1562    (elpher-restore-pos)))
1563
1564 ;; Bookmarks page page retrieval
1565
1566 (defun elpher-get-bookmarks-page (renderer)
1567   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1568   (when renderer
1569     (elpher-visit-previous-page)
1570     (error "Command not supported for bookmarks page"))
1571   (elpher-with-clean-buffer
1572    (insert "---- Bookmark list ----\n\n")
1573    (let ((bookmarks (elpher-load-bookmarks)))
1574      (if bookmarks
1575          (dolist (bookmark bookmarks)
1576            (let ((display-string (elpher-bookmark-display-string bookmark))
1577                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1578              (elpher-insert-index-record display-string address)))
1579        (insert "No bookmarks found.\n")))
1580    (insert "\n-----------------------\n"
1581            "\n"
1582            "- u: return to previous page\n"
1583            "- x: delete selected bookmark\n"
1584            "- a: rename selected bookmark\n"
1585            "\n"
1586            "Bookmarks are stored in the file ")
1587    (let ((filename elpher-bookmarks-file)
1588          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1589      (insert-text-button filename
1590                          'face 'link
1591                          'action (lambda (_)
1592                                    (interactive)
1593                                    (find-file filename))
1594                          'follow-link t
1595                          'help-echo help-string))
1596    (insert "\n")
1597    (elpher-restore-pos)))
1598
1599
1600 ;;; Bookmarks
1601 ;;
1602
1603 (defun elpher-make-bookmark (display-string url)
1604   "Make an elpher bookmark.
1605 DISPLAY-STRING determines how the bookmark will appear in the
1606 bookmark list, while URL is the url of the entry."
1607   (list display-string url))
1608
1609 (defun elpher-bookmark-display-string (bookmark)
1610   "Get the display string of BOOKMARK."
1611   (elt bookmark 0))
1612
1613 (defun elpher-set-bookmark-display-string (bookmark display-string)
1614   "Set the display string of BOOKMARK to DISPLAY-STRING."
1615   (setcar bookmark display-string))
1616
1617 (defun elpher-bookmark-url (bookmark)
1618   "Get the address for BOOKMARK."
1619   (elt bookmark 1))
1620
1621 (defun elpher-save-bookmarks (bookmarks)
1622   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1623 Beware that this completely replaces the existing contents of the file."
1624   (with-temp-file elpher-bookmarks-file
1625     (erase-buffer)
1626     (insert "; Elpher bookmarks file\n\n"
1627             "; Bookmarks are stored as a list of (label URL) items.\n"
1628             "; Feel free to edit by hand, but take care to ensure\n"
1629             "; the list structure remains intact.\n\n")
1630     (pp bookmarks (current-buffer))))
1631
1632 (defun elpher-load-bookmarks ()
1633   "Get the list of bookmarks from the users's bookmark file."
1634   (let ((bookmarks
1635          (with-temp-buffer
1636            (ignore-errors
1637              (insert-file-contents elpher-bookmarks-file)
1638              (goto-char (point-min))
1639              (read (current-buffer))))))
1640     (if (and bookmarks (listp (cadar bookmarks)))
1641         (progn
1642           (message "Reading old bookmark file. (Will be updated on write.)")
1643           (mapcar (lambda (old-bm)
1644                     (list (car old-bm)
1645                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1646                                                         (cadr old-bm)))))
1647                   bookmarks))
1648       bookmarks)))
1649
1650 (defun elpher-add-address-bookmark (address display-string)
1651   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1652 If ADDRESS is already bookmarked, update the label only."
1653   (let ((bookmarks (elpher-load-bookmarks))
1654         (url (elpher-address-to-url address)))
1655     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1656       (if existing-bookmark
1657           (elpher-set-bookmark-display-string existing-bookmark display-string)
1658         (push (elpher-make-bookmark display-string url) bookmarks)))
1659     (elpher-save-bookmarks bookmarks)))
1660
1661 (defun elpher-remove-address-bookmark (address)
1662   "Remove any bookmark to ADDRESS."
1663   (let ((url (elpher-address-to-url address)))
1664     (elpher-save-bookmarks
1665      (seq-filter (lambda (bookmark)
1666                    (not (equal (elpher-bookmark-url bookmark) url)))
1667                  (elpher-load-bookmarks)))))
1668
1669 ;;; Interactive procedures
1670 ;;
1671
1672 (defun elpher-next-link ()
1673   "Move point to the next link on the current page."
1674   (interactive)
1675   (forward-button 1))
1676
1677 (defun elpher-prev-link ()
1678   "Move point to the previous link on the current page."
1679   (interactive)
1680   (backward-button 1))
1681
1682 (defun elpher-follow-current-link ()
1683   "Open the link or url at point."
1684   (interactive)
1685   (push-button))
1686
1687 (defun elpher-go (host-or-url)
1688   "Go to a particular gopher site HOST-OR-URL.
1689 When run interactively HOST-OR-URL is read from the minibuffer."
1690   (interactive "sGopher or Gemini URL: ")
1691   (let* ((cleaned-host-or-url (string-trim host-or-url))
1692          (address (elpher-address-from-url cleaned-host-or-url))
1693          (page (elpher-make-page cleaned-host-or-url address)))
1694     (switch-to-buffer "*elpher*")
1695     (elpher-visit-page page)
1696     nil))
1697
1698 (defun elpher-go-current ()
1699   "Go to a particular site read from the minibuffer, initialized with the current URL."
1700   (interactive)
1701   (let ((address (elpher-page-address elpher-current-page)))
1702     (if (elpher-address-special-p address)
1703         (error "Command invalid for this page")
1704       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1705         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1706
1707 (defun elpher-redraw ()
1708   "Redraw current page."
1709   (interactive)
1710   (elpher-visit-page elpher-current-page))
1711
1712 (defun elpher-reload ()
1713   "Reload current page."
1714   (interactive)
1715   (elpher-reload-current-page))
1716
1717 (defun elpher-toggle-tls ()
1718   "Toggle TLS encryption mode for gopher."
1719   (interactive)
1720   (setq elpher-use-tls (not elpher-use-tls))
1721   (if elpher-use-tls
1722       (if (gnutls-available-p)
1723           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1724         (setq elpher-use-tls nil)
1725         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1726     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1727
1728 (defun elpher-view-raw ()
1729   "View raw server response for current page."
1730   (interactive)
1731   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1732       (error "This page was not generated by a server")
1733     (elpher-visit-page elpher-current-page
1734                        #'elpher-render-raw)))
1735
1736 (defun elpher-back ()
1737   "Go to previous site."
1738   (interactive)
1739   (elpher-visit-previous-page))
1740
1741 (defun elpher-back-to-start ()
1742   "Go all the way back to the start page."
1743   (interactive)
1744   (setq elpher-current-page nil)
1745   (setq elpher-history nil)
1746   (let ((start-page (elpher-make-page "Elpher Start Page"
1747                                       (elpher-make-special-address 'start))))
1748     (elpher-visit-page start-page)))
1749
1750 (defun elpher-download ()
1751   "Download the link at point."
1752   (interactive)
1753   (let ((button (button-at (point))))
1754     (if button
1755         (let ((page (button-get button 'elpher-page)))
1756           (if (elpher-address-special-p (elpher-page-address page))
1757               (error "Cannot download %s"
1758                      (elpher-page-display-string page))
1759             (elpher-visit-page (button-get button 'elpher-page)
1760                                #'elpher-render-download)))
1761       (error "No link selected"))))
1762
1763 (defun elpher-download-current ()
1764   "Download the current page."
1765   (interactive)
1766   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1767       (error "Cannot download %s"
1768              (elpher-page-display-string elpher-current-page))
1769     (elpher-visit-page (elpher-make-page
1770                         (elpher-page-display-string elpher-current-page)
1771                         (elpher-page-address elpher-current-page))
1772                        #'elpher-render-download
1773                        t)))
1774
1775 (defun elpher-build-link-map ()
1776   "Build alist mapping link names to destination pages in current buffer."
1777   (let ((link-map nil)
1778         (b (next-button (point-min) t)))
1779     (while b
1780       (push (cons (button-label b) b) link-map)
1781       (setq b (next-button (button-start b))))
1782     link-map))
1783
1784 (defun elpher-jump ()
1785   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1786   (interactive)
1787   (let* ((link-map (elpher-build-link-map)))
1788     (if link-map
1789         (let ((key (let ((completion-ignore-case t))
1790                      (completing-read "Directory item/link: "
1791                                       link-map nil t))))
1792           (if (and key (> (length key) 0))
1793               (let ((b (cdr (assoc key link-map))))
1794                 (goto-char (button-start b))
1795                 (button-activate b)))))))
1796
1797 (defun elpher-root-dir ()
1798   "Visit root of current server."
1799   (interactive)
1800   (let ((address (elpher-page-address elpher-current-page)))
1801     (if (not (elpher-address-special-p address))
1802         (if (or (member (url-filename address) '("/" ""))
1803                 (and (elpher-address-gopher-p address)
1804                      (= (length (elpher-gopher-address-selector address)) 0)))
1805             (error "Already at root directory of current server")
1806           (let ((address-copy (elpher-address-from-url
1807                                (elpher-address-to-url address))))
1808             (setf (url-filename address-copy) "")
1809             (elpher-go (elpher-address-to-url address-copy))))
1810       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1811
1812 (defun elpher-bookmarks-current-p ()
1813   "Return non-nil if current page is a bookmarks page."
1814   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1815          '(special bookmarks)))
1816
1817 (defun elpher-reload-bookmarks ()
1818   "Reload bookmarks if current page is a bookmarks page."
1819   (if (elpher-bookmarks-current-p)
1820       (elpher-reload-current-page)))
1821
1822 (defun elpher-bookmark-current ()
1823   "Bookmark the current page."
1824   (interactive)
1825   (let ((address (elpher-page-address elpher-current-page))
1826         (display-string (elpher-page-display-string elpher-current-page)))
1827     (if (not (elpher-address-special-p address))
1828         (let ((bookmark-display-string (read-string "Bookmark display string: "
1829                                                     display-string)))
1830           (elpher-add-address-bookmark address bookmark-display-string)
1831           (message "Bookmark added."))
1832       (error "Cannot bookmark %s" display-string))))
1833
1834 (defun elpher-bookmark-link ()
1835   "Bookmark the link at point."
1836   (interactive)
1837   (let ((button (button-at (point))))
1838     (if button
1839         (let* ((page (button-get button 'elpher-page))
1840                (address (elpher-page-address page))
1841                (display-string (elpher-page-display-string page)))
1842           (if (not (elpher-address-special-p address))
1843               (let ((bookmark-display-string (read-string "Bookmark display string: "
1844                                                           display-string)))
1845                 (elpher-add-address-bookmark address bookmark-display-string)
1846                 (elpher-reload-bookmarks)
1847                 (message "Bookmark added."))
1848             (error "Cannot bookmark %s" display-string)))
1849       (error "No link selected"))))
1850
1851 (defun elpher-unbookmark-current ()
1852   "Remove bookmark for the current page."
1853   (interactive)
1854   (let ((address (elpher-page-address elpher-current-page)))
1855     (when (and (not (elpher-address-special-p address))
1856                (y-or-n-p "Really remove bookmark for the current page? "))
1857       (elpher-remove-address-bookmark address)
1858       (message "Bookmark removed."))))
1859
1860 (defun elpher-unbookmark-link ()
1861   "Remove bookmark for the link at point."
1862   (interactive)
1863   (let ((button (button-at (point))))
1864     (if button
1865         (when (y-or-n-p "Really remove bookmark for this link? ")
1866           (let ((page (button-get button 'elpher-page)))
1867             (elpher-remove-address-bookmark (elpher-page-address page))
1868             (elpher-reload-bookmarks)
1869             (message "Bookmark removed.")))
1870       (error "No link selected"))))
1871
1872 (defun elpher-bookmarks ()
1873   "Visit bookmarks page."
1874   (interactive)
1875   (switch-to-buffer "*elpher*")
1876   (elpher-visit-page
1877    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1878
1879 (defun elpher-info-page (page)
1880   "Display information on PAGE."
1881   (let ((display-string (elpher-page-display-string page))
1882         (address (elpher-page-address page)))
1883     (if (elpher-address-special-p address)
1884         (message "Special page: %s" display-string)
1885       (message "%s" (elpher-address-to-url address)))))
1886
1887 (defun elpher-info-link ()
1888   "Display information on page corresponding to link at point."
1889   (interactive)
1890   (let ((button (button-at (point))))
1891     (if button
1892         (elpher-info-page (button-get button 'elpher-page))
1893       (error "No item selected"))))
1894
1895 (defun elpher-info-current ()
1896   "Display information on current page."
1897   (interactive)
1898   (elpher-info-page elpher-current-page))
1899
1900 (defun elpher-copy-page-url (page)
1901   "Copy URL representation of address of PAGE to `kill-ring'."
1902   (let ((address (elpher-page-address page)))
1903     (if (elpher-address-special-p address)
1904         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1905       (let ((url (elpher-address-to-url address)))
1906         (message "Copied \"%s\" to kill-ring/clipboard." url)
1907         (kill-new url)))))
1908
1909 (defun elpher-copy-link-url ()
1910   "Copy URL of item at point to `kill-ring'."
1911   (interactive)
1912   (let ((button (button-at (point))))
1913     (if button
1914         (elpher-copy-page-url (button-get button 'elpher-page))
1915       (error "No item selected"))))
1916
1917 (defun elpher-copy-current-url ()
1918   "Copy URL of current page to `kill-ring'."
1919   (interactive)
1920   (elpher-copy-page-url elpher-current-page))
1921
1922 (defun elpher-set-gopher-coding-system ()
1923   "Specify an explicit character coding system for gopher selectors."
1924   (interactive)
1925   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1926     (setq elpher-user-coding-system system)
1927     (if system
1928         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1929       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1930
1931
1932 ;;; Mode and keymap
1933 ;;
1934
1935 (defvar elpher-mode-map
1936   (let ((map (make-sparse-keymap)))
1937     (define-key map (kbd "TAB") 'elpher-next-link)
1938     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1939     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1940     (define-key map (kbd "u") 'elpher-back)
1941     (define-key map (kbd "U") 'elpher-back-to-start)
1942     (define-key map [mouse-3] 'elpher-back)
1943     (define-key map (kbd "O") 'elpher-root-dir)
1944     (define-key map (kbd "g") 'elpher-go)
1945     (define-key map (kbd "o") 'elpher-go-current)
1946     (define-key map (kbd "r") 'elpher-redraw)
1947     (define-key map (kbd "R") 'elpher-reload)
1948     (define-key map (kbd "T") 'elpher-toggle-tls)
1949     (define-key map (kbd ".") 'elpher-view-raw)
1950     (define-key map (kbd "d") 'elpher-download)
1951     (define-key map (kbd "D") 'elpher-download-current)
1952     (define-key map (kbd "m") 'elpher-jump)
1953     (define-key map (kbd "i") 'elpher-info-link)
1954     (define-key map (kbd "I") 'elpher-info-current)
1955     (define-key map (kbd "c") 'elpher-copy-link-url)
1956     (define-key map (kbd "C") 'elpher-copy-current-url)
1957     (define-key map (kbd "a") 'elpher-bookmark-link)
1958     (define-key map (kbd "A") 'elpher-bookmark-current)
1959     (define-key map (kbd "x") 'elpher-unbookmark-link)
1960     (define-key map (kbd "X") 'elpher-unbookmark-current)
1961     (define-key map (kbd "B") 'elpher-bookmarks)
1962     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1963     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1964     (when (fboundp 'evil-define-key*)
1965       (evil-define-key* 'motion map
1966         (kbd "TAB") 'elpher-next-link
1967         (kbd "C-") 'elpher-follow-current-link
1968         (kbd "C-t") 'elpher-back
1969         (kbd "u") 'elpher-back
1970         (kbd "U") 'elpher-back-to-start
1971         [mouse-3] 'elpher-back
1972         (kbd "g") 'elpher-go
1973         (kbd "o") 'elpher-go-current
1974         (kbd "r") 'elpher-redraw
1975         (kbd "R") 'elpher-reload
1976         (kbd "T") 'elpher-toggle-tls
1977         (kbd ".") 'elpher-view-raw
1978         (kbd "d") 'elpher-download
1979         (kbd "D") 'elpher-download-current
1980         (kbd "m") 'elpher-jump
1981         (kbd "i") 'elpher-info-link
1982         (kbd "I") 'elpher-info-current
1983         (kbd "c") 'elpher-copy-link-url
1984         (kbd "C") 'elpher-copy-current-url
1985         (kbd "a") 'elpher-bookmark-link
1986         (kbd "A") 'elpher-bookmark-current
1987         (kbd "x") 'elpher-unbookmark-link
1988         (kbd "X") 'elpher-unbookmark-current
1989         (kbd "B") 'elpher-bookmarks
1990         (kbd "S") 'elpher-set-gopher-coding-system
1991         (kbd "F") 'elpher-forget-current-certificate))
1992     map)
1993   "Keymap for gopher client.")
1994
1995 (define-derived-mode elpher-mode special-mode "elpher"
1996   "Major mode for elpher, an elisp gopher client.
1997
1998 This mode is automatically enabled by the interactive
1999 functions which initialize the gopher client, namely
2000 `elpher', `elpher-go' and `elpher-bookmarks'.")
2001
2002 (when (fboundp 'evil-set-initial-state)
2003   (evil-set-initial-state 'elpher-mode 'motion))
2004
2005
2006 ;;; Main start procedure
2007 ;;
2008
2009 ;;;###autoload
2010 (defun elpher ()
2011   "Start elpher with default landing page."
2012   (interactive)
2013   (if (get-buffer "*elpher*")
2014       (switch-to-buffer "*elpher*")
2015     (switch-to-buffer "*elpher*")
2016     (setq elpher-current-page nil)
2017     (setq elpher-history nil)
2018     (let ((start-page (elpher-make-page "Elpher Start Page"
2019                                         (elpher-make-special-address 'start))))
2020       (elpher-visit-page start-page)))
2021   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
2022
2023 ;;; elpher.el ends here