elpher.el

   1 ;;; elpher.el --- A friendly gopher client.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.3.5
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption,
  40 ;; - basic support for the fledgling Gemini protocol.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Full instructions can be found in the Elpher info manual.
  47
  48 ;; Elpher is under active development.  Any suggestions for
  49 ;; improvements are welcome!
  50
  51 ;;; Code:
  52
  53 (provide 'elpher)
  54
  55 ;;; Dependencies
  56 ;;
  57
  58 (require 'seq)
  59 (require 'pp)
  60 (require 'shr)
  61 (require 'url-util)
  62 (require 'subr-x)
  63
  64
  65 ;;; Global constants
  66 ;;
  67
  68 (defconst elpher-version "2.3.5"
  69   "Current version of elpher.")
  70
  71 (defconst elpher-margin-width 6
  72   "Width of left-hand margin used when rendering indicies.")
  73
  74 (defconst elpher-type-map
  75   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  76     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  77     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  78     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  79     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  80     ((gopher ?9) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  81     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  83     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  84     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  85     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  86     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  87     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  88     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  89     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  90     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  91     ((special bookmarks) elpher-get-bookmarks-node nil)
  92     ((special start) elpher-get-start-node nil))
  93   "Association list from types to getters, renderers, margin codes and index faces.")
  94
  95
  96 ;;; Customization group
  97 ;;
  98
  99 (defgroup elpher nil
 100   "A gopher client."
 101   :group 'applications)
 102
 103 ;; Face customizations
 104
 105 (defface elpher-index
 106   '((t :inherit font-lock-keyword-face))
 107   "Face used for directory type directory records.")
 108
 109 (defface elpher-text
 110   '((t :inherit bold))
 111   "Face used for text type directory records.")
 112
 113 (defface elpher-info
 114   '((t :inherit default))
 115   "Face used for info type directory records.")
 116
 117 (defface elpher-image
 118   '((t :inherit font-lock-string-face))
 119   "Face used for image type directory records.")
 120
 121 (defface elpher-search
 122   '((t :inherit warning))
 123   "Face used for search type directory records.")
 124
 125 (defface elpher-html
 126   '((t :inherit font-lock-comment-face))
 127   "Face used for html type directory records.")
 128
 129 (defface elpher-gemini
 130   '((t :inherit font-lock-regexp-grouping-backslash))
 131   "Face used for html type directory records.")
 132
 133 (defface elpher-other-url
 134   '((t :inherit font-lock-comment-face))
 135   "Face used for other URL type links records.")
 136
 137 (defface elpher-telnet
 138   '((t :inherit font-lock-function-name-face))
 139   "Face used for telnet type directory records.")
 140
 141 (defface elpher-binary
 142   '((t :inherit font-lock-doc-face))
 143   "Face used for binary type directory records.")
 144
 145 (defface elpher-unknown
 146   '((t :inherit error))
 147   "Face used for directory records with unknown/unsupported types.")
 148
 149 (defface elpher-margin-key
 150   '((t :inherit bold))
 151   "Face used for directory margin key.")
 152
 153 (defface elpher-margin-brackets
 154   '((t :inherit shadow))
 155   "Face used for brackets around directory margin key.")
 156
 157 ;; Other customizations
 158
 159 (defcustom elpher-open-urls-with-eww nil
 160   "If non-nil, open URL selectors using eww.
 161 Otherwise, use the system browser via the BROWSE-URL function."
 162   :type '(boolean))
 163
 164 (defcustom elpher-buttonify-urls-in-directories t
 165   "If non-nil, turns URLs matched in directories into clickable buttons."
 166   :type '(boolean))
 167
 168 (defcustom elpher-use-header t
 169   "If non-nil, display current node information in buffer header."
 170   :type '(boolean))
 171
 172 (defcustom elpher-auto-disengage-TLS nil
 173   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 174 While enabling this may seem convenient, it is also potentially dangerous as it
 175 allows switching from an encrypted channel back to plain text without user input."
 176   :type '(boolean))
 177
 178
 179 ;;; Model
 180 ;;
 181
 182 ;; Address
 183
 184 ;; An elpher "address" object is either a url object or a symbol.
 185 ;; Symbol addresses are "special", corresponding to pages generated
 186 ;; dynamically for and by elpher.  All others represent pages which
 187 ;; rely on content retrieved over the network.
 188
 189 (defun elpher-address-from-url (url-string)
 190   "Create a ADDRESS object corresponding to the given URL-STRING."
 191   (let ((data (match-data))) ; Prevent parsing clobbering match data
 192     (unwind-protect
 193         (let ((url (url-generic-parse-url url-string)))
 194           (unless (and (not (url-fullness url)) (url-type url))
 195             (setf (url-fullness url) t)
 196             (setf (url-filename url)
 197                   (url-unhex-string (url-filename url)))
 198             (unless (url-type url)
 199               (setf (url-type url) "gopher"))
 200             (when (or (equal "gopher" (url-type url))
 201                       (equal "gophers" (url-type url)))
 202               ;; Gopher defaults
 203               (unless (url-host url)
 204                 (setf (url-host url) (url-filename url))
 205                 (setf (url-filename url) ""))
 206               (when (or (equal (url-filename url) "")
 207                         (equal (url-filename url) "/"))
 208                 (setf (url-filename url) "/1")))
 209             (when (equal "gemini" (url-type url))
 210               ;; Gemini defaults
 211               (if (equal (url-filename url) "")
 212                   (setf (url-filename url) "/"))))
 213           url)
 214       (set-match-data data))))
 215
 216 (defun elpher-make-gopher-address (type selector host port &optional tls)
 217   "Create an ADDRESS object using gopher directory record attributes.
 218 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 219 If the optional attribute TLS is non-nil, the address will be marked as
 220 requiring gopher-over-TLS."
 221   (cond
 222    ((and (equal type ?h)
 223          (string-prefix-p "URL:" selector))
 224     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 225    ((equal type ?8)
 226     (elpher-address-from-url
 227      (concat "telnet"
 228              "://" host
 229              ":" (number-to-string port))))
 230    (t
 231     (elpher-address-from-url
 232      (concat "gopher" (if tls "s" "")
 233              "://" host
 234              ":" (number-to-string port)
 235              "/" (string type)
 236              selector)))))
 237
 238 (defun elpher-make-special-address (type)
 239   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 240   type)
 241
 242 (defun elpher-address-to-url (address)
 243   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 244   (if (not (elpher-address-special-p address))
 245       (url-encode-url (url-recreate-url address))
 246     nil))
 247
 248 (defun elpher-address-type (address)
 249   "Retrieve type of ADDRESS object.
 250 This is used to determine how to retrieve and render the document the
 251 address refers to, via the table `elpher-type-map'."
 252   (if (symbolp address)
 253       (list 'special address)
 254     (let ((protocol (url-type address)))
 255       (cond ((or (equal protocol "gopher")
 256                  (equal protocol "gophers"))
 257              (list 'gopher
 258                    (if (member (url-filename address) '("" "/"))
 259                        ?1
 260                      (string-to-char (substring (url-filename address) 1)))))
 261             ((equal protocol "gemini")
 262              'gemini)
 263             ((equal protocol "telnet")
 264              'telnet)
 265             (t 'other-url)))))
 266
 267 (defun elpher-address-protocol (address)
 268   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 269   (if (symbolp address)
 270       nil
 271     (url-type address)))
 272
 273 (defun elpher-address-filename (address)
 274   "Retrieve the filename component of ADDRESS.
 275 For gopher addresses this is a combination of the selector type and selector."
 276   (if (symbolp address)
 277       nil
 278     (url-filename address)))
 279
 280 (defun elpher-address-host (address)
 281   "Retrieve host from ADDRESS object."
 282   (url-host address))
 283
 284 (defun elpher-address-port (address)
 285   "Retrieve port from ADDRESS object."
 286   (if (symbolp address)
 287       nil)
 288   (if (> (url-port address) 0)
 289       (url-port address)
 290     (or (and (or (equal (url-type address) "gopher")
 291                  (equal (url-type address) "gophers"))
 292              70)
 293         (and (equal (url-type address) "gemini")
 294              1965))))
 295
 296 (defun elpher-address-special-p (address)
 297   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 298   (symbolp address))
 299
 300 (defun elpher-address-gopher-p (address)
 301   "Return non-nill if ADDRESS object is a gopher address."
 302   (and (not (elpher-address-special-p address))
 303        (member (elpher-address-protocol address) '("gopher gophers"))))
 304
 305 (defun elpher-gopher-address-selector (address)
 306   "Retrieve gopher selector from ADDRESS object."
 307   (if (member (url-filename address) '("" "/"))
 308       ""
 309     (substring (url-filename address) 2)))
 310
 311 ;; Node
 312
 313 (defun elpher-make-node (display-string address &optional parent)
 314   "Create a node in the page hierarchy.
 315
 316 DISPLAY-STRING records the display string used for the page.
 317
 318 ADDRESS specifies the address object of the page.
 319
 320 The optional PARENT specifies the parent node in the hierarchy.
 321 This is set every time the node is visited, so while it forms
 322 an important part of the node data there is no need to set it
 323 initially."
 324   (list display-string address parent))
 325
 326 (defun elpher-node-display-string (node)
 327   "Retrieve the display string of NODE."
 328   (elt node 0))
 329
 330 (defun elpher-node-address (node)
 331   "Retrieve the ADDRESS object of NODE."
 332   (elt node 1))
 333
 334 (defun elpher-node-parent (node)
 335   "Retrieve the parent node of NODE."
 336   (elt node 2))
 337
 338 (defun elpher-set-node-parent (node parent)
 339   "Set the parent node of NODE to be PARENT."
 340   (setcar (cdr (cdr node)) parent))
 341
 342 ;; Cache
 343
 344 (defvar elpher-content-cache (make-hash-table :test 'equal))
 345 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 346
 347 (defun elpher-get-cached-content (address)
 348   "Retrieve the cached content for ADDRESS, or nil if none exists."
 349   (gethash address elpher-content-cache))
 350
 351 (defun elpher-cache-content (address content)
 352   "Set the content cache for ADDRESS to CONTENT."
 353   (puthash address content elpher-content-cache))
 354
 355 (defun elpher-get-cached-pos (address)
 356   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 357   (gethash address elpher-pos-cache))
 358
 359 (defun elpher-cache-pos (address pos)
 360   "Set the cursor position cache for ADDRESS to POS."
 361   (puthash address pos elpher-pos-cache))
 362
 363 ;; Node graph traversal
 364
 365 (defvar elpher-current-node nil)
 366
 367 (defun elpher-visit-node (node &optional renderer preserve-parent)
 368   "Visit NODE using its own renderer or RENDERER, if non-nil.
 369 Additionally, set the parent of NODE to `elpher-current-node',
 370 unless PRESERVE-PARENT is non-nil."
 371   (elpher-save-pos)
 372   (elpher-process-cleanup)
 373   (unless preserve-parent
 374     (if (and (elpher-node-parent elpher-current-node)
 375              (equal (elpher-node-address elpher-current-node)
 376                     (elpher-node-address node)))
 377         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 378       (elpher-set-node-parent node elpher-current-node)))
 379   (setq elpher-current-node node)
 380   (let* ((address (elpher-node-address node))
 381          (type (elpher-address-type address))
 382          (type-record (cdr (assoc type elpher-type-map))))
 383     (if type-record
 384         (funcall (car type-record)
 385                  (if renderer
 386                      renderer
 387                    (cadr type-record)))
 388       (elpher-visit-parent-node)
 389       (pcase type
 390         (`(gopher ,type-char)
 391          (error "Unsupported gopher selector type '%c' for '%s'"
 392                 type-char (elpher-address-to-url address)))
 393         (other
 394          (error "Unsupported address type '%S' for '%s'"
 395                 other (elpher-address-to-url address)))))))
 396
 397 (defun elpher-visit-parent-node ()
 398   "Visit the parent of the current node."
 399   (let ((parent-node (elpher-node-parent elpher-current-node)))
 400     (when parent-node
 401       (elpher-visit-node parent-node nil t))))
 402
 403 (defun elpher-reload-current-node ()
 404   "Reload the current node, discarding any existing cached content."
 405   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 406   (elpher-visit-node elpher-current-node))
 407
 408 (defun elpher-save-pos ()
 409   "Save the current position of point to the current node."
 410   (when elpher-current-node
 411     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 412
 413 (defun elpher-restore-pos ()
 414   "Restore the position of point to that cached in the current node."
 415   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 416     (if pos
 417         (goto-char pos)
 418       (goto-char (point-min)))))
 419
 420
 421 ;;; Buffer preparation
 422 ;;
 423
 424 (defun elpher-update-header ()
 425   "If `elpher-use-header' is true, display current node info in window header."
 426   (if elpher-use-header
 427       (let* ((display-string (elpher-node-display-string elpher-current-node))
 428              (address (elpher-node-address elpher-current-node))
 429              (url-string (if (elpher-address-special-p address)
 430                              ""
 431                            (concat "  -  " (elpher-address-to-url address) "")))
 432              (header (replace-regexp-in-string "%" "%%" (concat display-string
 433                                                                 url-string))))
 434         (setq header-line-format header))))
 435
 436 (defmacro elpher-with-clean-buffer (&rest args)
 437   "Evaluate ARGS with a clean *elpher* buffer as current."
 438   (list 'with-current-buffer "*elpher*"
 439         '(elpher-mode)
 440         (append (list 'let '((inhibit-read-only t))
 441                       '(erase-buffer)
 442                       '(elpher-update-header))
 443                 args)))
 444
 445
 446 ;;; Text Processing
 447 ;;
 448
 449 (defvar elpher-user-coding-system nil
 450   "User-specified coding system to use for decoding text responses.")
 451
 452 (defun elpher-decode (string)
 453   "Decode STRING using autodetected or user-specified coding system."
 454   (decode-coding-string string
 455                         (if elpher-user-coding-system
 456                             elpher-user-coding-system
 457                           (detect-coding-string string t))))
 458
 459 (defun elpher-preprocess-text-response (string)
 460   "Preprocess text selector response contained in STRING.
 461 This involes decoding the character representation, and clearing
 462 away CRs and any terminating period."
 463   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 464                                            (replace-regexp-in-string "\r" "" string))))
 465
 466
 467 ;;; Network error reporting
 468 ;;
 469
 470 (defun elpher-network-error (address error)
 471   "Display ERROR message following unsuccessful negotiation with ADDRESS."
 472   (elpher-with-clean-buffer
 473    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 474            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 475            (error-message-string error) "\n"
 476            (propertize "\n----------------\n\n" 'face 'error)
 477            "Press 'u' to return to the previous page.")))
 478
 479
 480 ;;; Gopher selector retrieval
 481 ;;
 482
 483 (defun elpher-process-cleanup ()
 484   "Immediately shut down any extant elpher process."
 485   (let ((p (get-process "elpher-process")))
 486     (if p (delete-process p))))
 487
 488 (defvar elpher-use-tls nil
 489   "If non-nil, use TLS to communicate with gopher servers.")
 490
 491 (defvar elpher-selector-string)
 492
 493 (defun elpher-get-selector (address after &optional propagate-error)
 494   "Retrieve selector specified by ADDRESS, then execute AFTER.
 495 The result is stored as a string in the variable ‘elpher-selector-string’.
 496
 497 Usually errors result in an error page being displayed.  This is only
 498 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 499 is non-nil, this message is not displayed.  Instead, the error propagates
 500 up to the calling function."
 501   (setq elpher-selector-string "")
 502   (when (equal (elpher-address-protocol address) "gophers")
 503       (if (gnutls-available-p)
 504           (when (not elpher-use-tls)
 505             (setq elpher-use-tls t)
 506             (message "Engaging TLS gopher mode."))
 507         (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 508   (condition-case the-error
 509       (let* ((kill-buffer-query-functions nil)
 510              (proc (open-network-stream "elpher-process"
 511                                        nil
 512                                        (elpher-address-host address)
 513                                        (elpher-address-port address)
 514                                        :type (if elpher-use-tls 'tls 'plain))))
 515         (set-process-coding-system proc 'binary)
 516         (set-process-filter proc
 517                             (lambda (_proc string)
 518                               (setq elpher-selector-string
 519                                     (concat elpher-selector-string string))))
 520         (set-process-sentinel proc after)
 521         (let ((inhibit-eol-conversion t))
 522           (process-send-string proc
 523                                (concat (elpher-gopher-address-selector address) "\r\n"))))
 524     (error
 525      (if (and (consp the-error)
 526               (eq (car the-error) 'gnutls-error)
 527               (not (equal (elpher-address-protocol address) "gophers"))
 528               (or elpher-auto-disengage-TLS
 529                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 530          (progn
 531            (message "Disengaging TLS gopher mode.")
 532            (setq elpher-use-tls nil)
 533            (elpher-get-selector address after))
 534        (elpher-process-cleanup)
 535        (if propagate-error
 536            (error the-error)
 537          (elpher-with-clean-buffer
 538           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 539                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 540                   (propertize "\n----------------\n\n" 'face 'error)
 541                   "Press 'u' to return to the previous page.")))))))
 542
 543 (defun elpher-get-gopher-node (renderer)
 544   "Getter function for gopher nodes.
 545 The RENDERER procedure is used to display the contents of the node
 546 once they are retrieved from the gopher server."
 547   (let* ((address (elpher-node-address elpher-current-node))
 548          (content (elpher-get-cached-content address)))
 549     (if (and content (funcall renderer nil))
 550         (elpher-with-clean-buffer
 551          (insert content)
 552          (elpher-restore-pos))
 553       (elpher-with-clean-buffer
 554        (insert "LOADING... (use 'u' to cancel)"))
 555       (elpher-get-selector address
 556                            (lambda (_proc event)
 557                              (unless (string-prefix-p "deleted" event)
 558                                (funcall renderer elpher-selector-string)
 559                                (elpher-restore-pos)))))))
 560
 561 ;; Index rendering
 562
 563 (defun elpher-insert-index (string)
 564   "Insert the index corresponding to STRING into the current buffer."
 565   ;; Should be able to split directly on CRLF, but some non-conformant
 566   ;; LF-only servers sadly exist, hence the following.
 567   (let ((str-processed (elpher-preprocess-text-response string)))
 568     (dolist (line (split-string str-processed "\n"))
 569       (ignore-errors
 570         (unless (= (length line) 0)
 571           (let* ((type (elt line 0))
 572                  (fields (split-string (substring line 1) "\t"))
 573                  (display-string (elt fields 0))
 574                  (selector (elt fields 1))
 575                  (host (elt fields 2))
 576                  (port (if (elt fields 3)
 577                            (string-to-number (elt fields 3))
 578                          nil))
 579                  (address (elpher-make-gopher-address type selector host port)))
 580             (elpher-insert-index-record display-string address)))))))
 581
 582 (defun elpher-insert-margin (&optional type-name)
 583   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 584   (if type-name
 585       (progn
 586         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 587                         (concat
 588                          (propertize "[" 'face 'elpher-margin-brackets)
 589                          (propertize type-name 'face 'elpher-margin-key)
 590                          (propertize "]" 'face 'elpher-margin-brackets))))
 591         (insert " "))
 592     (insert (make-string elpher-margin-width ?\s))))
 593
 594 (defun elpher-node-button-help (node)
 595   "Return a string containing the help text for a button corresponding to NODE."
 596   (let ((address (elpher-node-address node)))
 597     (format "mouse-1, RET: open '%s'" (elpher-address-to-url address))))
 598
 599 (defun elpher-insert-index-record (display-string &optional address)
 600   "Function to insert an index record into the current buffer.
 601 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 602 If ADDRESS is not supplied or nil the record is rendered as an
 603 'information' line."
 604   (let* ((type (if address (elpher-address-type address) nil))
 605          (type-map-entry (cdr (assoc type elpher-type-map))))
 606     (if type-map-entry
 607         (let* ((margin-code (elt type-map-entry 2))
 608                (face (elt type-map-entry 3))
 609                (node (elpher-make-node display-string address)))
 610           (elpher-insert-margin margin-code)
 611           (insert-text-button display-string
 612                               'face face
 613                               'elpher-node node
 614                               'action #'elpher-click-link
 615                               'follow-link t
 616                               'help-echo (elpher-node-button-help node)))
 617       (pcase type
 618         ((or '(gopher ?i) 'nil) ;; Information
 619          (elpher-insert-margin)
 620          (let ((propertized-display-string
 621                 (propertize display-string 'face 'elpher-info)))
 622            (insert (if elpher-buttonify-urls-in-directories
 623                        (elpher-buttonify-urls propertized-display-string)
 624                      propertized-display-string))))
 625         (`(gopher ,selector-type) ;; Unknown
 626          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 627          (insert (propertize display-string
 628                              'face 'elpher-unknown)))))
 629     (insert "\n")))
 630
 631 (defun elpher-click-link (button)
 632   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 633   (let ((node (button-get button 'elpher-node)))
 634     (elpher-visit-node node)))
 635
 636 (defun elpher-render-index (data &optional _mime-type-string)
 637   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 638   (elpher-with-clean-buffer
 639    (if (not data)
 640        t
 641      (elpher-insert-index data)
 642      (elpher-cache-content (elpher-node-address elpher-current-node)
 643                            (buffer-string)))))
 644
 645 ;; Text rendering
 646
 647 (defconst elpher-url-regex
 648   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.]*[0-9a-zA-Z\-_~?/@|]\\)?\\)?"
 649   "Regexp used to locate and buttniofy URLs in text files loaded by elpher.")
 650
 651 (defun elpher-buttonify-urls (string)
 652   "Turn substrings which look like urls in STRING into clickable buttons."
 653   (with-temp-buffer
 654     (insert string)
 655     (goto-char (point-min))
 656     (while (re-search-forward elpher-url-regex nil t)
 657       (let ((node (elpher-make-node (substring-no-properties (match-string 0))
 658                                     (elpher-address-from-url (match-string 0)))))
 659           (make-text-button (match-beginning 0)
 660                             (match-end 0)
 661                             'elpher-node  node
 662                             'action #'elpher-click-link
 663                             'follow-link t
 664                             'help-echo (elpher-node-button-help node)
 665                             'face 'button)))
 666     (buffer-string)))
 667
 668 (defun elpher-render-text (data &optional _mime-type-string)
 669   "Render DATA as text.  MIME-TYPE-STRING is unused."
 670   (elpher-with-clean-buffer
 671    (if (not data)
 672        t
 673      (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 674      (elpher-cache-content
 675       (elpher-node-address elpher-current-node)
 676       (buffer-string)))))
 677
 678 ;; Image retrieval
 679
 680 (defun elpher-render-image (data &optional _mime-type-string)
 681   "Display DATA as image.  MIME-TYPE-STRING is unused."
 682   (if (not data)
 683       nil
 684     (if (display-images-p)
 685         (progn
 686           (let ((image (create-image
 687                         data
 688                         nil t)))
 689             (elpher-with-clean-buffer
 690              (insert-image image)
 691              (elpher-restore-pos))))
 692       (elpher-render-download data))))
 693
 694 ;; Search retrieval and rendering
 695
 696 (defun elpher-get-gopher-query-node (renderer)
 697   "Getter for gopher addresses requiring input.
 698 The response is rendered using the rendering function RENDERER."
 699    (let* ((address (elpher-node-address elpher-current-node))
 700           (content (elpher-get-cached-content address))
 701           (aborted t))
 702     (if (and content (funcall renderer nil))
 703         (elpher-with-clean-buffer
 704          (insert content)
 705          (elpher-restore-pos)
 706          (message "Displaying cached search results.  Reload to perform a new search."))
 707       (unwind-protect
 708           (let* ((query-string (read-string "Query: "))
 709                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 710                  (search-address (elpher-make-gopher-address ?1
 711                                                              query-selector
 712                                                              (elpher-address-host address)
 713                                                              (elpher-address-port address)
 714                                                              (equal (elpher-address-type address) "gophers"))))
 715             (setq aborted nil)
 716
 717             (elpher-with-clean-buffer
 718              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 719             (elpher-get-selector search-address
 720                                  (lambda (_proc event)
 721                                    (unless (string-prefix-p "deleted" event)
 722                                      (funcall renderer elpher-selector-string)
 723                                      (elpher-restore-pos)))))
 724         (if aborted
 725             (elpher-visit-parent-node))))))
 726
 727 ;; Raw server response rendering
 728
 729 (defun elpher-render-raw (data &optional _mime-type-string)
 730   "Display raw DATA in buffer.  MIME-TYPE-STRING is unused."
 731   (if (not data)
 732       nil
 733     (elpher-with-clean-buffer
 734      (insert data)
 735      (goto-char (point-min)))
 736     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 737
 738 ;; File save "rendering"
 739
 740 (defun elpher-render-download (data &optional _mime-type-string)
 741   "Save DATA to file.  MIME-TYPE-STRING is unused."
 742   (if (not data)
 743       nil
 744     (let* ((address (elpher-node-address elpher-current-node))
 745            (selector (elpher-gopher-address-selector address)))
 746       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 747       (let* ((filename-proposal (file-name-nondirectory selector))
 748              (filename (read-file-name "Download complete. Save file as: "
 749                                        nil nil nil
 750                                        (if (> (length filename-proposal) 0)
 751                                            filename-proposal
 752                                          "download.file"))))
 753         (let ((coding-system-for-write 'binary))
 754           (with-temp-file filename
 755             (insert data)))
 756         (message (format "Saved to file %s." filename))))))
 757
 758 ;; HTML rendering
 759
 760 (defun elpher-render-html (data &optional _mime-type-string)
 761   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 762   (elpher-with-clean-buffer
 763    (if (not data)
 764        t
 765      (let ((dom (with-temp-buffer
 766                   (insert data)
 767                   (libxml-parse-html-region (point-min) (point-max)))))
 768        (shr-insert-document dom)))))
 769
 770 ;; Gemini node retrieval
 771
 772 (defvar elpher-gemini-response)
 773
 774 (defun elpher-get-gemini-response (address after)
 775   "Retrieve gemini ADDRESS, then execute AFTER.
 776 The response is stored in the variable ‘elpher-gemini-response’."
 777   (setq elpher-gemini-response "")
 778   (if (not (gnutls-available-p))
 779       (error "Cannot establish gemini connection: GnuTLS not available")
 780     (condition-case the-error
 781         (let* ((kill-buffer-query-functions nil)
 782                (proc (open-network-stream "elpher-process"
 783                                           nil
 784                                           (elpher-address-host address)
 785                                           (elpher-address-port address)
 786                                           :type 'tls)))
 787           (set-process-coding-system proc 'binary)
 788           (set-process-filter proc
 789                               (lambda (_proc string)
 790                                 (setq elpher-gemini-response
 791                                       (concat elpher-gemini-response string))))
 792           (set-process-sentinel proc after)
 793           (let ((inhibit-eol-conversion t))
 794             (process-send-string proc
 795                                  (concat (elpher-address-to-url address) "\r\n"))))
 796       (error
 797        (error "Error initiating connection to server")))))
 798
 799 (defun elpher-parse-gemini-response (response)
 800   "Parse the RESPONSE string and return a list of components
 801 The list is of the form (code meta body). A response of nil implies
 802 that the response was malformed."
 803   (let ((header-end-idx (string-match "\r\n" response)))
 804     (if header-end-idx
 805         (let ((header (string-trim (substring response 0 header-end-idx)))
 806               (body (substring response (+ header-end-idx 2))))
 807           (if (>= (length header) 2)
 808               (let ((code (substring header 0 2))
 809                     (meta (string-trim (substring header 2))))
 810                 (list code meta body))
 811             (error "Malformed response: No response status found in header %s" header)))
 812       (error "Malformed response: No CRLF-delimited header found"))))
 813
 814
 815 (defun elpher-process-gemini-response (renderer)
 816   "Process the gemini response and pass the result to RENDERER.
 817 The response is assumed to be in the variable `elpher-gemini-response'."
 818   (condition-case the-error
 819       (let ((response-components (elpher-parse-gemini-response elpher-gemini-response)))
 820         (let ((response-code (elt response-components 0))
 821               (response-meta (elt response-components 1))
 822               (response-body (elt response-components 2)))
 823           (pcase (elt response-code 0)
 824             (?1 ; Input required
 825              (elpher-with-clean-buffer
 826               (insert "Gemini server is requesting input."))
 827              (let* ((query-string (read-string (concat response-meta ": ")))
 828                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 829                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 830                (elpher-get-gemini-response query-address
 831                                            (lambda (_proc event)
 832                                              (unless (string-prefix-p "deleted" event)
 833                                                (funcall #'elpher-process-gemini-response
 834                                                         renderer)
 835                                                (elpher-restore-pos))))))
 836             (?2 ; Normal response
 837              ;; (message response-header)
 838              (funcall renderer response-body response-meta))
 839             (?3 ; Redirect
 840              (message "Following redirect to %s" response-meta)
 841              (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 842                (elpher-get-gemini-response redirect-address
 843                                            (lambda (_proc event)
 844                                              (unless (string-prefix-p "deleted" event)
 845                                                (funcall #'elpher-process-gemini-response
 846                                                         renderer)
 847                                                (elpher-restore-pos))))))
 848             (?4 ; Temporary failure
 849              (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
 850                     response-code response-meta))
 851             (?5 ; Permanent failure
 852              (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
 853                     response-code response-meta))
 854             (?6 ; Client certificate required
 855              (error "Gemini server requires client certificate (unsupported at this time)"))
 856             (_other
 857              (error "Gemini server response unknown: %s %s"
 858                     response-code response-meta)))))
 859     (error
 860      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 861
 862 (defun elpher-get-gemini-node (renderer)
 863   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 864   (let* ((address (elpher-node-address elpher-current-node))
 865          (content (elpher-get-cached-content address)))
 866     (condition-case the-error
 867         (if (and content (funcall renderer nil))
 868             (elpher-with-clean-buffer
 869               (insert content)
 870               (elpher-restore-pos))
 871           (elpher-with-clean-buffer
 872            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 873           (elpher-get-gemini-response address
 874                                       (lambda (_proc event)
 875                                         (unless (string-prefix-p "deleted" event)
 876                                           (funcall #'elpher-process-gemini-response
 877                                                    renderer)
 878                                           (elpher-restore-pos)))))
 879       (error
 880        (elpher-network-error address the-error)))))
 881
 882
 883 (defun elpher-render-gemini (body &optional mime-type-string)
 884   "Render gemini response BODY with rendering MIME-TYPE-STRING."
 885   (if (not body)
 886       t
 887     (let* ((mime-type-string* (if (or (not mime-type-string)
 888                                       (string-empty-p mime-type-string))
 889                                   "text/gemini; charset=utf-8"
 890                                 mime-type-string))
 891            (mime-type-split (split-string mime-type-string* ";" t))
 892            (mime-type (string-trim (car mime-type-split)))
 893            (parameters (mapcar (lambda (s)
 894                                  (let ((key-val (split-string s "=")))
 895                                    (list (downcase (string-trim (car key-val)))
 896                                          (downcase (string-trim (cadr key-val))))))
 897                                (cdr mime-type-split))))
 898       (when (string-prefix-p "text/" mime-type)
 899         (setq body (decode-coding-string
 900                     body
 901                     (if (assoc "charset" parameters)
 902                         (intern (cadr (assoc "charset" parameters)))
 903                       'utf-8)))
 904         (setq body (replace-regexp-in-string "\r" "" body)))
 905       (pcase mime-type
 906         ((or "text/gemini" "")
 907          (elpher-render-gemini-map body parameters))
 908         ((pred (string-prefix-p "text/"))
 909          (elpher-render-gemini-plain-text body parameters))
 910         ((pred (string-prefix-p "image/"))
 911          (elpher-render-image body))
 912         (_other
 913          (error "Unsupported MIME type %S" mime-type))))))
 914
 915 (defun elpher-gemini-get-link-url (line)
 916   "Extract the url portion of LINE, a gemini map file link line."
 917   (string-trim (elt (split-string (substring line 2)) 0)))
 918
 919 (defun elpher-gemini-get-link-display-string (line)
 920   "Extract the display string portion of LINE, a gemini map file link line."
 921   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 922          (idx (string-match "[ \t]" rest)))
 923     (if idx
 924         (string-trim (substring rest (+ idx 1)))
 925       "")))
 926
 927 (defun elpher-collapse-dot-sequences (filename)
 928   "Collapse dot sequences in FILENAME.
 929 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
 930   (let* ((path (split-string filename "/"))
 931          (path-reversed-normalized
 932           (seq-reduce (lambda (a b)
 933                         (cond ((and a (equal b "..") (cdr a)))
 934                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
 935                               ((equal b ".") a)
 936                               (t (cons b a))))
 937                       path nil)))
 938     (string-join (reverse path-reversed-normalized) "/")))
 939
 940 (defun elpher-address-from-gemini-url (url)
 941   "Extract address from URL with defaults as per gemini map files."
 942   (let ((address (url-generic-parse-url url)))
 943     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 944       (setf (url-fullness address) t)
 945       (unless (url-host address) ;if there is an explicit host, filenames are absolute
 946         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 947         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 948           (setf (url-filename address)
 949                 (concat (file-name-directory
 950                          (url-filename (elpher-node-address elpher-current-node)))
 951                         (url-filename address)))))
 952       (unless (url-type address)
 953         (setf (url-type address) "gemini"))
 954       (if (equal (url-type address) "gemini")
 955           (setf (url-filename address)
 956                 (elpher-collapse-dot-sequences (url-filename address)))))
 957     address))
 958
 959 (defun elpher-render-gemini-map (data _parameters)
 960   "Render DATA as a gemini map file, PARAMETERS is currently unused."
 961   (elpher-with-clean-buffer
 962    (dolist (line (split-string data "\n"))
 963      (if (string-prefix-p "=>" line)
 964          (let* ((url (elpher-gemini-get-link-url line))
 965                 (display-string (elpher-gemini-get-link-display-string line))
 966                 (address (elpher-address-from-gemini-url url)))
 967            (if (> (length display-string) 0)
 968                (elpher-insert-index-record display-string address)
 969              (elpher-insert-index-record url address)))
 970        (elpher-insert-index-record line)))
 971    (elpher-cache-content
 972     (elpher-node-address elpher-current-node)
 973     (buffer-string))))
 974
 975 (defun elpher-render-gemini-plain-text (data _parameters)
 976   "Render DATA as plain text file.  PARAMETERS is currently unused."
 977   (elpher-with-clean-buffer
 978    (insert (elpher-buttonify-urls data))
 979    (elpher-cache-content
 980     (elpher-node-address elpher-current-node)
 981     (buffer-string))))
 982
 983 ;; Other URL node opening
 984
 985 (defun elpher-get-other-url-node (renderer)
 986   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 987   (when renderer
 988     (elpher-visit-parent-node)
 989     (error "Command not supported for general URLs"))
 990   (let* ((address (elpher-node-address elpher-current-node))
 991          (url (elpher-address-to-url address)))
 992     (progn
 993       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 994       (message "Opening URL...")
 995       (if elpher-open-urls-with-eww
 996           (browse-web url)
 997         (browse-url url)))))
 998
 999 ;; Telnet node connection
1000
1001 (defun elpher-get-telnet-node (renderer)
1002   "Opens a telnet connection to the current node address (RENDERER must be nil)."
1003   (when renderer
1004     (elpher-visit-parent-node)
1005     (error "Command not supported for telnet URLs"))
1006   (let* ((address (elpher-node-address elpher-current-node))
1007          (host (elpher-address-host address))
1008          (port (elpher-address-port address)))
1009     (elpher-visit-parent-node)
1010     (telnet host port)))
1011
1012 ;; Start page node retrieval
1013
1014 (defun elpher-get-start-node (renderer)
1015   "Getter which displays the start page (RENDERER must be nil)."
1016   (when renderer
1017     (elpher-visit-parent-node)
1018     (error "Command not supported for start page"))
1019   (elpher-with-clean-buffer
1020    (insert "     --------------------------------------------\n"
1021            "                Elpher Gopher Client             \n"
1022            "                   version " elpher-version "\n"
1023            "     --------------------------------------------\n"
1024            "\n"
1025            "Default bindings:\n"
1026            "\n"
1027            " - TAB/Shift-TAB: next/prev item on current page\n"
1028            " - RET/mouse-1: open item under cursor\n"
1029            " - m: select an item on current page by name (autocompletes)\n"
1030            " - u/mouse-3: return to previous page\n"
1031            " - o/O: visit different selector or the root menu of the current server\n"
1032            " - g: go to a particular gopher address\n"
1033            " - d/D: download item under cursor or current page\n"
1034            " - i/I: info on item under cursor or current page\n"
1035            " - c/C: copy URL representation of item under cursor or current page\n"
1036            " - a/A: bookmark the item under cursor or current page\n"
1037            " - x/X: remove bookmark for item under cursor or current page\n"
1038            " - B: visit the bookmarks page\n"
1039            " - r: redraw current page (using cached contents if available)\n"
1040            " - R: reload current page (regenerates cache)\n"
1041            " - S: set character coding system for gopher (default is to autodetect)\n"
1042            " - T: toggle TLS gopher mode\n"
1043            " - .: display the raw server response for the current page\n"
1044            "\n"
1045            "Start your exploration of gopher space:\n")
1046    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1047                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1048    (insert "\n"
1049            "Alternatively, select the following item and enter some search terms:\n")
1050    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
1051                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1052    (insert "\n"
1053            "** Refer to the ")
1054    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1055      (insert-text-button "Elpher info manual"
1056                          'face 'link
1057                          'action (lambda (_)
1058                                    (interactive)
1059                                    (info "(elpher)"))
1060                          'follow-link t
1061                          'help-echo help-string))
1062    (insert " for the full documentation. **\n")
1063    (insert (propertize
1064             (concat "  (This should be available if you have installed Elpher using\n"
1065                     "   MELPA. Otherwise you will have to install the manual yourself.)")
1066             'face 'shadow))
1067    (elpher-restore-pos)))
1068
1069 ;; Bookmarks page node retrieval
1070
1071 (defun elpher-get-bookmarks-node (renderer)
1072   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1073   (when renderer
1074     (elpher-visit-parent-node)
1075     (error "Command not supported for bookmarks page"))
1076   (elpher-with-clean-buffer
1077    (insert "---- Bookmark list ----\n\n")
1078    (let ((bookmarks (elpher-load-bookmarks)))
1079      (if bookmarks
1080          (dolist (bookmark bookmarks)
1081            (let ((display-string (elpher-bookmark-display-string bookmark))
1082                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1083              (elpher-insert-index-record display-string address)))
1084        (insert "No bookmarks found.\n")))
1085    (insert "\n-----------------------\n\n"
1086            "- u: return to previous page\n"
1087            "- x: delete selected bookmark\n"
1088            "- a: rename selected bookmark\n\n"
1089            "Bookmarks are stored in the file "
1090            (locate-user-emacs-file "elpher-bookmarks"))
1091    (elpher-restore-pos)))
1092
1093
1094 ;;; Bookmarks
1095 ;;
1096
1097 (defun elpher-make-bookmark (display-string url)
1098   "Make an elpher bookmark.
1099 DISPLAY-STRING determines how the bookmark will appear in the
1100 bookmark list, while URL is the url of the entry."
1101   (list display-string url))
1102
1103 (defun elpher-bookmark-display-string (bookmark)
1104   "Get the display string of BOOKMARK."
1105   (elt bookmark 0))
1106
1107 (defun elpher-set-bookmark-display-string (bookmark display-string)
1108   "Set the display string of BOOKMARK to DISPLAY-STRING."
1109   (setcar bookmark display-string))
1110
1111 (defun elpher-bookmark-url (bookmark)
1112   "Get the address for BOOKMARK."
1113   (elt bookmark 1))
1114
1115 (defun elpher-save-bookmarks (bookmarks)
1116   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1117 Beware that this completely replaces the existing contents of the file."
1118   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
1119     (erase-buffer)
1120     (insert "; Elpher bookmarks file\n\n"
1121             "; Bookmarks are stored as a list of (label URL) items.\n"
1122             "; Feel free to edit by hand, but take care to ensure\n"
1123             "; the list structure remains intact.\n\n")
1124     (pp bookmarks (current-buffer))))
1125
1126 (defun elpher-load-bookmarks ()
1127   "Get the list of bookmarks from the users's bookmark file."
1128   (let ((bookmarks
1129          (with-temp-buffer
1130            (ignore-errors
1131              (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
1132              (goto-char (point-min))
1133              (read (current-buffer))))))
1134     (if (and bookmarks (listp (cadar bookmarks)))
1135         (progn
1136           (message "Reading old bookmark file. (Will be updated on write.)")
1137           (mapcar (lambda (old-bm)
1138                     (list (car old-bm)
1139                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1140                                                         (cadr old-bm)))))
1141                   bookmarks))
1142       bookmarks)))
1143
1144 (defun elpher-add-address-bookmark (address display-string)
1145   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1146 If ADDRESS is already bookmarked, update the label only."
1147   (let ((bookmarks (elpher-load-bookmarks))
1148         (url (elpher-address-to-url address)))
1149     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1150       (if existing-bookmark
1151           (elpher-set-bookmark-display-string existing-bookmark display-string)
1152         (push (elpher-make-bookmark display-string url) bookmarks)))
1153     (elpher-save-bookmarks bookmarks)))
1154
1155 (defun elpher-remove-address-bookmark (address)
1156   "Remove any bookmark to ADDRESS."
1157   (let ((url (elpher-address-to-url address)))
1158     (elpher-save-bookmarks
1159      (seq-filter (lambda (bookmark)
1160                    (not (equal (elpher-bookmark-url bookmark) url)))
1161                  (elpher-load-bookmarks)))))
1162
1163 ;;; Interactive procedures
1164 ;;
1165
1166 (defun elpher-next-link ()
1167   "Move point to the next link on the current page."
1168   (interactive)
1169   (forward-button 1))
1170
1171 (defun elpher-prev-link ()
1172   "Move point to the previous link on the current page."
1173   (interactive)
1174   (backward-button 1))
1175
1176 (defun elpher-follow-current-link ()
1177   "Open the link or url at point."
1178   (interactive)
1179   (push-button))
1180
1181 (defun elpher-go ()
1182   "Go to a particular gopher site read from the minibuffer."
1183   (interactive)
1184   (let ((node
1185          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1186            (elpher-make-node host-or-url
1187                              (elpher-address-from-url host-or-url)))))
1188     (switch-to-buffer "*elpher*")
1189     (elpher-visit-node node)))
1190
1191 (defun elpher-go-current ()
1192   "Go to a particular site read from the minibuffer, initialized with the current URL."
1193   (interactive)
1194   (let ((address (elpher-node-address elpher-current-node)))
1195     (if (elpher-address-special-p address)
1196         (error "Command invalid for this page")
1197       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1198         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1199
1200 (defun elpher-redraw ()
1201   "Redraw current page."
1202   (interactive)
1203   (if elpher-current-node
1204       (elpher-visit-node elpher-current-node)
1205     (message "No current site.")))
1206
1207 (defun elpher-reload ()
1208   "Reload current page."
1209   (interactive)
1210   (if elpher-current-node
1211       (elpher-reload-current-node)
1212     (message "No current site.")))
1213
1214 (defun elpher-toggle-tls ()
1215   "Toggle TLS encryption mode for gopher."
1216   (interactive)
1217   (setq elpher-use-tls (not elpher-use-tls))
1218   (if elpher-use-tls
1219       (if (gnutls-available-p)
1220           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1221         (setq elpher-use-tls nil)
1222         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1223     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1224
1225 (defun elpher-view-raw ()
1226   "View raw server response for current page."
1227   (interactive)
1228   (if elpher-current-node
1229       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1230           (error "This page was not generated by a server")
1231         (elpher-visit-node elpher-current-node
1232                            #'elpher-render-raw))
1233     (message "No current site.")))
1234
1235 (defun elpher-back ()
1236   "Go to previous site."
1237   (interactive)
1238   (if (elpher-node-parent elpher-current-node)
1239       (elpher-visit-parent-node)
1240     (error "No previous site")))
1241
1242 (defun elpher-download ()
1243   "Download the link at point."
1244   (interactive)
1245   (let ((button (button-at (point))))
1246     (if button
1247         (let ((node (button-get button 'elpher-node)))
1248           (if (elpher-address-special-p (elpher-node-address node))
1249               (error "Cannot download %s"
1250                      (elpher-node-display-string node))
1251             (elpher-visit-node (button-get button 'elpher-node)
1252                                #'elpher-render-download)))
1253       (error "No link selected"))))
1254
1255 (defun elpher-download-current ()
1256   "Download the current page."
1257   (interactive)
1258   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1259       (error "Cannot download %s"
1260              (elpher-node-display-string elpher-current-node))
1261     (elpher-visit-node (elpher-make-node
1262                         (elpher-node-display-string elpher-current-node)
1263                         (elpher-node-address elpher-current-node)
1264                         elpher-current-node)
1265                        #'elpher-render-download
1266                        t)))
1267
1268 (defun elpher-build-link-map ()
1269   "Build alist mapping link names to destination nodes in current buffer."
1270   (let ((link-map nil)
1271         (b (next-button (point-min) t)))
1272     (while b
1273       (push (cons (button-label b) b) link-map)
1274       (setq b (next-button (button-start b))))
1275     link-map))
1276
1277 (defun elpher-jump ()
1278   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1279   (interactive)
1280   (let* ((link-map (elpher-build-link-map)))
1281     (if link-map
1282         (let ((key (let ((completion-ignore-case t))
1283                      (completing-read "Directory item/link: "
1284                                       link-map nil t))))
1285           (if (and key (> (length key) 0))
1286               (let ((b (cdr (assoc key link-map))))
1287                 (goto-char (button-start b))
1288                 (button-activate b)))))))
1289
1290 (defun elpher-root-dir ()
1291   "Visit root of current server."
1292   (interactive)
1293   (let ((address (elpher-node-address elpher-current-node)))
1294     (if (not (elpher-address-special-p address))
1295         (if (or (member (url-filename address) '("/" ""))
1296                 (and (elpher-address-gopher-p address)
1297                      (= (length (elpher-gopher-address-selector address)) 0)))
1298             (error "Already at root directory of current server")
1299           (let ((address-copy (elpher-address-from-url
1300                                (elpher-address-to-url address))))
1301             (setf (url-filename address-copy) "")
1302             (elpher-visit-node
1303              (elpher-make-node (elpher-address-to-url address-copy)
1304                                address-copy))))
1305       (error "Command invalid for %s" (elpher-node-display-string elpher-current-node)))))
1306
1307 (defun elpher-bookmarks-current-p ()
1308   "Return non-nil if current node is a bookmarks page."
1309   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1310          '(special bookmarks)))
1311
1312 (defun elpher-reload-bookmarks ()
1313   "Reload bookmarks if current node is a bookmarks page."
1314   (if (elpher-bookmarks-current-p)
1315       (elpher-reload-current-node)))
1316
1317 (defun elpher-bookmark-current ()
1318   "Bookmark the current node."
1319   (interactive)
1320   (let ((address (elpher-node-address elpher-current-node))
1321         (display-string (elpher-node-display-string elpher-current-node)))
1322     (if (not (elpher-address-special-p address))
1323         (let ((bookmark-display-string (read-string "Bookmark display string: "
1324                                                     display-string)))
1325           (elpher-add-address-bookmark address bookmark-display-string)
1326           (message "Bookmark added."))
1327       (error "Cannot bookmark %s" display-string))))
1328
1329 (defun elpher-bookmark-link ()
1330   "Bookmark the link at point."
1331   (interactive)
1332   (let ((button (button-at (point))))
1333     (if button
1334         (let* ((node (button-get button 'elpher-node))
1335                (address (elpher-node-address node))
1336                (display-string (elpher-node-display-string node)))
1337           (if (not (elpher-address-special-p address))
1338               (let ((bookmark-display-string (read-string "Bookmark display string: "
1339                                                           display-string)))
1340                 (elpher-add-address-bookmark address bookmark-display-string)
1341                 (elpher-reload-bookmarks)
1342                 (message "Bookmark added."))
1343             (error "Cannot bookmark %s" display-string)))
1344       (error "No link selected"))))
1345
1346 (defun elpher-unbookmark-current ()
1347   "Remove bookmark for the current node."
1348   (interactive)
1349   (let ((address (elpher-node-address elpher-current-node)))
1350     (unless (elpher-address-special-p address)
1351       (elpher-remove-address-bookmark address)
1352       (message "Bookmark removed."))))
1353
1354 (defun elpher-unbookmark-link ()
1355   "Remove bookmark for the link at point."
1356   (interactive)
1357   (let ((button (button-at (point))))
1358     (if button
1359         (let ((node (button-get button 'elpher-node)))
1360           (elpher-remove-address-bookmark (elpher-node-address node))
1361           (elpher-reload-bookmarks)
1362           (message "Bookmark removed."))
1363       (error "No link selected"))))
1364
1365 (defun elpher-bookmarks ()
1366   "Visit bookmarks page."
1367   (interactive)
1368   (switch-to-buffer "*elpher*")
1369   (elpher-visit-node
1370    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1371
1372 (defun elpher-info-node (node)
1373   "Display information on NODE."
1374   (let ((display-string (elpher-node-display-string node))
1375         (address (elpher-node-address node)))
1376     (if (elpher-address-special-p address)
1377         (message "Special page: %s" display-string)
1378       (message "%s" (elpher-address-to-url address)))))
1379
1380 (defun elpher-info-link ()
1381   "Display information on node corresponding to link at point."
1382   (interactive)
1383   (let ((button (button-at (point))))
1384     (if button
1385         (elpher-info-node (button-get button 'elpher-node))
1386       (error "No item selected"))))
1387
1388 (defun elpher-info-current ()
1389   "Display information on current node."
1390   (interactive)
1391   (elpher-info-node elpher-current-node))
1392
1393 (defun elpher-copy-node-url (node)
1394   "Copy URL representation of address of NODE to `kill-ring'."
1395   (let ((address (elpher-node-address node)))
1396     (if (elpher-address-special-p address)
1397         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1398       (let ((url (elpher-address-to-url address)))
1399         (message "Copied \"%s\" to kill-ring/clipboard." url)
1400         (kill-new url)))))
1401
1402 (defun elpher-copy-link-url ()
1403   "Copy URL of item at point to `kill-ring'."
1404   (interactive)
1405   (let ((button (button-at (point))))
1406     (if button
1407         (elpher-copy-node-url (button-get button 'elpher-node))
1408       (error "No item selected"))))
1409
1410 (defun elpher-copy-current-url ()
1411   "Copy URL of current node to `kill-ring'."
1412   (interactive)
1413   (elpher-copy-node-url elpher-current-node))
1414
1415 (defun elpher-set-gopher-coding-system ()
1416   "Specify an explicit character coding system for gopher selectors."
1417   (interactive)
1418   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1419     (setq elpher-user-coding-system system)
1420     (if system
1421         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1422       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1423
1424
1425 ;;; Mode and keymap
1426 ;;
1427
1428 (defvar elpher-mode-map
1429   (let ((map (make-sparse-keymap)))
1430     (define-key map (kbd "TAB") 'elpher-next-link)
1431     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1432     (define-key map (kbd "u") 'elpher-back)
1433     (define-key map [mouse-3] 'elpher-back)
1434     (define-key map (kbd "O") 'elpher-root-dir)
1435     (define-key map (kbd "g") 'elpher-go)
1436     (define-key map (kbd "o") 'elpher-go-current)
1437     (define-key map (kbd "r") 'elpher-redraw)
1438     (define-key map (kbd "R") 'elpher-reload)
1439     (define-key map (kbd "T") 'elpher-toggle-tls)
1440     (define-key map (kbd ".") 'elpher-view-raw)
1441     (define-key map (kbd "d") 'elpher-download)
1442     (define-key map (kbd "D") 'elpher-download-current)
1443     (define-key map (kbd "m") 'elpher-jump)
1444     (define-key map (kbd "i") 'elpher-info-link)
1445     (define-key map (kbd "I") 'elpher-info-current)
1446     (define-key map (kbd "c") 'elpher-copy-link-url)
1447     (define-key map (kbd "C") 'elpher-copy-current-url)
1448     (define-key map (kbd "a") 'elpher-bookmark-link)
1449     (define-key map (kbd "A") 'elpher-bookmark-current)
1450     (define-key map (kbd "x") 'elpher-unbookmark-link)
1451     (define-key map (kbd "X") 'elpher-unbookmark-current)
1452     (define-key map (kbd "B") 'elpher-bookmarks)
1453     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1454     (when (fboundp 'evil-define-key*)
1455       (evil-define-key* 'motion map
1456         (kbd "TAB") 'elpher-next-link
1457         (kbd "C-") 'elpher-follow-current-link
1458         (kbd "C-t") 'elpher-back
1459         (kbd "u") 'elpher-back
1460         [mouse-3] 'elpher-back
1461         (kbd "g") 'elpher-go
1462         (kbd "o") 'elpher-go-current
1463         (kbd "r") 'elpher-redraw
1464         (kbd "R") 'elpher-reload
1465         (kbd "T") 'elpher-toggle-tls
1466         (kbd ".") 'elpher-view-raw
1467         (kbd "d") 'elpher-download
1468         (kbd "D") 'elpher-download-current
1469         (kbd "m") 'elpher-jump
1470         (kbd "i") 'elpher-info-link
1471         (kbd "I") 'elpher-info-current
1472         (kbd "c") 'elpher-copy-link-url
1473         (kbd "C") 'elpher-copy-current-url
1474         (kbd "a") 'elpher-bookmark-link
1475         (kbd "A") 'elpher-bookmark-current
1476         (kbd "x") 'elpher-unbookmark-link
1477         (kbd "X") 'elpher-unbookmark-current
1478         (kbd "B") 'elpher-bookmarks
1479         (kbd "S") 'elpher-set-gopher-coding-system))
1480     map)
1481   "Keymap for gopher client.")
1482
1483 (define-derived-mode elpher-mode special-mode "elpher"
1484   "Major mode for elpher, an elisp gopher client.
1485
1486 This mode is automatically enabled by the interactive
1487 functions which initialize the gopher client, namely
1488 `elpher', `elpher-go' and `elpher-bookmarks'.")
1489
1490 (when (fboundp 'evil-set-initial-state)
1491   (evil-set-initial-state 'elpher-mode 'motion))
1492
1493
1494 ;;; Main start procedure
1495 ;;
1496
1497 ;;;###autoload
1498 (defun elpher ()
1499   "Start elpher with default landing page."
1500   (interactive)
1501   (if (get-buffer "*elpher*")
1502       (switch-to-buffer "*elpher*")
1503     (switch-to-buffer "*elpher*")
1504     (setq elpher-current-node nil)
1505     (let ((start-node (elpher-make-node "Elpher Start Page"
1506                                         (elpher-make-special-address 'start))))
1507       (elpher-visit-node start-node)))
1508   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1509
1510 ;;; elpher.el ends here