elopher.el

   1 ;;; elopher.el --- gopher client
   2
   3 ;;; Commentary:
   4
   5 ;; Simple gopher client in elisp.
   6
   7 ;;; Code:
   8
   9 ;;; Global constants
  10 ;;
  11
  12 (defconst elopher-version "1.0.0"
  13   "Current version of elopher.")
  14
  15 (defconst elopher-margin-width 6
  16   "Width of left-hand margin used when rendering indicies.")
  17
  18 (defconst elopher-start-index
  19   (string-join
  20    (list "i\tfake\tfake\t1"
  21          "i--------------------------------------------\tfake\tfake\t1"
  22          "i          Elopher Gopher Client             \tfake\tfake\t1"
  23          (format "i              version %s\tfake\tfake\t1" elopher-version)
  24          "i--------------------------------------------\tfake\tfake\t1"
  25          "i\tfake\tfake\t1"
  26          "iBasic usage:\tfake\tfake\t1"
  27          "i - tab/shift-tab: next/prev directory entry\tfake\tfake\t1"
  28          "i - RET/mouse-1: open directory entry\tfake\tfake\t1"
  29          "i - u: return to parent directory entry\tfake\tfake\t1"
  30          "i - g: go to a particular site\tfake\tfake\t1"
  31          "i - r: reload current page\tfake\tfake\t1"
  32          "i\tfake\tfake\t1"
  33          "iPlaces to start exploring Gopherspace:\tfake\tfake\t1"
  34          "1Floodgap Systems Gopher Server\t\tgopher.floodgap.com\t70"
  35          "1Super-Dimensional Fortress\t\tsdf.org\t70"
  36          "i\tfake\tfake\t1"
  37          "iTest entries:\tfake\tfake\t1"
  38          "pXKCD comic image\t/fun/xkcd/comics/2130/2137/text_entry.png\tgopher.floodgap.com\t70"
  39          "1Test server\t\tlocalhost\t70"
  40          ".")
  41    "\r\n"))
  42
  43
  44 ;;; Customization group
  45 ;;
  46
  47 (defgroup elopher nil
  48   "A simple gopher client."
  49   :group 'applications)
  50
  51 (defcustom elopher-index-face '(foreground-color . "cyan")
  52   "Face used for index records.")
  53 (defcustom elopher-text-face '(foreground-color . "white")
  54   "Face used for text records.")
  55 (defcustom elopher-info-face '(foreground-color . "gray")
  56   "Face used for info records.")
  57 (defcustom elopher-image-face '(foreground-color . "green")
  58   "Face used for image records.")
  59 (defcustom elopher-unknown-face '(foreground-color . "red")
  60   "Face used for unknown record types.")
  61
  62 ;;; Model
  63 ;;
  64
  65 ;; Address
  66
  67 (defun elopher-make-address (selector host port)
  68   (list selector host port))
  69
  70 (defun elopher-address-selector (address)
  71   (car address))
  72
  73 (defun elopher-address-host (address)
  74   (cadr address))
  75
  76 (defun elopher-address-port (address)
  77   (caddr address))
  78
  79 ;; Node
  80
  81 (defun elopher-make-node (parent address getter &optional content pos)
  82   (list parent address getter content pos))
  83
  84 (defun elopher-node-parent (node)
  85   (elt node 0))
  86
  87 (defun elopher-node-address (node)
  88   (elt node 1))
  89
  90 (defun elopher-node-getter (node)
  91   (elt node 2))
  92
  93 (defun elopher-node-content (node)
  94   (elt node 3))
  95
  96 (defun elopher-node-pos (node)
  97   (elt node 4))
  98
  99 (defun elopher-set-node-content (node content)
 100   (setcar (nthcdr 3 node) content))
 101
 102 (defun elopher-set-node-pos (node pos)
 103   (setcar (nthcdr 4 node) pos))
 104
 105 (defun elopher-save-pos ()
 106   (when elopher-current-node
 107     (elopher-set-node-pos elopher-current-node (point))))
 108
 109 (defun elopher-restore-pos ()
 110   (let ((pos (elopher-node-pos elopher-current-node)))
 111     (if pos
 112         (goto-char pos)
 113       (goto-char (point-min)))))
 114
 115 ;; Node graph traversal
 116
 117 (defvar elopher-current-node)
 118
 119 (defun elopher-visit-node (node)
 120   (elopher-save-pos)
 121   (elopher-prepare-buffer)
 122   (setq elopher-current-node node)
 123   (funcall (elopher-node-getter node)))
 124
 125 (defun elopher-visit-parent-node ()
 126   (let ((parent-node (elopher-node-parent elopher-current-node)))
 127     (when parent-node
 128       (elopher-visit-node parent-node))))
 129
 130 (defun elopher-reload-current-node ()
 131   (elopher-set-node-content elopher-current-node nil)
 132   (elopher-visit-node elopher-current-node))
 133
 134
 135 ;;; Buffer preparation
 136 ;;
 137
 138 (defun elopher-prepare-buffer ()
 139   (switch-to-buffer "*elopher*")
 140   (elopher-mode)
 141   (let ((inhibit-read-only t))
 142     (erase-buffer)))
 143
 144
 145 ;;; Index rendering
 146 ;;
 147
 148 (defun elopher-insert-index (string)
 149   "Inserts the index corresponding to STRING into the current buffer."
 150   (dolist (line (split-string string "\r\n"))
 151     (unless (string-empty-p line)
 152       (elopher-insert-index-record line))))
 153
 154 (defun elopher-insert-margin (&optional type-name)
 155   "Insert index margin, optionally containing the TYPE-NAME, into the current buffer."
 156   (if type-name
 157       (progn
 158         (insert (format (concat "%" (number-to-string (- elopher-margin-width 1)) "s")
 159                         (concat
 160                          (propertize "[" 'face '(foreground-color . "blue"))
 161                          (propertize type-name 'face '(foreground-color . "white"))
 162                          (propertize "]" 'face '(foreground-color . "blue")))))
 163         (insert " "))
 164     (insert (make-string elopher-margin-width ?\s))))
 165
 166 (defun elopher-insert-index-record (line)
 167   "Inserts the index record corresponding to LINE into the current buffer."
 168   (let* ((type (elt line 0))
 169          (fields (split-string (substring line 1) "\t"))
 170          (display-string (elt fields 0))
 171          (address (elopher-make-address (elt fields 1) (elt fields 2) (elt fields 3)))
 172          (help-string (format "mouse-1, RET: open %s on %s port %s"
 173                               (elopher-address-selector address)
 174                               (elopher-address-host address)
 175                               (elopher-address-port address))))
 176     (pcase type
 177       (?i (elopher-insert-margin)
 178           (insert (propertize display-string
 179                               'face elopher-info-face)))
 180       (?0 (elopher-insert-margin "T")
 181           (insert-text-button display-string
 182                               'face elopher-text-face
 183                               'elopher-node (elopher-make-node elopher-current-node
 184                                                                address
 185                                                                #'elopher-get-text-node)
 186                               'action #'elopher-click-link
 187                               'follow-link t
 188                               'help-echo help-string))
 189       (?1 (elopher-insert-margin "/")
 190           (insert-text-button display-string
 191                               'face elopher-index-face
 192                               'elopher-node (elopher-make-node elopher-current-node
 193                                                                address
 194                                                                #'elopher-get-index-node)
 195                               'action #'elopher-click-link
 196                               'follow-link t
 197                               'help-echo help-string))
 198       (?.) ; Occurs at end of index, can safely ignore.
 199       (tp (elopher-insert-margin (concat (char-to-string tp) "?"))
 200           (insert (propertize display-string
 201                               'face elopher-unknown-face))))
 202     (insert "\n")))
 203
 204
 205 ;;; Selector retrieval (all kinds)
 206 ;;
 207
 208 (defvar elopher-selector-string)
 209
 210 (defun elopher-get-selector (address after)
 211   (setq elopher-selector-string "")
 212   (let ((p (get-process "elopher-process")))
 213     (if p (delete-process p)))
 214   (make-network-process
 215    :name "elopher-process"
 216    :host (elopher-address-host address)
 217    :service (elopher-address-port address)
 218    :filter (lambda (proc string)
 219              (setq elopher-selector-string (concat elopher-selector-string string)))
 220    :sentinel after)
 221   (process-send-string "elopher-process"
 222                        (concat (elopher-address-selector address) "\n")))
 223
 224 ;; Index retrieval
 225
 226 (defun elopher-get-index-node ()
 227   (let ((content (elopher-node-content elopher-current-node))
 228         (address (elopher-node-address elopher-current-node)))
 229     (if content
 230         (progn
 231           (let ((inhibit-read-only t))
 232             (insert content))
 233           (elopher-restore-pos))
 234       (if address
 235           (elopher-get-selector address
 236                                 (lambda (proc event)
 237                                   (let ((inhibit-read-only t))
 238                                     (elopher-insert-index elopher-selector-string))
 239                                   (elopher-restore-pos)
 240                                   (elopher-set-node-content elopher-current-node
 241                                                             (buffer-string))))
 242         (progn
 243           (let ((inhibit-read-only t))
 244             (elopher-insert-index elopher-start-index))
 245           (elopher-restore-pos)
 246           (elopher-set-node-content elopher-current-node
 247                                     (buffer-string)))))))
 248
 249 ;; Text retrieval
 250
 251 (defun elopher-strip-CRs (string)
 252   (replace-regexp-in-string "\r" "" string))
 253
 254 (defun elopher-get-text-node ()
 255   (let ((content (elopher-node-content elopher-current-node))
 256         (address (elopher-node-address elopher-current-node)))
 257     (if content
 258         (progn
 259           (let ((inhibit-read-only t))
 260             (insert content))
 261           (elopher-restore-pos))
 262       (elopher-get-selector address
 263                             (lambda (proc event)
 264                               (let ((inhibit-read-only t))
 265                                 (insert (elopher-strip-CRs elopher-selector-string)))
 266                               (elopher-restore-pos)
 267                               (elopher-set-node-content elopher-current-node
 268                                                         (buffer-string)))))))
 269
 270 ;;; Navigation methods
 271 ;;
 272
 273 (defun elopher-next-link ()
 274   (interactive)
 275   (forward-button 1))
 276
 277 (defun elopher-prev-link ()
 278   (interactive)
 279   (backward-button 1))
 280
 281 (defun elopher-click-link (button)
 282   (let ((node (button-get button 'elopher-node)))
 283     (elopher-visit-node node)))
 284
 285 (defun elopher-follow-closest-link ()
 286   (interactive)
 287   (push-button))
 288
 289 (defun elopher-go ()
 290   "Go to a particular gopher site."
 291   (interactive)
 292   (let* ((selector "")
 293          (hostname (read-from-minibuffer "Gopher host: "))
 294          (port 70)
 295          (address (list selector hostname port)))
 296     (elopher-visit-node
 297      (elopher-make-node elopher-current-node
 298                         address
 299                         #'elopher-get-index-node))))
 300
 301 (defun  elopher-reload ()
 302   "Reload current site."
 303   (interactive)
 304   (elopher-reload-current-node))
 305
 306 (defun elopher-back ()
 307   "Go to previous site."
 308   (interactive)
 309   (if (elopher-node-parent elopher-current-node)
 310       (elopher-visit-parent-node)
 311     (message "No previous site.")))
 312
 313 ;;; Main start procedure
 314 ;;
 315 (defun elopher ()
 316   "Start elopher with default landing page."
 317   (interactive)
 318   (setq elopher-current-node nil)
 319   (let ((start-node (elopher-make-node nil nil #'elopher-get-index-node)))
 320     (elopher-visit-node start-node)))
 321
 322
 323 ;;; Mode and keymap
 324 ;;
 325
 326 (defvar elopher-mode-map
 327   (let ((map (make-sparse-keymap)))
 328     (define-key map (kbd "<tab>") 'elopher-next-link)
 329     (define-key map (kbd "<S-tab>") 'elopher-prev-link)
 330     (define-key map (kbd "u") 'elopher-back)
 331     (define-key map (kbd "g") 'elopher-go)
 332     (define-key map (kbd "r") 'elopher-reload)
 333     (when (require 'evil nil t)
 334       (evil-define-key 'normal map
 335         (kbd "C-]") 'elopher-follow-closest-link
 336         (kbd "C-t") 'elopher-back
 337         (kbd "u") 'elopher-back
 338         (kbd "g") 'elopher-go
 339         (kbd "r") 'elopher-reload))
 340     map)
 341   "Keymap for gopher client.")
 342
 343 (define-derived-mode elopher-mode special-mode "elopher"
 344   "Major mode for elopher, an elisp gopher client.")
 345
 346
 347 ;;; elopher.el ends here