elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2019-2020 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.10.2
   8 ;; Keywords: comm gopher
   9 ;; Homepage: http://thelambdalab.xyz/elpher
  10 ;; Package-Requires: ((emacs "26.2"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher and gemini
  30 ;; client for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official
  51 ;; project page, gopher://thelambdalab.xyz/1/projects/elpher/.
  52
  53 ;;; Code:
  54
  55 (provide 'elpher)
  56
  57 ;;; Dependencies
  58 ;;
  59
  60 (require 'seq)
  61 (require 'pp)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'dns)
  66 (require 'ansi-color)
  67 (require 'nsm)
  68 (require 'gnutls)
  69
  70
  71 ;;; Global constants
  72 ;;
  73
  74 (defconst elpher-version "2.10.2"
  75   "Current version of elpher.")
  76
  77 (defconst elpher-margin-width 6
  78   "Width of left-hand margin used when rendering indicies.")
  79
  80 (defconst elpher-type-map
  81   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  82     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  83     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  85     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  86     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  87     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  90     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  92     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  93     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  94     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     ((special bookmarks) elpher-get-bookmarks-page nil "/" elpher-index)
  99     ((special start) elpher-get-start-page nil))
 100   "Association list from types to getters, renderers, margin codes and index faces.")
 101
 102
 103 ;;; Customization group
 104 ;;
 105
 106 (defgroup elpher nil
 107   "A gopher and gemini client."
 108   :group 'applications)
 109
 110 ;; General appearance and customizations
 111
 112 (defcustom elpher-open-urls-with-eww nil
 113   "If non-nil, open URL selectors using eww.
 114 Otherwise, use the system browser via the BROWSE-URL function."
 115   :type '(boolean))
 116
 117 (defcustom elpher-use-header t
 118   "If non-nil, display current page information in buffer header."
 119   :type '(boolean))
 120
 121 (defcustom elpher-auto-disengage-TLS nil
 122   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 123 While enabling this may seem convenient, it is also potentially dangerous as it
 124 allows switching from an encrypted channel back to plain text without user input."
 125   :type '(boolean))
 126
 127 (defcustom elpher-connection-timeout 5
 128   "Specifies the number of seconds to wait for a network connection to time out."
 129   :type '(integer))
 130
 131 (defcustom elpher-filter-ansi-from-text nil
 132   "If non-nil, filter ANSI escape sequences from text.
 133 The default behaviour is to use the ansi-color package to interpret these
 134 sequences."
 135   :type '(boolean))
 136
 137 (defcustom elpher-certificate-directory
 138   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 139   "Specify the name of the directory where client certificates will be stored.
 140 These certificates may be used for establishing authenticated TLS connections."
 141   :type '(directory))
 142
 143 (defcustom elpher-openssl-command "openssl"
 144   "The command used to launch openssl when generating TLS client certificates."
 145   :type '(file))
 146
 147 (defcustom elpher-gemini-TLS-cert-checks nil
 148   "If non-nil, verify gemini server TLS certs using the default security level.
 149 Otherwise, certificate verification is disabled.
 150
 151 This defaults to off because it is standard practice for Gemini servers
 152 to use self-signed certificates, meaning that most servers provide what
 153 EMACS considers to be an invalid certificate."
 154   :type '(boolean))
 155
 156 (defcustom elpher-gemini-max-fill-width 80
 157   "Specify the maximum default width (in columns) of text/gemini documents.
 158 The actual width used is the minimum of this value and the window width at
 159 the time when the text is rendered."
 160   :type '(integer))
 161
 162 (defcustom elpher-gemini-link-string "→ "
 163   "Specify the string used to indicate links when rendering gemini maps.
 164 May be empty."
 165   :type '(string))
 166
 167 (defcustom elpher-gemini-bullet-string "•"
 168   "Specify the string used for bullets when rendering gemini maps."
 169   :type '(string))
 170
 171 (defcustom elpher-bookmarks-file (locate-user-emacs-file "elpher-bookmarks")
 172   "Specify the name of the file where elpher bookmarks will be saved."
 173   :type '(file))
 174
 175 (defcustom elpher-ipv4-always nil
 176   "If non-nil, elpher will always use IPv4 to establish network connections.
 177 This can be useful when browsing from a computer that supports IPv6, because
 178 some servers which do not support IPv6 can take a long time to time-out."
 179   :type '(boolean))
 180
 181 ;; Face customizations
 182
 183 (defgroup elpher-faces nil
 184   "Elpher face customizations."
 185   :group 'elpher)
 186
 187 (defface elpher-index
 188   '((t :inherit font-lock-keyword-face))
 189   "Face used for directory type directory records.")
 190
 191 (defface elpher-text
 192   '((t :inherit bold))
 193   "Face used for text type directory records.")
 194
 195 (defface elpher-info
 196   '((t :inherit default))
 197   "Face used for info type directory records.")
 198
 199 (defface elpher-image
 200   '((t :inherit font-lock-string-face))
 201   "Face used for image type directory records.")
 202
 203 (defface elpher-search
 204   '((t :inherit warning))
 205   "Face used for search type directory records.")
 206
 207 (defface elpher-html
 208   '((t :inherit font-lock-comment-face))
 209   "Face used for html type directory records.")
 210
 211 (defface elpher-gemini
 212   '((t :inherit font-lock-constant-face))
 213   "Face used for Gemini type directory records.")
 214
 215 (defface elpher-other-url
 216   '((t :inherit font-lock-comment-face))
 217   "Face used for other URL type links records.")
 218
 219 (defface elpher-telnet
 220   '((t :inherit font-lock-function-name-face))
 221   "Face used for telnet type directory records.")
 222
 223 (defface elpher-binary
 224   '((t :inherit font-lock-doc-face))
 225   "Face used for binary type directory records.")
 226
 227 (defface elpher-unknown
 228   '((t :inherit error))
 229   "Face used for directory records with unknown/unsupported types.")
 230
 231 (defface elpher-margin-key
 232   '((t :inherit bold))
 233   "Face used for directory margin key.")
 234
 235 (defface elpher-margin-brackets
 236   '((t :inherit shadow))
 237   "Face used for brackets around directory margin key.")
 238
 239 (defface elpher-gemini-heading1
 240   '((t :inherit bold :height 1.8))
 241   "Face used for gemini heading level 1.")
 242
 243 (defface elpher-gemini-heading2
 244   '((t :inherit bold :height 1.5))
 245   "Face used for gemini heading level 2.")
 246
 247 (defface elpher-gemini-heading3
 248   '((t :inherit bold :height 1.2))
 249   "Face used for gemini heading level 3.")
 250
 251 (defface elpher-gemini-preformatted
 252   '((t :inherit fixed-pitch))
 253   "Face used for pre-formatted gemini text blocks.")
 254
 255 ;;; Model
 256 ;;
 257
 258 ;; Address
 259
 260 ;; An elpher "address" object is either a url object or a symbol.
 261 ;; Symbol addresses are "special", corresponding to pages generated
 262 ;; dynamically for and by elpher.  All others represent pages which
 263 ;; rely on content retrieved over the network.
 264
 265 (defun elpher-address-from-url (url-string)
 266   "Create a ADDRESS object corresponding to the given URL-STRING."
 267   (let ((data (match-data))) ; Prevent parsing clobbering match data
 268     (unwind-protect
 269         (let ((url (url-generic-parse-url url-string)))
 270           (unless (and (not (url-fullness url)) (url-type url))
 271             (setf (url-fullness url) t)
 272             (setf (url-filename url)
 273                   (url-unhex-string (url-filename url)))
 274             (unless (url-type url)
 275               (setf (url-type url) "gopher"))
 276             (when (or (equal "gopher" (url-type url))
 277                       (equal "gophers" (url-type url)))
 278               ;; Gopher defaults
 279               (unless (url-host url)
 280                 (setf (url-host url) (url-filename url))
 281                 (setf (url-filename url) ""))
 282               (when (or (equal (url-filename url) "")
 283                         (equal (url-filename url) "/"))
 284                 (setf (url-filename url) "/1")))
 285             (when (equal "gemini" (url-type url))
 286               ;; Gemini defaults
 287               (if (equal (url-filename url) "")
 288                   (setf (url-filename url) "/"))))
 289           (elpher-remove-redundant-ports url))
 290       (set-match-data data))))
 291
 292 (defun elpher-remove-redundant-ports (address)
 293   "Remove redundant port specifiers from ADDRESS.
 294 Here 'redundant' means that the specified port matches the default
 295 for that protocol, eg 70 for gopher."
 296   (if (and (not (elpher-address-special-p address))
 297            (eq (url-portspec address) ; (url-port) is too slow!
 298                (pcase (url-type address)
 299                  ("gemini" 1965)
 300                  ((or "gopher" "gophers") 70)
 301                  ("finger" 79)
 302                  (_ -1))))
 303       (setf (url-portspec address) nil))
 304   address)
 305
 306 (defun elpher-make-gopher-address (type selector host port &optional tls)
 307   "Create an ADDRESS object using gopher directory record attributes.
 308 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 309 If the optional attribute TLS is non-nil, the address will be marked as
 310 requiring gopher-over-TLS."
 311   (cond
 312    ((equal type ?i) nil)
 313    ((and (equal type ?h)
 314          (string-prefix-p "URL:" selector))
 315     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 316    ((equal type ?8)
 317     (elpher-address-from-url
 318      (concat "telnet"
 319              "://" host
 320              ":" (number-to-string port))))
 321    (t
 322     (elpher-address-from-url
 323      (concat "gopher" (if tls "s" "")
 324              "://" host
 325              ":" (number-to-string port)
 326              "/" (string type)
 327              selector)))))
 328
 329 (defun elpher-make-special-address (type)
 330   "Create an ADDRESS object corresponding to the given special address symbol TYPE."
 331   type)
 332
 333 (defun elpher-address-to-url (address)
 334   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 335   (if (elpher-address-special-p address)
 336       nil
 337     (url-encode-url (url-recreate-url address))))
 338
 339 (defun elpher-address-type (address)
 340   "Retrieve type of ADDRESS object.
 341 This is used to determine how to retrieve and render the document the
 342 address refers to, via the table `elpher-type-map'."
 343   (if (symbolp address)
 344       (list 'special address)
 345     (let ((protocol (url-type address)))
 346       (cond ((or (equal protocol "gopher")
 347                  (equal protocol "gophers"))
 348              (list 'gopher
 349                    (if (member (url-filename address) '("" "/"))
 350                        ?1
 351                      (string-to-char (substring (url-filename address) 1)))))
 352             ((equal protocol "gemini")
 353              'gemini)
 354             ((equal protocol "telnet")
 355              'telnet)
 356             ((equal protocol "finger")
 357              'finger)
 358             (t 'other-url)))))
 359
 360 (defun elpher-address-protocol (address)
 361   "Retrieve the transport protocol for ADDRESS.  This is nil for special addresses."
 362   (if (symbolp address)
 363       nil
 364     (url-type address)))
 365
 366 (defun elpher-address-filename (address)
 367   "Retrieve the filename component of ADDRESS.
 368 For gopher addresses this is a combination of the selector type and selector."
 369   (if (symbolp address)
 370       nil
 371     (url-filename address)))
 372
 373 (defun elpher-address-host (address)
 374   "Retrieve host from ADDRESS object."
 375   (url-host address))
 376
 377 (defun elpher-address-user (address)
 378   "Retrieve user from ADDRESS object."
 379   (url-user address))
 380
 381 (defun elpher-address-port (address)
 382   "Retrieve port from ADDRESS object.
 383 If no address is defined, returns 0.  (This is for compatibility with the URL library.)"
 384   (if (symbolp address)
 385       0
 386     (url-port address)))
 387
 388 (defun elpher-address-special-p (address)
 389   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 390   (symbolp address))
 391
 392 (defun elpher-address-gopher-p (address)
 393   "Return non-nill if ADDRESS object is a gopher address."
 394   (and (not (elpher-address-special-p address))
 395        (member (elpher-address-protocol address) '("gopher gophers"))))
 396
 397 (defun elpher-gopher-address-selector (address)
 398   "Retrieve gopher selector from ADDRESS object."
 399   (if (member (url-filename address) '("" "/"))
 400       ""
 401     (url-unhex-string (substring (url-filename address) 2))))
 402
 403
 404 ;; Cache
 405
 406 (defvar elpher-content-cache (make-hash-table :test 'equal))
 407 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 408
 409 (defun elpher-get-cached-content (address)
 410   "Retrieve the cached content for ADDRESS, or nil if none exists."
 411   (gethash address elpher-content-cache))
 412
 413 (defun elpher-cache-content (address content)
 414   "Set the content cache for ADDRESS to CONTENT."
 415   (puthash address content elpher-content-cache))
 416
 417 (defun elpher-get-cached-pos (address)
 418   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 419   (gethash address elpher-pos-cache))
 420
 421 (defun elpher-cache-pos (address pos)
 422   "Set the cursor position cache for ADDRESS to POS."
 423   (puthash address pos elpher-pos-cache))
 424
 425
 426 ;; Page
 427
 428 (defun elpher-make-page (display-string address)
 429   "Create a page with DISPLAY-STRING and ADDRESS."
 430   (list display-string address))
 431
 432 (defun elpher-page-display-string (page)
 433   "Retrieve the display string corresponding to PAGE."
 434   (elt page 0))
 435
 436 (defun elpher-page-address (page)
 437   "Retrieve the address corresponding to PAGE."
 438   (elt page 1))
 439
 440 (defun elpher-page-set-address (page new-address)
 441   "Set the address corresponding to PAGE to NEW-ADDRESS."
 442   (setcar (cdr page) new-address))
 443
 444 (defvar elpher-current-page nil)        ; buffer local
 445 (defvar elpher-history nil)             ; buffer local
 446
 447 (defun elpher-visit-page (page &optional renderer no-history)
 448   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 449 Additionally, push PAGE onto the stack of previously-visited pages,
 450 unless NO-HISTORY is non-nil."
 451   (elpher-save-pos)
 452   (elpher-process-cleanup)
 453   (unless (or no-history
 454               (equal (elpher-page-address elpher-current-page)
 455                      (elpher-page-address page)))
 456     (push elpher-current-page elpher-history))
 457   (setq-local elpher-current-page page)
 458   (let* ((address (elpher-page-address page))
 459          (type (elpher-address-type address))
 460          (type-record (cdr (assoc type elpher-type-map))))
 461     (if type-record
 462         (funcall (car type-record)
 463                  (if renderer
 464                      renderer
 465                    (cadr type-record)))
 466       (elpher-visit-previous-page)
 467       (pcase type
 468         (`(gopher ,type-char)
 469          (error "Unsupported gopher selector type '%c' for '%s'"
 470                 type-char (elpher-address-to-url address)))
 471         (other
 472          (error "Unsupported address type '%S' for '%s'"
 473                 other (elpher-address-to-url address)))))))
 474
 475 (defun elpher-visit-previous-page ()
 476   "Visit the previous page in the history."
 477   (let ((previous-page (pop elpher-history)))
 478     (if previous-page
 479         (elpher-visit-page previous-page nil t)
 480       (error "No previous page"))))
 481
 482 (defun elpher-reload-current-page ()
 483   "Reload the current page, discarding any existing cached content."
 484   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 485   (elpher-visit-page elpher-current-page))
 486
 487 (defun elpher-save-pos ()
 488   "Save the current position of point to the current page."
 489   (when elpher-current-page
 490     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 491
 492 (defun elpher-restore-pos ()
 493   "Restore the position of point to that cached in the current page."
 494   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 495     (if pos
 496         (goto-char pos)
 497       (goto-char (point-min)))))
 498
 499
 500 ;;; Buffer preparation
 501 ;;
 502
 503 (defvar elpher-buffer-name "*elpher*"
 504   "The default name of the Elpher buffer.")
 505
 506 (defun elpher-update-header ()
 507   "If `elpher-use-header' is true, display current page info in window header."
 508   (if elpher-use-header
 509       (let* ((display-string (elpher-page-display-string elpher-current-page))
 510              (address (elpher-page-address elpher-current-page))
 511              (tls-string (if (and (not (elpher-address-special-p address))
 512                                   (member (elpher-address-protocol address)
 513                                           '("gophers" "gemini")))
 514                              " [TLS encryption]"
 515                            ""))
 516              (header (concat display-string
 517                              (propertize tls-string 'face 'bold))))
 518         (setq header-line-format header))))
 519
 520 (defmacro elpher-with-clean-buffer (&rest args)
 521   "Evaluate ARGS with a clean *elpher* buffer as current."
 522   `(with-current-buffer elpher-buffer-name
 523      (unless (eq major-mode 'elpher-mode)
 524        ;; avoid resetting buffer-local variables
 525        (elpher-mode))
 526      (let ((inhibit-read-only t))
 527        (setq-local network-security-level
 528                    (default-value 'network-security-level))
 529        (erase-buffer)
 530        (elpher-update-header)
 531        ,@args)))
 532
 533 (defun elpher-buffer-message (string &optional line)
 534   "Replace first line in elpher buffer with STRING.
 535 If LINE is non-nil, replace that line instead."
 536   (with-current-buffer elpher-buffer-name
 537     (let ((inhibit-read-only t))
 538       (goto-char (point-min))
 539       (if line
 540           (forward-line line))
 541       (let ((data (match-data)))
 542         (unwind-protect
 543             (progn
 544               (re-search-forward "^.*$")
 545               (replace-match string))
 546           (set-match-data data))))))
 547
 548
 549 ;;; Text Processing
 550 ;;
 551
 552 (defvar elpher-user-coding-system nil
 553   "User-specified coding system to use for decoding text responses.")
 554
 555 (defun elpher-decode (string)
 556   "Decode STRING using autodetected or user-specified coding system."
 557   (decode-coding-string string
 558                         (if elpher-user-coding-system
 559                             elpher-user-coding-system
 560                           (detect-coding-string string t))))
 561
 562 (defun elpher-preprocess-text-response (string)
 563   "Preprocess text selector response contained in STRING.
 564 This involes decoding the character representation, and clearing
 565 away CRs and any terminating period."
 566   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 567                                            (replace-regexp-in-string "\r" "" string))))
 568
 569
 570 ;;; Network error reporting
 571 ;;
 572
 573 (defun elpher-network-error (address error)
 574   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 575 ERROR can be either an error object or a string."
 576   (elpher-with-clean-buffer
 577    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 578            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 579            (if (stringp error) error (error-message-string error)) "\n"
 580            (propertize "\n----------------\n\n" 'face 'error)
 581            "Press 'u' to return to the previous page.")))
 582
 583
 584 ;;; General network communication
 585 ;;
 586
 587 (defvar elpher-network-timer nil
 588   "Timer used for network connections.")
 589
 590 (defvar elpher-use-tls nil
 591   "If non-nil, use TLS to communicate with gopher servers.")
 592
 593 (defvar elpher-client-certificate nil
 594   "If non-nil, contains client certificate details to use for TLS connections.")
 595
 596 (defun elpher-process-cleanup ()
 597   "Immediately shut down any extant elpher process and timers."
 598   (let ((p (get-process "elpher-process")))
 599     (if p (delete-process p)))
 600   (if (timerp elpher-network-timer)
 601       (cancel-timer elpher-network-timer)))
 602
 603 (defun elpher-get-host-response (address default-port query-string response-processor
 604                                          &optional use-tls force-ipv4)
 605   "Generic function for retrieving data from ADDRESS.
 606
 607 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 608 QUERY-STRING is a string sent to the host specified by ADDRESS to
 609 illicet a response.  This response is passed as an argument to the
 610 function RESPONSE-PROCESSOR.
 611
 612 If non-nil, USE-TLS specifies that the connection is to be made over
 613 TLS.  If set to gemini, the certificate verification will be disabled
 614 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 615
 616 If non-nil, FORCE-IPV4 causes the network connection to be made over
 617 ipv4 only.  (The default behaviour when this is not set depends on
 618 the host operating system and the local network capabilities."
 619   (if (and use-tls (not (gnutls-available-p)))
 620       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 621     (unless (< (elpher-address-port address) 65536)
 622       (error "Cannot establish network connection: port number > 65536"))
 623     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 624       (setq-local network-security-level 'low))
 625     (condition-case nil
 626         (let* ((kill-buffer-query-functions nil)
 627                (port (elpher-address-port address))
 628                (host (elpher-address-host address))
 629                (response-string-parts nil)
 630                (bytes-received 0)
 631                (hkbytes-received 0)
 632                (proc (make-network-process :name "elpher-process"
 633                                            :host host
 634                                            :family (and force-ipv4 'ipv4)
 635                                            :service (if (> port 0) port default-port)
 636                                            :buffer nil
 637                                            :coding 'binary
 638                                            :noquery t
 639                                            :nowait t
 640                                            :tls-parameters
 641                                            (and use-tls
 642                                                 (cons 'gnutls-x509pki
 643                                                       (gnutls-boot-parameters
 644                                                        :type 'gnutls-x509pki
 645                                                        :hostname host
 646                                                        :keylist
 647                                                        (elpher-get-current-keylist address))))))
 648                (timer (run-at-time elpher-connection-timeout nil
 649                                    (lambda ()
 650                                      (elpher-process-cleanup)
 651                                      (cond
 652                                         ; Try again with IPv4
 653                                       ((not force-ipv4)
 654                                        (message "Connection timed out.  Retrying with IPv4.")
 655                                        (elpher-get-host-response address default-port
 656                                                                  query-string
 657                                                                  response-processor
 658                                                                  use-tls t))
 659                                       ((and use-tls
 660                                             (not (eq use-tls 'gemini))
 661                                             (or elpher-auto-disengage-TLS
 662                                                 (y-or-n-p
 663                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 664                                        (setq elpher-use-tls nil)
 665                                        (elpher-get-host-response address default-port
 666                                                                  query-string
 667                                                                  response-processor
 668                                                                  nil force-ipv4))
 669                                       (t
 670                                        (elpher-network-error address "Connection time-out.")))))))
 671           (setq elpher-network-timer timer)
 672           (elpher-buffer-message (concat "Connecting to " host "..."
 673                                          " (press 'u' to abort)"))
 674           (set-process-filter proc
 675                               (lambda (_proc string)
 676                                 (when timer
 677                                   (cancel-timer timer)
 678                                   (setq timer nil))
 679                                 (setq bytes-received (+ bytes-received (length string)))
 680                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 681                                   (when (> new-hkbytes-received hkbytes-received)
 682                                     (setq hkbytes-received new-hkbytes-received)
 683                                     (elpher-buffer-message
 684                                         (concat "("
 685                                                 (number-to-string (/ hkbytes-received 10.0))
 686                                                 " MB read)")
 687                                         1)))
 688                                 (setq response-string-parts
 689                                       (cons string response-string-parts))))
 690           (set-process-sentinel proc
 691                                 (lambda (proc event)
 692                                   (when timer
 693                                     (cancel-timer timer))
 694                                   (condition-case the-error
 695                                       (cond
 696                                        ((string-prefix-p "open" event)    ; request URL
 697                                         (elpher-buffer-message
 698                                          (concat "Connected to " host ". Receiving data..."
 699                                                  " (press 'u' to abort)"))
 700                                         (let ((inhibit-eol-conversion t))
 701                                           (process-send-string proc query-string)))
 702                                        ((string-prefix-p "deleted" event)) ; do nothing
 703                                        ((and (not response-string-parts)
 704                                              (not (or elpher-ipv4-always force-ipv4)))
 705                                         ; Try again with IPv4
 706                                         (message "Connection failed. Retrying with IPv4.")
 707                                         (elpher-get-host-response address default-port
 708                                                                   query-string
 709                                                                   response-processor
 710                                                                   use-tls t))
 711                                        (response-string-parts
 712                                         (elpher-with-clean-buffer
 713                                          (insert "Data received.  Rendering..."))
 714                                         (funcall response-processor
 715                                                  (apply #'concat (reverse response-string-parts)))
 716                                         (elpher-restore-pos))
 717                                        (t
 718                                         (error "No response from server")))
 719                                     (error
 720                                      (elpher-network-error address the-error))))))
 721       (error
 722        (error "Error initiating connection to server")))))
 723
 724
 725 ;;; Client-side TLS Certificate Management
 726 ;;
 727
 728 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 729   "Generate a key and a self-signed client TLS certificate using openssl.
 730
 731 The Common Name field of the certificate is set to COMMON-NAME.  The
 732 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 733 the key and certificate files to write.
 734
 735 If TEMPORARY is non-nil, the certificate will be given an exporation
 736 period of one day, and the key and certificate files will be deleted
 737 when the certificate is no longer needed for the current session.
 738
 739 Otherwise, the certificate will be given a 100 year expiration period
 740 and the files will not be deleted.
 741
 742 The function returns a list containing the current host name, the
 743 temporary flag, and the key and cert file names in the form required
 744 by `gnutls-boot-parameters`."
 745   (let ((exp-key-file (expand-file-name key-file))
 746         (exp-cert-file (expand-file-name cert-file)))
 747     (condition-case nil
 748         (progn
 749           (call-process elpher-openssl-command nil nil nil
 750                         "req" "-x509" "-newkey" "rsa:2048"
 751                         "-days" (if temporary "1" "36500")
 752                         "-nodes"
 753                         "-subj" (concat "/CN=" common-name)
 754                         "-keyout" exp-key-file
 755                         "-out" exp-cert-file)
 756           (list (elpher-address-host (elpher-page-address elpher-current-page))
 757                 temporary exp-key-file exp-cert-file))
 758       (error
 759        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 760        (error "Program 'openssl', required for certificate generation, not found")))))
 761
 762 (defun elpher-generate-throwaway-certificate ()
 763   "Generate and return details of a throwaway certificate.
 764 The key and certificate files will be deleted when they are no
 765 longer needed for this session."
 766   (let* ((file-base (make-temp-name "elpher"))
 767          (key-file (concat temporary-file-directory file-base ".key"))
 768          (cert-file (concat temporary-file-directory file-base ".crt")))
 769     (elpher-generate-certificate file-base key-file cert-file t)))
 770
 771 (defun elpher-generate-persistent-certificate (file-base common-name)
 772   "Generate and return details of a persistent certificate.
 773 The argument FILE-BASE is used as the base for the key and certificate
 774 files, while COMMON-NAME specifies the common name field of the
 775 certificate.
 776
 777 The key and certificate files are written to in `elpher-certificate-directory'."
 778   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 779          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 780     (elpher-generate-certificate common-name key-file cert-file)))
 781
 782 (defun elpher-get-existing-certificate (file-base)
 783   "Return a certificate object corresponding to an existing certificate.
 784 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 785 the directory `elpher-certificate-directory'."
 786   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 787          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 788     (list (elpher-address-host (elpher-page-address elpher-current-page))
 789           nil
 790           (expand-file-name key-file)
 791           (expand-file-name cert-file))))
 792
 793 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
 794   "Install a key+certificate file pair in `elpher-certificate-directory'.
 795 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
 796 certificate files to install.  The argument FILE-BASE is used as the
 797 base for the installed key and certificate files."
 798   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 799          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 800     (if (or (file-exists-p key-file)
 801             (file-exists-p cert-file))
 802         (error "A certificate with base name %s is already installed" file-base))
 803     (copy-file key-file-src key-file)
 804     (copy-file cert-file-src cert-file)
 805     (list (elpher-address-host (elpher-page-address elpher-current-page))
 806           nil
 807           (expand-file-name key-file)
 808           (expand-file-name cert-file))))
 809
 810 (defun elpher-list-existing-certificates ()
 811   "Return a list of the persistent certificates in `elpher-certificate-directory'."
 812   (unless (file-directory-p elpher-certificate-directory)
 813     (make-directory elpher-certificate-directory))
 814   (mapcar
 815    (lambda (file)
 816      (file-name-sans-extension file))
 817    (directory-files elpher-certificate-directory nil "\.key$")))
 818
 819 (defun elpher-forget-current-certificate ()
 820   "Causes any current certificate to be forgotten.)
 821 In the case of throwaway certificates, the key and certificate files
 822 are also deleted."
 823   (interactive)
 824   (when elpher-client-certificate
 825     (unless (and (called-interactively-p 'any)
 826                  (not (y-or-n-p (concat "Really forget client certificate? "
 827                                         "(Throwaway certificates will be deleted.)"))))
 828       (when (cadr elpher-client-certificate)
 829         (delete-file (elt elpher-client-certificate 2))
 830         (delete-file (elt elpher-client-certificate 3)))
 831       (setq elpher-client-certificate nil)
 832       (if (called-interactively-p 'any)
 833           (message "Client certificate forgotten.")))))
 834
 835 (defun elpher-get-current-keylist (address)
 836   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
 837
 838 This is obtained from the client certificate described by
 839 `elpher-current-certificate', if one is available and the host for
 840 that certificate matches the host in ADDRESS.
 841
 842 If `elpher-current-certificate' is non-nil, and its host name doesn't
 843 match that of ADDRESS, the certificate is forgotten."
 844   (if elpher-client-certificate
 845       (if (string= (car elpher-client-certificate)
 846                    (elpher-address-host address))
 847           (list (cddr elpher-client-certificate))
 848         (elpher-forget-current-certificate)
 849         (message "Disabling client certificate for new host")
 850         nil)
 851     nil))
 852
 853
 854 ;;; Gopher selector retrieval
 855 ;;
 856
 857 (defun elpher-get-gopher-response (address renderer)
 858   "Get response string from gopher server at ADDRESS and render using RENDERER."
 859   (elpher-get-host-response address 70
 860                             (concat (elpher-gopher-address-selector address) "\r\n")
 861                             renderer
 862                             (or (string= (elpher-address-protocol address) "gophers")
 863                                 elpher-use-tls)))
 864
 865 (defun elpher-get-gopher-page (renderer)
 866   "Getter function for gopher pages.
 867 The RENDERER procedure is used to display the contents of the page
 868 once they are retrieved from the gopher server."
 869   (let* ((address (elpher-page-address elpher-current-page))
 870          (content (elpher-get-cached-content address)))
 871     (if (and content (funcall renderer nil))
 872         (elpher-with-clean-buffer
 873          (insert content)
 874          (elpher-restore-pos))
 875       (elpher-with-clean-buffer
 876        (insert "LOADING... (use 'u' to cancel)\n"))
 877       (condition-case the-error
 878           (elpher-get-gopher-response address renderer)
 879         (error
 880          (elpher-network-error address the-error))))))
 881
 882 ;; Index rendering
 883
 884 (defun elpher-insert-index (string)
 885   "Insert the index corresponding to STRING into the current buffer."
 886   ;; Should be able to split directly on CRLF, but some non-conformant
 887   ;; LF-only servers sadly exist, hence the following.
 888   (let ((str-processed (elpher-preprocess-text-response string)))
 889     (dolist (line (split-string str-processed "\n"))
 890       (ignore-errors
 891         (unless (= (length line) 0)
 892           (let* ((type (elt line 0))
 893                  (fields (split-string (substring line 1) "\t"))
 894                  (display-string (elt fields 0))
 895                  (selector (elt fields 1))
 896                  (host (elt fields 2))
 897                  (port (if (elt fields 3)
 898                            (string-to-number (elt fields 3))
 899                          nil))
 900                  (address (elpher-make-gopher-address type selector host port)))
 901             (elpher-insert-index-record display-string address)))))))
 902
 903 (defun elpher-insert-margin (&optional type-name)
 904   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 905   (if type-name
 906       (progn
 907         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 908                         (concat
 909                          (propertize "[" 'face 'elpher-margin-brackets)
 910                          (propertize type-name 'face 'elpher-margin-key)
 911                          (propertize "]" 'face 'elpher-margin-brackets))))
 912         (insert " "))
 913     (insert (make-string elpher-margin-width ?\s))))
 914
 915 (defun elpher--page-button-help (_window buffer pos)
 916   "Function called by Emacs to generate mouse-over text.
 917 The arguments specify the BUFFER and the POS within the buffer of the item
 918 for which help is required.  The function returns the help to be
 919 displayed.  The _WINDOW argument is currently unused."
 920   (with-current-buffer buffer
 921     (let ((button (button-at pos)))
 922       (when button
 923         (let* ((page (button-get button 'elpher-page))
 924                (address (elpher-page-address page)))
 925           (format "mouse-1, RET: open '%s'" (if (elpher-address-special-p address)
 926                                                 address
 927                                               (elpher-address-to-url address))))))))
 928
 929 (defun elpher-insert-index-record (display-string &optional address)
 930   "Function to insert an index record into the current buffer.
 931 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 932 If ADDRESS is not supplied or nil the record is rendered as an
 933 'information' line."
 934   (let* ((type (if address (elpher-address-type address) nil))
 935          (type-map-entry (cdr (assoc type elpher-type-map))))
 936     (if type-map-entry
 937         (let* ((margin-code (elt type-map-entry 2))
 938                (face (elt type-map-entry 3))
 939                (filtered-display-string (ansi-color-filter-apply display-string))
 940                (page (elpher-make-page filtered-display-string address)))
 941           (elpher-insert-margin margin-code)
 942           (insert-text-button filtered-display-string
 943                               'face face
 944                               'elpher-page page
 945                               'action #'elpher-click-link
 946                               'follow-link t
 947                               'help-echo #'elpher--page-button-help))
 948       (pcase type
 949         ('nil ;; Information
 950          (elpher-insert-margin)
 951          (let ((propertized-display-string
 952                 (propertize display-string 'face 'elpher-info)))
 953            (insert (elpher-process-text-for-display propertized-display-string))))
 954         (`(gopher ,selector-type) ;; Unknown
 955          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 956          (insert (propertize display-string
 957                              'face 'elpher-unknown)))))
 958     (insert "\n")))
 959
 960 (defun elpher-click-link (button)
 961   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 962   (let ((page (button-get button 'elpher-page)))
 963     (elpher-visit-page page)))
 964
 965 (defun elpher-render-index (data &optional _mime-type-string)
 966   "Render DATA as an index.  MIME-TYPE-STRING is unused."
 967   (elpher-with-clean-buffer
 968    (if (not data)
 969        t
 970      (elpher-insert-index data)
 971      (elpher-cache-content (elpher-page-address elpher-current-page)
 972                            (buffer-string)))))
 973
 974 ;; Text rendering
 975
 976 (defconst elpher-url-regex
 977   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]*[a-zA-Z0-9\-]\\|\[[a-zA-Z0-9:]+\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z\-_~?/@|:.%#=&]*[0-9a-zA-Z\-_~?/@|#]\\)?\\)?"
 978   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 979
 980 (defun elpher-buttonify-urls (string)
 981   "Turn substrings which look like urls in STRING into clickable buttons."
 982   (with-temp-buffer
 983     (insert string)
 984     (goto-char (point-min))
 985     (while (re-search-forward elpher-url-regex nil t)
 986       (let ((page (elpher-make-page (substring-no-properties (match-string 0))
 987                                     (elpher-address-from-url (match-string 0)))))
 988           (make-text-button (match-beginning 0)
 989                             (match-end 0)
 990                             'elpher-page  page
 991                             'action #'elpher-click-link
 992                             'follow-link t
 993                             'help-echo #'elpher--page-button-help
 994                             'face 'button)))
 995     (buffer-string)))
 996
 997 (defconst elpher-ansi-regex "\x1b\\[[^m]*m"
 998   "Wildly incomplete regexp used to strip out some troublesome ANSI escape sequences.")
 999
1000 (defun elpher-process-text-for-display (string)
1001   "Perform any desired processing of STRING prior to display as text.
1002 Currently includes buttonifying URLs and processing ANSI escape codes."
1003   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
1004                              (ansi-color-filter-apply string)
1005                            (ansi-color-apply string))))
1006
1007 (defun elpher-render-text (data &optional _mime-type-string)
1008   "Render DATA as text.  MIME-TYPE-STRING is unused."
1009   (elpher-with-clean-buffer
1010    (if (not data)
1011        t
1012      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1013      (elpher-cache-content
1014       (elpher-page-address elpher-current-page)
1015       (buffer-string)))))
1016
1017 ;; Image retrieval
1018
1019 (defun elpher-render-image (data &optional _mime-type-string)
1020   "Display DATA as image.  MIME-TYPE-STRING is unused."
1021   (if (not data)
1022       nil
1023     (if (display-images-p)
1024         (progn
1025           (let ((image (create-image
1026                         data
1027                         nil t)))
1028             (elpher-with-clean-buffer
1029              (insert-image image)
1030              (elpher-restore-pos))))
1031       (elpher-render-download data))))
1032
1033 ;; Search retrieval and rendering
1034
1035 (defun elpher-get-gopher-query-page (renderer)
1036   "Getter for gopher addresses requiring input.
1037 The response is rendered using the rendering function RENDERER."
1038    (let* ((address (elpher-page-address elpher-current-page))
1039           (content (elpher-get-cached-content address))
1040           (aborted t))
1041     (if (and content (funcall renderer nil))
1042         (elpher-with-clean-buffer
1043          (insert content)
1044          (elpher-restore-pos)
1045          (message "Displaying cached search results.  Reload to perform a new search."))
1046       (unwind-protect
1047           (let* ((query-string (read-string "Query: "))
1048                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1049                  (search-address (elpher-make-gopher-address ?1
1050                                                              query-selector
1051                                                              (elpher-address-host address)
1052                                                              (elpher-address-port address)
1053                                                              (equal (elpher-address-type address) "gophers"))))
1054             (setq aborted nil)
1055
1056             (elpher-with-clean-buffer
1057              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1058             (elpher-get-gopher-response search-address renderer))
1059         (if aborted
1060             (elpher-visit-previous-page))))))
1061
1062 ;; Raw server response rendering
1063
1064 (defun elpher-render-raw (data &optional mime-type-string)
1065   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1066   (if (not data)
1067       nil
1068     (elpher-with-clean-buffer
1069      (when mime-type-string
1070        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1071      (insert data)
1072      (goto-char (point-min)))
1073     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1074
1075 ;; File save "rendering"
1076
1077 (defun elpher-render-download (data &optional _mime-type-string)
1078   "Save DATA to file.  MIME-TYPE-STRING is unused."
1079   (if (not data)
1080       nil
1081     (let* ((address (elpher-page-address elpher-current-page))
1082            (selector (if (elpher-address-gopher-p address)
1083                          (elpher-gopher-address-selector address)
1084                        (elpher-address-filename address))))
1085       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1086       (let* ((filename-proposal (file-name-nondirectory selector))
1087              (filename (read-file-name "Download complete. Save file as: "
1088                                        nil nil nil
1089                                        (if (> (length filename-proposal) 0)
1090                                            filename-proposal
1091                                          "download.file"))))
1092         (let ((coding-system-for-write 'binary))
1093           (with-temp-file filename
1094             (insert data)))
1095         (message (format "Saved to file %s." filename))))))
1096
1097 ;; HTML rendering
1098
1099 (defun elpher-render-html (data &optional _mime-type-string)
1100   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1101   (elpher-with-clean-buffer
1102    (if (not data)
1103        t
1104      (let ((dom (with-temp-buffer
1105                   (insert data)
1106                   (libxml-parse-html-region (point-min) (point-max)))))
1107        (shr-insert-document dom)))))
1108
1109 ;; Gemini page retrieval
1110
1111 (defvar elpher-gemini-redirect-chain)
1112
1113 (defun elpher-get-gemini-response (address renderer)
1114   "Get response string from gemini server at ADDRESS and render using RENDERER."
1115   (elpher-get-host-response address 1965
1116                             (concat (elpher-address-to-url address) "\r\n")
1117                             (lambda (response-string)
1118                               (elpher-process-gemini-response response-string renderer))
1119                             'gemini))
1120
1121 (defun elpher-parse-gemini-response (response)
1122   "Parse the RESPONSE string and return a list of components.
1123 The list is of the form (code meta body).  A response of nil implies
1124 that the response was malformed."
1125   (let ((header-end-idx (string-match "\r\n" response)))
1126     (if header-end-idx
1127         (let ((header (string-trim (substring response 0 header-end-idx)))
1128               (body (substring response (+ header-end-idx 2))))
1129           (if (>= (length header) 2)
1130               (let ((code (substring header 0 2))
1131                     (meta (string-trim (substring header 2))))
1132                 (list code meta body))
1133             (error "Malformed response: No response status found in header %s" header)))
1134       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1135
1136 (defun elpher-process-gemini-response (response-string renderer)
1137   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1138   (let ((response-components (elpher-parse-gemini-response response-string)))
1139     (let ((response-code (elt response-components 0))
1140           (response-meta (elt response-components 1))
1141           (response-body (elt response-components 2)))
1142       (pcase (elt response-code 0)
1143         (?1 ; Input required
1144          (elpher-with-clean-buffer
1145           (insert "Gemini server is requesting input."))
1146          (let* ((query-string
1147                  (if (eq (elt response-code 1) ?1)
1148                      (read-passwd (concat response-meta ": "))
1149                    (read-string (concat response-meta ": "))))
1150                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1151                 (old-fname (url-filename query-address)))
1152            (setf (url-filename query-address)
1153                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1154            (elpher-get-gemini-response query-address renderer)))
1155         (?2 ; Normal response
1156          (funcall renderer response-body response-meta))
1157         (?3 ; Redirect
1158          (message "Following redirect to %s" response-meta)
1159          (if (>= (length elpher-gemini-redirect-chain) 5)
1160              (error "More than 5 consecutive redirects followed"))
1161          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1162            (if (member redirect-address elpher-gemini-redirect-chain)
1163                (error "Redirect loop detected"))
1164            (if (not (string= (elpher-address-protocol redirect-address)
1165                              "gemini"))
1166                (error "Server tried to automatically redirect to non-gemini URL: %s"
1167                       response-meta))
1168            (elpher-page-set-address elpher-current-page redirect-address)
1169            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1170            (elpher-get-gemini-response redirect-address renderer)))
1171         (?4 ; Temporary failure
1172          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1173                 response-code response-meta))
1174         (?5 ; Permanent failure
1175          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1176                 response-code response-meta))
1177         (?6 ; Client certificate required
1178          (elpher-with-clean-buffer
1179           (if elpher-client-certificate
1180               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1181             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1182           (auto-fill-mode 1)
1183           (elpher-gemini-insert-text response-meta))
1184          (let ((chosen-certificate (elpher-choose-client-certificate)))
1185            (unless chosen-certificate
1186              (error "Gemini server requires a client certificate and none was provided"))
1187            (setq elpher-client-certificate chosen-certificate))
1188          (elpher-with-clean-buffer)
1189          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1190         (_other
1191          (error "Gemini server response unknown: %s %s"
1192                 response-code response-meta))))))
1193
1194 (defun elpher-choose-client-certificate ()
1195   "Prompt for a client certificate to use to establish a TLS connection."
1196   (let* ((read-answer-short t))
1197     (pcase (read-answer "What do you want to do? "
1198                         '(("throwaway" ?t
1199                            "generate and use throw-away certificate")
1200                           ("persistent" ?p
1201                            "generate new or use existing persistent certificate")
1202                           ("abort" ?a
1203                            "stop immediately")))
1204       ("throwaway"
1205        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1206       ("persistent"
1207        (let* ((existing-certificates (elpher-list-existing-certificates))
1208               (file-base (completing-read
1209                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1210                           existing-certificates)))
1211          (if (string-empty-p (string-trim file-base))
1212              nil
1213            (if (member file-base existing-certificates)
1214                (setq elpher-client-certificate
1215                      (elpher-get-existing-certificate file-base))
1216              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1217                                  '(("new" ?n
1218                                     "generate new certificate")
1219                                    ("install" ?i
1220                                     "install existing certificate")
1221                                    ("abort" ?a
1222                                     "stop immediately")))
1223                ("new"
1224                 (let ((common-name (read-string "Common Name field for new certificate: "
1225                                                 file-base)))
1226                   (message "New key and self-signed certificate written to %s"
1227                            elpher-certificate-directory)
1228                   (elpher-generate-persistent-certificate file-base common-name)))
1229                ("install"
1230                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1231                        (key-file (read-file-name "Key file: " nil nil t)))
1232                   (message "Key and certificate installed in %s for future use"
1233                            elpher-certificate-directory)
1234                   (elpher-install-and-use-existing-certificate key-file
1235                                                                cert-file
1236                                                                file-base)))
1237                ("abort" nil))))))
1238       ("abort" nil))))
1239
1240 (defun elpher-get-gemini-page (renderer)
1241   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1242   (let* ((address (elpher-page-address elpher-current-page))
1243          (content (elpher-get-cached-content address)))
1244     (condition-case the-error
1245         (if (and content (funcall renderer nil))
1246             (elpher-with-clean-buffer
1247               (insert content)
1248               (elpher-restore-pos))
1249           (elpher-with-clean-buffer
1250            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1251           (setq elpher-gemini-redirect-chain nil)
1252           (elpher-get-gemini-response address renderer))
1253       (error
1254        (elpher-network-error address the-error)))))
1255
1256 (defun elpher-render-gemini (body &optional mime-type-string)
1257   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1258   (if (not body)
1259       t
1260     (let* ((mime-type-string* (if (or (not mime-type-string)
1261                                       (string-empty-p mime-type-string))
1262                                   "text/gemini; charset=utf-8"
1263                                 mime-type-string))
1264            (mime-type-split (split-string mime-type-string* ";" t))
1265            (mime-type (string-trim (car mime-type-split)))
1266            (parameters (mapcar (lambda (s)
1267                                  (let ((key-val (split-string s "=")))
1268                                    (list (downcase (string-trim (car key-val)))
1269                                          (downcase (string-trim (cadr key-val))))))
1270                                (cdr mime-type-split))))
1271       (when (string-prefix-p "text/" mime-type)
1272         (setq body (decode-coding-string
1273                     body
1274                     (if (assoc "charset" parameters)
1275                         (intern (cadr (assoc "charset" parameters)))
1276                       'utf-8)))
1277         (setq body (replace-regexp-in-string "\r" "" body)))
1278       (pcase mime-type
1279         ((or "text/gemini" "")
1280          (elpher-render-gemini-map body parameters))
1281         ("text/html"
1282          (elpher-render-html body))
1283         ((pred (string-prefix-p "text/"))
1284          (elpher-render-gemini-plain-text body parameters))
1285         ((pred (string-prefix-p "image/"))
1286          (elpher-render-image body))
1287         (_other
1288          (elpher-render-download body))))))
1289
1290 (defun elpher-gemini-get-link-url (link-line)
1291   "Extract the url portion of LINK-LINE, a gemini map file link line.
1292 Returns nil in the event that the contents of the line following the
1293 => prefix are empty."
1294   (let ((l (split-string (substring link-line 2))))
1295     (if l
1296         (string-trim (elt l 0))
1297       nil)))
1298
1299 (defun elpher-gemini-get-link-display-string (link-line)
1300   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1301 Returns the url portion in the event that the display-string portion is empty."
1302   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1303          (idx (string-match "[ \t]" rest)))
1304     (string-trim (if idx
1305                      (substring rest (+ idx 1))
1306                    rest))))
1307
1308 (defun elpher-collapse-dot-sequences (filename)
1309   "Collapse dot sequences in FILENAME.
1310 For instance, the filename /a/b/../c/./d will reduce to /a/c/d"
1311   (let* ((path (split-string filename "/"))
1312          (path-reversed-normalized
1313           (seq-reduce (lambda (a b)
1314                         (cond ((and a (equal b "..") (cdr a)))
1315                               ((and (not a) (equal b "..")) a) ;leading .. are dropped
1316                               ((equal b ".") a)
1317                               (t (cons b a))))
1318                       path nil)))
1319     (string-join (reverse path-reversed-normalized) "/")))
1320
1321 (defun elpher-address-from-gemini-url (url)
1322   "Extract address from URL with defaults as per gemini map files.
1323 While there's obviously some redundancy here between this function and
1324 `elpher-address-from-url', gemini map file URLs require enough special
1325 treatment that a separate function is warranted."
1326   (let ((address (url-generic-parse-url url))
1327         (current-address (elpher-page-address elpher-current-page)))
1328     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1329       (setf (url-fullness address) t)
1330       (if (url-host address) ;if there is an explicit host, filenames are absolute
1331           (if (string-empty-p (url-filename address))
1332               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1333         (setf (url-host address) (url-host current-address))
1334         (setf (url-port address) (url-port current-address))
1335         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1336           (setf (url-filename address)
1337                 (concat (file-name-directory (url-filename current-address))
1338                         (url-filename address)))))
1339       (unless (url-type address)
1340         (setf (url-type address) "gemini"))
1341       (when (equal (url-type address) "gemini")
1342         (setf (url-filename address)
1343               (elpher-collapse-dot-sequences (url-filename address)))))
1344     (elpher-remove-redundant-ports address)))
1345
1346 (defun elpher-gemini-insert-link (link-line)
1347   "Insert link described by LINK-LINE into a text/gemini document."
1348   (let* ((url (elpher-gemini-get-link-url link-line))
1349          (display-string (elpher-gemini-get-link-display-string link-line))
1350          (address (elpher-address-from-gemini-url url))
1351          (type (if address (elpher-address-type address) nil))
1352          (type-map-entry (cdr (assoc type elpher-type-map))))
1353     (when display-string
1354       (insert elpher-gemini-link-string)
1355       (if type-map-entry
1356           (let* ((face (elt type-map-entry 3))
1357                  (filtered-display-string (ansi-color-filter-apply display-string))
1358                  (page (elpher-make-page filtered-display-string address)))
1359             (insert-text-button filtered-display-string
1360                                 'face face
1361                                 'elpher-page page
1362                                 'action #'elpher-click-link
1363                                 'follow-link t
1364                                 'help-echo #'elpher--page-button-help))
1365         (insert (propertize display-string 'face 'elpher-unknown)))
1366       (insert "\n"))))
1367
1368 (defun elpher-gemini-insert-header (header-line)
1369   "Insert header described by HEADER-LINE into a text/gemini document.
1370 The gemini map file line describing the header is given
1371 by HEADER-LINE."
1372   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1373     (let* ((level (length (match-string 1 header-line)))
1374            (header (substring header-line (match-end 0)))
1375            (face (pcase level
1376                    (1 'elpher-gemini-heading1)
1377                    (2 'elpher-gemini-heading2)
1378                    (3 'elpher-gemini-heading3)
1379                    (_ 'default)))
1380            (fill-column (/ (* fill-column
1381                               (font-get (font-spec :name (face-font 'default)) :size))
1382                            (font-get (font-spec :name (face-font face)) :size))))
1383       (unless (display-graphic-p)
1384         (insert (make-string level ?#) " "))
1385       (insert (propertize header 'face face))
1386       (newline))))
1387
1388 (defun elpher-gemini-insert-text (text-line)
1389   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1390 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1391 width defined by elpher-gemini-max-fill-width."
1392   (string-match "\\(^[ \t]*\\)\\(\*[ \t]+\\|>[ \t]*\\)?" text-line)
1393   (let* ((processed-text-line (if (match-string 2 text-line)
1394                                   (concat
1395                                    (replace-regexp-in-string "\*"
1396                                                              elpher-gemini-bullet-string
1397                                                              (match-string 0 text-line))
1398                                    (substring text-line (match-end 0)))
1399                                 text-line))
1400          (adaptive-fill-mode nil)
1401          (fill-prefix (if (match-string 2 text-line)
1402                           (replace-regexp-in-string "[>\*]" " " (match-string 0 text-line))
1403                         nil)))
1404     (insert (elpher-process-text-for-display processed-text-line))
1405     (newline)))
1406
1407 (defun elpher-render-gemini-map (data _parameters)
1408   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1409   (elpher-with-clean-buffer
1410    (let ((preformatted nil))
1411      (auto-fill-mode 1)
1412      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1413      (dolist (line (split-string data "\n"))
1414        (cond
1415         ((string-prefix-p "```" line) (setq preformatted (not preformatted)))
1416         (preformatted (insert (elpher-process-text-for-display
1417                                (propertize line 'face 'elpher-gemini-preformatted))
1418                               "\n"))
1419         ((string-prefix-p "=>" line) (elpher-gemini-insert-link line))
1420         ((string-prefix-p "#" line) (elpher-gemini-insert-header line))
1421         (t (elpher-gemini-insert-text line)))))
1422    (elpher-cache-content
1423     (elpher-page-address elpher-current-page)
1424     (buffer-string))))
1425
1426 (defun elpher-render-gemini-plain-text (data _parameters)
1427   "Render DATA as plain text file.  PARAMETERS is currently unused."
1428   (elpher-with-clean-buffer
1429    (insert (elpher-process-text-for-display data))
1430    (elpher-cache-content
1431     (elpher-page-address elpher-current-page)
1432     (buffer-string))))
1433
1434
1435 ;; Finger page connection
1436
1437 (defun elpher-get-finger-page (renderer)
1438   "Opens a finger connection to the current page address.
1439 The result is rendered using RENDERER."
1440   (let* ((address (elpher-page-address elpher-current-page))
1441          (content (elpher-get-cached-content address)))
1442     (if (and content (funcall renderer nil))
1443         (elpher-with-clean-buffer
1444          (insert content)
1445          (elpher-restore-pos))
1446       (elpher-with-clean-buffer
1447        (insert "LOADING... (use 'u' to cancel)\n"))
1448       (condition-case the-error
1449           (let* ((kill-buffer-query-functions nil)
1450                  (user (let ((filename (elpher-address-filename address)))
1451                          (if (> (length filename) 1)
1452                              (substring filename 1)
1453                            (elpher-address-user address)))))
1454             (elpher-get-host-response address 79
1455                                       (concat user "\r\n")
1456                                       renderer))
1457         (error
1458          (elpher-network-error address the-error))))))
1459
1460
1461 ;; Telnet page connection
1462
1463 (defun elpher-get-telnet-page (renderer)
1464   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1465   (when renderer
1466     (elpher-visit-previous-page)
1467     (error "Command not supported for telnet URLs"))
1468   (let* ((address (elpher-page-address elpher-current-page))
1469          (host (elpher-address-host address))
1470          (port (elpher-address-port address)))
1471     (elpher-visit-previous-page)
1472     (if (> port 0)
1473         (telnet host port)
1474       (telnet host))))
1475
1476
1477 ;; Other URL page opening
1478
1479 (defun elpher-get-other-url-page (renderer)
1480   "Getter which attempts to open the URL specified by the current page (RENDERER must be nil)."
1481   (when renderer
1482     (elpher-visit-previous-page)
1483     (error "Command not supported for general URLs"))
1484   (let* ((address (elpher-page-address elpher-current-page))
1485          (url (elpher-address-to-url address)))
1486     (progn
1487       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1488       (message "Opening URL...")
1489       (if elpher-open-urls-with-eww
1490           (browse-web url)
1491         (browse-url url)))))
1492
1493
1494 ;; Start page page retrieval
1495
1496 (defun elpher-get-start-page (renderer)
1497   "Getter which displays the start page (RENDERER must be nil)."
1498   (when renderer
1499     (elpher-visit-previous-page)
1500     (error "Command not supported for start page"))
1501   (elpher-with-clean-buffer
1502    (insert "     --------------------------------------------\n"
1503            "           Elpher Gopher and Gemini Client       \n"
1504            "                   version " elpher-version "\n"
1505            "     --------------------------------------------\n"
1506            "\n"
1507            "Default bindings:\n"
1508            "\n"
1509            " - TAB/Shift-TAB: next/prev item on current page\n"
1510            " - RET/mouse-1: open item under cursor\n"
1511            " - m: select an item on current page by name (autocompletes)\n"
1512            " - u/mouse-3/U: return to previous page or to the start page\n"
1513            " - o/O: visit different selector or the root menu of the current server\n"
1514            " - g: go to a particular address (gopher, gemini, finger)\n"
1515            " - d/D: download item under cursor or current page\n"
1516            " - i/I: info on item under cursor or current page\n"
1517            " - c/C: copy URL representation of item under cursor or current page\n"
1518            " - a/A: bookmark the item under cursor or current page\n"
1519            " - x/X: remove bookmark for item under cursor or current page\n"
1520            " - B: visit the bookmarks page\n"
1521            " - r: redraw current page (using cached contents if available)\n"
1522            " - R: reload current page (regenerates cache)\n"
1523            " - S: set character coding system for gopher (default is to autodetect)\n"
1524            " - T: toggle TLS gopher mode\n"
1525            " - F: forget/discard current TLS client certificate\n"
1526            " - .: display the raw server response for the current page\n"
1527            "\n"
1528            "Start your exploration of gopher space and gemini:\n")
1529    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1530                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1531    (elpher-insert-index-record "Project Gemini home page"
1532                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1533    (insert "\n"
1534            "Alternatively, select a search engine and enter some search terms:\n")
1535    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1536                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1537    (elpher-insert-index-record "Gemini Search Engine (GUS)"
1538                                (elpher-address-from-url "gemini://gus.guru/search"))
1539    (insert "\n"
1540            "This page contains your bookmarked sites (also visit with B):\n")
1541    (elpher-insert-index-record "Your Bookmarks" 'bookmarks)
1542    (insert "\n"
1543            "For Elpher release news or to leave feedback, visit:\n")
1544    (elpher-insert-index-record "The Elpher Project Page"
1545                                (elpher-make-gopher-address ?1
1546                                                            "/projects/elpher/"
1547                                                            "thelambdalab.xyz"
1548                                                            70))
1549    (insert "\n"
1550            "** Refer to the ")
1551    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1552      (insert-text-button "Elpher info manual"
1553                          'face 'link
1554                          'action (lambda (_)
1555                                    (interactive)
1556                                    (info "(elpher)"))
1557                          'follow-link t
1558                          'help-echo help-string))
1559    (insert " for the full documentation. **\n")
1560    (insert (propertize
1561             (concat "  (This should be available if you have installed Elpher using\n"
1562                     "   MELPA. Otherwise you will have to install the manual yourself.)\n")
1563             'face 'shadow))
1564    (elpher-restore-pos)))
1565
1566 ;; Bookmarks page page retrieval
1567
1568 (defun elpher-get-bookmarks-page (renderer)
1569   "Getter to load and display the current bookmark list (RENDERER must be nil)."
1570   (when renderer
1571     (elpher-visit-previous-page)
1572     (error "Command not supported for bookmarks page"))
1573   (elpher-with-clean-buffer
1574    (insert "---- Bookmark list ----\n\n")
1575    (let ((bookmarks (elpher-load-bookmarks)))
1576      (if bookmarks
1577          (dolist (bookmark bookmarks)
1578            (let ((display-string (elpher-bookmark-display-string bookmark))
1579                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1580              (elpher-insert-index-record display-string address)))
1581        (insert "No bookmarks found.\n")))
1582    (insert "\n-----------------------\n"
1583            "\n"
1584            "- u: return to previous page\n"
1585            "- x: delete selected bookmark\n"
1586            "- a: rename selected bookmark\n"
1587            "\n"
1588            "Bookmarks are stored in the file ")
1589    (let ((filename elpher-bookmarks-file)
1590          (help-string "RET,mouse-1: Open bookmarks file in new buffer for editing."))
1591      (insert-text-button filename
1592                          'face 'link
1593                          'action (lambda (_)
1594                                    (interactive)
1595                                    (find-file filename))
1596                          'follow-link t
1597                          'help-echo help-string))
1598    (insert "\n")
1599    (elpher-restore-pos)))
1600
1601
1602 ;;; Bookmarks
1603 ;;
1604
1605 (defun elpher-make-bookmark (display-string url)
1606   "Make an elpher bookmark.
1607 DISPLAY-STRING determines how the bookmark will appear in the
1608 bookmark list, while URL is the url of the entry."
1609   (list display-string url))
1610
1611 (defun elpher-bookmark-display-string (bookmark)
1612   "Get the display string of BOOKMARK."
1613   (elt bookmark 0))
1614
1615 (defun elpher-set-bookmark-display-string (bookmark display-string)
1616   "Set the display string of BOOKMARK to DISPLAY-STRING."
1617   (setcar bookmark display-string))
1618
1619 (defun elpher-bookmark-url (bookmark)
1620   "Get the address for BOOKMARK."
1621   (elt bookmark 1))
1622
1623 (defun elpher-save-bookmarks (bookmarks)
1624   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1625 Beware that this completely replaces the existing contents of the file."
1626   (with-temp-file elpher-bookmarks-file
1627     (erase-buffer)
1628     (insert "; Elpher bookmarks file\n\n"
1629             "; Bookmarks are stored as a list of (label URL) items.\n"
1630             "; Feel free to edit by hand, but take care to ensure\n"
1631             "; the list structure remains intact.\n\n")
1632     (pp bookmarks (current-buffer))))
1633
1634 (defun elpher-load-bookmarks ()
1635   "Get the list of bookmarks from the users's bookmark file."
1636   (let ((bookmarks
1637          (with-temp-buffer
1638            (ignore-errors
1639              (insert-file-contents elpher-bookmarks-file)
1640              (goto-char (point-min))
1641              (read (current-buffer))))))
1642     (if (and bookmarks (listp (cadar bookmarks)))
1643         (progn
1644           (message "Reading old bookmark file. (Will be updated on write.)")
1645           (mapcar (lambda (old-bm)
1646                     (list (car old-bm)
1647                           (elpher-address-to-url (apply #'elpher-make-gopher-address
1648                                                         (cadr old-bm)))))
1649                   bookmarks))
1650       bookmarks)))
1651
1652 (defun elpher-add-address-bookmark (address display-string)
1653   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1654 If ADDRESS is already bookmarked, update the label only."
1655   (let ((bookmarks (elpher-load-bookmarks))
1656         (url (elpher-address-to-url address)))
1657     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1658       (if existing-bookmark
1659           (elpher-set-bookmark-display-string existing-bookmark display-string)
1660         (push (elpher-make-bookmark display-string url) bookmarks)))
1661     (elpher-save-bookmarks bookmarks)))
1662
1663 (defun elpher-remove-address-bookmark (address)
1664   "Remove any bookmark to ADDRESS."
1665   (let ((url (elpher-address-to-url address)))
1666     (elpher-save-bookmarks
1667      (seq-filter (lambda (bookmark)
1668                    (not (equal (elpher-bookmark-url bookmark) url)))
1669                  (elpher-load-bookmarks)))))
1670
1671 ;;; Interactive procedures
1672 ;;
1673
1674 (defun elpher-next-link ()
1675   "Move point to the next link on the current page."
1676   (interactive)
1677   (forward-button 1))
1678
1679 (defun elpher-prev-link ()
1680   "Move point to the previous link on the current page."
1681   (interactive)
1682   (backward-button 1))
1683
1684 (defun elpher-follow-current-link ()
1685   "Open the link or url at point."
1686   (interactive)
1687   (push-button))
1688
1689 (defun elpher-go (host-or-url)
1690   "Go to a particular gopher site HOST-OR-URL.
1691 When run interactively HOST-OR-URL is read from the minibuffer."
1692   (interactive "sGopher or Gemini URL: ")
1693   (let* ((cleaned-host-or-url (string-trim host-or-url))
1694          (address (elpher-address-from-url cleaned-host-or-url))
1695          (page (elpher-make-page cleaned-host-or-url address)))
1696     (switch-to-buffer elpher-buffer-name)
1697     (elpher-visit-page page)
1698     nil))
1699
1700 (defun elpher-go-current ()
1701   "Go to a particular site read from the minibuffer, initialized with the current URL."
1702   (interactive)
1703   (let ((address (elpher-page-address elpher-current-page)))
1704     (if (elpher-address-special-p address)
1705         (error "Command invalid for this page")
1706       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1707         (elpher-visit-page (elpher-make-page url (elpher-address-from-url url)))))))
1708
1709 (defun elpher-redraw ()
1710   "Redraw current page."
1711   (interactive)
1712   (elpher-visit-page elpher-current-page))
1713
1714 (defun elpher-reload ()
1715   "Reload current page."
1716   (interactive)
1717   (elpher-reload-current-page))
1718
1719 (defun elpher-toggle-tls ()
1720   "Toggle TLS encryption mode for gopher."
1721   (interactive)
1722   (setq elpher-use-tls (not elpher-use-tls))
1723   (if elpher-use-tls
1724       (if (gnutls-available-p)
1725           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
1726         (setq elpher-use-tls nil)
1727         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
1728     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
1729
1730 (defun elpher-view-raw ()
1731   "View raw server response for current page."
1732   (interactive)
1733   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1734       (error "This page was not generated by a server")
1735     (elpher-visit-page elpher-current-page
1736                        #'elpher-render-raw)))
1737
1738 (defun elpher-back ()
1739   "Go to previous site."
1740   (interactive)
1741   (elpher-visit-previous-page))
1742
1743 (defun elpher-back-to-start ()
1744   "Go all the way back to the start page."
1745   (interactive)
1746   (setq-local elpher-current-page nil)
1747   (setq-local elpher-history nil)
1748   (let ((start-page (elpher-make-page "Elpher Start Page"
1749                                       (elpher-make-special-address 'start))))
1750     (elpher-visit-page start-page)))
1751
1752 (defun elpher-download ()
1753   "Download the link at point."
1754   (interactive)
1755   (let ((button (button-at (point))))
1756     (if button
1757         (let ((page (button-get button 'elpher-page)))
1758           (if (elpher-address-special-p (elpher-page-address page))
1759               (error "Cannot download %s"
1760                      (elpher-page-display-string page))
1761             (elpher-visit-page (button-get button 'elpher-page)
1762                                #'elpher-render-download)))
1763       (error "No link selected"))))
1764
1765 (defun elpher-download-current ()
1766   "Download the current page."
1767   (interactive)
1768   (if (elpher-address-special-p (elpher-page-address elpher-current-page))
1769       (error "Cannot download %s"
1770              (elpher-page-display-string elpher-current-page))
1771     (elpher-visit-page (elpher-make-page
1772                         (elpher-page-display-string elpher-current-page)
1773                         (elpher-page-address elpher-current-page))
1774                        #'elpher-render-download
1775                        t)))
1776
1777 (defun elpher-build-link-map ()
1778   "Build alist mapping link names to destination pages in current buffer."
1779   (let ((link-map nil)
1780         (b (next-button (point-min) t)))
1781     (while b
1782       (push (cons (button-label b) b) link-map)
1783       (setq b (next-button (button-start b))))
1784     link-map))
1785
1786 (defun elpher-jump ()
1787   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1788   (interactive)
1789   (let* ((link-map (elpher-build-link-map)))
1790     (if link-map
1791         (let ((key (let ((completion-ignore-case t))
1792                      (completing-read "Directory item/link: "
1793                                       link-map nil t))))
1794           (if (and key (> (length key) 0))
1795               (let ((b (cdr (assoc key link-map))))
1796                 (goto-char (button-start b))
1797                 (button-activate b)))))))
1798
1799 (defun elpher-root-dir ()
1800   "Visit root of current server."
1801   (interactive)
1802   (let ((address (elpher-page-address elpher-current-page)))
1803     (if (not (elpher-address-special-p address))
1804         (if (or (member (url-filename address) '("/" ""))
1805                 (and (elpher-address-gopher-p address)
1806                      (= (length (elpher-gopher-address-selector address)) 0)))
1807             (error "Already at root directory of current server")
1808           (let ((address-copy (elpher-address-from-url
1809                                (elpher-address-to-url address))))
1810             (setf (url-filename address-copy) "")
1811             (elpher-go (elpher-address-to-url address-copy))))
1812       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
1813
1814 (defun elpher-bookmarks-current-p ()
1815   "Return non-nil if current page is a bookmarks page."
1816   (equal (elpher-address-type (elpher-page-address elpher-current-page))
1817          '(special bookmarks)))
1818
1819 (defun elpher-reload-bookmarks ()
1820   "Reload bookmarks if current page is a bookmarks page."
1821   (if (elpher-bookmarks-current-p)
1822       (elpher-reload-current-page)))
1823
1824 (defun elpher-bookmark-current ()
1825   "Bookmark the current page."
1826   (interactive)
1827   (let ((address (elpher-page-address elpher-current-page))
1828         (display-string (elpher-page-display-string elpher-current-page)))
1829     (if (not (elpher-address-special-p address))
1830         (let ((bookmark-display-string (read-string "Bookmark display string: "
1831                                                     display-string)))
1832           (elpher-add-address-bookmark address bookmark-display-string)
1833           (message "Bookmark added."))
1834       (error "Cannot bookmark %s" display-string))))
1835
1836 (defun elpher-bookmark-link ()
1837   "Bookmark the link at point."
1838   (interactive)
1839   (let ((button (button-at (point))))
1840     (if button
1841         (let* ((page (button-get button 'elpher-page))
1842                (address (elpher-page-address page))
1843                (display-string (elpher-page-display-string page)))
1844           (if (not (elpher-address-special-p address))
1845               (let ((bookmark-display-string (read-string "Bookmark display string: "
1846                                                           display-string)))
1847                 (elpher-add-address-bookmark address bookmark-display-string)
1848                 (elpher-reload-bookmarks)
1849                 (message "Bookmark added."))
1850             (error "Cannot bookmark %s" display-string)))
1851       (error "No link selected"))))
1852
1853 (defun elpher-unbookmark-current ()
1854   "Remove bookmark for the current page."
1855   (interactive)
1856   (let ((address (elpher-page-address elpher-current-page)))
1857     (when (and (not (elpher-address-special-p address))
1858                (y-or-n-p "Really remove bookmark for the current page? "))
1859       (elpher-remove-address-bookmark address)
1860       (message "Bookmark removed."))))
1861
1862 (defun elpher-unbookmark-link ()
1863   "Remove bookmark for the link at point."
1864   (interactive)
1865   (let ((button (button-at (point))))
1866     (if button
1867         (when (y-or-n-p "Really remove bookmark for this link? ")
1868           (let ((page (button-get button 'elpher-page)))
1869             (elpher-remove-address-bookmark (elpher-page-address page))
1870             (elpher-reload-bookmarks)
1871             (message "Bookmark removed.")))
1872       (error "No link selected"))))
1873
1874 (defun elpher-bookmarks ()
1875   "Visit bookmarks page."
1876   (interactive)
1877   (switch-to-buffer elpher-buffer-name)
1878   (elpher-visit-page
1879    (elpher-make-page "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1880
1881 (defun elpher-info-page (page)
1882   "Display information on PAGE."
1883   (let ((display-string (elpher-page-display-string page))
1884         (address (elpher-page-address page)))
1885     (if (elpher-address-special-p address)
1886         (message "Special page: %s" display-string)
1887       (message "%s" (elpher-address-to-url address)))))
1888
1889 (defun elpher-info-link ()
1890   "Display information on page corresponding to link at point."
1891   (interactive)
1892   (let ((button (button-at (point))))
1893     (if button
1894         (elpher-info-page (button-get button 'elpher-page))
1895       (error "No item selected"))))
1896
1897 (defun elpher-info-current ()
1898   "Display information on current page."
1899   (interactive)
1900   (elpher-info-page elpher-current-page))
1901
1902 (defun elpher-copy-page-url (page)
1903   "Copy URL representation of address of PAGE to `kill-ring'."
1904   (let ((address (elpher-page-address page)))
1905     (if (elpher-address-special-p address)
1906         (error (format "Cannot represent %s as URL" (elpher-page-display-string page)))
1907       (let ((url (elpher-address-to-url address)))
1908         (message "Copied \"%s\" to kill-ring/clipboard." url)
1909         (kill-new url)))))
1910
1911 (defun elpher-copy-link-url ()
1912   "Copy URL of item at point to `kill-ring'."
1913   (interactive)
1914   (let ((button (button-at (point))))
1915     (if button
1916         (elpher-copy-page-url (button-get button 'elpher-page))
1917       (error "No item selected"))))
1918
1919 (defun elpher-copy-current-url ()
1920   "Copy URL of current page to `kill-ring'."
1921   (interactive)
1922   (elpher-copy-page-url elpher-current-page))
1923
1924 (defun elpher-set-gopher-coding-system ()
1925   "Specify an explicit character coding system for gopher selectors."
1926   (interactive)
1927   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
1928     (setq elpher-user-coding-system system)
1929     (if system
1930         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
1931       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
1932
1933
1934 ;;; Mode and keymap
1935 ;;
1936
1937 (defvar elpher-mode-map
1938   (let ((map (make-sparse-keymap)))
1939     (define-key map (kbd "TAB") 'elpher-next-link)
1940     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1941     (define-key map (kbd "C-M-i") 'elpher-prev-link)
1942     (define-key map (kbd "u") 'elpher-back)
1943     (define-key map (kbd "U") 'elpher-back-to-start)
1944     (define-key map [mouse-3] 'elpher-back)
1945     (define-key map (kbd "O") 'elpher-root-dir)
1946     (define-key map (kbd "g") 'elpher-go)
1947     (define-key map (kbd "o") 'elpher-go-current)
1948     (define-key map (kbd "r") 'elpher-redraw)
1949     (define-key map (kbd "R") 'elpher-reload)
1950     (define-key map (kbd "T") 'elpher-toggle-tls)
1951     (define-key map (kbd ".") 'elpher-view-raw)
1952     (define-key map (kbd "d") 'elpher-download)
1953     (define-key map (kbd "D") 'elpher-download-current)
1954     (define-key map (kbd "m") 'elpher-jump)
1955     (define-key map (kbd "i") 'elpher-info-link)
1956     (define-key map (kbd "I") 'elpher-info-current)
1957     (define-key map (kbd "c") 'elpher-copy-link-url)
1958     (define-key map (kbd "C") 'elpher-copy-current-url)
1959     (define-key map (kbd "a") 'elpher-bookmark-link)
1960     (define-key map (kbd "A") 'elpher-bookmark-current)
1961     (define-key map (kbd "x") 'elpher-unbookmark-link)
1962     (define-key map (kbd "X") 'elpher-unbookmark-current)
1963     (define-key map (kbd "B") 'elpher-bookmarks)
1964     (define-key map (kbd "S") 'elpher-set-gopher-coding-system)
1965     (define-key map (kbd "F") 'elpher-forget-current-certificate)
1966     (when (fboundp 'evil-define-key*)
1967       (evil-define-key* 'motion map
1968         (kbd "TAB") 'elpher-next-link
1969         (kbd "C-") 'elpher-follow-current-link
1970         (kbd "C-t") 'elpher-back
1971         (kbd "u") 'elpher-back
1972         (kbd "U") 'elpher-back-to-start
1973         [mouse-3] 'elpher-back
1974         (kbd "g") 'elpher-go
1975         (kbd "o") 'elpher-go-current
1976         (kbd "r") 'elpher-redraw
1977         (kbd "R") 'elpher-reload
1978         (kbd "T") 'elpher-toggle-tls
1979         (kbd ".") 'elpher-view-raw
1980         (kbd "d") 'elpher-download
1981         (kbd "D") 'elpher-download-current
1982         (kbd "m") 'elpher-jump
1983         (kbd "i") 'elpher-info-link
1984         (kbd "I") 'elpher-info-current
1985         (kbd "c") 'elpher-copy-link-url
1986         (kbd "C") 'elpher-copy-current-url
1987         (kbd "a") 'elpher-bookmark-link
1988         (kbd "A") 'elpher-bookmark-current
1989         (kbd "x") 'elpher-unbookmark-link
1990         (kbd "X") 'elpher-unbookmark-current
1991         (kbd "B") 'elpher-bookmarks
1992         (kbd "S") 'elpher-set-gopher-coding-system
1993         (kbd "F") 'elpher-forget-current-certificate))
1994     map)
1995   "Keymap for gopher client.")
1996
1997 (define-derived-mode elpher-mode special-mode "elpher"
1998   "Major mode for elpher, an elisp gopher client.
1999
2000 This mode is automatically enabled by the interactive
2001 functions which initialize the gopher client, namely
2002 `elpher', `elpher-go' and `elpher-bookmarks'."
2003   (setq-local elpher-current-page nil)
2004   (setq-local elpher-history nil)
2005   (setq-local elpher-buffer-name (buffer-name)))
2006
2007 (when (fboundp 'evil-set-initial-state)
2008   (evil-set-initial-state 'elpher-mode 'motion))
2009
2010 ;;; Menu
2011 ;;
2012
2013 (defun elpher-menu (&optional arg)
2014   "Show a list of all your `elpher' buffers.
2015 With an optional argument, add all the history items, too."
2016   (interactive "P")
2017   (switch-to-buffer (get-buffer-create "*Elpher Menu*"))
2018   (elpher-menu-mode)
2019   (elpher-menu-refresh arg)
2020   (tabulated-list-print))
2021
2022 (defvar elpher-menu-mode-map
2023   (let ((map (make-sparse-keymap))
2024         (menu-map (make-sparse-keymap)))
2025     (set-keymap-parent map tabulated-list-mode-map)
2026     (define-key map "v" 'Buffer-menu-select)
2027     (define-key map "2" 'Buffer-menu-2-window)
2028     (define-key map "1" 'Buffer-menu-1-window)
2029     (define-key map "f" 'Buffer-menu-this-window)
2030     (define-key map "e" 'Buffer-menu-this-window)
2031     (define-key map "\C-m" 'elpher-menu-this-window)
2032     (define-key map "o" 'elpher-menu-other-window)
2033     (define-key map "\C-o" 'elpher-menu-switch-other-window)
2034     (define-key map "d" 'Buffer-menu-delete)
2035     (define-key map "k" 'Buffer-menu-delete)
2036     (define-key map "\C-k" 'Buffer-menu-delete)
2037     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
2038     (define-key map "x" 'Buffer-menu-execute)
2039     (define-key map " " 'next-line)
2040     (define-key map "\177" 'Buffer-menu-backup-unmark)
2041     (define-key map "u" 'Buffer-menu-unmark)
2042     (define-key map "m" 'Buffer-menu-mark)
2043     (define-key map "b" 'Buffer-menu-bury)
2044     (define-key map (kbd "M-s a C-s")   'Buffer-menu-isearch-buffers)
2045     (define-key map (kbd "M-s a M-C-s") 'Buffer-menu-isearch-buffers-regexp)
2046     (define-key map (kbd "M-s a C-o") 'Buffer-menu-multi-occur)
2047     (define-key map [mouse-2] 'Buffer-menu-mouse-select)
2048     (define-key map [follow-link] 'mouse-face)
2049     (define-key map [menu-bar elpher-menu-mode] (cons (purecopy "Elpher-Menu") menu-map))
2050     (bindings--define-key menu-map [quit]
2051       '(menu-item "Quit" quit-window
2052                  :help "Remove the elpher menu from the display"))
2053     (bindings--define-key menu-map [rev]
2054       '(menu-item "Refresh" revert-buffer
2055                  :help "Refresh the *Elpher Menu* buffer contents"))
2056     (bindings--define-key menu-map [s0] menu-bar-separator)
2057     (bindings--define-key menu-map [sel]
2058       '(menu-item "Select Marked" Buffer-menu-select
2059                  :help "Select this line's buffer; also display buffers marked with `>'"))
2060     (bindings--define-key menu-map [bm2]
2061       '(menu-item "Select Two" Buffer-menu-2-window
2062                  :help "Select this line's buffer, with previous buffer in second window"))
2063     (bindings--define-key menu-map [bm1]
2064       '(menu-item "Select Current" Buffer-menu-1-window
2065                  :help "Select this line's buffer, alone, in full frame"))
2066     (bindings--define-key menu-map [ow]
2067       '(menu-item "Select in Other Window" elpher-menu-other-window
2068                  :help "Select this line's buffer in other window, leaving buffer menu visible"))
2069     (bindings--define-key menu-map [tw]
2070       '(menu-item "Select in Current Window" elpher-menu-this-window
2071                  :help "Select this line's buffer in this window"))
2072     (bindings--define-key menu-map [s2] menu-bar-separator)
2073     (bindings--define-key menu-map [is]
2074       '(menu-item "Regexp Isearch Marked Buffers..." Buffer-menu-isearch-buffers-regexp
2075                  :help "Search for a regexp through all marked buffers using Isearch"))
2076     (bindings--define-key menu-map [ir]
2077       '(menu-item "Isearch Marked Buffers..." Buffer-menu-isearch-buffers
2078                  :help "Search for a string through all marked buffers using Isearch"))
2079     (bindings--define-key menu-map [mo]
2080       '(menu-item "Multi Occur Marked Buffers..." Buffer-menu-multi-occur
2081                  :help "Show lines matching a regexp in marked buffers using Occur"))
2082     (bindings--define-key menu-map [s3] menu-bar-separator)
2083     (bindings--define-key menu-map [by]
2084       '(menu-item "Bury" Buffer-menu-bury
2085                  :help "Bury the buffer listed on this line"))
2086     (bindings--define-key menu-map [ex]
2087       '(menu-item "Execute" Buffer-menu-execute
2088                  :help "Delete buffers marked with k commands"))
2089     (bindings--define-key menu-map [s4] menu-bar-separator)
2090     (bindings--define-key menu-map [delb]
2091       '(menu-item "Mark for Delete and Move Backwards" Buffer-menu-delete-backwards
2092                  :help "Mark buffer on this line to be deleted by x command and move up one line"))
2093     (bindings--define-key menu-map [del]
2094       '(menu-item "Mark for Delete" Buffer-menu-delete
2095                  :help "Mark buffer on this line to be deleted by x command"))
2096     (bindings--define-key menu-map [umk]
2097       '(menu-item "Unmark" Buffer-menu-unmark
2098                  :help "Cancel all requested operations on buffer on this line and move down"))
2099     (bindings--define-key menu-map [mk]
2100       '(menu-item "Mark" Buffer-menu-mark
2101                  :help "Mark buffer on this line for being displayed by v command"))
2102     map)
2103   "Local keymap for `elpher-menu-mode' buffers.")
2104
2105 (define-derived-mode elpher-menu-mode tabulated-list-mode "Elpher Menu"
2106   "Major mode for Elpher Menu buffers.
2107 The Elpher Menu is invoked by the command \\[elpher-menu]. When
2108 invoked with a prefix, the command also shows history items.
2109 Since history items are no longer showing in a buffer, many of
2110 the commands shown below will not work on them.
2111
2112 In Elpher Menu mode, the following commands are defined:
2113 \\<elpher-menu-mode-map>
2114 \\[quit-window]    Remove the Buffer Menu from the display.
2115 \\[tabulated-list-sort]    Sorts buffers according to the current
2116      column. With a numerical argument, sort by that column.
2117 \\[elpher-menu-this-window]  Select current line's buffer in place of the buffer menu.
2118 \\[elpher-menu-other-window]    Select that buffer in another window,
2119      so the Buffer Menu remains visible in its window.
2120 \\[elpher-menu-switch-other-window]  Make another window display that buffer.
2121 \\[Buffer-menu-mark]    Mark current line's buffer to be displayed.
2122 \\[Buffer-menu-select]    Select current line's buffer.
2123      Also show buffers marked with m, in other windows.
2124 \\[Buffer-menu-1-window]    Select that buffer in full-frame window.
2125 \\[Buffer-menu-2-window]    Select that buffer in one window, together with the
2126      buffer selected before this one in another window.
2127 \\[Buffer-menu-isearch-buffers]    Incremental search in the marked buffers.
2128 \\[Buffer-menu-isearch-buffers-regexp]  Isearch for regexp in the marked buffers.
2129 \\[Buffer-menu-multi-occur] Show lines matching regexp in the marked buffers.
2130 \\[Buffer-menu-delete]  Mark that buffer to be deleted, and move down.
2131 \\[Buffer-menu-delete-backwards]  Mark that buffer to be deleted, and move up.
2132 \\[Buffer-menu-execute]    Delete or save marked buffers.
2133 \\[Buffer-menu-unmark]    Remove all marks from current line.
2134      With prefix argument, also move up one line.
2135 \\[Buffer-menu-backup-unmark]  Back up a line and remove marks.
2136 \\[revert-buffer]    Update the list of buffers.
2137 \\[Buffer-menu-bury]    Bury the buffer listed on this line."
2138   (add-hook 'tabulated-list-revert-hook 'elpher-menu-refresh nil t))
2139
2140 (defun elpher-menu-this-window ()
2141   "Select this line’s buffer in this window.
2142 Switch to the buffer, if possible. If there is no buffer, chances
2143 are that we're looking at a history item. Let's visit the item
2144 instead of complaining that their buffers have been killed."
2145   (interactive)
2146   (elpher-menu-handle-buffer-or-data 'switch-to-buffer))
2147
2148 (defun elpher-menu-other-window ()
2149   "Select this line’s buffer in other window, leaving buffer menu visible."
2150   (interactive)
2151   (elpher-menu-handle-buffer-or-data 'switch-to-buffer-other-window))
2152
2153 (defun elpher-menu-switch-other-window ()
2154   "Make the other window select this line's buffer.
2155 The current window remains selected."
2156   (interactive)
2157   (elpher-menu-handle-buffer-or-data
2158    (lambda (buf) (display-buffer buf t))))
2159
2160 (defun elpher-menu-handle-buffer-or-data (buffer-func)
2161   "Handle an item in `elpher-menu-mode'.
2162 Determine the entry ID of the Tabulated List entry at point. If
2163 ID is a buffer, invoke BUFFER-FUNC on it. Otherwise, ID is a
2164 list (BUFFER FUNC ARGS...). Switch to BUFFER using BUFFER-FUNC
2165 and apply FUNC to ARGS."
2166   (let ((data (tabulated-list-get-id)))
2167     (cond ((bufferp data)
2168            (funcall buffer-func data))
2169           ((and (listp data)
2170                 (buffer-live-p (nth 0 data))
2171                 (fboundp (nth 1 data)))
2172            (funcall buffer-func (nth 0 data))
2173            (apply (nth 1 data) (nthcdr 2 data)))
2174           (t
2175            (error "There's no entry on this line of the menu")))))
2176
2177 (defvar elpher-title nil)
2178
2179 (defun elpher-find-title ()
2180   "Return the first heading1."
2181   (if elpher-title
2182       elpher-title
2183     (let ((start (text-property-any
2184                   (point-min) (point-max)
2185                   'face 'elpher-gemini-heading1)))
2186       (when start
2187         (save-excursion
2188           (goto-char start)
2189           (setq-local elpher-title
2190                       (buffer-substring-no-properties
2191                        start (line-end-position))))))))
2192
2193 (defun elpher-menu-refresh (&optional arg)
2194   "Refresh the list of buffers.
2195 With an optional argument, add all the history items, too. Note
2196 that there are no buffers for history items so many of the buffer
2197 menu commands won't work on them."
2198     (setq tabulated-list-format
2199           (vector '("T" 1 t)
2200                   '("URL" 40 t)
2201                   '("Name" 30 t))
2202           tabulated-list-sort-key nil)
2203     ;; Collect info for each buffer we're interested in.
2204     (let (entries)
2205       (dolist (buf (buffer-list))
2206         (with-current-buffer buf
2207           (when (memq major-mode '(elpher-mode eww-mode gemini-mode))
2208             (if arg
2209                 (setq entries (nconc (elpher-menu-refresh-history) entries))
2210               (push (elpher-menu-refresh-current) entries)))))
2211       (setq tabulated-list-entries (nreverse entries)))
2212     (tabulated-list-init-header))
2213
2214 (defun elpher-menu-refresh-current ()
2215   "Returns an item for `elpher-menu-refresh'
2216 based on the current buffer.
2217
2218 An item is a list (BUFFER VECTOR) where BUFFER is the buffer this
2219 item refers to and VECTOR is what to display in the tabulated
2220 list established by `elpher-menu-refresh'. See
2221 `tabulated-list-format'."
2222   (list (current-buffer)
2223         (cond ((eq major-mode 'elpher-mode)
2224                (vector "G"
2225                        (or (elpher-address-to-url
2226                             (elpher-page-address elpher-current-page))
2227                            "none")
2228                        (or (elpher-find-title)
2229                            (elpher-page-display-string elpher-current-page)
2230                            (buffer-name))))
2231               ((eq major-mode 'gemini-mode)
2232                (vector "E"
2233                        (or (elpher-address-to-url
2234                             (elpher-page-address elpher-current-page))
2235                            "none")
2236                        (or (elpher-page-display-string elpher-current-page)
2237                            (buffer-name))))
2238               ((eq major-mode 'eww-mode)
2239                (vector "W"
2240                        (or (eww-current-url)
2241                            "none")
2242                        (or (plist-get eww-data :title)
2243                            (buffer-name)))))))
2244
2245 (defun elpher-menu-refresh-history ()
2246   "Return current entries for `elpher-menu-refresh'.
2247 This returns a list of items for the current buffer, based on the
2248 buffer's history.
2249
2250 An item is a list (BUFFER VECTOR) where BUFFER is the buffer this
2251 item refers to and VECTOR is what to display in the tabulated
2252 list established by `elpher-menu-refresh'. See
2253 `tabulated-list-format'."
2254   ;; Every section starts with the current page, followed by some
2255   ;; history items, and ends with the separator.
2256   (let ((separator (list nil
2257                          (vector "-"
2258                                  (make-string 25 ?-)
2259                                  (make-string 25 ?-)))))
2260     (cond ((eq major-mode 'elpher-mode)
2261            ;; A pair is (BUFFER-OR-DATA . PAGE) where BUFFER-OR-DTA is
2262            ;; the current buffer, if possible, or list (BUFFER FUNC
2263            ;; &rest ARGS) telling us which BUFFER to switch to, and
2264            ;; what function to call. The last item of elpher-history
2265            ;; has a nil page, so when that shows up, use the separator
2266            (mapcar (lambda (pair)
2267                      (if (cdr pair)
2268                          (list (car pair)
2269                                (vector "G"
2270                                        (or (elpher-address-to-url
2271                                             (elpher-page-address (cdr pair))) "none")
2272                                        (or (elpher-page-display-string (cdr pair)) "?")))
2273                        separator))
2274                    (cons (cons (current-buffer) elpher-current-page)
2275                          (mapcar (lambda (page)
2276                                    (cons (list (current-buffer) 'elpher-visit-page page)
2277                                          page))
2278                                  elpher-history))))
2279           ((eq major-mode 'gemini-mode)
2280            ;; No history means a list of one item. Add a separator.
2281            (list (list (current-buffer)
2282                        (vector "E"
2283                                (or (elpher-address-to-url
2284                                     (elpher-page-address elpher-current-page)))
2285                                (or (elpher-page-display-string elpher-current-page)
2286                                    (buffer-name))))
2287                  separator))
2288            ((eq major-mode 'eww-mode)
2289            ;; A pair is (BUFFER-OR-DATA . PAGE) where BUFFER-OR-DTA is
2290            ;; the current buffer, if possible, or list (BUFFER FUNC
2291            ;; &rest ARGS) telling us which BUFFER to switch to, and
2292            ;; what function to call. Add the separator at the end.
2293             (nconc (cons (list (current-buffer)
2294                                (vector "W"
2295                                        (or (plist-get eww-data :url) "none")
2296                                        (or (plist-get eww-data :title) "none")))
2297                          (mapcar (lambda (data)
2298                                    (list
2299                                     (list (current-buffer) 'eww-restore-history data)
2300                                     (vector "W"
2301                                             (or (plist-get data :url) "none")
2302                                             (or (plist-get data :title) "none"))))
2303                                  eww-history))
2304                    (list separator))))))
2305
2306 ;;; Main start procedure
2307 ;;
2308
2309 ;;;###autoload
2310 (defun elpher (&optional arg)
2311   "Start elpher with default landing page.
2312 The buffer used for Elpher sessions is determined by the value of
2313 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2314 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2315 will begin.  A numeric prefix arg (as in ‘C-u 42 M-x elpher RET’)
2316 switches to the session with that number, creating it if necessary.  A
2317 nonnumeric prefix arg means to create a new session.  Returns the
2318 buffer selected (or created)."
2319   (interactive "P")
2320   (let* ((name (default-value 'elpher-buffer-name))
2321          (buf (cond ((numberp arg)
2322                      (get-buffer-create (format "%s<%d>" name arg)))
2323                     (arg
2324                      (generate-new-buffer name))
2325                     (t
2326                      (get-buffer-create name)))))
2327     (pop-to-buffer-same-window buf)
2328     (unless (buffer-modified-p)
2329       (elpher-mode)
2330       (let ((start-page (elpher-make-page "Elpher Start Page"
2331                                           (elpher-make-special-address 'start))))
2332         (elpher-visit-page start-page))
2333       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2334
2335 ;;; elpher.el ends here