elopher.el

   1 ;;; elopher.el --- gopher client
   2
   3 ;;; Commentary:
   4
   5 ;; Simple gopher client in elisp.
   6
   7 ;;; Code:
   8
   9 ;;; Global constants
  10 ;;
  11
  12 (defconst elopher-version "1.0.0"
  13   "Current version of elopher.")
  14
  15 (defconst elopher-margin-width 6
  16   "Width of left-hand margin used when rendering indicies.")
  17
  18 (defconst elopher-start-index
  19   (mapconcat
  20    'identity
  21    (list "i\tfake\tfake\t1"
  22          "i--------------------------------------------\tfake\tfake\t1"
  23          "i          Elopher Gopher Client             \tfake\tfake\t1"
  24          (format "i              version %s\tfake\tfake\t1" elopher-version)
  25          "i--------------------------------------------\tfake\tfake\t1"
  26          "i\tfake\tfake\t1"
  27          "iBasic usage:\tfake\tfake\t1"
  28          "i\tfake\tfake\t1"
  29          "i - tab/shift-tab: next/prev directory entry on current page\tfake\tfake\t1"
  30          "i - RET/mouse-1: open directory entry under cursor\tfake\tfake\t1"
  31          "i - u: return to parent directory entry\tfake\tfake\t1"
  32          "i - g: go to a particular page\tfake\tfake\t1"
  33          "i - r: reload current page\tfake\tfake\t1"
  34          "i - d: download directory entry under cursor\tfake\tfake\t1"
  35          "i - w: display the raw server response for the current page\tfake\tfake\t1"
  36          "i\tfake\tfake\t1"
  37          "iPlaces to start exploring Gopherspace:\tfake\tfake\t1"
  38          "i\tfake\tfake\t1"
  39          "1Floodgap Systems Gopher Server\t\tgopher.floodgap.com\t70"
  40          "i\tfake\tfake\t1"
  41          "iAlternatively, select the following item and enter some\tfake\tfake\t1"
  42          "isearch terms:\tfake\tfake\t1"
  43          "i\tfake\tfake\t1"
  44          "7Veronica-2 Gopher Search Engine\t/v2/vs\tgopher.floodgap.com\t70"
  45          ".")
  46    "\r\n"))
  47
  48
  49 ;;; Customization group
  50 ;;
  51
  52 (defgroup elopher nil
  53   "A simple gopher client."
  54   :group 'applications)
  55
  56 (defcustom elopher-index-face '(foreground-color . "cyan")
  57   "Face used for index records."
  58   :type '(face))
  59
  60 (defcustom elopher-text-face '(foreground-color . "white")
  61   "Face used for text records."
  62   :type '(face))
  63
  64 (defcustom elopher-info-face '(foreground-color . "gray")
  65   "Face used for info records."
  66   :type '(face))
  67
  68 (defcustom elopher-image-face '(foreground-color . "green")
  69   "Face used for image records."
  70   :type '(face))
  71
  72 (defcustom elopher-search-face '(foreground-color . "orange")
  73   "Face used for image records."
  74   :type '(face))
  75
  76 (defcustom elopher-http-face '(foreground-color . "yellow")
  77   "Face used for image records."
  78   :type '(face))
  79
  80 (defcustom elopher-binary-face '(foreground-color . "magenta")
  81   "Face used for image records."
  82   :type '(face))
  83
  84 (defcustom elopher-unknown-face '(foreground-color . "red")
  85   "Face used for unknown record types."
  86   :type '(face))
  87
  88 (defcustom elopher-open-urls-with-eww nil
  89   "If non-nil, open URL selectors using eww.
  90 Otherwise, use the system browser via the BROWSE-URL function."
  91   :type '(boolean))
  92
  93 ;;; Model
  94 ;;
  95
  96 ;; Address
  97
  98 (defun elopher-make-address (selector host port)
  99   (list selector host port))
 100
 101 (defun elopher-address-selector (address)
 102   (car address))
 103
 104 (defun elopher-address-host (address)
 105   (cadr address))
 106
 107 (defun elopher-address-port (address)
 108   (caddr address))
 109
 110 ;; Node
 111
 112 (defun elopher-make-node (parent address getter &optional content pos)
 113   (list parent address getter content pos))
 114
 115 (defun elopher-node-parent (node)
 116   (elt node 0))
 117
 118 (defun elopher-node-address (node)
 119   (elt node 1))
 120
 121 (defun elopher-node-getter (node)
 122   (elt node 2))
 123
 124 (defun elopher-node-content (node)
 125   (elt node 3))
 126
 127 (defun elopher-node-pos (node)
 128   (elt node 4))
 129
 130 (defun elopher-set-node-content (node content)
 131   (setcar (nthcdr 3 node) content))
 132
 133 (defun elopher-set-node-pos (node pos)
 134   (setcar (nthcdr 4 node) pos))
 135
 136 (defun elopher-save-pos ()
 137   (when elopher-current-node
 138     (elopher-set-node-pos elopher-current-node (point))))
 139
 140 (defun elopher-restore-pos ()
 141   (let ((pos (elopher-node-pos elopher-current-node)))
 142     (if pos
 143         (goto-char pos)
 144       (goto-char (point-min)))))
 145
 146 ;; Node graph traversal
 147
 148 (defvar elopher-current-node)
 149
 150 (defun elopher-visit-node (node &optional getter)
 151   (elopher-save-pos)
 152   (elopher-process-cleanup)
 153   (setq elopher-current-node node)
 154   (if getter
 155       (funcall getter)
 156     (funcall (elopher-node-getter node))))
 157
 158 (defun elopher-visit-parent-node ()
 159   (let ((parent-node (elopher-node-parent elopher-current-node)))
 160     (when parent-node
 161       (elopher-visit-node parent-node))))
 162
 163 (defun elopher-reload-current-node ()
 164   (elopher-set-node-content elopher-current-node nil)
 165   (elopher-visit-node elopher-current-node))
 166
 167 ;;; Buffer preparation
 168 ;;
 169
 170 (defmacro elopher-with-clean-buffer (&rest args)
 171   "Evaluate ARGS with a clean *elopher* buffer as current."
 172   (list 'progn
 173         '(switch-to-buffer "*elopher*")
 174         '(elopher-mode)
 175         (append (list 'let '((inhibit-read-only t))
 176                       '(erase-buffer))
 177                 args)))
 178
 179 ;;; Index rendering
 180 ;;
 181
 182 (defun elopher-insert-index (string)
 183   "Insert the index corresponding to STRING into the current buffer."
 184   (dolist (line (split-string string "\r\n"))
 185     (unless (= (length line) 0)
 186       (elopher-insert-index-record line))))
 187
 188 (defun elopher-insert-margin (&optional type-name)
 189   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 190   (if type-name
 191       (progn
 192         (insert (format (concat "%" (number-to-string (- elopher-margin-width 1)) "s")
 193                         (concat
 194                          (propertize "[" 'face '(foreground-color . "blue"))
 195                          (propertize type-name 'face '(foreground-color . "white"))
 196                          (propertize "]" 'face '(foreground-color . "blue")))))
 197         (insert " "))
 198     (insert (make-string elopher-margin-width ?\s))))
 199
 200 (defvar elopher-type-map
 201   `((?0 elopher-get-text-node "T" ,elopher-text-face)
 202     (?1 elopher-get-index-node "/" ,elopher-index-face)
 203     (?g elopher-get-image-node "im" ,elopher-image-face)
 204     (?p elopher-get-image-node "im" ,elopher-image-face)
 205     (?I elopher-get-image-node "im" ,elopher-image-face)
 206     (?4 elopher-get-binary-node "B" ,elopher-binary-face)
 207     (?9 elopher-get-binary-node "B" ,elopher-binary-face)
 208     (?7 elopher-get-search-node "?" ,elopher-search-face)))
 209
 210 (defun elopher-insert-index-record (line)
 211   "Insert the index record corresponding to LINE into the current buffer."
 212   (let* ((type (elt line 0))
 213          (fields (split-string (substring line 1) "\t"))
 214          (display-string (elt fields 0))
 215          (selector (elt fields 1))
 216          (host (elt fields 2))
 217          (port (elt fields 3))
 218          (address (elopher-make-address selector host port))
 219          (type-map-entry (alist-get type elopher-type-map)))
 220     (if type-map-entry
 221         (let ((getter (car type-map-entry))
 222               (margin-code (cadr type-map-entry))
 223               (face (caddr type-map-entry)))
 224           (elopher-insert-margin margin-code)
 225           (insert-text-button display-string
 226                               'face face
 227                               'elopher-node (elopher-make-node elopher-current-node
 228                                                                address
 229                                                                getter)
 230                               'action #'elopher-click-link
 231                               'follow-link t
 232                               'help-echo (format "mouse-1, RET: open %s on %s port %s"
 233                                                  selector host port)))
 234       (pcase type
 235         (?i (elopher-insert-margin) ; Information
 236             (insert (propertize display-string
 237                                 'face elopher-info-face)))
 238         (?h (elopher-insert-margin "W") ; Web link
 239             (let ((url (elt (split-string selector "URL:") 1)))
 240               (insert-text-button display-string
 241                                   'face elopher-http-face
 242                                   'elopher-url url
 243                                   'action #'elopher-click-url
 244                                   'follow-link t
 245                                   'help-echo (format "mouse-1, RET: open url %s" url))))
 246         (?.) ; Occurs at end of index, can safely ignore.
 247         (tp (elopher-insert-margin (concat (char-to-string tp) "?"))
 248             (insert (propertize display-string
 249                                 'face elopher-unknown-face)))))
 250     (insert "\n")))
 251
 252
 253 ;;; Selector retrieval (all kinds)
 254 ;;
 255
 256 (defun elopher-process-cleanup ()
 257   "Immediately shut down any extant elopher process."
 258   (let ((p (get-process "elopher-process")))
 259     (if p (delete-process p))))
 260
 261 (defvar elopher-selector-string)
 262
 263 (defun elopher-get-selector (address after)
 264   "Retrieve selector specified by ADDRESS, then execute AFTER.
 265 The result is stored as a string in the variable elopher-selector-string."
 266   (setq elopher-selector-string "")
 267   (make-network-process
 268    :name "elopher-process"
 269    :host (elopher-address-host address)
 270    :service (elopher-address-port address)
 271    :filter (lambda (proc string)
 272              (setq elopher-selector-string (concat elopher-selector-string string)))
 273    :sentinel after)
 274   (process-send-string "elopher-process"
 275                        (concat (elopher-address-selector address) "\n")))
 276
 277 ;; Index retrieval
 278
 279 (defun elopher-get-index-node ()
 280   (let ((content (elopher-node-content elopher-current-node))
 281         (address (elopher-node-address elopher-current-node)))
 282     (if content
 283         (progn
 284           (elopher-with-clean-buffer
 285            (insert content))
 286           (elopher-restore-pos))
 287       (if address
 288           (progn
 289             (elopher-with-clean-buffer
 290              (insert "LOADING DIRECTORY..."))
 291             (elopher-get-selector address
 292                                   (lambda (proc event)
 293                                     (unless (string-prefix-p "deleted" event)
 294                                       (elopher-with-clean-buffer
 295                                        (elopher-insert-index elopher-selector-string))
 296                                       (elopher-restore-pos)
 297                                       (elopher-set-node-content elopher-current-node
 298                                                                 (buffer-string))))))
 299         (progn
 300           (elopher-with-clean-buffer
 301            (elopher-insert-index elopher-start-index))
 302           (elopher-restore-pos)
 303           (elopher-set-node-content elopher-current-node
 304                                     (buffer-string)))))))
 305
 306 ;; Text retrieval
 307
 308 (defvar elopher-url-regex "\\(https?\\|gopher\\)://\\([a-z.\-]+\\)\\(?3::[0-9]+\\)?\\(?4:/[^ \r\n\t(),]*\\)")
 309
 310 (defun elopher-buttonify-urls (string)
 311   "Turn substrings which look like urls in STRING into clickable buttons."
 312   (with-temp-buffer
 313     (insert string)
 314     (goto-char (point-min))
 315     (while (re-search-forward elopher-url-regex nil t)
 316       (let ((url (match-string 0))
 317             (protocol (downcase (match-string 1))))
 318         (if (string= protocol "gopher")
 319             (let* ((host (match-string 2))
 320                    (port 70)
 321                    (type-and-selector (match-string 4))
 322                    (type (if (> (length type-and-selector) 1)
 323                              (elt type-and-selector 1)
 324                            ?1))
 325                    (selector (if (> (length type-and-selector) 1)
 326                                  (substring type-and-selector 2)
 327                                ""))
 328                    (address (elopher-make-address selector host port))
 329                    (getter (car (alist-get type elopher-type-map))))
 330               (make-text-button (match-beginning 0)
 331                                 (match-end 0)
 332                                 'elopher-node (elopher-make-node elopher-current-node
 333                                                                  address
 334                                                                  getter)
 335                                 'action #'elopher-click-link
 336                                 'follow-link t
 337                                 'help-echo (format "mouse-1, RET: open %s on %s port %s"
 338                                                    selector host port)))
 339           (make-text-button (match-beginning 0)
 340                             (match-end 0)
 341                             'elopher-url url
 342                             'action #'elopher-click-url
 343                             'follow-link t
 344                             'help-echo (format "mouse-1, RET: open url %s" url)))))
 345     (buffer-string)))
 346
 347 (defun elopher-process-text (string)
 348   (let* ((chopped-str (replace-regexp-in-string "\r\n\.\r\n$" "\r\n" string))
 349          (cleaned-str (replace-regexp-in-string "\r" "" chopped-str)))
 350     (elopher-buttonify-urls cleaned-str)))
 351
 352 (defun elopher-get-text-node ()
 353   (let ((content (elopher-node-content elopher-current-node))
 354         (address (elopher-node-address elopher-current-node)))
 355     (if content
 356         (progn
 357           (elopher-with-clean-buffer
 358            (insert content))
 359           (elopher-restore-pos))
 360       (progn
 361         (elopher-with-clean-buffer
 362          (insert "LOADING TEXT..."))
 363         (elopher-get-selector address
 364                               (lambda (proc event)
 365                                 (unless (string-prefix-p "deleted" event)
 366                                   (elopher-with-clean-buffer
 367                                    (insert (elopher-process-text elopher-selector-string)))
 368                                   (elopher-restore-pos)
 369                                   (elopher-set-node-content elopher-current-node
 370                                                             (buffer-string)))))))))
 371
 372 ;; Image retrieval
 373
 374 (defun elopher-get-image-node ()
 375   (let ((content (elopher-node-content elopher-current-node))
 376         (address (elopher-node-address elopher-current-node)))
 377     (if content
 378         (progn
 379           (elopher-with-clean-buffer
 380            (insert-image content))
 381           (setq cursor-type nil)
 382           (elopher-restore-pos))
 383       (progn
 384         (elopher-with-clean-buffer
 385          (insert "LOADING IMAGE..."))
 386         (elopher-get-selector address
 387                               (lambda (proc event)
 388                                 (unless (string-prefix-p "deleted" event)
 389                                   (let ((image (create-image
 390                                                 (string-as-unibyte elopher-selector-string)
 391                                                 nil t)))
 392                                     (elopher-with-clean-buffer
 393                                      (insert-image image))
 394                                     (setq cursor-type nil)
 395                                     (elopher-restore-pos)
 396                                     (elopher-set-node-content elopher-current-node
 397                                                               image)))))))))
 398
 399 ;; Search retrieval
 400
 401 (defun elopher-get-search-node ()
 402   (let* ((content (elopher-node-content elopher-current-node))
 403          (address (elopher-node-address elopher-current-node)))
 404     (if content
 405         (progn
 406           (elopher-with-clean-buffer
 407             (insert content))
 408           (elopher-restore-pos)
 409           (message "Displaying cached search results.  Reload to perform a new search."))
 410       (let* ((query-string (read-string "Query: "))
 411              (query-selector (concat (elopher-address-selector address) "\t" query-string))
 412              (search-address (elopher-make-address query-selector
 413                                                    (elopher-address-host address)
 414                                                    (elopher-address-port address))))
 415         (elopher-with-clean-buffer
 416          (insert "LOADING RESULTS..."))
 417         (elopher-get-selector search-address
 418                               (lambda (proc event)
 419                                 (unless (string-prefix-p "deleted" event)
 420                                   (elopher-with-clean-buffer
 421                                    (elopher-insert-index elopher-selector-string))
 422                                   (goto-char (point-min))
 423                                   (elopher-set-node-content elopher-current-node
 424                                                             (buffer-string)))))))))
 425
 426 ;; Raw server response retrieval
 427
 428 (defun elopher-get-node-raw ()
 429   (let* ((content (elopher-node-content elopher-current-node))
 430          (address (elopher-node-address elopher-current-node)))
 431     (elopher-with-clean-buffer
 432      (insert "LOADING RAW SERVER RESPONSE..."))
 433     (if address
 434         (elopher-get-selector address
 435                               (lambda (proc event)
 436                                 (unless (string-prefix-p "deleted" event)
 437                                   (elopher-with-clean-buffer
 438                                    (insert elopher-selector-string))
 439                                   (goto-char (point-min)))))
 440       (progn
 441         (elopher-with-clean-buffer
 442          (insert elopher-start-index))
 443         (goto-char (point-min)))))
 444   (message "Displaying raw server response.  Reload to return to standard view."))
 445
 446
 447 ;; File export retrieval
 448
 449 (defvar elopher-download-filename)
 450
 451 (defun elopher-get-node-download ()
 452   (let* ((address (elopher-node-address elopher-current-node))
 453          (selector (elopher-address-selector address)))
 454     (elopher-visit-parent-node) ; Do first in case of non-local exits.
 455     (let* ((filename-proposal (file-name-nondirectory selector))
 456            (filename (read-file-name "Save file as: "
 457                                      nil nil nil
 458                                      (if (> (length filename-proposal) 0)
 459                                          filename-proposal
 460                                        "gopher.file"))))
 461       (message "Downloading...")
 462       (setq elopher-download-filename filename)
 463       (elopher-get-selector address
 464                             (lambda (proc event)
 465                               (let ((coding-system-for-write 'binary))
 466                                 (with-temp-file elopher-download-filename
 467                                   (insert elopher-selector-string)
 468                                   (message (format "Download complate, saved to file %s."
 469                                                    elopher-download-filename)))))))))
 470
 471
 472 ;;; Navigation procedures
 473 ;;
 474
 475 (defun elopher-next-link ()
 476   (interactive)
 477   (forward-button 1))
 478
 479 (defun elopher-prev-link ()
 480   (interactive)
 481   (backward-button 1))
 482
 483 (defun elopher-click-link (button)
 484   (let ((node (button-get button 'elopher-node)))
 485     (elopher-visit-node node)))
 486
 487 (defun elopher-click-url (button)
 488   (let ((url (button-get button 'elopher-url)))
 489     (if elopher-open-urls-with-eww
 490         (browse-web url)
 491       (browse-url url))))
 492
 493 (defun elopher-follow-closest-link ()
 494   (interactive)
 495   (push-button))
 496
 497 (defun elopher-go ()
 498   "Go to a particular gopher site."
 499   (interactive)
 500   (let* (
 501          (hostname (read-string "Gopher host: "))
 502          (selector (read-string "Selector (default none): " nil nil ""))
 503          (port (read-string "Port (default 70): " nil nil 70))
 504          (address (list selector hostname port)))
 505     (elopher-visit-node
 506      (elopher-make-node elopher-current-node
 507                         address
 508                         #'elopher-get-index-node))))
 509
 510 (defun  elopher-reload ()
 511   "Reload current page."
 512   (interactive)
 513   (elopher-reload-current-node))
 514
 515 (defun elopher-view-raw ()
 516   "View current page as plain text."
 517   (interactive)
 518   (elopher-visit-node elopher-current-node
 519                       #'elopher-get-node-raw))
 520
 521 (defun elopher-back ()
 522   "Go to previous site."
 523   (interactive)
 524   (if (elopher-node-parent elopher-current-node)
 525       (elopher-visit-parent-node)
 526     (message "No previous site.")))
 527
 528 (defun elopher-download ()
 529   "Download the link at point."
 530   (interactive)
 531   (let ((button (button-at (point))))
 532     (if button
 533         (elopher-visit-node (button-get button 'elopher-node)
 534                             #'elopher-get-node-download)
 535       (message "No link selected."))))
 536
 537
 538 ;;; Mode and keymap
 539 ;;
 540
 541 (defvar elopher-mode-map
 542   (let ((map (make-sparse-keymap)))
 543     (define-key map (kbd "<tab>") 'elopher-next-link)
 544     (define-key map (kbd "<S-tab>") 'elopher-prev-link)
 545     (define-key map (kbd "u") 'elopher-back)
 546     (define-key map (kbd "g") 'elopher-go)
 547     (define-key map (kbd "r") 'elopher-reload)
 548     (define-key map (kbd "w") 'elopher-view-raw)
 549     (define-key map (kbd "d") 'elopher-download)
 550     (when (fboundp 'evil-define-key)
 551       (evil-define-key 'normal map
 552         (kbd "C-]") 'elopher-follow-closest-link
 553         (kbd "C-t") 'elopher-back
 554         (kbd "u") 'elopher-back
 555         (kbd "g") 'elopher-go
 556         (kbd "r") 'elopher-reload
 557         (kbd "w") 'elopher-view-raw
 558         (kbd "d") 'elopher-download))
 559     map)
 560   "Keymap for gopher client.")
 561
 562 (define-derived-mode elopher-mode special-mode "elopher"
 563   "Major mode for elopher, an elisp gopher client.")
 564
 565
 566 ;;; Main start procedure
 567 ;;
 568
 569 (defun elopher ()
 570   "Start elopher with default landing page."
 571   (interactive)
 572   (setq elopher-current-node nil)
 573   (let ((start-node (elopher-make-node nil nil #'elopher-get-index-node)))
 574     (elopher-visit-node start-node))
 575   "Started Elopher.") ; Otherwise (elopher) evaluates to start page string.
 576
 577 ;;; elopher.el ends here
 578