elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.10.2
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69 (require 'socks)
  70
  71
  72 ;;; Global constants
  73 ;;
  74
  75 (defconst elpher-version "2.10.2"
  76   "Current version of elpher.")
  77
  78 (defconst elpher-margin-width 6
  79   "Width of left-hand margin used when rendering indicies.")
  80
  81 (defconst elpher-type-map
  82   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  83     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  84     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  87     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  88     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  91     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  93     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  94     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  95     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  96     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  97     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  98     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  99     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
 100     ((special start) elpher-get-start-page nil))
 101   "Association list from types to getters, renderers, margin codes and index faces.")
 102
 103
 104 ;;; Customization group
 105 ;;
 106
 107 (defgroup elpher nil
 108   "A gopher and gemini client."
 109   :group 'applications)
 110
 111 ;; General appearance and customizations
 112
 113 (defcustom elpher-open-urls-with-eww nil
 114   "If non-nil, open URL selectors using eww.
 115 Otherwise, use the system browser via the BROWSE-URL function."
 116   :type '(boolean))
 117
 118 (defcustom elpher-use-header t
 119   "If non-nil, display current page information in buffer header."
 120   :type '(boolean))
 121
 122 (defcustom elpher-auto-disengage-TLS nil
 123   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 124 While enabling this may seem convenient, it is also potentially dangerous as it
 125 allows switching from an encrypted channel back to plain text without user input."
 126   :type '(boolean))
 127
 128 (defcustom elpher-connection-timeout 5
 129   "Specifies the number of seconds to wait for a network connection to time out."
 130   :type '(integer))
 131
 132 (defcustom elpher-filter-ansi-from-text nil
 133   "If non-nil, filter ANSI escape sequences from text.
 134 The default behaviour is to use the ansi-color package to interpret these
 135 sequences."
 136   :type '(boolean))
 137
 138 (defcustom elpher-certificate-directory
 139   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 140   "Specify the name of the directory where client certificates will be stored.
 141 These certificates may be used for establishing authenticated TLS connections."
 142   :type '(directory))
 143
 144 (defcustom elpher-openssl-command "openssl"
 145   "The command used to launch openssl when generating TLS client certificates."
 146   :type '(file))
 147
 148 (defcustom elpher-gemini-TLS-cert-checks nil
 149   "If non-nil, verify gemini server TLS certs using the default security level.
 150 Otherwise, certificate verification is disabled.
 151
 152 This defaults to off because it is standard practice for Gemini servers
 153 to use self-signed certificates, meaning that most servers provide what
 154 EMACS considers to be an invalid certificate."
 155   :type '(boolean))
 156
 157 (defcustom elpher-gemini-max-fill-width 80
 158   "Specify the maximum default width (in columns) of text/gemini documents.
 159 The actual width used is the minimum of this value and the window width at
 160 the time when the text is rendered."
 161   :type '(integer))
 162
 163 (defcustom elpher-gemini-link-string "→ "
 164   "Specify the string used to indicate links when rendering gemini maps.
 165 May be empty."
 166   :type '(string))
 167
 168 (defcustom elpher-gemini-bullet-string "•"
 169   "Specify the string used for bullets when rendering gemini maps."
 170   :type '(string))
 171
 172 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 173   "Specify the name of the file where elpher bookmarks will be saved."
 174   :type '(file))
 175
 176 (defcustom elpher-ipv4-always nil
 177   "If non-nil, elpher will always use IPv4 to establish network connections.
 178 This can be useful when browsing from a computer that supports IPv6, because
 179 some servers which do not support IPv6 can take a long time to time-out."
 180   :type '(boolean))
 181
 182 (defcustom elpher-socks-always nil
 183   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 184 Otherwise, the SOCKS proxy is only used for connections to onion services."
 185   :type '(boolean))
 186
 187 ;; Face customizations
 188
 189 (defgroup elpher-faces nil
 190   "Elpher face customizations."
 191   :group 'elpher)
 192
 193 (defface elpher-index
 194   '((t :inherit font-lock-keyword-face))
 195   "Face used for directory type directory records.")
 196
 197 (defface elpher-text
 198   '((t :inherit bold))
 199   "Face used for text type directory records.")
 200
 201 (defface elpher-info
 202   '((t :inherit default))
 203   "Face used for info type directory records.")
 204
 205 (defface elpher-image
 206   '((t :inherit font-lock-string-face))
 207   "Face used for image type directory records.")
 208
 209 (defface elpher-search
 210   '((t :inherit warning))
 211   "Face used for search type directory records.")
 212
 213 (defface elpher-html
 214   '((t :inherit font-lock-comment-face))
 215   "Face used for html type directory records.")
 216
 217 (defface elpher-gemini
 218   '((t :inherit font-lock-constant-face))
 219   "Face used for Gemini type directory records.")
 220
 221 (defface elpher-other-url
 222   '((t :inherit font-lock-comment-face))
 223   "Face used for other URL type links records.")
 224
 225 (defface elpher-telnet
 226   '((t :inherit font-lock-function-name-face))
 227   "Face used for telnet type directory records.")
 228
 229 (defface elpher-binary
 230   '((t :inherit font-lock-doc-face))
 231   "Face used for binary type directory records.")
 232
 233 (defface elpher-unknown
 234   '((t :inherit error))
 235   "Face used for directory records with unknown/unsupported types.")
 236
 237 (defface elpher-margin-key
 238   '((t :inherit bold))
 239   "Face used for directory margin key.")
 240
 241 (defface elpher-margin-brackets
 242   '((t :inherit shadow))
 243   "Face used for brackets around directory margin key.")
 244
 245 (defface elpher-gemini-heading1
 246   '((t :inherit bold :height 1.8))
 247   "Face used for gemini heading level 1.")
 248
 249 (defface elpher-gemini-heading2
 250   '((t :inherit bold :height 1.5))
 251   "Face used for gemini heading level 2.")
 252
 253 (defface elpher-gemini-heading3
 254   '((t :inherit bold :height 1.2))
 255   "Face used for gemini heading level 3.")
 256
 257 (defface elpher-gemini-preformatted
 258   '((t :inherit fixed-pitch))
 259   "Face used for pre-formatted gemini text blocks.")
 260
 261 (defface elpher-gemini-quoted
 262   '((t :inherit font-lock-doc-face))
 263   "Face used for gemini quoted texts.")
 264
 265 ;;; Model
 266 ;;
 267
 268 ;; Address
 269
 270 ;; An elpher "address" object is either a url object or a symbol.
 271 ;; Symbol addresses are "special", corresponding to pages generated
 272 ;; dynamically for and by elpher.  All others represent pages which
 273 ;; rely on content retrieved over the network.
 274
 275 (defun elpher-address-from-url (url-string)
 276   "Create a ADDRESS object corresponding to the given URL-STRING."
 277   (let ((data (match-data))) ; Prevent parsing clobbering match data
 278     (unwind-protect
 279         (let ((url (url-generic-parse-url url-string)))
 280           (unless (and (not (url-fullness url)) (url-type url))
 281             (setf (url-fullness url) t)
 282             (setf (url-filename url)
 283                   (url-unhex-string (url-filename url)))
 284             (unless (url-type url)
 285               (setf (url-type url) "gopher"))
 286             (when (or (equal "gopher" (url-type url))
 287                       (equal "gophers" (url-type url)))
 288               ;; Gopher defaults
 289               (unless (url-host url)
 290                 (setf (url-host url) (url-filename url))
 291                 (setf (url-filename url) ""))
 292               (when (or (equal (url-filename url) "")
 293                         (equal (url-filename url) "/"))
 294                 (setf (url-filename url) "/1")))
 295             (when (equal "gemini" (url-type url))
 296               ;; Gemini defaults
 297               (if (equal (url-filename url) "")
 298                   (setf (url-filename url) "/"))))
 299           (elpher-remove-redundant-ports url))
 300       (set-match-data data))))
 301
 302 (defun elpher-remove-redundant-ports (address)
 303   "Remove redundant port specifiers from ADDRESS.
 304 Here 'redundant' means that the specified port matches the default
 305 for that protocol, eg 70 for gopher."
 306   (if (and (not (elpher-address-special-p address))
 307            (eq (url-portspec address) ; (url-port) is too slow!
 308                (pcase (url-type address)
 309                  ("gemini" 1965)
 310                  ((or "gopher" "gophers") 70)
 311                  ("finger" 79)
 312                  (_ -1))))
 313       (setf (url-portspec address) nil))
 314   address)
 315
 316 (defun elpher-make-gopher-address (type selector host port &optional tls)
 317   "Create an ADDRESS object using gopher directory record attributes.
 318 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 319 If the optional attribute TLS is non-nil, the address will be marked as
 320 requiring gopher-over-TLS."
 321   (cond
 322    ((equal type ?i) nil)
 323    ((and (equal type ?h)
 324          (string-prefix-p "URL:" selector))
 325     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 326    ((equal type ?8)
 327     (elpher-address-from-url
 328      (concat "telnet"
 329              "://" host
 330              ":" (number-to-string port))))
 331    (t
 332     (elpher-address-from-url
 333      (concat "gopher" (if tls "s" "")
 334              "://" host
 335              ":" (number-to-string port)
 336              "/" (string type)
 337              selector)))))
 338
 339 (defun elpher-make-special-address (type)
 340   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 341   type)
 342
 343 (defun elpher-address-to-url (address)
 344   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 345   (if (elpher-address-special-p address)
 346       nil
 347     (url-encode-url (url-recreate-url address))))
 348
 349 (defun elpher-address-type (address)
 350   "Retrieve type of ADDRESS object.
 351 This is used to determine how to retrieve and render the document the
 352 address refers to, via the table `elpher-type-map'."
 353   (if (symbolp address)
 354       (list 'special address)
 355     (let ((protocol (url-type address)))
 356       (cond ((or (equal protocol "gopher")
 357                  (equal protocol "gophers"))
 358              (list 'gopher
 359                    (if (member (url-filename address) '("" "/"))
 360                        ?1
 361                      (string-to-char (substring (url-filename address) 1)))))
 362             ((equal protocol "gemini")
 363              'gemini)
 364             ((equal protocol "telnet")
 365              'telnet)
 366             ((equal protocol "finger")
 367              'finger)
 368             (t 'other-url)))))
 369
 370 (defun elpher-address-protocol (address)
 371   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 372   (if (symbolp address)
 373       nil
 374     (url-type address)))
 375
 376 (defun elpher-address-filename (address)
 377   "Retrieve the filename component of ADDRESS.
 378 For gopher addresses this is a combination of the selector type and selector."
 379   (if (symbolp address)
 380       nil
 381     (url-filename address)))
 382
 383 (defun elpher-address-host (address)
 384   "Retrieve host from ADDRESS object."
 385   (url-host address))
 386
 387 (defun elpher-address-user (address)
 388   "Retrieve user from ADDRESS object."
 389   (url-user address))
 390
 391 (defun elpher-address-port (address)
 392   "Retrieve port from ADDRESS object.
 393 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 394   (if (symbolp address)
 395       0
 396     (url-port address)))
 397
 398 (defun elpher-address-special-p (address)
 399   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 400   (symbolp address))
 401
 402 (defun elpher-address-gopher-p (address)
 403   "Return non-nill if ADDRESS object is a gopher address."
 404   (and (not (elpher-address-special-p address))
 405        (member (elpher-address-protocol address) '("gopher gophers"))))
 406
 407 (defun elpher-gopher-address-selector (address)
 408   "Retrieve gopher selector from ADDRESS object."
 409   (if (member (url-filename address) '("" "/"))
 410       ""
 411     (url-unhex-string (substring (url-filename address) 2))))
 412
 413
 414 ;; Cache
 415
 416 (defvar elpher-content-cache (make-hash-table :test 'equal))
 417 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 418
 419 (defun elpher-get-cached-content (address)
 420   "Retrieve the cached content for ADDRESS, or nil if none exists."
 421   (gethash address elpher-content-cache))
 422
 423 (defun elpher-cache-content (address content)
 424   "Set the content cache for ADDRESS to CONTENT."
 425   (puthash address content elpher-content-cache))
 426
 427 (defun elpher-get-cached-pos (address)
 428   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 429   (gethash address elpher-pos-cache))
 430
 431 (defun elpher-cache-pos (address pos)
 432   "Set the cursor position cache for ADDRESS to POS."
 433   (puthash address pos elpher-pos-cache))
 434
 435
 436 ;; Page
 437
 438 (defun elpher-make-page (display-string address)
 439   "Create a page with DISPLAY-STRING and ADDRESS."
 440   (list display-string address))
 441
 442 (defun elpher-page-display-string (page)
 443   "Retrieve the display string corresponding to PAGE."
 444   (elt page 0))
 445
 446 (defun elpher-page-address (page)
 447   "Retrieve the address corresponding to PAGE."
 448   (elt page 1))
 449
 450 (defun elpher-page-set-address (page new-address)
 451   "Set the address corresponding to PAGE to NEW-ADDRESS."
 452   (setcar (cdr page) new-address))
 453
 454 (defvar elpher-current-page nil)        ; buffer local
 455 (defvar elpher-history nil)             ; buffer local
 456
 457 (defun elpher-visit-page (page &optional renderer no-history)
 458   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 459 Additionally, push PAGE onto the stack of previously-visited pages,
 460 unless NO-HISTORY is non-nil."
 461   (elpher-save-pos)
 462   (elpher-process-cleanup)
 463   (unless (or no-history
 464               (equal (elpher-page-address elpher-current-page)
 465                      (elpher-page-address page)))
 466     (push elpher-current-page elpher-history))
 467   (setq-local elpher-current-page page)
 468   (let* ((address (elpher-page-address page))
 469          (type (elpher-address-type address))
 470          (type-record (cdr (assoc type elpher-type-map))))
 471     (if type-record
 472         (funcall (car type-record)
 473                  (if renderer
 474                      renderer
 475                    (cadr type-record)))
 476       (elpher-visit-previous-page)
 477       (pcase type
 478         (`(gopher ,type-char)
 479          (error "Unsupported gopher selector type '%c' for '%s'"
 480                 type-char (elpher-address-to-url address)))
 481         (other
 482          (error "Unsupported address type '%S' for '%s'"
 483                 other (elpher-address-to-url address)))))))
 484
 485 (defun elpher-visit-previous-page ()
 486   "Visit the previous page in the history."
 487   (let ((previous-page (pop elpher-history)))
 488     (if previous-page
 489         (elpher-visit-page previous-page nil t)
 490       (error "No previous page"))))
 491
 492 (defun elpher-reload-current-page ()
 493   "Reload the current page, discarding any existing cached content."
 494   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 495   (elpher-visit-page elpher-current-page))
 496
 497 (defun elpher-save-pos ()
 498   "Save the current position of point to the current page."
 499   (when elpher-current-page
 500     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 501
 502 (defun elpher-restore-pos ()
 503   "Restore the position of point to that cached in the current page."
 504   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 505     (if pos
 506         (goto-char pos)
 507       (goto-char (point-min)))))
 508
 509
 510 ;;; Buffer preparation
 511 ;;
 512
 513 (defvar elpher-buffer-name "*elpher*"
 514   "The default name of the Elpher buffer.")
 515
 516 (defun elpher-update-header ()
 517   "If `elpher-use-header' is true, display current page info in window header."
 518   (if elpher-use-header
 519       (let* ((display-string (elpher-page-display-string elpher-current-page))
 520              (address (elpher-page-address elpher-current-page))
 521              (tls-string (if (and (not (elpher-address-special-p address))
 522                                   (member (elpher-address-protocol address)
 523                                           '("gophers" "gemini")))
 524                              " [TLS encryption]"
 525                            ""))
 526              (header (concat display-string
 527                              (propertize tls-string 'face 'bold))))
 528         (setq header-line-format header))))
 529
 530 (defmacro elpher-with-clean-buffer (&rest args)
 531   "Evaluate ARGS with a clean *elpher* buffer as current."
 532   `(with-current-buffer elpher-buffer-name
 533      (unless (eq major-mode 'elpher-mode)
 534        ;; avoid resetting buffer-local variables
 535        (elpher-mode))
 536      (let ((inhibit-read-only t))
 537        (setq-local network-security-level
 538                    (default-value 'network-security-level))
 539        (erase-buffer)
 540        (elpher-update-header)
 541        ,@args)))
 542
 543 (defun elpher-buffer-message (string &optional line)
 544   "Replace first line in elpher buffer with STRING.
 545 If LINE is non-nil, replace that line instead."
 546   (with-current-buffer elpher-buffer-name
 547     (let ((inhibit-read-only t))
 548       (goto-char (point-min))
 549       (if line
 550           (forward-line line))
 551       (let ((data (match-data)))
 552         (unwind-protect
 553             (progn
 554               (re-search-forward "^.*$")
 555               (replace-match string))
 556           (set-match-data data))))))
 557
 558
 559 ;;; Text Processing
 560 ;;
 561
 562 (defvar elpher-user-coding-system nil
 563   "User-specified coding system to use for decoding text responses.")
 564
 565 (defun elpher-decode (string)
 566   "Decode STRING using autodetected or user-specified coding system."
 567   (decode-coding-string string
 568                         (if elpher-user-coding-system
 569                             elpher-user-coding-system
 570                           (detect-coding-string string t))))
 571
 572 (defun elpher-preprocess-text-response (string)
 573   "Preprocess text selector response contained in STRING.
 574 This involes decoding the character representation, and clearing
 575 away CRs and any terminating period."
 576   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 577                                            (replace-regexp-in-string "\r" "" string))))
 578
 579
 580 ;;; Network error reporting
 581 ;;
 582
 583 (defun elpher-network-error (address error)
 584   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 585 ERROR can be either an error object or a string."
 586   (elpher-with-clean-buffer
 587    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 588            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 589            (if (stringp error) error (error-message-string error)) "\n"
 590            (propertize "\n----------------\n\n" 'face 'error)
 591            "Press 'u' to return to the previous page.")))
 592
 593
 594 ;;; General network communication
 595 ;;
 596
 597 (defvar elpher-network-timer nil
 598   "Timer used for network connections.")
 599
 600 (defvar elpher-use-tls nil
 601   "If non-nil, use TLS to communicate with gopher servers.")
 602
 603 (defvar elpher-client-certificate nil
 604   "If non-nil, contains client certificate details to use for TLS connections.")
 605
 606 (defun elpher-process-cleanup ()
 607   "Immediately shut down any extant elpher process and timers."
 608   (let ((p (get-process "elpher-process")))
 609     (if p (delete-process p)))
 610   (if (timerp elpher-network-timer)
 611       (cancel-timer elpher-network-timer)))
 612
 613 (defun elpher-get-host-response (address default-port query-string response-processor
 614                                          &optional use-tls force-ipv4)
 615   "Generic function for retrieving data from ADDRESS.
 616
 617 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 618 QUERY-STRING is a string sent to the host specified by ADDRESS to
 619 illicet a response.  This response is passed as an argument to the
 620 function RESPONSE-PROCESSOR.
 621
 622 If non-nil, USE-TLS specifies that the connection is to be made over
 623 TLS.  If set to gemini, the certificate verification will be disabled
 624 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 625
 626 If non-nil, FORCE-IPV4 causes the network connection to be made over
 627 ipv4 only.  (The default behaviour when this is not set depends on
 628 the host operating system and the local network capabilities."
 629   (if (and use-tls (not (gnutls-available-p)))
 630       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 631     (unless (< (elpher-address-port address) 65536)
 632       (error "Cannot establish network connection: port number > 65536"))
 633     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 634       (setq-local network-security-level 'low))
 635     (condition-case nil
 636         (let* ((kill-buffer-query-functions nil)
 637                (port (elpher-address-port address))
 638                (service (if (> port 0) port default-port))
 639                (host (elpher-address-host address))
 640                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 641                (response-string-parts nil)
 642                (bytes-received 0)
 643                (hkbytes-received 0)
 644                (timer (run-at-time elpher-connection-timeout nil
 645                                    (lambda ()
 646                                      (elpher-process-cleanup)
 647                                      (cond
 648                                         ; Try again with IPv4
 649                                       ((not (or force-ipv4 socks))
 650                                        (message "Connection timed out.  Retrying with IPv4.")
 651                                        (elpher-get-host-response address default-port
 652                                                                  query-string
 653                                                                  response-processor
 654                                                                  use-tls t))
 655                                       ((and use-tls
 656                                             (not (eq use-tls 'gemini))
 657                                             (or elpher-auto-disengage-TLS
 658                                                 (y-or-n-p
 659                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 660                                        (setq elpher-use-tls nil)
 661                                        (elpher-get-host-response address default-port
 662                                                                  query-string
 663                                                                  response-processor
 664                                                                  nil force-ipv4))
 665                                       (t
 666                                        (elpher-network-error address "Connection time-out."))))))
 667                (gnutls-params (list :type 'gnutls-x509pki :hostname host
 668                                     :keylist (elpher-get-current-keylist address)))
 669                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 670                        (make-network-process :name "elpher-process"
 671                                              :host host
 672                                              :family (and force-ipv4 'ipv4)
 673                                              :service service
 674                                              :buffer nil
 675                                              :nowait t
 676                                              :tls-parameters
 677                                              (and use-tls
 678                                                   (cons 'gnutls-x509pki
 679                                                         (apply #'gnutls-boot-parameters
 680                                                                gnutls-params)))))))
 681           (setq elpher-network-timer timer)
 682           (set-process-coding-system proc 'binary 'binary)
 683           (set-process-query-on-exit-flag proc nil)
 684           (elpher-buffer-message (concat "Connecting to " host "..."
 685                                          " (press 'u' to abort)"))
 686           (set-process-filter proc
 687                               (lambda (_proc string)
 688                                 (when timer
 689                                   (cancel-timer timer)
 690                                   (setq timer nil))
 691                                 (setq bytes-received (+ bytes-received (length string)))
 692                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 693                                   (when (> new-hkbytes-received hkbytes-received)
 694                                     (setq hkbytes-received new-hkbytes-received)
 695                                     (elpher-buffer-message
 696                                         (concat "("
 697                                                 (number-to-string (/ hkbytes-received 10.0))
 698                                                 " MB read)")
 699                                         1)))
 700                                 (setq response-string-parts
 701                                       (cons string response-string-parts))))
 702           (set-process-sentinel proc
 703                                 (lambda (proc event)
 704                                   (when timer
 705                                     (cancel-timer timer))
 706                                   (condition-case the-error
 707                                       (cond
 708                                        ((string-prefix-p "open" event)    ; request URL
 709                                         (elpher-buffer-message
 710                                          (concat "Connected to " host ". Receiving data..."
 711                                                  " (press 'u' to abort)"))
 712                                         (let ((inhibit-eol-conversion t))
 713                                           (process-send-string proc query-string)))
 714                                        ((string-prefix-p "deleted" event)) ; do nothing
 715                                        ((and (not response-string-parts)
 716                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 717                                         ; Try again with IPv4
 718                                         (message "Connection failed. Retrying with IPv4.")
 719                                         (elpher-get-host-response address default-port
 720                                                                   query-string
 721                                                                   response-processor
 722                                                                   use-tls t))
 723                                        (response-string-parts
 724                                         (elpher-with-clean-buffer
 725                                          (insert "Data received.  Rendering..."))
 726                                         (funcall response-processor
 727                                                  (apply #'concat (reverse response-string-parts)))
 728                                         (elpher-restore-pos))
 729                                        (t
 730                                         (error "No response from server")))
 731                                     (error
 732                                      (elpher-network-error address the-error)))))
 733           (when socks
 734             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 735             (funcall (process-sentinel proc) proc "open\n")))
 736       (error
 737        (error "Error initiating connection to server")))))
 738
 739
 740 ;;; Client-side TLS Certificate Management
 741 ;;
 742
 743 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 744   "Generate a key and a self-signed client TLS certificate using openssl.
 745
 746 The Common Name field of the certificate is set to COMMON-NAME.  The
 747 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 748 the key and certificate files to write.
 749
 750 If TEMPORARY is non-nil, the certificate will be given an exporation
 751 period of one day, and the key and certificate files will be deleted
 752 when the certificate is no longer needed for the current session.
 753
 754 Otherwise, the certificate will be given a 100 year expiration period
 755 and the files will not be deleted.
 756
 757 The function returns a list containing the current host name, the
 758 temporary flag, and the key and cert file names in the form required
 759 by `gnutls-boot-parameters`."
 760   (let ((exp-key-file (expand-file-name key-file))
 761         (exp-cert-file (expand-file-name cert-file)))
 762     (condition-case nil
 763         (progn
 764           (call-process elpher-openssl-command nil nil nil
 765                         "req" "-x509" "-newkey" "rsa:2048"
 766                         "-days" (if temporary "1" "36500")
 767                         "-nodes"
 768                         "-subj" (concat "/CN=" common-name)
 769                         "-keyout" exp-key-file
 770                         "-out" exp-cert-file)
 771           (list (elpher-address-host (elpher-page-address elpher-current-page))
 772                 temporary exp-key-file exp-cert-file))
 773       (error
 774        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 775        (error "Program 'openssl', required for certificate generation, not found")))))
 776
 777 (defun elpher-generate-throwaway-certificate ()
 778   "Generate and return details of a throwaway certificate.
 779 The key and certificate files will be deleted when they are no
 780 longer needed for this session."
 781   (let* ((file-base (make-temp-name "elpher"))
 782          (key-file (concat temporary-file-directory file-base ".key"))
 783          (cert-file (concat temporary-file-directory file-base ".crt")))
 784     (elpher-generate-certificate file-base key-file cert-file t)))
 785
 786 (defun elpher-generate-persistent-certificate (file-base common-name)
 787   "Generate and return details of a persistent certificate.
 788 The argument FILE-BASE is used as the base for the key and certificate
 789 files, while COMMON-NAME specifies the common name field of the
 790 certificate.
 791
 792 The key and certificate files are written to in `elpher-certificate-directory'."
 793   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 794          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 795     (elpher-generate-certificate common-name key-file cert-file)))
 796
 797 (defun elpher-get-existing-certificate (file-base)
 798   "Return a certificate object corresponding to an existing certificate.
 799 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 800 the directory `elpher-certificate-directory'."
 801   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 802          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 803     (list (elpher-address-host (elpher-page-address elpher-current-page))
 804           nil
 805           (expand-file-name key-file)
 806           (expand-file-name cert-file))))
 807
 808 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 809   "Install a key+certificate file pair in `elpher-certificate-directory'.
 810 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 811 certificate files to install.  The argument FILE-BASE is used as the
 812 base for the installed key and certificate files."
 813   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 814          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 815     (if (or (file-exists-p key-file)
 816             (file-exists-p cert-file))
 817         (error "A certificate with base name %s is already installed" file-base))
 818     (copy-file key-file-src key-file)
 819     (copy-file cert-file-src cert-file)
 820     (list (elpher-address-host (elpher-page-address elpher-current-page))
 821           nil
 822           (expand-file-name key-file)
 823           (expand-file-name cert-file))))
 824
 825 (defun elpher-list-existing-certificates ()
 826   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 827   (unless (file-directory-p elpher-certificate-directory)
 828     (make-directory elpher-certificate-directory))
 829   (mapcar
 830    (lambda (file)
 831      (file-name-sans-extension file))
 832    (directory-files elpher-certificate-directory nil "\.key$")))
 833
 834 (defun elpher-forget-current-certificate ()
 835   "Causes any current certificate to be forgotten.)
 836 In the case of throwaway certificates, the key and certificate files
 837 are also deleted."
 838   (interactive)
 839   (when elpher-client-certificate
 840     (unless (and (called-interactively-p 'any)
 841                  (not (y-or-n-p (concat "Really forget client certificate? "
 842                                         "(Throwaway certificates will be deleted.)"))))
 843       (when (cadr elpher-client-certificate)
 844         (delete-file (elt elpher-client-certificate 2))
 845         (delete-file (elt elpher-client-certificate 3)))
 846       (setq elpher-client-certificate nil)
 847       (if (called-interactively-p 'any)
 848           (message "Client certificate forgotten.")))))
 849
 850 (defun elpher-get-current-keylist (address)
 851   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 852
 853 This is obtained from the client certificate described by
 854 `elpher-current-certificate', if one is available and the host for
 855 that certificate matches the host in ADDRESS.
 856
 857 If `elpher-current-certificate' is non-nil, and its host name doesn't
 858 match that of ADDRESS, the certificate is forgotten."
 859   (if elpher-client-certificate
 860       (if (string= (car elpher-client-certificate)
 861                    (elpher-address-host address))
 862           (list (cddr elpher-client-certificate))
 863         (elpher-forget-current-certificate)
 864         (message "Disabling client certificate for new host")
 865         nil)
 866     nil))
 867
 868
 869 ;;; Gopher selector retrieval
 870 ;;
 871
 872 (defun elpher-get-gopher-response (address renderer)
 873   "Get response string from gopher server at ADDRESS and render using RENDERER."
 874   (elpher-get-host-response address 70
 875                             (concat (elpher-gopher-address-selector address) "\r\n")
 876                             renderer
 877                             (or (string= (elpher-address-protocol address) "gophers")
 878                                 elpher-use-tls)))
 879
 880 (defun elpher-get-gopher-page (renderer)
 881   "Getter function for gopher pages.
 882 The RENDERER procedure is used to display the contents of the page
 883 once they are retrieved from the gopher server."
 884   (let* ((address (elpher-page-address elpher-current-page))
 885          (content (elpher-get-cached-content address)))
 886     (if (and content (funcall renderer nil))
 887         (elpher-with-clean-buffer
 888          (insert content)
 889          (elpher-restore-pos))
 890       (elpher-with-clean-buffer
 891        (insert "LOADING... (use 'u' to cancel)\n"))
 892       (condition-case the-error
 893           (elpher-get-gopher-response address renderer)
 894         (error
 895          (elpher-network-error address the-error))))))
 896
 897 ;; Index rendering
 898
 899 (defun elpher-insert-index (string)
 900   "Insert the index corresponding to STRING into the current buffer."
 901   ;; Should be able to split directly on CRLF, but some non-conformant
 902   ;; LF-only servers sadly exist, hence the following.
 903   (let ((str-processed (elpher-preprocess-text-response string)))
 904     (dolist (line (split-string str-processed "\n"))
 905       (ignore-errors
 906         (unless (= (length line) 0)
 907           (let* ((type (elt line 0))
 908                  (fields (split-string (substring line 1) "\t"))
 909                  (display-string (elt fields 0))
 910                  (selector (elt fields 1))
 911                  (host (elt fields 2))
 912                  (port (if (elt fields 3)
 913                            (string-to-number (elt fields 3))
 914                          nil))
 915                  (address (elpher-make-gopher-address type selector host port)))
 916             (elpher-insert-index-record display-string address)))))))
 917
 918 (defun elpher-insert-margin (&optional type-name)
 919   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 920   (if type-name
 921       (progn
 922         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 923                         (concat
 924                          (propertize "[" 'face 'elpher-margin-brackets)
 925                          (propertize type-name 'face 'elpher-margin-key)
 926                          (propertize "]" 'face 'elpher-margin-brackets))))
 927         (insert " "))
 928     (insert (make-string elpher-margin-width ?\s))))
 929
 930 (defun elpher--page-button-help (_window buffer pos)
 931   "Function called by Emacs to generate mouse-over text.
 932 The arguments specify the BUFFER and the POS within the buffer of the item
 933 for which help is required.  The function returns the help to be
 934 displayed.  The _WINDOW argument is currently unused."
 935   (with-current-buffer buffer
 936     (let ((button (button-at pos)))
 937       (when button
 938         (let* ((page (button-get button 'elpher-page))
 939                (address (elpher-page-address page)))
 940           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 941                                                 address
 942                                               (elpher-address-to-url address))))))))
 943
 944 (defun elpher-insert-index-record (display-string &optional address)
 945   "Function to insert an index record into the current buffer.
 946 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 947 If ADDRESS is not supplied or nil the record is rendered as an
 948 'information' line."
 949   (let* ((type (if address (elpher-address-type address) nil))
 950          (type-map-entry (cdr (assoc type elpher-type-map))))
 951     (if type-map-entry
 952         (let* ((margin-code (elt type-map-entry 2))
 953                (face (elt type-map-entry 3))
 954                (filtered-display-string (ansi-color-filter-apply display-string))
 955                (page (elpher-make-page filtered-display-string address)))
 956           (elpher-insert-margin margin-code)
 957           (insert-text-button filtered-display-string
 958                               'face face
 959                               'elpher-page page
 960                               'action #'elpher-click-link
 961                               'follow-link t
 962                               'help-echo #'elpher--page-button-help))
 963       (pcase type
 964         ('nil ;; Information
 965          (elpher-insert-margin)
 966          (let ((propertized-display-string
 967                 (propertize display-string 'face 'elpher-info)))
 968            (insert (elpher-process-text-for-display propertized-display-string))))
 969         (`(gopher ,selector-type) ;; Unknown
 970          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 971          (insert (propertize display-string
 972                              'face 'elpher-unknown)))))
 973     (insert "\n")))
 974
 975 (defun elpher-click-link (button)
 976   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 977   (let ((page (button-get button 'elpher-page)))
 978     (elpher-visit-page page)))
 979
 980 (defun elpher-render-index (data &optional _mime-type-string)
 981   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 982   (elpher-with-clean-buffer
 983    (if (not data)
 984        t
 985      (elpher-insert-index data)
 986      (elpher-cache-content (elpher-page-address elpher-current-page)
 987                            (buffer-string)))))
 988
 989 ;; Text rendering
 990
 991 (defconst elpher-url-regex
 992   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 993   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 994
 995 (defun elpher-buttonify-urls (string)
 996   "Turn substrings which look like urls in STRING into clickable buttons."
 997   (with-temp-buffer
 998     (insert string)
 999     (goto-char (point-min))
1000     (while (re-search-forward elpher-url-regex nil t)
1001       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
1002                                     (elpher-address-from-url (match-string 0)))))
1003           (make-text-button (match-beginning 0)
1004                             (match-end 0)
1005                             'elpher-page  page
1006                             'action #'elpher-click-link
1007                             'follow-link t
1008                             'help-echo #'elpher--page-button-help
1009                             'face 'button)))
1010     (buffer-string)))
1011
1012 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
1013   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
1014
1015 (defun elpher-process-text-for-display (string)
1016   "Perform any desired processing of STRING prior to display as text.
1017 Currently includes buttonifying URLs and processing ANSI escape codes."
1018   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1019                              (ansi-color-filter-apply string)
1020                            (ansi-color-apply string))))
1021
1022 (defun elpher-render-text (data &optional _mime-type-string)
1023   "Render DATA as text.  MIME-TYPE-STRING is unused."
1024   (elpher-with-clean-buffer
1025    (if (not data)
1026        t
1027      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1028      (elpher-cache-content
1029       (elpher-page-address elpher-current-page)
1030       (buffer-string)))))
1031
1032 ;; Image retrieval
1033
1034 (defun elpher-render-image (data &optional _mime-type-string)
1035   "Display DATA as image.  MIME-TYPE-STRING is unused."
1036   (if (not data)
1037       nil
1038     (if (display-images-p)
1039         (progn
1040           (let ((image (create-image
1041                         data
1042                         nil t)))
1043             (elpher-with-clean-buffer
1044              (insert-image image)
1045              (elpher-restore-pos))))
1046       (elpher-render-download data))))
1047
1048 ;; Search retrieval and rendering
1049
1050 (defun elpher-get-gopher-query-page (renderer)
1051   "Getter for gopher addresses requiring input.
1052 The response is rendered using the rendering function RENDERER."
1053    (let* ((address (elpher-page-address elpher-current-page))
1054           (content (elpher-get-cached-content address))
1055           (aborted t))
1056     (if (and content (funcall renderer nil))
1057         (elpher-with-clean-buffer
1058          (insert content)
1059          (elpher-restore-pos)
1060          (message "Displaying cached search results.  Reload to perform a new search."))
1061       (unwind-protect
1062           (let* ((query-string (read-string "Query: "))
1063                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1064                  (search-address (elpher-make-gopher-address ?1
1065                                                              query-selector
1066                                                              (elpher-address-host address)
1067                                                              (elpher-address-port address)
1068                                                              (equal (elpher-address-type address) "gophers"))))
1069             (setq aborted nil)
1070
1071             (elpher-with-clean-buffer
1072              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1073             (elpher-get-gopher-response search-address renderer))
1074         (if aborted
1075             (elpher-visit-previous-page))))))
1076
1077 ;; Raw server response rendering
1078
1079 (defun elpher-render-raw (data &optional mime-type-string)
1080   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1081   (if (not data)
1082       nil
1083     (elpher-with-clean-buffer
1084      (when mime-type-string
1085        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1086      (insert data)
1087      (goto-char (point-min)))
1088     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1089
1090 ;; File save "rendering"
1091
1092 (defun elpher-render-download (data &optional _mime-type-string)
1093   "Save DATA to file.  MIME-TYPE-STRING is unused."
1094   (if (not data)
1095       nil
1096     (let* ((address (elpher-page-address elpher-current-page))
1097            (selector (if (elpher-address-gopher-p address)
1098                          (elpher-gopher-address-selector address)
1099                        (elpher-address-filename address))))
1100       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1101       (let* ((filename-proposal (file-name-nondirectory selector))
1102              (filename (read-file-name "Download complete. Save file as: "
1103                                        nil nil nil
1104                                        (if (> (length filename-proposal) 0)
1105                                            filename-proposal
1106                                          "download.file"))))
1107         (let ((coding-system-for-write 'binary))
1108           (with-temp-file filename
1109             (insert data)))
1110         (message (format "Saved to file %s." filename))))))
1111
1112 ;; HTML rendering
1113
1114 (defun elpher-render-html (data &optional _mime-type-string)
1115   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1116   (elpher-with-clean-buffer
1117    (if (not data)
1118        t
1119      (let ((dom (with-temp-buffer
1120                   (insert data)
1121                   (libxml-parse-html-region (point-min) (point-max)))))
1122        (shr-insert-document dom)))))
1123
1124 ;; Gemini page retrieval
1125
1126 (defvar elpher-gemini-redirect-chain)
1127
1128 (defun elpher-get-gemini-response (address renderer)
1129   "Get response string from gemini server at ADDRESS and render using RENDERER."
1130   (elpher-get-host-response address 1965
1131                             (concat (elpher-address-to-url address) "\r\n")
1132                             (lambda (response-string)
1133                               (elpher-process-gemini-response response-string renderer))
1134                             'gemini))
1135
1136 (defun elpher-parse-gemini-response (response)
1137   "Parse the RESPONSE string and return a list of components.
1138 The list is of the form (code meta body).  A response of nil implies
1139 that the response was malformed."
1140   (let ((header-end-idx (string-match "\r\n" response)))
1141     (if header-end-idx
1142         (let ((header (string-trim (substring response 0 header-end-idx)))
1143               (body (substring response (+ header-end-idx 2))))
1144           (if (>= (length header) 2)
1145               (let ((code (substring header 0 2))
1146                     (meta (string-trim (substring header 2))))
1147                 (list code meta body))
1148             (error "Malformed response: No response status found in header %s" header)))
1149       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1150
1151 (defun elpher-process-gemini-response (response-string renderer)
1152   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1153   (let ((response-components (elpher-parse-gemini-response response-string)))
1154     (let ((response-code (elt response-components 0))
1155           (response-meta (elt response-components 1))
1156           (response-body (elt response-components 2)))
1157       (pcase (elt response-code 0)
1158         (?1 ; Input required
1159          (elpher-with-clean-buffer
1160           (insert "Gemini server is requesting input."))
1161          (let* ((query-string
1162                  (if (eq (elt response-code 1) ?1)
1163                      (read-passwd (concat response-meta ": "))
1164                    (read-string (concat response-meta ": "))))
1165                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1166                 (old-fname (url-filename query-address)))
1167            (setf (url-filename query-address)
1168                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1169            (elpher-get-gemini-response query-address renderer)))
1170         (?2 ; Normal response
1171          (funcall renderer response-body response-meta))
1172         (?3 ; Redirect
1173          (message "Following redirect to %s" response-meta)
1174          (if (>= (length elpher-gemini-redirect-chain) 5)
1175              (error "More than 5 consecutive redirects followed"))
1176          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1177            (if (member redirect-address elpher-gemini-redirect-chain)
1178                (error "Redirect loop detected"))
1179            (if (not (string= (elpher-address-protocol redirect-address)
1180                              "gemini"))
1181                (error "Server tried to automatically redirect to non-gemini URL: %s"
1182                       response-meta))
1183            (elpher-page-set-address elpher-current-page redirect-address)
1184            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1185            (elpher-get-gemini-response redirect-address renderer)))
1186         (?4 ; Temporary failure
1187          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1188                 response-code response-meta))
1189         (?5 ; Permanent failure
1190          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1191                 response-code response-meta))
1192         (?6 ; Client certificate required
1193          (elpher-with-clean-buffer
1194           (if elpher-client-certificate
1195               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1196             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1197           (auto-fill-mode 1)
1198           (elpher-gemini-insert-text response-meta))
1199          (let ((chosen-certificate (elpher-choose-client-certificate)))
1200            (unless chosen-certificate
1201              (error "Gemini server requires a client certificate and none was provided"))
1202            (setq elpher-client-certificate chosen-certificate))
1203          (elpher-with-clean-buffer)
1204          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1205         (_other
1206          (error "Gemini server response unknown: %s %s"
1207                 response-code response-meta))))))
1208
1209 (defun elpher-choose-client-certificate ()
1210   "Prompt for a client certificate to use to establish a TLS connection."
1211   (let* ((read-answer-short t))
1212     (pcase (read-answer "What do you want to do? "
1213                         '(("throwaway" ?t
1214                            "generate and use throw-away certificate")
1215                           ("persistent" ?p
1216                            "generate new or use existing persistent certificate")
1217                           ("abort" ?a
1218                            "stop immediately")))
1219       ("throwaway"
1220        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1221       ("persistent"
1222        (let* ((existing-certificates (elpher-list-existing-certificates))
1223               (file-base (completing-read
1224                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1225                           existing-certificates)))
1226          (if (string-empty-p (string-trim file-base))
1227              nil
1228            (if (member file-base existing-certificates)
1229                (setq elpher-client-certificate
1230                      (elpher-get-existing-certificate file-base))
1231              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1232                                  '(("new" ?n
1233                                     "generate new certificate")
1234                                    ("install" ?i
1235                                     "install existing certificate")
1236                                    ("abort" ?a
1237                                     "stop immediately")))
1238                ("new"
1239                 (let ((common-name (read-string "Common Name field for new certificate: "
1240                                                 file-base)))
1241                   (message "New key and self-signed certificate written to %s"
1242                            elpher-certificate-directory)
1243                   (elpher-generate-persistent-certificate file-base common-name)))
1244                ("install"
1245                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1246                        (key-file (read-file-name "Key file: " nil nil t)))
1247                   (message "Key and certificate installed in %s for future use"
1248                            elpher-certificate-directory)
1249                   (elpher-install-and-use-existing-certificate key-file
1250                                                                cert-file
1251                                                                file-base)))
1252                ("abort" nil))))))
1253       ("abort" nil))))
1254
1255 (defun elpher-get-gemini-page (renderer)
1256   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1257   (let* ((address (elpher-page-address elpher-current-page))
1258          (content (elpher-get-cached-content address)))
1259     (condition-case the-error
1260         (if (and content (funcall renderer nil))
1261             (elpher-with-clean-buffer
1262               (insert content)
1263               (elpher-restore-pos))
1264           (elpher-with-clean-buffer
1265            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1266           (setq elpher-gemini-redirect-chain nil)
1267           (elpher-get-gemini-response address renderer))
1268       (error
1269        (elpher-network-error address the-error)))))
1270
1271 (defun elpher-render-gemini (body &optional mime-type-string)
1272   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1273   (if (not body)
1274       t
1275     (let* ((mime-type-string* (if (or (not mime-type-string)
1276                                       (string-empty-p mime-type-string))
1277                                   "text/gemini; charset=utf-8"
1278                                 mime-type-string))
1279            (mime-type-split (split-string mime-type-string* ";" t))
1280            (mime-type (string-trim (car mime-type-split)))
1281            (parameters (mapcar (lambda (s)
1282                                  (let ((key-val (split-string s "=")))
1283                                    (list (downcase (string-trim (car key-val)))
1284                                          (downcase (string-trim (cadr key-val))))))
1285                                (cdr mime-type-split))))
1286       (when (string-prefix-p "text/" mime-type)
1287         (setq body (decode-coding-string
1288                     body
1289                     (if (assoc "charset" parameters)
1290                         (intern (cadr (assoc "charset" parameters)))
1291                       'utf-8)))
1292         (setq body (replace-regexp-in-string "\r" "" body)))
1293       (pcase mime-type
1294         ((or "text/gemini" "")
1295          (elpher-render-gemini-map body parameters))
1296         ("text/html"
1297          (elpher-render-html body))
1298         ((pred (string-prefix-p "text/"))
1299          (elpher-render-gemini-plain-text body parameters))
1300         ((pred (string-prefix-p "image/"))
1301          (elpher-render-image body))
1302         (_other
1303          (elpher-render-download body))))))
1304
1305 (defun elpher-gemini-get-link-url (link-line)
1306   "Extract the url portion of LINK-LINE, a gemini map file link line.
1307 Returns nil in the event that the contents of the line following the
1308 => prefix are empty."
1309   (let ((l (split-string (substring link-line 2))))
1310     (if l
1311         (string-trim (elt l 0))
1312       nil)))
1313
1314 (defun elpher-gemini-get-link-display-string (link-line)
1315   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1316 Returns the url portion in the event that the display-string portion is empty."
1317   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1318          (idx (string-match "[ \t]" rest)))
1319     (string-trim (if idx
1320                      (substring rest (+ idx 1))
1321                    rest))))
1322
1323 (defun elpher-collapse-dot-sequences (filename)
1324   "Collapse dot sequences in FILENAME.
1325 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1326   (let* ((path (split-string filename "/"))
1327          (path-reversed-normalized
1328           (seq-reduce (lambda (a b)
1329                         (cond ((and a (equal b "..") (cdr a)))
1330                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1331                               ((equal b ".") a)
1332                               (t (cons b a))))
1333                       path nil)))
1334     (string-join (reverse path-reversed-normalized) "/")))
1335
1336 (defun elpher-address-from-gemini-url (url)
1337   "Extract address from URL with defaults as per gemini map files.
1338 While there's obviously some redundancy here between this function and
1339 `elpher-address-from-url', gemini map file URLs require enough special
1340 treatment that a separate function is warranted."
1341   (let ((address (url-generic-parse-url url))
1342         (current-address (elpher-page-address elpher-current-page)))
1343     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1344       (setf (url-fullness address) t)
1345       (if (url-host address) ;if there is an explicit host, filenames are absolute
1346           (if (string-empty-p (url-filename address))
1347               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1348         (setf (url-host address) (url-host current-address))
1349         (setf (url-port address) (url-port current-address))
1350         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1351           (setf (url-filename address)
1352                 (concat (file-name-directory (url-filename current-address))
1353                         (url-filename address)))))
1354       (unless (url-type address)
1355         (setf (url-type address) "gemini"))
1356       (when (equal (url-type address) "gemini")
1357         (setf (url-filename address)
1358               (elpher-collapse-dot-sequences (url-filename address)))))
1359     (elpher-remove-redundant-ports address)))
1360
1361 (defun elpher-gemini-insert-link (link-line)
1362   "Insert link described by LINK-LINE into a text/gemini document."
1363   (let* ((url (elpher-gemini-get-link-url link-line))
1364          (display-string (elpher-gemini-get-link-display-string link-line))
1365          (address (elpher-address-from-gemini-url url))
1366          (type (if address (elpher-address-type address) nil))
1367          (type-map-entry (cdr (assoc type elpher-type-map))))
1368     (when display-string
1369       (insert elpher-gemini-link-string)
1370       (if type-map-entry
1371           (let* ((face (elt type-map-entry 3))
1372                  (filtered-display-string (ansi-color-filter-apply display-string))
1373                  (page (elpher-make-page filtered-display-string address)))
1374             (insert-text-button filtered-display-string
1375                                 'face face
1376                                 'elpher-page page
1377                                 'action #'elpher-click-link
1378                                 'follow-link t
1379                                 'help-echo #'elpher--page-button-help))
1380         (insert (propertize display-string 'face 'elpher-unknown)))
1381       (insert "\n"))))
1382
1383 (defun elpher-gemini-insert-header (header-line)
1384   "Insert header described by HEADER-LINE into a text/gemini document.
1385 The gemini map file line describing the header is given
1386 by HEADER-LINE."
1387   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1388     (let* ((level (length (match-string 1 header-line)))
1389            (header (substring header-line (match-end 0)))
1390            (face (pcase level
1391                    (1 'elpher-gemini-heading1)
1392                    (2 'elpher-gemini-heading2)
1393                    (3 'elpher-gemini-heading3)
1394                    (_ 'default))))
1395       (unless (display-graphic-p)
1396         (insert (make-string level ?#) " "))
1397       (insert (propertize header 'face face))
1398       (newline))))
1399
1400 (defun elpher-gemini-insert-text (text-line)
1401   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1402 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1403 width defined by elpher-gemini-max-fill-width."
1404   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1405   (let* ((line-prefix (match-string 2 text-line))
1406          (processed-text-line
1407           (if line-prefix
1408               (cond ((string-prefix-p "*" line-prefix)
1409                      (concat
1410                       (replace-regexp-in-string "\*"
1411                                                 elpher-gemini-bullet-string
1412                                                 (match-string 0 text-line))
1413                       (substring text-line (match-end 0))))
1414                     ((string-prefix-p ">" line-prefix)
1415                      (propertize text-line 'face 'elpher-gemini-quoted))
1416                     (t text-line))
1417             text-line))
1418          (adaptive-fill-mode nil))
1419     (insert (elpher-process-text-for-display processed-text-line))
1420     (newline)))
1421
1422 (defun elpher-render-gemini-map (data _parameters)
1423   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1424   (elpher-with-clean-buffer
1425    (let ((preformatted nil))
1426      (auto-fill-mode 1)
1427      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1428      (dolist (line (split-string data "\n"))
1429        (cond
1430         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1431         (preformatted (insert (elpher-process-text-for-display
1432                                (propertize line 'face 'elpher-gemini-preformatted))
1433                               "\n"))
1434         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1435         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1436         (t (elpher-gemini-insert-text line)))))
1437    (elpher-cache-content
1438     (elpher-page-address elpher-current-page)
1439     (buffer-string))))
1440
1441 (defun elpher-render-gemini-plain-text (data _parameters)
1442   "Render DATA as plain text file.  PARAMETERS is currently unused."
1443   (elpher-with-clean-buffer
1444    (insert (elpher-process-text-for-display data))
1445    (elpher-cache-content
1446     (elpher-page-address elpher-current-page)
1447     (buffer-string))))
1448
1449
1450 ;; Finger page connection
1451
1452 (defun elpher-get-finger-page (renderer)
1453   "Opens a finger connection to the current page address.
1454 The result is rendered using RENDERER."
1455   (let* ((address (elpher-page-address elpher-current-page))
1456          (content (elpher-get-cached-content address)))
1457     (if (and content (funcall renderer nil))
1458         (elpher-with-clean-buffer
1459          (insert content)
1460          (elpher-restore-pos))
1461       (elpher-with-clean-buffer
1462        (insert "LOADING... (use 'u' to cancel)\n"))
1463       (condition-case the-error
1464           (let* ((kill-buffer-query-functions nil)
1465                  (user (let ((filename (elpher-address-filename address)))
1466                          (if (> (length filename) 1)
1467                              (substring filename 1)
1468                            (elpher-address-user address)))))
1469             (elpher-get-host-response address 79
1470                                       (concat user "\r\n")
1471                                       renderer))
1472         (error
1473          (elpher-network-error address the-error))))))
1474
1475
1476 ;; Telnet page connection
1477
1478 (defun elpher-get-telnet-page (renderer)
1479   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1480   (when renderer
1481     (elpher-visit-previous-page)
1482     (error "Command not supported for telnet URLs"))
1483   (let* ((address (elpher-page-address elpher-current-page))
1484          (host (elpher-address-host address))
1485          (port (elpher-address-port address)))
1486     (elpher-visit-previous-page)
1487     (if (> port 0)
1488         (telnet host port)
1489       (telnet host))))
1490
1491
1492 ;; Other URL page opening
1493
1494 (defun elpher-get-other-url-page (renderer)
1495   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1496   (when renderer
1497     (elpher-visit-previous-page)
1498     (error "Command not supported for general URLs"))
1499   (let* ((address (elpher-page-address elpher-current-page))
1500          (url (elpher-address-to-url address)))
1501     (progn
1502       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1503       (message "Opening URL...")
1504       (if elpher-open-urls-with-eww
1505           (browse-web url)
1506         (browse-url url)))))
1507
1508
1509 ;; Start page page retrieval
1510
1511 (defun elpher-get-start-page (renderer)
1512   "Getter which displays the start page (RENDERER must be nil)."
1513   (when renderer
1514     (elpher-visit-previous-page)
1515     (error "Command not supported for start page"))
1516   (elpher-with-clean-buffer
1517    (insert "     --------------------------------------------\n"
1518            "           Elpher Gopher and Gemini Client       \n"
1519            "                   version " elpher-version "\n"
1520            "     --------------------------------------------\n"
1521            "\n"
1522            "Default bindings:\n"
1523            "\n"
1524            " - TAB/Shift-TAB: next/prev item on current page\n"
1525            " - RET/mouse-1: open item under cursor\n"
1526            " - m: select an item on current page by name (autocompletes)\n"
1527            " - u/mouse-3/U: return to previous page or to the start page\n"
1528            " - o/O: visit different selector or the root menu of the current server\n"
1529            " - g: go to a particular address (gopher, gemini, finger)\n"
1530            " - d/D: download item under cursor or current page\n"
1531            " - i/I: info on item under cursor or current page\n"
1532            " - c/C: copy URL representation of item under cursor or current page\n"
1533            " - a/A: bookmark the item under cursor or current page\n"
1534            " - x/X: remove bookmark for item under cursor or current page\n"
1535            " - B: visit the bookmarks page\n"
1536            " - r: redraw current page (using cached contents if available)\n"
1537            " - R: reload current page (regenerates cache)\n"
1538            " - S: set character coding system for gopher (default is to autodetect)\n"
1539            " - T: toggle TLS gopher mode\n"
1540            " - F: forget/discard current TLS client certificate\n"
1541            " - .: display the raw server response for the current page\n"
1542            "\n"
1543            "Start your exploration of gopher space and gemini:\n")
1544    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1545                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1546    (elpher-insert-index-record "Project Gemini home page"
1547                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1548    (insert "\n"
1549            "Alternatively, select a search engine and enter some search terms:\n")
1550    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1551                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1552    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1553                                (elpher-address-from-url "gemini://gus.guru/search"))
1554    (insert "\n"
1555            "This page contains your bookmarked sites (also visit with B):\n")
1556    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1557    (insert "\n"
1558            "For Elpher release news or to leave feedback, visit:\n")
1559    (elpher-insert-index-record "The Elpher Project Page"
1560                                (elpher-make-gopher-address ?1
1561                                                            "/projects/elpher/"
1562                                                            "thelambdalab.xyz"
1563                                                            70))
1564    (insert "\n"
1565            "** Refer to the ")
1566    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1567      (insert-text-button "Elpher info manual"
1568                          'face 'link
1569                          'action (lambda (_)
1570                                    (interactive)
1571                                    (info "(elpher)"))
1572                          'follow-link t
1573                          'help-echo help-string))
1574    (insert " for the full documentation. **\n")
1575    (insert (propertize
1576             (concat "  (This should be available if you have installed Elpher using\n"
1577                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1578             'face 'shadow))
1579    (elpher-restore-pos)))
1580
1581 ;; Bookmarks page page retrieval
1582
1583 (defun elpher-get-bookmarks-page (renderer)
1584   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1585   (when renderer
1586     (elpher-visit-previous-page)
1587     (error "Command not supported for bookmarks page"))
1588   (elpher-with-clean-buffer
1589    (insert "---- Bookmark list ----\n\n")
1590    (let ((bookmarks (elpher-load-bookmarks)))
1591      (if bookmarks
1592          (dolist (bookmark bookmarks)
1593            (let ((display-string (elpher-bookmark-display-string bookmark))
1594                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1595              (elpher-insert-index-record display-string address)))
1596        (insert "No bookmarks found.\n")))
1597    (insert "\n-----------------------\n"
1598            "\n"
1599            "- u: return to previous page\n"
1600            "- x: delete selected bookmark\n"
1601            "- a: rename selected bookmark\n"
1602            "\n"
1603            "Bookmarks are stored in the file ")
1604    (let ((filename elpher-bookmarks-file)
1605          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1606      (insert-text-button filename
1607                          'face 'link
1608                          'action (lambda (_)
1609                                    (interactive)
1610                                    (find-file filename))
1611                          'follow-link t
1612                          'help-echo help-string))
1613    (insert "\n")
1614    (elpher-restore-pos)))
1615
1616
1617 ;;; Bookmarks
1618 ;;
1619
1620 (defun elpher-make-bookmark (display-string url)
1621   "Make an elpher bookmark.
1622 DISPLAY-STRING determines how the bookmark will appear in the
1623 bookmark list, while URL is the url of the entry."
1624   (list display-string url))
1625
1626 (defun elpher-bookmark-display-string (bookmark)
1627   "Get the display string of BOOKMARK."
1628   (elt bookmark 0))
1629
1630 (defun elpher-set-bookmark-display-string (bookmark display-string)
1631   "Set the display string of BOOKMARK to DISPLAY-STRING."
1632   (setcar bookmark display-string))
1633
1634 (defun elpher-bookmark-url (bookmark)
1635   "Get the address for BOOKMARK."
1636   (elt bookmark 1))
1637
1638 (defun elpher-save-bookmarks (bookmarks)
1639   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1640 Beware that this completely replaces the existing contents of the file."
1641   (with-temp-file elpher-bookmarks-file
1642     (erase-buffer)
1643     (insert "; Elpher bookmarks file\n\n"
1644             "; Bookmarks are stored as a list of (label URL) items.\n"
1645             "; Feel free to edit by hand, but take care to ensure\n"
1646             "; the list structure remains intact.\n\n")
1647     (pp bookmarks (current-buffer))))
1648
1649 (defun elpher-load-bookmarks ()
1650   "Get the list of bookmarks from the users's bookmark file."
1651   (let ((bookmarks
1652          (with-temp-buffer
1653            (ignore-errors
1654              (insert-file-contents elpher-bookmarks-file)
1655              (goto-char (point-min))
1656              (read (current-buffer))))))
1657     (if (and bookmarks (listp (cadar bookmarks)))
1658         (progn
1659           (message "Reading old bookmark file. (Will be updated on write.)")
1660           (mapcar (lambda (old-bm)
1661                     (list (car old-bm)
1662                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1663                                                         (cadr old-bm)))))
1664                   bookmarks))
1665       bookmarks)))
1666
1667 (defun elpher-add-address-bookmark (address display-string)
1668   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1669 If ADDRESS is already bookmarked, update the label only."
1670   (let ((bookmarks (elpher-load-bookmarks))
1671         (url (elpher-address-to-url address)))
1672     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1673       (if existing-bookmark
1674           (elpher-set-bookmark-display-string existing-bookmark display-string)
1675         (push (elpher-make-bookmark display-string url) bookmarks)))
1676     (elpher-save-bookmarks bookmarks)))
1677
1678 (defun elpher-remove-address-bookmark (address)
1679   "Remove any bookmark to ADDRESS."
1680   (let ((url (elpher-address-to-url address)))
1681     (elpher-save-bookmarks
1682      (seq-filter (lambda (bookmark)
1683                    (not (equal (elpher-bookmark-url bookmark) url)))
1684                  (elpher-load-bookmarks)))))
1685
1686 ;;; Interactive procedures
1687 ;;
1688
1689 (defun elpher-next-link ()
1690   "Move point to the next link on the current page."
1691   (interactive)
1692   (forward-button 1))
1693
1694 (defun elpher-prev-link ()
1695   "Move point to the previous link on the current page."
1696   (interactive)
1697   (backward-button 1))
1698
1699 (defun elpher-follow-current-link ()
1700   "Open the link or url at point."
1701   (interactive)
1702   (push-button))
1703
1704 (defun elpher-go (host-or-url)
1705   "Go to a particular gopher site HOST-OR-URL.
1706 When run interactively HOST-OR-URL is read from the minibuffer."
1707   (interactive "sGopher or Gemini URL: ")
1708   (let* ((cleaned-host-or-url (string-trim host-or-url))
1709          (address (elpher-address-from-url cleaned-host-or-url))
1710          (page (elpher-make-page cleaned-host-or-url address)))
1711     (switch-to-buffer elpher-buffer-name)
1712     (elpher-visit-page page)
1713     nil))
1714
1715 (defun elpher-go-current ()
1716   "Go to a particular site read from the minibuffer, initialized with the current URL."
1717   (interactive)
1718   (let ((address (elpher-page-address elpher-current-page)))
1719     (if (elpher-address-special-p address)
1720         (error "Command invalid for this page")
1721       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1722         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1723
1724 (defun elpher-redraw ()
1725   "Redraw current page."
1726   (interactive)
1727   (elpher-visit-page elpher-current-page))
1728
1729 (defun elpher-reload ()
1730   "Reload current page."
1731   (interactive)
1732   (elpher-reload-current-page))
1733
1734 (defun elpher-toggle-tls ()
1735   "Toggle TLS encryption mode for gopher."
1736   (interactive)
1737   (setq elpher-use-tls (not elpher-use-tls))
1738   (if elpher-use-tls
1739       (if (gnutls-available-p)
1740           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1741         (setq elpher-use-tls nil)
1742         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1743     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1744
1745 (defun elpher-view-raw ()
1746   "View raw server response for current page."
1747   (interactive)
1748   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1749       (error "This page was not generated by a server")
1750     (elpher-visit-page elpher-current-page
1751                        #'elpher-render-raw)))
1752
1753 (defun elpher-back ()
1754   "Go to previous site."
1755   (interactive)
1756   (elpher-visit-previous-page))
1757
1758 (defun elpher-back-to-start ()
1759   "Go all the way back to the start page."
1760   (interactive)
1761   (setq-local elpher-current-page nil)
1762   (setq-local elpher-history nil)
1763   (let ((start-page (elpher-make-page "Elpher Start Page"
1764                                       (elpher-make-special-address 'start))))
1765     (elpher-visit-page start-page)))
1766
1767 (defun elpher-download ()
1768   "Download the link at point."
1769   (interactive)
1770   (let ((button (button-at (point))))
1771     (if button
1772         (let ((page (button-get button 'elpher-page)))
1773           (if (elpher-address-special-p (elpher-page-address page))
1774               (error "Cannot download %s"
1775                      (elpher-page-display-string page))
1776             (elpher-visit-page (button-get button 'elpher-page)
1777                                #'elpher-render-download)))
1778       (error "No link selected"))))
1779
1780 (defun elpher-download-current ()
1781   "Download the current page."
1782   (interactive)
1783   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1784       (error "Cannot download %s"
1785              (elpher-page-display-string elpher-current-page))
1786     (elpher-visit-page (elpher-make-page
1787                         (elpher-page-display-string elpher-current-page)
1788                         (elpher-page-address elpher-current-page))
1789                        #'elpher-render-download
1790                        t)))
1791
1792 (defun elpher-build-link-map ()
1793   "Build alist mapping link names to destination pages in current buffer."
1794   (let ((link-map nil)
1795         (b (next-button (point-min) t)))
1796     (while b
1797       (push (cons (button-label b) b) link-map)
1798       (setq b (next-button (button-start b))))
1799     link-map))
1800
1801 (defun elpher-jump ()
1802   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1803   (interactive)
1804   (let* ((link-map (elpher-build-link-map)))
1805     (if link-map
1806         (let ((key (let ((completion-ignore-case t))
1807                      (completing-read "Directory item/link: "
1808                                       link-map nil t))))
1809           (if (and key (> (length key) 0))
1810               (let ((b (cdr (assoc key link-map))))
1811                 (goto-char (button-start b))
1812                 (button-activate b)))))))
1813
1814 (defun elpher-root-dir ()
1815   "Visit root of current server."
1816   (interactive)
1817   (let ((address (elpher-page-address elpher-current-page)))
1818     (if (not (elpher-address-special-p address))
1819         (if (or (member (url-filename address) '("/" ""))
1820                 (and (elpher-address-gopher-p address)
1821                      (= (length (elpher-gopher-address-selector address)) 0)))
1822             (error "Already at root directory of current server")
1823           (let ((address-copy (elpher-address-from-url
1824                                (elpher-address-to-url address))))
1825             (setf (url-filename address-copy) "")
1826             (elpher-go (elpher-address-to-url address-copy))))
1827       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1828
1829 (defun elpher-bookmarks-current-p ()
1830   "Return non-nil if current page is a bookmarks page."
1831   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1832          '(special bookmarks)))
1833
1834 (defun elpher-reload-bookmarks ()
1835   "Reload bookmarks if current page is a bookmarks page."
1836   (if (elpher-bookmarks-current-p)
1837       (elpher-reload-current-page)))
1838
1839 (defun elpher-bookmark-current ()
1840   "Bookmark the current page."
1841   (interactive)
1842   (let ((address (elpher-page-address elpher-current-page))
1843         (display-string (elpher-page-display-string elpher-current-page)))
1844     (if (not (elpher-address-special-p address))
1845         (let ((bookmark-display-string (read-string "Bookmark display string: "
1846                                                     display-string)))
1847           (elpher-add-address-bookmark address bookmark-display-string)
1848           (message "Bookmark added."))
1849       (error "Cannot bookmark %s" display-string))))
1850
1851 (defun elpher-bookmark-link ()
1852   "Bookmark the link at point."
1853   (interactive)
1854   (let ((button (button-at (point))))
1855     (if button
1856         (let* ((page (button-get button 'elpher-page))
1857                (address (elpher-page-address page))
1858                (display-string (elpher-page-display-string page)))
1859           (if (not (elpher-address-special-p address))
1860               (let ((bookmark-display-string (read-string "Bookmark display string: "
1861                                                           display-string)))
1862                 (elpher-add-address-bookmark address bookmark-display-string)
1863                 (elpher-reload-bookmarks)
1864                 (message "Bookmark added."))
1865             (error "Cannot bookmark %s" display-string)))
1866       (error "No link selected"))))
1867
1868 (defun elpher-unbookmark-current ()
1869   "Remove bookmark for the current page."
1870   (interactive)
1871   (let ((address (elpher-page-address elpher-current-page)))
1872     (when (and (not (elpher-address-special-p address))
1873                (y-or-n-p "Really remove bookmark for the current page? "))
1874       (elpher-remove-address-bookmark address)
1875       (message "Bookmark removed."))))
1876
1877 (defun elpher-unbookmark-link ()
1878   "Remove bookmark for the link at point."
1879   (interactive)
1880   (let ((button (button-at (point))))
1881     (if button
1882         (when (y-or-n-p "Really remove bookmark for this link? ")
1883           (let ((page (button-get button 'elpher-page)))
1884             (elpher-remove-address-bookmark (elpher-page-address page))
1885             (elpher-reload-bookmarks)
1886             (message "Bookmark removed.")))
1887       (error "No link selected"))))
1888
1889 (defun elpher-bookmarks ()
1890   "Visit bookmarks page."
1891   (interactive)
1892   (switch-to-buffer elpher-buffer-name)
1893   (elpher-visit-page
1894    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1895
1896 (defun elpher-info-page (page)
1897   "Display information on PAGE."
1898   (let ((display-string (elpher-page-display-string page))
1899         (address (elpher-page-address page)))
1900     (if (elpher-address-special-p address)
1901         (message "Special page: %s" display-string)
1902       (message "%s" (elpher-address-to-url address)))))
1903
1904 (defun elpher-info-link ()
1905   "Display information on page corresponding to link at point."
1906   (interactive)
1907   (let ((button (button-at (point))))
1908     (if button
1909         (elpher-info-page (button-get button 'elpher-page))
1910       (error "No item selected"))))
1911
1912 (defun elpher-info-current ()
1913   "Display information on current page."
1914   (interactive)
1915   (elpher-info-page elpher-current-page))
1916
1917 (defun elpher-copy-page-url (page)
1918   "Copy URL representation of address of PAGE to `kill-ring'."
1919   (let ((address (elpher-page-address page)))
1920     (if (elpher-address-special-p address)
1921         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1922       (let ((url (elpher-address-to-url address)))
1923         (message "Copied \"%s\" to kill-ring/clipboard." url)
1924         (kill-new url)))))
1925
1926 (defun elpher-copy-link-url ()
1927   "Copy URL of item at point to `kill-ring'."
1928   (interactive)
1929   (let ((button (button-at (point))))
1930     (if button
1931         (elpher-copy-page-url (button-get button 'elpher-page))
1932       (error "No item selected"))))
1933
1934 (defun elpher-copy-current-url ()
1935   "Copy URL of current page to `kill-ring'."
1936   (interactive)
1937   (elpher-copy-page-url elpher-current-page))
1938
1939 (defun elpher-set-gopher-coding-system ()
1940   "Specify an explicit character coding system for gopher selectors."
1941   (interactive)
1942   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1943     (setq elpher-user-coding-system system)
1944     (if system
1945         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1946       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1947
1948
1949 ;;; Mode and keymap
1950 ;;
1951
1952 (defvar elpher-mode-map
1953   (let ((map (make-sparse-keymap)))
1954     (define-key map (kbd "TAB") 'elpher-next-link)
1955     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1956     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1957     (define-key map (kbd "u") 'elpher-back)
1958     (define-key map (kbd "U") 'elpher-back-to-start)
1959     (define-key map [mouse-3] 'elpher-back)
1960     (define-key map (kbd "O") 'elpher-root-dir)
1961     (define-key map (kbd "g") 'elpher-go)
1962     (define-key map (kbd "o") 'elpher-go-current)
1963     (define-key map (kbd "r") 'elpher-redraw)
1964     (define-key map (kbd "R") 'elpher-reload)
1965     (define-key map (kbd "T") 'elpher-toggle-tls)
1966     (define-key map (kbd ".") 'elpher-view-raw)
1967     (define-key map (kbd "d") 'elpher-download)
1968     (define-key map (kbd "D") 'elpher-download-current)
1969     (define-key map (kbd "m") 'elpher-jump)
1970     (define-key map (kbd "i") 'elpher-info-link)
1971     (define-key map (kbd "I") 'elpher-info-current)
1972     (define-key map (kbd "c") 'elpher-copy-link-url)
1973     (define-key map (kbd "C") 'elpher-copy-current-url)
1974     (define-key map (kbd "a") 'elpher-bookmark-link)
1975     (define-key map (kbd "A") 'elpher-bookmark-current)
1976     (define-key map (kbd "x") 'elpher-unbookmark-link)
1977     (define-key map (kbd "X") 'elpher-unbookmark-current)
1978     (define-key map (kbd "B") 'elpher-bookmarks)
1979     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1980     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1981     (when (fboundp 'evil-define-key*)
1982       (evil-define-key* 'motion map
1983         (kbd "TAB") 'elpher-next-link
1984         (kbd "C-") 'elpher-follow-current-link
1985         (kbd "C-t") 'elpher-back
1986         (kbd "u") 'elpher-back
1987         (kbd "U") 'elpher-back-to-start
1988         [mouse-3] 'elpher-back
1989         (kbd "g") 'elpher-go
1990         (kbd "o") 'elpher-go-current
1991         (kbd "r") 'elpher-redraw
1992         (kbd "R") 'elpher-reload
1993         (kbd "T") 'elpher-toggle-tls
1994         (kbd ".") 'elpher-view-raw
1995         (kbd "d") 'elpher-download
1996         (kbd "D") 'elpher-download-current
1997         (kbd "m") 'elpher-jump
1998         (kbd "i") 'elpher-info-link
1999         (kbd "I") 'elpher-info-current
2000         (kbd "c") 'elpher-copy-link-url
2001         (kbd "C") 'elpher-copy-current-url
2002         (kbd "a") 'elpher-bookmark-link
2003         (kbd "A") 'elpher-bookmark-current
2004         (kbd "x") 'elpher-unbookmark-link
2005         (kbd "X") 'elpher-unbookmark-current
2006         (kbd "B") 'elpher-bookmarks
2007         (kbd "S") 'elpher-set-gopher-coding-system
2008         (kbd "F") 'elpher-forget-current-certificate))
2009     map)
2010   "Keymap for gopher client.")
2011
2012 (define-derived-mode elpher-mode special-mode "elpher"
2013   "Major mode for elpher, an elisp gopher client.
2014
2015 This mode is automatically enabled by the interactive
2016 functions which initialize the gopher client, namely
2017 `elpher', `elpher-go' and `elpher-bookmarks'."
2018   (setq-local elpher-current-page nil)
2019   (setq-local elpher-history nil)
2020   (setq-local elpher-buffer-name (buffer-name)))
2021
2022 (when (fboundp 'evil-set-initial-state)
2023   (evil-set-initial-state 'elpher-mode 'motion))
2024
2025
2026 ;;; Main start procedure
2027 ;;
2028
2029 ;;;###autoload
2030 (defun elpher (&optional arg)
2031   "Start elpher with default landing page.
2032 The buffer used for Elpher sessions is determined by the value of
2033 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2034 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2035 will begin.  A numeric prefix arg (as in ‘C-u 42 M-x elpher RET’)
2036 switches to the session with that number, creating it if necessary.  A
2037 nonnumeric prefix arg means to create a new session.  Returns the
2038 buffer selected (or created)."
2039   (interactive "P")
2040   (let* ((name (default-value 'elpher-buffer-name))
2041          (buf (cond ((numberp arg)
2042                      (get-buffer-create (format "%s<%d>" name arg)))
2043                     (arg
2044                      (generate-new-buffer name))
2045                     (t
2046                      (get-buffer-create name)))))
2047     (pop-to-buffer-same-window buf)
2048     (unless (buffer-modified-p)
2049       (elpher-mode)
2050       (let ((start-page (elpher-make-page "Elpher Start Page"
2051                                           (elpher-make-special-address 'start))))
2052         (elpher-visit-page start-page))
2053       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2054
2055 ;;; elpher.el ends here