elpher.el

   1 ;;; elpher.el --- A friendly gopher and gemini client  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2019-2022 Tim Vaughan <plugd@thelambdalab.xyz>
   4 ;; Copyright (C) 2020-2022 Elpher contributors (See info manual for full list)
   5
   6 ;; Author: Tim Vaughan <plugd@thelambdalab.xyz>
   7 ;; Created: 11 April 2019
   8 ;; Version: 3.4.1
   9 ;; Keywords: comm gopher
  10 ;; Homepage: https://thelambdalab.xyz/elpher
  11 ;; Package-Requires: ((emacs "27.1"))
  12
  13 ;; This file is not part of GNU Emacs.
  14
  15 ;; This program is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; This program is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with this file.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;; Elpher aims to provide a practical and friendly gopher and gemini
  31 ;; client for GNU Emacs.  It supports:
  32
  33 ;; - intuitive keyboard and mouse-driven browsing,
  34 ;; - out-of-the-box compatibility with evil-mode,
  35 ;; - clickable web and gopher links *in plain text*,
  36 ;; - caching of visited sites,
  37 ;; - pleasant and configurable colouring of Gopher directories,
  38 ;; - direct visualisation of image files,
  39 ;; - gopher connections using TLS encryption,
  40 ;; - the fledgling Gemini protocol,
  41 ;; - the greybeard Finger protocol.
  42
  43 ;; To launch Elpher, simply use 'M-x elpher'.  This will open a start
  44 ;; page containing information on key bindings and suggested starting
  45 ;; points for your gopher exploration.
  46
  47 ;; Full instructions can be found in the Elpher info manual.
  48
  49 ;; Elpher is under active development.  Any suggestions for
  50 ;; improvements are welcome, and can be made on the official project
  51 ;; page, gopher://thelambdalab.xyz/1/projects/elpher, or via the
  52 ;; project mailing list at https://lists.sr.ht/~michel-slm/elpher.
  53
  54 ;;; Code:
  55
  56 (provide 'elpher)
  57
  58 ;;; Dependencies
  59 ;;
  60
  61 (require 'seq)
  62 (require 'shr)
  63 (require 'url-util)
  64 (require 'subr-x)
  65 (require 'nsm)
  66 (require 'gnutls)
  67 (require 'socks)
  68 (require 'bookmark)
  69
  70 ;;; Global constants
  71 ;;
  72
  73 (defconst elpher-version "3.4.1"
  74   "Current version of elpher.")
  75
  76 (defconst elpher-margin-width 6
  77   "Width of left-hand margin used when rendering indicies.")
  78
  79 (defconst elpher-type-map
  80   '(((gopher ?0) elpher-get-gopher-page elpher-render-text "txt" elpher-text)
  81     ((gopher ?1) elpher-get-gopher-page elpher-render-index "/" elpher-index)
  82     ((gopher ?4) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  83     ((gopher ?5) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  84     ((gopher ?7) elpher-get-gopher-query-page elpher-render-index "?" elpher-search)
  85     ((gopher ?9) elpher-get-gopher-page elpher-render-download "bin" elpher-binary)
  86     ((gopher ?g) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  87     ((gopher ?p) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  88     ((gopher ?I) elpher-get-gopher-page elpher-render-image "img" elpher-image)
  89     ((gopher ?d) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  90     ((gopher ?P) elpher-get-gopher-page elpher-render-download "doc" elpher-binary)
  91     ((gopher ?s) elpher-get-gopher-page elpher-render-download "snd" elpher-binary)
  92     ((gopher ?h) elpher-get-gopher-page elpher-render-html "htm" elpher-html)
  93     (gemini elpher-get-gemini-page elpher-render-gemini "gem" elpher-gemini)
  94     (spartan elpher-get-spartan-page elpher-render-spartan "spt" elpher-spartan)
  95     (finger elpher-get-finger-page elpher-render-text "txt" elpher-text)
  96     (telnet elpher-get-telnet-page nil "tel" elpher-telnet)
  97     (other-url elpher-get-other-url-page nil "url" elpher-other-url)
  98     (file elpher-get-file-page nil "~" elpher-gemini)
  99     ((about welcome) elpher-get-welcome-page nil "E" elpher-index)
 100     ((about bookmarks) elpher-get-bookmarks-page nil "E" elpher-index)
 101     ((about history) elpher-get-history-page nil "E" elpher-index)
 102     ((about visited-pages) elpher-get-visited-pages-page nil "E" elpher-index))
 103   "Association list from types to getters, renderers, margin codes and index faces.")
 104
 105
 106 ;;; Declarations to avoid compiler warnings.
 107 ;;
 108
 109 (eval-when-compile
 110   (declare-function ansi-color-filter-apply "ansi-color")
 111   (declare-function ansi-color-apply "ansi-color")
 112   (declare-function bookmark-store "bookmark")
 113   (declare-function org-link-store-props "ol")
 114   (declare-function org-link-set-parameters "ol")
 115   (defvar ansi-color-context)
 116   (defvar xterm-color--current-fg)
 117   (defvar xterm-color--current-bg)
 118   (defvar bookmark-make-record-function)
 119   (defvar mu4e~view-beginning-of-url-regexp)
 120   (defvar eww-use-browse-url)
 121   (defvar thing-at-point-uri-schemes))
 122
 123
 124 ;;; Customization group
 125 ;;
 126
 127 (defgroup elpher nil
 128   "A gopher and gemini client."
 129   :group 'applications)
 130
 131 ;; General appearance and customizations
 132
 133 (defcustom elpher-open-urls-with-eww nil
 134   "If non-nil, open URL selectors using eww.
 135 Otherwise, use the system browser via the `browse-url' function."
 136   :type '(boolean))
 137
 138 (defcustom elpher-use-header t
 139   "If non-nil, display current page information in buffer header."
 140   :type '(boolean))
 141
 142 (defcustom elpher-auto-disengage-TLS nil
 143   "If non-nil, automatically disengage TLS following an unsuccessful connection.
 144 While enabling this may seem convenient, it is also potentially
 145 dangerous as it allows switching from an encrypted channel back to
 146 plain text without user input."
 147   :type '(boolean))
 148
 149 (defcustom elpher-connection-timeout 5
 150   "Specifies the number of seconds to wait for a network connection to time out."
 151   :type '(integer))
 152
 153 (defcustom elpher-filter-ansi-from-text nil
 154   "If non-nil, filter ANSI escape sequences from text.
 155 The default behaviour is to use the ansi-color package (or xterm-color if it is
 156 available) to interpret these sequences."
 157   :type '(boolean))
 158
 159 (defcustom elpher-certificate-directory
 160   (file-name-as-directory (locate-user-emacs-file "elpher-certificates"))
 161   "Specify the name of the directory where client certificates will be stored.
 162 These certificates may be used for establishing authenticated TLS connections."
 163   :type '(directory))
 164
 165 (defcustom elpher-openssl-command "openssl"
 166   "The command used to launch openssl when generating TLS client certificates."
 167   :type '(file))
 168
 169 (defcustom elpher-default-url-type "gopher"
 170   "Default URL type (i.e. scheme) to assume if not explicitly given."
 171   :type '(choice (const "gopher")
 172                  (const "gemini")))
 173
 174 (defcustom elpher-gemini-TLS-cert-checks nil
 175   "If non-nil, verify gemini server TLS certs using the default security level.
 176 Otherwise, certificate verification is disabled.
 177
 178 This defaults to off because it is standard practice for Gemini servers
 179 to use self-signed certificates, meaning that most servers provide what
 180 EMACS considers to be an invalid certificate."
 181   :type '(boolean))
 182
 183 (defcustom elpher-gemini-max-fill-width 80
 184   "Specify the maximum default width (in columns) of text/gemini documents.
 185 The actual width used is the minimum of this value and the window width at
 186 the time when the text is rendered."
 187   :type '(integer))
 188
 189 (defcustom elpher-gemini-link-string "→ "
 190   "Specify the string used to indicate links when rendering gemini maps.
 191 May be empty."
 192   :type '(string))
 193
 194 (defcustom elpher-gemini-bullet-string "•"
 195   "Specify the string used for bullets when rendering gemini maps."
 196   :type '(string))
 197
 198 (defcustom elpher-ipv4-always nil
 199   "If non-nil, elpher will always use IPv4 to establish network connections.
 200 This can be useful when browsing from a computer that supports IPv6, because
 201 some servers which do not support IPv6 can take a long time to time-out."
 202   :type '(boolean))
 203
 204 (defcustom elpher-socks-always nil
 205   "If non-nil, elpher will establish network connections over a SOCKS proxy.
 206 Otherwise, the SOCKS proxy is only used for connections to onion services."
 207   :type '(boolean))
 208
 209 (defcustom elpher-use-emacs-bookmark-menu nil
 210   "If non-nil, elpher will only use the native Emacs bookmark menu.
 211 Otherwise, \\[elpher-show-bookmarks] will visit a special elpher bookmark
 212 page within which all of the standard elpher keybindings are active."
 213   :type '(boolean))
 214
 215 (defcustom elpher-start-page-url "about:welcome"
 216   "Specify the page displayed initially by elpher.
 217 The default welcome screen is \"about:welcome\", while the bookmarks list
 218 is \"about:bookmarks\".  You can also specify local files via \"file:\".
 219
 220 Beware that using \"about:bookmarks\" as a start page in combination with
 221 the `elpher-use-bookmark-menu' variable set to non-nil will prevent the
 222 Emacs bookmark menu being accessible via \\[elpher-show-bookmarks] from
 223 the start page."
 224   :type '(string))
 225
 226 (defcustom elpher-gemini-hide-preformatted nil
 227   "Cause elpher to hide preformatted gemini text by default.
 228 When this option is enabled, preformatted text in text/gemini documents
 229 is replaced with a button which can be used to toggle its display.
 230
 231 This is intended to improve accessibility, as preformatted text often
 232 includes art which can be difficult for screen readers to interpret
 233 meaningfully."
 234   :type '(boolean))
 235
 236 (defcustom elpher-gemini-preformatted-toggle-bullet "‣ "
 237   "Margin symbol used to distinguish the preformatted text toggle."
 238   :type '(string))
 239
 240 (defcustom elpher-gemini-preformatted-toggle-label "[Toggle Preformatted Text]"
 241   "Label of button used to toggle formatted text."
 242   :type '(string))
 243
 244 ;; Face customizations
 245
 246 (defgroup elpher-faces nil
 247   "Elpher face customizations."
 248   :group 'elpher)
 249
 250 (defface elpher-index
 251   '((t :inherit font-lock-keyword-face))
 252   "Face used for directory type directory records.")
 253
 254 (defface elpher-text
 255   '((t :inherit bold))
 256   "Face used for text type directory records.")
 257
 258 (defface elpher-info
 259   '((t :inherit default))
 260   "Face used for info type directory records.")
 261
 262 (defface elpher-image
 263   '((t :inherit font-lock-string-face))
 264   "Face used for image type directory records.")
 265
 266 (defface elpher-search
 267   '((t :inherit warning))
 268   "Face used for search type directory records.")
 269
 270 (defface elpher-html
 271   '((t :inherit font-lock-comment-face))
 272   "Face used for html type directory records.")
 273
 274 (defface elpher-gemini
 275   '((t :inherit font-lock-constant-face))
 276   "Face used for Gemini type directory records.")
 277
 278 (defface elpher-spartan
 279   '((t :inherit font-lock-constant-face))
 280   "Face used for Spartan type directory records.")
 281
 282 (defface elpher-other-url
 283   '((t :inherit font-lock-comment-face))
 284   "Face used for other URL type links records.")
 285
 286 (defface elpher-telnet
 287   '((t :inherit font-lock-function-name-face))
 288   "Face used for telnet type directory records.")
 289
 290 (defface elpher-binary
 291   '((t :inherit font-lock-doc-face))
 292   "Face used for binary type directory records.")
 293
 294 (defface elpher-unknown
 295   '((t :inherit error))
 296   "Face used for directory records with unknown/unsupported types.")
 297
 298 (defface elpher-margin-key
 299   '((t :inherit bold))
 300   "Face used for directory margin key.")
 301
 302 (defface elpher-margin-brackets
 303   '((t :inherit shadow))
 304   "Face used for brackets around directory margin key.")
 305
 306 (defface elpher-gemini-heading1
 307   '((t :inherit bold :height 1.8))
 308   "Face used for gemini heading level 1.")
 309
 310 (defface elpher-gemini-heading2
 311   '((t :inherit bold :height 1.5))
 312   "Face used for gemini heading level 2.")
 313
 314 (defface elpher-gemini-heading3
 315   '((t :inherit bold :height 1.2))
 316   "Face used for gemini heading level 3.")
 317
 318 (defface elpher-gemini-quoted
 319   '((t :inherit font-lock-doc-face))
 320   "Face used for gemini quoted texts.")
 321
 322 (defface elpher-gemini-preformatted-toggle
 323   '((t :inherit button))
 324   "Face used for buttons used to toggle display of preformatted text.")
 325
 326 ;;; Model
 327 ;;
 328
 329 ;; Address
 330
 331 ;; An elpher "address" object is either a url object or a symbol.
 332 ;; Addresses with the "about" type, corresponding to pages generated
 333 ;; dynamically for and by elpher.  All others represent pages which
 334 ;; rely on content retrieved over the network.
 335
 336 (defun elpher-address-from-url (url-string &optional default-scheme)
 337   "Create a ADDRESS object corresponding to the given URL-STRING.
 338 If DEFAULT-SCHEME is non-nil, this sets the scheme of the URL when one
 339 is not explicitly given."
 340   (let ((data (match-data))) ; Prevent parsing clobbering match data
 341     (unwind-protect
 342         (let ((url (url-generic-parse-url url-string)))
 343           (unless (and (not (url-fullness url)) (url-type url))
 344             (unless (url-type url)
 345               (setf (url-type url) default-scheme))
 346             (unless (url-host url)
 347               (let ((p (split-string (url-filename url) "/" nil nil)))
 348                 (setf (url-host url) (car p))
 349                 (setf (url-filename url)
 350                       (if (cdr p)
 351                           (concat "/" (mapconcat #'identity (cdr p) "/"))
 352                         ""))))
 353             (when (not (string-empty-p (url-host url)))
 354               (setf (url-fullness url) t)
 355               (setf (url-host url) (puny-encode-domain (url-host url))))
 356             (when (or (equal "gopher" (url-type url))
 357                       (equal "gophers" (url-type url)))
 358               ;; Gopher defaults
 359               (when (or (equal (url-filename url) "")
 360                         (equal (url-filename url) "/"))
 361                 (setf (url-filename url) "/1")))
 362             (when (equal "gemini" (url-type url))
 363               ;; Gemini defaults
 364               (if (equal (url-filename url) "")
 365                   (setf (url-filename url) "/"))))
 366           (elpher-remove-redundant-ports url))
 367       (set-match-data data))))
 368
 369 (defun elpher-remove-redundant-ports (address)
 370   "Remove redundant port specifiers from ADDRESS.
 371 Here 'redundant' means that the specified port matches the default
 372 for that protocol, eg 70 for gopher."
 373   (if (and (not (elpher-address-about-p address))
 374            (eq (url-portspec address) ; (url-port) is too slow!
 375                (pcase (url-type address)
 376                  ("gemini" 1965)
 377                  ((or "gopher" "gophers") 70)
 378                  ("finger" 79)
 379                  (_ -1))))
 380       (setf (url-portspec address) nil))
 381   address)
 382
 383 (defun elpher-make-gopher-address (type selector host port &optional tls)
 384   "Create an ADDRESS object using gopher directory record attributes.
 385 The basic attributes include: TYPE, SELECTOR, HOST and PORT.
 386 If the optional attribute TLS is non-nil, the address will be marked as
 387 requiring gopher-over-TLS."
 388   (cond
 389    ((equal type ?i) nil)
 390    ((and (equal type ?h)
 391          (string-prefix-p "URL:" selector))
 392     (elpher-address-from-url (elt (split-string selector "URL:") 1)))
 393    ((equal type ?8)
 394     (elpher-address-from-url
 395      (concat "telnet"
 396              "://" host
 397              ":" (number-to-string port))))
 398    (t
 399     (elpher-address-from-url
 400      (concat "gopher" (if tls "s" "")
 401              "://" host
 402              ":" (number-to-string port)
 403              "/" (string type)
 404              selector)))))
 405
 406 (defun elpher-make-about-address (type)
 407   "Create an ADDRESS object corresponding to the given about address TYPE."
 408   (elpher-address-from-url (concat "about:" (symbol-name type))))
 409
 410 (defun elpher-address-to-url (address)
 411   "Get string representation of ADDRESS."
 412   (url-encode-url (url-recreate-url address)))
 413
 414 (defun elpher-address-type (address)
 415   "Retrieve type of ADDRESS object.
 416 This is used to determine how to retrieve and render the document the
 417 address refers to, via the table `elpher-type-map'."
 418   (pcase (url-type address)
 419     ("about"
 420      (list 'about (intern (url-filename address))))
 421     ((or "gopher" "gophers")
 422      (list 'gopher
 423            (if (member (url-filename address) '("" "/"))
 424                ?1
 425              (string-to-char (substring (url-filename address) 1)))))
 426     ("gemini" 'gemini)
 427     ("telnet" 'telnet)
 428     ("finger" 'finger)
 429     ("file" 'file)
 430     (_ 'other-url)))
 431
 432 (defun elpher-address-about-p (address)
 433   "Return non-nil if ADDRESS is an  about address."
 434   (pcase (elpher-address-type address) (`(about ,_) t)))
 435
 436 (defun elpher-address-gopher-p (address)
 437   "Return non-nill if ADDRESS object is a gopher address."
 438   (pcase (elpher-address-type address) (`(gopher ,_) t)))
 439
 440 (defun elpher-address-protocol (address)
 441   "Retrieve the transport protocol for ADDRESS."
 442   (url-type address))
 443
 444 (defun elpher-address-filename (address)
 445   "Retrieve the filename component of ADDRESS.
 446 For gopher addresses this is a combination of the selector type and selector."
 447   (url-unhex-string (url-filename address)))
 448
 449 (defun elpher-address-host (address)
 450   "Retrieve host from ADDRESS object."
 451   (let ((host-pre (url-host address)))
 452     ;; The following strips out square brackets which sometimes enclose IPv6
 453     ;; addresses.  Doing this here rather than at the parsing stage may seem
 454     ;; weird, but this lets us way we avoid having to muck with both URL parsing
 455     ;; and reconstruction.  It's also more efficient, as this method is not
 456     ;; called during page rendering.
 457     (if (and (> (length host-pre) 2)
 458              (eq (elt host-pre 0) ?\[)
 459              (eq (elt host-pre (- (length host-pre) 1)) ?\]))
 460         (substring host-pre 1 (- (length host-pre) 1))
 461       host-pre)))
 462
 463 (defun elpher-address-user (address)
 464   "Retrieve user from ADDRESS object."
 465   (url-user address))
 466
 467 (defun elpher-address-port (address)
 468   "Retrieve port from ADDRESS object.
 469 If no address is defined, returns 0.  (This is for compatibility with
 470 the URL library.)"
 471   (url-port address))
 472
 473 (defun elpher-gopher-address-selector (address)
 474   "Retrieve gopher selector from ADDRESS object."
 475   (if (member (url-filename address) '("" "/"))
 476       ""
 477     (url-unhex-string (substring (url-filename address) 2))))
 478
 479
 480 ;; Cache
 481
 482 (defvar elpher-content-cache (make-hash-table :test 'equal))
 483 (defvar elpher-pos-cache (make-hash-table :test 'equal))
 484
 485 (defun elpher-get-cached-content (address)
 486   "Retrieve the cached content for ADDRESS, or nil if none exists."
 487   (gethash address elpher-content-cache))
 488
 489 (defun elpher-cache-content (address content)
 490   "Set the content cache for ADDRESS to CONTENT."
 491   (puthash address content elpher-content-cache))
 492
 493 (defun elpher-get-cached-pos (address)
 494   "Retrieve the cached cursor position for ADDRESS, or nil if none exists."
 495   (gethash address elpher-pos-cache))
 496
 497 (defun elpher-cache-pos (address pos)
 498   "Set the cursor position cache for ADDRESS to POS."
 499   (puthash address pos elpher-pos-cache))
 500
 501
 502 ;; Page
 503
 504 (defun elpher-make-page (display-string address)
 505   "Create a page with DISPLAY-STRING and ADDRESS."
 506   (list display-string address))
 507
 508 (defun elpher-make-start-page ()
 509   "Create the start page."
 510   (elpher-make-page "Start Page"
 511                     (elpher-address-from-url elpher-start-page-url)))
 512
 513 (defun elpher-page-display-string (page)
 514   "Retrieve the display string corresponding to PAGE."
 515   (elt page 0))
 516
 517 (defun elpher-page-address (page)
 518   "Retrieve the address corresponding to PAGE."
 519   (elt page 1))
 520
 521 (defun elpher-page-set-address (page new-address)
 522   "Set the address corresponding to PAGE to NEW-ADDRESS."
 523   (setcar (cdr page) new-address))
 524
 525 (defun elpher-page-from-url (url &optional default-scheme)
 526   "Create a page with address and display string defined by URL.
 527 The URL is unhexed prior to its use as a display string to improve
 528 readability.
 529
 530 If DEFAULT-SCHEME is non-nil, this scheme is applied to the URL
 531 in the instance that URL itself doesn't specify one."
 532   (let ((address (elpher-address-from-url url default-scheme)))
 533     (elpher-make-page (elpher-address-to-iri address) address)))
 534
 535 (defun elpher-address-to-iri (address)
 536   "Return an IRI for ADDRESS.
 537 Decode percent-escapes and handle punycode in the domain name.
 538 Drop the password, if any."
 539   (let ((data (match-data)) ; Prevent parsing clobbering match data
 540         (host (url-host address))
 541         (pass (url-password address)))
 542     (unwind-protect
 543         (let* ((host (url-host address))
 544                (pass (url-password address)))
 545           (when host
 546             (setf (url-host address) (puny-decode-domain host)))
 547           (when pass                             ; RFC 3986 says we should not render
 548             (setf (url-password address) nil)) ; the password as clear text
 549           (elpher-decode (url-unhex-string (url-recreate-url address))))
 550       (setf (url-host address) host)
 551       (setf (url-password address) pass)
 552       (set-match-data data))))
 553
 554 (defvar elpher-current-page nil
 555   "The current page for this Elpher buffer.")
 556
 557 (defvar elpher-history nil
 558   "The local history stack for this Elpher buffer.
 559 This variable is used by `elpher-back' and
 560 `elpher-show-history'.")
 561
 562 (defvar elpher-visited-pages nil
 563   "The global history for all Elpher buffers.
 564 This variable is used by `elpher-show-visited-pages'.")
 565
 566 (defun elpher-visit-page (page &optional renderer no-history)
 567   "Visit PAGE using its own renderer or RENDERER, if non-nil.
 568 Additionally, push PAGE onto the history stack and the list of
 569 previously-visited pages,unless NO-HISTORY is non-nil."
 570   (elpher-save-pos)
 571   (elpher-process-cleanup)
 572   (unless no-history
 573     (unless (or (not elpher-current-page)
 574                  (equal (elpher-page-address elpher-current-page)
 575                         (elpher-page-address page)))
 576       (push elpher-current-page elpher-history)
 577       (unless (or (elpher-address-about-p (elpher-page-address page))
 578                   (and elpher-visited-pages
 579                        (equal page (car elpher-visited-pages))))
 580         (push page elpher-visited-pages))))
 581   (setq-local elpher-current-page page)
 582   (let* ((address (elpher-page-address page))
 583          (type (elpher-address-type address))
 584          (type-record (cdr (assoc type elpher-type-map))))
 585     (if type-record
 586         (funcall (car type-record)
 587                  (if renderer
 588                      renderer
 589                    (cadr type-record)))
 590       (elpher-visit-previous-page)
 591       (pcase type
 592         (`(gopher ,type-char)
 593          (error "Unsupported gopher selector type '%c' for '%s'"
 594                 type-char (elpher-address-to-url address)))
 595         (other
 596          (error "Unsupported address type '%S' for '%s'"
 597                 other (elpher-address-to-url address)))))))
 598
 599 (defun elpher-visit-previous-page ()
 600   "Visit the previous page in the history."
 601   (if elpher-history
 602       (elpher-visit-page (pop elpher-history) nil t)
 603     (error "No previous page")))
 604
 605 (defun elpher-reload-current-page ()
 606   "Reload the current page, discarding any existing cached content."
 607   (elpher-cache-content (elpher-page-address elpher-current-page) nil)
 608   (elpher-visit-page elpher-current-page))
 609
 610 (defun elpher-save-pos ()
 611   "Save the current position of point to the current page."
 612   (when elpher-current-page
 613     (elpher-cache-pos (elpher-page-address elpher-current-page) (point))))
 614
 615 (defun elpher-restore-pos ()
 616   "Restore the position of point to that cached in the current page."
 617   (let ((pos (elpher-get-cached-pos (elpher-page-address elpher-current-page))))
 618     (if pos
 619         (goto-char pos)
 620       (goto-char (point-min)))))
 621
 622 (defun elpher-get-default-url-scheme ()
 623   "Suggest default URL scheme for visiting addresses based on the current page."
 624   (if elpher-current-page
 625       (let* ((address (elpher-page-address elpher-current-page))
 626              (current-type (elpher-address-type address)))
 627         (pcase current-type
 628           ((or (and 'file (guard (not elpher-history)))
 629                `(about ,_))
 630            elpher-default-url-type)
 631           (_
 632            (url-type address))))
 633       elpher-default-url-type))
 634
 635
 636 ;;; Buffer preparation
 637 ;;
 638
 639 (defvar elpher-buffer-name "*elpher*"
 640   "The default name of the Elpher buffer.")
 641
 642 (defun elpher-update-header ()
 643   "If `elpher-use-header' is true, display current page info in window header."
 644   (if (and elpher-use-header elpher-current-page)
 645       (let* ((display-string (elpher-page-display-string elpher-current-page))
 646              (sanitized-display-string (replace-regexp-in-string "%" "%%" display-string))
 647              (address (elpher-page-address elpher-current-page))
 648              (tls-string (if (and (not (elpher-address-about-p address))
 649                                   (member (elpher-address-protocol address)
 650                                           '("gophers" "gemini")))
 651                              " [TLS encryption]"
 652                            ""))
 653              (header (concat sanitized-display-string
 654                              (propertize tls-string 'face 'bold))))
 655         (setq header-line-format header))))
 656
 657 (defmacro elpher-with-clean-buffer (&rest args)
 658   "Evaluate ARGS with a clean *elpher* buffer as current."
 659   (declare (debug (body))) ;; Allow edebug to step through body
 660   `(with-current-buffer elpher-buffer-name
 661      (unless (eq major-mode 'elpher-mode)
 662        ;; avoid resetting buffer-local variables
 663        (elpher-mode))
 664      (let ((inhibit-read-only t)
 665            (ansi-color-context nil)) ;; clean ansi interpreter state (also next 2 lines)
 666        (setq-local xterm-color--current-fg nil)
 667        (setq-local xterm-color--current-bg nil)
 668        (setq-local network-security-level
 669                    (default-value 'network-security-level))
 670        (erase-buffer)
 671        (elpher-update-header)
 672        ,@args)))
 673
 674 (defun elpher-buffer-message (string &optional line)
 675   "Replace first line in elpher buffer with STRING.
 676 If LINE is non-nil, replace that line instead."
 677   (with-current-buffer elpher-buffer-name
 678     (let ((inhibit-read-only t))
 679       (goto-char (point-min))
 680       (if line
 681           (forward-line line))
 682       (let ((data (match-data)))
 683         (unwind-protect
 684             (progn
 685               (re-search-forward "^.*$")
 686               (replace-match string))
 687           (set-match-data data))))))
 688
 689
 690 ;;; Text Processing
 691 ;;
 692
 693 (defvar elpher-user-coding-system nil
 694   "User-specified coding system to use for decoding text responses.")
 695
 696 (defun elpher-decode (string)
 697   "Decode STRING using autodetected or user-specified coding system."
 698   (decode-coding-string string
 699                         (if elpher-user-coding-system
 700                             elpher-user-coding-system
 701                           (detect-coding-string string t))))
 702
 703 (defun elpher-preprocess-text-response (string)
 704   "Preprocess text selector response contained in STRING.
 705 This involes decoding the character representation, and clearing
 706 away CRs and any terminating period."
 707   (elpher-decode (replace-regexp-in-string "\n\\.\n$" "\n"
 708                                            (replace-regexp-in-string "\r" "" string))))
 709
 710 ;;; Buttonify urls
 711
 712 (defconst elpher-url-regex
 713   "\\([a-zA-Z]+\\)://\\([a-zA-Z0-9.-]*[a-zA-Z0-9-]\\|\\[[a-zA-Z0-9:]+\\]\\)\\(:[0-9]+\\)?\\(/\\([0-9a-zA-Z_~?/@|:.%#=&-]*[0-9a-zA-Z_~?/@|#-]\\)?\\)?"
 714   "Regexp used to locate and buttonify URLs in text files loaded by elpher.")
 715
 716 (defun elpher-buttonify-urls (string)
 717   "Turn substrings which look like urls in STRING into clickable buttons."
 718   (with-temp-buffer
 719     (insert string)
 720     (goto-char (point-min))
 721     (while (re-search-forward elpher-url-regex nil t)
 722       (let ((page (elpher-page-from-url (substring-no-properties (match-string 0)))))
 723         (make-text-button (match-beginning 0)
 724                           (match-end 0)
 725                           'elpher-page  page
 726                           'action #'elpher-click-link
 727                           'follow-link t
 728                           'help-echo #'elpher--page-button-help
 729                           'face 'button)))
 730     (buffer-string)))
 731
 732 ;;; ANSI colors or XTerm colors (application and filtering)
 733
 734 (or (require 'xterm-color nil t)
 735     (require 'ansi-color))
 736
 737 (defalias 'elpher-color-filter-apply
 738   (if (fboundp 'xterm-color-filter)
 739       (lambda (s)
 740         (let ((_xterm-color-render nil))
 741           (xterm-color-filter s)))
 742     #'ansi-color-filter-apply)
 743   "A function to filter out ANSI escape sequences.")
 744
 745 (defalias 'elpher-color-apply
 746   (if (fboundp 'xterm-color-filter)
 747       #'xterm-color-filter
 748     #'ansi-color-apply)
 749   "A function to apply ANSI escape sequences.")
 750
 751 ;;; Processing text for display
 752
 753 (defun elpher-process-text-for-display (string)
 754   "Perform any desired processing of STRING prior to display as text.
 755 Currently includes buttonifying URLs and processing ANSI escape codes."
 756   (elpher-buttonify-urls (if elpher-filter-ansi-from-text
 757                              (elpher-color-filter-apply string)
 758                            (elpher-color-apply string))))
 759
 760
 761 ;;; Network error reporting
 762 ;;
 763
 764 (defun elpher-network-error (address error)
 765   "Display ERROR message following unsuccessful negotiation with ADDRESS.
 766 ERROR can be either an error object or a string."
 767   (elpher-with-clean-buffer
 768    (insert (propertize "\n---- ERROR -----\n\n" 'face 'error)
 769            "When attempting to retrieve " (elpher-address-to-url address) ":\n"
 770            (if (stringp error) error (error-message-string error)) "\n"
 771            (propertize "\n----------------\n\n" 'face 'error)
 772            "Press 'u' to return to the previous page.")))
 773
 774
 775 ;;; General network communication
 776 ;;
 777
 778 (defvar elpher-network-timer nil
 779   "Timer used for network connections.")
 780
 781 (defvar elpher-use-tls nil
 782   "If non-nil, use TLS to communicate with gopher servers.")
 783
 784 (defvar elpher-client-certificate nil
 785   "If non-nil, contains client certificate details to use for TLS connections.")
 786
 787 (defun elpher-process-cleanup ()
 788   "Immediately shut down any extant elpher process and timers."
 789   (let ((p (get-process "elpher-process")))
 790     (if p (delete-process p)))
 791   (if (timerp elpher-network-timer)
 792       (cancel-timer elpher-network-timer)))
 793
 794 (defun elpher-make-network-timer (thunk)
 795   "Create a timer to run the THUNK after `elpher-connection-timeout' seconds.
 796 This is just a wraper around `run-at-time' which additionally sets the
 797 buffer-local variable `elpher-network-timer' to allow
 798 `elpher-process-cleanup' to also clear the timer."
 799   (let ((timer (run-at-time elpher-connection-timeout nil thunk)))
 800     (setq-local elpher-network-timer timer)
 801     timer))
 802
 803 (defun elpher-get-host-response (address default-port query-string response-processor
 804                                          &optional use-tls force-ipv4)
 805   "Generic function for retrieving data from ADDRESS.
 806
 807 When ADDRESS lacks a specific port, DEFAULT-PORT is used instead.
 808 QUERY-STRING is a string sent to the host specified by ADDRESS to
 809 illicet a response.  This response is passed as an argument to the
 810 function RESPONSE-PROCESSOR.
 811
 812 If non-nil, USE-TLS specifies that the connection is to be made over
 813 TLS.  If set to gemini, the certificate verification will be disabled
 814 unless `elpher-gemini-TLS-cert-checks' is non-nil.
 815
 816 If non-nil, FORCE-IPV4 causes the network connection to be made over
 817 ipv4 only.  (The default behaviour when this is not set depends on
 818 the host operating system and the local network capabilities.)"
 819   (if (and use-tls (not (gnutls-available-p)))
 820       (error "Use of TLS requires Emacs to be compiled with GNU TLS support")
 821     (unless (< (elpher-address-port address) 65536)
 822       (error "Cannot establish network connection: port number > 65536"))
 823     (when (and (eq use-tls 'gemini) (not elpher-gemini-TLS-cert-checks))
 824       (setq-local network-security-level 'low)
 825       (setq-local gnutls-verify-error nil))
 826     (condition-case nil
 827         (let* ((kill-buffer-query-functions nil)
 828                (port (elpher-address-port address))
 829                (host (elpher-address-host address))
 830                (service (if (> port 0) port default-port))
 831                (response-string-parts nil)
 832                (bytes-received 0)
 833                (hkbytes-received 0)
 834                (socks (or elpher-socks-always (string-suffix-p ".onion" host)))
 835                (gnutls-params (list :type 'gnutls-x509pki
 836                                     :hostname host
 837                                     :keylist
 838                                     (elpher-get-current-keylist address)))
 839                (timer (elpher-make-network-timer
 840                                    (lambda ()
 841                                      (elpher-process-cleanup)
 842                                      (cond
 843                                         ; Try again with IPv4
 844                                       ((not (or elpher-ipv4-always force-ipv4 socks))
 845                                        (message "Connection timed out.  Retrying with IPv4.")
 846                                        (elpher-get-host-response address default-port
 847                                                                  query-string
 848                                                                  response-processor
 849                                                                  use-tls t))
 850                                       ((and use-tls
 851                                             (not (eq use-tls 'gemini))
 852                                             (or elpher-auto-disengage-TLS
 853                                                 (y-or-n-p
 854                                                  "TLS connetion failed.  Disable TLS mode and retry? ")))
 855                                        (setq elpher-use-tls nil)
 856                                        (elpher-get-host-response address default-port
 857                                                                  query-string
 858                                                                  response-processor
 859                                                                  nil force-ipv4))
 860                                       (t
 861                                        (elpher-network-error address "Connection time-out."))))))
 862                (proc (if socks (socks-open-network-stream "elpher-process" nil host service)
 863                        (make-network-process :name "elpher-process"
 864                                              :host host
 865                                              :family (and (or force-ipv4
 866                                                               elpher-ipv4-always)
 867                                                           'ipv4)
 868                                              :service service
 869                                              :buffer nil
 870                                              :nowait t
 871                                              :tls-parameters
 872                                              (and use-tls
 873                                                   (cons 'gnutls-x509pki
 874                                                         (apply #'gnutls-boot-parameters
 875                                                                gnutls-params)))))))
 876           (setq elpher-network-timer timer)
 877           (set-process-coding-system proc 'binary 'binary)
 878           (set-process-query-on-exit-flag proc nil)
 879           (elpher-buffer-message (concat "Connecting to " host "..."
 880                                          " (press 'u' to abort)"))
 881           (set-process-filter proc
 882                               (lambda (_proc string)
 883                                 (when timer
 884                                   (cancel-timer timer)
 885                                   (setq timer nil))
 886                                 (setq bytes-received (+ bytes-received (length string)))
 887                                 (let ((new-hkbytes-received (/ bytes-received 102400)))
 888                                   (when (> new-hkbytes-received hkbytes-received)
 889                                     (setq hkbytes-received new-hkbytes-received)
 890                                     (elpher-buffer-message
 891                                      (concat "("
 892                                              (number-to-string (/ hkbytes-received 10.0))
 893                                              " MB read)")
 894                                      1)))
 895                                 (setq response-string-parts
 896                                       (cons string response-string-parts))))
 897           (set-process-sentinel proc
 898                                 (lambda (proc event)
 899                                   (when timer
 900                                     (cancel-timer timer))
 901                                   (condition-case the-error
 902                                       (cond
 903                                        ((string-prefix-p "open" event)    ; request URL
 904                                         (elpher-buffer-message
 905                                          (concat "Connected to " host ". Receiving data..."
 906                                                  " (press 'u' to abort)"))
 907                                         (let ((inhibit-eol-conversion t))
 908                                           (process-send-string proc query-string)))
 909                                        ((string-prefix-p "deleted" event)) ; do nothing
 910                                        ((and (not response-string-parts)
 911                                              (not (or elpher-ipv4-always force-ipv4 socks)))
 912                                         ; Try again with IPv4
 913                                         (message "Connection failed. Retrying with IPv4.")
 914                                         (elpher-get-host-response address default-port
 915                                                                   query-string
 916                                                                   response-processor
 917                                                                   use-tls t))
 918                                        (response-string-parts
 919                                         (elpher-with-clean-buffer
 920                                          (insert "Data received.  Rendering..."))
 921                                         (funcall response-processor
 922                                                  (apply #'concat (reverse response-string-parts)))
 923                                         (elpher-restore-pos))
 924                                        (t
 925                                         (error "No response from server")))
 926                                     (error
 927                                      (elpher-network-error address the-error)))))
 928           (when socks
 929             (if use-tls (apply #'gnutls-negotiate :process proc gnutls-params))
 930             (funcall (process-sentinel proc) proc "open\n")))
 931       (error
 932        (elpher-process-cleanup)
 933        (error "Error initiating connection to server")))))
 934
 935
 936 ;;; Client-side TLS Certificate Management
 937 ;;
 938
 939 (defun elpher-generate-certificate (common-name key-file cert-file &optional temporary)
 940   "Generate a key and a self-signed client TLS certificate using openssl.
 941
 942 The Common Name field of the certificate is set to COMMON-NAME.  The
 943 arguments KEY-FILE and CERT-FILE should contain the absolute paths of
 944 the key and certificate files to write.
 945
 946 If TEMPORARY is non-nil, the certificate will be given an exporation
 947 period of one day, and the key and certificate files will be deleted
 948 when the certificate is no longer needed for the current session.
 949
 950 Otherwise, the certificate will be given a 100 year expiration period
 951 and the files will not be deleted.
 952
 953 The function returns a list containing the current host name, the
 954 temporary flag, and the key and cert file names in the form required
 955 by `gnutls-boot-parameters`."
 956   (let ((exp-key-file (expand-file-name key-file))
 957         (exp-cert-file (expand-file-name cert-file)))
 958     (condition-case nil
 959         (progn
 960           (call-process elpher-openssl-command nil nil nil
 961                         "req" "-x509" "-newkey" "rsa:2048"
 962                         "-days" (if temporary "1" "36500")
 963                         "-nodes"
 964                         "-subj" (concat "/CN=" common-name)
 965                         "-keyout" exp-key-file
 966                         "-out" exp-cert-file)
 967           (list (elpher-address-host (elpher-page-address elpher-current-page))
 968                 temporary exp-key-file exp-cert-file))
 969       (error
 970        (message "Check that openssl is installed, or customize `elpher-openssl-command`.")
 971        (error "Program 'openssl', required for certificate generation, not found")))))
 972
 973 (defun elpher-generate-throwaway-certificate ()
 974   "Generate and return details of a throwaway certificate.
 975 The key and certificate files will be deleted when they are no
 976 longer needed for this session."
 977   (let* ((file-base (make-temp-name "elpher"))
 978          (key-file (concat temporary-file-directory file-base ".key"))
 979          (cert-file (concat temporary-file-directory file-base ".crt")))
 980     (elpher-generate-certificate file-base key-file cert-file t)))
 981
 982 (defun elpher-generate-persistent-certificate (file-base common-name)
 983   "Generate and return details of a persistent certificate.
 984 The argument FILE-BASE is used as the base for the key and certificate
 985 files, while COMMON-NAME specifies the common name field of the
 986 certificate.
 987
 988 The key and certificate files are written to in `elpher-certificate-directory'."
 989   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 990          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 991     (elpher-generate-certificate common-name key-file cert-file)))
 992
 993 (defun elpher-get-existing-certificate (file-base)
 994   "Return a certificate object corresponding to an existing certificate.
 995 It is assumed that the key files FILE-BASE.key and FILE-BASE.crt exist in
 996 the directory `elpher-certificate-directory'."
 997   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
 998          (cert-file (concat elpher-certificate-directory file-base ".crt")))
 999     (list (elpher-address-host (elpher-page-address elpher-current-page))
1000           nil
1001           (expand-file-name key-file)
1002           (expand-file-name cert-file))))
1003
1004 (defun elpher-install-and-use-existing-certificate (key-file-src cert-file-src file-base)
1005   "Install a key+certificate file pair in `elpher-certificate-directory'.
1006 The strings KEY-FILE-SRC and CERT-FILE-SRC are the existing key and
1007 certificate files to install.  The argument FILE-BASE is used as the
1008 base for the installed key and certificate files."
1009   (let* ((key-file (concat elpher-certificate-directory file-base ".key"))
1010          (cert-file (concat elpher-certificate-directory file-base ".crt")))
1011     (if (or (file-exists-p key-file)
1012             (file-exists-p cert-file))
1013         (error "A certificate with base name %s is already installed" file-base))
1014     (copy-file key-file-src key-file)
1015     (copy-file cert-file-src cert-file)
1016     (list (elpher-address-host (elpher-page-address elpher-current-page))
1017           nil
1018           (expand-file-name key-file)
1019           (expand-file-name cert-file))))
1020
1021 (defun elpher-list-existing-certificates ()
1022   "Return a list of the persistent certificates in `elpher-certificate-directory'."
1023   (unless (file-directory-p elpher-certificate-directory)
1024     (make-directory elpher-certificate-directory))
1025   (mapcar
1026    (lambda (file)
1027      (file-name-sans-extension file))
1028    (directory-files elpher-certificate-directory nil "\\.key$")))
1029
1030 (defun elpher-forget-current-certificate ()
1031   "Causes any current certificate to be forgotten.)
1032 In the case of throwaway certificates, the key and certificate files
1033 are also deleted."
1034   (interactive)
1035   (when elpher-client-certificate
1036     (unless (and (called-interactively-p 'any)
1037                  (not (y-or-n-p (concat "Really forget client certificate? "
1038                                         "(Throwaway certificates will be deleted.)"))))
1039       (when (cadr elpher-client-certificate)
1040         (delete-file (elt elpher-client-certificate 2))
1041         (delete-file (elt elpher-client-certificate 3)))
1042       (setq elpher-client-certificate nil)
1043       (if (called-interactively-p 'any)
1044           (message "Client certificate forgotten.")))))
1045
1046 (defun elpher-get-current-keylist (address)
1047   "Retrieve the `gnutls-boot-parameters'-compatable keylist.
1048
1049 This is obtained from the client certificate described by
1050 `elpher-current-certificate', if one is available and the host for
1051 that certificate matches the host in ADDRESS.
1052
1053 If `elpher-current-certificate' is non-nil, and its host name doesn't
1054 match that of ADDRESS, the certificate is forgotten."
1055   (if elpher-client-certificate
1056       (if (string= (car elpher-client-certificate)
1057                    (elpher-address-host address))
1058           (list (cddr elpher-client-certificate))
1059         (elpher-forget-current-certificate)
1060         (message "Disabling client certificate for new host")
1061         nil)
1062     nil))
1063
1064
1065 ;;; Gopher selector retrieval
1066 ;;
1067
1068 (defun elpher-get-gopher-response (address renderer)
1069   "Get response string from gopher server at ADDRESS and render using RENDERER."
1070   (elpher-get-host-response address 70
1071                             (concat (elpher-gopher-address-selector address) "\r\n")
1072                             renderer
1073                             (or (string= (elpher-address-protocol address) "gophers")
1074                                 elpher-use-tls)))
1075
1076 (defun elpher-get-gopher-page (renderer)
1077   "Getter function for gopher pages.
1078 The RENDERER procedure is used to display the contents of the page
1079 once they are retrieved from the gopher server."
1080   (let* ((address (elpher-page-address elpher-current-page))
1081          (content (elpher-get-cached-content address)))
1082     (if (and content (funcall renderer nil))
1083         (elpher-with-clean-buffer
1084          (insert content)
1085          (elpher-restore-pos))
1086       (elpher-with-clean-buffer
1087        (insert "LOADING... (use 'u' to cancel)\n"))
1088       (condition-case the-error
1089           (elpher-get-gopher-response address renderer)
1090         (error
1091          (elpher-network-error address the-error))))))
1092
1093 ;; Index rendering
1094
1095 (defun elpher-insert-margin (&optional type-name)
1096   "Insert index margin, optionally containing the TYPE-NAME, into current buffer."
1097   (if type-name
1098       (progn
1099         (insert (format (concat "%" (number-to-string (- elpher-margin-width 1)) "s")
1100                         (concat
1101                          (propertize "[" 'face 'elpher-margin-brackets)
1102                          (propertize type-name 'face 'elpher-margin-key)
1103                          (propertize "]" 'face 'elpher-margin-brackets))))
1104         (insert " "))
1105     (insert (make-string elpher-margin-width ?\s))))
1106
1107 (defun elpher--page-button-help (_window buffer pos)
1108   "Function called by Emacs to generate mouse-over text.
1109 The arguments specify the BUFFER and the POS within the buffer of the item
1110 for which help is required.  The function returns the help to be
1111 displayed.  The _WINDOW argument is currently unused."
1112   (with-current-buffer buffer
1113     (let ((button (button-at pos)))
1114       (when button
1115         (let* ((page (button-get button 'elpher-page))
1116                (address (elpher-page-address page)))
1117           (format "mouse-1, RET: open '%s'" (elpher-address-to-url address)))))))
1118
1119 (defun elpher-insert-index-record (display-string &optional address)
1120   "Function to insert an index record into the current buffer.
1121 The contents of the record are dictated by DISPLAY-STRING and ADDRESS.
1122 If ADDRESS is not supplied or nil the record is rendered as an
1123 'information' line."
1124   (let* ((type (if address (elpher-address-type address) nil))
1125          (type-map-entry (cdr (assoc type elpher-type-map))))
1126     (if type-map-entry
1127         (let* ((margin-code (elt type-map-entry 2))
1128                (face (elt type-map-entry 3))
1129                (filtered-display-string (elpher-color-filter-apply display-string))
1130                (page (elpher-make-page filtered-display-string address)))
1131           (elpher-insert-margin margin-code)
1132           (insert-text-button filtered-display-string
1133                               'face face
1134                               'elpher-page page
1135                               'action #'elpher-click-link
1136                               'follow-link t
1137                               'help-echo #'elpher--page-button-help))
1138       (pcase type
1139         ('nil ;; Information
1140          (elpher-insert-margin)
1141          (let ((propertized-display-string
1142                 (propertize display-string 'face 'elpher-info)))
1143            (insert (elpher-process-text-for-display propertized-display-string))))
1144         (`(gopher ,selector-type) ;; Unknown
1145          (elpher-insert-margin (concat (char-to-string selector-type) "?"))
1146          (insert (propertize display-string
1147                              'face 'elpher-unknown)))))
1148     (insert "\n")))
1149
1150 (defun elpher-click-link (button)
1151   "Function called when the gopher link BUTTON is activated."
1152   (let ((page (button-get button 'elpher-page)))
1153     (elpher-visit-page page)))
1154
1155 (defun elpher-render-index (data &optional _mime-type-string)
1156   "Render DATA as an index.  MIME-TYPE-STRING is unused."
1157   (elpher-with-clean-buffer
1158    (if (not data)
1159        t
1160      (let ((data-processed (elpher-preprocess-text-response data)))
1161        (dolist (line (split-string data-processed "\n"))
1162          (ignore-errors
1163            (unless (= (length line) 0)
1164              (let* ((type (elt line 0))
1165                     (fields (split-string (substring line 1) "\t"))
1166                     (display-string (elt fields 0))
1167                     (selector (elt fields 1))
1168                     (host (elt fields 2))
1169                     (port (if (elt fields 3)
1170                               (string-to-number (elt fields 3))
1171                             nil))
1172                     (address (elpher-make-gopher-address type selector host port)))
1173                (elpher-insert-index-record display-string address))))))
1174      (elpher-cache-content (elpher-page-address elpher-current-page)
1175                            (buffer-string)))))
1176
1177 ;; Text rendering
1178
1179 (defun elpher-render-text (data &optional _mime-type-string)
1180   "Render DATA as text.  MIME-TYPE-STRING is unused."
1181   (elpher-with-clean-buffer
1182    (if (not data)
1183        t
1184      (insert (elpher-process-text-for-display (elpher-preprocess-text-response data)))
1185      (elpher-cache-content
1186       (elpher-page-address elpher-current-page)
1187       (buffer-string)))))
1188
1189 ;; Image retrieval
1190
1191 (defun elpher-render-image (data &optional _mime-type-string)
1192   "Display DATA as image.  MIME-TYPE-STRING is unused."
1193   (if (not data)
1194       nil
1195     (if (display-images-p)
1196         (let* ((image (create-image
1197                        data
1198                        nil t)))
1199           (if (not image)
1200               (error "Unsupported image format")
1201             (let ((window (get-buffer-window elpher-buffer-name)))
1202               (when window
1203                 (setf (image-property image :max-width) (window-body-width window t))
1204                 (setf (image-property image :max-height) (window-body-height window t))))
1205             (elpher-with-clean-buffer
1206              (insert-image image)
1207              (elpher-restore-pos))))
1208       (elpher-render-download data))))
1209
1210 ;; Search retrieval and rendering
1211
1212 (defun elpher-get-gopher-query-page (renderer)
1213   "Getter for gopher addresses requiring input.
1214 The response is rendered using the rendering function RENDERER."
1215   (let* ((address (elpher-page-address elpher-current-page))
1216          (content (elpher-get-cached-content address))
1217          (aborted t))
1218     (if (and content (funcall renderer nil))
1219         (elpher-with-clean-buffer
1220          (insert content)
1221          (elpher-restore-pos)
1222          (message "Displaying cached search results.  Reload to perform a new search."))
1223       (unwind-protect
1224           (let* ((query-string (read-string "Query: "))
1225                  (query-selector (concat (elpher-gopher-address-selector address) "\t" query-string))
1226                  (search-address (elpher-make-gopher-address ?1
1227                                                              query-selector
1228                                                              (elpher-address-host address)
1229                                                              (elpher-address-port address)
1230                                                              (equal (elpher-address-type address) "gophers"))))
1231             (setq aborted nil)
1232
1233             (elpher-with-clean-buffer
1234              (insert "LOADING RESULTS... (use 'u' to cancel)"))
1235             (elpher-get-gopher-response search-address renderer))
1236         (if aborted
1237             (elpher-visit-previous-page))))))
1238
1239 ;; Raw server response rendering
1240
1241 (defun elpher-render-raw (data &optional mime-type-string)
1242   "Display raw DATA in buffer.  MIME-TYPE-STRING is also displayed if provided."
1243   (if (not data)
1244       nil
1245     (elpher-with-clean-buffer
1246      (when mime-type-string
1247        (insert "MIME type specified by server: '" mime-type-string "'\n"))
1248      (insert data)
1249      (goto-char (point-min)))
1250     (message "Displaying raw server response.  Reload or redraw to return to standard view.")))
1251
1252 ;; File save "rendering"
1253
1254 (defun elpher-render-download (data &optional _mime-type-string)
1255   "Save DATA to file.  MIME-TYPE-STRING is unused."
1256   (if (not data)
1257       nil
1258     (let* ((address (elpher-page-address elpher-current-page))
1259            (selector (if (elpher-address-gopher-p address)
1260                          (elpher-gopher-address-selector address)
1261                        (elpher-address-filename address))))
1262       (elpher-visit-previous-page) ; Do first in case of non-local exits.
1263       (let* ((filename-proposal (file-name-nondirectory selector))
1264              (filename (read-file-name "Download complete. Save file as: "
1265                                        nil nil nil
1266                                        (if (> (length filename-proposal) 0)
1267                                            filename-proposal
1268                                          "download.file"))))
1269         (let ((coding-system-for-write 'binary))
1270           (with-temp-file filename
1271             (insert data)))
1272         (message (format "Saved to file %s." filename))))))
1273
1274 ;; HTML rendering
1275
1276 (defun elpher-render-html (data &optional _mime-type-string)
1277   "Render DATA as HTML using shr.  MIME-TYPE-STRING is unused."
1278   (elpher-with-clean-buffer
1279    (if (not data)
1280        t
1281      (let ((dom (with-temp-buffer
1282                   (insert data)
1283                   (libxml-parse-html-region (point-min) (point-max)))))
1284        (shr-insert-document dom)))))
1285
1286 ;; Gemini page retrieval
1287
1288 (defvar elpher-gemini-redirect-chain)
1289
1290 (defun elpher-get-gemini-response (address renderer)
1291   "Get response string from gemini server at ADDRESS and render using RENDERER."
1292   (elpher-get-host-response address 1965
1293                             (concat (elpher-address-to-url address) "\r\n")
1294                             (lambda (response-string)
1295                               (elpher-process-gemini-response response-string renderer))
1296                             'gemini))
1297
1298 (defun elpher-parse-gemini-response (response)
1299   "Parse the RESPONSE string and return a list of components.
1300 The list is of the form (code meta body).  A response of nil implies
1301 that the response was malformed."
1302   (let ((header-end-idx (string-match "\r\n" response)))
1303     (if header-end-idx
1304         (let ((header (string-trim (substring response 0 header-end-idx)))
1305               (body (substring response (+ header-end-idx 2))))
1306           (if (>= (length header) 2)
1307               (let ((code (substring header 0 2))
1308                     (meta (string-trim (substring header 2))))
1309                 (list code meta body))
1310             (error "Malformed response: No response status found in header %s" header)))
1311       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1312
1313 (defun elpher-process-gemini-response (response-string renderer)
1314   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1315   (let ((response-components (elpher-parse-gemini-response response-string)))
1316     (let ((response-code (elt response-components 0))
1317           (response-meta (elt response-components 1))
1318           (response-body (elt response-components 2)))
1319       (pcase (elt response-code 0)
1320         (?1 ; Input required
1321          (elpher-with-clean-buffer
1322           (insert "Gemini server is requesting input."))
1323          (let* ((query-string
1324                  (if (eq (elt response-code 1) ?1)
1325                      (read-passwd (concat response-meta ": "))
1326                    (read-string (concat response-meta ": "))))
1327                 (query-address (seq-copy (elpher-page-address elpher-current-page)))
1328                 (old-fname (url-filename query-address)))
1329            (setf (url-filename query-address)
1330                  (concat old-fname "?" (url-build-query-string `((,query-string)))))
1331            (elpher-get-gemini-response query-address renderer)))
1332         (?2 ; Normal response
1333          (funcall renderer response-body response-meta))
1334         (?3 ; Redirect
1335          (message "Following redirect to %s" response-meta)
1336          (if (>= (length elpher-gemini-redirect-chain) 5)
1337              (error "More than 5 consecutive redirects followed"))
1338          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1339            (if (member redirect-address elpher-gemini-redirect-chain)
1340                (error "Redirect loop detected"))
1341            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1342                (error "Server tried to automatically redirect to non-gemini URL: %s"
1343                       response-meta))
1344            (elpher-page-set-address elpher-current-page redirect-address)
1345            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1346            (elpher-get-gemini-response redirect-address renderer)))
1347         (?4 ; Temporary failure
1348          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1349                 response-code response-meta))
1350         (?5 ; Permanent failure
1351          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1352                 response-code response-meta))
1353         (?6 ; Client certificate required
1354          (elpher-with-clean-buffer
1355           (if elpher-client-certificate
1356               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1357             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1358           (auto-fill-mode 1)
1359           (elpher-gemini-insert-text response-meta))
1360          (let ((chosen-certificate (elpher-choose-client-certificate)))
1361            (unless chosen-certificate
1362              (error "Gemini server requires a client certificate and none was provided"))
1363            (setq elpher-client-certificate chosen-certificate))
1364          (elpher-with-clean-buffer)
1365          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1366         (_other
1367          (error "Gemini server response unknown: %s %s"
1368                 response-code response-meta))))))
1369
1370 (defun elpher--read-answer-polyfill (question answers)
1371   "Polyfill for `read-answer' in Emacs 26.1.
1372 QUESTION is a string containing a question, and ANSWERS
1373 is a list of possible answers."
1374     (completing-read question (mapcar 'identity answers)))
1375
1376 (if (fboundp 'read-answer)
1377     (defalias 'elpher-read-answer 'read-answer)
1378   (defalias 'elpher-read-answer 'elpher--read-answer-polyfill))
1379
1380 (defun elpher-choose-client-certificate ()
1381   "Prompt for a client certificate to use to establish a TLS connection."
1382   (let* ((read-answer-short t))
1383     (pcase (read-answer "What do you want to do? "
1384                         '(("throwaway" ?t
1385                            "generate and use throw-away certificate")
1386                           ("persistent" ?p
1387                            "generate new or use existing persistent certificate")
1388                           ("abort" ?a
1389                            "stop immediately")))
1390       ("throwaway"
1391        (setq elpher-client-certificate (elpher-generate-throwaway-certificate)))
1392       ("persistent"
1393        (let* ((existing-certificates (elpher-list-existing-certificates))
1394               (file-base (completing-read
1395                           "Nickname for new or existing certificate (autocompletes, empty response aborts): "
1396                           existing-certificates)))
1397          (if (string-empty-p (string-trim file-base))
1398              nil
1399            (if (member file-base existing-certificates)
1400                (setq elpher-client-certificate
1401                      (elpher-get-existing-certificate file-base))
1402              (pcase (read-answer "Generate new certificate or install externally-generated one? "
1403                                  '(("new" ?n
1404                                     "generate new certificate")
1405                                    ("install" ?i
1406                                     "install existing certificate")
1407                                    ("abort" ?a
1408                                     "stop immediately")))
1409                ("new"
1410                 (let ((common-name (read-string "Common Name field for new certificate: "
1411                                                 file-base)))
1412                   (message "New key and self-signed certificate written to %s"
1413                            elpher-certificate-directory)
1414                   (elpher-generate-persistent-certificate file-base common-name)))
1415                ("install"
1416                 (let* ((cert-file (read-file-name "Certificate file: " nil nil t))
1417                        (key-file (read-file-name "Key file: " nil nil t)))
1418                   (message "Key and certificate installed in %s for future use"
1419                            elpher-certificate-directory)
1420                   (elpher-install-and-use-existing-certificate key-file
1421                                                                cert-file
1422                                                                file-base)))
1423                ("abort" nil))))))
1424       ("abort" nil))))
1425
1426 (defun elpher-get-gemini-page (renderer)
1427   "Getter which retrieves and renders a Gemini page and renders it using RENDERER."
1428   (let* ((address (elpher-page-address elpher-current-page))
1429          (content (elpher-get-cached-content address)))
1430     (condition-case the-error
1431         (if (and content (funcall renderer nil))
1432             (elpher-with-clean-buffer
1433              (insert content)
1434              (elpher-restore-pos))
1435           (elpher-with-clean-buffer
1436            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1437           (setq elpher-gemini-redirect-chain nil)
1438           (elpher-get-gemini-response address renderer))
1439       (error
1440        (elpher-network-error address the-error)))))
1441
1442 (defun elpher-render-gemini (body &optional mime-type-string)
1443   "Render gemini response BODY with rendering MIME-TYPE-STRING."
1444   (if (not body)
1445       t
1446     (let* ((mime-type-string* (if (or (not mime-type-string)
1447                                       (string-empty-p mime-type-string))
1448                                   "text/gemini; charset=utf-8"
1449                                 mime-type-string))
1450            (mime-type-split (split-string mime-type-string* ";" t))
1451            (mime-type (string-trim (car mime-type-split)))
1452            (parameters (mapcar (lambda (s)
1453                                  (let ((key-val (split-string s "=")))
1454                                    (list (downcase (string-trim (car key-val)))
1455                                          (downcase (string-trim (cadr key-val))))))
1456                                (cdr mime-type-split))))
1457       (when (string-prefix-p "text/" mime-type)
1458         (setq body (decode-coding-string
1459                     body
1460                     (if (assoc "charset" parameters)
1461                         (intern (cadr (assoc "charset" parameters)))
1462                       'utf-8)))
1463         (setq body (replace-regexp-in-string "\r" "" body)))
1464       (pcase mime-type
1465         ((or "text/gemini" "")
1466          (elpher-render-gemini-map body parameters))
1467         ("text/html"
1468          (elpher-render-html body))
1469         ((pred (string-prefix-p "text/"))
1470          (elpher-render-gemini-plain-text body parameters))
1471         ((pred (string-prefix-p "image/"))
1472          (elpher-render-image body))
1473         (_other
1474          (elpher-render-download body))))))
1475
1476 (defun elpher-gemini-get-link-url (link-line)
1477   "Extract the url portion of LINK-LINE, a gemini map file link line.
1478 Returns nil in the event that the contents of the line following the
1479 => prefix are empty."
1480   (let ((l (split-string (substring link-line 2))))
1481     (if l
1482         (string-trim (elt l 0))
1483       nil)))
1484
1485 (defun elpher-gemini-get-link-display-string (link-line)
1486   "Extract the display string portion of LINK-LINE, a gemini map file link line.
1487 Return nil if this portion is not provided."
1488   (let* ((rest (string-trim (elt (split-string link-line "=>") 1)))
1489          (idx (string-match "[ \t]" rest)))
1490     (and idx
1491          (elpher-color-filter-apply (string-trim (substring rest (+ idx 1)))))))
1492
1493 (defun elpher-collapse-dot-sequences (filename)
1494   "Collapse dot sequences in the (absolute) FILENAME.
1495 For instance, the filename \"/a/b/../c/./d\" will reduce to \"/a/c/d\""
1496   (let* ((path (split-string filename "/" t))
1497          (is-directory (string-match-p (rx (: (or "." ".." "/") line-end)) filename))
1498          (path-reversed-normalized
1499           (seq-reduce (lambda (a b)
1500                         (cond ((equal b "..") (cdr a))
1501                               ((equal b ".") a)
1502                               (t (cons b a))))
1503                       path nil))
1504          (path-normalized (reverse path-reversed-normalized)))
1505     (if path-normalized
1506         (concat "/" (string-join path-normalized "/") (and is-directory "/"))
1507       "/")))
1508
1509 (defun elpher-address-from-gemini-url (url)
1510   "Extract address from URL with defaults as per gemini map files.
1511 While there's obviously some redundancy here between this function and
1512 `elpher-address-from-url', gemini map file URLs require enough special
1513 treatment that a separate function is warranted."
1514   (let ((address (url-generic-parse-url url))
1515         (current-address (elpher-page-address elpher-current-page)))
1516     (unless (and (url-type address) (not (url-fullness address))) ;avoid mangling mailto: urls
1517       (if (url-host address) ;if there is an explicit host, filenames are absolute
1518           (if (string-empty-p (url-filename address))
1519               (setf (url-filename address) "/")) ;ensure empty filename is marked as absolute
1520         (setf (url-host address) (url-host current-address))
1521         (setf (url-fullness address) (url-host address)) ; set fullness to t if host is set
1522         (setf (url-portspec address) (url-portspec current-address)) ; (url-port) too slow!
1523         (unless (string-prefix-p "/" (url-filename address)) ;deal with relative links
1524           (setf (url-filename address)
1525                 (concat (file-name-directory (url-filename current-address))
1526                         (url-filename address)))))
1527       (when (url-host address)
1528         (setf (url-host address) (puny-encode-domain (url-host address))))
1529       (unless (url-type address)
1530         (setf (url-type address) (url-type current-address)))
1531       (when (equal (url-type address) "gemini")
1532         (setf (url-filename address)
1533               (elpher-collapse-dot-sequences (url-filename address)))))
1534     (elpher-remove-redundant-ports address)))
1535
1536 (defun elpher-gemini-insert-link (link-line)
1537   "Insert link described by LINK-LINE into a text/gemini document."
1538   (let ((url (elpher-gemini-get-link-url link-line)))
1539     (when url
1540       (let* ((given-display-string (elpher-gemini-get-link-display-string link-line))
1541              (address (elpher-address-from-gemini-url url))
1542              (type (if address (elpher-address-type address) nil))
1543              (type-map-entry (cdr (assoc type elpher-type-map)))
1544              (fill-prefix (make-string (+ 1 (length elpher-gemini-link-string)) ?\s)))
1545         (when type-map-entry
1546           (insert elpher-gemini-link-string)
1547           (let* ((face (elt type-map-entry 3))
1548                  (display-string (or given-display-string
1549                                      (elpher-address-to-iri address)))
1550                  (page (elpher-make-page display-string
1551                                          address)))
1552             (insert-text-button display-string
1553                                 'face face
1554                                 'elpher-page page
1555                                 'action #'elpher-click-link
1556                                 'follow-link t
1557                                 'help-echo #'elpher--page-button-help))
1558           (newline))))))
1559
1560 (defun elpher-gemini-insert-header (header-line)
1561   "Insert header described by HEADER-LINE into a text/gemini document.
1562 The gemini map file line describing the header is given
1563 by HEADER-LINE."
1564   (when (string-match "^\\(#+\\)[ \t]*" header-line)
1565     (let* ((level (length (match-string 1 header-line)))
1566            (header (substring header-line (match-end 0)))
1567            (face (pcase level
1568                    (1 'elpher-gemini-heading1)
1569                    (2 'elpher-gemini-heading2)
1570                    (3 'elpher-gemini-heading3)
1571                    (_ 'default)))
1572            (fill-column (if (display-graphic-p)
1573                             (/ (* fill-column
1574                                   (font-get (font-spec :name (face-font 'default)) :size))
1575                                (font-get (font-spec :name (face-font face)) :size)) fill-column)))
1576       (unless (display-graphic-p)
1577         (insert (make-string level ?#) " "))
1578       (insert (propertize header
1579                           'face face
1580                           'gemini-heading t
1581                           'rear-nonsticky t))
1582       (newline))))
1583
1584 (defun elpher-gemini-insert-text (text-line)
1585   "Insert a plain non-preformatted TEXT-LINE into a text/gemini document.
1586 This function uses Emacs' auto-fill to wrap text sensibly to a maximum
1587 width defined by `elpher-gemini-max-fill-width'."
1588   (string-match
1589    (rx (: line-start
1590           (optional
1591            (group (or (: "*" (+ (any " \t")))
1592                       (: ">" (* (any " \t"))))))))
1593    text-line)
1594   (let* ((line-prefix (match-string 1 text-line))
1595          (processed-text-line
1596           (if line-prefix
1597               (cond ((string-prefix-p "*" line-prefix)
1598                      (concat
1599                       (replace-regexp-in-string "\\*"
1600                                                 elpher-gemini-bullet-string
1601                                                 (match-string 0 text-line))
1602                       (substring text-line (match-end 0))))
1603                     ((string-prefix-p ">" line-prefix)
1604                      (propertize text-line 'face 'elpher-gemini-quoted))
1605                     (t text-line))
1606             text-line))
1607          (fill-prefix (if line-prefix
1608                           (make-string (length (match-string 0 text-line)) ?\s)
1609                         "")))
1610     (insert (elpher-process-text-for-display processed-text-line))
1611     (newline)))
1612
1613 (defun elpher-gemini-pref-expand-collapse (button)
1614   "Function called when the preformatted text toggle BUTTON is activated."
1615   (let ((id (button-get button 'pref-id)))
1616     (if (invisible-p id)
1617         (remove-from-invisibility-spec id)
1618       (add-to-invisibility-spec id))
1619     (redraw-display)))
1620
1621 (defun elpher-gemini-insert-preformatted-toggler (alt-text)
1622   "Insert a button for toggling the visibility of preformatted text.
1623 If non-nil, ALT-TEXT is displayed alongside the button."
1624   (let* ((url-string (url-recreate-url (elpher-page-address elpher-current-page)))
1625          (pref-id (intern (concat "pref-"
1626                                   (number-to-string (point))
1627                                   "-"
1628                                   url-string))))
1629     (insert elpher-gemini-preformatted-toggle-bullet)
1630     (when alt-text
1631       (insert (propertize (concat alt-text " ")
1632                           'face 'elpher-gemin-preformatted)))
1633     (insert-text-button elpher-gemini-preformatted-toggle-label
1634                         'action #'elpher-gemini-pref-expand-collapse
1635                         'pref-id pref-id
1636                         'face 'elpher-gemini-preformatted-toggle)
1637     (add-to-invisibility-spec pref-id)
1638     (newline)
1639     pref-id))
1640
1641 (defun elpher-gemini-insert-preformatted-line (line &optional pref-id)
1642   "Insert a LINE of preformatted text.
1643 PREF-ID is the value assigned to the \"invisible\" text attribute, which
1644 can be used to toggle the display of the preformatted text."
1645   (insert (propertize (concat (elpher-process-text-for-display line) "\n")
1646                       'invisible pref-id
1647                       'rear-nonsticky t)))
1648
1649 (defun elpher-render-gemini-map (data _parameters)
1650   "Render DATA as a gemini map file, PARAMETERS is currently unused."
1651   (elpher-with-clean-buffer
1652    (auto-fill-mode 1)
1653    (setq-local buffer-invisibility-spec nil)
1654    (let ((preformatted nil)
1655          (adaptive-fill-mode nil)) ;Prevent automatic setting of fill-prefix
1656      (setq-local fill-column (min (window-width) elpher-gemini-max-fill-width))
1657      (dolist (line (split-string data "\n"))
1658        (pcase line
1659          ((rx (: "```" (opt (let alt-text (+ any)))))
1660           (setq preformatted
1661                 (if preformatted
1662                     nil
1663                   (if elpher-gemini-hide-preformatted
1664                       (elpher-gemini-insert-preformatted-toggler alt-text)
1665                     t))))
1666          ((guard  preformatted)
1667           (elpher-gemini-insert-preformatted-line line preformatted))
1668          ((pred (string-prefix-p "=>"))
1669           (elpher-gemini-insert-link line))
1670          ((pred (string-prefix-p "#"))
1671           (elpher-gemini-insert-header line))
1672          (_ (elpher-gemini-insert-text line))))
1673    (elpher-cache-content
1674     (elpher-page-address elpher-current-page)
1675     (buffer-string)))))
1676
1677 (defun elpher-render-gemini-plain-text (data _parameters)
1678   "Render DATA as plain text file.  PARAMETERS is currently unused."
1679   (elpher-with-clean-buffer
1680    (insert (elpher-process-text-for-display data))
1681    (elpher-cache-content
1682     (elpher-page-address elpher-current-page)
1683     (buffer-string))))
1684
1685 (defun elpher-build-current-imenu-index ()
1686   "Build imenu index for current elpher buffer."
1687   (save-excursion
1688     (goto-char (point-min))
1689     (let ((match nil)
1690           (headers nil))
1691       (while (setq match (text-property-search-forward 'gemini-heading t t))
1692         (push (cons
1693                (buffer-substring-no-properties (prop-match-beginning match)
1694                                                (prop-match-end match))
1695                (prop-match-beginning match))
1696               headers))
1697       (reverse headers))))
1698
1699 ;; Spartan page retrieval
1700
1701 (defun elpher-get-spartan-page (renderer)
1702   "Getter which retrieves and renders a Spartan page and renders it using RENDERER."
1703   (let* ((address (elpher-page-address elpher-current-page))
1704          (content (elpher-get-cached-content address)))
1705     (condition-case the-error
1706         (if (and content (funcall renderer nil))
1707             (elpher-with-clean-buffer
1708              (insert content)
1709              (elpher-restore-pos))
1710           (elpher-with-clean-buffer
1711            (insert "LOADING GEMINI... (use 'u' to cancel)\n"))
1712           (setq elpher-gemini-redirect-chain nil)
1713           (elpher-get-spartan-response address renderer))
1714       (error
1715        (elpher-network-error address the-error)))))
1716
1717 (defun elpher-get-spartan-response (address renderer)
1718   "Get response string from spartan server at ADDRESS and render using RENDERER."
1719   (elpher-get-host-response address 300
1720                             (concat (elpher-address-host address) " "
1721                                     (elpher-address-filename address) " "
1722                                     "0\r\n") ; No uploads for now
1723                             (lambda (response-string)
1724                               (elpher-process-spartan-response response-string renderer))))
1725
1726 (defun elpher-parse-spartan-response (response)
1727   "Parse the RESPONSE string and return a list of components.
1728 The list is of the form (code meta body).  A response of nil implies
1729 that the response was malformed."
1730   (let ((header-end-idx (string-match "\r\n" response)))
1731     (if header-end-idx
1732         (let ((header (string-trim (substring response 0 header-end-idx)))
1733               (body (substring response (+ header-end-idx 2))))
1734           (if (>= (length header) 2)
1735               (let ((code (substring header 0 1))
1736                     (meta (string-trim (substring header 1))))
1737                 (list code meta body))
1738             (error "Malformed response: No response status found in header %s" header)))
1739       (error "Malformed response: No CRLF-delimited header found in response %s" response))))
1740
1741 (defun elpher-process-spartan-response (response-string renderer)
1742   "Process the gemini response RESPONSE-STRING and pass the result to RENDERER."
1743   (let ((response-components (elpher-parse-gemini-response response-string)))
1744     (let ((response-code (elt response-components 0))
1745           (response-meta (elt response-components 1))
1746           (response-body (elt response-components 2)))
1747       (pcase (elt response-code 0)
1748         (?2 ; Normal response
1749          (funcall renderer response-body response-meta))
1750         (?3 ; Redirect
1751          (message "Following redirect to %s" response-meta)
1752          (if (>= (length elpher-gemini-redirect-chain) 5)
1753              (error "More than 5 consecutive redirects followed"))
1754          (let ((redirect-address (elpher-address-from-gemini-url response-meta)))
1755            (if (member redirect-address elpher-gemini-redirect-chain)
1756                (error "Redirect loop detected"))
1757            (if (not (eq (elpher-address-type redirect-address) 'gemini))
1758                (error "Server tried to automatically redirect to non-gemini URL: %s"
1759                       response-meta))
1760            (elpher-page-set-address elpher-current-page redirect-address)
1761            (add-to-list 'elpher-gemini-redirect-chain redirect-address)
1762            (elpher-get-gemini-response redirect-address renderer)))
1763         (?4 ; Temporary failure
1764          (error "Gemini server reports TEMPORARY FAILURE for this request: %s %s"
1765                 response-code response-meta))
1766         (?5 ; Permanent failure
1767          (error "Gemini server reports PERMANENT FAILURE for this request: %s %s"
1768                 response-code response-meta))
1769         (?6 ; Client certificate required
1770          (elpher-with-clean-buffer
1771           (if elpher-client-certificate
1772               (insert "Gemini server does not recognise the provided TLS certificate:\n\n")
1773             (insert "Gemini server is requesting a valid TLS certificate:\n\n"))
1774           (auto-fill-mode 1)
1775           (elpher-gemini-insert-text response-meta))
1776          (let ((chosen-certificate (elpher-choose-client-certificate)))
1777            (unless chosen-certificate
1778              (error "Gemini server requires a client certificate and none was provided"))
1779            (setq elpher-client-certificate chosen-certificate))
1780          (elpher-with-clean-buffer)
1781          (elpher-get-gemini-response (elpher-page-address elpher-current-page) renderer))
1782         (_other
1783          (error "Gemini server response unknown: %s %s"
1784                 response-code response-meta))))))
1785
1786 ;; Finger page connection
1787
1788 (defun elpher-get-finger-page (renderer)
1789   "Opens a finger connection to the current page address.
1790 The result is rendered using RENDERER."
1791   (let* ((address (elpher-page-address elpher-current-page))
1792          (content (elpher-get-cached-content address)))
1793     (if (and content (funcall renderer nil))
1794         (elpher-with-clean-buffer
1795          (insert content)
1796          (elpher-restore-pos))
1797       (elpher-with-clean-buffer
1798        (insert "LOADING... (use 'u' to cancel)\n"))
1799       (condition-case the-error
1800           (let* ((kill-buffer-query-functions nil)
1801                  (user (let ((filename (elpher-address-filename address)))
1802                          (if (> (length filename) 1)
1803                              (substring filename 1)
1804                            (elpher-address-user address)))))
1805             (elpher-get-host-response address 79
1806                                       (concat user "\r\n")
1807                                       renderer))
1808         (error
1809          (elpher-network-error address the-error))))))
1810
1811
1812 ;; Telnet page connection
1813
1814 (defun elpher-get-telnet-page (renderer)
1815   "Opens a telnet connection to the current page address (RENDERER must be nil)."
1816   (when renderer
1817     (elpher-visit-previous-page)
1818     (error "Command not supported for telnet URLs"))
1819   (let* ((address (elpher-page-address elpher-current-page))
1820          (host (elpher-address-host address))
1821          (port (elpher-address-port address)))
1822     (elpher-visit-previous-page)
1823     (if (> port 0)
1824         (telnet host port)
1825       (telnet host))))
1826
1827
1828 ;; Other URL page opening
1829
1830 (defun elpher-get-other-url-page (renderer)
1831   "Getter which attempts to open the URL specified by the current page.
1832 The RENDERER argument to this getter must be nil."
1833   (when renderer
1834     (elpher-visit-previous-page)
1835     (error "Command not supported for general URLs"))
1836   (let* ((address (elpher-page-address elpher-current-page))
1837          (url (elpher-address-to-url address)))
1838     (elpher-visit-previous-page) ; Do first in case of non-local exits.
1839     (message "Opening URL...")
1840     (if elpher-open-urls-with-eww
1841         (browse-web url)
1842       (browse-url url))))
1843
1844
1845 ;; File page
1846
1847 (defun elpher-get-file-page (renderer)
1848   "Getter which renders a local file using RENDERER.
1849 Assumes UTF-8 encoding for all text files."
1850   (let* ((address (elpher-page-address elpher-current-page))
1851          (filename (elpher-address-filename address)))
1852     (unless (file-exists-p filename)
1853       (elpher-visit-previous-page)
1854         (error "File not found"))
1855     (unless (file-readable-p filename)
1856       (elpher-visit-previous-page)
1857         (error "Could not read from file"))
1858     (let ((body (with-temp-buffer
1859        (let ((coding-system-for-read 'binary)
1860              (coding-system-for-write 'binary))
1861          (insert-file-contents-literally filename)
1862          (encode-coding-string (buffer-string) 'raw-text)))))
1863        (if renderer
1864            (funcall renderer body nil)
1865          (pcase (file-name-extension filename)
1866            ((or  "gmi" "gemini")
1867             (elpher-render-gemini-map (decode-coding-string body 'utf-8) nil))
1868            ((or "htm" "html")
1869             (elpher-render-html (decode-coding-string body 'utf-8)))
1870            ((or "txt" "")
1871             (elpher-render-text (decode-coding-string body 'utf-8)))
1872            ((or "jpg" "jpeg" "gif" "png" "bmp" "tif" "tiff")
1873             (elpher-render-image body))
1874            ((or "gopher" "gophermap")
1875             (elpher-render-index (elpher-decode body)))
1876            (_
1877             (elpher-render-download body))))
1878        (elpher-restore-pos))))
1879
1880
1881 ;; Welcome page retrieval
1882
1883 (defun elpher-get-welcome-page (renderer)
1884   "Getter which displays the welcome page (RENDERER must be nil)."
1885   (when renderer
1886     (elpher-visit-previous-page)
1887     (error "Command not supported for welcome page"))
1888   (elpher-with-clean-buffer
1889    (insert "     --------------------------------------------\n"
1890            "           Elpher Gopher and Gemini Client       \n"
1891            "                   version " elpher-version "\n"
1892            "     --------------------------------------------\n"
1893            "\n"
1894            "Default bindings:\n"
1895            "\n"
1896            " - TAB/Shift-TAB: next/prev item on current page\n"
1897            " - RET/mouse-1: open item under cursor\n"
1898            " - m: select an item on current page by name (autocompletes)\n"
1899            " - u/mouse-3/U: return to previous page or to the start page\n"
1900            " - g: go to a particular address (gopher, gemini, finger)\n"
1901            " - o/O: open a different address selector or the root menu of the current server\n"
1902            " - d/D: download item under cursor or current page\n"
1903            " - i/I: info on item under cursor or current page\n"
1904            " - c/C: copy URL representation of item under cursor or current page\n"
1905            " - a/A: bookmark the item under cursor or current page\n"
1906            " - B: list all bookmarks\n"
1907            " - s/S: show current history stack or all previously visted pages\n"
1908            " - r: redraw current page (using cached contents if available)\n"
1909            " - R: reload current page (regenerates cache)\n"
1910            " - !: set character coding system for gopher (default is to autodetect)\n"
1911            " - T: toggle TLS gopher mode\n"
1912            " - F: forget/discard current TLS client certificate\n"
1913            " - .: display the raw server response for the current page\n"
1914            "\n"
1915            "Start your exploration of gopher space and gemini:\n")
1916    (elpher-insert-index-record "Floodgap Systems Gopher Server"
1917                                (elpher-make-gopher-address ?1 "" "gopher.floodgap.com" 70))
1918    (elpher-insert-index-record "Project Gemini home page"
1919                                (elpher-address-from-url "gemini://gemini.circumlunar.space/"))
1920    (insert "\n"
1921            "Alternatively, select a search engine and enter some search terms:\n")
1922    (elpher-insert-index-record "Gopher Search Engine (Veronica-2)"
1923                                (elpher-make-gopher-address ?7 "/v2/vs" "gopher.floodgap.com" 70))
1924    (elpher-insert-index-record "Gemini Search Engine (geminispace.info)"
1925                                (elpher-address-from-url "gemini://geminispace.info/search"))
1926    (insert "\n"
1927            "Your bookmarks are stored in your ")
1928    (insert-text-button "bookmark list"
1929                        'face 'link
1930                        'action #'elpher-click-link
1931                        'follow-link t
1932                        'help-echo #'elpher--page-button-help
1933                        'elpher-page
1934                        (elpher-make-page "Elpher Bookmarks"
1935                                          (elpher-make-about-address 'bookmarks)))
1936    (insert ".\n")
1937    (insert (propertize
1938             "(Bookmarks from legacy elpher-bookmarks files will be automatically imported.)\n"
1939             'face 'shadow))
1940    (insert "\n"
1941            "The gopher home of the Elpher project is here:\n")
1942    (elpher-insert-index-record "The Elpher Project Page"
1943                                (elpher-make-gopher-address ?1
1944                                                            "/projects/elpher/"
1945                                                            "thelambdalab.xyz"
1946                                                            70))
1947    (let ((help-string "RET,mouse-1: Open Elpher info manual (if available)"))
1948      (insert "\n"
1949              "The following info documentation is available:\n"
1950              "   - ")
1951      (insert-text-button "Elpher Manual"
1952                          'face 'link
1953                          'action (lambda (_)
1954                                    (interactive)
1955                                    (info "(elpher)"))
1956                          'follow-link t
1957                          'help-echo help-string)
1958      (insert "\n   - ")
1959      (insert-text-button "Changes introduced by the latest release"
1960                        'face 'link
1961                        'action (lambda (_)
1962                                  (interactive)
1963                                  (info "(elpher)News"))
1964                        'follow-link t
1965                        'help-echo help-string))
1966    (insert "\n")
1967    (insert (propertize
1968             (concat "(These documents should be available if you have installed Elpher\n"
1969                     " from MELPA or non-GNU ELPA. Otherwise you may have to install the\n"
1970                     " manual yourself.)\n")
1971             'face 'shadow))
1972    (elpher-restore-pos)))
1973
1974
1975 ;; History page retrieval
1976
1977 (defun elpher-show-history ()
1978   "Show the current contents of elpher's history stack.
1979 Use \\[elpher-show-visited-pages] to see the entire history.
1980 This is rendered using `elpher-get-history-page' via `elpher-type-map'."
1981   (interactive)
1982   (elpher-visit-page
1983    (elpher-make-page "Current History Stack"
1984                      (elpher-make-about-address 'history))))
1985
1986 (defun elpher-show-visited-pages ()
1987   "Show the all the pages you've visited using Elpher.
1988 Use \\[elpher-show-history] to see just the current history stack.
1989 This is rendered using `elpher-get-visited-pages-page' via `elpher-type-map'."
1990   (interactive)
1991   (elpher-visit-page
1992    (elpher-make-page "Elpher Visted Pages"
1993                      (elpher-make-about-address 'visited-pages))))
1994
1995 (defun elpher-get-history-page (renderer)
1996   "Getter which displays the history page (RENDERER must be nil)."
1997   (when renderer
1998     (elpher-visit-previous-page)
1999     (error "Command not supported for history page"))
2000   (elpher-display-history-links elpher-history "Current history stack"))
2001
2002 (defun elpher-get-visited-pages-page (renderer)
2003   "Getter which displays the list of visited pages (RENDERER must be nil)."
2004   (when renderer
2005     (elpher-visit-previous-page)
2006     (error "Command not supported for history page"))
2007   (elpher-display-history-links
2008    (seq-filter (lambda (page)
2009                  (not (elpher-address-about-p (elpher-page-address page))))
2010                elpher-visited-pages)
2011    "All visited pages"))
2012
2013 (defun elpher-display-history-links (pages title)
2014   "Show all PAGES in an Elpher buffer with a given TITLE."
2015   (let* ((title-line (concat " ---- " title " ----"))
2016          (footer-line (make-string (length title-line) ?-)))
2017     (elpher-with-clean-buffer
2018      (insert title-line "\n\n")
2019      (if pages
2020          (dolist (page pages)
2021            (when page
2022              (let ((display-string (elpher-page-display-string page))
2023                    (address (elpher-page-address page)))
2024                (elpher-insert-index-record display-string address))))
2025        (insert "No history items found.\n"))
2026      (insert "\n " footer-line "\n"
2027              "Select an entry or press 'u' to return to the previous page.")
2028      (elpher-restore-pos))))
2029
2030
2031 ;;; Bookmarks
2032
2033 ;; This code allows Elpher to use the standard Emacs bookmarks: `C-x r
2034 ;; m' to add a bookmark, `C-x r l' to list bookmarks (which is where
2035 ;; you can anotate bookmarks!), `C-x r b' to jump to a bookmark, and
2036 ;; so on. See the Bookmarks section in the Emacs info manual for more.
2037
2038 (defvar elpher-bookmark-link nil
2039   "Prefer bookmarking a link or the current page.
2040 Bind this variable dynamically, or set it to t.
2041 If you set it to t, the commands \\[bookmark-set-no-overwrite]
2042 and \\[elpher-set-bookmark-no-overwrite] do the same thing.")
2043
2044 (defun elpher-bookmark-make-record ()
2045   "Return a bookmark record.
2046 If `elpher-bookmark-link' is non-nil and point is on a link button,
2047 return a bookmark record for that link.  Otherwise, return a bookmark
2048 record for the current elpher page."
2049   (let* ((button (and elpher-bookmark-link (button-at (point))))
2050          (page (if button
2051                    (button-get button 'elpher-page)
2052                  elpher-current-page)))
2053     (unless page
2054       (error "Cannot bookmark this link"))
2055     (let* ((address (elpher-page-address page))
2056            (url (elpher-address-to-url address))
2057            (display-string (elpher-page-display-string page))
2058            (pos (if button nil (point))))
2059       (if (elpher-address-about-p address)
2060           (error "Cannot bookmark %s" display-string)
2061         `(,display-string
2062           (defaults . (,display-string))
2063           (position . ,pos)
2064           (location . ,url)
2065           (handler . elpher-bookmark-jump))))))
2066
2067 ;;;###autoload
2068 (defun elpher-bookmark-jump (bookmark)
2069   "Handler used to open a bookmark using elpher.
2070 The argument BOOKMARK is a bookmark record passed to the function.
2071 This handler is responsible for loading the bookmark in some buffer,
2072 then making that buffer the current buffer.  It should not switch
2073 to the buffer."
2074   (let* ((url (cdr (assq 'location bookmark)))
2075          (cleaned-url (string-trim url))
2076          (page (elpher-page-from-url cleaned-url))
2077          (buffer (get-buffer-create elpher-buffer-name)))
2078     (elpher-with-clean-buffer
2079      (elpher-visit-page page))
2080     (set-buffer buffer)
2081     nil))
2082
2083 (defun elpher-bookmark-link ()
2084   "Bookmark the link at point.
2085 To bookmark the current page, use \\[elpher-bookmark-current]."
2086   (interactive)
2087   (let ((elpher-bookmark-link t))
2088     (bookmark-set-no-overwrite)))
2089
2090 (defun elpher-bookmark-current ()
2091   "Bookmark the current page.
2092 To bookmark the link at point use \\[elpher-bookmark-link]."
2093   (interactive)
2094   (call-interactively #'bookmark-set-no-overwrite))
2095
2096 (defun elpher-bookmark-import (file)
2097   "Import legacy Elpher bookmarks file FILE into Emacs bookmarks."
2098   (interactive (list (if (and (boundp 'elpher-bookmarks-file)
2099                               (file-readable-p elpher-bookmarks-file))
2100                          elpher-bookmarks-file
2101                        (read-file-name "Old Elpher bookmarks: "
2102                                        user-emacs-directory nil t
2103                                        "elpher-bookmarks"))))
2104   (dolist (bookmark (with-temp-buffer
2105                       (insert-file-contents file)
2106                       (read (current-buffer))))
2107     (let* ((display-string (car bookmark))
2108            (url (cadr bookmark))
2109            (record `(,display-string
2110                      (location . ,url)
2111                      (handler . elpher-bookmark-jump))))
2112       (bookmark-store display-string (cdr record) t)))
2113   (bookmark-save))
2114
2115 (defun elpher-get-bookmarks-page (renderer)
2116   "Getter which displays the bookmarks (RENDERER must be nil)."
2117   (when renderer
2118     (elpher-visit-previous-page)
2119     (error "Command not supported for bookmarks page"))
2120
2121   (let ((old-bookmarks-file (or (and (boundp 'elpher-bookmarks-file)
2122                                      elpher-bookmarks-file)
2123                                 (locate-user-emacs-file "elpher-bookmarks"))))
2124     (when (and (file-readable-p old-bookmarks-file)
2125                (y-or-n-p (concat "Legacy elpher-bookmarks file \""
2126                                  old-bookmarks-file
2127                                  "\" found. Import now?")))
2128       (elpher-bookmark-import old-bookmarks-file)
2129       (rename-file old-bookmarks-file (concat old-bookmarks-file "-legacy"))))
2130
2131   (if (and elpher-use-emacs-bookmark-menu
2132            elpher-history)
2133       (progn
2134         (elpher-visit-previous-page)
2135         (call-interactively #'bookmark-bmenu-list))
2136     (elpher-with-clean-buffer
2137      (insert " ---- Elpher Bookmarks ---- \n\n")
2138      (bookmark-maybe-load-default-file)
2139      (dolist (bookmark (bookmark-maybe-sort-alist))
2140        (when (eq #'elpher-bookmark-jump (alist-get 'handler (cdr bookmark)))
2141          (let* ((name (car bookmark))
2142                 (url (alist-get 'location (cdr bookmark)))
2143                 (address (elpher-address-from-url url)))
2144            (elpher-insert-index-record name address))))
2145      (when (<= (line-number-at-pos) 3)
2146        (insert "No bookmarked pages found.\n"))
2147      (insert "\n --------------------------\n\n"
2148              "Select an entry or press 'u' to return to the previous page.\n\n"
2149              "Bookmarks can be renamed or deleted via the ")
2150      (insert-text-button "Emacs bookmark menu"
2151                          'action (lambda (_)
2152                                    (interactive)
2153                                    (call-interactively #'bookmark-bmenu-list))
2154                          'follow-link t
2155                          'help-echo "RET,mouse-1: open Emacs bookmark menu")
2156      (insert (substitute-command-keys
2157               ",\nwhich can also be opened from anywhere using '\\[bookmark-bmenu-list]'."))
2158      (elpher-restore-pos))))
2159
2160 (defun elpher-show-bookmarks ()
2161   "Interactive function to display the current list of elpher bookmarks."
2162   (interactive)
2163   (elpher-visit-page
2164    (elpher-make-page "Elpher Bookmarks"
2165                      (elpher-make-about-address 'bookmarks))))
2166
2167
2168 ;;; Integrations
2169 ;;
2170
2171 ;;; Org
2172
2173 (defun elpher-org-export-link (link description format protocol)
2174   "Export a LINK with DESCRIPTION for the given PROTOCOL and FORMAT.
2175
2176 FORMAT is an Org export backend.  DESCRIPTION may be nil.  PROTOCOL may be one
2177 of gemini, gopher or finger."
2178   (let* ((url (if (equal protocol "elpher")
2179                   (string-remove-prefix "elpher:" link)
2180                 (format "%s:%s" protocol link)))
2181          (desc (or description url)))
2182     (pcase format
2183       (`gemini (format "=> %s %s" url desc))
2184       (`html (format "<a href=\"%s\">%s</a>" url desc))
2185       (`latex (format "\\href{%s}{%s}" url desc))
2186       (_ (if (not description)
2187              url
2188            (format "%s (%s)" desc url))))))
2189
2190 (defun elpher-org-store-link ()
2191   "Store link to an `elpher' page in Org."
2192   (when (eq major-mode 'elpher-mode)
2193     (let* ((url (elpher-info-current))
2194            (desc (car elpher-current-page))
2195            (protocol (cond
2196                       ((string-prefix-p "gemini:" url) "gemini")
2197                       ((string-prefix-p "gopher:" url) "gopher")
2198                       ((string-prefix-p "finger:" url) "finger")
2199                       (t "elpher"))))
2200       (when (equal "elpher" protocol)
2201         ;; Weird link. Or special inner link?
2202         (setq url (concat "elpher:" url)))
2203       (org-link-store-props :type protocol :link url :description desc)
2204       t)))
2205
2206 (defun elpher-org-follow-link (link protocol)
2207   "Visit a LINK for the given PROTOCOL.
2208
2209 PROTOCOL may be one of gemini, gopher or finger.  This method also
2210 supports the old protocol elpher, where the link is self-contained."
2211   (let ((url (if (equal protocol "elpher")
2212                  (string-remove-prefix "elpher:" link)
2213                (format "%s:%s" protocol link))))
2214     (elpher-go url)))
2215
2216 (defun elpher-org-mode-integration ()
2217   "Set up `elpher' integration for `org-mode'."
2218   (org-link-set-parameters
2219    "elpher"
2220    :store #'elpher-org-store-link
2221    :export (lambda (link description format _plist)
2222              (elpher-org-export-link link description format "elpher"))
2223    :follow (lambda (link _arg) (elpher-org-follow-link link "elpher")))
2224   (org-link-set-parameters
2225    "gemini"
2226    :export (lambda (link description format _plist)
2227              (elpher-org-export-link link description format "gemini"))
2228    :follow (lambda (link _arg) (elpher-org-follow-link link "gemini")))
2229   (org-link-set-parameters
2230    "gopher"
2231    :export (lambda (link description format _plist)
2232              (elpher-org-export-link link description format "gopher"))
2233    :follow (lambda (link _arg) (elpher-org-follow-link link "gopher")))
2234   (org-link-set-parameters
2235    "finger"
2236    :export (lambda (link description format _plist)
2237              (elpher-org-export-link link description format "finger"))
2238    :follow (lambda (link _arg) (elpher-org-follow-link link "finger"))))
2239
2240 (add-hook 'org-mode-hook #'elpher-org-mode-integration)
2241
2242 ;;; Browse URL
2243
2244 ;;;###autoload
2245 (defun elpher-browse-url-elpher (url &rest _args)
2246   "Browse URL using Elpher.  This function is used by `browse-url'."
2247   (interactive (browse-url-interactive-arg "Elpher URL: "))
2248   (elpher-go url))
2249
2250 ;; Use elpher to open gopher, finger and gemini links
2251 ;; For recent version of `browse-url' package
2252 (if (boundp 'browse-url-default-handlers)
2253     (add-to-list
2254      'browse-url-default-handlers
2255      '("^\\(gopher\\|finger\\|gemini\\)://" . elpher-browse-url-elpher))
2256   ;; Patch `browse-url-browser-function' for older ones. The value of
2257   ;; that variable is `browse-url-default-browser' by default, so
2258   ;; that's the function that gets advised. If the value is an alist,
2259   ;; however, we don't know what to do. Better not interfere?
2260   (when (and (symbolp browse-url-browser-function)
2261              (fboundp browse-url-browser-function))
2262     (advice-add browse-url-browser-function :before-while
2263                 (lambda (url &rest _args)
2264                   "Handle gemini, gopher, and finger schemes using Elpher."
2265                   (let ((scheme (downcase (car (split-string url ":" t)))))
2266                     (if (member scheme '("gemini" "gopher" "finger"))
2267                         ;; `elpher-go' always returns nil, which will stop the
2268                         ;; advice chain here in a before-while
2269                         (elpher-go url)
2270                       ;; chain must continue, then return t.
2271                       t))))))
2272
2273 ;; Register "gemini://" as a URI scheme so `browse-url' does the right thing
2274 (with-eval-after-load 'thingatpt
2275   (add-to-list 'thing-at-point-uri-schemes "gemini://"))
2276
2277 ;;; Mu4e:
2278
2279 ;; Make mu4e aware of the gemini world
2280 (setq mu4e~view-beginning-of-url-regexp
2281       "\\(?:https?\\|gopher\\|finger\\|gemini\\)://\\|mailto:")
2282
2283 ;;; eww:
2284
2285 ;; Let elpher handle gemini, gopher links in eww buffer.
2286 (setq eww-use-browse-url
2287       "\\`mailto:\\|\\(\\`gemini\\|\\`gopher\\|\\`finger\\)://")
2288
2289
2290 ;;; Interactive procedures
2291 ;;
2292
2293 (defun elpher-next-link ()
2294   "Move point to the next link on the current page."
2295   (interactive)
2296   (forward-button 1))
2297
2298 (defun elpher-prev-link ()
2299   "Move point to the previous link on the current page."
2300   (interactive)
2301   (backward-button 1))
2302
2303 (defun elpher-follow-current-link ()
2304   "Open the link or url at point."
2305   (interactive)
2306   (push-button))
2307
2308 ;;;###autoload
2309 (defun elpher-go (host-or-url)
2310   "Go to a particular gopher site HOST-OR-URL.
2311 When run interactively HOST-OR-URL is read from the minibuffer."
2312   (interactive (list
2313                 (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme)))))
2314   (let ((trimmed-host-or-url (string-trim host-or-url)))
2315     (unless (string-empty-p trimmed-host-or-url)
2316       (let ((page (elpher-page-from-url trimmed-host-or-url
2317                                         (elpher-get-default-url-scheme))))
2318         (unless (get-buffer-window elpher-buffer-name t)
2319           (switch-to-buffer elpher-buffer-name))
2320         (elpher-with-clean-buffer
2321          (elpher-visit-page page))
2322         nil)))) ; non-nil value is displayed by eshell
2323
2324 (defun elpher-go-current ()
2325   "Go to a particular URL which is read from the minibuffer.
2326 Unlike `elpher-go', the reader is initialized with the URL of the
2327 current page."
2328   (interactive)
2329   (let* ((address (elpher-page-address elpher-current-page))
2330          (url (read-string (format "Visit URL (default scheme %s): " (elpher-get-default-url-scheme))
2331                            (elpher-address-to-url address))))
2332     (unless (string-empty-p (string-trim url))
2333       (elpher-visit-page (elpher-page-from-url url)))))
2334
2335 (defun elpher-redraw ()
2336   "Redraw current page."
2337   (interactive)
2338   (elpher-visit-page elpher-current-page))
2339
2340 (defun elpher-reload ()
2341   "Reload current page."
2342   (interactive)
2343   (elpher-reload-current-page))
2344
2345 (defun elpher-toggle-tls ()
2346   "Toggle TLS encryption mode for gopher."
2347   (interactive)
2348   (setq elpher-use-tls (not elpher-use-tls))
2349   (if elpher-use-tls
2350       (if (gnutls-available-p)
2351           (message "TLS gopher mode enabled.  (Will not affect current page until reload.)")
2352         (setq elpher-use-tls nil)
2353         (error "Cannot enable TLS gopher mode: GnuTLS not available"))
2354     (message "TLS gopher mode disabled.  (Will not affect current page until reload.)")))
2355
2356 (defun elpher-view-raw ()
2357   "View raw server response for current page."
2358   (interactive)
2359   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2360       (error "This page was not generated by a server")
2361     (elpher-visit-page elpher-current-page
2362                        #'elpher-render-raw)))
2363
2364 (defun elpher-back ()
2365   "Go to previous site."
2366   (interactive)
2367   (elpher-visit-previous-page))
2368
2369 (defun elpher-back-to-start ()
2370   "Go all the way back to the start page."
2371   (interactive)
2372   (setq-local elpher-current-page nil)
2373   (setq-local elpher-history nil)
2374   (elpher-visit-page (elpher-make-start-page)))
2375
2376 (defun elpher-download ()
2377   "Download the link at point."
2378   (interactive)
2379   (let ((button (button-at (point))))
2380     (if button
2381         (let ((page (button-get button 'elpher-page)))
2382           (unless page
2383             (error "Not an elpher page"))
2384           (when (elpher-address-about-p (elpher-page-address page))
2385             (error "Cannot download %s" (elpher-page-display-string page)))
2386           (elpher-visit-page (button-get button 'elpher-page)
2387                              #'elpher-render-download))
2388       (error "No link selected"))))
2389
2390 (defun elpher-download-current ()
2391   "Download the current page."
2392   (interactive)
2393   (if (elpher-address-about-p (elpher-page-address elpher-current-page))
2394       (error "Cannot download %s"
2395              (elpher-page-display-string elpher-current-page))
2396     (elpher-visit-page (elpher-make-page
2397                         (elpher-page-display-string elpher-current-page)
2398                         (elpher-page-address elpher-current-page))
2399                        #'elpher-render-download
2400                        t)))
2401
2402 (defun elpher--build-link-map ()
2403   "Build alist mapping link names to destination pages in current buffer."
2404   (let ((link-map nil)
2405         (b (next-button (point-min) t)))
2406     (while b
2407       (push (cons (button-label b) b) link-map)
2408       (setq b (next-button (button-start b))))
2409     link-map))
2410
2411 (defun elpher-jump ()
2412   "Select a directory entry by name.  Similar to the info browser (m)enu command."
2413   (interactive)
2414   (let* ((link-map (elpher--build-link-map)))
2415     (if link-map
2416         (let ((key (let ((completion-ignore-case t))
2417                      (completing-read "Directory item/link: "
2418                                       link-map nil t))))
2419           (if (and key (> (length key) 0))
2420               (let ((b (cdr (assoc key link-map))))
2421                 (goto-char (button-start b))
2422                 (button-activate b)))))))
2423
2424 (defun elpher-root-dir ()
2425   "Visit root of current server."
2426   (interactive)
2427   (let ((address (elpher-page-address elpher-current-page)))
2428     (if (not (elpher-address-about-p address))
2429         (if (or (member (url-filename address) '("/" ""))
2430                 (and (elpher-address-gopher-p address)
2431                      (= (length (elpher-gopher-address-selector address)) 0)))
2432             (error "Already at root directory of current server")
2433           (let ((address-copy (elpher-address-from-url
2434                                (elpher-address-to-url address))))
2435             (setf (url-filename address-copy) "")
2436             (elpher-go (elpher-address-to-url address-copy))))
2437       (error "Command invalid for %s" (elpher-page-display-string elpher-current-page)))))
2438
2439 (defun elpher-info-page (page)
2440   "Display URL of PAGE in minibuffer."
2441   (let* ((address (elpher-page-address page))
2442          (url (elpher-address-to-url address))
2443          (iri (elpher-address-to-iri address)))
2444     (if (equal url iri)
2445         (message "%s" url)
2446       (message "%s (Raw: %s)" iri url))))
2447
2448 (defun elpher-info-link ()
2449   "Display information on page corresponding to link at point."
2450   (interactive)
2451   (let ((button (button-at (point))))
2452     (unless button
2453       (error "No item selected"))
2454     (let ((page (button-get button 'elpher-page)))
2455       (unless page
2456         (error "Not an elpher page"))
2457       (elpher-info-page page))))
2458
2459 (defun elpher-info-current ()
2460   "Display information on current page."
2461   (interactive)
2462   (elpher-info-page elpher-current-page))
2463
2464 (defun elpher-copy-page-url (page)
2465   "Copy URL representation of address of PAGE to `kill-ring'."
2466   (let* ((address (elpher-page-address page))
2467          (url (elpher-address-to-url address)))
2468     (message "Copied \"%s\" to kill-ring/clipboard." url)
2469     (kill-new url)))
2470
2471 (defun elpher-copy-link-url ()
2472   "Copy URL of item at point to `kill-ring'."
2473   (interactive)
2474   (let ((button (button-at (point))))
2475     (unless button
2476       (error "No item selected"))
2477     (let ((page (button-get button 'elpher-page)))
2478       (unless page
2479         (error "Not an elpher page"))
2480       (elpher-copy-page-url page))))
2481
2482 (defun elpher-copy-current-url ()
2483   "Copy URL of current page to `kill-ring'."
2484   (interactive)
2485   (elpher-copy-page-url elpher-current-page))
2486
2487 (defun elpher-set-gopher-coding-system ()
2488   "Specify an explicit character coding system for gopher selectors."
2489   (interactive)
2490   (let ((system (read-coding-system "Set coding system to use for gopher (default is to autodetect): " nil)))
2491     (setq elpher-user-coding-system system)
2492     (if system
2493         (message "Gopher coding system fixed to %s. (Reload to see effect)." system)
2494       (message "Gopher coding system set to autodetect. (Reload to see effect)."))))
2495
2496
2497 ;;; Mode and keymap
2498 ;;
2499
2500 (defvar elpher-mode-map
2501   (let ((map (make-sparse-keymap)))
2502     (define-key map (kbd "TAB") 'elpher-next-link)
2503     (define-key map (kbd "<backtab>") 'elpher-prev-link)
2504     (define-key map (kbd "C-M-i") 'elpher-prev-link)
2505     (define-key map (kbd "u") 'elpher-back)
2506     (define-key map (kbd "-") 'elpher-back)
2507     (define-key map (kbd "^") 'elpher-back)
2508     (define-key map [mouse-3] 'elpher-back)
2509     (define-key map (kbd "U") 'elpher-back-to-start)
2510     (define-key map (kbd "g") 'elpher-go)
2511     (define-key map (kbd "o") 'elpher-go-current)
2512     (define-key map (kbd "O") 'elpher-root-dir)
2513     (define-key map (kbd "s") 'elpher-show-history)
2514     (define-key map (kbd "S") 'elpher-show-visited-pages)
2515     (define-key map (kbd "r") 'elpher-redraw)
2516     (define-key map (kbd "R") 'elpher-reload)
2517     (define-key map (kbd "T") 'elpher-toggle-tls)
2518     (define-key map (kbd ".") 'elpher-view-raw)
2519     (define-key map (kbd "d") 'elpher-download)
2520     (define-key map (kbd "D") 'elpher-download-current)
2521     (define-key map (kbd "m") 'elpher-jump)
2522     (define-key map (kbd "i") 'elpher-info-link)
2523     (define-key map (kbd "I") 'elpher-info-current)
2524     (define-key map (kbd "c") 'elpher-copy-link-url)
2525     (define-key map (kbd "C") 'elpher-copy-current-url)
2526     (define-key map (kbd "a") 'elpher-bookmark-link)
2527     (define-key map (kbd "A") 'elpher-bookmark-current)
2528     (define-key map (kbd "B") 'elpher-show-bookmarks)
2529     (define-key map (kbd "!") 'elpher-set-gopher-coding-system)
2530     (define-key map (kbd "F") 'elpher-forget-current-certificate)
2531     (when (fboundp 'evil-define-key*)
2532       (evil-define-key*
2533        'motion map
2534        (kbd "TAB") 'elpher-next-link
2535        (kbd "C-") 'elpher-follow-current-link
2536        (kbd "C-t") 'elpher-back
2537        (kbd "u") 'elpher-back
2538        (kbd "-") 'elpher-back
2539        (kbd "^") 'elpher-back
2540        [mouse-3] 'elpher-back
2541        (kbd "U") 'elpher-back-to-start
2542        (kbd "g") 'elpher-go
2543        (kbd "o") 'elpher-go-current
2544        (kbd "O") 'elpher-root-dir
2545        (kbd "s") 'elpher-show-history
2546        (kbd "S") 'elpher-show-visited-pages
2547        (kbd "r") 'elpher-redraw
2548        (kbd "R") 'elpher-reload
2549        (kbd "T") 'elpher-toggle-tls
2550        (kbd ".") 'elpher-view-raw
2551        (kbd "d") 'elpher-download
2552        (kbd "D") 'elpher-download-current
2553        (kbd "m") 'elpher-jump
2554        (kbd "i") 'elpher-info-link
2555        (kbd "I") 'elpher-info-current
2556        (kbd "c") 'elpher-copy-link-url
2557        (kbd "C") 'elpher-copy-current-url
2558        (kbd "a") 'elpher-bookmark-link
2559        (kbd "A") 'elpher-bookmark-current
2560        (kbd "B") 'elpher-show-bookmarks
2561        (kbd "!") 'elpher-set-gopher-coding-system
2562        (kbd "F") 'elpher-forget-current-certificate))
2563     map)
2564   "Keymap for gopher client.")
2565
2566 (define-derived-mode elpher-mode special-mode "elpher"
2567   "Major mode for elpher, an elisp gopher client.
2568
2569 This mode is automatically enabled by the interactive
2570 functions which initialize the client, namely
2571 `elpher', and `elpher-go'."
2572   (setq-local elpher-current-page nil)
2573   (setq-local elpher-history nil)
2574   (setq-local elpher-buffer-name (buffer-name))
2575   (setq-local bookmark-make-record-function #'elpher-bookmark-make-record)
2576   (setq-local imenu-create-index-function #'elpher-build-current-imenu-index))
2577
2578 (when (fboundp 'evil-set-initial-state)
2579   (evil-set-initial-state 'elpher-mode 'motion))
2580
2581
2582 ;;; Main start procedure
2583 ;;
2584
2585 ;;;###autoload
2586 (defun elpher (&optional arg)
2587   "Start elpher with default landing page.
2588 The buffer used for Elpher sessions is determined by the value of
2589 ‘elpher-buffer-name’.  If there is already an Elpher session active in
2590 that buffer, Emacs will simply switch to it.  Otherwise, a new session
2591 will begin.  A numeric prefix ARG (as in ‘\\[universal-argument] 42
2592 \\[execute-extended-command] elpher RET’) switches to the session with
2593 that number, creating it if necessary.  A non numeric prefix ARG means
2594 to create a new session.  Returns the buffer selected (or created)."
2595   (interactive "P")
2596   (let* ((name (default-value 'elpher-buffer-name))
2597          (buf (cond ((numberp arg)
2598                      (get-buffer-create (format "%s<%d>" name arg)))
2599                     (arg
2600                      (generate-new-buffer name))
2601                     (t
2602                      (get-buffer-create name)))))
2603     (pop-to-buffer-same-window buf)
2604     (unless (buffer-modified-p)
2605       (elpher-mode)
2606       (elpher-visit-page (elpher-make-start-page))
2607       "Started Elpher."))); Otherwise (elpher) evaluates to start page string.
2608
2609 ;;; elpher.el ends here