elpher.el

   1 ;;; elpher.el --- A friendly gopher client.
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.0.0
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption.
  40
  41 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  42 ;; page containing information on key bindings and suggested starting
  43 ;; points for your gopher exploration.
  44
  45 ;; Full instructions can be found in the Elpher info manual.
  46
  47 ;; Elpher is under active development.  Any suggestions for
  48 ;; improvements are welcome!
  49
  50 ;;; Code:
  51
  52 (provide 'elpher)
  53
  54 ;;; Dependencies
  55 ;;
  56
  57 (require 'seq)
  58 (require 'pp)
  59 (require 'shr)
  60 (require 'url-util)
  61
  62
  63 ;;; Global constants
  64 ;;
  65
  66 (defconst elpher-version "2.0.0"
  67   "Current version of elpher.")
  68
  69 (defconst elpher-margin-width 6
  70   "Width of left-hand margin used when rendering indicies.")
  71
  72 (defconst elpher-type-map
  73   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  74     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  75     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  76     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  77     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  78     ((gopher ?9) elpher-get-gopher-node elpher-render-node-download "bin" elpher-binary)
  79     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  80     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  81     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  83     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  84     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  85     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  86     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  87     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  88     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  89     ((special bookmarks) elpher-get-bookmarks-node nil)
  90     ((special start) elpher-get-start-node nil))
  91   "Association list from types to getters, margin codes and index faces.")
  92
  93
  94 ;;; Customization group
  95 ;;
  96
  97 (defgroup elpher nil
  98   "A gopher client."
  99   :group 'applications)
 100
 101 ;; Face customizations
 102
 103 (defface elpher-index
 104   '((t :inherit font-lock-keyword-face))
 105   "Face used for directory type directory records.")
 106
 107 (defface elpher-text
 108   '((t :inherit bold))
 109   "Face used for text type directory records.")
 110
 111 (defface elpher-info
 112   '((t :inherit default))
 113   "Face used for info type directory records.")
 114
 115 (defface elpher-image
 116   '((t :inherit font-lock-string-face))
 117   "Face used for image type directory records.")
 118
 119 (defface elpher-search
 120   '((t :inherit warning))
 121   "Face used for search type directory records.")
 122
 123 (defface elpher-html
 124   '((t :inherit font-lock-comment-face))
 125   "Face used for html type directory records.")
 126
 127 (defface elpher-gemini
 128   '((t :inherit font-lock-function-name-face))
 129   "Face used for html type directory records.")
 130
 131 (defface elpher-other-url
 132   '((t :inherit font-lock-comment-face))
 133   "Face used for other URL type links records.")
 134
 135 (defface elpher-telnet
 136   '((t :inherit font-lock-function-name-face))
 137   "Face used for telnet type directory records.")
 138
 139 (defface elpher-binary
 140   '((t :inherit font-lock-doc-face))
 141   "Face used for binary type directory records.")
 142
 143 (defface elpher-unknown
 144   '((t :inherit error))
 145   "Face used for directory records with unknown/unsupported types.")
 146
 147 (defface elpher-margin-key
 148   '((t :inherit bold))
 149   "Face used for directory margin key.")
 150
 151 (defface elpher-margin-brackets
 152   '((t :inherit shadow))
 153   "Face used for brackets around directory margin key.")
 154
 155 ;; Other customizations
 156
 157 (defcustom elpher-open-urls-with-eww nil
 158   "If non-nil, open URL selectors using eww.
 159 Otherwise, use the system browser via the BROWSE-URL function."
 160   :type '(boolean))
 161
 162 (defcustom elpher-buttonify-urls-in-directories nil
 163   "If non-nil, turns URLs matched in directories into clickable buttons."
 164   :type '(boolean))
 165
 166 (defcustom elpher-use-header t
 167   "If non-nil, display current node information in buffer header."
 168   :type '(boolean))
 169
 170 (defcustom elpher-auto-disengage-TLS nil
 171   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 172 While enabling this may seem convenient, it is also potentially dangerous as it
 173 allows switching from an encrypted channel back to plain text without user input."
 174   :type '(boolean))
 175
 176
 177 ;;; Model
 178 ;;
 179
 180 ;; Address
 181
 182 ;; An elpher "address" object is either a url object or a symbol.
 183 ;; Symbol addresses are "special", corresponding to pages generated
 184 ;; dynamically for and by elpher.  All others represent pages which
 185 ;; rely on content retrieved over the network.
 186
 187 (defun elpher-address-from-url (url-string)
 188   "Create a ADDRESS object corresponding to the given URL-STRING."
 189   (let ((data (match-data))) ; Prevent parsing clobbering match data
 190     (unwind-protect
 191         (let ((url (url-generic-parse-url url-string)))
 192           (setf (url-fullness url) t)
 193           (setf (url-filename url)
 194                 (url-unhex-string (url-filename url)))
 195           (unless (url-type url)
 196             (setf (url-type url) "gopher"))
 197           (let ((is-gopher (or (equal "gopher" (url-type url))
 198                                (equal "gophers" (url-type url))))
 199                 (is-gemini (equal "gemini" (url-type url))))
 200             (when is-gopher
 201               ;; Gopher defaults
 202               (unless (url-host url)
 203                 (setf (url-host url) (url-filename url))
 204                 (setf (url-filename url) ""))
 205               (when (or (equal (url-filename url) "")
 206                         (equal (url-filename url) "/"))
 207                 (setf (url-filename url) "/1"))))
 208           url)
 209       (set-match-data data))))
 210
 211 (defun elpher-make-gopher-address (type selector host port &optional tls)
 212   "Create an ADDRESS object corresponding to the given gopher directory record
 213 attributes: TYPE, SELECTOR, HOST and PORT."
 214   (if (and (equal type ?h)
 215            (string-prefix-p "URL:" selector))
 216       (elpher-address-from-url (elt (split-string selector "URL:") 1))
 217     (elpher-address-from-url
 218      (concat "gopher" (if tls "s" "")
 219              "://" host
 220              ":" (number-to-string port)
 221              "/" (string type)
 222              selector))))
 223
 224 (defun elpher-make-special-address (type)
 225   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 226   type)
 227
 228 (defun elpher-address-to-url (address)
 229   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 230   (if (not (elpher-address-special-p address))
 231       (url-encode-url (url-recreate-url address))
 232     nil))
 233
 234 (defun elpher-address-type (address)
 235   "Retrieve selector type from ADDRESS object."
 236   (if (symbolp address)
 237       (list 'special address)
 238     (let ((protocol (url-type address)))
 239       (cond ((or (equal protocol "gopher")
 240                  (equal protocol "gophers"))
 241              (list 'gopher
 242                    (if (member (url-filename address) '("" "/"))
 243                        ?1
 244                      (string-to-char (substring (url-filename address) 1)))))
 245             ((equal protocol "gemini")
 246              'gemini)
 247             (t 'other-url)))))
 248
 249 (defun elpher-address-protocol (address)
 250   (if (symbolp address)
 251       nil
 252     (url-type address)))
 253
 254 (defun elpher-address-filename (address)
 255   (if (symbolp address)
 256       nil
 257     (url-filename address)))
 258
 259 (defun elpher-address-host (address)
 260   "Retrieve host from ADDRESS object."
 261   (url-host address))
 262
 263 (defun elpher-address-port (address)
 264   "Retrieve port from ADDRESS object."
 265   (url-port address))
 266
 267 (defun elpher-address-special-p (address)
 268   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 269   (symbolp address))
 270
 271 (defun elpher-address-gopher-p (address)
 272   "Return non-nill if ADDRESS object is a gopher address."
 273   (and (not (elpher-address-special-p address))
 274        (member (elpher-address-protocol address) '("gopher gophers"))))
 275
 276 (defun elpher-gopher-address-selector (address)
 277   "Retrieve gopher selector from ADDRESS object."
 278   (if (member (url-filename address) '("" "/"))
 279       ""
 280     (substring (url-filename address) 2)))
 281
 282 ;; Node
 283
 284 (defun elpher-make-node (display-string address &optional parent)
 285   "Create a node in the page hierarchy.
 286
 287 DISPLAY-STRING records the display string used for the page.
 288
 289 ADDRESS specifies the address object of the page.
 290
 291 The optional PARENT specifies the parent node in the hierarchy.
 292 This is set every time the node is visited, so while it forms
 293 an important part of the node data there is no need to set it
 294 initially."
 295   (list display-string address parent))
 296
 297 (defun elpher-node-display-string (node)
 298   "Retrieve the display string of NODE."
 299   (elt node 0))
 300
 301 (defun elpher-node-address (node)
 302   "Retrieve the ADDRESS object of NODE."
 303   (elt node 1))
 304
 305 (defun elpher-node-parent (node)
 306   "Retrieve the parent node of NODE."
 307   (elt node 2))
 308
 309 (defun elpher-set-node-parent (node parent)
 310   "Set the parent node of NODE to be PARENT."
 311   (setcar (cdr (cdr node)) parent))
 312
 313 ;; Cache
 314
 315 (defvar elpher-content-cache (make-hash-table :test 'equal))
 316 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 317
 318 (defun elpher-get-cached-content (address)
 319   "Retrieve the cached content for ADDRESS, or nil if none exists."
 320   (gethash address elpher-content-cache))
 321
 322 (defun elpher-cache-content (address content)
 323   "Set the content cache for ADDRESS to CONTENT."
 324   (puthash address content elpher-content-cache))
 325
 326 (defun elpher-get-cached-pos (address)
 327   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 328   (gethash address elpher-pos-cache))
 329
 330 (defun elpher-cache-pos (address pos)
 331   "Set the cursor position cache for ADDRESS to POS."
 332   (puthash address pos elpher-pos-cache))
 333
 334 ;; Node graph traversal
 335
 336 (defvar elpher-current-node nil)
 337
 338 (defun elpher-visit-node (node &optional renderer preserve-parent)
 339   "Visit NODE using its own renderer or RENDERER, if non-nil.
 340 Additionally, set the parent of NODE to `elpher-current-node',
 341 unless PRESERVE-PARENT is non-nil."
 342   (elpher-save-pos)
 343   (elpher-process-cleanup)
 344   (unless preserve-parent
 345     (if (and (elpher-node-parent elpher-current-node)
 346              (equal (elpher-node-address elpher-current-node)
 347                     (elpher-node-address node)))
 348         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 349       (elpher-set-node-parent node elpher-current-node)))
 350   (setq elpher-current-node node)
 351   (let* ((address (elpher-node-address node))
 352          (type (elpher-address-type address))
 353          (type-record (cdr (assoc type elpher-type-map))))
 354     (if type-record
 355         (funcall (car type-record)
 356                  (if renderer
 357                      renderer
 358                    (cadr type-record)))
 359       (elpher-visit-parent-node)
 360       (pcase type
 361         (`(gopher ,type-char)
 362          (error "Unsupported gopher selector type '%c' for '%s'"
 363                 type-char (elpher-address-to-url address)))
 364         (else
 365          (error "Unsupported address type '%S' for '%s'"
 366                 type (elpher-address-to-url address)))))))
 367
 368 (defun elpher-visit-parent-node ()
 369   "Visit the parent of the current node."
 370   (let ((parent-node (elpher-node-parent elpher-current-node)))
 371     (when parent-node
 372       (elpher-visit-node parent-node nil t))))
 373
 374 (defun elpher-reload-current-node ()
 375   "Reload the current node, discarding any existing cached content."
 376   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 377   (elpher-visit-node elpher-current-node))
 378
 379 (defun elpher-save-pos ()
 380   "Save the current position of point to the current node."
 381   (when elpher-current-node
 382     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 383
 384 (defun elpher-restore-pos ()
 385   "Restore the position of point to that cached in the current node."
 386   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 387     (if pos
 388         (goto-char pos)
 389       (goto-char (point-min)))))
 390
 391
 392 ;;; Buffer preparation
 393 ;;
 394
 395 (defun elpher-update-header ()
 396   "If `elpher-use-header' is true, display current node info in window header."
 397   (if elpher-use-header
 398       (setq header-line-format (elpher-node-display-string elpher-current-node))))
 399
 400 (defmacro elpher-with-clean-buffer (&rest args)
 401   "Evaluate ARGS with a clean *elpher* buffer as current."
 402   (list 'with-current-buffer "*elpher*"
 403         '(elpher-mode)
 404         (append (list 'let '((inhibit-read-only t))
 405                       '(erase-buffer)
 406                       '(elpher-update-header))
 407                 args)))
 408
 409
 410 ;;; Text Processing
 411 ;;
 412
 413 (defvar elpher-user-coding-system nil
 414   "User-specified coding system to use for decoding text responses.")
 415
 416 (defun elpher-decode (string)
 417   "Decode STRING using autodetected or user-specified coding system."
 418   (decode-coding-string string
 419                         (if elpher-user-coding-system
 420                             elpher-user-coding-system
 421                           (detect-coding-string string t))))
 422
 423 (defun elpher-preprocess-text-response (string)
 424   "Preprocess text selector response contained in STRING.
 425 This involes decoding the character representation, and clearing
 426 away CRs and any terminating period."
 427   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 428                                            (replace-regexp-in-string "\r" "" string))))
 429
 430
 431 ;;; Index rendering
 432 ;;
 433
 434 ;;; Network error reporting
 435 ;;
 436
 437 (defun elpher-network-error (address error)
 438   (elpher-with-clean-buffer
 439    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 440            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 441            (error-message-string the-error) ".\n"
 442            (propertize "\n----------------\n\n" 'face 'error)
 443            "Press 'u' to return to the previous page.")))
 444
 445
 446 ;;; Gopher selector retrieval (all kinds)
 447 ;;
 448
 449 (defun elpher-process-cleanup ()
 450   "Immediately shut down any extant elpher process."
 451   (let ((p (get-process "elpher-process")))
 452     (if p (delete-process p))))
 453
 454 (defvar elpher-use-tls nil
 455   "If non-nil, use TLS to communicate with gopher servers.")
 456
 457 (defvar elpher-selector-string)
 458
 459 (defun elpher-get-selector (address after &optional propagate-error)
 460   "Retrieve selector specified by ADDRESS, then execute AFTER.
 461 The result is stored as a string in the variable ‘elpher-selector-string’.
 462
 463 Usually errors result in an error page being displayed.  This is only
 464 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 465 is non-nil, this message is not displayed.  Instead, the error propagates
 466 up to the calling function."
 467   (setq elpher-selector-string "")
 468   (when (equal (elpher-address-protocol address) "gophers")
 469       (if (gnutls-available-p)
 470           (when (not elpher-use-tls)
 471             (setq elpher-use-tls t)
 472             (message "Engaging TLS mode."))
 473         (error "Cannot retrieve TLS selector: GnuTLS not available")))
 474   (condition-case the-error
 475       (let* ((kill-buffer-query-functions nil)
 476              (proc (open-network-stream "elpher-process"
 477                                        nil
 478                                        (elpher-address-host address)
 479                                        (if (> (elpher-address-port address) 0)
 480                                            (elpher-address-port address)
 481                                          70)
 482                                        :type (if elpher-use-tls 'tls 'plain))))
 483         (set-process-coding-system proc 'binary)
 484         (set-process-filter proc
 485                             (lambda (proc string)
 486                               (setq elpher-selector-string
 487                                     (concat elpher-selector-string string))))
 488         (set-process-sentinel proc after)
 489         (process-send-string proc
 490                              (concat (elpher-gopher-address-selector address) "\n")))
 491     (error
 492      (if (and (consp the-error)
 493               (eq (car the-error) 'gnutls-error)
 494               (not (equal (elpher-address-protocol address) "gophers"))
 495               (or elpher-auto-disengage-TLS
 496                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 497          (progn
 498            (message "Disengaging TLS mode.")
 499            (setq elpher-use-tls nil)
 500            (elpher-get-selector address after))
 501        (elpher-process-cleanup)
 502        (if propagate-error
 503            (error the-error)
 504          (elpher-with-clean-buffer
 505           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 506                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 507                   (propertize "\n----------------\n\n" 'face 'error)
 508                   "Press 'u' to return to the previous page.")))))))
 509
 510 (defun elpher-get-gopher-node (renderer)
 511   (let* ((address (elpher-node-address elpher-current-node))
 512          (content (elpher-get-cached-content address)))
 513     (if (not (and content (funcall renderer nil content)))
 514       (elpher-with-clean-buffer
 515        (insert "LOADING... (use 'u' to cancel)"))
 516       (elpher-get-selector address
 517                            (lambda (proc event)
 518                              (unless (string-prefix-p "deleted" event)
 519                                (funcall renderer elpher-selector-string))))))
 520   (elpher-restore-pos))
 521
 522 ;; Index rendering
 523
 524
 525 (defun elpher-insert-index (string)
 526   "Insert the index corresponding to STRING into the current buffer."
 527   ;; Should be able to split directly on CRLF, but some non-conformant
 528   ;; LF-only servers sadly exist, hence the following.
 529   (let ((str-processed (elpher-preprocess-text-response string)))
 530     (dolist (line (split-string str-processed "\n"))
 531       (unless (= (length line) 0)
 532         (let* ((type (elt line 0))
 533                (fields (split-string (substring line 1) "\t"))
 534                (display-string (elt fields 0))
 535                (selector (elt fields 1))
 536                (host (elt fields 2))
 537                (port (if (elt fields 3)
 538                          (string-to-number (elt fields 3))
 539                        nil))
 540                (address (elpher-make-gopher-address type selector host port)))
 541           (elpher-insert-index-record display-string address))))))
 542
 543 (defun elpher-insert-margin (&optional type-name)
 544   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 545   (if type-name
 546       (progn
 547         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 548                         (concat
 549                          (propertize "[" 'face 'elpher-margin-brackets)
 550                          (propertize type-name 'face 'elpher-margin-key)
 551                          (propertize "]" 'face 'elpher-margin-brackets))))
 552         (insert " "))
 553     (insert (make-string elpher-margin-width ?\s))))
 554
 555 (defun elpher-node-button-help (node)
 556   "Return a string containing the help text for a button corresponding to NODE."
 557   (let ((address (elpher-node-address node)))
 558     (format "mouse-1, RET: open '%s'" (elpher-address-to-url address))))
 559
 560 (defun elpher-insert-index-record (display-string &optional address)
 561   "Function to insert an index record into the current buffer.
 562 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 563 If ADDRESS is not supplied or nil the record is rendered as an
 564 'information' line."
 565   (let* ((type (if address (elpher-address-type address) nil))
 566          (type-map-entry (cdr (assoc type elpher-type-map))))
 567     (if type-map-entry
 568         (let* ((margin-code (elt type-map-entry 1))
 569                (face (elt type-map-entry 2))
 570                (node (elpher-make-node display-string address)))
 571           (elpher-insert-margin margin-code)
 572           (insert-text-button display-string
 573                               'face face
 574                               'elpher-node node
 575                               'action #'elpher-click-link
 576                               'follow-link t
 577                               'help-echo (elpher-node-button-help node)))
 578       (pcase type
 579         ((or '(gopher ?i) 'nil) ;; Information
 580          (elpher-insert-margin)
 581          (insert (propertize
 582                   (if elpher-buttonify-urls-in-directories
 583                       (elpher-buttonify-urls display-string)
 584                     display-string)
 585                   'face 'elpher-info)))
 586         (`(gopher ,selector-type) ;; Unknown
 587          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 588          (insert (propertize display-string
 589                              'face 'elpher-unknown)))))
 590     (insert "\n")))
 591
 592 (defun elpher-click-link (button)
 593   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 594   (let ((node (button-get button 'elpher-node)))
 595     (elpher-visit-node node)))
 596
 597 (defun elpher-render-index (data &optional cached-data)
 598   "Render DATA as an index, using CACHED-DATA instead if supplied."
 599   (elpher-with-clean-buffer
 600    (if cached-data
 601        (progn (insert cached-data) t)
 602      (elpher-insert-index data)
 603      (elpher-cache-content (elpher-node-address elpher-current-node)
 604                            (buffer-string)))))
 605
 606 ;; Text rendering
 607
 608 (defconst elpher-url-regex
 609   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]+\\|\[[a-zA-Z0-9:]+\]\\)\\(?3::[0-9]+\\)?\\(?4:/[^<> \r\n\t(),]*\\)?"
 610   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 611
 612 (defun elpher-buttonify-urls (string)
 613   "Turn substrings which look like urls in STRING into clickable buttons."
 614   (with-temp-buffer
 615     (insert string)
 616     (goto-char (point-min))
 617     (while (re-search-forward elpher-url-regex nil t)
 618       (let ((node (elpher-make-node (match-string 0)
 619                                     (elpher-address-from-url (match-string 0)))))
 620           (make-text-button (match-beginning 0)
 621                             (match-end 0)
 622                             'elpher-node  node
 623                             'action #'elpher-click-link
 624                             'follow-link t
 625                             'help-echo (elpher-node-button-help node))))
 626     (buffer-string)))
 627
 628 (defun elpher-render-text (data &optional cached-data)
 629   "Render DATA as text, using CACHED-DATA instead if supplied."
 630   (elpher-with-clean-buffer
 631    (if cached-data
 632        (progn (insert cached-data) t)
 633      (insert (elpher-buttonify-urls
 634               (elpher-preprocess-text-response)
 635               elpher-selector-string))
 636      (elpher-cache-content
 637       (elpher-node-address elpher-current-node)
 638       (buffer-string)))))
 639
 640 ;; Image retrieval
 641
 642 (defun elpher-render-image (data &optional cached-data)
 643   "Display DATA as image, CACHED-DATA is ignored."
 644   (if cached-data
 645       f
 646     (if (display-images-p)
 647         (progn
 648           (let ((image (create-image
 649                         data
 650                         nil t)))
 651             (elpher-with-clean-buffer
 652              (insert-image image)
 653              (elpher-restore-pos))))
 654       (elpher-save-to-file data))))
 655
 656 ;; Search retrieval and rendering
 657
 658 (defun elpher-get-gopher-query-node (renderer)
 659    (let* ((address (elpher-node-address elpher-current-node))
 660           (content (elpher-get-cached-content address))
 661           (aborted t))
 662     (if content
 663         (progn
 664           (funcall renderer nil content)
 665           (elpher-restore-pos)
 666           (message "Displaying cached search results.  Reload to perform a new search."))
 667       (unwind-protect
 668           (let* ((query-string (read-string "Query: "))
 669                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 670                  (search-address (elpher-make-gopher-address ?1
 671                                                              query-selector
 672                                                              (elpher-address-host address)
 673                                                              (elpher-address-port address)
 674                                                              (equal (elpher-address-type address) "gophers"))))
 675             (setq aborted nil)
 676
 677             (elpher-with-clean-buffer
 678              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 679             (elpher-get-selector search-address
 680                                  (lambda (proc event)
 681                                    (unless (string-prefix-p "deleted" event)
 682                                      (funcall renderer elpher-selector-string)
 683                                      (elpher-restore-pos)))))
 684         (if aborted
 685             (elpher-visit-parent-node))))))
 686
 687 ;; Raw server response rendering
 688
 689 (defun elpher-render-raw (data &optional cached-data)
 690   "Display raw DATA in buffer. CACHED-DATA is ignored."
 691   (if cached-data
 692       f
 693     (elpher-with-clean-buffer
 694      (insert data)
 695      (goto-char (point-min)))
 696     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 697
 698 ;; File save renderer
 699
 700 (defun elpher-render-download (data &optional cached-data)
 701   "Save DATA to file. CACHED-DATA is ignored."
 702   (if cached-data
 703       f
 704     (let* ((address (elpher-node-address elpher-current-node))
 705            (selector (elpher-gopher-address-selector address)))
 706       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 707       (let* ((filename-proposal (file-name-nondirectory selector))
 708              (filename (read-file-name "Download complete. Save file as: "
 709                                        nil nil nil
 710                                        (if (> (length filename-proposal) 0)
 711                                            filename-proposal
 712                                          "gopher.file"))))
 713         (with-temp-file filename
 714           (insert elpher-selector-string)
 715           (message (format "Saved to file %s."
 716                            elpher-download-filename)))))))
 717
 718 ;; HTML node retrieval
 719
 720 (defun elpher-render-html (data &optional cached-data)
 721   "Render DATA as HTML using shr, or insert CACHED-DATA if non-nil."
 722   (elpher-with-clean-buffer
 723    (if cached-data
 724        (progn (insert cached-data) t)
 725      (let ((dom (with-temp-buffer
 726                   (insert string)
 727                   (libxml-parse-html-region (point-min) (point-max)))))
 728        (shr-insert-document dom)))))
 729
 730 ;;;;;;;;; ONLY COMPLETED TO HERE ;;;;;;;;;;;;;;;;;;;;
 731
 732 ;; Gemini node retrieval
 733
 734 (defvar elpher-gemini-response)
 735
 736 (defun elpher-get-gemini (address after)
 737   "Retrieve gemini ADDRESS, then execute AFTER.
 738 The response is stored in the variable ‘elpher-gemini-response’."
 739   (setq elpher-gemini-response "")
 740   (if (not (gnutls-available-p))
 741       (error "Cannot retrieve TLS selector: GnuTLS not available")
 742     (let* ((kill-buffer-query-functions nil)
 743            (proc (open-network-stream "elpher-process"
 744                                       nil
 745                                       (elpher-address-host address)
 746                                       (if (> (elpher-address-port address) 0)
 747                                           (elpher-address-port address)
 748                                         1965)
 749                                       :type 'tls)))
 750       (set-process-coding-system proc 'binary)
 751       (set-process-filter proc
 752                           (lambda (proc string)
 753                             (setq elpher-gemini-response
 754                                   (concat elpher-gemini-response string))))
 755       (set-process-sentinel proc after)
 756       (process-send-string proc
 757                            (concat (elpher-address-to-url address) "\r\n")))))
 758
 759
 760 (defun elpher-render-gemini-response (mime-type-string)
 761   (let* ((mime-type-string* (if (string-empty-p mime-type-string)
 762                                 "text/gemini; charset=utf-8"
 763                               mime-type-string))
 764          (mime-type-split (split-string mime-type-string* ";"))
 765          (mime-type (string-trim (car mime-type-split)))
 766          (parameters (mapcar (lambda (s)
 767                                (let ((key-val (split-string s "=")))
 768                                  (list (downcase (string-trim (car key-val)))
 769                                        (downcase (string-trim (cadr key-val))))))
 770                              (cdr mime-type-split))))
 771     (if (and (equal "text/gemini" mime-type)
 772              (not (assoc "charset" parameters)))
 773         (setq parameters (cons (list "charset" "utf-8") parameters)))
 774     (when (string-prefix-p "text/" mime-type)
 775       (if (assoc "charset" parameters)
 776           (setq elpher-gemini-response
 777                 (decode-coding-string elpher-gemini-response
 778                                       (intern (cadr (assoc "charset" parameters))))))
 779       (setq elpher-gemini-response
 780             (replace-regexp-in-string "\r" "" elpher-gemini-response)))
 781     (pcase mime-type
 782       ((or "text/gemini" "")
 783        (elpher-render--mimetype-text/gemini elpher-gemini-response parameters))
 784       ((pred (string-prefix-p "text/"))
 785        (elpher-render--mimetype-text/plain elpher-gemini-response parameters))
 786       ((pred (string-prefix-p "image/"))
 787        (elpher-render--mimetype-image/* elpher-gemini-response parameters))
 788       (other
 789        (error "Unsupported MIME type %S" mime-type)))))
 790
 791 (defun elpher-gemini-get-link-url (line)
 792   (string-trim (elt (split-string (substring line 2)) 0)))
 793
 794 (defun elpher-gemini-get-link-display-string (line)
 795   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 796          (idx (string-match "[ \t]" rest)))
 797     (if idx
 798         (string-trim (substring rest (+ idx 1)))
 799       "")))
 800
 801 (defun elpher-address-from-gemini-url (url)
 802   "Extract address from URL with defaults as per gemini map files."
 803   (let ((address (url-generic-parse-url url)))
 804     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 805       (setf (url-fullness address) t)
 806       (unless (url-host address) ;if there is an explicit host, filenames are explicit
 807         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 808         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 809           (setf (url-filename address)
 810                 (concat (file-name-directory
 811                          (url-filename (elpher-node-address elpher-current-node)))
 812                         (url-filename address)))))
 813       (unless (url-type address)
 814         (setf (url-type address) "gemini")))
 815     address))
 816
 817 (defun elpher-render--mimetype-text/gemini (data parameters)
 818   (elpher-with-clean-buffer
 819    (dolist (line (split-string data "\n"))
 820      (if (string-prefix-p "=>" line)
 821          (let* ((url (elpher-gemini-get-link-url line))
 822                 (display-string (elpher-gemini-get-link-display-string line))
 823                 (address (elpher-address-from-gemini-url url)))
 824            (if (> (length display-string) 0)
 825                (elpher-insert-index-record display-string address)
 826              (elpher-insert-index-record url address)))
 827        (elpher-insert-index-record line)))
 828    (elpher-restore-pos)
 829    (elpher-cache-content
 830     (elpher-node-address elpher-current-node)
 831     (buffer-string))))
 832
 833 (defun elpher-render--mimetype-text/plain (data parameters)
 834   (elpher-with-clean-buffer
 835    (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 836    (elpher-restore-pos)
 837    (elpher-cache-content
 838     (elpher-node-address elpher-current-node)
 839     (buffer-string))))
 840
 841 (defun elpher-render--mimetype-image/* (data parameters)
 842   (let ((image (create-image data nil t)))
 843     (elpher-with-clean-buffer
 844      (insert-image image)
 845      (elpher-restore-pos))))
 846
 847 (defun elpher-process-gemini-response (proc event)
 848   (condition-case the-error
 849       (unless (string-prefix-p "deleted" event)
 850         (let ((response-code (car (split-string elpher-gemini-response-header)))
 851               (meta (string-trim
 852                      (substring elpher-gemini-response-header
 853                                 (string-match "[ \t]+"
 854                                               elpher-gemini-response-header)))))
 855           (pcase (elt response-code 0)
 856             (?1 ; Input required
 857              (elpher-with-clean-buffer
 858               (insert "Gemini server is requesting input."))
 859              (let* ((query-string (read-string (concat meta ": ")))
 860                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 861                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 862                (elpher-get-gemini query-address #'elpher-process-gemini-response)))
 863             (?2 ; Normal response
 864              (message elpher-gemini-response-header)
 865              (elpher-render-gemini-response meta))
 866             (?3 ; Redirect
 867              (message "Following redirect to %s" meta)
 868              (let ((redirect-address (elpher-address-from-gemini-url meta)))
 869                (elpher-get-gemini redirect-address #'elpher-process-gemini-response)))
 870             (?4 ; Temporary failure
 871              (error "Gemini server reports TEMPORARY FAILURE for this request"))
 872             (?5 ; Permanent failure
 873              (error "Gemini server reports PERMANENT FAILURE for this request"))
 874             (?6 ; Client certificate required
 875              (error "Gemini server requires client certificate (unsupported at this time)"))
 876             (other
 877              (error "Gemini server responded with unknown response code %S"
 878                     response-code)))))
 879     (error
 880      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 881
 882
 883 (defun elpher-get-gemini-node (renderer)
 884   "Getter which retrieves and renders a Gemini node."
 885   (let* ((address (elpher-node-address elpher-current-node))
 886          (content (elpher-get-cached-content address)))
 887     (condition-case the-error
 888         (if content
 889             (progn
 890               (elpher-with-clean-buffer
 891                (insert content)
 892                (elpher-restore-pos)))
 893           (elpher-with-clean-buffer
 894            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 895           (elpher-get-gemini address #'elpher-process-gemini-response))
 896       (error
 897        (elpher-network-error address the-error)))))
 898
 899
 900 ;; Other URL node opening
 901
 902 (defun elpher-get-other-url-node (renderer)
 903   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 904   (when renderer
 905     (elpher-visit-parent-node)
 906     (error "Command not supported for general URLs"))
 907   (let* ((address (elpher-node-address elpher-current-node))
 908          (url (elpher-address-to-url address)))
 909     (progn
 910       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 911       (message "Opening URL...")
 912       (if elpher-open-urls-with-eww
 913           (browse-web url)
 914         (browse-url url)))))
 915
 916 ;; Telnet node connection
 917
 918 (defun elpher-get-telnet-node (renderer)
 919   "Opens a telnet connection to the current node address (RENDERER must be nil)."
 920   (when renderer
 921     (elpher-visit-parent-node)
 922     (error "Command not supported for telnet URLs"))
 923   (let* ((address (elpher-node-address elpher-current-node))
 924          (host (elpher-address-host address))
 925          (port (elpher-address-port address)))
 926     (elpher-visit-parent-node)
 927     (telnet host port)))
 928
 929 ;; Start page node retrieval
 930
 931 (defun elpher-get-start-node (renderer)
 932   "Getter which displays the start page (RENDERER must be nil)."
 933   (when renderer
 934     (elpher-visit-parent-node)
 935     (error "Command not supported for start page."))
 936   (elpher-with-clean-buffer
 937    (insert "     --------------------------------------------\n"
 938            "                Elpher Gopher Client             \n"
 939            "                   version " elpher-version "\n"
 940            "     --------------------------------------------\n"
 941            "\n"
 942            "Default bindings:\n"
 943            "\n"
 944            " - TAB/Shift-TAB: next/prev item on current page\n"
 945            " - RET/mouse-1: open item under cursor\n"
 946            " - m: select an item on current page by name (autocompletes)\n"
 947            " - u: return to previous page\n"
 948            " - o/O: visit different selector or the root menu of the current server\n"
 949            " - g: go to a particular gopher address\n"
 950            " - i/I: info on item under cursor or current page\n"
 951            " - c/C: copy URL representation of item under cursor or current page\n"
 952            " - a/A: bookmark the item under cursor or current page\n"
 953            " - x/X: remove bookmark for item under cursor or current page\n"
 954            " - B: visit the bookmarks page\n"
 955            " - r: redraw current page (using cached contents if available)\n"
 956            " - R: reload current page (regenerates cache)\n"
 957            " - T: toggle TLS mode\n"
 958            " - d/D: download item under cursor or current page\n"
 959            " - .: display the raw server response for the current page\n"
 960            " - S: set an explicit character coding system (default is to autodetect)\n"
 961            "\n"
 962            "Start your exploration of gopher space:\n")
 963    (elpher-insert-index-record "Floodgap Systems Gopher Server"
 964                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
 965    (insert "\n"
 966            "Alternatively, select the following item and enter some search terms:\n")
 967    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
 968                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
 969    (insert "\n"
 970            "** Refer to the ")
 971    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
 972      (insert-text-button "Elpher info manual"
 973                          'face 'link
 974                          'action (lambda (button)
 975                                    (interactive)
 976                                    (info "(elpher)"))
 977                          'follow-link t
 978                          'help-echo help-string))
 979    (insert " for the full documentation. **\n")
 980    (insert (propertize
 981             (concat "  (This should be available if you have installed Elpher using\n"
 982                     "   MELPA. Otherwise you will have to install the manual yourself.)")
 983             'face 'shadow))
 984    (elpher-restore-pos)))
 985
 986 ;; Bookmarks page node retrieval
 987
 988 (defun elpher-get-bookmarks-node (renderer)
 989   "Getter to load and display the current bookmark list (RENDERER must be nil)."
 990   (when renderer
 991     (elpher-visit-parent-node)
 992     (error "Command not supported for bookmarks page."))
 993   (elpher-with-clean-buffer
 994    (insert "---- Bookmark list ----\n\n")
 995    (let ((bookmarks (elpher-load-bookmarks)))
 996      (if bookmarks
 997          (dolist (bookmark bookmarks)
 998            (let ((display-string (elpher-bookmark-display-string bookmark))
 999                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1000              (elpher-insert-index-record display-string address)))
1001        (insert "No bookmarks found.\n")))
1002    (insert "\n-----------------------\n\n"
1003            "- u: return to previous page\n"
1004            "- x: delete selected bookmark\n"
1005            "- a: rename selected bookmark\n\n"
1006            "Bookmarks are stored in the file "
1007            (locate-user-emacs-file "elpher-bookmarks"))
1008    (elpher-restore-pos)))
1009
1010
1011 ;;; Bookmarks
1012 ;;
1013
1014 (defun elpher-make-bookmark (display-string url)
1015   "Make an elpher bookmark.
1016 DISPLAY-STRING determines how the bookmark will appear in the
1017 bookmark list, while ADDRESS is the address of the entry."
1018   (list display-string (elpher-address-to-url address)))
1019
1020 (defun elpher-bookmark-display-string (bookmark)
1021   "Get the display string of BOOKMARK."
1022   (elt bookmark 0))
1023
1024 (defun elpher-set-bookmark-display-string (bookmark display-string)
1025   "Set the display string of BOOKMARK to DISPLAY-STRING."
1026   (setcar bookmark display-string))
1027
1028 (defun elpher-bookmark-url (bookmark)
1029   "Get the address for BOOKMARK."
1030   (elt bookmark 1))
1031
1032
1033 (defun elpher-save-bookmarks (bookmarks)
1034   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1035 Beware that this completely replaces the existing contents of the file."
1036   (with-temp-file (locate-user-emacs-file "elpher2-bookmarks")
1037     (erase-buffer)
1038     (insert "; Elpher bookmarks file\n\n"
1039             "; Bookmarks are stored as a list of (label URL) items.\n"
1040             "; Feel free to edit by hand, but take care to ensure\n"
1041             "; the list structure remains intact.\n\n")
1042     (pp bookmarks (current-buffer))))
1043
1044 (defun elpher-load-bookmarks ()
1045   "Get the list of bookmarks from the users's bookmark file."
1046   (with-temp-buffer
1047     (ignore-errors
1048       (insert-file-contents (locate-user-emacs-file "elpher2-bookmarks"))
1049       (goto-char (point-min))
1050       (read (current-buffer)))))
1051
1052 (defun elpher-add-address-bookmark (address display-string)
1053   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1054 If ADDRESS is already bookmarked, update the label only."
1055   (let ((bookmarks (elpher-load-bookmarks))
1056         (url (elpher-address-to-url address)))
1057     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1058       (if existing-bookmark
1059           (elpher-set-bookmark-display-string existing-bookmark display-string)
1060         (add-to-list 'bookmarks (elpher-make-bookmark display-string url))))
1061     (elpher-save-bookmarks bookmarks)))
1062
1063 (defun elpher-remove-address-bookmark (address)
1064   "Remove any bookmark to ADDRESS."
1065   (let ((url (elpher-address-to-url address)))
1066     (elpher-save-bookmarks
1067      (seq-filter (lambda (bookmark)
1068                    (not (equal (elpher-bookmark-url bookmark) url)))
1069                  (elpher-load-bookmarks)))))
1070
1071 ;;; Interactive procedures
1072 ;;
1073
1074 (defun elpher-next-link ()
1075   "Move point to the next link on the current page."
1076   (interactive)
1077   (forward-button 1))
1078
1079 (defun elpher-prev-link ()
1080   "Move point to the previous link on the current page."
1081   (interactive)
1082   (backward-button 1))
1083
1084 (defun elpher-follow-current-link ()
1085   "Open the link or url at point."
1086   (interactive)
1087   (push-button))
1088
1089 (defun elpher-go ()
1090   "Go to a particular gopher site read from the minibuffer."
1091   (interactive)
1092   (let ((node
1093          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1094            (elpher-make-node host-or-url
1095                              (elpher-address-from-url host-or-url)))))
1096     (switch-to-buffer "*elpher*")
1097     (elpher-visit-node node)))
1098
1099 (defun elpher-go-current ()
1100   "Go to a particular site read from the minibuffer, initialized with the current URL."
1101   (interactive)
1102   (let ((address (elpher-node-address elpher-current-node)))
1103     (if (elpher-address-special-p address)
1104         (error "Command not valid for this page")
1105       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1106         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1107
1108 (defun elpher-redraw ()
1109   "Redraw current page."
1110   (interactive)
1111   (if elpher-current-node
1112       (elpher-visit-node elpher-current-node)
1113     (message "No current site.")))
1114
1115 (defun elpher-reload ()
1116   "Reload current page."
1117   (interactive)
1118   (if elpher-current-node
1119       (elpher-reload-current-node)
1120     (message "No current site.")))
1121
1122 (defun elpher-toggle-tls ()
1123   "Toggle TLS encryption mode."
1124   (interactive)
1125   (setq elpher-use-tls (not elpher-use-tls))
1126   (if elpher-use-tls
1127       (if (gnutls-available-p)
1128           (message "TLS mode enabled.  (Will not affect current page until reload.)")
1129         (setq elpher-use-tls nil)
1130         (error "Cannot enable TLS mode: GnuTLS not available"))
1131     (message "TLS mode disabled.  (Will not affect current page until reload.)")))
1132
1133 (defun elpher-view-raw ()
1134   "View raw server response for current page."
1135   (interactive)
1136   (if elpher-current-node
1137       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1138           (error "This page was not generated by a server")
1139         (elpher-visit-node elpher-current-node
1140                            #'elpher-get-node-raw))
1141     (message "No current site.")))
1142
1143 (defun elpher-back ()
1144   "Go to previous site."
1145   (interactive)
1146   (if (elpher-node-parent elpher-current-node)
1147       (elpher-visit-parent-node)
1148     (error "No previous site")))
1149
1150 (defun elpher-download ()
1151   "Download the link at point."
1152   (interactive)
1153   (let ((button (button-at (point))))
1154     (if button
1155         (let ((node (button-get button 'elpher-node)))
1156           (if (elpher-address-special-p (elpher-node-address node))
1157               (error "Cannot download this link")
1158             (elpher-visit-node (button-get button 'elpher-node)
1159                                #'elpher-get-node-download)))
1160       (error "No link selected"))))
1161
1162 (defun elpher-download-current ()
1163   "Download the current page."
1164   (interactive)
1165   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1166       (error "Cannot download this page")
1167     (elpher-visit-node (elpher-make-node
1168                         (elpher-node-display-string elpher-current-node)
1169                         (elpher-node-address elpher-current-node)
1170                         elpher-current-node)
1171                        #'elpher-get-node-download
1172                        t)))
1173
1174 (defun elpher-build-link-map ()
1175   "Build alist mapping link names to destination nodes in current buffer."
1176   (let ((link-map nil)
1177         (b (next-button (point-min) t)))
1178     (while b
1179       (add-to-list 'link-map (cons (button-label b) b))
1180       (setq b (next-button (button-start b))))
1181     link-map))
1182
1183 (defun elpher-jump ()
1184   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1185   (interactive)
1186   (let* ((link-map (elpher-build-link-map)))
1187     (if link-map
1188         (let ((key (let ((completion-ignore-case t))
1189                      (completing-read "Directory item/link: "
1190                                       link-map nil t))))
1191           (if (and key (> (length key) 0))
1192               (let ((b (cdr (assoc key link-map))))
1193                 (goto-char (button-start b))
1194                 (button-activate b)))))))
1195
1196 (defun elpher-root-dir ()
1197   "Visit root of current server."
1198   (interactive)
1199   (let ((address (elpher-node-address elpher-current-node)))
1200     (if (not (elpher-address-special-p address))
1201         (if (or (member (url-filename address) '("/" ""))
1202                 (and (elpher-address-gopher-p address)
1203                      (= (length (elpher-gopher-address-selector address)) 0)))
1204             (error "Already at root directory of current server")
1205           (let ((address-copy (elpher-address-from-url
1206                                (elpher-address-to-url address))))
1207             (setf (url-filename address-copy) "")
1208             (elpher-visit-node
1209              (elpher-make-node (elpher-address-to-url address-copy)
1210                                address-copy))))
1211       (error "Command invalid for this page"))))
1212
1213 (defun elpher-bookmarks-current-p ()
1214   "Return non-nil if current node is a bookmarks page."
1215   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1216          '(special bookmarks)))
1217
1218 (defun elpher-reload-bookmarks ()
1219   "Reload bookmarks if current node is a bookmarks page."
1220   (if (elpher-bookmarks-current-p)
1221       (elpher-reload-current-node)))
1222
1223 (defun elpher-bookmark-current ()
1224   "Bookmark the current node."
1225   (interactive)
1226   (let ((address (elpher-node-address elpher-current-node))
1227         (display-string (elpher-node-display-string elpher-current-node)))
1228     (if (not (elpher-address-special-p address))
1229         (let ((bookmark-display-string (read-string "Bookmark display string: "
1230                                                     display-string)))
1231           (elpher-add-address-bookmark address bookmark-display-string)
1232           (message "Bookmark added."))
1233       (error "Cannot bookmark %s" display-string))))
1234
1235 (defun elpher-bookmark-link ()
1236   "Bookmark the link at point."
1237   (interactive)
1238   (let ((button (button-at (point))))
1239     (if button
1240         (let* ((node (button-get button 'elpher-node))
1241                (address (elpher-node-address node))
1242                (display-string (elpher-node-display-string node)))
1243           (if (not (elpher-address-special-p address))
1244               (let ((bookmark-display-string (read-string "Bookmark display string: "
1245                                                           display-string)))
1246                 (elpher-add-address-bookmark address bookmark-display-string)
1247                 (elpher-reload-bookmarks)
1248                 (message "Bookmark added."))
1249             (error "Cannot bookmark %s" display-string)))
1250       (error "No link selected"))))
1251
1252 (defun elpher-unbookmark-current ()
1253   "Remove bookmark for the current node."
1254   (interactive)
1255   (let ((address (elpher-node-address elpher-current-node)))
1256     (unless (elpher-address-special-p address)
1257       (elpher-remove-address-bookmark address)
1258       (message "Bookmark removed."))))
1259
1260 (defun elpher-unbookmark-link ()
1261   "Remove bookmark for the link at point."
1262   (interactive)
1263   (let ((button (button-at (point))))
1264     (if button
1265         (let ((node (button-get button 'elpher-node)))
1266           (elpher-remove-address-bookmark (elpher-node-address node))
1267           (elpher-reload-bookmarks)
1268           (message "Bookmark removed."))
1269       (error "No link selected"))))
1270
1271 (defun elpher-bookmarks ()
1272   "Visit bookmarks page."
1273   (interactive)
1274   (switch-to-buffer "*elpher*")
1275   (elpher-visit-node
1276    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1277
1278 (defun elpher-info-node (node)
1279   "Display information on NODE."
1280   (let ((display-string (elpher-node-display-string node))
1281         (address (elpher-node-address node)))
1282     (if (elpher-address-special-p address)
1283         (message "Special page: %s" display-string)
1284       (message (elpher-address-to-url address)))))
1285
1286 (defun elpher-info-link ()
1287   "Display information on node corresponding to link at point."
1288   (interactive)
1289   (let ((button (button-at (point))))
1290     (if button
1291         (elpher-info-node (button-get button 'elpher-node))
1292       (error "No item selected"))))
1293
1294 (defun elpher-info-current ()
1295   "Display information on current node."
1296   (interactive)
1297   (elpher-info-node elpher-current-node))
1298
1299 (defun elpher-copy-node-url (node)
1300   "Copy URL representation of address of NODE to `kill-ring'."
1301   (let ((address (elpher-node-address node)))
1302     (if (elpher-address-special-p address)
1303         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1304       (let ((url (elpher-address-to-url address)))
1305         (message "Copied \"%s\" to kill-ring/clipboard." url)
1306         (kill-new url)))))
1307
1308 (defun elpher-copy-link-url ()
1309   "Copy URL of item at point to `kill-ring'."
1310   (interactive)
1311   (let ((button (button-at (point))))
1312     (if button
1313         (elpher-copy-node-url (button-get button 'elpher-node))
1314       (error "No item selected"))))
1315
1316 (defun elpher-copy-current-url ()
1317   "Copy URL of current node to `kill-ring'."
1318   (interactive)
1319   (elpher-copy-node-url elpher-current-node))
1320
1321 (defun elpher-set-coding-system ()
1322   "Specify an explicit character coding system."
1323   (interactive)
1324   (let ((system (read-coding-system "Set coding system to use (default is to autodetect): " nil)))
1325     (setq elpher-user-coding-system system)
1326     (if system
1327         (message "Coding system fixed to %s. (Reload to see effect)." system)
1328       (message "Coding system set to autodetect. (Reload to see effect)."))))
1329
1330
1331 ;;; Mode and keymap
1332 ;;
1333
1334 (defvar elpher-mode-map
1335   (let ((map (make-sparse-keymap)))
1336     (define-key map (kbd "TAB") 'elpher-next-link)
1337     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1338     (define-key map (kbd "u") 'elpher-back)
1339     (define-key map (kbd "O") 'elpher-root-dir)
1340     (define-key map (kbd "g") 'elpher-go)
1341     (define-key map (kbd "o") 'elpher-go-current)
1342     (define-key map (kbd "r") 'elpher-redraw)
1343     (define-key map (kbd "R") 'elpher-reload)
1344     (define-key map (kbd "T") 'elpher-toggle-tls)
1345     (define-key map (kbd ".") 'elpher-view-raw)
1346     (define-key map (kbd "d") 'elpher-download)
1347     (define-key map (kbd "D") 'elpher-download-current)
1348     (define-key map (kbd "m") 'elpher-jump)
1349     (define-key map (kbd "i") 'elpher-info-link)
1350     (define-key map (kbd "I") 'elpher-info-current)
1351     (define-key map (kbd "c") 'elpher-copy-link-url)
1352     (define-key map (kbd "C") 'elpher-copy-current-url)
1353     (define-key map (kbd "a") 'elpher-bookmark-link)
1354     (define-key map (kbd "A") 'elpher-bookmark-current)
1355     (define-key map (kbd "x") 'elpher-unbookmark-link)
1356     (define-key map (kbd "X") 'elpher-unbookmark-current)
1357     (define-key map (kbd "B") 'elpher-bookmarks)
1358     (define-key map (kbd "S") 'elpher-set-coding-system)
1359     (when (fboundp 'evil-define-key)
1360       (evil-define-key 'motion map
1361         (kbd "TAB") 'elpher-next-link
1362         (kbd "C-") 'elpher-follow-current-link
1363         (kbd "C-t") 'elpher-back
1364         (kbd "u") 'elpher-back
1365         (kbd "g") 'elpher-go
1366         (kbd "o") 'elpher-go-current
1367         (kbd "r") 'elpher-redraw
1368         (kbd "R") 'elpher-reload
1369         (kbd "T") 'elpher-toggle-tls
1370         (kbd ".") 'elpher-view-raw
1371         (kbd "d") 'elpher-download
1372         (kbd "D") 'elpher-download-current
1373         (kbd "m") 'elpher-jump
1374         (kbd "i") 'elpher-info-link
1375         (kbd "I") 'elpher-info-current
1376         (kbd "c") 'elpher-copy-link-url
1377         (kbd "C") 'elpher-copy-current-url
1378         (kbd "a") 'elpher-bookmark-link
1379         (kbd "A") 'elpher-bookmark-current
1380         (kbd "x") 'elpher-unbookmark-link
1381         (kbd "X") 'elpher-unbookmark-current
1382         (kbd "B") 'elpher-bookmarks
1383         (kbd "S") 'elpher-set-coding-system))
1384     map)
1385   "Keymap for gopher client.")
1386
1387 (define-derived-mode elpher-mode special-mode "elpher"
1388   "Major mode for elpher, an elisp gopher client.)
1389
1390 This mode is automatically enabled by the interactive
1391 functions which initialize the gopher client, namely
1392 `elpher', `elpher-go' and `elpher-bookmarks'.")
1393
1394 (when (fboundp 'evil-set-initial-state)
1395   (evil-set-initial-state 'elpher-mode 'motion))
1396
1397
1398 ;;; Main start procedure
1399 ;;
1400
1401 ;;;###autoload
1402 (defun elpher ()
1403   "Start elpher with default landing page."
1404   (interactive)
1405   (if (get-buffer "*elpher*")
1406       (switch-to-buffer "*elpher*")
1407     (switch-to-buffer "*elpher*")
1408     (setq elpher-current-node nil)
1409     (let ((start-node (elpher-make-node "Elpher Start Page"
1410                                         (elpher-make-special-address 'start))))
1411       (elpher-visit-node start-node)))
1412   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1413
1414 ;;; elpher.el ends here