elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.1
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.1"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (spartan elpher-get-spartan-page elpher-render-gemini "spt" elpher-spartan)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 ;; Face customizations
 245
 246 (defgroup elpher-faces nil
 247   "Elpher face customizations."
 248   :group 'elpher)
 249
 250 (defface elpher-index
 251   '((t :inherit font-lock-keyword-face))
 252   "Face used for directory type directory records.")
 253
 254 (defface elpher-text
 255   '((t :inherit bold))
 256   "Face used for text type directory records.")
 257
 258 (defface elpher-info
 259   '((t :inherit default))
 260   "Face used for info type directory records.")
 261
 262 (defface elpher-image
 263   '((t :inherit font-lock-string-face))
 264   "Face used for image type directory records.")
 265
 266 (defface elpher-search
 267   '((t :inherit warning))
 268   "Face used for search type directory records.")
 269
 270 (defface elpher-html
 271   '((t :inherit font-lock-comment-face))
 272   "Face used for html type directory records.")
 273
 274 (defface elpher-gemini
 275   '((t :inherit font-lock-constant-face))
 276   "Face used for Gemini type directory records.")
 277
 278 (defface elpher-spartan
 279   '((t :inherit font-lock-constant-face))
 280   "Face used for Spartan type directory records.")
 281
 282 (defface elpher-spartan-post
 283   '((t :inherit font-lock-string-face))
 284   "Face used for Spartan type directory records.")
 285
 286 (defface elpher-other-url
 287   '((t :inherit font-lock-comment-face))
 288   "Face used for other URL type links records.")
 289
 290 (defface elpher-telnet
 291   '((t :inherit font-lock-function-name-face))
 292   "Face used for telnet type directory records.")
 293
 294 (defface elpher-binary
 295   '((t :inherit font-lock-doc-face))
 296   "Face used for binary type directory records.")
 297
 298 (defface elpher-unknown
 299   '((t :inherit error))
 300   "Face used for directory records with unknown/unsupported types.")
 301
 302 (defface elpher-margin-key
 303   '((t :inherit bold))
 304   "Face used for directory margin key.")
 305
 306 (defface elpher-margin-brackets
 307   '((t :inherit shadow))
 308   "Face used for brackets around directory margin key.")
 309
 310 (defface elpher-gemini-heading1
 311   '((t :inherit bold :height 1.8))
 312   "Face used for gemini heading level 1.")
 313
 314 (defface elpher-gemini-heading2
 315   '((t :inherit bold :height 1.5))
 316   "Face used for gemini heading level 2.")
 317
 318 (defface elpher-gemini-heading3
 319   '((t :inherit bold :height 1.2))
 320   "Face used for gemini heading level 3.")
 321
 322 (defface elpher-gemini-quoted
 323   '((t :inherit font-lock-doc-face))
 324   "Face used for gemini quoted texts.")
 325
 326 (defface elpher-gemini-preformatted-toggle
 327   '((t :inherit button))
 328   "Face used for buttons used to toggle display of preformatted text.")
 329
 330 ;;; Model
 331 ;;
 332
 333 ;; Address
 334
 335 ;; An elpher "address" object is either a url object or a symbol.
 336 ;; Addresses with the "about" type, corresponding to pages generated
 337 ;; dynamically for and by elpher.  All others represent pages which
 338 ;; rely on content retrieved over the network.
 339
 340 (defun elpher-address-from-url (url-string &optional default-scheme)
 341   "Create a ADDRESS object corresponding to the given URL-STRING.
 342 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 343 is not explicitly given."
 344   (let ((data (match-data))) ; Prevent parsing clobbering match data
 345     (unwind-protect
 346         (let ((url (url-generic-parse-url url-string)))
 347           (unless (and (not (url-fullness url)) (url-type url))
 348             (unless (url-type url)
 349               (setf (url-type url) default-scheme))
 350             (unless (url-host url)
 351               (let ((p (split-string (url-filename url) "/" nil nil)))
 352                 (setf (url-host url) (car p))
 353                 (setf (url-filename url)
 354                       (if (cdr p)
 355                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 356                         ""))))
 357             (when (not (string-empty-p (url-host url)))
 358               (setf (url-fullness url) t)
 359               (setf (url-host url) (puny-encode-domain (url-host url))))
 360             (when (or (equal "gopher" (url-type url))
 361                       (equal "gophers" (url-type url)))
 362               ;; Gopher defaults
 363               (when (or (equal (url-filename url) "")
 364                         (equal (url-filename url) "/"))
 365                 (setf (url-filename url) "/1")))
 366             (when (equal "gemini" (url-type url))
 367               ;; Gemini defaults
 368               (if (equal (url-filename url) "")
 369                   (setf (url-filename url) "/"))))
 370           (elpher-remove-redundant-ports url))
 371       (set-match-data data))))
 372
 373 (defun elpher-remove-redundant-ports (address)
 374   "Remove redundant port specifiers from ADDRESS.
 375 Here 'redundant' means that the specified port matches the default
 376 for that protocol, eg 70 for gopher."
 377   (if (and (not (elpher-address-about-p address))
 378            (eq (url-portspec address) ; (url-port) is too slow!
 379                (pcase (url-type address)
 380                  ("gemini" 1965)
 381                  ((or "gopher" "gophers") 70)
 382                  ("finger" 79)
 383                  (_ -1))))
 384       (setf (url-portspec address) nil))
 385   address)
 386
 387 (defun elpher-make-gopher-address (type selector host port &optional tls)
 388   "Create an ADDRESS object using gopher directory record attributes.
 389 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 390 If the optional attribute TLS is non-nil, the address will be marked as
 391 requiring gopher-over-TLS."
 392   (cond
 393    ((equal type ?i) nil)
 394    ((and (equal type ?h)
 395          (string-prefix-p "URL:" selector))
 396     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 397    ((equal type ?8)
 398     (elpher-address-from-url
 399      (concat "telnet"
 400              "://" host
 401              ":" (number-to-string port))))
 402    (t
 403     (elpher-address-from-url
 404      (concat "gopher" (if tls "s" "")
 405              "://" host
 406              ":" (number-to-string port)
 407              "/" (string type)
 408              selector)))))
 409
 410 (defun elpher-make-about-address (type)
 411   "Create an ADDRESS object corresponding to the given about address TYPE."
 412   (elpher-address-from-url (concat "about:" (symbol-name type))))
 413
 414 (defun elpher-address-to-url (address)
 415   "Get string representation of ADDRESS."
 416   (url-encode-url (url-recreate-url address)))
 417
 418 (defun elpher-address-type (address)
 419   "Retrieve type of ADDRESS object.
 420 This is used to determine how to retrieve and render the document the
 421 address refers to, via the table `elpher-type-map'."
 422   (pcase (url-type address)
 423     ("about"
 424      (list 'about (intern (url-filename address))))
 425     ((or "gopher" "gophers")
 426      (list 'gopher
 427            (if (member (url-filename address) '("" "/"))
 428                ?1
 429              (string-to-char (substring (url-filename address) 1)))))
 430     ("gemini" 'gemini)
 431     ("spartan" 'spartan)
 432     ("telnet" 'telnet)
 433     ("finger" 'finger)
 434     ("file" 'file)
 435     (_ 'other-url)))
 436
 437 (defun elpher-address-about-p (address)
 438   "Return non-nil if ADDRESS is an  about address."
 439   (pcase (elpher-address-type address) (`(about ,_) t)))
 440
 441 (defun elpher-address-gopher-p (address)
 442   "Return non-nill if ADDRESS object is a gopher address."
 443   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 444
 445 (defun elpher-address-protocol (address)
 446   "Retrieve the transport protocol for ADDRESS."
 447   (url-type address))
 448
 449 (defun elpher-address-filename (address)
 450   "Retrieve the filename component of ADDRESS.
 451 For gopher addresses this is a combination of the selector type and selector."
 452   (url-unhex-string (url-filename address)))
 453
 454 (defun elpher-address-host (address)
 455   "Retrieve host from ADDRESS object."
 456   (let ((host-pre (url-host address)))
 457     ;; The following strips out square brackets which sometimes enclose IPv6
 458     ;; addresses.  Doing this here rather than at the parsing stage may seem
 459     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 460     ;; and reconstruction.  It's also more efficient, as this method is not
 461     ;; called during page rendering.
 462     (if (and (> (length host-pre) 2)
 463              (eq (elt host-pre 0) ?\[)
 464              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 465         (substring host-pre 1 (- (length host-pre) 1))
 466       host-pre)))
 467
 468 (defun elpher-address-user (address)
 469   "Retrieve user from ADDRESS object."
 470   (url-user address))
 471
 472 (defun elpher-address-port (address)
 473   "Retrieve port from ADDRESS object.
 474 If no address is defined, returns 0.  (This is for compatibility with
 475 the URL library.)"
 476   (url-port address))
 477
 478 (defun elpher-address-path-and-query (address)
 479   "Retrieve path and query portion of ADDRESS as a pair."
 480   (let ((path-and-query (url-path-and-query address)))
 481     (cons (car path-and-query)
 482           (url-unhex-string (cdr path-and-query)))))
 483
 484 (defun elpher-gopher-address-selector (address)
 485   "Retrieve gopher selector from ADDRESS object."
 486   (if (member (url-filename address) '("" "/"))
 487       ""
 488     (url-unhex-string (substring (url-filename address) 2))))
 489
 490
 491 ;; Cache
 492
 493 (defvar elpher-content-cache (make-hash-table :test 'equal))
 494 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 495
 496 (defun elpher-get-cached-content (address)
 497   "Retrieve the cached content for ADDRESS, or nil if none exists."
 498   (gethash address elpher-content-cache))
 499
 500 (defun elpher-cache-content (address content)
 501   "Set the content cache for ADDRESS to CONTENT."
 502   (puthash address content elpher-content-cache))
 503
 504 (defun elpher-get-cached-pos (address)
 505   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 506   (gethash address elpher-pos-cache))
 507
 508 (defun elpher-cache-pos (address pos)
 509   "Set the cursor position cache for ADDRESS to POS."
 510   (puthash address pos elpher-pos-cache))
 511
 512
 513 ;; Page
 514
 515 (defun elpher-make-page (display-string address)
 516   "Create a page with DISPLAY-STRING and ADDRESS."
 517   (list display-string address))
 518
 519 (defun elpher-make-start-page ()
 520   "Create the start page."
 521   (elpher-make-page "Start Page"
 522                     (elpher-address-from-url elpher-start-page-url)))
 523
 524 (defun elpher-page-display-string (page)
 525   "Retrieve the display string corresponding to PAGE."
 526   (elt page 0))
 527
 528 (defun elpher-page-address (page)
 529   "Retrieve the address corresponding to PAGE."
 530   (elt page 1))
 531
 532 (defun elpher-page-set-address (page new-address)
 533   "Set the address corresponding to PAGE to NEW-ADDRESS."
 534   (setcar (cdr page) new-address))
 535
 536 (defun elpher-page-from-url (url &optional default-scheme)
 537   "Create a page with address and display string defined by URL.
 538 The URL is unhexed prior to its use as a display string to improve
 539 readability.
 540
 541 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 542 in the instance that URL itself doesn't specify one."
 543   (let ((address (elpher-address-from-url url default-scheme)))
 544     (elpher-make-page (elpher-address-to-iri address) address)))
 545
 546 (defun elpher-address-to-iri (address)
 547   "Return an IRI for ADDRESS.
 548 Decode percent-escapes and handle punycode in the domain name.
 549 Drop the password, if any."
 550   (let ((data (match-data)) ; Prevent parsing clobbering match data
 551         (host (url-host address))
 552         (pass (url-password address)))
 553     (unwind-protect
 554         (let* ((host (url-host address))
 555                (pass (url-password address)))
 556           (when host
 557             (setf (url-host address) (puny-decode-domain host)))
 558           (when pass                             ; RFC 3986 says we should not render
 559             (setf (url-password address) nil)) ; the password as clear text
 560           (elpher-decode (url-unhex-string (url-recreate-url address))))
 561       (setf (url-host address) host)
 562       (setf (url-password address) pass)
 563       (set-match-data data))))
 564
 565 (defvar elpher-current-page nil
 566   "The current page for this Elpher buffer.")
 567
 568 (defvar elpher-history nil
 569   "The local history stack for this Elpher buffer.
 570 This variable is used by `elpher-back' and
 571 `elpher-show-history'.")
 572
 573 (defvar elpher-visited-pages nil
 574   "The global history for all Elpher buffers.
 575 This variable is used by `elpher-show-visited-pages'.")
 576
 577 (defun elpher-visit-page (page &optional renderer no-history)
 578   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 579 Additionally, push PAGE onto the history stack and the list of
 580 previously-visited pages,unless NO-HISTORY is non-nil."
 581   (elpher-save-pos)
 582   (elpher-process-cleanup)
 583   (unless no-history
 584     (unless (or (not elpher-current-page)
 585                  (equal (elpher-page-address elpher-current-page)
 586                         (elpher-page-address page)))
 587       (push elpher-current-page elpher-history)
 588       (unless (or (elpher-address-about-p (elpher-page-address page))
 589                   (and elpher-visited-pages
 590                        (equal page (car elpher-visited-pages))))
 591         (push page elpher-visited-pages))))
 592   (setq-local elpher-current-page page)
 593   (let* ((address (elpher-page-address page))
 594          (type (elpher-address-type address))
 595          (type-record (cdr (assoc type elpher-type-map))))
 596     (if type-record
 597         (funcall (car type-record)
 598                  (if renderer
 599                      renderer
 600                    (cadr type-record)))
 601       (elpher-visit-previous-page)
 602       (pcase type
 603         (`(gopher ,type-char)
 604          (error "Unsupported gopher selector type '%c' for '%s'"
 605                 type-char (elpher-address-to-url address)))
 606         (other
 607          (error "Unsupported address type '%S' for '%s'"
 608                 other (elpher-address-to-url address)))))))
 609
 610 (defun elpher-visit-previous-page ()
 611   "Visit the previous page in the history."
 612   (if elpher-history
 613       (elpher-visit-page (pop elpher-history) nil t)
 614     (error "No previous page")))
 615
 616 (defun elpher-reload-current-page ()
 617   "Reload the current page, discarding any existing cached content."
 618   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 619   (elpher-visit-page elpher-current-page))
 620
 621 (defun elpher-save-pos ()
 622   "Save the current position of point to the current page."
 623   (when elpher-current-page
 624     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 625
 626 (defun elpher-restore-pos ()
 627   "Restore the position of point to that cached in the current page."
 628   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 629     (if pos
 630         (goto-char pos)
 631       (goto-char (point-min)))))
 632
 633 (defun elpher-get-default-url-scheme ()
 634   "Suggest default URL scheme for visiting addresses based on the current page."
 635   (if elpher-current-page
 636       (let* ((address (elpher-page-address elpher-current-page))
 637              (current-type (elpher-address-type address)))
 638         (pcase current-type
 639           ((or (and 'file (guard (not elpher-history)))
 640                `(about ,_))
 641            elpher-default-url-type)
 642           (_
 643            (url-type address))))
 644       elpher-default-url-type))
 645
 646
 647 ;;; Buffer preparation
 648 ;;
 649
 650 (defvar elpher-buffer-name "*elpher*"
 651   "The default name of the Elpher buffer.")
 652
 653 (defun elpher-update-header ()
 654   "If `elpher-use-header' is true, display current page info in window header."
 655   (if (and elpher-use-header elpher-current-page)
 656       (let* ((display-string (elpher-page-display-string elpher-current-page))
 657              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 658              (address (elpher-page-address elpher-current-page))
 659              (tls-string (if (and (not (elpher-address-about-p address))
 660                                   (member (elpher-address-protocol address)
 661                                           '("gophers" "gemini")))
 662                              " [TLS encryption]"
 663                            ""))
 664              (header (concat sanitized-display-string
 665                              (propertize tls-string 'face 'bold))))
 666         (setq header-line-format header))))
 667
 668 (defmacro elpher-with-clean-buffer (&rest args)
 669   "Evaluate ARGS with a clean *elpher* buffer as current."
 670   (declare (debug (body))) ;; Allow edebug to step through body
 671   `(with-current-buffer elpher-buffer-name
 672      (unless (eq major-mode 'elpher-mode)
 673        ;; avoid resetting buffer-local variables
 674        (elpher-mode))
 675      (let ((inhibit-read-only t)
 676            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 677        (setq-local xterm-color--current-fg nil)
 678        (setq-local xterm-color--current-bg nil)
 679        (setq-local network-security-level
 680                    (default-value 'network-security-level))
 681        (erase-buffer)
 682        (elpher-update-header)
 683        ,@args)))
 684
 685 (defun elpher-buffer-message (string &optional line)
 686   "Replace first line in elpher buffer with STRING.
 687 If LINE is non-nil, replace that line instead."
 688   (with-current-buffer elpher-buffer-name
 689     (let ((inhibit-read-only t))
 690       (goto-char (point-min))
 691       (if line
 692           (forward-line line))
 693       (let ((data (match-data)))
 694         (unwind-protect
 695             (progn
 696               (re-search-forward "^.*$")
 697               (replace-match string))
 698           (set-match-data data))))))
 699
 700
 701 ;;; Text Processing
 702 ;;
 703
 704 (defvar elpher-user-coding-system nil
 705   "User-specified coding system to use for decoding text responses.")
 706
 707 (defun elpher-decode (string)
 708   "Decode STRING using autodetected or user-specified coding system."
 709   (decode-coding-string string
 710                         (if elpher-user-coding-system
 711                             elpher-user-coding-system
 712                           (detect-coding-string string t))))
 713
 714 (defun elpher-preprocess-text-response (string)
 715   "Preprocess text selector response contained in STRING.
 716 This involes decoding the character representation, and clearing
 717 away CRs and any terminating period."
 718   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 719                                            (replace-regexp-in-string "\r" "" string))))
 720
 721 ;;; Buttonify urls
 722
 723 (defconst elpher-url-regex
 724   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 725   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 726
 727 (defun elpher-buttonify-urls (string)
 728   "Turn substrings which look like urls in STRING into clickable buttons."
 729   (with-temp-buffer
 730     (insert string)
 731     (goto-char (point-min))
 732     (while (re-search-forward elpher-url-regex nil t)
 733       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 734         (make-text-button (match-beginning 0)
 735                           (match-end 0)
 736                           'elpher-page  page
 737                           'action #'elpher-click-link
 738                           'follow-link t
 739                           'help-echo #'elpher--page-button-help
 740                           'face 'button)))
 741     (buffer-string)))
 742
 743 ;;; ANSI colors or XTerm colors (application and filtering)
 744
 745 (or (require 'xterm-color nil t)
 746     (require 'ansi-color))
 747
 748 (defalias 'elpher-color-filter-apply
 749   (if (fboundp 'xterm-color-filter)
 750       (lambda (s)
 751         (let ((_xterm-color-render nil))
 752           (xterm-color-filter s)))
 753     #'ansi-color-filter-apply)
 754   "A function to filter out ANSI escape sequences.")
 755
 756 (defalias 'elpher-color-apply
 757   (if (fboundp 'xterm-color-filter)
 758       #'xterm-color-filter
 759     #'ansi-color-apply)
 760   "A function to apply ANSI escape sequences.")
 761
 762 ;;; Processing text for display
 763
 764 (defun elpher-process-text-for-display (string)
 765   "Perform any desired processing of STRING prior to display as text.
 766 Currently includes buttonifying URLs and processing ANSI escape codes."
 767   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 768                              (elpher-color-filter-apply string)
 769                            (elpher-color-apply string))))
 770
 771
 772 ;;; Network error reporting
 773 ;;
 774
 775 (defun elpher-network-error (address error)
 776   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 777 ERROR can be either an error object or a string."
 778   (elpher-with-clean-buffer
 779    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 780            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 781            (if (stringp error) error (error-message-string error)) "\n"
 782            (propertize "\n----------------\n\n" 'face 'error)
 783            "Press 'u' to return to the previous page.")))
 784
 785
 786 ;;; General network communication
 787 ;;
 788
 789 (defvar elpher-network-timer nil
 790   "Timer used for network connections.")
 791
 792 (defvar elpher-use-tls nil
 793   "If non-nil, use TLS to communicate with gopher servers.")
 794
 795 (defvar elpher-client-certificate nil
 796   "If non-nil, contains client certificate details to use for TLS connections.")
 797
 798 (defun elpher-process-cleanup ()
 799   "Immediately shut down any extant elpher process and timers."
 800   (let ((p (get-process "elpher-process")))
 801     (if p (delete-process p)))
 802   (if (timerp elpher-network-timer)
 803       (cancel-timer elpher-network-timer)))
 804
 805 (defun elpher-make-network-timer (thunk)
 806   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 807 This is just a wraper around `run-at-time' which additionally sets the
 808 buffer-local variable `elpher-network-timer' to allow
 809 `elpher-process-cleanup' to also clear the timer."
 810   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 811     (setq-local elpher-network-timer timer)
 812     timer))
 813
 814 (defun elpher-get-host-response (address default-port query-string response-processor
 815                                          &optional use-tls force-ipv4)
 816   "Generic function for retrieving data from ADDRESS.
 817
 818 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 819 QUERY-STRING is a string sent to the host specified by ADDRESS to
 820 illicet a response.  This response is passed as an argument to the
 821 function RESPONSE-PROCESSOR.
 822
 823 If non-nil, USE-TLS specifies that the connection is to be made over
 824 TLS.  If set to gemini, the certificate verification will be disabled
 825 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 826
 827 If non-nil, FORCE-IPV4 causes the network connection to be made over
 828 ipv4 only.  (The default behaviour when this is not set depends on
 829 the host operating system and the local network capabilities.)"
 830   (if (and use-tls (not (gnutls-available-p)))
 831       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 832     (unless (< (elpher-address-port address) 65536)
 833       (error "Cannot establish network connection: port number > 65536"))
 834     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 835       (setq-local network-security-level 'low)
 836       (setq-local gnutls-verify-error nil))
 837     (condition-case nil
 838         (let* ((kill-buffer-query-functions nil)
 839                (port (elpher-address-port address))
 840                (host (elpher-address-host address))
 841                (service (if (> port 0) port default-port))
 842                (response-string-parts nil)
 843                (bytes-received 0)
 844                (hkbytes-received 0)
 845                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 846                (gnutls-params (list :type 'gnutls-x509pki
 847                                     :hostname host
 848                                     :keylist
 849                                     (elpher-get-current-keylist address)))
 850                (timer (elpher-make-network-timer
 851                                    (lambda ()
 852                                      (elpher-process-cleanup)
 853                                      (cond
 854                                         ; Try again with IPv4
 855                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 856                                        (message "Connection timed out.  Retrying with IPv4.")
 857                                        (elpher-get-host-response address default-port
 858                                                                  query-string
 859                                                                  response-processor
 860                                                                  use-tls t))
 861                                       ((and use-tls
 862                                             (not (eq use-tls 'gemini))
 863                                             (or elpher-auto-disengage-TLS
 864                                                 (y-or-n-p
 865                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 866                                        (setq elpher-use-tls nil)
 867                                        (elpher-get-host-response address default-port
 868                                                                  query-string
 869                                                                  response-processor
 870                                                                  nil force-ipv4))
 871                                       (t
 872                                        (elpher-network-error address "Connection time-out."))))))
 873                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 874                        (make-network-process :name "elpher-process"
 875                                              :host host
 876                                              :family (and (or force-ipv4
 877                                                               elpher-ipv4-always)
 878                                                           'ipv4)
 879                                              :service service
 880                                              :buffer nil
 881                                              :nowait t
 882                                              :tls-parameters
 883                                              (and use-tls
 884                                                   (cons 'gnutls-x509pki
 885                                                         (apply #'gnutls-boot-parameters
 886                                                                gnutls-params)))))))
 887           (setq elpher-network-timer timer)
 888           (set-process-coding-system proc 'binary 'binary)
 889           (set-process-query-on-exit-flag proc nil)
 890           (elpher-buffer-message (concat "Connecting to " host "..."
 891                                          " (press 'u' to abort)"))
 892           (set-process-filter proc
 893                               (lambda (_proc string)
 894                                 (when timer
 895                                   (cancel-timer timer)
 896                                   (setq timer nil))
 897                                 (setq bytes-received (+ bytes-received (length string)))
 898                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 899                                   (when (> new-hkbytes-received hkbytes-received)
 900                                     (setq hkbytes-received new-hkbytes-received)
 901                                     (elpher-buffer-message
 902                                      (concat "("
 903                                              (number-to-string (/ hkbytes-received 10.0))
 904                                              " MB read)")
 905                                      1)))
 906                                 (setq response-string-parts
 907                                       (cons string response-string-parts))))
 908           (set-process-sentinel proc
 909                                 (lambda (proc event)
 910                                   (when timer
 911                                     (cancel-timer timer))
 912                                   (condition-case the-error
 913                                       (cond
 914                                        ((string-prefix-p "open" event)    ; request URL
 915                                         (elpher-buffer-message
 916                                          (concat "Connected to " host ". Receiving data..."
 917                                                  " (press 'u' to abort)"))
 918                                         (let ((inhibit-eol-conversion t))
 919                                           (process-send-string proc query-string)))
 920                                        ((string-prefix-p "deleted" event)) ; do nothing
 921                                        ((and (not response-string-parts)
 922                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 923                                         ; Try again with IPv4
 924                                         (message "Connection failed. Retrying with IPv4.")
 925                                         (elpher-get-host-response address default-port
 926                                                                   query-string
 927                                                                   response-processor
 928                                                                   use-tls t))
 929                                        (response-string-parts
 930                                         (elpher-with-clean-buffer
 931                                          (insert "Data received.  Rendering..."))
 932                                         (funcall response-processor
 933                                                  (apply #'concat (reverse response-string-parts)))
 934                                         (elpher-restore-pos))
 935                                        (t
 936                                         (error "No response from server")))
 937                                     (error
 938                                      (elpher-network-error address the-error)))))
 939           (when socks
 940             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 941             (funcall (process-sentinel proc) proc "open\n")))
 942       (error
 943        (elpher-process-cleanup)
 944        (error "Error initiating connection to server")))))
 945
 946
 947 ;;; Client-side TLS Certificate Management
 948 ;;
 949
 950 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 951   "Generate a key and a self-signed client TLS certificate using openssl.
 952
 953 The Common Name field of the certificate is set to COMMON-NAME.  The
 954 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 955 the key and certificate files to write.
 956
 957 If TEMPORARY is non-nil, the certificate will be given an exporation
 958 period of one day, and the key and certificate files will be deleted
 959 when the certificate is no longer needed for the current session.
 960
 961 Otherwise, the certificate will be given a 100 year expiration period
 962 and the files will not be deleted.
 963
 964 The function returns a list containing the current host name, the
 965 temporary flag, and the key and cert file names in the form required
 966 by `gnutls-boot-parameters`."
 967   (let ((exp-key-file (expand-file-name key-file))
 968         (exp-cert-file (expand-file-name cert-file)))
 969     (condition-case nil
 970         (progn
 971           (call-process elpher-openssl-command nil nil nil
 972                         "req" "-x509" "-newkey" "rsa:2048"
 973                         "-days" (if temporary "1" "36500")
 974                         "-nodes"
 975                         "-subj" (concat "/CN=" common-name)
 976                         "-keyout" exp-key-file
 977                         "-out" exp-cert-file)
 978           (list (elpher-address-host (elpher-page-address elpher-current-page))
 979                 temporary exp-key-file exp-cert-file))
 980       (error
 981        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 982        (error "Program 'openssl', required for certificate generation, not found")))))
 983
 984 (defun elpher-generate-throwaway-certificate ()
 985   "Generate and return details of a throwaway certificate.
 986 The key and certificate files will be deleted when they are no
 987 longer needed for this session."
 988   (let* ((file-base (make-temp-name "elpher"))
 989          (key-file (concat temporary-file-directory file-base ".key"))
 990          (cert-file (concat temporary-file-directory file-base ".crt")))
 991     (elpher-generate-certificate file-base key-file cert-file t)))
 992
 993 (defun elpher-generate-persistent-certificate (file-base common-name)
 994   "Generate and return details of a persistent certificate.
 995 The argument FILE-BASE is used as the base for the key and certificate
 996 files, while COMMON-NAME specifies the common name field of the
 997 certificate.
 998
 999 The key and certificate files are written to in `elpher-certificate-directory'."
1000   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1001          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1002     (elpher-generate-certificate common-name key-file cert-file)))
1003
1004 (defun elpher-get-existing-certificate (file-base)
1005   "Return a certificate object corresponding to an existing certificate.
1006 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
1007 the directory `elpher-certificate-directory'."
1008   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1009          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1010     (list (elpher-address-host (elpher-page-address elpher-current-page))
1011           nil
1012           (expand-file-name key-file)
1013           (expand-file-name cert-file))))
1014
1015 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1016   "Install a key+certificate file pair in `elpher-certificate-directory'.
1017 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1018 certificate files to install.  The argument FILE-BASE is used as the
1019 base for the installed key and certificate files."
1020   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1021          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1022     (if (or (file-exists-p key-file)
1023             (file-exists-p cert-file))
1024         (error "A certificate with base name %s is already installed" file-base))
1025     (copy-file key-file-src key-file)
1026     (copy-file cert-file-src cert-file)
1027     (list (elpher-address-host (elpher-page-address elpher-current-page))
1028           nil
1029           (expand-file-name key-file)
1030           (expand-file-name cert-file))))
1031
1032 (defun elpher-list-existing-certificates ()
1033   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1034   (unless (file-directory-p elpher-certificate-directory)
1035     (make-directory elpher-certificate-directory))
1036   (mapcar
1037    (lambda (file)
1038      (file-name-sans-extension file))
1039    (directory-files elpher-certificate-directory nil "\\.key$")))
1040
1041 (defun elpher-forget-current-certificate ()
1042   "Causes any current certificate to be forgotten.)
1043 In the case of throwaway certificates, the key and certificate files
1044 are also deleted."
1045   (interactive)
1046   (when elpher-client-certificate
1047     (unless (and (called-interactively-p 'any)
1048                  (not (y-or-n-p (concat "Really forget client certificate? "
1049                                         "(Throwaway certificates will be deleted.)"))))
1050       (when (cadr elpher-client-certificate)
1051         (delete-file (elt elpher-client-certificate 2))
1052         (delete-file (elt elpher-client-certificate 3)))
1053       (setq elpher-client-certificate nil)
1054       (if (called-interactively-p 'any)
1055           (message "Client certificate forgotten.")))))
1056
1057 (defun elpher-get-current-keylist (address)
1058   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1059
1060 This is obtained from the client certificate described by
1061 `elpher-current-certificate', if one is available and the host for
1062 that certificate matches the host in ADDRESS.
1063
1064 If `elpher-current-certificate' is non-nil, and its host name doesn't
1065 match that of ADDRESS, the certificate is forgotten."
1066   (if elpher-client-certificate
1067       (if (string= (car elpher-client-certificate)
1068                    (elpher-address-host address))
1069           (list (cddr elpher-client-certificate))
1070         (elpher-forget-current-certificate)
1071         (message "Disabling client certificate for new host")
1072         nil)
1073     nil))
1074
1075
1076 ;;; Gopher selector retrieval
1077 ;;
1078
1079 (defun elpher-get-gopher-response (address renderer)
1080   "Get response string from gopher server at ADDRESS and render using RENDERER."
1081   (elpher-get-host-response address 70
1082                             (concat (elpher-gopher-address-selector address) "\r\n")
1083                             renderer
1084                             (or (string= (elpher-address-protocol address) "gophers")
1085                                 elpher-use-tls)))
1086
1087 (defun elpher-get-gopher-page (renderer)
1088   "Getter function for gopher pages.
1089 The RENDERER procedure is used to display the contents of the page
1090 once they are retrieved from the gopher server."
1091   (let* ((address (elpher-page-address elpher-current-page))
1092          (content (elpher-get-cached-content address)))
1093     (if (and content (funcall renderer nil))
1094         (elpher-with-clean-buffer
1095          (insert content)
1096          (elpher-restore-pos))
1097       (elpher-with-clean-buffer
1098        (insert "LOADING... (use 'u' to cancel)\n"))
1099       (condition-case the-error
1100           (elpher-get-gopher-response address renderer)
1101         (error
1102          (elpher-network-error address the-error))))))
1103
1104 ;; Index rendering
1105
1106 (defun elpher-insert-margin (&optional type-name)
1107   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1108   (if type-name
1109       (progn
1110         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1111                         (concat
1112                          (propertize "[" 'face 'elpher-margin-brackets)
1113                          (propertize type-name 'face 'elpher-margin-key)
1114                          (propertize "]" 'face 'elpher-margin-brackets))))
1115         (insert " "))
1116     (insert (make-string elpher-margin-width ?\s))))
1117
1118 (defun elpher--page-button-help (_window buffer pos)
1119   "Function called by Emacs to generate mouse-over text.
1120 The arguments specify the BUFFER and the POS within the buffer of the item
1121 for which help is required.  The function returns the help to be
1122 displayed.  The _WINDOW argument is currently unused."
1123   (with-current-buffer buffer
1124     (let ((button (button-at pos)))
1125       (when button
1126         (let* ((page (button-get button 'elpher-page))
1127                (address (elpher-page-address page)))
1128           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1129
1130 (defun elpher-insert-index-record (display-string &optional address)
1131   "Function to insert an index record into the current buffer.
1132 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1133 If ADDRESS is not supplied or nil the record is rendered as an
1134 'information' line."
1135   (let* ((type (if address (elpher-address-type address) nil))
1136          (type-map-entry (cdr (assoc type elpher-type-map))))
1137     (if type-map-entry
1138         (let* ((margin-code (elt type-map-entry 2))
1139                (face (elt type-map-entry 3))
1140                (filtered-display-string (elpher-color-filter-apply display-string))
1141                (page (elpher-make-page filtered-display-string address)))
1142           (elpher-insert-margin margin-code)
1143           (insert-text-button filtered-display-string
1144                               'face face
1145                               'elpher-page page
1146                               'action #'elpher-click-link
1147                               'follow-link t
1148                               'help-echo #'elpher--page-button-help))
1149       (pcase type
1150         ('nil ;; Information
1151          (elpher-insert-margin)
1152          (let ((propertized-display-string
1153                 (propertize display-string 'face 'elpher-info)))
1154            (insert (elpher-process-text-for-display propertized-display-string))))
1155         (`(gopher ,selector-type) ;; Unknown
1156          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1157          (insert (propertize display-string
1158                              'face 'elpher-unknown)))))
1159     (insert "\n")))
1160
1161 (defun elpher-click-link (button)
1162   "Function called when the gopher link BUTTON is activated."
1163   (let ((page (button-get button 'elpher-page)))
1164     (elpher-visit-page page)))
1165
1166 (defun elpher-render-index (data &optional _mime-type-string)
1167   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1168   (elpher-with-clean-buffer
1169    (if (not data)
1170        t
1171      (let ((data-processed (elpher-preprocess-text-response data)))
1172        (dolist (line (split-string data-processed "\n"))
1173          (ignore-errors
1174            (unless (= (length line) 0)
1175              (let* ((type (elt line 0))
1176                     (fields (split-string (substring line 1) "\t"))
1177                     (display-string (elt fields 0))
1178                     (selector (elt fields 1))
1179                     (host (elt fields 2))
1180                     (port (if (elt fields 3)
1181                               (string-to-number (elt fields 3))
1182                             nil))
1183                     (address (elpher-make-gopher-address type selector host port)))
1184                (elpher-insert-index-record display-string address))))))
1185      (elpher-cache-content (elpher-page-address elpher-current-page)
1186                            (buffer-string)))))
1187
1188 ;; Text rendering
1189
1190 (defun elpher-render-text (data &optional _mime-type-string)
1191   "Render DATA as text.  MIME-TYPE-STRING is unused."
1192   (elpher-with-clean-buffer
1193    (if (not data)
1194        t
1195      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1196      (elpher-cache-content
1197       (elpher-page-address elpher-current-page)
1198       (buffer-string)))))
1199
1200 ;; Image retrieval
1201
1202 (defun elpher-render-image (data &optional _mime-type-string)
1203   "Display DATA as image.  MIME-TYPE-STRING is unused."
1204   (if (not data)
1205       nil
1206     (if (display-images-p)
1207         (let* ((image (create-image
1208                        data
1209                        nil t)))
1210           (if (not image)
1211               (error "Unsupported image format")
1212             (let ((window (get-buffer-window elpher-buffer-name)))
1213               (when window
1214                 (setf (image-property image :max-width) (window-body-width window t))
1215                 (setf (image-property image :max-height) (window-body-height window t))))
1216             (elpher-with-clean-buffer
1217              (insert-image image)
1218              (elpher-restore-pos))))
1219       (elpher-render-download data))))
1220
1221 ;; Search retrieval and rendering
1222
1223 (defun elpher-get-gopher-query-page (renderer)
1224   "Getter for gopher addresses requiring input.
1225 The response is rendered using the rendering function RENDERER."
1226   (let* ((address (elpher-page-address elpher-current-page))
1227          (content (elpher-get-cached-content address))
1228          (aborted t))
1229     (if (and content (funcall renderer nil))
1230         (elpher-with-clean-buffer
1231          (insert content)
1232          (elpher-restore-pos)
1233          (message "Displaying cached search results.  Reload to perform a new search."))
1234       (unwind-protect
1235           (let* ((query-string (read-string "Query: "))
1236                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1237                  (search-address (elpher-make-gopher-address ?1
1238                                                              query-selector
1239                                                              (elpher-address-host address)
1240                                                              (elpher-address-port address)
1241                                                              (equal (elpher-address-type address) "gophers"))))
1242             (setq aborted nil)
1243
1244             (elpher-with-clean-buffer
1245              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1246             (elpher-get-gopher-response search-address renderer))
1247         (if aborted
1248             (elpher-visit-previous-page))))))
1249
1250 ;; Raw server response rendering
1251
1252 (defun elpher-render-raw (data &optional mime-type-string)
1253   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1254   (if (not data)
1255       nil
1256     (elpher-with-clean-buffer
1257      (when mime-type-string
1258        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1259      (insert data)
1260      (goto-char (point-min)))
1261     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1262
1263 ;; File save "rendering"
1264
1265 (defun elpher-render-download (data &optional _mime-type-string)
1266   "Save DATA to file.  MIME-TYPE-STRING is unused."
1267   (if (not data)
1268       nil
1269     (let* ((address (elpher-page-address elpher-current-page))
1270            (selector (if (elpher-address-gopher-p address)
1271                          (elpher-gopher-address-selector address)
1272                        (elpher-address-filename address))))
1273       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1274       (let* ((filename-proposal (file-name-nondirectory selector))
1275              (filename (read-file-name "Download complete. Save file as: "
1276                                        nil nil nil
1277                                        (if (> (length filename-proposal) 0)
1278                                            filename-proposal
1279                                          "download.file"))))
1280         (let ((coding-system-for-write 'binary))
1281           (with-temp-file filename
1282             (insert data)))
1283         (message (format "Saved to file %s." filename))))))
1284
1285 ;; HTML rendering
1286
1287 (defun elpher-render-html (data &optional _mime-type-string)
1288   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1289   (elpher-with-clean-buffer
1290    (if (not data)
1291        t
1292      (let ((dom (with-temp-buffer
1293                   (insert data)
1294                   (libxml-parse-html-region (point-min) (point-max)))))
1295        (shr-insert-document dom)))))
1296
1297 ;; Gemini page retrieval
1298
1299 (defvar elpher-gemini-redirect-chain)
1300
1301 (defun elpher-get-gemini-response (address renderer)
1302   "Get response string from gemini server at ADDRESS and render using RENDERER."
1303   (elpher-get-host-response address 1965
1304                             (concat (elpher-address-to-url address) "\r\n")
1305                             (lambda (response-string)
1306                               (elpher-process-gemini-response response-string renderer))
1307                             'gemini))
1308
1309 (defun elpher-parse-gemini-response (response)
1310   "Parse the RESPONSE string and return a list of components.
1311 The list is of the form (code meta body).  A response of nil implies
1312 that the response was malformed."
1313   (let ((header-end-idx (string-match "\r\n" response)))
1314     (if header-end-idx
1315         (let ((header (string-trim (substring response 0 header-end-idx)))
1316               (body (substring response (+ header-end-idx 2))))
1317           (if (>= (length header) 2)
1318               (let ((code (substring header 0 2))
1319                     (meta (string-trim (substring header 2))))
1320                 (list code meta body))
1321             (error "Malformed response: No response status found in header %s" header)))
1322       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1323
1324 (defun elpher-process-gemini-response (response-string renderer)
1325   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1326   (let ((response-components (elpher-parse-gemini-response response-string)))
1327     (let ((response-code (elt response-components 0))
1328           (response-meta (elt response-components 1))
1329           (response-body (elt response-components 2)))
1330       (pcase (elt response-code 0)
1331         (?1 ; Input required
1332          (elpher-with-clean-buffer
1333           (insert "Gemini server is requesting input."))
1334          (let* ((query-string
1335                  (if (eq (elt response-code 1) ?1)
1336                      (read-passwd (concat response-meta ": "))
1337                    (read-string (concat response-meta ": "))))
1338                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1339                 (old-fname (url-filename query-address)))
1340            (setf (url-filename query-address)
1341                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1342            (elpher-get-gemini-response query-address renderer)))
1343         (?2 ; Normal response
1344          (funcall renderer response-body response-meta))
1345         (?3 ; Redirect
1346          (message "Following redirect to %s" response-meta)
1347          (if (>= (length elpher-gemini-redirect-chain) 5)
1348              (error "More than 5 consecutive redirects followed"))
1349          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1350            (if (member redirect-address elpher-gemini-redirect-chain)
1351                (error "Redirect loop detected"))
1352            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1353                (error "Server tried to automatically redirect to non-gemini URL: %s"
1354                       response-meta))
1355            (elpher-page-set-address elpher-current-page redirect-address)
1356            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1357            (elpher-get-gemini-response redirect-address renderer)))
1358         (?4 ; Temporary failure
1359          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1360                 response-code response-meta))
1361         (?5 ; Permanent failure
1362          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1363                 response-code response-meta))
1364         (?6 ; Client certificate required
1365          (elpher-with-clean-buffer
1366           (if elpher-client-certificate
1367               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1368             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1369           (auto-fill-mode 1)
1370           (elpher-gemini-insert-text response-meta))
1371          (let ((chosen-certificate (elpher-choose-client-certificate)))
1372            (unless chosen-certificate
1373              (error "Gemini server requires a client certificate and none was provided"))
1374            (setq elpher-client-certificate chosen-certificate))
1375          (elpher-with-clean-buffer)
1376          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1377         (_other
1378          (error "Gemini server response unknown: %s %s"
1379                 response-code response-meta))))))
1380
1381 (defun elpher--read-answer-polyfill (question answers)
1382   "Polyfill for `read-answer' in Emacs 26.1.
1383 QUESTION is a string containing a question, and ANSWERS
1384 is a list of possible answers."
1385     (completing-read question (mapcar 'identity answers)))
1386
1387 (if (fboundp 'read-answer)
1388     (defalias 'elpher-read-answer 'read-answer)
1389   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1390
1391 (defun elpher-choose-client-certificate ()
1392   "Prompt for a client certificate to use to establish a TLS connection."
1393   (let* ((read-answer-short t))
1394     (pcase (read-answer "What do you want to do? "
1395                         '(("throwaway" ?t
1396                            "generate and use throw-away certificate")
1397                           ("persistent" ?p
1398                            "generate new or use existing persistent certificate")
1399                           ("abort" ?a
1400                            "stop immediately")))
1401       ("throwaway"
1402        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1403       ("persistent"
1404        (let* ((existing-certificates (elpher-list-existing-certificates))
1405               (file-base (completing-read
1406                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1407                           existing-certificates)))
1408          (if (string-empty-p (string-trim file-base))
1409              nil
1410            (if (member file-base existing-certificates)
1411                (setq elpher-client-certificate
1412                      (elpher-get-existing-certificate file-base))
1413              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1414                                  '(("new" ?n
1415                                     "generate new certificate")
1416                                    ("install" ?i
1417                                     "install existing certificate")
1418                                    ("abort" ?a
1419                                     "stop immediately")))
1420                ("new"
1421                 (let ((common-name (read-string "Common Name field for new certificate: "
1422                                                 file-base)))
1423                   (message "New key and self-signed certificate written to %s"
1424                            elpher-certificate-directory)
1425                   (elpher-generate-persistent-certificate file-base common-name)))
1426                ("install"
1427                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1428                        (key-file (read-file-name "Key file: " nil nil t)))
1429                   (message "Key and certificate installed in %s for future use"
1430                            elpher-certificate-directory)
1431                   (elpher-install-and-use-existing-certificate key-file
1432                                                                cert-file
1433                                                                file-base)))
1434                ("abort" nil))))))
1435       ("abort" nil))))
1436
1437 (defun elpher-get-gemini-page (renderer)
1438   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1439   (let* ((address (elpher-page-address elpher-current-page))
1440          (content (elpher-get-cached-content address)))
1441     (condition-case the-error
1442         (if (and content (funcall renderer nil))
1443             (elpher-with-clean-buffer
1444              (insert content)
1445              (elpher-restore-pos))
1446           (elpher-with-clean-buffer
1447            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1448           (setq elpher-gemini-redirect-chain nil)
1449           (elpher-get-gemini-response address renderer))
1450       (error
1451        (elpher-network-error address the-error)))))
1452
1453 (defun elpher-render-gemini (body &optional mime-type-string)
1454   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1455   (if (not body)
1456       t
1457     (let* ((mime-type-string* (if (or (not mime-type-string)
1458                                       (string-empty-p mime-type-string))
1459                                   "text/gemini; charset=utf-8"
1460                                 mime-type-string))
1461            (mime-type-split (split-string mime-type-string* ";" t))
1462            (mime-type (string-trim (car mime-type-split)))
1463            (parameters (mapcar (lambda (s)
1464                                  (let ((key-val (split-string s "=")))
1465                                    (list (downcase (string-trim (car key-val)))
1466                                          (downcase (string-trim (cadr key-val))))))
1467                                (cdr mime-type-split))))
1468       (when (string-prefix-p "text/" mime-type)
1469         (setq body (decode-coding-string
1470                     body
1471                     (if (assoc "charset" parameters)
1472                         (intern (cadr (assoc "charset" parameters)))
1473                       'utf-8)))
1474         (setq body (replace-regexp-in-string "\r" "" body)))
1475       (pcase mime-type
1476         ((or "text/gemini" "")
1477          (elpher-render-gemini-map body parameters))
1478         ("text/html"
1479          (elpher-render-html body))
1480         ((pred (string-prefix-p "text/"))
1481          (elpher-render-gemini-plain-text body parameters))
1482         ((pred (string-prefix-p "image/"))
1483          (elpher-render-image body))
1484         (_other
1485          (elpher-render-download body))))))
1486
1487 (defun elpher-gemini-get-link-url (link-line)
1488   "Extract the url portion of LINK-LINE, a gemini map file link line.
1489 Returns nil in the event that the contents of the line following the
1490 => prefix are empty."
1491   (let ((l (split-string (substring link-line 2))))
1492     (if l
1493         (string-trim (elt l 0))
1494       nil)))
1495
1496 (defun elpher-gemini-get-link-display-string (link-line)
1497   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1498 Return nil if this portion is not provided."
1499   (let* ((rest (string-trim (substring link-line 2)))
1500          (idx (string-match "[ \t]" rest)))
1501     (and idx
1502          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1503
1504 (defun elpher-collapse-dot-sequences (filename)
1505   "Collapse dot sequences in the (absolute) FILENAME.
1506 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1507   (let* ((path (split-string filename "/" t))
1508          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1509          (path-reversed-normalized
1510           (seq-reduce (lambda (a b)
1511                         (cond ((equal b "..") (cdr a))
1512                               ((equal b ".") a)
1513                               (t (cons b a))))
1514                       path nil))
1515          (path-normalized (reverse path-reversed-normalized)))
1516     (if path-normalized
1517         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1518       "/")))
1519
1520 (defun elpher-address-from-gemini-url (url)
1521   "Extract address from URL with defaults as per gemini map files.
1522 While there's obviously some redundancy here between this function and
1523 `elpher-address-from-url', gemini map file URLs require enough special
1524 treatment that a separate function is warranted."
1525   (let ((address (url-generic-parse-url url))
1526         (current-address (elpher-page-address elpher-current-page)))
1527     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1528       (if (url-host address) ;if there is an explicit host, filenames are absolute
1529           (if (string-empty-p (url-filename address))
1530               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1531         (setf (url-host address) (url-host current-address))
1532         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1533         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1534         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1535           (setf (url-filename address)
1536                 (concat (file-name-directory (url-filename current-address))
1537                         (url-filename address)))))
1538       (when (url-host address)
1539         (setf (url-host address) (puny-encode-domain (url-host address))))
1540       (unless (url-type address)
1541         (setf (url-type address) (url-type current-address)))
1542       (when (equal (url-type address) "gemini")
1543         (setf (url-filename address)
1544               (elpher-collapse-dot-sequences (url-filename address)))))
1545     (elpher-remove-redundant-ports address)))
1546
1547 (defun elpher-gemini-insert-link (link-line)
1548   "Insert link described by LINK-LINE into a text/gemini document."
1549   (let ((url (elpher-gemini-get-link-url link-line)))
1550     (when url
1551       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1552              (address (elpher-address-from-gemini-url url))
1553              (type (if address (elpher-address-type address) nil))
1554              (type-map-entry (cdr (assoc type elpher-type-map)))
1555              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1556         (when type-map-entry
1557           (insert elpher-gemini-link-string)
1558           (let* ((face (elt type-map-entry 3))
1559                  (display-string (or given-display-string
1560                                      (elpher-address-to-iri address)))
1561                  (page (elpher-make-page display-string
1562                                          address)))
1563             (insert-text-button display-string
1564                                 'face face
1565                                 'elpher-page page
1566                                 'action #'elpher-click-link
1567                                 'follow-link t
1568                                 'help-echo #'elpher--page-button-help))
1569           (newline))))))
1570
1571 (defun elpher-gemini-insert-header (header-line)
1572   "Insert header described by HEADER-LINE into a text/gemini document.
1573 The gemini map file line describing the header is given
1574 by HEADER-LINE."
1575   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1576     (let* ((level (length (match-string 1 header-line)))
1577            (header (substring header-line (match-end 0)))
1578            (face (pcase level
1579                    (1 'elpher-gemini-heading1)
1580                    (2 'elpher-gemini-heading2)
1581                    (3 'elpher-gemini-heading3)
1582                    (_ 'default)))
1583            (fill-column (if (display-graphic-p)
1584                             (/ (* fill-column
1585                                   (font-get (font-spec :name (face-font 'default)) :size))
1586                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1587       (unless (display-graphic-p)
1588         (insert (make-string level ?#) " "))
1589       (insert (propertize header
1590                           'face face
1591                           'gemini-heading t
1592                           'rear-nonsticky t))
1593       (newline))))
1594
1595 (defun elpher-gemini-insert-text (text-line)
1596   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1597 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1598 width defined by `elpher-gemini-max-fill-width'."
1599   (string-match
1600    (rx (: line-start
1601           (optional
1602            (group (or (: "*" (+ (any " \t")))
1603                       (: ">" (* (any " \t"))))))))
1604    text-line)
1605   (let* ((line-prefix (match-string 1 text-line))
1606          (processed-text-line
1607           (if line-prefix
1608               (cond ((string-prefix-p "*" line-prefix)
1609                      (concat
1610                       (replace-regexp-in-string "\\*"
1611                                                 elpher-gemini-bullet-string
1612                                                 (match-string 0 text-line))
1613                       (substring text-line (match-end 0))))
1614                     ((string-prefix-p ">" line-prefix)
1615                      (propertize text-line 'face 'elpher-gemini-quoted))
1616                     (t text-line))
1617             text-line))
1618          (fill-prefix (if line-prefix
1619                           (make-string (length (match-string 0 text-line)) ?\s)
1620                         "")))
1621     (insert (elpher-process-text-for-display processed-text-line))
1622     (newline)))
1623
1624 (defun elpher-gemini-pref-expand-collapse (button)
1625   "Function called when the preformatted text toggle BUTTON is activated."
1626   (let ((id (button-get button 'pref-id)))
1627     (if (invisible-p id)
1628         (remove-from-invisibility-spec id)
1629       (add-to-invisibility-spec id))
1630     (redraw-display)))
1631
1632 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1633   "Insert a button for toggling the visibility of preformatted text.
1634 If non-nil, ALT-TEXT is displayed alongside the button."
1635   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1636          (pref-id (intern (concat "pref-"
1637                                   (number-to-string (point))
1638                                   "-"
1639                                   url-string))))
1640     (insert elpher-gemini-preformatted-toggle-bullet)
1641     (when alt-text
1642       (insert (propertize (concat alt-text " ")
1643                           'face 'elpher-gemin-preformatted)))
1644     (insert-text-button elpher-gemini-preformatted-toggle-label
1645                         'action #'elpher-gemini-pref-expand-collapse
1646                         'pref-id pref-id
1647                         'face 'elpher-gemini-preformatted-toggle)
1648     (add-to-invisibility-spec pref-id)
1649     (newline)
1650     pref-id))
1651
1652 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1653   "Insert a LINE of preformatted text.
1654 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1655 can be used to toggle the display of the preformatted text."
1656   (insert (propertize (concat (elpher-process-text-for-display line) "\n")
1657                       'invisible pref-id
1658                       'rear-nonsticky t)))
1659
1660 (defun elpher-render-gemini-map (data _parameters)
1661   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1662   (elpher-with-clean-buffer
1663    (auto-fill-mode 1)
1664    (setq-local buffer-invisibility-spec nil)
1665    (let ((preformatted nil)
1666          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1667      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1668      (dolist (line (split-string data "\n"))
1669        (pcase line
1670          ((rx (: "```" (opt (let alt-text (+ any)))))
1671           (setq preformatted
1672                 (if preformatted
1673                     nil
1674                   (if elpher-gemini-hide-preformatted
1675                       (elpher-gemini-insert-preformatted-toggler alt-text)
1676                     t))))
1677          ((guard  preformatted)
1678           (elpher-gemini-insert-preformatted-line line preformatted))
1679          ((pred (string-prefix-p "=>"))
1680           (elpher-gemini-insert-link line))
1681          ((pred (string-prefix-p "=:"))
1682           (elpher-spartan-insert-query line))
1683          ((pred (string-prefix-p "#"))
1684           (elpher-gemini-insert-header line))
1685          (_ (elpher-gemini-insert-text line))))
1686    (elpher-cache-content
1687     (elpher-page-address elpher-current-page)
1688     (buffer-string)))))
1689
1690 (defun elpher-render-gemini-plain-text (data _parameters)
1691   "Render DATA as plain text file.  PARAMETERS is currently unused."
1692   (elpher-with-clean-buffer
1693    (insert (elpher-process-text-for-display data))
1694    (elpher-cache-content
1695     (elpher-page-address elpher-current-page)
1696     (buffer-string))))
1697
1698 (defun elpher-build-current-imenu-index ()
1699   "Build imenu index for current elpher buffer."
1700   (save-excursion
1701     (goto-char (point-min))
1702     (let ((match nil)
1703           (headers nil))
1704       (while (setq match (text-property-search-forward 'gemini-heading t t))
1705         (push (cons
1706                (buffer-substring-no-properties (prop-match-beginning match)
1707                                                (prop-match-end match))
1708                (prop-match-beginning match))
1709               headers))
1710       (reverse headers))))
1711
1712
1713 ;; Spartan page retrieval
1714
1715 (defvar elpher-spartan-redirect-chain)
1716
1717 (defun elpher-get-spartan-page (renderer)
1718   "Getter which retrieves and renders a Spartan page and renders it using RENDERER."
1719   (let* ((address (elpher-page-address elpher-current-page))
1720          (content (elpher-get-cached-content address)))
1721     (condition-case the-error
1722         (if (and content (funcall renderer nil))
1723             (elpher-with-clean-buffer
1724              (insert content)
1725              (elpher-restore-pos))
1726           (elpher-with-clean-buffer
1727            (insert "LOADING SPARTAN... (use 'u' to cancel)\n"))
1728           (setq elpher-spartan-redirect-chain nil)
1729           (elpher-get-spartan-response address renderer))
1730       (error
1731        (elpher-network-error address the-error)))))
1732
1733 (defun elpher-get-spartan-response (address renderer)
1734   "Get response string from spartan server at ADDRESS and render using RENDERER."
1735   (let* ((host (elpher-address-host address))
1736          (path-and-query (elpher-address-path-and-query address))
1737          (filename (car path-and-query))
1738          (data (cdr path-and-query))
1739          (data-len (length data)))
1740     (elpher-get-host-response address 300
1741                               (concat host " "
1742                                       filename " "
1743                                       (number-to-string data-len) "\r\n"
1744                                       data)
1745                               (lambda (response-string)
1746                                 (elpher-process-spartan-response response-string renderer)))))
1747
1748 (defun elpher-parse-spartan-response (response)
1749   "Parse the RESPONSE string and return a list of components.
1750 The list is of the form (code meta body).  A response of nil implies
1751 that the response was malformed."
1752   (let ((header-end-idx (string-match "\r\n" response)))
1753     (if header-end-idx
1754         (let ((header (string-trim (substring response 0 header-end-idx)))
1755               (body (substring response (+ header-end-idx 2))))
1756           (if (>= (length header) 2)
1757               (let ((code (substring header 0 1))
1758                     (meta (string-trim (substring header 1))))
1759                 (list code meta body))
1760             (error "Malformed response: No response status found in header %s" header)))
1761       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1762
1763 (defun elpher-process-spartan-response (response-string renderer)
1764   "Process the spartan response RESPONSE-STRING and pass the result to RENDERER."
1765   (let ((response-components (elpher-parse-spartan-response response-string)))
1766     (let ((response-code (elt response-components 0))
1767           (response-meta (elt response-components 1))
1768           (response-body (elt response-components 2)))
1769       (pcase (elt response-code 0)
1770         (?2 ; Normal response
1771          (funcall renderer response-body response-meta))
1772         (?3 ; Redirect
1773          (message "Following redirect to %s" response-meta)
1774          (if (>= (length elpher-spartan-redirect-chain) 5)
1775              (error "More than 5 consecutive redirects followed"))
1776          (let* ((current-address (elpher-page-address elpher-current-page))
1777                 (redirect-address (elpher-address-from-url
1778                                    (concat "spartan://"
1779                                            (elpher-address-host current-address)
1780                                            ":"
1781                                            (elpher-address-port current-address)
1782                                            "/"
1783                                            response-meta))))
1784            (if (member redirect-address elpher-spartan-redirect-chain)
1785                (error "Redirect loop detected"))
1786            (elpher-page-set-address elpher-current-page redirect-address)
1787            (add-to-list 'elpher-spartan-redirect-chain redirect-address)
1788            (elpher-get-spartan-response redirect-address renderer)))
1789         (?4 ; Client error
1790          (error "Spartan server reports CLIENT ERROR for this request: %s %s"
1791                 response-code response-meta))
1792         (?5 ; Server error
1793          (error "Spartan server reports SERVER ERROR for this request: %s %s"
1794                 response-code response-meta))
1795         (_other
1796          (error "Spartan server response unknown: %s %s"
1797                 response-code response-meta))))))
1798
1799 (defun elpher-spartan-insert-query (query-line)
1800   "Insert link described by QUERY-LINE into a text/gemini document."
1801   (let ((url (elpher-gemini-get-link-url query-line)))
1802     (when url
1803       (let* ((address (elpher-address-from-gemini-url url))
1804              (given-display-string (elpher-gemini-get-link-display-string query-line))
1805              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1806         (insert elpher-gemini-link-string)
1807         (let ((display-string (or given-display-string url)))
1808           (insert-text-button display-string
1809                               'face 'elpher-spartan-post
1810                               'display-string display-string
1811                               'url (elpher-address-to-url address)
1812                               'action #'elpher-spartan-post
1813                               'follow-link t
1814                               'help-echo #'elpher--page-button-help))
1815         (newline)))))
1816
1817 (defun elpher-spartan-post (button)
1818   "Function called when the spartan post link BUTTON is clicked."
1819   (let* ((display-string (button-get button 'display-string))
1820          (url (button-get button 'url))
1821          (post-url (concat url "?" (url-hexify-string (read-string "Text to post: ")))))
1822     (elpher-visit-page (elpher-make-page
1823                         display-string
1824                         (elpher-address-from-url post-url)))))
1825
1826 ;; Finger page connection
1827
1828 (defun elpher-get-finger-page (renderer)
1829   "Opens a finger connection to the current page address.
1830 The result is rendered using RENDERER."
1831   (let* ((address (elpher-page-address elpher-current-page))
1832          (content (elpher-get-cached-content address)))
1833     (if (and content (funcall renderer nil))
1834         (elpher-with-clean-buffer
1835          (insert content)
1836          (elpher-restore-pos))
1837       (elpher-with-clean-buffer
1838        (insert "LOADING... (use 'u' to cancel)\n"))
1839       (condition-case the-error
1840           (let* ((kill-buffer-query-functions nil)
1841                  (user (let ((filename (elpher-address-filename address)))
1842                          (if (> (length filename) 1)
1843                              (substring filename 1)
1844                            (elpher-address-user address)))))
1845             (elpher-get-host-response address 79
1846                                       (concat user "\r\n")
1847                                       renderer))
1848         (error
1849          (elpher-network-error address the-error))))))
1850
1851
1852 ;; Telnet page connection
1853
1854 (defun elpher-get-telnet-page (renderer)
1855   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1856   (when renderer
1857     (elpher-visit-previous-page)
1858     (error "Command not supported for telnet URLs"))
1859   (let* ((address (elpher-page-address elpher-current-page))
1860          (host (elpher-address-host address))
1861          (port (elpher-address-port address)))
1862     (elpher-visit-previous-page)
1863     (if (> port 0)
1864         (telnet host port)
1865       (telnet host))))
1866
1867
1868 ;; Other URL page opening
1869
1870 (defun elpher-get-other-url-page (renderer)
1871   "Getter which attempts to open the URL specified by the current page.
1872 The RENDERER argument to this getter must be nil."
1873   (when renderer
1874     (elpher-visit-previous-page)
1875     (error "Command not supported for general URLs"))
1876   (let* ((address (elpher-page-address elpher-current-page))
1877          (url (elpher-address-to-url address)))
1878     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1879     (message "Opening URL...")
1880     (if elpher-open-urls-with-eww
1881         (browse-web url)
1882       (browse-url url))))
1883
1884
1885 ;; File page
1886
1887 (defun elpher-get-file-page (renderer)
1888   "Getter which renders a local file using RENDERER.
1889 Assumes UTF-8 encoding for all text files."
1890   (let* ((address (elpher-page-address elpher-current-page))
1891          (filename (elpher-address-filename address)))
1892     (unless (file-exists-p filename)
1893       (elpher-visit-previous-page)
1894         (error "File not found"))
1895     (unless (file-readable-p filename)
1896       (elpher-visit-previous-page)
1897         (error "Could not read from file"))
1898     (let ((body (with-temp-buffer
1899        (let ((coding-system-for-read 'binary)
1900              (coding-system-for-write 'binary))
1901          (insert-file-contents-literally filename)
1902          (encode-coding-string (buffer-string) 'raw-text)))))
1903        (if renderer
1904            (funcall renderer body nil)
1905          (pcase (file-name-extension filename)
1906            ((or  "gmi" "gemini")
1907             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1908            ((or "htm" "html")
1909             (elpher-render-html (decode-coding-string body 'utf-8)))
1910            ((or "txt" "")
1911             (elpher-render-text (decode-coding-string body 'utf-8)))
1912            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1913             (elpher-render-image body))
1914            ((or "gopher" "gophermap")
1915             (elpher-render-index (elpher-decode body)))
1916            (_
1917             (elpher-render-download body))))
1918        (elpher-restore-pos))))
1919
1920
1921 ;; Welcome page retrieval
1922
1923 (defun elpher-get-welcome-page (renderer)
1924   "Getter which displays the welcome page (RENDERER must be nil)."
1925   (when renderer
1926     (elpher-visit-previous-page)
1927     (error "Command not supported for welcome page"))
1928   (elpher-with-clean-buffer
1929    (insert "     --------------------------------------------\n"
1930            "           Elpher Gopher and Gemini Client       \n"
1931            "                   version " elpher-version "\n"
1932            "     --------------------------------------------\n"
1933            "\n"
1934            "Default bindings:\n"
1935            "\n"
1936            " - TAB/Shift-TAB: next/prev item on current page\n"
1937            " - RET/mouse-1: open item under cursor\n"
1938            " - m: select an item on current page by name (autocompletes)\n"
1939            " - u/mouse-3/U: return to previous page or to the start page\n"
1940            " - g: go to a particular address (gopher, gemini, finger)\n"
1941            " - o/O: open a different address selector or the root menu of the current server\n"
1942            " - d/D: download item under cursor or current page\n"
1943            " - i/I: info on item under cursor or current page\n"
1944            " - c/C: copy URL representation of item under cursor or current page\n"
1945            " - a/A: bookmark the item under cursor or current page\n"
1946            " - B: list all bookmarks\n"
1947            " - s/S: show current history stack or all previously visted pages\n"
1948            " - r: redraw current page (using cached contents if available)\n"
1949            " - R: reload current page (regenerates cache)\n"
1950            " - !: set character coding system for gopher (default is to autodetect)\n"
1951            " - T: toggle TLS gopher mode\n"
1952            " - F: forget/discard current TLS client certificate\n"
1953            " - .: display the raw server response for the current page\n"
1954            "\n"
1955            "Start your exploration of gopher space and gemini:\n")
1956    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1957                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1958    (elpher-insert-index-record "Project Gemini home page"
1959                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1960    (insert "\n"
1961            "Alternatively, select a search engine and enter some search terms:\n")
1962    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1963                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1964    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1965                                (elpher-address-from-url "gemini://geminispace.info/search"))
1966    (insert "\n"
1967            "Your bookmarks are stored in your ")
1968    (insert-text-button "bookmark list"
1969                        'face 'link
1970                        'action #'elpher-click-link
1971                        'follow-link t
1972                        'help-echo #'elpher--page-button-help
1973                        'elpher-page
1974                        (elpher-make-page "Elpher Bookmarks"
1975                                          (elpher-make-about-address 'bookmarks)))
1976    (insert ".\n")
1977    (insert (propertize
1978             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1979             'face 'shadow))
1980    (insert "\n"
1981            "The gopher home of the Elpher project is here:\n")
1982    (elpher-insert-index-record "The Elpher Project Page"
1983                                (elpher-make-gopher-address ?1
1984                                                            "/projects/elpher/"
1985                                                            "thelambdalab.xyz"
1986                                                            70))
1987    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1988      (insert "\n"
1989              "The following info documentation is available:\n"
1990              "   - ")
1991      (insert-text-button "Elpher Manual"
1992                          'face 'link
1993                          'action (lambda (_)
1994                                    (interactive)
1995                                    (info "(elpher)"))
1996                          'follow-link t
1997                          'help-echo help-string)
1998      (insert "\n   - ")
1999      (insert-text-button "Changes introduced by the latest release"
2000                        'face 'link
2001                        'action (lambda (_)
2002                                  (interactive)
2003                                  (info "(elpher)News"))
2004                        'follow-link t
2005                        'help-echo help-string))
2006    (insert "\n")
2007    (insert (propertize
2008             (concat "(These documents should be available if you have installed Elpher\n"
2009                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
2010                     " manual yourself.)\n")
2011             'face 'shadow))
2012    (elpher-restore-pos)))
2013
2014
2015 ;; History page retrieval
2016
2017 (defun elpher-show-history ()
2018   "Show the current contents of elpher's history stack.
2019 Use \\[elpher-show-visited-pages] to see the entire history.
2020 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
2021   (interactive)
2022   (elpher-visit-page
2023    (elpher-make-page "Current History Stack"
2024                      (elpher-make-about-address 'history))))
2025
2026 (defun elpher-show-visited-pages ()
2027   "Show the all the pages you've visited using Elpher.
2028 Use \\[elpher-show-history] to see just the current history stack.
2029 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
2030   (interactive)
2031   (elpher-visit-page
2032    (elpher-make-page "Elpher Visted Pages"
2033                      (elpher-make-about-address 'visited-pages))))
2034
2035 (defun elpher-get-history-page (renderer)
2036   "Getter which displays the history page (RENDERER must be nil)."
2037   (when renderer
2038     (elpher-visit-previous-page)
2039     (error "Command not supported for history page"))
2040   (elpher-display-history-links elpher-history "Current history stack"))
2041
2042 (defun elpher-get-visited-pages-page (renderer)
2043   "Getter which displays the list of visited pages (RENDERER must be nil)."
2044   (when renderer
2045     (elpher-visit-previous-page)
2046     (error "Command not supported for history page"))
2047   (elpher-display-history-links
2048    (seq-filter (lambda (page)
2049                  (not (elpher-address-about-p (elpher-page-address page))))
2050                elpher-visited-pages)
2051    "All visited pages"))
2052
2053 (defun elpher-display-history-links (pages title)
2054   "Show all PAGES in an Elpher buffer with a given TITLE."
2055   (let* ((title-line (concat " ---- " title " ----"))
2056          (footer-line (make-string (length title-line) ?-)))
2057     (elpher-with-clean-buffer
2058      (insert title-line "\n\n")
2059      (if pages
2060          (dolist (page pages)
2061            (when page
2062              (let ((display-string (elpher-page-display-string page))
2063                    (address (elpher-page-address page)))
2064                (elpher-insert-index-record display-string address))))
2065        (insert "No history items found.\n"))
2066      (insert "\n " footer-line "\n"
2067              "Select an entry or press 'u' to return to the previous page.")
2068      (elpher-restore-pos))))
2069
2070
2071 ;;; Bookmarks
2072
2073 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
2074 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
2075 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
2076 ;; so on. See the Bookmarks section in the Emacs info manual for more.
2077
2078 (defvar elpher-bookmark-link nil
2079   "Prefer bookmarking a link or the current page.
2080 Bind this variable dynamically, or set it to t.
2081 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2082 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2083
2084 (defun elpher-bookmark-make-record ()
2085   "Return a bookmark record.
2086 If `elpher-bookmark-link' is non-nil and point is on a link button,
2087 return a bookmark record for that link.  Otherwise, return a bookmark
2088 record for the current elpher page."
2089   (let* ((button (and elpher-bookmark-link (button-at (point))))
2090          (page (if button
2091                    (button-get button 'elpher-page)
2092                  elpher-current-page)))
2093     (unless page
2094       (error "Cannot bookmark this link"))
2095     (let* ((address (elpher-page-address page))
2096            (url (elpher-address-to-url address))
2097            (display-string (elpher-page-display-string page))
2098            (pos (if button nil (point))))
2099       (if (elpher-address-about-p address)
2100           (error "Cannot bookmark %s" display-string)
2101         `(,display-string
2102           (defaults . (,display-string))
2103           (position . ,pos)
2104           (location . ,url)
2105           (handler . elpher-bookmark-jump))))))
2106
2107 ;;;###autoload
2108 (defun elpher-bookmark-jump (bookmark)
2109   "Handler used to open a bookmark using elpher.
2110 The argument BOOKMARK is a bookmark record passed to the function.
2111 This handler is responsible for loading the bookmark in some buffer,
2112 then making that buffer the current buffer.  It should not switch
2113 to the buffer."
2114   (let* ((url (cdr (assq 'location bookmark)))
2115          (cleaned-url (string-trim url))
2116          (page (elpher-page-from-url cleaned-url))
2117          (buffer (get-buffer-create elpher-buffer-name)))
2118     (elpher-with-clean-buffer
2119      (elpher-visit-page page))
2120     (set-buffer buffer)
2121     nil))
2122
2123 (defun elpher-bookmark-link ()
2124   "Bookmark the link at point.
2125 To bookmark the current page, use \\[elpher-bookmark-current]."
2126   (interactive)
2127   (let ((elpher-bookmark-link t))
2128     (bookmark-set-no-overwrite)))
2129
2130 (defun elpher-bookmark-current ()
2131   "Bookmark the current page.
2132 To bookmark the link at point use \\[elpher-bookmark-link]."
2133   (interactive)
2134   (call-interactively #'bookmark-set-no-overwrite))
2135
2136 (defun elpher-bookmark-import (file)
2137   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2138   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2139                               (file-readable-p elpher-bookmarks-file))
2140                          elpher-bookmarks-file
2141                        (read-file-name "Old Elpher bookmarks: "
2142                                        user-emacs-directory nil t
2143                                        "elpher-bookmarks"))))
2144   (dolist (bookmark (with-temp-buffer
2145                       (insert-file-contents file)
2146                       (read (current-buffer))))
2147     (let* ((display-string (car bookmark))
2148            (url (cadr bookmark))
2149            (record `(,display-string
2150                      (location . ,url)
2151                      (handler . elpher-bookmark-jump))))
2152       (bookmark-store display-string (cdr record) t)))
2153   (bookmark-save))
2154
2155 (defun elpher-get-bookmarks-page (renderer)
2156   "Getter which displays the bookmarks (RENDERER must be nil)."
2157   (when renderer
2158     (elpher-visit-previous-page)
2159     (error "Command not supported for bookmarks page"))
2160
2161   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2162                                      elpher-bookmarks-file)
2163                                 (locate-user-emacs-file "elpher-bookmarks"))))
2164     (when (and (file-readable-p old-bookmarks-file)
2165                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2166                                  old-bookmarks-file
2167                                  "\" found. Import now?")))
2168       (elpher-bookmark-import old-bookmarks-file)
2169       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2170
2171   (if (and elpher-use-emacs-bookmark-menu
2172            elpher-history)
2173       (progn
2174         (elpher-visit-previous-page)
2175         (call-interactively #'bookmark-bmenu-list))
2176     (elpher-with-clean-buffer
2177      (insert " ---- Elpher Bookmarks ---- \n\n")
2178      (bookmark-maybe-load-default-file)
2179      (dolist (bookmark (bookmark-maybe-sort-alist))
2180        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2181          (let* ((name (car bookmark))
2182                 (url (alist-get 'location (cdr bookmark)))
2183                 (address (elpher-address-from-url url)))
2184            (elpher-insert-index-record name address))))
2185      (when (<= (line-number-at-pos) 3)
2186        (insert "No bookmarked pages found.\n"))
2187      (insert "\n --------------------------\n\n"
2188              "Select an entry or press 'u' to return to the previous page.\n\n"
2189              "Bookmarks can be renamed or deleted via the ")
2190      (insert-text-button "Emacs bookmark menu"
2191                          'action (lambda (_)
2192                                    (interactive)
2193                                    (call-interactively #'bookmark-bmenu-list))
2194                          'follow-link t
2195                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2196      (insert (substitute-command-keys
2197               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2198      (elpher-restore-pos))))
2199
2200 (defun elpher-show-bookmarks ()
2201   "Interactive function to display the current list of elpher bookmarks."
2202   (interactive)
2203   (elpher-visit-page
2204    (elpher-make-page "Elpher Bookmarks"
2205                      (elpher-make-about-address 'bookmarks))))
2206
2207
2208 ;;; Integrations
2209 ;;
2210
2211 ;;; Org
2212
2213 (defun elpher-org-export-link (link description format protocol)
2214   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2215
2216 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2217 of gemini, gopher or finger."
2218   (let* ((url (if (equal protocol "elpher")
2219                   (string-remove-prefix "elpher:" link)
2220                 (format "%s:%s" protocol link)))
2221          (desc (or description url)))
2222     (pcase format
2223       (`gemini (format "=> %s %s" url desc))
2224       (`html (format "<a href=\"%s\">%s</a>" url desc))
2225       (`latex (format "\\href{%s}{%s}" url desc))
2226       (_ (if (not description)
2227              url
2228            (format "%s (%s)" desc url))))))
2229
2230 (defun elpher-org-store-link ()
2231   "Store link to an `elpher' page in Org."
2232   (when (eq major-mode 'elpher-mode)
2233     (let* ((url (elpher-info-current))
2234            (desc (car elpher-current-page))
2235            (protocol (cond
2236                       ((string-prefix-p "gemini:" url) "gemini")
2237                       ((string-prefix-p "gopher:" url) "gopher")
2238                       ((string-prefix-p "finger:" url) "finger")
2239                       (t "elpher"))))
2240       (when (equal "elpher" protocol)
2241         ;; Weird link. Or special inner link?
2242         (setq url (concat "elpher:" url)))
2243       (org-link-store-props :type protocol :link url :description desc)
2244       t)))
2245
2246 (defun elpher-org-follow-link (link protocol)
2247   "Visit a LINK for the given PROTOCOL.
2248
2249 PROTOCOL may be one of gemini, gopher or finger.  This method also
2250 supports the old protocol elpher, where the link is self-contained."
2251   (let ((url (if (equal protocol "elpher")
2252                  (string-remove-prefix "elpher:" link)
2253                (format "%s:%s" protocol link))))
2254     (elpher-go url)))
2255
2256 (defun elpher-org-mode-integration ()
2257   "Set up `elpher' integration for `org-mode'."
2258   (org-link-set-parameters
2259    "elpher"
2260    :store #'elpher-org-store-link
2261    :export (lambda (link description format _plist)
2262              (elpher-org-export-link link description format "elpher"))
2263    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2264   (org-link-set-parameters
2265    "gemini"
2266    :export (lambda (link description format _plist)
2267              (elpher-org-export-link link description format "gemini"))
2268    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2269   (org-link-set-parameters
2270    "gopher"
2271    :export (lambda (link description format _plist)
2272              (elpher-org-export-link link description format "gopher"))
2273    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2274   (org-link-set-parameters
2275    "finger"
2276    :export (lambda (link description format _plist)
2277              (elpher-org-export-link link description format "finger"))
2278    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2279
2280 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2281
2282 ;;; Browse URL
2283
2284 ;;;###autoload
2285 (defun elpher-browse-url-elpher (url &rest _args)
2286   "Browse URL using Elpher.  This function is used by `browse-url'."
2287   (interactive (browse-url-interactive-arg "Elpher URL: "))
2288   (elpher-go url))
2289
2290 ;; Use elpher to open gopher, finger and gemini links
2291 ;; For recent version of `browse-url' package
2292 (if (boundp 'browse-url-default-handlers)
2293     (add-to-list
2294      'browse-url-default-handlers
2295      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2296   ;; Patch `browse-url-browser-function' for older ones. The value of
2297   ;; that variable is `browse-url-default-browser' by default, so
2298   ;; that's the function that gets advised. If the value is an alist,
2299   ;; however, we don't know what to do. Better not interfere?
2300   (when (and (symbolp browse-url-browser-function)
2301              (fboundp browse-url-browser-function))
2302     (advice-add browse-url-browser-function :before-while
2303                 (lambda (url &rest _args)
2304                   "Handle gemini, gopher, and finger schemes using Elpher."
2305                   (let ((scheme (downcase (car (split-string url ":" t)))))
2306                     (if (member scheme '("gemini" "gopher" "finger"))
2307                         ;; `elpher-go' always returns nil, which will stop the
2308                         ;; advice chain here in a before-while
2309                         (elpher-go url)
2310                       ;; chain must continue, then return t.
2311                       t))))))
2312
2313 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2314 (with-eval-after-load 'thingatpt
2315   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2316
2317 ;;; Mu4e:
2318
2319 ;; Make mu4e aware of the gemini world
2320 (setq mu4e~view-beginning-of-url-regexp
2321       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2322
2323 ;;; eww:
2324
2325 ;; Let elpher handle gemini, gopher links in eww buffer.
2326 (setq eww-use-browse-url
2327       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2328
2329
2330 ;;; Interactive procedures
2331 ;;
2332
2333 (defun elpher-next-link ()
2334   "Move point to the next link on the current page."
2335   (interactive)
2336   (forward-button 1))
2337
2338 (defun elpher-prev-link ()
2339   "Move point to the previous link on the current page."
2340   (interactive)
2341   (backward-button 1))
2342
2343 (defun elpher-follow-current-link ()
2344   "Open the link or url at point."
2345   (interactive)
2346   (push-button))
2347
2348 ;;;###autoload
2349 (defun elpher-go (host-or-url)
2350   "Go to a particular gopher site HOST-OR-URL.
2351 When run interactively HOST-OR-URL is read from the minibuffer."
2352   (interactive (list
2353                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2354   (let ((trimmed-host-or-url (string-trim host-or-url)))
2355     (unless (string-empty-p trimmed-host-or-url)
2356       (let ((page (elpher-page-from-url trimmed-host-or-url
2357                                         (elpher-get-default-url-scheme))))
2358         (unless (get-buffer-window elpher-buffer-name t)
2359           (switch-to-buffer elpher-buffer-name))
2360         (elpher-with-clean-buffer
2361          (elpher-visit-page page))
2362         nil)))) ; non-nil value is displayed by eshell
2363
2364 (defun elpher-go-current ()
2365   "Go to a particular URL which is read from the minibuffer.
2366 Unlike `elpher-go', the reader is initialized with the URL of the
2367 current page."
2368   (interactive)
2369   (let* ((address (elpher-page-address elpher-current-page))
2370          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2371                            (elpher-address-to-url address))))
2372     (unless (string-empty-p (string-trim url))
2373       (elpher-visit-page (elpher-page-from-url url)))))
2374
2375 (defun elpher-redraw ()
2376   "Redraw current page."
2377   (interactive)
2378   (elpher-visit-page elpher-current-page))
2379
2380 (defun elpher-reload ()
2381   "Reload current page."
2382   (interactive)
2383   (elpher-reload-current-page))
2384
2385 (defun elpher-toggle-tls ()
2386   "Toggle TLS encryption mode for gopher."
2387   (interactive)
2388   (setq elpher-use-tls (not elpher-use-tls))
2389   (if elpher-use-tls
2390       (if (gnutls-available-p)
2391           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2392         (setq elpher-use-tls nil)
2393         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2394     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2395
2396 (defun elpher-view-raw ()
2397   "View raw server response for current page."
2398   (interactive)
2399   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2400       (error "This page was not generated by a server")
2401     (elpher-visit-page elpher-current-page
2402                        #'elpher-render-raw)))
2403
2404 (defun elpher-back ()
2405   "Go to previous site."
2406   (interactive)
2407   (elpher-visit-previous-page))
2408
2409 (defun elpher-back-to-start ()
2410   "Go all the way back to the start page."
2411   (interactive)
2412   (setq-local elpher-current-page nil)
2413   (setq-local elpher-history nil)
2414   (elpher-visit-page (elpher-make-start-page)))
2415
2416 (defun elpher-download ()
2417   "Download the link at point."
2418   (interactive)
2419   (let ((button (button-at (point))))
2420     (if button
2421         (let ((page (button-get button 'elpher-page)))
2422           (unless page
2423             (error "Not an elpher page"))
2424           (when (elpher-address-about-p (elpher-page-address page))
2425             (error "Cannot download %s" (elpher-page-display-string page)))
2426           (elpher-visit-page (button-get button 'elpher-page)
2427                              #'elpher-render-download))
2428       (error "No link selected"))))
2429
2430 (defun elpher-download-current ()
2431   "Download the current page."
2432   (interactive)
2433   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2434       (error "Cannot download %s"
2435              (elpher-page-display-string elpher-current-page))
2436     (elpher-visit-page (elpher-make-page
2437                         (elpher-page-display-string elpher-current-page)
2438                         (elpher-page-address elpher-current-page))
2439                        #'elpher-render-download
2440                        t)))
2441
2442 (defun elpher--build-link-map ()
2443   "Build alist mapping link names to destination pages in current buffer."
2444   (let ((link-map nil)
2445         (b (next-button (point-min) t)))
2446     (while b
2447       (push (cons (button-label b) b) link-map)
2448       (setq b (next-button (button-start b))))
2449     link-map))
2450
2451 (defun elpher-jump ()
2452   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2453   (interactive)
2454   (let* ((link-map (elpher--build-link-map)))
2455     (if link-map
2456         (let ((key (let ((completion-ignore-case t))
2457                      (completing-read "Directory item/link: "
2458                                       link-map nil t))))
2459           (if (and key (> (length key) 0))
2460               (let ((b (cdr (assoc key link-map))))
2461                 (goto-char (button-start b))
2462                 (button-activate b)))))))
2463
2464 (defun elpher-root-dir ()
2465   "Visit root of current server."
2466   (interactive)
2467   (let ((address (elpher-page-address elpher-current-page)))
2468     (if (not (elpher-address-about-p address))
2469         (if (or (member (url-filename address) '("/" ""))
2470                 (and (elpher-address-gopher-p address)
2471                      (= (length (elpher-gopher-address-selector address)) 0)))
2472             (error "Already at root directory of current server")
2473           (let ((address-copy (elpher-address-from-url
2474                                (elpher-address-to-url address))))
2475             (setf (url-filename address-copy) "")
2476             (elpher-go (elpher-address-to-url address-copy))))
2477       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2478
2479 (defun elpher-info-page (page)
2480   "Display URL of PAGE in minibuffer."
2481   (let* ((address (elpher-page-address page))
2482          (url (elpher-address-to-url address))
2483          (iri (elpher-address-to-iri address)))
2484     (if (equal url iri)
2485         (message "%s" url)
2486       (message "%s (Raw: %s)" iri url))))
2487
2488 (defun elpher-info-link ()
2489   "Display information on page corresponding to link at point."
2490   (interactive)
2491   (let ((button (button-at (point))))
2492     (unless button
2493       (error "No item selected"))
2494     (let ((page (button-get button 'elpher-page)))
2495       (unless page
2496         (error "Not an elpher page"))
2497       (elpher-info-page page))))
2498
2499 (defun elpher-info-current ()
2500   "Display information on current page."
2501   (interactive)
2502   (elpher-info-page elpher-current-page))
2503
2504 (defun elpher-copy-page-url (page)
2505   "Copy URL representation of address of PAGE to `kill-ring'."
2506   (let* ((address (elpher-page-address page))
2507          (url (elpher-address-to-url address)))
2508     (message "Copied \"%s\" to kill-ring/clipboard." url)
2509     (kill-new url)))
2510
2511 (defun elpher-copy-link-url ()
2512   "Copy URL of item at point to `kill-ring'."
2513   (interactive)
2514   (let ((button (button-at (point))))
2515     (unless button
2516       (error "No item selected"))
2517     (let ((page (button-get button 'elpher-page)))
2518       (unless page
2519         (error "Not an elpher page"))
2520       (elpher-copy-page-url page))))
2521
2522 (defun elpher-copy-current-url ()
2523   "Copy URL of current page to `kill-ring'."
2524   (interactive)
2525   (elpher-copy-page-url elpher-current-page))
2526
2527 (defun elpher-set-gopher-coding-system ()
2528   "Specify an explicit character coding system for gopher selectors."
2529   (interactive)
2530   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2531     (setq elpher-user-coding-system system)
2532     (if system
2533         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2534       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2535
2536
2537 ;;; Mode and keymap
2538 ;;
2539
2540 (defvar elpher-mode-map
2541   (let ((map (make-sparse-keymap)))
2542     (define-key map (kbd "TAB") 'elpher-next-link)
2543     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2544     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2545     (define-key map (kbd "u") 'elpher-back)
2546     (define-key map (kbd "-") 'elpher-back)
2547     (define-key map (kbd "^") 'elpher-back)
2548     (define-key map [mouse-3] 'elpher-back)
2549     (define-key map (kbd "U") 'elpher-back-to-start)
2550     (define-key map (kbd "g") 'elpher-go)
2551     (define-key map (kbd "o") 'elpher-go-current)
2552     (define-key map (kbd "O") 'elpher-root-dir)
2553     (define-key map (kbd "s") 'elpher-show-history)
2554     (define-key map (kbd "S") 'elpher-show-visited-pages)
2555     (define-key map (kbd "r") 'elpher-redraw)
2556     (define-key map (kbd "R") 'elpher-reload)
2557     (define-key map (kbd "T") 'elpher-toggle-tls)
2558     (define-key map (kbd ".") 'elpher-view-raw)
2559     (define-key map (kbd "d") 'elpher-download)
2560     (define-key map (kbd "D") 'elpher-download-current)
2561     (define-key map (kbd "m") 'elpher-jump)
2562     (define-key map (kbd "i") 'elpher-info-link)
2563     (define-key map (kbd "I") 'elpher-info-current)
2564     (define-key map (kbd "c") 'elpher-copy-link-url)
2565     (define-key map (kbd "C") 'elpher-copy-current-url)
2566     (define-key map (kbd "a") 'elpher-bookmark-link)
2567     (define-key map (kbd "A") 'elpher-bookmark-current)
2568     (define-key map (kbd "B") 'elpher-show-bookmarks)
2569     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2570     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2571     (when (fboundp 'evil-define-key*)
2572       (evil-define-key*
2573        'motion map
2574        (kbd "TAB") 'elpher-next-link
2575        (kbd "C-") 'elpher-follow-current-link
2576        (kbd "C-t") 'elpher-back
2577        (kbd "u") 'elpher-back
2578        (kbd "-") 'elpher-back
2579        (kbd "^") 'elpher-back
2580        [mouse-3] 'elpher-back
2581        (kbd "U") 'elpher-back-to-start
2582        (kbd "g") 'elpher-go
2583        (kbd "o") 'elpher-go-current
2584        (kbd "O") 'elpher-root-dir
2585        (kbd "s") 'elpher-show-history
2586        (kbd "S") 'elpher-show-visited-pages
2587        (kbd "r") 'elpher-redraw
2588        (kbd "R") 'elpher-reload
2589        (kbd "T") 'elpher-toggle-tls
2590        (kbd ".") 'elpher-view-raw
2591        (kbd "d") 'elpher-download
2592        (kbd "D") 'elpher-download-current
2593        (kbd "m") 'elpher-jump
2594        (kbd "i") 'elpher-info-link
2595        (kbd "I") 'elpher-info-current
2596        (kbd "c") 'elpher-copy-link-url
2597        (kbd "C") 'elpher-copy-current-url
2598        (kbd "a") 'elpher-bookmark-link
2599        (kbd "A") 'elpher-bookmark-current
2600        (kbd "B") 'elpher-show-bookmarks
2601        (kbd "!") 'elpher-set-gopher-coding-system
2602        (kbd "F") 'elpher-forget-current-certificate))
2603     map)
2604   "Keymap for gopher client.")
2605
2606 (define-derived-mode elpher-mode special-mode "elpher"
2607   "Major mode for elpher, an elisp gopher client.
2608
2609 This mode is automatically enabled by the interactive
2610 functions which initialize the client, namely
2611 `elpher', and `elpher-go'."
2612   (setq-local elpher-current-page nil)
2613   (setq-local elpher-history nil)
2614   (setq-local elpher-buffer-name (buffer-name))
2615   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2616   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2617
2618 (when (fboundp 'evil-set-initial-state)
2619   (evil-set-initial-state 'elpher-mode 'motion))
2620
2621
2622 ;;; Main start procedure
2623 ;;
2624
2625 ;;;###autoload
2626 (defun elpher (&optional arg)
2627   "Start elpher with default landing page.
2628 The buffer used for Elpher sessions is determined by the value of
2629 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2630 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2631 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2632 \\[execute-extended-command] elpher RET’) switches to the session with
2633 that number, creating it if necessary.  A non numeric prefix ARG means
2634 to create a new session.  Returns the buffer selected (or created)."
2635   (interactive "P")
2636   (let* ((name (default-value 'elpher-buffer-name))
2637          (buf (cond ((numberp arg)
2638                      (get-buffer-create (format "%s<%d>" name arg)))
2639                     (arg
2640                      (generate-new-buffer name))
2641                     (t
2642                      (get-buffer-create name)))))
2643     (pop-to-buffer-same-window buf)
2644     (unless (buffer-modified-p)
2645       (elpher-mode)
2646       (elpher-visit-page (elpher-make-start-page))
2647       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2648
2649 ;;; elpher.el ends here