;;; lurk.el --- Little Unified iRc Klient -*- lexical-binding:t -*-

;; Copyright (C) 2021 Tim Vaughan

;; Author: Tim Vaughan <timv@ughan.xyz>
;; Created: 14 June 2021
;; Version: 1.0
;; Keywords: network
;; Homepage: http://thelambdalab.xyz/erc
;; Package-Requires: ((emacs "26"))

;; This file is not part of GNU Emacs.

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this file.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(provide 'lurk)


;;; Customizations
;;

(defgroup lurk nil
  "Little Unified iRc Klient."
  :group 'network)

(defcustom lurk-nick "plugd"
  "Default nick.")
(defcustom lurk-full-name "plugd"
  "Default full name.")
(defcustom lurk-user-name "plugd"
  "Default user name.")

(defcustom lurk-networks
  '(("libera" "irc.libera.chat" 6697)
    ("freenode" "chat.freenode.net" 6697)
    ("local" "localhost" 6697))
  "IRC networks.")

(defcustom lurk-allow-ipv6 nil
  "Set to non-nil to allow use of IPv6.")

;;; Faces
;;

(defface lurk-text
  '((t :inherit font-lock-preprocessor-face))
  "Face used for Lurk text.")

(defface lurk-your-nick
  '((t :inherit font-lock-constant-face))
  "Face used for highlighting your nick.")

(defface lurk-prompt
  '((t :inherit org-level-2))
  "Face used for the prompt.")

(defface lurk-context
  '((t :inherit org-list-dt))
  "Face used for the context name in the prompt.")

(defface lurk-faded
  '((t :inherit font-lock-preprocessor-face))
  "Face used for faded Lurk text.")

(defface lurk-bold
  '((t :inherit font-lock-function-name-face))
  "Face used for bold Lurk text.")

(defface lurk-error
  '((t :inherit font-lock-regexp-grouping-construct))
  "Face used for Lurk error text.")

;;; Global variables
;;

(defvar lurk-version "Lurk v0.1")

(defvar lurk-notice-prefix
  (concat
   (propertize
    "-" 'face 'lurk-faded)
   (propertize
    "!" 'face 'lurk-bold)
   (propertize
    "-" 'face 'lurk-faded)))

(defvar lurk-error-prefix
  (propertize "!!!" 'face 'lurk-error))


(defvar lurk-prompt-string
  (propertize "> " 'face 'lurk-prompt))


;;; Network process
;;

(defvar lurk-response "")

(defun lurk-filter (proc string)
  (dolist (line (split-string (concat lurk-response string) "\n"))
    (if (string-suffix-p "\r" line)
        (lurk-eval-msg-string (string-trim line))
      (setq lurk-response line))))

(defun lurk-sentinel (proc string)
  (unless (equal "open" (string-trim string))
    (lurk-display-error "Disconnected from server.")
    (clrhash lurk-contexts)
    (setq lurk-current-context nil)
    (lurk-render-prompt)
    (cancel-timer lurk-ping-timer)))

(defun lurk-start-process (network)
  (let* ((row (assoc network lurk-networks))
         (host (elt row 1))
         (port (elt row 2))
         (flags (seq-drop row 3)))
    (make-network-process :name "lurk"
                          :host host
                          :service port
                          :family (if lurk-allow-ipv6 nil 'ipv4)
                          :filter #'lurk-filter
                          :sentinel #'lurk-sentinel
                          :nowait nil
                          :tls-parameters (if (memq :notls flags)
                                              nil
                                            (cons 'gnutls-x509pki
                                                  (gnutls-boot-parameters
                                                   :type 'gnutls-x509pki
                                                   :hostname host)))
                          :buffer "*lurk*")))

(defvar lurk-ping-timer nil)
(defvar lurk-ping-period 60)

(defun lurk-ping-function ()
  (lurk-send-msg (lurk-msg nil nil "PING" (car (process-contact (get-process "lurk")))))
  (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))

(defun lurk-connect (network)
  (if (get-process "lurk")
      (lurk-display-error "Already connected.  Disconnect first.")
    (if (not (assoc network lurk-networks))
        (lurk-display-error "Network '" network "' is unknown.")
      (clrhash lurk-contexts)
      (setq lurk-current-context nil)
      (lurk-start-process network)
      (lurk-send-msg (lurk-msg nil nil "USER" lurk-user-name 0 "*" lurk-full-name))
      (lurk-send-msg (lurk-msg nil nil "NICK" lurk-nick))
      (setq lurk-ping-timer (run-with-timer lurk-ping-period nil #'lurk-ping-function)))))


(defun lurk-send-msg (msg)
  (let ((proc (get-process "lurk")))
    (if (and proc (eq (process-status proc) 'open))
        (process-send-string proc (concat (lurk-msg->string msg) "\r\n"))
      (lurk-display-error "No server connection established.")
      (error "No server connection established"))))


;;; Server messages
;;

(defun lurk--as-string (obj)
  (if obj
      (with-output-to-string (princ obj))
    nil))

(defun lurk-msg (tags src cmd &rest params)
  (list (lurk--as-string tags)
        (lurk--as-string src)
        (upcase (lurk--as-string cmd))
        (mapcar #'lurk--as-string
                (if (and params (listp (elt params 0)))
                    (elt params 0)
                  params))))

(defun lurk-msg-tags (msg) (elt msg 0))
(defun lurk-msg-src (msg) (elt msg 1))
(defun lurk-msg-cmd (msg) (elt msg 2))
(defun lurk-msg-params (msg) (elt msg 3))
(defun lurk-msg-trail (msg)
  (let ((params (lurk-msg-params msg)))
    (if params
        (elt params (- (length params) 1)))))

(defvar lurk-msg-regex
  (rx
   (opt (: "@" (group (* (not (or "\n" "\r" ";" " ")))))
        (* whitespace))
   (opt (: ":" (: (group (* (not (any space "!" "@"))))
                  (* (not (any space)))))
        (* whitespace))
   (group (: (* (not whitespace))))
   (* whitespace)
   (opt (group (+ not-newline))))
  "Regex used to parse IRC messages.
Note that this regex is incomplete.  Noteably, we discard the non-nick
portion of the source component of the message, as LURK doesn't use this.")

(defun lurk-string->msg (string)
  (if (string-match lurk-msg-regex string)
      (let* ((tags (match-string 1 string))
             (src (match-string 2 string))
             (cmd (upcase (match-string 3 string)))
             (params-str (match-string 4 string))
             (params
              (if params-str
                  (let* ((idx (cl-search ":" params-str))
                         (l (split-string (string-trim (substring params-str 0 idx))))
                         (r (if idx (list (substring params-str (+ 1 idx))) nil)))
                    (append l r))
                nil)))
        (apply #'lurk-msg (append (list tags src cmd) params)))
    (error "Failed to parse string " string)))

(defun lurk--filtered-join (&rest args)
  (string-join (seq-filter (lambda (el) el) args) " "))

(defun lurk-msg->string (msg)
  (let ((tags (lurk-msg-tags msg))
        (src (lurk-msg-src msg))
        (cmd (lurk-msg-cmd msg))
        (params (lurk-msg-params msg)))
    (lurk--filtered-join
     (if tags (concat "@" tags) nil)
     (if src (concat ":" src) nil)
     cmd
     (if (> (length params) 1)
         (string-join (seq-take params (- (length params) 1)) " ")
       nil)
     (if (> (length params) 0)
         (concat ":" (elt params (- (length params) 1)))
       nil))))


;;; Contexts and users
;;

(defvar lurk-context-table
  '((channel lurk-display-channel-message)
    (nick lurk-display-private-message)
    (host lurk-diaplay-server-message)))

(defvar lurk-current-context nil)
(defvar lurk-contexts (make-hash-table :test #'equal))

(defun lurk-add-context (name)
  (puthash name nil lurk-contexts))

(defun lurk-del-context (name)
  (remhash name lurk-contexts))

(defun lurk-get-context-users (name)
  (gethash name lurk-contexts))

(defun lurk-add-context-users (context users)
  (puthash context
           (append users
                   (gethash context lurk-contexts))
           lurk-contexts))

(defun lurk-del-context-user (context user)
  (puthash context
           (remove user (gethash context lurk-contexts))
           lurk-contexts))

(defun lurk-del-user (user)
  (dolist (context (lurk-get-context-list))
    (lurk-del-context-user context user)))

(defun lurk-get-context-type (name)
  (cond
   ((string-prefix-p "#" name) 'channel)
   ((string-match-p (rx (or "." "localhost")) name) 'host)
   (t 'nick)))

(defun lurk-get-context-list ()
  (let ((res nil))
    (maphash (lambda (key val)
               (cl-pushnew key res))
             lurk-contexts)
    res))

(defun lurk-get-next-context (&optional prev)
  (if lurk-current-context
      (let* ((context-list (if prev
                               (reverse (lurk-get-context-list))
                             (lurk-get-context-list)))
             (context-list* (member lurk-current-context context-list)))
        (if (> (length context-list*) 1)
            (cadr context-list*)
          (car context-list)))
    nil))

(defun lurk-cycle-contexts (&optional rev)
  (if lurk-current-context
      (progn
        (setq lurk-current-context (lurk-get-next-context rev))
        (lurk-render-prompt))
    (lurk-display-error "No channels joined.")))

(defun lurk-cycle-contexts-forward ()
  (interactive)
  (lurk-cycle-contexts))

(defun lurk-cycle-contexts-reverse ()
  (interactive)
  (lurk-cycle-contexts t))

;;; Buffer
;;

(defun lurk-display-string (&rest strings)
  (with-current-buffer (get-buffer-create "*lurk*")
    (save-excursion
      (goto-char lurk-prompt-marker)
      (let ((inhibit-read-only t)
            (old-pos (marker-position lurk-prompt-marker))
            (adaptive-fill-regexp (rx (= 6 anychar))))
        (insert-before-markers
         (propertize (concat (format-time-string "%H:%M") " ")
                     'face 'lurk-text
                     'read-only t)
         (propertize (concat (apply #'concat strings) "\n")
                     'read-only t))
        (fill-region old-pos lurk-prompt-marker)))))

(defun lurk-render-prompt ()
  (with-current-buffer "*lurk*"
    (let ((update-point (= lurk-input-marker (point)))
          (update-window-points (mapcar (lambda (w)
                                          (list (= (window-point w) lurk-input-marker)
                                                w))
                                        (get-buffer-window-list nil nil t))))
      (save-excursion
        (set-marker-insertion-type lurk-prompt-marker nil)
        (set-marker-insertion-type lurk-input-marker t)
        (let ((inhibit-read-only t))
          (delete-region lurk-prompt-marker lurk-input-marker)
          (goto-char lurk-prompt-marker)
          (insert
           (propertize (if lurk-current-context
                           lurk-current-context
                         "")
                       'face 'lurk-context
                       'read-only t)
           (propertize lurk-prompt-string
                       'face 'lurk-prompt
                       'read-only t
                       'rear-nonsticky t)))
        (set-marker-insertion-type lurk-input-marker nil))
      (if update-point
          (goto-char lurk-input-marker))
      (dolist (v update-window-points)
        (if (car v)
            (set-window-point (cadr v) lurk-input-marker))))))
  
(defvar lurk-prompt-marker nil
  "Marker for prompt position in LURK buffer.")

(defvar lurk-input-marker nil
  "Marker for prompt position in LURK buffer.")

(defun lurk-setup-buffer ()
  (with-current-buffer (get-buffer-create "*lurk*")
    (if (markerp lurk-prompt-marker)
        (set-marker lurk-prompt-marker (point-max))
      (setq lurk-prompt-marker (point-max-marker)))
    (if (markerp lurk-input-marker)
        (set-marker lurk-input-marker (point-max))
      (setq lurk-input-marker (point-max-marker)))
    (goto-char (point-max))
    (lurk-render-prompt)))


;;; Output formatting
;;

(defun lurk-display-message (from to text)
  (let* ((to-type (lurk-get-context-type to))
         (display-fun (cadr (assoc to-type lurk-context-table))))
    (funcall display-fun from to text)))

(defun lurk-display-channel-message (from to text)
  (lurk-display-string
   (propertize (concat to
                       " <" from "> "
                       text)
               'face 'lurk-text)))
               

(defun lurk-display-action (channel-name nick action)
  (lurk-display-string (concat channel-name
                               " * "
                               (propertize (concat nick " " action)
                                           'face 'lurk-text))))

(defun lurk-display-private-message (from to text)
  (lurk-display-string
   (concat
    (propertize
     (concat "[" from " -> " to "] "
             text)
     'face 'lurk-text))))
        

(defun lurk-display-notice (&rest notices)
  (lurk-display-string lurk-notice-prefix " " (apply #'concat notices)))

(defun lurk-display-error (&rest messages)
  (lurk-display-string lurk-error-prefix " "
                       (propertize (apply #'concat messages)
                                   'face 'lurk-error)))

;;; Message evaluation
;;

(defun lurk-eval-msg-string (string)
  ;; (lurk-display-string string)
  (let* ((msg (lurk-string->msg string)))
    (pcase (lurk-msg-cmd msg)
      ("PING"
       (lurk-send-msg
        (lurk-msg nil nil "PONG" (lurk-msg-params msg)))
       (lurk-display-notice "ping-pong"))

      ("353" ; NAMEREPLY
       (let* ((params (lurk-msg-params msg))
              (channel (elt params 2))
              (names (split-string (elt params 3))))
         (lurk-add-context-users channel names)))

      ("366" ; ENDOFNAMES
       (lurk-display-notice
        (lurk--as-string (length (lurk-get-context-users lurk-current-context)))
        " users in " lurk-current-context))

      ((rx (= 3 (any digit)))
       (lurk-display-notice (mapconcat 'identity (cdr (lurk-msg-params msg)) " ")))

      ((and "JOIN"
            (guard (equal lurk-nick (lurk-msg-src msg))))
       (let ((channel-name (car (lurk-msg-params msg))))
         (lurk-add-context channel-name)
         (setq lurk-current-context channel-name)
         (lurk-display-notice "Joining channel " channel-name)
         (lurk-render-prompt)))

      ("JOIN"
       (let ((channel-name (car (lurk-msg-params msg)))
             (nick (lurk-msg-src msg)))
         (lurk-add-context-users channel-name (list nick))
         (lurk-display-notice nick " joined channel " channel-name)))

      ((and "PART"
            (guard (equal lurk-nick (lurk-msg-src msg))))
       (let ((channel-name (car (lurk-msg-params msg))))
         (lurk-display-notice "Left channel " channel-name)
         (lurk-del-context channel-name)
         (if (equal channel-name lurk-current-context)
             (setq lurk-current-context (lurk-get-next-context)))
         (lurk-render-prompt)))

      ("PART"
       (let ((channel-name (car (lurk-msg-params msg)))
             (nick (lurk-msg-src msg)))
         (lurk-del-context-user channel-name nick)
         (lurk-display-notice nick " left channel " channel-name)))

      ("QUIT"
       (let ((nick (lurk-msg-src msg))
             (reason (mapconcat 'identity (lurk-msg-params msg) " ")))
         (lurk-del-user nick)
         (lurk-display-notice nick " quit: " reason)))

      ((and "NICK"
            (guard (equal lurk-nick (lurk-msg-src msg))))
       (setq lurk-nick (car (lurk-msg-params msg)))
       (lurk-display-notice "Set nick to " lurk-nick))

      ("NICK"
       (let ((old-nick (lurk-msg-src msg))
             (new-nick (car (lurk-msg-params msg))))
         (lurk-display-notice nick " is now known as " new-nick)
         (lurk-rename-user nick new-nick)))

      ("NOTICE"
       (let ((nick (lurk-msg-src msg))
             (channel (car (lurk-msg-params msg)))
             (text (cadr (lurk-msg-params msg))))
         (pcase text
           ((rx (: "\01VERSION "
                   (let version (* (not "\01")))
                   "\01"))
            (lurk-display-notice "CTCP version reply from " nick ": " version))
           (_
            (lurk-display-notice text)))))

      ("PRIVMSG"
       (let* ((from (lurk-msg-src msg))
              (params (lurk-msg-params msg))
              (to (car params))
              (text (cadr params)))
         (pcase text
           ("\01VERSION\01"
            (let ((version-string (concat lurk-version " - running on GNU Emacs " emacs-version)))
              (lurk-send-msg (lurk-msg nil nil "NOTICE"
                                       (list from (concat "\01VERSION "
                                                          version-string
                                                          "\01")))))
            (lurk-display-notice "CTCP version request received from " from))

           ((rx (let ping (: "\01PING " (* (not "\01")) "\01")))
            (lurk-send-msg (lurk-msg nil nil "NOTICE" (list from ping)))
            (lurk-display-notice "CTCP ping received from " from))

           ("\01USERINFO\01"
            (lurk-display-notice "CTCP userinfo request from " from " (no response sent)"))

           (_
            (lurk-display-message from to text)))))
      (_
       (lurk-display-string (lurk-msg->string msg))))))


;;; Command entering
;;

(defun lurk-enter-string (string)
  (if (string-prefix-p "/" string)
      (pcase (substring string 1)
        ((rx (: "CONNECT " (let network (* not-newline))))
         (lurk-display-notice "Attempting to connect to " network "...")
         (lurk-connect network))

        ((rx (: "TOPIC " (let new-topic (* not-newline))))
         (lurk-send-msg (lurk-msg nil nil "TOPIC" lurk-current-context new-topic)))

        ((rx (: "ME " (let action (* not-newline))))
         (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
                                  (list lurk-current-context
                                        (concat "\01ACTION " action "\01"))))
         (lurk-display-action lurk-nick action))

        ((rx (: "VERSION" " " (let nick (* (not whitespace)))))
         (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
                                  (list nick "\01VERSION\01")))
         (lurk-display-notice "CTCP version request sent to " nick))

        ((rx "PART" (opt (: " " (let channel (* not-newline)))))
         (if (or lurk-current-context channel)
             (lurk-send-msg (lurk-msg nil nil "PART" (if channel
                                                         channel
                                                       lurk-current-context)))
           (lurk-display-error "No current channel to leave.")))

        ((rx "MSG "
             (let to (* (not whitespace)))
             " "
             (let text (* not-newline)))
         (lurk-send-msg (lurk-msg nil nil "PRIVMSG" to text))
         (lurk-display-message lurk-nick to text))

        ((rx (: (let cmd-str (+ (not whitespace)))
                (opt (: " " (let params-str (* not-newline))))))
         (lurk-send-msg (lurk-msg nil nil (upcase cmd-str)
                                  (if params-str
                                      (split-string params-str)
                                    nil)))))

    (unless (string-empty-p string)
      (if lurk-current-context
          (progn
            (lurk-send-msg (lurk-msg nil nil "PRIVMSG"
                                     lurk-current-context
                                     string))
            (lurk-display-message lurk-nick lurk-current-context string))
        (lurk-display-error "No current context.")))))

(defun lurk-enter ()
  "Enter current contents of line after prompt."
  (interactive)
  (with-current-buffer "*lurk*"
    (lurk-enter-string
     (buffer-substring lurk-input-marker (point-max)))
    (let ((inhibit-read-only t))
      (delete-region lurk-input-marker (point-max)))))


;;; Mode
;;

(defvar lurk-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "RET") 'lurk-enter)
    (define-key map (kbd "<C-tab>") 'lurk-cycle-contexts-forward)
    (define-key map (kbd "<C-S-tab>") 'lurk-cycle-contexts-reverse)
    map))

(define-derived-mode lurk-mode text-mode "lurk"
  "Major mode for LURK.")

(when (fboundp 'evil-set-initial-state)
  (evil-set-initial-state 'lurk-mode 'insert))

;;; Main start procedure
;;

(defun lurk ()
  "Switch to *lurk* buffer."
  (interactive)
  (if (get-buffer "*lurk*")
      (switch-to-buffer "*lurk*")
    (switch-to-buffer "*lurk*"))
  (lurk-mode)
  (lurk-setup-buffer)
  "Started LURK.")



;;; lurk.el ends here