elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
   4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
   5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
   6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
   7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
   8 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
   9 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
  10 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
  11 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
  12 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
  13 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
  14 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
  15 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
  16 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
  17 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
  18 ;; Copyright (C) 2019-2020 Tim Vaughan <plugd@thelambdalab.xyz>
  19
  20 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
  21 ;; Created: 11 April 2019
  22 ;; Version: 2.11.0
  23 ;; Keywords: comm gopher
  24 ;; Homepage: http://thelambdalab.xyz/elpher
  25 ;; Package-Requires: ((emacs "26.2"))
  26
  27 ;; This file is not part of GNU Emacs.
  28
  29 ;; This program is free software: you can redistribute it and/or modify
  30 ;; it under the terms of the GNU General Public License as published by
  31 ;; the Free Software Foundation, either version 3 of the License, or
  32 ;; (at your option) any later version.
  33
  34 ;; This program is distributed in the hope that it will be useful,
  35 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  36 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  37 ;; GNU General Public License for more details.
  38
  39 ;; You should have received a copy of the GNU General Public License
  40 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  41
  42 ;;; Commentary:
  43
  44 ;; Elpher aims to provide a practical and friendly gopher and gemini
  45 ;; client for GNU Emacs.  It supports:
  46
  47 ;; - intuitive keyboard and mouse-driven browsing,
  48 ;; - out-of-the-box compatibility with evil-mode,
  49 ;; - clickable web and gopher links *in plain text*,
  50 ;; - caching of visited sites,
  51 ;; - pleasant and configurable colouring of Gopher directories,
  52 ;; - direct visualisation of image files,
  53 ;; - a simple bookmark management system,
  54 ;; - gopher connections using TLS encryption,
  55 ;; - the fledgling Gemini protocol,
  56 ;; - the greybeard Finger protocol.
  57
  58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  59 ;; page containing information on key bindings and suggested starting
  60 ;; points for your gopher exploration.
  61
  62 ;; Full instructions can be found in the Elpher info manual.
  63
  64 ;; Elpher is under active development.  Any suggestions for
  65 ;; improvements are welcome, and can be made on the official
  66 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  67
  68 ;;; Code:
  69
  70 (provide 'elpher)
  71
  72 ;;; Dependencies
  73 ;;
  74
  75 (require 'seq)
  76 (require 'pp)
  77 (require 'shr)
  78 (require 'url-util)
  79 (require 'subr-x)
  80 (require 'dns)
  81 (require 'nsm)
  82 (require 'gnutls)
  83 (require 'socks)
  84
  85 ;;; ANSI colors or XTerm colors
  86
  87 (or (require 'xterm-color nil t)
  88     (require 'ansi-color))
  89
  90 (defalias 'elpher-color-filter-apply
  91   (if (fboundp 'xterm-color-filter)
  92       (lambda (s)
  93         (let ((xterm-color-render nil))
  94           (xterm-color-filter s)))
  95     'ansi-color-filter-apply)
  96   "A function to filter out ANSI escape sequences.")
  97 (defalias 'elpher-color-apply
  98   (if (fboundp 'xterm-color-filter)
  99       'xterm-color-filter
 100     'ansi-color-apply)
 101   "A function to apply ANSI escape sequences.")
 102
 103 ;;; Global constants
 104 ;;
 105
 106 (defconst elpher-version "2.10.2"
 107   "Current version of elpher.")
 108
 109 (defconst elpher-margin-width 6
 110   "Width of left-hand margin used when rendering indicies.")
 111
 112 (defconst elpher-type-map
 113   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
 114     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
 115     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 116     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 117     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
 118     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
 119     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 120     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 121     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
 122     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 123     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
 124     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
 125     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
 126     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
 127     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
 128     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
 129     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
 130     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
 131     ((special start) elpher-get-start-page nil))
 132   "Association list from types to getters, renderers, margin codes and index faces.")
 133
 134
 135 ;;; Internal variables
 136 ;;
 137
 138 ;; buffer-local
 139 (defvar elpher--gemini-page-headings nil
 140   "List of headings on the page.")
 141
 142 (defvar elpher--gemini-page-links nil
 143   "List of links on the page.")
 144
 145 (defvar elpher--gemini-page-links-cache (make-hash-table :test 'equal)
 146   "Hash of addresses and page links.")
 147
 148 ;;; Customization group
 149 ;;
 150
 151 (defgroup elpher nil
 152   "A gopher and gemini client."
 153   :group 'applications)
 154
 155 ;; General appearance and customizations
 156
 157 (defcustom elpher-open-urls-with-eww nil
 158   "If non-nil, open URL selectors using eww.
 159 Otherwise, use the system browser via the BROWSE-URL function."
 160   :type '(boolean))
 161
 162 (defcustom elpher-use-header t
 163   "If non-nil, display current page information in buffer header."
 164   :type '(boolean))
 165
 166 (defcustom elpher-auto-disengage-TLS nil
 167   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 168 While enabling this may seem convenient, it is also potentially dangerous as it
 169 allows switching from an encrypted channel back to plain text without user input."
 170   :type '(boolean))
 171
 172 (defcustom elpher-connection-timeout 5
 173   "Specifies the number of seconds to wait for a network connection to time out."
 174   :type '(integer))
 175
 176 (defcustom elpher-filter-ansi-from-text nil
 177   "If non-nil, filter ANSI escape sequences from text.
 178 The default behaviour is to use the ansi-color package to interpret these
 179 sequences."
 180   :type '(boolean))
 181
 182 (defcustom elpher-certificate-directory
 183   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 184   "Specify the name of the directory where client certificates will be stored.
 185 These certificates may be used for establishing authenticated TLS connections."
 186   :type '(directory))
 187
 188 (defcustom elpher-openssl-command "openssl"
 189   "The command used to launch openssl when generating TLS client certificates."
 190   :type '(file))
 191
 192 (defcustom elpher-default-url-type "gopher"
 193   "Default URL type (i.e. scheme) to assume if not explicitly given."
 194   :type '(choice (const "gopher")
 195                  (const "gemini")))
 196
 197 (defcustom elpher-gemini-TLS-cert-checks nil
 198   "If non-nil, verify gemini server TLS certs using the default security level.
 199 Otherwise, certificate verification is disabled.
 200
 201 This defaults to off because it is standard practice for Gemini servers
 202 to use self-signed certificates, meaning that most servers provide what
 203 EMACS considers to be an invalid certificate."
 204   :type '(boolean))
 205
 206 (defcustom elpher-gemini-max-fill-width 80
 207   "Specify the maximum default width (in columns) of text/gemini documents.
 208 The actual width used is the minimum of this value and the window width at
 209 the time when the text is rendered."
 210   :type '(integer))
 211
 212 (defcustom elpher-gemini-link-string "→ "
 213   "Specify the string used to indicate links when rendering gemini maps.
 214 May be empty."
 215   :type '(string))
 216
 217 (defcustom elpher-gemini-bullet-string "•"
 218   "Specify the string used for bullets when rendering gemini maps."
 219   :type '(string))
 220
 221 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 222   "Specify the name of the file where elpher bookmarks will be saved."
 223   :type '(file))
 224
 225 (defcustom elpher-ipv4-always nil
 226   "If non-nil, elpher will always use IPv4 to establish network connections.
 227 This can be useful when browsing from a computer that supports IPv6, because
 228 some servers which do not support IPv6 can take a long time to time-out."
 229   :type '(boolean))
 230
 231 (defcustom elpher-socks-always nil
 232   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 233 Otherwise, the SOCKS proxy is only used for connections to onion services."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-number-links nil
 237   "If non-nil, number links in gemini pages when rendering.
 238 Links can be accessed by pressing `v' ('visit') followed by the link number."
 239   :type '(boolean))
 240
 241 ;; Face customizations
 242
 243 (defgroup elpher-faces nil
 244   "Elpher face customizations."
 245   :group 'elpher)
 246
 247 (defface elpher-index
 248   '((t :inherit font-lock-keyword-face))
 249   "Face used for directory type directory records.")
 250
 251 (defface elpher-text
 252   '((t :inherit bold))
 253   "Face used for text type directory records.")
 254
 255 (defface elpher-info
 256   '((t :inherit default))
 257   "Face used for info type directory records.")
 258
 259 (defface elpher-image
 260   '((t :inherit font-lock-string-face))
 261   "Face used for image type directory records.")
 262
 263 (defface elpher-search
 264   '((t :inherit warning))
 265   "Face used for search type directory records.")
 266
 267 (defface elpher-html
 268   '((t :inherit font-lock-comment-face))
 269   "Face used for html type directory records.")
 270
 271 (defface elpher-gemini
 272   '((t :inherit font-lock-constant-face))
 273   "Face used for Gemini type directory records.")
 274
 275 (defface elpher-other-url
 276   '((t :inherit font-lock-comment-face))
 277   "Face used for other URL type links records.")
 278
 279 (defface elpher-telnet
 280   '((t :inherit font-lock-function-name-face))
 281   "Face used for telnet type directory records.")
 282
 283 (defface elpher-binary
 284   '((t :inherit font-lock-doc-face))
 285   "Face used for binary type directory records.")
 286
 287 (defface elpher-unknown
 288   '((t :inherit error))
 289   "Face used for directory records with unknown/unsupported types.")
 290
 291 (defface elpher-margin-key
 292   '((t :inherit bold))
 293   "Face used for directory margin key.")
 294
 295 (defface elpher-margin-brackets
 296   '((t :inherit shadow))
 297   "Face used for brackets around directory margin key.")
 298
 299 (defface elpher-gemini-heading1
 300   '((t :inherit bold :height 1.8))
 301   "Face used for gemini heading level 1.")
 302
 303 (defface elpher-gemini-heading2
 304   '((t :inherit bold :height 1.5))
 305   "Face used for gemini heading level 2.")
 306
 307 (defface elpher-gemini-heading3
 308   '((t :inherit bold :height 1.2))
 309   "Face used for gemini heading level 3.")
 310
 311 (defface elpher-gemini-preformatted
 312   '((t :inherit fixed-pitch))
 313   "Face used for pre-formatted gemini text blocks.")
 314
 315 (defface elpher-gemini-quoted
 316   '((t :inherit font-lock-doc-face))
 317   "Face used for gemini quoted texts.")
 318
 319 ;;; Model
 320 ;;
 321
 322 ;; Address
 323
 324 ;; An elpher "address" object is either a url object or a symbol.
 325 ;; Symbol addresses are "special", corresponding to pages generated
 326 ;; dynamically for and by elpher.  All others represent pages which
 327 ;; rely on content retrieved over the network.
 328
 329 (defun elpher-address-from-url (url-string)
 330   "Create a ADDRESS object corresponding to the given URL-STRING."
 331   (let ((data (match-data))) ; Prevent parsing clobbering match data
 332     (unwind-protect
 333         (let ((url (url-generic-parse-url url-string)))
 334           (unless (and (not (url-fullness url)) (url-type url))
 335             (setf (url-fullness url) t)
 336             (setf (url-filename url)
 337                   (url-unhex-string (url-filename url)))
 338             (unless (url-type url)
 339               (setf (url-type url) elpher-default-url-type))
 340             (unless (url-host url)
 341               (let ((p (split-string (url-filename url) "/" nil nil)))
 342                 (setf (url-host url) (car p))
 343                 (setf (url-filename url)
 344                       (if (cdr p)
 345                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 346                         ""))))
 347             (when (or (equal "gopher" (url-type url))
 348                       (equal "gophers" (url-type url)))
 349               ;; Gopher defaults
 350               (when (or (equal (url-filename url) "")
 351                         (equal (url-filename url) "/"))
 352                 (setf (url-filename url) "/1")))
 353             (when (equal "gemini" (url-type url))
 354               ;; Gemini defaults
 355               (if (equal (url-filename url) "")
 356                   (setf (url-filename url) "/"))))
 357           (elpher-remove-redundant-ports url))
 358       (set-match-data data))))
 359
 360 (defun elpher-remove-redundant-ports (address)
 361   "Remove redundant port specifiers from ADDRESS.
 362 Here 'redundant' means that the specified port matches the default
 363 for that protocol, eg 70 for gopher."
 364   (if (and (not (elpher-address-special-p address))
 365            (eq (url-portspec address) ; (url-port) is too slow!
 366                (pcase (url-type address)
 367                  ("gemini" 1965)
 368                  ((or "gopher" "gophers") 70)
 369                  ("finger" 79)
 370                  (_ -1))))
 371       (setf (url-portspec address) nil))
 372   address)
 373
 374 (defun elpher-make-gopher-address (type selector host port &optional tls)
 375   "Create an ADDRESS object using gopher directory record attributes.
 376 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 377 If the optional attribute TLS is non-nil, the address will be marked as
 378 requiring gopher-over-TLS."
 379   (cond
 380    ((equal type ?i) nil)
 381    ((and (equal type ?h)
 382          (string-prefix-p "URL:" selector))
 383     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 384    ((equal type ?8)
 385     (elpher-address-from-url
 386      (concat "telnet"
 387              "://" host
 388              ":" (number-to-string port))))
 389    (t
 390     (elpher-address-from-url
 391      (concat "gopher" (if tls "s" "")
 392              "://" host
 393              ":" (number-to-string port)
 394              "/" (string type)
 395              selector)))))
 396
 397 (defun elpher-make-special-address (type)
 398   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 399   type)
 400
 401 (defun elpher-address-to-url (address)
 402   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 403   (if (elpher-address-special-p address)
 404       nil
 405     (url-encode-url (url-recreate-url address))))
 406
 407 (defun elpher-address-type (address)
 408   "Retrieve type of ADDRESS object.
 409 This is used to determine how to retrieve and render the document the
 410 address refers to, via the table `elpher-type-map'."
 411   (if (symbolp address)
 412       (list 'special address)
 413     (let ((protocol (url-type address)))
 414       (cond ((or (equal protocol "gopher")
 415                  (equal protocol "gophers"))
 416              (list 'gopher
 417                    (if (member (url-filename address) '("" "/"))
 418                        ?1
 419                      (string-to-char (substring (url-filename address) 1)))))
 420             ((equal protocol "gemini")
 421              'gemini)
 422             ((equal protocol "telnet")
 423              'telnet)
 424             ((equal protocol "finger")
 425              'finger)
 426             (t 'other-url)))))
 427
 428 (defun elpher-address-protocol (address)
 429   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 430   (if (symbolp address)
 431       nil
 432     (url-type address)))
 433
 434 (defun elpher-address-filename (address)
 435   "Retrieve the filename component of ADDRESS.
 436 For gopher addresses this is a combination of the selector type and selector."
 437   (if (symbolp address)
 438       nil
 439     (url-filename address)))
 440
 441 (defun elpher-address-host (address)
 442   "Retrieve host from ADDRESS object."
 443   (url-host address))
 444
 445 (defun elpher-address-user (address)
 446   "Retrieve user from ADDRESS object."
 447   (url-user address))
 448
 449 (defun elpher-address-port (address)
 450   "Retrieve port from ADDRESS object.
 451 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 452   (if (symbolp address)
 453       0
 454     (url-port address)))
 455
 456 (defun elpher-address-special-p (address)
 457   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 458   (symbolp address))
 459
 460 (defun elpher-address-gopher-p (address)
 461   "Return non-nill if ADDRESS object is a gopher address."
 462   (and (not (elpher-address-special-p address))
 463        (member (elpher-address-protocol address) '("gopher gophers"))))
 464
 465 (defun elpher-gopher-address-selector (address)
 466   "Retrieve gopher selector from ADDRESS object."
 467   (if (member (url-filename address) '("" "/"))
 468       ""
 469     (url-unhex-string (substring (url-filename address) 2))))
 470
 471
 472 ;; Cache
 473
 474 (defvar elpher-content-cache (make-hash-table :test 'equal))
 475 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 476
 477 (defun elpher-get-cached-content (address)
 478   "Retrieve the cached content for ADDRESS, or nil if none exists."
 479   (gethash address elpher-content-cache))
 480
 481 (defun elpher-cache-content (address content)
 482   "Set the content cache for ADDRESS to CONTENT."
 483   (puthash address content elpher-content-cache))
 484
 485 (defun elpher-get-cached-pos (address)
 486   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 487   (gethash address elpher-pos-cache))
 488
 489 (defun elpher-cache-pos (address pos)
 490   "Set the cursor position cache for ADDRESS to POS."
 491   (puthash address pos elpher-pos-cache))
 492
 493
 494 ;; Page
 495
 496 (defun elpher-make-page (display-string address)
 497   "Create a page with DISPLAY-STRING and ADDRESS."
 498   (list display-string address))
 499
 500 (defun elpher-page-display-string (page)
 501   "Retrieve the display string corresponding to PAGE."
 502   (elt page 0))
 503
 504 (defun elpher-page-address (page)
 505   "Retrieve the address corresponding to PAGE."
 506   (elt page 1))
 507
 508 (defun elpher-page-set-address (page new-address)
 509   "Set the address corresponding to PAGE to NEW-ADDRESS."
 510   (setcar (cdr page) new-address))
 511
 512 (defvar elpher-current-page nil)        ; buffer local
 513 (defvar elpher-history nil)             ; buffer local
 514
 515 (defun elpher-visit-page (page &optional renderer no-history)
 516   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 517 Additionally, push PAGE onto the stack of previously-visited pages,
 518 unless NO-HISTORY is non-nil."
 519   (elpher-save-pos)
 520   (elpher-process-cleanup)
 521   (unless (or no-history
 522               (equal (elpher-page-address elpher-current-page)
 523                      (elpher-page-address page)))
 524     (push elpher-current-page elpher-history))
 525   (setq-local elpher-current-page page)
 526   (let* ((address (elpher-page-address page))
 527          (type (elpher-address-type address))
 528          (type-record (cdr (assoc type elpher-type-map)))
 529          (page-links nil))
 530     (if type-record
 531         (progn
 532           (funcall (car type-record)
 533                    (if renderer
 534                        renderer
 535                      (cadr type-record)))
 536           (setq page-links (gethash address elpher--gemini-page-links-cache))
 537           (if page-links
 538               (setq elpher--gemini-page-links page-links)))
 539       (elpher-visit-previous-page)
 540       (pcase type
 541         (`(gopher ,type-char)
 542          (error "Unsupported gopher selector type '%c' for '%s'"
 543                 type-char (elpher-address-to-url address)))
 544         (other
 545          (error "Unsupported address type '%S' for '%s'"
 546                 other (elpher-address-to-url address)))))))
 547
 548 (defun elpher-visit-previous-page ()
 549   "Visit the previous page in the history."
 550   (let ((previous-page (pop elpher-history)))
 551     (if previous-page
 552         (elpher-visit-page previous-page nil t)
 553       (error "No previous page"))))
 554
 555 (defun elpher-reload-current-page ()
 556   "Reload the current page, discarding any existing cached content."
 557   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 558   (elpher-visit-page elpher-current-page))
 559
 560 (defun elpher-save-pos ()
 561   "Save the current position of point to the current page."
 562   (when elpher-current-page
 563     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 564
 565 (defun elpher-restore-pos ()
 566   "Restore the position of point to that cached in the current page."
 567   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 568     (if pos
 569         (goto-char pos)
 570       (goto-char (point-min)))))
 571
 572
 573 ;;; Buffer preparation
 574 ;;
 575
 576 (defvar elpher-buffer-name "*elpher*"
 577   "The default name of the Elpher buffer.")
 578
 579 (defun elpher-update-header ()
 580   "If `elpher-use-header' is true, display current page info in window header."
 581   (if elpher-use-header
 582       (let* ((display-string (elpher-page-display-string elpher-current-page))
 583              (address (elpher-page-address elpher-current-page))
 584              (tls-string (if (and (not (elpher-address-special-p address))
 585                                   (member (elpher-address-protocol address)
 586                                           '("gophers" "gemini")))
 587                              " [TLS encryption]"
 588                            ""))
 589              (header (concat display-string
 590                              (propertize tls-string 'face 'bold))))
 591         (setq header-line-format header))))
 592
 593 (defmacro elpher-with-clean-buffer (&rest args)
 594   "Evaluate ARGS with a clean *elpher* buffer as current."
 595   `(with-current-buffer elpher-buffer-name
 596      (unless (eq major-mode 'elpher-mode)
 597        ;; avoid resetting buffer-local variables
 598        (elpher-mode))
 599      (let ((inhibit-read-only t))
 600        (setq-local network-security-level
 601                    (default-value 'network-security-level))
 602        (erase-buffer)
 603        (elpher-update-header)
 604        ,@args)))
 605
 606 (defun elpher-buffer-message (string &optional line)
 607   "Replace first line in elpher buffer with STRING.
 608 If LINE is non-nil, replace that line instead."
 609   (with-current-buffer elpher-buffer-name
 610     (let ((inhibit-read-only t))
 611       (goto-char (point-min))
 612       (if line
 613           (forward-line line))
 614       (let ((data (match-data)))
 615         (unwind-protect
 616             (progn
 617               (re-search-forward "^.*$")
 618               (replace-match string))
 619           (set-match-data data))))))
 620
 621
 622 ;;; Text Processing
 623 ;;
 624
 625 (defvar elpher-user-coding-system nil
 626   "User-specified coding system to use for decoding text responses.")
 627
 628 (defun elpher-decode (string)
 629   "Decode STRING using autodetected or user-specified coding system."
 630   (decode-coding-string string
 631                         (if elpher-user-coding-system
 632                             elpher-user-coding-system
 633                           (detect-coding-string string t))))
 634
 635 (defun elpher-preprocess-text-response (string)
 636   "Preprocess text selector response contained in STRING.
 637 This involes decoding the character representation, and clearing
 638 away CRs and any terminating period."
 639   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 640                                            (replace-regexp-in-string "\r" "" string))))
 641
 642
 643 ;;; Network error reporting
 644 ;;
 645
 646 (defun elpher-network-error (address error)
 647   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 648 ERROR can be either an error object or a string."
 649   (elpher-with-clean-buffer
 650    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 651            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 652            (if (stringp error) error (error-message-string error)) "\n"
 653            (propertize "\n----------------\n\n" 'face 'error)
 654            "Press 'u' to return to the previous page.")))
 655
 656
 657 ;;; General network communication
 658 ;;
 659
 660 (defvar elpher-network-timer nil
 661   "Timer used for network connections.")
 662
 663 (defvar elpher-use-tls nil
 664   "If non-nil, use TLS to communicate with gopher servers.")
 665
 666 (defvar elpher-client-certificate nil
 667   "If non-nil, contains client certificate details to use for TLS connections.")
 668
 669 (defun elpher-process-cleanup ()
 670   "Immediately shut down any extant elpher process and timers."
 671   (let ((p (get-process "elpher-process")))
 672     (if p (delete-process p)))
 673   (if (timerp elpher-network-timer)
 674       (cancel-timer elpher-network-timer)))
 675
 676 (defun elpher-get-host-response (address default-port query-string response-processor
 677                                          &optional use-tls force-ipv4)
 678   "Generic function for retrieving data from ADDRESS.
 679
 680 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 681 QUERY-STRING is a string sent to the host specified by ADDRESS to
 682 illicet a response.  This response is passed as an argument to the
 683 function RESPONSE-PROCESSOR.
 684
 685 If non-nil, USE-TLS specifies that the connection is to be made over
 686 TLS.  If set to gemini, the certificate verification will be disabled
 687 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 688
 689 If non-nil, FORCE-IPV4 causes the network connection to be made over
 690 ipv4 only.  (The default behaviour when this is not set depends on
 691 the host operating system and the local network capabilities."
 692   (if (and use-tls (not (gnutls-available-p)))
 693       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 694     (unless (< (elpher-address-port address) 65536)
 695       (error "Cannot establish network connection: port number > 65536"))
 696     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 697       (setq-local network-security-level 'low)
 698       (setq-local gnutls-verify-error nil))
 699     (condition-case nil
 700         (let* ((kill-buffer-query-functions nil)
 701                (port (elpher-address-port address))
 702                (service (if (> port 0) port default-port))
 703                (host (elpher-address-host address))
 704                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 705                (response-string-parts nil)
 706                (bytes-received 0)
 707                (hkbytes-received 0)
 708                (timer (run-at-time elpher-connection-timeout nil
 709                                    (lambda ()
 710                                      (elpher-process-cleanup)
 711                                      (cond
 712                                         ; Try again with IPv4
 713                                       ((not (or force-ipv4 socks))
 714                                        (message "Connection timed out.  Retrying with IPv4.")
 715                                        (elpher-get-host-response address default-port
 716                                                                  query-string
 717                                                                  response-processor
 718                                                                  use-tls t))
 719                                       ((and use-tls
 720                                             (not (eq use-tls 'gemini))
 721                                             (or elpher-auto-disengage-TLS
 722                                                 (y-or-n-p
 723                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 724                                        (setq elpher-use-tls nil)
 725                                        (elpher-get-host-response address default-port
 726                                                                  query-string
 727                                                                  response-processor
 728                                                                  nil force-ipv4))
 729                                       (t
 730                                        (elpher-network-error address "Connection time-out."))))))
 731                (gnutls-params (list :type 'gnutls-x509pki :hostname host
 732                                     :keylist (elpher-get-current-keylist address)))
 733                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 734                        (make-network-process :name "elpher-process"
 735                                              :host host
 736                                              :family (and force-ipv4 'ipv4)
 737                                              :service service
 738                                              :buffer nil
 739                                              :nowait t
 740                                              :tls-parameters
 741                                              (and use-tls
 742                                                   (cons 'gnutls-x509pki
 743                                                         (apply #'gnutls-boot-parameters
 744                                                                gnutls-params)))))))
 745           (setq elpher-network-timer timer)
 746           (set-process-coding-system proc 'binary 'binary)
 747           (set-process-query-on-exit-flag proc nil)
 748           (elpher-buffer-message (concat "Connecting to " host "..."
 749                                          " (press 'u' to abort)"))
 750           (set-process-filter proc
 751                               (lambda (_proc string)
 752                                 (when timer
 753                                   (cancel-timer timer)
 754                                   (setq timer nil))
 755                                 (setq bytes-received (+ bytes-received (length string)))
 756                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 757                                   (when (> new-hkbytes-received hkbytes-received)
 758                                     (setq hkbytes-received new-hkbytes-received)
 759                                     (elpher-buffer-message
 760                                         (concat "("
 761                                                 (number-to-string (/ hkbytes-received 10.0))
 762                                                 " MB read)")
 763                                         1)))
 764                                 (setq response-string-parts
 765                                       (cons string response-string-parts))))
 766           (set-process-sentinel proc
 767                                 (lambda (proc event)
 768                                   (when timer
 769                                     (cancel-timer timer))
 770                                   (condition-case the-error
 771                                       (cond
 772                                        ((string-prefix-p "open" event)    ; request URL
 773                                         (elpher-buffer-message
 774                                          (concat "Connected to " host ". Receiving data..."
 775                                                  " (press 'u' to abort)"))
 776                                         (let ((inhibit-eol-conversion t))
 777                                           (process-send-string proc query-string)))
 778                                        ((string-prefix-p "deleted" event)) ; do nothing
 779                                        ((and (not response-string-parts)
 780                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 781                                         ; Try again with IPv4
 782                                         (message "Connection failed. Retrying with IPv4.")
 783                                         (elpher-get-host-response address default-port
 784                                                                   query-string
 785                                                                   response-processor
 786                                                                   use-tls t))
 787                                        (response-string-parts
 788                                         (elpher-with-clean-buffer
 789                                          (insert "Data received.  Rendering..."))
 790                                         (funcall response-processor
 791                                                  (apply #'concat (reverse response-string-parts)))
 792                                         (elpher-restore-pos))
 793                                        (t
 794                                         (error "No response from server")))
 795                                     (error
 796                                      (elpher-network-error address the-error)))))
 797           (when socks
 798             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 799             (funcall (process-sentinel proc) proc "open\n")))
 800       (error
 801        (error "Error initiating connection to server")))))
 802
 803
 804 ;;; Client-side TLS Certificate Management
 805 ;;
 806
 807 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 808   "Generate a key and a self-signed client TLS certificate using openssl.
 809
 810 The Common Name field of the certificate is set to COMMON-NAME.  The
 811 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 812 the key and certificate files to write.
 813
 814 If TEMPORARY is non-nil, the certificate will be given an exporation
 815 period of one day, and the key and certificate files will be deleted
 816 when the certificate is no longer needed for the current session.
 817
 818 Otherwise, the certificate will be given a 100 year expiration period
 819 and the files will not be deleted.
 820
 821 The function returns a list containing the current host name, the
 822 temporary flag, and the key and cert file names in the form required
 823 by `gnutls-boot-parameters`."
 824   (let ((exp-key-file (expand-file-name key-file))
 825         (exp-cert-file (expand-file-name cert-file)))
 826     (condition-case nil
 827         (progn
 828           (call-process elpher-openssl-command nil nil nil
 829                         "req" "-x509" "-newkey" "rsa:2048"
 830                         "-days" (if temporary "1" "36500")
 831                         "-nodes"
 832                         "-subj" (concat "/CN=" common-name)
 833                         "-keyout" exp-key-file
 834                         "-out" exp-cert-file)
 835           (list (elpher-address-host (elpher-page-address elpher-current-page))
 836                 temporary exp-key-file exp-cert-file))
 837       (error
 838        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 839        (error "Program 'openssl', required for certificate generation, not found")))))
 840
 841 (defun elpher-generate-throwaway-certificate ()
 842   "Generate and return details of a throwaway certificate.
 843 The key and certificate files will be deleted when they are no
 844 longer needed for this session."
 845   (let* ((file-base (make-temp-name "elpher"))
 846          (key-file (concat temporary-file-directory file-base ".key"))
 847          (cert-file (concat temporary-file-directory file-base ".crt")))
 848     (elpher-generate-certificate file-base key-file cert-file t)))
 849
 850 (defun elpher-generate-persistent-certificate (file-base common-name)
 851   "Generate and return details of a persistent certificate.
 852 The argument FILE-BASE is used as the base for the key and certificate
 853 files, while COMMON-NAME specifies the common name field of the
 854 certificate.
 855
 856 The key and certificate files are written to in `elpher-certificate-directory'."
 857   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 858          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 859     (elpher-generate-certificate common-name key-file cert-file)))
 860
 861 (defun elpher-get-existing-certificate (file-base)
 862   "Return a certificate object corresponding to an existing certificate.
 863 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 864 the directory `elpher-certificate-directory'."
 865   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 866          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 867     (list (elpher-address-host (elpher-page-address elpher-current-page))
 868           nil
 869           (expand-file-name key-file)
 870           (expand-file-name cert-file))))
 871
 872 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 873   "Install a key+certificate file pair in `elpher-certificate-directory'.
 874 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 875 certificate files to install.  The argument FILE-BASE is used as the
 876 base for the installed key and certificate files."
 877   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 878          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 879     (if (or (file-exists-p key-file)
 880             (file-exists-p cert-file))
 881         (error "A certificate with base name %s is already installed" file-base))
 882     (copy-file key-file-src key-file)
 883     (copy-file cert-file-src cert-file)
 884     (list (elpher-address-host (elpher-page-address elpher-current-page))
 885           nil
 886           (expand-file-name key-file)
 887           (expand-file-name cert-file))))
 888
 889 (defun elpher-list-existing-certificates ()
 890   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 891   (unless (file-directory-p elpher-certificate-directory)
 892     (make-directory elpher-certificate-directory))
 893   (mapcar
 894    (lambda (file)
 895      (file-name-sans-extension file))
 896    (directory-files elpher-certificate-directory nil "\\.key$")))
 897
 898 (defun elpher-forget-current-certificate ()
 899   "Causes any current certificate to be forgotten.)
 900 In the case of throwaway certificates, the key and certificate files
 901 are also deleted."
 902   (interactive)
 903   (when elpher-client-certificate
 904     (unless (and (called-interactively-p 'any)
 905                  (not (y-or-n-p (concat "Really forget client certificate? "
 906                                         "(Throwaway certificates will be deleted.)"))))
 907       (when (cadr elpher-client-certificate)
 908         (delete-file (elt elpher-client-certificate 2))
 909         (delete-file (elt elpher-client-certificate 3)))
 910       (setq elpher-client-certificate nil)
 911       (if (called-interactively-p 'any)
 912           (message "Client certificate forgotten.")))))
 913
 914 (defun elpher-get-current-keylist (address)
 915   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 916
 917 This is obtained from the client certificate described by
 918 `elpher-current-certificate', if one is available and the host for
 919 that certificate matches the host in ADDRESS.
 920
 921 If `elpher-current-certificate' is non-nil, and its host name doesn't
 922 match that of ADDRESS, the certificate is forgotten."
 923   (if elpher-client-certificate
 924       (if (string= (car elpher-client-certificate)
 925                    (elpher-address-host address))
 926           (list (cddr elpher-client-certificate))
 927         (elpher-forget-current-certificate)
 928         (message "Disabling client certificate for new host")
 929         nil)
 930     nil))
 931
 932
 933 ;;; Gopher selector retrieval
 934 ;;
 935
 936 (defun elpher-get-gopher-response (address renderer)
 937   "Get response string from gopher server at ADDRESS and render using RENDERER."
 938   (elpher-get-host-response address 70
 939                             (concat (elpher-gopher-address-selector address) "\r\n")
 940                             renderer
 941                             (or (string= (elpher-address-protocol address) "gophers")
 942                                 elpher-use-tls)))
 943
 944 (defun elpher-get-gopher-page (renderer)
 945   "Getter function for gopher pages.
 946 The RENDERER procedure is used to display the contents of the page
 947 once they are retrieved from the gopher server."
 948   (let* ((address (elpher-page-address elpher-current-page))
 949          (content (elpher-get-cached-content address)))
 950     (if (and content (funcall renderer nil))
 951         (elpher-with-clean-buffer
 952          (insert content)
 953          (elpher-restore-pos))
 954       (elpher-with-clean-buffer
 955        (insert "LOADING... (use 'u' to cancel)\n"))
 956       (condition-case the-error
 957           (elpher-get-gopher-response address renderer)
 958         (error
 959          (elpher-network-error address the-error))))))
 960
 961 ;; Index rendering
 962
 963 (defun elpher-insert-index (string)
 964   "Insert the index corresponding to STRING into the current buffer."
 965   ;; Should be able to split directly on CRLF, but some non-conformant
 966   ;; LF-only servers sadly exist, hence the following.
 967   (let ((str-processed (elpher-preprocess-text-response string)))
 968     (dolist (line (split-string str-processed "\n"))
 969       (ignore-errors
 970         (unless (= (length line) 0)
 971           (let* ((type (elt line 0))
 972                  (fields (split-string (substring line 1) "\t"))
 973                  (display-string (elt fields 0))
 974                  (selector (elt fields 1))
 975                  (host (elt fields 2))
 976                  (port (if (elt fields 3)
 977                            (string-to-number (elt fields 3))
 978                          nil))
 979                  (address (elpher-make-gopher-address type selector host port)))
 980             (elpher-insert-index-record display-string address)))))))
 981
 982 (defun elpher-insert-margin (&optional type-name)
 983   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 984   (if type-name
 985       (progn
 986         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 987                         (concat
 988                          (propertize "[" 'face 'elpher-margin-brackets)
 989                          (propertize type-name 'face 'elpher-margin-key)
 990                          (propertize "]" 'face 'elpher-margin-brackets))))
 991         (insert " "))
 992     (insert (make-string elpher-margin-width ?\s))))
 993
 994 (defun elpher--page-button-help (_window buffer pos)
 995   "Function called by Emacs to generate mouse-over text.
 996 The arguments specify the BUFFER and the POS within the buffer of the item
 997 for which help is required.  The function returns the help to be
 998 displayed.  The _WINDOW argument is currently unused."
 999   (with-current-buffer buffer
1000     (let ((button (button-at pos)))
1001       (when button
1002         (let* ((page (button-get button 'elpher-page))
1003                (address (elpher-page-address page)))
1004           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
1005                                                 address
1006                                               (elpher-address-to-url address))))))))
1007
1008 (defun elpher-insert-index-record (display-string &optional address)
1009   "Function to insert an index record into the current buffer.
1010 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1011 If ADDRESS is not supplied or nil the record is rendered as an
1012 'information' line."
1013   (let* ((type (if address (elpher-address-type address) nil))
1014          (type-map-entry (cdr (assoc type elpher-type-map))))
1015     (if type-map-entry
1016         (let* ((margin-code (elt type-map-entry 2))
1017                (face (elt type-map-entry 3))
1018                (filtered-display-string (elpher-color-filter-apply display-string))
1019                (page (elpher-make-page filtered-display-string address)))
1020           (elpher-insert-margin margin-code)
1021           (insert-text-button filtered-display-string
1022                               'face face
1023                               'elpher-page page
1024                               'action #'elpher-click-link
1025                               'follow-link t
1026                               'help-echo #'elpher--page-button-help))
1027       (pcase type
1028         ('nil ;; Information
1029          (elpher-insert-margin)
1030          (let ((propertized-display-string
1031                 (propertize display-string 'face 'elpher-info)))
1032            (insert (elpher-process-text-for-display propertized-display-string))))
1033         (`(gopher ,selector-type) ;; Unknown
1034          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1035          (insert (propertize display-string
1036                              'face 'elpher-unknown)))))
1037     (insert "\n")))
1038
1039 (defun elpher-click-link (button)
1040   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1041   (let ((page (button-get button 'elpher-page)))
1042     (elpher-visit-page page)))
1043
1044 (defun elpher-render-index (data &optional _mime-type-string)
1045   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1046   (elpher-with-clean-buffer
1047    (if (not data)
1048        t
1049      (elpher-insert-index data)
1050      (elpher-cache-content (elpher-page-address elpher-current-page)
1051                            (buffer-string)))))
1052
1053 ;; Text rendering
1054
1055 (defconst elpher-url-regex
1056   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
1057   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
1058
1059 (defun elpher-buttonify-urls (string)
1060   "Turn substrings which look like urls in STRING into clickable buttons."
1061   (with-temp-buffer
1062     (insert string)
1063     (goto-char (point-min))
1064     (while (re-search-forward elpher-url-regex nil t)
1065       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1066                                     (elpher-address-from-url (match-string 0)))))
1067           (make-text-button (match-beginning 0)
1068                             (match-end 0)
1069                             'elpher-page  page
1070                             'action #'elpher-click-link
1071                             'follow-link t
1072                             'help-echo #'elpher--page-button-help
1073                             'face 'button)))
1074     (buffer-string)))
1075
1076 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
1077   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
1078
1079 (defun elpher-process-text-for-display (string)
1080   "Perform any desired processing of STRING prior to display as text.
1081 Currently includes buttonifying URLs and processing ANSI escape codes."
1082   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1083                              (elpher-color-filter-apply string)
1084                            (elpher-color-apply string))))
1085
1086 (defun elpher-render-text (data &optional _mime-type-string)
1087   "Render DATA as text.  MIME-TYPE-STRING is unused."
1088   (elpher-with-clean-buffer
1089    (if (not data)
1090        t
1091      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1092      (elpher-cache-content
1093       (elpher-page-address elpher-current-page)
1094       (buffer-string)))))
1095
1096 ;; Image retrieval
1097
1098 (defun elpher-render-image (data &optional _mime-type-string)
1099   "Display DATA as image.  MIME-TYPE-STRING is unused."
1100   (if (not data)
1101       nil
1102     (if (display-images-p)
1103         (progn
1104           (let ((image (create-image
1105                         data
1106                         nil t)))
1107             (elpher-with-clean-buffer
1108              (insert-image image)
1109              (elpher-restore-pos))))
1110       (elpher-render-download data))))
1111
1112 ;; Search retrieval and rendering
1113
1114 (defun elpher-get-gopher-query-page (renderer)
1115   "Getter for gopher addresses requiring input.
1116 The response is rendered using the rendering function RENDERER."
1117    (let* ((address (elpher-page-address elpher-current-page))
1118           (content (elpher-get-cached-content address))
1119           (aborted t))
1120     (if (and content (funcall renderer nil))
1121         (elpher-with-clean-buffer
1122          (insert content)
1123          (elpher-restore-pos)
1124          (message "Displaying cached search results.  Reload to perform a new search."))
1125       (unwind-protect
1126           (let* ((query-string (read-string "Query: "))
1127                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1128                  (search-address (elpher-make-gopher-address ?1
1129                                                              query-selector
1130                                                              (elpher-address-host address)
1131                                                              (elpher-address-port address)
1132                                                              (equal (elpher-address-type address) "gophers"))))
1133             (setq aborted nil)
1134
1135             (elpher-with-clean-buffer
1136              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1137             (elpher-get-gopher-response search-address renderer))
1138         (if aborted
1139             (elpher-visit-previous-page))))))
1140
1141 ;; Raw server response rendering
1142
1143 (defun elpher-render-raw (data &optional mime-type-string)
1144   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1145   (if (not data)
1146       nil
1147     (elpher-with-clean-buffer
1148      (when mime-type-string
1149        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1150      (insert data)
1151      (goto-char (point-min)))
1152     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1153
1154 ;; File save "rendering"
1155
1156 (defun elpher-render-download (data &optional _mime-type-string)
1157   "Save DATA to file.  MIME-TYPE-STRING is unused."
1158   (if (not data)
1159       nil
1160     (let* ((address (elpher-page-address elpher-current-page))
1161            (selector (if (elpher-address-gopher-p address)
1162                          (elpher-gopher-address-selector address)
1163                        (elpher-address-filename address))))
1164       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1165       (let* ((filename-proposal (file-name-nondirectory selector))
1166              (filename (read-file-name "Download complete. Save file as: "
1167                                        nil nil nil
1168                                        (if (> (length filename-proposal) 0)
1169                                            filename-proposal
1170                                          "download.file"))))
1171         (let ((coding-system-for-write 'binary))
1172           (with-temp-file filename
1173             (insert data)))
1174         (message (format "Saved to file %s." filename))))))
1175
1176 ;; HTML rendering
1177
1178 (defun elpher-render-html (data &optional _mime-type-string)
1179   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1180   (elpher-with-clean-buffer
1181    (if (not data)
1182        t
1183      (let ((dom (with-temp-buffer
1184                   (insert data)
1185                   (libxml-parse-html-region (point-min) (point-max)))))
1186        (shr-insert-document dom)))))
1187
1188 ;; Gemini page retrieval
1189
1190 (defvar elpher-gemini-redirect-chain)
1191
1192 (defun elpher-get-gemini-response (address renderer)
1193   "Get response string from gemini server at ADDRESS and render using RENDERER."
1194   (elpher-get-host-response address 1965
1195                             (concat (elpher-address-to-url address) "\r\n")
1196                             (lambda (response-string)
1197                               (elpher-process-gemini-response response-string renderer))
1198                             'gemini))
1199
1200 (defun elpher-parse-gemini-response (response)
1201   "Parse the RESPONSE string and return a list of components.
1202 The list is of the form (code meta body).  A response of nil implies
1203 that the response was malformed."
1204   (let ((header-end-idx (string-match "\r\n" response)))
1205     (if header-end-idx
1206         (let ((header (string-trim (substring response 0 header-end-idx)))
1207               (body (substring response (+ header-end-idx 2))))
1208           (if (>= (length header) 2)
1209               (let ((code (substring header 0 2))
1210                     (meta (string-trim (substring header 2))))
1211                 (list code meta body))
1212             (error "Malformed response: No response status found in header %s" header)))
1213       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1214
1215 (defun elpher-process-gemini-response (response-string renderer)
1216   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1217   (let ((response-components (elpher-parse-gemini-response response-string)))
1218     (let ((response-code (elt response-components 0))
1219           (response-meta (elt response-components 1))
1220           (response-body (elt response-components 2)))
1221       (pcase (elt response-code 0)
1222         (?1 ; Input required
1223          (elpher-with-clean-buffer
1224           (insert "Gemini server is requesting input."))
1225          (let* ((query-string
1226                  (if (eq (elt response-code 1) ?1)
1227                      (read-passwd (concat response-meta ": "))
1228                    (read-string (concat response-meta ": "))))
1229                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1230                 (old-fname (url-filename query-address)))
1231            (setf (url-filename query-address)
1232                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1233            (elpher-get-gemini-response query-address renderer)))
1234         (?2 ; Normal response
1235          (funcall renderer response-body response-meta))
1236         (?3 ; Redirect
1237          (message "Following redirect to %s" response-meta)
1238          (if (>= (length elpher-gemini-redirect-chain) 5)
1239              (error "More than 5 consecutive redirects followed"))
1240          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1241            (if (member redirect-address elpher-gemini-redirect-chain)
1242                (error "Redirect loop detected"))
1243            (if (not (string= (elpher-address-protocol redirect-address)
1244                              "gemini"))
1245                (error "Server tried to automatically redirect to non-gemini URL: %s"
1246                       response-meta))
1247            (elpher-page-set-address elpher-current-page redirect-address)
1248            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1249            (elpher-get-gemini-response redirect-address renderer)))
1250         (?4 ; Temporary failure
1251          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1252                 response-code response-meta))
1253         (?5 ; Permanent failure
1254          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1255                 response-code response-meta))
1256         (?6 ; Client certificate required
1257          (elpher-with-clean-buffer
1258           (if elpher-client-certificate
1259               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1260             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1261           (auto-fill-mode 1)
1262           (elpher-gemini-insert-text response-meta))
1263          (let ((chosen-certificate (elpher-choose-client-certificate)))
1264            (unless chosen-certificate
1265              (error "Gemini server requires a client certificate and none was provided"))
1266            (setq elpher-client-certificate chosen-certificate))
1267          (elpher-with-clean-buffer)
1268          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1269         (_other
1270          (error "Gemini server response unknown: %s %s"
1271                 response-code response-meta))))))
1272
1273 (defun elpher-choose-client-certificate ()
1274   "Prompt for a client certificate to use to establish a TLS connection."
1275   (let* ((read-answer-short t))
1276     (pcase (read-answer "What do you want to do? "
1277                         '(("throwaway" ?t
1278                            "generate and use throw-away certificate")
1279                           ("persistent" ?p
1280                            "generate new or use existing persistent certificate")
1281                           ("abort" ?a
1282                            "stop immediately")))
1283       ("throwaway"
1284        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1285       ("persistent"
1286        (let* ((existing-certificates (elpher-list-existing-certificates))
1287               (file-base (completing-read
1288                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1289                           existing-certificates)))
1290          (if (string-empty-p (string-trim file-base))
1291              nil
1292            (if (member file-base existing-certificates)
1293                (setq elpher-client-certificate
1294                      (elpher-get-existing-certificate file-base))
1295              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1296                                  '(("new" ?n
1297                                     "generate new certificate")
1298                                    ("install" ?i
1299                                     "install existing certificate")
1300                                    ("abort" ?a
1301                                     "stop immediately")))
1302                ("new"
1303                 (let ((common-name (read-string "Common Name field for new certificate: "
1304                                                 file-base)))
1305                   (message "New key and self-signed certificate written to %s"
1306                            elpher-certificate-directory)
1307                   (elpher-generate-persistent-certificate file-base common-name)))
1308                ("install"
1309                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1310                        (key-file (read-file-name "Key file: " nil nil t)))
1311                   (message "Key and certificate installed in %s for future use"
1312                            elpher-certificate-directory)
1313                   (elpher-install-and-use-existing-certificate key-file
1314                                                                cert-file
1315                                                                file-base)))
1316                ("abort" nil))))))
1317       ("abort" nil))))
1318
1319 (defun elpher-get-gemini-page (renderer)
1320   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1321   (let* ((address (elpher-page-address elpher-current-page))
1322          (content (elpher-get-cached-content address)))
1323     (condition-case the-error
1324         (if (and content (funcall renderer nil))
1325             (elpher-with-clean-buffer
1326               (insert content)
1327               (elpher-restore-pos))
1328           (elpher-with-clean-buffer
1329            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1330           (setq elpher-gemini-redirect-chain nil)
1331           (elpher-get-gemini-response address renderer))
1332       (error
1333        (elpher-network-error address the-error)))))
1334
1335 (defun elpher-render-gemini (body &optional mime-type-string)
1336   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1337   (if (not body)
1338       t
1339     (let* ((mime-type-string* (if (or (not mime-type-string)
1340                                       (string-empty-p mime-type-string))
1341                                   "text/gemini; charset=utf-8"
1342                                 mime-type-string))
1343            (mime-type-split (split-string mime-type-string* ";" t))
1344            (mime-type (string-trim (car mime-type-split)))
1345            (parameters (mapcar (lambda (s)
1346                                  (let ((key-val (split-string s "=")))
1347                                    (list (downcase (string-trim (car key-val)))
1348                                          (downcase (string-trim (cadr key-val))))))
1349                                (cdr mime-type-split))))
1350       (when (string-prefix-p "text/" mime-type)
1351         (setq body (decode-coding-string
1352                     body
1353                     (if (assoc "charset" parameters)
1354                         (intern (cadr (assoc "charset" parameters)))
1355                       'utf-8)))
1356         (setq body (replace-regexp-in-string "\r" "" body)))
1357       (pcase mime-type
1358         ((or "text/gemini" "")
1359          (elpher-render-gemini-map body parameters))
1360         ("text/html"
1361          (elpher-render-html body))
1362         ((pred (string-prefix-p "text/"))
1363          (elpher-render-gemini-plain-text body parameters))
1364         ((pred (string-prefix-p "image/"))
1365          (elpher-render-image body))
1366         (_other
1367          (elpher-render-download body))))))
1368
1369 (defun elpher-gemini-get-link-url (link-line)
1370   "Extract the url portion of LINK-LINE, a gemini map file link line.
1371 Returns nil in the event that the contents of the line following the
1372 => prefix are empty."
1373   (let ((l (split-string (substring link-line 2))))
1374     (if l
1375         (string-trim (elt l 0))
1376       nil)))
1377
1378 (defun elpher-gemini-get-link-display-string (link-line)
1379   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1380 Returns the url portion in the event that the display-string portion is empty."
1381   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1382          (idx (string-match "[ \t]" rest)))
1383     (string-trim (if idx
1384                      (substring rest (+ idx 1))
1385                    rest))))
1386
1387 (defun elpher-collapse-dot-sequences (filename)
1388   "Collapse dot sequences in FILENAME.
1389 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1390   (let* ((path (split-string filename "/"))
1391          (path-reversed-normalized
1392           (seq-reduce (lambda (a b)
1393                         (cond ((and a (equal b "..") (cdr a)))
1394                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1395                               ((equal b ".") a)
1396                               (t (cons b a))))
1397                       path nil)))
1398     (string-join (reverse path-reversed-normalized) "/")))
1399
1400 (defun elpher-address-from-gemini-url (url)
1401   "Extract address from URL with defaults as per gemini map files.
1402 While there's obviously some redundancy here between this function and
1403 `elpher-address-from-url', gemini map file URLs require enough special
1404 treatment that a separate function is warranted."
1405   (let ((address (url-generic-parse-url url))
1406         (current-address (elpher-page-address elpher-current-page)))
1407     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1408       (setf (url-fullness address) t)
1409       (if (url-host address) ;if there is an explicit host, filenames are absolute
1410           (if (string-empty-p (url-filename address))
1411               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1412         (setf (url-host address) (url-host current-address))
1413         (setf (url-port address) (url-port current-address))
1414         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1415           (setf (url-filename address)
1416                 (concat (file-name-directory (url-filename current-address))
1417                         (url-filename address)))))
1418       (unless (url-type address)
1419         (setf (url-type address) "gemini"))
1420       (when (equal (url-type address) "gemini")
1421         (setf (url-filename address)
1422               (elpher-collapse-dot-sequences (url-filename address)))))
1423     (elpher-remove-redundant-ports address)))
1424
1425 (defun elpher-gemini-insert-link (link-line)
1426   "Insert link described by LINK-LINE into a text/gemini document."
1427   (let* ((url (elpher-gemini-get-link-url link-line))
1428          (display-string (elpher-gemini-get-link-display-string link-line))
1429          (address (elpher-address-from-gemini-url url))
1430          (type (if address (elpher-address-type address) nil))
1431          (type-map-entry (cdr (assoc type elpher-type-map))))
1432     (setq elpher--gemini-page-links (append elpher--gemini-page-links `(,address)))
1433     (when display-string
1434       (insert elpher-gemini-link-string)
1435       (if type-map-entry
1436           (let* ((face (elt type-map-entry 3))
1437                  (filtered-display-string (elpher-color-filter-apply display-string))
1438                  (page (elpher-make-page filtered-display-string address)))
1439             (insert-text-button filtered-display-string
1440                                 'face face
1441                                 'elpher-page page
1442                                 'action #'elpher-click-link
1443                                 'follow-link t
1444                                 'help-echo #'elpher--page-button-help))
1445         (insert (propertize display-string 'face 'elpher-unknown)))
1446       (insert "\n"))))
1447
1448 (defun elpher-gemini-insert-header (header-line)
1449   "Insert header described by HEADER-LINE into a text/gemini document.
1450 The gemini map file line describing the header is given
1451 by HEADER-LINE."
1452   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1453     (let* ((level (length (match-string 1 header-line)))
1454            (header (substring header-line (match-end 0)))
1455            (face (pcase level
1456                    (1 'elpher-gemini-heading1)
1457                    (2 'elpher-gemini-heading2)
1458                    (3 'elpher-gemini-heading3)
1459                    (_ 'default)))
1460            (fill-column (if (display-graphic-p)
1461                             (/ (* fill-column
1462                                   (font-get (font-spec :name (face-font 'default)) :size))
1463                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1464       (setq elpher--gemini-page-headings (cons (cons header (point))
1465                                                elpher--gemini-page-headings))
1466       (unless (display-graphic-p)
1467         (insert (make-string level ?#) " "))
1468       (insert (propertize header 'face face))
1469       (newline))))
1470
1471 (defun elpher-gemini-insert-text (text-line)
1472   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1473 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1474 width defined by elpher-gemini-max-fill-width."
1475   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1476   (let* ((line-prefix (match-string 2 text-line))
1477          (processed-text-line
1478           (if line-prefix
1479               (cond ((string-prefix-p "*" line-prefix)
1480                      (concat
1481                       (replace-regexp-in-string "\*"
1482                                                 elpher-gemini-bullet-string
1483                                                 (match-string 0 text-line))
1484                       (substring text-line (match-end 0))))
1485                     ((string-prefix-p ">" line-prefix)
1486                      (propertize text-line 'face 'elpher-gemini-quoted))
1487                     (t text-line))
1488             text-line))
1489          (adaptive-fill-mode nil))
1490     (insert (elpher-process-text-for-display processed-text-line))
1491     (newline)))
1492
1493 (defun elpher-render-gemini-map (data _parameters)
1494   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1495   (elpher-with-clean-buffer
1496    (setq elpher--gemini-page-headings nil)
1497    (let ((preformatted nil)
1498          (link-counter 1))
1499      (auto-fill-mode 1)
1500      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1501      (setq elpher--gemini-page-links '())
1502      (dolist (line (split-string data "\n"))
1503        (cond
1504         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1505         (preformatted (insert (elpher-process-text-for-display
1506                                (propertize line 'face 'elpher-gemini-preformatted))
1507                               "\n"))
1508         ((string-prefix-p "=>" line)
1509          (progn
1510            (if elpher-gemini-number-links
1511                (insert
1512                 (concat
1513                  "["
1514                  (number-to-string link-counter)
1515                  "] ")))
1516            (setq link-counter (1+ link-counter))
1517            (elpher-gemini-insert-link line)))
1518         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1519         (t (elpher-gemini-insert-text line)))))
1520    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1521    (elpher-cache-content
1522     (elpher-page-address elpher-current-page)
1523     (buffer-string))
1524    (puthash
1525     (elpher-page-address elpher-current-page)
1526     elpher--gemini-page-links
1527     elpher--gemini-page-links-cache)))
1528
1529 (defun elpher-render-gemini-plain-text (data _parameters)
1530   "Render DATA as plain text file.  PARAMETERS is currently unused."
1531   (elpher-with-clean-buffer
1532    (insert (elpher-process-text-for-display data))
1533    (elpher-cache-content
1534     (elpher-page-address elpher-current-page)
1535     (buffer-string))))
1536
1537
1538 ;; Finger page connection
1539
1540 (defun elpher-get-finger-page (renderer)
1541   "Opens a finger connection to the current page address.
1542 The result is rendered using RENDERER."
1543   (let* ((address (elpher-page-address elpher-current-page))
1544          (content (elpher-get-cached-content address)))
1545     (if (and content (funcall renderer nil))
1546         (elpher-with-clean-buffer
1547          (insert content)
1548          (elpher-restore-pos))
1549       (elpher-with-clean-buffer
1550        (insert "LOADING... (use 'u' to cancel)\n"))
1551       (condition-case the-error
1552           (let* ((kill-buffer-query-functions nil)
1553                  (user (let ((filename (elpher-address-filename address)))
1554                          (if (> (length filename) 1)
1555                              (substring filename 1)
1556                            (elpher-address-user address)))))
1557             (elpher-get-host-response address 79
1558                                       (concat user "\r\n")
1559                                       renderer))
1560         (error
1561          (elpher-network-error address the-error))))))
1562
1563
1564 ;; Telnet page connection
1565
1566 (defun elpher-get-telnet-page (renderer)
1567   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1568   (when renderer
1569     (elpher-visit-previous-page)
1570     (error "Command not supported for telnet URLs"))
1571   (let* ((address (elpher-page-address elpher-current-page))
1572          (host (elpher-address-host address))
1573          (port (elpher-address-port address)))
1574     (elpher-visit-previous-page)
1575     (if (> port 0)
1576         (telnet host port)
1577       (telnet host))))
1578
1579
1580 ;; Other URL page opening
1581
1582 (defun elpher-get-other-url-page (renderer)
1583   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1584   (when renderer
1585     (elpher-visit-previous-page)
1586     (error "Command not supported for general URLs"))
1587   (let* ((address (elpher-page-address elpher-current-page))
1588          (url (elpher-address-to-url address)))
1589     (progn
1590       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1591       (message "Opening URL...")
1592       (if elpher-open-urls-with-eww
1593           (browse-web url)
1594         (browse-url url)))))
1595
1596
1597 ;; Start page page retrieval
1598
1599 (defun elpher-get-start-page (renderer)
1600   "Getter which displays the start page (RENDERER must be nil)."
1601   (when renderer
1602     (elpher-visit-previous-page)
1603     (error "Command not supported for start page"))
1604   (elpher-with-clean-buffer
1605    (insert "     --------------------------------------------\n"
1606            "           Elpher Gopher and Gemini Client       \n"
1607            "                   version " elpher-version "\n"
1608            "     --------------------------------------------\n"
1609            "\n"
1610            "Default bindings:\n"
1611            "\n"
1612            " - TAB/Shift-TAB: next/prev item on current page\n"
1613            " - RET/mouse-1: open item under cursor\n"
1614            " - m: select an item on current page by name (autocompletes)\n"
1615            " - u/mouse-3/U: return to previous page or to the start page\n"
1616            " - o/O: visit different selector or the root menu of the current server\n"
1617            " - g: go to a particular address (gopher, gemini, finger)\n"
1618            " - v: visit a numbered link on a gemini page\n"
1619            " - d/D: download item under cursor or current page\n"
1620            " - i/I: info on item under cursor or current page\n"
1621            " - c/C: copy URL representation of item under cursor or current page\n"
1622            " - a/A: bookmark the item under cursor or current page\n"
1623            " - x/X: remove bookmark for item under cursor or current page\n"
1624            " - B: visit the bookmarks page\n"
1625            " - r: redraw current page (using cached contents if available)\n"
1626            " - R: reload current page (regenerates cache)\n"
1627            " - S: set character coding system for gopher (default is to autodetect)\n"
1628            " - T: toggle TLS gopher mode\n"
1629            " - F: forget/discard current TLS client certificate\n"
1630            " - .: display the raw server response for the current page\n"
1631            "\n"
1632            "Start your exploration of gopher space and gemini:\n")
1633    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1634                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1635    (elpher-insert-index-record "Project Gemini home page"
1636                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1637    (insert "\n"
1638            "Alternatively, select a search engine and enter some search terms:\n")
1639    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1640                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1641    (elpher-insert-index-record "Gemini Search Engine"
1642                                (elpher-address-from-url "gemini://geminispace.info"))
1643    (insert "\n"
1644            "This page contains your bookmarked sites (also visit with B):\n")
1645    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1646    (insert "\n"
1647            "For Elpher release news or to leave feedback, visit:\n")
1648    (elpher-insert-index-record "The Elpher Project Page"
1649                                (elpher-make-gopher-address ?1
1650                                                            "/projects/elpher/"
1651                                                            "thelambdalab.xyz"
1652                                                            70))
1653    (insert "\n"
1654            "** Refer to the ")
1655    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1656      (insert-text-button "Elpher info manual"
1657                          'face 'link
1658                          'action (lambda (_)
1659                                    (interactive)
1660                                    (info "(elpher)"))
1661                          'follow-link t
1662                          'help-echo help-string))
1663    (insert " for the full documentation. **\n")
1664    (insert (propertize
1665             (concat "  (This should be available if you have installed Elpher using\n"
1666                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1667             'face 'shadow))
1668    (elpher-restore-pos)))
1669
1670 ;; Bookmarks page page retrieval
1671
1672 (defun elpher-get-bookmarks-page (renderer)
1673   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1674   (when renderer
1675     (elpher-visit-previous-page)
1676     (error "Command not supported for bookmarks page"))
1677   (elpher-with-clean-buffer
1678    (insert "---- Bookmark list ----\n\n")
1679    (let ((bookmarks (elpher-load-bookmarks)))
1680      (if bookmarks
1681          (dolist (bookmark bookmarks)
1682            (let ((display-string (elpher-bookmark-display-string bookmark))
1683                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1684              (elpher-insert-index-record display-string address)))
1685        (insert "No bookmarks found.\n")))
1686    (insert "\n-----------------------\n"
1687            "\n"
1688            "- u: return to previous page\n"
1689            "- x: delete selected bookmark\n"
1690            "- a: rename selected bookmark\n"
1691            "\n"
1692            "Bookmarks are stored in the file ")
1693    (let ((filename elpher-bookmarks-file)
1694          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1695      (insert-text-button filename
1696                          'face 'link
1697                          'action (lambda (_)
1698                                    (interactive)
1699                                    (find-file filename))
1700                          'follow-link t
1701                          'help-echo help-string))
1702    (insert "\n")
1703    (elpher-restore-pos)))
1704
1705
1706 ;;; Bookmarks
1707 ;;
1708
1709 (defun elpher-make-bookmark (display-string url)
1710   "Make an elpher bookmark.
1711 DISPLAY-STRING determines how the bookmark will appear in the
1712 bookmark list, while URL is the url of the entry."
1713   (list display-string url))
1714
1715 (defun elpher-bookmark-display-string (bookmark)
1716   "Get the display string of BOOKMARK."
1717   (elt bookmark 0))
1718
1719 (defun elpher-set-bookmark-display-string (bookmark display-string)
1720   "Set the display string of BOOKMARK to DISPLAY-STRING."
1721   (setcar bookmark display-string))
1722
1723 (defun elpher-bookmark-url (bookmark)
1724   "Get the address for BOOKMARK."
1725   (elt bookmark 1))
1726
1727 (defun elpher-save-bookmarks (bookmarks)
1728   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1729 Beware that this completely replaces the existing contents of the file."
1730   (let ((bookmark-dir (file-name-directory elpher-bookmarks-file)))
1731     (unless (file-directory-p bookmark-dir)
1732       (make-directory bookmark-dir)))
1733   (with-temp-file elpher-bookmarks-file
1734     (erase-buffer)
1735     (insert "; Elpher bookmarks file\n\n"
1736             "; Bookmarks are stored as a list of (label URL) items.\n"
1737             "; Feel free to edit by hand, but take care to ensure\n"
1738             "; the list structure remains intact.\n\n")
1739     (pp bookmarks (current-buffer))))
1740
1741 (defun elpher-load-bookmarks ()
1742   "Get the list of bookmarks from the users's bookmark file."
1743   (let ((bookmarks
1744          (with-temp-buffer
1745            (ignore-errors
1746              (insert-file-contents elpher-bookmarks-file)
1747              (goto-char (point-min))
1748              (read (current-buffer))))))
1749     (if (and bookmarks (listp (cadar bookmarks)))
1750         (progn
1751           (message "Reading old bookmark file. (Will be updated on write.)")
1752           (mapcar (lambda (old-bm)
1753                     (list (car old-bm)
1754                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1755                                                         (cadr old-bm)))))
1756                   bookmarks))
1757       bookmarks)))
1758
1759 (defun elpher-add-address-bookmark (address display-string)
1760   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1761 If ADDRESS is already bookmarked, update the label only."
1762   (let ((bookmarks (elpher-load-bookmarks))
1763         (url (elpher-address-to-url address)))
1764     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1765       (if existing-bookmark
1766           (elpher-set-bookmark-display-string existing-bookmark display-string)
1767         (push (elpher-make-bookmark display-string url) bookmarks)))
1768     (elpher-save-bookmarks bookmarks)))
1769
1770 (defun elpher-remove-address-bookmark (address)
1771   "Remove any bookmark to ADDRESS."
1772   (let ((url (elpher-address-to-url address)))
1773     (elpher-save-bookmarks
1774      (seq-filter (lambda (bookmark)
1775                    (not (equal (elpher-bookmark-url bookmark) url)))
1776                  (elpher-load-bookmarks)))))
1777
1778 ;;; Integrations
1779 ;;
1780
1781 (defun elpher-org-link-store ()
1782   "Store link to an `elpher' page in org-mode."
1783   (when (eq major-mode 'elpher-mode)
1784     (let ((link (concat "elpher:" (elpher-info-current)))
1785           (desc (car elpher-current-page)))
1786       (org-link-store-props :type "elpher"
1787                             :link link
1788                             :description desc)
1789       t)))
1790
1791 (defun elpher-org-link-follow (link _args)
1792   "Follow an `elpher' link in an `org' buffer."
1793   (require 'elpher)
1794   (message (concat "Got link: " link))
1795   (when (or
1796          (string-match-p "^gemini://.+" link)
1797          (string-match-p "^gopher://.+" link)
1798          (string-match-p "^finger://.+" link))
1799     (elpher-go (string-remove-prefix "elpher:" link))))
1800
1801 (with-eval-after-load "org"
1802   ;; Use `org-link-set-parameters' if defined (org-mode 9+)
1803   (if (fboundp 'org-link-set-parameters)
1804       (org-link-set-parameters "elpher"
1805                                :store #'elpher-org-link-store
1806                                :follow #'elpher-org-link-follow)
1807     (org-add-link-type "mu4e" 'elpher-org-link-follow)
1808     (add-hook 'org-store-link-functions 'elpher-org-link-store)))
1809
1810 (defun browse-url-elpher (url &rest _args)
1811   "Browse URL. This function is used by `browse-url'."
1812   (interactive (browse-url-interactive-arg "Elpher URL: "))
1813   (elpher-go url))
1814
1815 (with-eval-after-load "browse-url"
1816   ;; Use elpher to open gopher, finger and gemini links
1817   (when (boundp 'browse-url-default-handlers)
1818     (add-to-list 'browse-url-default-handlers
1819                  '("^\\(gopher\\|finger\\|gemini\\)://" . browse-url-elpher)))
1820   ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
1821   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
1822
1823 ;;; Interactive procedures
1824 ;;
1825
1826 (defun elpher-next-link ()
1827   "Move point to the next link on the current page."
1828   (interactive)
1829   (forward-button 1))
1830
1831 (defun elpher-prev-link ()
1832   "Move point to the previous link on the current page."
1833   (interactive)
1834   (backward-button 1))
1835
1836 (defun elpher-follow-current-link ()
1837   "Open the link or url at point."
1838   (interactive)
1839   (push-button))
1840
1841 ;;;###autoload
1842 (defun elpher-go (host-or-url)
1843   "Go to a particular gopher site HOST-OR-URL.
1844 When run interactively HOST-OR-URL is read from the minibuffer."
1845   (interactive "sGopher or Gemini URL: ")
1846   (let* ((cleaned-host-or-url (string-trim host-or-url))
1847          (address (elpher-address-from-url cleaned-host-or-url))
1848          (page (elpher-make-page cleaned-host-or-url address)))
1849     (switch-to-buffer elpher-buffer-name)
1850     (elpher-visit-page page)
1851     nil))
1852
1853 (defun elpher-go-current ()
1854   "Go to a particular site read from the minibuffer, initialized with the current URL."
1855   (interactive)
1856   (let ((address (elpher-page-address elpher-current-page)))
1857     (if (elpher-address-special-p address)
1858         (error "Command invalid for this page")
1859       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1860         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1861
1862 (defun elpher-visit-gemini-numbered-link (n)
1863   "Visit link designated by a number."
1864   (interactive "nLink number: ")
1865   (if (or (> n (length elpher--gemini-page-links))
1866           (< n 1))
1867       (user-error "Invalid link number"))
1868   (let ((address (nth (1- n) elpher--gemini-page-links)))
1869     (elpher-go (url-recreate-url address))))
1870
1871 (defun elpher-redraw ()
1872   "Redraw current page."
1873   (interactive)
1874   (elpher-visit-page elpher-current-page))
1875
1876 (defun elpher-reload ()
1877   "Reload current page."
1878   (interactive)
1879   (elpher-reload-current-page))
1880
1881 (defun elpher-toggle-tls ()
1882   "Toggle TLS encryption mode for gopher."
1883   (interactive)
1884   (setq elpher-use-tls (not elpher-use-tls))
1885   (if elpher-use-tls
1886       (if (gnutls-available-p)
1887           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1888         (setq elpher-use-tls nil)
1889         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1890     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1891
1892 (defun elpher-view-raw ()
1893   "View raw server response for current page."
1894   (interactive)
1895   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1896       (error "This page was not generated by a server")
1897     (elpher-visit-page elpher-current-page
1898                        #'elpher-render-raw)))
1899
1900 (defun elpher-back ()
1901   "Go to previous site."
1902   (interactive)
1903   (elpher-visit-previous-page))
1904
1905 (defun elpher-back-to-start ()
1906   "Go all the way back to the start page."
1907   (interactive)
1908   (setq-local elpher-current-page nil)
1909   (setq-local elpher-history nil)
1910   (let ((start-page (elpher-make-page "Elpher Start Page"
1911                                       (elpher-make-special-address 'start))))
1912     (elpher-visit-page start-page)))
1913
1914 (defun elpher-download ()
1915   "Download the link at point."
1916   (interactive)
1917   (let ((button (button-at (point))))
1918     (if button
1919         (let ((page (button-get button 'elpher-page)))
1920           (if (elpher-address-special-p (elpher-page-address page))
1921               (error "Cannot download %s"
1922                      (elpher-page-display-string page))
1923             (elpher-visit-page (button-get button 'elpher-page)
1924                                #'elpher-render-download)))
1925       (error "No link selected"))))
1926
1927 (defun elpher-download-current ()
1928   "Download the current page."
1929   (interactive)
1930   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1931       (error "Cannot download %s"
1932              (elpher-page-display-string elpher-current-page))
1933     (elpher-visit-page (elpher-make-page
1934                         (elpher-page-display-string elpher-current-page)
1935                         (elpher-page-address elpher-current-page))
1936                        #'elpher-render-download
1937                        t)))
1938
1939 (defun elpher-build-link-map ()
1940   "Build alist mapping link names to destination pages in current buffer."
1941   (let ((link-map nil)
1942         (b (next-button (point-min) t)))
1943     (while b
1944       (push (cons (button-label b) b) link-map)
1945       (setq b (next-button (button-start b))))
1946     link-map))
1947
1948 (defun elpher-jump ()
1949   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1950   (interactive)
1951   (let* ((link-map (elpher-build-link-map)))
1952     (if link-map
1953         (let ((key (let ((completion-ignore-case t))
1954                      (completing-read "Directory item/link: "
1955                                       link-map nil t))))
1956           (if (and key (> (length key) 0))
1957               (let ((b (cdr (assoc key link-map))))
1958                 (goto-char (button-start b))
1959                 (button-activate b)))))))
1960
1961 (defun elpher-root-dir ()
1962   "Visit root of current server."
1963   (interactive)
1964   (let ((address (elpher-page-address elpher-current-page)))
1965     (if (not (elpher-address-special-p address))
1966         (if (or (member (url-filename address) '("/" ""))
1967                 (and (elpher-address-gopher-p address)
1968                      (= (length (elpher-gopher-address-selector address)) 0)))
1969             (error "Already at root directory of current server")
1970           (let ((address-copy (elpher-address-from-url
1971                                (elpher-address-to-url address))))
1972             (setf (url-filename address-copy) "")
1973             (elpher-go (elpher-address-to-url address-copy))))
1974       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1975
1976 (defun elpher-bookmarks-current-p ()
1977   "Return non-nil if current page is a bookmarks page."
1978   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1979          '(special bookmarks)))
1980
1981 (defun elpher-reload-bookmarks ()
1982   "Reload bookmarks if current page is a bookmarks page."
1983   (if (elpher-bookmarks-current-p)
1984       (elpher-reload-current-page)))
1985
1986 (defun elpher-bookmark-current ()
1987   "Bookmark the current page."
1988   (interactive)
1989   (let ((address (elpher-page-address elpher-current-page))
1990         (display-string (elpher-page-display-string elpher-current-page)))
1991     (if (not (elpher-address-special-p address))
1992         (let ((bookmark-display-string (read-string "Bookmark display string: "
1993                                                     display-string)))
1994           (elpher-add-address-bookmark address bookmark-display-string)
1995           (message "Bookmark added."))
1996       (error "Cannot bookmark %s" display-string))))
1997
1998 (defun elpher-bookmark-link ()
1999   "Bookmark the link at point."
2000   (interactive)
2001   (let ((button (button-at (point))))
2002     (if button
2003         (let* ((page (button-get button 'elpher-page))
2004                (address (elpher-page-address page))
2005                (display-string (elpher-page-display-string page)))
2006           (if (not (elpher-address-special-p address))
2007               (let ((bookmark-display-string (read-string "Bookmark display string: "
2008                                                           display-string)))
2009                 (elpher-add-address-bookmark address bookmark-display-string)
2010                 (elpher-reload-bookmarks)
2011                 (message "Bookmark added."))
2012             (error "Cannot bookmark %s" display-string)))
2013       (error "No link selected"))))
2014
2015 (defun elpher-unbookmark-current ()
2016   "Remove bookmark for the current page."
2017   (interactive)
2018   (let ((address (elpher-page-address elpher-current-page)))
2019     (when (and (not (elpher-address-special-p address))
2020                (y-or-n-p "Really remove bookmark for the current page? "))
2021       (elpher-remove-address-bookmark address)
2022       (message "Bookmark removed."))))
2023
2024 (defun elpher-unbookmark-link ()
2025   "Remove bookmark for the link at point."
2026   (interactive)
2027   (let ((button (button-at (point))))
2028     (if button
2029         (when (y-or-n-p "Really remove bookmark for this link? ")
2030           (let ((page (button-get button 'elpher-page)))
2031             (elpher-remove-address-bookmark (elpher-page-address page))
2032             (elpher-reload-bookmarks)
2033             (message "Bookmark removed.")))
2034       (error "No link selected"))))
2035
2036 ;;;###autoload
2037 (defun elpher-bookmarks ()
2038   "Visit bookmarks page."
2039   (interactive)
2040   (switch-to-buffer elpher-buffer-name)
2041   (elpher-visit-page
2042    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
2043
2044 (defun elpher-info-page (page)
2045   "Display information on PAGE."
2046   (let ((display-string (elpher-page-display-string page))
2047         (address (elpher-page-address page)))
2048     (if (elpher-address-special-p address)
2049         (message "Special page: %s" display-string)
2050       (message "%s" (elpher-address-to-url address)))))
2051
2052 (defun elpher-info-link ()
2053   "Display information on page corresponding to link at point."
2054   (interactive)
2055   (let ((button (button-at (point))))
2056     (if button
2057         (elpher-info-page (button-get button 'elpher-page))
2058       (error "No item selected"))))
2059
2060 (defun elpher-info-current ()
2061   "Display information on current page."
2062   (interactive)
2063   (elpher-info-page elpher-current-page))
2064
2065 (defun elpher-copy-page-url (page)
2066   "Copy URL representation of address of PAGE to `kill-ring'."
2067   (let ((address (elpher-page-address page)))
2068     (if (elpher-address-special-p address)
2069         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
2070       (let ((url (elpher-address-to-url address)))
2071         (message "Copied \"%s\" to kill-ring/clipboard." url)
2072         (kill-new url)))))
2073
2074 (defun elpher-copy-link-url ()
2075   "Copy URL of item at point to `kill-ring'."
2076   (interactive)
2077   (let ((button (button-at (point))))
2078     (if button
2079         (elpher-copy-page-url (button-get button 'elpher-page))
2080       (error "No item selected"))))
2081
2082 (defun elpher-copy-current-url ()
2083   "Copy URL of current page to `kill-ring'."
2084   (interactive)
2085   (elpher-copy-page-url elpher-current-page))
2086
2087 (defun elpher-set-gopher-coding-system ()
2088   "Specify an explicit character coding system for gopher selectors."
2089   (interactive)
2090   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2091     (setq elpher-user-coding-system system)
2092     (if system
2093         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2094       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2095
2096
2097 ;;; Mode and keymap
2098 ;;
2099
2100 (defvar elpher-mode-map
2101   (let ((map (make-sparse-keymap)))
2102     (define-key map (kbd "TAB") 'elpher-next-link)
2103     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2104     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2105     (define-key map (kbd "u") 'elpher-back)
2106     (define-key map (kbd "U") 'elpher-back-to-start)
2107     (define-key map [mouse-3] 'elpher-back)
2108     (define-key map (kbd "O") 'elpher-root-dir)
2109     (define-key map (kbd "g") 'elpher-go)
2110     (define-key map (kbd "o") 'elpher-go-current)
2111     (define-key map (kbd "r") 'elpher-redraw)
2112     (define-key map (kbd "R") 'elpher-reload)
2113     (define-key map (kbd "T") 'elpher-toggle-tls)
2114     (define-key map (kbd ".") 'elpher-view-raw)
2115     (define-key map (kbd "d") 'elpher-download)
2116     (define-key map (kbd "D") 'elpher-download-current)
2117     (define-key map (kbd "m") 'elpher-jump)
2118     (define-key map (kbd "i") 'elpher-info-link)
2119     (define-key map (kbd "I") 'elpher-info-current)
2120     (define-key map (kbd "c") 'elpher-copy-link-url)
2121     (define-key map (kbd "C") 'elpher-copy-current-url)
2122     (define-key map (kbd "a") 'elpher-bookmark-link)
2123     (define-key map (kbd "A") 'elpher-bookmark-current)
2124     (define-key map (kbd "x") 'elpher-unbookmark-link)
2125     (define-key map (kbd "X") 'elpher-unbookmark-current)
2126     (define-key map (kbd "B") 'elpher-bookmarks)
2127     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
2128     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2129     (define-key map (kbd "v") 'elpher-visit-gemini-numbered-link)
2130     (when (fboundp 'evil-define-key*)
2131       (evil-define-key* 'motion map
2132         (kbd "TAB") 'elpher-next-link
2133         (kbd "C-") 'elpher-follow-current-link
2134         (kbd "C-t") 'elpher-back
2135         (kbd "u") 'elpher-back
2136         (kbd "-") 'elpher-back
2137         (kbd "^") 'elpher-back
2138         (kbd "U") 'elpher-back-to-start
2139         [mouse-3] 'elpher-back
2140         (kbd "o") 'elpher-go
2141         (kbd "O") 'elpher-go-current
2142         (kbd "r") 'elpher-redraw
2143         (kbd "R") 'elpher-reload
2144         (kbd "T") 'elpher-toggle-tls
2145         (kbd ".") 'elpher-view-raw
2146         (kbd "d") 'elpher-download
2147         (kbd "D") 'elpher-download-current
2148         (kbd "J") 'elpher-jump
2149         (kbd "i") 'elpher-info-link
2150         (kbd "I") 'elpher-info-current
2151         (kbd "c") 'elpher-copy-link-url
2152         (kbd "C") 'elpher-copy-current-url
2153         (kbd "a") 'elpher-bookmark-link
2154         (kbd "A") 'elpher-bookmark-current
2155         (kbd "x") 'elpher-unbookmark-link
2156         (kbd "X") 'elpher-unbookmark-current
2157         (kbd "B") 'elpher-bookmarks
2158         (kbd "S") 'elpher-set-gopher-coding-system
2159         (kbd "F") 'elpher-forget-current-certificate
2160         (kbd "v") 'elpher-visit-gemini-numbered-link))
2161     map)
2162   "Keymap for gopher client.")
2163
2164 (define-derived-mode elpher-mode special-mode "elpher"
2165   "Major mode for elpher, an elisp gopher client.
2166
2167 This mode is automatically enabled by the interactive
2168 functions which initialize the gopher client, namely
2169 `elpher', `elpher-go' and `elpher-bookmarks'."
2170   (setq-local elpher--gemini-page-headings nil)
2171   (setq-local elpher-current-page nil)
2172   (setq-local elpher-history nil)
2173   (setq-local elpher-buffer-name (buffer-name))
2174
2175   (setq-local imenu-create-index-function
2176               (lambda ()
2177                 elpher--gemini-page-headings)))
2178
2179 (when (fboundp 'evil-set-initial-state)
2180   (evil-set-initial-state 'elpher-mode 'motion))
2181
2182
2183 ;;; Main start procedure
2184 ;;
2185
2186 ;;;###autoload
2187 (defun elpher (&optional arg)
2188   "Start elpher with default landing page.
2189 The buffer used for Elpher sessions is determined by the value of
2190 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2191 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2192 will begin.  A numeric prefix arg (as in ‘C-u 42 M-x elpher RET’)
2193 switches to the session with that number, creating it if necessary.  A
2194 nonnumeric prefix arg means to create a new session.  Returns the
2195 buffer selected (or created)."
2196   (interactive "P")
2197   (let* ((name (default-value 'elpher-buffer-name))
2198          (buf (cond ((numberp arg)
2199                      (get-buffer-create (format "%s<%d>" name arg)))
2200                     (arg
2201                      (generate-new-buffer name))
2202                     (t
2203                      (get-buffer-create name)))))
2204     (pop-to-buffer-same-window buf)
2205     (unless (buffer-modified-p)
2206       (elpher-mode)
2207       (let ((start-page (elpher-make-page "Elpher Start Page"
2208                                           (elpher-make-special-address 'start))))
2209         (elpher-visit-page start-page))
2210       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2211
2212 ;;; elpher.el ends here