ez.el

   1 ;;; ez.el --- Emacs Z-machine
   2
   3 ;; Copyright (C) 2021 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <timv@ughan.xyz>
   6 ;; Created: 13 Oct 2021
   7 ;; Version: 1.0
   8 ;; Keywords: game
   9 ;; Homepage: http://thelambdalab.xyz/ez
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 ;; Utility functions
  32
  33 (defun ez-decode-signed-bits (n nbits)
  34   (if (= 0 (lsh n (- 1 nbits)))
  35       n
  36     (- n (lsh 1 nbits))))
  37
  38 (defun ez-decode-signed-byte (b)
  39   (ez-decode-signed-bits b 8))
  40
  41 (defun ez-decode-signed-word (w)
  42   (ez-decode-signed-bits w 16))
  43
  44 (defun ez-decode-signed-operand (operand operand-type)
  45   (if (eq operand-type 'b)
  46       (ez-decode-signed-byte operand)
  47     (ez-decode-signed-word operand)))
  48
  49 (defun binformat (n &optional s)
  50   (unless s
  51     (setq s ""))
  52   (let ((d (/ n 2))
  53         (new-s (concat (number-to-string (mod n 2)) s)))
  54     (if (= d 0)
  55         new-s
  56       (binformat d new-s))))
  57
  58 ;; Memory
  59
  60 (defvar ez-memory nil
  61   "Memory of z-machine.")
  62
  63 (defvar ez-version nil)
  64
  65 (defvar ez-start-pc nil)
  66 (defvar ez-himem-base nil)
  67 (defvar ez-dict-base nil)
  68 (defvar ez-objtab-addr nil)
  69 (defvar ez-abbrevtab-addr nil)
  70 (defvar ez-globalvartab-addr nil)
  71
  72 (defun ez-mem-ref-byte (addr)
  73   (aref ez-memory addr))
  74
  75 (defun ez-mem-set-byte (addr val)
  76   (aset ez-memory addr val))
  77
  78 (defun ez-mem-ref-word (addr)
  79   (+ (* 256 (aref ez-memory addr))
  80      (aref ez-memory (+ addr 1))))
  81
  82 (defun ez-mem-set-word (addr val)
  83   (let ((byte-high (/ val 256))
  84         (byte-low (mod val 256)))
  85     (aset ez-memory addr byte-high)
  86     (aset ez-memory (+ addr 1) byte-low)))
  87
  88 (defun ez-parse-header ()
  89   (setq ez-version (ez-mem-ref-byte #x0))
  90   (setq ez-himem-addr (ez-mem-ref-word #x4))
  91   (setq ez-start-pc (ez-mem-ref-word #x6))
  92   (setq ez-dict-base (ez-mem-ref-word #x8))
  93   (setq ez-objtab-addr (ez-mem-ref-word #xA))
  94   (setq ez-globalvartab-addr (ez-mem-ref-word #xC))
  95   (setq ez-abbrevtab-addr (ez-mem-ref-word #x18)))
  96
  97 (defun ez-load-file (filename)
  98   "Load story file into memory."
  99   (with-temp-buffer
 100     (insert-file-contents-literally filename)
 101     (setq ez-memory (encode-coding-string (buffer-string) 'raw-text)))
 102   'done)
 103
 104 ;; Global variables
 105
 106 (defun ez-get-global-var (gvar)
 107   (if (> gvar 239)
 108       (error "Invalid global variable %d" gvar))
 109   (ez-mem-ref-word (+ (* 2 gvar) ez-globalvartab-addr)))
 110
 111 (defun ez-set-global-var (gvar val)
 112   (ez-mem-set-word (+ (* 2 gvar) ez-globalvartab-addr) val))
 113
 114 ;; Object tree
 115
 116 (defvar ez-property-defaults nil)
 117
 118 (defun ez-load-property-defaults ()
 119   (setq ez-property-defaults (make-vector 31 0))
 120   (dotimes (i 31)
 121     (aset ez-property-defaults i (aref ez-memory (+ ez-objtab-addr (* 2 i))))))
 122
 123 (defun ez-get-obj-addr (obj)
 124   (+ ez-objtab-addr (* 2 31) (* 9 (- obj 1))))
 125
 126 (defun ez-get-obj-parent (obj)
 127   (let ((addr (ez-get-obj-addr obj)))
 128     (ez-mem-ref-byte (+ addr 4))))
 129
 130 (defun ez-set-obj-parent (obj new-parent)
 131   (let ((addr (ez-get-obj-addr obj)))
 132     (ez-mem-set-byte (+ addr 4) new-parent)))
 133
 134 (defun ez-get-obj-sibling (obj)
 135   (let ((addr (ez-get-obj-addr obj)))
 136     (ez-mem-ref-byte (+ addr 5))))
 137
 138 (defun ez-set-obj-sibling (obj new-sibling)
 139   (let ((addr (ez-get-obj-addr obj)))
 140     (ez-mem-set-byte (+ addr 5) new-sibling)))
 141
 142 (defun ez-get-obj-child (obj)
 143   (let ((addr (ez-get-obj-addr obj)))
 144     (ez-mem-ref-byte (+ addr 6))))
 145
 146 (defun ez-set-obj-child (obj new-child)
 147   (let ((addr (ez-get-obj-addr obj)))
 148     (ez-mem-set-byte (+ addr 6) new-child)))
 149
 150 (defun ez-get-obj-plist-addr (obj)
 151   (let ((addr (ez-get-obj-addr obj)))
 152     (ez-mem-ref-word (+ addr 7))))
 153
 154 (defun ez-get-obj-name (obj)
 155   (let ((plist-addr (ez-get-obj-plist-addr obj)))
 156     (if (> (ez-mem-ref-byte plist-addr) 0)
 157         (ez-get-zstring (+ 1 (ez-get-obj-plist-addr obj)))
 158       nil)))
 159
 160 (defun ez-get-prop-default (prop)
 161   (ez-mem-ref-word (+ ez-objtab-addr (* 2 (+ 1 prop)))))
 162
 163 (defun ez-get-prop-len (prop-size-byte)
 164   (lsh prop-size-byte -5))
 165
 166 (defun ez-get-prop-num (prop-size-byte)
 167   (logand #b00011111 prop-size-byte))
 168
 169 (defun ez-get-obj-prop-addr (obj prop)
 170   (let* ((plist-addr (ez-get-obj-plist-addr obj))
 171          (prop-addr (+ plist-addr 1 (* 2 (ez-mem-ref-byte plist-addr))))
 172          (size-byte (ez-mem-ref-byte prop-addr)))
 173     (while (not (or (= size-byte 0)
 174                     (= prop (ez-get-prop-num size-byte))))
 175       (setq prop-addr (+ prop-addr (ez-get-prop-len size-byte) 2)
 176             size-byte (ez-mem-ref-byte prop-addr)))
 177     prop-addr))
 178
 179 (defun ez-get-obj-prop (obj prop)
 180   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 181          (size-byte (ez-mem-ref-byte prop-addr)))
 182     (if (= size-byte 0)
 183         (ez-get-prop-default prop)
 184       (let ((prop-len (ez-get-prop-len size-byte))
 185             (data-addr (+ prop-addr 1)))
 186         (cond
 187          ((= prop-len 0)
 188           (ez-mem-ref-byte data-addr))
 189          ((>= prop-len 1)
 190           (ez-mem-ref-word data-addr)))))))
 191
 192 (defun ez-set-obj-prop (obj prop value)
 193   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 194          (size-byte (ez-mem-ref-byte prop-addr)))
 195     (cond
 196      ((= size-byte 0)
 197       (error "Tried to set non-existant property"))
 198      ((= (ez-get-prop-len size-byte) 1)
 199       (ez-mem-set-byte (+ prop-addr 1) value))
 200      (t
 201       (ez-mem-set-word (+ prop-addr 1) value)))))
 202
 203 (defun ez-get-obj-attr (obj attr)
 204   (let* ((byte-num (/ attr 8))
 205          (bit-num (mod attr 8))
 206          (bit-mask (lsh 1 (- 7 bit-num))))
 207     (if (> (logand bit-mask (ez-mem-ref-byte (+ (ez-get-obj-addr obj) byte-num))) 0)
 208         1
 209       0)))
 210
 211 (defun ez-set-obj-attr (obj attr val)
 212   (let* ((byte-num (/ attr 8))
 213          (bit-num (mod attr 8))
 214          (bit-mask (lsh 1 (- 7 bit-num)))
 215          (byte-addr (+ (ez-get-obj-addr obj) byte-num))
 216          (byte (ez-mem-ref-byte byte-addr))
 217          (current-set (> (logand bit-mask byte) 0)))
 218     (if (or (and current-set (= val 0))
 219             (and (not current-set) (> val 0)))
 220         (ez-mem-set-byte byte-addr (logxor byte bit-mask)))))
 221
 222
 223 (defun ez-remove-obj (obj)
 224   (let ((parent (ez-get-obj-parent obj))
 225         (sibling (ez-get-obj-sibling obj)))
 226     (unless (= parent 0)
 227       (let ((child (ez-get-obj-child parent)))
 228         (if (= child obj)
 229             (ez-set-obj-child parent sibling)
 230           (while (not (= obj (ez-get-obj-sibling child)))
 231             (setq child (ez-get-obj-sibling child)))
 232           (ez-set-obj-sibling child (ez-get-obj-sibling obj))))
 233       (ez-set-obj-parent obj 0))
 234     (ez-set-obj-sibling obj 0)))
 235
 236 (defun ez-insert-obj (obj new-parent)
 237   (ez-remove-obj obj)
 238   (unless (= new-parent 0)
 239     (ez-set-obj-sibling obj (ez-get-obj-child new-parent))
 240     (ez-set-obj-child new-parent obj)))
 241
 242 ;; Z-strings
 243
 244 (defvar ez-zstring-alphabets
 245   ;                1    1    2    2    3
 246   ;      0    5    0    5    0    5    0
 247   (list "      abcdefghijklmnopqrstuvwxyz"
 248         "      ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 249         "       \n0123456789.,!?_#'\"/\\-:()")
 250   "Alphabets used by V3")
 251
 252 (defun ez-parse-zstring-word (word)
 253   (list (lsh word -15)
 254         (logand (lsh word -10) #b11111)
 255         (logand (lsh word -5) #b11111)
 256         (logand word #b11111)))
 257
 258 (defun ez-get-zstring-chars-and-length (base-addr)
 259   (let ((addr base-addr)
 260         (chars nil)
 261         (not-done t)
 262         (word-count 0))
 263     (while not-done
 264       (let ((components (ez-parse-zstring-word (ez-mem-ref-word addr))))
 265         (setq chars (append chars (cdr components)))
 266         (setq addr (+ addr 2))
 267         (setq word-count (+ word-count 1))
 268         (when (= (car components) 1)
 269           (setq not-done nil))))
 270     (cons word-count chars)))
 271
 272 (defun ez-get-zstring-and-length (base-addr)
 273   (let* ((word-count-and-chars (ez-get-zstring-chars-and-length base-addr))
 274          (word-count (car word-count-and-chars))
 275          (chars (cdr word-count-and-chars))
 276          (cur 0)
 277          (lock 0)
 278          (abbrev-char nil)
 279          (s ""))
 280     (dolist (char chars)
 281       (cond
 282        (abbrev-char
 283         (let ((abbrev-addr
 284                (* 2 (ez-mem-ref-word (+ ez-abbrevtab-addr
 285                                         (* 2 (+ (* (- abbrev-char 1) 32) char)))))))
 286           (setq s (concat s (cdr (ez-get-zstring-and-length abbrev-addr)))))
 287         (setq abbrev-char nil))
 288        ((memq char '(1 2 3)) ;Abbreviation
 289         (setq abbrev-char char))
 290        ((= char 4)
 291         (setq cur (mod (+ cur 1) 3)))
 292        ((= char 5)
 293         (setq cur (mod (+ 3 (- cur 1)) 3)))
 294        (t
 295         (setq s (concat s (substring (elt ez-zstring-alphabets cur)
 296                                      char (+ char 1))))
 297         (setq cur lock))))
 298     (cons word-count s)))
 299
 300 (defun ez-get-zstring (base-addr)
 301   (cdr (ez-get-zstring-and-length base-addr)))
 302
 303
 304 ;; Call stack
 305
 306 (defvar ez-call-stack nil)
 307
 308 (defun ez-make-call-stack-frame (pc &optional call-method)
 309   (list pc
 310         nil
 311         (make-vector 15 0)
 312         call-method))
 313
 314 (defun ez-add-call-stack-frame (pc &optional call-method)
 315   (push (ez-make-call-stack-frame pc call-method) ez-call-stack))
 316
 317 (defun ez-pop-call-stack-frame ()
 318   (pop ez-call-stack))
 319
 320 (defun ez-routine-stack ()
 321   (elt (car ez-call-stack) 1))
 322
 323 (defun ez-routine-stack-push (val)
 324   (let ((frame (car ez-call-stack)))
 325     (setf (elt frame 1) (cons val (elt frame 1)))))
 326
 327 (defun ez-routine-stack-pop ()
 328   (let* ((frame (car ez-call-stack))
 329          (rs-head (car (elt frame 1))))
 330     (setf (elt frame 1) (cdr (elt frame 1)))
 331     rs-head))
 332
 333 (defun ez-get-local-var (lvar)
 334   (let ((frame (car ez-call-stack)))
 335     (aref (elt frame 2) (- lvar 1))))
 336
 337 (defun ez-set-local-var (lvar val)
 338   (let ((frame (car ez-call-stack)))
 339     (aset (elt frame 2) (- lvar 1) val)))
 340
 341 (defun ez-get-pc ()
 342   (caar ez-call-stack))
 343
 344 (defun ez-set-pc (new-pc)
 345   (setf (car (car ez-call-stack)) new-pc))
 346
 347 (defun ez-increment-pc (inc)
 348   (ez-set-pc (+ (ez-get-pc) inc)))
 349
 350 (defun ez-read-pc-byte-and-inc ()
 351   (let ((res (ez-mem-ref-byte (ez-get-pc))))
 352     (ez-increment-pc 1)
 353     res))
 354
 355 (defun ez-read-pc-word-and-inc ()
 356   (let ((res (ez-mem-ref-word (ez-get-pc))))
 357     (ez-increment-pc 2)
 358     res))
 359
 360 ;; Instruction execution
 361
 362 (defun ez-get-var (var)
 363   (cond
 364    ((= var 0)
 365     (ez-routine-stack-pop))
 366    ((< var 16)
 367     (ez-get-local-var var))
 368    (t
 369     (ez-get-global-var (- var 16)))))
 370
 371 (defun ez-set-var (var val)
 372   (cond
 373    ((= var 0)
 374     (ez-routine-stack-push val))
 375    ((< var 16)
 376     (ez-set-local-var var val))
 377    (t
 378     (ez-set-global-var (- var 16) val))))
 379
 380 (defun ez-read-pc-var-and-inc ()
 381   (ez-get-var (ez-read-pc-byte-and-inc)))
 382
 383 (defun ez-execute-instr ()
 384   (let ((instr-pc (ez-get-pc))
 385         (opbyte (ez-read-pc-byte-and-inc))
 386         (optype) (opcode) (operands))
 387     (cond
 388      ((<= #x0 opbyte #x1f)
 389       (setq optype '2op
 390             opcode opbyte
 391             operands (list (ez-read-pc-byte-and-inc)
 392                            (ez-read-pc-byte-and-inc))
 393             operand-types '(b b)))
 394      ((<= #x20 opbyte #x3F)
 395       (setq optype '2op
 396             opcode (- opbyte #x20)
 397             operands (list (ez-read-pc-byte-and-inc)
 398                            (ez-read-pc-var-and-inc))
 399             operand-types '(b w)))
 400      ((<= #x40 opbyte #x5F)
 401       (setq optype '2op
 402             opcode (- opbyte #x40)
 403             operands (list (ez-read-pc-var-and-inc)
 404                            (ez-read-pc-byte-and-inc))
 405             operand-types '(w b)))
 406      ((<= #x60 opbyte #x7F)
 407       (setq optype '2op
 408             opcode (- opbyte #x60)
 409             operands (list (ez-read-pc-var-and-inc)
 410                            (ez-read-pc-var-and-inc))
 411             operand-types '(w w)))
 412      ((<= #x80 opbyte #x8F)
 413       (setq optype '1op
 414             opcode (- opbyte #x80)
 415             operands (list (ez-read-pc-word-and-inc))
 416             operand-types '(w)))
 417      ((<= #x90 opbyte #x9F)
 418       (setq optype '1op
 419             opcode (- opbyte #x90)
 420             operands (list (ez-read-pc-byte-and-inc))
 421             operand-types '(b)))
 422      ((<= #xA0 opbyte #xAF)
 423       (setq optype '1op
 424             opcode (- opbyte #xa0)
 425             operands (list (ez-read-pc-var-and-inc))
 426             operand-types '(w)))
 427      ((<= #xB0 opbyte #xBF)
 428       (setq optype '0op
 429             opcode (- opbyte #xb0)
 430             operands '()
 431             operand-types '()))
 432      ((<= #xC0 opbyte #xDF)
 433       (setq optype '2op
 434             opcode (- opbyte #xc0))
 435       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 436         (setq operands (car operands-and-types)
 437               operand-types (cdr operands-and-types))))
 438      ((<= #xE0 opbyte #xFF)
 439       (setq optype 'var
 440             opcode (- opbyte #xe0))
 441       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 442         (setq operands (car operands-and-types)
 443               operand-types (cdr operands-and-types)))))
 444     (let ((table-row (assoc (list optype opcode) ez-op-table)))
 445       (unless table-row
 446         (error "Unsupported op PC:%x Optype:%s Opcode:%x Operands:%s Operand-types:%s"
 447                instr-pc optype opcode operands operand-types))
 448       (let ((mnemonic (elt table-row 1)))
 449         (message "PC:%x Optype:%s Opcode:%x Mnemonic:%s Operands:%s Operand-types:%s"
 450                  instr-pc optype opcode mnemonic operands operand-types))
 451       (funcall (elt table-row 2) operands operand-types))))
 452
 453 (defun ez-read-var-operands-and-inc ()
 454   (let* ((type-byte (ez-read-pc-byte-and-inc))
 455          (types (let ((type1 (lsh type-byte -6)))
 456                   (if (= type1 #b11)
 457                       nil
 458                     (cons type1
 459                           (let ((type2 (lsh (logand #b110000 type-byte) -4)))
 460                             (if (= type2 #b11)
 461                                 nil
 462                               (cons type2
 463                                     (let ((type3 (lsh (logand #b1100 type-byte) -2)))
 464                                       (if (= type3 #b11)
 465                                           nil
 466                                         (cons type3
 467                                               (let ((type4 (logand #b11)))
 468                                                 (if (= type4 #b11)
 469                                                     nil
 470                                                   (list type4))))))))))))))
 471     (cons
 472      (mapcar
 473       (lambda (type)
 474         (cond
 475          ((= type 0) (ez-read-pc-word-and-inc))
 476          ((= type 1) (ez-read-pc-byte-and-inc))
 477          ((= type 2) (ez-read-pc-var-and-inc))))
 478       types)
 479      (mapcar
 480       (lambda (type)
 481         (if (= type 1)
 482             'b
 483           'w))
 484       types))))
 485
 486 ;; Branches
 487
 488 (defun ez-do-branch (branch)
 489   (let* ((branch-byte (ez-read-pc-byte-and-inc))
 490          (invert (= 0 (logand branch-byte #b10000000)))
 491          (single-byte (> (logand branch-byte #b01000000) 0))
 492          (offset
 493           (if single-byte
 494               (logand branch-byte #b00111111)
 495             (let ((pos (= (logand branch-byte #b00100000) 0))
 496                   (val (+ (* 256 (logand branch-byte #b00011111))
 497                           (ez-read-pc-byte-and-inc))))
 498               (if pos
 499                   val
 500                 (- val 8192))))))
 501     (if (or (and branch (not invert))
 502             (and (not branch) invert))
 503         (cond
 504          ((= offset 0)
 505           (ez-op-rfalse))
 506          ((= offset 1)
 507           (ez-op-rtrue))
 508          (t
 509           (ez-set-pc (+ (ez-get-pc) offset -2)))))))
 510
 511 ;; Operations
 512
 513 (defvar ez-op-table
 514   '(((0op #x00) rtrue ez-op-rtrue)
 515     ((0op #x01) rfalse ez-op-rfalse)
 516     ((1op #x00) jz ez-op-jz)
 517     ((1op #x05) inc ez-op-inc)
 518     ((1op #x06) dec ez-op-dec)
 519     ((1op #x0B) ret ez-op-ret)
 520     ((1op #x0C) jump ez-op-jump)
 521     ((2op #x05) inc_jg ez-op-inc-jg)
 522     ((2op #x04) dec_jg ez-op-dec-jg)
 523     ((2op #x0D) store ez-op-store)
 524     ((1op #x0E) load ez-op-load)
 525     ((var #x01) storew ez-op-storew)
 526     ((2op #x0F) loadw ez-op-loadw)
 527     ((var #x02) storeb ez-op-storeb)
 528     ((2op #x10) loadb ez-op-loadb)
 529     ((2op #x01) je ez-op-je)
 530     ((2op #x02) jl ez-op-jl)
 531     ((2op #x06) jin ez-op-jin)
 532     ((2op #x08) or ez-op-or)
 533     ((2op #x09) and ez-op-and)
 534     ((2op #x14) add ez-op-add)
 535     ((2op #x15) sub ez-op-sub)
 536     ((2op #x16) mul ez-op-mul)
 537     ((2op #x17) div ez-op-div)
 538     ((2op #x18) mod ez-op-mod)
 539     ((var #x00) call_fv ez-op-callf)
 540     ((1op #x01) get_sibling ez-op-get-sibling)
 541     ((1op #x02) get_child ez-op-get-child)
 542     ((1op #x03) get_parent ez-op-get-parent)
 543     ((2op #x0A) test_attr ez-op-test-attr)
 544     ((2op #x0B) set_attr ez-op-set-attr)
 545     ((2op #x0C) clear_attr ez-op-clear-attr)
 546     ((1op #x09) remove_obj ez-op-remove-obj)
 547     ((2op #x0E) insert_obj ez-op-insert-obj)
 548     ((var #x03) put_prop ez-op-put-prop)
 549     ((2op #x11) get_prop ez-op-get-prop)
 550     ((0op #x02) print ez-op-print)
 551     ((0op #x0B) new_line ez-op-new-line)
 552     ((var #x06) print_num ez-op-print-num)
 553     ((var #x05) print_char ez-op-print-char)
 554     ((1op #x0A) print_obj ez-op-print-obj)))
 555
 556 (defun ez-op-ret (operands &optional operand-types)
 557   (let ((retval (car operands)))
 558     (ez-pop-call-stack-frame)
 559     (ez-set-var (ez-read-pc-byte-and-inc) retval))
 560   t)
 561
 562 (defun ez-op-rtrue (&optional operands operand-types)
 563   (ez-op-ret (list 1))
 564   t)
 565
 566 (defun ez-op-rfalse (&optional operands operand-types)
 567   (ez-op-ret (list 0))
 568   t)
 569
 570 (defun ez-op-jz (operands operand-types)
 571   (ez-do-branch (= (car operands) 0))
 572   t)
 573
 574 (defun ez-op-je (operands operand-types)
 575   (ez-do-branch (memq (car operands) (cdr operands)))
 576   t)
 577
 578 (defun ez-op-jg (operands operand-types)
 579   (let ((s1 (ez-decode-signed-operand (car operands) (car operand-types)))
 580         (s2 (ez-decode-signed-operand (cadr operands) (cadr operand-types))))
 581     (ez-do-branch (> s1 s2)))
 582   t)
 583
 584 (defun ez-op-jl (operands operand-types)
 585   (let ((s1 (ez-decode-signed-operand (car operands) (car operand-types)))
 586         (s2 (ez-decode-signed-operand (cadr operands) (cadr operand-types))))
 587     (ez-do-branch (< s1 s2)))
 588   t)
 589
 590 (defun ez-op-inc-jg (operands operand-types)
 591   (let ((var (car operands)))
 592     (ez-op-inc (list var))
 593     (ez-op-jg (cons (ez-get-var var) (cdr operands)) (cons 'w (cdr operand-types))))
 594   t)
 595
 596 (defun ez-op-dec-jl (operands operand-types)
 597   (let ((var (car operands)))
 598     (ez-op-dec (list var))
 599     (ez-op-jl (cons (ez-get-var var) (cdr operands)) (cons 'w (cdr operand-types))))
 600   t)
 601
 602 (defun ez-op-jin (operands operand-types)
 603   (let ((obj (car operands))
 604         (n (cadr operands)))
 605     (ez-do-branch (or (= n 0)
 606                       (= n (ez-get-obj-parent obj)))))
 607   t)
 608
 609 (defun ez-op-jump (operands operand-types)
 610   (let ((offset (if (eq (car operand-types) 'b)
 611                     (ez-decode-signed-byte (car operands))
 612                   (ez-decode-signed-word (car operands)))))
 613     (ez-set-pc (+ (ez-get-pc) offset -2)))
 614   t)
 615
 616 (defun ez-op-inc (operands &optional operand-types)
 617   (let ((var (car operands)))
 618     (ez-set-var var (mod (+ 1 (ez-get-var var)) #x10000)))
 619   t)
 620
 621 (defun ez-op-dec (operands &optional operand-types)
 622   (let ((var (car operands)))
 623     (ez-set-var var (mod (+ (ez-get-var var) 1) #x10000)))
 624   t)
 625
 626 (defun ez-op-store (operands operand-types)
 627   (let ((var (car operands))
 628         (a (cadr operands)))
 629     (ez-set-var var a))
 630   t)
 631
 632 (defun ez-op-load (operands operand-types)
 633   (let ((var (car operands)))
 634     (ez-set-var (ez-read-pc-byte-and-inc) (ez-get-var var)))
 635   t)
 636
 637 (defun ez-op-storew (operands operand-types)
 638   (let ((baddr (car operands))
 639         (n (cadr operands))
 640         (a (caddr operands)))
 641     (ez-mem-set-word (+ baddr (* 2 n)) a))
 642   t)
 643
 644 (defun ez-op-loadw (operands operand-types)
 645   (let ((baddr (car operands))
 646         (n (cadr operands)))
 647     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-word (+ baddr (* 2 n)))))
 648   t)
 649
 650 (defun ez-op-storeb (operands operand-types)
 651   (let ((baddr (car operands))
 652         (n (cadr operands))
 653         (a (caddr operands)))
 654     (ez-mem-set-byte (+ baddr n) a))
 655   t)
 656
 657 (defun ez-op-loadb (operands operand-types)
 658   (let ((baddr (car operands))
 659         (n (cadr operands)))
 660     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-byte (+ baddr n))))
 661   t)
 662
 663 (defun ez-op-and (operands operand-types)
 664   (let ((a (car operands))
 665         (b (cadr operands)))
 666     (ez-set-var (ez-read-pc-byte-and-inc) (logand a b)))
 667   t)
 668
 669 (defun ez-op-or (operands operand-types)
 670   (let ((a (car operands))
 671         (b (cadr operands)))
 672     (ez-set-var (ez-read-pc-byte-and-inc) (logior a b)))
 673   t)
 674
 675 (defun ez-op-add (operands operand-types)
 676   (let ((a (car operands))
 677         (b (cadr operands)))
 678     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ a b) #x10000)))
 679   t)
 680
 681 (defun ez-op-sub (operands operand-types)
 682   (let ((a (car operands))
 683         (b (cadr operands)))
 684     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ (- a b) #x10000) #x10000)))
 685   t)
 686
 687 (defun ez-op-mul (a b)
 688   (let ((a (car operands))
 689         (b (cadr operands)))
 690     (ez-set-var (ez-read-pc-byte-and-inc) (mod (* a b) #x10000)))
 691   t)
 692
 693 (defun ez-op-div (a b)
 694   (error "Not implemented"))
 695
 696 (defun ez-op-mod (a b)
 697   (error "Not implemented"))
 698
 699 (defun ez-op-callf (operands operand-types)
 700   (let* ((raddr (car operands))
 701          (call-operands (cdr operands))
 702          (r (* 2 raddr))
 703          (L (ez-mem-ref-byte r))
 704          (n (length call-operands))
 705          (new-pc (+ r 1 (* L 2))))
 706     (ez-add-call-stack-frame new-pc)
 707     (dotimes (i L)
 708       (if (< i n)
 709           (ez-set-local-var (+ i 1) (elt call-operands i))
 710         (ez-set-local-var (+ i 1) (ez-mem-ref-word (+ r 1 (* 2 i)))))))
 711   t)
 712
 713 (defun ez-op-test-attr (operands operand-types)
 714   (let ((obj (car operands))
 715         (attr (cadr operands)))
 716     (ez-do-branch (= 1 (ez-get-obj-attr obj attr)))
 717     t))
 718
 719 (defun ez-op-set-attr (operands operand-types)
 720   (let ((obj (car operands))
 721         (attr (cadr operands)))
 722     (ez-set-obj-attr obj attr 1))
 723   t)
 724
 725 (defun ez-op-clear-attr (operands operand-types)
 726   (let ((obj (car operands))
 727         (attr (cadr operands)))
 728     (ez-set-obj-attr obj attr 0))
 729   t)
 730
 731 (defun ez-op-get-sibling (operands operand-types)
 732   (let ((sib (ez-get-obj-sibling (car operands))))
 733     (ez-set-var (ez-read-pc-byte-and-inc) sib)
 734     (ez-do-branch (> sib 0)))
 735   t)
 736
 737 (defun ez-op-get-child (operands operand-types)
 738   (let ((child (ez-get-obj-child (car operands))))
 739     (ez-set-var (ez-read-pc-byte-and-inc) child)
 740     (ez-do-branch (> child 0)))
 741   t)
 742
 743 (defun ez-op-get-parent (operands operand-types)
 744   (let ((parent (ez-get-obj-parent (car operands))))
 745     (ez-set-var (ez-read-pc-byte-and-inc) parent))
 746   t)
 747
 748 (defun ez-op-remove-obj (operands operand-types)
 749   (let ((obj (car operands)))
 750     (ez-remove-obj obj))
 751   t)
 752
 753 (defun ez-op-insert-obj (operands operand-types)
 754   (let ((obj1 (car operands))
 755         (obj2 (cadr operands)))
 756     (ez-insert-obj obj1 obj2))
 757   t)
 758
 759 (defun ez-op-put-prop (operands operand-types)
 760   (let* ((obj (car operands))
 761          (prop (cadr operands))
 762          (a (caddr operands)))
 763     (ez-set-obj-prop obj prop a))
 764   t)
 765
 766 (defun ez-op-get-prop (operands operand-types)
 767   (let* ((obj (car operands))
 768          (prop (cadr operands)))
 769     (ez-set-var (ez-read-pc-byte-and-inc)
 770                 (ez-get-obj-prop obj prop)))
 771   t)
 772
 773 (defun ez-op-print (operands operand-types)
 774   (let* ((word-count-and-string (ez-get-zstring-and-length (ez-get-pc)))
 775          (word-count (car word-count-and-string))
 776          (string (cdr word-count-and-string)))
 777     (ez-print string)
 778     (ez-increment-pc (* 2 word-count)))
 779   t)
 780
 781 (defun ez-op-new-line (operands operand-types)
 782   (ez-print "\n")
 783   t)
 784
 785 (defun ez-op-print-num (operands operand-types)
 786   (let ((s (ez-decode-signed-operand (car operands) (car operand-types))))
 787     (ez-print (number-to-string s)))
 788   t)
 789
 790 (defun ez-op-print-char (operands operand-types)
 791   (let ((c (car operands)))
 792     (ez-print (string c)))
 793   t)
 794
 795 (defun ez-op-print-obj (operands operand-types)
 796   (let ((obj (car operands)))
 797     (ez-print (ez-get-obj-name obj)))
 798   t)
 799
 800 ;; Execution loop
 801
 802 (defun ez-run (filename)
 803   (ez-load-file filename)
 804   (ez-parse-header)
 805   (setq ez-call-stack (list (ez-make-call-stack-frame ez-start-pc)))
 806
 807   (while (ez-execute-instr)))
 808
 809
 810 ;;; Buffer and I/O
 811 ;;
 812
 813 (defun ez-render-prompt ()
 814   (with-current-buffer "*ez*"
 815     (let ((update-point (= ez-input-marker (point)))
 816           (update-window-points (mapcar (lambda (w)
 817                                           (list (= (window-point w) ez-input-marker)
 818                                                 w))
 819                                         (get-buffer-window-list nil nil t))))
 820       (save-excursion
 821         (set-marker-insertion-type ez-prompt-marker nil)
 822         (set-marker-insertion-type ez-input-marker t)
 823         (let ((inhibit-read-only t))
 824           (delete-region ez-prompt-marker ez-input-marker)
 825           (goto-char ez-prompt-marker)
 826           (insert
 827            ">"
 828            (propertize " " ; Need this to be separate to mark it as rear-nonsticky
 829                        'read-only t
 830                        'rear-nonsticky t)))
 831         (set-marker-insertion-type ez-input-marker nil))
 832       (goto-char ez-input-marker))))
 833
 834 (defvar ez-prompt-marker nil
 835   "Marker for prompt position in buffer.")
 836
 837 (defvar ez-input-marker nil
 838   "Marker for prompt position in buffer.")
 839
 840 (defun ez-setup-buffer ()
 841   (with-current-buffer (get-buffer-create "*ez*")
 842     (let ((inhibit-read-only t))
 843       (delete-region (point-min) (point-max)))
 844     (setq-local scroll-conservatively 1)
 845     (if (markerp ez-prompt-marker)
 846         (set-marker ez-prompt-marker (point-max))
 847       (setq ez-prompt-marker (point-max-marker)))
 848     (if (markerp ez-input-marker)
 849         (set-marker ez-input-marker (point-max))
 850       (setq ez-input-marker (point-max-marker)))
 851     (goto-char (point-max))
 852     (ez-render-prompt)))
 853
 854
 855 (defun ez-print (string)
 856   (with-current-buffer "*ez*"
 857     (save-excursion
 858       (goto-char ez-prompt-marker)
 859       (insert-before-markers string))))
 860
 861 ;; Mode
 862
 863 (defvar ez-mode-map
 864   (let ((map (make-sparse-keymap)))
 865     (define-key map (kbd "RET") 'ez-enter)
 866     map))
 867
 868 (define-derived-mode ez-mode text-mode "ez"
 869   "Major mode for EZ.")
 870
 871 (when (fboundp 'evil-set-initial-state)
 872   (evil-set-initial-state 'ez-mode 'insert))
 873
 874 (defun ez (zfile)
 875   (interactive "fEnter name of z3 story file: ")
 876   (if (get-buffer "*ez*")
 877       (switch-to-buffer "*ez*")
 878     (switch-to-buffer "*ez*")
 879     (ez-mode)
 880     (ez-setup-buffer)
 881     (ez-run zfile))
 882   "Started EZ.")
 883
 884 (defun ez-debug ()
 885   (interactive)
 886   (switch-to-buffer "*ez*")
 887   (ez-mode)
 888   (ez-setup-buffer)
 889   (ez-run "zork1.z3"))
 890
 891 ;;; ez.el ends here