src/forth.jl

   1 module forth
   2
   3 # VM mem size
   4 size_mem = 1000000 # 1 mega-int
   5
   6 # Buffer sizes
   7 size_RS = 1000   # Return stack size
   8 size_PS = 1000   # Parameter stack size
   9 size_TIB = 1000  # Terminal input buffer size
  10
  11 # Memory arrays
  12 mem = Array{Int64,1}(size_mem)
  13 primitives = Array{Function,1}()
  14 primNames = Array{ASCIIString,1}()
  15
  16 # Built-in variables
  17
  18 nextVarAddr = 1
  19 H = nextVarAddr; nextVarAddr += 1       # Next free memory address
  20 FORTH = nextVarAddr; nextVarAddr += 1   # LFA of latest word in system dict
  21 CURRENT = nextVarAddr; nextVarAddr += 1 # Current compilation dict
  22
  23 RSP0 = nextVarAddr                  # bottom of RS
  24 PSP0 = RSP0 + size_RS               # bottom of PS
  25 TIB = PSP0 + size_PS                # address of terminal input buffer
  26 mem[H] = TIB + size_TIB             # location of bottom of dictionary
  27 mem[FORTH] = 0                      # no previous definition
  28 mem[CURRENT] = FORTH                # Compile words to system dict initially
  29
  30 DICT = mem[H] # Save bottom of dictionary as constant
  31
  32 # VM registers
  33 type Reg
  34     RSP::Int64  # Return stack pointer
  35     PSP::Int64  # Parameter/data stack pointer
  36     IP::Int64   # Instruction pointer
  37     W::Int64    # Working register
  38 end
  39 reg = Reg(RSP0, PSP0, 0, 0)
  40
  41 # Stack manipulation functions
  42
  43 function ensurePSDepth(depth::Int64)
  44     if reg.PSP - PSP0 < depth
  45         error("Parameter stack underflow.")
  46     end
  47 end
  48
  49 function ensureRSDepth(depth::Int64)
  50     if reg.RSP - RSP0 < depth
  51         error("Return stack underflow.")
  52     end
  53 end
  54
  55 function pushRS(val::Int64)
  56     mem[reg.RSP+=1] = val
  57 end
  58
  59 function popRS()
  60     ensureRSDepth(1)
  61
  62     val = mem[reg.RSP]
  63     reg.RSP -= 1
  64     return val
  65 end
  66
  67 function pushPS(val::Int64)
  68     mem[reg.PSP += 1] = val
  69 end
  70
  71 function popPS()
  72     ensurePSDepth(1)
  73
  74     val = mem[reg.PSP]
  75     reg.PSP -= 1
  76     return val
  77 end
  78
  79 # Handy functions for adding/retrieving strings to/from memory.
  80
  81 getString(addr::Int64, len::Int64) = ASCIIString([Char(c) for c in mem[addr:(addr+len-1)]])
  82
  83 function putString(str::ASCIIString, addr::Int64)
  84     mem[addr:(addr+length(str)-1)] = [Int64(c) for c in str]
  85 end
  86
  87 # Primitive creation and calling functions
  88
  89 function defPrim(f::Function; name="nameless")
  90     push!(primitives, f)
  91     push!(primNames, replace(name, "\004", "EOF"))
  92
  93     return -length(primitives)
  94 end
  95
  96 function callPrim(addr::Int64)
  97     if addr >=0 || -addr>length(primitives)
  98         error("Attempted to execute non-existent primitive at address $addr.")
  99     else
 100         primitives[-addr]()
 101     end
 102 end
 103 getPrimName(addr::Int64) = primNames[-addr]
 104
 105 # Word creation functions
 106
 107 F_LENMASK = 31
 108 F_IMMED = 32
 109 F_HIDDEN = 64
 110 NFA_MARK = 128
 111
 112 function dictWrite(ints::Array{Int64,1})
 113     mem[mem[H]:(mem[H]+length(ints)-1)] = ints
 114     mem[H] += length(ints)
 115 end
 116 dictWrite(int::Int64) = dictWrite([int])
 117 dictWriteString(string::ASCIIString) = dictWrite([Int64(c) for c in string])
 118
 119 function createHeader(name::AbstractString, flags::Int64)
 120     mem[mem[H]] = mem[mem[CURRENT]]
 121     mem[mem[CURRENT]] = mem[H]
 122     mem[H] += 1
 123
 124     dictWrite(length(name) | flags | NFA_MARK)
 125     dictWriteString(name)
 126 end
 127
 128 function defPrimWord(name::AbstractString, f::Function; flags::Int64=0)
 129     createHeader(name, flags)
 130
 131     codeWordAddr = mem[H]
 132     dictWrite(defPrim(f, name=name))
 133
 134     return codeWordAddr
 135 end
 136
 137 function defWord(name::AbstractString, wordAddrs::Array{Int64,1}; flags::Int64=0)
 138     createHeader(name, flags)
 139
 140     addr = mem[H]
 141     dictWrite(DOCOL)
 142
 143     dictWrite(wordAddrs)
 144
 145     return addr
 146 end
 147
 148 # Variable creation functions
 149
 150 function defExistingVar(name::AbstractString, varAddr::Int64; flags::Int64=0)
 151
 152     defPrimWord(name, eval(:(() -> begin
 153         pushPS($(varAddr))
 154         return NEXT
 155     end)))
 156 end
 157
 158 function defNewVar(name::AbstractString, initial::Array{Int64,1}; flags::Int64=0)
 159     createHeader(name, flags)
 160
 161     codeWordAddr = mem[H]
 162     varAddr = mem[H] + 1
 163
 164     dictWrite(DOVAR)
 165     dictWrite(initial)
 166
 167     return varAddr, codeWordAddr
 168 end
 169
 170 defNewVar(name::AbstractString, initial::Int64; flags::Int64=0) =
 171     defNewVar(name, [initial]; flags=flags)
 172
 173 function defConst(name::AbstractString, val::Int64; flags::Int64=0)
 174     createHeader(name, flags)
 175
 176     codeWordAddr = mem[H]
 177
 178     dictWrite(DOCON)
 179     dictWrite(val)
 180
 181     return codeWordAddr
 182 end
 183
 184 # Threading Primitives (inner interpreter)
 185
 186 NEXT = defPrim(() -> begin
 187     reg.W = mem[reg.IP]
 188     reg.IP += 1
 189     return mem[reg.W]
 190 end, name="NEXT")
 191
 192 DOCOL = defPrim(() -> begin
 193     pushRS(reg.IP)
 194     reg.IP = reg.W + 1
 195     return NEXT
 196 end, name="DOCOL")
 197
 198 DOVAR = defPrim(() -> begin
 199     pushPS(reg.W + 1)
 200     return NEXT
 201 end, name="DOVAR")
 202
 203 DOCON = defPrim(() -> begin
 204     pushPS(mem[reg.W + 1])
 205     return NEXT
 206 end, name="DOVAR")
 207
 208 EXIT_CFA = defPrimWord("EXIT", () -> begin
 209     reg.IP = popRS()
 210     return NEXT
 211 end)
 212
 213 # Dictionary entries for core built-in variables, constants
 214
 215 H_CFA = defExistingVar("H", H)
 216 FORTH_CFA = defExistingVar("FORTH", FORTH)
 217 CURRENT_CFA = defExistingVar("CURRENT", CURRENT)
 218
 219 PSP0_CFA = defConst("PSP0", PSP0)
 220 RSP0_CFA = defConst("RSP0", RSP0)
 221
 222 defConst("DOCOL", DOCOL)
 223 defConst("DOCON", DOCON)
 224 defConst("DOVAR", DOVAR)
 225
 226 defConst("DICT", DICT)
 227 defConst("MEMSIZE", size_mem)
 228
 229 F_IMMED_CFA = defConst("F_IMMED", F_IMMED)
 230 F_HIDDEN_CFA = defConst("F_HIDDEN", F_HIDDEN)
 231 F_LENMASK_CFA = defConst("F_LENMASK", F_LENMASK)
 232 NFA_MARK_CFA = defConst("NFA_MARK", NFA_MARK)
 233
 234 # Basic forth primitives
 235
 236 DROP_CFA = defPrimWord("DROP", () -> begin
 237     popPS()
 238     return NEXT
 239 end)
 240
 241 SWAP_CFA = defPrimWord("SWAP", () -> begin
 242     a = popPS()
 243     b = popPS()
 244     pushPS(a)
 245     pushPS(b)
 246     return NEXT
 247 end)
 248
 249 DUP_CFA = defPrimWord("DUP", () -> begin
 250     ensurePSDepth(1)
 251     pushPS(mem[reg.PSP])
 252     return NEXT
 253 end)
 254
 255 OVER_CFA = defPrimWord("OVER", () -> begin
 256     ensurePSDepth(2)
 257     pushPS(mem[reg.PSP-1])
 258     return NEXT
 259 end)
 260
 261 ROT_CFA = defPrimWord("ROT", () -> begin
 262     a = popPS()
 263     b = popPS()
 264     c = popPS()
 265     pushPS(b)
 266     pushPS(a)
 267     pushPS(c)
 268     return NEXT
 269 end)
 270
 271 NROT_CFA = defPrimWord("-ROT", () -> begin
 272     a = popPS()
 273     b = popPS()
 274     c = popPS()
 275     pushPS(a)
 276     pushPS(c)
 277     pushPS(b)
 278     return NEXT
 279 end)
 280
 281
 282 TWODROP_CFA = defPrimWord("2DROP", () -> begin
 283     popPS()
 284     popPS()
 285     return NEXT
 286 end)
 287
 288 TWODUP_CFA = defPrimWord("2DUP", () -> begin
 289     ensurePSDepth(2)
 290     a = mem[reg.PSP-1]
 291     b = mem[reg.PSP]
 292     pushPS(a)
 293     pushPS(b)
 294     return NEXT
 295 end)
 296
 297 TWOSWAP_CFA = defPrimWord("2SWAP", () -> begin
 298     a = popPS()
 299     b = popPS()
 300     c = popPS()
 301     d = popPS()
 302     pushPS(b)
 303     pushPS(a)
 304     pushPS(d)
 305     pushPS(c)
 306     return NEXT
 307 end)
 308
 309 TWOOVER_CFA = defPrimWord("2OVER", () -> begin
 310     ensurePSDepth(4)
 311     a = mem[reg.PSP-3]
 312     b = mem[reg.PSP-2]
 313     pushPS(a)
 314     pushPS(b)
 315     return NEXT
 316 end)
 317
 318 QDUP_CFA = defPrimWord("?DUP", () -> begin
 319     ensurePSDepth(1)
 320     val = mem[reg.PSP]
 321     if val != 0
 322         pushPS(val)
 323     end
 324     return NEXT
 325 end)
 326
 327 INCR_CFA = defPrimWord("1+", () -> begin
 328     ensurePSDepth(1)
 329     mem[reg.PSP] += 1
 330     return NEXT
 331 end)
 332
 333 DECR_CFA = defPrimWord("1-", () -> begin
 334     ensurePSDepth(1)
 335     mem[reg.PSP] -= 1
 336     return NEXT
 337 end)
 338
 339 INCR2_CFA = defPrimWord("2+", () -> begin
 340     ensurePSDepth(1)
 341     mem[reg.PSP] += 2
 342     return NEXT
 343 end)
 344
 345 DECR2_CFA = defPrimWord("2-", () -> begin
 346     ensurePSDepth(1)
 347     mem[reg.PSP] -= 2
 348     return NEXT
 349 end)
 350
 351 ADD_CFA = defPrimWord("+", () -> begin
 352     b = popPS()
 353     a = popPS()
 354     pushPS(a+b)
 355     return NEXT
 356 end)
 357
 358 SUB_CFA = defPrimWord("-", () -> begin
 359     b = popPS()
 360     a = popPS()
 361     pushPS(a-b)
 362     return NEXT
 363 end)
 364
 365 MUL_CFA = defPrimWord("*", () -> begin
 366     b = popPS()
 367     a = popPS()
 368     pushPS(a*b)
 369     return NEXT
 370 end)
 371
 372 DIVMOD_CFA = defPrimWord("/MOD", () -> begin
 373     b = popPS()
 374     a = popPS()
 375     q,r = divrem(a,b)
 376     pushPS(r)
 377     pushPS(q)
 378     return NEXT
 379 end)
 380
 381 TWOMUL_CFA = defPrimWord("2*", () -> begin
 382     pushPS(popPS() << 1)
 383     return NEXT
 384 end)
 385
 386 TWODIV_CFA = defPrimWord("2/", () -> begin
 387     pushPS(popPS() >> 1)
 388     return NEXT
 389 end)
 390
 391 EQ_CFA = defPrimWord("=", () -> begin
 392     b = popPS()
 393     a = popPS()
 394     pushPS(a==b ? -1 : 0)
 395     return NEXT
 396 end)
 397
 398 NE_CFA = defPrimWord("<>", () -> begin
 399     b = popPS()
 400     a = popPS()
 401     pushPS(a!=b ? -1 : 0)
 402     return NEXT
 403 end)
 404
 405 LT_CFA = defPrimWord("<", () -> begin
 406     b = popPS()
 407     a = popPS()
 408     pushPS(a<b ? -1 : 0)
 409     return NEXT
 410 end)
 411
 412 GT_CFA = defPrimWord(">", () -> begin
 413     b = popPS()
 414     a = popPS()
 415     pushPS(a>b ? -1 : 0)
 416     return NEXT
 417 end)
 418
 419 LE_CFA = defPrimWord("<=", () -> begin
 420     b = popPS()
 421     a = popPS()
 422     pushPS(a<=b ? -1 : 0)
 423     return NEXT
 424 end)
 425
 426 GE_CFA = defPrimWord(">=", () -> begin
 427     b = popPS()
 428     a = popPS()
 429     pushPS(a>=b ? -1 : 0)
 430     return NEXT
 431 end)
 432
 433 ZE_CFA = defPrimWord("0=", () -> begin
 434     pushPS(popPS() == 0 ? -1 : 0)
 435     return NEXT
 436 end)
 437
 438 ZNE_CFA = defPrimWord("0<>", () -> begin
 439     pushPS(popPS() != 0 ? -1 : 0)
 440     return NEXT
 441 end)
 442
 443 ZLT_CFA = defPrimWord("0<", () -> begin
 444     pushPS(popPS() < 0 ? -1 : 0)
 445     return NEXT
 446 end)
 447
 448 ZGT_CFA = defPrimWord("0>", () -> begin
 449     pushPS(popPS() > 0 ? -1 : 0)
 450     return NEXT
 451 end)
 452
 453 ZLE_CFA = defPrimWord("0<=", () -> begin
 454     pushPS(popPS() <= 0 ? -1 : 0)
 455     return NEXT
 456 end)
 457
 458 ZGE_CFA = defPrimWord("0>=", () -> begin
 459     pushPS(popPS() >= 0 ? -1 : 0)
 460     return NEXT
 461 end)
 462
 463 AND_CFA = defPrimWord("AND", () -> begin
 464     b = popPS()
 465     a = popPS()
 466     pushPS(a & b)
 467     return NEXT
 468 end)
 469
 470 OR_CFA = defPrimWord("OR", () -> begin
 471     b = popPS()
 472     a = popPS()
 473     pushPS(a | b)
 474     return NEXT
 475 end)
 476
 477 XOR_CFA = defPrimWord("XOR", () -> begin
 478     b = popPS()
 479     a = popPS()
 480     pushPS(a $ b)
 481     return NEXT
 482 end)
 483
 484 INVERT_CFA = defPrimWord("INVERT", () -> begin
 485     pushPS(~popPS())
 486     return NEXT
 487 end)
 488
 489 # Literals
 490
 491 LIT_CFA = defPrimWord("LIT", () -> begin
 492     pushPS(mem[reg.IP])
 493     reg.IP += 1
 494     return NEXT
 495 end)
 496
 497 # Memory primitives
 498
 499 STORE_CFA = defPrimWord("!", () -> begin
 500     addr = popPS()
 501     dat = popPS()
 502     mem[addr] = dat
 503     return NEXT
 504 end)
 505
 506 FETCH_CFA = defPrimWord("@", () -> begin
 507     addr = popPS()
 508     pushPS(mem[addr])
 509     return NEXT
 510 end)
 511
 512 ADDSTORE_CFA = defPrimWord("+!", () -> begin
 513     addr = popPS()
 514     toAdd = popPS()
 515     mem[addr] += toAdd
 516     return NEXT
 517 end)
 518
 519 SUBSTORE_CFA = defPrimWord("-!", () -> begin
 520     addr = popPS()
 521     toSub = popPS()
 522     mem[addr] -= toSub
 523     return NEXT
 524 end)
 525
 526
 527 # Return Stack
 528
 529 TOR_CFA = defPrimWord(">R", () -> begin
 530     pushRS(popPS())
 531     return NEXT
 532 end)
 533
 534 FROMR_CFA = defPrimWord("R>", () -> begin
 535     pushPS(popRS())
 536     return NEXT
 537 end)
 538
 539 RFETCH_CFA = defPrimWord("R@", () -> begin
 540     pushPS(mem[reg.RSP])
 541     return NEXT
 542 end)
 543
 544 RSPFETCH_CFA = defPrimWord("RSP@", () -> begin
 545     pushPS(reg.RSP)
 546     return NEXT
 547 end)
 548
 549 RSPSTORE_CFA = defPrimWord("RSP!", () -> begin
 550     reg.RSP = popPS()
 551     return NEXT
 552 end)
 553
 554 RDROP_CFA = defPrimWord("RDROP", () -> begin
 555     popRS()
 556     return NEXT
 557 end)
 558
 559 # Parameter Stack
 560
 561 PSPFETCH_CFA = defPrimWord("PSP@", () -> begin
 562     pushPS(reg.PSP)
 563     return NEXT
 564 end)
 565
 566 PSPSTORE_CFA = defPrimWord("PSP!", () -> begin
 567     reg.PSP = popPS()
 568     return NEXT
 569 end)
 570
 571 # Working Register
 572
 573 WFETCH_CFA = defPrimWord("W@", () -> begin
 574     pushPS(reg.W)
 575     return NEXT
 576 end)
 577
 578 WSTORE_CFA = defPrimWord("W!", () -> begin
 579     reg.W = popPS()
 580     return NEXT
 581 end)
 582
 583 # I/O
 584
 585 sources = Array{Any,1}()
 586 currentSource() = sources[length(sources)]
 587
 588 EOF_CFA = defPrimWord("\x04", () -> begin
 589     if currentSource() != STDIN
 590         close(pop!(sources))
 591         return NEXT
 592     else
 593         return 0
 594     end
 595 end)
 596
 597 EMIT_CFA = defPrimWord("EMIT", () -> begin
 598     print(Char(popPS()))
 599     return NEXT
 600 end)
 601
 602 function raw_mode!(mode::Bool)
 603     if ccall(:jl_tty_set_mode, Int32, (Ptr{Void}, Int32), STDIN.handle, mode) != 0
 604         throw("FATAL: Terminal unable to enter raw mode.")
 605     end
 606 end
 607
 608 function getKey()
 609     raw_mode!(true)
 610     byte = readbytes(STDIN, 1)[1]
 611     raw_mode!(false)
 612
 613     if byte == 0x0d
 614         return 0x0a
 615     elseif byte == 127
 616         return 0x08
 617     else
 618         return byte
 619     end
 620 end
 621
 622 KEY_CFA = defPrimWord("KEY", () -> begin
 623     pushPS(Int(getKey()))
 624     return NEXT
 625 end)
 626
 627 function getLineFromSTDIN()
 628     line = ""
 629     while true
 630         key = Char(getKey())
 631
 632         if key == '\n'
 633             print(" ")
 634             return ASCIIString(line)
 635
 636         elseif key == '\x04'
 637             if isempty(line)
 638                 return string("\x04")
 639             end
 640
 641         elseif key == '\b'
 642             if !isempty(line)
 643                 line = line[1:length(line)-1]
 644                 print("\b \b")
 645             end
 646
 647         elseif key == '\e'
 648             # Strip ANSI escape sequence
 649             nextKey = Char(getKey())
 650             if nextKey == '['
 651                 while true
 652                     nextKey = Char(getKey())
 653                     if nextKey >= '@' || nextKey <= '~'
 654                         break
 655                     end
 656                 end
 657             end
 658
 659         else
 660             print(key)
 661             line = string(line, key)
 662         end
 663     end
 664 end
 665
 666 SPAN, SPAN_CFA = defNewVar("SPAN", 0)
 667 EXPECT_CFA = defPrimWord("EXPECT", () -> begin
 668     maxLen = popPS()
 669     addr = popPS()
 670
 671     if currentSource() == STDIN
 672         line = getLineFromSTDIN()
 673     else
 674         if !eof(currentSource())
 675             line = chomp(readline(currentSource()))
 676         else
 677             line = "\x04" # eof
 678         end
 679     end
 680
 681     mem[SPAN] = min(length(line), maxLen)
 682     putString(line[1:mem[SPAN]], addr)
 683
 684     return NEXT
 685 end)
 686
 687 BASE, BASE_CFA = defNewVar("BASE", 10)
 688 NUMBER_CFA = defPrimWord("NUMBER", () -> begin
 689     wordAddr = popPS()+1
 690     wordLen = mem[wordAddr-1]
 691
 692     s = getString(wordAddr, wordLen)
 693
 694     pushPS(parse(Int64, s, mem[BASE]))
 695
 696     return NEXT
 697 end)
 698
 699 # Dictionary searches
 700
 701 FROMLINK_CFA = defPrimWord("LINK>", () -> begin
 702
 703     addr = popPS()
 704     lenAndFlags = mem[addr+1]
 705     len = lenAndFlags & F_LENMASK
 706
 707     pushPS(addr + 2 + len)
 708
 709     return NEXT
 710 end)
 711
 712 CONTEXT, CONTEXT_CFA = defNewVar("CONTEXT", zeros(Int64, 100))
 713 mem[CONTEXT] = FORTH_CFA
 714 NUMCONTEXT, NUMCONTEXT_CFA = defNewVar("#CONTEXT", 1)
 715
 716 FIND_CFA = defPrimWord("FIND", () -> begin
 717
 718     countedAddr = popPS()
 719     wordAddr = countedAddr + 1
 720     wordLen = mem[countedAddr]
 721     word = lowercase(getString(wordAddr, wordLen))
 722
 723     context = mem[CONTEXT:(CONTEXT+mem[NUMCONTEXT]-1)]
 724
 725     lenAndFlags = 0
 726     lfa = 0
 727
 728     for vocabCFA in reverse(context)
 729         callPrim(mem[vocabCFA])
 730         lfa = popPS()
 731
 732         while (lfa = mem[lfa]) > 0
 733
 734             lenAndFlags = mem[lfa+1]
 735             len = lenAndFlags & F_LENMASK
 736             hidden = (lenAndFlags & F_HIDDEN) == F_HIDDEN
 737
 738             if hidden || len != wordLen
 739                 continue
 740             end
 741
 742             thisWord = lowercase(getString(lfa+2, len))
 743
 744             if thisWord == word
 745                 break
 746             end
 747         end
 748
 749         if lfa>0
 750             break
 751         end
 752     end
 753
 754     if lfa > 0
 755         pushPS(lfa)
 756         callPrim(mem[FROMLINK_CFA])
 757         if (lenAndFlags & F_IMMED) == F_IMMED
 758             pushPS(1)
 759         else
 760             pushPS(-1)
 761         end
 762     else
 763         pushPS(countedAddr)
 764         pushPS(0)
 765     end
 766
 767     return NEXT
 768 end)
 769
 770
 771 # Branching
 772
 773 BRANCH_CFA = defPrimWord("BRANCH", () -> begin
 774     reg.IP += mem[reg.IP]
 775     return NEXT
 776 end)
 777
 778 ZBRANCH_CFA = defPrimWord("0BRANCH", () -> begin
 779     if (popPS() == 0)
 780         reg.IP += mem[reg.IP]
 781     else
 782         reg.IP += 1
 783     end
 784
 785     return NEXT
 786 end)
 787
 788 # Strings
 789
 790 LITSTRING_CFA = defPrimWord("LITSTRING", () -> begin
 791     len = mem[reg.IP]
 792     reg.IP += 1
 793     pushPS(reg.IP)
 794     pushPS(len)
 795     reg.IP += len
 796
 797     return NEXT
 798 end)
 799
 800 TYPE_CFA = defPrimWord("TYPE", () -> begin
 801     len = popPS()
 802     addr = popPS()
 803     str = getString(addr, len)
 804     print(str)
 805     return NEXT
 806 end)
 807
 808 # Interpreter/Compiler-specific I/O
 809
 810 TIB_CFA = defConst("TIB", TIB)
 811 NUMTIB, NUMTIB_CFA = defNewVar("#TIB", 0)
 812 TOIN, TOIN_CFA = defNewVar(">IN", 0)
 813
 814 QUERY_CFA = defWord("QUERY",
 815     [TIB_CFA, LIT_CFA, 160, EXPECT_CFA,
 816     SPAN_CFA, FETCH_CFA, NUMTIB_CFA, STORE_CFA,
 817     LIT_CFA, 0, TOIN_CFA, STORE_CFA,
 818     EXIT_CFA])
 819
 820 WORD_CFA = defPrimWord("WORD", () -> begin
 821     delim = popPS()
 822
 823     # Chew up initial occurrences of delim
 824     while (mem[TOIN]<mem[NUMTIB] && mem[TIB+mem[TOIN]] == delim)
 825         mem[TOIN] += 1
 826     end
 827
 828     countAddr = mem[H]
 829     addr = mem[H]+1
 830
 831     # Start reading in word
 832     count = 0
 833     while (mem[TOIN]<mem[NUMTIB])
 834         mem[addr] = mem[TIB+mem[TOIN]]
 835         mem[TOIN] += 1
 836
 837         if (mem[addr] == delim)
 838             break
 839         end
 840
 841         count += 1
 842         addr += 1
 843     end
 844
 845     # Record count
 846     mem[countAddr] = count
 847     pushPS(countAddr)
 848
 849     return NEXT
 850 end)
 851
 852 # Compilation
 853
 854 STATE, STATE_CFA = defNewVar("STATE", 0)
 855
 856 COMMA_CFA = defPrimWord(",", () -> begin
 857     mem[mem[H]] = popPS()
 858     mem[H] += 1
 859
 860     return NEXT
 861 end)
 862
 863 HERE_CFA = defWord("HERE",
 864     [H_CFA, FETCH_CFA, EXIT_CFA])
 865
 866 HEADER_CFA = defPrimWord("HEADER", () -> begin
 867     wordAddr = popPS()+1
 868     wordLen = mem[wordAddr-1]
 869     word = getString(wordAddr, wordLen)
 870
 871     createHeader(word, 0)
 872
 873     return NEXT
 874 end)
 875
 876 CREATE_CFA = defWord("CREATE",
 877     [LIT_CFA, 32, WORD_CFA, HEADER_CFA,
 878     LIT_CFA, DOVAR, COMMA_CFA,
 879     EXIT_CFA])
 880
 881 DODOES = defPrim(() -> begin
 882     pushRS(reg.IP)
 883     reg.IP = popPS()
 884     pushPS(reg.W + 1)
 885     return NEXT
 886 end, name="DODOES")
 887
 888 DOES_HELPER_CFA = defPrimWord("(DOES>)", () -> begin
 889
 890     pushPS(mem[mem[CURRENT]])
 891     callPrim(mem[FROMLINK_CFA])
 892     cfa = popPS()
 893
 894     runtimeAddr = popPS()
 895
 896     mem[cfa] = defPrim(eval(:(() -> begin
 897         pushPS($(runtimeAddr))
 898         return DODOES
 899     end)), name="doesPrim")
 900
 901     return NEXT
 902 end, flags=F_IMMED | F_HIDDEN)
 903
 904 DOES_CFA = defWord("DOES>",
 905     [LIT_CFA, LIT_CFA, COMMA_CFA, HERE_CFA, LIT_CFA, 3, ADD_CFA, COMMA_CFA,
 906     LIT_CFA, DOES_HELPER_CFA, COMMA_CFA, LIT_CFA, EXIT_CFA, COMMA_CFA, EXIT_CFA],
 907     flags=F_IMMED)
 908
 909 LBRAC_CFA = defPrimWord("[", () -> begin
 910     mem[STATE] = 0
 911     return NEXT
 912 end, flags=F_IMMED)
 913
 914 RBRAC_CFA = defPrimWord("]", () -> begin
 915     mem[STATE] = 1
 916     return NEXT
 917 end, flags=F_IMMED)
 918
 919 HIDDEN_CFA = defPrimWord("HIDDEN", () -> begin
 920     lenAndFlagsAddr = mem[mem[CURRENT]] + 1
 921     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_HIDDEN
 922     return NEXT
 923 end)
 924
 925 COLON_CFA = defWord(":",
 926     [LIT_CFA, 32, WORD_CFA,
 927     HEADER_CFA,
 928     LIT_CFA, DOCOL, COMMA_CFA,
 929     HIDDEN_CFA,
 930     RBRAC_CFA,
 931     EXIT_CFA])
 932
 933 SEMICOLON_CFA = defWord(";",
 934     [LIT_CFA, EXIT_CFA, COMMA_CFA,
 935     HIDDEN_CFA,
 936     LBRAC_CFA,
 937     EXIT_CFA], flags=F_IMMED)
 938
 939 IMMEDIATE_CFA = defPrimWord("IMMEDIATE", () -> begin
 940     lenAndFlagsAddr = mem[mem[CURRENT]] + 1
 941     mem[lenAndFlagsAddr] = mem[lenAndFlagsAddr] $ F_IMMED
 942     return NEXT
 943 end, flags=F_IMMED)
 944
 945 # Outer Interpreter
 946
 947 EXECUTE_CFA = defPrimWord("EXECUTE", () -> begin
 948     reg.W = popPS()
 949     return mem[reg.W]
 950 end)
 951
 952 INTERPRET_CFA = defWord("INTERPRET",
 953     [LIT_CFA, 32, WORD_CFA, # Read next space-delimited word
 954
 955     DUP_CFA, FETCH_CFA, ZE_CFA, ZBRANCH_CFA, 3,
 956         DROP_CFA, EXIT_CFA, # Exit if TIB is exhausted
 957
 958     STATE_CFA, FETCH_CFA, ZBRANCH_CFA, 24,
 959         # Compiling
 960         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 13,
 961
 962             # Found word.
 963             LIT_CFA, -1, EQ_CFA, INVERT_CFA, ZBRANCH_CFA, 4,
 964
 965                 # Immediate: Execute!
 966                 EXECUTE_CFA, BRANCH_CFA, -26,
 967
 968                 # Not immediate: Compile!
 969                 COMMA_CFA, BRANCH_CFA, -29,
 970
 971             # No word found, parse number
 972             NUMBER_CFA, LIT_CFA, LIT_CFA, COMMA_CFA, COMMA_CFA, BRANCH_CFA, -36,
 973
 974        # Interpreting
 975         FIND_CFA, QDUP_CFA, ZBRANCH_CFA, 5,
 976
 977             # Found word. Execute!
 978             DROP_CFA, EXECUTE_CFA, BRANCH_CFA, -44,
 979
 980             # No word found, parse number and leave on stack
 981             NUMBER_CFA, BRANCH_CFA, -47,
 982     EXIT_CFA])
 983
 984 PROMPT_CFA = defPrimWord("PROMPT", () -> begin
 985     if (mem[STATE] == 0 && currentSource() == STDIN)
 986         println(" ok")
 987     end
 988
 989     return NEXT
 990 end)
 991
 992 QUIT_CFA = defWord("QUIT",
 993     [LIT_CFA, 0, STATE_CFA, STORE_CFA,
 994     LIT_CFA, 0, NUMTIB_CFA, STORE_CFA,
 995     RSP0_CFA, RSPSTORE_CFA,
 996     QUERY_CFA,
 997     INTERPRET_CFA, PROMPT_CFA,
 998     BRANCH_CFA,-4])
 999
1000 ABORT_CFA = defWord("ABORT",
1001     [PSP0_CFA, PSPSTORE_CFA, QUIT_CFA])
1002
1003 BYE_CFA = defPrimWord("BYE", () -> begin
1004     println("\nBye!")
1005     return 0
1006 end)
1007
1008 # File I/O
1009
1010 INCLUDE_CFA = defPrimWord("INCLUDE", () -> begin
1011     pushPS(32)
1012     callPrim(mem[WORD_CFA])
1013     wordAddr = popPS()+1
1014     wordLen = mem[wordAddr-1]
1015     word = getString(wordAddr, wordLen)
1016
1017     fname = word
1018     if !isfile(fname)
1019         fname = Pkg.dir("forth","src",word)
1020         if !isfile(fname)
1021             error("No file named $word found in current directory or package source directory.")
1022         end
1023     end
1024     push!(sources, open(fname, "r"))
1025
1026     # Clear input buffer
1027     mem[NUMTIB] = 0
1028
1029     return NEXT
1030 end)
1031
1032
1033 #### VM loop ####
1034
1035 initialized = false
1036 initFileName = nothing
1037 if isfile("lib.4th")
1038     initFileName = "lib.4th"
1039 elseif isfile(Pkg.dir("forth","src", "lib.4th"))
1040     initFileName = Pkg.dir("forth","src","lib.4th")
1041 end
1042
1043 function run(;initialize=true)
1044     # Begin with STDIN as source
1045     push!(sources, STDIN)
1046
1047     global initialized, initFileName
1048     if !initialized && initialize
1049         if initFileName != nothing
1050             print("Including definitions from $initFileName...")
1051             push!(sources, open(initFileName, "r"))
1052             initialized = true
1053         else
1054             println("No library file found. Only primitive words available.")
1055         end
1056     end
1057
1058     # Start with IP pointing to first instruction of outer interpreter
1059     reg.IP = QUIT_CFA + 1
1060
1061     # Primitive processing loop.
1062     # Everyting else is simply a consequence of this loop!
1063     jmp = NEXT
1064     while jmp != 0
1065         try
1066             #println("Entering prim $(getPrimName(jmp))")
1067             jmp = callPrim(jmp)
1068
1069         catch ex
1070             showerror(STDOUT, ex)
1071             println()
1072
1073             while !isempty(sources) && currentSource() != STDIN
1074                 close(pop!(sources))
1075             end
1076
1077             # QUIT
1078             reg.IP = ABORT_CFA + 1
1079             jmp = NEXT
1080         end
1081     end
1082 end
1083
1084 # Debugging tools
1085
1086 TRACE_CFA = defPrimWord("TRACE", () -> begin
1087     println("reg.W: $(reg.W) reg.IP: $(reg.IP)")
1088     print("PS: "); printPS()
1089     print("RS: "); printRS()
1090     print("[paused]")
1091     readline()
1092
1093     return NEXT
1094 end)
1095
1096 function dump(startAddr::Int64; count::Int64 = 100, cellsPerLine::Int64 = 10)
1097     chars = Array{Char,1}(cellsPerLine)
1098
1099     lineStartAddr = cellsPerLine*div((startAddr-1),cellsPerLine) + 1
1100     endAddr = startAddr + count - 1
1101
1102     q, r = divrem((endAddr-lineStartAddr+1), cellsPerLine)
1103     numLines = q + (r > 0 ? 1 : 0)
1104
1105     i = lineStartAddr
1106     for l in 1:numLines
1107         print(i,":")
1108
1109         for c in 1:cellsPerLine
1110             if i >= startAddr && i <= endAddr
1111                 print("\t",mem[i])
1112                 if mem[i]>=32 && mem[i]<128
1113                     chars[c] = Char(mem[i])
1114                 else
1115                     chars[c] = '.'
1116                 end
1117             else
1118                 print("\t")
1119                 chars[c] = ' '
1120             end
1121
1122             i += 1
1123         end
1124
1125         println("\t", ASCIIString(chars))
1126     end
1127 end
1128
1129 function printPS()
1130     count = reg.PSP - PSP0
1131
1132     if count > 0
1133         print("<$count>")
1134         for i in (PSP0+1):reg.PSP
1135             print(" $(mem[i])")
1136         end
1137         println()
1138     else
1139         println("Parameter stack empty")
1140     end
1141 end
1142
1143 function printRS()
1144     count = reg.RSP - RSP0
1145
1146     if count > 0
1147         print("<$count>")
1148         for i in (RSP0+1):reg.RSP
1149             print(" $(mem[i])")
1150         end
1151         println()
1152     else
1153         println("Return stack empty")
1154     end
1155 end
1156
1157 DUMP = defPrimWord("DUMP", () -> begin
1158     count = popPS()
1159     addr = popPS()
1160
1161     println()
1162     dump(addr, count=count)
1163
1164     return NEXT
1165 end)
1166
1167 end