ez.el

   1 ;;; ez.el --- Emacs Z-machine
   2
   3 ;; Copyright (C) 2021 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <timv@ughan.xyz>
   6 ;; Created: 13 Oct 2021
   7 ;; Version: 1.0
   8 ;; Keywords: game
   9 ;; Homepage: http://thelambdalab.xyz/ez
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 ;; Utility functions
  32
  33 (defun ez-decode-signed-bits (n nbits)
  34   (if (= 0 (lsh n (- 1 nbits)))
  35       n
  36     (- n (lsh 1 nbits))))
  37
  38 (defun ez-decode-signed-byte (b)
  39   (ez-decode-signed-bits b 8))
  40
  41 (defun ez-decode-signed-word (w)
  42   (ez-decode-signed-bits w 16))
  43
  44 (defun binformat (n &optional s)
  45   (unless s
  46     (setq s ""))
  47   (let ((d (/ n 2))
  48         (new-s (concat (number-to-string (mod n 2)) s)))
  49     (if (= d 0)
  50         new-s
  51       (binformat d new-s))))
  52
  53 ;; Memory
  54
  55 (defvar ez-memory nil
  56   "Memory of z-machine.")
  57
  58 (defvar ez-version nil)
  59
  60 (defvar ez-start-pc nil)
  61 (defvar ez-himem-base nil)
  62 (defvar ez-dict-addr nil)
  63 (defvar ez-objtab-addr nil)
  64 (defvar ez-abbrevtab-addr nil)
  65 (defvar ez-globalvartab-addr nil)
  66
  67 (defun ez-mem-ref-byte (addr)
  68   (aref ez-memory addr))
  69
  70 (defun ez-mem-set-byte (addr val)
  71   (aset ez-memory addr val))
  72
  73 (defun ez-mem-ref-word (addr)
  74   (+ (* 256 (aref ez-memory addr))
  75      (aref ez-memory (+ addr 1))))
  76
  77 (defun ez-mem-set-word (addr val)
  78   (let ((byte-high (/ val 256))
  79         (byte-low (mod val 256)))
  80     (aset ez-memory addr byte-high)
  81     (aset ez-memory (+ addr 1) byte-low)))
  82
  83 (defun ez-parse-header ()
  84   (setq ez-version (ez-mem-ref-byte #x0))
  85   (setq ez-himem-addr (ez-mem-ref-word #x4))
  86   (setq ez-start-pc (ez-mem-ref-word #x6))
  87   (setq ez-dict-base (ez-mem-ref-word #x8))
  88   (setq ez-objtab-addr (ez-mem-ref-word #xA))
  89   (setq ez-globalvartab-addr (ez-mem-ref-word #xC))
  90   (setq ez-abbrevtab-addr (ez-mem-ref-word #x18)))
  91
  92 (defun ez-load-file (filename)
  93   "Load story file into memory."
  94   (with-temp-buffer
  95     (insert-file-contents-literally filename)
  96     (setq ez-memory (encode-coding-string (buffer-string) 'raw-text)))
  97   'done)
  98
  99 ;; Global variables
 100
 101 (defun ez-get-global-var (gvar)
 102   (ez-mem-ref-word (+ (* 2 gvar) ez-globalvartab-addr)))
 103
 104 (defun ez-set-global-var (gvar val)
 105   (ez-mem-set-word (+ (* 2 gvar) ez-globalvartab-addr) val))
 106
 107 ;; Object tree
 108
 109 (defvar ez-property-defaults nil)
 110
 111 (defun ez-load-property-defaults ()
 112   (setq ez-property-defaults (make-vector 31 0))
 113   (dotimes (i 31)
 114     (aset ez-property-defaults i (aref ez-memory (+ ez-objtab-addr (* 2 i))))))
 115
 116 (defun ez-get-obj-addr (obj-id)
 117   (+ ez-objtab-addr (* 2 31) (* 9 (- obj-id 1))))
 118
 119 (defun ez-get-obj-parent (obj-id)
 120   (let ((addr (ez-get-obj-addr obj-id)))
 121     (ez-mem-ref-byte (+ addr 4))))
 122
 123 (defun ez-get-obj-sibling (obj-id)
 124   (let ((addr (ez-get-obj-addr obj-id)))
 125     (ez-mem-ref-byte (+ addr 5))))
 126
 127 (defun ez-get-obj-child (obj-id)
 128   (let ((addr (ez-get-obj-addr obj-id)))
 129     (ez-mem-ref-byte (+ addr 6))))
 130
 131 (defun ez-get-obj-plist-addr (obj-id)
 132   (let ((addr (ez-get-obj-addr obj-id)))
 133     (ez-mem-ref-word (+ addr 7))))
 134
 135 (defun ez-get-obj-name (obj-id)
 136   (let ((plist-addr (ez-get-obj-plist-addr obj-id)))
 137     (if (> (ez-mem-ref-byte plist-addr) 0)
 138         (ez-get-zstring (+ 1 (ez-get-obj-plist-addr obj-id)))
 139       nil)))
 140
 141 (defun ez-get-obj (obj-id)
 142   (let ((addr (+ ez-objtab-addr
 143                  (* 2 31)
 144                  (* 9 (- obj-id 1)))))
 145     (list
 146      obj-id
 147      (ez-mem-ref-byte (+ addr 4))
 148      (ez-mem-ref-byte (+ addr 5))
 149      (ez-mem-ref-byte (+ addr 6))
 150      (ez-mem-ref-word (+ addr 7))
 151      (let ((plist-addr (ez-mem-ref-word (+ addr 7))))
 152        (if (> (ez-mem-ref-byte plist-addr) 0)
 153            (ez-get-zstring (+ 1 plist-addr))
 154          nil)))))
 155
 156 (defun ez-get-prop-default (prop)
 157   (ez-mem-ref-word (+ ez-objtab-addr (* 2 (+ 1 prop)))))
 158
 159 (defun ez-get-prop-len (prop-size-byte)
 160   (lsh prop-size-byte -5))
 161
 162 (defun ez-get-prop-num (prop-size-byte)
 163   (logand #b00011111 prop-size-byte))
 164
 165 (defun ez-get-obj-prop-addr (obj prop)
 166   (let* ((plist-addr (ez-get-obj-plist-addr obj))
 167          (prop-addr (+ plist-addr 1 (* 2 (ez-mem-ref-byte plist-addr))))
 168          (size-byte (ez-mem-ref-byte prop-addr)))
 169     (while (not (or (= size-byte 0)
 170                     (= prop (ez-get-prop-num size-byte))))
 171       (setq prop-addr (+ prop-addr (ez-get-prop-len size-byte) 2)
 172             size-byte (ez-mem-ref-byte prop-addr)))
 173     prop-addr))
 174
 175 (defun ez-get-obj-prop (obj prop)
 176   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 177          (size-byte (ez-mem-ref-byte prop-addr)))
 178     (if (= size-byte 0)
 179         (ez-get-prop-default prop)
 180       (let ((prop-len (ez-get-prop-len size-byte))
 181             (data-addr (+ prop-addr 1)))
 182         (cond
 183          ((= prop-len 0)
 184           (ez-mem-ref-byte data-addr))
 185          ((>= prop-len 1)
 186           (ez-mem-ref-word data-addr)))))))
 187
 188 (defun ez-set-obj-prop (obj prop value)
 189   (let* ((prop-addr (ez-get-obj-prop-addr obj prop))
 190          (size-byte (ez-mem-ref-byte prop-addr)))
 191     (cond
 192      ((= size-byte 0)
 193       (error "Tried to set non-existant property"))
 194      ((= (ez-get-prop-len size-byte) 1)
 195       (ez-mem-set-byte (+ prop-addr 1) value))
 196      (t
 197       (ez-mem-set-word (+ prop-addr 1) value)))))
 198
 199 (defun ez-get-obj-attr (obj attr)
 200   (let* ((byte-num (/ attr 8))
 201          (bit-num (mod attr 8))
 202          (bit-mask (lsh 1 (- 7 bit-num))))
 203     (if (> (logand bit-mask (ez-mem-ref-byte (+ (ez-get-obj-addr obj) byte-num))) 0)
 204         1
 205       0)))
 206
 207 (defun ez-set-obj-attr (obj attr val)
 208   (let* ((byte-num (/ attr 8))
 209          (bit-num (mod attr 8))
 210          (bit-mask (lsh 1 (- 7 bit-num)))
 211          (byte-addr (+ (ez-get-obj-addr obj) byte-num))
 212          (byte (ez-mem-ref-byte byte-addr))
 213          (current-set (> (logand bit-mask byte) 0)))
 214     (if (or (and current-set (= val 0))
 215             (and (not current-set) (> val 0)))
 216         (ez-mem-set-byte byte-addr (logxor byte bit-mask)))))
 217
 218 ;; Z-strings
 219
 220 (defvar ez-zstring-alphabets
 221   ;                1    1    2    2    3
 222   ;      0    5    0    5    0    5    0
 223   (list "      abcdefghijklmnopqrstuvwxyz"
 224         "      ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 225         "       \n0123456789.,!?_#'\"/\\-:()")
 226   "Alphabets used by V3")
 227
 228 (defun ez-parse-zstring-word (word)
 229   (list (lsh word -15)
 230         (logand (lsh word -10) #b11111)
 231         (logand (lsh word -5) #b11111)
 232         (logand word #b11111)))
 233
 234 (defun ez-get-zstring-chars (base-addr)
 235   (let ((addr base-addr)
 236         (chars nil)
 237         (not-done t))
 238     (while not-done
 239       (let ((components (ez-parse-zstring-word (ez-mem-ref-word addr))))
 240         (setq chars (append chars (cdr components)))
 241         (setq addr (+ addr 2))
 242         (when (= (car components) 1)
 243           (setq not-done nil))))
 244     chars))
 245
 246 (defun ez-get-zstring (base-addr)
 247   (let ((chars (ez-get-zstring-chars base-addr))
 248         (cur 0)
 249         (lock 0)
 250         (abbrev-char nil)
 251         (s ""))
 252     (dolist (char chars)
 253       (cond
 254        (abbrev-char
 255         (let ((abbrev-addr
 256                (* 2 (ez-mem-ref-word (+ ez-abbrevtab-addr
 257                                         (* 2 (+ (* (- abbrev-char 1) 32) char)))))))
 258           (setq s (concat s (ez-get-zstring abbrev-addr))))
 259         (setq abbrev-char nil))
 260        ((memq char '(1 2 3)) ;Abbreviation
 261         (setq abbrev-char char))
 262        ((= char 4)
 263         (setq cur (mod (+ cur 1) 3)))
 264        ((= char 5)
 265         (setq cur (mod (+ 3 (- cur 1)) 3)))
 266        (t
 267         (setq s (concat s (substring (elt ez-zstring-alphabets cur)
 268                                      char (+ char 1))))
 269         (setq cur lock))))
 270     s))
 271
 272
 273 ;; Call stack
 274
 275 (defvar ez-call-stack nil)
 276
 277 (defun ez-make-call-stack-frame (pc &optional call-method)
 278   (list pc
 279         nil
 280         (make-vector 15 0)
 281         call-method))
 282
 283 (defun ez-add-call-stack-frame (pc &optional call-method)
 284   (push (ez-make-call-stack-frame pc call-method) ez-call-stack))
 285
 286 (defun ez-pop-call-stack-frame ()
 287   (pop ez-call-stack))
 288
 289 (defun ez-routine-stack ()
 290   (elt (car ez-call-stack) 1))
 291
 292 (defun ez-routine-stack-push (val)
 293   (let ((frame (car ez-call-stack)))
 294     (setf (elt frame 1) (cons val (elt frame 1)))))
 295
 296 (defun ez-routine-stack-pop ()
 297   (let* ((frame (car ez-call-stack))
 298          (rs-head (car (elt frame 1))))
 299     (setf (elt frame 1) (cdr (elt frame 1)))
 300     rs-head))
 301
 302 (defun ez-get-local-var (lvar)
 303   (let ((frame (car ez-call-stack)))
 304     (aref (elt frame 2) (- lvar 1))))
 305
 306 (defun ez-set-local-var (lvar val)
 307   (let ((frame (car ez-call-stack)))
 308     (aset (elt frame 2) (- lvar 1) val)))
 309
 310 (defun ez-get-pc ()
 311   (caar ez-call-stack))
 312
 313 (defun ez-set-pc (new-pc)
 314   (setf (car (car ez-call-stack)) new-pc))
 315
 316 (defun ez-increment-pc (inc)
 317   (ez-set-pc (+ (ez-get-pc) inc)))
 318
 319 (defun ez-read-pc-byte-and-inc ()
 320   (let ((res (ez-mem-ref-byte (ez-get-pc))))
 321     (ez-increment-pc 1)
 322     res))
 323
 324 (defun ez-read-pc-word-and-inc ()
 325   (let ((res (ez-mem-ref-word (ez-get-pc))))
 326     (ez-increment-pc 2)
 327     res))
 328
 329 ;; Instruction execution
 330
 331 (defun ez-get-var (var)
 332   (cond
 333    ((= var 0)
 334     (ez-routine-stack-pop))
 335    ((< var 16)
 336     (ez-get-local-var var))
 337    (t
 338     (ez-get-global-var (- var 16)))))
 339
 340 (defun ez-set-var (var val)
 341   (cond
 342    ((= var 0)
 343     (ez-routine-stack-push val))
 344    ((< var 16)
 345     (ez-set-local-var var val))
 346    (t
 347     (ez-set-global-var (- var 16) val))))
 348
 349 (defun ez-read-pc-var-and-inc ()
 350   (ez-get-var (ez-read-pc-byte-and-inc)))
 351
 352 (defun ez-execute-instr ()
 353   (let ((instr-pc (ez-get-pc))
 354         (opbyte (ez-read-pc-byte-and-inc))
 355         (optype)
 356         (opcode nil)
 357         (operands))
 358     (cond
 359      ((<= #x0 opbyte #x1f)
 360       (setq optype '2op
 361             opcode opbyte
 362             operands (list (ez-read-pc-byte-and-inc)
 363                            (ez-read-pc-byte-and-inc))
 364             operand-types '(b b)))
 365      ((<= #x20 opbyte #x3F)
 366       (setq optype '2op
 367             opcode (- opbyte #x20)
 368             operands (list (ez-read-pc-byte-and-inc)
 369                            (ez-read-pc-var-and-inc))
 370             operand-types '(b w)))
 371      ((<= #x40 opbyte #x5F)
 372       (setq optype '2op
 373             opcode (- opbyte #x40)
 374             operands (list (ez-read-pc-var-and-inc)
 375                            (ez-read-pc-byte-and-inc))
 376             operand-types '(w b)))
 377      ((<= #x60 opbyte #x7F)
 378       (setq optype '2op
 379             opcode (- opbyte #x60)
 380             operands (list (ez-read-pc-var-and-inc)
 381                            (ez-read-pc-var-and-inc))
 382             operand-types '(w w)))
 383      ((<= #x80 opbyte #x8F)
 384       (setq optype '1op
 385             opcode (- opbyte #x80)
 386             operands (list (ez-read-pc-word-and-inc))
 387             operand-types '(w)))
 388      ((<= #x90 opbyte #x9F)
 389       (setq optype '1op
 390             opcode (- opbyte #x90)
 391             operands (list (ez-read-pc-byte-and-inc))
 392             operand-types '(b)))
 393      ((<= #xA0 opbyte #xAF)
 394       (setq optype '1op
 395             opcode (- opbyte #xa0)
 396             operands (list (ez-read-pc-var-and-inc))
 397             operand-types '(w)))
 398      ((<= #xB0 opbyte #xBF)
 399       (setq optype '0op
 400             opcode (- opbyte #xb0)
 401             operands '()
 402             operand-types '()))
 403      ((<= #xC0 opbyte #xDF)
 404       (error "Unsupported op %x" opbyte))
 405      ((<= #xE0 opbyte #xFF)
 406       (setq optype 'var
 407             opcode (- opbyte #xe0))
 408       (let ((operands-and-types (ez-read-var-operands-and-inc)))
 409         (setq operands (car operands-and-types)
 410               operand-types (cdr operands-and-types)))))
 411     (let ((table-row (assoc (list optype opcode) ez-op-table)))
 412       (unless table-row
 413         (error "Unsupported op PC:%x Optype:%s Opcode:%x Operands:%s Operand-types:%s"
 414                instr-pc optype opcode operands operand-types))
 415       (let ((mnemonic (elt table-row 1)))
 416         (message "PC:%x Optype:%s Opcode:%x Mnemonic:%s Operands:%s Operand-types:%s"
 417                  instr-pc optype opcode mnemonic operands operand-types))
 418       (funcall (elt table-row 2) operands operand-types))))
 419
 420 (defun ez-read-var-operands-and-inc ()
 421   (let* ((type-byte (ez-read-pc-byte-and-inc))
 422          (types (let ((type1 (lsh type-byte -6)))
 423                   (if (= type1 #b11)
 424                       nil
 425                     (cons type1
 426                           (let ((type2 (lsh (logand #b110000 type-byte) -4)))
 427                             (if (= type2 #b11)
 428                                 nil
 429                               (cons type2
 430                                     (let ((type3 (lsh (logand #b1100 type-byte) -2)))
 431                                       (if (= type3 #b11)
 432                                           nil
 433                                         (cons type3
 434                                               (let ((type4 (logand #b11)))
 435                                                 (if (= type4 #b11)
 436                                                     nil
 437                                                   (list type4))))))))))))))
 438     (cons
 439      (mapcar
 440       (lambda (type)
 441         (cond
 442          ((= type 0) (ez-read-pc-word-and-inc))
 443          ((= type 1) (ez-read-pc-byte-and-inc))
 444          ((= type 2) (ez-read-pc-var-and-inc))))
 445       types)
 446      (mapcar
 447       (lambda (type)
 448         (if (= type 1)
 449             'b
 450           'w))
 451       types))))
 452
 453 ;; Branches
 454
 455 (defun ez-do-branch (branch)
 456   (let* ((branch-byte (ez-read-pc-byte-and-inc))
 457          (invert (= 0 (logand branch-byte #b10000000)))
 458          (single-byte (> (logand branch-byte #b01000000) 0))
 459          (offset
 460           (if single-byte
 461               (logand branch-byte #b00111111)
 462             (let ((pos (= (logand branch-byte #b00100000) 0))
 463                   (val (+ (* 256 (logand branch-byte #b00011111))
 464                           (ez-read-pc-byte-and-inc))))
 465               (if pos
 466                   val
 467                 (- val 8192))))))
 468     (if (or (and branch (not invert))
 469             (and (not branch) invert))
 470         (cond
 471          ((= offset 0)
 472           (ez-op-rfalse))
 473          ((= offset 1)
 474           (ez-op-rtrue))
 475          (t
 476           (ez-set-pc (+ (ez-get-pc) offset -2)))))))
 477
 478 ;; Operations
 479
 480 (defvar ez-op-table
 481   '(((0op #x00) rtrue ez-op-rtrue)
 482     ((0op #x01) rfalse ez-op-rfalse)
 483     ((1op #x00) jz ez-op-jz)
 484     ((1op #x0B) ret ez-op-ret)
 485     ((1op #x0C) jump ez-op-jump)
 486     ((2op #x0D) store ez-op-store)
 487     ((1op #x0E) load ez-op-load)
 488     ((var #x01) storew ez-op-storew)
 489     ((2op #x0F) loadw ez-op-loadw)
 490     ((2op #x01) je ez-op-je)
 491     ((2op #x08) or ez-op-or)
 492     ((2op #x09) and ez-op-and)
 493     ((2op #x14) add ez-op-add)
 494     ((2op #x15) sub ez-op-sub)
 495     ((2op #x16) mul ez-op-mul)
 496     ((2op #x17) div ez-op-div)
 497     ((2op #x18) mod ez-op-mod)
 498     ((var #x00) call_fv ez-op-callf)
 499     ((1op #x01) get_sibling ez-op-get-sibling)
 500     ((1op #x02) get_child ez-op-get-child)
 501     ((1op #x03) get_parent ez-op-get-parent)
 502     ((2op #x0A) test_attr ez-op-test-attr)
 503     ((var #x03) put_prop ez-op-put-prop)
 504     ((0op #x02) print ez-op-print)))
 505
 506 (defun ez-op-ret (operands &optional operand-types)
 507   (let ((retval (car operands)))
 508     (ez-pop-call-stack-frame)
 509     (ez-set-var (ez-read-pc-byte-and-inc) retval))
 510   t)
 511
 512 (defun ez-op-rtrue (&optional operands operand-types)
 513   (ez-op-ret (list 1))
 514   t)
 515
 516 (defun ez-op-rfalse (&optional operands operand-types)
 517   (ez-op-ret (list 0))
 518   t)
 519
 520 (defun ez-op-jz (operands operand-types)
 521   (ez-do-branch (= (car operands) 0))
 522   t)
 523
 524 (defun ez-op-je (operands operand-types)
 525   (ez-do-branch (memq (car operands) (cdr operands)))
 526   t)
 527
 528 (defun ez-op-jump (operands operand-types)
 529   (let ((offset (if (eq (car operand-types) 'b)
 530                     (ez-decode-signed-byte (car operands))
 531                   (ez-decode-signed-word (car operands)))))
 532     (ez-set-pc (+ (ez-get-pc) offset -2)))
 533   t)
 534
 535 (defun ez-op-store (operands operand-types)
 536   (let ((var (car operands))
 537         (a (cadr operands)))
 538     (ez-set-var var a))
 539   t)
 540
 541 (defun ez-op-load (operands operand-types)
 542   (let ((var (car operands)))
 543     (ez-set-var (ez-read-pc-byte-and-inc) (ez-get-var var)))
 544   t)
 545
 546 (defun ez-op-storew (operands operand-types)
 547   (let ((baddr (car operands))
 548         (n (cadr operands))
 549         (a (caddr operands)))
 550     (ez-mem-set-word (+ baddr (* 2 n)) a))
 551   t)
 552
 553 (defun ez-op-loadw (operands operand-types)
 554   (let ((baddr (car operands))
 555         (n (cadr operands)))
 556     (ez-set-var (ez-read-pc-byte-and-inc) (ez-mem-ref-word (+ baddr (* 2 n)))))
 557   t)
 558
 559 (defun ez-op-and (operands operand-types)
 560   (let ((a (car operands))
 561         (b (cadr operands)))
 562     (ez-set-var (ez-read-pc-byte-and-inc) (logand a b)))
 563   t)
 564
 565 (defun ez-op-or (operands operand-types)
 566   (let ((a (car operands))
 567         (b (cadr operands)))
 568     (ez-set-var (ez-read-pc-byte-and-inc) (logior a b)))
 569   t)
 570
 571 (defun ez-op-add (operands operand-types)
 572   (let ((a (car operands))
 573         (b (cadr operands)))
 574     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ a b) #x10000)))
 575   t)
 576
 577 (defun ez-op-sub (operands operand-types)
 578   (let ((a (car operands))
 579         (b (cadr operands)))
 580     (ez-set-var (ez-read-pc-byte-and-inc) (mod (+ (- a b) #x10000) #x10000)))
 581   t)
 582
 583 (defun ez-op-mul (a b)
 584   (let ((a (car operands))
 585         (b (cadr operands)))
 586     (ez-set-var (ez-read-pc-byte-and-inc) (mod (* a b) #x10000)))
 587   t)
 588
 589 (defun ez-op-div (a b)
 590   (error "Not implemented"))
 591
 592 (defun ez-op-mod (a b)
 593   (error "Not implemented"))
 594
 595 (defun ez-op-callf (operands operand-types)
 596   (let* ((raddr (car operands))
 597          (call-operands (cdr operands))
 598          (r (* 2 raddr))
 599          (L (ez-mem-ref-byte r))
 600          (n (length call-operands))
 601          (new-pc (+ r 1 (* L 2))))
 602     (ez-add-call-stack-frame new-pc)
 603     (dotimes (i L)
 604       (if (< i n)
 605           (ez-set-local-var (+ i 1) (elt call-operands i))
 606         (ez-set-local-var (+ i 1) (ez-mem-ref-word (+ r 1 (* 2 i)))))))
 607   t)
 608
 609 (defun ez-op-test-attr (operands operand-types)
 610   (let ((obj (car operands))
 611         (attr (cadr operands)))
 612     (ez-do-branch (= 1 (ez-get-obj-attr obj attr)))
 613     t))
 614
 615 (defun ez-op-get-sibling (operands operand-types)
 616   (let ((sib (ez-get-obj-sibling (car operands))))
 617     (ez-set-var (ez-read-pc-byte-and-inc) sib)
 618     (ez-do-branch (> sib 0))
 619     t))
 620
 621 (defun ez-op-get-child (operands operand-types)
 622   (let ((child (ez-get-obj-child (car operands))))
 623     (ez-set-var (ez-read-pc-byte-and-inc) child)
 624     (ez-do-branch (> child 0))
 625     t))
 626
 627 (defun ez-op-get-parent (operands operand-types)
 628   (let ((parent (ez-get-obj-parent (car operands))))
 629     (ez-set-var (ez-read-pc-byte-and-inc) parent)
 630     (ez-do-branch (> parent 0))
 631     t))
 632
 633 (defun ez-op-put-prop (operands operand-types)
 634   (let* ((obj (car operands))
 635          (prop (cadr operands))
 636          (a (caddr operands)))
 637     (ez-set-obj-prop obj prop a)
 638     t))
 639
 640 (defun ez-op-print (operands operand-types)
 641   (ez-print (ez-get-zstring (ez-get-pc)))
 642   t)
 643
 644
 645 ;; Execution loop
 646
 647 (defun ez-run (filename)
 648   (ez-load-file filename)
 649   (ez-parse-header)
 650   (setq ez-call-stack (list (ez-make-call-stack-frame ez-start-pc)))
 651
 652   (while (ez-execute-instr)))
 653
 654
 655 ;;; Buffer and I/O
 656 ;;
 657
 658 (defun ez-render-prompt ()
 659   (with-current-buffer "*ez*"
 660     (let ((update-point (= ez-input-marker (point)))
 661           (update-window-points (mapcar (lambda (w)
 662                                           (list (= (window-point w) ez-input-marker)
 663                                                 w))
 664                                         (get-buffer-window-list nil nil t))))
 665       (save-excursion
 666         (set-marker-insertion-type ez-prompt-marker nil)
 667         (set-marker-insertion-type ez-input-marker t)
 668         (let ((inhibit-read-only t))
 669           (delete-region ez-prompt-marker ez-input-marker)
 670           (goto-char ez-prompt-marker)
 671           (insert
 672            ">"
 673            (propertize " " ; Need this to be separate to mark it as rear-nonsticky
 674                        'read-only t
 675                        'rear-nonsticky t)))
 676         (set-marker-insertion-type ez-input-marker nil))
 677       (goto-char ez-input-marker))))
 678
 679 (defvar ez-prompt-marker nil
 680   "Marker for prompt position in buffer.")
 681
 682 (defvar ez-input-marker nil
 683   "Marker for prompt position in buffer.")
 684
 685 (defun ez-setup-buffer ()
 686   (with-current-buffer (get-buffer-create "*ez*")
 687     (let ((inhibit-read-only t))
 688       (delete-region (point-min) (point-max)))
 689     (setq-local scroll-conservatively 1)
 690     (if (markerp ez-prompt-marker)
 691         (set-marker ez-prompt-marker (point-max))
 692       (setq ez-prompt-marker (point-max-marker)))
 693     (if (markerp ez-input-marker)
 694         (set-marker ez-input-marker (point-max))
 695       (setq ez-input-marker (point-max-marker)))
 696     (goto-char (point-max))
 697     (ez-render-prompt)))
 698
 699
 700 (defun ez-print (string)
 701   (with-current-buffer "*ez*"
 702     (save-excursion
 703       (goto-char ez-prompt-marker)
 704       (insert-before-markers string))))
 705
 706 ;; Mode
 707
 708 (defvar ez-mode-map
 709   (let ((map (make-sparse-keymap)))
 710     (define-key map (kbd "RET") 'ez-enter)
 711     map))
 712
 713 (define-derived-mode ez-mode text-mode "ez"
 714   "Major mode for EZ.")
 715
 716 (when (fboundp 'evil-set-initial-state)
 717   (evil-set-initial-state 'ez-mode 'insert))
 718
 719 (defun ez (zfile)
 720   (interactive "fEnter name of z3 story file: ")
 721   (if (get-buffer "*ez*")
 722       (switch-to-buffer "*ez*")
 723     (switch-to-buffer "*ez*")
 724     (ez-mode)
 725     (ez-setup-buffer)
 726     (ez-run zfile))
 727   "Started EZ.")
 728
 729 (defun ez-debug ()
 730   (interactive)
 731   (switch-to-buffer "*ez*")
 732   (ez-mode)
 733   (ez-setup-buffer)
 734   (ez-run "zork1.z3"))
 735
 736 ;;; ez.el ends here