;;; lurk.el --- Little Unibuffer iRc Klient -*- lexical-binding:t -*-

;; Copyright (C) 2021 Tim Vaughan

;; Author: Tim Vaughan <timv@ughan.xyz>
;; Created: 14 June 2021
;; Version: 1.0
;; Keywords: network
;; Homepage: http://thelambdalab.xyz/lurk
;; Package-Requires: ((emacs "26"))

;; This file is not part of GNU Emacs.

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this file.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(provide 'lurk)


;;; Customizations
;;

(defgroup lurk nil
  "Little Unibuffer iRc Klient."
  :group 'network)

(defcustom lurk-nick "plugd"
  "Default nick.")

(defcustom lurk-default-quit-msg "Bye"
  "Default quit message when none supplied.")

(defcustom lurk-networks
  '(("libera" "irc.libera.chat" 6697))
  "IRC networks.")

(defcustom lurk-allow-ipv6 nil
  "Set to non-nil to allow use of IPv6.")

(defcustom lurk-show-joins nil
  "Set to non-nil to be notified of joins, parts and quits.")

(defcustom lurk-display-header t
  "If non-nil, use buffer header to display information on current host and channel.")

;;; Faces
;;

(defface lurk-text
  '((t :inherit default))
  "Face used for Lurk text.")

(defface lurk-prompt
  '((t :inherit font-lock-keyword-face))
  "Face used for the prompt.")

(defface lurk-context
  '((t :inherit lurk-context))
  "Face used for the context name in the prompt.")

(defface lurk-faded
  '((t :inherit shadow))
  "Face used for faded Lurk text.")

(defface lurk-timestamp
  '((t :inherit shadow))
  "Face used for timestamps.")

(defface lurk-error
  '((t :inherit error))
  "Face used for Lurk error text.")

(defface lurk-notice
  '((t :inherit warning))
  "Face used for Lurk notice text.")

;;; Global variables
;;

(defvar lurk-version "Lurk v0.1"
  "Value of this string is used in response to CTCP version queries.")

(defvar lurk-notice-prefix "-!-")

(defvar lurk-error-prefix "!!!")

(defvar lurk-prompt-string ">")

(defvar lurk-debug nil
  "If non-nil, enable debug mode.")


;;; Utility procedures
;;

(defun lurk--filtered-join (&rest args)
  (string-join (seq-filter (lambda (el) el) args) " "))

(defun lurk--as-string (obj)
  (if obj
      (with-output-to-string (princ obj))
    nil))


;;; Network process
;;

(defvar lurk-response "")

(defun lurk-filter (proc string)
  (dolist (line (split-string (concat lurk-response string) "\n"))
    (if (string-suffix-p "\r" line)
        (lurk-eval-msg-string (string-trim line))
      (setq lurk-response line))))

(defun lurk-sentinel (proc string)
  (unless (equal "open" (string-trim string))
    (lurk-display-error "Disconnected from server.")
    (clrhash lurk-contexts)
    (lurk-set-current-context nil)
    (lurk-render-prompt)
    (cancel-timer lurk-ping-timer)))

(defun lurk-start-process (network)
  (let* ((row (assoc network lurk-networks))
         (host (elt row 1))
         (port (elt row 2))
         (flags (seq-drop row 3)))
    (make-network-process :name "lurk"
                          :host host
                          :service port
                          :family (if lurk-allow-ipv6 nil 'ipv4)
                          :filter #'lurk-filter
                          :sentinel #'lurk-sentinel
                          :nowait nil
                          :tls-parameters (if (memq :notls flags)
                                              nil
                                            (cons 'gnutls-x509pki
                                                  (gnutls-boot-parameters
                                                   :type 'gnutls-x509pki
                                                   :hostname host)))
                          :buffer "*lurk*")))

(defvar lurk-ping-timer nil)
(defvar lurk-ping-period 60)

(defun lurk-ping-function ()
  (lurk-send-msg (lurk-msg nil nil "PING" (car (process-contact (get-process "lurk")))))
  (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))

(defun lurk-connect (network)
  (if (get-process "lurk")
      (lurk-display-error "Already connected.  Disconnect first.")
    (if (not (assoc network lurk-networks))
        (lurk-display-error "Network '" network "' is unknown.")
      (clrhash lurk-contexts)
      (lurk-set-current-context nil)
      (lurk-start-process network)
      (lurk-send-msg (lurk-msg nil nil "USER" lurk-nick 0 "*" lurk-nick))
      (lurk-send-msg (lurk-msg nil nil "NICK" lurk-nick))
      (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))))

(defun lurk-connected-p ()
  (let ((proc (get-process "lurk")))
    (and proc (eq (process-status proc) 'open))))

(defun lurk-send-msg (msg)
  (if lurk-debug
      (lurk-display-string nil nil (lurk-msg->string msg)))
  (let ((proc (get-process "lurk")))
    (if (and proc (eq (process-status proc) 'open))
        (process-send-string proc (concat (lurk-msg->string msg) "\r\n"))
      (lurk-display-error "No server connection established.")
      (error "No server connection established"))))


;;; Server messages
;;

(defun lurk-msg (tags src cmd &rest params)
  (list (lurk--as-string tags)
        (lurk--as-string src)
        (upcase (lurk--as-string cmd))
        (mapcar #'lurk--as-string
                (if (and params (listp (elt params 0)))
                    (elt params 0)
                  params))))

(defun lurk-msg-tags (msg) (elt msg 0))
(defun lurk-msg-src (msg) (elt msg 1))
(defun lurk-msg-cmd (msg) (elt msg 2))
(defun lurk-msg-params (msg) (elt msg 3))
(defun lurk-msg-trail (msg)
  (let ((params (lurk-msg-params msg)))
    (if params
        (elt params (- (length params) 1)))))

(defvar lurk-msg-regex
  (rx
   (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
        (* whitespace))
   (opt (: ":" (: (group (* (not (any space "!" "@"))))
                  (* (not (any space)))))
        (* whitespace))
   (group (: (* (not whitespace))))
   (* whitespace)
   (opt (group (+ not-newline))))
  "Regex used to parse IRC messages.
Note that this regex is incomplete.  Noteably, we discard the non-nick
portion of the source component of the message, as LURK doesn't use this.")

(defun lurk-string->msg (string)
  (if (string-match lurk-msg-regex string)
      (let* ((tags (match-string 1 string))
             (src (match-string 2 string))
             (cmd (upcase (match-string 3 string)))
             (params-str (match-string 4 string))
             (params
              (if params-str
                  (let* ((idx (cl-search ":" params-str))
                         (l (split-string (string-trim (substring params-str 0 idx))))
                         (r (if idx (list (substring params-str (+ 1 idx))) nil)))
                    (append l r))
                nil)))
        (apply #'lurk-msg (append (list tags src cmd) params)))
    (error "Failed to parse string " string)))

(defun lurk-msg->string (msg)
  (let ((tags (lurk-msg-tags msg))
        (src (lurk-msg-src msg))
        (cmd (lurk-msg-cmd msg))
        (params (lurk-msg-params msg)))
    (lurk--filtered-join
     (if tags (concat "@" tags) nil)
     (if src (concat ":" src) nil)
     cmd
     (if (> (length params) 1)
         (string-join (seq-take params (- (length params) 1)) " ")
       nil)
     (if (> (length params) 0)
         (concat ":" (elt params (- (length params) 1)))
       nil))))


;;; Contexts
;;

(defvar lurk-current-context nil)
(defvar lurk-contexts (make-hash-table :test #'equal))

(defun lurk-add-context (name)
  (puthash name nil lurk-contexts))

(defun lurk-del-context (name)
  (remhash name lurk-contexts))

(defun lurk-get-context-users (name)
  (gethash name lurk-contexts))

(defun lurk-context-known-p (name)
  (not (eq (gethash name lurk-contexts 0) 0)))

(defun lurk-add-context-users (context users)
  (puthash context
           (cl-union users
                     (gethash context lurk-contexts))
           lurk-contexts))

(defun lurk-del-context-user (context user)
  (puthash context
           (remove user (gethash context lurk-contexts))
           lurk-contexts))

(defun lurk-del-user (user)
  (dolist (context (lurk-get-context-list))
    (lurk-del-context-user context user)))

(defun lurk-rename-user (old-nick new-nick)
  (dolist (context (lurk-get-context-list))
    (lurk-del-context-user context old-nick)
    (lurk-add-context-users context (list new-nick))))

(defun lurk-get-context-type (name)
  (cond
   ((string-prefix-p "#" name) 'channel)
   ((string-match-p (rx (or "." "localhost")) name) 'host)
   (t 'nick)))

(defun lurk-get-context-list ()
  (let ((res nil))
    (maphash (lambda (key val)
               (cl-pushnew key res))
             lurk-contexts)
    res))

(defun lurk-get-next-context (&optional prev)
  (if lurk-current-context
      (let* ((context-list (if prev
                               (reverse (lurk-get-context-list))
                             (lurk-get-context-list)))
             (context-list* (member lurk-current-context context-list)))
        (if (> (length context-list*) 1)
            (cadr context-list*)
          (car context-list)))
    nil))

(defun lurk-set-current-context (context)
  (setq lurk-current-context context)
  (lurk-highlight-context context)
  (lurk-render-prompt)
  (if lurk-zoomed
      (lurk-zoom-in lurk-current-context)))

(defun lurk-cycle-contexts (&optional rev)
  (if lurk-current-context
      (lurk-set-current-context (lurk-get-next-context rev))
    (lurk-display-error "No channels joined.")))


;;; Buffer
;;

(defun lurk-render-prompt ()
  (with-current-buffer "*lurk*"
    (let ((update-point (= lurk-input-marker (point)))
          (update-window-points (mapcar (lambda (w)
                                          (list (= (window-point w) lurk-input-marker)
                                                w))
                                        (get-buffer-window-list nil nil t))))
      (save-excursion
        (set-marker-insertion-type lurk-prompt-marker nil)
        (set-marker-insertion-type lurk-input-marker t)
        (let ((inhibit-read-only t))
          (delete-region lurk-prompt-marker lurk-input-marker)
          (goto-char lurk-prompt-marker)
          (insert
           (propertize (if lurk-current-context
                           lurk-current-context
                         "")
                       'face 'lurk-context
                       'read-only t)
           (propertize lurk-prompt-string
                       'face 'lurk-prompt
                       'read-only t)
           (propertize " " ; Need this to be separate to mark it as rear-nonsticky
                       'read-only t
                       'rear-nonsticky t)))
        (set-marker-insertion-type lurk-input-marker nil))
      (if update-point
          (goto-char lurk-input-marker))
      (dolist (v update-window-points)
        (if (car v)
            (set-window-point (cadr v) lurk-input-marker))))))
  
(defvar lurk-prompt-marker nil
  "Marker for prompt position in LURK buffer.")

(defvar lurk-input-marker nil
  "Marker for prompt position in LURK buffer.")

(defun lurk-setup-header ()
  (with-current-buffer "*lurk*"
    (setq-local header-line-format
                '((:eval
                   (let ((proc (get-process "lurk")))
                     (if proc
                         (concat
                          "Host: " (car (process-contact proc))
                          ", Context: "
                          (if lurk-current-context
                              (concat
                               lurk-current-context
                               " ("
                               (number-to-string
                                (length (lurk-get-context-users lurk-current-context)))
                               " users)")
                            "Server"))
                       "No connection")))
                  (:eval
                   (if lurk-zoomed " [ZOOMED]" ""))))))

(defun lurk-setup-buffer ()
  (with-current-buffer (get-buffer-create "*lurk*")
    (setq-local scroll-conservatively 1)
    (setq-local buffer-invisibility-spec nil)
    (if (markerp lurk-prompt-marker)
        (set-marker lurk-prompt-marker (point-max))
      (setq lurk-prompt-marker (point-max-marker)))
    (if (markerp lurk-input-marker)
        (set-marker lurk-input-marker (point-max))
      (setq lurk-input-marker (point-max-marker)))
    (goto-char (point-max))
    (lurk-render-prompt)
    (if lurk-display-header
        (lurk-setup-header))))

(defun lurk-clear-buffer ()
  "Completely erase all non-prompt and non-input text from lurk buffer."
  (with-current-buffer "*lurk*"
    (let ((inhibit-read-only t))
      (delete-region (point-min) lurk-prompt-marker))))

;;; Output formatting and highlighting
;;

;; Idea: the face text property can be a list of faces, applied in
;; order.  By assigning each context a unique list and keeping track
;; of these in a hash table, we can easily switch the face
;; corresponding to a particular context by modifying the elements of
;; this list.
;;
;; More subtly, we make only the cdrs of this list shared among
;; all text of a given context, allowing the cars to be different
;; and for different elements of the context-specific text to have
;; different styling.

;; Additionally, we allow selective hiding of contexts via
;; the buffer-invisibility-spec.

(defvar lurk-context-facelists (make-hash-table :test 'equal)
  "List of seen contexts and associated face lists.")

(defun lurk-get-context-facelist (context)
  (let ((facelist (gethash context lurk-context-facelists)))
    (unless facelist
      (setq facelist (list 'lurk-text))
      (puthash context facelist lurk-context-facelists))
    facelist))

(defun lurk--fill-strings (col indent &rest strings)
  (with-temp-buffer
    (setq buffer-invisibility-spec nil)
    (let ((fill-column col)
          (adaptive-fill-regexp (rx-to-string `(= ,indent anychar))))
      (apply #'insert strings)
      (fill-region (point-min) (point-max) nil t)
      (buffer-string))))

(defun lurk--start-of-final-line ()
  (with-current-buffer "*lurk*"
    (save-excursion
      (goto-char (point-max))
      (line-beginning-position))))

(defun lurk-scroll-windows-to-last-line ()
  (with-current-buffer "*lurk*"
    (dolist (window (get-buffer-window-list))
      (if (>= (window-point window) (lurk--start-of-final-line))
          (with-selected-window window
            (recenter -1))))))

(defun lurk-make-context-button (context &optional label)
  (with-temp-buffer
    (insert-text-button (or label context)
                        'action #'lurk--context-button-action
                        'follow-link t
                        'help-echo "Switch context.")
    (buffer-string)))

(defun lurk--context-button-action (button)
  (let ((context (button-get button 'context)))
    (if (eq lurk-current-context context)
        (lurk-toggle-zoom)
      (lurk-set-current-context context))))

(defun lurk-display-string (context prefix &rest strings)
  (with-current-buffer "*lurk*"
    (save-excursion
      (goto-char lurk-prompt-marker)
      (let* ((inhibit-read-only t)
             (old-pos (marker-position lurk-prompt-marker))
             (padded-timestamp (concat (format-time-string "%H:%M ")))
             (padded-prefix (if prefix (concat prefix " ") ""))
             (context-atom (if context (intern context) nil)))
        (insert-before-markers
         (lurk--fill-strings
          80
          (+ (length padded-timestamp)
             (length padded-prefix))
          (propertize padded-timestamp
                      'face 'lurk-timestamp
                      'read-only t
                      'context context
                      'invisible context-atom)
          (propertize padded-prefix
                      'read-only t
                      'context context
                      'invisible context-atom)
          (lurk-add-formatting
           (propertize (concat (apply #'lurk-buttonify-urls strings) "\n")
                       'face (lurk-get-context-facelist context)
                       'read-only t
                       'context context
                       'invisible context-atom)))))))
  (lurk-scroll-windows-to-last-line))

(defun lurk-display-message (from to text)
  (let ((context (if (eq 'channel (lurk-get-context-type to))
                     to
                   (if (equal to lurk-nick) from to))))
    (lurk-display-string
     context
     (propertize
      (pcase (lurk-get-context-type to)
        ('channel (concat
                   (lurk-make-context-button to)
                   " <" from ">"))
        ('nick (lurk-make-context-button context (concat "[" from " -> " to "]")))
        (_
         (error "Unsupported context type")))
      'face (lurk-get-context-facelist context))
     text)))

(defun lurk-display-action (from to action-text)
  (let ((context (if (eq 'channel (lurk-get-context-type to))
                     to
                   (if (equal to lurk-nick) from to))))
    (lurk-display-string
     context
     (propertize
      (concat (lurk-make-context-button context) " * " from)
      'face (lurk-get-context-facelist context))
     action-text)))

(defun lurk-display-notice (context &rest notices)
  (lurk-display-string
   context
   (propertize lurk-notice-prefix 'face 'lurk-notice)
   (apply #'concat notices)))

(defun lurk-display-error (&rest messages)
  (lurk-display-string
   nil
   (propertize lurk-error-prefix 'face 'lurk-error)
   (apply #'concat messages)))

(defun lurk-highlight-context (context)
  (maphash
   (lambda (this-context facelist)
     (if (equal this-context context)
         (setcar facelist 'lurk-text)
       (setcar facelist 'lurk-faded)))
   lurk-context-facelists)
  (force-window-update "*lurk*"))

(defun lurk-zoom-in (context)
  (with-current-buffer "*lurk*"
    (maphash
     (lambda (this-context _)
       (when this-context
         (let ((this-context-atom (intern this-context)))
           (if (equal this-context context)
               (remove-from-invisibility-spec this-context-atom)
             (add-to-invisibility-spec this-context-atom)))))
     lurk-context-facelists)
    (force-window-update "*lurk*"))
  (lurk-scroll-windows-to-last-line))

(defun lurk-zoom-out ()
  (with-current-buffer "*lurk*"
    (maphash
     (lambda (this-context _)
       (let ((this-context-atom (if this-context (intern this-context) nil)))
         (remove-from-invisibility-spec this-context-atom)))
     lurk-context-facelists)
    (force-window-update "*lurk*"))
  (lurk-scroll-windows-to-last-line))

(defun lurk-clear-context (context)
  (with-current-buffer "*lurk*"
    (save-excursion
      (goto-char (point-min))
      (let ((inhibit-read-only t)
            (match nil))
        (while (setq match (text-property-search-forward 'context context t))
          (delete-region (prop-match-beginning match)
                         (prop-match-end match)))))))

(defconst lurk-url-regex
  (rx (:
       (group (+ alpha))
       "://"
       (group (or (+ (any alnum "." "-"))
                  (+ (any alnum ":"))))
       (opt (group (: ":" (+ digit))))
       (opt (group (: "/"
                      (opt
                       (* (any alnum "-/.,#:%=&_?~@+"))
                       (any alnum "-/#:%=&_~@+")))))))
  "Imperfect regex used to find URLs in plain text.")

(defun lurk-click-url (button)
  (browse-url (button-get button 'url)))

(defun lurk-buttonify-urls (&rest strings)
  "Turn substrings which look like urls in STRING into clickable buttons."
  (with-temp-buffer
    (apply #'insert strings)
    (goto-char (point-min))
    (while (re-search-forward lurk-url-regex nil t)
      (let ((url (match-string 0)))
        (make-text-button (match-beginning 0)
                          (match-end 0)
                          'action #'lurk-click-url
                          'url url
                          'follow-link t
                          'face 'button
                          'help-echo "Open URL in browser.")))
    (buffer-string)))

(defun lurk-add-formatting (string)
  (with-temp-buffer
    (insert string)
    (goto-char (point-min))
    (let ((bold nil)
          (italics nil)
          (underline nil)
          (strikethrough nil)
          (prev-point (point)))
      (while (re-search-forward (rx (or (any "\x02\x1D\x1F\x1E\x0F")
                                        (: "\x03" (+ digit) (opt "," (* digit)))))
                                nil t)
        (let ((beg (+ (match-beginning 0) 1)))
          (if bold
              (add-face-text-property prev-point beg '(:weight bold)))
          (if italics
              (add-face-text-property prev-point beg '(:slant italic)))
          (if underline
              (add-face-text-property prev-point beg '(:underline t)))
          (if strikethrough
              (add-face-text-property prev-point beg '(:strike-through t)))
          (pcase (match-string 0)
            ("\x02" (setq bold (not bold)))
            ("\x1D" (setq italics (not italics)))
            ("\x1F" (setq underline (not underline)))
            ("\x1E" (setq strikethrough (not strikethrough)))
            ("\x0F" ; Reset
             (setq bold nil)
             (setq italics nil)
             (setq underline nil)
             (setq strikethrough nil))
            (_))
          (delete-region (match-beginning 0) (match-end 0))
          (setq prev-point (point)))))
    (buffer-string)))


;;; Message evaluation
;;

(defun lurk-eval-msg-string (string)
  (if lurk-debug
      (lurk-display-string nil nil string))
  (let* ((msg (lurk-string->msg string)))
    (lurk-process-autoreplies msg)
    (pcase (lurk-msg-cmd msg)
      ("PING"
       (lurk-send-msg
        (lurk-msg nil nil "PONG" (lurk-msg-params msg))))

      ("PONG")

      ("001"
       (let* ((params (lurk-msg-params msg))
              (nick (elt params 0))
              (text (string-join (seq-drop params 1) " ")))
         (setq lurk-nick nick)
         (lurk-display-notice nil text)))

      ("353" ; NAMEREPLY
       (let* ((params (lurk-msg-params msg))
              (channel (elt params 2))
              (names (split-string (elt params 3))))
         (if (lurk-context-known-p channel)
             (lurk-add-context-users channel names)
           (lurk-display-notice nil "Users in " channel ": " (string-join names " ")))))

      ("366" ; ENDOFNAMES
       (let* ((params (lurk-msg-params msg))
              (channel (elt params 1)))
         (if (lurk-context-known-p channel)
             (lurk-display-notice
              channel
              (lurk--as-string (length (lurk-get-context-users channel)))
              " users in " channel)
           (lurk-display-notice nil "End of " channel " names list."))))

      ("331"
       (let* ((params (lurk-msg-params msg))
              (channel (elt params 1)))
         (lurk-display-notice
          channel
          "No topic set.")))

      ("332"
       (let* ((params (lurk-msg-params msg))
              (channel (elt params 1))
              (topic (elt params 2)))
         (lurk-display-notice channel "Topic: " topic)))

      ("333") ; Avoid displaying these

      ((rx (= 3 (any digit)))
       (lurk-display-notice nil (mapconcat 'identity (cdr (lurk-msg-params msg)) " ")))

      ((and "JOIN"
            (guard (equal lurk-nick (lurk-msg-src msg))))
       (let ((channel (car (lurk-msg-params msg))))
         (lurk-add-context channel)
         (lurk-set-current-context channel)
         (lurk-display-notice channel "Joining channel " channel)
         (lurk-render-prompt)))

      ("JOIN"
       (let ((channel (car (lurk-msg-params msg)))
             (nick (lurk-msg-src msg)))
         (lurk-add-context-users channel (list nick))
         (if lurk-show-joins
             (lurk-display-notice channel nick " joined channel " channel))))

      ((and "PART"
            (guard (equal lurk-nick (lurk-msg-src msg))))
       (let ((channel (car (lurk-msg-params msg))))
         (lurk-display-notice channel "Left channel " channel)
         (lurk-del-context channel)
         (if (equal channel lurk-current-context)
             (lurk-set-current-context (lurk-get-next-context)))
         (lurk-render-prompt)))

      ("PART"
       (let ((channel (car (lurk-msg-params msg)))
             (nick (lurk-msg-src msg)))
         (lurk-del-context-user channel nick)
         (if lurk-show-joins
             (lurk-display-notice channel nick " left channel " channel))))

      ((and "KICK")
       (let ((kicker-nick (lurk-msg-src msg))
             (channel (car (lurk-msg-params msg)))
             (nick (cadr (lurk-msg-params msg)))
             (reason (caddr (lurk-msg-params msg))))
         (if (equal nick lurk-nick)
             (progn
               (lurk-display-notice channel kicker-nick " kicked you from " channel ": " reason)
               (lurk-del-context channel)
               (if (equal channel lurk-current-context)
                   (lurk-set-current-context (lurk-get-next-context)))
               (lurk-render-prompt))
           (lurk-del-context-user channel nick)
           (lurk-display-notice channel kicker-nick " kicked " nick " from " channel ": " reason))))

      ("QUIT"
       (let ((nick (lurk-msg-src msg))
             (reason (mapconcat 'identity (lurk-msg-params msg) " ")))
         (lurk-del-user nick)
         (if lurk-show-joins
             (lurk-display-notice nil nick " quit: " reason))))

      ((and "NICK"
            (guard (equal lurk-nick (lurk-msg-src msg))))
       (setq lurk-nick (car (lurk-msg-params msg)))
       (lurk-display-notice nil "Set nick to " lurk-nick))

      ("NICK"
       (let ((old-nick (lurk-msg-src msg))
             (new-nick (car (lurk-msg-params msg))))
         (lurk-display-notice nil old-nick " is now known as " new-nick)
         (lurk-rename-user old-nick new-nick)))

      ("NOTICE"
       (let ((nick (lurk-msg-src msg))
             (channel (car (lurk-msg-params msg)))
             (text (cadr (lurk-msg-params msg))))
         (pcase text
           ((rx (: "\01VERSION "
                   (let version (* (not "\01")))
                   "\01"))
            (lurk-display-notice nil "CTCP version reply from " nick ": " version))
           (_
            (lurk-display-notice nil text)))))

      ("PRIVMSG"
       (let* ((from (lurk-msg-src msg))
              (params (lurk-msg-params msg))
              (to (car params))
              (text (cadr params)))
         (pcase text
           ("\01VERSION\01"
            (let ((version-string (concat lurk-version " - running on GNU Emacs " emacs-version)))
              (lurk-send-msg (lurk-msg nil nil "NOTICE"
                                       (list from (concat "\01VERSION "
                                                          version-string
                                                          "\01")))))
            (lurk-display-notice nil "CTCP version request received from " from))

           ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
            (lurk-send-msg (lurk-msg nil nil "NOTICE" (list from ping)))
            (lurk-display-notice from "CTCP ping received from " from))

           ("\01USERINFO\01"
            (lurk-display-notice from "CTCP userinfo request from " from " (no response sent)"))

           ((rx (: "\01ACTION " (let action-text (* (not "\01"))) "\01"))
            (lurk-display-action from to action-text))

           (_
            (lurk-display-message from to text)))))
      (_
       (lurk-display-notice nil (lurk-msg->string msg))))))


;;; User-defined responses


(defvar lurk-autoreply-table nil
  "Table of autoreply messages.

Each autoreply is a list of two elements: (matcher reply)

Here matcher is a list:

(network src cmd params ...)

and reply is another list:

 (cmd params ...)

Each entry in the matcher list is a regular expression tested against the
corresponding values in the incomming message.  Entries can be nil,
in which case they match anything.")

(defun lurk--lists-equal (l1 l2)
    (if (and l1 l2)
        (if (or (not (and (car l1) (car l2)))
                (string-match (car l1) (car l2)))
            (lurk--lists-equal (cdr l1) (cdr l2))
          nil)
      t))

(defun lurk-process-autoreply (msg autoreply)
  (let ((matcher (car autoreply))
        (reply (cadr autoreply)))
    (let ((network (car matcher)))
      (when (and (or (not network)
                     (and (get-process "lurk")
                          (equal (car (process-contact (get-process "lurk")))
                                 (cadr (assoc network lurk-networks)))))
                 (lurk--lists-equal (cdr matcher)
                                    (append (list (lurk-msg-src msg)
                                                  (lurk-msg-cmd msg))
                                            (lurk-msg-params msg))))
        (lurk-send-msg
         (lurk-msg nil nil (car reply) (cdr reply)))))))

(defun lurk-process-autoreplies (msg)
  (mapc
   (lambda (autoreply)
     (lurk-process-autoreply msg autoreply))
   lurk-autoreply-table))


;;; Commands
;;

(defvar lurk-command-table
  '(("DEBUG" "Toggle debug mode on/off." lurk-command-debug lurk-boolean-completions)
    ("HEADER" "Toggle display of header." lurk-command-header lurk-boolean-completions)
    ("CONNECT" "Connect to an IRC network." lurk-command-connect lurk-network-completions)
    ("NETWORKS" "List known IRC networks." lurk-command-networks)
    ("JOIN" "Join one or more channels." lurk-command-join)
    ("TOPIC" "Set topic for current channel." lurk-command-topic)
    ("ME" "Display action." lurk-command-me)
    ("VERSION" "Request version of another user's client via CTCP." lurk-command-version lurk-nick-completions)
    ("PART" "Leave channel." lurk-command-part lurk-context-completions)
    ("QUIT" "Disconnect from current network." lurk-command-quit)
    ("NICK" "Change nick." lurk-command-nick)
    ("LIST" "Display details of one or more channels." lurk-command-list)
    ("WHOIS" "Ask server for details of nick." nil lurk-nick-completions)
    ("USERS" "List nicks of users in current context." lurk-command-users)
    ("MSG" "Send private message to user." lurk-command-msg lurk-nick-completions)
    ("CLEAR" "Clear buffer text." lurk-command-clear lurk-context-completions)
    ("HELP" "Display help on client commands." lurk-command-help lurk-help-completions))
  "Table of commands explicitly supported by Lurk.")

(defun lurk-boolean-completions ()
  '("on" "off"))

(defun lurk-network-completions ()
  (mapcar (lambda (row) (car row)) lurk-networks))

(defun lurk-nick-completions ()
  (lurk-get-context-users lurk-current-context))

(defun lurk-context-completions ()
  (lurk-get-context-list))

(defun lurk-help-completions ()
  (mapcar (lambda (row) (car row)) lurk-command-table))

(defun lurk-command-help (params)
  (if params
      (let* ((cmd-str (upcase (car params)))
             (row (assoc cmd-str lurk-command-table #'equal)))
        (if row
            (progn
              (lurk-display-notice nil "Help for \x02" cmd-str "\x02:")
              (lurk-display-notice nil "  " (elt row 1)))
          (lurk-display-notice nil "No such (client-interpreted) command.")))
    (lurk-display-notice nil "Client-interpreted commands:")
    (dolist (row lurk-command-table)
      (lurk-display-notice nil "  \x02" (elt row 0) "\x02: " (elt row 1)))
    (lurk-display-notice nil "Use /HELP COMMAND to display information about a specific command.")))

(defun lurk-command-debug (params)
  (setq lurk-debug 
        (if params
            (if (equal (upcase (car params)) "ON")
                t
              nil)
          (not lurk-debug)))
  (lurk-display-notice nil "Debug mode now " (if lurk-debug "on" "off") "."))

(defun lurk-command-header (params)
  (if
      (if params
          (equal (upcase (car params)) "ON")
        (not header-line-format))
      (progn
        (lurk-setup-header)
        (lurk-display-notice nil "Header enabled."))
    (setq-local header-line-format nil)
    (lurk-display-notice nil "Header disabled.")))

(defun lurk-command-connect (params)
  (if params
      (let ((network (car params)))
        (lurk-display-notice nil "Attempting to connect to " network "...")
        (lurk-connect network))
    (lurk-display-notice nil "Usage: /connect <network>")))

(defun lurk-command-networks (params)
  (lurk-display-notice nil "Currently-known networks:")
  (dolist (row lurk-networks)
    (seq-let (network server port &rest others) row
      (lurk-display-notice nil "\t" network
                           " [" server
                           " " (number-to-string port) "]")))
  (lurk-display-notice nil "(Modify the `lurk-networks' variable to add more.)"))

(defun lurk-command-join (params)
  (if params
      (dolist (channel params)
        (lurk-send-msg (lurk-msg nil nil "JOIN" channel)))
    (lurk-display-notice nil "Usage: /join channel [channel2 ...]")))

(defun lurk-command-part (params)
  (let ((channel (if params (car params) lurk-current-context)))
    (if channel
        (lurk-send-msg (lurk-msg nil nil "PART" channel))
      (lurk-display-error "No current channel to leave."))))

(defun lurk-command-version (params)
  (if params
      (let ((nick (car params)))
        (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
                                 (list nick "\01VERSION\01")))
        (lurk-display-notice nil "CTCP version request sent to " nick))
    (lurk-display-notice nil "Usage: /version <nick>")))

(defun lurk-command-quit (params)
  (let ((quit-msg (if params (string-join params " ") lurk-default-quit-msg)))
    (lurk-send-msg (lurk-msg nil nil "QUIT" quit-msg))))

(defun lurk-command-nick (params)
  (let ((new-nick (if params (string-join params " ") nil)))
    (if new-nick
        (if (lurk-connected-p)
            (lurk-send-msg (lurk-msg nil nil "NICK" new-nick))
          (setq lurk-nick new-nick)
          (lurk-display-notice nil "Set default nick to '" lurk-nick "'."))
      (lurk-display-notice nil "Current nick: " lurk-nick))))

(defun lurk-command-me (params)
  (if lurk-current-context
      (if params
          (let* ((action (string-join params " "))
                 (ctcp-text (concat "\01ACTION " action "\01")))
            (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
                                     (list lurk-current-context ctcp-text)))
            (lurk-display-action lurk-nick lurk-current-context action))
        (lurk-display-notice nil "Usage: /me <action>"))
    (lurk-display-notice nil "No current channel.")))

(defun lurk-command-list (params)
  (if (not params)
      (lurk-display-notice nil "This command can generate lots of output. Use `/LIST -yes' if you really want this, or `/LIST <channel_regexp>' to reduce the output.")
    (if (equal (upcase (car params)) "-YES")
        (lurk-send-msg (lurk-msg nil nil "LIST"))
      (lurk-send-msg (lurk-msg nil nil "LIST" (car params))))))

(defun lurk-command-topic (params)
  (if lurk-current-context
      (if params
          (lurk-send-msg (lurk-msg nil nil "TOPIC" lurk-current-context (string-join params " ")))
        (lurk-display-notice nil "Usage: /topic <new topic>"))
    (lurk-display-notice nil "No current channel.")))

(defun lurk-command-msg (params)
  (if (and params (>= (length params) 2))
      (let ((to (car params))
            (text (string-join (cdr params) " ")))
        (lurk-send-msg (lurk-msg nil nil "PRIVMSG" to text))
        (lurk-display-message lurk-nick to text))
    (lurk-display-notice nil "Usage: /msg <nick> <message>")))

(defun lurk-command-clear (params)
  (if (not params)
      (lurk-clear-buffer)
    (dolist (context params)
      (lurk-clear-context context))))

(defun lurk-command-users (params)
  (if lurk-current-context
      (progn
        (lurk-display-notice lurk-current-context "Users in " lurk-current-context ":")
        (lurk-display-notice
         lurk-current-context
         (string-join (lurk-get-context-users lurk-current-context) " ")))
    (lurk-display-notice nil "No current channel.")))

;;; Command entering
;;

(defun lurk-enter-string (string)
  (if (string-prefix-p "/" string)
      (pcase string
        ((rx (: "/" (let cmd-str (+ (not whitespace)))
                (opt (+ whitespace)
                     (let params-str (+ anychar))
                     string-end)))
         (let ((command-row (assoc (upcase  cmd-str) lurk-command-table #'equal))
               (params (if params-str
                           (split-string params-str nil t)
                         nil)))
           (if (and command-row (elt command-row 2))
               (funcall (elt command-row 2) params)
             (lurk-send-msg (lurk-msg nil nil (upcase cmd-str) params)))))
        (_
         (lurk-display-error "Badly formed command.")))
    (unless (string-empty-p string)
      (if lurk-current-context
          (progn
            (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
                                     lurk-current-context
                                     string))
            (lurk-display-message lurk-nick lurk-current-context string))
        (lurk-display-error "No current context.")))))


;;; Command history
;;

(defvar lurk-history nil
  "Commands and messages sent in current session.")

(defvar lurk-history-index nil)

(defun lurk-history-cycle (delta)
  (when lurk-history
    (with-current-buffer "*lurk*"
      (if lurk-history-index
          (setq lurk-history-index
                (max 0
                     (min (- (length lurk-history) 1)
                          (+ delta lurk-history-index))))
        (setq lurk-history-index 0))
      (delete-region lurk-input-marker (point-max))
      (insert (elt lurk-history lurk-history-index)))))


;;; Interactive functions
;;

(defun lurk-cycle-contexts-forward ()
  (interactive)
  (lurk-cycle-contexts))

(defun lurk-cycle-contexts-reverse ()
  (interactive)
  (lurk-cycle-contexts t))

(defvar lurk-zoomed nil
  "Keeps track of zoom status.")

(defun lurk-toggle-zoom ()
  (interactive)
  (if lurk-zoomed
      (lurk-zoom-out)
    (lurk-zoom-in lurk-current-context))
  (setq lurk-zoomed (not lurk-zoomed)))

(defun lurk-history-next ()
  (interactive)
  (lurk-history-cycle -1))

(defun lurk-history-prev ()
  (interactive)
  (lurk-history-cycle +1))

(defun lurk-complete-input ()
  (interactive)
  (let ((completion-ignore-case t))
    (when (>= (point) lurk-input-marker)
      (pcase (buffer-substring lurk-input-marker (point))
        ((rx (: "/" (let cmd-str (+ (not whitespace))) (+ " ") (* (not whitespace)) string-end))
         (let ((space-idx (save-excursion
                            (re-search-backward " " lurk-input-marker t)))
               (table-row (assoc (upcase cmd-str) lurk-command-table #'equal)))
           (if (and table-row (elt table-row 3))
               (let* ((completions-nospace (funcall (elt table-row 3)))
                      (completions (mapcar (lambda (el) (concat el " ")) completions-nospace)))
                 (completion-in-region (+ 1 space-idx) (point) completions)))))
        ((rx (: "/" (* (not whitespace)) string-end))
         (message (buffer-substring lurk-input-marker (point)))
         (completion-in-region lurk-input-marker (point)
                               (mapcar (lambda (row) (concat "/" (car row) " "))
                                       lurk-command-table)))
        (_
         (let* ((end (max lurk-input-marker (point)))
                (space-idx (save-excursion
                             (re-search-backward " " lurk-input-marker t)))
                (start (if space-idx (+ 1 space-idx) lurk-input-marker)))
           (unless (string-prefix-p "/" (buffer-substring start end))
             (let* ((users (lurk-get-context-users lurk-current-context))
                    (users-no@ (mapcar
                                (lambda (u) (car (split-string u "@" t)))
                                users)))
               (completion-in-region start end users-no@)))))))))

(defun lurk-enter ()
  "Enter current contents of line after prompt."
  (interactive)
  (with-current-buffer "*lurk*"
    (let ((line (buffer-substring lurk-input-marker (point-max))))
      (push line lurk-history)
      (setq lurk-history-index nil)
      (let ((inhibit-read-only t))
        (delete-region lurk-input-marker (point-max)))
      (lurk-enter-string line))))


;;; Mode
;;

(defvar lurk-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "RET") 'lurk-enter)
    (define-key map (kbd "TAB") 'lurk-complete-input)
    (define-key map (kbd "C-c C-z") 'lurk-toggle-zoom)
    (define-key map (kbd "<C-tab>") 'lurk-cycle-contexts-forward)
    (define-key map (kbd "<C-S-tab>") 'lurk-cycle-contexts-reverse)
    (define-key map (kbd "<C-up>") 'lurk-history-prev)
    (define-key map (kbd "<C-down>") 'lurk-history-next)
    (when (fboundp 'evil-define-key*)
      (evil-define-key* 'motion map
        (kbd "TAB") 'lurk-complete-input))
    map))

(define-derived-mode lurk-mode text-mode "lurk"
  "Major mode for LURK.")

(when (fboundp 'evil-set-initial-state)
  (evil-set-initial-state 'lurk-mode 'insert))


;;; Main start procedure
;;

(defun lurk (&optional network)
  "Start lurk or just switch to the lurk buffer if one already exists.
Also connect to NETWORK if non-nil."
  (interactive)
  (if (get-buffer "*lurk*")
      (switch-to-buffer "*lurk*")
    (switch-to-buffer "*lurk*")
    (lurk-mode)
    (lurk-setup-buffer)
    (if network
        (lurk-command-connect (list network))))
  "Started LURK.")


;;; lurk.el ends here