elopher.el

   1 ;;; elopher.el --- gopher client
   2
   3 ;;; Commentary:
   4
   5 ;; Simple gopher client in elisp.
   6
   7 ;;; Code:
   8
   9 ;;; Global constants
  10 ;;
  11
  12 (defconst elopher-version "1.0.0"
  13   "Current version of elopher.")
  14
  15 (defconst elopher-margin-width 6
  16   "Width of left-hand margin used when rendering indicies.")
  17
  18 (defconst elopher-start-index
  19   (string-join
  20    (list "i\tfake\tfake\t1"
  21          "i--------------------------------------------\tfake\tfake\t1"
  22          "i          Elopher Gopher Client             \tfake\tfake\t1"
  23          (format "i              version %s\tfake\tfake\t1" elopher-version)
  24          "i--------------------------------------------\tfake\tfake\t1"
  25          "i\tfake\tfake\t1"
  26          "iBasic usage:\tfake\tfake\t1"
  27          "i - tab/shift-tab: next/prev directory entry\tfake\tfake\t1"
  28          "i - RET/mouse-1: open directory entry\tfake\tfake\t1"
  29          "i - u: return to parent directory entry\tfake\tfake\t1"
  30          "i - g: go to a particular site\tfake\tfake\t1"
  31          "i - r: reload current page\tfake\tfake\t1"
  32          "i\tfake\tfake\t1"
  33          "iPlaces to start exploring Gopherspace:\tfake\tfake\t1"
  34          "1Floodgap Systems Gopher Server\t\tgopher.floodgap.com\t70"
  35          "1Super-Dimensional Fortress\t\tsdf.org\t70"
  36          "i\tfake\tfake\t1"
  37          "iTest entries:\tfake\tfake\t1"
  38          "pXKCD comic image\t/fun/xkcd/comics/2130/2137/text_entry.png\tgopher.floodgap.com\t70"
  39          "1Test server\t\tlocalhost\t70"
  40          ".")
  41    "\r\n"))
  42
  43
  44 ;;; Customization group
  45 ;;
  46
  47 (defgroup elopher nil
  48   "A simple gopher client."
  49   :group 'applications)
  50
  51 (defcustom elopher-index-face '(foreground-color . "cyan")
  52   "Face used for index records.")
  53 (defcustom elopher-text-face '(foreground-color . "white")
  54   "Face used for text records.")
  55 (defcustom elopher-info-face '(foreground-color . "gray")
  56   "Face used for info records.")
  57 (defcustom elopher-image-face '(foreground-color . "green")
  58   "Face used for image records.")
  59 (defcustom elopher-unknown-face '(foreground-color . "red")
  60   "Face used for unknown record types.")
  61
  62 ;;; Model
  63 ;;
  64
  65 ;; Address
  66
  67 (defun elopher-make-address (selector host port)
  68   (list selector host port))
  69
  70 (defun elopher-address-selector (address)
  71   (car address))
  72
  73 (defun elopher-address-host (address)
  74   (cadr address))
  75
  76 (defun elopher-address-port (address)
  77   (caddr address))
  78
  79 ;; Node
  80
  81 (defun elopher-make-node (parent address getter &optional content pos)
  82   (list parent address getter content pos))
  83
  84 (defun elopher-node-parent (node)
  85   (elt node 0))
  86
  87 (defun elopher-node-address (node)
  88   (elt node 1))
  89
  90 (defun elopher-node-getter (node)
  91   (elt node 2))
  92
  93 (defun elopher-node-content (node)
  94   (elt node 3))
  95
  96 (defun elopher-node-pos (node)
  97   (elt node 4))
  98
  99 (defun elopher-set-node-content (node content)
 100   (setcar (nthcdr 3 node) content))
 101
 102 (defun elopher-set-node-pos (node pos)
 103   (setcar (nthcdr 4 node) pos))
 104
 105 (defun elopher-save-pos ()
 106   (when elopher-current-node
 107     (elopher-set-node-pos elopher-current-node (point))))
 108
 109 (defun elopher-restore-pos ()
 110   (let ((pos (elopher-node-pos elopher-current-node)))
 111     (if pos
 112         (goto-char pos)
 113       (goto-char (point-min)))))
 114
 115 ;; Node graph traversal
 116
 117 (defvar elopher-current-node)
 118
 119 (defun elopher-visit-node (node)
 120   (elopher-save-pos)
 121   (elopher-prepare-buffer)
 122   (setq elopher-current-node node)
 123   (funcall (elopher-node-getter node)))
 124
 125 (defun elopher-visit-parent-node ()
 126   (let ((parent-node (elopher-node-parent elopher-current-node)))
 127     (when parent-node
 128       (elopher-visit-node parent-node))))
 129
 130 (defun elopher-reload-current-node ()
 131   (elopher-set-node-content elopher-current-node nil)
 132   (elopher-visit-node elopher-current-node))
 133
 134
 135 ;;; Buffer preparation
 136 ;;
 137
 138 (defun elopher-prepare-buffer ()
 139   (switch-to-buffer "*elopher*")
 140   (elopher-mode)
 141   (let ((inhibit-read-only t))
 142     (erase-buffer)))
 143
 144
 145 ;;; Index rendering
 146 ;;
 147
 148 (defun elopher-insert-index (string)
 149   "Inserts the index corresponding to STRING into the current buffer."
 150   (dolist (line (split-string string "\r\n"))
 151     (unless (string-empty-p line)
 152       (elopher-insert-index-record line))))
 153
 154 (defun elopher-insert-margin (&optional type-name)
 155   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 156   (if type-name
 157       (progn
 158         (insert (format (concat "%" (number-to-string (- elopher-margin-width 1)) "s")
 159                         (concat
 160                          (propertize "[" 'face '(foreground-color . "blue"))
 161                          (propertize type-name 'face '(foreground-color . "white"))
 162                          (propertize "]" 'face '(foreground-color . "blue")))))
 163         (insert " "))
 164     (insert (make-string elopher-margin-width ?\s))))
 165
 166 (defun elopher-insert-index-record (line)
 167   "Inserts the index record corresponding to LINE into the current buffer."
 168   (let* ((type (elt line 0))
 169          (fields (split-string (substring line 1) "\t"))
 170          (display-string (elt fields 0))
 171          (address (elopher-make-address (elt fields 1) (elt fields 2) (elt fields 3)))
 172          (help-string (format "mouse-1, RET: open %s on %s port %s"
 173                               (elopher-address-selector address)
 174                               (elopher-address-host address)
 175                               (elopher-address-port address))))
 176     (pcase type
 177       (?i (elopher-insert-margin)
 178           (insert (propertize display-string
 179                               'face elopher-info-face)))
 180       (?0 (elopher-insert-margin "T")
 181           (insert-text-button display-string
 182                               'face elopher-text-face
 183                               'elopher-node (elopher-make-node elopher-current-node
 184                                                                address
 185                                                                #'elopher-get-text-node)
 186                               'action #'elopher-click-link
 187                               'follow-link t
 188                               'help-echo help-string))
 189       (?1 (elopher-insert-margin "/")
 190           (insert-text-button display-string
 191                               'face elopher-index-face
 192                               'elopher-node (elopher-make-node elopher-current-node
 193                                                                address
 194                                                                #'elopher-get-index-node)
 195                               'action #'elopher-click-link
 196                               'follow-link t
 197                               'help-echo help-string))
 198       ((or ?g ?p ?I) (elopher-insert-margin "im")
 199           (insert-text-button display-string
 200                               'face elopher-image-face
 201                               'elopher-node (elopher-make-node elopher-current-node
 202                                                                address
 203                                                                #'elopher-get-image-node)
 204                               'action #'elopher-click-link
 205                               'follow-link t
 206                               'help-echo help-string))
 207       (?.) ; Occurs at end of index, can safely ignore.
 208       (tp (elopher-insert-margin (concat (char-to-string tp) "?"))
 209           (insert (propertize display-string
 210                               'face elopher-unknown-face))))
 211     (insert "\n")))
 212
 213
 214 ;;; Selector retrieval (all kinds)
 215 ;;
 216
 217 (defvar elopher-selector-string)
 218
 219 (defun elopher-get-selector (address after &optional binary)
 220   "Retrieve selector specified by ADDRESS and store it in the
 221 string elopher-selector-string, then execute AFTER as the
 222 sentinal function."
 223   (setq elopher-selector-string "")
 224   (let ((p (get-process "elopher-process")))
 225     (if p (delete-process p)))
 226   (make-network-process
 227    :name "elopher-process"
 228    :host (elopher-address-host address)
 229    :service (elopher-address-port address)
 230    :filter (lambda (proc string)
 231              (setq elopher-selector-string (concat elopher-selector-string string)))
 232    :sentinel after)
 233   (process-send-string "elopher-process"
 234                        (concat (elopher-address-selector address) "\n")))
 235
 236 ;; Index retrieval
 237
 238 (defun elopher-get-index-node ()
 239   (let ((content (elopher-node-content elopher-current-node))
 240         (address (elopher-node-address elopher-current-node)))
 241     (if content
 242         (progn
 243           (let ((inhibit-read-only t))
 244             (insert content))
 245           (elopher-restore-pos))
 246       (if address
 247           (elopher-get-selector address
 248                                 (lambda (proc event)
 249                                   (let ((inhibit-read-only t))
 250                                     (elopher-insert-index elopher-selector-string))
 251                                   (elopher-restore-pos)
 252                                   (elopher-set-node-content elopher-current-node
 253                                                             (buffer-string))))
 254         (progn
 255           (let ((inhibit-read-only t))
 256             (elopher-insert-index elopher-start-index))
 257           (elopher-restore-pos)
 258           (elopher-set-node-content elopher-current-node
 259                                     (buffer-string)))))))
 260
 261 ;; Text retrieval
 262
 263 (defun elopher-strip-CRs (string)
 264   (replace-regexp-in-string "\r" "" string))
 265
 266 (defun elopher-get-text-node ()
 267   (let ((content (elopher-node-content elopher-current-node))
 268         (address (elopher-node-address elopher-current-node)))
 269     (if content
 270         (progn
 271           (let ((inhibit-read-only t))
 272             (insert content))
 273           (elopher-restore-pos))
 274       (elopher-get-selector address
 275                             (lambda (proc event)
 276                               (let ((inhibit-read-only t))
 277                                 (insert (elopher-strip-CRs elopher-selector-string)))
 278                               (elopher-restore-pos)
 279                               (elopher-set-node-content elopher-current-node
 280                                                         (buffer-string)))))))
 281
 282 ;; Image retrieval
 283
 284 (defun elopher-get-image-node ()
 285   (let ((content (elopher-node-content elopher-current-node))
 286         (address (elopher-node-address elopher-current-node)))
 287     (if content
 288         (progn
 289           (let ((inhibit-read-only t))
 290             (insert-image content))
 291           (elopher-restore-pos))
 292       (elopher-get-selector address
 293                             (lambda (proc event)
 294                               (let ((image (create-image
 295                                             (string-as-unibyte elopher-selector-string)
 296                                             nil t))
 297                                     (inhibit-read-only t))
 298                                 (insert-image image)
 299                                 (elopher-restore-pos)
 300                                 (elopher-set-node-content elopher-current-node image)))))))
 301
 302
 303
 304 ;;; Navigation procedures
 305 ;;
 306
 307 (defun elopher-next-link ()
 308   (interactive)
 309   (forward-button 1))
 310
 311 (defun elopher-prev-link ()
 312   (interactive)
 313   (backward-button 1))
 314
 315 (defun elopher-click-link (button)
 316   (let ((node (button-get button 'elopher-node)))
 317     (elopher-visit-node node)))
 318
 319 (defun elopher-follow-closest-link ()
 320   (interactive)
 321   (push-button))
 322
 323 (defun elopher-go ()
 324   "Go to a particular gopher site."
 325   (interactive)
 326   (let* ((selector "")
 327          (hostname (read-from-minibuffer "Gopher host: "))
 328          (port 70)
 329          (address (list selector hostname port)))
 330     (elopher-visit-node
 331      (elopher-make-node elopher-current-node
 332                         address
 333                         #'elopher-get-index-node))))
 334
 335 (defun  elopher-reload ()
 336   "Reload current site."
 337   (interactive)
 338   (elopher-reload-current-node))
 339
 340 (defun elopher-back ()
 341   "Go to previous site."
 342   (interactive)
 343   (if (elopher-node-parent elopher-current-node)
 344       (elopher-visit-parent-node)
 345     (message "No previous site.")))
 346
 347
 348 ;;; Mode and keymap
 349 ;;
 350
 351 (defvar elopher-mode-map
 352   (let ((map (make-sparse-keymap)))
 353     (define-key map (kbd "<tab>") 'elopher-next-link)
 354     (define-key map (kbd "<S-tab>") 'elopher-prev-link)
 355     (define-key map (kbd "u") 'elopher-back)
 356     (define-key map (kbd "g") 'elopher-go)
 357     (define-key map (kbd "r") 'elopher-reload)
 358     (when (require 'evil nil t)
 359       (evil-define-key 'normal map
 360         (kbd "C-]") 'elopher-follow-closest-link
 361         (kbd "C-t") 'elopher-back
 362         (kbd "u") 'elopher-back
 363         (kbd "g") 'elopher-go
 364         (kbd "r") 'elopher-reload))
 365     map)
 366   "Keymap for gopher client.")
 367
 368 (define-derived-mode elopher-mode special-mode "elopher"
 369   "Major mode for elopher, an elisp gopher client.")
 370
 371
 372 ;;; Main start procedure
 373 ;;
 374 (defun elopher ()
 375   "Start elopher with default landing page."
 376   (interactive)
 377   (setq elopher-current-node nil)
 378   (let ((start-node (elopher-make-node nil nil #'elopher-get-index-node)))
 379     (elopher-visit-node start-node)))
 380
 381 ;;; elopher.el ends here