elpher.el

   1 ;;; elpher.el --- A friendly gopher client.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.3.5
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption,
  40 ;; - basic support for the fledgling Gemini protocol.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Full instructions can be found in the Elpher info manual.
  47
  48 ;; Elpher is under active development.  Any suggestions for
  49 ;; improvements are welcome!
  50
  51 ;;; Code:
  52
  53 (provide 'elpher)
  54
  55 ;;; Dependencies
  56 ;;
  57
  58 (require 'seq)
  59 (require 'pp)
  60 (require 'shr)
  61 (require 'url-util)
  62 (require 'subr-x)
  63
  64
  65 ;;; Global constants
  66 ;;
  67
  68 (defconst elpher-version "2.3.5"
  69   "Current version of elpher.")
  70
  71 (defconst elpher-margin-width 6
  72   "Width of left-hand margin used when rendering indicies.")
  73
  74 (defconst elpher-type-map
  75   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  76     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  77     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  78     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  79     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  80     ((gopher ?9) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  81     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  83     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  84     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  85     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  86     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  87     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  88     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  89     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  90     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  91     ((special bookmarks) elpher-get-bookmarks-node nil "/" elpher-index)
  92     ((special start) elpher-get-start-node nil))
  93   "Association list from types to getters, renderers, margin codes and index faces.")
  94
  95
  96 ;;; Customization group
  97 ;;
  98
  99 (defgroup elpher nil
 100   "A gopher client."
 101   :group 'applications)
 102
 103 ;; Face customizations
 104
 105 (defface elpher-index
 106   '((t :inherit font-lock-keyword-face))
 107   "Face used for directory type directory records.")
 108
 109 (defface elpher-text
 110   '((t :inherit bold))
 111   "Face used for text type directory records.")
 112
 113 (defface elpher-info
 114   '((t :inherit default))
 115   "Face used for info type directory records.")
 116
 117 (defface elpher-image
 118   '((t :inherit font-lock-string-face))
 119   "Face used for image type directory records.")
 120
 121 (defface elpher-search
 122   '((t :inherit warning))
 123   "Face used for search type directory records.")
 124
 125 (defface elpher-html
 126   '((t :inherit font-lock-comment-face))
 127   "Face used for html type directory records.")
 128
 129 (defface elpher-gemini
 130   '((t :inherit font-lock-regexp-grouping-backslash))
 131   "Face used for html type directory records.")
 132
 133 (defface elpher-other-url
 134   '((t :inherit font-lock-comment-face))
 135   "Face used for other URL type links records.")
 136
 137 (defface elpher-telnet
 138   '((t :inherit font-lock-function-name-face))
 139   "Face used for telnet type directory records.")
 140
 141 (defface elpher-binary
 142   '((t :inherit font-lock-doc-face))
 143   "Face used for binary type directory records.")
 144
 145 (defface elpher-unknown
 146   '((t :inherit error))
 147   "Face used for directory records with unknown/unsupported types.")
 148
 149 (defface elpher-margin-key
 150   '((t :inherit bold))
 151   "Face used for directory margin key.")
 152
 153 (defface elpher-margin-brackets
 154   '((t :inherit shadow))
 155   "Face used for brackets around directory margin key.")
 156
 157 ;; Other customizations
 158
 159 (defcustom elpher-open-urls-with-eww nil
 160   "If non-nil, open URL selectors using eww.
 161 Otherwise, use the system browser via the BROWSE-URL function."
 162   :type '(boolean))
 163
 164 (defcustom elpher-buttonify-urls-in-directories t
 165   "If non-nil, turns URLs matched in directories into clickable buttons."
 166   :type '(boolean))
 167
 168 (defcustom elpher-use-header t
 169   "If non-nil, display current node information in buffer header."
 170   :type '(boolean))
 171
 172 (defcustom elpher-auto-disengage-TLS nil
 173   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 174 While enabling this may seem convenient, it is also potentially dangerous as it
 175 allows switching from an encrypted channel back to plain text without user input."
 176   :type '(boolean))
 177
 178
 179 ;;; Model
 180 ;;
 181
 182 ;; Address
 183
 184 ;; An elpher "address" object is either a url object or a symbol.
 185 ;; Symbol addresses are "special", corresponding to pages generated
 186 ;; dynamically for and by elpher.  All others represent pages which
 187 ;; rely on content retrieved over the network.
 188
 189 (defun elpher-address-from-url (url-string)
 190   "Create a ADDRESS object corresponding to the given URL-STRING."
 191   (let ((data (match-data))) ; Prevent parsing clobbering match data
 192     (unwind-protect
 193         (let ((url (url-generic-parse-url url-string)))
 194           (unless (and (not (url-fullness url)) (url-type url))
 195             (setf (url-fullness url) t)
 196             (setf (url-filename url)
 197                   (url-unhex-string (url-filename url)))
 198             (unless (url-type url)
 199               (setf (url-type url) "gopher"))
 200             (when (or (equal "gopher" (url-type url))
 201                       (equal "gophers" (url-type url)))
 202               ;; Gopher defaults
 203               (unless (url-host url)
 204                 (setf (url-host url) (url-filename url))
 205                 (setf (url-filename url) ""))
 206               (when (or (equal (url-filename url) "")
 207                         (equal (url-filename url) "/"))
 208                 (setf (url-filename url) "/1")))
 209             (when (equal "gemini" (url-type url))
 210               ;; Gemini defaults
 211               (if (equal (url-filename url) "")
 212                   (setf (url-filename url) "/"))))
 213           url)
 214       (set-match-data data))))
 215
 216 (defun elpher-make-gopher-address (type selector host port &optional tls)
 217   "Create an ADDRESS object using gopher directory record attributes.
 218 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 219 If the optional attribute TLS is non-nil, the address will be marked as
 220 requiring gopher-over-TLS."
 221   (cond
 222    ((and (equal type ?h)
 223          (string-prefix-p "URL:" selector))
 224     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 225    ((equal type ?8)
 226     (elpher-address-from-url
 227      (concat "telnet"
 228              "://" host
 229              ":" (number-to-string port))))
 230    (t
 231     (elpher-address-from-url
 232      (concat "gopher" (if tls "s" "")
 233              "://" host
 234              ":" (number-to-string port)
 235              "/" (string type)
 236              selector)))))
 237
 238 (defun elpher-make-special-address (type)
 239   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 240   type)
 241
 242 (defun elpher-address-to-url (address)
 243   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 244   (if (not (elpher-address-special-p address))
 245       (url-encode-url (url-recreate-url address))
 246     nil))
 247
 248 (defun elpher-address-type (address)
 249   "Retrieve type of ADDRESS object.
 250 This is used to determine how to retrieve and render the document the
 251 address refers to, via the table `elpher-type-map'."
 252   (if (symbolp address)
 253       (list 'special address)
 254     (let ((protocol (url-type address)))
 255       (cond ((or (equal protocol "gopher")
 256                  (equal protocol "gophers"))
 257              (list 'gopher
 258                    (if (member (url-filename address) '("" "/"))
 259                        ?1
 260                      (string-to-char (substring (url-filename address) 1)))))
 261             ((equal protocol "gemini")
 262              'gemini)
 263             ((equal protocol "telnet")
 264              'telnet)
 265             (t 'other-url)))))
 266
 267 (defun elpher-address-protocol (address)
 268   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 269   (if (symbolp address)
 270       nil
 271     (url-type address)))
 272
 273 (defun elpher-address-filename (address)
 274   "Retrieve the filename component of ADDRESS.
 275 For gopher addresses this is a combination of the selector type and selector."
 276   (if (symbolp address)
 277       nil
 278     (url-filename address)))
 279
 280 (defun elpher-address-host (address)
 281   "Retrieve host from ADDRESS object."
 282   (url-host address))
 283
 284 (defun elpher-address-port (address)
 285   "Retrieve port from ADDRESS object."
 286   (if (symbolp address)
 287       nil)
 288   (if (> (url-port address) 0)
 289       (url-port address)
 290     (or (and (or (equal (url-type address) "gopher")
 291                  (equal (url-type address) "gophers"))
 292              70)
 293         (and (equal (url-type address) "gemini")
 294              1965))))
 295
 296 (defun elpher-address-special-p (address)
 297   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 298   (symbolp address))
 299
 300 (defun elpher-address-gopher-p (address)
 301   "Return non-nill if ADDRESS object is a gopher address."
 302   (and (not (elpher-address-special-p address))
 303        (member (elpher-address-protocol address) '("gopher gophers"))))
 304
 305 (defun elpher-gopher-address-selector (address)
 306   "Retrieve gopher selector from ADDRESS object."
 307   (if (member (url-filename address) '("" "/"))
 308       ""
 309     (substring (url-filename address) 2)))
 310
 311 ;; Node
 312
 313 (defun elpher-make-node (display-string address &optional parent)
 314   "Create a node in the page hierarchy.
 315
 316 DISPLAY-STRING records the display string used for the page.
 317
 318 ADDRESS specifies the address object of the page.
 319
 320 The optional PARENT specifies the parent node in the hierarchy.
 321 This is set every time the node is visited, so while it forms
 322 an important part of the node data there is no need to set it
 323 initially."
 324   (list display-string address parent))
 325
 326 (defun elpher-node-display-string (node)
 327   "Retrieve the display string of NODE."
 328   (elt node 0))
 329
 330 (defun elpher-node-address (node)
 331   "Retrieve the ADDRESS object of NODE."
 332   (elt node 1))
 333
 334 (defun elpher-node-parent (node)
 335   "Retrieve the parent node of NODE."
 336   (elt node 2))
 337
 338 (defun elpher-set-node-parent (node parent)
 339   "Set the parent node of NODE to be PARENT."
 340   (setcar (cdr (cdr node)) parent))
 341
 342 ;; Cache
 343
 344 (defvar elpher-content-cache (make-hash-table :test 'equal))
 345 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 346
 347 (defun elpher-get-cached-content (address)
 348   "Retrieve the cached content for ADDRESS, or nil if none exists."
 349   (gethash address elpher-content-cache))
 350
 351 (defun elpher-cache-content (address content)
 352   "Set the content cache for ADDRESS to CONTENT."
 353   (puthash address content elpher-content-cache))
 354
 355 (defun elpher-get-cached-pos (address)
 356   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 357   (gethash address elpher-pos-cache))
 358
 359 (defun elpher-cache-pos (address pos)
 360   "Set the cursor position cache for ADDRESS to POS."
 361   (puthash address pos elpher-pos-cache))
 362
 363 ;; Node graph traversal
 364
 365 (defvar elpher-current-node nil)
 366
 367 (defun elpher-visit-node (node &optional renderer preserve-parent)
 368   "Visit NODE using its own renderer or RENDERER, if non-nil.
 369 Additionally, set the parent of NODE to `elpher-current-node',
 370 unless PRESERVE-PARENT is non-nil."
 371   (elpher-save-pos)
 372   (elpher-process-cleanup)
 373   (unless preserve-parent
 374     (if (and (elpher-node-parent elpher-current-node)
 375              (equal (elpher-node-address elpher-current-node)
 376                     (elpher-node-address node)))
 377         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 378       (elpher-set-node-parent node elpher-current-node)))
 379   (setq elpher-current-node node)
 380   (let* ((address (elpher-node-address node))
 381          (type (elpher-address-type address))
 382          (type-record (cdr (assoc type elpher-type-map))))
 383     (if type-record
 384         (funcall (car type-record)
 385                  (if renderer
 386                      renderer
 387                    (cadr type-record)))
 388       (elpher-visit-parent-node)
 389       (pcase type
 390         (`(gopher ,type-char)
 391          (error "Unsupported gopher selector type '%c' for '%s'"
 392                 type-char (elpher-address-to-url address)))
 393         (other
 394          (error "Unsupported address type '%S' for '%s'"
 395                 other (elpher-address-to-url address)))))))
 396
 397 (defun elpher-visit-parent-node ()
 398   "Visit the parent of the current node."
 399   (let ((parent-node (elpher-node-parent elpher-current-node)))
 400     (when parent-node
 401       (elpher-visit-node parent-node nil t))))
 402
 403 (defun elpher-reload-current-node ()
 404   "Reload the current node, discarding any existing cached content."
 405   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 406   (elpher-visit-node elpher-current-node))
 407
 408 (defun elpher-save-pos ()
 409   "Save the current position of point to the current node."
 410   (when elpher-current-node
 411     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 412
 413 (defun elpher-restore-pos ()
 414   "Restore the position of point to that cached in the current node."
 415   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 416     (if pos
 417         (goto-char pos)
 418       (goto-char (point-min)))))
 419
 420
 421 ;;; Buffer preparation
 422 ;;
 423
 424 (defun elpher-update-header ()
 425   "If `elpher-use-header' is true, display current node info in window header."
 426   (if elpher-use-header
 427       (let* ((display-string (elpher-node-display-string elpher-current-node))
 428              (address (elpher-node-address elpher-current-node))
 429              (tls-string (if (and (not (elpher-address-special-p address))
 430                                   (member (elpher-address-protocol address)
 431                                           '("gophers" "gemini")))
 432                              " [TLS encryption]"
 433                            ""))
 434              (header (concat display-string
 435                              (propertize tls-string 'face 'bold))))
 436         (setq header-line-format header))))
 437
 438 (defmacro elpher-with-clean-buffer (&rest args)
 439   "Evaluate ARGS with a clean *elpher* buffer as current."
 440   (list 'with-current-buffer "*elpher*"
 441         '(elpher-mode)
 442         (append (list 'let '((inhibit-read-only t))
 443                       '(erase-buffer)
 444                       '(elpher-update-header))
 445                 args)))
 446
 447
 448 ;;; Text Processing
 449 ;;
 450
 451 (defvar elpher-user-coding-system nil
 452   "User-specified coding system to use for decoding text responses.")
 453
 454 (defun elpher-decode (string)
 455   "Decode STRING using autodetected or user-specified coding system."
 456   (decode-coding-string string
 457                         (if elpher-user-coding-system
 458                             elpher-user-coding-system
 459                           (detect-coding-string string t))))
 460
 461 (defun elpher-preprocess-text-response (string)
 462   "Preprocess text selector response contained in STRING.
 463 This involes decoding the character representation, and clearing
 464 away CRs and any terminating period."
 465   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 466                                            (replace-regexp-in-string "\r" "" string))))
 467
 468
 469 ;;; Network error reporting
 470 ;;
 471
 472 (defun elpher-network-error (address error)
 473   "Display ERROR message following unsuccessful negotiation with ADDRESS."
 474   (elpher-with-clean-buffer
 475    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 476            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 477            (error-message-string error) "\n"
 478            (propertize "\n----------------\n\n" 'face 'error)
 479            "Press 'u' to return to the previous page.")))
 480
 481
 482 ;;; Gopher selector retrieval
 483 ;;
 484
 485 (defun elpher-process-cleanup ()
 486   "Immediately shut down any extant elpher process."
 487   (let ((p (get-process "elpher-process")))
 488     (if p (delete-process p))))
 489
 490 (defvar elpher-use-tls nil
 491   "If non-nil, use TLS to communicate with gopher servers.")
 492
 493 (defvar elpher-selector-string)
 494
 495 (defun elpher-get-selector (address after &optional propagate-error)
 496   "Retrieve selector specified by ADDRESS, then execute AFTER.
 497 The result is stored as a string in the variable ‘elpher-selector-string’.
 498
 499 Usually errors result in an error page being displayed.  This is only
 500 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 501 is non-nil, this message is not displayed.  Instead, the error propagates
 502 up to the calling function."
 503   (setq elpher-selector-string "")
 504   (when (equal (elpher-address-protocol address) "gophers")
 505       (if (gnutls-available-p)
 506           (when (not elpher-use-tls)
 507             (setq elpher-use-tls t)
 508             (message "Engaging TLS gopher mode."))
 509         (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 510   (condition-case the-error
 511       (let* ((kill-buffer-query-functions nil)
 512              (proc (open-network-stream "elpher-process"
 513                                        nil
 514                                        (elpher-address-host address)
 515                                        (elpher-address-port address)
 516                                        :type (if elpher-use-tls 'tls 'plain))))
 517         (set-process-coding-system proc 'binary)
 518         (set-process-filter proc
 519                             (lambda (_proc string)
 520                               (setq elpher-selector-string
 521                                     (concat elpher-selector-string string))))
 522         (set-process-sentinel proc after)
 523         (let ((inhibit-eol-conversion t))
 524           (process-send-string proc
 525                                (concat (elpher-gopher-address-selector address) "\r\n"))))
 526     (error
 527      (if (and (consp the-error)
 528               (eq (car the-error) 'gnutls-error)
 529               (not (equal (elpher-address-protocol address) "gophers"))
 530               (or elpher-auto-disengage-TLS
 531                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 532          (progn
 533            (message "Disengaging TLS gopher mode.")
 534            (setq elpher-use-tls nil)
 535            (elpher-get-selector address after))
 536        (elpher-process-cleanup)
 537        (if propagate-error
 538            (error the-error)
 539          (elpher-with-clean-buffer
 540           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 541                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 542                   (propertize "\n----------------\n\n" 'face 'error)
 543                   "Press 'u' to return to the previous page.")))))))
 544
 545 (defun elpher-get-gopher-node (renderer)
 546   "Getter function for gopher nodes.
 547 The RENDERER procedure is used to display the contents of the node
 548 once they are retrieved from the gopher server."
 549   (let* ((address (elpher-node-address elpher-current-node))
 550          (content (elpher-get-cached-content address)))
 551     (if (and content (funcall renderer nil))
 552         (elpher-with-clean-buffer
 553          (insert content)
 554          (elpher-restore-pos))
 555       (elpher-with-clean-buffer
 556        (insert "LOADING... (use 'u' to cancel)"))
 557       (elpher-get-selector address
 558                            (lambda (_proc event)
 559                              (unless (string-prefix-p "deleted" event)
 560                                (funcall renderer elpher-selector-string)
 561                                (elpher-restore-pos)))))))
 562
 563 ;; Index rendering
 564
 565 (defun elpher-insert-index (string)
 566   "Insert the index corresponding to STRING into the current buffer."
 567   ;; Should be able to split directly on CRLF, but some non-conformant
 568   ;; LF-only servers sadly exist, hence the following.
 569   (let ((str-processed (elpher-preprocess-text-response string)))
 570     (dolist (line (split-string str-processed "\n"))
 571       (ignore-errors
 572         (unless (= (length line) 0)
 573           (let* ((type (elt line 0))
 574                  (fields (split-string (substring line 1) "\t"))
 575                  (display-string (elt fields 0))
 576                  (selector (elt fields 1))
 577                  (host (elt fields 2))
 578                  (port (if (elt fields 3)
 579                            (string-to-number (elt fields 3))
 580                          nil))
 581                  (address (elpher-make-gopher-address type selector host port)))
 582             (elpher-insert-index-record display-string address)))))))
 583
 584 (defun elpher-insert-margin (&optional type-name)
 585   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 586   (if type-name
 587       (progn
 588         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 589                         (concat
 590                          (propertize "[" 'face 'elpher-margin-brackets)
 591                          (propertize type-name 'face 'elpher-margin-key)
 592                          (propertize "]" 'face 'elpher-margin-brackets))))
 593         (insert " "))
 594     (insert (make-string elpher-margin-width ?\s))))
 595
 596 (defun elpher-node-button-help (node)
 597   "Return a string containing the help text for a button corresponding to NODE."
 598   (let ((address (elpher-node-address node)))
 599     (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 600                                           address
 601                                         (elpher-address-to-url address)))))
 602
 603 (defun elpher-insert-index-record (display-string &optional address)
 604   "Function to insert an index record into the current buffer.
 605 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 606 If ADDRESS is not supplied or nil the record is rendered as an
 607 'information' line."
 608   (let* ((type (if address (elpher-address-type address) nil))
 609          (type-map-entry (cdr (assoc type elpher-type-map))))
 610     (if type-map-entry
 611         (let* ((margin-code (elt type-map-entry 2))
 612                (face (elt type-map-entry 3))
 613                (node (elpher-make-node display-string address)))
 614           (elpher-insert-margin margin-code)
 615           (insert-text-button display-string
 616                               'face face
 617                               'elpher-node node
 618                               'action #'elpher-click-link
 619                               'follow-link t
 620                               'help-echo (elpher-node-button-help node)))
 621       (pcase type
 622         ((or '(gopher ?i) 'nil) ;; Information
 623          (elpher-insert-margin)
 624          (let ((propertized-display-string
 625                 (propertize display-string 'face 'elpher-info)))
 626            (insert (if elpher-buttonify-urls-in-directories
 627                        (elpher-buttonify-urls propertized-display-string)
 628                      propertized-display-string))))
 629         (`(gopher ,selector-type) ;; Unknown
 630          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 631          (insert (propertize display-string
 632                              'face 'elpher-unknown)))))
 633     (insert "\n")))
 634
 635 (defun elpher-click-link (button)
 636   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 637   (let ((node (button-get button 'elpher-node)))
 638     (elpher-visit-node node)))
 639
 640 (defun elpher-render-index (data &optional _mime-type-string)
 641   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 642   (elpher-with-clean-buffer
 643    (if (not data)
 644        t
 645      (elpher-insert-index data)
 646      (elpher-cache-content (elpher-node-address elpher-current-node)
 647                            (buffer-string)))))
 648
 649 ;; Text rendering
 650
 651 (defconst elpher-url-regex
 652   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.]*[0-9a-zA-Z\-_~?/@|]\\)?\\)?"
 653   "Regexp used to locate and buttniofy URLs in text files loaded by elpher.")
 654
 655 (defun elpher-buttonify-urls (string)
 656   "Turn substrings which look like urls in STRING into clickable buttons."
 657   (with-temp-buffer
 658     (insert string)
 659     (goto-char (point-min))
 660     (while (re-search-forward elpher-url-regex nil t)
 661       (let ((node (elpher-make-node (substring-no-properties (match-string 0))
 662                                     (elpher-address-from-url (match-string 0)))))
 663           (make-text-button (match-beginning 0)
 664                             (match-end 0)
 665                             'elpher-node  node
 666                             'action #'elpher-click-link
 667                             'follow-link t
 668                             'help-echo (elpher-node-button-help node)
 669                             'face 'button)))
 670     (buffer-string)))
 671
 672 (defun elpher-render-text (data &optional _mime-type-string)
 673   "Render DATA as text.  MIME-TYPE-STRING is unused."
 674   (elpher-with-clean-buffer
 675    (if (not data)
 676        t
 677      (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 678      (elpher-cache-content
 679       (elpher-node-address elpher-current-node)
 680       (buffer-string)))))
 681
 682 ;; Image retrieval
 683
 684 (defun elpher-render-image (data &optional _mime-type-string)
 685   "Display DATA as image.  MIME-TYPE-STRING is unused."
 686   (if (not data)
 687       nil
 688     (if (display-images-p)
 689         (progn
 690           (let ((image (create-image
 691                         data
 692                         nil t)))
 693             (elpher-with-clean-buffer
 694              (insert-image image)
 695              (elpher-restore-pos))))
 696       (elpher-render-download data))))
 697
 698 ;; Search retrieval and rendering
 699
 700 (defun elpher-get-gopher-query-node (renderer)
 701   "Getter for gopher addresses requiring input.
 702 The response is rendered using the rendering function RENDERER."
 703    (let* ((address (elpher-node-address elpher-current-node))
 704           (content (elpher-get-cached-content address))
 705           (aborted t))
 706     (if (and content (funcall renderer nil))
 707         (elpher-with-clean-buffer
 708          (insert content)
 709          (elpher-restore-pos)
 710          (message "Displaying cached search results.  Reload to perform a new search."))
 711       (unwind-protect
 712           (let* ((query-string (read-string "Query: "))
 713                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 714                  (search-address (elpher-make-gopher-address ?1
 715                                                              query-selector
 716                                                              (elpher-address-host address)
 717                                                              (elpher-address-port address)
 718                                                              (equal (elpher-address-type address) "gophers"))))
 719             (setq aborted nil)
 720
 721             (elpher-with-clean-buffer
 722              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 723             (elpher-get-selector search-address
 724                                  (lambda (_proc event)
 725                                    (unless (string-prefix-p "deleted" event)
 726                                      (funcall renderer elpher-selector-string)
 727                                      (elpher-restore-pos)))))
 728         (if aborted
 729             (elpher-visit-parent-node))))))
 730
 731 ;; Raw server response rendering
 732
 733 (defun elpher-render-raw (data &optional _mime-type-string)
 734   "Display raw DATA in buffer.  MIME-TYPE-STRING is unused."
 735   (if (not data)
 736       nil
 737     (elpher-with-clean-buffer
 738      (insert data)
 739      (goto-char (point-min)))
 740     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 741
 742 ;; File save "rendering"
 743
 744 (defun elpher-render-download (data &optional _mime-type-string)
 745   "Save DATA to file.  MIME-TYPE-STRING is unused."
 746   (if (not data)
 747       nil
 748     (let* ((address (elpher-node-address elpher-current-node))
 749            (selector (elpher-gopher-address-selector address)))
 750       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 751       (let* ((filename-proposal (file-name-nondirectory selector))
 752              (filename (read-file-name "Download complete. Save file as: "
 753                                        nil nil nil
 754                                        (if (> (length filename-proposal) 0)
 755                                            filename-proposal
 756                                          "download.file"))))
 757         (let ((coding-system-for-write 'binary))
 758           (with-temp-file filename
 759             (insert data)))
 760         (message (format "Saved to file %s." filename))))))
 761
 762 ;; HTML rendering
 763
 764 (defun elpher-render-html (data &optional _mime-type-string)
 765   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 766   (elpher-with-clean-buffer
 767    (if (not data)
 768        t
 769      (let ((dom (with-temp-buffer
 770                   (insert data)
 771                   (libxml-parse-html-region (point-min) (point-max)))))
 772        (shr-insert-document dom)))))
 773
 774 ;; Gemini node retrieval
 775
 776 (defvar elpher-gemini-response)
 777
 778 (defun elpher-get-gemini-response (address after)
 779   "Retrieve gemini ADDRESS, then execute AFTER.
 780 The response is stored in the variable ‘elpher-gemini-response’."
 781   (setq elpher-gemini-response "")
 782   (if (not (gnutls-available-p))
 783       (error "Cannot establish gemini connection: GnuTLS not available")
 784     (condition-case the-error
 785         (let* ((kill-buffer-query-functions nil)
 786                (network-security-level 'medium)
 787                (proc (open-network-stream "elpher-process"
 788                                           nil
 789                                           (elpher-address-host address)
 790                                           (elpher-address-port address)
 791                                           :type 'tls)))
 792           (set-process-coding-system proc 'binary)
 793           (set-process-filter proc
 794                               (lambda (_proc string)
 795                                 (setq elpher-gemini-response
 796                                       (concat elpher-gemini-response string))))
 797           (set-process-sentinel proc after)
 798           (let ((inhibit-eol-conversion t))
 799             (process-send-string proc
 800                                  (concat (elpher-address-to-url address) "\r\n"))))
 801       (error
 802        (error "Error initiating connection to server")))))
 803
 804 (defun elpher-parse-gemini-response (response)
 805   "Parse the RESPONSE string and return a list of components
 806 The list is of the form (code meta body). A response of nil implies
 807 that the response was malformed."
 808   (let ((header-end-idx (string-match "\r\n" response)))
 809     (if header-end-idx
 810         (let ((header (string-trim (substring response 0 header-end-idx)))
 811               (body (substring response (+ header-end-idx 2))))
 812           (if (>= (length header) 2)
 813               (let ((code (substring header 0 2))
 814                     (meta (string-trim (substring header 2))))
 815                 (list code meta body))
 816             (error "Malformed response: No response status found in header %s" header)))
 817       (error "Malformed response: No CRLF-delimited header found"))))
 818
 819
 820 (defun elpher-process-gemini-response (renderer)
 821   "Process the gemini response and pass the result to RENDERER.
 822 The response is assumed to be in the variable `elpher-gemini-response'."
 823   (condition-case the-error
 824       (let ((response-components (elpher-parse-gemini-response elpher-gemini-response)))
 825         (let ((response-code (elt response-components 0))
 826               (response-meta (elt response-components 1))
 827               (response-body (elt response-components 2)))
 828           (pcase (elt response-code 0)
 829             (?1 ; Input required
 830              (elpher-with-clean-buffer
 831               (insert "Gemini server is requesting input."))
 832              (let* ((query-string (read-string (concat response-meta ": ")))
 833                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 834                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 835                (elpher-get-gemini-response query-address
 836                                            (lambda (_proc event)
 837                                              (unless (string-prefix-p "deleted" event)
 838                                                (funcall #'elpher-process-gemini-response
 839                                                         renderer)
 840                                                (elpher-restore-pos))))))
 841             (?2 ; Normal response
 842              ;; (message response-header)
 843              (funcall renderer response-body response-meta))
 844             (?3 ; Redirect
 845              (message "Following redirect to %s" response-meta)
 846              (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 847                (elpher-get-gemini-response redirect-address
 848                                            (lambda (_proc event)
 849                                              (unless (string-prefix-p "deleted" event)
 850                                                (funcall #'elpher-process-gemini-response
 851                                                         renderer)
 852                                                (elpher-restore-pos))))))
 853             (?4 ; Temporary failure
 854              (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
 855                     response-code response-meta))
 856             (?5 ; Permanent failure
 857              (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
 858                     response-code response-meta))
 859             (?6 ; Client certificate required
 860              (error "Gemini server requires client certificate (unsupported at this time)"))
 861             (_other
 862              (error "Gemini server response unknown: %s %s"
 863                     response-code response-meta)))))
 864     (error
 865      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 866
 867 (defun elpher-get-gemini-node (renderer)
 868   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 869   (let* ((address (elpher-node-address elpher-current-node))
 870          (content (elpher-get-cached-content address)))
 871     (condition-case the-error
 872         (if (and content (funcall renderer nil))
 873             (elpher-with-clean-buffer
 874               (insert content)
 875               (elpher-restore-pos))
 876           (elpher-with-clean-buffer
 877            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 878           (elpher-get-gemini-response address
 879                                       (lambda (_proc event)
 880                                         (unless (string-prefix-p "deleted" event)
 881                                           (funcall #'elpher-process-gemini-response
 882                                                    renderer)
 883                                           (elpher-restore-pos)))))
 884       (error
 885        (elpher-network-error address the-error)))))
 886
 887
 888 (defun elpher-render-gemini (body &optional mime-type-string)
 889   "Render gemini response BODY with rendering MIME-TYPE-STRING."
 890   (if (not body)
 891       t
 892     (let* ((mime-type-string* (if (or (not mime-type-string)
 893                                       (string-empty-p mime-type-string))
 894                                   "text/gemini; charset=utf-8"
 895                                 mime-type-string))
 896            (mime-type-split (split-string mime-type-string* ";" t))
 897            (mime-type (string-trim (car mime-type-split)))
 898            (parameters (mapcar (lambda (s)
 899                                  (let ((key-val (split-string s "=")))
 900                                    (list (downcase (string-trim (car key-val)))
 901                                          (downcase (string-trim (cadr key-val))))))
 902                                (cdr mime-type-split))))
 903       (when (string-prefix-p "text/" mime-type)
 904         (setq body (decode-coding-string
 905                     body
 906                     (if (assoc "charset" parameters)
 907                         (intern (cadr (assoc "charset" parameters)))
 908                       'utf-8)))
 909         (setq body (replace-regexp-in-string "\r" "" body)))
 910       (pcase mime-type
 911         ((or "text/gemini" "")
 912          (elpher-render-gemini-map body parameters))
 913         ((pred (string-prefix-p "text/"))
 914          (elpher-render-gemini-plain-text body parameters))
 915         ((pred (string-prefix-p "image/"))
 916          (elpher-render-image body))
 917         (_other
 918          (error "Unsupported MIME type %S" mime-type))))))
 919
 920 (defun elpher-gemini-get-link-url (line)
 921   "Extract the url portion of LINE, a gemini map file link line."
 922   (string-trim (elt (split-string (substring line 2)) 0)))
 923
 924 (defun elpher-gemini-get-link-display-string (line)
 925   "Extract the display string portion of LINE, a gemini map file link line."
 926   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 927          (idx (string-match "[ \t]" rest)))
 928     (if idx
 929         (string-trim (substring rest (+ idx 1)))
 930       "")))
 931
 932 (defun elpher-collapse-dot-sequences (filename)
 933   "Collapse dot sequences in FILENAME.
 934 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
 935   (let* ((path (split-string filename "/"))
 936          (path-reversed-normalized
 937           (seq-reduce (lambda (a b)
 938                         (cond ((and a (equal b "..") (cdr a)))
 939                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
 940                               ((equal b ".") a)
 941                               (t (cons b a))))
 942                       path nil)))
 943     (string-join (reverse path-reversed-normalized) "/")))
 944
 945 (defun elpher-address-from-gemini-url (url)
 946   "Extract address from URL with defaults as per gemini map files."
 947   (let ((address (url-generic-parse-url url)))
 948     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 949       (setf (url-fullness address) t)
 950       (unless (url-host address) ;if there is an explicit host, filenames are absolute
 951         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 952         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 953           (setf (url-filename address)
 954                 (concat (file-name-directory
 955                          (url-filename (elpher-node-address elpher-current-node)))
 956                         (url-filename address)))))
 957       (unless (url-type address)
 958         (setf (url-type address) "gemini"))
 959       (if (equal (url-type address) "gemini")
 960           (setf (url-filename address)
 961                 (elpher-collapse-dot-sequences (url-filename address)))))
 962     address))
 963
 964 (defun elpher-render-gemini-map (data _parameters)
 965   "Render DATA as a gemini map file, PARAMETERS is currently unused."
 966   (elpher-with-clean-buffer
 967    (dolist (line (split-string data "\n"))
 968      (if (string-prefix-p "=>" line)
 969          (let* ((url (elpher-gemini-get-link-url line))
 970                 (display-string (elpher-gemini-get-link-display-string line))
 971                 (address (elpher-address-from-gemini-url url)))
 972            (if (> (length display-string) 0)
 973                (elpher-insert-index-record display-string address)
 974              (elpher-insert-index-record url address)))
 975        (elpher-insert-index-record line)))
 976    (elpher-cache-content
 977     (elpher-node-address elpher-current-node)
 978     (buffer-string))))
 979
 980 (defun elpher-render-gemini-plain-text (data _parameters)
 981   "Render DATA as plain text file.  PARAMETERS is currently unused."
 982   (elpher-with-clean-buffer
 983    (insert (elpher-buttonify-urls data))
 984    (elpher-cache-content
 985     (elpher-node-address elpher-current-node)
 986     (buffer-string))))
 987
 988 ;; Other URL node opening
 989
 990 (defun elpher-get-other-url-node (renderer)
 991   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 992   (when renderer
 993     (elpher-visit-parent-node)
 994     (error "Command not supported for general URLs"))
 995   (let* ((address (elpher-node-address elpher-current-node))
 996          (url (elpher-address-to-url address)))
 997     (progn
 998       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 999       (message "Opening URL...")
1000       (if elpher-open-urls-with-eww
1001           (browse-web url)
1002         (browse-url url)))))
1003
1004 ;; Telnet node connection
1005
1006 (defun elpher-get-telnet-node (renderer)
1007   "Opens a telnet connection to the current node address (RENDERER must be nil)."
1008   (when renderer
1009     (elpher-visit-parent-node)
1010     (error "Command not supported for telnet URLs"))
1011   (let* ((address (elpher-node-address elpher-current-node))
1012          (host (elpher-address-host address))
1013          (port (elpher-address-port address)))
1014     (elpher-visit-parent-node)
1015     (telnet host port)))
1016
1017 ;; Start page node retrieval
1018
1019 (defun elpher-get-start-node (renderer)
1020   "Getter which displays the start page (RENDERER must be nil)."
1021   (when renderer
1022     (elpher-visit-parent-node)
1023     (error "Command not supported for start page"))
1024   (elpher-with-clean-buffer
1025    (insert "     --------------------------------------------\n"
1026            "                Elpher Gopher Client             \n"
1027            "                   version " elpher-version "\n"
1028            "     --------------------------------------------\n"
1029            "\n"
1030            "Default bindings:\n"
1031            "\n"
1032            " - TAB/Shift-TAB: next/prev item on current page\n"
1033            " - RET/mouse-1: open item under cursor\n"
1034            " - m: select an item on current page by name (autocompletes)\n"
1035            " - u/mouse-3: return to previous page\n"
1036            " - o/O: visit different selector or the root menu of the current server\n"
1037            " - g: go to a particular gopher address\n"
1038            " - d/D: download item under cursor or current page\n"
1039            " - i/I: info on item under cursor or current page\n"
1040            " - c/C: copy URL representation of item under cursor or current page\n"
1041            " - a/A: bookmark the item under cursor or current page\n"
1042            " - x/X: remove bookmark for item under cursor or current page\n"
1043            " - B: visit the bookmarks page\n"
1044            " - r: redraw current page (using cached contents if available)\n"
1045            " - R: reload current page (regenerates cache)\n"
1046            " - S: set character coding system for gopher (default is to autodetect)\n"
1047            " - T: toggle TLS gopher mode\n"
1048            " - .: display the raw server response for the current page\n"
1049            "\n"
1050            "Start your exploration of gopher space:\n")
1051    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1052                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1053    (insert "\n"
1054            "Alternatively, select the following item and enter some search terms:\n")
1055    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
1056                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1057    (insert "\n"
1058            "This page contains your bookmarked sites (also visit with B):\n")
1059    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1060    (insert "\n"
1061            "** Refer to the ")
1062    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1063      (insert-text-button "Elpher info manual"
1064                          'face 'link
1065                          'action (lambda (_)
1066                                    (interactive)
1067                                    (info "(elpher)"))
1068                          'follow-link t
1069                          'help-echo help-string))
1070    (insert " for the full documentation. **\n")
1071    (insert (propertize
1072             (concat "  (This should be available if you have installed Elpher using\n"
1073                     "   MELPA. Otherwise you will have to install the manual yourself.)")
1074             'face 'shadow))
1075    (elpher-restore-pos)))
1076
1077 ;; Bookmarks page node retrieval
1078
1079 (defun elpher-get-bookmarks-node (renderer)
1080   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1081   (when renderer
1082     (elpher-visit-parent-node)
1083     (error "Command not supported for bookmarks page"))
1084   (elpher-with-clean-buffer
1085    (insert "---- Bookmark list ----\n\n")
1086    (let ((bookmarks (elpher-load-bookmarks)))
1087      (if bookmarks
1088          (dolist (bookmark bookmarks)
1089            (let ((display-string (elpher-bookmark-display-string bookmark))
1090                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1091              (elpher-insert-index-record display-string address)))
1092        (insert "No bookmarks found.\n")))
1093    (insert "\n-----------------------\n\n"
1094            "- u: return to previous page\n"
1095            "- x: delete selected bookmark\n"
1096            "- a: rename selected bookmark\n\n"
1097            "Bookmarks are stored in the file "
1098            (locate-user-emacs-file "elpher-bookmarks"))
1099    (elpher-restore-pos)))
1100
1101
1102 ;;; Bookmarks
1103 ;;
1104
1105 (defun elpher-make-bookmark (display-string url)
1106   "Make an elpher bookmark.
1107 DISPLAY-STRING determines how the bookmark will appear in the
1108 bookmark list, while URL is the url of the entry."
1109   (list display-string url))
1110
1111 (defun elpher-bookmark-display-string (bookmark)
1112   "Get the display string of BOOKMARK."
1113   (elt bookmark 0))
1114
1115 (defun elpher-set-bookmark-display-string (bookmark display-string)
1116   "Set the display string of BOOKMARK to DISPLAY-STRING."
1117   (setcar bookmark display-string))
1118
1119 (defun elpher-bookmark-url (bookmark)
1120   "Get the address for BOOKMARK."
1121   (elt bookmark 1))
1122
1123 (defun elpher-save-bookmarks (bookmarks)
1124   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1125 Beware that this completely replaces the existing contents of the file."
1126   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
1127     (erase-buffer)
1128     (insert "; Elpher bookmarks file\n\n"
1129             "; Bookmarks are stored as a list of (label URL) items.\n"
1130             "; Feel free to edit by hand, but take care to ensure\n"
1131             "; the list structure remains intact.\n\n")
1132     (pp bookmarks (current-buffer))))
1133
1134 (defun elpher-load-bookmarks ()
1135   "Get the list of bookmarks from the users's bookmark file."
1136   (let ((bookmarks
1137          (with-temp-buffer
1138            (ignore-errors
1139              (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
1140              (goto-char (point-min))
1141              (read (current-buffer))))))
1142     (if (and bookmarks (listp (cadar bookmarks)))
1143         (progn
1144           (message "Reading old bookmark file. (Will be updated on write.)")
1145           (mapcar (lambda (old-bm)
1146                     (list (car old-bm)
1147                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1148                                                         (cadr old-bm)))))
1149                   bookmarks))
1150       bookmarks)))
1151
1152 (defun elpher-add-address-bookmark (address display-string)
1153   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1154 If ADDRESS is already bookmarked, update the label only."
1155   (let ((bookmarks (elpher-load-bookmarks))
1156         (url (elpher-address-to-url address)))
1157     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1158       (if existing-bookmark
1159           (elpher-set-bookmark-display-string existing-bookmark display-string)
1160         (push (elpher-make-bookmark display-string url) bookmarks)))
1161     (elpher-save-bookmarks bookmarks)))
1162
1163 (defun elpher-remove-address-bookmark (address)
1164   "Remove any bookmark to ADDRESS."
1165   (let ((url (elpher-address-to-url address)))
1166     (elpher-save-bookmarks
1167      (seq-filter (lambda (bookmark)
1168                    (not (equal (elpher-bookmark-url bookmark) url)))
1169                  (elpher-load-bookmarks)))))
1170
1171 ;;; Interactive procedures
1172 ;;
1173
1174 (defun elpher-next-link ()
1175   "Move point to the next link on the current page."
1176   (interactive)
1177   (forward-button 1))
1178
1179 (defun elpher-prev-link ()
1180   "Move point to the previous link on the current page."
1181   (interactive)
1182   (backward-button 1))
1183
1184 (defun elpher-follow-current-link ()
1185   "Open the link or url at point."
1186   (interactive)
1187   (push-button))
1188
1189 (defun elpher-go ()
1190   "Go to a particular gopher site read from the minibuffer."
1191   (interactive)
1192   (let ((node
1193          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1194            (elpher-make-node host-or-url
1195                              (elpher-address-from-url host-or-url)))))
1196     (switch-to-buffer "*elpher*")
1197     (elpher-visit-node node)))
1198
1199 (defun elpher-go-current ()
1200   "Go to a particular site read from the minibuffer, initialized with the current URL."
1201   (interactive)
1202   (let ((address (elpher-node-address elpher-current-node)))
1203     (if (elpher-address-special-p address)
1204         (error "Command invalid for this page")
1205       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1206         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1207
1208 (defun elpher-redraw ()
1209   "Redraw current page."
1210   (interactive)
1211   (if elpher-current-node
1212       (elpher-visit-node elpher-current-node)
1213     (message "No current site.")))
1214
1215 (defun elpher-reload ()
1216   "Reload current page."
1217   (interactive)
1218   (if elpher-current-node
1219       (elpher-reload-current-node)
1220     (message "No current site.")))
1221
1222 (defun elpher-toggle-tls ()
1223   "Toggle TLS encryption mode for gopher."
1224   (interactive)
1225   (setq elpher-use-tls (not elpher-use-tls))
1226   (if elpher-use-tls
1227       (if (gnutls-available-p)
1228           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1229         (setq elpher-use-tls nil)
1230         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1231     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1232
1233 (defun elpher-view-raw ()
1234   "View raw server response for current page."
1235   (interactive)
1236   (if elpher-current-node
1237       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1238           (error "This page was not generated by a server")
1239         (elpher-visit-node elpher-current-node
1240                            #'elpher-render-raw))
1241     (message "No current site.")))
1242
1243 (defun elpher-back ()
1244   "Go to previous site."
1245   (interactive)
1246   (if (elpher-node-parent elpher-current-node)
1247       (elpher-visit-parent-node)
1248     (error "No previous site")))
1249
1250 (defun elpher-download ()
1251   "Download the link at point."
1252   (interactive)
1253   (let ((button (button-at (point))))
1254     (if button
1255         (let ((node (button-get button 'elpher-node)))
1256           (if (elpher-address-special-p (elpher-node-address node))
1257               (error "Cannot download %s"
1258                      (elpher-node-display-string node))
1259             (elpher-visit-node (button-get button 'elpher-node)
1260                                #'elpher-render-download)))
1261       (error "No link selected"))))
1262
1263 (defun elpher-download-current ()
1264   "Download the current page."
1265   (interactive)
1266   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1267       (error "Cannot download %s"
1268              (elpher-node-display-string elpher-current-node))
1269     (elpher-visit-node (elpher-make-node
1270                         (elpher-node-display-string elpher-current-node)
1271                         (elpher-node-address elpher-current-node)
1272                         elpher-current-node)
1273                        #'elpher-render-download
1274                        t)))
1275
1276 (defun elpher-build-link-map ()
1277   "Build alist mapping link names to destination nodes in current buffer."
1278   (let ((link-map nil)
1279         (b (next-button (point-min) t)))
1280     (while b
1281       (push (cons (button-label b) b) link-map)
1282       (setq b (next-button (button-start b))))
1283     link-map))
1284
1285 (defun elpher-jump ()
1286   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1287   (interactive)
1288   (let* ((link-map (elpher-build-link-map)))
1289     (if link-map
1290         (let ((key (let ((completion-ignore-case t))
1291                      (completing-read "Directory item/link: "
1292                                       link-map nil t))))
1293           (if (and key (> (length key) 0))
1294               (let ((b (cdr (assoc key link-map))))
1295                 (goto-char (button-start b))
1296                 (button-activate b)))))))
1297
1298 (defun elpher-root-dir ()
1299   "Visit root of current server."
1300   (interactive)
1301   (let ((address (elpher-node-address elpher-current-node)))
1302     (if (not (elpher-address-special-p address))
1303         (if (or (member (url-filename address) '("/" ""))
1304                 (and (elpher-address-gopher-p address)
1305                      (= (length (elpher-gopher-address-selector address)) 0)))
1306             (error "Already at root directory of current server")
1307           (let ((address-copy (elpher-address-from-url
1308                                (elpher-address-to-url address))))
1309             (setf (url-filename address-copy) "")
1310             (elpher-visit-node
1311              (elpher-make-node (elpher-address-to-url address-copy)
1312                                address-copy))))
1313       (error "Command invalid for %s" (elpher-node-display-string elpher-current-node)))))
1314
1315 (defun elpher-bookmarks-current-p ()
1316   "Return non-nil if current node is a bookmarks page."
1317   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1318          '(special bookmarks)))
1319
1320 (defun elpher-reload-bookmarks ()
1321   "Reload bookmarks if current node is a bookmarks page."
1322   (if (elpher-bookmarks-current-p)
1323       (elpher-reload-current-node)))
1324
1325 (defun elpher-bookmark-current ()
1326   "Bookmark the current node."
1327   (interactive)
1328   (let ((address (elpher-node-address elpher-current-node))
1329         (display-string (elpher-node-display-string elpher-current-node)))
1330     (if (not (elpher-address-special-p address))
1331         (let ((bookmark-display-string (read-string "Bookmark display string: "
1332                                                     display-string)))
1333           (elpher-add-address-bookmark address bookmark-display-string)
1334           (message "Bookmark added."))
1335       (error "Cannot bookmark %s" display-string))))
1336
1337 (defun elpher-bookmark-link ()
1338   "Bookmark the link at point."
1339   (interactive)
1340   (let ((button (button-at (point))))
1341     (if button
1342         (let* ((node (button-get button 'elpher-node))
1343                (address (elpher-node-address node))
1344                (display-string (elpher-node-display-string node)))
1345           (if (not (elpher-address-special-p address))
1346               (let ((bookmark-display-string (read-string "Bookmark display string: "
1347                                                           display-string)))
1348                 (elpher-add-address-bookmark address bookmark-display-string)
1349                 (elpher-reload-bookmarks)
1350                 (message "Bookmark added."))
1351             (error "Cannot bookmark %s" display-string)))
1352       (error "No link selected"))))
1353
1354 (defun elpher-unbookmark-current ()
1355   "Remove bookmark for the current node."
1356   (interactive)
1357   (let ((address (elpher-node-address elpher-current-node)))
1358     (unless (elpher-address-special-p address)
1359       (elpher-remove-address-bookmark address)
1360       (message "Bookmark removed."))))
1361
1362 (defun elpher-unbookmark-link ()
1363   "Remove bookmark for the link at point."
1364   (interactive)
1365   (let ((button (button-at (point))))
1366     (if button
1367         (let ((node (button-get button 'elpher-node)))
1368           (elpher-remove-address-bookmark (elpher-node-address node))
1369           (elpher-reload-bookmarks)
1370           (message "Bookmark removed."))
1371       (error "No link selected"))))
1372
1373 (defun elpher-bookmarks ()
1374   "Visit bookmarks page."
1375   (interactive)
1376   (switch-to-buffer "*elpher*")
1377   (elpher-visit-node
1378    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1379
1380 (defun elpher-info-node (node)
1381   "Display information on NODE."
1382   (let ((display-string (elpher-node-display-string node))
1383         (address (elpher-node-address node)))
1384     (if (elpher-address-special-p address)
1385         (message "Special page: %s" display-string)
1386       (message "%s" (elpher-address-to-url address)))))
1387
1388 (defun elpher-info-link ()
1389   "Display information on node corresponding to link at point."
1390   (interactive)
1391   (let ((button (button-at (point))))
1392     (if button
1393         (elpher-info-node (button-get button 'elpher-node))
1394       (error "No item selected"))))
1395
1396 (defun elpher-info-current ()
1397   "Display information on current node."
1398   (interactive)
1399   (elpher-info-node elpher-current-node))
1400
1401 (defun elpher-copy-node-url (node)
1402   "Copy URL representation of address of NODE to `kill-ring'."
1403   (let ((address (elpher-node-address node)))
1404     (if (elpher-address-special-p address)
1405         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1406       (let ((url (elpher-address-to-url address)))
1407         (message "Copied \"%s\" to kill-ring/clipboard." url)
1408         (kill-new url)))))
1409
1410 (defun elpher-copy-link-url ()
1411   "Copy URL of item at point to `kill-ring'."
1412   (interactive)
1413   (let ((button (button-at (point))))
1414     (if button
1415         (elpher-copy-node-url (button-get button 'elpher-node))
1416       (error "No item selected"))))
1417
1418 (defun elpher-copy-current-url ()
1419   "Copy URL of current node to `kill-ring'."
1420   (interactive)
1421   (elpher-copy-node-url elpher-current-node))
1422
1423 (defun elpher-set-gopher-coding-system ()
1424   "Specify an explicit character coding system for gopher selectors."
1425   (interactive)
1426   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1427     (setq elpher-user-coding-system system)
1428     (if system
1429         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1430       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1431
1432
1433 ;;; Mode and keymap
1434 ;;
1435
1436 (defvar elpher-mode-map
1437   (let ((map (make-sparse-keymap)))
1438     (define-key map (kbd "TAB") 'elpher-next-link)
1439     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1440     (define-key map (kbd "u") 'elpher-back)
1441     (define-key map [mouse-3] 'elpher-back)
1442     (define-key map (kbd "O") 'elpher-root-dir)
1443     (define-key map (kbd "g") 'elpher-go)
1444     (define-key map (kbd "o") 'elpher-go-current)
1445     (define-key map (kbd "r") 'elpher-redraw)
1446     (define-key map (kbd "R") 'elpher-reload)
1447     (define-key map (kbd "T") 'elpher-toggle-tls)
1448     (define-key map (kbd ".") 'elpher-view-raw)
1449     (define-key map (kbd "d") 'elpher-download)
1450     (define-key map (kbd "D") 'elpher-download-current)
1451     (define-key map (kbd "m") 'elpher-jump)
1452     (define-key map (kbd "i") 'elpher-info-link)
1453     (define-key map (kbd "I") 'elpher-info-current)
1454     (define-key map (kbd "c") 'elpher-copy-link-url)
1455     (define-key map (kbd "C") 'elpher-copy-current-url)
1456     (define-key map (kbd "a") 'elpher-bookmark-link)
1457     (define-key map (kbd "A") 'elpher-bookmark-current)
1458     (define-key map (kbd "x") 'elpher-unbookmark-link)
1459     (define-key map (kbd "X") 'elpher-unbookmark-current)
1460     (define-key map (kbd "B") 'elpher-bookmarks)
1461     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1462     (when (fboundp 'evil-define-key*)
1463       (evil-define-key* 'motion map
1464         (kbd "TAB") 'elpher-next-link
1465         (kbd "C-") 'elpher-follow-current-link
1466         (kbd "C-t") 'elpher-back
1467         (kbd "u") 'elpher-back
1468         [mouse-3] 'elpher-back
1469         (kbd "g") 'elpher-go
1470         (kbd "o") 'elpher-go-current
1471         (kbd "r") 'elpher-redraw
1472         (kbd "R") 'elpher-reload
1473         (kbd "T") 'elpher-toggle-tls
1474         (kbd ".") 'elpher-view-raw
1475         (kbd "d") 'elpher-download
1476         (kbd "D") 'elpher-download-current
1477         (kbd "m") 'elpher-jump
1478         (kbd "i") 'elpher-info-link
1479         (kbd "I") 'elpher-info-current
1480         (kbd "c") 'elpher-copy-link-url
1481         (kbd "C") 'elpher-copy-current-url
1482         (kbd "a") 'elpher-bookmark-link
1483         (kbd "A") 'elpher-bookmark-current
1484         (kbd "x") 'elpher-unbookmark-link
1485         (kbd "X") 'elpher-unbookmark-current
1486         (kbd "B") 'elpher-bookmarks
1487         (kbd "S") 'elpher-set-gopher-coding-system))
1488     map)
1489   "Keymap for gopher client.")
1490
1491 (define-derived-mode elpher-mode special-mode "elpher"
1492   "Major mode for elpher, an elisp gopher client.
1493
1494 This mode is automatically enabled by the interactive
1495 functions which initialize the gopher client, namely
1496 `elpher', `elpher-go' and `elpher-bookmarks'.")
1497
1498 (when (fboundp 'evil-set-initial-state)
1499   (evil-set-initial-state 'elpher-mode 'motion))
1500
1501
1502 ;;; Main start procedure
1503 ;;
1504
1505 ;;;###autoload
1506 (defun elpher ()
1507   "Start elpher with default landing page."
1508   (interactive)
1509   (if (get-buffer "*elpher*")
1510       (switch-to-buffer "*elpher*")
1511     (switch-to-buffer "*elpher*")
1512     (setq elpher-current-node nil)
1513     (let ((start-node (elpher-make-node "Elpher Start Page"
1514                                         (elpher-make-special-address 'start))))
1515       (elpher-visit-node start-node)))
1516   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1517
1518 ;;; elpher.el ends here