;;; lirc.el --- Lightweight irc client  -*- lexical-binding:t -*-

;; Copyright (C) 2021 Tim Vaughan

;; Author: Tim Vaughan <timv@ughan.xyz>
;; Created: 14 June 2021
;; Version: 1.0
;; Keywords: network
;; Homepage: http://thelambdalab.xyz/erc
;; Package-Requires: ((emacs "26"))

;; This file is not part of GNU Emacs.

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this file.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(provide 'lerc)

;;; Customizations
;;

(defgroup lirc nil
  "Lightweight IRC client."
  :group 'network)

(defcustom lirc-nick "plugd"
  "Default nick.")
(defcustom lirc-full-name "plugd"
  "Default full name.")
(defcustom lirc-user-name "plugd"
  "Default user name.")
(defcustom lirc-host "irc.libera.chat"
  "Default server.")
(defcustom lirc-port 6667
  "Default port.")

(defcustom lirc-prompt-string "> "
  "Prompt.")

;;; Faces
;;

(defface lirc-prompt
  '((t :inherit org-level-2))
  "Face used for the prompt.")

(defface lirc-channel
  '((t :inherit org-list-dt))
  "Face used for the channel name in the prompt.")

;;; Global variables
;;

(defvar lirc-current-channel nil)
(defvar lirc-channel-list nil)

(defvar lirc-response "")


;;; Network process
;;

(defun lirc-filter (proc string)
  (dolist (line (split-string (concat lirc-response string) "\n"))
    (if (string-suffix-p "\r" line)
        (lirc-eval-msg-string (string-trim line))
      (setq lirc-response line))))

(defun lirc-get-process ()
  (let ((proc (get-process "lirc")))
    (if (and proc (eq (process-status proc) 'open))
        proc
      (make-network-process :name "lirc"
                            :host lirc-host
                            :service lirc-port
                            :filter #'lirc-filter
                            :nowait t
                            :buffer "*lirc*"))))

;;; Messages
;;

(defun lirc-as-string (obj)
  (if obj
      (with-output-to-string (princ obj))
    nil))

(defun lirc-msg (tags src cmd &rest params)
  (list (lirc-as-string tags)
        (lirc-as-string src)
        (upcase (lirc-as-string cmd))
        (mapcar #'lirc-as-string
                (if (and params (listp (elt params 0)))
                    (elt params 0)
                  params))))

(defun lirc-msg-tags (msg) (elt msg 0))
(defun lirc-msg-src (msg) (elt msg 1))
(defun lirc-msg-cmd (msg) (elt msg 2))
(defun lirc-msg-params (msg) (elt msg 3))
(defun lirc-msg-trail (msg)
  (let ((params (lirc-msg-params msg)))
    (if params
        (elt params (- (length params) 1)))))

(defvar lirc-msg-regex
  (rx
   (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
        (* whitespace))
   (opt (: ":" (group (* (not (or "\n" "\r" " ")))))
        (* whitespace))
   (group (: (* (not whitespace))))
   (* whitespace)
   (opt (group (+ not-newline)))))

(defun lirc-string->msg (string)
  (if (string-match lirc-msg-regex string)
      (let* ((tags (match-string 1 string))
             (src (match-string 2 string))
             (cmd (upcase (match-string 3 string)))
             (params-str (match-string 4 string))
             (params
              (if params-str
                  (let* ((idx (cl-search ":" params-str))
                         (l (split-string (string-trim (substring params-str 0 idx))))
                         (r (if idx (list (substring params-str (+ 1 idx))) nil)))
                    (append l r))
                nil)))
        (apply #'lirc-msg (append (list tags src cmd) params)))
    (error "Failed to parse string " string)))

(defun lirc--filtered-join (&rest args)
  (string-join (seq-filter (lambda (el) el) args) " "))

(defun lirc-msg->string (msg)
  (let ((tags (lirc-msg-tags msg))
        (src (lirc-msg-src msg))
        (cmd (lirc-msg-cmd msg))
        (params (lirc-msg-params msg)))
    (lirc--filtered-join
     (if tags (concat "@" tags) nil)
     (if src (concat ":" src) nil)
     cmd
     (if (> (length params) 1)
         (string-join (seq-take params (- (length params) 1)) " ")
       nil)
     (if (> (length params) 0)
         (concat ":" (elt params (- (length params) 1)))
       nil))))


;;; Buffer
;;

(defun lirc-display-string (string)
  (with-current-buffer (get-buffer-create "*lirc*")
    (save-excursion
      (goto-char lirc-prompt-marker)
      (let ((inhibit-read-only t))
        (insert-before-markers (propertize (concat string "\n") 'read-only t))))))

(defun lirc-connect ()
  (lirc-send-msg (lirc-msg nil nil "USER" lirc-user-name 0 "*" lirc-full-name))
  (lirc-send-msg (lirc-msg nil nil "NICK" lirc-nick)))

(defun lirc-send-msg (msg)
  (let ((proc (lirc-get-process)))
    (process-send-string proc (concat (lirc-msg->string msg) "\r\n"))))

(defun lirc-render-prompt ()
  (with-current-buffer "*lirc*"
    (set-marker-insertion-type lirc-prompt-marker nil)
    (set-marker-insertion-type lirc-input-marker t)
    (let ((inhibit-read-only t))
      (delete-region lirc-prompt-marker lirc-input-marker))
    (save-excursion
      (goto-char lirc-prompt-marker)
      (let ((inhibit-read-only t))
        (insert
         (propertize (if lirc-current-channel
                         lirc-current-channel
                       "[no channel]")
                     'face 'lirc-channel
                     'read-only t)
         (propertize lirc-prompt-string
                     'face 'lirc-prompt
                     'read-only t
                     'rear-nonsticky t))))
    (set-marker-insertion-type lirc-input-marker nil)))
  
(defvar lirc-prompt-marker nil
  "Marker for prompt position in LIRC buffer.")

(defvar lirc-input-marker nil
  "Marker for prompt position in LIRC buffer.")

(defun lirc-setup-buffer ()
  (with-current-buffer (get-buffer-create "*lirc*")
    (if (markerp lirc-prompt-marker)
        (set-marker lirc-prompt-marker (point-max))
      (setq lirc-prompt-marker (point-max-marker)))
    (if (markerp lirc-input-marker)
        (set-marker lirc-input-marker (point-max))
      (setq lirc-input-marker (point-max-marker)))
    (lirc-render-prompt)
    (goto-char (point-max))
    (recenter -1)))

;;; Message evaluation
;;

(defun lirc-eval-msg-string (string)
  (let* ((msg (lirc-string->msg string)))
    (cond
     ((equal (lirc-msg-cmd msg) "PING")
      (lirc-send-msg
       (lirc-msg nil nil "PONG" (lirc-msg-params msg))))
     ((string-match (rx (= 3 digit)) (lirc-msg-cmd msg))
      (lirc-display-string (string-join (cdr (lirc-msg-params msg)) " ")))
     (t
      (lirc-display-string (lirc-msg->string msg))))))


;;; Command entering
;;

(defun lirc-enter-string (string)
  (cond ((string-prefix-p "/" string)
         (let ((cmd-str (substring string 1)))
           (lirc-send-msg (lirc-msg nil nil cmd-str))))
        (t
         (error "Unknown command" string))))

(defun lirc-enter ()
  "Enter current contents of line after prompt."
  (interactive)
  (with-current-buffer "*lirc*"
    (lirc-enter-string
     (buffer-substring lirc-input-marker (point-max)))
    (let ((inhibit-read-only t))
      (delete-region lirc-input-marker (point-max)))))



;;; Mode
;;

(defvar lirc-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "RET") 'lirc-enter)
    map))

(define-derived-mode lirc-mode text-mode "lirc"
  "Major mode for LIRC.")

(when (fboundp 'evil-set-initial-state)
  (evil-set-initial-state 'lirc-mode 'insert))

;;; Main start procedure
;;

(defun lirc ()
  "Switch to *lirc* buffer."
  (interactive)
  (if (get-buffer "*lirc*")
      (switch-to-buffer "*lirc*")
    (switch-to-buffer "*lirc*"))
  (lirc-mode)
  (lirc-setup-buffer)
  (lirc-connect)
  "Started LIRC.")



;;; lirc.el ends here