elpher.el

   1 ;;; elpher.el --- A friendly gopher client.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.0.2
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption,
  40 ;; - basic support for the fledgling Gemini protocol.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Full instructions can be found in the Elpher info manual.
  47
  48 ;; Elpher is under active development.  Any suggestions for
  49 ;; improvements are welcome!
  50
  51 ;;; Code:
  52
  53 (provide 'elpher)
  54
  55 ;;; Dependencies
  56 ;;
  57
  58 (require 'seq)
  59 (require 'pp)
  60 (require 'shr)
  61 (require 'url-util)
  62 (require 'subr-x)
  63
  64
  65 ;;; Global constants
  66 ;;
  67
  68 (defconst elpher-version "2.0.2"
  69   "Current version of elpher.")
  70
  71 (defconst elpher-margin-width 6
  72   "Width of left-hand margin used when rendering indicies.")
  73
  74 (defconst elpher-type-map
  75   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  76     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  77     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  78     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  79     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  80     ((gopher ?9) elpher-get-gopher-node elpher-render-node-download "bin" elpher-binary)
  81     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  83     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  84     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  85     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  86     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  87     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  88     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  89     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  90     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  91     ((special bookmarks) elpher-get-bookmarks-node nil)
  92     ((special start) elpher-get-start-node nil))
  93   "Association list from types to getters, renderers, margin codes and index faces.")
  94
  95
  96 ;;; Customization group
  97 ;;
  98
  99 (defgroup elpher nil
 100   "A gopher client."
 101   :group 'applications)
 102
 103 ;; Face customizations
 104
 105 (defface elpher-index
 106   '((t :inherit font-lock-keyword-face))
 107   "Face used for directory type directory records.")
 108
 109 (defface elpher-text
 110   '((t :inherit bold))
 111   "Face used for text type directory records.")
 112
 113 (defface elpher-info
 114   '((t :inherit default))
 115   "Face used for info type directory records.")
 116
 117 (defface elpher-image
 118   '((t :inherit font-lock-string-face))
 119   "Face used for image type directory records.")
 120
 121 (defface elpher-search
 122   '((t :inherit warning))
 123   "Face used for search type directory records.")
 124
 125 (defface elpher-html
 126   '((t :inherit font-lock-comment-face))
 127   "Face used for html type directory records.")
 128
 129 (defface elpher-gemini
 130   '((t :inherit font-lock-regexp-grouping-backslash))
 131   "Face used for html type directory records.")
 132
 133 (defface elpher-other-url
 134   '((t :inherit font-lock-comment-face))
 135   "Face used for other URL type links records.")
 136
 137 (defface elpher-telnet
 138   '((t :inherit font-lock-function-name-face))
 139   "Face used for telnet type directory records.")
 140
 141 (defface elpher-binary
 142   '((t :inherit font-lock-doc-face))
 143   "Face used for binary type directory records.")
 144
 145 (defface elpher-unknown
 146   '((t :inherit error))
 147   "Face used for directory records with unknown/unsupported types.")
 148
 149 (defface elpher-margin-key
 150   '((t :inherit bold))
 151   "Face used for directory margin key.")
 152
 153 (defface elpher-margin-brackets
 154   '((t :inherit shadow))
 155   "Face used for brackets around directory margin key.")
 156
 157 ;; Other customizations
 158
 159 (defcustom elpher-open-urls-with-eww nil
 160   "If non-nil, open URL selectors using eww.
 161 Otherwise, use the system browser via the BROWSE-URL function."
 162   :type '(boolean))
 163
 164 (defcustom elpher-buttonify-urls-in-directories nil
 165   "If non-nil, turns URLs matched in directories into clickable buttons."
 166   :type '(boolean))
 167
 168 (defcustom elpher-use-header t
 169   "If non-nil, display current node information in buffer header."
 170   :type '(boolean))
 171
 172 (defcustom elpher-auto-disengage-TLS nil
 173   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 174 While enabling this may seem convenient, it is also potentially dangerous as it
 175 allows switching from an encrypted channel back to plain text without user input."
 176   :type '(boolean))
 177
 178
 179 ;;; Model
 180 ;;
 181
 182 ;; Address
 183
 184 ;; An elpher "address" object is either a url object or a symbol.
 185 ;; Symbol addresses are "special", corresponding to pages generated
 186 ;; dynamically for and by elpher.  All others represent pages which
 187 ;; rely on content retrieved over the network.
 188
 189 (defun elpher-address-from-url (url-string)
 190   "Create a ADDRESS object corresponding to the given URL-STRING."
 191   (let ((data (match-data))) ; Prevent parsing clobbering match data
 192     (unwind-protect
 193         (let ((url (url-generic-parse-url url-string)))
 194           (setf (url-fullness url) t)
 195           (setf (url-filename url)
 196                 (url-unhex-string (url-filename url)))
 197           (unless (url-type url)
 198             (setf (url-type url) "gopher"))
 199           (when (or (equal "gopher" (url-type url))
 200                     (equal "gophers" (url-type url)))
 201               ;; Gopher defaults
 202               (unless (url-host url)
 203                 (setf (url-host url) (url-filename url))
 204                 (setf (url-filename url) ""))
 205               (when (or (equal (url-filename url) "")
 206                         (equal (url-filename url) "/"))
 207                 (setf (url-filename url) "/1")))
 208           url)
 209       (set-match-data data))))
 210
 211 (defun elpher-make-gopher-address (type selector host port &optional tls)
 212   "Create an ADDRESS object using gopher directory record attributes.
 213 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 214 If the optional attribute TLS is non-nil, the address will be marked as
 215 requiring gopher-over-TLS."
 216   (cond
 217    ((and (equal type ?h)
 218          (string-prefix-p "URL:" selector))
 219     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 220    ((equal type ?8)
 221     (elpher-address-from-url
 222      (concat "telnet"
 223              "://" host
 224              ":" (number-to-string port))))
 225    (t
 226     (elpher-address-from-url
 227      (concat "gopher" (if tls "s" "")
 228              "://" host
 229              ":" (number-to-string port)
 230              "/" (string type)
 231              selector)))))
 232
 233 (defun elpher-make-special-address (type)
 234   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 235   type)
 236
 237 (defun elpher-address-to-url (address)
 238   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 239   (if (not (elpher-address-special-p address))
 240       (url-encode-url (url-recreate-url address))
 241     nil))
 242
 243 (defun elpher-address-type (address)
 244   "Retrieve type of ADDRESS object.
 245 This is used to determine how to retrieve and render the document the
 246 address refers to, via the table `elpher-type-map'."
 247   (if (symbolp address)
 248       (list 'special address)
 249     (let ((protocol (url-type address)))
 250       (cond ((or (equal protocol "gopher")
 251                  (equal protocol "gophers"))
 252              (list 'gopher
 253                    (if (member (url-filename address) '("" "/"))
 254                        ?1
 255                      (string-to-char (substring (url-filename address) 1)))))
 256             ((equal protocol "gemini")
 257              'gemini)
 258             ((equal protocol "telnet")
 259              'telnet)
 260             (t 'other-url)))))
 261
 262 (defun elpher-address-protocol (address)
 263   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 264   (if (symbolp address)
 265       nil
 266     (url-type address)))
 267
 268 (defun elpher-address-filename (address)
 269   "Retrieve the filename component of ADDRESS.
 270 For gopher addresses this is a combination of the selector type and selector."
 271   (if (symbolp address)
 272       nil
 273     (url-filename address)))
 274
 275 (defun elpher-address-host (address)
 276   "Retrieve host from ADDRESS object."
 277   (url-host address))
 278
 279 (defun elpher-address-port (address)
 280   "Retrieve port from ADDRESS object."
 281   (url-port address))
 282
 283 (defun elpher-address-special-p (address)
 284   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 285   (symbolp address))
 286
 287 (defun elpher-address-gopher-p (address)
 288   "Return non-nill if ADDRESS object is a gopher address."
 289   (and (not (elpher-address-special-p address))
 290        (member (elpher-address-protocol address) '("gopher gophers"))))
 291
 292 (defun elpher-gopher-address-selector (address)
 293   "Retrieve gopher selector from ADDRESS object."
 294   (if (member (url-filename address) '("" "/"))
 295       ""
 296     (substring (url-filename address) 2)))
 297
 298 ;; Node
 299
 300 (defun elpher-make-node (display-string address &optional parent)
 301   "Create a node in the page hierarchy.
 302
 303 DISPLAY-STRING records the display string used for the page.
 304
 305 ADDRESS specifies the address object of the page.
 306
 307 The optional PARENT specifies the parent node in the hierarchy.
 308 This is set every time the node is visited, so while it forms
 309 an important part of the node data there is no need to set it
 310 initially."
 311   (list display-string address parent))
 312
 313 (defun elpher-node-display-string (node)
 314   "Retrieve the display string of NODE."
 315   (elt node 0))
 316
 317 (defun elpher-node-address (node)
 318   "Retrieve the ADDRESS object of NODE."
 319   (elt node 1))
 320
 321 (defun elpher-node-parent (node)
 322   "Retrieve the parent node of NODE."
 323   (elt node 2))
 324
 325 (defun elpher-set-node-parent (node parent)
 326   "Set the parent node of NODE to be PARENT."
 327   (setcar (cdr (cdr node)) parent))
 328
 329 ;; Cache
 330
 331 (defvar elpher-content-cache (make-hash-table :test 'equal))
 332 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 333
 334 (defun elpher-get-cached-content (address)
 335   "Retrieve the cached content for ADDRESS, or nil if none exists."
 336   (gethash address elpher-content-cache))
 337
 338 (defun elpher-cache-content (address content)
 339   "Set the content cache for ADDRESS to CONTENT."
 340   (puthash address content elpher-content-cache))
 341
 342 (defun elpher-get-cached-pos (address)
 343   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 344   (gethash address elpher-pos-cache))
 345
 346 (defun elpher-cache-pos (address pos)
 347   "Set the cursor position cache for ADDRESS to POS."
 348   (puthash address pos elpher-pos-cache))
 349
 350 ;; Node graph traversal
 351
 352 (defvar elpher-current-node nil)
 353
 354 (defun elpher-visit-node (node &optional renderer preserve-parent)
 355   "Visit NODE using its own renderer or RENDERER, if non-nil.
 356 Additionally, set the parent of NODE to `elpher-current-node',
 357 unless PRESERVE-PARENT is non-nil."
 358   (elpher-save-pos)
 359   (elpher-process-cleanup)
 360   (unless preserve-parent
 361     (if (and (elpher-node-parent elpher-current-node)
 362              (equal (elpher-node-address elpher-current-node)
 363                     (elpher-node-address node)))
 364         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 365       (elpher-set-node-parent node elpher-current-node)))
 366   (setq elpher-current-node node)
 367   (let* ((address (elpher-node-address node))
 368          (type (elpher-address-type address))
 369          (type-record (cdr (assoc type elpher-type-map))))
 370     (if type-record
 371         (funcall (car type-record)
 372                  (if renderer
 373                      renderer
 374                    (cadr type-record)))
 375       (elpher-visit-parent-node)
 376       (pcase type
 377         (`(gopher ,type-char)
 378          (error "Unsupported gopher selector type '%c' for '%s'"
 379                 type-char (elpher-address-to-url address)))
 380         (other
 381          (error "Unsupported address type '%S' for '%s'"
 382                 other (elpher-address-to-url address)))))))
 383
 384 (defun elpher-visit-parent-node ()
 385   "Visit the parent of the current node."
 386   (let ((parent-node (elpher-node-parent elpher-current-node)))
 387     (when parent-node
 388       (elpher-visit-node parent-node nil t))))
 389
 390 (defun elpher-reload-current-node ()
 391   "Reload the current node, discarding any existing cached content."
 392   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 393   (elpher-visit-node elpher-current-node))
 394
 395 (defun elpher-save-pos ()
 396   "Save the current position of point to the current node."
 397   (when elpher-current-node
 398     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 399
 400 (defun elpher-restore-pos ()
 401   "Restore the position of point to that cached in the current node."
 402   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 403     (if pos
 404         (goto-char pos)
 405       (goto-char (point-min)))))
 406
 407
 408 ;;; Buffer preparation
 409 ;;
 410
 411 (defun elpher-update-header ()
 412   "If `elpher-use-header' is true, display current node info in window header."
 413   (if elpher-use-header
 414       (setq header-line-format (elpher-node-display-string elpher-current-node))))
 415
 416 (defmacro elpher-with-clean-buffer (&rest args)
 417   "Evaluate ARGS with a clean *elpher* buffer as current."
 418   (list 'with-current-buffer "*elpher*"
 419         '(elpher-mode)
 420         (append (list 'let '((inhibit-read-only t))
 421                       '(erase-buffer)
 422                       '(elpher-update-header))
 423                 args)))
 424
 425
 426 ;;; Text Processing
 427 ;;
 428
 429 (defvar elpher-user-coding-system nil
 430   "User-specified coding system to use for decoding text responses.")
 431
 432 (defun elpher-decode (string)
 433   "Decode STRING using autodetected or user-specified coding system."
 434   (decode-coding-string string
 435                         (if elpher-user-coding-system
 436                             elpher-user-coding-system
 437                           (detect-coding-string string t))))
 438
 439 (defun elpher-preprocess-text-response (string)
 440   "Preprocess text selector response contained in STRING.
 441 This involes decoding the character representation, and clearing
 442 away CRs and any terminating period."
 443   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 444                                            (replace-regexp-in-string "\r" "" string))))
 445
 446
 447 ;;; Network error reporting
 448 ;;
 449
 450 (defun elpher-network-error (address error)
 451   "Display ERROR message following unsuccessful negotiation with ADDRESS."
 452   (elpher-with-clean-buffer
 453    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 454            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 455            (error-message-string error) ".\n"
 456            (propertize "\n----------------\n\n" 'face 'error)
 457            "Press 'u' to return to the previous page.")))
 458
 459
 460 ;;; Gopher selector retrieval
 461 ;;
 462
 463 (defun elpher-process-cleanup ()
 464   "Immediately shut down any extant elpher process."
 465   (let ((p (get-process "elpher-process")))
 466     (if p (delete-process p))))
 467
 468 (defvar elpher-use-tls nil
 469   "If non-nil, use TLS to communicate with gopher servers.")
 470
 471 (defvar elpher-selector-string)
 472
 473 (defun elpher-get-selector (address after &optional propagate-error)
 474   "Retrieve selector specified by ADDRESS, then execute AFTER.
 475 The result is stored as a string in the variable ‘elpher-selector-string’.
 476
 477 Usually errors result in an error page being displayed.  This is only
 478 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 479 is non-nil, this message is not displayed.  Instead, the error propagates
 480 up to the calling function."
 481   (setq elpher-selector-string "")
 482   (when (equal (elpher-address-protocol address) "gophers")
 483       (if (gnutls-available-p)
 484           (when (not elpher-use-tls)
 485             (setq elpher-use-tls t)
 486             (message "Engaging TLS gopher mode."))
 487         (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 488   (condition-case the-error
 489       (let* ((kill-buffer-query-functions nil)
 490              (proc (open-network-stream "elpher-process"
 491                                        nil
 492                                        (elpher-address-host address)
 493                                        (if (> (elpher-address-port address) 0)
 494                                            (elpher-address-port address)
 495                                          70)
 496                                        :type (if elpher-use-tls 'tls 'plain))))
 497         (set-process-coding-system proc 'binary)
 498         (set-process-filter proc
 499                             (lambda (_proc string)
 500                               (setq elpher-selector-string
 501                                     (concat elpher-selector-string string))))
 502         (set-process-sentinel proc after)
 503         (process-send-string proc
 504                              (concat (elpher-gopher-address-selector address) "\n")))
 505     (error
 506      (if (and (consp the-error)
 507               (eq (car the-error) 'gnutls-error)
 508               (not (equal (elpher-address-protocol address) "gophers"))
 509               (or elpher-auto-disengage-TLS
 510                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 511          (progn
 512            (message "Disengaging TLS gopher mode.")
 513            (setq elpher-use-tls nil)
 514            (elpher-get-selector address after))
 515        (elpher-process-cleanup)
 516        (if propagate-error
 517            (error the-error)
 518          (elpher-with-clean-buffer
 519           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 520                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 521                   (propertize "\n----------------\n\n" 'face 'error)
 522                   "Press 'u' to return to the previous page.")))))))
 523
 524 (defun elpher-get-gopher-node (renderer)
 525   "Getter function for gopher nodes.
 526 The RENDERER procedure is used to display the contents of the node
 527 once they are retrieved from the gopher server."
 528   (let* ((address (elpher-node-address elpher-current-node))
 529          (content (elpher-get-cached-content address)))
 530     (if (and content (funcall renderer nil))
 531         (elpher-with-clean-buffer
 532          (insert content)
 533          (elpher-restore-pos))
 534       (elpher-with-clean-buffer
 535        (insert "LOADING... (use 'u' to cancel)"))
 536       (elpher-get-selector address
 537                            (lambda (_proc event)
 538                              (unless (string-prefix-p "deleted" event)
 539                                (funcall renderer elpher-selector-string)
 540                                (elpher-restore-pos)))))))
 541
 542 ;; Index rendering
 543
 544 (defun elpher-insert-index (string)
 545   "Insert the index corresponding to STRING into the current buffer."
 546   ;; Should be able to split directly on CRLF, but some non-conformant
 547   ;; LF-only servers sadly exist, hence the following.
 548   (let ((str-processed (elpher-preprocess-text-response string)))
 549     (dolist (line (split-string str-processed "\n"))
 550       (ignore-errors
 551         (unless (= (length line) 0)
 552           (let* ((type (elt line 0))
 553                  (fields (split-string (substring line 1) "\t"))
 554                  (display-string (elt fields 0))
 555                  (selector (elt fields 1))
 556                  (host (elt fields 2))
 557                  (port (if (elt fields 3)
 558                            (string-to-number (elt fields 3))
 559                          nil))
 560                  (address (elpher-make-gopher-address type selector host port)))
 561             (elpher-insert-index-record display-string address)))))))
 562
 563 (defun elpher-insert-margin (&optional type-name)
 564   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 565   (if type-name
 566       (progn
 567         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 568                         (concat
 569                          (propertize "[" 'face 'elpher-margin-brackets)
 570                          (propertize type-name 'face 'elpher-margin-key)
 571                          (propertize "]" 'face 'elpher-margin-brackets))))
 572         (insert " "))
 573     (insert (make-string elpher-margin-width ?\s))))
 574
 575 (defun elpher-node-button-help (node)
 576   "Return a string containing the help text for a button corresponding to NODE."
 577   (let ((address (elpher-node-address node)))
 578     (format "mouse-1, RET: open '%s'" (elpher-address-to-url address))))
 579
 580 (defun elpher-insert-index-record (display-string &optional address)
 581   "Function to insert an index record into the current buffer.
 582 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 583 If ADDRESS is not supplied or nil the record is rendered as an
 584 'information' line."
 585   (let* ((type (if address (elpher-address-type address) nil))
 586          (type-map-entry (cdr (assoc type elpher-type-map))))
 587     (if type-map-entry
 588         (let* ((margin-code (elt type-map-entry 2))
 589                (face (elt type-map-entry 3))
 590                (node (elpher-make-node display-string address)))
 591           (elpher-insert-margin margin-code)
 592           (insert-text-button display-string
 593                               'face face
 594                               'elpher-node node
 595                               'action #'elpher-click-link
 596                               'follow-link t
 597                               'help-echo (elpher-node-button-help node)))
 598       (pcase type
 599         ((or '(gopher ?i) 'nil) ;; Information
 600          (elpher-insert-margin)
 601          (insert (propertize
 602                   (if elpher-buttonify-urls-in-directories
 603                       (elpher-buttonify-urls display-string)
 604                     display-string)
 605                   'face 'elpher-info)))
 606         (`(gopher ,selector-type) ;; Unknown
 607          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 608          (insert (propertize display-string
 609                              'face 'elpher-unknown)))))
 610     (insert "\n")))
 611
 612 (defun elpher-click-link (button)
 613   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 614   (let ((node (button-get button 'elpher-node)))
 615     (elpher-visit-node node)))
 616
 617 (defun elpher-render-index (data &optional _mime-type-string)
 618   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 619   (elpher-with-clean-buffer
 620    (if (not data)
 621        t
 622      (elpher-insert-index data)
 623      (elpher-cache-content (elpher-node-address elpher-current-node)
 624                            (buffer-string)))))
 625
 626 ;; Text rendering
 627
 628 (defconst elpher-url-regex
 629   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]+\\|\[[a-zA-Z0-9:]+\]\\)\\(?3::[0-9]+\\)?\\(?4:/[^<> \r\n\t(),]*\\)?"
 630   "Regexp used to locate and buttniofy URLs in text files loaded by elpher.")
 631
 632 (defun elpher-buttonify-urls (string)
 633   "Turn substrings which look like urls in STRING into clickable buttons."
 634   (with-temp-buffer
 635     (insert string)
 636     (goto-char (point-min))
 637     (while (re-search-forward elpher-url-regex nil t)
 638       (let ((node (elpher-make-node (match-string 0)
 639                                     (elpher-address-from-url (match-string 0)))))
 640           (make-text-button (match-beginning 0)
 641                             (match-end 0)
 642                             'elpher-node  node
 643                             'action #'elpher-click-link
 644                             'follow-link t
 645                             'help-echo (elpher-node-button-help node))))
 646     (buffer-string)))
 647
 648 (defun elpher-render-text (data &optional _mime-type-string)
 649   "Render DATA as text.  MIME-TYPE-STRING is unused."
 650   (elpher-with-clean-buffer
 651    (if (not data)
 652        t
 653      (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 654      (elpher-cache-content
 655       (elpher-node-address elpher-current-node)
 656       (buffer-string)))))
 657
 658 ;; Image retrieval
 659
 660 (defun elpher-render-image (data &optional _mime-type-string)
 661   "Display DATA as image.  MIME-TYPE-STRING is unused."
 662   (if (not data)
 663       nil
 664     (if (display-images-p)
 665         (progn
 666           (let ((image (create-image
 667                         data
 668                         nil t)))
 669             (elpher-with-clean-buffer
 670              (insert-image image)
 671              (elpher-restore-pos))))
 672       (elpher-render-download data))))
 673
 674 ;; Search retrieval and rendering
 675
 676 (defun elpher-get-gopher-query-node (renderer)
 677   "Getter for gopher addresses requiring input.
 678 The response is rendered using the rendering function RENDERER."
 679    (let* ((address (elpher-node-address elpher-current-node))
 680           (content (elpher-get-cached-content address))
 681           (aborted t))
 682     (if (and content (funcall renderer nil))
 683         (elpher-with-clean-buffer
 684          (insert content)
 685          (elpher-restore-pos)
 686          (message "Displaying cached search results.  Reload to perform a new search."))
 687       (unwind-protect
 688           (let* ((query-string (read-string "Query: "))
 689                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 690                  (search-address (elpher-make-gopher-address ?1
 691                                                              query-selector
 692                                                              (elpher-address-host address)
 693                                                              (elpher-address-port address)
 694                                                              (equal (elpher-address-type address) "gophers"))))
 695             (setq aborted nil)
 696
 697             (elpher-with-clean-buffer
 698              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 699             (elpher-get-selector search-address
 700                                  (lambda (_proc event)
 701                                    (unless (string-prefix-p "deleted" event)
 702                                      (funcall renderer elpher-selector-string)
 703                                      (elpher-restore-pos)))))
 704         (if aborted
 705             (elpher-visit-parent-node))))))
 706
 707 ;; Raw server response rendering
 708
 709 (defun elpher-render-raw (data &optional _mime-type-string)
 710   "Display raw DATA in buffer.  MIME-TYPE-STRING is unused."
 711   (if (not data)
 712       nil
 713     (elpher-with-clean-buffer
 714      (insert data)
 715      (goto-char (point-min)))
 716     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 717
 718 ;; File save "rendering"
 719
 720 (defun elpher-render-download (data &optional _mime-type-string)
 721   "Save DATA to file.  MIME-TYPE-STRING is unused."
 722   (if (not data)
 723       nil
 724     (let* ((address (elpher-node-address elpher-current-node))
 725            (selector (elpher-gopher-address-selector address)))
 726       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 727       (let* ((filename-proposal (file-name-nondirectory selector))
 728              (filename (read-file-name "Download complete. Save file as: "
 729                                        nil nil nil
 730                                        (if (> (length filename-proposal) 0)
 731                                            filename-proposal
 732                                          "download.file"))))
 733         (let ((coding-system-for-write 'binary))
 734           (with-temp-file filename
 735             (insert data)))
 736         (message (format "Saved to file %s." filename))))))
 737
 738 ;; HTML rendering
 739
 740 (defun elpher-render-html (data &optional _mime-type-string)
 741   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 742   (elpher-with-clean-buffer
 743    (if (not data)
 744        t
 745      (let ((dom (with-temp-buffer
 746                   (insert data)
 747                   (libxml-parse-html-region (point-min) (point-max)))))
 748        (shr-insert-document dom)))))
 749
 750 ;; Gemini node retrieval
 751
 752 (defvar elpher-gemini-response)
 753
 754 (defun elpher-get-gemini-response (address after)
 755   "Retrieve gemini ADDRESS, then execute AFTER.
 756 The response is stored in the variable ‘elpher-gemini-response’."
 757   (setq elpher-gemini-response "")
 758   (if (not (gnutls-available-p))
 759       (error "Cannot retrieve TLS selector: GnuTLS not available")
 760     (let* ((kill-buffer-query-functions nil)
 761            (proc (open-network-stream "elpher-process"
 762                                       nil
 763                                       (elpher-address-host address)
 764                                       (if (> (elpher-address-port address) 0)
 765                                           (elpher-address-port address)
 766                                         1965)
 767                                       :type 'tls)))
 768       (set-process-coding-system proc 'binary)
 769       (set-process-filter proc
 770                           (lambda (_proc string)
 771                             (setq elpher-gemini-response
 772                                   (concat elpher-gemini-response string))))
 773       (set-process-sentinel proc after)
 774       (process-send-string proc
 775                            (concat (elpher-address-to-url address) "\r\n")))))
 776
 777
 778 (defun elpher-process-gemini-response (renderer)
 779   "Process the gemini response and pass the result to RENDERER.
 780 The response is assumed to be in the variable `elpher-gemini-response'."
 781   (condition-case the-error
 782       (let* ((response-header (car (split-string elpher-gemini-response "\r\n")))
 783              (response-body (substring elpher-gemini-response
 784                                        (+ (string-match "\r\n" elpher-gemini-response) 2)))
 785              (response-code (car (split-string response-header)))
 786              (response-meta (string-trim
 787                              (substring response-header
 788                                         (string-match "[ \t]+" response-header)))))
 789         (pcase (elt response-code 0)
 790           (?1 ; Input required
 791            (elpher-with-clean-buffer
 792             (insert "Gemini server is requesting input."))
 793            (let* ((query-string (read-string (concat response-meta ": ")))
 794                   (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 795                   (query-address (elpher-address-from-url (concat url "?" query-string))))
 796              (elpher-get-gemini-response query-address
 797                                          (lambda (_proc event)
 798                                            (unless (string-prefix-p "deleted" event)
 799                                              (funcall #'elpher-process-gemini-response
 800                                                       renderer)
 801                                              (elpher-restore-pos))))))
 802           (?2 ; Normal response
 803            ;; (message response-header)
 804            (funcall renderer response-body response-meta))
 805           (?3 ; Redirect
 806            (message "Following redirect to %s" response-meta)
 807            (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 808              (elpher-get-gemini-response redirect-address
 809                                          (lambda (_proc event)
 810                                            (unless (string-prefix-p "deleted" event)
 811                                              (funcall #'elpher-process-gemini-response
 812                                                       renderer)
 813                                              (elpher-restore-pos))))))
 814           (?4 ; Temporary failure
 815            (error "Gemini server reports TEMPORARY FAILURE for this request"))
 816           (?5 ; Permanent failure
 817            (error "Gemini server reports PERMANENT FAILURE for this request"))
 818           (?6 ; Client certificate required
 819            (error "Gemini server requires client certificate (unsupported at this time)"))
 820           (_other
 821            (error "Gemini server responded with unknown response code %S"
 822                   response-code))))
 823     (error
 824      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 825
 826 (defun elpher-get-gemini-node (renderer)
 827   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 828   (let* ((address (elpher-node-address elpher-current-node))
 829          (content (elpher-get-cached-content address)))
 830     (condition-case the-error
 831         (if (and content (funcall renderer nil))
 832             (elpher-with-clean-buffer
 833               (insert content)
 834               (elpher-restore-pos))
 835           (elpher-with-clean-buffer
 836            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 837           (elpher-get-gemini-response address
 838                                       (lambda (_proc event)
 839                                         (unless (string-prefix-p "deleted" event)
 840                                           (funcall #'elpher-process-gemini-response
 841                                                    renderer)
 842                                           (elpher-restore-pos)))))
 843       (error
 844        (elpher-network-error address the-error)))))
 845
 846
 847 (defun elpher-render-gemini (body &optional mime-type-string)
 848   "Render gemini response BODY with rendering MIME-TYPE-STRING."
 849   (if (not body)
 850       t
 851     (let* ((mime-type-string* (if (or (not mime-type-string)
 852                                       (string-empty-p mime-type-string))
 853                                   "text/gemini; charset=utf-8"
 854                                 mime-type-string))
 855            (mime-type-split (split-string mime-type-string* ";" t))
 856            (mime-type (string-trim (car mime-type-split)))
 857            (parameters (mapcar (lambda (s)
 858                                  (let ((key-val (split-string s "=")))
 859                                    (list (downcase (string-trim (car key-val)))
 860                                          (downcase (string-trim (cadr key-val))))))
 861                                (cdr mime-type-split))))
 862       (if (and (equal "text/gemini" mime-type)
 863                (not (assoc "charset" parameters)))
 864           (setq parameters (cons (list "charset" "utf-8") parameters)))
 865       (when (string-prefix-p "text/" mime-type)
 866         (if (assoc "charset" parameters)
 867             (setq body (decode-coding-string body
 868                                              (intern (cadr (assoc "charset" parameters))))))
 869         (setq body (replace-regexp-in-string "\r" "" body)))
 870       (pcase mime-type
 871         ((or "text/gemini" "")
 872          (elpher-render-gemini-map body parameters))
 873         ((pred (string-prefix-p "text/"))
 874          (elpher-render-gemini-plain-text body parameters))
 875         ((pred (string-prefix-p "image/"))
 876          (elpher-render-image body))
 877         (_other
 878          (error "Unsupported MIME type %S" mime-type))))))
 879
 880 (defun elpher-gemini-get-link-url (line)
 881   "Extract the url portion of LINE, a gemini map file link line."
 882   (string-trim (elt (split-string (substring line 2)) 0)))
 883
 884 (defun elpher-gemini-get-link-display-string (line)
 885   "Extract the display string portion of LINE, a gemini map file link line."
 886   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 887          (idx (string-match "[ \t]" rest)))
 888     (if idx
 889         (string-trim (substring rest (+ idx 1)))
 890       "")))
 891
 892 (defun elpher-address-from-gemini-url (url)
 893   "Extract address from URL with defaults as per gemini map files."
 894   (let ((address (url-generic-parse-url url)))
 895     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 896       (setf (url-fullness address) t)
 897       (unless (url-host address) ;if there is an explicit host, filenames are explicit
 898         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 899         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 900           (setf (url-filename address)
 901                 (concat (file-name-directory
 902                          (url-filename (elpher-node-address elpher-current-node)))
 903                         (url-filename address)))))
 904       (unless (url-type address)
 905         (setf (url-type address) "gemini")))
 906     address))
 907
 908 (defun elpher-render-gemini-map (data _parameters)
 909   "Render DATA as a gemini map file, PARAMETERS is currently unused."
 910   (elpher-with-clean-buffer
 911    (dolist (line (split-string data "\n"))
 912      (if (string-prefix-p "=>" line)
 913          (let* ((url (elpher-gemini-get-link-url line))
 914                 (display-string (elpher-gemini-get-link-display-string line))
 915                 (address (elpher-address-from-gemini-url url)))
 916            (if (> (length display-string) 0)
 917                (elpher-insert-index-record display-string address)
 918              (elpher-insert-index-record url address)))
 919        (elpher-insert-index-record line)))
 920    (elpher-cache-content
 921     (elpher-node-address elpher-current-node)
 922     (buffer-string))))
 923
 924 (defun elpher-render-gemini-plain-text (data _parameters)
 925   "Render DATA as plain text file.  PARAMETERS is currently unused."
 926   (elpher-with-clean-buffer
 927    (insert (elpher-buttonify-urls data))
 928    (elpher-cache-content
 929     (elpher-node-address elpher-current-node)
 930     (buffer-string))))
 931
 932 ;; Other URL node opening
 933
 934 (defun elpher-get-other-url-node (renderer)
 935   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 936   (when renderer
 937     (elpher-visit-parent-node)
 938     (error "Command not supported for general URLs"))
 939   (let* ((address (elpher-node-address elpher-current-node))
 940          (url (elpher-address-to-url address)))
 941     (progn
 942       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 943       (message "Opening URL...")
 944       (if elpher-open-urls-with-eww
 945           (browse-web url)
 946         (browse-url url)))))
 947
 948 ;; Telnet node connection
 949
 950 (defun elpher-get-telnet-node (renderer)
 951   "Opens a telnet connection to the current node address (RENDERER must be nil)."
 952   (when renderer
 953     (elpher-visit-parent-node)
 954     (error "Command not supported for telnet URLs"))
 955   (let* ((address (elpher-node-address elpher-current-node))
 956          (host (elpher-address-host address))
 957          (port (elpher-address-port address)))
 958     (elpher-visit-parent-node)
 959     (telnet host port)))
 960
 961 ;; Start page node retrieval
 962
 963 (defun elpher-get-start-node (renderer)
 964   "Getter which displays the start page (RENDERER must be nil)."
 965   (when renderer
 966     (elpher-visit-parent-node)
 967     (error "Command not supported for start page"))
 968   (elpher-with-clean-buffer
 969    (insert "     --------------------------------------------\n"
 970            "                Elpher Gopher Client             \n"
 971            "                   version " elpher-version "\n"
 972            "     --------------------------------------------\n"
 973            "\n"
 974            "Default bindings:\n"
 975            "\n"
 976            " - TAB/Shift-TAB: next/prev item on current page\n"
 977            " - RET/mouse-1: open item under cursor\n"
 978            " - m: select an item on current page by name (autocompletes)\n"
 979            " - u: return to previous page\n"
 980            " - o/O: visit different selector or the root menu of the current server\n"
 981            " - g: go to a particular gopher address\n"
 982            " - d/D: download item under cursor or current page\n"
 983            " - i/I: info on item under cursor or current page\n"
 984            " - c/C: copy URL representation of item under cursor or current page\n"
 985            " - a/A: bookmark the item under cursor or current page\n"
 986            " - x/X: remove bookmark for item under cursor or current page\n"
 987            " - B: visit the bookmarks page\n"
 988            " - r: redraw current page (using cached contents if available)\n"
 989            " - R: reload current page (regenerates cache)\n"
 990            " - S: set character coding system for gopher (default is to autodetect)\n"
 991            " - T: toggle TLS gopher mode\n"
 992            " - .: display the raw server response for the current page\n"
 993            "\n"
 994            "Start your exploration of gopher space:\n")
 995    (elpher-insert-index-record "Floodgap Systems Gopher Server"
 996                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
 997    (insert "\n"
 998            "Alternatively, select the following item and enter some search terms:\n")
 999    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
1000                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1001    (insert "\n"
1002            "** Refer to the ")
1003    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1004      (insert-text-button "Elpher info manual"
1005                          'face 'link
1006                          'action (lambda (_)
1007                                    (interactive)
1008                                    (info "(elpher)"))
1009                          'follow-link t
1010                          'help-echo help-string))
1011    (insert " for the full documentation. **\n")
1012    (insert (propertize
1013             (concat "  (This should be available if you have installed Elpher using\n"
1014                     "   MELPA. Otherwise you will have to install the manual yourself.)")
1015             'face 'shadow))
1016    (elpher-restore-pos)))
1017
1018 ;; Bookmarks page node retrieval
1019
1020 (defun elpher-get-bookmarks-node (renderer)
1021   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1022   (when renderer
1023     (elpher-visit-parent-node)
1024     (error "Command not supported for bookmarks page"))
1025   (elpher-with-clean-buffer
1026    (insert "---- Bookmark list ----\n\n")
1027    (let ((bookmarks (elpher-load-bookmarks)))
1028      (if bookmarks
1029          (dolist (bookmark bookmarks)
1030            (let ((display-string (elpher-bookmark-display-string bookmark))
1031                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1032              (elpher-insert-index-record display-string address)))
1033        (insert "No bookmarks found.\n")))
1034    (insert "\n-----------------------\n\n"
1035            "- u: return to previous page\n"
1036            "- x: delete selected bookmark\n"
1037            "- a: rename selected bookmark\n\n"
1038            "Bookmarks are stored in the file "
1039            (locate-user-emacs-file "elpher-bookmarks"))
1040    (elpher-restore-pos)))
1041
1042
1043 ;;; Bookmarks
1044 ;;
1045
1046 (defun elpher-make-bookmark (display-string url)
1047   "Make an elpher bookmark.
1048 DISPLAY-STRING determines how the bookmark will appear in the
1049 bookmark list, while URL is the url of the entry."
1050   (list display-string url))
1051
1052 (defun elpher-bookmark-display-string (bookmark)
1053   "Get the display string of BOOKMARK."
1054   (elt bookmark 0))
1055
1056 (defun elpher-set-bookmark-display-string (bookmark display-string)
1057   "Set the display string of BOOKMARK to DISPLAY-STRING."
1058   (setcar bookmark display-string))
1059
1060 (defun elpher-bookmark-url (bookmark)
1061   "Get the address for BOOKMARK."
1062   (elt bookmark 1))
1063
1064 (defun elpher-save-bookmarks (bookmarks)
1065   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1066 Beware that this completely replaces the existing contents of the file."
1067   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
1068     (erase-buffer)
1069     (insert "; Elpher bookmarks file\n\n"
1070             "; Bookmarks are stored as a list of (label URL) items.\n"
1071             "; Feel free to edit by hand, but take care to ensure\n"
1072             "; the list structure remains intact.\n\n")
1073     (pp bookmarks (current-buffer))))
1074
1075 (defun elpher-load-bookmarks ()
1076   "Get the list of bookmarks from the users's bookmark file."
1077   (let ((bookmarks
1078          (with-temp-buffer
1079            (ignore-errors
1080              (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
1081              (goto-char (point-min))
1082              (read (current-buffer))))))
1083     (if (and bookmarks (listp (cadar bookmarks)))
1084         (progn
1085           (message "Reading old bookmark file. (Will be updated on write.)")
1086           (mapcar (lambda (old-bm)
1087                     (list (car old-bm)
1088                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1089                                                         (cadr old-bm)))))
1090                   bookmarks))
1091       bookmarks)))
1092
1093 (defun elpher-add-address-bookmark (address display-string)
1094   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1095 If ADDRESS is already bookmarked, update the label only."
1096   (let ((bookmarks (elpher-load-bookmarks))
1097         (url (elpher-address-to-url address)))
1098     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1099       (if existing-bookmark
1100           (elpher-set-bookmark-display-string existing-bookmark display-string)
1101         (push (elpher-make-bookmark display-string url) bookmarks)))
1102     (elpher-save-bookmarks bookmarks)))
1103
1104 (defun elpher-remove-address-bookmark (address)
1105   "Remove any bookmark to ADDRESS."
1106   (let ((url (elpher-address-to-url address)))
1107     (elpher-save-bookmarks
1108      (seq-filter (lambda (bookmark)
1109                    (not (equal (elpher-bookmark-url bookmark) url)))
1110                  (elpher-load-bookmarks)))))
1111
1112 ;;; Interactive procedures
1113 ;;
1114
1115 (defun elpher-next-link ()
1116   "Move point to the next link on the current page."
1117   (interactive)
1118   (forward-button 1))
1119
1120 (defun elpher-prev-link ()
1121   "Move point to the previous link on the current page."
1122   (interactive)
1123   (backward-button 1))
1124
1125 (defun elpher-follow-current-link ()
1126   "Open the link or url at point."
1127   (interactive)
1128   (push-button))
1129
1130 (defun elpher-go ()
1131   "Go to a particular gopher site read from the minibuffer."
1132   (interactive)
1133   (let ((node
1134          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1135            (elpher-make-node host-or-url
1136                              (elpher-address-from-url host-or-url)))))
1137     (switch-to-buffer "*elpher*")
1138     (elpher-visit-node node)))
1139
1140 (defun elpher-go-current ()
1141   "Go to a particular site read from the minibuffer, initialized with the current URL."
1142   (interactive)
1143   (let ((address (elpher-node-address elpher-current-node)))
1144     (if (elpher-address-special-p address)
1145         (error "Command invalid for this page")
1146       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1147         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1148
1149 (defun elpher-redraw ()
1150   "Redraw current page."
1151   (interactive)
1152   (if elpher-current-node
1153       (elpher-visit-node elpher-current-node)
1154     (message "No current site.")))
1155
1156 (defun elpher-reload ()
1157   "Reload current page."
1158   (interactive)
1159   (if elpher-current-node
1160       (elpher-reload-current-node)
1161     (message "No current site.")))
1162
1163 (defun elpher-toggle-tls ()
1164   "Toggle TLS encryption mode."
1165   (interactive)
1166   (setq elpher-use-tls (not elpher-use-tls))
1167   (if elpher-use-tls
1168       (if (gnutls-available-p)
1169           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1170         (setq elpher-use-tls nil)
1171         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1172     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1173
1174 (defun elpher-view-raw ()
1175   "View raw server response for current page."
1176   (interactive)
1177   (if elpher-current-node
1178       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1179           (error "This page was not generated by a server")
1180         (elpher-visit-node elpher-current-node
1181                            #'elpher-render-raw))
1182     (message "No current site.")))
1183
1184 (defun elpher-back ()
1185   "Go to previous site."
1186   (interactive)
1187   (if (elpher-node-parent elpher-current-node)
1188       (elpher-visit-parent-node)
1189     (error "No previous site")))
1190
1191 (defun elpher-download ()
1192   "Download the link at point."
1193   (interactive)
1194   (let ((button (button-at (point))))
1195     (if button
1196         (let ((node (button-get button 'elpher-node)))
1197           (if (elpher-address-special-p (elpher-node-address node))
1198               (error "Cannot download %s"
1199                      (elpher-node-display-string node))
1200             (elpher-visit-node (button-get button 'elpher-node)
1201                                #'elpher-render-download)))
1202       (error "No link selected"))))
1203
1204 (defun elpher-download-current ()
1205   "Download the current page."
1206   (interactive)
1207   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1208       (error "Cannot download %s"
1209              (elpher-node-display-string elpher-current-node))
1210     (elpher-visit-node (elpher-make-node
1211                         (elpher-node-display-string elpher-current-node)
1212                         (elpher-node-address elpher-current-node)
1213                         elpher-current-node)
1214                        #'elpher-render-download
1215                        t)))
1216
1217 (defun elpher-build-link-map ()
1218   "Build alist mapping link names to destination nodes in current buffer."
1219   (let ((link-map nil)
1220         (b (next-button (point-min) t)))
1221     (while b
1222       (push (cons (button-label b) b) link-map)
1223       (setq b (next-button (button-start b))))
1224     link-map))
1225
1226 (defun elpher-jump ()
1227   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1228   (interactive)
1229   (let* ((link-map (elpher-build-link-map)))
1230     (if link-map
1231         (let ((key (let ((completion-ignore-case t))
1232                      (completing-read "Directory item/link: "
1233                                       link-map nil t))))
1234           (if (and key (> (length key) 0))
1235               (let ((b (cdr (assoc key link-map))))
1236                 (goto-char (button-start b))
1237                 (button-activate b)))))))
1238
1239 (defun elpher-root-dir ()
1240   "Visit root of current server."
1241   (interactive)
1242   (let ((address (elpher-node-address elpher-current-node)))
1243     (if (not (elpher-address-special-p address))
1244         (if (or (member (url-filename address) '("/" ""))
1245                 (and (elpher-address-gopher-p address)
1246                      (= (length (elpher-gopher-address-selector address)) 0)))
1247             (error "Already at root directory of current server")
1248           (let ((address-copy (elpher-address-from-url
1249                                (elpher-address-to-url address))))
1250             (setf (url-filename address-copy) "")
1251             (elpher-visit-node
1252              (elpher-make-node (elpher-address-to-url address-copy)
1253                                address-copy))))
1254       (error "Command invalid for %s" (elpher-node-display-string elpher-current-node)))))
1255
1256 (defun elpher-bookmarks-current-p ()
1257   "Return non-nil if current node is a bookmarks page."
1258   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1259          '(special bookmarks)))
1260
1261 (defun elpher-reload-bookmarks ()
1262   "Reload bookmarks if current node is a bookmarks page."
1263   (if (elpher-bookmarks-current-p)
1264       (elpher-reload-current-node)))
1265
1266 (defun elpher-bookmark-current ()
1267   "Bookmark the current node."
1268   (interactive)
1269   (let ((address (elpher-node-address elpher-current-node))
1270         (display-string (elpher-node-display-string elpher-current-node)))
1271     (if (not (elpher-address-special-p address))
1272         (let ((bookmark-display-string (read-string "Bookmark display string: "
1273                                                     display-string)))
1274           (elpher-add-address-bookmark address bookmark-display-string)
1275           (message "Bookmark added."))
1276       (error "Cannot bookmark %s" display-string))))
1277
1278 (defun elpher-bookmark-link ()
1279   "Bookmark the link at point."
1280   (interactive)
1281   (let ((button (button-at (point))))
1282     (if button
1283         (let* ((node (button-get button 'elpher-node))
1284                (address (elpher-node-address node))
1285                (display-string (elpher-node-display-string node)))
1286           (if (not (elpher-address-special-p address))
1287               (let ((bookmark-display-string (read-string "Bookmark display string: "
1288                                                           display-string)))
1289                 (elpher-add-address-bookmark address bookmark-display-string)
1290                 (elpher-reload-bookmarks)
1291                 (message "Bookmark added."))
1292             (error "Cannot bookmark %s" display-string)))
1293       (error "No link selected"))))
1294
1295 (defun elpher-unbookmark-current ()
1296   "Remove bookmark for the current node."
1297   (interactive)
1298   (let ((address (elpher-node-address elpher-current-node)))
1299     (unless (elpher-address-special-p address)
1300       (elpher-remove-address-bookmark address)
1301       (message "Bookmark removed."))))
1302
1303 (defun elpher-unbookmark-link ()
1304   "Remove bookmark for the link at point."
1305   (interactive)
1306   (let ((button (button-at (point))))
1307     (if button
1308         (let ((node (button-get button 'elpher-node)))
1309           (elpher-remove-address-bookmark (elpher-node-address node))
1310           (elpher-reload-bookmarks)
1311           (message "Bookmark removed."))
1312       (error "No link selected"))))
1313
1314 (defun elpher-bookmarks ()
1315   "Visit bookmarks page."
1316   (interactive)
1317   (switch-to-buffer "*elpher*")
1318   (elpher-visit-node
1319    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1320
1321 (defun elpher-info-node (node)
1322   "Display information on NODE."
1323   (let ((display-string (elpher-node-display-string node))
1324         (address (elpher-node-address node)))
1325     (if (elpher-address-special-p address)
1326         (message "Special page: %s" display-string)
1327       (message (elpher-address-to-url address)))))
1328
1329 (defun elpher-info-link ()
1330   "Display information on node corresponding to link at point."
1331   (interactive)
1332   (let ((button (button-at (point))))
1333     (if button
1334         (elpher-info-node (button-get button 'elpher-node))
1335       (error "No item selected"))))
1336
1337 (defun elpher-info-current ()
1338   "Display information on current node."
1339   (interactive)
1340   (elpher-info-node elpher-current-node))
1341
1342 (defun elpher-copy-node-url (node)
1343   "Copy URL representation of address of NODE to `kill-ring'."
1344   (let ((address (elpher-node-address node)))
1345     (if (elpher-address-special-p address)
1346         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1347       (let ((url (elpher-address-to-url address)))
1348         (message "Copied \"%s\" to kill-ring/clipboard." url)
1349         (kill-new url)))))
1350
1351 (defun elpher-copy-link-url ()
1352   "Copy URL of item at point to `kill-ring'."
1353   (interactive)
1354   (let ((button (button-at (point))))
1355     (if button
1356         (elpher-copy-node-url (button-get button 'elpher-node))
1357       (error "No item selected"))))
1358
1359 (defun elpher-copy-current-url ()
1360   "Copy URL of current node to `kill-ring'."
1361   (interactive)
1362   (elpher-copy-node-url elpher-current-node))
1363
1364 (defun elpher-set-gopher-coding-system ()
1365   "Specify an explicit character coding system for gopher selectors."
1366   (interactive)
1367   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1368     (setq elpher-user-coding-system system)
1369     (if system
1370         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1371       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1372
1373
1374 ;;; Mode and keymap
1375 ;;
1376
1377 (defvar elpher-mode-map
1378   (let ((map (make-sparse-keymap)))
1379     (define-key map (kbd "TAB") 'elpher-next-link)
1380     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1381     (define-key map (kbd "u") 'elpher-back)
1382     (define-key map (kbd "O") 'elpher-root-dir)
1383     (define-key map (kbd "g") 'elpher-go)
1384     (define-key map (kbd "o") 'elpher-go-current)
1385     (define-key map (kbd "r") 'elpher-redraw)
1386     (define-key map (kbd "R") 'elpher-reload)
1387     (define-key map (kbd "T") 'elpher-toggle-tls)
1388     (define-key map (kbd ".") 'elpher-view-raw)
1389     (define-key map (kbd "d") 'elpher-download)
1390     (define-key map (kbd "D") 'elpher-download-current)
1391     (define-key map (kbd "m") 'elpher-jump)
1392     (define-key map (kbd "i") 'elpher-info-link)
1393     (define-key map (kbd "I") 'elpher-info-current)
1394     (define-key map (kbd "c") 'elpher-copy-link-url)
1395     (define-key map (kbd "C") 'elpher-copy-current-url)
1396     (define-key map (kbd "a") 'elpher-bookmark-link)
1397     (define-key map (kbd "A") 'elpher-bookmark-current)
1398     (define-key map (kbd "x") 'elpher-unbookmark-link)
1399     (define-key map (kbd "X") 'elpher-unbookmark-current)
1400     (define-key map (kbd "B") 'elpher-bookmarks)
1401     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1402     (when (fboundp 'evil-define-key*)
1403       (evil-define-key* 'motion map
1404         (kbd "TAB") 'elpher-next-link
1405         (kbd "C-") 'elpher-follow-current-link
1406         (kbd "C-t") 'elpher-back
1407         (kbd "u") 'elpher-back
1408         (kbd "g") 'elpher-go
1409         (kbd "o") 'elpher-go-current
1410         (kbd "r") 'elpher-redraw
1411         (kbd "R") 'elpher-reload
1412         (kbd "T") 'elpher-toggle-tls
1413         (kbd ".") 'elpher-view-raw
1414         (kbd "d") 'elpher-download
1415         (kbd "D") 'elpher-download-current
1416         (kbd "m") 'elpher-jump
1417         (kbd "i") 'elpher-info-link
1418         (kbd "I") 'elpher-info-current
1419         (kbd "c") 'elpher-copy-link-url
1420         (kbd "C") 'elpher-copy-current-url
1421         (kbd "a") 'elpher-bookmark-link
1422         (kbd "A") 'elpher-bookmark-current
1423         (kbd "x") 'elpher-unbookmark-link
1424         (kbd "X") 'elpher-unbookmark-current
1425         (kbd "B") 'elpher-bookmarks
1426         (kbd "S") 'elpher-set-gopher-coding-system))
1427     map)
1428   "Keymap for gopher client.")
1429
1430 (define-derived-mode elpher-mode special-mode "elpher"
1431   "Major mode for elpher, an elisp gopher client.)))))))
1432
1433 This mode is automatically enabled by the interactive
1434 functions which initialize the gopher client, namely
1435 `elpher', `elpher-go' and `elpher-bookmarks'.")
1436
1437 (when (fboundp 'evil-set-initial-state)
1438   (evil-set-initial-state 'elpher-mode 'motion))
1439
1440
1441 ;;; Main start procedure
1442 ;;
1443
1444 ;;;###autoload
1445 (defun elpher ()
1446   "Start elpher with default landing page."
1447   (interactive)
1448   (if (get-buffer "*elpher*")
1449       (switch-to-buffer "*elpher*")
1450     (switch-to-buffer "*elpher*")
1451     (setq elpher-current-node nil)
1452     (let ((start-node (elpher-make-node "Elpher Start Page"
1453                                         (elpher-make-special-address 'start))))
1454       (elpher-visit-node start-node)))
1455   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1456
1457 ;;; elpher.el ends here