elpher.el

   1 ;;; elpher.el --- A friendly gopher client.
   2
   3 ;; Copyright (C) 2019 Tim Vaughan
   4
   5 ;; Author: Tim Vaughan <tgvaughan@gmail.com>
   6 ;; Created: 11 April 2019
   7 ;; Version: 2.0.0
   8 ;; Keywords: comm gopher
   9 ;; Homepage: https://github.com/tgvaughan/elpher
  10 ;; Package-Requires: ((emacs "26"))
  11
  12 ;; This file is not part of GNU Emacs.
  13
  14 ;; This program is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Elpher aims to provide a practical and friendly gopher client
  30 ;; for GNU Emacs.  It supports:
  31
  32 ;; - intuitive keyboard and mouse-driven browsing,
  33 ;; - out-of-the-box compatibility with evil-mode,
  34 ;; - clickable web and gopher links *in plain text*,
  35 ;; - caching of visited sites,
  36 ;; - pleasant and configurable colouring of Gopher directories,
  37 ;; - direct visualisation of image files,
  38 ;; - a simple bookmark management system,
  39 ;; - connections using TLS encryption.
  40
  41 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  42 ;; page containing information on key bindings and suggested starting
  43 ;; points for your gopher exploration.
  44
  45 ;; Full instructions can be found in the Elpher info manual.
  46
  47 ;; Elpher is under active development.  Any suggestions for
  48 ;; improvements are welcome!
  49
  50 ;;; Code:
  51
  52 (provide 'elpher)
  53
  54 ;;; Dependencies
  55 ;;
  56
  57 (require 'seq)
  58 (require 'pp)
  59 (require 'shr)
  60 (require 'url-util)
  61
  62
  63 ;;; Global constants
  64 ;;
  65
  66 (defconst elpher-version "2.0.0"
  67   "Current version of elpher.")
  68
  69 (defconst elpher-margin-width 6
  70   "Width of left-hand margin used when rendering indicies.")
  71
  72 (defconst elpher-type-map
  73   '(((gopher ?0) elpher-get-gopher-node elpher-render-text "txt" elpher-text)
  74     ((gopher ?1) elpher-get-gopher-node elpher-render-index "/" elpher-index)
  75     ((gopher ?4) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  76     ((gopher ?5) elpher-get-gopher-node elpher-render-download "bin" elpher-binary)
  77     ((gopher ?7) elpher-get-gopher-query-node elpher-render-index "?" elpher-search)
  78     ((gopher ?9) elpher-get-gopher-node elpher-render-node-download "bin" elpher-binary)
  79     ((gopher ?g) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  80     ((gopher ?p) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  81     ((gopher ?I) elpher-get-gopher-node elpher-render-image "img" elpher-image)
  82     ((gopher ?d) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  83     ((gopher ?P) elpher-get-gopher-node elpher-render-download "doc" elpher-binary)
  84     ((gopher ?s) elpher-get-gopher-node elpher-render-download "snd" elpher-binary)
  85     ((gopher ?h) elpher-get-gopher-node elpher-render-html "htm" elpher-html)
  86     (gemini elpher-get-gemini-node elpher-render-gemini "gem" elpher-gemini)
  87     (telnet elpher-get-telnet-node nil "tel" elpher-telnet)
  88     (other-url elpher-get-other-url-node nil "url" elpher-other-url)
  89     ((special bookmarks) elpher-get-bookmarks-node nil)
  90     ((special start) elpher-get-start-node nil))
  91   "Association list from types to getters, margin codes and index faces.")
  92
  93
  94 ;;; Customization group
  95 ;;
  96
  97 (defgroup elpher nil
  98   "A gopher client."
  99   :group 'applications)
 100
 101 ;; Face customizations
 102
 103 (defface elpher-index
 104   '((t :inherit font-lock-keyword-face))
 105   "Face used for directory type directory records.")
 106
 107 (defface elpher-text
 108   '((t :inherit bold))
 109   "Face used for text type directory records.")
 110
 111 (defface elpher-info
 112   '((t :inherit default))
 113   "Face used for info type directory records.")
 114
 115 (defface elpher-image
 116   '((t :inherit font-lock-string-face))
 117   "Face used for image type directory records.")
 118
 119 (defface elpher-search
 120   '((t :inherit warning))
 121   "Face used for search type directory records.")
 122
 123 (defface elpher-html
 124   '((t :inherit font-lock-comment-face))
 125   "Face used for html type directory records.")
 126
 127 (defface elpher-gemini
 128   '((t :inherit font-lock-function-name-face))
 129   "Face used for html type directory records.")
 130
 131 (defface elpher-other-url
 132   '((t :inherit font-lock-comment-face))
 133   "Face used for other URL type links records.")
 134
 135 (defface elpher-telnet
 136   '((t :inherit font-lock-function-name-face))
 137   "Face used for telnet type directory records.")
 138
 139 (defface elpher-binary
 140   '((t :inherit font-lock-doc-face))
 141   "Face used for binary type directory records.")
 142
 143 (defface elpher-unknown
 144   '((t :inherit error))
 145   "Face used for directory records with unknown/unsupported types.")
 146
 147 (defface elpher-margin-key
 148   '((t :inherit bold))
 149   "Face used for directory margin key.")
 150
 151 (defface elpher-margin-brackets
 152   '((t :inherit shadow))
 153   "Face used for brackets around directory margin key.")
 154
 155 ;; Other customizations
 156
 157 (defcustom elpher-open-urls-with-eww nil
 158   "If non-nil, open URL selectors using eww.
 159 Otherwise, use the system browser via the BROWSE-URL function."
 160   :type '(boolean))
 161
 162 (defcustom elpher-buttonify-urls-in-directories nil
 163   "If non-nil, turns URLs matched in directories into clickable buttons."
 164   :type '(boolean))
 165
 166 (defcustom elpher-use-header t
 167   "If non-nil, display current node information in buffer header."
 168   :type '(boolean))
 169
 170 (defcustom elpher-auto-disengage-TLS nil
 171   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 172 While enabling this may seem convenient, it is also potentially dangerous as it
 173 allows switching from an encrypted channel back to plain text without user input."
 174   :type '(boolean))
 175
 176
 177 ;;; Model
 178 ;;
 179
 180 ;; Address
 181
 182 ;; An elpher "address" object is either a url object or a symbol.
 183 ;; Symbol addresses are "special", corresponding to pages generated
 184 ;; dynamically for and by elpher.  All others represent pages which
 185 ;; rely on content retrieved over the network.
 186
 187 (defun elpher-address-from-url (url-string)
 188   "Create a ADDRESS object corresponding to the given URL-STRING."
 189   (let ((data (match-data))) ; Prevent parsing clobbering match data
 190     (unwind-protect
 191         (let ((url (url-generic-parse-url url-string)))
 192           (setf (url-fullness url) t)
 193           (setf (url-filename url)
 194                 (url-unhex-string (url-filename url)))
 195           (unless (url-type url)
 196             (setf (url-type url) "gopher"))
 197           (let ((is-gopher (or (equal "gopher" (url-type url))
 198                                (equal "gophers" (url-type url))))
 199                 (is-gemini (equal "gemini" (url-type url))))
 200             (when is-gopher
 201               ;; Gopher defaults
 202               (unless (url-host url)
 203                 (setf (url-host url) (url-filename url))
 204                 (setf (url-filename url) ""))
 205               (when (or (equal (url-filename url) "")
 206                         (equal (url-filename url) "/"))
 207                 (setf (url-filename url) "/1"))))
 208           url)
 209       (set-match-data data))))
 210
 211 (defun elpher-make-gopher-address (type selector host port &optional tls)
 212   "Create an ADDRESS object corresponding to the given gopher directory record
 213 attributes: TYPE, SELECTOR, HOST and PORT."
 214   (if (and (equal type ?h)
 215            (string-prefix-p "URL:" selector))
 216       (elpher-address-from-url (elt (split-string selector "URL:") 1))
 217     (elpher-address-from-url
 218      (concat "gopher" (if tls "s" "")
 219              "://" host
 220              ":" (number-to-string port)
 221              "/" (string type)
 222              selector))))
 223
 224 (defun elpher-make-special-address (type)
 225   "Create an ADDRESS object corresponding to the given special page symbol TYPE."
 226   type)
 227
 228 (defun elpher-address-to-url (address)
 229   "Get string representation of ADDRESS, or nil if ADDRESS is special."
 230   (if (not (elpher-address-special-p address))
 231       (url-encode-url (url-recreate-url address))
 232     nil))
 233
 234 (defun elpher-address-type (address)
 235   "Retrieve selector type from ADDRESS object."
 236   (if (symbolp address)
 237       (list 'special address)
 238     (let ((protocol (url-type address)))
 239       (cond ((or (equal protocol "gopher")
 240                  (equal protocol "gophers"))
 241              (list 'gopher
 242                    (if (member (url-filename address) '("" "/"))
 243                        ?1
 244                      (string-to-char (substring (url-filename address) 1)))))
 245             ((equal protocol "gemini")
 246              'gemini)
 247             (t 'other-url)))))
 248
 249 (defun elpher-address-protocol (address)
 250   (if (symbolp address)
 251       nil
 252     (url-type address)))
 253
 254 (defun elpher-address-filename (address)
 255   (if (symbolp address)
 256       nil
 257     (url-filename address)))
 258
 259 (defun elpher-address-host (address)
 260   "Retrieve host from ADDRESS object."
 261   (url-host address))
 262
 263 (defun elpher-address-port (address)
 264   "Retrieve port from ADDRESS object."
 265   (url-port address))
 266
 267 (defun elpher-address-special-p (address)
 268   "Return non-nil if ADDRESS object is special (e.g. start page, bookmarks page)."
 269   (symbolp address))
 270
 271 (defun elpher-address-gopher-p (address)
 272   "Return non-nill if ADDRESS object is a gopher address."
 273   (and (not (elpher-address-special-p address))
 274        (member (elpher-address-protocol address) '("gopher gophers"))))
 275
 276 (defun elpher-gopher-address-selector (address)
 277   "Retrieve gopher selector from ADDRESS object."
 278   (if (member (url-filename address) '("" "/"))
 279       ""
 280     (substring (url-filename address) 2)))
 281
 282 ;; Node
 283
 284 (defun elpher-make-node (display-string address &optional parent)
 285   "Create a node in the page hierarchy.
 286
 287 DISPLAY-STRING records the display string used for the page.
 288
 289 ADDRESS specifies the address object of the page.
 290
 291 The optional PARENT specifies the parent node in the hierarchy.
 292 This is set every time the node is visited, so while it forms
 293 an important part of the node data there is no need to set it
 294 initially."
 295   (list display-string address parent))
 296
 297 (defun elpher-node-display-string (node)
 298   "Retrieve the display string of NODE."
 299   (elt node 0))
 300
 301 (defun elpher-node-address (node)
 302   "Retrieve the ADDRESS object of NODE."
 303   (elt node 1))
 304
 305 (defun elpher-node-parent (node)
 306   "Retrieve the parent node of NODE."
 307   (elt node 2))
 308
 309 (defun elpher-set-node-parent (node parent)
 310   "Set the parent node of NODE to be PARENT."
 311   (setcar (cdr (cdr node)) parent))
 312
 313 ;; Cache
 314
 315 (defvar elpher-content-cache (make-hash-table :test 'equal))
 316 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 317
 318 (defun elpher-get-cached-content (address)
 319   "Retrieve the cached content for ADDRESS, or nil if none exists."
 320   (gethash address elpher-content-cache))
 321
 322 (defun elpher-cache-content (address content)
 323   "Set the content cache for ADDRESS to CONTENT."
 324   (puthash address content elpher-content-cache))
 325
 326 (defun elpher-get-cached-pos (address)
 327   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 328   (gethash address elpher-pos-cache))
 329
 330 (defun elpher-cache-pos (address pos)
 331   "Set the cursor position cache for ADDRESS to POS."
 332   (puthash address pos elpher-pos-cache))
 333
 334 ;; Node graph traversal
 335
 336 (defvar elpher-current-node nil)
 337
 338 (defun elpher-visit-node (node &optional renderer preserve-parent)
 339   "Visit NODE using its own renderer or RENDERER, if non-nil.
 340 Additionally, set the parent of NODE to `elpher-current-node',
 341 unless PRESERVE-PARENT is non-nil."
 342   (elpher-save-pos)
 343   (elpher-process-cleanup)
 344   (unless preserve-parent
 345     (if (and (elpher-node-parent elpher-current-node)
 346              (equal (elpher-node-address elpher-current-node)
 347                     (elpher-node-address node)))
 348         (elpher-set-node-parent node (elpher-node-parent elpher-current-node))
 349       (elpher-set-node-parent node elpher-current-node)))
 350   (setq elpher-current-node node)
 351   (let* ((address (elpher-node-address node))
 352          (type (elpher-address-type address))
 353          (type-record (cdr (assoc type elpher-type-map))))
 354     (if type-record
 355         (funcall (car type-record)
 356                  (if renderer
 357                      renderer
 358                    (cadr type-record)))
 359       (elpher-visit-parent-node)
 360       (pcase type
 361         (`(gopher ,type-char)
 362          (error "Unsupported gopher selector type '%c' for '%s'"
 363                 type-char (elpher-address-to-url address)))
 364         (else
 365          (error "Unsupported address type '%S' for '%s'"
 366                 type (elpher-address-to-url address)))))))
 367
 368 (defun elpher-visit-parent-node ()
 369   "Visit the parent of the current node."
 370   (let ((parent-node (elpher-node-parent elpher-current-node)))
 371     (when parent-node
 372       (elpher-visit-node parent-node nil t))))
 373
 374 (defun elpher-reload-current-node ()
 375   "Reload the current node, discarding any existing cached content."
 376   (elpher-cache-content (elpher-node-address elpher-current-node) nil)
 377   (elpher-visit-node elpher-current-node))
 378
 379 (defun elpher-save-pos ()
 380   "Save the current position of point to the current node."
 381   (when elpher-current-node
 382     (elpher-cache-pos (elpher-node-address elpher-current-node) (point))))
 383
 384 (defun elpher-restore-pos ()
 385   "Restore the position of point to that cached in the current node."
 386   (let ((pos (elpher-get-cached-pos (elpher-node-address elpher-current-node))))
 387     (if pos
 388         (goto-char pos)
 389       (goto-char (point-min)))))
 390
 391
 392 ;;; Buffer preparation
 393 ;;
 394
 395 (defun elpher-update-header ()
 396   "If `elpher-use-header' is true, display current node info in window header."
 397   (if elpher-use-header
 398       (setq header-line-format (elpher-node-display-string elpher-current-node))))
 399
 400 (defmacro elpher-with-clean-buffer (&rest args)
 401   "Evaluate ARGS with a clean *elpher* buffer as current."
 402   (list 'with-current-buffer "*elpher*"
 403         '(elpher-mode)
 404         (append (list 'let '((inhibit-read-only t))
 405                       '(erase-buffer)
 406                       '(elpher-update-header))
 407                 args)))
 408
 409
 410 ;;; Text Processing
 411 ;;
 412
 413 (defvar elpher-user-coding-system nil
 414   "User-specified coding system to use for decoding text responses.")
 415
 416 (defun elpher-decode (string)
 417   "Decode STRING using autodetected or user-specified coding system."
 418   (decode-coding-string string
 419                         (if elpher-user-coding-system
 420                             elpher-user-coding-system
 421                           (detect-coding-string string t))))
 422
 423 (defun elpher-preprocess-text-response (string)
 424   "Preprocess text selector response contained in STRING.
 425 This involes decoding the character representation, and clearing
 426 away CRs and any terminating period."
 427   (elpher-decode (replace-regexp-in-string "\n\.\n$" "\n"
 428                                            (replace-regexp-in-string "\r" "" string))))
 429
 430
 431 ;;; Index rendering
 432 ;;
 433
 434 ;;; Network error reporting
 435 ;;
 436
 437 (defun elpher-network-error (address error)
 438   (elpher-with-clean-buffer
 439    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 440            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 441            (error-message-string the-error) ".\n"
 442            (propertize "\n----------------\n\n" 'face 'error)
 443            "Press 'u' to return to the previous page.")))
 444
 445
 446 ;;; Gopher selector retrieval (all kinds)
 447 ;;
 448
 449 (defun elpher-process-cleanup ()
 450   "Immediately shut down any extant elpher process."
 451   (let ((p (get-process "elpher-process")))
 452     (if p (delete-process p))))
 453
 454 (defvar elpher-use-tls nil
 455   "If non-nil, use TLS to communicate with gopher servers.")
 456
 457 (defvar elpher-selector-string)
 458
 459 (defun elpher-get-selector (address after &optional propagate-error)
 460   "Retrieve selector specified by ADDRESS, then execute AFTER.
 461 The result is stored as a string in the variable ‘elpher-selector-string’.
 462
 463 Usually errors result in an error page being displayed.  This is only
 464 appropriate if the selector is to be directly viewed.  If PROPAGATE-ERROR
 465 is non-nil, this message is not displayed.  Instead, the error propagates
 466 up to the calling function."
 467   (setq elpher-selector-string "")
 468   (when (equal (elpher-address-protocol address) "gophers")
 469       (if (gnutls-available-p)
 470           (when (not elpher-use-tls)
 471             (setq elpher-use-tls t)
 472             (message "Engaging TLS mode."))
 473         (error "Cannot retrieve TLS selector: GnuTLS not available")))
 474   (condition-case the-error
 475       (let* ((kill-buffer-query-functions nil)
 476              (proc (open-network-stream "elpher-process"
 477                                        nil
 478                                        (elpher-address-host address)
 479                                        (if (> (elpher-address-port address) 0)
 480                                            (elpher-address-port address)
 481                                          70)
 482                                        :type (if elpher-use-tls 'tls 'plain))))
 483         (set-process-coding-system proc 'binary)
 484         (set-process-filter proc
 485                             (lambda (proc string)
 486                               (setq elpher-selector-string
 487                                     (concat elpher-selector-string string))))
 488         (set-process-sentinel proc after)
 489         (process-send-string proc
 490                              (concat (elpher-gopher-address-selector address) "\n")))
 491     (error
 492      (if (and (consp the-error)
 493               (eq (car the-error) 'gnutls-error)
 494               (not (equal (elpher-address-protocol address) "gophers"))
 495               (or elpher-auto-disengage-TLS
 496                   (yes-or-no-p "Could not establish encrypted connection.  Disable TLS mode? ")))
 497          (progn
 498            (message "Disengaging TLS mode.")
 499            (setq elpher-use-tls nil)
 500            (elpher-get-selector address after))
 501        (elpher-process-cleanup)
 502        (if propagate-error
 503            (error the-error)
 504          (elpher-with-clean-buffer
 505           (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 506                   "Failed to connect to " (elpher-address-to-url address) ".\n"
 507                   (propertize "\n----------------\n\n" 'face 'error)
 508                   "Press 'u' to return to the previous page.")))))))
 509
 510 (defun elpher-get-gopher-node (renderer)
 511   (let* ((address (elpher-node-address elpher-current-node))
 512          (content (elpher-get-cached-content address)))
 513     (if (and content (funcall renderer nil))
 514         (progn
 515           (elpher-with-clean-buffer)
 516           (insert content)
 517           (elpher-restore-pos))
 518       (elpher-with-clean-buffer
 519        (insert "LOADING... (use 'u' to cancel)"))
 520       (elpher-get-selector address
 521                            (lambda (proc event)
 522                              (unless (string-prefix-p "deleted" event)
 523                                (funcall renderer elpher-selector-string)
 524                                (elpher-restore-pos)))))))
 525
 526 ;; Index rendering
 527
 528 (defun elpher-insert-index (string)
 529   "Insert the index corresponding to STRING into the current buffer."
 530   ;; Should be able to split directly on CRLF, but some non-conformant
 531   ;; LF-only servers sadly exist, hence the following.
 532   (let ((str-processed (elpher-preprocess-text-response string)))
 533     (dolist (line (split-string str-processed "\n"))
 534       (unless (= (length line) 0)
 535         (let* ((type (elt line 0))
 536                (fields (split-string (substring line 1) "\t"))
 537                (display-string (elt fields 0))
 538                (selector (elt fields 1))
 539                (host (elt fields 2))
 540                (port (if (elt fields 3)
 541                          (string-to-number (elt fields 3))
 542                        nil))
 543                (address (elpher-make-gopher-address type selector host port)))
 544           (elpher-insert-index-record display-string address))))))
 545
 546 (defun elpher-insert-margin (&optional type-name)
 547   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 548   (if type-name
 549       (progn
 550         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
 551                         (concat
 552                          (propertize "[" 'face 'elpher-margin-brackets)
 553                          (propertize type-name 'face 'elpher-margin-key)
 554                          (propertize "]" 'face 'elpher-margin-brackets))))
 555         (insert " "))
 556     (insert (make-string elpher-margin-width ?\s))))
 557
 558 (defun elpher-node-button-help (node)
 559   "Return a string containing the help text for a button corresponding to NODE."
 560   (let ((address (elpher-node-address node)))
 561     (format "mouse-1, RET: open '%s'" (elpher-address-to-url address))))
 562
 563 (defun elpher-insert-index-record (display-string &optional address)
 564   "Function to insert an index record into the current buffer.
 565 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
 566 If ADDRESS is not supplied or nil the record is rendered as an
 567 'information' line."
 568   (let* ((type (if address (elpher-address-type address) nil))
 569          (type-map-entry (cdr (assoc type elpher-type-map))))
 570     (if type-map-entry
 571         (let* ((margin-code (elt type-map-entry 1))
 572                (face (elt type-map-entry 2))
 573                (node (elpher-make-node display-string address)))
 574           (elpher-insert-margin margin-code)
 575           (insert-text-button display-string
 576                               'face face
 577                               'elpher-node node
 578                               'action #'elpher-click-link
 579                               'follow-link t
 580                               'help-echo (elpher-node-button-help node)))
 581       (pcase type
 582         ((or '(gopher ?i) 'nil) ;; Information
 583          (elpher-insert-margin)
 584          (insert (propertize
 585                   (if elpher-buttonify-urls-in-directories
 586                       (elpher-buttonify-urls display-string)
 587                     display-string)
 588                   'face 'elpher-info)))
 589         (`(gopher ,selector-type) ;; Unknown
 590          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
 591          (insert (propertize display-string
 592                              'face 'elpher-unknown)))))
 593     (insert "\n")))
 594
 595 (defun elpher-click-link (button)
 596   "Function called when the gopher link BUTTON is activated (via mouse or keypress)."
 597   (let ((node (button-get button 'elpher-node)))
 598     (elpher-visit-node node)))
 599
 600 (defun elpher-render-index (data)
 601   "Render DATA as an index."
 602   (elpher-with-clean-buffer
 603    (if (not data)
 604        t
 605      (elpher-insert-index data)
 606      (elpher-cache-content (elpher-node-address elpher-current-node)
 607                            (buffer-string)))))
 608
 609 ;; Text rendering
 610
 611 (defconst elpher-url-regex
 612   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.\-]+\\|\[[a-zA-Z0-9:]+\]\\)\\(?3::[0-9]+\\)?\\(?4:/[^<> \r\n\t(),]*\\)?"
 613   "Regexp used to locate and buttinofy URLs in text files loaded by elpher.")
 614
 615 (defun elpher-buttonify-urls (string)
 616   "Turn substrings which look like urls in STRING into clickable buttons."
 617   (with-temp-buffer
 618     (insert string)
 619     (goto-char (point-min))
 620     (while (re-search-forward elpher-url-regex nil t)
 621       (let ((node (elpher-make-node (match-string 0)
 622                                     (elpher-address-from-url (match-string 0)))))
 623           (make-text-button (match-beginning 0)
 624                             (match-end 0)
 625                             'elpher-node  node
 626                             'action #'elpher-click-link
 627                             'follow-link t
 628                             'help-echo (elpher-node-button-help node))))
 629     (buffer-string)))
 630
 631 (defun elpher-render-text (data)
 632   "Render DATA as text."
 633   (elpher-with-clean-buffer
 634    (if (not data)
 635        t
 636      (insert (elpher-buttonify-urls
 637               (elpher-preprocess-text-response)
 638               elpher-selector-string))
 639      (elpher-cache-content
 640       (elpher-node-address elpher-current-node)
 641       (buffer-string)))))
 642
 643 ;; Image retrieval
 644
 645 (defun elpher-render-image (data)
 646   "Display DATA as image."
 647   (if (not data)
 648       f
 649     (if (display-images-p)
 650         (progn
 651           (let ((image (create-image
 652                         data
 653                         nil t)))
 654             (elpher-with-clean-buffer
 655              (insert-image image)
 656              (elpher-restore-pos))))
 657       (elpher-save-to-file data))))
 658
 659 ;; Search retrieval and rendering
 660
 661 (defun elpher-get-gopher-query-node (renderer)
 662    (let* ((address (elpher-node-address elpher-current-node))
 663           (content (elpher-get-cached-content address))
 664           (aborted t))
 665     (if (and content (funcall renderer nil))
 666         (elpher-with-clean-buffer
 667          (insert content)
 668          (elpher-restore-pos)
 669          (message "Displaying cached search results.  Reload to perform a new search."))
 670       (unwind-protect
 671           (let* ((query-string (read-string "Query: "))
 672                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
 673                  (search-address (elpher-make-gopher-address ?1
 674                                                              query-selector
 675                                                              (elpher-address-host address)
 676                                                              (elpher-address-port address)
 677                                                              (equal (elpher-address-type address) "gophers"))))
 678             (setq aborted nil)
 679
 680             (elpher-with-clean-buffer
 681              (insert "LOADING RESULTS... (use 'u' to cancel)"))
 682             (elpher-get-selector search-address
 683                                  (lambda (proc event)
 684                                    (unless (string-prefix-p "deleted" event)
 685                                      (funcall renderer elpher-selector-string)
 686                                      (elpher-restore-pos)))))
 687         (if aborted
 688             (elpher-visit-parent-node))))))
 689
 690 ;; Raw server response rendering
 691
 692 (defun elpher-render-raw (data)
 693   "Display raw DATA in buffer."
 694   (if (not data)
 695       f
 696     (elpher-with-clean-buffer
 697      (insert data)
 698      (goto-char (point-min)))
 699     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
 700
 701 ;; File save "rendering"
 702
 703 (defun elpher-render-download (data)
 704   "Save DATA to file."
 705   (if (not data)
 706       f
 707     (let* ((address (elpher-node-address elpher-current-node))
 708            (selector (elpher-gopher-address-selector address)))
 709       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 710       (let* ((filename-proposal (file-name-nondirectory selector))
 711              (filename (read-file-name "Download complete. Save file as: "
 712                                        nil nil nil
 713                                        (if (> (length filename-proposal) 0)
 714                                            filename-proposal
 715                                          "gopher.file"))))
 716         (with-temp-file filename
 717           (insert elpher-selector-string)
 718           (message (format "Saved to file %s."
 719                            elpher-download-filename)))))))
 720
 721 ;; HTML rendering
 722
 723 (defun elpher-render-html (data)
 724   "Render DATA as HTML using shr."
 725   (elpher-with-clean-buffer
 726    (if (not data)
 727        t
 728      (let ((dom (with-temp-buffer
 729                   (insert string)
 730                   (libxml-parse-html-region (point-min) (point-max)))))
 731        (shr-insert-document dom)))))
 732
 733 ;; Gemini node retrieval
 734
 735 (defvar elpher-gemini-response)
 736
 737
 738 (defun elpher-get-gemini-response (address renderer)
 739   "Retrieve gemini ADDRESS, then execute RENDERER on the result.
 740 The response is stored in the variable ‘elpher-gemini-response’."
 741   (setq elpher-gemini-response "")
 742   (if (not (gnutls-available-p))
 743       (error "Cannot retrieve TLS selector: GnuTLS not available")
 744     (let* ((kill-buffer-query-functions nil)
 745            (proc (open-network-stream "elpher-process"
 746                                       nil
 747                                       (elpher-address-host address)
 748                                       (if (> (elpher-address-port address) 0)
 749                                           (elpher-address-port address)
 750                                         1965)
 751                                       :type 'tls)))
 752       (set-process-coding-system proc 'binary)
 753       (set-process-filter proc
 754                           (lambda (proc string)
 755                             (setq elpher-gemini-response
 756                                   (concat elpher-gemini-response string))))
 757       (set-process-sentinel proc
 758                             (lambda (proc event)
 759                               (unless (string-prefix-p "deleted" event)
 760                                 (elpher-process-gemini-response #'after))))
 761       (process-send-string proc
 762                            (concat (elpher-address-to-url address) "\r\n")))))
 763
 764
 765 (defun elpher-process-gemini-response (renderer)
 766   "Process the gemini response found in the variable elpher-gemini-response and
 767 pass the result to RENDERER."
 768   (condition-case the-error
 769       (unless (string-prefix-p "deleted" event)
 770         (let* ((response-header (car (split-string elpher-gemini-response "\r\n")))
 771                (response-body (substring elpher-gemini-response
 772                                          (+ (string-match "\r\n" elpher-gemini-response) 2)))
 773                (response-code (car (split-string response-header)))
 774                (response-meta (string-trim
 775                                (substring response-header
 776                                           (string-match "[ \t]+" response-header)))))
 777           (pcase (elt response-code 0)
 778             (?1 ; Input required
 779              (elpher-with-clean-buffer
 780               (insert "Gemini server is requesting input."))
 781              (let* ((query-string (read-string (concat response-meta ": ")))
 782                     (url (elpher-address-to-url (elpher-node-address elpher-current-node)))
 783                     (query-address (elpher-address-from-url (concat url "?" query-string))))
 784                (elpher-get-gemini query-address #'renderer)))
 785             (?2 ; Normal response
 786              (message response-header)
 787              (funcall #'renderer elpher-gemini-response))
 788             (?3 ; Redirect
 789              (message "Following redirect to %s" meta)
 790              (let ((redirect-address (elpher-address-from-gemini-url meta)))
 791                (elpher-get-gemini redirect-address #'renderer)))
 792             (?4 ; Temporary failure
 793              (error "Gemini server reports TEMPORARY FAILURE for this request"))
 794             (?5 ; Permanent failure
 795              (error "Gemini server reports PERMANENT FAILURE for this request"))
 796             (?6 ; Client certificate required
 797              (error "Gemini server requires client certificate (unsupported at this time)"))
 798             (other
 799              (error "Gemini server responded with unknown response code %S"
 800                     response-code)))))
 801     (error
 802      (elpher-network-error (elpher-node-address elpher-current-node) the-error))))
 803
 804 (defun elpher-get-gemini-node (renderer)
 805   "Getter which retrieves and renders a Gemini node and renders it using RENDERER."
 806   (let* ((address (elpher-node-address elpher-current-node))
 807          (content (elpher-get-cached-content address)))
 808     (condition-case the-error
 809         (if (and content (funcall renderer nil))
 810             (progn
 811               (insert content)
 812               (elpher-restore-pos))
 813           (elpher-with-clean-buffer
 814            (insert "LOADING GEMINI... (use 'u' to cancel)"))
 815           (elpher-get-gemini address
 816                              (lambda (proc event)
 817                                (unless (string-prefix-p "deleted" event)
 818                                  (funcall renderer elpher-gemini-response)
 819                                  (elpher-restore-pos)))))
 820       (error
 821        (elpher-network-error address the-error)))))
 822
 823
 824 (defun elpher-render-gemini (data)
 825   "Render gemini response DATA."
 826   (if (not data)
 827       t
 828     (let* ((response-header (car (split-string data "\r\n")))
 829            (response-body (substring data (+ (string-match "\r\n" data) 2)))
 830            (mime-type-string (string-trim (substring response-header 2)))
 831            (mime-type-string* (if (string-empty-p mime-type-string)
 832                                   "text/gemini; charset=utf-8"
 833                                 mime-type-string))
 834            (mime-type-split (split-string mime-type-string* ";"))
 835            (mime-type (string-trim (car mime-type-split)))
 836            (parameters (mapcar (lambda (s)
 837                                  (let ((key-val (split-string s "=")))
 838                                    (list (downcase (string-trim (car key-val)))
 839                                          (downcase (string-trim (cadr key-val))))))
 840                                (cdr mime-type-split))))
 841       (if (and (equal "text/gemini" mime-type)
 842                (not (assoc "charset" parameters)))
 843           (setq parameters (cons (list "charset" "utf-8") parameters)))
 844       (when (string-prefix-p "text/" mime-type)
 845         (if (assoc "charset" parameters)
 846             (setq elpher-gemini-response
 847                   (decode-coding-string elpher-gemini-response
 848                                         (intern (cadr (assoc "charset" parameters))))))
 849         (setq elpher-gemini-response
 850               (replace-regexp-in-string "\r" "" elpher-gemini-response)))
 851       (pcase mime-type
 852         ((or "text/gemini" "")
 853          (elpher-render-gemini-text/gemini response-body parameters))
 854         ((pred (string-prefix-p "text/"))
 855          (elpher-render-gemini-text/plain response-body parameters))
 856         ((pred (string-prefix-p "image/"))
 857          (elpher-render-image response-body))
 858         (other
 859          (error "Unsupported MIME type %S" mime-type))))))
 860
 861 (defun elpher-gemini-get-link-url (line)
 862   (string-trim (elt (split-string (substring line 2)) 0)))
 863
 864 (defun elpher-gemini-get-link-display-string (line)
 865   (let* ((rest (string-trim (elt (split-string line "=>") 1)))
 866          (idx (string-match "[ \t]" rest)))
 867     (if idx
 868         (string-trim (substring rest (+ idx 1)))
 869       "")))
 870
 871 (defun elpher-address-from-gemini-url (url)
 872   "Extract address from URL with defaults as per gemini map files."
 873   (let ((address (url-generic-parse-url url)))
 874     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
 875       (setf (url-fullness address) t)
 876       (unless (url-host address) ;if there is an explicit host, filenames are explicit
 877         (setf (url-host address) (url-host (elpher-node-address elpher-current-node)))
 878         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
 879           (setf (url-filename address)
 880                 (concat (file-name-directory
 881                          (url-filename (elpher-node-address elpher-current-node)))
 882                         (url-filename address)))))
 883       (unless (url-type address)
 884         (setf (url-type address) "gemini")))
 885     address))
 886
 887 (defun elpher-render-gemini-text/gemini (data parameters)
 888   (elpher-with-clean-buffer
 889    (dolist (line (split-string data "\n"))
 890      (if (string-prefix-p "=>" line)
 891          (let* ((url (elpher-gemini-get-link-url line))
 892                 (display-string (elpher-gemini-get-link-display-string line))
 893                 (address (elpher-address-from-gemini-url url)))
 894            (if (> (length display-string) 0)
 895                (elpher-insert-index-record display-string address)
 896              (elpher-insert-index-record url address)))
 897        (elpher-insert-index-record line)))
 898    (elpher-cache-content
 899     (elpher-node-address elpher-current-node)
 900     (buffer-string))))
 901
 902 (defun elpher-render-gemini-text/plain (data parameters)
 903   (elpher-with-clean-buffer
 904    (insert (elpher-buttonify-urls (elpher-preprocess-text-response data)))
 905    (elpher-cache-content
 906     (elpher-node-address elpher-current-node)
 907     (buffer-string))))
 908
 909 ;; Other URL node opening
 910
 911 (defun elpher-get-other-url-node (renderer)
 912   "Getter which attempts to open the URL specified by the current node (RENDERER must be nil)."
 913   (when renderer
 914     (elpher-visit-parent-node)
 915     (error "Command not supported for general URLs"))
 916   (let* ((address (elpher-node-address elpher-current-node))
 917          (url (elpher-address-to-url address)))
 918     (progn
 919       (elpher-visit-parent-node) ; Do first in case of non-local exits.
 920       (message "Opening URL...")
 921       (if elpher-open-urls-with-eww
 922           (browse-web url)
 923         (browse-url url)))))
 924
 925 ;; Telnet node connection
 926
 927 (defun elpher-get-telnet-node (renderer)
 928   "Opens a telnet connection to the current node address (RENDERER must be nil)."
 929   (when renderer
 930     (elpher-visit-parent-node)
 931     (error "Command not supported for telnet URLs"))
 932   (let* ((address (elpher-node-address elpher-current-node))
 933          (host (elpher-address-host address))
 934          (port (elpher-address-port address)))
 935     (elpher-visit-parent-node)
 936     (telnet host port)))
 937
 938 ;; Start page node retrieval
 939
 940 (defun elpher-get-start-node (renderer)
 941   "Getter which displays the start page (RENDERER must be nil)."
 942   (when renderer
 943     (elpher-visit-parent-node)
 944     (error "Command not supported for start page."))
 945   (elpher-with-clean-buffer
 946    (insert "     --------------------------------------------\n"
 947            "                Elpher Gopher Client             \n"
 948            "                   version " elpher-version "\n"
 949            "     --------------------------------------------\n"
 950            "\n"
 951            "Default bindings:\n"
 952            "\n"
 953            " - TAB/Shift-TAB: next/prev item on current page\n"
 954            " - RET/mouse-1: open item under cursor\n"
 955            " - m: select an item on current page by name (autocompletes)\n"
 956            " - u: return to previous page\n"
 957            " - o/O: visit different selector or the root menu of the current server\n"
 958            " - g: go to a particular gopher address\n"
 959            " - i/I: info on item under cursor or current page\n"
 960            " - c/C: copy URL representation of item under cursor or current page\n"
 961            " - a/A: bookmark the item under cursor or current page\n"
 962            " - x/X: remove bookmark for item under cursor or current page\n"
 963            " - B: visit the bookmarks page\n"
 964            " - r: redraw current page (using cached contents if available)\n"
 965            " - R: reload current page (regenerates cache)\n"
 966            " - T: toggle TLS mode\n"
 967            " - d/D: download item under cursor or current page\n"
 968            " - .: display the raw server response for the current page\n"
 969            " - S: set an explicit character coding system (default is to autodetect)\n"
 970            "\n"
 971            "Start your exploration of gopher space:\n")
 972    (elpher-insert-index-record "Floodgap Systems Gopher Server"
 973                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
 974    (insert "\n"
 975            "Alternatively, select the following item and enter some search terms:\n")
 976    (elpher-insert-index-record "Veronica-2 Gopher Search Engine"
 977                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
 978    (insert "\n"
 979            "** Refer to the ")
 980    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
 981      (insert-text-button "Elpher info manual"
 982                          'face 'link
 983                          'action (lambda (button)
 984                                    (interactive)
 985                                    (info "(elpher)"))
 986                          'follow-link t
 987                          'help-echo help-string))
 988    (insert " for the full documentation. **\n")
 989    (insert (propertize
 990             (concat "  (This should be available if you have installed Elpher using\n"
 991                     "   MELPA. Otherwise you will have to install the manual yourself.)")
 992             'face 'shadow))
 993    (elpher-restore-pos)))
 994
 995 ;; Bookmarks page node retrieval
 996
 997 (defun elpher-get-bookmarks-node (renderer)
 998   "Getter to load and display the current bookmark list (RENDERER must be nil)."
 999   (when renderer
1000     (elpher-visit-parent-node)
1001     (error "Command not supported for bookmarks page."))
1002   (elpher-with-clean-buffer
1003    (insert "---- Bookmark list ----\n\n")
1004    (let ((bookmarks (elpher-load-bookmarks)))
1005      (if bookmarks
1006          (dolist (bookmark bookmarks)
1007            (let ((display-string (elpher-bookmark-display-string bookmark))
1008                  (address (elpher-address-from-url (elpher-bookmark-url bookmark))))
1009              (elpher-insert-index-record display-string address)))
1010        (insert "No bookmarks found.\n")))
1011    (insert "\n-----------------------\n\n"
1012            "- u: return to previous page\n"
1013            "- x: delete selected bookmark\n"
1014            "- a: rename selected bookmark\n\n"
1015            "Bookmarks are stored in the file "
1016            (locate-user-emacs-file "elpher-bookmarks"))
1017    (elpher-restore-pos)))
1018
1019
1020 ;;; Bookmarks
1021 ;;
1022
1023 (defun elpher-make-bookmark (display-string url)
1024   "Make an elpher bookmark.
1025 DISPLAY-STRING determines how the bookmark will appear in the
1026 bookmark list, while ADDRESS is the address of the entry."
1027   (list display-string (elpher-address-to-url address)))
1028
1029 (defun elpher-bookmark-display-string (bookmark)
1030   "Get the display string of BOOKMARK."
1031   (elt bookmark 0))
1032
1033 (defun elpher-set-bookmark-display-string (bookmark display-string)
1034   "Set the display string of BOOKMARK to DISPLAY-STRING."
1035   (setcar bookmark display-string))
1036
1037 (defun elpher-bookmark-url (bookmark)
1038   "Get the address for BOOKMARK."
1039   (elt bookmark 1))
1040
1041
1042 (defun elpher-save-bookmarks (bookmarks)
1043   "Record the bookmark list BOOKMARKS to the user's bookmark file.
1044 Beware that this completely replaces the existing contents of the file."
1045   (with-temp-file (locate-user-emacs-file "elpher2-bookmarks")
1046     (erase-buffer)
1047     (insert "; Elpher bookmarks file\n\n"
1048             "; Bookmarks are stored as a list of (label URL) items.\n"
1049             "; Feel free to edit by hand, but take care to ensure\n"
1050             "; the list structure remains intact.\n\n")
1051     (pp bookmarks (current-buffer))))
1052
1053 (defun elpher-load-bookmarks ()
1054   "Get the list of bookmarks from the users's bookmark file."
1055   (with-temp-buffer
1056     (ignore-errors
1057       (insert-file-contents (locate-user-emacs-file "elpher2-bookmarks"))
1058       (goto-char (point-min))
1059       (read (current-buffer)))))
1060
1061 (defun elpher-add-address-bookmark (address display-string)
1062   "Save a bookmark for ADDRESS with label DISPLAY-STRING.)))
1063 If ADDRESS is already bookmarked, update the label only."
1064   (let ((bookmarks (elpher-load-bookmarks))
1065         (url (elpher-address-to-url address)))
1066     (let ((existing-bookmark (rassoc (list url) bookmarks)))
1067       (if existing-bookmark
1068           (elpher-set-bookmark-display-string existing-bookmark display-string)
1069         (add-to-list 'bookmarks (elpher-make-bookmark display-string url))))
1070     (elpher-save-bookmarks bookmarks)))
1071
1072 (defun elpher-remove-address-bookmark (address)
1073   "Remove any bookmark to ADDRESS."
1074   (let ((url (elpher-address-to-url address)))
1075     (elpher-save-bookmarks
1076      (seq-filter (lambda (bookmark)
1077                    (not (equal (elpher-bookmark-url bookmark) url)))
1078                  (elpher-load-bookmarks)))))
1079
1080 ;;; Interactive procedures
1081 ;;
1082
1083 (defun elpher-next-link ()
1084   "Move point to the next link on the current page."
1085   (interactive)
1086   (forward-button 1))
1087
1088 (defun elpher-prev-link ()
1089   "Move point to the previous link on the current page."
1090   (interactive)
1091   (backward-button 1))
1092
1093 (defun elpher-follow-current-link ()
1094   "Open the link or url at point."
1095   (interactive)
1096   (push-button))
1097
1098 (defun elpher-go ()
1099   "Go to a particular gopher site read from the minibuffer."
1100   (interactive)
1101   (let ((node
1102          (let ((host-or-url (read-string "Gopher or Gemini URL: ")))
1103            (elpher-make-node host-or-url
1104                              (elpher-address-from-url host-or-url)))))
1105     (switch-to-buffer "*elpher*")
1106     (elpher-visit-node node)))
1107
1108 (defun elpher-go-current ()
1109   "Go to a particular site read from the minibuffer, initialized with the current URL."
1110   (interactive)
1111   (let ((address (elpher-node-address elpher-current-node)))
1112     (if (elpher-address-special-p address)
1113         (error "Command not valid for this page")
1114       (let ((url (read-string "Gopher or Gemini URL: " (elpher-address-to-url address))))
1115         (elpher-visit-node (elpher-make-node url (elpher-address-from-url url)))))))
1116
1117 (defun elpher-redraw ()
1118   "Redraw current page."
1119   (interactive)
1120   (if elpher-current-node
1121       (elpher-visit-node elpher-current-node)
1122     (message "No current site.")))
1123
1124 (defun elpher-reload ()
1125   "Reload current page."
1126   (interactive)
1127   (if elpher-current-node
1128       (elpher-reload-current-node)
1129     (message "No current site.")))
1130
1131 (defun elpher-toggle-tls ()
1132   "Toggle TLS encryption mode."
1133   (interactive)
1134   (setq elpher-use-tls (not elpher-use-tls))
1135   (if elpher-use-tls
1136       (if (gnutls-available-p)
1137           (message "TLS mode enabled.  (Will not affect current page until reload.)")
1138         (setq elpher-use-tls nil)
1139         (error "Cannot enable TLS mode: GnuTLS not available"))
1140     (message "TLS mode disabled.  (Will not affect current page until reload.)")))
1141
1142 (defun elpher-view-raw ()
1143   "View raw server response for current page."
1144   (interactive)
1145   (if elpher-current-node
1146       (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1147           (error "This page was not generated by a server")
1148         (elpher-visit-node elpher-current-node
1149                            #'elpher-get-node-raw))
1150     (message "No current site.")))
1151
1152 (defun elpher-back ()
1153   "Go to previous site."
1154   (interactive)
1155   (if (elpher-node-parent elpher-current-node)
1156       (elpher-visit-parent-node)
1157     (error "No previous site")))
1158
1159 (defun elpher-download ()
1160   "Download the link at point."
1161   (interactive)
1162   (let ((button (button-at (point))))
1163     (if button
1164         (let ((node (button-get button 'elpher-node)))
1165           (if (elpher-address-special-p (elpher-node-address node))
1166               (error "Cannot download this link")
1167             (elpher-visit-node (button-get button 'elpher-node)
1168                                #'elpher-get-node-download)))
1169       (error "No link selected"))))
1170
1171 (defun elpher-download-current ()
1172   "Download the current page."
1173   (interactive)
1174   (if (elpher-address-special-p (elpher-node-address elpher-current-node))
1175       (error "Cannot download this page")
1176     (elpher-visit-node (elpher-make-node
1177                         (elpher-node-display-string elpher-current-node)
1178                         (elpher-node-address elpher-current-node)
1179                         elpher-current-node)
1180                        #'elpher-get-node-download
1181                        t)))
1182
1183 (defun elpher-build-link-map ()
1184   "Build alist mapping link names to destination nodes in current buffer."
1185   (let ((link-map nil)
1186         (b (next-button (point-min) t)))
1187     (while b
1188       (add-to-list 'link-map (cons (button-label b) b))
1189       (setq b (next-button (button-start b))))
1190     link-map))
1191
1192 (defun elpher-jump ()
1193   "Select a directory entry by name.  Similar to the info browser (m)enu command."
1194   (interactive)
1195   (let* ((link-map (elpher-build-link-map)))
1196     (if link-map
1197         (let ((key (let ((completion-ignore-case t))
1198                      (completing-read "Directory item/link: "
1199                                       link-map nil t))))
1200           (if (and key (> (length key) 0))
1201               (let ((b (cdr (assoc key link-map))))
1202                 (goto-char (button-start b))
1203                 (button-activate b)))))))
1204
1205 (defun elpher-root-dir ()
1206   "Visit root of current server."
1207   (interactive)
1208   (let ((address (elpher-node-address elpher-current-node)))
1209     (if (not (elpher-address-special-p address))
1210         (if (or (member (url-filename address) '("/" ""))
1211                 (and (elpher-address-gopher-p address)
1212                      (= (length (elpher-gopher-address-selector address)) 0)))
1213             (error "Already at root directory of current server")
1214           (let ((address-copy (elpher-address-from-url
1215                                (elpher-address-to-url address))))
1216             (setf (url-filename address-copy) "")
1217             (elpher-visit-node
1218              (elpher-make-node (elpher-address-to-url address-copy)
1219                                address-copy))))
1220       (error "Command invalid for this page"))))
1221
1222 (defun elpher-bookmarks-current-p ()
1223   "Return non-nil if current node is a bookmarks page."
1224   (equal (elpher-address-type (elpher-node-address elpher-current-node))
1225          '(special bookmarks)))
1226
1227 (defun elpher-reload-bookmarks ()
1228   "Reload bookmarks if current node is a bookmarks page."
1229   (if (elpher-bookmarks-current-p)
1230       (elpher-reload-current-node)))
1231
1232 (defun elpher-bookmark-current ()
1233   "Bookmark the current node."
1234   (interactive)
1235   (let ((address (elpher-node-address elpher-current-node))
1236         (display-string (elpher-node-display-string elpher-current-node)))
1237     (if (not (elpher-address-special-p address))
1238         (let ((bookmark-display-string (read-string "Bookmark display string: "
1239                                                     display-string)))
1240           (elpher-add-address-bookmark address bookmark-display-string)
1241           (message "Bookmark added."))
1242       (error "Cannot bookmark %s" display-string))))
1243
1244 (defun elpher-bookmark-link ()
1245   "Bookmark the link at point."
1246   (interactive)
1247   (let ((button (button-at (point))))
1248     (if button
1249         (let* ((node (button-get button 'elpher-node))
1250                (address (elpher-node-address node))
1251                (display-string (elpher-node-display-string node)))
1252           (if (not (elpher-address-special-p address))
1253               (let ((bookmark-display-string (read-string "Bookmark display string: "
1254                                                           display-string)))
1255                 (elpher-add-address-bookmark address bookmark-display-string)
1256                 (elpher-reload-bookmarks)
1257                 (message "Bookmark added."))
1258             (error "Cannot bookmark %s" display-string)))
1259       (error "No link selected"))))
1260
1261 (defun elpher-unbookmark-current ()
1262   "Remove bookmark for the current node."
1263   (interactive)
1264   (let ((address (elpher-node-address elpher-current-node)))
1265     (unless (elpher-address-special-p address)
1266       (elpher-remove-address-bookmark address)
1267       (message "Bookmark removed."))))
1268
1269 (defun elpher-unbookmark-link ()
1270   "Remove bookmark for the link at point."
1271   (interactive)
1272   (let ((button (button-at (point))))
1273     (if button
1274         (let ((node (button-get button 'elpher-node)))
1275           (elpher-remove-address-bookmark (elpher-node-address node))
1276           (elpher-reload-bookmarks)
1277           (message "Bookmark removed."))
1278       (error "No link selected"))))
1279
1280 (defun elpher-bookmarks ()
1281   "Visit bookmarks page."
1282   (interactive)
1283   (switch-to-buffer "*elpher*")
1284   (elpher-visit-node
1285    (elpher-make-node "Bookmarks Page" (elpher-make-special-address 'bookmarks))))
1286
1287 (defun elpher-info-node (node)
1288   "Display information on NODE."
1289   (let ((display-string (elpher-node-display-string node))
1290         (address (elpher-node-address node)))
1291     (if (elpher-address-special-p address)
1292         (message "Special page: %s" display-string)
1293       (message (elpher-address-to-url address)))))
1294
1295 (defun elpher-info-link ()
1296   "Display information on node corresponding to link at point."
1297   (interactive)
1298   (let ((button (button-at (point))))
1299     (if button
1300         (elpher-info-node (button-get button 'elpher-node))
1301       (error "No item selected"))))
1302
1303 (defun elpher-info-current ()
1304   "Display information on current node."
1305   (interactive)
1306   (elpher-info-node elpher-current-node))
1307
1308 (defun elpher-copy-node-url (node)
1309   "Copy URL representation of address of NODE to `kill-ring'."
1310   (let ((address (elpher-node-address node)))
1311     (if (elpher-address-special-p address)
1312         (error (format "Cannot represent %s as URL" (elpher-node-display-string node)))
1313       (let ((url (elpher-address-to-url address)))
1314         (message "Copied \"%s\" to kill-ring/clipboard." url)
1315         (kill-new url)))))
1316
1317 (defun elpher-copy-link-url ()
1318   "Copy URL of item at point to `kill-ring'."
1319   (interactive)
1320   (let ((button (button-at (point))))
1321     (if button
1322         (elpher-copy-node-url (button-get button 'elpher-node))
1323       (error "No item selected"))))
1324
1325 (defun elpher-copy-current-url ()
1326   "Copy URL of current node to `kill-ring'."
1327   (interactive)
1328   (elpher-copy-node-url elpher-current-node))
1329
1330 (defun elpher-set-coding-system ()
1331   "Specify an explicit character coding system."
1332   (interactive)
1333   (let ((system (read-coding-system "Set coding system to use (default is to autodetect): " nil)))
1334     (setq elpher-user-coding-system system)
1335     (if system
1336         (message "Coding system fixed to %s. (Reload to see effect)." system)
1337       (message "Coding system set to autodetect. (Reload to see effect)."))))
1338
1339
1340 ;;; Mode and keymap
1341 ;;
1342
1343 (defvar elpher-mode-map
1344   (let ((map (make-sparse-keymap)))
1345     (define-key map (kbd "TAB") 'elpher-next-link)
1346     (define-key map (kbd "<backtab>") 'elpher-prev-link)
1347     (define-key map (kbd "u") 'elpher-back)
1348     (define-key map (kbd "O") 'elpher-root-dir)
1349     (define-key map (kbd "g") 'elpher-go)
1350     (define-key map (kbd "o") 'elpher-go-current)
1351     (define-key map (kbd "r") 'elpher-redraw)
1352     (define-key map (kbd "R") 'elpher-reload)
1353     (define-key map (kbd "T") 'elpher-toggle-tls)
1354     (define-key map (kbd ".") 'elpher-view-raw)
1355     (define-key map (kbd "d") 'elpher-download)
1356     (define-key map (kbd "D") 'elpher-download-current)
1357     (define-key map (kbd "m") 'elpher-jump)
1358     (define-key map (kbd "i") 'elpher-info-link)
1359     (define-key map (kbd "I") 'elpher-info-current)
1360     (define-key map (kbd "c") 'elpher-copy-link-url)
1361     (define-key map (kbd "C") 'elpher-copy-current-url)
1362     (define-key map (kbd "a") 'elpher-bookmark-link)
1363     (define-key map (kbd "A") 'elpher-bookmark-current)
1364     (define-key map (kbd "x") 'elpher-unbookmark-link)
1365     (define-key map (kbd "X") 'elpher-unbookmark-current)
1366     (define-key map (kbd "B") 'elpher-bookmarks)
1367     (define-key map (kbd "S") 'elpher-set-coding-system)
1368     (when (fboundp 'evil-define-key)
1369       (evil-define-key 'motion map
1370         (kbd "TAB") 'elpher-next-link
1371         (kbd "C-") 'elpher-follow-current-link
1372         (kbd "C-t") 'elpher-back
1373         (kbd "u") 'elpher-back
1374         (kbd "g") 'elpher-go
1375         (kbd "o") 'elpher-go-current
1376         (kbd "r") 'elpher-redraw
1377         (kbd "R") 'elpher-reload
1378         (kbd "T") 'elpher-toggle-tls
1379         (kbd ".") 'elpher-view-raw
1380         (kbd "d") 'elpher-download
1381         (kbd "D") 'elpher-download-current
1382         (kbd "m") 'elpher-jump
1383         (kbd "i") 'elpher-info-link
1384         (kbd "I") 'elpher-info-current
1385         (kbd "c") 'elpher-copy-link-url
1386         (kbd "C") 'elpher-copy-current-url
1387         (kbd "a") 'elpher-bookmark-link
1388         (kbd "A") 'elpher-bookmark-current
1389         (kbd "x") 'elpher-unbookmark-link
1390         (kbd "X") 'elpher-unbookmark-current
1391         (kbd "B") 'elpher-bookmarks
1392         (kbd "S") 'elpher-set-coding-system))
1393     map)
1394   "Keymap for gopher client.")
1395
1396 (define-derived-mode elpher-mode special-mode "elpher"
1397   "Major mode for elpher, an elisp gopher client.)
1398
1399 This mode is automatically enabled by the interactive
1400 functions which initialize the gopher client, namely
1401 `elpher', `elpher-go' and `elpher-bookmarks'.")
1402
1403 (when (fboundp 'evil-set-initial-state)
1404   (evil-set-initial-state 'elpher-mode 'motion))
1405
1406
1407 ;;; Main start procedure
1408 ;;
1409
1410 ;;;###autoload
1411 (defun elpher ()
1412   "Start elpher with default landing page."
1413   (interactive)
1414   (if (get-buffer "*elpher*")
1415       (switch-to-buffer "*elpher*")
1416     (switch-to-buffer "*elpher*")
1417     (setq elpher-current-node nil)
1418     (let ((start-node (elpher-make-node "Elpher Start Page"
1419                                         (elpher-make-special-address 'start))))
1420       (elpher-visit-node start-node)))
1421   "Started Elpher.") ; Otherwise (elpher) evaluates to start page string.
1422
1423 ;;; elpher.el ends here