URLs now unhexed and decoded prior to use as display strings.
[elpher.git] / elpher.el
1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
2
3 ;; Copyright (C) 2021 Jens Östlund <jostlund@gmail.com>
4 ;; Copyright (C) 2021 F. Jason Park <jp@neverwas.me>
5 ;; Copyright (C) 2021 Christopher Brannon <chris@the-brannons.com>
6 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
7 ;; Copyright (C) 2021 Noodles! <nnoodle@chiru.no>
8 ;; Copyright (C) 2021 Abhiseck Paira <abhiseckpaira@disroot.org>
9 ;; Copyright (C) 2020-2021 Alex Schroeder <alex@gnu.org>
10 ;; Copyright (C) 2020 Zhiwei Chen <chenzhiwei03@kuaishou.com>
11 ;; Copyright (C) 2020 condy0919 <condy0919@gmail.com>
12 ;; Copyright (C) 2020 Alexis <flexibeast@gmail.com>
13 ;; Copyright (C) 2020 Étienne Deparis <etienne@depar.is>
14 ;; Copyright (C) 2020 Simon Nicolussi <sinic@sinic.name>
15 ;; Copyright (C) 2020 Michel Alexandre Salim <michel@michel-slm.name>
16 ;; Copyright (C) 2020 Koushk Roy <kroy@twilio.com>
17 ;; Copyright (C) 2020 Vee <vee@vnsf.xyz>
18 ;; Copyright (C) 2020 Simon South <simon@simonsouth.net>
19 ;; Copyright (C) 2019-2021 Tim Vaughan <plugd@thelambdalab.xyz>
20
21 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
22 ;; Created: 11 April 2019
23 ;; Version: 3.2.1
24 ;; Keywords: comm gopher
25 ;; Homepage: https://thelambdalab.xyz/elpher
26 ;; Package-Requires: ((emacs "27.1"))
27
28 ;; This file is not part of GNU Emacs.
29
30 ;; This program is free software: you can redistribute it and/or modify
31 ;; it under the terms of the GNU General Public License as published by
32 ;; the Free Software Foundation, either version 3 of the License, or
33 ;; (at your option) any later version.
34
35 ;; This program is distributed in the hope that it will be useful,
36 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
37 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
38 ;; GNU General Public License for more details.
39
40 ;; You should have received a copy of the GNU General Public License
41 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
42
43 ;;; Commentary:
44
45 ;; Elpher aims to provide a practical and friendly gopher and gemini
46 ;; client for GNU Emacs.  It supports:
47
48 ;; - intuitive keyboard and mouse-driven browsing,
49 ;; - out-of-the-box compatibility with evil-mode,
50 ;; - clickable web and gopher links *in plain text*,
51 ;; - caching of visited sites,
52 ;; - pleasant and configurable colouring of Gopher directories,
53 ;; - direct visualisation of image files,
54 ;; - gopher connections using TLS encryption,
55 ;; - the fledgling Gemini protocol,
56 ;; - the greybeard Finger protocol.
57
58 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
59 ;; page containing information on key bindings and suggested starting
60 ;; points for your gopher exploration.
61
62 ;; Full instructions can be found in the Elpher info manual.
63
64 ;; Elpher is under active development.  Any suggestions for
65 ;; improvements are welcome, and can be made on the official project
66 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
67 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
68
69 ;;; Code:
70
71 (provide 'elpher)
72
73 ;;; Dependencies
74 ;;
75
76 (require 'seq)
77 (require 'shr)
78 (require 'url-util)
79 (require 'subr-x)
80 (require 'nsm)
81 (require 'gnutls)
82 (require 'socks)
83 (require 'bookmark)
84
85 ;;; Global constants
86 ;;
87
88 (defconst elpher-version "3.2.1"
89   "Current version of elpher.")
90
91 (defconst elpher-margin-width 6
92   "Width of left-hand margin used when rendering indicies.")
93
94 (defconst elpher-type-map
95   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
96     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
97     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
98     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
99     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
100     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
101     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
102     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
103     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
104     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
105     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
106     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
107     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
108     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
109     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
110     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
111     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
112     (file elpher-get-file-page nil "~" elpher-gemini)
113     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
114     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
115     ((about history) elpher-get-history-page nil "E" elpher-index)
116     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
117   "Association list from types to getters, renderers, margin codes and index faces.")
118
119
120 ;;; Declarations to avoid compiler warnings.
121 ;;
122
123 (eval-when-compile
124   (declare-function ansi-color-filter-apply "ansi-color")
125   (declare-function ansi-color-apply "ansi-color")
126   (declare-function bookmark-store "bookmark")
127   (declare-function org-link-store-props "ol")
128   (declare-function org-link-set-parameters "ol")
129   (defvar ansi-color-context)
130   (defvar bookmark-make-record-function)
131   (defvar mu4e~view-beginning-of-url-regexp)
132   (defvar eww-use-browse-url)
133   (defvar thing-at-point-uri-schemes)
134   (defvar xterm-color-preserve-properties))
135
136
137 ;;; Customization group
138 ;;
139
140 (defgroup elpher nil
141   "A gopher and gemini client."
142   :group 'applications)
143
144 ;; General appearance and customizations
145
146 (defcustom elpher-open-urls-with-eww nil
147   "If non-nil, open URL selectors using eww.
148 Otherwise, use the system browser via the `browse-url' function."
149   :type '(boolean))
150
151 (defcustom elpher-use-header t
152   "If non-nil, display current page information in buffer header."
153   :type '(boolean))
154
155 (defcustom elpher-auto-disengage-TLS nil
156   "If non-nil, automatically disengage TLS following an unsuccessful connection.
157 While enabling this may seem convenient, it is also potentially
158 dangerous as it allows switching from an encrypted channel back to
159 plain text without user input."
160   :type '(boolean))
161
162 (defcustom elpher-connection-timeout 5
163   "Specifies the number of seconds to wait for a network connection to time out."
164   :type '(integer))
165
166 (defcustom elpher-filter-ansi-from-text nil
167   "If non-nil, filter ANSI escape sequences from text.
168 The default behaviour is to use the ansi-color package to interpret these
169 sequences."
170   :type '(boolean))
171
172 (defcustom elpher-certificate-directory
173   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
174   "Specify the name of the directory where client certificates will be stored.
175 These certificates may be used for establishing authenticated TLS connections."
176   :type '(directory))
177
178 (defcustom elpher-openssl-command "openssl"
179   "The command used to launch openssl when generating TLS client certificates."
180   :type '(file))
181
182 (defcustom elpher-default-url-type "gopher"
183   "Default URL type (i.e. scheme) to assume if not explicitly given."
184   :type '(choice (const "gopher")
185                  (const "gemini")))
186
187 (defcustom elpher-gemini-TLS-cert-checks nil
188   "If non-nil, verify gemini server TLS certs using the default security level.
189 Otherwise, certificate verification is disabled.
190
191 This defaults to off because it is standard practice for Gemini servers
192 to use self-signed certificates, meaning that most servers provide what
193 EMACS considers to be an invalid certificate."
194   :type '(boolean))
195
196 (defcustom elpher-gemini-max-fill-width 80
197   "Specify the maximum default width (in columns) of text/gemini documents.
198 The actual width used is the minimum of this value and the window width at
199 the time when the text is rendered."
200   :type '(integer))
201
202 (defcustom elpher-gemini-link-string "→ "
203   "Specify the string used to indicate links when rendering gemini maps.
204 May be empty."
205   :type '(string))
206
207 (defcustom elpher-gemini-bullet-string "•"
208   "Specify the string used for bullets when rendering gemini maps."
209   :type '(string))
210
211 (defcustom elpher-ipv4-always nil
212   "If non-nil, elpher will always use IPv4 to establish network connections.
213 This can be useful when browsing from a computer that supports IPv6, because
214 some servers which do not support IPv6 can take a long time to time-out."
215   :type '(boolean))
216
217 (defcustom elpher-socks-always nil
218   "If non-nil, elpher will establish network connections over a SOCKS proxy.
219 Otherwise, the SOCKS proxy is only used for connections to onion services."
220   :type '(boolean))
221
222 (defcustom elpher-use-emacs-bookmark-menu nil
223   "If non-nil, elpher will only use the native Emacs bookmark menu.
224 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
225 page within which all of the standard elpher keybindings are active."
226   :type '(boolean))
227
228 (defcustom elpher-start-page "about:welcome"
229   "Specify the page displayed initially by elpher.
230 The default welcome screen is \"about:welcome\", while the bookmarks list
231 is \"about:bookmarks\".  You can also specify local files via \"file:\".
232
233 Beware that using \"about:bookmarks\" as a start page in combination with
234 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
235 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
236 the start page."
237   :type '(string))
238
239 ;; Face customizations
240
241 (defgroup elpher-faces nil
242   "Elpher face customizations."
243   :group 'elpher)
244
245 (defface elpher-index
246   '((t :inherit font-lock-keyword-face))
247   "Face used for directory type directory records.")
248
249 (defface elpher-text
250   '((t :inherit bold))
251   "Face used for text type directory records.")
252
253 (defface elpher-info
254   '((t :inherit default))
255   "Face used for info type directory records.")
256
257 (defface elpher-image
258   '((t :inherit font-lock-string-face))
259   "Face used for image type directory records.")
260
261 (defface elpher-search
262   '((t :inherit warning))
263   "Face used for search type directory records.")
264
265 (defface elpher-html
266   '((t :inherit font-lock-comment-face))
267   "Face used for html type directory records.")
268
269 (defface elpher-gemini
270   '((t :inherit font-lock-constant-face))
271   "Face used for Gemini type directory records.")
272
273 (defface elpher-other-url
274   '((t :inherit font-lock-comment-face))
275   "Face used for other URL type links records.")
276
277 (defface elpher-telnet
278   '((t :inherit font-lock-function-name-face))
279   "Face used for telnet type directory records.")
280
281 (defface elpher-binary
282   '((t :inherit font-lock-doc-face))
283   "Face used for binary type directory records.")
284
285 (defface elpher-unknown
286   '((t :inherit error))
287   "Face used for directory records with unknown/unsupported types.")
288
289 (defface elpher-margin-key
290   '((t :inherit bold))
291   "Face used for directory margin key.")
292
293 (defface elpher-margin-brackets
294   '((t :inherit shadow))
295   "Face used for brackets around directory margin key.")
296
297 (defface elpher-gemini-heading1
298   '((t :inherit bold :height 1.8))
299   "Face used for gemini heading level 1.")
300
301 (defface elpher-gemini-heading2
302   '((t :inherit bold :height 1.5))
303   "Face used for gemini heading level 2.")
304
305 (defface elpher-gemini-heading3
306   '((t :inherit bold :height 1.2))
307   "Face used for gemini heading level 3.")
308
309 (defface elpher-gemini-preformatted
310   '((t :inherit fixed-pitch))
311   "Face used for pre-formatted gemini text blocks.")
312
313 (defface elpher-gemini-quoted
314   '((t :inherit font-lock-doc-face))
315   "Face used for gemini quoted texts.")
316
317 ;;; Model
318 ;;
319
320 ;; Address
321
322 ;; An elpher "address" object is either a url object or a symbol.
323 ;; Addresses with the "about" type, corresponding to pages generated
324 ;; dynamically for and by elpher.  All others represent pages which
325 ;; rely on content retrieved over the network.
326
327 (defun elpher-address-from-url (url-string)
328   "Create a ADDRESS object corresponding to the given URL-STRING."
329   (let ((data (match-data))) ; Prevent parsing clobbering match data
330     (unwind-protect
331         (let ((url (url-generic-parse-url url-string)))
332           (unless (and (not (url-fullness url)) (url-type url))
333             (setf (url-fullness url) t)
334             (unless (url-type url)
335               (setf (url-type url) elpher-default-url-type))
336             (unless (url-host url)
337               (let ((p (split-string (url-filename url) "/" nil nil)))
338                 (setf (url-host url) (car p))
339                 (setf (url-filename url)
340                       (if (cdr p)
341                           (concat "/" (mapconcat #'identity (cdr p) "/"))
342                         ""))))
343             (when (or (equal "gopher" (url-type url))
344                       (equal "gophers" (url-type url)))
345               ;; Gopher defaults
346               (when (or (equal (url-filename url) "")
347                         (equal (url-filename url) "/"))
348                 (setf (url-filename url) "/1")))
349             (when (equal "gemini" (url-type url))
350               ;; Gemini defaults
351               (if (equal (url-filename url) "")
352                   (setf (url-filename url) "/"))))
353           (elpher-remove-redundant-ports url))
354       (set-match-data data))))
355
356 (defun elpher-remove-redundant-ports (address)
357   "Remove redundant port specifiers from ADDRESS.
358 Here 'redundant' means that the specified port matches the default
359 for that protocol, eg 70 for gopher."
360   (if (and (not (elpher-address-about-p address))
361            (eq (url-portspec address) ; (url-port) is too slow!
362                (pcase (url-type address)
363                  ("gemini" 1965)
364                  ((or "gopher" "gophers") 70)
365                  ("finger" 79)
366                  (_ -1))))
367       (setf (url-portspec address) nil))
368   address)
369
370 (defun elpher-make-gopher-address (type selector host port &optional tls)
371   "Create an ADDRESS object using gopher directory record attributes.
372 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
373 If the optional attribute TLS is non-nil, the address will be marked as
374 requiring gopher-over-TLS."
375   (cond
376    ((equal type ?i) nil)
377    ((and (equal type ?h)
378          (string-prefix-p "URL:" selector))
379     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
380    ((equal type ?8)
381     (elpher-address-from-url
382      (concat "telnet"
383              "://" host
384              ":" (number-to-string port))))
385    (t
386     (elpher-address-from-url
387      (concat "gopher" (if tls "s" "")
388              "://" host
389              ":" (number-to-string port)
390              "/" (string type)
391              selector)))))
392
393 (defun elpher-make-about-address (type)
394   "Create an ADDRESS object corresponding to the given about address TYPE."
395   (elpher-address-from-url (concat "about:" (symbol-name type))))
396
397 (defun elpher-address-to-url (address)
398   "Get string representation of ADDRESS."
399   (url-encode-url (url-recreate-url address)))
400
401 (defun elpher-address-type (address)
402   "Retrieve type of ADDRESS object.
403 This is used to determine how to retrieve and render the document the
404 address refers to, via the table `elpher-type-map'."
405   (pcase (url-type address)
406     ("about"
407      (list 'about (intern (url-filename address))))
408     ((or "gopher" "gophers")
409      (list 'gopher
410            (if (member (url-filename address) '("" "/"))
411                ?1
412              (string-to-char (substring (url-filename address) 1)))))
413     ("gemini" 'gemini)
414     ("telnet" 'telnet)
415     ("finger" 'finger)
416     ("file" 'file)
417     (_ 'other-url)))
418
419 (defun elpher-address-about-p (address)
420   "Return non-nil if ADDRESS is an  about address."
421   (pcase (elpher-address-type address) (`(about ,_) t)))
422
423 (defun elpher-address-gopher-p (address)
424   "Return non-nill if ADDRESS object is a gopher address."
425   (eq 'gopher (elpher-address-type address)))
426
427 (defun elpher-address-protocol (address)
428   "Retrieve the transport protocol for ADDRESS."
429   (url-type address))
430
431 (defun elpher-address-filename (address)
432   "Retrieve the filename component of ADDRESS.
433 For gopher addresses this is a combination of the selector type and selector."
434   (url-unhex-string (url-filename address)))
435
436 (defun elpher-address-host (address)
437   "Retrieve host from ADDRESS object."
438   (url-host address))
439
440 (defun elpher-address-user (address)
441   "Retrieve user from ADDRESS object."
442   (url-user address))
443
444 (defun elpher-address-port (address)
445   "Retrieve port from ADDRESS object.
446 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
447   (url-port address))
448
449 (defun elpher-gopher-address-selector (address)
450   "Retrieve gopher selector from ADDRESS object."
451   (if (member (url-filename address) '("" "/"))
452       ""
453     (url-unhex-string (substring (url-filename address) 2))))
454
455
456 ;; Cache
457
458 (defvar elpher-content-cache (make-hash-table :test 'equal))
459 (defvar elpher-pos-cache (make-hash-table :test 'equal))
460
461 (defun elpher-get-cached-content (address)
462   "Retrieve the cached content for ADDRESS, or nil if none exists."
463   (gethash address elpher-content-cache))
464
465 (defun elpher-cache-content (address content)
466   "Set the content cache for ADDRESS to CONTENT."
467   (puthash address content elpher-content-cache))
468
469 (defun elpher-get-cached-pos (address)
470   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
471   (gethash address elpher-pos-cache))
472
473 (defun elpher-cache-pos (address pos)
474   "Set the cursor position cache for ADDRESS to POS."
475   (puthash address pos elpher-pos-cache))
476
477
478 ;; Page
479
480 (defun elpher-make-page (display-string address)
481   "Create a page with DISPLAY-STRING and ADDRESS."
482   (list display-string address))
483
484 (defun elpher-make-start-page ()
485   "Create the welcome page."
486   (elpher-make-page "Start Page"
487                     (elpher-address-from-url elpher-start-page)))
488
489 (defun elpher-page-display-string (page)
490   "Retrieve the display string corresponding to PAGE."
491   (elt page 0))
492
493 (defun elpher-page-address (page)
494   "Retrieve the address corresponding to PAGE."
495   (elt page 1))
496
497 (defun elpher-page-set-address (page new-address)
498   "Set the address corresponding to PAGE to NEW-ADDRESS."
499   (setcar (cdr page) new-address))
500
501 (defun elpher-page-from-url (url)
502   "Create a page with address and display string defined by URL.
503 The URL is unhexed prior to its use as a display string to improve
504 readability."
505   (elpher-make-page (elpher-decode (url-unhex-string url))
506                     (elpher-address-from-url url)))
507
508 (defvar elpher-current-page nil
509   "The current page for this Elpher buffer.")
510
511 (defvar elpher-history nil
512   "The local history stack for this Elpher buffer.
513 This variable is used by `elpher-back' and
514 `elpher-show-history'.")
515
516 (defvar elpher-visited-pages nil
517   "The global history for all Elpher buffers.
518 This variable is used by `elpher-show-visited-pages'.")
519
520 (defun elpher-visit-page (page &optional renderer no-history)
521   "Visit PAGE using its own renderer or RENDERER, if non-nil.
522 Additionally, push PAGE onto the history stack and the list of
523 previously-visited pages,unless NO-HISTORY is non-nil."
524   (elpher-save-pos)
525   (elpher-process-cleanup)
526   (unless no-history
527     (unless (or (not elpher-current-page)
528                  (equal (elpher-page-address elpher-current-page)
529                         (elpher-page-address page)))
530       (push elpher-current-page elpher-history)
531       (unless (or (elpher-address-about-p (elpher-page-address page))
532                   (and elpher-visited-pages
533                        (equal page (car elpher-visited-pages))))
534         (push page elpher-visited-pages))))
535   (setq-local elpher-current-page page)
536   (let* ((address (elpher-page-address page))
537          (type (elpher-address-type address))
538          (type-record (cdr (assoc type elpher-type-map))))
539     (if type-record
540         (funcall (car type-record)
541                  (if renderer
542                      renderer
543                    (cadr type-record)))
544       (elpher-visit-previous-page)
545       (pcase type
546         (`(gopher ,type-char)
547          (error "Unsupported gopher selector type '%c' for '%s'"
548                 type-char (elpher-address-to-url address)))
549         (other
550          (error "Unsupported address type '%S' for '%s'"
551                 other (elpher-address-to-url address)))))))
552
553 (defun elpher-visit-previous-page ()
554   "Visit the previous page in the history."
555   (if elpher-history
556       (elpher-visit-page (pop elpher-history) nil t)
557     (error "No previous page")))
558
559 (defun elpher-reload-current-page ()
560   "Reload the current page, discarding any existing cached content."
561   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
562   (elpher-visit-page elpher-current-page))
563
564 (defun elpher-save-pos ()
565   "Save the current position of point to the current page."
566   (when elpher-current-page
567     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
568
569 (defun elpher-restore-pos ()
570   "Restore the position of point to that cached in the current page."
571   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
572     (if pos
573         (goto-char pos)
574       (goto-char (point-min)))))
575
576
577 ;;; Buffer preparation
578 ;;
579
580 (defvar elpher-buffer-name "*elpher*"
581   "The default name of the Elpher buffer.")
582
583 (defun elpher-update-header ()
584   "If `elpher-use-header' is true, display current page info in window header."
585   (if elpher-use-header
586       (let* ((display-string (elpher-page-display-string elpher-current-page))
587              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
588              (address (elpher-page-address elpher-current-page))
589              (tls-string (if (and (not (elpher-address-about-p address))
590                                   (member (elpher-address-protocol address)
591                                           '("gophers" "gemini")))
592                              " [TLS encryption]"
593                            ""))
594              (header (concat sanitized-display-string
595                              (propertize tls-string 'face 'bold))))
596         (setq header-line-format header))))
597
598 (defmacro elpher-with-clean-buffer (&rest args)
599   "Evaluate ARGS with a clean *elpher* buffer as current."
600   (declare (debug (body))) ;; Allow edebug to step through body
601   `(with-current-buffer elpher-buffer-name
602      (unless (eq major-mode 'elpher-mode)
603        ;; avoid resetting buffer-local variables
604        (elpher-mode))
605      (let ((inhibit-read-only t)
606            (ansi-color-context nil)) ;; clean ansi interpreter state
607        (setq-local network-security-level
608                    (default-value 'network-security-level))
609        (erase-buffer)
610        (elpher-update-header)
611        ,@args)))
612
613 (defun elpher-buffer-message (string &optional line)
614   "Replace first line in elpher buffer with STRING.
615 If LINE is non-nil, replace that line instead."
616   (with-current-buffer elpher-buffer-name
617     (let ((inhibit-read-only t))
618       (goto-char (point-min))
619       (if line
620           (forward-line line))
621       (let ((data (match-data)))
622         (unwind-protect
623             (progn
624               (re-search-forward "^.*$")
625               (replace-match string))
626           (set-match-data data))))))
627
628
629 ;;; Text Processing
630 ;;
631
632 (defvar elpher-user-coding-system nil
633   "User-specified coding system to use for decoding text responses.")
634
635 (defun elpher-decode (string)
636   "Decode STRING using autodetected or user-specified coding system."
637   (decode-coding-string string
638                         (if elpher-user-coding-system
639                             elpher-user-coding-system
640                           (detect-coding-string string t))))
641
642 (defun elpher-preprocess-text-response (string)
643   "Preprocess text selector response contained in STRING.
644 This involes decoding the character representation, and clearing
645 away CRs and any terminating period."
646   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
647                                            (replace-regexp-in-string "\r" "" string))))
648
649 ;;; Buttonify urls
650
651 (defconst elpher-url-regex
652   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
653   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
654
655 (defun elpher-buttonify-urls (string)
656   "Turn substrings which look like urls in STRING into clickable buttons."
657   (with-temp-buffer
658     (insert string)
659     (goto-char (point-min))
660     (while (re-search-forward elpher-url-regex nil t)
661       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
662         (make-text-button (match-beginning 0)
663                           (match-end 0)
664                           'elpher-page  page
665                           'action #'elpher-click-link
666                           'follow-link t
667                           'help-echo #'elpher--page-button-help
668                           'face 'button)))
669     (buffer-string)))
670
671 ;;; ANSI colors or XTerm colors (application and filtering)
672
673 (or (require 'xterm-color nil t)
674     (require 'ansi-color))
675
676 (defalias 'elpher-color-filter-apply
677   (if (fboundp 'xterm-color-filter)
678       (lambda (s)
679         (let ((_xterm-color-render nil))
680           (xterm-color-filter s)))
681     #'ansi-color-filter-apply)
682   "A function to filter out ANSI escape sequences.")
683
684 (defalias 'elpher-color-apply
685   (if (fboundp 'xterm-color-filter)
686       #'xterm-color-filter
687     #'ansi-color-apply)
688   "A function to apply ANSI escape sequences.")
689
690 ;;; Processing text for display
691
692 (defun elpher-process-text-for-display (string)
693   "Perform any desired processing of STRING prior to display as text.
694 Currently includes buttonifying URLs and processing ANSI escape codes."
695   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
696                              (elpher-color-filter-apply string)
697                            (elpher-color-apply string))))
698
699
700 ;;; Network error reporting
701 ;;
702
703 (defun elpher-network-error (address error)
704   "Display ERROR message following unsuccessful negotiation with ADDRESS.
705 ERROR can be either an error object or a string."
706   (elpher-with-clean-buffer
707    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
708            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
709            (if (stringp error) error (error-message-string error)) "\n"
710            (propertize "\n----------------\n\n" 'face 'error)
711            "Press 'u' to return to the previous page.")))
712
713
714 ;;; General network communication
715 ;;
716
717 (defvar elpher-network-timer nil
718   "Timer used for network connections.")
719
720 (defvar elpher-use-tls nil
721   "If non-nil, use TLS to communicate with gopher servers.")
722
723 (defvar elpher-client-certificate nil
724   "If non-nil, contains client certificate details to use for TLS connections.")
725
726 (defun elpher-process-cleanup ()
727   "Immediately shut down any extant elpher process and timers."
728   (let ((p (get-process "elpher-process")))
729     (if p (delete-process p)))
730   (if (timerp elpher-network-timer)
731       (cancel-timer elpher-network-timer)))
732
733 (defun elpher-make-network-timer (thunk)
734   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
735 This is just a wraper around `run-at-time' which additionally sets the
736 buffer-local variable `elpher-network-timer' to allow
737 `elpher-process-cleanup' to also clear the timer."
738   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
739     (setq-local elpher-network-timer timer)
740     timer))
741
742 (defun elpher-get-host-response (address default-port query-string response-processor
743                                          &optional use-tls force-ipv4)
744   "Generic function for retrieving data from ADDRESS.
745
746 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
747 QUERY-STRING is a string sent to the host specified by ADDRESS to
748 illicet a response.  This response is passed as an argument to the
749 function RESPONSE-PROCESSOR.
750
751 If non-nil, USE-TLS specifies that the connection is to be made over
752 TLS.  If set to gemini, the certificate verification will be disabled
753 unless `elpher-gemini-TLS-cert-checks' is non-nil.
754
755 If non-nil, FORCE-IPV4 causes the network connection to be made over
756 ipv4 only.  (The default behaviour when this is not set depends on
757 the host operating system and the local network capabilities.)"
758   (if (and use-tls (not (gnutls-available-p)))
759       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
760     (unless (< (elpher-address-port address) 65536)
761       (error "Cannot establish network connection: port number > 65536"))
762     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
763       (setq-local network-security-level 'low)
764       (setq-local gnutls-verify-error nil))
765     (condition-case nil
766         (let* ((kill-buffer-query-functions nil)
767                (port (elpher-address-port address))
768                (host (elpher-address-host address))
769                (service (if (> port 0) port default-port))
770                (response-string-parts nil)
771                (bytes-received 0)
772                (hkbytes-received 0)
773                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
774                (gnutls-params (list :type 'gnutls-x509pki
775                                     :hostname host
776                                     :keylist
777                                     (elpher-get-current-keylist address)))
778                (timer (elpher-make-network-timer
779                                    (lambda ()
780                                      (elpher-process-cleanup)
781                                      (cond
782                                         ; Try again with IPv4
783                                       ((not (or elpher-ipv4-always force-ipv4 socks))
784                                        (message "Connection timed out.  Retrying with IPv4.")
785                                        (elpher-get-host-response address default-port
786                                                                  query-string
787                                                                  response-processor
788                                                                  use-tls t))
789                                       ((and use-tls
790                                             (not (eq use-tls 'gemini))
791                                             (or elpher-auto-disengage-TLS
792                                                 (y-or-n-p
793                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
794                                        (setq elpher-use-tls nil)
795                                        (elpher-get-host-response address default-port
796                                                                  query-string
797                                                                  response-processor
798                                                                  nil force-ipv4))
799                                       (t
800                                        (elpher-network-error address "Connection time-out."))))))
801                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
802                        (make-network-process :name "elpher-process"
803                                              :host host
804                                              :family (and (or force-ipv4
805                                                               elpher-ipv4-always)
806                                                           'ipv4)
807                                              :service service
808                                              :buffer nil
809                                              :nowait t
810                                              :tls-parameters
811                                              (and use-tls
812                                                   (cons 'gnutls-x509pki
813                                                         (apply #'gnutls-boot-parameters
814                                                                gnutls-params)))))))
815           (setq elpher-network-timer timer)
816           (set-process-coding-system proc 'binary 'binary)
817           (set-process-query-on-exit-flag proc nil)
818           (elpher-buffer-message (concat "Connecting to " host "..."
819                                          " (press 'u' to abort)"))
820           (set-process-filter proc
821                               (lambda (_proc string)
822                                 (when timer
823                                   (cancel-timer timer)
824                                   (setq timer nil))
825                                 (setq bytes-received (+ bytes-received (length string)))
826                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
827                                   (when (> new-hkbytes-received hkbytes-received)
828                                     (setq hkbytes-received new-hkbytes-received)
829                                     (elpher-buffer-message
830                                      (concat "("
831                                              (number-to-string (/ hkbytes-received 10.0))
832                                              " MB read)")
833                                      1)))
834                                 (setq response-string-parts
835                                       (cons string response-string-parts))))
836           (set-process-sentinel proc
837                                 (lambda (proc event)
838                                   (when timer
839                                     (cancel-timer timer))
840                                   (condition-case the-error
841                                       (cond
842                                        ((string-prefix-p "open" event)    ; request URL
843                                         (elpher-buffer-message
844                                          (concat "Connected to " host ". Receiving data..."
845                                                  " (press 'u' to abort)"))
846                                         (let ((inhibit-eol-conversion t))
847                                           (process-send-string proc query-string)))
848                                        ((string-prefix-p "deleted" event)) ; do nothing
849                                        ((and (not response-string-parts)
850                                              (not (or elpher-ipv4-always force-ipv4 socks)))
851                                         ; Try again with IPv4
852                                         (message "Connection failed. Retrying with IPv4.")
853                                         (elpher-get-host-response address default-port
854                                                                   query-string
855                                                                   response-processor
856                                                                   use-tls t))
857                                        (response-string-parts
858                                         (elpher-with-clean-buffer
859                                          (insert "Data received.  Rendering..."))
860                                         (funcall response-processor
861                                                  (apply #'concat (reverse response-string-parts)))
862                                         (elpher-restore-pos))
863                                        (t
864                                         (error "No response from server")))
865                                     (error
866                                      (elpher-network-error address the-error)))))
867           (when socks
868             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
869             (funcall (process-sentinel proc) proc "open\n")))
870       (error
871        (elpher-process-cleanup)
872        (error "Error initiating connection to server")))))
873
874
875 ;;; Client-side TLS Certificate Management
876 ;;
877
878 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
879   "Generate a key and a self-signed client TLS certificate using openssl.
880
881 The Common Name field of the certificate is set to COMMON-NAME.  The
882 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
883 the key and certificate files to write.
884
885 If TEMPORARY is non-nil, the certificate will be given an exporation
886 period of one day, and the key and certificate files will be deleted
887 when the certificate is no longer needed for the current session.
888
889 Otherwise, the certificate will be given a 100 year expiration period
890 and the files will not be deleted.
891
892 The function returns a list containing the current host name, the
893 temporary flag, and the key and cert file names in the form required
894 by `gnutls-boot-parameters`."
895   (let ((exp-key-file (expand-file-name key-file))
896         (exp-cert-file (expand-file-name cert-file)))
897     (condition-case nil
898         (progn
899           (call-process elpher-openssl-command nil nil nil
900                         "req" "-x509" "-newkey" "rsa:2048"
901                         "-days" (if temporary "1" "36500")
902                         "-nodes"
903                         "-subj" (concat "/CN=" common-name)
904                         "-keyout" exp-key-file
905                         "-out" exp-cert-file)
906           (list (elpher-address-host (elpher-page-address elpher-current-page))
907                 temporary exp-key-file exp-cert-file))
908       (error
909        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
910        (error "Program 'openssl', required for certificate generation, not found")))))
911
912 (defun elpher-generate-throwaway-certificate ()
913   "Generate and return details of a throwaway certificate.
914 The key and certificate files will be deleted when they are no
915 longer needed for this session."
916   (let* ((file-base (make-temp-name "elpher"))
917          (key-file (concat temporary-file-directory file-base ".key"))
918          (cert-file (concat temporary-file-directory file-base ".crt")))
919     (elpher-generate-certificate file-base key-file cert-file t)))
920
921 (defun elpher-generate-persistent-certificate (file-base common-name)
922   "Generate and return details of a persistent certificate.
923 The argument FILE-BASE is used as the base for the key and certificate
924 files, while COMMON-NAME specifies the common name field of the
925 certificate.
926
927 The key and certificate files are written to in `elpher-certificate-directory'."
928   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
929          (cert-file (concat elpher-certificate-directory file-base ".crt")))
930     (elpher-generate-certificate common-name key-file cert-file)))
931
932 (defun elpher-get-existing-certificate (file-base)
933   "Return a certificate object corresponding to an existing certificate.
934 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
935 the directory `elpher-certificate-directory'."
936   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
937          (cert-file (concat elpher-certificate-directory file-base ".crt")))
938     (list (elpher-address-host (elpher-page-address elpher-current-page))
939           nil
940           (expand-file-name key-file)
941           (expand-file-name cert-file))))
942
943 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
944   "Install a key+certificate file pair in `elpher-certificate-directory'.
945 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
946 certificate files to install.  The argument FILE-BASE is used as the
947 base for the installed key and certificate files."
948   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
949          (cert-file (concat elpher-certificate-directory file-base ".crt")))
950     (if (or (file-exists-p key-file)
951             (file-exists-p cert-file))
952         (error "A certificate with base name %s is already installed" file-base))
953     (copy-file key-file-src key-file)
954     (copy-file cert-file-src cert-file)
955     (list (elpher-address-host (elpher-page-address elpher-current-page))
956           nil
957           (expand-file-name key-file)
958           (expand-file-name cert-file))))
959
960 (defun elpher-list-existing-certificates ()
961   "Return a list of the persistent certificates in `elpher-certificate-directory'."
962   (unless (file-directory-p elpher-certificate-directory)
963     (make-directory elpher-certificate-directory))
964   (mapcar
965    (lambda (file)
966      (file-name-sans-extension file))
967    (directory-files elpher-certificate-directory nil "\\.key$")))
968
969 (defun elpher-forget-current-certificate ()
970   "Causes any current certificate to be forgotten.)
971 In the case of throwaway certificates, the key and certificate files
972 are also deleted."
973   (interactive)
974   (when elpher-client-certificate
975     (unless (and (called-interactively-p 'any)
976                  (not (y-or-n-p (concat "Really forget client certificate? "
977                                         "(Throwaway certificates will be deleted.)"))))
978       (when (cadr elpher-client-certificate)
979         (delete-file (elt elpher-client-certificate 2))
980         (delete-file (elt elpher-client-certificate 3)))
981       (setq elpher-client-certificate nil)
982       (if (called-interactively-p 'any)
983           (message "Client certificate forgotten.")))))
984
985 (defun elpher-get-current-keylist (address)
986   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
987
988 This is obtained from the client certificate described by
989 `elpher-current-certificate', if one is available and the host for
990 that certificate matches the host in ADDRESS.
991
992 If `elpher-current-certificate' is non-nil, and its host name doesn't
993 match that of ADDRESS, the certificate is forgotten."
994   (if elpher-client-certificate
995       (if (string= (car elpher-client-certificate)
996                    (elpher-address-host address))
997           (list (cddr elpher-client-certificate))
998         (elpher-forget-current-certificate)
999         (message "Disabling client certificate for new host")
1000         nil)
1001     nil))
1002
1003
1004 ;;; Gopher selector retrieval
1005 ;;
1006
1007 (defun elpher-get-gopher-response (address renderer)
1008   "Get response string from gopher server at ADDRESS and render using RENDERER."
1009   (elpher-get-host-response address 70
1010                             (concat (elpher-gopher-address-selector address) "\r\n")
1011                             renderer
1012                             (or (string= (elpher-address-protocol address) "gophers")
1013                                 elpher-use-tls)))
1014
1015 (defun elpher-get-gopher-page (renderer)
1016   "Getter function for gopher pages.
1017 The RENDERER procedure is used to display the contents of the page
1018 once they are retrieved from the gopher server."
1019   (let* ((address (elpher-page-address elpher-current-page))
1020          (content (elpher-get-cached-content address)))
1021     (if (and content (funcall renderer nil))
1022         (elpher-with-clean-buffer
1023          (insert content)
1024          (elpher-restore-pos))
1025       (elpher-with-clean-buffer
1026        (insert "LOADING... (use 'u' to cancel)\n"))
1027       (condition-case the-error
1028           (elpher-get-gopher-response address renderer)
1029         (error
1030          (elpher-network-error address the-error))))))
1031
1032 ;; Index rendering
1033
1034 (defun elpher-insert-margin (&optional type-name)
1035   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
1036   (if type-name
1037       (progn
1038         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1039                         (concat
1040                          (propertize "[" 'face 'elpher-margin-brackets)
1041                          (propertize type-name 'face 'elpher-margin-key)
1042                          (propertize "]" 'face 'elpher-margin-brackets))))
1043         (insert " "))
1044     (insert (make-string elpher-margin-width ?\s))))
1045
1046 (defun elpher--page-button-help (_window buffer pos)
1047   "Function called by Emacs to generate mouse-over text.
1048 The arguments specify the BUFFER and the POS within the buffer of the item
1049 for which help is required.  The function returns the help to be
1050 displayed.  The _WINDOW argument is currently unused."
1051   (with-current-buffer buffer
1052     (let ((button (button-at pos)))
1053       (when button
1054         (let* ((page (button-get button 'elpher-page))
1055                (address (elpher-page-address page)))
1056           (format "mouse-1, RET: open '%s'" (if (elpher-address-about-p address)
1057                                                 address
1058                                               (elpher-address-to-url address))))))))
1059
1060 (defun elpher-insert-index-record (display-string &optional address)
1061   "Function to insert an index record into the current buffer.
1062 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1063 If ADDRESS is not supplied or nil the record is rendered as an
1064 'information' line."
1065   (let* ((type (if address (elpher-address-type address) nil))
1066          (type-map-entry (cdr (assoc type elpher-type-map))))
1067     (if type-map-entry
1068         (let* ((margin-code (elt type-map-entry 2))
1069                (face (elt type-map-entry 3))
1070                (filtered-display-string (elpher-color-filter-apply display-string))
1071                (page (elpher-make-page filtered-display-string address)))
1072           (elpher-insert-margin margin-code)
1073           (insert-text-button filtered-display-string
1074                               'face face
1075                               'elpher-page page
1076                               'action #'elpher-click-link
1077                               'follow-link t
1078                               'help-echo #'elpher--page-button-help))
1079       (pcase type
1080         ('nil ;; Information
1081          (elpher-insert-margin)
1082          (let ((propertized-display-string
1083                 (propertize display-string 'face 'elpher-info)))
1084            (insert (elpher-process-text-for-display propertized-display-string))))
1085         (`(gopher ,selector-type) ;; Unknown
1086          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1087          (insert (propertize display-string
1088                              'face 'elpher-unknown)))))
1089     (insert "\n")))
1090
1091 (defun elpher-click-link (button)
1092   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
1093   (let ((page (button-get button 'elpher-page)))
1094     (elpher-visit-page page)))
1095
1096 (defun elpher-render-index (data &optional _mime-type-string)
1097   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1098   (elpher-with-clean-buffer
1099    (if (not data)
1100        t
1101      (let ((data-processed (elpher-preprocess-text-response data)))
1102        (dolist (line (split-string data-processed "\n"))
1103          (ignore-errors
1104            (unless (= (length line) 0)
1105              (let* ((type (elt line 0))
1106                     (fields (split-string (substring line 1) "\t"))
1107                     (display-string (elt fields 0))
1108                     (selector (elt fields 1))
1109                     (host (elt fields 2))
1110                     (port (if (elt fields 3)
1111                               (string-to-number (elt fields 3))
1112                             nil))
1113                     (address (elpher-make-gopher-address type selector host port)))
1114                (elpher-insert-index-record display-string address))))))
1115      (elpher-cache-content (elpher-page-address elpher-current-page)
1116                            (buffer-string)))))
1117
1118 ;; Text rendering
1119
1120 (defun elpher-render-text (data &optional _mime-type-string)
1121   "Render DATA as text.  MIME-TYPE-STRING is unused."
1122   (elpher-with-clean-buffer
1123    (if (not data)
1124        t
1125      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1126      (elpher-cache-content
1127       (elpher-page-address elpher-current-page)
1128       (buffer-string)))))
1129
1130 ;; Image retrieval
1131
1132 (defun elpher-render-image (data &optional _mime-type-string)
1133   "Display DATA as image.  MIME-TYPE-STRING is unused."
1134   (if (not data)
1135       nil
1136     (if (display-images-p)
1137         (let* ((image (create-image
1138                        data
1139                        nil t))
1140                (window (get-buffer-window elpher-buffer-name)))
1141           (when window
1142             (setf (image-property image :max-width) (window-body-width window t))
1143             (setf (image-property image :max-height) (window-body-height window t)))
1144           (elpher-with-clean-buffer
1145            (insert-image image)
1146            (elpher-restore-pos)))
1147       (elpher-render-download data))))
1148
1149 ;; Search retrieval and rendering
1150
1151 (defun elpher-get-gopher-query-page (renderer)
1152   "Getter for gopher addresses requiring input.
1153 The response is rendered using the rendering function RENDERER."
1154   (let* ((address (elpher-page-address elpher-current-page))
1155          (content (elpher-get-cached-content address))
1156          (aborted t))
1157     (if (and content (funcall renderer nil))
1158         (elpher-with-clean-buffer
1159          (insert content)
1160          (elpher-restore-pos)
1161          (message "Displaying cached search results.  Reload to perform a new search."))
1162       (unwind-protect
1163           (let* ((query-string (read-string "Query: "))
1164                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1165                  (search-address (elpher-make-gopher-address ?1
1166                                                              query-selector
1167                                                              (elpher-address-host address)
1168                                                              (elpher-address-port address)
1169                                                              (equal (elpher-address-type address) "gophers"))))
1170             (setq aborted nil)
1171
1172             (elpher-with-clean-buffer
1173              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1174             (elpher-get-gopher-response search-address renderer))
1175         (if aborted
1176             (elpher-visit-previous-page))))))
1177
1178 ;; Raw server response rendering
1179
1180 (defun elpher-render-raw (data &optional mime-type-string)
1181   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1182   (if (not data)
1183       nil
1184     (elpher-with-clean-buffer
1185      (when mime-type-string
1186        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1187      (insert data)
1188      (goto-char (point-min)))
1189     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1190
1191 ;; File save "rendering"
1192
1193 (defun elpher-render-download (data &optional _mime-type-string)
1194   "Save DATA to file.  MIME-TYPE-STRING is unused."
1195   (if (not data)
1196       nil
1197     (let* ((address (elpher-page-address elpher-current-page))
1198            (selector (if (elpher-address-gopher-p address)
1199                          (elpher-gopher-address-selector address)
1200                        (elpher-address-filename address))))
1201       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1202       (let* ((filename-proposal (file-name-nondirectory selector))
1203              (filename (read-file-name "Download complete. Save file as: "
1204                                        nil nil nil
1205                                        (if (> (length filename-proposal) 0)
1206                                            filename-proposal
1207                                          "download.file"))))
1208         (let ((coding-system-for-write 'binary))
1209           (with-temp-file filename
1210             (insert data)))
1211         (message (format "Saved to file %s." filename))))))
1212
1213 ;; HTML rendering
1214
1215 (defun elpher-render-html (data &optional _mime-type-string)
1216   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1217   (elpher-with-clean-buffer
1218    (if (not data)
1219        t
1220      (let ((dom (with-temp-buffer
1221                   (insert data)
1222                   (libxml-parse-html-region (point-min) (point-max)))))
1223        (shr-insert-document dom)))))
1224
1225 ;; Gemini page retrieval
1226
1227 (defvar elpher-gemini-redirect-chain)
1228
1229 (defun elpher-get-gemini-response (address renderer)
1230   "Get response string from gemini server at ADDRESS and render using RENDERER."
1231   (elpher-get-host-response address 1965
1232                             (concat (elpher-address-to-url address) "\r\n")
1233                             (lambda (response-string)
1234                               (elpher-process-gemini-response response-string renderer))
1235                             'gemini))
1236
1237 (defun elpher-parse-gemini-response (response)
1238   "Parse the RESPONSE string and return a list of components.
1239 The list is of the form (code meta body).  A response of nil implies
1240 that the response was malformed."
1241   (let ((header-end-idx (string-match "\r\n" response)))
1242     (if header-end-idx
1243         (let ((header (string-trim (substring response 0 header-end-idx)))
1244               (body (substring response (+ header-end-idx 2))))
1245           (if (>= (length header) 2)
1246               (let ((code (substring header 0 2))
1247                     (meta (string-trim (substring header 2))))
1248                 (list code meta body))
1249             (error "Malformed response: No response status found in header %s" header)))
1250       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1251
1252 (defun elpher-process-gemini-response (response-string renderer)
1253   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1254   (let ((response-components (elpher-parse-gemini-response response-string)))
1255     (let ((response-code (elt response-components 0))
1256           (response-meta (elt response-components 1))
1257           (response-body (elt response-components 2)))
1258       (pcase (elt response-code 0)
1259         (?1 ; Input required
1260          (elpher-with-clean-buffer
1261           (insert "Gemini server is requesting input."))
1262          (let* ((query-string
1263                  (if (eq (elt response-code 1) ?1)
1264                      (read-passwd (concat response-meta ": "))
1265                    (read-string (concat response-meta ": "))))
1266                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1267                 (old-fname (url-filename query-address)))
1268            (setf (url-filename query-address)
1269                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1270            (elpher-get-gemini-response query-address renderer)))
1271         (?2 ; Normal response
1272          (funcall renderer response-body response-meta))
1273         (?3 ; Redirect
1274          (message "Following redirect to %s" response-meta)
1275          (if (>= (length elpher-gemini-redirect-chain) 5)
1276              (error "More than 5 consecutive redirects followed"))
1277          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1278            (if (member redirect-address elpher-gemini-redirect-chain)
1279                (error "Redirect loop detected"))
1280            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1281                (error "Server tried to automatically redirect to non-gemini URL: %s"
1282                       response-meta))
1283            (elpher-page-set-address elpher-current-page redirect-address)
1284            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1285            (elpher-get-gemini-response redirect-address renderer)))
1286         (?4 ; Temporary failure
1287          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1288                 response-code response-meta))
1289         (?5 ; Permanent failure
1290          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1291                 response-code response-meta))
1292         (?6 ; Client certificate required
1293          (elpher-with-clean-buffer
1294           (if elpher-client-certificate
1295               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1296             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1297           (auto-fill-mode 1)
1298           (elpher-gemini-insert-text response-meta))
1299          (let ((chosen-certificate (elpher-choose-client-certificate)))
1300            (unless chosen-certificate
1301              (error "Gemini server requires a client certificate and none was provided"))
1302            (setq elpher-client-certificate chosen-certificate))
1303          (elpher-with-clean-buffer)
1304          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1305         (_other
1306          (error "Gemini server response unknown: %s %s"
1307                 response-code response-meta))))))
1308
1309 (defun elpher--read-answer-polyfill (question answers)
1310   "Polyfill for `read-answer' in Emacs 26.1.
1311 QUESTION is a string containing a question, and ANSWERS
1312 is a list of possible answers."
1313     (completing-read question (mapcar 'identity answers)))
1314
1315 (if (fboundp 'read-answer)
1316     (defalias 'elpher-read-answer 'read-answer)
1317   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1318
1319 (defun elpher-choose-client-certificate ()
1320   "Prompt for a client certificate to use to establish a TLS connection."
1321   (let* ((read-answer-short t))
1322     (pcase (read-answer "What do you want to do? "
1323                         '(("throwaway" ?t
1324                            "generate and use throw-away certificate")
1325                           ("persistent" ?p
1326                            "generate new or use existing persistent certificate")
1327                           ("abort" ?a
1328                            "stop immediately")))
1329       ("throwaway"
1330        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1331       ("persistent"
1332        (let* ((existing-certificates (elpher-list-existing-certificates))
1333               (file-base (completing-read
1334                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1335                           existing-certificates)))
1336          (if (string-empty-p (string-trim file-base))
1337              nil
1338            (if (member file-base existing-certificates)
1339                (setq elpher-client-certificate
1340                      (elpher-get-existing-certificate file-base))
1341              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1342                                  '(("new" ?n
1343                                     "generate new certificate")
1344                                    ("install" ?i
1345                                     "install existing certificate")
1346                                    ("abort" ?a
1347                                     "stop immediately")))
1348                ("new"
1349                 (let ((common-name (read-string "Common Name field for new certificate: "
1350                                                 file-base)))
1351                   (message "New key and self-signed certificate written to %s"
1352                            elpher-certificate-directory)
1353                   (elpher-generate-persistent-certificate file-base common-name)))
1354                ("install"
1355                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1356                        (key-file (read-file-name "Key file: " nil nil t)))
1357                   (message "Key and certificate installed in %s for future use"
1358                            elpher-certificate-directory)
1359                   (elpher-install-and-use-existing-certificate key-file
1360                                                                cert-file
1361                                                                file-base)))
1362                ("abort" nil))))))
1363       ("abort" nil))))
1364
1365 (defun elpher-get-gemini-page (renderer)
1366   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1367   (let* ((address (elpher-page-address elpher-current-page))
1368          (content (elpher-get-cached-content address)))
1369     (condition-case the-error
1370         (if (and content (funcall renderer nil))
1371             (elpher-with-clean-buffer
1372              (insert content)
1373              (elpher-restore-pos))
1374           (elpher-with-clean-buffer
1375            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1376           (setq elpher-gemini-redirect-chain nil)
1377           (elpher-get-gemini-response address renderer))
1378       (error
1379        (elpher-network-error address the-error)))))
1380
1381 (defun elpher-render-gemini (body &optional mime-type-string)
1382   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1383   (if (not body)
1384       t
1385     (let* ((mime-type-string* (if (or (not mime-type-string)
1386                                       (string-empty-p mime-type-string))
1387                                   "text/gemini; charset=utf-8"
1388                                 mime-type-string))
1389            (mime-type-split (split-string mime-type-string* ";" t))
1390            (mime-type (string-trim (car mime-type-split)))
1391            (parameters (mapcar (lambda (s)
1392                                  (let ((key-val (split-string s "=")))
1393                                    (list (downcase (string-trim (car key-val)))
1394                                          (downcase (string-trim (cadr key-val))))))
1395                                (cdr mime-type-split))))
1396       (when (string-prefix-p "text/" mime-type)
1397         (setq body (decode-coding-string
1398                     body
1399                     (if (assoc "charset" parameters)
1400                         (intern (cadr (assoc "charset" parameters)))
1401                       'utf-8)))
1402         (setq body (replace-regexp-in-string "\r" "" body)))
1403       (pcase mime-type
1404         ((or "text/gemini" "")
1405          (elpher-render-gemini-map body parameters))
1406         ("text/html"
1407          (elpher-render-html body))
1408         ((pred (string-prefix-p "text/"))
1409          (elpher-render-gemini-plain-text body parameters))
1410         ((pred (string-prefix-p "image/"))
1411          (elpher-render-image body))
1412         (_other
1413          (elpher-render-download body))))))
1414
1415 (defun elpher-gemini-get-link-url (link-line)
1416   "Extract the url portion of LINK-LINE, a gemini map file link line.
1417 Returns nil in the event that the contents of the line following the
1418 => prefix are empty."
1419   (let ((l (split-string (substring link-line 2))))
1420     (if l
1421         (string-trim (elt l 0))
1422       nil)))
1423
1424 (defun elpher-gemini-get-link-display-string (link-line)
1425   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1426 Returns the url portion in the event that the display-string portion is empty."
1427   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1428          (idx (string-match "[ \t]" rest)))
1429     (string-trim (if idx
1430                      (substring rest (+ idx 1))
1431                    rest))))
1432
1433 (defun elpher-collapse-dot-sequences (filename)
1434   "Collapse dot sequences in FILENAME.
1435 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1436   (let* ((path (split-string filename "/"))
1437          (path-reversed-normalized
1438           (seq-reduce (lambda (a b)
1439                         (cond ((and a (equal b "..") (cdr a)))
1440                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1441                               ((equal b ".") a)
1442                               (t (cons b a))))
1443                       path nil)))
1444     (string-join (reverse path-reversed-normalized) "/")))
1445
1446 (defun elpher-address-from-gemini-url (url)
1447   "Extract address from URL with defaults as per gemini map files.
1448 While there's obviously some redundancy here between this function and
1449 `elpher-address-from-url', gemini map file URLs require enough special
1450 treatment that a separate function is warranted."
1451   (let ((address (url-generic-parse-url url))
1452         (current-address (elpher-page-address elpher-current-page)))
1453     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1454       (setf (url-fullness address) t)
1455       (if (url-host address) ;if there is an explicit host, filenames are absolute
1456           (if (string-empty-p (url-filename address))
1457               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1458         (setf (url-host address) (url-host current-address))
1459         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1460         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1461           (setf (url-filename address)
1462                 (concat (file-name-directory (url-filename current-address))
1463                         (url-filename address)))))
1464       (unless (url-type address)
1465         (setf (url-type address) (url-type current-address)))
1466       (when (equal (url-type address) "gemini")
1467         (setf (url-filename address)
1468               (elpher-collapse-dot-sequences (url-filename address)))))
1469     (elpher-remove-redundant-ports address)))
1470
1471 (defun elpher-gemini-insert-link (link-line)
1472   "Insert link described by LINK-LINE into a text/gemini document."
1473   (let* ((url (elpher-gemini-get-link-url link-line))
1474          (display-string (elpher-gemini-get-link-display-string link-line))
1475          (address (elpher-address-from-gemini-url url))
1476          (type (if address (elpher-address-type address) nil))
1477          (type-map-entry (cdr (assoc type elpher-type-map))))
1478     (when display-string
1479       (insert elpher-gemini-link-string)
1480       (if type-map-entry
1481           (let* ((face (elt type-map-entry 3))
1482                  (filtered-display-string (elpher-color-filter-apply display-string))
1483                  (page (elpher-make-page filtered-display-string address)))
1484             (insert-text-button filtered-display-string
1485                                 'face face
1486                                 'elpher-page page
1487                                 'action #'elpher-click-link
1488                                 'follow-link t
1489                                 'help-echo #'elpher--page-button-help))
1490         (insert (propertize display-string 'face 'elpher-unknown)))
1491       (insert "\n"))))
1492
1493 (defvar elpher--gemini-page-headings nil
1494   "List of headings on the page.")
1495
1496 (defun elpher-gemini-insert-header (header-line)
1497   "Insert header described by HEADER-LINE into a text/gemini document.
1498 The gemini map file line describing the header is given
1499 by HEADER-LINE."
1500   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1501     (let* ((level (length (match-string 1 header-line)))
1502            (header (substring header-line (match-end 0)))
1503            (face (pcase level
1504                    (1 'elpher-gemini-heading1)
1505                    (2 'elpher-gemini-heading2)
1506                    (3 'elpher-gemini-heading3)
1507                    (_ 'default)))
1508            (fill-column (if (display-graphic-p)
1509                             (/ (* fill-column
1510                                   (font-get (font-spec :name (face-font 'default)) :size))
1511                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1512       (setq elpher--gemini-page-headings (cons (cons header (point))
1513                                                elpher--gemini-page-headings))
1514       (unless (display-graphic-p)
1515         (insert (make-string level ?#) " "))
1516       (insert (propertize header 'face face 'rear-nonsticky t))
1517       (newline))))
1518
1519 (defun elpher-gemini-insert-text (text-line)
1520   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1521 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1522 width defined by `elpher-gemini-max-fill-width'."
1523   (string-match
1524    (rx (: line-start
1525           (* (any " \t"))
1526           (optional
1527            (group (or (: "*" (+ (any " \t")))
1528                       (: ">" (* (any " \t"))))))))
1529    text-line)
1530   (let* ((line-prefix (match-string 1 text-line))
1531          (processed-text-line
1532           (if line-prefix
1533               (cond ((string-prefix-p "*" line-prefix)
1534                      (concat
1535                       (replace-regexp-in-string "\\*"
1536                                                 elpher-gemini-bullet-string
1537                                                 (match-string 0 text-line))
1538                       (substring text-line (match-end 0))))
1539                     ((string-prefix-p ">" line-prefix)
1540                      (propertize text-line 'face 'elpher-gemini-quoted))
1541                     (t text-line))
1542             text-line))
1543          (adaptive-fill-mode t)
1544          ;; fill-prefix is important for adaptive-fill-mode: without
1545          ;; it, multi-line list items are not indented correct
1546          (fill-prefix (if (match-string 1 text-line)
1547                           (make-string (length (match-string 0 text-line)) ?\s)
1548                         nil)))
1549     (insert (elpher-process-text-for-display processed-text-line))
1550     (newline)))
1551
1552 (defun elpher-render-gemini-map (data _parameters)
1553   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1554   (elpher-with-clean-buffer
1555    (setq elpher--gemini-page-headings nil)
1556    (let ((preformatted nil))
1557      (auto-fill-mode 1)
1558      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1559      (dolist (line (split-string data "\n"))
1560        (cond
1561         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1562         (preformatted (insert (elpher-process-text-for-display
1563                                (propertize line 'face 'elpher-gemini-preformatted))
1564                               "\n"))
1565         ((string-prefix-p "=>" line)
1566          (elpher-gemini-insert-link line))
1567         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1568         (t (elpher-gemini-insert-text line)))))
1569    (setq elpher--gemini-page-headings (nreverse elpher--gemini-page-headings))
1570    (elpher-cache-content
1571     (elpher-page-address elpher-current-page)
1572     (buffer-string))))
1573
1574 (defun elpher-render-gemini-plain-text (data _parameters)
1575   "Render DATA as plain text file.  PARAMETERS is currently unused."
1576   (elpher-with-clean-buffer
1577    (insert (elpher-process-text-for-display data))
1578    (elpher-cache-content
1579     (elpher-page-address elpher-current-page)
1580     (buffer-string))))
1581
1582
1583 ;; Finger page connection
1584
1585 (defun elpher-get-finger-page (renderer)
1586   "Opens a finger connection to the current page address.
1587 The result is rendered using RENDERER."
1588   (let* ((address (elpher-page-address elpher-current-page))
1589          (content (elpher-get-cached-content address)))
1590     (if (and content (funcall renderer nil))
1591         (elpher-with-clean-buffer
1592          (insert content)
1593          (elpher-restore-pos))
1594       (elpher-with-clean-buffer
1595        (insert "LOADING... (use 'u' to cancel)\n"))
1596       (condition-case the-error
1597           (let* ((kill-buffer-query-functions nil)
1598                  (user (let ((filename (elpher-address-filename address)))
1599                          (if (> (length filename) 1)
1600                              (substring filename 1)
1601                            (elpher-address-user address)))))
1602             (elpher-get-host-response address 79
1603                                       (concat user "\r\n")
1604                                       renderer))
1605         (error
1606          (elpher-network-error address the-error))))))
1607
1608
1609 ;; Telnet page connection
1610
1611 (defun elpher-get-telnet-page (renderer)
1612   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1613   (when renderer
1614     (elpher-visit-previous-page)
1615     (error "Command not supported for telnet URLs"))
1616   (let* ((address (elpher-page-address elpher-current-page))
1617          (host (elpher-address-host address))
1618          (port (elpher-address-port address)))
1619     (elpher-visit-previous-page)
1620     (if (> port 0)
1621         (telnet host port)
1622       (telnet host))))
1623
1624
1625 ;; Other URL page opening
1626
1627 (defun elpher-get-other-url-page (renderer)
1628   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1629   (when renderer
1630     (elpher-visit-previous-page)
1631     (error "Command not supported for general URLs"))
1632   (let* ((address (elpher-page-address elpher-current-page))
1633          (url (elpher-address-to-url address)))
1634     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1635     (message "Opening URL...")
1636     (if elpher-open-urls-with-eww
1637         (browse-web url)
1638       (browse-url url))))
1639
1640 ;; File page
1641
1642 (defun elpher-get-file-page (renderer)
1643   "Getter which renders a local file using RENDERER.
1644 Assumes UTF-8 encoding for all text files."
1645   (let* ((address (elpher-page-address elpher-current-page))
1646          (filename (elpher-address-filename address)))
1647     (unless (file-exists-p filename)
1648       (elpher-visit-previous-page)
1649         (error "File not found"))
1650     (unless (file-readable-p filename)
1651       (elpher-visit-previous-page)
1652         (error "Could not read from file"))
1653     (let ((body (with-temp-buffer
1654        (let ((coding-system-for-read 'binary)
1655              (coding-system-for-write 'binary))
1656          (insert-file-contents-literally filename)
1657          (encode-coding-string (buffer-string) 'raw-text)))))
1658        (if renderer
1659            (funcall renderer body nil)
1660          (pcase (file-name-extension filename)
1661            ((or  "gmi" "gemini")
1662             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1663            ((or "htm" "html")
1664             (elpher-render-html (decode-coding-string body 'utf-8)))
1665            ((or "txt" "")
1666             (elpher-render-text (decode-coding-string body 'utf-8)))
1667            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1668             (elpher-render-image body))
1669            (_
1670             (elpher-render-download body))))
1671        (elpher-restore-pos))))
1672
1673
1674 ;; Welcome page retrieval
1675
1676 (defun elpher-get-welcome-page (renderer)
1677   "Getter which displays the welcome page (RENDERER must be nil)."
1678   (when renderer
1679     (elpher-visit-previous-page)
1680     (error "Command not supported for welcome page"))
1681   (elpher-with-clean-buffer
1682    (insert "     --------------------------------------------\n"
1683            "           Elpher Gopher and Gemini Client       \n"
1684            "                   version " elpher-version "\n"
1685            "     --------------------------------------------\n"
1686            "\n"
1687            "Default bindings:\n"
1688            "\n"
1689            " - TAB/Shift-TAB: next/prev item on current page\n"
1690            " - RET/mouse-1: open item under cursor\n"
1691            " - m: select an item on current page by name (autocompletes)\n"
1692            " - u/mouse-3/U: return to previous page or to the start page\n"
1693            " - g: go to a particular address (gopher, gemini, finger)\n"
1694            " - o/O: open a different address selector or the root menu of the current server\n"
1695            " - d/D: download item under cursor or current page\n"
1696            " - i/I: info on item under cursor or current page\n"
1697            " - c/C: copy URL representation of item under cursor or current page\n"
1698            " - a/A: bookmark the item under cursor or current page\n"
1699            " - B: list all bookmarks\n"
1700            " - s/S: show current history stack or all previously visted pages\n"
1701            " - r: redraw current page (using cached contents if available)\n"
1702            " - R: reload current page (regenerates cache)\n"
1703            " - !: set character coding system for gopher (default is to autodetect)\n"
1704            " - T: toggle TLS gopher mode\n"
1705            " - F: forget/discard current TLS client certificate\n"
1706            " - .: display the raw server response for the current page\n"
1707            "\n"
1708            "Start your exploration of gopher space and gemini:\n")
1709    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1710                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1711    (elpher-insert-index-record "Project Gemini home page"
1712                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1713    (insert "\n"
1714            "Alternatively, select a search engine and enter some search terms:\n")
1715    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1716                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1717    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1718                                (elpher-address-from-url "gemini://geminispace.info/search"))
1719    (insert "\n"
1720            "Your bookmarks are stored in your ")
1721    (let ((help-string "RET,mouse-1: Open bookmark list"))
1722      (insert-text-button "bookmark list"
1723                          'face 'link
1724                          'action (lambda (_)
1725                                    (interactive)
1726                                    (call-interactively #'elpher-show-bookmarks))
1727                          'follow-link t
1728                          'help-echo help-string))
1729    (insert ".\n")
1730    (insert (propertize
1731             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1732             'face 'shadow))
1733    (insert "\n"
1734            "The gopher home of the Elpher project is here:\n")
1735    (elpher-insert-index-record "The Elpher Project Page"
1736                                (elpher-make-gopher-address ?1
1737                                                            "/projects/elpher/"
1738                                                            "thelambdalab.xyz"
1739                                                            70))
1740    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1741      (insert "\n"
1742              "The following info documentation is available:\n"
1743              "   - ")
1744      (insert-text-button "Elpher Manual"
1745                          'face 'link
1746                          'action (lambda (_)
1747                                    (interactive)
1748                                    (info "(elpher)"))
1749                          'follow-link t
1750                          'help-echo help-string)
1751      (insert "\n   - ")
1752      (insert-text-button "Changes introduced by the latest release"
1753                        'face 'link
1754                        'action (lambda (_)
1755                                  (interactive)
1756                                  (info "(elpher)News"))
1757                        'follow-link t
1758                        'help-echo help-string))
1759    (insert "\n")
1760    (insert (propertize
1761             (concat "(These documents should be available if you have installed Elpher \n"
1762                     " using MELPA. Otherwise you may have to install the manual yourself.)\n")
1763             'face 'shadow))
1764    (elpher-restore-pos)))
1765
1766 ;; History page retrieval
1767
1768 (defun elpher-show-history ()
1769   "Show the current contents of elpher's history stack.
1770 Use \\[elpher-show-visited-pages] to see the entire history.
1771 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1772   (interactive)
1773   (elpher-visit-page
1774    (elpher-make-page "Current History Stack"
1775                      (elpher-make-about-address 'history))))
1776
1777 (defun elpher-show-visited-pages ()
1778   "Show the all the pages you've visited using Elpher.
1779 Use \\[elpher-show-history] to see just the current history stack.
1780 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1781   (interactive)
1782   (elpher-visit-page
1783    (elpher-make-page "Elpher Visted Pages"
1784                      (elpher-make-about-address 'visited-pages))))
1785
1786 (defun elpher-get-history-page (renderer)
1787   "Getter which displays the history page (RENDERER must be nil)."
1788   (when renderer
1789     (elpher-visit-previous-page)
1790     (error "Command not supported for history page"))
1791   (elpher-display-history-links elpher-history "Current history stack"))
1792
1793 (defun elpher-get-visited-pages-page (renderer)
1794   "Getter which displays the list of visited pages (RENDERER must be nil)."
1795   (when renderer
1796     (elpher-visit-previous-page)
1797     (error "Command not supported for history page"))
1798   (elpher-display-history-links
1799    (seq-filter (lambda (page)
1800                  (not (elpher-address-about-p (elpher-page-address page))))
1801                elpher-visited-pages)
1802    "All visited pages"))
1803
1804 (defun elpher-display-history-links (pages title)
1805   "Show all PAGES in an Elpher buffer with a given TITLE."
1806   (let* ((title-line (concat " ---- " title " ----"))
1807          (footer-line (make-string (length title-line) ?-)))
1808     (elpher-with-clean-buffer
1809      (insert title-line "\n\n")
1810      (if pages
1811          (dolist (page pages)
1812            (when page
1813              (let ((display-string (elpher-page-display-string page))
1814                    (address (elpher-page-address page)))
1815                (elpher-insert-index-record display-string address))))
1816        (insert "No history items found.\n"))
1817      (insert "\n " footer-line "\n"
1818              "Select an entry or press 'u' to return to the previous page.")
1819      (elpher-restore-pos))))
1820
1821
1822 ;;; Bookmarks
1823
1824 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
1825 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
1826 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
1827 ;; so on. See the Bookmarks section in the Emacs info manual for more.
1828
1829 (defvar elpher-bookmark-link nil
1830   "Prefer bookmarking a link or the current page.
1831 Bind this variable dynamically, or set it to t.
1832 If you set it to t, the commands \\[bookmark-set-no-overwrite]
1833 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
1834
1835 (defun elpher-bookmark-make-record ()
1836   "Return a bookmark record.
1837 If `elpher-bookmark-link' is non-nil and point is on a link button,
1838 return a bookmark record for that link.  Otherwise, return a bookmark
1839 record for the current elpher page."
1840   (let* ((button (and elpher-bookmark-link (button-at (point))))
1841          (page (if button
1842                    (button-get button 'elpher-page)
1843                  elpher-current-page)))
1844     (unless page
1845       (error "Cannot bookmark this link"))
1846     (let* ((address (elpher-page-address page))
1847            (url (elpher-address-to-url address))
1848            (display-string (elpher-page-display-string page))
1849            (pos (if button nil (point))))
1850       (if (elpher-address-about-p address)
1851           (error "Cannot bookmark %s" display-string)
1852         `(,display-string
1853           (defaults . (,display-string))
1854           (position . ,pos)
1855           (location . ,url)
1856           (handler . elpher-bookmark-jump))))))
1857
1858 ;;;###autoload
1859 (defun elpher-bookmark-jump (bookmark)
1860   "Handler used to open a bookmark using elpher.
1861 The argument BOOKMARK is a bookmark record passed to the function.
1862 This handler is responsible for loading the bookmark in some buffer,
1863 then making that buffer the current buffer.  It should not switch
1864 to the buffer."
1865   (let* ((url (cdr (assq 'location bookmark)))
1866          (cleaned-url (string-trim url))
1867          (page (elpher-page-from-url cleaned-url)))
1868     (elpher-with-clean-buffer
1869      (elpher-visit-page page))
1870     (set-buffer (get-buffer elpher-buffer-name))
1871     nil))
1872
1873 (defun elpher-bookmark-link ()
1874   "Bookmark the link at point.
1875 To bookmark the current page, use \\[elpher-bookmark-current]."
1876   (interactive)
1877   (let ((elpher-bookmark-link t))
1878     (bookmark-set-no-overwrite)))
1879
1880 (defun elpher-bookmark-current ()
1881   "Bookmark the current page.
1882 To bookmark the link at point use \\[elpher-bookmark-link]."
1883   (interactive)
1884   (call-interactively #'bookmark-set-no-overwrite))
1885
1886 (defun elpher-bookmark-import (file)
1887   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
1888   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
1889                               (file-readable-p elpher-bookmarks-file))
1890                          elpher-bookmarks-file
1891                        (read-file-name "Old Elpher bookmarks: "
1892                                        user-emacs-directory nil t
1893                                        "elpher-bookmarks"))))
1894   (dolist (bookmark (with-temp-buffer
1895                       (insert-file-contents file)
1896                       (read (current-buffer))))
1897     (let* ((display-string (car bookmark))
1898            (url (cadr bookmark))
1899            (record `(,display-string
1900                      (location . ,url)
1901                      (handler . elpher-bookmark-jump))))
1902       (bookmark-store display-string (cdr record) t)))
1903   (bookmark-save))
1904
1905 (defun elpher-get-bookmarks-page (renderer)
1906   "Getter which displays the bookmarks (RENDERER must be nil)."
1907   (when renderer
1908     (elpher-visit-previous-page)
1909     (error "Command not supported for bookmarks page"))
1910
1911   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
1912                                      elpher-bookmarks-file)
1913                                 (locate-user-emacs-file "elpher-bookmarks"))))
1914     (when (and (file-readable-p old-bookmarks-file)
1915                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
1916                                  old-bookmarks-file
1917                                  "\" found. Import now?")))
1918       (elpher-bookmark-import old-bookmarks-file)
1919       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
1920
1921   (if (and elpher-use-emacs-bookmark-menu
1922            elpher-history)
1923       (progn
1924         (elpher-visit-previous-page)
1925         (call-interactively #'bookmark-bmenu-list))
1926     (elpher-with-clean-buffer
1927      (insert " ---- Elpher Bookmarks ---- \n\n")
1928      (bookmark-maybe-load-default-file)
1929      (dolist (bookmark (bookmark-maybe-sort-alist))
1930        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
1931          (let* ((name (car bookmark))
1932                 (url (alist-get 'location (cdr bookmark)))
1933                 (address (elpher-address-from-url url)))
1934            (elpher-insert-index-record name address))))
1935      (when (<= (line-number-at-pos) 3)
1936        (insert "No bookmarked pages found.\n"))
1937      (insert "\n --------------------------\n\n"
1938              "Select an entry or press 'u' to return to the previous page.\n\n"
1939              "Bookmarks can be renamed or deleted via the ")
1940      (insert-text-button "Emacs bookmark menu"
1941                          'action (lambda (_)
1942                                    (interactive)
1943                                    (call-interactively #'bookmark-bmenu-list))
1944                          'follow-link t
1945                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
1946      (insert (substitute-command-keys
1947               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
1948      (elpher-restore-pos))))
1949
1950 (defun elpher-show-bookmarks ()
1951   "Interactive function to display the current list of elpher bookmarks."
1952   (interactive)
1953   (elpher-visit-page
1954    (elpher-make-page "Elpher Bookmarks"
1955                      (elpher-make-about-address 'bookmarks))))
1956
1957
1958 ;;; Integrations
1959 ;;
1960
1961 ;;; Org
1962
1963 (defun elpher-org-export-link (link description format protocol)
1964   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
1965
1966 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
1967 of gemini, gopher or finger."
1968   (let* ((url (if (equal protocol "elpher")
1969                   (string-remove-prefix "elpher:" link)
1970                 (format "%s:%s" protocol link)))
1971          (desc (or description url)))
1972     (pcase format
1973       (`gemini (format "=> %s %s" url desc))
1974       (`html (format "<a href=\"%s\">%s</a>" url desc))
1975       (`latex (format "\\href{%s}{%s}" url desc))
1976       (_ (if (not description)
1977              url
1978            (format "%s (%s)" desc url))))))
1979
1980 (defun elpher-org-store-link ()
1981   "Store link to an `elpher' page in Org."
1982   (when (eq major-mode 'elpher-mode)
1983     (let* ((url (elpher-info-current))
1984            (desc (car elpher-current-page))
1985            (protocol (cond
1986                       ((string-prefix-p "gemini:" url) "gemini")
1987                       ((string-prefix-p "gopher:" url) "gopher")
1988                       ((string-prefix-p "finger:" url) "finger")
1989                       (t "elpher"))))
1990       (when (equal "elpher" protocol)
1991         ;; Weird link. Or special inner link?
1992         (setq url (concat "elpher:" url)))
1993       (org-link-store-props :type protocol :link url :description desc)
1994       t)))
1995
1996 (defun elpher-org-follow-link (link protocol)
1997   "Visit a LINK for the given PROTOCOL.
1998
1999 PROTOCOL may be one of gemini, gopher or finger.  This method also
2000 supports the old protocol elpher, where the link is self-contained."
2001   (let ((url (if (equal protocol "elpher")
2002                  (string-remove-prefix "elpher:" link)
2003                (format "%s:%s" protocol link))))
2004     (elpher-go url)))
2005
2006 (defun elpher-org-mode-integration ()
2007   "Set up `elpher' integration for `org-mode'."
2008   (org-link-set-parameters
2009    "elpher"
2010    :store #'elpher-org-store-link
2011    :export (lambda (link description format _plist)
2012              (elpher-org-export-link link description format "elpher"))
2013    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2014   (org-link-set-parameters
2015    "gemini"
2016    :export (lambda (link description format _plist)
2017              (elpher-org-export-link link description format "gemini"))
2018    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2019   (org-link-set-parameters
2020    "gopher"
2021    :export (lambda (link description format _plist)
2022              (elpher-org-export-link link description format "gopher"))
2023    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2024   (org-link-set-parameters
2025    "finger"
2026    :export (lambda (link description format _plist)
2027              (elpher-org-export-link link description format "finger"))
2028    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2029
2030 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2031
2032 ;;; Browse URL
2033
2034 ;;;###autoload
2035 (defun elpher-browse-url-elpher (url &rest _args)
2036   "Browse URL using Elpher.  This function is used by `browse-url'."
2037   (interactive (browse-url-interactive-arg "Elpher URL: "))
2038   (elpher-go url))
2039
2040 ;; Use elpher to open gopher, finger and gemini links
2041 ;; For recent version of `browse-url' package
2042 (if (boundp 'browse-url-default-handlers)
2043     (add-to-list
2044      'browse-url-default-handlers
2045      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2046   ;; Patch `browse-url-browser-function' for older ones. The value of
2047   ;; that variable is `browse-url-default-browser' by default, so
2048   ;; that's the function that gets advised.
2049   (advice-add browse-url-browser-function :before-while
2050               (lambda (url &rest _args)
2051                 "Handle gemini, gopher, and finger schemes using Elpher."
2052                 (let ((scheme (downcase (car (split-string url ":" t)))))
2053                   (if (member scheme '("gemini" "gopher" "finger"))
2054                       ;; `elpher-go' always returns nil, which will stop the
2055                       ;; advice chain here in a before-while
2056                       (elpher-go url)
2057                     ;; chain must continue, then return t.
2058                     t)))))
2059
2060 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2061 (with-eval-after-load 'thingatpt
2062   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2063
2064 ;;; Mu4e:
2065
2066 ;; Make mu4e aware of the gemini world
2067 (setq mu4e~view-beginning-of-url-regexp
2068       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2069
2070 ;;; eww:
2071
2072 ;; Let elpher handle gemini, gopher links in eww buffer.
2073 (setq eww-use-browse-url
2074       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2075
2076
2077 ;;; Interactive procedures
2078 ;;
2079
2080 (defun elpher-next-link ()
2081   "Move point to the next link on the current page."
2082   (interactive)
2083   (forward-button 1))
2084
2085 (defun elpher-prev-link ()
2086   "Move point to the previous link on the current page."
2087   (interactive)
2088   (backward-button 1))
2089
2090 (defun elpher-follow-current-link ()
2091   "Open the link or url at point."
2092   (interactive)
2093   (push-button))
2094
2095 ;;;###autoload
2096 (defun elpher-go (host-or-url)
2097   "Go to a particular gopher site HOST-OR-URL.
2098 When run interactively HOST-OR-URL is read from the minibuffer."
2099   (interactive "sGopher or Gemini URL: ")
2100   (let ((trimmed-host-or-url (string-trim host-or-url)))
2101     (unless (string-empty-p trimmed-host-or-url)
2102       (let ((page (elpher-page-from-url trimmed-host-or-url)))
2103         (switch-to-buffer elpher-buffer-name)
2104         (elpher-with-clean-buffer
2105          (elpher-visit-page page))
2106         nil)))) ; non-nil value is displayed by eshell
2107
2108 (defun elpher-go-current ()
2109   "Go to a particular site read from the minibuffer, initialized with the current URL."
2110   (interactive)
2111   (let* ((address (elpher-page-address elpher-current-page))
2112          (url (read-string "Gopher or Gemini URL: "
2113                            (unless (elpher-address-about-p address)
2114                              (elpher-address-to-url address)))))
2115     (unless (string-empty-p (string-trim url))
2116       (elpher-visit-page (elpher-page-from-url url)))))
2117
2118 (defun elpher-redraw ()
2119   "Redraw current page."
2120   (interactive)
2121   (elpher-visit-page elpher-current-page))
2122
2123 (defun elpher-reload ()
2124   "Reload current page."
2125   (interactive)
2126   (elpher-reload-current-page))
2127
2128 (defun elpher-toggle-tls ()
2129   "Toggle TLS encryption mode for gopher."
2130   (interactive)
2131   (setq elpher-use-tls (not elpher-use-tls))
2132   (if elpher-use-tls
2133       (if (gnutls-available-p)
2134           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2135         (setq elpher-use-tls nil)
2136         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2137     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2138
2139 (defun elpher-view-raw ()
2140   "View raw server response for current page."
2141   (interactive)
2142   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2143       (error "This page was not generated by a server")
2144     (elpher-visit-page elpher-current-page
2145                        #'elpher-render-raw)))
2146
2147 (defun elpher-back ()
2148   "Go to previous site."
2149   (interactive)
2150   (elpher-visit-previous-page))
2151
2152 (defun elpher-back-to-start ()
2153   "Go all the way back to the start page."
2154   (interactive)
2155   (setq-local elpher-current-page nil)
2156   (setq-local elpher-history nil)
2157   (elpher-visit-page (elpher-make-start-page)))
2158
2159 (defun elpher-download ()
2160   "Download the link at point."
2161   (interactive)
2162   (let ((button (button-at (point))))
2163     (if button
2164         (let ((page (button-get button 'elpher-page)))
2165           (unless page
2166             (error "Not an elpher page"))
2167           (when (elpher-address-about-p (elpher-page-address page))
2168             (error "Cannot download %s" (elpher-page-display-string page)))
2169           (elpher-visit-page (button-get button 'elpher-page)
2170                              #'elpher-render-download))
2171       (error "No link selected"))))
2172
2173 (defun elpher-download-current ()
2174   "Download the current page."
2175   (interactive)
2176   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2177       (error "Cannot download %s"
2178              (elpher-page-display-string elpher-current-page))
2179     (elpher-visit-page (elpher-make-page
2180                         (elpher-page-display-string elpher-current-page)
2181                         (elpher-page-address elpher-current-page))
2182                        #'elpher-render-download
2183                        t)))
2184
2185 (defun elpher--build-link-map ()
2186   "Build alist mapping link names to destination pages in current buffer."
2187   (let ((link-map nil)
2188         (b (next-button (point-min) t)))
2189     (while b
2190       (push (cons (button-label b) b) link-map)
2191       (setq b (next-button (button-start b))))
2192     link-map))
2193
2194 (defun elpher-jump ()
2195   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2196   (interactive)
2197   (let* ((link-map (elpher--build-link-map)))
2198     (if link-map
2199         (let ((key (let ((completion-ignore-case t))
2200                      (completing-read "Directory item/link: "
2201                                       link-map nil t))))
2202           (if (and key (> (length key) 0))
2203               (let ((b (cdr (assoc key link-map))))
2204                 (goto-char (button-start b))
2205                 (button-activate b)))))))
2206
2207 (defun elpher-root-dir ()
2208   "Visit root of current server."
2209   (interactive)
2210   (let ((address (elpher-page-address elpher-current-page)))
2211     (if (not (elpher-address-about-p address))
2212         (if (or (member (url-filename address) '("/" ""))
2213                 (and (elpher-address-gopher-p address)
2214                      (= (length (elpher-gopher-address-selector address)) 0)))
2215             (error "Already at root directory of current server")
2216           (let ((address-copy (elpher-address-from-url
2217                                (elpher-address-to-url address))))
2218             (setf (url-filename address-copy) "")
2219             (elpher-go (elpher-address-to-url address-copy))))
2220       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2221
2222 (defun elpher-info-page (page)
2223   "Display URL of PAGE in minibuffer."
2224   (let ((address (elpher-page-address page)))
2225     (message "%s" (elpher-address-to-url address))))
2226
2227 (defun elpher-info-link ()
2228   "Display information on page corresponding to link at point."
2229   (interactive)
2230   (let ((button (button-at (point))))
2231     (unless button
2232       (error "No item selected"))
2233     (let ((page (button-get button 'elpher-page)))
2234       (unless page
2235         (error "Not an elpher page"))
2236       (elpher-info-page page))))
2237
2238 (defun elpher-info-current ()
2239   "Display information on current page."
2240   (interactive)
2241   (elpher-info-page elpher-current-page))
2242
2243 (defun elpher-copy-page-url (page)
2244   "Copy URL representation of address of PAGE to `kill-ring'."
2245   (let* ((address (elpher-page-address page))
2246          (url (elpher-address-to-url address)))
2247     (message "Copied \"%s\" to kill-ring/clipboard." url)
2248     (kill-new url)))
2249
2250 (defun elpher-copy-link-url ()
2251   "Copy URL of item at point to `kill-ring'."
2252   (interactive)
2253   (let ((button (button-at (point))))
2254     (unless button
2255       (error "No item selected"))
2256     (let ((page (button-get button 'elpher-page)))
2257       (unless page
2258         (error "Not an elpher page"))
2259       (elpher-copy-page-url page))))
2260
2261 (defun elpher-copy-current-url ()
2262   "Copy URL of current page to `kill-ring'."
2263   (interactive)
2264   (elpher-copy-page-url elpher-current-page))
2265
2266 (defun elpher-set-gopher-coding-system ()
2267   "Specify an explicit character coding system for gopher selectors."
2268   (interactive)
2269   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2270     (setq elpher-user-coding-system system)
2271     (if system
2272         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2273       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2274
2275
2276 ;;; Mode and keymap
2277 ;;
2278
2279 (defvar elpher-mode-map
2280   (let ((map (make-sparse-keymap)))
2281     (define-key map (kbd "TAB") 'elpher-next-link)
2282     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2283     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2284     (define-key map (kbd "u") 'elpher-back)
2285     (define-key map (kbd "-") 'elpher-back)
2286     (define-key map (kbd "^") 'elpher-back)
2287     (define-key map [mouse-3] 'elpher-back)
2288     (define-key map (kbd "U") 'elpher-back-to-start)
2289     (define-key map (kbd "g") 'elpher-go)
2290     (define-key map (kbd "o") 'elpher-go-current)
2291     (define-key map (kbd "O") 'elpher-root-dir)
2292     (define-key map (kbd "s") 'elpher-show-history)
2293     (define-key map (kbd "S") 'elpher-show-visited-pages)
2294     (define-key map (kbd "r") 'elpher-redraw)
2295     (define-key map (kbd "R") 'elpher-reload)
2296     (define-key map (kbd "T") 'elpher-toggle-tls)
2297     (define-key map (kbd ".") 'elpher-view-raw)
2298     (define-key map (kbd "d") 'elpher-download)
2299     (define-key map (kbd "D") 'elpher-download-current)
2300     (define-key map (kbd "m") 'elpher-jump)
2301     (define-key map (kbd "i") 'elpher-info-link)
2302     (define-key map (kbd "I") 'elpher-info-current)
2303     (define-key map (kbd "c") 'elpher-copy-link-url)
2304     (define-key map (kbd "C") 'elpher-copy-current-url)
2305     (define-key map (kbd "a") 'elpher-bookmark-link)
2306     (define-key map (kbd "A") 'elpher-bookmark-current)
2307     (define-key map (kbd "B") 'elpher-show-bookmarks)
2308     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2309     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2310     (when (fboundp 'evil-define-key*)
2311       (evil-define-key*
2312        'motion map
2313        (kbd "TAB") 'elpher-next-link
2314        (kbd "C-") 'elpher-follow-current-link
2315        (kbd "C-t") 'elpher-back
2316        (kbd "u") 'elpher-back
2317        (kbd "-") 'elpher-back
2318        (kbd "^") 'elpher-back
2319        [mouse-3] 'elpher-back
2320        (kbd "U") 'elpher-back-to-start
2321        (kbd "g") 'elpher-go
2322        (kbd "o") 'elpher-go-current
2323        (kbd "O") 'elpher-root-dir
2324        (kbd "s") 'elpher-show-history
2325        (kbd "S") 'elpher-show-visited-pages
2326        (kbd "r") 'elpher-redraw
2327        (kbd "R") 'elpher-reload
2328        (kbd "T") 'elpher-toggle-tls
2329        (kbd ".") 'elpher-view-raw
2330        (kbd "d") 'elpher-download
2331        (kbd "D") 'elpher-download-current
2332        (kbd "m") 'elpher-jump
2333        (kbd "i") 'elpher-info-link
2334        (kbd "I") 'elpher-info-current
2335        (kbd "c") 'elpher-copy-link-url
2336        (kbd "C") 'elpher-copy-current-url
2337        (kbd "a") 'elpher-bookmark-link
2338        (kbd "A") 'elpher-bookmark-current
2339        (kbd "B") 'elpher-show-bookmarks
2340        (kbd "!") 'elpher-set-gopher-coding-system
2341        (kbd "F") 'elpher-forget-current-certificate))
2342     map)
2343   "Keymap for gopher client.")
2344
2345 (define-derived-mode elpher-mode special-mode "elpher"
2346   "Major mode for elpher, an elisp gopher client.
2347
2348 This mode is automatically enabled by the interactive
2349 functions which initialize the client, namely
2350 `elpher', and `elpher-go'."
2351   (setq-local elpher--gemini-page-headings nil)
2352   (setq-local elpher-current-page nil)
2353   (setq-local elpher-history nil)
2354   (setq-local elpher-buffer-name (buffer-name))
2355   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2356   (setq-local imenu-create-index-function (lambda () elpher--gemini-page-headings))
2357   (setq-local xterm-color-preserve-properties t))
2358
2359 (when (fboundp 'evil-set-initial-state)
2360   (evil-set-initial-state 'elpher-mode 'motion))
2361
2362
2363 ;;; Main start procedure
2364 ;;
2365
2366 ;;;###autoload
2367 (defun elpher (&optional arg)
2368   "Start elpher with default landing page.
2369 The buffer used for Elpher sessions is determined by the value of
2370 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2371 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2372 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2373 \\[execute-extended-command] elpher RET’) switches to the session with
2374 that number, creating it if necessary.  A non numeric prefix ARG means
2375 to create a new session.  Returns the buffer selected (or created)."
2376   (interactive "P")
2377   (let* ((name (default-value 'elpher-buffer-name))
2378          (buf (cond ((numberp arg)
2379                      (get-buffer-create (format "%s<%d>" name arg)))
2380                     (arg
2381                      (generate-new-buffer name))
2382                     (t
2383                      (get-buffer-create name)))))
2384     (pop-to-buffer-same-window buf)
2385     (unless (buffer-modified-p)
2386       (elpher-mode)
2387       (elpher-visit-page (elpher-make-start-page))
2388       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2389
2390 ;;; elpher.el ends here