elpher.el

   1 ;;; elpher.el --- A friendly gopher client.  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.3.4
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption,
  40 ;; - basic support for the fledgling Gemini protocol.
  41
  42 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  43 ;; page containing information on key bindings and suggested starting
  44 ;; points for your gopher exploration.
  45
  46 ;; Full instructions can be found in the Elpher info manual.
  47
  48 ;; Elpher is under active development.  Any suggestions for
  49 ;; improvements are welcome!
  50
  51 ;;; Code:
  52
  53 (provide 'elpher)
  54
  55 ;;; Dependencies
  56 ;;
  57
  58 (require 'seq)
  59 (require 'pp)
  60 (require 'shr)
  61 (require 'url-util)
  62 (require 'subr-x)
  63
  64
  65 ;;; Global constants
  66 ;;
  67
  68 (defconst elpher-version "2.3.4"
  69   "Current version of elpher.")
  70
  71 (defconst elpher-margin-width 6
  72   "Width of left-hand margin used when rendering indicies.")
  73
  74 (defconst elpher-type-map
  75   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  76     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  77     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  78     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  79     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  80     ((gopher ?9) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  81     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  83     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  84     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  85     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  86     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  87     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  88     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  89     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  90     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  91     ((special bookmarks) elpher-get-bookmarks-node nil)
  92     ((special start) elpher-get-start-node nil))
  93   "Association list from types to getters, renderers, margin codes and index faces.")
  94
  95
  96 ;;; Customization group
  97 ;;
  98
  99 (defgroup elpher nil
 100   "A gopher client."
 101   :group 'applications)
 102
 103 ;; Face customizations
 104
 105 (defface elpher-index
 106   '((t :inherit font-lock-keyword-face))
 107   "Face used for directory type directory records.")
 108
 109 (defface elpher-text
 110   '((t :inherit bold))
 111   "Face used for text type directory records.")
 112
 113 (defface elpher-info
 114   '((t :inherit default))
 115   "Face used for info type directory records.")
 116
 117 (defface elpher-image
 118   '((t :inherit font-lock-string-face))
 119   "Face used for image type directory records.")
 120
 121 (defface elpher-search
 122   '((t :inherit warning))
 123   "Face used for search type directory records.")
 124
 125 (defface elpher-html
 126   '((t :inherit font-lock-comment-face))
 127   "Face used for html type directory records.")
 128
 129 (defface elpher-gemini
 130   '((t :inherit font-lock-regexp-grouping-backslash))
 131   "Face used for html type directory records.")
 132
 133 (defface elpher-other-url
 134   '((t :inherit font-lock-comment-face))
 135   "Face used for other URL type links records.")
 136
 137 (defface elpher-telnet
 138   '((t :inherit font-lock-function-name-face))
 139   "Face used for telnet type directory records.")
 140
 141 (defface elpher-binary
 142   '((t :inherit font-lock-doc-face))
 143   "Face used for binary type directory records.")
 144
 145 (defface elpher-unknown
 146   '((t :inherit error))
 147   "Face used for directory records with unknown/unsupported types.")
 148
 149 (defface elpher-margin-key
 150   '((t :inherit bold))
 151   "Face used for directory margin key.")
 152
 153 (defface elpher-margin-brackets
 154   '((t :inherit shadow))
 155   "Face used for brackets around directory margin key.")
 156
 157 ;; Other customizations
 158
 159 (defcustom elpher-open-urls-with-eww nil
 160   "If non-nil, open URL selectors using eww.
 161 Otherwise, use the system browser via the BROWSE-URL function."
 162   :type '(boolean))
 163
 164 (defcustom elpher-buttonify-urls-in-directories t
 165   "If non-nil, turns URLs matched in directories into clickable buttons."
 166   :type '(boolean))
 167
 168 (defcustom elpher-use-header t
 169   "If non-nil, display current node information in buffer header."
 170   :type '(boolean))
 171
 172 (defcustom elpher-auto-disengage-TLS nil
 173   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 174 While enabling this may seem convenient, it is also potentially dangerous as it
 175 allows switching from an encrypted channel back to plain text without user input."
 176   :type '(boolean))
 177
 178
 179 ;;; Model
 180 ;;
 181
 182 ;; Address
 183
 184 ;; An elpher "address" object is either a url object or a symbol.
 185 ;; Symbol addresses are "special", corresponding to pages generated
 186 ;; dynamically for and by elpher.  All others represent pages which
 187 ;; rely on content retrieved over the network.
 188
 189 (defun elpher-address-from-url (url-string)
 190   "Create a ADDRESS object corresponding to the given URL-STRING."
 191   (let ((data (match-data))) ; Prevent parsing clobbering match data
 192     (unwind-protect
 193         (let ((url (url-generic-parse-url url-string)))
 194           (unless (and (not (url-fullness url)) (url-type url))
 195             (setf (url-fullness url) t)
 196             (setf (url-filename url)
 197                   (url-unhex-string (url-filename url)))
 198             (unless (url-type url)
 199               (setf (url-type url) "gopher"))
 200             (when (or (equal "gopher" (url-type url))
 201                       (equal "gophers" (url-type url)))
 202               ;; Gopher defaults
 203               (unless (url-host url)
 204                 (setf (url-host url) (url-filename url))
 205                 (setf (url-filename url) ""))
 206               (when (or (equal (url-filename url) "")
 207                         (equal (url-filename url) "/"))
 208                 (setf (url-filename url) "/1")))
 209             (when (equal "gemini" (url-type url))
 210               ;; Gemini defaults
 211               (if (equal (url-filename url) "")
 212                   (setf (url-filename url) "/"))))
 213           url)
 214       (set-match-data data))))
 215
 216 (defun elpher-make-gopher-address (type selector host port &optional tls)
 217   "Create an ADDRESS object using gopher directory record attributes.
 218 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 219 If the optional attribute TLS is non-nil, the address will be marked as
 220 requiring gopher-over-TLS."
 221   (cond
 222    ((and (equal type ?h)
 223          (string-prefix-p "URL:" selector))
 224     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 225    ((equal type ?8)
 226     (elpher-address-from-url
 227      (concat "telnet"
 228              "://" host
 229              ":" (number-to-string port))))
 230    (t
 231     (elpher-address-from-url
 232      (concat "gopher" (if tls "s" "")
 233              "://" host
 234              ":" (number-to-string port)
 235              "/" (string type)
 236              selector)))))
 237
 238 (defun elpher-make-special-address (type)
 239   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 240   type)
 241
 242 (defun elpher-address-to-url (address)
 243   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 244   (if (not (elpher-address-special-p address))
 245       (url-encode-url (url-recreate-url address))
 246     nil))
 247
 248 (defun elpher-address-type (address)
 249   "Retrieve type of ADDRESS object.
 250 This is used to determine how to retrieve and render the document the
 251 address refers to, via the table `elpher-type-map'."
 252   (if (symbolp address)
 253       (list 'special address)
 254     (let ((protocol (url-type address)))
 255       (cond ((or (equal protocol "gopher")
 256                  (equal protocol "gophers"))
 257              (list 'gopher
 258                    (if (member (url-filename address) '("" "/"))
 259                        ?1
 260                      (string-to-char (substring (url-filename address) 1)))))
 261             ((equal protocol "gemini")
 262              'gemini)
 263             ((equal protocol "telnet")
 264              'telnet)
 265             (t 'other-url)))))
 266
 267 (defun elpher-address-protocol (address)
 268   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 269   (if (symbolp address)
 270       nil
 271     (url-type address)))
 272
 273 (defun elpher-address-filename (address)
 274   "Retrieve the filename component of ADDRESS.
 275 For gopher addresses this is a combination of the selector type and selector."
 276   (if (symbolp address)
 277       nil
 278     (url-filename address)))
 279
 280 (defun elpher-address-host (address)
 281   "Retrieve host from ADDRESS object."
 282   (url-host address))
 283
 284 (defun elpher-address-port (address)
 285   "Retrieve port from ADDRESS object."
 286   (if (symbolp address)
 287       nil)
 288   (if (> (url-port address) 0)
 289       (url-port address)
 290     (or (and (or (equal (url-type address) "gopher")
 291                  (equal (url-type address) "gophers"))
 292              70)
 293         (and (equal (url-type address) "gemini")
 294              1965))))
 295
 296 (defun elpher-address-special-p (address)
 297   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 298   (symbolp address))
 299
 300 (defun elpher-address-gopher-p (address)
 301   "Return non-nill if ADDRESS object is a gopher address."
 302   (and (not (elpher-address-special-p address))
 303        (member (elpher-address-protocol address) '("gopher gophers"))))
 304
 305 (defun elpher-gopher-address-selector (address)
 306   "Retrieve gopher selector from ADDRESS object."
 307   (if (member (url-filename address) '("" "/"))
 308       ""
 309     (substring (url-filename address) 2)))
 310
 311 ;; Node
 312
 313 (defun elpher-make-node (display-string address &optional parent)
 314   "Create a node in the page hierarchy.
 315
 316 DISPLAY-STRING records the display string used for the page.
 317
 318 ADDRESS specifies the address object of the page.
 319
 320 The optional PARENT specifies the parent node in the hierarchy.
 321 This is set every time the node is visited, so while it forms
 322 an important part of the node data there is no need to set it
 323 initially."
 324   (list display-string address parent))
 325
 326 (defun elpher-node-display-string (node)
 327   "Retrieve the display string of NODE."
 328   (elt node 0))
 329
 330 (defun elpher-node-address (node)
 331   "Retrieve the ADDRESS object of NODE."
 332   (elt node 1))
 333
 334 (defun elpher-node-parent (node)
 335   "Retrieve the parent node of NODE."
 336   (elt node 2))
 337
 338 (defun elpher-set-node-parent (node parent)
 339   "Set the parent node of NODE to be PARENT."
 340   (setcar (cdr (cdr node)) parent))
 341
 342 ;; Cache
 343
 344 (defvar elpher-content-cache (make-hash-table :test 'equal))
 345 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 346
 347 (defun elpher-get-cached-content (address)
 348   "Retrieve the cached content for ADDRESS, or nil if none exists."
 349   (gethash address elpher-content-cache))
 350
 351 (defun elpher-cache-content (address content)
 352   "Set the content cache for ADDRESS to CONTENT."
 353   (puthash address content elpher-content-cache))
 354
 355 (defun elpher-get-cached-pos (address)
 356   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 357   (gethash address elpher-pos-cache))
 358
 359 (defun elpher-cache-pos (address pos)
 360   "Set the cursor position cache for ADDRESS to POS."
 361   (puthash address pos elpher-pos-cache))
 362
 363 ;; Node graph traversal
 364
 365 (defvar elpher-current-node nil)
 366
 367 (defun elpher-visit-node (node &optional renderer preserve-parent)
 368   "Visit NODE using its own renderer or RENDERER, if non-nil.
 369 Additionally, set the parent of NODE to `elpher-current-node',
 370 unless PRESERVE-PARENT is non-nil."
 371   (elpher-save-pos)
 372   (elpher-process-cleanup)
 373   (unless preserve-parent
 374     (if (and (elpher-node-parent elpher-current-node)
 375              (equal (elpher-node-address elpher-current-node)
 376                     (elpher-node-address node)))
 377         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 378       (elpher-set-node-parent node elpher-current-node)))
 379   (setq elpher-current-node node)
 380   (let* ((address (elpher-node-address node))
 381          (type (elpher-address-type address))
 382          (type-record (cdr (assoc type elpher-type-map))))
 383     (if type-record
 384         (funcall (car type-record)
 385                  (if renderer
 386                      renderer
 387                    (cadr type-record)))
 388       (elpher-visit-parent-node)
 389       (pcase type
 390         (`(gopher ,type-char)
 391          (error "Unsupported gopher selector type '%c' for '%s'"
 392                 type-char (elpher-address-to-url address)))
 393         (other
 394          (error "Unsupported address type '%S' for '%s'"
 395                 other (elpher-address-to-url address)))))))
 396
 397 (defun elpher-visit-parent-node ()
 398   "Visit the parent of the current node."
 399   (let ((parent-node (elpher-node-parent elpher-current-node)))
 400     (when parent-node
 401       (elpher-visit-node parent-node nil t))))
 402
 403 (defun elpher-reload-current-node ()
 404   "Reload the current node, discarding any existing cached content."
 405   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 406   (elpher-visit-node elpher-current-node))
 407
 408 (defun elpher-save-pos ()
 409   "Save the current position of point to the current node."
 410   (when elpher-current-node
 411     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 412
 413 (defun elpher-restore-pos ()
 414   "Restore the position of point to that cached in the current node."
 415   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 416     (if pos
 417         (goto-char pos)
 418       (goto-char (point-min)))))
 419
 420
 421 ;;; Buffer preparation
 422 ;;
 423
 424 (defun elpher-update-header ()
 425   "If `elpher-use-header' is true, display current node info in window header."
 426   (if elpher-use-header
 427       (let* ((display-string (elpher-node-display-string elpher-current-node))
 428              (address (elpher-node-address elpher-current-node))
 429              (url-string (if (elpher-address-special-p address)
 430                              ""
 431                            (concat "  -  " (elpher-address-to-url address) "")))
 432              (header (replace-regexp-in-string "%" "%%" (concat display-string
 433                                                                 url-string))))
 434         (setq header-line-format header))))
 435
 436 (defmacro elpher-with-clean-buffer (&rest args)
 437   "Evaluate ARGS with a clean *elpher* buffer as current."
 438   (list 'with-current-buffer "*elpher*"
 439         '(elpher-mode)
 440         (append (list 'let '((inhibit-read-only t))
 441                       '(erase-buffer)
 442                       '(elpher-update-header))
 443                 args)))
 444
 445
 446 ;;; Text Processing
 447 ;;
 448
 449 (defvar elpher-user-coding-system nil
 450   "User-specified coding system to use for decoding text responses.")
 451
 452 (defun elpher-decode (string)
 453   "Decode STRING using autodetected or user-specified coding system."
 454   (decode-coding-string string
 455                         (if elpher-user-coding-system
 456                             elpher-user-coding-system
 457                           (detect-coding-string string t))))
 458
 459 (defun elpher-preprocess-text-response (string)
 460   "Preprocess text selector response contained in STRING.
 461 This involes decoding the character representation, and clearing
 462 away CRs and any terminating period."
 463   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 464                                            (replace-regexp-in-string "\r" "" string))))
 465
 466
 467 ;;; Network error reporting
 468 ;;
 469
 470 (defun elpher-network-error (address error)
 471   "Display ERROR message following unsuccessful negotiation with ADDRESS."
 472   (elpher-with-clean-buffer
 473    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 474            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 475            (error-message-string error) "\n"
 476            (propertize "\n----------------\n\n" 'face 'error)
 477            "Press 'u' to return to the previous page.")))
 478
 479
 480 ;;; Gopher selector retrieval
 481 ;;
 482
 483 (defun elpher-process-cleanup ()
 484   "Immediately shut down any extant elpher process."
 485   (let ((p (get-process "elpher-process")))
 486     (if p (delete-process p))))
 487
 488 (defvar elpher-use-tls nil
 489   "If non-nil, use TLS to communicate with gopher servers.")
 490
 491 (defvar elpher-selector-string)
 492
 493 (defun elpher-get-selector (address after &optional propagate-error)
 494   "Retrieve selector specified by ADDRESS, then execute AFTER.
 495 The result is stored as a string in the variable ‘elpher-selector-string’.
 496
 497 Usually errors result in an error page being displayed.  This is only
 498 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 499 is non-nil, this message is not displayed.  Instead, the error propagates
 500 up to the calling function."
 501   (setq elpher-selector-string "")
 502   (when (equal (elpher-address-protocol address) "gophers")
 503       (if (gnutls-available-p)
 504           (when (not elpher-use-tls)
 505             (setq elpher-use-tls t)
 506             (message "Engaging TLS gopher mode."))
 507         (error "Cannot retrieve TLS gopher selector: GnuTLS not available")))
 508   (condition-case the-error
 509       (let* ((kill-buffer-query-functions nil)
 510              (proc (open-network-stream "elpher-process"
 511                                        nil
 512                                        (elpher-address-host address)
 513                                        (elpher-address-port address)
 514                                        :type (if elpher-use-tls 'tls 'plain))))
 515         (set-process-coding-system proc 'binary)
 516         (set-process-filter proc
 517                             (lambda (_proc string)
 518                               (setq elpher-selector-string
 519                                     (concat elpher-selector-string string))))
 520         (set-process-sentinel proc after)
 521         (process-send-string proc
 522                              (concat (elpher-gopher-address-selector address) "\n")))
 523     (error
 524      (if (and (consp the-error)
 525               (eq (car the-error) 'gnutls-error)
 526               (not (equal (elpher-address-protocol address) "gophers"))
 527               (or elpher-auto-disengage-TLS
 528                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 529          (progn
 530            (message "Disengaging TLS gopher mode.")
 531            (setq elpher-use-tls nil)
 532            (elpher-get-selector address after))
 533        (elpher-process-cleanup)
 534        (if propagate-error
 535            (error the-error)
 536          (elpher-with-clean-buffer
 537           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 538                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 539                   (propertize "\n----------------\n\n" 'face 'error)
 540                   "Press 'u' to return to the previous page.")))))))
 541
 542 (defun elpher-get-gopher-node (renderer)
 543   "Getter function for gopher nodes.
 544 The RENDERER procedure is used to display the contents of the node
 545 once they are retrieved from the gopher server."
 546   (let* ((address (elpher-node-address elpher-current-node))
 547          (content (elpher-get-cached-content address)))
 548     (if (and content (funcall renderer nil))
 549         (elpher-with-clean-buffer
 550          (insert content)
 551          (elpher-restore-pos))
 552       (elpher-with-clean-buffer
 553        (insert "LOADING... (use 'u' to cancel)"))
 554       (elpher-get-selector address
 555                            (lambda (_proc event)
 556                              (unless (string-prefix-p "deleted" event)
 557                                (funcall renderer elpher-selector-string)
 558                                (elpher-restore-pos)))))))
 559
 560 ;; Index rendering
 561
 562 (defun elpher-insert-index (string)
 563   "Insert the index corresponding to STRING into the current buffer."
 564   ;; Should be able to split directly on CRLF, but some non-conformant
 565   ;; LF-only servers sadly exist, hence the following.
 566   (let ((str-processed (elpher-preprocess-text-response string)))
 567     (dolist (line (split-string str-processed "\n"))
 568       (ignore-errors
 569         (unless (= (length line) 0)
 570           (let* ((type (elt line 0))
 571                  (fields (split-string (substring line 1) "\t"))
 572                  (display-string (elt fields 0))
 573                  (selector (elt fields 1))
 574                  (host (elt fields 2))
 575                  (port (if (elt fields 3)
 576                            (string-to-number (elt fields 3))
 577                          nil))
 578                  (address (elpher-make-gopher-address type selector host port)))
 579             (elpher-insert-index-record display-string address)))))))
 580
 581 (defun elpher-insert-margin (&optional type-name)
 582   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 583   (if type-name
 584       (progn
 585         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 586                         (concat
 587                          (propertize "[" 'face 'elpher-margin-brackets)
 588                          (propertize type-name 'face 'elpher-margin-key)
 589                          (propertize "]" 'face 'elpher-margin-brackets))))
 590         (insert " "))
 591     (insert (make-string elpher-margin-width ?\s))))
 592
 593 (defun elpher-node-button-help (node)
 594   "Return a string containing the help text for a button corresponding to NODE."
 595   (let ((address (elpher-node-address node)))
 596     (format "mouse-1, RET: open '%s'" (elpher-address-to-url address))))
 597
 598 (defun elpher-insert-index-record (display-string &optional address)
 599   "Function to insert an index record into the current buffer.
 600 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 601 If ADDRESS is not supplied or nil the record is rendered as an
 602 'information' line."
 603   (let* ((type (if address (elpher-address-type address) nil))
 604          (type-map-entry (cdr (assoc type elpher-type-map))))
 605     (if type-map-entry
 606         (let* ((margin-code (elt type-map-entry 2))
 607                (face (elt type-map-entry 3))
 608                (node (elpher-make-node display-string address)))
 609           (elpher-insert-margin margin-code)
 610           (insert-text-button display-string
 611                               'face face
 612                               'elpher-node node
 613                               'action #'elpher-click-link
 614                               'follow-link t
 615                               'help-echo (elpher-node-button-help node)))
 616       (pcase type
 617         ((or '(gopher ?i) 'nil) ;; Information
 618          (elpher-insert-margin)
 619          (let ((propertized-display-string
 620                 (propertize display-string 'face 'elpher-info)))
 621            (insert (if elpher-buttonify-urls-in-directories
 622                        (elpher-buttonify-urls propertized-display-string)
 623                      propertized-display-string))))
 624         (`(gopher ,selector-type) ;; Unknown
 625          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 626          (insert (propertize display-string
 627                              'face 'elpher-unknown)))))
 628     (insert "\n")))
 629
 630 (defun elpher-click-link (button)
 631   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 632   (let ((node (button-get button 'elpher-node)))
 633     (elpher-visit-node node)))
 634
 635 (defun elpher-render-index (data &optional _mime-type-string)
 636   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 637   (elpher-with-clean-buffer
 638    (if (not data)
 639        t
 640      (elpher-insert-index data)
 641      (elpher-cache-content (elpher-node-address elpher-current-node)
 642                            (buffer-string)))))
 643
 644 ;; Text rendering
 645
 646 (defconst elpher-url-regex
 647   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.]*[0-9a-zA-Z\-_~?/@|]\\)?\\)?"
 648   "Regexp used to locate and buttniofy URLs in text files loaded by elpher.")
 649
 650 (defun elpher-buttonify-urls (string)
 651   "Turn substrings which look like urls in STRING into clickable buttons."
 652   (with-temp-buffer
 653     (insert string)
 654     (goto-char (point-min))
 655     (while (re-search-forward elpher-url-regex nil t)
 656       (let ((node (elpher-make-node (match-string 0)
 657                                     (elpher-address-from-url (match-string 0)))))
 658           (make-text-button (match-beginning 0)
 659                             (match-end 0)
 660                             'elpher-node  node
 661                             'action #'elpher-click-link
 662                             'follow-link t
 663                             'help-echo (elpher-node-button-help node)
 664                             'face 'button)))
 665     (buffer-string)))
 666
 667 (defun elpher-render-text (data &optional _mime-type-string)
 668   "Render DATA as text.  MIME-TYPE-STRING is unused."
 669   (elpher-with-clean-buffer
 670    (if (not data)
 671        t
 672      (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 673      (elpher-cache-content
 674       (elpher-node-address elpher-current-node)
 675       (buffer-string)))))
 676
 677 ;; Image retrieval
 678
 679 (defun elpher-render-image (data &optional _mime-type-string)
 680   "Display DATA as image.  MIME-TYPE-STRING is unused."
 681   (if (not data)
 682       nil
 683     (if (display-images-p)
 684         (progn
 685           (let ((image (create-image
 686                         data
 687                         nil t)))
 688             (elpher-with-clean-buffer
 689              (insert-image image)
 690              (elpher-restore-pos))))
 691       (elpher-render-download data))))
 692
 693 ;; Search retrieval and rendering
 694
 695 (defun elpher-get-gopher-query-node (renderer)
 696   "Getter for gopher addresses requiring input.
 697 The response is rendered using the rendering function RENDERER."
 698    (let* ((address (elpher-node-address elpher-current-node))
 699           (content (elpher-get-cached-content address))
 700           (aborted t))
 701     (if (and content (funcall renderer nil))
 702         (elpher-with-clean-buffer
 703          (insert content)
 704          (elpher-restore-pos)
 705          (message "Displaying cached search results.  Reload to perform a new search."))
 706       (unwind-protect
 707           (let* ((query-string (read-string "Query: "))
 708                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 709                  (search-address (elpher-make-gopher-address ?1
 710                                                              query-selector
 711                                                              (elpher-address-host address)
 712                                                              (elpher-address-port address)
 713                                                              (equal (elpher-address-type address) "gophers"))))
 714             (setq aborted nil)
 715
 716             (elpher-with-clean-buffer
 717              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 718             (elpher-get-selector search-address
 719                                  (lambda (_proc event)
 720                                    (unless (string-prefix-p "deleted" event)
 721                                      (funcall renderer elpher-selector-string)
 722                                      (elpher-restore-pos)))))
 723         (if aborted
 724             (elpher-visit-parent-node))))))
 725
 726 ;; Raw server response rendering
 727
 728 (defun elpher-render-raw (data &optional _mime-type-string)
 729   "Display raw DATA in buffer.  MIME-TYPE-STRING is unused."
 730   (if (not data)
 731       nil
 732     (elpher-with-clean-buffer
 733      (insert data)
 734      (goto-char (point-min)))
 735     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 736
 737 ;; File save "rendering"
 738
 739 (defun elpher-render-download (data &optional _mime-type-string)
 740   "Save DATA to file.  MIME-TYPE-STRING is unused."
 741   (if (not data)
 742       nil
 743     (let* ((address (elpher-node-address elpher-current-node))
 744            (selector (elpher-gopher-address-selector address)))
 745       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 746       (let* ((filename-proposal (file-name-nondirectory selector))
 747              (filename (read-file-name "Download complete. Save file as: "
 748                                        nil nil nil
 749                                        (if (> (length filename-proposal) 0)
 750                                            filename-proposal
 751                                          "download.file"))))
 752         (let ((coding-system-for-write 'binary))
 753           (with-temp-file filename
 754             (insert data)))
 755         (message (format "Saved to file %s." filename))))))
 756
 757 ;; HTML rendering
 758
 759 (defun elpher-render-html (data &optional _mime-type-string)
 760   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
 761   (elpher-with-clean-buffer
 762    (if (not data)
 763        t
 764      (let ((dom (with-temp-buffer
 765                   (insert data)
 766                   (libxml-parse-html-region (point-min) (point-max)))))
 767        (shr-insert-document dom)))))
 768
 769 ;; Gemini node retrieval
 770
 771 (defvar elpher-gemini-response)
 772
 773 (defun elpher-get-gemini-response (address after)
 774   "Retrieve gemini ADDRESS, then execute AFTER.
 775 The response is stored in the variable ‘elpher-gemini-response’."
 776   (setq elpher-gemini-response "")
 777   (if (not (gnutls-available-p))
 778       (error "Cannot retrieve TLS selector: GnuTLS not available")
 779     (condition-case the-error
 780         (let* ((kill-buffer-query-functions nil)
 781                (proc (open-network-stream "elpher-process"
 782                                           nil
 783                                           (elpher-address-host address)
 784                                           (elpher-address-port address)
 785                                           :type 'tls)))
 786           (set-process-coding-system proc 'binary)
 787           (set-process-filter proc
 788                               (lambda (_proc string)
 789                                 (setq elpher-gemini-response
 790                                       (concat elpher-gemini-response string))))
 791           (set-process-sentinel proc after)
 792           (process-send-string proc
 793                                (concat (elpher-address-to-url address) "\r\n")))
 794       (error
 795        (error "Error initiating connection to server")))))
 796
 797 (defun elpher-parse-gemini-response (response)
 798   "Parse the RESPONSE string and return a list of components
 799 The list is of the form (code meta body). A response of nil implies
 800 that the response was malformed."
 801   (let ((header-end-idx (string-match "\r\n" response)))
 802     (if header-end-idx
 803         (let ((header (string-trim (substring response 0 header-end-idx)))
 804               (body (substring response (+ header-end-idx 2))))
 805           (if (>= (length header) 2)
 806               (let ((code (substring header 0 2))
 807                     (meta (string-trim (substring header 2))))
 808                 (list code meta body))
 809             (error "Malformed response: No response status found in header %s" header)))
 810       (error "Malformed response: No CRLF-delimited header found"))))
 811
 812
 813 (defun elpher-process-gemini-response (renderer)
 814   "Process the gemini response and pass the result to RENDERER.
 815 The response is assumed to be in the variable `elpher-gemini-response'."
 816   (condition-case the-error
 817       (let ((response-components (elpher-parse-gemini-response elpher-gemini-response)))
 818         (let ((response-code (elt response-components 0))
 819               (response-meta (elt response-components 1))
 820               (response-body (elt response-components 2)))
 821           (pcase (elt response-code 0)
 822             (?1 ; Input required
 823              (elpher-with-clean-buffer
 824               (insert "Gemini server is requesting input."))
 825              (let* ((query-string (read-string (concat response-meta ": ")))
 826                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 827                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 828                (elpher-get-gemini-response query-address
 829                                            (lambda (_proc event)
 830                                              (unless (string-prefix-p "deleted" event)
 831                                                (funcall #'elpher-process-gemini-response
 832                                                         renderer)
 833                                                (elpher-restore-pos))))))
 834             (?2 ; Normal response
 835              ;; (message response-header)
 836              (funcall renderer response-body response-meta))
 837             (?3 ; Redirect
 838              (message "Following redirect to %s" response-meta)
 839              (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
 840                (elpher-get-gemini-response redirect-address
 841                                            (lambda (_proc event)
 842                                              (unless (string-prefix-p "deleted" event)
 843                                                (funcall #'elpher-process-gemini-response
 844                                                         renderer)
 845                                                (elpher-restore-pos))))))
 846             (?4 ; Temporary failure
 847              (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
 848                     response-code response-meta))
 849             (?5 ; Permanent failure
 850              (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
 851                     response-code response-meta))
 852             (?6 ; Client certificate required
 853              (error "Gemini server requires client certificate (unsupported at this time)"))
 854             (_other
 855              (error "Gemini server response unknown: %s %s"
 856                     response-code response-meta)))))
 857     (error
 858      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 859
 860 (defun elpher-get-gemini-node (renderer)
 861   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 862   (let* ((address (elpher-node-address elpher-current-node))
 863          (content (elpher-get-cached-content address)))
 864     (condition-case the-error
 865         (if (and content (funcall renderer nil))
 866             (elpher-with-clean-buffer
 867               (insert content)
 868               (elpher-restore-pos))
 869           (elpher-with-clean-buffer
 870            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 871           (elpher-get-gemini-response address
 872                                       (lambda (_proc event)
 873                                         (unless (string-prefix-p "deleted" event)
 874                                           (funcall #'elpher-process-gemini-response
 875                                                    renderer)
 876                                           (elpher-restore-pos)))))
 877       (error
 878        (elpher-network-error address the-error)))))
 879
 880
 881 (defun elpher-render-gemini (body &optional mime-type-string)
 882   "Render gemini response BODY with rendering MIME-TYPE-STRING."
 883   (if (not body)
 884       t
 885     (let* ((mime-type-string* (if (or (not mime-type-string)
 886                                       (string-empty-p mime-type-string))
 887                                   "text/gemini; charset=utf-8"
 888                                 mime-type-string))
 889            (mime-type-split (split-string mime-type-string* ";" t))
 890            (mime-type (string-trim (car mime-type-split)))
 891            (parameters (mapcar (lambda (s)
 892                                  (let ((key-val (split-string s "=")))
 893                                    (list (downcase (string-trim (car key-val)))
 894                                          (downcase (string-trim (cadr key-val))))))
 895                                (cdr mime-type-split))))
 896       (when (string-prefix-p "text/" mime-type)
 897         (setq body (decode-coding-string
 898                     body
 899                     (if (assoc "charset" parameters)
 900                         (intern (cadr (assoc "charset" parameters)))
 901                       'utf-8)))
 902         (setq body (replace-regexp-in-string "\r" "" body)))
 903       (pcase mime-type
 904         ((or "text/gemini" "")
 905          (elpher-render-gemini-map body parameters))
 906         ((pred (string-prefix-p "text/"))
 907          (elpher-render-gemini-plain-text body parameters))
 908         ((pred (string-prefix-p "image/"))
 909          (elpher-render-image body))
 910         (_other
 911          (error "Unsupported MIME type %S" mime-type))))))
 912
 913 (defun elpher-gemini-get-link-url (line)
 914   "Extract the url portion of LINE, a gemini map file link line."
 915   (string-trim (elt (split-string (substring line 2)) 0)))
 916
 917 (defun elpher-gemini-get-link-display-string (line)
 918   "Extract the display string portion of LINE, a gemini map file link line."
 919   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 920          (idx (string-match "[ \t]" rest)))
 921     (if idx
 922         (string-trim (substring rest (+ idx 1)))
 923       "")))
 924
 925 (defun elpher-collapse-dot-sequences (filename)
 926   "Collapse dot sequences in FILENAME.
 927 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
 928   (let* ((path (split-string filename "/"))
 929          (path-reversed-normalized
 930           (seq-reduce (lambda (a b)
 931                         (cond ((and a (equal b "..") (cdr a)))
 932                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
 933                               ((equal b ".") a)
 934                               (t (cons b a))))
 935                       path nil)))
 936     (string-join (reverse path-reversed-normalized) "/")))
 937
 938 (defun elpher-address-from-gemini-url (url)
 939   "Extract address from URL with defaults as per gemini map files."
 940   (let ((address (url-generic-parse-url url)))
 941     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 942       (setf (url-fullness address) t)
 943       (unless (url-host address) ;if there is an explicit host, filenames are absolute
 944         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 945         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 946           (setf (url-filename address)
 947                 (concat (file-name-directory
 948                          (url-filename (elpher-node-address elpher-current-node)))
 949                         (url-filename address)))))
 950       (unless (url-type address)
 951         (setf (url-type address) "gemini"))
 952       (if (equal (url-type address) "gemini")
 953           (setf (url-filename address)
 954                 (elpher-collapse-dot-sequences (url-filename address)))))
 955     address))
 956
 957 (defun elpher-render-gemini-map (data _parameters)
 958   "Render DATA as a gemini map file, PARAMETERS is currently unused."
 959   (elpher-with-clean-buffer
 960    (dolist (line (split-string data "\n"))
 961      (if (string-prefix-p "=>" line)
 962          (let* ((url (elpher-gemini-get-link-url line))
 963                 (display-string (elpher-gemini-get-link-display-string line))
 964                 (address (elpher-address-from-gemini-url url)))
 965            (if (> (length display-string) 0)
 966                (elpher-insert-index-record display-string address)
 967              (elpher-insert-index-record url address)))
 968        (elpher-insert-index-record line)))
 969    (elpher-cache-content
 970     (elpher-node-address elpher-current-node)
 971     (buffer-string))))
 972
 973 (defun elpher-render-gemini-plain-text (data _parameters)
 974   "Render DATA as plain text file.  PARAMETERS is currently unused."
 975   (elpher-with-clean-buffer
 976    (insert (elpher-buttonify-urls data))
 977    (elpher-cache-content
 978     (elpher-node-address elpher-current-node)
 979     (buffer-string))))
 980
 981 ;; Other URL node opening
 982
 983 (defun elpher-get-other-url-node (renderer)
 984   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 985   (when renderer
 986     (elpher-visit-parent-node)
 987     (error "Command not supported for general URLs"))
 988   (let* ((address (elpher-node-address elpher-current-node))
 989          (url (elpher-address-to-url address)))
 990     (progn
 991       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 992       (message "Opening URL...")
 993       (if elpher-open-urls-with-eww
 994           (browse-web url)
 995         (browse-url url)))))
 996
 997 ;; Telnet node connection
 998
 999 (defun elpher-get-telnet-node (renderer)
1000   "Opens a telnet connection to the current node address (RENDERER must be nil)."
1001   (when renderer
1002     (elpher-visit-parent-node)
1003     (error "Command not supported for telnet URLs"))
1004   (let* ((address (elpher-node-address elpher-current-node))
1005          (host (elpher-address-host address))
1006          (port (elpher-address-port address)))
1007     (elpher-visit-parent-node)
1008     (telnet host port)))
1009
1010 ;; Start page node retrieval
1011
1012 (defun elpher-get-start-node (renderer)
1013   "Getter which displays the start page (RENDERER must be nil)."
1014   (when renderer
1015     (elpher-visit-parent-node)
1016     (error "Command not supported for start page"))
1017   (elpher-with-clean-buffer
1018    (insert "     --------------------------------------------\n"
1019            "                Elpher Gopher Client             \n"
1020            "                   version " elpher-version "\n"
1021            "     --------------------------------------------\n"
1022            "\n"
1023            "Default bindings:\n"
1024            "\n"
1025            " - TAB/Shift-TAB: next/prev item on current page\n"
1026            " - RET/mouse-1: open item under cursor\n"
1027            " - m: select an item on current page by name (autocompletes)\n"
1028            " - u/mouse-3: return to previous page\n"
1029            " - o/O: visit different selector or the root menu of the current server\n"
1030            " - g: go to a particular gopher address\n"
1031            " - d/D: download item under cursor or current page\n"
1032            " - i/I: info on item under cursor or current page\n"
1033            " - c/C: copy URL representation of item under cursor or current page\n"
1034            " - a/A: bookmark the item under cursor or current page\n"
1035            " - x/X: remove bookmark for item under cursor or current page\n"
1036            " - B: visit the bookmarks page\n"
1037            " - r: redraw current page (using cached contents if available)\n"
1038            " - R: reload current page (regenerates cache)\n"
1039            " - S: set character coding system for gopher (default is to autodetect)\n"
1040            " - T: toggle TLS gopher mode\n"
1041            " - .: display the raw server response for the current page\n"
1042            "\n"
1043            "Start your exploration of gopher space:\n")
1044    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1045                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1046    (insert "\n"
1047            "Alternatively, select the following item and enter some search terms:\n")
1048    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
1049                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1050    (insert "\n"
1051            "** Refer to the ")
1052    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1053      (insert-text-button "Elpher info manual"
1054                          'face 'link
1055                          'action (lambda (_)
1056                                    (interactive)
1057                                    (info "(elpher)"))
1058                          'follow-link t
1059                          'help-echo help-string))
1060    (insert " for the full documentation. **\n")
1061    (insert (propertize
1062             (concat "  (This should be available if you have installed Elpher using\n"
1063                     "   MELPA. Otherwise you will have to install the manual yourself.)")
1064             'face 'shadow))
1065    (elpher-restore-pos)))
1066
1067 ;; Bookmarks page node retrieval
1068
1069 (defun elpher-get-bookmarks-node (renderer)
1070   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1071   (when renderer
1072     (elpher-visit-parent-node)
1073     (error "Command not supported for bookmarks page"))
1074   (elpher-with-clean-buffer
1075    (insert "---- Bookmark list ----\n\n")
1076    (let ((bookmarks (elpher-load-bookmarks)))
1077      (if bookmarks
1078          (dolist (bookmark bookmarks)
1079            (let ((display-string (elpher-bookmark-display-string bookmark))
1080                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1081              (elpher-insert-index-record display-string address)))
1082        (insert "No bookmarks found.\n")))
1083    (insert "\n-----------------------\n\n"
1084            "- u: return to previous page\n"
1085            "- x: delete selected bookmark\n"
1086            "- a: rename selected bookmark\n\n"
1087            "Bookmarks are stored in the file "
1088            (locate-user-emacs-file "elpher-bookmarks"))
1089    (elpher-restore-pos)))
1090
1091
1092 ;;; Bookmarks
1093 ;;
1094
1095 (defun elpher-make-bookmark (display-string url)
1096   "Make an elpher bookmark.
1097 DISPLAY-STRING determines how the bookmark will appear in the
1098 bookmark list, while URL is the url of the entry."
1099   (list display-string url))
1100
1101 (defun elpher-bookmark-display-string (bookmark)
1102   "Get the display string of BOOKMARK."
1103   (elt bookmark 0))
1104
1105 (defun elpher-set-bookmark-display-string (bookmark display-string)
1106   "Set the display string of BOOKMARK to DISPLAY-STRING."
1107   (setcar bookmark display-string))
1108
1109 (defun elpher-bookmark-url (bookmark)
1110   "Get the address for BOOKMARK."
1111   (elt bookmark 1))
1112
1113 (defun elpher-save-bookmarks (bookmarks)
1114   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1115 Beware that this completely replaces the existing contents of the file."
1116   (with-temp-file (locate-user-emacs-file "elpher-bookmarks")
1117     (erase-buffer)
1118     (insert "; Elpher bookmarks file\n\n"
1119             "; Bookmarks are stored as a list of (label URL) items.\n"
1120             "; Feel free to edit by hand, but take care to ensure\n"
1121             "; the list structure remains intact.\n\n")
1122     (pp bookmarks (current-buffer))))
1123
1124 (defun elpher-load-bookmarks ()
1125   "Get the list of bookmarks from the users's bookmark file."
1126   (let ((bookmarks
1127          (with-temp-buffer
1128            (ignore-errors
1129              (insert-file-contents (locate-user-emacs-file "elpher-bookmarks"))
1130              (goto-char (point-min))
1131              (read (current-buffer))))))
1132     (if (and bookmarks (listp (cadar bookmarks)))
1133         (progn
1134           (message "Reading old bookmark file. (Will be updated on write.)")
1135           (mapcar (lambda (old-bm)
1136                     (list (car old-bm)
1137                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1138                                                         (cadr old-bm)))))
1139                   bookmarks))
1140       bookmarks)))
1141
1142 (defun elpher-add-address-bookmark (address display-string)
1143   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1144 If ADDRESS is already bookmarked, update the label only."
1145   (let ((bookmarks (elpher-load-bookmarks))
1146         (url (elpher-address-to-url address)))
1147     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1148       (if existing-bookmark
1149           (elpher-set-bookmark-display-string existing-bookmark display-string)
1150         (push (elpher-make-bookmark display-string url) bookmarks)))
1151     (elpher-save-bookmarks bookmarks)))
1152
1153 (defun elpher-remove-address-bookmark (address)
1154   "Remove any bookmark to ADDRESS."
1155   (let ((url (elpher-address-to-url address)))
1156     (elpher-save-bookmarks
1157      (seq-filter (lambda (bookmark)
1158                    (not (equal (elpher-bookmark-url bookmark) url)))
1159                  (elpher-load-bookmarks)))))
1160
1161 ;;; Interactive procedures
1162 ;;
1163
1164 (defun elpher-next-link ()
1165   "Move point to the next link on the current page."
1166   (interactive)
1167   (forward-button 1))
1168
1169 (defun elpher-prev-link ()
1170   "Move point to the previous link on the current page."
1171   (interactive)
1172   (backward-button 1))
1173
1174 (defun elpher-follow-current-link ()
1175   "Open the link or url at point."
1176   (interactive)
1177   (push-button))
1178
1179 (defun elpher-go ()
1180   "Go to a particular gopher site read from the minibuffer."
1181   (interactive)
1182   (let ((node
1183          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1184            (elpher-make-node host-or-url
1185                              (elpher-address-from-url host-or-url)))))
1186     (switch-to-buffer "*elpher*")
1187     (elpher-visit-node node)))
1188
1189 (defun elpher-go-current ()
1190   "Go to a particular site read from the minibuffer, initialized with the current URL."
1191   (interactive)
1192   (let ((address (elpher-node-address elpher-current-node)))
1193     (if (elpher-address-special-p address)
1194         (error "Command invalid for this page")
1195       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1196         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1197
1198 (defun elpher-redraw ()
1199   "Redraw current page."
1200   (interactive)
1201   (if elpher-current-node
1202       (elpher-visit-node elpher-current-node)
1203     (message "No current site.")))
1204
1205 (defun elpher-reload ()
1206   "Reload current page."
1207   (interactive)
1208   (if elpher-current-node
1209       (elpher-reload-current-node)
1210     (message "No current site.")))
1211
1212 (defun elpher-toggle-tls ()
1213   "Toggle TLS encryption mode."
1214   (interactive)
1215   (setq elpher-use-tls (not elpher-use-tls))
1216   (if elpher-use-tls
1217       (if (gnutls-available-p)
1218           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1219         (setq elpher-use-tls nil)
1220         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1221     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1222
1223 (defun elpher-view-raw ()
1224   "View raw server response for current page."
1225   (interactive)
1226   (if elpher-current-node
1227       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1228           (error "This page was not generated by a server")
1229         (elpher-visit-node elpher-current-node
1230                            #'elpher-render-raw))
1231     (message "No current site.")))
1232
1233 (defun elpher-back ()
1234   "Go to previous site."
1235   (interactive)
1236   (if (elpher-node-parent elpher-current-node)
1237       (elpher-visit-parent-node)
1238     (error "No previous site")))
1239
1240 (defun elpher-download ()
1241   "Download the link at point."
1242   (interactive)
1243   (let ((button (button-at (point))))
1244     (if button
1245         (let ((node (button-get button 'elpher-node)))
1246           (if (elpher-address-special-p (elpher-node-address node))
1247               (error "Cannot download %s"
1248                      (elpher-node-display-string node))
1249             (elpher-visit-node (button-get button 'elpher-node)
1250                                #'elpher-render-download)))
1251       (error "No link selected"))))
1252
1253 (defun elpher-download-current ()
1254   "Download the current page."
1255   (interactive)
1256   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1257       (error "Cannot download %s"
1258              (elpher-node-display-string elpher-current-node))
1259     (elpher-visit-node (elpher-make-node
1260                         (elpher-node-display-string elpher-current-node)
1261                         (elpher-node-address elpher-current-node)
1262                         elpher-current-node)
1263                        #'elpher-render-download
1264                        t)))
1265
1266 (defun elpher-build-link-map ()
1267   "Build alist mapping link names to destination nodes in current buffer."
1268   (let ((link-map nil)
1269         (b (next-button (point-min) t)))
1270     (while b
1271       (push (cons (button-label b) b) link-map)
1272       (setq b (next-button (button-start b))))
1273     link-map))
1274
1275 (defun elpher-jump ()
1276   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1277   (interactive)
1278   (let* ((link-map (elpher-build-link-map)))
1279     (if link-map
1280         (let ((key (let ((completion-ignore-case t))
1281                      (completing-read "Directory item/link: "
1282                                       link-map nil t))))
1283           (if (and key (> (length key) 0))
1284               (let ((b (cdr (assoc key link-map))))
1285                 (goto-char (button-start b))
1286                 (button-activate b)))))))
1287
1288 (defun elpher-root-dir ()
1289   "Visit root of current server."
1290   (interactive)
1291   (let ((address (elpher-node-address elpher-current-node)))
1292     (if (not (elpher-address-special-p address))
1293         (if (or (member (url-filename address) '("/" ""))
1294                 (and (elpher-address-gopher-p address)
1295                      (= (length (elpher-gopher-address-selector address)) 0)))
1296             (error "Already at root directory of current server")
1297           (let ((address-copy (elpher-address-from-url
1298                                (elpher-address-to-url address))))
1299             (setf (url-filename address-copy) "")
1300             (elpher-visit-node
1301              (elpher-make-node (elpher-address-to-url address-copy)
1302                                address-copy))))
1303       (error "Command invalid for %s" (elpher-node-display-string elpher-current-node)))))
1304
1305 (defun elpher-bookmarks-current-p ()
1306   "Return non-nil if current node is a bookmarks page."
1307   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1308          '(special bookmarks)))
1309
1310 (defun elpher-reload-bookmarks ()
1311   "Reload bookmarks if current node is a bookmarks page."
1312   (if (elpher-bookmarks-current-p)
1313       (elpher-reload-current-node)))
1314
1315 (defun elpher-bookmark-current ()
1316   "Bookmark the current node."
1317   (interactive)
1318   (let ((address (elpher-node-address elpher-current-node))
1319         (display-string (elpher-node-display-string elpher-current-node)))
1320     (if (not (elpher-address-special-p address))
1321         (let ((bookmark-display-string (read-string "Bookmark display string: "
1322                                                     display-string)))
1323           (elpher-add-address-bookmark address bookmark-display-string)
1324           (message "Bookmark added."))
1325       (error "Cannot bookmark %s" display-string))))
1326
1327 (defun elpher-bookmark-link ()
1328   "Bookmark the link at point."
1329   (interactive)
1330   (let ((button (button-at (point))))
1331     (if button
1332         (let* ((node (button-get button 'elpher-node))
1333                (address (elpher-node-address node))
1334                (display-string (elpher-node-display-string node)))
1335           (if (not (elpher-address-special-p address))
1336               (let ((bookmark-display-string (read-string "Bookmark display string: "
1337                                                           display-string)))
1338                 (elpher-add-address-bookmark address bookmark-display-string)
1339                 (elpher-reload-bookmarks)
1340                 (message "Bookmark added."))
1341             (error "Cannot bookmark %s" display-string)))
1342       (error "No link selected"))))
1343
1344 (defun elpher-unbookmark-current ()
1345   "Remove bookmark for the current node."
1346   (interactive)
1347   (let ((address (elpher-node-address elpher-current-node)))
1348     (unless (elpher-address-special-p address)
1349       (elpher-remove-address-bookmark address)
1350       (message "Bookmark removed."))))
1351
1352 (defun elpher-unbookmark-link ()
1353   "Remove bookmark for the link at point."
1354   (interactive)
1355   (let ((button (button-at (point))))
1356     (if button
1357         (let ((node (button-get button 'elpher-node)))
1358           (elpher-remove-address-bookmark (elpher-node-address node))
1359           (elpher-reload-bookmarks)
1360           (message "Bookmark removed."))
1361       (error "No link selected"))))
1362
1363 (defun elpher-bookmarks ()
1364   "Visit bookmarks page."
1365   (interactive)
1366   (switch-to-buffer "*elpher*")
1367   (elpher-visit-node
1368    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1369
1370 (defun elpher-info-node (node)
1371   "Display information on NODE."
1372   (let ((display-string (elpher-node-display-string node))
1373         (address (elpher-node-address node)))
1374     (if (elpher-address-special-p address)
1375         (message "Special page: %s" display-string)
1376       (message "%s" (elpher-address-to-url address)))))
1377
1378 (defun elpher-info-link ()
1379   "Display information on node corresponding to link at point."
1380   (interactive)
1381   (let ((button (button-at (point))))
1382     (if button
1383         (elpher-info-node (button-get button 'elpher-node))
1384       (error "No item selected"))))
1385
1386 (defun elpher-info-current ()
1387   "Display information on current node."
1388   (interactive)
1389   (elpher-info-node elpher-current-node))
1390
1391 (defun elpher-copy-node-url (node)
1392   "Copy URL representation of address of NODE to `kill-ring'."
1393   (let ((address (elpher-node-address node)))
1394     (if (elpher-address-special-p address)
1395         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1396       (let ((url (elpher-address-to-url address)))
1397         (message "Copied \"%s\" to kill-ring/clipboard." url)
1398         (kill-new url)))))
1399
1400 (defun elpher-copy-link-url ()
1401   "Copy URL of item at point to `kill-ring'."
1402   (interactive)
1403   (let ((button (button-at (point))))
1404     (if button
1405         (elpher-copy-node-url (button-get button 'elpher-node))
1406       (error "No item selected"))))
1407
1408 (defun elpher-copy-current-url ()
1409   "Copy URL of current node to `kill-ring'."
1410   (interactive)
1411   (elpher-copy-node-url elpher-current-node))
1412
1413 (defun elpher-set-gopher-coding-system ()
1414   "Specify an explicit character coding system for gopher selectors."
1415   (interactive)
1416   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1417     (setq elpher-user-coding-system system)
1418     (if system
1419         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1420       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1421
1422
1423 ;;; Mode and keymap
1424 ;;
1425
1426 (defvar elpher-mode-map
1427   (let ((map (make-sparse-keymap)))
1428     (define-key map (kbd "TAB") 'elpher-next-link)
1429     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1430     (define-key map (kbd "u") 'elpher-back)
1431     (define-key map [mouse-3] 'elpher-back)
1432     (define-key map (kbd "O") 'elpher-root-dir)
1433     (define-key map (kbd "g") 'elpher-go)
1434     (define-key map (kbd "o") 'elpher-go-current)
1435     (define-key map (kbd "r") 'elpher-redraw)
1436     (define-key map (kbd "R") 'elpher-reload)
1437     (define-key map (kbd "T") 'elpher-toggle-tls)
1438     (define-key map (kbd ".") 'elpher-view-raw)
1439     (define-key map (kbd "d") 'elpher-download)
1440     (define-key map (kbd "D") 'elpher-download-current)
1441     (define-key map (kbd "m") 'elpher-jump)
1442     (define-key map (kbd "i") 'elpher-info-link)
1443     (define-key map (kbd "I") 'elpher-info-current)
1444     (define-key map (kbd "c") 'elpher-copy-link-url)
1445     (define-key map (kbd "C") 'elpher-copy-current-url)
1446     (define-key map (kbd "a") 'elpher-bookmark-link)
1447     (define-key map (kbd "A") 'elpher-bookmark-current)
1448     (define-key map (kbd "x") 'elpher-unbookmark-link)
1449     (define-key map (kbd "X") 'elpher-unbookmark-current)
1450     (define-key map (kbd "B") 'elpher-bookmarks)
1451     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1452     (when (fboundp 'evil-define-key*)
1453       (evil-define-key* 'motion map
1454         (kbd "TAB") 'elpher-next-link
1455         (kbd "C-") 'elpher-follow-current-link
1456         (kbd "C-t") 'elpher-back
1457         (kbd "u") 'elpher-back
1458         [mouse-3] 'elpher-back
1459         (kbd "g") 'elpher-go
1460         (kbd "o") 'elpher-go-current
1461         (kbd "r") 'elpher-redraw
1462         (kbd "R") 'elpher-reload
1463         (kbd "T") 'elpher-toggle-tls
1464         (kbd ".") 'elpher-view-raw
1465         (kbd "d") 'elpher-download
1466         (kbd "D") 'elpher-download-current
1467         (kbd "m") 'elpher-jump
1468         (kbd "i") 'elpher-info-link
1469         (kbd "I") 'elpher-info-current
1470         (kbd "c") 'elpher-copy-link-url
1471         (kbd "C") 'elpher-copy-current-url
1472         (kbd "a") 'elpher-bookmark-link
1473         (kbd "A") 'elpher-bookmark-current
1474         (kbd "x") 'elpher-unbookmark-link
1475         (kbd "X") 'elpher-unbookmark-current
1476         (kbd "B") 'elpher-bookmarks
1477         (kbd "S") 'elpher-set-gopher-coding-system))
1478     map)
1479   "Keymap for gopher client.")
1480
1481 (define-derived-mode elpher-mode special-mode "elpher"
1482   "Major mode for elpher, an elisp gopher client.
1483
1484 This mode is automatically enabled by the interactive
1485 functions which initialize the gopher client, namely
1486 `elpher', `elpher-go' and `elpher-bookmarks'.")
1487
1488 (when (fboundp 'evil-set-initial-state)
1489   (evil-set-initial-state 'elpher-mode 'motion))
1490
1491
1492 ;;; Main start procedure
1493 ;;
1494
1495 ;;;###autoload
1496 (defun elpher ()
1497   "Start elpher with default landing page."
1498   (interactive)
1499   (if (get-buffer "*elpher*")
1500       (switch-to-buffer "*elpher*")
1501     (switch-to-buffer "*elpher*")
1502     (setq elpher-current-node nil)
1503     (let ((start-node (elpher-make-node "Elpher Start Page"
1504                                         (elpher-make-special-address 'start))))
1505       (elpher-visit-node start-node)))
1506   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1507
1508 ;;; elpher.el ends here