;;; lirc.el --- Lightweight irc client  -*- lexical-binding:t -*-

;; Copyright (C) 2021 Tim Vaughan

;; Author: Tim Vaughan <timv@ughan.xyz>
;; Created: 14 June 2021
;; Version: 1.0
;; Keywords: network
;; Homepage: http://thelambdalab.xyz/erc
;; Package-Requires: ((emacs "26"))

;; This file is not part of GNU Emacs.

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this file.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(provide 'lirc)

;;; Customizations
;;

(defgroup lirc nil
  "Lightweight IRC client."
  :group 'network)

(defcustom lirc-nick "plugd"
  "Default nick.")
(defcustom lirc-full-name "plugd"
  "Default full name.")
(defcustom lirc-user-name "plugd"
  "Default user name.")
(defcustom lirc-host "irc.libera.chat"
  "Default server.")
(defcustom lirc-port 6697
  "Default port.")

(defcustom lirc-prompt-string "> "
  "Prompt.")

;;; Faces
;;

(defface lirc-text
  '((t :inherit font-lock-preprocessor-face))
  "Face used for Lirc text.")

(defface lirc-your-nick
  '((t :inherit font-lock-constant-face))
  "Face used for highlighting your nick.")

(defface lirc-prompt
  '((t :inherit org-level-2))
  "Face used for the prompt.")

(defface lirc-channel
  '((t :inherit org-list-dt))
  "Face used for the channel name in the prompt.")

(defface lirc-faded
  '((t :inherit font-lock-preprocessor-face))
  "Face used for faded Lirc text.")

(defface lirc-bold
  '((t :inherit font-lock-function-name-face))
  "Face used for bold Lirc text.")

(defface lirc-error
  '((t :inherit font-lock-regexp-grouping-construct))
  "Face used for Lirc error text.")

;;; Global variables
;;

(defvar lirc-version "Lirc v0.1")

(defvar lirc-notice-prompt
  (concat
   (propertize
    "-" 'face 'lirc-faded)
   (propertize
    "!" 'face 'lirc-bold)
   (propertize
    "-" 'face 'lirc-faded)))

(defvar lirc-error-prompt
  (propertize "!!!" 'face 'lirc-error))


;;; Network process
;;

(defvar lirc-response "")

(defun lirc-filter (proc string)
  (dolist (line (split-string (concat lirc-response string) "\n"))
    (if (string-suffix-p "\r" line)
        (lirc-eval-msg-string (string-trim line))
      (setq lirc-response line))))

(defun lirc-get-process (&optional connect)
  (let ((proc (get-process "lirc")))
    (if (and proc (eq (process-status proc) 'open))
        proc
      (if connect
          (make-network-process :name "lirc"
                                :host lirc-host
                                :service lirc-port
                                :filter #'lirc-filter
                                :nowait nil
                                :tls-parameters (cons 'gnutls-x509pki
                                                      (gnutls-boot-parameters
                                                       :type 'gnutls-x509pki
                                                       :hostname lirc-host))
                                :buffer "*lirc*")
        (lirc-display-error "No server connection established.")
        (error "No server connection established")))))

;;; Messages
;;

(defun lirc-as-string (obj)
  (if obj
      (with-output-to-string (princ obj))
    nil))

(defun lirc-msg (tags src cmd &rest params)
  (list (lirc-as-string tags)
        (lirc-as-string src)
        (upcase (lirc-as-string cmd))
        (mapcar #'lirc-as-string
                (if (and params (listp (elt params 0)))
                    (elt params 0)
                  params))))

(defun lirc-msg-tags (msg) (elt msg 0))
(defun lirc-msg-src (msg) (elt msg 1))
(defun lirc-msg-cmd (msg) (elt msg 2))
(defun lirc-msg-params (msg) (elt msg 3))
(defun lirc-msg-trail (msg)
  (let ((params (lirc-msg-params msg)))
    (if params
        (elt params (- (length params) 1)))))

(defvar lirc-msg-regex
  (rx
   (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
        (* whitespace))
   (opt (: ":" (: (group (* (not (any space "!" "@"))))
                  (* (not (any space)))))
        (* whitespace))
   (group (: (* (not whitespace))))
   (* whitespace)
   (opt (group (+ not-newline))))
  "Regex used to parse IRC messages.
Note that this regex is incomplete.  Noteably, we discard the non-nick
portion of the source component of the message, as LIRC doesn't use this.")

(defun lirc-string->msg (string)
  (if (string-match lirc-msg-regex string)
      (let* ((tags (match-string 1 string))
             (src (match-string 2 string))
             (cmd (upcase (match-string 3 string)))
             (params-str (match-string 4 string))
             (params
              (if params-str
                  (let* ((idx (cl-search ":" params-str))
                         (l (split-string (string-trim (substring params-str 0 idx))))
                         (r (if idx (list (substring params-str (+ 1 idx))) nil)))
                    (append l r))
                nil)))
        (apply #'lirc-msg (append (list tags src cmd) params)))
    (error "Failed to parse string " string)))

(defun lirc--filtered-join (&rest args)
  (string-join (seq-filter (lambda (el) el) args) " "))

(defun lirc-msg->string (msg)
  (let ((tags (lirc-msg-tags msg))
        (src (lirc-msg-src msg))
        (cmd (lirc-msg-cmd msg))
        (params (lirc-msg-params msg)))
    (lirc--filtered-join
     (if tags (concat "@" tags) nil)
     (if src (concat ":" src) nil)
     cmd
     (if (> (length params) 1)
         (string-join (seq-take params (- (length params) 1)) " ")
       nil)
     (if (> (length params) 0)
         (concat ":" (elt params (- (length params) 1)))
       nil))))


;;; Channels
;;

(defvar lirc-current-channel nil)
(defvar lirc-channel-list nil)

(defun lirc-add-channel (channel-name)
  (add-to-list 'lirc-channel-list
               (list channel-name)))

(defun lirc-del-channel (channel-name)
  (setq lirc-channel-list
        (assoc-delete-all channel-name lirc-channel-list)))

(defun lirc-get-channel-users (channel-name)
  (cdr (assoc channel-name lirc-channel-list)))

(defun lirc-set-channel-users (channel-name users)
  (setcdr (assoc channel-name lirc-channel-list) users))

(defun lirc-add-channel-users (channel-name &rest users)
  (let ((current-users (lirc-get-channel-users channel-name)))
    (lirc-set-channel-users channel-name (append users current-users))))

(defun lirc-del-channel-users (channel-name &rest users)
  (let ((current-users (lirc-get-channel-users channel-name)))
    (lirc-set-channel-users channel-name
                            (cl-set-difference current-users users :test #'equal))))

(defun lirc-del-users (&rest users)
  (dolist (channel lirc-channel-list)
    (apply #'lirc-del-channel-users (cons (car channel) users))))

(defun lirc-rename-user (old-nick new-nick)
  (dolist (channel lirc-channel-list)
    (let ((channel-name (car channel))
          (channel-users (cdr channel)))
      (when (memq old-nick channel-users)
        (lirc-del-channel-users old-nick)
        (lirc-add-channel-users new-nick)))))


;;; Buffer
;;

(defun lirc-display-string (&rest strings)
  (with-current-buffer (get-buffer-create "*lirc*")
    (save-excursion
      (goto-char lirc-prompt-marker)
      (let ((inhibit-read-only t))
        (insert-before-markers
         (propertize (concat (format-time-string "%H:%M") " ")
                     'face 'lirc-text
                     'read-only t)
         (propertize (concat (apply #'concat strings) "\n")
                     'read-only t))))))

(defun lirc-connect ()
  (lirc-get-process t)
  (lirc-send-msg (lirc-msg nil nil "USER" lirc-user-name 0 "*" lirc-full-name))
  (lirc-send-msg (lirc-msg nil nil "NICK" lirc-nick)))

(defun lirc-send-msg (msg)
  (let ((proc (lirc-get-process)))
    (process-send-string proc (concat (lirc-msg->string msg) "\r\n"))))

(defun lirc-render-prompt ()
  (with-current-buffer "*lirc*"
    (save-excursion
      (set-marker-insertion-type lirc-prompt-marker nil)
      (set-marker-insertion-type lirc-input-marker t)
      (let ((inhibit-read-only t))
        (delete-region lirc-prompt-marker lirc-input-marker)
        (goto-char lirc-prompt-marker)
        (insert
         (propertize (if lirc-current-channel
                         lirc-current-channel
                       "[no channel]")
                     'face 'lirc-channel
                     'read-only t)
         (propertize lirc-prompt-string
                     'face 'lirc-prompt
                     'read-only t
                     'rear-nonsticky t)))
      (set-marker-insertion-type lirc-input-marker nil))))
  
(defvar lirc-prompt-marker nil
  "Marker for prompt position in LIRC buffer.")

(defvar lirc-input-marker nil
  "Marker for prompt position in LIRC buffer.")

(defun lirc-setup-buffer ()
  (with-current-buffer (get-buffer-create "*lirc*")
    (if (markerp lirc-prompt-marker)
        (set-marker lirc-prompt-marker (point-max))
      (setq lirc-prompt-marker (point-max-marker)))
    (if (markerp lirc-input-marker)
        (set-marker lirc-input-marker (point-max))
      (setq lirc-input-marker (point-max-marker)))
    (lirc-render-prompt)
    (goto-char (point-max))
    (recenter -1)))


;;; Output formatting
;;

(defun lirc-display-action (channel nick action)
  (lirc-display-string (concat " * "
                               (propertize (concat nick " " action)
                                           'face 'lirc-text))))

(defun lirc-display-message (channel nick message)
  (lirc-display-string
   (concat
    (propertize (concat channel " ")
                'face 'lirc-text)
    (propertize (concat "<" nick "> ")
                'face
                (if (equal nick lirc-nick)
                    'lirc-your-nick
                  'lirc-text))
    (propertize message 'face 'lirc-text))))

(defun lirc-display-notice (&rest notices)
  (lirc-display-string lirc-notice-prompt " " (apply #'concat notices)))

(defun lirc-display-error (&rest messages)
  (lirc-display-string lirc-error-prompt " "
                       (propertize (apply #'concat messages)
                                   'face 'lirc-error)))

;;; Message evaluation
;;

(defun lirc-eval-msg-string (string)
  ;; (lirc-display-string string)
  (let* ((msg (lirc-string->msg string)))
    (pcase (lirc-msg-cmd msg)
      ("PING"
       (lirc-send-msg
        (lirc-msg nil nil "PONG" (lirc-msg-params msg))))

      ("353" ; NAMEREPLY
       (let* ((params (lirc-msg-params msg))
              (channel (elt params 2))
              (names (split-string (elt params 3))))
         (apply #'lirc-add-channel-users (cons channel names))))

      ("366" ; ENDOFNAMES
       (lirc-display-notice
        (lirc-as-string (length (lirc-get-channel-users lirc-current-channel)))
        " users in " lirc-current-channel))

      ((rx (= 3 (any digit)))
       (lirc-display-notice (mapconcat 'identity (cdr (lirc-msg-params msg)) " ")))

      ((and "JOIN"
            (guard (equal lirc-nick (lirc-msg-src msg))))
       (let ((channel (car (lirc-msg-params msg))))
         (setq lirc-current-channel channel)
         (lirc-add-channel channel)
         (lirc-display-notice "Joining channel " channel)
         (lirc-render-prompt)))

      ("JOIN"
       (let ((channel (car (lirc-msg-params msg)))
             (nick (lirc-msg-src msg)))
         (lirc-add-channel-users channel nick)
         (lirc-display-notice nick " joined channel " channel)))

      ((and "PART"
            (guard (equal lirc-nick (lirc-msg-src msg))))
       (lirc-display-notice "Left channel " lirc-current-channel)
       (setq lirc-current-channel nil)
       (lirc-del-channel (car (lirc-msg-params msg)))
       (lirc-render-prompt))

      ("PART"
       (let ((channel (car (lirc-msg-params msg)))
             (nick (lirc-msg-src msg)))
         (lirc-del-channel-users channel nick)
         (lirc-display-notice nick " left channel " channel)))

      ("QUIT"
       (let ((nick (lirc-msg-src msg))
             (reason (mapconcat 'identity (lirc-msg-params msg) " ")))
         (lirc-del-users nick)
         (lirc-display-notice nick " quit: " reason)))

      ((and "NICK"
            (guard (equal lirc-nick (lirc-msg-src msg))))
       (setq lirc-nick (car (lirc-msg-params msg)))
       (lirc-display-notice "Set nick to " lirc-nick))

      ("NICK"
       (let ((old-nick (lirc-msg-src msg))
             (new-nick (car (lirc-msg-params msg))))
         (lirc-display-notice nick " is now known as " new-nick)
         (lirc-rename-user nick new-nick)))

      ("NOTICE"
       (let ((nick (lirc-msg-src msg))
             (channel (car (lirc-msg-params msg)))
             (text (cadr (lirc-msg-params msg))))
         (pcase text
           ((rx (: "\01VERSION "
                   (let version (* (not "\01")))
                   "\01"))
            (lirc-display-notice "CTCP version reply from " nick ": " version))
           (_
            (lirc-display-notice text)))))

      ("PRIVMSG"
       (let ((nick (lirc-msg-src msg))
             (channel (car (lirc-msg-params msg)))
             (text (cadr (lirc-msg-params msg))))
         (pcase text
           ((rx (: "\01ACTION "
                   (let action (* (not "\01")))
                   "\01"))
            (lirc-display-action nick action))

           ("\01VERSION\01"
            (let ((version-string (concat lirc-version " - running on GNU Emacs " emacs-version)))
              (lirc-send-msg (lirc-msg nil nil "NOTICE"
                                       (list nick (concat "\01VERSION "
                                                          version-string
                                                          "\01")))))
            (lirc-display-notice "CTCP version request received from " nick))

           ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
            (lirc-send-msg (lirc-msg nil nil "NOTICE" (list nick ping)))
            (lirc-display-notice "CTCP ping received from " nick))

           ("\01USERINFO\01"
            (lirc-display-notice "CTCP userinfo request from " nick " (no response sent)"))

           (_
            (lirc-display-message channel nick text)))))
      (_
       (lirc-display-string (lirc-msg->string msg))))))


;;; Command entering
;;

(defun lirc-enter-string (string)
  (if (string-prefix-p "/" string)
      (pcase (substring string 1)
        ((rx (: "TOPIC" " " (let new-topic (* not-newline))))
         (lirc-send-msg (lirc-msg nil nil "TOPIC" lirc-current-channel new-topic)))

        ((rx (: "me" " " (let action (* not-newline))))
         (lirc-send-msg (lirc-msg nil nil "PRIVMSG"
                                  (list lirc-current-channel
                                        (concat "\01ACTION " action "\01"))))
         (lirc-display-action lirc-nick action))

        ((rx (: "VERSION" " " (let nick (* (not whitespace)))))
         (lirc-send-msg (lirc-msg nil nil "PRIVMSG"
                                  (list nick "\01VERSION\01")))
         (lirc-display-notice "CTCP version request sent to " nick))

        ((rx "PART")
         (lirc-send-msg (lirc-msg nil nil "PART" lirc-current-channel)))

        ((rx "MSG "
             (let target (* (not whitespace)))
             " "
             (let text (* not-newline)))
         (lirc-send-msg (lirc-msg nil nil "PRIVMSG" target text))
         (lirc-display-message target lirc-nick text))

        ((rx (: (let cmd-str (+ (not whitespace)))
                (opt (: " " (let params-str (* not-newline))))))
         (lirc-send-msg (lirc-msg nil nil (upcase cmd-str)
                                  (if params-str
                                      (split-string params-str)
                                    nil)))))

    (unless (string-empty-p string)
      (lirc-send-msg (lirc-msg nil nil "PRIVMSG" lirc-current-channel string))
      (lirc-display-message lirc-current-channel lirc-nick string))))

(defun lirc-enter ()
  "Enter current contents of line after prompt."
  (interactive)
  (with-current-buffer "*lirc*"
    (lirc-enter-string
     (buffer-substring lirc-input-marker (point-max)))
    (let ((inhibit-read-only t))
      (delete-region lirc-input-marker (point-max)))))



;;; Mode
;;

(defvar lirc-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "RET") 'lirc-enter)
    map))

(define-derived-mode lirc-mode text-mode "lirc"
  "Major mode for LIRC.")

(when (fboundp 'evil-set-initial-state)
  (evil-set-initial-state 'lirc-mode 'insert))

;;; Main start procedure
;;

(defun lirc ()
  "Switch to *lirc* buffer."
  (interactive)
  (if (get-buffer "*lirc*")
      (switch-to-buffer "*lirc*")
    (switch-to-buffer "*lirc*"))
  (lirc-mode)
  (lirc-setup-buffer)
  (lirc-connect)
  "Started LIRC.")



;;; lirc.el ends here