+
+( STRINGS ---------------------------------------------------------------------- )
+
+
+( Block copy, however, is important and novel: )
+: CMOVE ( src dest length -- )
+
+ DUP 0<= IF
+ EXIT
+ THEN
+
+ -ROT OVER - ( length src (dest-src) )
+ -ROT DUP ROT + SWAP ( (dest-src) (src+length) src )
+
+ DO
+ I @ ( (dest-src) i@ )
+ OVER I + ( (dest-src) i@ (dest-src+i) )
+ ! ( (dest-src) )
+ LOOP
+
+ DROP
+;
+
+( C, appends a byte to the current compiled word. )
+: C,
+ HERE C!
+ 1 H +!
+;
+
+: S" IMMEDIATE ( -- addr len )
+ STATE @ IF ( compiling? )
+ ['] LITSTRING , ( compile LITSTRING )
+ HERE ( save the address of the length word on the stack )
+ 0 , ( dummy length - we don't know what it is yet )
+
+ BEGIN
+ >IN @ #TIB @ >= IF \ End of TIB?
+ QUERY \ Get next line
+ THEN
+
+ TIB >IN @ + @ 1 >IN +! \ Get char from TIB
+
+ DUP [CHAR] " <>
+ WHILE
+ C, ( copy character )
+ REPEAT
+ DROP ( drop the double quote character at the end )
+ DUP ( get the saved address of the length word )
+ HERE SWAP - ( calculate the length )
+ 1- ( subtract 1 (because we measured from the start of the length word) )
+ SWAP ! ( and back-fill the length location )
+ ELSE ( immediate mode )
+ HERE ( get the start address of the temporary space )
+
+ BEGIN
+ >IN @ #TIB @ >= IF \ End of TIB?
+ QUERY \ Get next line
+ THEN
+
+ TIB >IN @ + @ 1 >IN +! \ Get char from TIB
+
+ DUP [CHAR] " <>
+ WHILE
+ OVER C! ( save next character )
+ 1+ ( increment address )
+ REPEAT
+ DROP ( drop the final " character )
+ HERE - ( calculate the length )
+ HERE ( push the start address )
+ SWAP ( addr len )
+ THEN
+;
+
+: ." IMMEDIATE ( -- )
+ [COMPILE] S" ( read the string, and compile LITSTRING, etc. )
+ ['] TYPE , ( compile the final TYPE )
+;
+
+: .(
+ BEGIN
+ >IN @ #TIB @ >= IF \ End of TIB?
+ QUERY \ Get next line
+ THEN
+
+ TIB >IN @ + @ 1 >IN +! \ Get char from TIB
+
+ DUP [CHAR] ) = IF
+ DROP ( drop the double quote character )
+ EXIT ( return from this function )
+ THEN
+ EMIT
+ AGAIN
+;
+
+( Converts address of counted string into address of
+ start of string and length of string. )
+: COUNT ( addr1 -- addr2 n )
+ DUP 1+ SWAP @ ;
+
+
+( CONSTANTS AND VARIABLES ------------------------------------------------------ )
+
+: CONSTANT
+ BL WORD HEADER ( make dictionary entry (the name follows CONSTANT) )
+ DOCOL , ( append DOCOL (the codeword field of this word) )
+ ['] LIT , ( append the codeword LIT )
+ , ( append the value on the top of the stack )
+ ['] EXIT , ( append the codeword EXIT )
+;
+
+: ALLOT ( n -- )
+ H +! ( adds n to H, after this the old value of H is still on the stack )
+;
+
+: VARIABLE
+ BL WORD HEADER
+ DOVAR ,
+ 1 CELLS ALLOT ( allocate 1 cell of memory, push the pointer to this memory )
+;
+
+: VALUE ( n -- )
+ BL WORD HEADER ( make the dictionary entry (the name follows VALUE) )
+ DOCOL , ( append DOCOL )
+ ['] LIT , ( append the codeword LIT )
+ , ( append the initial value )
+ ['] EXIT , ( append the codeword EXIT )
+;
+
+: TO IMMEDIATE ( n -- )
+ BL WORD ( get the name of the value )
+ FIND ( look it up in the dictionary )
+ >PFA ( get a pointer to the first data field (the 'LIT') )
+ 1+ ( increment to point at the value )
+ STATE @ IF ( compiling? )
+ ['] LIT , ( compile LIT )
+ , ( compile the address of the value )
+ ['] ! , ( compile ! )
+ ELSE ( immediate mode )
+ ! ( update it straightaway )
+ THEN
+;
+
+( x +TO VAL adds x to VAL )
+: +TO IMMEDIATE
+ BL WORD ( get the name of the value )
+ FIND ( look it up in the dictionary )
+ >PFA ( get a pointer to the first data field (the 'LIT') )
+ 1+ ( increment to point at the value )
+ STATE @ IF ( compiling? )
+ ['] LIT , ( compile LIT )
+ , ( compile the address of the value )
+ ['] +! , ( compile +! )
+ ELSE ( immediate mode )
+ +! ( update it straightaway )
+ THEN
+;
+
+( Fill u ints, starting at a, with the value b )
+: FILL ( a u b -- )
+ -ROT OVER + SWAP ?DO
+ DUP I !
+ LOOP
+ DROP
+;
+
+: ERASE ( a u -- )
+ 0 FILL
+;
+
+( PRINTING THE DICTIONARY ------------------------------------------------------ )
+
+: ID.
+ 1+ ( skip over the link pointer )
+ DUP @ ( get the flags/length byte )
+ F_LENMASK AND ( mask out the flags - just want the length )
+
+ BEGIN
+ DUP 0> ( length > 0? )
+ WHILE
+ SWAP 1+ ( addr len -- len addr+1 )
+ DUP @ ( len addr -- len addr char | get the next character)
+ DUP 32 >= OVER 127 <= AND IF
+ EMIT ( len addr char -- len addr | and print it)
+ ELSE
+ BASE @ SWAP HEX
+ ." \x" 0 .R
+ BASE !
+ THEN
+ SWAP 1- ( len addr -- addr len-1 | subtract one from length )
+ REPEAT
+ 2DROP ( len addr -- )
+;
+
+: ?HIDDEN
+ 1+ ( skip over the link pointer )
+ @ ( get the flags/length byte )
+ F_HIDDEN AND ( mask the F_HIDDEN flag and return it (as a truth value) )
+;
+: ?IMMEDIATE
+ 1+ ( skip over the link pointer )
+ @ ( get the flags/length byte )
+ F_IMMED AND ( mask the F_IMMED flag and return it (as a truth value) )
+;
+
+: WORDS
+ LATEST @ ( start at LATEST dictionary entry )
+ BEGIN
+ ?DUP ( while link pointer is not null )
+ WHILE
+ DUP ?HIDDEN NOT IF ( ignore hidden words )
+ DUP ID. ( but if not hidden, print the word )
+ SPACE
+ THEN
+ @ ( dereference the link pointer - go to previous word )
+ REPEAT
+ CR
+;
+
+
+( FORGET ---------------------------------------------------------------------- )
+
+: FORGET
+ BL WORD FIND ( find the word, gets the dictionary entry address )
+ DUP @ LATEST ! ( set LATEST to point to the previous word )
+ H ! ( and store H with the dictionary address )
+;
+
+( DUMP ------------------------------------------------------------------------ )
+
+\ TODO!
+
+
+( DECOMPILER ------------------------------------------------------------------ )
+
+: CFA>
+ LATEST @ ( start at LATEST dictionary entry )
+ BEGIN
+ ?DUP ( while link pointer is not null )
+ WHILE
+ 2DUP SWAP ( cfa curr curr cfa )
+ < IF ( current dictionary entry < cfa? )
+ NIP ( leave curr dictionary entry on the stack )
+ EXIT
+ THEN
+ @ ( follow link pointer back )
+ REPEAT
+ DROP ( restore stack )
+ 0 ( sorry, nothing found )
+;
+
+: SEE
+ BL WORD DUP FIND ( find the dictionary entry to decompile )
+
+ ?DUP 0= IF
+ ." Word '" COUNT TYPE ." ' not found in dictionary."
+ EXIT
+ THEN
+
+ SWAP DROP
+
+ ( Now we search again, looking for the next word in the dictionary. This gives us
+ the length of the word that we will be decompiling. (Well, mostly it does). )
+ HERE ( address of the end of the last compiled word )
+ LATEST @ ( word last curr )
+ BEGIN
+ 2 PICK ( word last curr word )
+ OVER ( word last curr word curr )
+ <> ( word last curr word<>curr? )
+ WHILE ( word last curr )
+ NIP ( word curr )
+ DUP @ ( word curr prev (which becomes: word last curr) )
+ REPEAT
+
+ DROP ( at this point, the stack is: start-of-word end-of-word )
+ SWAP ( end-of-word start-of-word )
+
+ DUP >CFA @ CASE
+ DOCOL OF
+ \ Colon definition
+ [CHAR] : EMIT SPACE DUP ID. SPACE
+ DUP ?IMMEDIATE IF ." IMMEDIATE " THEN CR
+ ENDOF
+ DOVAR OF
+ \ Variable definition
+ ." Variable " DUP ID. CR
+ 2DROP EXIT
+ ENDOF
+ DOCON OF
+ \ Constant definition
+ ." Constant " DUP ID. CR
+ 2DROP EXIT
+ ENDOF
+
+ \ Unknown codeword
+ ." Primitive or word with unrecognized codeword." CR
+ DROP 2DROP EXIT
+ ENDCASE
+
+ ( begin the definition with : NAME [IMMEDIATE] )
+ ( [CHAR] : EMIT SPACE DUP ID. SPACE
+ DUP ?IMMEDIATE IF ." IMMEDIATE " THEN CR 4 )
+
+ 4 SPACES
+
+ >PFA ( get the data address, ie. points after DOCOL | end-of-word start-of-data )
+
+ ( now we start decompiling until we hit the end of the word )
+ BEGIN ( end start )
+ 2DUP >
+ WHILE
+ DUP @ ( end start codeword )
+
+ CASE
+ ['] LIT OF ( is it LIT ? )
+ 1+ DUP @ ( get next word which is the integer constant )
+ . ( and print it )
+ ENDOF
+ ['] LITSTRING OF ( is it LITSTRING ? )
+ [CHAR] S EMIT [CHAR] " EMIT SPACE ( print S"<space> )
+ 1+ DUP @ ( get the length word )
+ SWAP 1+ SWAP ( end start+1 length )
+ 2DUP TYPE ( print the string )
+ [CHAR] " EMIT SPACE ( finish the string with a final quote )
+ + ( end start+1+len, aligned )
+ 1- ( because we're about to add 4 below )
+ ENDOF
+ ['] 0BRANCH OF ( is it 0BRANCH ? )
+ ." 0BRANCH ( "
+ 1+ DUP @ ( print the offset )
+ .
+ ." ) "
+ ENDOF
+ ['] BRANCH OF ( is it BRANCH ? )
+ ." BRANCH ( "
+ 1+ DUP @ ( print the offset )
+ .
+ ." ) "
+ ENDOF
+ ['] ['] OF ( is it ['] ? )
+ ." ['] "
+ 1+ DUP @ ( get the next codeword )
+ CFA> ( and force it to be printed as a dictionary entry )
+ ID. SPACE
+ ENDOF
+ ['] EXIT OF ( is it EXIT? )
+ ( We expect the last word to be EXIT, and if it is then we don't print it
+ because EXIT is normally implied by ;. EXIT can also appear in the middle
+ of words, and then it needs to be printed. )
+ 2DUP ( end start end start )
+ 1+ ( end start end start+1 )
+ <> IF ( end start | we're not at the end )
+ ." EXIT "
+ THEN
+ ENDOF
+ ( default case: )
+ DUP ( in the default case we always need to DUP before using )
+ CFA> ( look up the codeword to get the dictionary entry )
+ ID. SPACE ( and print it )
+ ENDCASE
+
+ 1+ ( end start+1 )
+ REPEAT
+
+ [CHAR] ; EMIT CR
+
+ 2DROP ( restore stack )
+;
+
+
+( MEMORY ------------------------------------------------------------------ )
+
+: UNUSED ( -- cells )
+ MEMSIZE HERE - ;