run-mars.scm

   1 ;; run-mars: command-line utility for running redcode programs
   2 ;;
   3
   4 (import (chicken io)
   5         (chicken process-context)
   6         matchable
   7         mars visualizer parser)
   8
   9 (define (make-color-map progs colors)
  10   (let loop ((entries '())
  11              (progs-left progs)
  12              (colors-left colors))
  13     (if (null? progs-left)
  14         entries
  15         (let ((this-prog (car progs-left))
  16               (this-col (car colors-left)))
  17           (loop (cons (cons (prog-name this-prog) this-col) entries)
  18                 (cdr progs-left)
  19                 (cdr colors-left))))))
  20
  21 (define (mars-runner files iters core-size visualization)
  22   (print "Iters: " iters ", core size: " core-size)
  23   (let* ((progs (map
  24                  (lambda (fname)
  25                    (string->prog (with-input-from-file fname read-string)))
  26                  files))
  27          (core (if visualization
  28                    (let* ((colors '("red" "blue" "green" "magenta" "cyan"))
  29                           (color-map (make-color-map progs colors))
  30                           (vis (make-vis 640 480 core-size color-map)))
  31                      (make-core 8000 (lambda (i n)
  32                                        (vis 'update-owner i n))))
  33                    (make-core 8000)))
  34          (queues (run-mars core (install-progs core progs) iters)))
  35     (for-each (lambda (q)
  36                 (print)
  37                 (print "Final queue for " (queue-owner q) ":")
  38                 (dump-queue q core))
  39               queues)
  40     (when visualization
  41       (print* "Press enter to finish...")
  42       (read-line))))
  43
  44 (define (print-usage)
  45   (print "Usage: run-mars [-h|--help]\n"
  46          "       run-mars [-c|--core size]\n"
  47          "                [-i|--iterations iters]\n"
  48          "                [-n|--no-visualization]\n"
  49          "                warrior1.red [warrior2.red [...]]"))
  50
  51 (define (main)
  52   (let loop ((args (cdr (argv)))
  53              (iters 10000)
  54              (core-size 8000)
  55              (visualization #t))
  56     (match args
  57       ((or () ((or "-h" "--help")))
  58        (print-usage))
  59       (((or "-i" "--iterations") istr rest ...)
  60        (loop rest (string->number istr) core-size visualization))
  61       (((or "-c" "--core-size") cstr rest ...)
  62        (loop rest iters (string->number cstr) visualization))
  63       (((or "-n" "--no-visualization") rest ...)
  64        (loop rest iters core-size #f))
  65       ((files ...)
  66        (mars-runner files iters core-size visualization)))))
  67 (main)